dist/B-Deparse/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
   3 # All rights reserved.
   4 # This module is free software; you can redistribute and/or modify
   5 # it under the same terms as Perl itself.
   6
   7 # This is based on the module of the same name by Malcolm Beattie,
   8 # but essentially none of his code remains.
   9
  10 package B::Deparse;
  11 use Carp;
  12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
  13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPpPAD_STATE
  15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  17          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  18          OPpSORT_REVERSE OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED
  19          OPpREVERSE_INPLACE
  20          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
  21          CVf_METHOD CVf_LVALUE
  22          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
  23          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED),
  24          ($] < 5.009 ? 'PMf_SKIPWHITE' : 'RXf_SKIPWHITE'),
  25          ($] < 5.011 ? 'CVf_LOCKED' : ());
  26 $VERSION = 0.95;
  27 use strict;
  28 use vars qw/$AUTOLOAD/;
  29 use warnings ();
  30
  31 BEGIN {
  32     # Easiest way to keep this code portable between 5.12.x and 5.10.x looks to
  33     # be to fake up a dummy CVf_LOCKED that will never actually be true.
  34     *CVf_LOCKED = sub () {0} unless defined &CVf_LOCKED;
  35 }
  36
  37 # Changes between 0.50 and 0.51:
  38 # - fixed nulled leave with live enter in sort { }
  39 # - fixed reference constants (\"str")
  40 # - handle empty programs gracefully
  41 # - handle infinte loops (for (;;) {}, while (1) {})
  42 # - differentiate between `for my $x ...' and `my $x; for $x ...'
  43 # - various minor cleanups
  44 # - moved globals into an object
  45 # - added `-u', like B::C
  46 # - package declarations using cop_stash
  47 # - subs, formats and code sorted by cop_seq
  48 # Changes between 0.51 and 0.52:
  49 # - added pp_threadsv (special variables under USE_5005THREADS)
  50 # - added documentation
  51 # Changes between 0.52 and 0.53:
  52 # - many changes adding precedence contexts and associativity
  53 # - added `-p' and `-s' output style options
  54 # - various other minor fixes
  55 # Changes between 0.53 and 0.54:
  56 # - added support for new `for (1..100)' optimization,
  57 #   thanks to Gisle Aas
  58 # Changes between 0.54 and 0.55:
  59 # - added support for new qr// construct
  60 # - added support for new pp_regcreset OP
  61 # Changes between 0.55 and 0.56:
  62 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  63 # - fixed $# on non-lexicals broken in last big rewrite
  64 # - added temporary fix for change in opcode of OP_STRINGIFY
  65 # - fixed problem in 0.54's for() patch in `for (@ary)'
  66 # - fixed precedence in conditional of ?:
  67 # - tweaked list paren elimination in `my($x) = @_'
  68 # - made continue-block detection trickier wrt. null ops
  69 # - fixed various prototype problems in pp_entersub
  70 # - added support for sub prototypes that never get GVs
  71 # - added unquoting for special filehandle first arg in truncate
  72 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
  73 # - added semicolons at the ends of blocks
  74 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
  75 # Changes between 0.56 and 0.561:
  76 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  77 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  78 # Changes between 0.561 and 0.57:
  79 # - stylistic changes to symbolic constant stuff
  80 # - handled scope in s///e replacement code
  81 # - added unquote option for expanding "" into concats, etc.
  82 # - split method and proto parts of pp_entersub into separate functions
  83 # - various minor cleanups
  84 # Changes after 0.57:
  85 # - added parens in \&foo (patch by Albert Dvornik)
  86 # Changes between 0.57 and 0.58:
  87 # - fixed `0' statements that weren't being printed
  88 # - added methods for use from other programs
  89 #   (based on patches from James Duncan and Hugo van der Sanden)
  90 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  91 # - added -sv to print something else instead of '???'
  92 # - preliminary version of utf8 tr/// handling
  93 # Changes after 0.58:
  94 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
  95 # - added support for Hugo's new OP_SETSTATE (like nextstate)
  96 # Changes between 0.58 and 0.59
  97 # - added support for Chip's OP_METHOD_NAMED
  98 # - added support for Ilya's OPpTARGET_MY optimization
  99 # - elided arrows before `()' subscripts when possible
 100 # Changes between 0.59 and 0.60
 101 # - support for method attribues was added
 102 # - some warnings fixed
 103 # - separate recognition of constant subs
 104 # - rewrote continue block handling, now recoginizing for loops
 105 # - added more control of expanding control structures
 106 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
 107 # - many bug-fixes
 108 # - support for pragmas and 'use'
 109 # - support for the little-used $[ variable
 110 # - support for __DATA__ sections
 111 # - UTF8 support
 112 # - BEGIN, CHECK, INIT and END blocks
 113 # - scoping of subroutine declarations fixed
 114 # - compile-time output from the input program can be suppressed, so that the
 115 #   output is just the deparsed code. (a change to O.pm in fact)
 116 # - our() declarations
 117 # - *all* the known bugs are now listed in the BUGS section
 118 # - comprehensive test mechanism (TEST -deparse)
 119 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
 120 # - bug-fixes
 121 # - new switch -P
 122 # - support for command-line switches (-l, -0, etc.)
 123 # Changes between 0.63 and 0.64
 124 # - support for //, CHECK blocks, and assertions
 125 # - improved handling of foreach loops and lexicals
 126 # - option to use Data::Dumper for constants
 127 # - more bug fixes
 128 # - discovered lots more bugs not yet fixed
 129 #
 130 # ...
 131 #
 132 # Changes between 0.72 and 0.73
 133 # - support new switch constructs
 134
 135 # Todo:
 136 #  (See also BUGS section at the end of this file)
 137 #
 138 # - finish tr/// changes
 139 # - add option for even more parens (generalize \&foo change)
 140 # - left/right context
 141 # - copy comments (look at real text with $^P?)
 142 # - avoid semis in one-statement blocks
 143 # - associativity of &&=, ||=, ?:
 144 # - ',' => '=>' (auto-unquote?)
 145 # - break long lines ("\r" as discretionary break?)
 146 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 147 # - more style options: brace style, hex vs. octal, quotes, ...
 148 # - print big ints as hex/octal instead of decimal (heuristic?)
 149 # - handle `my $x if 0'?
 150 # - version using op_next instead of op_first/sibling?
 151 # - avoid string copies (pass arrays, one big join?)
 152 # - here-docs?
 153
 154 # Current test.deparse failures
 155 # comp/hints 6 - location of BEGIN blocks wrt. block openings
 156 # run/switchI 1 - missing -I switches entirely
 157 #    perl -Ifoo -e 'print @INC'
 158 # op/caller 2 - warning mask propagates backwards before warnings::register
 159 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
 160 # op/getpid 2 - can't assign to shared my() declaration (threads only)
 161 #    'my $x : shared = 5'
 162 # op/override 7 - parens on overriden require change v-string interpretation
 163 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
 164 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
 165 # op/pat 774 - losing Unicode-ness of Latin1-only strings
 166 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
 167 # op/recurse 12 - missing parens on recursive call makes it look like method
 168 #    'sub f { f($x) }'
 169 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
 170 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
 171 # op/tiehandle compile - "use strict" deparsed in the wrong place
 172 # uni/tr_ several
 173 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
 174 # ext/Data/Dumper/t/dumper compile
 175 # ext/DB_file/several
 176 # ext/Encode/several
 177 # ext/Ernno/Errno warnings
 178 # ext/IO/lib/IO/t/io_sel 23
 179 # ext/PerlIO/t/encoding compile
 180 # ext/POSIX/t/posix 6
 181 # ext/Socket/Socket 8
 182 # ext/Storable/t/croak compile
 183 # lib/Attribute/Handlers/t/multi compile
 184 # lib/bignum/ several
 185 # lib/charnames 35
 186 # lib/constant 32
 187 # lib/English 40
 188 # lib/ExtUtils/t/bytes 4
 189 # lib/File/DosGlob compile
 190 # lib/Filter/Simple/t/data 1
 191 # lib/Math/BigInt/t/constant 1
 192 # lib/Net/t/config Deparse-warning
 193 # lib/overload compile
 194 # lib/Switch/ several
 195 # lib/Symbol 4
 196 # lib/Test/Simple several
 197 # lib/Term/Complete
 198 # lib/Tie/File/t/29_downcopy 5
 199 # lib/vars 22
 200
 201 # Object fields (were globals):
 202 #
 203 # avoid_local:
 204 # (local($a), local($b)) and local($a, $b) have the same internal
 205 # representation but the short form looks better. We notice we can
 206 # use a large-scale local when checking the list, but need to prevent
 207 # individual locals too. This hash holds the addresses of OPs that
 208 # have already had their local-ness accounted for. The same thing
 209 # is done with my().
 210 #
 211 # curcv:
 212 # CV for current sub (or main program) being deparsed
 213 #
 214 # curcvlex:
 215 # Cached hash of lexical variables for curcv: keys are names,
 216 # each value is an array of pairs, indicating the cop_seq of scopes
 217 # in which a var of that name is valid.
 218 #
 219 # curcop:
 220 # COP for statement being deparsed
 221 #
 222 # curstash:
 223 # name of the current package for deparsed code
 224 #
 225 # subs_todo:
 226 # array of [cop_seq, CV, is_format?] for subs and formats we still
 227 # want to deparse
 228 #
 229 # protos_todo:
 230 # as above, but [name, prototype] for subs that never got a GV
 231 #
 232 # subs_done, forms_done:
 233 # keys are addresses of GVs for subs and formats we've already
 234 # deparsed (or at least put into subs_todo)
 235 #
 236 # subs_declared
 237 # keys are names of subs for which we've printed declarations.
 238 # That means we can omit parentheses from the arguments.
 239 #
 240 # subs_deparsed
 241 # Keeps track of fully qualified names of all deparsed subs.
 242 #
 243 # parens: -p
 244 # linenums: -l
 245 # unquote: -q
 246 # cuddle: ` ' or `\n', depending on -sC
 247 # indent_size: -si
 248 # use_tabs: -sT
 249 # ex_const: -sv
 250
 251 # A little explanation of how precedence contexts and associativity
 252 # work:
 253 #
 254 # deparse() calls each per-op subroutine with an argument $cx (short
 255 # for context, but not the same as the cx* in the perl core), which is
 256 # a number describing the op's parents in terms of precedence, whether
 257 # they're inside an expression or at statement level, etc.  (see
 258 # chart below). When ops with children call deparse on them, they pass
 259 # along their precedence. Fractional values are used to implement
 260 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
 261 # parentheses hacks. The major disadvantage of this scheme is that
 262 # it doesn't know about right sides and left sides, so say if you
 263 # assign a listop to a variable, it can't tell it's allowed to leave
 264 # the parens off the listop.
 265
 266 # Precedences:
 267 # 26             [TODO] inside interpolation context ("")
 268 # 25 left        terms and list operators (leftward)
 269 # 24 left        ->
 270 # 23 nonassoc    ++ --
 271 # 22 right       **
 272 # 21 right       ! ~ \ and unary + and -
 273 # 20 left        =~ !~
 274 # 19 left        * / % x
 275 # 18 left        + - .
 276 # 17 left        << >>
 277 # 16 nonassoc    named unary operators
 278 # 15 nonassoc    < > <= >= lt gt le ge
 279 # 14 nonassoc    == != <=> eq ne cmp
 280 # 13 left        &
 281 # 12 left        | ^
 282 # 11 left        &&
 283 # 10 left        ||
 284 #  9 nonassoc    ..  ...
 285 #  8 right       ?:
 286 #  7 right       = += -= *= etc.
 287 #  6 left        , =>
 288 #  5 nonassoc    list operators (rightward)
 289 #  4 right       not
 290 #  3 left        and
 291 #  2 left        or xor
 292 #  1             statement modifiers
 293 #  0.5           statements, but still print scopes as do { ... }
 294 #  0             statement level
 295
 296 # Nonprinting characters with special meaning:
 297 # \cS - steal parens (see maybe_parens_unop)
 298 # \n - newline and indent
 299 # \t - increase indent
 300 # \b - decrease indent (`outdent')
 301 # \f - flush left (no indent)
 302 # \cK - kill following semicolon, if any
 303
 304 sub null {
 305     my $op = shift;
 306     return class($op) eq "NULL";
 307 }
 308
 309 sub todo {
 310     my $self = shift;
 311     my($cv, $is_form) = @_;
 312     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 313     my $seq;
 314     if ($cv->OUTSIDE_SEQ) {
 315         $seq = $cv->OUTSIDE_SEQ;
 316     } elsif (!null($cv->START) and is_state($cv->START)) {
 317         $seq = $cv->START->cop_seq;
 318     } else {
 319         $seq = 0;
 320     }
 321     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 322     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 323         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 324     }
 325 }
 326
 327 sub next_todo {
 328     my $self = shift;
 329     my $ent = shift @{$self->{'subs_todo'}};
 330     my $cv = $ent->[1];
 331     my $gv = $cv->GV;
 332     my $name = $self->gv_name($gv);
 333     if ($ent->[2]) {
 334         return "format $name =\n"
 335             . $self->deparse_format($ent->[1]). "\n";
 336     } else {
 337         $self->{'subs_declared'}{$name} = 1;
 338         if ($name eq "BEGIN") {
 339             my $use_dec = $self->begin_is_use($cv);
 340             if (defined ($use_dec) and $self->{'expand'} < 5) {
 341                 return () if 0 == length($use_dec);
 342                 return $use_dec;
 343             }
 344         }
 345         my $l = '';
 346         if ($self->{'linenums'}) {
 347             my $line = $gv->LINE;
 348             my $file = $gv->FILE;
 349             $l = "\n\f#line $line \"$file\"\n";
 350         }
 351         my $p = '';
 352         if (class($cv->STASH) ne "SPECIAL") {
 353             my $stash = $cv->STASH->NAME;
 354             if ($stash ne $self->{'curstash'}) {
 355                 $p = "package $stash;\n";
 356                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
 357                 $self->{'curstash'} = $stash;
 358             }
 359             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
 360         }
 361         return "${p}${l}sub $name " . $self->deparse_sub($cv);
 362     }
 363 }
 364
 365 # Return a "use" declaration for this BEGIN block, if appropriate
 366 sub begin_is_use {
 367     my ($self, $cv) = @_;
 368     my $root = $cv->ROOT;
 369     local @$self{qw'curcv curcvlex'} = ($cv);
 370 #require B::Debug;
 371 #B::walkoptree($cv->ROOT, "debug");
 372     my $lineseq = $root->first;
 373     return if $lineseq->name ne "lineseq";
 374
 375     my $req_op = $lineseq->first->sibling;
 376     return if $req_op->name ne "require";
 377
 378     my $module;
 379     if ($req_op->first->private & OPpCONST_BARE) {
 380         # Actually it should always be a bareword
 381         $module = $self->const_sv($req_op->first)->PV;
 382         $module =~ s[/][::]g;
 383         $module =~ s/.pm$//;
 384     }
 385     else {
 386         $module = $self->const($self->const_sv($req_op->first), 6);
 387     }
 388
 389     my $version;
 390     my $version_op = $req_op->sibling;
 391     return if class($version_op) eq "NULL";
 392     if ($version_op->name eq "lineseq") {
 393         # We have a version parameter; skip nextstate & pushmark
 394         my $constop = $version_op->first->next->next;
 395
 396         return unless $self->const_sv($constop)->PV eq $module;
 397         $constop = $constop->sibling;
 398         $version = $self->const_sv($constop);
 399         if (class($version) eq "IV") {
 400             $version = $version->int_value;
 401         } elsif (class($version) eq "NV") {
 402             $version = $version->NV;
 403         } elsif (class($version) ne "PVMG") {
 404             # Includes PVIV and PVNV
 405             $version = $version->PV;
 406         } else {
 407             # version specified as a v-string
 408             $version = 'v'.join '.', map ord, split //, $version->PV;
 409         }
 410         $constop = $constop->sibling;
 411         return if $constop->name ne "method_named";
 412         return if $self->const_sv($constop)->PV ne "VERSION";
 413     }
 414
 415     $lineseq = $version_op->sibling;
 416     return if $lineseq->name ne "lineseq";
 417     my $entersub = $lineseq->first->sibling;
 418     if ($entersub->name eq "stub") {
 419         return "use $module $version ();\n" if defined $version;
 420         return "use $module ();\n";
 421     }
 422     return if $entersub->name ne "entersub";
 423
 424     # See if there are import arguments
 425     my $args = '';
 426
 427     my $svop = $entersub->first->sibling; # Skip over pushmark
 428     return unless $self->const_sv($svop)->PV eq $module;
 429
 430     # Pull out the arguments
 431     for ($svop=$svop->sibling; $svop->name ne "method_named";
 432                 $svop = $svop->sibling) {
 433         $args .= ", " if length($args);
 434         $args .= $self->deparse($svop, 6);
 435     }
 436
 437     my $use = 'use';
 438     my $method_named = $svop;
 439     return if $method_named->name ne "method_named";
 440     my $method_name = $self->const_sv($method_named)->PV;
 441
 442     if ($method_name eq "unimport") {
 443         $use = 'no';
 444     }
 445
 446     # Certain pragmas are dealt with using hint bits,
 447     # so we ignore them here
 448     if ($module eq 'strict' || $module eq 'integer'
 449         || $module eq 'bytes' || $module eq 'warnings'
 450         || $module eq 'feature') {
 451         return "";
 452     }
 453
 454     if (defined $version && length $args) {
 455         return "$use $module $version ($args);\n";
 456     } elsif (defined $version) {
 457         return "$use $module $version;\n";
 458     } elsif (length $args) {
 459         return "$use $module ($args);\n";
 460     } else {
 461         return "$use $module;\n";
 462     }
 463 }
 464
 465 sub stash_subs {
 466     my ($self, $pack) = @_;
 467     my (@ret, $stash);
 468     if (!defined $pack) {
 469         $pack = '';
 470         $stash = \%::;
 471     }
 472     else {
 473         $pack =~ s/(::)?$/::/;
 474         no strict 'refs';
 475         $stash = \%$pack;
 476     }
 477     my %stash = svref_2object($stash)->ARRAY;
 478     while (my ($key, $val) = each %stash) {
 479         my $class = class($val);
 480         if ($class eq "PV") {
 481             # Just a prototype. As an ugly but fairly effective way
 482             # to find out if it belongs here is to see if the AUTOLOAD
 483             # (if any) for the stash was defined in one of our files.
 484             my $A = $stash{"AUTOLOAD"};
 485             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 486                 && class($A->CV) eq "CV") {
 487                 my $AF = $A->FILE;
 488                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 489             }
 490             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 491         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
 492             # Just a name. As above.
 493             # But skip proxy constant subroutines, as some form of perl-space
 494             # visible code must have created them, be it a use statement, or
 495             # some direct symbol-table manipulation code that we will Deparse
 496             my $A = $stash{"AUTOLOAD"};
 497             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 498                 && class($A->CV) eq "CV") {
 499                 my $AF = $A->FILE;
 500                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 501             }
 502             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 503         } elsif ($class eq "GV") {
 504             if (class(my $cv = $val->CV) ne "SPECIAL") {
 505                 next if $self->{'subs_done'}{$$val}++;
 506                 next if $$val != ${$cv->GV};   # Ignore imposters
 507                 $self->todo($cv, 0);
 508             }
 509             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 510                 next if $self->{'forms_done'}{$$val}++;
 511                 next if $$val != ${$cv->GV};   # Ignore imposters
 512                 $self->todo($cv, 1);
 513             }
 514             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 515                 $self->stash_subs($pack . $key)
 516                     unless $pack eq '' && $key eq 'main::';
 517                     # avoid infinite recursion
 518             }
 519         }
 520     }
 521 }
 522
 523 sub print_protos {
 524     my $self = shift;
 525     my $ar;
 526     my @ret;
 527     foreach $ar (@{$self->{'protos_todo'}}) {
 528         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 529         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 530     }
 531     delete $self->{'protos_todo'};
 532     return @ret;
 533 }
 534
 535 sub style_opts {
 536     my $self = shift;
 537     my $opts = shift;
 538     my $opt;
 539     while (length($opt = substr($opts, 0, 1))) {
 540         if ($opt eq "C") {
 541             $self->{'cuddle'} = " ";
 542             $opts = substr($opts, 1);
 543         } elsif ($opt eq "i") {
 544             $opts =~ s/^i(\d+)//;
 545             $self->{'indent_size'} = $1;
 546         } elsif ($opt eq "T") {
 547             $self->{'use_tabs'} = 1;
 548             $opts = substr($opts, 1);
 549         } elsif ($opt eq "v") {
 550             $opts =~ s/^v([^.]*)(.|$)//;
 551             $self->{'ex_const'} = $1;
 552         }
 553     }
 554 }
 555
 556 sub new {
 557     my $class = shift;
 558     my $self = bless {}, $class;
 559     $self->{'cuddle'} = "\n";
 560     $self->{'curcop'} = undef;
 561     $self->{'curstash'} = "main";
 562     $self->{'ex_const'} = "'???'";
 563     $self->{'expand'} = 0;
 564     $self->{'files'} = {};
 565     $self->{'indent_size'} = 4;
 566     $self->{'linenums'} = 0;
 567     $self->{'parens'} = 0;
 568     $self->{'subs_todo'} = [];
 569     $self->{'unquote'} = 0;
 570     $self->{'use_dumper'} = 0;
 571     $self->{'use_tabs'} = 0;
 572
 573     $self->{'ambient_arybase'} = 0;
 574     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 575     $self->{'ambient_hints'} = 0;
 576     $self->{'ambient_hinthash'} = undef;
 577     $self->init();
 578
 579     while (my $arg = shift @_) {
 580         if ($arg eq "-d") {
 581             $self->{'use_dumper'} = 1;
 582             require Data::Dumper;
 583         } elsif ($arg =~ /^-f(.*)/) {
 584             $self->{'files'}{$1} = 1;
 585         } elsif ($arg eq "-l") {
 586             $self->{'linenums'} = 1;
 587         } elsif ($arg eq "-p") {
 588             $self->{'parens'} = 1;
 589         } elsif ($arg eq "-P") {
 590             $self->{'noproto'} = 1;
 591         } elsif ($arg eq "-q") {
 592             $self->{'unquote'} = 1;
 593         } elsif (substr($arg, 0, 2) eq "-s") {
 594             $self->style_opts(substr $arg, 2);
 595         } elsif ($arg =~ /^-x(\d)$/) {
 596             $self->{'expand'} = $1;
 597         }
 598     }
 599     return $self;
 600 }
 601
 602 {
 603     # Mask out the bits that L<warnings::register> uses
 604     my $WARN_MASK;
 605     BEGIN {
 606         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 607     }
 608     sub WARN_MASK () {
 609         return $WARN_MASK;
 610     }
 611 }
 612
 613 # Initialise the contextual information, either from
 614 # defaults provided with the ambient_pragmas method,
 615 # or from perl's own defaults otherwise.
 616 sub init {
 617     my $self = shift;
 618
 619     $self->{'arybase'}  = $self->{'ambient_arybase'};
 620     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 621                                 ? $self->{'ambient_warnings'} & WARN_MASK
 622                                 : undef;
 623     $self->{'hints'}    = $self->{'ambient_hints'};
 624     $self->{'hints'} &= 0xFF if $] < 5.009;
 625     $self->{'hinthash'} = $self->{'ambient_hinthash'};
 626
 627     # also a convenient place to clear out subs_declared
 628     delete $self->{'subs_declared'};
 629 }
 630
 631 sub compile {
 632     my(@args) = @_;
 633     return sub {
 634         my $self = B::Deparse->new(@args);
 635         # First deparse command-line args
 636         if (defined $^I) { # deparse -i
 637             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
 638         }
 639         if ($^W) { # deparse -w
 640             print qq(BEGIN { \$^W = $^W; }\n);
 641         }
 642         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 643             my $fs = perlstring($/) || 'undef';
 644             my $bs = perlstring($O::savebackslash) || 'undef';
 645             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 646         }
 647         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 648         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
 649             ? B::unitcheck_av->ARRAY
 650             : ();
 651         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
 652         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 653         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 654         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
 655             $self->todo($block, 0);
 656         }
 657         $self->stash_subs();
 658         local($SIG{"__DIE__"}) =
 659           sub {
 660               if ($self->{'curcop'}) {
 661                   my $cop = $self->{'curcop'};
 662                   my($line, $file) = ($cop->line, $cop->file);
 663                   print STDERR "While deparsing $file near line $line,\n";
 664               }
 665             };
 666         $self->{'curcv'} = main_cv;
 667         $self->{'curcvlex'} = undef;
 668         print $self->print_protos;
 669         @{$self->{'subs_todo'}} =
 670           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 671         print $self->indent($self->deparse_root(main_root)), "\n"
 672           unless null main_root;
 673         my @text;
 674         while (scalar(@{$self->{'subs_todo'}})) {
 675             push @text, $self->next_todo;
 676         }
 677         print $self->indent(join("", @text)), "\n" if @text;
 678
 679         # Print __DATA__ section, if necessary
 680         no strict 'refs';
 681         my $laststash = defined $self->{'curcop'}
 682             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 683         if (defined *{$laststash."::DATA"}{IO}) {
 684             print "package $laststash;\n"
 685                 unless $laststash eq $self->{'curstash'};
 686             print "__DATA__\n";
 687             print readline(*{$laststash."::DATA"});
 688         }
 689     }
 690 }
 691
 692 sub coderef2text {
 693     my $self = shift;
 694     my $sub = shift;
 695     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
 696
 697     $self->init();
 698     return $self->indent($self->deparse_sub(svref_2object($sub)));
 699 }
 700
 701 sub ambient_pragmas {
 702     my $self = shift;
 703     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
 704
 705     while (@_ > 1) {
 706         my $name = shift();
 707         my $val  = shift();
 708
 709         if ($name eq 'strict') {
 710             require strict;
 711
 712             if ($val eq 'none') {
 713                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 714                 next();
 715             }
 716
 717             my @names;
 718             if ($val eq "all") {
 719                 @names = qw/refs subs vars/;
 720             }
 721             elsif (ref $val) {
 722                 @names = @$val;
 723             }
 724             else {
 725                 @names = split' ', $val;
 726             }
 727             $hint_bits |= strict::bits(@names);
 728         }
 729
 730         elsif ($name eq '$[') {
 731             $arybase = $val;
 732         }
 733
 734         elsif ($name eq 'integer'
 735             || $name eq 'bytes'
 736             || $name eq 'utf8') {
 737             require "$name.pm";
 738             if ($val) {
 739                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 740             }
 741             else {
 742                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 743             }
 744         }
 745
 746         elsif ($name eq 're') {
 747             require re;
 748             if ($val eq 'none') {
 749                 $hint_bits &= ~re::bits(qw/taint eval/);
 750                 next();
 751             }
 752
 753             my @names;
 754             if ($val eq 'all') {
 755                 @names = qw/taint eval/;
 756             }
 757             elsif (ref $val) {
 758                 @names = @$val;
 759             }
 760             else {
 761                 @names = split' ',$val;
 762             }
 763             $hint_bits |= re::bits(@names);
 764         }
 765
 766         elsif ($name eq 'warnings') {
 767             if ($val eq 'none') {
 768                 $warning_bits = $warnings::NONE;
 769                 next();
 770             }
 771
 772             my @names;
 773             if (ref $val) {
 774                 @names = @$val;
 775             }
 776             else {
 777                 @names = split/\s+/, $val;
 778             }
 779
 780             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 781             $warning_bits |= warnings::bits(@names);
 782         }
 783
 784         elsif ($name eq 'warning_bits') {
 785             $warning_bits = $val;
 786         }
 787
 788         elsif ($name eq 'hint_bits') {
 789             $hint_bits = $val;
 790         }
 791
 792         elsif ($name eq '%^H') {
 793             $hinthash = $val;
 794         }
 795
 796         else {
 797             croak "Unknown pragma type: $name";
 798         }
 799     }
 800     if (@_) {
 801         croak "The ambient_pragmas method expects an even number of args";
 802     }
 803
 804     $self->{'ambient_arybase'} = $arybase;
 805     $self->{'ambient_warnings'} = $warning_bits;
 806     $self->{'ambient_hints'} = $hint_bits;
 807     $self->{'ambient_hinthash'} = $hinthash;
 808 }
 809
 810 # This method is the inner loop, so try to keep it simple
 811 sub deparse {
 812     my $self = shift;
 813     my($op, $cx) = @_;
 814
 815     Carp::confess("Null op in deparse") if !defined($op)
 816                                         || class($op) eq "NULL";
 817     my $meth = "pp_" . $op->name;
 818     return $self->$meth($op, $cx);
 819 }
 820
 821 sub indent {
 822     my $self = shift;
 823     my $txt = shift;
 824     my @lines = split(/\n/, $txt);
 825     my $leader = "";
 826     my $level = 0;
 827     my $line;
 828     for $line (@lines) {
 829         my $cmd = substr($line, 0, 1);
 830         if ($cmd eq "\t" or $cmd eq "\b") {
 831             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 832             if ($self->{'use_tabs'}) {
 833                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 834             } else {
 835                 $leader = " " x $level;
 836             }
 837             $line = substr($line, 1);
 838         }
 839         if (substr($line, 0, 1) eq "\f") {
 840             $line = substr($line, 1); # no indent
 841         } else {
 842             $line = $leader . $line;
 843         }
 844         $line =~ s/\cK;?//g;
 845     }
 846     return join("\n", @lines);
 847 }
 848
 849 sub deparse_sub {
 850     my $self = shift;
 851     my $cv = shift;
 852     my $proto = "";
 853 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 854 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 855     local $self->{'curcop'} = $self->{'curcop'};
 856     if ($cv->FLAGS & SVf_POK) {
 857         $proto = "(". $cv->PV . ") ";
 858     }
 859     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
 860         $proto .= ": ";
 861         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 862         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 863         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 864     }
 865
 866     local($self->{'curcv'}) = $cv;
 867     local($self->{'curcvlex'});
 868     local(@$self{qw'curstash warnings hints hinthash'})
 869                 = @$self{qw'curstash warnings hints hinthash'};
 870     my $body;
 871     if (not null $cv->ROOT) {
 872         my $lineseq = $cv->ROOT->first;
 873         if ($lineseq->name eq "lineseq") {
 874             my @ops;
 875             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 876                 push @ops, $o;
 877             }
 878             $body = $self->lineseq(undef, @ops).";";
 879             my $scope_en = $self->find_scope_en($lineseq);
 880             if (defined $scope_en) {
 881                 my $subs = join"", $self->seq_subs($scope_en);
 882                 $body .= ";\n$subs" if length($subs);
 883             }
 884         }
 885         else {
 886             $body = $self->deparse($cv->ROOT->first, 0);
 887         }
 888     }
 889     else {
 890         my $sv = $cv->const_sv;
 891         if ($$sv) {
 892             # uh-oh. inlinable sub... format it differently
 893             return $proto . "{ " . $self->const($sv, 0) . " }\n";
 894         } else { # XSUB? (or just a declaration)
 895             return "$proto;\n";
 896         }
 897     }
 898     return $proto ."{\n\t$body\n\b}" ."\n";
 899 }
 900
 901 sub deparse_format {
 902     my $self = shift;
 903     my $form = shift;
 904     my @text;
 905     local($self->{'curcv'}) = $form;
 906     local($self->{'curcvlex'});
 907     local($self->{'in_format'}) = 1;
 908     local(@$self{qw'curstash warnings hints hinthash'})
 909                 = @$self{qw'curstash warnings hints hinthash'};
 910     my $op = $form->ROOT;
 911     my $kid;
 912     return "\f." if $op->first->name eq 'stub'
 913                 || $op->first->name eq 'nextstate';
 914     $op = $op->first->first; # skip leavewrite, lineseq
 915     while (not null $op) {
 916         $op = $op->sibling; # skip nextstate
 917         my @exprs;
 918         $kid = $op->first->sibling; # skip pushmark
 919         push @text, "\f".$self->const_sv($kid)->PV;
 920         $kid = $kid->sibling;
 921         for (; not null $kid; $kid = $kid->sibling) {
 922             push @exprs, $self->deparse($kid, 0);
 923         }
 924         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 925         $op = $op->sibling;
 926     }
 927     return join("", @text) . "\f.";
 928 }
 929
 930 sub is_scope {
 931     my $op = shift;
 932     return $op->name eq "leave" || $op->name eq "scope"
 933       || $op->name eq "lineseq"
 934         || ($op->name eq "null" && class($op) eq "UNOP"
 935             && (is_scope($op->first) || $op->first->name eq "enter"));
 936 }
 937
 938 sub is_state {
 939     my $name = $_[0]->name;
 940     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 941 }
 942
 943 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
 944     my $op = shift;
 945     return (!null($op) and null($op->sibling)
 946             and $op->name eq "null" and class($op) eq "UNOP"
 947             and (($op->first->name =~ /^(and|or)$/
 948                   and $op->first->first->sibling->name eq "lineseq")
 949                  or ($op->first->name eq "lineseq"
 950                      and not null $op->first->first->sibling
 951                      and $op->first->first->sibling->name eq "unstack")
 952                  ));
 953 }
 954
 955 # Check if the op and its sibling are the initialization and the rest of a
 956 # for (..;..;..) { ... } loop
 957 sub is_for_loop {
 958     my $op = shift;
 959     # This OP might be almost anything, though it won't be a
 960     # nextstate. (It's the initialization, so in the canonical case it
 961     # will be an sassign.) The sibling is a lineseq whose first child
 962     # is a nextstate and whose second is a leaveloop.
 963     my $lseq = $op->sibling;
 964     if (!is_state $op and !null($lseq) and $lseq->name eq "lineseq") {
 965         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
 966             && (my $sib = $lseq->first->sibling)) {
 967             return (!null($sib) && $sib->name eq "leaveloop");
 968         }
 969     }
 970     return 0;
 971 }
 972
 973 sub is_scalar {
 974     my $op = shift;
 975     return ($op->name eq "rv2sv" or
 976             $op->name eq "padsv" or
 977             $op->name eq "gv" or # only in array/hash constructs
 978             $op->flags & OPf_KIDS && !null($op->first)
 979               && $op->first->name eq "gvsv");
 980 }
 981
 982 sub maybe_parens {
 983     my $self = shift;
 984     my($text, $cx, $prec) = @_;
 985     if ($prec < $cx              # unary ops nest just fine
 986         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
 987         or $self->{'parens'})
 988     {
 989         $text = "($text)";
 990         # In a unop, let parent reuse our parens; see maybe_parens_unop
 991         $text = "\cS" . $text if $cx == 16;
 992         return $text;
 993     } else {
 994         return $text;
 995     }
 996 }
 997
 998 # same as above, but get around the `if it looks like a function' rule
 999 sub maybe_parens_unop {
1000     my $self = shift;
1001     my($name, $kid, $cx) = @_;
1002     if ($cx > 16 or $self->{'parens'}) {
1003         $kid =  $self->deparse($kid, 1);
1004         if ($name eq "umask" && $kid =~ /^\d+$/) {
1005             $kid = sprintf("%#o", $kid);
1006         }
1007         return "$name($kid)";
1008     } else {
1009         $kid = $self->deparse($kid, 16);
1010         if ($name eq "umask" && $kid =~ /^\d+$/) {
1011             $kid = sprintf("%#o", $kid);
1012         }
1013         if (substr($kid, 0, 1) eq "\cS") {
1014             # use kid's parens
1015             return $name . substr($kid, 1);
1016         } elsif (substr($kid, 0, 1) eq "(") {
1017             # avoid looks-like-a-function trap with extra parens
1018             # (`+' can lead to ambiguities)
1019             return "$name(" . $kid  . ")";
1020         } else {
1021             return "$name $kid";
1022         }
1023     }
1024 }
1025
1026 sub maybe_parens_func {
1027     my $self = shift;
1028     my($func, $text, $cx, $prec) = @_;
1029     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1030         return "$func($text)";
1031     } else {
1032         return "$func $text";
1033     }
1034 }
1035
1036 sub maybe_local {
1037     my $self = shift;
1038     my($op, $cx, $text) = @_;
1039     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1040     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1041         and not $self->{'avoid_local'}{$$op}) {
1042         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1043         if( $our_local eq 'our' ) {
1044             # XXX This assertion fails code with non-ASCII identifiers,
1045             # like ./ext/Encode/t/jperl.t
1046             die "Unexpected our($text)\n" unless $text =~ /^\W(\w+::)*\w+\z/;
1047             $text =~ s/(\w+::)+//;
1048         }
1049         if (want_scalar($op)) {
1050             return "$our_local $text";
1051         } else {
1052             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1053         }
1054     } else {
1055         return $text;
1056     }
1057 }
1058
1059 sub maybe_targmy {
1060     my $self = shift;
1061     my($op, $cx, $func, @args) = @_;
1062     if ($op->private & OPpTARGET_MY) {
1063         my $var = $self->padname($op->targ);
1064         my $val = $func->($self, $op, 7, @args);
1065         return $self->maybe_parens("$var = $val", $cx, 7);
1066     } else {
1067         return $func->($self, $op, $cx, @args);
1068     }
1069 }
1070
1071 sub padname_sv {
1072     my $self = shift;
1073     my $targ = shift;
1074     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1075 }
1076
1077 sub maybe_my {
1078     my $self = shift;
1079     my($op, $cx, $text) = @_;
1080     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1081         my $my = $op->private & OPpPAD_STATE ? "state" : "my";
1082         if (want_scalar($op)) {
1083             return "$my $text";
1084         } else {
1085             return $self->maybe_parens_func($my, $text, $cx, 16);
1086         }
1087     } else {
1088         return $text;
1089     }
1090 }
1091
1092 # The following OPs don't have functions:
1093
1094 # pp_padany -- does not exist after parsing
1095
1096 sub AUTOLOAD {
1097     if ($AUTOLOAD =~ s/^.*::pp_//) {
1098         warn "unexpected OP_".uc $AUTOLOAD;
1099         return "XXX";
1100     } else {
1101         die "Undefined subroutine $AUTOLOAD called";
1102     }
1103 }
1104
1105 sub DESTROY {}  #       Do not AUTOLOAD
1106
1107 # $root should be the op which represents the root of whatever
1108 # we're sequencing here. If it's undefined, then we don't append
1109 # any subroutine declarations to the deparsed ops, otherwise we
1110 # append appropriate declarations.
1111 sub lineseq {
1112     my($self, $root, @ops) = @_;
1113     my($expr, @exprs);
1114
1115     my $out_cop = $self->{'curcop'};
1116     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1117     my $limit_seq;
1118     if (defined $root) {
1119         $limit_seq = $out_seq;
1120         my $nseq;
1121         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1122         $limit_seq = $nseq if !defined($limit_seq)
1123                            or defined($nseq) && $nseq < $limit_seq;
1124     }
1125     $limit_seq = $self->{'limit_seq'}
1126         if defined($self->{'limit_seq'})
1127         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1128     local $self->{'limit_seq'} = $limit_seq;
1129
1130     $self->walk_lineseq($root, \@ops,
1131                        sub { push @exprs, $_[0]} );
1132
1133     my $body = join(";\n", grep {length} @exprs);
1134     my $subs = "";
1135     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1136         $subs = join "\n", $self->seq_subs($limit_seq);
1137     }
1138     return join(";\n", grep {length} $body, $subs);
1139 }
1140
1141 sub scopeop {
1142     my($real_block, $self, $op, $cx) = @_;
1143     my $kid;
1144     my @kids;
1145
1146     local(@$self{qw'curstash warnings hints hinthash'})
1147                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1148     if ($real_block) {
1149         $kid = $op->first->sibling; # skip enter
1150         if (is_miniwhile($kid)) {
1151             my $top = $kid->first;
1152             my $name = $top->name;
1153             if ($name eq "and") {
1154                 $name = "while";
1155             } elsif ($name eq "or") {
1156                 $name = "until";
1157             } else { # no conditional -> while 1 or until 0
1158                 return $self->deparse($top->first, 1) . " while 1";
1159             }
1160             my $cond = $top->first;
1161             my $body = $cond->sibling->first; # skip lineseq
1162             $cond = $self->deparse($cond, 1);
1163             $body = $self->deparse($body, 1);
1164             return "$body $name $cond";
1165         }
1166     } else {
1167         $kid = $op->first;
1168     }
1169     for (; !null($kid); $kid = $kid->sibling) {
1170         push @kids, $kid;
1171     }
1172     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1173         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1174     } else {
1175         my $lineseq = $self->lineseq($op, @kids);
1176         return (length ($lineseq) ? "$lineseq;" : "");
1177     }
1178 }
1179
1180 sub pp_scope { scopeop(0, @_); }
1181 sub pp_lineseq { scopeop(0, @_); }
1182 sub pp_leave { scopeop(1, @_); }
1183
1184 # This is a special case of scopeop and lineseq, for the case of the
1185 # main_root. The difference is that we print the output statements as
1186 # soon as we get them, for the sake of impatient users.
1187 sub deparse_root {
1188     my $self = shift;
1189     my($op) = @_;
1190     local(@$self{qw'curstash warnings hints hinthash'})
1191       = @$self{qw'curstash warnings hints hinthash'};
1192     my @kids;
1193     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1194     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1195         push @kids, $kid;
1196     }
1197     $self->walk_lineseq($op, \@kids,
1198                         sub { print $self->indent($_[0].';');
1199                               print "\n" unless $_[1] == $#kids;
1200                           });
1201 }
1202
1203 sub walk_lineseq {
1204     my ($self, $op, $kids, $callback) = @_;
1205     my @kids = @$kids;
1206     for (my $i = 0; $i < @kids; $i++) {
1207         my $expr = "";
1208         if (is_state $kids[$i]) {
1209             $expr = $self->deparse($kids[$i++], 0);
1210             if ($i > $#kids) {
1211                 $callback->($expr, $i);
1212                 last;
1213             }
1214         }
1215         if (is_for_loop($kids[$i])) {
1216             $callback->($expr . $self->for_loop($kids[$i], 0), $i++);
1217             next;
1218         }
1219         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1220         $expr =~ s/;\n?\z//;
1221         $callback->($expr, $i);
1222     }
1223 }
1224
1225 # The BEGIN {} is used here because otherwise this code isn't executed
1226 # when you run B::Deparse on itself.
1227 my %globalnames;
1228 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1229             "ENV", "ARGV", "ARGVOUT", "_"); }
1230
1231 sub gv_name {
1232     my $self = shift;
1233     my $gv = shift;
1234 Carp::confess() unless ref($gv) eq "B::GV";
1235     my $stash = $gv->STASH->NAME;
1236     my $name = $gv->SAFENAME;
1237     if ($stash eq 'main' && $name =~ /^::/) {
1238         $stash = '::';
1239     }
1240     elsif (($stash eq 'main' && $globalnames{$name})
1241         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1242             && ($stash eq 'main' || $name !~ /::/))
1243         or $name =~ /^[^A-Za-z_:]/)
1244     {
1245         $stash = "";
1246     } else {
1247         $stash = $stash . "::";
1248     }
1249     if ($name =~ /^(\^..|{)/) {
1250         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1251     }
1252     return $stash . $name;
1253 }
1254
1255 # Return the name to use for a stash variable.
1256 # If a lexical with the same name is in scope, it may need to be
1257 # fully-qualified.
1258 sub stash_variable {
1259     my ($self, $prefix, $name) = @_;
1260
1261     return "$prefix$name" if $name =~ /::/;
1262
1263     unless ($prefix eq '$' || $prefix eq '@' || #'
1264             $prefix eq '%' || $prefix eq '$#') {
1265         return "$prefix$name";
1266     }
1267
1268     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1269     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1270     return "$prefix$name";
1271 }
1272
1273 sub lex_in_scope {
1274     my ($self, $name) = @_;
1275     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1276
1277     return 0 if !defined($self->{'curcop'});
1278     my $seq = $self->{'curcop'}->cop_seq;
1279     return 0 if !exists $self->{'curcvlex'}{$name};
1280     for my $a (@{$self->{'curcvlex'}{$name}}) {
1281         my ($st, $en) = @$a;
1282         return 1 if $seq > $st && $seq <= $en;
1283     }
1284     return 0;
1285 }
1286
1287 sub populate_curcvlex {
1288     my $self = shift;
1289     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1290         my $padlist = $cv->PADLIST;
1291         # an undef CV still in lexical chain
1292         next if class($padlist) eq "SPECIAL";
1293         my @padlist = $padlist->ARRAY;
1294         my @ns = $padlist[0]->ARRAY;
1295
1296         for (my $i=0; $i<@ns; ++$i) {
1297             next if class($ns[$i]) eq "SPECIAL";
1298             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1299             if (class($ns[$i]) eq "PV") {
1300                 # Probably that pesky lexical @_
1301                 next;
1302             }
1303             my $name = $ns[$i]->PVX;
1304             my ($seq_st, $seq_en) =
1305                 ($ns[$i]->FLAGS & SVf_FAKE)
1306                     ? (0, 999999)
1307                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1308
1309             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1310         }
1311     }
1312 }
1313
1314 sub find_scope_st { ((find_scope(@_))[0]); }
1315 sub find_scope_en { ((find_scope(@_))[1]); }
1316
1317 # Recurses down the tree, looking for pad variable introductions and COPs
1318 sub find_scope {
1319     my ($self, $op, $scope_st, $scope_en) = @_;
1320     carp("Undefined op in find_scope") if !defined $op;
1321     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1322
1323     my @queue = ($op);
1324     while(my $op = shift @queue ) {
1325         for (my $o=$op->first; $$o; $o=$o->sibling) {
1326             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1327                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1328                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1329                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1330                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1331                 return ($scope_st, $scope_en);
1332             }
1333             elsif (is_state($o)) {
1334                 my $c = $o->cop_seq;
1335                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1336                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1337                 return ($scope_st, $scope_en);
1338             }
1339             elsif ($o->flags & OPf_KIDS) {
1340                 unshift (@queue, $o);
1341             }
1342         }
1343     }
1344
1345     return ($scope_st, $scope_en);
1346 }
1347
1348 # Returns a list of subs which should be inserted before the COP
1349 sub cop_subs {
1350     my ($self, $op, $out_seq) = @_;
1351     my $seq = $op->cop_seq;
1352     # If we have nephews, then our sequence number indicates
1353     # the cop_seq of the end of some sort of scope.
1354     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1355         and my $nseq = $self->find_scope_st($op->sibling) ) {
1356         $seq = $nseq;
1357     }
1358     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1359     return $self->seq_subs($seq);
1360 }
1361
1362 sub seq_subs {
1363     my ($self, $seq) = @_;
1364     my @text;
1365 #push @text, "# ($seq)\n";
1366
1367     return "" if !defined $seq;
1368     while (scalar(@{$self->{'subs_todo'}})
1369            and $seq > $self->{'subs_todo'}[0][0]) {
1370         push @text, $self->next_todo;
1371     }
1372     return @text;
1373 }
1374
1375 # Notice how subs and formats are inserted between statements here;
1376 # also $[ assignments and pragmas.
1377 sub pp_nextstate {
1378     my $self = shift;
1379     my($op, $cx) = @_;
1380     $self->{'curcop'} = $op;
1381     my @text;
1382     push @text, $self->cop_subs($op);
1383     push @text, $op->label . ": " if $op->label;
1384     my $stash = $op->stashpv;
1385     if ($stash ne $self->{'curstash'}) {
1386         push @text, "package $stash;\n";
1387         $self->{'curstash'} = $stash;
1388     }
1389
1390     if ($self->{'arybase'} != $op->arybase) {
1391         push @text, '$[ = '. $op->arybase .";\n";
1392         $self->{'arybase'} = $op->arybase;
1393     }
1394
1395     my $warnings = $op->warnings;
1396     my $warning_bits;
1397     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1398         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1399     }
1400     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1401         $warning_bits = $warnings::NONE;
1402     }
1403     elsif ($warnings->isa("B::SPECIAL")) {
1404         $warning_bits = undef;
1405     }
1406     else {
1407         $warning_bits = $warnings->PV & WARN_MASK;
1408     }
1409
1410     if (defined ($warning_bits) and
1411        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1412         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1413         $self->{'warnings'} = $warning_bits;
1414     }
1415
1416     if ($self->{'hints'} != $op->hints) {
1417         push @text, declare_hints($self->{'hints'}, $op->hints);
1418         $self->{'hints'} = $op->hints;
1419     }
1420
1421     # hack to check that the hint hash hasn't changed
1422     if ($] > 5.009 &&
1423         "@{[sort %{$self->{'hinthash'} || {}}]}"
1424         ne "@{[sort %{$op->hints_hash->HASH || {}}]}") {
1425         push @text, declare_hinthash($self->{'hinthash'}, $op->hints_hash->HASH, $self->{indent_size});
1426         $self->{'hinthash'} = $op->hints_hash->HASH;
1427     }
1428
1429     # This should go after of any branches that add statements, to
1430     # increase the chances that it refers to the same line it did in
1431     # the original program.
1432     if ($self->{'linenums'}) {
1433         push @text, "\f#line " . $op->line .
1434           ' "' . $op->file, qq'"\n';
1435     }
1436
1437     return join("", @text);
1438 }
1439
1440 sub declare_warnings {
1441     my ($from, $to) = @_;
1442     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1443         return "use warnings;\n";
1444     }
1445     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1446         return "no warnings;\n";
1447     }
1448     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1449 }
1450
1451 sub declare_hints {
1452     my ($from, $to) = @_;
1453     my $use = $to   & ~$from;
1454     my $no  = $from & ~$to;
1455     my $decls = "";
1456     for my $pragma (hint_pragmas($use)) {
1457         $decls .= "use $pragma;\n";
1458     }
1459     for my $pragma (hint_pragmas($no)) {
1460         $decls .= "no $pragma;\n";
1461     }
1462     return $decls;
1463 }
1464
1465 # Internal implementation hints that the core sets automatically, so don't need
1466 # (or want) to be passed back to the user
1467 my %ignored_hints = (
1468     'open<' => 1,
1469     'open>' => 1,
1470     ':'     => 1,
1471 );
1472
1473 sub declare_hinthash {
1474     my ($from, $to, $indent) = @_;
1475     my @decls;
1476     for my $key (keys %$to) {
1477         next if $ignored_hints{$key};
1478         if (!defined $from->{$key} or $from->{$key} ne $to->{$key}) {
1479             push @decls, qq(\$^H{'$key'} = q($to->{$key}););
1480         }
1481     }
1482     for my $key (keys %$from) {
1483         next if $ignored_hints{$key};
1484         if (!exists $to->{$key}) {
1485             push @decls, qq(delete \$^H{'$key'};);
1486         }
1487     }
1488     @decls or return '';
1489     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1490 }
1491
1492 sub hint_pragmas {
1493     my ($bits) = @_;
1494     my @pragmas;
1495     push @pragmas, "integer" if $bits & 0x1;
1496     push @pragmas, "strict 'refs'" if $bits & 0x2;
1497     push @pragmas, "bytes" if $bits & 0x8;
1498     return @pragmas;
1499 }
1500
1501 sub pp_dbstate { pp_nextstate(@_) }
1502 sub pp_setstate { pp_nextstate(@_) }
1503
1504 sub pp_unstack { return "" } # see also leaveloop
1505
1506 sub baseop {
1507     my $self = shift;
1508     my($op, $cx, $name) = @_;
1509     return $name;
1510 }
1511
1512 sub pp_stub {
1513     my $self = shift;
1514     my($op, $cx, $name) = @_;
1515     if ($cx >= 1) {
1516         return "()";
1517     }
1518     else {
1519         return "();";
1520     }
1521 }
1522 sub pp_wantarray { baseop(@_, "wantarray") }
1523 sub pp_fork { baseop(@_, "fork") }
1524 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1525 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1526 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1527 sub pp_tms { baseop(@_, "times") }
1528 sub pp_ghostent { baseop(@_, "gethostent") }
1529 sub pp_gnetent { baseop(@_, "getnetent") }
1530 sub pp_gprotoent { baseop(@_, "getprotoent") }
1531 sub pp_gservent { baseop(@_, "getservent") }
1532 sub pp_ehostent { baseop(@_, "endhostent") }
1533 sub pp_enetent { baseop(@_, "endnetent") }
1534 sub pp_eprotoent { baseop(@_, "endprotoent") }
1535 sub pp_eservent { baseop(@_, "endservent") }
1536 sub pp_gpwent { baseop(@_, "getpwent") }
1537 sub pp_spwent { baseop(@_, "setpwent") }
1538 sub pp_epwent { baseop(@_, "endpwent") }
1539 sub pp_ggrent { baseop(@_, "getgrent") }
1540 sub pp_sgrent { baseop(@_, "setgrent") }
1541 sub pp_egrent { baseop(@_, "endgrent") }
1542 sub pp_getlogin { baseop(@_, "getlogin") }
1543
1544 sub POSTFIX () { 1 }
1545
1546 # I couldn't think of a good short name, but this is the category of
1547 # symbolic unary operators with interesting precedence
1548
1549 sub pfixop {
1550     my $self = shift;
1551     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1552     my $kid = $op->first;
1553     $kid = $self->deparse($kid, $prec);
1554     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1555                                $cx, $prec);
1556 }
1557
1558 sub pp_preinc { pfixop(@_, "++", 23) }
1559 sub pp_predec { pfixop(@_, "--", 23) }
1560 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1561 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1562 sub pp_i_preinc { pfixop(@_, "++", 23) }
1563 sub pp_i_predec { pfixop(@_, "--", 23) }
1564 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1565 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1566 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1567
1568 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1569 sub real_negate {
1570     my $self = shift;
1571     my($op, $cx) = @_;
1572     if ($op->first->name =~ /^(i_)?negate$/) {
1573         # avoid --$x
1574         $self->pfixop($op, $cx, "-", 21.5);
1575     } else {
1576         $self->pfixop($op, $cx, "-", 21);
1577     }
1578 }
1579 sub pp_i_negate { pp_negate(@_) }
1580
1581 sub pp_not {
1582     my $self = shift;
1583     my($op, $cx) = @_;
1584     if ($cx <= 4) {
1585         $self->pfixop($op, $cx, "not ", 4);
1586     } else {
1587         $self->pfixop($op, $cx, "!", 21);
1588     }
1589 }
1590
1591 sub unop {
1592     my $self = shift;
1593     my($op, $cx, $name) = @_;
1594     my $kid;
1595     if ($op->flags & OPf_KIDS) {
1596         $kid = $op->first;
1597         if (not $name) {
1598             # this deals with 'boolkeys' right now
1599             return $self->deparse($kid,$cx);
1600         }
1601         my $builtinname = $name;
1602         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1603         if (defined prototype($builtinname)
1604            && prototype($builtinname) =~ /^;?\*/
1605            && $kid->name eq "rv2gv") {
1606             $kid = $kid->first;
1607         }
1608
1609         return $self->maybe_parens_unop($name, $kid, $cx);
1610     } else {
1611         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1612     }
1613 }
1614
1615 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1616 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1617 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1618 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1619 sub pp_defined { unop(@_, "defined") }
1620 sub pp_undef { unop(@_, "undef") }
1621 sub pp_study { unop(@_, "study") }
1622 sub pp_ref { unop(@_, "ref") }
1623 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1624
1625 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1626 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1627 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1628 sub pp_srand { unop(@_, "srand") }
1629 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1630 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1631 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1632 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1633 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1634 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1635 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1636
1637 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1638 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1639 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1640
1641 sub pp_each { unop(@_, "each") }
1642 sub pp_values { unop(@_, "values") }
1643 sub pp_keys { unop(@_, "keys") }
1644 sub pp_boolkeys {
1645     # no name because its an optimisation op that has no keyword
1646     unop(@_,"");
1647 }
1648 sub pp_aeach { unop(@_, "each") }
1649 sub pp_avalues { unop(@_, "values") }
1650 sub pp_akeys { unop(@_, "keys") }
1651 sub pp_pop { unop(@_, "pop") }
1652 sub pp_shift { unop(@_, "shift") }
1653
1654 sub pp_caller { unop(@_, "caller") }
1655 sub pp_reset { unop(@_, "reset") }
1656 sub pp_exit { unop(@_, "exit") }
1657 sub pp_prototype { unop(@_, "prototype") }
1658
1659 sub pp_close { unop(@_, "close") }
1660 sub pp_fileno { unop(@_, "fileno") }
1661 sub pp_umask { unop(@_, "umask") }
1662 sub pp_untie { unop(@_, "untie") }
1663 sub pp_tied { unop(@_, "tied") }
1664 sub pp_dbmclose { unop(@_, "dbmclose") }
1665 sub pp_getc { unop(@_, "getc") }
1666 sub pp_eof { unop(@_, "eof") }
1667 sub pp_tell { unop(@_, "tell") }
1668 sub pp_getsockname { unop(@_, "getsockname") }
1669 sub pp_getpeername { unop(@_, "getpeername") }
1670
1671 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1672 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1673 sub pp_readlink { unop(@_, "readlink") }
1674 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1675 sub pp_readdir { unop(@_, "readdir") }
1676 sub pp_telldir { unop(@_, "telldir") }
1677 sub pp_rewinddir { unop(@_, "rewinddir") }
1678 sub pp_closedir { unop(@_, "closedir") }
1679 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1680 sub pp_localtime { unop(@_, "localtime") }
1681 sub pp_gmtime { unop(@_, "gmtime") }
1682 sub pp_alarm { unop(@_, "alarm") }
1683 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1684
1685 sub pp_dofile { unop(@_, "do") }
1686 sub pp_entereval { unop(@_, "eval") }
1687
1688 sub pp_ghbyname { unop(@_, "gethostbyname") }
1689 sub pp_gnbyname { unop(@_, "getnetbyname") }
1690 sub pp_gpbyname { unop(@_, "getprotobyname") }
1691 sub pp_shostent { unop(@_, "sethostent") }
1692 sub pp_snetent { unop(@_, "setnetent") }
1693 sub pp_sprotoent { unop(@_, "setprotoent") }
1694 sub pp_sservent { unop(@_, "setservent") }
1695 sub pp_gpwnam { unop(@_, "getpwnam") }
1696 sub pp_gpwuid { unop(@_, "getpwuid") }
1697 sub pp_ggrnam { unop(@_, "getgrnam") }
1698 sub pp_ggrgid { unop(@_, "getgrgid") }
1699
1700 sub pp_lock { unop(@_, "lock") }
1701
1702 sub pp_continue { unop(@_, "continue"); }
1703 sub pp_break {
1704     my ($self, $op) = @_;
1705     return "" if $op->flags & OPf_SPECIAL;
1706     unop(@_, "break");
1707 }
1708
1709 sub givwhen {
1710     my $self = shift;
1711     my($op, $cx, $givwhen) = @_;
1712
1713     my $enterop = $op->first;
1714     my ($head, $block);
1715     if ($enterop->flags & OPf_SPECIAL) {
1716         $head = "default";
1717         $block = $self->deparse($enterop->first, 0);
1718     }
1719     else {
1720         my $cond = $enterop->first;
1721         my $cond_str = $self->deparse($cond, 1);
1722         $head = "$givwhen ($cond_str)";
1723         $block = $self->deparse($cond->sibling, 0);
1724     }
1725
1726     return "$head {\n".
1727         "\t$block\n".
1728         "\b}\cK";
1729 }
1730
1731 sub pp_leavegiven { givwhen(@_, "given"); }
1732 sub pp_leavewhen  { givwhen(@_, "when"); }
1733
1734 sub pp_exists {
1735     my $self = shift;
1736     my($op, $cx) = @_;
1737     my $arg;
1738     if ($op->private & OPpEXISTS_SUB) {
1739         # Checking for the existence of a subroutine
1740         return $self->maybe_parens_func("exists",
1741                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1742     }
1743     if ($op->flags & OPf_SPECIAL) {
1744         # Array element, not hash element
1745         return $self->maybe_parens_func("exists",
1746                                 $self->pp_aelem($op->first, 16), $cx, 16);
1747     }
1748     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1749                                     $cx, 16);
1750 }
1751
1752 sub pp_delete {
1753     my $self = shift;
1754     my($op, $cx) = @_;
1755     my $arg;
1756     if ($op->private & OPpSLICE) {
1757         if ($op->flags & OPf_SPECIAL) {
1758             # Deleting from an array, not a hash
1759             return $self->maybe_parens_func("delete",
1760                                         $self->pp_aslice($op->first, 16),
1761                                         $cx, 16);
1762         }
1763         return $self->maybe_parens_func("delete",
1764                                         $self->pp_hslice($op->first, 16),
1765                                         $cx, 16);
1766     } else {
1767         if ($op->flags & OPf_SPECIAL) {
1768             # Deleting from an array, not a hash
1769             return $self->maybe_parens_func("delete",
1770                                         $self->pp_aelem($op->first, 16),
1771                                         $cx, 16);
1772         }
1773         return $self->maybe_parens_func("delete",
1774                                         $self->pp_helem($op->first, 16),
1775                                         $cx, 16);
1776     }
1777 }
1778
1779 sub pp_require {
1780     my $self = shift;
1781     my($op, $cx) = @_;
1782     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1783     if (class($op) eq "UNOP" and $op->first->name eq "const"
1784         and $op->first->private & OPpCONST_BARE)
1785     {
1786         my $name = $self->const_sv($op->first)->PV;
1787         $name =~ s[/][::]g;
1788         $name =~ s/\.pm//g;
1789         return "$opname $name";
1790     } else {
1791         $self->unop($op, $cx, $opname);
1792     }
1793 }
1794
1795 sub pp_scalar {
1796     my $self = shift;
1797     my($op, $cx) = @_;
1798     my $kid = $op->first;
1799     if (not null $kid->sibling) {
1800         # XXX Was a here-doc
1801         return $self->dquote($op);
1802     }
1803     $self->unop(@_, "scalar");
1804 }
1805
1806
1807 sub padval {
1808     my $self = shift;
1809     my $targ = shift;
1810     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1811 }
1812
1813 sub anon_hash_or_list {
1814     my $self = shift;
1815     my($op, $cx) = @_;
1816
1817     my($pre, $post) = @{{"anonlist" => ["[","]"],
1818                          "anonhash" => ["{","}"]}->{$op->name}};
1819     my($expr, @exprs);
1820     $op = $op->first->sibling; # skip pushmark
1821     for (; !null($op); $op = $op->sibling) {
1822         $expr = $self->deparse($op, 6);
1823         push @exprs, $expr;
1824     }
1825     if ($pre eq "{" and $cx < 1) {
1826         # Disambiguate that it's not a block
1827         $pre = "+{";
1828     }
1829     return $pre . join(", ", @exprs) . $post;
1830 }
1831
1832 sub pp_anonlist {
1833     my $self = shift;
1834     my ($op, $cx) = @_;
1835     if ($op->flags & OPf_SPECIAL) {
1836         return $self->anon_hash_or_list($op, $cx);
1837     }
1838     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1839     return 'XXX';
1840 }
1841
1842 *pp_anonhash = \&pp_anonlist;
1843
1844 sub pp_refgen {
1845     my $self = shift;
1846     my($op, $cx) = @_;
1847     my $kid = $op->first;
1848     if ($kid->name eq "null") {
1849         $kid = $kid->first;
1850         if (!null($kid->sibling) and
1851                  $kid->sibling->name eq "anoncode") {
1852             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1853         } elsif ($kid->name eq "pushmark") {
1854             my $sib_name = $kid->sibling->name;
1855             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1856                 and not $kid->sibling->flags & OPf_REF)
1857             {
1858                 # The @a in \(@a) isn't in ref context, but only when the
1859                 # parens are there.
1860                 return "\\(" . $self->pp_list($op->first) . ")";
1861             } elsif ($sib_name eq 'entersub') {
1862                 my $text = $self->deparse($kid->sibling, 1);
1863                 # Always show parens for \(&func()), but only with -p otherwise
1864                 $text = "($text)" if $self->{'parens'}
1865                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1866                 return "\\$text";
1867             }
1868         }
1869     }
1870     $self->pfixop($op, $cx, "\\", 20);
1871 }
1872
1873 sub e_anoncode {
1874     my ($self, $info) = @_;
1875     my $text = $self->deparse_sub($info->{code});
1876     return "sub " . $text;
1877 }
1878
1879 sub pp_srefgen { pp_refgen(@_) }
1880
1881 sub pp_readline {
1882     my $self = shift;
1883     my($op, $cx) = @_;
1884     my $kid = $op->first;
1885     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1886     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1887     return $self->unop($op, $cx, "readline");
1888 }
1889
1890 sub pp_rcatline {
1891     my $self = shift;
1892     my($op) = @_;
1893     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1894 }
1895
1896 # Unary operators that can occur as pseudo-listops inside double quotes
1897 sub dq_unop {
1898     my $self = shift;
1899     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1900     my $kid;
1901     if ($op->flags & OPf_KIDS) {
1902        $kid = $op->first;
1903        # If there's more than one kid, the first is an ex-pushmark.
1904        $kid = $kid->sibling if not null $kid->sibling;
1905        return $self->maybe_parens_unop($name, $kid, $cx);
1906     } else {
1907        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1908     }
1909 }
1910
1911 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1912 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1913 sub pp_uc { dq_unop(@_, "uc") }
1914 sub pp_lc { dq_unop(@_, "lc") }
1915 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1916
1917 sub loopex {
1918     my $self = shift;
1919     my ($op, $cx, $name) = @_;
1920     if (class($op) eq "PVOP") {
1921         return "$name " . $op->pv;
1922     } elsif (class($op) eq "OP") {
1923         return $name;
1924     } elsif (class($op) eq "UNOP") {
1925         # Note -- loop exits are actually exempt from the
1926         # looks-like-a-func rule, but a few extra parens won't hurt
1927         return $self->maybe_parens_unop($name, $op->first, $cx);
1928     }
1929 }
1930
1931 sub pp_last { loopex(@_, "last") }
1932 sub pp_next { loopex(@_, "next") }
1933 sub pp_redo { loopex(@_, "redo") }
1934 sub pp_goto { loopex(@_, "goto") }
1935 sub pp_dump { loopex(@_, "dump") }
1936
1937 sub ftst {
1938     my $self = shift;
1939     my($op, $cx, $name) = @_;
1940     if (class($op) eq "UNOP") {
1941         # Genuine `-X' filetests are exempt from the LLAFR, but not
1942         # l?stat(); for the sake of clarity, give'em all parens
1943         return $self->maybe_parens_unop($name, $op->first, $cx);
1944     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
1945         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1946     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1947         return $name;
1948     }
1949 }
1950
1951 sub pp_lstat    { ftst(@_, "lstat") }
1952 sub pp_stat     { ftst(@_, "stat") }
1953 sub pp_ftrread  { ftst(@_, "-R") }
1954 sub pp_ftrwrite { ftst(@_, "-W") }
1955 sub pp_ftrexec  { ftst(@_, "-X") }
1956 sub pp_fteread  { ftst(@_, "-r") }
1957 sub pp_ftewrite { ftst(@_, "-w") }
1958 sub pp_fteexec  { ftst(@_, "-x") }
1959 sub pp_ftis     { ftst(@_, "-e") }
1960 sub pp_fteowned { ftst(@_, "-O") }
1961 sub pp_ftrowned { ftst(@_, "-o") }
1962 sub pp_ftzero   { ftst(@_, "-z") }
1963 sub pp_ftsize   { ftst(@_, "-s") }
1964 sub pp_ftmtime  { ftst(@_, "-M") }
1965 sub pp_ftatime  { ftst(@_, "-A") }
1966 sub pp_ftctime  { ftst(@_, "-C") }
1967 sub pp_ftsock   { ftst(@_, "-S") }
1968 sub pp_ftchr    { ftst(@_, "-c") }
1969 sub pp_ftblk    { ftst(@_, "-b") }
1970 sub pp_ftfile   { ftst(@_, "-f") }
1971 sub pp_ftdir    { ftst(@_, "-d") }
1972 sub pp_ftpipe   { ftst(@_, "-p") }
1973 sub pp_ftlink   { ftst(@_, "-l") }
1974 sub pp_ftsuid   { ftst(@_, "-u") }
1975 sub pp_ftsgid   { ftst(@_, "-g") }
1976 sub pp_ftsvtx   { ftst(@_, "-k") }
1977 sub pp_fttty    { ftst(@_, "-t") }
1978 sub pp_fttext   { ftst(@_, "-T") }
1979 sub pp_ftbinary { ftst(@_, "-B") }
1980
1981 sub SWAP_CHILDREN () { 1 }
1982 sub ASSIGN () { 2 } # has OP= variant
1983 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1984
1985 my(%left, %right);
1986
1987 sub assoc_class {
1988     my $op = shift;
1989     my $name = $op->name;
1990     if ($name eq "concat" and $op->first->name eq "concat") {
1991         # avoid spurious `=' -- see comment in pp_concat
1992         return "concat";
1993     }
1994     if ($name eq "null" and class($op) eq "UNOP"
1995         and $op->first->name =~ /^(and|x?or)$/
1996         and null $op->first->sibling)
1997     {
1998         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1999         # with a null that's used as the common end point of the two
2000         # flows of control. For precedence purposes, ignore it.
2001         # (COND_EXPRs have these too, but we don't bother with
2002         # their associativity).
2003         return assoc_class($op->first);
2004     }
2005     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2006 }
2007
2008 # Left associative operators, like `+', for which
2009 # $a + $b + $c is equivalent to ($a + $b) + $c
2010
2011 BEGIN {
2012     %left = ('multiply' => 19, 'i_multiply' => 19,
2013              'divide' => 19, 'i_divide' => 19,
2014              'modulo' => 19, 'i_modulo' => 19,
2015              'repeat' => 19,
2016              'add' => 18, 'i_add' => 18,
2017              'subtract' => 18, 'i_subtract' => 18,
2018              'concat' => 18,
2019              'left_shift' => 17, 'right_shift' => 17,
2020              'bit_and' => 13,
2021              'bit_or' => 12, 'bit_xor' => 12,
2022              'and' => 3,
2023              'or' => 2, 'xor' => 2,
2024             );
2025 }
2026
2027 sub deparse_binop_left {
2028     my $self = shift;
2029     my($op, $left, $prec) = @_;
2030     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2031         and $left{assoc_class($op)} == $left{assoc_class($left)})
2032     {
2033         return $self->deparse($left, $prec - .00001);
2034     } else {
2035         return $self->deparse($left, $prec);
2036     }
2037 }
2038
2039 # Right associative operators, like `=', for which
2040 # $a = $b = $c is equivalent to $a = ($b = $c)
2041
2042 BEGIN {
2043     %right = ('pow' => 22,
2044               'sassign=' => 7, 'aassign=' => 7,
2045               'multiply=' => 7, 'i_multiply=' => 7,
2046               'divide=' => 7, 'i_divide=' => 7,
2047               'modulo=' => 7, 'i_modulo=' => 7,
2048               'repeat=' => 7,
2049               'add=' => 7, 'i_add=' => 7,
2050               'subtract=' => 7, 'i_subtract=' => 7,
2051               'concat=' => 7,
2052               'left_shift=' => 7, 'right_shift=' => 7,
2053               'bit_and=' => 7,
2054               'bit_or=' => 7, 'bit_xor=' => 7,
2055               'andassign' => 7,
2056               'orassign' => 7,
2057              );
2058 }
2059
2060 sub deparse_binop_right {
2061     my $self = shift;
2062     my($op, $right, $prec) = @_;
2063     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2064         and $right{assoc_class($op)} == $right{assoc_class($right)})
2065     {
2066         return $self->deparse($right, $prec - .00001);
2067     } else {
2068         return $self->deparse($right, $prec);
2069     }
2070 }
2071
2072 sub binop {
2073     my $self = shift;
2074     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2075     my $left = $op->first;
2076     my $right = $op->last;
2077     my $eq = "";
2078     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2079         $eq = "=";
2080         $prec = 7;
2081     }
2082     if ($flags & SWAP_CHILDREN) {
2083         ($left, $right) = ($right, $left);
2084     }
2085     $left = $self->deparse_binop_left($op, $left, $prec);
2086     $left = "($left)" if $flags & LIST_CONTEXT
2087                 && $left !~ /^(my|our|local|)[\@\(]/;
2088     $right = $self->deparse_binop_right($op, $right, $prec);
2089     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2090 }
2091
2092 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2093 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2094 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2095 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2096 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2097 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2098 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2099 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2100 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2101 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2102 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2103
2104 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2105 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2106 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2107 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2108 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2109
2110 sub pp_eq { binop(@_, "==", 14) }
2111 sub pp_ne { binop(@_, "!=", 14) }
2112 sub pp_lt { binop(@_, "<", 15) }
2113 sub pp_gt { binop(@_, ">", 15) }
2114 sub pp_ge { binop(@_, ">=", 15) }
2115 sub pp_le { binop(@_, "<=", 15) }
2116 sub pp_ncmp { binop(@_, "<=>", 14) }
2117 sub pp_i_eq { binop(@_, "==", 14) }
2118 sub pp_i_ne { binop(@_, "!=", 14) }
2119 sub pp_i_lt { binop(@_, "<", 15) }
2120 sub pp_i_gt { binop(@_, ">", 15) }
2121 sub pp_i_ge { binop(@_, ">=", 15) }
2122 sub pp_i_le { binop(@_, "<=", 15) }
2123 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2124
2125 sub pp_seq { binop(@_, "eq", 14) }
2126 sub pp_sne { binop(@_, "ne", 14) }
2127 sub pp_slt { binop(@_, "lt", 15) }
2128 sub pp_sgt { binop(@_, "gt", 15) }
2129 sub pp_sge { binop(@_, "ge", 15) }
2130 sub pp_sle { binop(@_, "le", 15) }
2131 sub pp_scmp { binop(@_, "cmp", 14) }
2132
2133 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2134 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2135
2136 sub pp_smartmatch {
2137     my ($self, $op, $cx) = @_;
2138     if ($op->flags & OPf_SPECIAL) {
2139         return $self->deparse($op->last, $cx);
2140     }
2141     else {
2142         binop(@_, "~~", 14);
2143     }
2144 }
2145
2146 # `.' is special because concats-of-concats are optimized to save copying
2147 # by making all but the first concat stacked. The effect is as if the
2148 # programmer had written `($a . $b) .= $c', except legal.
2149 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2150 sub real_concat {
2151     my $self = shift;
2152     my($op, $cx) = @_;
2153     my $left = $op->first;
2154     my $right = $op->last;
2155     my $eq = "";
2156     my $prec = 18;
2157     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2158         $eq = "=";
2159         $prec = 7;
2160     }
2161     $left = $self->deparse_binop_left($op, $left, $prec);
2162     $right = $self->deparse_binop_right($op, $right, $prec);
2163     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2164 }
2165
2166 # `x' is weird when the left arg is a list
2167 sub pp_repeat {
2168     my $self = shift;
2169     my($op, $cx) = @_;
2170     my $left = $op->first;
2171     my $right = $op->last;
2172     my $eq = "";
2173     my $prec = 19;
2174     if ($op->flags & OPf_STACKED) {
2175         $eq = "=";
2176         $prec = 7;
2177     }
2178     if (null($right)) { # list repeat; count is inside left-side ex-list
2179         my $kid = $left->first->sibling; # skip pushmark
2180         my @exprs;
2181         for (; !null($kid->sibling); $kid = $kid->sibling) {
2182             push @exprs, $self->deparse($kid, 6);
2183         }
2184         $right = $kid;
2185         $left = "(" . join(", ", @exprs). ")";
2186     } else {
2187         $left = $self->deparse_binop_left($op, $left, $prec);
2188     }
2189     $right = $self->deparse_binop_right($op, $right, $prec);
2190     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2191 }
2192
2193 sub range {
2194     my $self = shift;
2195     my ($op, $cx, $type) = @_;
2196     my $left = $op->first;
2197     my $right = $left->sibling;
2198     $left = $self->deparse($left, 9);
2199     $right = $self->deparse($right, 9);
2200     return $self->maybe_parens("$left $type $right", $cx, 9);
2201 }
2202
2203 sub pp_flop {
2204     my $self = shift;
2205     my($op, $cx) = @_;
2206     my $flip = $op->first;
2207     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2208     return $self->range($flip->first, $cx, $type);
2209 }
2210
2211 # one-line while/until is handled in pp_leave
2212
2213 sub logop {
2214     my $self = shift;
2215     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2216     my $left = $op->first;
2217     my $right = $op->first->sibling;
2218     if ($cx < 1 and is_scope($right) and $blockname
2219         and $self->{'expand'} < 7)
2220     { # if ($a) {$b}
2221         $left = $self->deparse($left, 1);
2222         $right = $self->deparse($right, 0);
2223         return "$blockname ($left) {\n\t$right\n\b}\cK";
2224     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2225              and $self->{'expand'} < 7) { # $b if $a
2226         $right = $self->deparse($right, 1);
2227         $left = $self->deparse($left, 1);
2228         return "$right $blockname $left";
2229     } elsif ($cx > $lowprec and $highop) { # $a && $b
2230         $left = $self->deparse_binop_left($op, $left, $highprec);
2231         $right = $self->deparse_binop_right($op, $right, $highprec);
2232         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2233     } else { # $a and $b
2234         $left = $self->deparse_binop_left($op, $left, $lowprec);
2235         $right = $self->deparse_binop_right($op, $right, $lowprec);
2236         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2237     }
2238 }
2239
2240 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2241 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2242 sub pp_dor { logop(@_, "//", 10) }
2243
2244 # xor is syntactically a logop, but it's really a binop (contrary to
2245 # old versions of opcode.pl). Syntax is what matters here.
2246 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2247
2248 sub logassignop {
2249     my $self = shift;
2250     my ($op, $cx, $opname) = @_;
2251     my $left = $op->first;
2252     my $right = $op->first->sibling->first; # skip sassign
2253     $left = $self->deparse($left, 7);
2254     $right = $self->deparse($right, 7);
2255     return $self->maybe_parens("$left $opname $right", $cx, 7);
2256 }
2257
2258 sub pp_andassign { logassignop(@_, "&&=") }
2259 sub pp_orassign  { logassignop(@_, "||=") }
2260 sub pp_dorassign { logassignop(@_, "//=") }
2261
2262 sub listop {
2263     my $self = shift;
2264     my($op, $cx, $name) = @_;
2265     my(@exprs);
2266     my $parens = ($cx >= 5) || $self->{'parens'};
2267     my $kid = $op->first->sibling;
2268     return $name if null $kid;
2269     my $first;
2270     $name = "socketpair" if $name eq "sockpair";
2271     my $proto = prototype("CORE::$name");
2272     if (defined $proto
2273         && $proto =~ /^;?\*/
2274         && $kid->name eq "rv2gv") {
2275         $first = $self->deparse($kid->first, 6);
2276     }
2277     else {
2278         $first = $self->deparse($kid, 6);
2279     }
2280     if ($name eq "chmod" && $first =~ /^\d+$/) {
2281         $first = sprintf("%#o", $first);
2282     }
2283     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2284     push @exprs, $first;
2285     $kid = $kid->sibling;
2286     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2287         push @exprs, $self->deparse($kid->first, 6);
2288         $kid = $kid->sibling;
2289     }
2290     for (; !null($kid); $kid = $kid->sibling) {
2291         push @exprs, $self->deparse($kid, 6);
2292     }
2293     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2294         return "$exprs[0] = $name" . ($parens ? "($exprs[0])" : " $exprs[0]");
2295     }
2296     if ($parens) {
2297         return "$name(" . join(", ", @exprs) . ")";
2298     } else {
2299         return "$name " . join(", ", @exprs);
2300     }
2301 }
2302
2303 sub pp_bless { listop(@_, "bless") }
2304 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2305 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2306 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2307 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2308 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2309 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2310 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2311 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2312 sub pp_unpack { listop(@_, "unpack") }
2313 sub pp_pack { listop(@_, "pack") }
2314 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2315 sub pp_splice { listop(@_, "splice") }
2316 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2317 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2318 sub pp_reverse { listop(@_, "reverse") }
2319 sub pp_warn { listop(@_, "warn") }
2320 sub pp_die { listop(@_, "die") }
2321 # Actually, return is exempt from the LLAFR (see examples in this very
2322 # module!), but for consistency's sake, ignore that fact
2323 sub pp_return { listop(@_, "return") }
2324 sub pp_open { listop(@_, "open") }
2325 sub pp_pipe_op { listop(@_, "pipe") }
2326 sub pp_tie { listop(@_, "tie") }
2327 sub pp_binmode { listop(@_, "binmode") }
2328 sub pp_dbmopen { listop(@_, "dbmopen") }
2329 sub pp_sselect { listop(@_, "select") }
2330 sub pp_select { listop(@_, "select") }
2331 sub pp_read { listop(@_, "read") }
2332 sub pp_sysopen { listop(@_, "sysopen") }
2333 sub pp_sysseek { listop(@_, "sysseek") }
2334 sub pp_sysread { listop(@_, "sysread") }
2335 sub pp_syswrite { listop(@_, "syswrite") }
2336 sub pp_send { listop(@_, "send") }
2337 sub pp_recv { listop(@_, "recv") }
2338 sub pp_seek { listop(@_, "seek") }
2339 sub pp_fcntl { listop(@_, "fcntl") }
2340 sub pp_ioctl { listop(@_, "ioctl") }
2341 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2342 sub pp_socket { listop(@_, "socket") }
2343 sub pp_sockpair { listop(@_, "sockpair") }
2344 sub pp_bind { listop(@_, "bind") }
2345 sub pp_connect { listop(@_, "connect") }
2346 sub pp_listen { listop(@_, "listen") }
2347 sub pp_accept { listop(@_, "accept") }
2348 sub pp_shutdown { listop(@_, "shutdown") }
2349 sub pp_gsockopt { listop(@_, "getsockopt") }
2350 sub pp_ssockopt { listop(@_, "setsockopt") }
2351 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2352 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2353 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2354 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2355 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2356 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2357 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2358 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2359 sub pp_open_dir { listop(@_, "opendir") }
2360 sub pp_seekdir { listop(@_, "seekdir") }
2361 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2362 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2363 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2364 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2365 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2366 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2367 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2368 sub pp_shmget { listop(@_, "shmget") }
2369 sub pp_shmctl { listop(@_, "shmctl") }
2370 sub pp_shmread { listop(@_, "shmread") }
2371 sub pp_shmwrite { listop(@_, "shmwrite") }
2372 sub pp_msgget { listop(@_, "msgget") }
2373 sub pp_msgctl { listop(@_, "msgctl") }
2374 sub pp_msgsnd { listop(@_, "msgsnd") }
2375 sub pp_msgrcv { listop(@_, "msgrcv") }
2376 sub pp_semget { listop(@_, "semget") }
2377 sub pp_semctl { listop(@_, "semctl") }
2378 sub pp_semop { listop(@_, "semop") }
2379 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2380 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2381 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2382 sub pp_gsbyname { listop(@_, "getservbyname") }
2383 sub pp_gsbyport { listop(@_, "getservbyport") }
2384 sub pp_syscall { listop(@_, "syscall") }
2385
2386 sub pp_glob {
2387     my $self = shift;
2388     my($op, $cx) = @_;
2389     my $text = $self->dq($op->first->sibling);  # skip pushmark
2390     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2391         or $text =~ /[<>]/) {
2392         return 'glob(' . single_delim('qq', '"', $text) . ')';
2393     } else {
2394         return '<' . $text . '>';
2395     }
2396 }
2397
2398 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2399 # be a filehandle. This could probably be better fixed in the core
2400 # by moving the GV lookup into ck_truc.
2401
2402 sub pp_truncate {
2403     my $self = shift;
2404     my($op, $cx) = @_;
2405     my(@exprs);
2406     my $parens = ($cx >= 5) || $self->{'parens'};
2407     my $kid = $op->first->sibling;
2408     my $fh;
2409     if ($op->flags & OPf_SPECIAL) {
2410         # $kid is an OP_CONST
2411         $fh = $self->const_sv($kid)->PV;
2412     } else {
2413         $fh = $self->deparse($kid, 6);
2414         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2415     }
2416     my $len = $self->deparse($kid->sibling, 6);
2417     if ($parens) {
2418         return "truncate($fh, $len)";
2419     } else {
2420         return "truncate $fh, $len";
2421     }
2422 }
2423
2424 sub indirop {
2425     my $self = shift;
2426     my($op, $cx, $name) = @_;
2427     my($expr, @exprs);
2428     my $kid = $op->first->sibling;
2429     my $indir = "";
2430     if ($op->flags & OPf_STACKED) {
2431         $indir = $kid;
2432         $indir = $indir->first; # skip rv2gv
2433         if (is_scope($indir)) {
2434             $indir = "{" . $self->deparse($indir, 0) . "}";
2435             $indir = "{;}" if $indir eq "{}";
2436         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2437             $indir = $self->const_sv($indir)->PV;
2438         } else {
2439             $indir = $self->deparse($indir, 24);
2440         }
2441         $indir = $indir . " ";
2442         $kid = $kid->sibling;
2443     }
2444     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2445         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2446                                                   : '{$a <=> $b} ';
2447     }
2448     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2449         $indir = '{$b cmp $a} ';
2450     }
2451     for (; !null($kid); $kid = $kid->sibling) {
2452         $expr = $self->deparse($kid, 6);
2453         push @exprs, $expr;
2454     }
2455     my $name2 = $name;
2456     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2457         $name2 = 'reverse sort';
2458     }
2459     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2460         return "$exprs[0] = $name2 $indir $exprs[0]";
2461     }
2462
2463     my $args = $indir . join(", ", @exprs);
2464     if ($indir ne "" and $name eq "sort") {
2465         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2466         # give bareword warnings in that case. Therefore if context
2467         # requires, we'll put parens around the outside "(sort f 1, 2,
2468         # 3)". Unfortunately, we'll currently think the parens are
2469         # necessary more often that they really are, because we don't
2470         # distinguish which side of an assignment we're on.
2471         if ($cx >= 5) {
2472             return "($name2 $args)";
2473         } else {
2474             return "$name2 $args";
2475         }
2476     } else {
2477         return $self->maybe_parens_func($name2, $args, $cx, 5);
2478     }
2479
2480 }
2481
2482 sub pp_prtf { indirop(@_, "printf") }
2483 sub pp_print { indirop(@_, "print") }
2484 sub pp_say  { indirop(@_, "say") }
2485 sub pp_sort { indirop(@_, "sort") }
2486
2487 sub mapop {
2488     my $self = shift;
2489     my($op, $cx, $name) = @_;
2490     my($expr, @exprs);
2491     my $kid = $op->first; # this is the (map|grep)start
2492     $kid = $kid->first->sibling; # skip a pushmark
2493     my $code = $kid->first; # skip a null
2494     if (is_scope $code) {
2495         $code = "{" . $self->deparse($code, 0) . "} ";
2496     } else {
2497         $code = $self->deparse($code, 24) . ", ";
2498     }
2499     $kid = $kid->sibling;
2500     for (; !null($kid); $kid = $kid->sibling) {
2501         $expr = $self->deparse($kid, 6);
2502         push @exprs, $expr if defined $expr;
2503     }
2504     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2505 }
2506
2507 sub pp_mapwhile { mapop(@_, "map") }
2508 sub pp_grepwhile { mapop(@_, "grep") }
2509 sub pp_mapstart { baseop(@_, "map") }
2510 sub pp_grepstart { baseop(@_, "grep") }
2511
2512 sub pp_list {
2513     my $self = shift;
2514     my($op, $cx) = @_;
2515     my($expr, @exprs);
2516     my $kid = $op->first->sibling; # skip pushmark
2517     my $lop;
2518     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2519     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2520         # This assumes that no other private flags equal 128, and that
2521         # OPs that store things other than flags in their op_private,
2522         # like OP_AELEMFAST, won't be immediate children of a list.
2523         #
2524         # OP_ENTERSUB can break this logic, so check for it.
2525         # I suspect that open and exit can too.
2526
2527         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2528                 or $lop->name eq "undef")
2529             or $lop->name eq "entersub"
2530             or $lop->name eq "exit"
2531             or $lop->name eq "open")
2532         {
2533             $local = ""; # or not
2534             last;
2535         }
2536         if ($lop->name =~ /^pad[ash]v$/) {
2537             if ($lop->private & OPpPAD_STATE) { # state()
2538                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2539                 $local = "state";
2540             } else { # my()
2541                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2542                 $local = "my";
2543             }
2544         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2545                         && $lop->private & OPpOUR_INTRO
2546                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2547                         && $lop->first->private & OPpOUR_INTRO) { # our()
2548             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2549             $local = "our";
2550         } elsif ($lop->name ne "undef"
2551                 # specifically avoid the "reverse sort" optimisation,
2552                 # where "reverse" is nullified
2553                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2554         {
2555             # local()
2556             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2557             $local = "local";
2558         }
2559     }
2560     $local = "" if $local eq "either"; # no point if it's all undefs
2561     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2562     for (; !null($kid); $kid = $kid->sibling) {
2563         if ($local) {
2564             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2565                 $lop = $kid->first;
2566             } else {
2567                 $lop = $kid;
2568             }
2569             $self->{'avoid_local'}{$$lop}++;
2570             $expr = $self->deparse($kid, 6);
2571             delete $self->{'avoid_local'}{$$lop};
2572         } else {
2573             $expr = $self->deparse($kid, 6);
2574         }
2575         push @exprs, $expr;
2576     }
2577     if ($local) {
2578         return "$local(" . join(", ", @exprs) . ")";
2579     } else {
2580         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2581     }
2582 }
2583
2584 sub is_ifelse_cont {
2585     my $op = shift;
2586     return ($op->name eq "null" and class($op) eq "UNOP"
2587             and $op->first->name =~ /^(and|cond_expr)$/
2588             and is_scope($op->first->first->sibling));
2589 }
2590
2591 sub pp_cond_expr {
2592     my $self = shift;
2593     my($op, $cx) = @_;
2594     my $cond = $op->first;
2595     my $true = $cond->sibling;
2596     my $false = $true->sibling;
2597     my $cuddle = $self->{'cuddle'};
2598     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2599             (is_scope($false) || is_ifelse_cont($false))
2600             and $self->{'expand'} < 7) {
2601         $cond = $self->deparse($cond, 8);
2602         $true = $self->deparse($true, 6);
2603         $false = $self->deparse($false, 8);
2604         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2605     }
2606
2607     $cond = $self->deparse($cond, 1);
2608     $true = $self->deparse($true, 0);
2609     my $head = "if ($cond) {\n\t$true\n\b}";
2610     my @elsifs;
2611     while (!null($false) and is_ifelse_cont($false)) {
2612         my $newop = $false->first;
2613         my $newcond = $newop->first;
2614         my $newtrue = $newcond->sibling;
2615         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2616         if ($newcond->name eq "lineseq")
2617         {
2618             # lineseq to ensure correct line numbers in elsif()
2619             # Bug #37302 fixed by change #33710.
2620             $newcond = $newcond->first->sibling;
2621         }
2622         $newcond = $self->deparse($newcond, 1);
2623         $newtrue = $self->deparse($newtrue, 0);
2624         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2625     }
2626     if (!null($false)) {
2627         $false = $cuddle . "else {\n\t" .
2628           $self->deparse($false, 0) . "\n\b}\cK";
2629     } else {
2630         $false = "\cK";
2631     }
2632     return $head . join($cuddle, "", @elsifs) . $false;
2633 }
2634
2635 sub pp_once {
2636     my ($self, $op, $cx) = @_;
2637     my $cond = $op->first;
2638     my $true = $cond->sibling;
2639
2640     return $self->deparse($true, $cx);
2641 }
2642
2643 sub loop_common {
2644     my $self = shift;
2645     my($op, $cx, $init) = @_;
2646     my $enter = $op->first;
2647     my $kid = $enter->sibling;
2648     local(@$self{qw'curstash warnings hints hinthash'})
2649                 = @$self{qw'curstash warnings hints hinthash'};
2650     my $head = "";
2651     my $bare = 0;
2652     my $body;
2653     my $cond = undef;
2654     if ($kid->name eq "lineseq") { # bare or infinite loop
2655         if ($kid->last->name eq "unstack") { # infinite
2656             $head = "while (1) "; # Can't use for(;;) if there's a continue
2657             $cond = "";
2658         } else {
2659             $bare = 1;
2660         }
2661         $body = $kid;
2662     } elsif ($enter->name eq "enteriter") { # foreach
2663         my $ary = $enter->first->sibling; # first was pushmark
2664         my $var = $ary->sibling;
2665         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2666             # "reverse" was optimised away
2667             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2668         } elsif ($enter->flags & OPf_STACKED
2669             and not null $ary->first->sibling->sibling)
2670         {
2671             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2672               $self->deparse($ary->first->sibling->sibling, 9);
2673         } else {
2674             $ary = $self->deparse($ary, 1);
2675         }
2676         if (null $var) {
2677             if ($enter->flags & OPf_SPECIAL) { # thread special var
2678                 $var = $self->pp_threadsv($enter, 1);
2679             } else { # regular my() variable
2680                 $var = $self->pp_padsv($enter, 1);
2681             }
2682         } elsif ($var->name eq "rv2gv") {
2683             $var = $self->pp_rv2sv($var, 1);
2684             if ($enter->private & OPpOUR_INTRO) {
2685                 # our declarations don't have package names
2686                 $var =~ s/^(.).*::/$1/;
2687                 $var = "our $var";
2688             }
2689         } elsif ($var->name eq "gv") {
2690             $var = "\$" . $self->deparse($var, 1);
2691         }
2692         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2693         if (!is_state $body->first and $body->first->name ne "stub") {
2694             confess unless $var eq '$_';
2695             $body = $body->first;
2696             return $self->deparse($body, 2) . " foreach ($ary)";
2697         }
2698         $head = "foreach $var ($ary) ";
2699     } elsif ($kid->name eq "null") { # while/until
2700         $kid = $kid->first;
2701         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2702         $cond = $self->deparse($kid->first, 1);
2703         $head = "$name ($cond) ";
2704         $body = $kid->first->sibling;
2705     } elsif ($kid->name eq "stub") { # bare and empty
2706         return "{;}"; # {} could be a hashref
2707     }
2708     # If there isn't a continue block, then the next pointer for the loop
2709     # will point to the unstack, which is kid's last child, except
2710     # in a bare loop, when it will point to the leaveloop. When neither of
2711     # these conditions hold, then the second-to-last child is the continue
2712     # block (or the last in a bare loop).
2713     my $cont_start = $enter->nextop;
2714     my $cont;
2715     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2716         if ($bare) {
2717             $cont = $body->last;
2718         } else {
2719             $cont = $body->first;
2720             while (!null($cont->sibling->sibling)) {
2721                 $cont = $cont->sibling;
2722             }
2723         }
2724         my $state = $body->first;
2725         my $cuddle = $self->{'cuddle'};
2726         my @states;
2727         for (; $$state != $$cont; $state = $state->sibling) {
2728             push @states, $state;
2729         }
2730         $body = $self->lineseq(undef, @states);
2731         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2732             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2733             $cont = "\cK";
2734         } else {
2735             $cont = $cuddle . "continue {\n\t" .
2736               $self->deparse($cont, 0) . "\n\b}\cK";
2737         }
2738     } else {
2739         return "" if !defined $body;
2740         if (length $init) {
2741             $head = "for ($init; $cond;) ";
2742         }
2743         $cont = "\cK";
2744         $body = $self->deparse($body, 0);
2745     }
2746     $body =~ s/;?$/;\n/;
2747
2748     return $head . "{\n\t" . $body . "\b}" . $cont;
2749 }
2750
2751 sub pp_leaveloop { shift->loop_common(@_, "") }
2752
2753 sub for_loop {
2754     my $self = shift;
2755     my($op, $cx) = @_;
2756     my $init = $self->deparse($op, 1);
2757     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2758 }
2759
2760 sub pp_leavetry {
2761     my $self = shift;
2762     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2763 }
2764
2765 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2766 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2767 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2768 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2769
2770 sub pp_null {
2771     my $self = shift;
2772     my($op, $cx) = @_;
2773     if (class($op) eq "OP") {
2774         # old value is lost
2775         return $self->{'ex_const'} if $op->targ == OP_CONST;
2776     } elsif ($op->first->name eq "pushmark") {
2777         return $self->pp_list($op, $cx);
2778     } elsif ($op->first->name eq "enter") {
2779         return $self->pp_leave($op, $cx);
2780     } elsif ($op->first->name eq "leave") {
2781         return $self->pp_leave($op->first, $cx);
2782     } elsif ($op->first->name eq "scope") {
2783         return $self->pp_scope($op->first, $cx);
2784     } elsif ($op->targ == OP_STRINGIFY) {
2785         return $self->dquote($op, $cx);
2786     } elsif (!null($op->first->sibling) and
2787              $op->first->sibling->name eq "readline" and
2788              $op->first->sibling->flags & OPf_STACKED) {
2789         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2790                                    . $self->deparse($op->first->sibling, 7),
2791                                    $cx, 7);
2792     } elsif (!null($op->first->sibling) and
2793              $op->first->sibling->name eq "trans" and
2794              $op->first->sibling->flags & OPf_STACKED) {
2795         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2796                                    . $self->deparse($op->first->sibling, 20),
2797                                    $cx, 20);
2798     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2799         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2800     } elsif (!null($op->first->sibling) and
2801              $op->first->sibling->name eq "null" and
2802              class($op->first->sibling) eq "UNOP" and
2803              $op->first->sibling->first->flags & OPf_STACKED and
2804              $op->first->sibling->first->name eq "rcatline") {
2805         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2806                                    . $self->deparse($op->first->sibling, 18),
2807                                    $cx, 18);
2808     } else {
2809         return $self->deparse($op->first, $cx);
2810     }
2811 }
2812
2813 sub padname {
2814     my $self = shift;
2815     my $targ = shift;
2816     return $self->padname_sv($targ)->PVX;
2817 }
2818
2819 sub padany {
2820     my $self = shift;
2821     my $op = shift;
2822     return substr($self->padname($op->targ), 1); # skip $/@/%
2823 }
2824
2825 sub pp_padsv {
2826     my $self = shift;
2827     my($op, $cx) = @_;
2828     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2829 }
2830
2831 sub pp_padav { pp_padsv(@_) }
2832 sub pp_padhv { pp_padsv(@_) }
2833
2834 my @threadsv_names;
2835
2836 BEGIN {
2837     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2838                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2839                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2840                        "!", "@");
2841 }
2842
2843 sub pp_threadsv {
2844     my $self = shift;
2845     my($op, $cx) = @_;
2846     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2847 }
2848
2849 sub gv_or_padgv {
2850     my $self = shift;
2851     my $op = shift;
2852     if (class($op) eq "PADOP") {
2853         return $self->padval($op->padix);
2854     } else { # class($op) eq "SVOP"
2855         return $op->gv;
2856     }
2857 }
2858
2859 sub pp_gvsv {
2860     my $self = shift;
2861     my($op, $cx) = @_;
2862     my $gv = $self->gv_or_padgv($op);
2863     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2864                                  $self->gv_name($gv)));
2865 }
2866
2867 sub pp_gv {
2868     my $self = shift;
2869     my($op, $cx) = @_;
2870     my $gv = $self->gv_or_padgv($op);
2871     return $self->gv_name($gv);
2872 }
2873
2874 sub pp_aelemfast {
2875     my $self = shift;
2876     my($op, $cx) = @_;
2877     my $name;
2878     if ($op->flags & OPf_SPECIAL) { # optimised PADAV
2879         $name = $self->padname($op->targ);
2880         $name =~ s/^@/\$/;
2881     }
2882     else {
2883         my $gv = $self->gv_or_padgv($op);
2884         $name = $self->gv_name($gv);
2885         $name = $self->{'curstash'}."::$name"
2886             if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2887         $name = '$' . $name;
2888     }
2889
2890     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2891 }
2892
2893 sub rv2x {
2894     my $self = shift;
2895     my($op, $cx, $type) = @_;
2896
2897     if (class($op) eq 'NULL' || !$op->can("first")) {
2898         carp("Unexpected op in pp_rv2x");
2899         return 'XXX';
2900     }
2901     my $kid = $op->first;
2902     if ($kid->name eq "gv") {
2903         return $self->stash_variable($type, $self->deparse($kid, 0));
2904     } elsif (is_scalar $kid) {
2905         my $str = $self->deparse($kid, 0);
2906         if ($str =~ /^\$([^\w\d])\z/) {
2907             # "$$+" isn't a legal way to write the scalar dereference
2908             # of $+, since the lexer can't tell you aren't trying to
2909             # do something like "$$ + 1" to get one more than your
2910             # PID. Either "${$+}" or "$${+}" are workable
2911             # disambiguations, but if the programmer did the former,
2912             # they'd be in the "else" clause below rather than here.
2913             # It's not clear if this should somehow be unified with
2914             # the code in dq and re_dq that also adds lexer
2915             # disambiguation braces.
2916             $str = '$' . "{$1}"; #'
2917         }
2918         return $type . $str;
2919     } else {
2920         return $type . "{" . $self->deparse($kid, 0) . "}";
2921     }
2922 }
2923
2924 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2925 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2926 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2927
2928 # skip rv2av
2929 sub pp_av2arylen {
2930     my $self = shift;
2931     my($op, $cx) = @_;
2932     if ($op->first->name eq "padav") {
2933         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2934     } else {
2935         return $self->maybe_local($op, $cx,
2936                                   $self->rv2x($op->first, $cx, '$#'));
2937     }
2938 }
2939
2940 # skip down to the old, ex-rv2cv
2941 sub pp_rv2cv {
2942     my ($self, $op, $cx) = @_;
2943     if (!null($op->first) && $op->first->name eq 'null' &&
2944         $op->first->targ eq OP_LIST)
2945     {
2946         return $self->rv2x($op->first->first->sibling, $cx, "&")
2947     }
2948     else {
2949         return $self->rv2x($op, $cx, "")
2950     }
2951 }
2952
2953 sub list_const {
2954     my $self = shift;
2955     my($cx, @list) = @_;
2956     my @a = map $self->const($_, 6), @list;
2957     if (@a == 0) {
2958         return "()";
2959     } elsif (@a == 1) {
2960         return $a[0];
2961     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
2962         # collapse (-1,0,1,2) into (-1..2)
2963         my ($s, $e) = @a[0,-1];
2964         my $i = $s;
2965         return $self->maybe_parens("$s..$e", $cx, 9)
2966           unless grep $i++ != $_, @a;
2967     }
2968     return $self->maybe_parens(join(", ", @a), $cx, 6);
2969 }
2970
2971 sub pp_rv2av {
2972     my $self = shift;
2973     my($op, $cx) = @_;
2974     my $kid = $op->first;
2975     if ($kid->name eq "const") { # constant list
2976         my $av = $self->const_sv($kid);
2977         return $self->list_const($cx, $av->ARRAY);
2978     } else {
2979         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2980     }
2981  }
2982
2983 sub is_subscriptable {
2984     my $op = shift;
2985     if ($op->name =~ /^[ahg]elem/) {
2986         return 1;
2987     } elsif ($op->name eq "entersub") {
2988         my $kid = $op->first;
2989         return 0 unless null $kid->sibling;
2990         $kid = $kid->first;
2991         $kid = $kid->sibling until null $kid->sibling;
2992         return 0 if is_scope($kid);
2993         $kid = $kid->first;
2994         return 0 if $kid->name eq "gv";
2995         return 0 if is_scalar($kid);
2996         return is_subscriptable($kid);
2997     } else {
2998         return 0;
2999     }
3000 }
3001
3002 sub elem_or_slice_array_name
3003 {
3004     my $self = shift;
3005     my ($array, $left, $padname, $allow_arrow) = @_;
3006
3007     if ($array->name eq $padname) {
3008         return $self->padany($array);
3009     } elsif (is_scope($array)) { # ${expr}[0]
3010         return "{" . $self->deparse($array, 0) . "}";
3011     } elsif ($array->name eq "gv") {
3012         $array = $self->gv_name($self->gv_or_padgv($array));
3013         if ($array !~ /::/) {
3014             my $prefix = ($left eq '[' ? '@' : '%');
3015             $array = $self->{curstash}.'::'.$array
3016                 if $self->lex_in_scope($prefix . $array);
3017         }
3018         return $array;
3019     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3020         return $self->deparse($array, 24);
3021     } else {
3022         return undef;
3023     }
3024 }
3025
3026 sub elem_or_slice_single_index
3027 {
3028     my $self = shift;
3029     my ($idx) = @_;
3030
3031     $idx = $self->deparse($idx, 1);
3032
3033     # Outer parens in an array index will confuse perl
3034     # if we're interpolating in a regular expression, i.e.
3035     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3036     #
3037     # If $self->{parens}, then an initial '(' will
3038     # definitely be paired with a final ')'. If
3039     # !$self->{parens}, the misleading parens won't
3040     # have been added in the first place.
3041     #
3042     # [You might think that we could get "(...)...(...)"
3043     # where the initial and final parens do not match
3044     # each other. But we can't, because the above would
3045     # only happen if there's an infix binop between the
3046     # two pairs of parens, and *that* means that the whole
3047     # expression would be parenthesized as well.]
3048     #
3049     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3050
3051     # Hash-element braces will autoquote a bareword inside themselves.
3052     # We need to make sure that C<$hash{warn()}> doesn't come out as
3053     # C<$hash{warn}>, which has a quite different meaning. Currently
3054     # B::Deparse will always quote strings, even if the string was a
3055     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3056     # for constant strings.) So we can cheat slightly here - if we see
3057     # a bareword, we know that it is supposed to be a function call.
3058     #
3059     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3060
3061     return $idx;
3062 }
3063
3064 sub elem {
3065     my $self = shift;
3066     my ($op, $cx, $left, $right, $padname) = @_;
3067     my($array, $idx) = ($op->first, $op->first->sibling);
3068
3069     $idx = $self->elem_or_slice_single_index($idx);
3070
3071     unless ($array->name eq $padname) { # Maybe this has been fixed
3072         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3073     }
3074     if (my $array_name=$self->elem_or_slice_array_name
3075             ($array, $left, $padname, 1)) {
3076         return "\$" . $array_name . $left . $idx . $right;
3077     } else {
3078         # $x[20][3]{hi} or expr->[20]
3079         my $arrow = is_subscriptable($array) ? "" : "->";
3080         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3081     }
3082
3083 }
3084
3085 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3086 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3087
3088 sub pp_gelem {
3089     my $self = shift;
3090     my($op, $cx) = @_;
3091     my($glob, $part) = ($op->first, $op->last);
3092     $glob = $glob->first; # skip rv2gv
3093     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3094     my $scope = is_scope($glob);
3095     $glob = $self->deparse($glob, 0);
3096     $part = $self->deparse($part, 1);
3097     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3098 }
3099
3100 sub slice {
3101     my $self = shift;
3102     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3103     my $last;
3104     my(@elems, $kid, $array, $list);
3105     if (class($op) eq "LISTOP") {
3106         $last = $op->last;
3107     } else { # ex-hslice inside delete()
3108         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3109         $last = $kid;
3110     }
3111     $array = $last;
3112     $array = $array->first
3113         if $array->name eq $regname or $array->name eq "null";
3114     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3115     $kid = $op->first->sibling; # skip pushmark
3116     if ($kid->name eq "list") {
3117         $kid = $kid->first->sibling; # skip list, pushmark
3118         for (; !null $kid; $kid = $kid->sibling) {
3119             push @elems, $self->deparse($kid, 6);
3120         }
3121         $list = join(", ", @elems);
3122     } else {
3123         $list = $self->elem_or_slice_single_index($kid);
3124     }
3125     return "\@" . $array . $left . $list . $right;
3126 }
3127
3128 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3129 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3130
3131 sub pp_lslice {
3132     my $self = shift;
3133     my($op, $cx) = @_;
3134     my $idx = $op->first;
3135     my $list = $op->last;
3136     my(@elems, $kid);
3137     $list = $self->deparse($list, 1);
3138     $idx = $self->deparse($idx, 1);
3139     return "($list)" . "[$idx]";
3140 }
3141
3142 sub want_scalar {
3143     my $op = shift;
3144     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3145 }
3146
3147 sub want_list {
3148     my $op = shift;
3149     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3150 }
3151
3152 sub _method {
3153     my $self = shift;
3154     my($op, $cx) = @_;
3155     my $kid = $op->first->sibling; # skip pushmark
3156     my($meth, $obj, @exprs);
3157     if ($kid->name eq "list" and want_list $kid) {
3158         # When an indirect object isn't a bareword but the args are in
3159         # parens, the parens aren't part of the method syntax (the LLAFR
3160         # doesn't apply), but they make a list with OPf_PARENS set that
3161         # doesn't get flattened by the append_elem that adds the method,
3162         # making a (object, arg1, arg2, ...) list where the object
3163         # usually is. This can be distinguished from
3164         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3165         # object) because in the later the list is in scalar context
3166         # as the left side of -> always is, while in the former
3167         # the list is in list context as method arguments always are.
3168         # (Good thing there aren't method prototypes!)
3169         $meth = $kid->sibling;
3170         $kid = $kid->first->sibling; # skip pushmark
3171         $obj = $kid;
3172         $kid = $kid->sibling;
3173         for (; not null $kid; $kid = $kid->sibling) {
3174             push @exprs, $kid;
3175         }
3176     } else {
3177         $obj = $kid;
3178         $kid = $kid->sibling;
3179         for (; !null ($kid->sibling) && $kid->name ne "method_named";
3180               $kid = $kid->sibling) {
3181             push @exprs, $kid
3182         }
3183         $meth = $kid;
3184     }
3185
3186     if ($meth->name eq "method_named") {
3187         $meth = $self->const_sv($meth)->PV;
3188     } else {
3189         $meth = $meth->first;
3190         if ($meth->name eq "const") {
3191             # As of 5.005_58, this case is probably obsoleted by the
3192             # method_named case above
3193             $meth = $self->const_sv($meth)->PV; # needs to be bare
3194         }
3195     }
3196
3197     return { method => $meth, variable_method => ref($meth),
3198              object => $obj, args => \@exprs  };
3199 }
3200
3201 # compat function only
3202 sub method {
3203     my $self = shift;
3204     my $info = $self->_method(@_);
3205     return $self->e_method( $self->_method(@_) );
3206 }
3207
3208 sub e_method {
3209     my ($self, $info) = @_;
3210     my $obj = $self->deparse($info->{object}, 24);
3211
3212     my $meth = $info->{method};
3213     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3214     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3215     my $kid = $obj . "->" . $meth;
3216     if (length $args) {
3217         return $kid . "(" . $args . ")"; # parens mandatory
3218     } else {
3219         return $kid;
3220     }
3221 }
3222
3223 # returns "&" if the prototype doesn't match the args,
3224 # or ("", $args_after_prototype_demunging) if it does.
3225 sub check_proto {
3226     my $self = shift;
3227     return "&" if $self->{'noproto'};
3228     my($proto, @args) = @_;
3229     my($arg, $real);
3230     my $doneok = 0;
3231     my @reals;
3232     # An unbackslashed @ or % gobbles up the rest of the args
3233     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3234     while ($proto) {
3235         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3236         my $chr = $1;
3237         if ($chr eq "") {
3238             return "&" if @args;
3239         } elsif ($chr eq ";") {
3240             $doneok = 1;
3241         } elsif ($chr eq "@" or $chr eq "%") {
3242             push @reals, map($self->deparse($_, 6), @args);
3243             @args = ();
3244         } else {
3245             $arg = shift @args;
3246             last unless $arg;
3247             if ($chr eq "\$" || $chr eq "_") {
3248                 if (want_scalar $arg) {
3249                     push @reals, $self->deparse($arg, 6);
3250                 } else {
3251                     return "&";
3252                 }
3253             } elsif ($chr eq "&") {
3254                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3255                     push @reals, $self->deparse($arg, 6);
3256                 } else {
3257                     return "&";
3258                 }
3259             } elsif ($chr eq "*") {
3260                 if ($arg->name =~ /^s?refgen$/
3261                     and $arg->first->first->name eq "rv2gv")
3262                   {
3263                       $real = $arg->first->first; # skip refgen, null
3264                       if ($real->first->name eq "gv") {
3265                           push @reals, $self->deparse($real, 6);
3266                       } else {
3267                           push @reals, $self->deparse($real->first, 6);
3268                       }
3269                   } else {
3270                       return "&";
3271                   }
3272             } elsif (substr($chr, 0, 1) eq "\\") {
3273                 $chr =~ tr/\\[]//d;
3274                 if ($arg->name =~ /^s?refgen$/ and
3275                     !null($real = $arg->first) and
3276                     ($chr =~ /\$/ && is_scalar($real->first)
3277                      or ($chr =~ /@/
3278                          && class($real->first->sibling) ne 'NULL'
3279                          && $real->first->sibling->name
3280                          =~ /^(rv2|pad)av$/)
3281                      or ($chr =~ /%/
3282                          && class($real->first->sibling) ne 'NULL'
3283                          && $real->first->sibling->name
3284                          =~ /^(rv2|pad)hv$/)
3285                      #or ($chr =~ /&/ # This doesn't work
3286                      #   && $real->first->name eq "rv2cv")
3287                      or ($chr =~ /\*/
3288                          && $real->first->name eq "rv2gv")))
3289                   {
3290                       push @reals, $self->deparse($real, 6);
3291                   } else {
3292                       return "&";
3293                   }
3294             }
3295        }
3296     }
3297     return "&" if $proto and !$doneok; # too few args and no `;'
3298     return "&" if @args;               # too many args
3299     return ("", join ", ", @reals);
3300 }
3301
3302 sub pp_entersub {
3303     my $self = shift;
3304     my($op, $cx) = @_;
3305     return $self->e_method($self->_method($op, $cx))
3306         unless null $op->first->sibling;
3307     my $prefix = "";
3308     my $amper = "";
3309     my($kid, @exprs);
3310     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3311         $prefix = "do ";
3312     } elsif ($op->private & OPpENTERSUB_AMPER) {
3313         $amper = "&";
3314     }
3315     $kid = $op->first;
3316     $kid = $kid->first->sibling; # skip ex-list, pushmark
3317     for (; not null $kid->sibling; $kid = $kid->sibling) {
3318         push @exprs, $kid;
3319     }
3320     my $simple = 0;
3321     my $proto = undef;
3322     if (is_scope($kid)) {
3323         $amper = "&";
3324         $kid = "{" . $self->deparse($kid, 0) . "}";
3325     } elsif ($kid->first->name eq "gv") {
3326         my $gv = $self->gv_or_padgv($kid->first);
3327         if (class($gv->CV) ne "SPECIAL") {
3328             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3329         }
3330         $simple = 1; # only calls of named functions can be prototyped
3331         $kid = $self->deparse($kid, 24);
3332         if (!$amper) {
3333             if ($kid eq 'main::') {
3334                 $kid = '::';
3335             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3336                 $kid = single_delim("q", "'", $kid) . '->';
3337             }
3338         }
3339     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3340         $amper = "&";
3341         $kid = $self->deparse($kid, 24);
3342     } else {
3343         $prefix = "";
3344         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3345         $kid = $self->deparse($kid, 24) . $arrow;
3346     }
3347
3348     # Doesn't matter how many prototypes there are, if
3349     # they haven't happened yet!
3350     my $declared;
3351     {
3352         no strict 'refs';
3353         no warnings 'uninitialized';
3354         $declared = exists $self->{'subs_declared'}{$kid}
3355             || (
3356                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3357                  && !exists
3358                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3359                  && defined prototype $self->{'curstash'}."::".$kid
3360                );
3361         if (!$declared && defined($proto)) {
3362             # Avoid "too early to check prototype" warning
3363             ($amper, $proto) = ('&');
3364         }
3365     }
3366
3367     my $args;
3368     if ($declared and defined $proto and not $amper) {
3369         ($amper, $args) = $self->check_proto($proto, @exprs);
3370         if ($amper eq "&") {
3371             $args = join(", ", map($self->deparse($_, 6), @exprs));
3372         }
3373     } else {
3374         $args = join(", ", map($self->deparse($_, 6), @exprs));
3375     }
3376     if ($prefix or $amper) {
3377         if ($op->flags & OPf_STACKED) {
3378             return $prefix . $amper . $kid . "(" . $args . ")";
3379         } else {
3380             return $prefix . $amper. $kid;
3381         }
3382     } else {
3383         # glob() invocations can be translated into calls of
3384         # CORE::GLOBAL::glob with a second parameter, a number.
3385         # Reverse this.
3386         if ($kid eq "CORE::GLOBAL::glob") {
3387             $kid = "glob";
3388             $args =~ s/\s*,[^,]+$//;
3389         }
3390
3391         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
3392         # so it must have been translated from a keyword call. Translate
3393         # it back.
3394         $kid =~ s/^CORE::GLOBAL:://;
3395
3396         my $dproto = defined($proto) ? $proto : "undefined";
3397         if (!$declared) {
3398             return "$kid(" . $args . ")";
3399         } elsif ($dproto eq "") {
3400             return $kid;
3401         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3402             # is_scalar is an excessively conservative test here:
3403             # really, we should be comparing to the precedence of the
3404             # top operator of $exprs[0] (ala unop()), but that would
3405             # take some major code restructuring to do right.
3406             return $self->maybe_parens_func($kid, $args, $cx, 16);
3407         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3408             return $self->maybe_parens_func($kid, $args, $cx, 5);
3409         } else {
3410             return "$kid(" . $args . ")";
3411         }
3412     }
3413 }
3414
3415 sub pp_enterwrite { unop(@_, "write") }
3416
3417 # escape things that cause interpolation in double quotes,
3418 # but not character escapes
3419 sub uninterp {
3420     my($str) = @_;
3421     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3422     return $str;
3423 }
3424
3425 {
3426 my $bal;
3427 BEGIN {
3428     use re "eval";
3429     # Matches any string which is balanced with respect to {braces}
3430     $bal = qr(
3431       (?:
3432         [^\\{}]
3433       | \\\\
3434       | \\[{}]
3435       | \{(??{$bal})\}
3436       )*
3437     )x;
3438 }
3439
3440 # the same, but treat $|, $), $( and $ at the end of the string differently
3441 sub re_uninterp {
3442     my($str) = @_;
3443
3444     $str =~ s/
3445           ( ^|\G                  # $1
3446           | [^\\]
3447           )
3448
3449           (                       # $2
3450             (?:\\\\)*
3451           )
3452
3453           (                       # $3
3454             (\(\?\??\{$bal\}\))   # $4
3455           | [\$\@]
3456             (?!\||\)|\(|$)
3457           | \\[uUlLQE]
3458           )
3459
3460         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3461
3462     return $str;
3463 }
3464
3465 # This is for regular expressions with the /x modifier
3466 # We have to leave comments unmangled.
3467 sub re_uninterp_extended {
3468     my($str) = @_;
3469
3470     $str =~ s/
3471           ( ^|\G                  # $1
3472           | [^\\]
3473           )
3474
3475           (                       # $2
3476             (?:\\\\)*
3477           )
3478
3479           (                       # $3
3480             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3481             | \#[^\n]*            #     (skip over comments)
3482             )
3483           | [\$\@]
3484             (?!\||\)|\(|$|\s)
3485           | \\[uUlLQE]
3486           )
3487
3488         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3489
3490     return $str;
3491 }
3492 }
3493
3494 my %unctrl = # portable to to EBCDIC
3495     (
3496      "\c@" => '\c@',    # unused
3497      "\cA" => '\cA',
3498      "\cB" => '\cB',
3499      "\cC" => '\cC',
3500      "\cD" => '\cD',
3501      "\cE" => '\cE',
3502      "\cF" => '\cF',
3503      "\cG" => '\cG',
3504      "\cH" => '\cH',
3505      "\cI" => '\cI',
3506      "\cJ" => '\cJ',
3507      "\cK" => '\cK',
3508      "\cL" => '\cL',
3509      "\cM" => '\cM',
3510      "\cN" => '\cN',
3511      "\cO" => '\cO',
3512      "\cP" => '\cP',
3513      "\cQ" => '\cQ',
3514      "\cR" => '\cR',
3515      "\cS" => '\cS',
3516      "\cT" => '\cT',
3517      "\cU" => '\cU',
3518      "\cV" => '\cV',
3519      "\cW" => '\cW',
3520      "\cX" => '\cX',
3521      "\cY" => '\cY',
3522      "\cZ" => '\cZ',
3523      "\c[" => '\c[',    # unused
3524      "\c\\" => '\c\\',  # unused
3525      "\c]" => '\c]',    # unused
3526      "\c_" => '\c_',    # unused
3527     );
3528
3529 # character escapes, but not delimiters that might need to be escaped
3530 sub escape_str { # ASCII, UTF8
3531     my($str) = @_;
3532     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3533     $str =~ s/\a/\\a/g;
3534 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3535     $str =~ s/\t/\\t/g;
3536     $str =~ s/\n/\\n/g;
3537     $str =~ s/\e/\\e/g;
3538     $str =~ s/\f/\\f/g;
3539     $str =~ s/\r/\\r/g;
3540     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3541     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3542     return $str;
3543 }
3544
3545 # For regexes with the /x modifier.
3546 # Leave whitespace unmangled.
3547 sub escape_extended_re {
3548     my($str) = @_;
3549     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3550     $str =~ s/([[:^print:]])/
3551         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3552     $str =~ s/\n/\n\f/g;
3553     return $str;
3554 }
3555
3556 # Don't do this for regexen
3557 sub unback {
3558     my($str) = @_;
3559     $str =~ s/\\/\\\\/g;
3560     return $str;
3561 }
3562
3563 # Remove backslashes which precede literal control characters,
3564 # to avoid creating ambiguity when we escape the latter.
3565 sub re_unback {
3566     my($str) = @_;
3567
3568     # the insane complexity here is due to the behaviour of "\c\"
3569     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3570     return $str;
3571 }
3572
3573 sub balanced_delim {
3574     my($str) = @_;
3575     my @str = split //, $str;
3576     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3577     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3578         ($open, $close) = @$ar;
3579         $fail = 0; $cnt = 0; $last_bs = 0;
3580         for $c (@str) {
3581             if ($c eq $open) {
3582                 $fail = 1 if $last_bs;
3583                 $cnt++;
3584             } elsif ($c eq $close) {
3585                 $fail = 1 if $last_bs;
3586                 $cnt--;
3587                 if ($cnt < 0) {
3588                     # qq()() isn't ")("
3589                     $fail = 1;
3590                     last;
3591                 }
3592             }
3593             $last_bs = $c eq '\\';
3594         }
3595         $fail = 1 if $cnt != 0;
3596         return ($open, "$open$str$close") if not $fail;
3597     }
3598     return ("", $str);
3599 }
3600
3601 sub single_delim {
3602     my($q, $default, $str) = @_;
3603     return "$default$str$default" if $default and index($str, $default) == -1;
3604     if ($q ne 'qr') {
3605         (my $succeed, $str) = balanced_delim($str);
3606         return "$q$str" if $succeed;
3607     }
3608     for my $delim ('/', '"', '#') {
3609         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3610     }
3611     if ($default) {
3612         $str =~ s/$default/\\$default/g;
3613         return "$default$str$default";
3614     } else {
3615         $str =~ s[/][\\/]g;
3616         return "$q/$str/";
3617     }
3618 }
3619
3620 my $max_prec;
3621 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3622
3623 # Split a floating point number into an integer mantissa and a binary
3624 # exponent. Assumes you've already made sure the number isn't zero or
3625 # some weird infinity or NaN.
3626 sub split_float {
3627     my($f) = @_;
3628     my $exponent = 0;
3629     if ($f == int($f)) {
3630         while ($f % 2 == 0) {
3631             $f /= 2;
3632             $exponent++;
3633         }
3634     } else {
3635         while ($f != int($f)) {
3636             $f *= 2;
3637             $exponent--;
3638         }
3639     }
3640     my $mantissa = sprintf("%.0f", $f);
3641     return ($mantissa, $exponent);
3642 }
3643
3644 sub const {
3645     my $self = shift;
3646     my($sv, $cx) = @_;
3647     if ($self->{'use_dumper'}) {
3648         return $self->const_dumper($sv, $cx);
3649     }
3650     if (class($sv) eq "SPECIAL") {
3651         # sv_undef, sv_yes, sv_no
3652         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3653     }
3654     if (class($sv) eq "NULL") {
3655        return 'undef';
3656     }
3657     # convert a version object into the "v1.2.3" string in its V magic
3658     if ($sv->FLAGS & SVs_RMG) {
3659         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3660             return $mg->PTR if $mg->TYPE eq 'V';
3661         }
3662     }
3663
3664     if ($sv->FLAGS & SVf_IOK) {
3665         my $str = $sv->int_value;
3666         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3667         return $str;
3668     } elsif ($sv->FLAGS & SVf_NOK) {
3669         my $nv = $sv->NV;
3670         if ($nv == 0) {
3671             if (pack("F", $nv) eq pack("F", 0)) {
3672                 # positive zero
3673                 return "0";
3674             } else {
3675                 # negative zero
3676                 return $self->maybe_parens("-.0", $cx, 21);
3677             }
3678         } elsif (1/$nv == 0) {
3679             if ($nv > 0) {
3680                 # positive infinity
3681                 return $self->maybe_parens("9**9**9", $cx, 22);
3682             } else {
3683                 # negative infinity
3684                 return $self->maybe_parens("-9**9**9", $cx, 21);
3685             }
3686         } elsif ($nv != $nv) {
3687             # NaN
3688             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3689                 # the normal kind
3690                 return "sin(9**9**9)";
3691             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3692                 # the inverted kind
3693                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3694             } else {
3695                 # some other kind
3696                 my $hex = unpack("h*", pack("F", $nv));
3697                 return qq'unpack("F", pack("h*", "$hex"))';
3698             }
3699         }
3700         # first, try the default stringification
3701         my $str = "$nv";
3702         if ($str != $nv) {
3703             # failing that, try using more precision
3704             $str = sprintf("%.${max_prec}g", $nv);
3705 #           if (pack("F", $str) ne pack("F", $nv)) {
3706             if ($str != $nv) {
3707                 # not representable in decimal with whatever sprintf()
3708                 # and atof() Perl is using here.
3709                 my($mant, $exp) = split_float($nv);
3710                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3711             }
3712         }
3713         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3714         return $str;
3715     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3716         my $ref = $sv->RV;
3717         if (class($ref) eq "AV") {
3718             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3719         } elsif (class($ref) eq "HV") {
3720             my %hash = $ref->ARRAY;
3721             my @elts;
3722             for my $k (sort keys %hash) {
3723                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3724             }
3725             return "{" . join(", ", @elts) . "}";
3726         } elsif (class($ref) eq "CV") {
3727             return "sub " . $self->deparse_sub($ref);
3728         }
3729         if ($ref->FLAGS & SVs_SMG) {
3730             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3731                 if ($mg->TYPE eq 'r') {
3732                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3733                     return single_delim("qr", "", $re);
3734                 }
3735             }
3736         }
3737
3738         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3739     } elsif ($sv->FLAGS & SVf_POK) {
3740         my $str = $sv->PV;
3741         if ($str =~ /[[:^print:]]/) {
3742             return single_delim("qq", '"', uninterp escape_str unback $str);
3743         } else {
3744             return single_delim("q", "'", unback $str);
3745         }
3746     } else {
3747         return "undef";
3748     }
3749 }
3750
3751 sub const_dumper {
3752     my $self = shift;
3753     my($sv, $cx) = @_;
3754     my $ref = $sv->object_2svref();
3755     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3756     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3757     my $str = $dumper->Dump();
3758     if ($str =~ /^\$v/) {
3759         return '${my ' . $str . ' \$v}';
3760     } else {
3761         return $str;
3762     }
3763 }
3764
3765 sub const_sv {
3766     my $self = shift;
3767     my $op = shift;
3768     my $sv = $op->sv;
3769     # the constant could be in the pad (under useithreads)
3770     $sv = $self->padval($op->targ) unless $$sv;
3771     return $sv;
3772 }
3773
3774 sub pp_const {
3775     my $self = shift;
3776     my($op, $cx) = @_;
3777     if ($op->private & OPpCONST_ARYBASE) {
3778         return '$[';
3779     }
3780 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3781 #       return $self->const_sv($op)->PV;
3782 #    }
3783     my $sv = $self->const_sv($op);
3784     return $self->const($sv, $cx);
3785 }
3786
3787 sub dq {
3788     my $self = shift;
3789     my $op = shift;
3790     my $type = $op->name;
3791     if ($type eq "const") {
3792         return '$[' if $op->private & OPpCONST_ARYBASE;
3793         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3794     } elsif ($type eq "concat") {
3795         my $first = $self->dq($op->first);
3796         my $last  = $self->dq($op->last);
3797
3798         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3799         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3800             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3801             || ($last =~ /^[:'{\[\w_]/ && #'
3802                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3803
3804         return $first . $last;
3805     } elsif ($type eq "uc") {
3806         return '\U' . $self->dq($op->first->sibling) . '\E';
3807     } elsif ($type eq "lc") {
3808         return '\L' . $self->dq($op->first->sibling) . '\E';
3809     } elsif ($type eq "ucfirst") {
3810         return '\u' . $self->dq($op->first->sibling);
3811     } elsif ($type eq "lcfirst") {
3812         return '\l' . $self->dq($op->first->sibling);
3813     } elsif ($type eq "quotemeta") {
3814         return '\Q' . $self->dq($op->first->sibling) . '\E';
3815     } elsif ($type eq "join") {
3816         return $self->deparse($op->last, 26); # was join($", @ary)
3817     } else {
3818         return $self->deparse($op, 26);
3819     }
3820 }
3821
3822 sub pp_backtick {
3823     my $self = shift;
3824     my($op, $cx) = @_;
3825     # skip pushmark if it exists (readpipe() vs ``)
3826     my $child = $op->first->sibling->isa('B::NULL')
3827         ? $op->first : $op->first->sibling;
3828     return single_delim("qx", '`', $self->dq($child));
3829 }
3830
3831 sub dquote {
3832     my $self = shift;
3833     my($op, $cx) = @_;
3834     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3835     return $self->deparse($kid, $cx) if $self->{'unquote'};
3836     $self->maybe_targmy($kid, $cx,
3837                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3838 }
3839
3840 # OP_STRINGIFY is a listop, but it only ever has one arg
3841 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3842
3843 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3844 # note that tr(from)/to/ is OK, but not tr/from/(to)
3845 sub double_delim {
3846     my($from, $to) = @_;
3847     my($succeed, $delim);
3848     if ($from !~ m[/] and $to !~ m[/]) {
3849         return "/$from/$to/";
3850     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3851         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3852             return "$from$to";
3853         } else {
3854             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3855                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3856             }
3857             $to =~ s[/][\\/]g;
3858             return "$from/$to/";
3859         }
3860     } else {
3861         for $delim ('/', '"', '#') { # note no '
3862             return "$delim$from$delim$to$delim"
3863                 if index($to . $from, $delim) == -1;
3864         }
3865         $from =~ s[/][\\/]g;
3866         $to =~ s[/][\\/]g;
3867         return "/$from/$to/";
3868     }
3869 }
3870
3871 # Only used by tr///, so backslashes hyphens
3872 sub pchr { # ASCII
3873     my($n) = @_;
3874     if ($n == ord '\\') {
3875         return '\\\\';
3876     } elsif ($n == ord "-") {
3877         return "\\-";
3878     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3879         return chr($n);
3880     } elsif ($n == ord "\a") {
3881         return '\\a';
3882     } elsif ($n == ord "\b") {
3883         return '\\b';
3884     } elsif ($n == ord "\t") {
3885         return '\\t';
3886     } elsif ($n == ord "\n") {
3887         return '\\n';
3888     } elsif ($n == ord "\e") {
3889         return '\\e';
3890     } elsif ($n == ord "\f") {
3891         return '\\f';
3892     } elsif ($n == ord "\r") {
3893         return '\\r';
3894     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3895         return '\\c' . chr(ord("@") + $n);
3896     } else {
3897 #       return '\x' . sprintf("%02x", $n);
3898         return '\\' . sprintf("%03o", $n);
3899     }
3900 }
3901
3902 sub collapse {
3903     my(@chars) = @_;
3904     my($str, $c, $tr) = ("");
3905     for ($c = 0; $c < @chars; $c++) {
3906         $tr = $chars[$c];
3907         $str .= pchr($tr);
3908         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3909             $chars[$c + 2] == $tr + 2)
3910         {
3911             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3912               {}
3913             $str .= "-";
3914             $str .= pchr($chars[$c]);
3915         }
3916     }
3917     return $str;
3918 }
3919
3920 sub tr_decode_byte {
3921     my($table, $flags) = @_;
3922     my(@table) = unpack("s*", $table);
3923     splice @table, 0x100, 1;   # Number of subsequent elements
3924     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3925     if ($table[ord "-"] != -1 and
3926         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3927     {
3928         $tr = $table[ord "-"];
3929         $table[ord "-"] = -1;
3930         if ($tr >= 0) {
3931             @from = ord("-");
3932             @to = $tr;
3933         } else { # -2 ==> delete
3934             $delhyphen = 1;
3935         }
3936     }
3937     for ($c = 0; $c < @table; $c++) {
3938         $tr = $table[$c];
3939         if ($tr >= 0) {
3940             push @from, $c; push @to, $tr;
3941         } elsif ($tr == -2) {
3942             push @delfrom, $c;
3943         }
3944     }
3945     @from = (@from, @delfrom);
3946     if ($flags & OPpTRANS_COMPLEMENT) {
3947         my @newfrom = ();
3948         my %from;
3949         @from{@from} = (1) x @from;
3950         for ($c = 0; $c < 256; $c++) {
3951             push @newfrom, $c unless $from{$c};
3952         }
3953         @from = @newfrom;
3954     }
3955     unless ($flags & OPpTRANS_DELETE || !@to) {
3956         pop @to while $#to and $to[$#to] == $to[$#to -1];
3957     }
3958     my($from, $to);
3959     $from = collapse(@from);
3960     $to = collapse(@to);
3961     $from .= "-" if $delhyphen;
3962     return ($from, $to);
3963 }
3964
3965 sub tr_chr {
3966     my $x = shift;
3967     if ($x == ord "-") {
3968         return "\\-";
3969     } elsif ($x == ord "\\") {
3970         return "\\\\";
3971     } else {
3972         return chr $x;
3973     }
3974 }
3975
3976 # XXX This doesn't yet handle all cases correctly either
3977
3978 sub tr_decode_utf8 {
3979     my($swash_hv, $flags) = @_;
3980     my %swash = $swash_hv->ARRAY;
3981     my $final = undef;
3982     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3983     my $none = $swash{"NONE"}->IV;
3984     my $extra = $none + 1;
3985     my(@from, @delfrom, @to);
3986     my $line;
3987     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3988         my($min, $max, $result) = split(/\t/, $line);
3989         $min = hex $min;
3990         if (length $max) {
3991             $max = hex $max;
3992         } else {
3993             $max = $min;
3994         }
3995         $result = hex $result;
3996         if ($result == $extra) {
3997             push @delfrom, [$min, $max];
3998         } else {
3999             push @from, [$min, $max];
4000             push @to, [$result, $result + $max - $min];
4001         }
4002     }
4003     for my $i (0 .. $#from) {
4004         if ($from[$i][0] == ord '-') {
4005             unshift @from, splice(@from, $i, 1);
4006             unshift @to, splice(@to, $i, 1);
4007             last;
4008         } elsif ($from[$i][1] == ord '-') {
4009             $from[$i][1]--;
4010             $to[$i][1]--;
4011             unshift @from, ord '-';
4012             unshift @to, ord '-';
4013             last;
4014         }
4015     }
4016     for my $i (0 .. $#delfrom) {
4017         if ($delfrom[$i][0] == ord '-') {
4018             push @delfrom, splice(@delfrom, $i, 1);
4019             last;
4020         } elsif ($delfrom[$i][1] == ord '-') {
4021             $delfrom[$i][1]--;
4022             push @delfrom, ord '-';
4023             last;
4024         }
4025     }
4026     if (defined $final and $to[$#to][1] != $final) {
4027         push @to, [$final, $final];
4028     }
4029     push @from, @delfrom;
4030     if ($flags & OPpTRANS_COMPLEMENT) {
4031         my @newfrom;
4032         my $next = 0;
4033         for my $i (0 .. $#from) {
4034             push @newfrom, [$next, $from[$i][0] - 1];
4035             $next = $from[$i][1] + 1;
4036         }
4037         @from = ();
4038         for my $range (@newfrom) {
4039             if ($range->[0] <= $range->[1]) {
4040                 push @from, $range;
4041             }
4042         }
4043     }
4044     my($from, $to, $diff);
4045     for my $chunk (@from) {
4046         $diff = $chunk->[1] - $chunk->[0];
4047         if ($diff > 1) {
4048             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4049         } elsif ($diff == 1) {
4050             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4051         } else {
4052             $from .= tr_chr($chunk->[0]);
4053         }
4054     }
4055     for my $chunk (@to) {
4056         $diff = $chunk->[1] - $chunk->[0];
4057         if ($diff > 1) {
4058             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4059         } elsif ($diff == 1) {
4060             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4061         } else {
4062             $to .= tr_chr($chunk->[0]);
4063         }
4064     }
4065     #$final = sprintf("%04x", $final) if defined $final;
4066     #$none = sprintf("%04x", $none) if defined $none;
4067     #$extra = sprintf("%04x", $extra) if defined $extra;
4068     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4069     #print STDERR $swash{'LIST'}->PV;
4070     return (escape_str($from), escape_str($to));
4071 }
4072
4073 sub pp_trans {
4074     my $self = shift;
4075     my($op, $cx) = @_;
4076     my($from, $to);
4077     if (class($op) eq "PVOP") {
4078         ($from, $to) = tr_decode_byte($op->pv, $op->private);
4079     } else { # class($op) eq "SVOP"
4080         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
4081     }
4082     my $flags = "";
4083     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
4084     $flags .= "d" if $op->private & OPpTRANS_DELETE;
4085     $to = "" if $from eq $to and $flags eq "";
4086     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
4087     return "tr" . double_delim($from, $to) . $flags;
4088 }
4089
4090 sub re_dq_disambiguate {
4091     my ($first, $last) = @_;
4092     # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4093     ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4094         $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4095         || ($last =~ /^[{\[\w_]/ &&
4096             $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4097     return $first . $last;
4098 }
4099
4100 # Like dq(), but different
4101 sub re_dq {
4102     my $self = shift;
4103     my ($op, $extended) = @_;
4104
4105     my $type = $op->name;
4106     if ($type eq "const") {
4107         return '$[' if $op->private & OPpCONST_ARYBASE;
4108         my $unbacked = re_unback($self->const_sv($op)->as_string);
4109         return re_uninterp_extended(escape_extended_re($unbacked))
4110             if $extended;
4111         return re_uninterp(escape_str($unbacked));
4112     } elsif ($type eq "concat") {
4113         my $first = $self->re_dq($op->first, $extended);
4114         my $last  = $self->re_dq($op->last,  $extended);
4115         return re_dq_disambiguate($first, $last);
4116     } elsif ($type eq "uc") {
4117         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4118     } elsif ($type eq "lc") {
4119         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4120     } elsif ($type eq "ucfirst") {
4121         return '\u' . $self->re_dq($op->first->sibling, $extended);
4122     } elsif ($type eq "lcfirst") {
4123         return '\l' . $self->re_dq($op->first->sibling, $extended);
4124     } elsif ($type eq "quotemeta") {
4125         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4126     } elsif ($type eq "join") {
4127         return $self->deparse($op->last, 26); # was join($", @ary)
4128     } else {
4129         return $self->deparse($op, 26);
4130     }
4131 }
4132
4133 sub pure_string {
4134     my ($self, $op) = @_;
4135     return 0 if null $op;
4136     my $type = $op->name;
4137
4138     if ($type eq 'const') {
4139         return 1;
4140     }
4141     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4142         return $self->pure_string($op->first->sibling);
4143     }
4144     elsif ($type eq 'join') {
4145         my $join_op = $op->first->sibling;  # Skip pushmark
4146         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4147
4148         my $gvop = $join_op->first;
4149         return 0 unless $gvop->name eq 'gvsv';
4150         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4151
4152         return 0 unless ${$join_op->sibling} eq ${$op->last};
4153         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4154     }
4155     elsif ($type eq 'concat') {
4156         return $self->pure_string($op->first)
4157             && $self->pure_string($op->last);
4158     }
4159     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4160         return 1;
4161     }
4162     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4163            $op->first->name eq "null" and $op->first->can('first')
4164            and not null $op->first->first and
4165            $op->first->first->name eq "aelemfast") {
4166         return 1;
4167     }
4168     else {
4169         return 0;
4170     }
4171
4172     return 1;
4173 }
4174
4175 sub regcomp {
4176     my $self = shift;
4177     my($op, $cx, $extended) = @_;
4178     my $kid = $op->first;
4179     $kid = $kid->first if $kid->name eq "regcmaybe";
4180     $kid = $kid->first if $kid->name eq "regcreset";
4181     if ($kid->name eq "null" and !null($kid->first)
4182         and $kid->first->name eq 'pushmark')
4183     {
4184         my $str = '';
4185         $kid = $kid->first->sibling;
4186         while (!null($kid)) {
4187             my $first = $str;
4188             my $last = $self->re_dq($kid, $extended);
4189             $str = re_dq_disambiguate($first, $last);
4190             $kid = $kid->sibling;
4191         }
4192         return $str, 1;
4193     }
4194
4195     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4196     return ($self->deparse($kid, $cx), 0);
4197 }
4198
4199 sub pp_regcomp {
4200     my ($self, $op, $cx) = @_;
4201     return (($self->regcomp($op, $cx, 0))[0]);
4202 }
4203
4204 # osmic acid -- see osmium tetroxide
4205
4206 my %matchwords;
4207 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4208     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4209     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4210
4211 sub matchop {
4212     my $self = shift;
4213     my($op, $cx, $name, $delim) = @_;
4214     my $kid = $op->first;
4215     my ($binop, $var, $re) = ("", "", "");
4216     if ($op->flags & OPf_STACKED) {
4217         $binop = 1;
4218         $var = $self->deparse($kid, 20);
4219         $kid = $kid->sibling;
4220     }
4221     my $quote = 1;
4222     my $extended = ($op->pmflags & PMf_EXTENDED);
4223     if (null $kid) {
4224         my $unbacked = re_unback($op->precomp);
4225         if ($extended) {
4226             $re = re_uninterp_extended(escape_extended_re($unbacked));
4227         } else {
4228             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4229         }
4230     } elsif ($kid->name ne 'regcomp') {
4231         carp("found ".$kid->name." where regcomp expected");
4232     } else {
4233         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4234     }
4235     my $flags = "";
4236     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4237     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4238     $flags .= "i" if $op->pmflags & PMf_FOLD;
4239     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4240     $flags .= "o" if $op->pmflags & PMf_KEEP;
4241     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4242     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4243     $flags = $matchwords{$flags} if $matchwords{$flags};
4244     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4245         $re =~ s/\?/\\?/g;
4246         $re = "?$re?";
4247     } elsif ($quote) {
4248         $re = single_delim($name, $delim, $re);
4249     }
4250     $re = $re . $flags if $quote;
4251     if ($binop) {
4252         return $self->maybe_parens("$var =~ $re", $cx, 20);
4253     } else {
4254         return $re;
4255     }
4256 }
4257
4258 sub pp_match { matchop(@_, "m", "/") }
4259 sub pp_pushre { matchop(@_, "m", "/") }
4260 sub pp_qr { matchop(@_, "qr", "") }
4261
4262 sub pp_split {
4263     my $self = shift;
4264     my($op, $cx) = @_;
4265     my($kid, @exprs, $ary, $expr);
4266     $kid = $op->first;
4267
4268     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4269     # root of a replacement; it's either empty, or abused to point to
4270     # the GV for an array we split into (an optimization to save
4271     # assignment overhead). Depending on whether we're using ithreads,
4272     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs
4273     # figures out for us which it is.
4274     my $replroot = $kid->pmreplroot;
4275     my $gv = 0;
4276     if (ref($replroot) eq "B::GV") {
4277         $gv = $replroot;
4278     } elsif (!ref($replroot) and $replroot > 0) {
4279         $gv = $self->padval($replroot);
4280     }
4281     $ary = $self->stash_variable('@', $self->gv_name($gv)) if $gv;
4282
4283     for (; !null($kid); $kid = $kid->sibling) {
4284         push @exprs, $self->deparse($kid, 6);
4285     }
4286
4287     # handle special case of split(), and split(' ') that compiles to /\s+/
4288     # Under 5.10, the reflags may be undef if the split regexp isn't a constant
4289     $kid = $op->first;
4290     if ( $kid->flags & OPf_SPECIAL
4291          and ( $] < 5.009 ? $kid->pmflags & PMf_SKIPWHITE()
4292               : ($kid->reflags || 0) & RXf_SKIPWHITE() ) ) {
4293         $exprs[0] = "' '";
4294     }
4295
4296     $expr = "split(" . join(", ", @exprs) . ")";
4297     if ($ary) {
4298         return $self->maybe_parens("$ary = $expr", $cx, 7);
4299     } else {
4300         return $expr;
4301     }
4302 }
4303
4304 # oxime -- any of various compounds obtained chiefly by the action of
4305 # hydroxylamine on aldehydes and ketones and characterized by the
4306 # bivalent grouping C=NOH [Webster's Tenth]
4307
4308 my %substwords;
4309 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
4310     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
4311     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
4312     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
4313
4314 sub pp_subst {
4315     my $self = shift;
4316     my($op, $cx) = @_;
4317     my $kid = $op->first;
4318     my($binop, $var, $re, $repl) = ("", "", "", "");
4319     if ($op->flags & OPf_STACKED) {
4320         $binop = 1;
4321         $var = $self->deparse($kid, 20);
4322         $kid = $kid->sibling;
4323     }
4324     my $flags = "";
4325     if (null($op->pmreplroot)) {
4326         $repl = $self->dq($kid);
4327         $kid = $kid->sibling;
4328     } else {
4329         $repl = $op->pmreplroot->first; # skip substcont
4330         while ($repl->name eq "entereval") {
4331             $repl = $repl->first;
4332             $flags .= "e";
4333         }
4334         if ($op->pmflags & PMf_EVAL) {
4335             $repl = $self->deparse($repl->first, 0);
4336         } else {
4337             $repl = $self->dq($repl);
4338         }
4339     }
4340     my $extended = ($op->pmflags & PMf_EXTENDED);
4341     if (null $kid) {
4342         my $unbacked = re_unback($op->precomp);
4343         if ($extended) {
4344             $re = re_uninterp_extended(escape_extended_re($unbacked));
4345         }
4346         else {
4347             $re = re_uninterp(escape_str($unbacked));
4348         }
4349     } else {
4350         ($re) = $self->regcomp($kid, 1, $extended);
4351     }
4352     $flags .= "e" if $op->pmflags & PMf_EVAL;
4353     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4354     $flags .= "i" if $op->pmflags & PMf_FOLD;
4355     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4356     $flags .= "o" if $op->pmflags & PMf_KEEP;
4357     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4358     $flags .= "x" if $extended;
4359     $flags = $substwords{$flags} if $substwords{$flags};
4360     if ($binop) {
4361         return $self->maybe_parens("$var =~ s"
4362                                    . double_delim($re, $repl) . $flags,
4363                                    $cx, 20);
4364     } else {
4365         return "s". double_delim($re, $repl) . $flags;
4366     }
4367 }
4368
4369 1;
4370 __END__
4371
4372 =head1 NAME
4373
4374 B::Deparse - Perl compiler backend to produce perl code
4375
4376