This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
aa861ae46e7149f7610c7f5db76412c3feb79b21
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item i
31 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
32 X<regular expression, case-insensitive>
33
34 Do case-insensitive pattern matching.
35
36 If C<use locale> is in effect, the case map is taken from the current
37 locale.  See L<perllocale>.
38
39 =item m
40 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
41
42 Treat string as multiple lines.  That is, change "^" and "$" from matching
43 the start or end of the string to matching the start or end of any
44 line anywhere within the string.
45
46 =item s
47 X</s> X<regex, single-line> X<regexp, single-line>
48 X<regular expression, single-line>
49
50 Treat string as single line.  That is, change "." to match any character
51 whatsoever, even a newline, which normally it would not match.
52
53 Used together, as /ms, they let the "." match any character whatsoever,
54 while still allowing "^" and "$" to match, respectively, just after
55 and just before newlines within the string.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =back
63
64 These are usually written as "the C</x> modifier", even though the delimiter
65 in question might not really be a slash.  Any of these
66 modifiers may also be embedded within the regular expression itself using
67 the C<(?...)> construct.  See below.
68
69 The C</x> modifier itself needs a little more explanation.  It tells
70 the regular expression parser to ignore whitespace that is neither
71 backslashed nor within a character class.  You can use this to break up
72 your regular expression into (slightly) more readable parts.  The C<#>
73 character is also treated as a metacharacter introducing a comment,
74 just as in ordinary Perl code.  This also means that if you want real
75 whitespace or C<#> characters in the pattern (outside a character
76 class, where they are unaffected by C</x>), then you'll either have to
77 escape them (using backslashes or C<\Q...\E>) or encode them using octal
78 or hex escapes.  Taken together, these features go a long way towards
79 making Perl's regular expressions more readable.  Note that you have to
80 be careful not to include the pattern delimiter in the comment--perl has
81 no way of knowing you did not intend to close the pattern early.  See
82 the C-comment deletion code in L<perlop>.  Also note that anything inside
83 a C<\Q...\E> stays unaffected by C</x>.
84 X</x>
85
86 =head2 Regular Expressions
87
88 =head3 Metacharacters
89
90 The patterns used in Perl pattern matching evolved from the ones supplied in
91 the Version 8 regex routines.  (The routines are derived
92 (distantly) from Henry Spencer's freely redistributable reimplementation
93 of the V8 routines.)  See L<Version 8 Regular Expressions> for
94 details.
95
96 In particular the following metacharacters have their standard I<egrep>-ish
97 meanings:
98 X<metacharacter>
99 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
100
101
102     \   Quote the next metacharacter
103     ^   Match the beginning of the line
104     .   Match any character (except newline)
105     $   Match the end of the line (or before newline at the end)
106     |   Alternation
107     ()  Grouping
108     []  Character class
109
110 By default, the "^" character is guaranteed to match only the
111 beginning of the string, the "$" character only the end (or before the
112 newline at the end), and Perl does certain optimizations with the
113 assumption that the string contains only one line.  Embedded newlines
114 will not be matched by "^" or "$".  You may, however, wish to treat a
115 string as a multi-line buffer, such that the "^" will match after any
116 newline within the string (except if the newline is the last character in
117 the string), and "$" will match before any newline.  At the
118 cost of a little more overhead, you can do this by using the /m modifier
119 on the pattern match operator.  (Older programs did this by setting C<$*>,
120 but this practice has been removed in perl 5.9.)
121 X<^> X<$> X</m>
122
123 To simplify multi-line substitutions, the "." character never matches a
124 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
125 the string is a single line--even if it isn't.
126 X<.> X</s>
127
128 =head3 Quantifiers
129
130 The following standard quantifiers are recognized:
131 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
132
133     *      Match 0 or more times
134     +      Match 1 or more times
135     ?      Match 1 or 0 times
136     {n}    Match exactly n times
137     {n,}   Match at least n times
138     {n,m}  Match at least n but not more than m times
139
140 (If a curly bracket occurs in any other context, it is treated
141 as a regular character.  In particular, the lower bound
142 is not optional.)  The "*" modifier is equivalent to C<{0,}>, the "+"
143 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
144 to integral values less than a preset limit defined when perl is built.
145 This is usually 32766 on the most common platforms.  The actual limit can
146 be seen in the error message generated by code such as this:
147
148     $_ **= $_ , / {$_} / for 2 .. 42;
149
150 By default, a quantified subpattern is "greedy", that is, it will match as
151 many times as possible (given a particular starting location) while still
152 allowing the rest of the pattern to match.  If you want it to match the
153 minimum number of times possible, follow the quantifier with a "?".  Note
154 that the meanings don't change, just the "greediness":
155 X<metacharacter> X<greedy> X<greediness>
156 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
157
158     *?     Match 0 or more times, not greedily
159     +?     Match 1 or more times, not greedily
160     ??     Match 0 or 1 time, not greedily
161     {n}?   Match exactly n times, not greedily
162     {n,}?  Match at least n times, not greedily
163     {n,m}? Match at least n but not more than m times, not greedily
164
165 By default, when a quantified subpattern does not allow the rest of the
166 overall pattern to match, Perl will backtrack. However, this behaviour is
167 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
168 as well.
169
170     *+     Match 0 or more times and give nothing back
171     ++     Match 1 or more times and give nothing back
172     ?+     Match 0 or 1 time and give nothing back
173     {n}+   Match exactly n times and give nothing back (redundant)
174     {n,}+  Match at least n times and give nothing back
175     {n,m}+ Match at least n but not more than m times and give nothing back
176
177 For instance,
178
179    'aaaa' =~ /a++a/
180
181 will never match, as the C<a++> will gobble up all the C<a>'s in the
182 string and won't leave any for the remaining part of the pattern. This
183 feature can be extremely useful to give perl hints about where it
184 shouldn't backtrack. For instance, the typical "match a double-quoted
185 string" problem can be most efficiently performed when written as:
186
187    /"(?:[^"\\]++|\\.)*+"/
188
189 as we know that if the final quote does not match, backtracking will not
190 help. See the independent subexpression C<< (?>...) >> for more details;
191 possessive quantifiers are just syntactic sugar for that construct. For
192 instance the above example could also be written as follows:
193
194    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
195
196 =head3 Escape sequences
197
198 Because patterns are processed as double quoted strings, the following
199 also work:
200 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
201 X<\0> X<\c> X<\N> X<\x>
202
203     \t          tab                   (HT, TAB)
204     \n          newline               (LF, NL)
205     \r          return                (CR)
206     \f          form feed             (FF)
207     \a          alarm (bell)          (BEL)
208     \e          escape (think troff)  (ESC)
209     \033        octal char            (example: ESC)
210     \x1B        hex char              (example: ESC)
211     \x{263a}    wide hex char         (example: Unicode SMILEY)
212     \cK         control char          (example: VT)
213     \N{name}    named char
214     \l          lowercase next char (think vi)
215     \u          uppercase next char (think vi)
216     \L          lowercase till \E (think vi)
217     \U          uppercase till \E (think vi)
218     \E          end case modification (think vi)
219     \Q          quote (disable) pattern metacharacters till \E
220
221 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
222 and C<\U> is taken from the current locale.  See L<perllocale>.  For
223 documentation of C<\N{name}>, see L<charnames>.
224
225 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
226 An unescaped C<$> or C<@> interpolates the corresponding variable,
227 while escaping will cause the literal string C<\$> to be matched.
228 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
229
230 =head3 Character classes
231
232 In addition, Perl defines the following:
233 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
234 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V>
235 X<word> X<whitespace> X<character class> X<backreference>
236
237     \w       Match a "word" character (alphanumeric plus "_")
238     \W       Match a non-"word" character
239     \s       Match a whitespace character
240     \S       Match a non-whitespace character
241     \d       Match a digit character
242     \D       Match a non-digit character
243     \pP      Match P, named property.  Use \p{Prop} for longer names.
244     \PP      Match non-P
245     \X       Match eXtended Unicode "combining character sequence",
246              equivalent to (?:\PM\pM*)
247     \C       Match a single C char (octet) even under Unicode.
248              NOTE: breaks up characters into their UTF-8 bytes,
249              so you may end up with malformed pieces of UTF-8.
250              Unsupported in lookbehind.
251     \1       Backreference to a specific group.
252              '1' may actually be any positive integer.
253     \g1      Backreference to a specific or previous group,
254     \g{-1}   number may be negative indicating a previous buffer and may
255              optionally be wrapped in curly brackets for safer parsing.
256     \g{name} Named backreference
257     \k<name> Named backreference
258     \N{name} Named unicode character, or unicode escape
259     \x12     Hexadecimal escape sequence
260     \x{1234} Long hexadecimal escape sequence
261     \K       Keep the stuff left of the \K, don't include it in $&
262     \v       Shortcut for (*PRUNE)
263     \V       Shortcut for (*SKIP)
264
265 A C<\w> matches a single alphanumeric character (an alphabetic
266 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
267 to match a string of Perl-identifier characters (which isn't the same
268 as matching an English word).  If C<use locale> is in effect, the list
269 of alphabetic characters generated by C<\w> is taken from the current
270 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
271 C<\d>, and C<\D> within character classes, but they aren't usable
272 as either end of a range. If any of them precedes or follows a "-",
273 the "-" is understood literally. If Unicode is in effect, C<\s> matches
274 also "\x{85}", "\x{2028}, and "\x{2029}". See L<perlunicode> for more
275 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
276 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
277 in general.
278 X<\w> X<\W> X<word>
279
280 The POSIX character class syntax
281 X<character class>
282
283     [:class:]
284
285 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
286 they must always be used within a character class expression.
287
288     # this is correct:
289     $string =~ /[[:alpha:]]/;
290
291     # this is not, and will generate a warning:
292     $string =~ /[:alpha:]/;
293
294 The available classes and their backslash equivalents (if available) are
295 as follows:
296 X<character class>
297 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
298 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
299
300     alpha
301     alnum
302     ascii
303     blank               [1]
304     cntrl
305     digit       \d
306     graph
307     lower
308     print
309     punct
310     space       \s      [2]
311     upper
312     word        \w      [3]
313     xdigit
314
315 =over
316
317 =item [1]
318
319 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
320
321 =item [2]
322
323 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
324 also the (very rare) "vertical tabulator", "\cK" or chr(11) in ASCII.
325
326 =item [3]
327
328 A Perl extension, see above.
329
330 =back
331
332 For example use C<[:upper:]> to match all the uppercase characters.
333 Note that the C<[]> are part of the C<[::]> construct, not part of the
334 whole character class.  For example:
335
336     [01[:alpha:]%]
337
338 matches zero, one, any alphabetic character, and the percent sign.
339
340 The following equivalences to Unicode \p{} constructs and equivalent
341 backslash character classes (if available), will hold:
342 X<character class> X<\p> X<\p{}>
343
344     [[:...:]]   \p{...}         backslash
345
346     alpha       IsAlpha
347     alnum       IsAlnum
348     ascii       IsASCII
349     blank
350     cntrl       IsCntrl
351     digit       IsDigit        \d
352     graph       IsGraph
353     lower       IsLower
354     print       IsPrint
355     punct       IsPunct
356     space       IsSpace
357                 IsSpacePerl    \s
358     upper       IsUpper
359     word        IsWord
360     xdigit      IsXDigit
361
362 For example C<[[:lower:]]> and C<\p{IsLower}> are equivalent.
363
364 If the C<utf8> pragma is not used but the C<locale> pragma is, the
365 classes correlate with the usual isalpha(3) interface (except for
366 "word" and "blank").
367
368 The assumedly non-obviously named classes are:
369
370 =over 4
371
372 =item cntrl
373 X<cntrl>
374
375 Any control character.  Usually characters that don't produce output as
376 such but instead control the terminal somehow: for example newline and
377 backspace are control characters.  All characters with ord() less than
378 32 are usually classified as control characters (assuming ASCII,
379 the ISO Latin character sets, and Unicode), as is the character with
380 the ord() value of 127 (C<DEL>).
381
382 =item graph
383 X<graph>
384
385 Any alphanumeric or punctuation (special) character.
386
387 =item print
388 X<print>
389
390 Any alphanumeric or punctuation (special) character or the space character.
391
392 =item punct
393 X<punct>
394
395 Any punctuation (special) character.
396
397 =item xdigit
398 X<xdigit>
399
400 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
401 work just fine) it is included for completeness.
402
403 =back
404
405 You can negate the [::] character classes by prefixing the class name
406 with a '^'. This is a Perl extension.  For example:
407 X<character class, negation>
408
409     POSIX         traditional  Unicode
410
411     [[:^digit:]]    \D         \P{IsDigit}
412     [[:^space:]]    \S         \P{IsSpace}
413     [[:^word:]]     \W         \P{IsWord}
414
415 Perl respects the POSIX standard in that POSIX character classes are
416 only supported within a character class.  The POSIX character classes
417 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
418 use them will cause an error.
419
420 =head3 Assertions
421
422 Perl defines the following zero-width assertions:
423 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
424 X<regexp, zero-width assertion>
425 X<regular expression, zero-width assertion>
426 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
427
428     \b  Match a word boundary
429     \B  Match except at a word boundary
430     \A  Match only at beginning of string
431     \Z  Match only at end of string, or before newline at the end
432     \z  Match only at end of string
433     \G  Match only at pos() (e.g. at the end-of-match position
434         of prior m//g)
435
436 A word boundary (C<\b>) is a spot between two characters
437 that has a C<\w> on one side of it and a C<\W> on the other side
438 of it (in either order), counting the imaginary characters off the
439 beginning and end of the string as matching a C<\W>.  (Within
440 character classes C<\b> represents backspace rather than a word
441 boundary, just as it normally does in any double-quoted string.)
442 The C<\A> and C<\Z> are just like "^" and "$", except that they
443 won't match multiple times when the C</m> modifier is used, while
444 "^" and "$" will match at every internal line boundary.  To match
445 the actual end of the string and not ignore an optional trailing
446 newline, use C<\z>.
447 X<\b> X<\A> X<\Z> X<\z> X</m>
448
449 The C<\G> assertion can be used to chain global matches (using
450 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
451 It is also useful when writing C<lex>-like scanners, when you have
452 several patterns that you want to match against consequent substrings
453 of your string, see the previous reference.  The actual location
454 where C<\G> will match can also be influenced by using C<pos()> as
455 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
456 matches is modified somewhat, in that contents to the left of C<\G> is
457 not counted when determining the length of the match. Thus the following
458 will not match forever:
459 X<\G>
460
461     $str = 'ABC';
462     pos($str) = 1;
463     while (/.\G/g) {
464         print $&;
465     }
466
467 It will print 'A' and then terminate, as it considers the match to
468 be zero-width, and thus will not match at the same position twice in a
469 row.
470
471 It is worth noting that C<\G> improperly used can result in an infinite
472 loop. Take care when using patterns that include C<\G> in an alternation.
473
474 =head3 Capture buffers
475
476 The bracketing construct C<( ... )> creates capture buffers. To refer
477 to the current contents of a buffer later on, within the same pattern,
478 use \1 for the first, \2 for the second, and so on.
479 Outside the match use "$" instead of "\".  (The
480 \<digit> notation works in certain circumstances outside
481 the match.  See the warning below about \1 vs $1 for details.)
482 Referring back to another part of the match is called a
483 I<backreference>.
484 X<regex, capture buffer> X<regexp, capture buffer>
485 X<regular expression, capture buffer> X<backreference>
486
487 There is no limit to the number of captured substrings that you may
488 use.  However Perl also uses \10, \11, etc. as aliases for \010,
489 \011, etc.  (Recall that 0 means octal, so \011 is the character at
490 number 9 in your coded character set; which would be the 10th character,
491 a horizontal tab under ASCII.)  Perl resolves this
492 ambiguity by interpreting \10 as a backreference only if at least 10
493 left parentheses have opened before it.  Likewise \11 is a
494 backreference only if at least 11 left parentheses have opened
495 before it.  And so on.  \1 through \9 are always interpreted as
496 backreferences.
497
498 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
499 In order to provide a safer and easier way to construct patterns using
500 backreferences, Perl 5.10 provides the C<\g{N}> notation. The curly
501 brackets are optional, however omitting them is less safe as the meaning
502 of the pattern can be changed by text (such as digits) following it.
503 When N is a positive integer the C<\g{N}> notation is exactly equivalent
504 to using normal backreferences. When N is a negative integer then it is
505 a relative backreference referring to the previous N'th capturing group.
506 When the bracket form is used and N is not an integer, it is treated as a
507 reference to a named buffer.
508
509 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
510 buffer before that. For example:
511
512         /
513          (Y)            # buffer 1
514          (              # buffer 2
515             (X)         # buffer 3
516             \g{-1}      # backref to buffer 3
517             \g{-3}      # backref to buffer 1
518          )
519         /x
520
521 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
522
523 Additionally, as of Perl 5.10 you may use named capture buffers and named
524 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
525 to reference. You may also use apostrophes instead of angle brackets to delimit the
526 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
527 It's possible to refer to a named capture buffer by absolute and relative number as well.
528 Outside the pattern, a named capture buffer is available via the C<%+> hash.
529 When different buffers within the same pattern have the same name, C<$+{name}>
530 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
531 to do things with named capture buffers that would otherwise require C<(??{})>
532 code to accomplish.)
533 X<named capture buffer> X<regular expression, named capture buffer>
534 X<%+> X<$+{name}> X<\k{name}>
535
536 Examples:
537
538     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
539
540     /(.)\1/                         # find first doubled char
541          and print "'$1' is the first doubled character\n";
542
543     /(?<char>.)\k<char>/            # ... a different way
544          and print "'$+{char}' is the first doubled character\n";
545
546     /(?'char'.)\1/                  # ... mix and match
547          and print "'$1' is the first doubled character\n";
548
549     if (/Time: (..):(..):(..)/) {   # parse out values
550         $hours = $1;
551         $minutes = $2;
552         $seconds = $3;
553     }
554
555 Several special variables also refer back to portions of the previous
556 match.  C<$+> returns whatever the last bracket match matched.
557 C<$&> returns the entire matched string.  (At one point C<$0> did
558 also, but now it returns the name of the program.)  C<$`> returns
559 everything before the matched string.  C<$'> returns everything
560 after the matched string. And C<$^N> contains whatever was matched by
561 the most-recently closed group (submatch). C<$^N> can be used in
562 extended patterns (see below), for example to assign a submatch to a
563 variable.
564 X<$+> X<$^N> X<$&> X<$`> X<$'>
565
566 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
567 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
568 until the end of the enclosing block or until the next successful
569 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
570 X<$+> X<$^N> X<$&> X<$`> X<$'>
571 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
572
573
574 B<NOTE>: Failed matches in Perl do not reset the match variables,
575 which makes it easier to write code that tests for a series of more
576 specific cases and remembers the best match.
577
578 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
579 C<$'> anywhere in the program, it has to provide them for every
580 pattern match.  This may substantially slow your program.  Perl
581 uses the same mechanism to produce $1, $2, etc, so you also pay a
582 price for each pattern that contains capturing parentheses.  (To
583 avoid this cost while retaining the grouping behaviour, use the
584 extended regular expression C<(?: ... )> instead.)  But if you never
585 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
586 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
587 if you can, but if you can't (and some algorithms really appreciate
588 them), once you've used them once, use them at will, because you've
589 already paid the price.  As of 5.005, C<$&> is not so costly as the
590 other two.
591 X<$&> X<$`> X<$'>
592
593 As a workaround for this problem, Perl 5.10 introduces C<${^PREMATCH}>,
594 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
595 and C<$'>, B<except> that they are only guaranteed to be defined after a
596 successful match that was executed with the C</k> (keep-copy) modifier.
597 The use of these variables incurs no global performance penalty, unlike
598 their punctuation char equivalents, however at the trade-off that you
599 have to tell perl when you want to use them.
600 X</k> X<k modifier>
601
602 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
603 C<\w>, C<\n>.  Unlike some other regular expression languages, there
604 are no backslashed symbols that aren't alphanumeric.  So anything
605 that looks like \\, \(, \), \<, \>, \{, or \} is always
606 interpreted as a literal character, not a metacharacter.  This was
607 once used in a common idiom to disable or quote the special meanings
608 of regular expression metacharacters in a string that you want to
609 use for a pattern. Simply quote all non-"word" characters:
610
611     $pattern =~ s/(\W)/\\$1/g;
612
613 (If C<use locale> is set, then this depends on the current locale.)
614 Today it is more common to use the quotemeta() function or the C<\Q>
615 metaquoting escape sequence to disable all metacharacters' special
616 meanings like this:
617
618     /$unquoted\Q$quoted\E$unquoted/
619
620 Beware that if you put literal backslashes (those not inside
621 interpolated variables) between C<\Q> and C<\E>, double-quotish
622 backslash interpolation may lead to confusing results.  If you
623 I<need> to use literal backslashes within C<\Q...\E>,
624 consult L<perlop/"Gory details of parsing quoted constructs">.
625
626 =head2 Extended Patterns
627
628 Perl also defines a consistent extension syntax for features not
629 found in standard tools like B<awk> and B<lex>.  The syntax is a
630 pair of parentheses with a question mark as the first thing within
631 the parentheses.  The character after the question mark indicates
632 the extension.
633
634 The stability of these extensions varies widely.  Some have been
635 part of the core language for many years.  Others are experimental
636 and may change without warning or be completely removed.  Check
637 the documentation on an individual feature to verify its current
638 status.
639
640 A question mark was chosen for this and for the minimal-matching
641 construct because 1) question marks are rare in older regular
642 expressions, and 2) whenever you see one, you should stop and
643 "question" exactly what is going on.  That's psychology...
644
645 =over 10
646
647 =item C<(?#text)>
648 X<(?#)>
649
650 A comment.  The text is ignored.  If the C</x> modifier enables
651 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
652 the comment as soon as it sees a C<)>, so there is no way to put a literal
653 C<)> in the comment.
654
655 =item C<(?kimsx-imsx)>
656 X<(?)>
657
658 One or more embedded pattern-match modifiers, to be turned on (or
659 turned off, if preceded by C<->) for the remainder of the pattern or
660 the remainder of the enclosing pattern group (if any). This is
661 particularly useful for dynamic patterns, such as those read in from a
662 configuration file, taken from an argument, or specified in a table
663 somewhere.  Consider the case where some patterns want to be case
664 sensitive and some do not:  The case insensitive ones merely need to
665 include C<(?i)> at the front of the pattern.  For example:
666
667     $pattern = "foobar";
668     if ( /$pattern/i ) { }
669
670     # more flexible:
671
672     $pattern = "(?i)foobar";
673     if ( /$pattern/ ) { }
674
675 These modifiers are restored at the end of the enclosing group. For example,
676
677     ( (?i) blah ) \s+ \1
678
679 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
680 repetition of the previous word, assuming the C</x> modifier, and no C</i>
681 modifier outside this group.
682
683 Note that the C<k> modifier is special in that it can only be enabled,
684 not disabled, and that its presence anywhere in a pattern has a global
685 effect. Thus C<(?-k)> and C<(?-k:...)> are meaningless and will warn
686 when executed under C<use warnings>.
687
688 =item C<(?:pattern)>
689 X<(?:)>
690
691 =item C<(?imsx-imsx:pattern)>
692
693 This is for clustering, not capturing; it groups subexpressions like
694 "()", but doesn't make backreferences as "()" does.  So
695
696     @fields = split(/\b(?:a|b|c)\b/)
697
698 is like
699
700     @fields = split(/\b(a|b|c)\b/)
701
702 but doesn't spit out extra fields.  It's also cheaper not to capture
703 characters if you don't need to.
704
705 Any letters between C<?> and C<:> act as flags modifiers as with
706 C<(?imsx-imsx)>.  For example,
707
708     /(?s-i:more.*than).*million/i
709
710 is equivalent to the more verbose
711
712     /(?:(?s-i)more.*than).*million/i
713
714 =item C<(?|pattern)>
715 X<(?|)> X<Branch reset>
716
717 This is the "branch reset" pattern, which has the special property
718 that the capture buffers are numbered from the same starting point
719 in each branch. It is available starting from perl 5.10.
720
721 Normally capture buffers in a pattern are numbered sequentially,
722 from left to right.  Inside this construct that behaviour is
723 overridden so that the capture buffers are shared between all the
724 branches and take their values from the branch that matched.
725
726 The numbering within each branch will be as normal, and any buffers
727 following this construct will be numbered as though the construct
728 contained only one branch, that being the one with the most capture
729 buffers in it.
730
731 This construct will be useful when you want to capture one of a
732 number of alternative matches.
733
734 Consider the following pattern.  The numbers underneath show in
735 which buffer the captured content will be stored.
736
737
738     # before  ---------------branch-reset----------- after        
739     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
740     # 1            2         2  3        2     3     4  
741
742 =item Look-Around Assertions
743 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
744
745 Look-around assertions are zero width patterns which match a specific
746 pattern without including it in C<$&>. Positive assertions match when
747 their subpattern matches, negative assertions match when their subpattern
748 fails. Look-behind matches text up to the current match position,
749 look-ahead matches text following the current match position.
750
751 =over 4
752
753 =item C<(?=pattern)>
754 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
755
756 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
757 matches a word followed by a tab, without including the tab in C<$&>.
758
759 =item C<(?!pattern)>
760 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
761
762 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
763 matches any occurrence of "foo" that isn't followed by "bar".  Note
764 however that look-ahead and look-behind are NOT the same thing.  You cannot
765 use this for look-behind.
766
767 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
768 will not do what you want.  That's because the C<(?!foo)> is just saying that
769 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
770 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
771 say "like" because there's the case of your "bar" not having three characters
772 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
773 Sometimes it's still easier just to say:
774
775     if (/bar/ && $` !~ /foo$/)
776
777 For look-behind see below.
778
779 =item C<(?<=pattern)> C<\K>
780 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
781
782 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
783 matches a word that follows a tab, without including the tab in C<$&>.
784 Works only for fixed-width look-behind.
785
786 There is a special form of this construct, called C<\K>, which causes the
787 regex engine to "keep" everything it had matched prior to the C<\K> and
788 not include it in C<$&>. This effectively provides variable length
789 look-behind. The use of C<\K> inside of another look-around assertion
790 is allowed, but the behaviour is currently not well defined.
791
792 For various reasons C<\K> may be signifigantly more efficient than the
793 equivalent C<< (?<=...) >> construct, and it is especially useful in
794 situations where you want to efficiently remove something following
795 something else in a string. For instance
796
797   s/(foo)bar/$1/g;
798
799 can be rewritten as the much more efficient
800
801   s/foo\Kbar//g;
802
803 =item C<(?<!pattern)>
804 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
805
806 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
807 matches any occurrence of "foo" that does not follow "bar".  Works
808 only for fixed-width look-behind.
809
810 =back
811
812 =item C<(?'NAME'pattern)>
813
814 =item C<< (?<NAME>pattern) >>
815 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
816
817 A named capture buffer. Identical in every respect to normal capturing
818 parentheses C<()> but for the additional fact that C<%+> may be used after
819 a succesful match to refer to a named buffer. See C<perlvar> for more
820 details on the C<%+> hash.
821
822 If multiple distinct capture buffers have the same name then the
823 $+{NAME} will refer to the leftmost defined buffer in the match.
824
825 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
826
827 B<NOTE:> While the notation of this construct is the same as the similar
828 function in .NET regexes, the behavior is not. In Perl the buffers are
829 numbered sequentially regardless of being named or not. Thus in the
830 pattern
831
832   /(x)(?<foo>y)(z)/
833
834 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
835 the opposite which is what a .NET regex hacker might expect.
836
837 Currently NAME is restricted to simple identifiers only.
838 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
839 its Unicode extension (see L<utf8>),
840 though it isn't extended by the locale (see L<perllocale>).
841
842 B<NOTE:> In order to make things easier for programmers with experience
843 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
844 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
845 support the use of single quotes as a delimiter for the name. This is
846 only available in Perl 5.10 or later.
847
848 =item C<< \k<NAME> >>
849
850 =item C<< \k'NAME' >>
851
852 Named backreference. Similar to numeric backreferences, except that
853 the group is designated by name and not number. If multiple groups
854 have the same name then it refers to the leftmost defined group in
855 the current match.
856
857 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
858 earlier in the pattern.
859
860 Both forms are equivalent.
861
862 B<NOTE:> In order to make things easier for programmers with experience
863 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
864 may be used instead of C<< \k<NAME> >> in Perl 5.10 or later.
865
866 =item C<(?{ code })>
867 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
868
869 B<WARNING>: This extended regular expression feature is considered
870 experimental, and may be changed without notice. Code executed that
871 has side effects may not perform identically from version to version
872 due to the effect of future optimisations in the regex engine.
873
874 This zero-width assertion evaluates any embedded Perl code.  It
875 always succeeds, and its C<code> is not interpolated.  Currently,
876 the rules to determine where the C<code> ends are somewhat convoluted.
877
878 This feature can be used together with the special variable C<$^N> to
879 capture the results of submatches in variables without having to keep
880 track of the number of nested parentheses. For example:
881
882   $_ = "The brown fox jumps over the lazy dog";
883   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
884   print "color = $color, animal = $animal\n";
885
886 Inside the C<(?{...})> block, C<$_> refers to the string the regular
887 expression is matching against. You can also use C<pos()> to know what is
888 the current position of matching within this string.
889
890 The C<code> is properly scoped in the following sense: If the assertion
891 is backtracked (compare L<"Backtracking">), all changes introduced after
892 C<local>ization are undone, so that
893
894   $_ = 'a' x 8;
895   m<
896      (?{ $cnt = 0 })                    # Initialize $cnt.
897      (
898        a
899        (?{
900            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
901        })
902      )*
903      aaaa
904      (?{ $res = $cnt })                 # On success copy to non-localized
905                                         # location.
906    >x;
907
908 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
909 introduced value, because the scopes that restrict C<local> operators
910 are unwound.
911
912 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
913 switch.  If I<not> used in this way, the result of evaluation of
914 C<code> is put into the special variable C<$^R>.  This happens
915 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
916 inside the same regular expression.
917
918 The assignment to C<$^R> above is properly localized, so the old
919 value of C<$^R> is restored if the assertion is backtracked; compare
920 L<"Backtracking">.
921
922 Due to an unfortunate implementation issue, the Perl code contained in these
923 blocks is treated as a compile time closure that can have seemingly bizarre
924 consequences when used with lexically scoped variables inside of subroutines
925 or loops.  There are various workarounds for this, including simply using
926 global variables instead.  If you are using this construct and strange results
927 occur then check for the use of lexically scoped variables.
928
929 For reasons of security, this construct is forbidden if the regular
930 expression involves run-time interpolation of variables, unless the
931 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
932 variables contain results of C<qr//> operator (see
933 L<perlop/"qr/STRING/imosx">).
934
935 This restriction is due to the wide-spread and remarkably convenient
936 custom of using run-time determined strings as patterns.  For example:
937
938     $re = <>;
939     chomp $re;
940     $string =~ /$re/;
941
942 Before Perl knew how to execute interpolated code within a pattern,
943 this operation was completely safe from a security point of view,
944 although it could raise an exception from an illegal pattern.  If
945 you turn on the C<use re 'eval'>, though, it is no longer secure,
946 so you should only do so if you are also using taint checking.
947 Better yet, use the carefully constrained evaluation within a Safe
948 compartment.  See L<perlsec> for details about both these mechanisms.
949
950 Because Perl's regex engine is currently not re-entrant, interpolated
951 code may not invoke the regex engine either directly with C<m//> or C<s///>),
952 or indirectly with functions such as C<split>.
953
954 =item C<(??{ code })>
955 X<(??{})>
956 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
957
958 B<WARNING>: This extended regular expression feature is considered
959 experimental, and may be changed without notice. Code executed that
960 has side effects may not perform identically from version to version
961 due to the effect of future optimisations in the regex engine.
962
963 This is a "postponed" regular subexpression.  The C<code> is evaluated
964 at run time, at the moment this subexpression may match.  The result
965 of evaluation is considered as a regular expression and matched as
966 if it were inserted instead of this construct.  Note that this means
967 that the contents of capture buffers defined inside an eval'ed pattern
968 are not available outside of the pattern, and vice versa, there is no
969 way for the inner pattern to refer to a capture buffer defined outside.
970 Thus,
971
972     ('a' x 100)=~/(??{'(.)' x 100})/
973
974 B<will> match, it will B<not> set $1.
975
976 The C<code> is not interpolated.  As before, the rules to determine
977 where the C<code> ends are currently somewhat convoluted.
978
979 The following pattern matches a parenthesized group:
980
981   $re = qr{
982              \(
983              (?:
984                 (?> [^()]+ )    # Non-parens without backtracking
985               |
986                 (??{ $re })     # Group with matching parens
987              )*
988              \)
989           }x;
990
991 See also C<(?PARNO)> for a different, more efficient way to accomplish
992 the same task.
993
994 Because perl's regex engine is not currently re-entrant, delayed
995 code may not invoke the regex engine either directly with C<m//> or C<s///>),
996 or indirectly with functions such as C<split>.
997
998 Recursing deeper than 50 times without consuming any input string will
999 result in a fatal error.  The maximum depth is compiled into perl, so
1000 changing it requires a custom build.
1001
1002 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1003 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1004 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1005 X<regex, relative recursion>
1006
1007 Similar to C<(??{ code })> except it does not involve compiling any code,
1008 instead it treats the contents of a capture buffer as an independent
1009 pattern that must match at the current position.  Capture buffers
1010 contained by the pattern will have the value as determined by the
1011 outermost recursion.
1012
1013 PARNO is a sequence of digits (not starting with 0) whose value reflects
1014 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1015 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1016 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1017 to be relative, with negative numbers indicating preceding capture buffers
1018 and positive ones following. Thus C<(?-1)> refers to the most recently
1019 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1020 Note that the counting for relative recursion differs from that of
1021 relative backreferences, in that with recursion unclosed buffers B<are>
1022 included.
1023
1024 The following pattern matches a function foo() which may contain
1025 balanced parentheses as the argument.
1026
1027   $re = qr{ (                    # paren group 1 (full function)
1028               foo
1029               (                  # paren group 2 (parens)
1030                 \(
1031                   (              # paren group 3 (contents of parens)
1032                   (?:
1033                    (?> [^()]+ )  # Non-parens without backtracking
1034                   |
1035                    (?2)          # Recurse to start of paren group 2
1036                   )*
1037                   )
1038                 \)
1039               )
1040             )
1041           }x;
1042
1043 If the pattern was used as follows
1044
1045     'foo(bar(baz)+baz(bop))'=~/$re/
1046         and print "\$1 = $1\n",
1047                   "\$2 = $2\n",
1048                   "\$3 = $3\n";
1049
1050 the output produced should be the following:
1051
1052     $1 = foo(bar(baz)+baz(bop))
1053     $2 = (bar(baz)+baz(bop))
1054     $3 = bar(baz)+baz(bop)
1055
1056 If there is no corresponding capture buffer defined, then it is a
1057 fatal error.  Recursing deeper than 50 times without consuming any input
1058 string will also result in a fatal error.  The maximum depth is compiled
1059 into perl, so changing it requires a custom build.
1060
1061 The following shows how using negative indexing can make it
1062 easier to embed recursive patterns inside of a C<qr//> construct
1063 for later use:
1064
1065     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1066     if (/foo $parens \s+ + \s+ bar $parens/x) {
1067        # do something here...
1068     }
1069
1070 B<Note> that this pattern does not behave the same way as the equivalent
1071 PCRE or Python construct of the same form. In Perl you can backtrack into
1072 a recursed group, in PCRE and Python the recursed into group is treated
1073 as atomic. Also, modifiers are resolved at compile time, so constructs
1074 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1075 be processed.
1076
1077 =item C<(?&NAME)>
1078 X<(?&NAME)>
1079
1080 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1081 parenthesis to recurse to is determined by name. If multiple parentheses have
1082 the same name, then it recurses to the leftmost.
1083
1084 It is an error to refer to a name that is not declared somewhere in the
1085 pattern.
1086
1087 B<NOTE:> In order to make things easier for programmers with experience
1088 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1089 may be used instead of C<< (?&NAME) >> in Perl 5.10 or later.
1090
1091 =item C<(?(condition)yes-pattern|no-pattern)>
1092 X<(?()>
1093
1094 =item C<(?(condition)yes-pattern)>
1095
1096 Conditional expression.  C<(condition)> should be either an integer in
1097 parentheses (which is valid if the corresponding pair of parentheses
1098 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1099 name in angle brackets or single quotes (which is valid if a buffer
1100 with the given name matched), or the special symbol (R) (true when
1101 evaluated inside of recursion or eval). Additionally the R may be
1102 followed by a number, (which will be true when evaluated when recursing
1103 inside of the appropriate group), or by C<&NAME>, in which case it will
1104 be true only when evaluated during recursion in the named group.
1105
1106 Here's a summary of the possible predicates:
1107
1108 =over 4
1109
1110 =item (1) (2) ...
1111
1112 Checks if the numbered capturing buffer has matched something.
1113
1114 =item (<NAME>) ('NAME')
1115
1116 Checks if a buffer with the given name has matched something.
1117
1118 =item (?{ CODE })
1119
1120 Treats the code block as the condition.
1121
1122 =item (R)
1123
1124 Checks if the expression has been evaluated inside of recursion.
1125
1126 =item (R1) (R2) ...
1127
1128 Checks if the expression has been evaluated while executing directly
1129 inside of the n-th capture group. This check is the regex equivalent of
1130
1131   if ((caller(0))[3] eq 'subname') { ... }
1132
1133 In other words, it does not check the full recursion stack.
1134
1135 =item (R&NAME)
1136
1137 Similar to C<(R1)>, this predicate checks to see if we're executing
1138 directly inside of the leftmost group with a given name (this is the same
1139 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1140 stack, but only the name of the innermost active recursion.
1141
1142 =item (DEFINE)
1143
1144 In this case, the yes-pattern is never directly executed, and no
1145 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1146 See below for details.
1147
1148 =back
1149
1150 For example:
1151
1152     m{ ( \( )?
1153        [^()]+
1154        (?(1) \) )
1155      }x
1156
1157 matches a chunk of non-parentheses, possibly included in parentheses
1158 themselves.
1159
1160 A special form is the C<(DEFINE)> predicate, which never executes directly
1161 its yes-pattern, and does not allow a no-pattern. This allows to define
1162 subpatterns which will be executed only by using the recursion mechanism.
1163 This way, you can define a set of regular expression rules that can be
1164 bundled into any pattern you choose.
1165
1166 It is recommended that for this usage you put the DEFINE block at the
1167 end of the pattern, and that you name any subpatterns defined within it.
1168
1169 Also, it's worth noting that patterns defined this way probably will
1170 not be as efficient, as the optimiser is not very clever about
1171 handling them.
1172
1173 An example of how this might be used is as follows:
1174
1175   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1176    (?(DEFINE)
1177      (?<NAME_PAT>....)
1178      (?<ADRESS_PAT>....)
1179    )/x
1180
1181 Note that capture buffers matched inside of recursion are not accessible
1182 after the recursion returns, so the extra layer of capturing buffers is
1183 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1184 C<$+{NAME}> would be.
1185
1186 =item C<< (?>pattern) >>
1187 X<backtrack> X<backtracking> X<atomic> X<possessive>
1188
1189 An "independent" subexpression, one which matches the substring
1190 that a I<standalone> C<pattern> would match if anchored at the given
1191 position, and it matches I<nothing other than this substring>.  This
1192 construct is useful for optimizations of what would otherwise be
1193 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1194 It may also be useful in places where the "grab all you can, and do not
1195 give anything back" semantic is desirable.
1196
1197 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1198 (anchored at the beginning of string, as above) will match I<all>
1199 characters C<a> at the beginning of string, leaving no C<a> for
1200 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1201 since the match of the subgroup C<a*> is influenced by the following
1202 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1203 C<a*ab> will match fewer characters than a standalone C<a*>, since
1204 this makes the tail match.
1205
1206 An effect similar to C<< (?>pattern) >> may be achieved by writing
1207 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1208 C<a+>, and the following C<\1> eats the matched string; it therefore
1209 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1210 (The difference between these two constructs is that the second one
1211 uses a capturing group, thus shifting ordinals of backreferences
1212 in the rest of a regular expression.)
1213
1214 Consider this pattern:
1215
1216     m{ \(
1217           (
1218             [^()]+              # x+
1219           |
1220             \( [^()]* \)
1221           )+
1222        \)
1223      }x
1224
1225 That will efficiently match a nonempty group with matching parentheses
1226 two levels deep or less.  However, if there is no such group, it
1227 will take virtually forever on a long string.  That's because there
1228 are so many different ways to split a long string into several
1229 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1230 to a subpattern of the above pattern.  Consider how the pattern
1231 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1232 seconds, but that each extra letter doubles this time.  This
1233 exponential performance will make it appear that your program has
1234 hung.  However, a tiny change to this pattern
1235
1236     m{ \(
1237           (
1238             (?> [^()]+ )        # change x+ above to (?> x+ )
1239           |
1240             \( [^()]* \)
1241           )+
1242        \)
1243      }x
1244
1245 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1246 this yourself would be a productive exercise), but finishes in a fourth
1247 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1248 however, that this pattern currently triggers a warning message under
1249 the C<use warnings> pragma or B<-w> switch saying it
1250 C<"matches null string many times in regex">.
1251
1252 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1253 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1254 This was only 4 times slower on a string with 1000000 C<a>s.
1255
1256 The "grab all you can, and do not give anything back" semantic is desirable
1257 in many situations where on the first sight a simple C<()*> looks like
1258 the correct solution.  Suppose we parse text with comments being delimited
1259 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1260 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1261 the comment delimiter, because it may "give up" some whitespace if
1262 the remainder of the pattern can be made to match that way.  The correct
1263 answer is either one of these:
1264
1265     (?>#[ \t]*)
1266     #[ \t]*(?![ \t])
1267
1268 For example, to grab non-empty comments into $1, one should use either
1269 one of these:
1270
1271     / (?> \# [ \t]* ) (        .+ ) /x;
1272     /     \# [ \t]*   ( [^ \t] .* ) /x;
1273
1274 Which one you pick depends on which of these expressions better reflects
1275 the above specification of comments.
1276
1277 In some literature this construct is called "atomic matching" or
1278 "possessive matching".
1279
1280 Possessive quantifiers are equivalent to putting the item they are applied
1281 to inside of one of these constructs. The following equivalences apply:
1282
1283     Quantifier Form     Bracketing Form
1284     ---------------     ---------------
1285     PAT*+               (?>PAT*)
1286     PAT++               (?>PAT+)
1287     PAT?+               (?>PAT?)
1288     PAT{min,max}+       (?>PAT{min,max})
1289
1290 =back
1291
1292 =head2 Special Backtracking Control Verbs
1293
1294 B<WARNING:> These patterns are experimental and subject to change or
1295 removal in a future version of Perl. Their usage in production code should
1296 be noted to avoid problems during upgrades.
1297
1298 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1299 otherwise stated the ARG argument is optional; in some cases, it is
1300 forbidden.
1301
1302 Any pattern containing a special backtracking verb that allows an argument
1303 has the special behaviour that when executed it sets the current packages'
1304 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1305 rules apply:
1306
1307 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1308 verb pattern, if the verb was involved in the failure of the match. If the
1309 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1310 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1311 none. Also, the C<$REGMARK> variable will be set to FALSE.
1312
1313 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1314 the C<$REGMARK> variable will be set to the name of the last
1315 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1316 C<(*MARK:NAME)> verb below for more details.
1317
1318 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1319 and most other regex related variables. They are not local to a scope, nor
1320 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1321 Use C<local> to localize changes to them to a specific scope if necessary.
1322
1323 If a pattern does not contain a special backtracking verb that allows an
1324 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1325
1326 =over 4
1327
1328 =item Verbs that take an argument
1329
1330 =over 4
1331
1332 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1333 X<(*PRUNE)> X<(*PRUNE:NAME)> X<\v>
1334
1335 This zero-width pattern prunes the backtracking tree at the current point
1336 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1337 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1338 A may backtrack as necessary to match. Once it is reached, matching
1339 continues in B, which may also backtrack as necessary; however, should B
1340 not match, then no further backtracking will take place, and the pattern
1341 will fail outright at the current starting position.
1342
1343 As a shortcut, C<\v> is exactly equivalent to C<(*PRUNE)>.
1344
1345 The following example counts all the possible matching strings in a
1346 pattern (without actually matching any of them).
1347
1348     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1349     print "Count=$count\n";
1350
1351 which produces:
1352
1353     aaab
1354     aaa
1355     aa
1356     a
1357     aab
1358     aa
1359     a
1360     ab
1361     a
1362     Count=9
1363
1364 If we add a C<(*PRUNE)> before the count like the following
1365
1366     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1367     print "Count=$count\n";
1368
1369 we prevent backtracking and find the count of the longest matching
1370 at each matching startpoint like so:
1371
1372     aaab
1373     aab
1374     ab
1375     Count=3
1376
1377 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1378
1379 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1380 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1381 replaced with a C<< (?>pattern) >> with no functional difference; however,
1382 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1383 C<< (?>pattern) >> alone.
1384
1385
1386 =item C<(*SKIP)> C<(*SKIP:NAME)>
1387 X<(*SKIP)>
1388
1389 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1390 failure it also signifies that whatever text that was matched leading up
1391 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1392 of this pattern. This effectively means that the regex engine "skips" forward
1393 to this position on failure and tries to match again, (assuming that
1394 there is sufficient room to match).
1395
1396 As a shortcut C<\V> is exactly equivalent to C<(*SKIP)>.
1397
1398 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1399 C<(*MARK:NAME)> was encountered while matching, then it is that position
1400 which is used as the "skip point". If no C<(*MARK)> of that name was
1401 encountered, then the C<(*SKIP)> operator has no effect. When used
1402 without a name the "skip point" is where the match point was when
1403 executing the (*SKIP) pattern.
1404
1405 Compare the following to the examples in C<(*PRUNE)>, note the string
1406 is twice as long:
1407
1408     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1409     print "Count=$count\n";
1410
1411 outputs
1412
1413     aaab
1414     aaab
1415     Count=2
1416
1417 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1418 executed, the next startpoint will be where the cursor was when the
1419 C<(*SKIP)> was executed.
1420
1421 =item C<(*MARK:NAME)> C<(*:NAME)>
1422 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1423
1424 This zero-width pattern can be used to mark the point reached in a string
1425 when a certain part of the pattern has been successfully matched. This
1426 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1427 forward to that point if backtracked into on failure. Any number of
1428 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1429 be duplicated.
1430
1431 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1432 can be used to "label" a pattern branch, so that after matching, the
1433 program can determine which branches of the pattern were involved in the
1434 match.
1435
1436 When a match is successful, the C<$REGMARK> variable will be set to the
1437 name of the most recently executed C<(*MARK:NAME)> that was involved
1438 in the match.
1439
1440 This can be used to determine which branch of a pattern was matched
1441 without using a seperate capture buffer for each branch, which in turn
1442 can result in a performance improvement, as perl cannot optimize
1443 C</(?:(x)|(y)|(z))/> as efficiently as something like
1444 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1445
1446 When a match has failed, and unless another verb has been involved in
1447 failing the match and has provided its own name to use, the C<$REGERROR>
1448 variable will be set to the name of the most recently executed
1449 C<(*MARK:NAME)>.
1450
1451 See C<(*SKIP)> for more details.
1452
1453 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1454
1455 =item C<(*THEN)> C<(*THEN:NAME)>
1456
1457 This is similar to the "cut group" operator C<::> from Perl6. Like
1458 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1459 failure, it causes the regex engine to try the next alternation in the
1460 innermost enclosing group (capturing or otherwise).
1461
1462 Its name comes from the observation that this operation combined with the
1463 alternation operator (C<|>) can be used to create what is essentially a
1464 pattern-based if/then/else block:
1465
1466   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1467
1468 Note that if this operator is used and NOT inside of an alternation then
1469 it acts exactly like the C<(*PRUNE)> operator.
1470
1471   / A (*PRUNE) B /
1472
1473 is the same as
1474
1475   / A (*THEN) B /
1476
1477 but
1478
1479   / ( A (*THEN) B | C (*THEN) D ) /
1480
1481 is not the same as
1482
1483   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1484
1485 as after matching the A but failing on the B the C<(*THEN)> verb will
1486 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1487
1488 =item C<(*COMMIT)>
1489 X<(*COMMIT)>
1490
1491 This is the Perl6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1492 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1493 into on failure it causes the match to fail outright. No further attempts
1494 to find a valid match by advancing the start pointer will occur again.
1495 For example,
1496
1497     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1498     print "Count=$count\n";
1499
1500 outputs
1501
1502     aaab
1503     Count=1
1504
1505 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1506 does not match, the regex engine will not try any further matching on the
1507 rest of the string.
1508
1509 =back
1510
1511 =item Verbs without an argument
1512
1513 =over 4
1514
1515 =item C<(*FAIL)> C<(*F)>
1516 X<(*FAIL)> X<(*F)>
1517
1518 This pattern matches nothing and always fails. It can be used to force the
1519 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1520 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1521
1522 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1523
1524 =item C<(*ACCEPT)>
1525 X<(*ACCEPT)>
1526
1527 B<WARNING:> This feature is highly experimental. It is not recommended
1528 for production code.
1529
1530 This pattern matches nothing and causes the end of successful matching at
1531 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1532 whether there is actually more to match in the string. When inside of a
1533 nested pattern, such as recursion, or in a subpattern dynamically generated
1534 via C<(??{})>, only the innermost pattern is ended immediately.
1535
1536 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1537 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1538 For instance:
1539
1540   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1541
1542 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1543 be set. If another branch in the inner parentheses were matched, such as in the
1544 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1545
1546 =back
1547
1548 =back
1549
1550 =head2 Backtracking
1551 X<backtrack> X<backtracking>
1552
1553 NOTE: This section presents an abstract approximation of regular
1554 expression behavior.  For a more rigorous (and complicated) view of
1555 the rules involved in selecting a match among possible alternatives,
1556 see L<Combining RE Pieces>.
1557
1558 A fundamental feature of regular expression matching involves the
1559 notion called I<backtracking>, which is currently used (when needed)
1560 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1561 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1562 internally, but the general principle outlined here is valid.
1563
1564 For a regular expression to match, the I<entire> regular expression must
1565 match, not just part of it.  So if the beginning of a pattern containing a
1566 quantifier succeeds in a way that causes later parts in the pattern to
1567 fail, the matching engine backs up and recalculates the beginning
1568 part--that's why it's called backtracking.
1569
1570 Here is an example of backtracking:  Let's say you want to find the
1571 word following "foo" in the string "Food is on the foo table.":
1572
1573     $_ = "Food is on the foo table.";
1574     if ( /\b(foo)\s+(\w+)/i ) {
1575         print "$2 follows $1.\n";
1576     }
1577
1578 When the match runs, the first part of the regular expression (C<\b(foo)>)
1579 finds a possible match right at the beginning of the string, and loads up
1580 $1 with "Foo".  However, as soon as the matching engine sees that there's
1581 no whitespace following the "Foo" that it had saved in $1, it realizes its
1582 mistake and starts over again one character after where it had the
1583 tentative match.  This time it goes all the way until the next occurrence
1584 of "foo". The complete regular expression matches this time, and you get
1585 the expected output of "table follows foo."
1586
1587 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1588 everything between "foo" and "bar".  Initially, you write something
1589 like this:
1590
1591     $_ =  "The food is under the bar in the barn.";
1592     if ( /foo(.*)bar/ ) {
1593         print "got <$1>\n";
1594     }
1595
1596 Which perhaps unexpectedly yields:
1597
1598   got <d is under the bar in the >
1599
1600 That's because C<.*> was greedy, so you get everything between the
1601 I<first> "foo" and the I<last> "bar".  Here it's more effective
1602 to use minimal matching to make sure you get the text between a "foo"
1603 and the first "bar" thereafter.
1604
1605     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1606   got <d is under the >
1607
1608 Here's another example. Let's say you'd like to match a number at the end
1609 of a string, and you also want to keep the preceding part of the match.
1610 So you write this:
1611
1612     $_ = "I have 2 numbers: 53147";
1613     if ( /(.*)(\d*)/ ) {                                # Wrong!
1614         print "Beginning is <$1>, number is <$2>.\n";
1615     }
1616
1617 That won't work at all, because C<.*> was greedy and gobbled up the
1618 whole string. As C<\d*> can match on an empty string the complete
1619 regular expression matched successfully.
1620
1621     Beginning is <I have 2 numbers: 53147>, number is <>.
1622
1623 Here are some variants, most of which don't work:
1624
1625     $_ = "I have 2 numbers: 53147";
1626     @pats = qw{
1627         (.*)(\d*)
1628         (.*)(\d+)
1629         (.*?)(\d*)
1630         (.*?)(\d+)
1631         (.*)(\d+)$
1632         (.*?)(\d+)$
1633         (.*)\b(\d+)$
1634         (.*\D)(\d+)$
1635     };
1636
1637     for $pat (@pats) {
1638         printf "%-12s ", $pat;
1639         if ( /$pat/ ) {
1640             print "<$1> <$2>\n";
1641         } else {
1642             print "FAIL\n";
1643         }
1644     }
1645
1646 That will print out:
1647
1648     (.*)(\d*)    <I have 2 numbers: 53147> <>
1649     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1650     (.*?)(\d*)   <> <>
1651     (.*?)(\d+)   <I have > <2>
1652     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1653     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1654     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1655     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1656
1657 As you see, this can be a bit tricky.  It's important to realize that a
1658 regular expression is merely a set of assertions that gives a definition
1659 of success.  There may be 0, 1, or several different ways that the
1660 definition might succeed against a particular string.  And if there are
1661 multiple ways it might succeed, you need to understand backtracking to
1662 know which variety of success you will achieve.
1663
1664 When using look-ahead assertions and negations, this can all get even
1665 trickier.  Imagine you'd like to find a sequence of non-digits not
1666 followed by "123".  You might try to write that as
1667
1668     $_ = "ABC123";
1669     if ( /^\D*(?!123)/ ) {              # Wrong!
1670         print "Yup, no 123 in $_\n";
1671     }
1672
1673 But that isn't going to match; at least, not the way you're hoping.  It
1674 claims that there is no 123 in the string.  Here's a clearer picture of
1675 why that pattern matches, contrary to popular expectations:
1676
1677     $x = 'ABC123';
1678     $y = 'ABC445';
1679
1680     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1681     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1682
1683     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1684     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1685
1686 This prints
1687
1688     2: got ABC
1689     3: got AB
1690     4: got ABC
1691
1692 You might have expected test 3 to fail because it seems to a more
1693 general purpose version of test 1.  The important difference between
1694 them is that test 3 contains a quantifier (C<\D*>) and so can use
1695 backtracking, whereas test 1 will not.  What's happening is
1696 that you've asked "Is it true that at the start of $x, following 0 or more
1697 non-digits, you have something that's not 123?"  If the pattern matcher had
1698 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1699 fail.
1700
1701 The search engine will initially match C<\D*> with "ABC".  Then it will
1702 try to match C<(?!123> with "123", which fails.  But because
1703 a quantifier (C<\D*>) has been used in the regular expression, the
1704 search engine can backtrack and retry the match differently
1705 in the hope of matching the complete regular expression.
1706
1707 The pattern really, I<really> wants to succeed, so it uses the
1708 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1709 time.  Now there's indeed something following "AB" that is not
1710 "123".  It's "C123", which suffices.
1711
1712 We can deal with this by using both an assertion and a negation.
1713 We'll say that the first part in $1 must be followed both by a digit
1714 and by something that's not "123".  Remember that the look-aheads
1715 are zero-width expressions--they only look, but don't consume any
1716 of the string in their match.  So rewriting this way produces what
1717 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1718
1719     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1720     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1721
1722     6: got ABC
1723
1724 In other words, the two zero-width assertions next to each other work as though
1725 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1726 matches only if you're at the beginning of the line AND the end of the
1727 line simultaneously.  The deeper underlying truth is that juxtaposition in
1728 regular expressions always means AND, except when you write an explicit OR
1729 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1730 although the attempted matches are made at different positions because "a"
1731 is not a zero-width assertion, but a one-width assertion.
1732
1733 B<WARNING>: Particularly complicated regular expressions can take
1734 exponential time to solve because of the immense number of possible
1735 ways they can use backtracking to try for a match.  For example, without
1736 internal optimizations done by the regular expression engine, this will
1737 take a painfully long time to run:
1738
1739     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1740
1741 And if you used C<*>'s in the internal groups instead of limiting them
1742 to 0 through 5 matches, then it would take forever--or until you ran
1743 out of stack space.  Moreover, these internal optimizations are not
1744 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1745 on the external group, no current optimization is applicable, and the
1746 match takes a long time to finish.
1747
1748 A powerful tool for optimizing such beasts is what is known as an
1749 "independent group",
1750 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1751 zero-length look-ahead/look-behind assertions will not backtrack to make
1752 the tail match, since they are in "logical" context: only
1753 whether they match is considered relevant.  For an example
1754 where side-effects of look-ahead I<might> have influenced the
1755 following match, see L<C<< (?>pattern) >>>.
1756
1757 =head2 Version 8 Regular Expressions
1758 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1759
1760 In case you're not familiar with the "regular" Version 8 regex
1761 routines, here are the pattern-matching rules not described above.
1762
1763 Any single character matches itself, unless it is a I<metacharacter>
1764 with a special meaning described here or above.  You can cause
1765 characters that normally function as metacharacters to be interpreted
1766 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1767 character; "\\" matches a "\"). This escape mechanism is also required
1768 for the character used as the pattern delimiter.
1769
1770 A series of characters matches that series of characters in the target
1771 string, so the pattern  C<blurfl> would match "blurfl" in the target
1772 string.
1773
1774 You can specify a character class, by enclosing a list of characters
1775 in C<[]>, which will match any character from the list.  If the
1776 first character after the "[" is "^", the class matches any character not
1777 in the list.  Within a list, the "-" character specifies a
1778 range, so that C<a-z> represents all characters between "a" and "z",
1779 inclusive.  If you want either "-" or "]" itself to be a member of a
1780 class, put it at the start of the list (possibly after a "^"), or
1781 escape it with a backslash.  "-" is also taken literally when it is
1782 at the end of the list, just before the closing "]".  (The
1783 following all specify the same class of three characters: C<[-az]>,
1784 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1785 specifies a class containing twenty-six characters, even on EBCDIC-based
1786 character sets.)  Also, if you try to use the character
1787 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1788 a range, the "-" is understood literally.
1789
1790 Note also that the whole range idea is rather unportable between
1791 character sets--and even within character sets they may cause results
1792 you probably didn't expect.  A sound principle is to use only ranges
1793 that begin from and end at either alphabetics of equal case ([a-e],
1794 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1795 spell out the character sets in full.
1796
1797 Characters may be specified using a metacharacter syntax much like that
1798 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1799 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1800 of octal digits, matches the character whose coded character set value
1801 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1802 matches the character whose numeric value is I<nn>. The expression \cI<x>
1803 matches the character control-I<x>.  Finally, the "." metacharacter
1804 matches any character except "\n" (unless you use C</s>).
1805
1806 You can specify a series of alternatives for a pattern using "|" to
1807 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1808 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1809 first alternative includes everything from the last pattern delimiter
1810 ("(", "[", or the beginning of the pattern) up to the first "|", and
1811 the last alternative contains everything from the last "|" to the next
1812 pattern delimiter.  That's why it's common practice to include
1813 alternatives in parentheses: to minimize confusion about where they
1814 start and end.
1815
1816 Alternatives are tried from left to right, so the first
1817 alternative found for which the entire expression matches, is the one that
1818 is chosen. This means that alternatives are not necessarily greedy. For
1819 example: when matching C<foo|foot> against "barefoot", only the "foo"
1820 part will match, as that is the first alternative tried, and it successfully
1821 matches the target string. (This might not seem important, but it is
1822 important when you are capturing matched text using parentheses.)
1823
1824 Also remember that "|" is interpreted as a literal within square brackets,
1825 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1826
1827 Within a pattern, you may designate subpatterns for later reference
1828 by enclosing them in parentheses, and you may refer back to the
1829 I<n>th subpattern later in the pattern using the metacharacter
1830 \I<n>.  Subpatterns are numbered based on the left to right order
1831 of their opening parenthesis.  A backreference matches whatever
1832 actually matched the subpattern in the string being examined, not
1833 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1834 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1835 1 matched "0x", even though the rule C<0|0x> could potentially match
1836 the leading 0 in the second number.
1837
1838 =head2 Warning on \1 Instead of $1
1839
1840 Some people get too used to writing things like:
1841
1842     $pattern =~ s/(\W)/\\\1/g;
1843
1844 This is grandfathered for the RHS of a substitute to avoid shocking the
1845 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1846 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1847 the usual double-quoted string means a control-A.  The customary Unix
1848 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1849 of doing that, you get yourself into trouble if you then add an C</e>
1850 modifier.
1851
1852     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1853
1854 Or if you try to do
1855
1856     s/(\d+)/\1000/;
1857
1858 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1859 C<${1}000>.  The operation of interpolation should not be confused
1860 with the operation of matching a backreference.  Certainly they mean two
1861 different things on the I<left> side of the C<s///>.
1862
1863 =head2 Repeated Patterns Matching a Zero-length Substring
1864
1865 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1866
1867 Regular expressions provide a terse and powerful programming language.  As
1868 with most other power tools, power comes together with the ability
1869 to wreak havoc.
1870
1871 A common abuse of this power stems from the ability to make infinite
1872 loops using regular expressions, with something as innocuous as:
1873
1874     'foo' =~ m{ ( o? )* }x;
1875
1876 The C<o?> matches at the beginning of C<'foo'>, and since the position
1877 in the string is not moved by the match, C<o?> would match again and again
1878 because of the C<*> modifier.  Another common way to create a similar cycle
1879 is with the looping modifier C<//g>:
1880
1881     @matches = ( 'foo' =~ m{ o? }xg );
1882
1883 or
1884
1885     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1886
1887 or the loop implied by split().
1888
1889 However, long experience has shown that many programming tasks may
1890 be significantly simplified by using repeated subexpressions that
1891 may match zero-length substrings.  Here's a simple example being:
1892
1893     @chars = split //, $string;           # // is not magic in split
1894     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1895
1896 Thus Perl allows such constructs, by I<forcefully breaking
1897 the infinite loop>.  The rules for this are different for lower-level
1898 loops given by the greedy modifiers C<*+{}>, and for higher-level
1899 ones like the C</g> modifier or split() operator.
1900
1901 The lower-level loops are I<interrupted> (that is, the loop is
1902 broken) when Perl detects that a repeated expression matched a
1903 zero-length substring.   Thus
1904
1905    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1906
1907 is made equivalent to
1908
1909    m{   (?: NON_ZERO_LENGTH )*
1910       |
1911         (?: ZERO_LENGTH )?
1912     }x;
1913
1914 The higher level-loops preserve an additional state between iterations:
1915 whether the last match was zero-length.  To break the loop, the following
1916 match after a zero-length match is prohibited to have a length of zero.
1917 This prohibition interacts with backtracking (see L<"Backtracking">),
1918 and so the I<second best> match is chosen if the I<best> match is of
1919 zero length.
1920
1921 For example:
1922
1923     $_ = 'bar';
1924     s/\w??/<$&>/g;
1925
1926 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1927 match given by non-greedy C<??> is the zero-length match, and the I<second
1928 best> match is what is matched by C<\w>.  Thus zero-length matches
1929 alternate with one-character-long matches.
1930
1931 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1932 position one notch further in the string.
1933
1934 The additional state of being I<matched with zero-length> is associated with
1935 the matched string, and is reset by each assignment to pos().
1936 Zero-length matches at the end of the previous match are ignored
1937 during C<split>.
1938
1939 =head2 Combining RE Pieces
1940
1941 Each of the elementary pieces of regular expressions which were described
1942 before (such as C<ab> or C<\Z>) could match at most one substring
1943 at the given position of the input string.  However, in a typical regular
1944 expression these elementary pieces are combined into more complicated
1945 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1946 (in these examples C<S> and C<T> are regular subexpressions).
1947
1948 Such combinations can include alternatives, leading to a problem of choice:
1949 if we match a regular expression C<a|ab> against C<"abc">, will it match
1950 substring C<"a"> or C<"ab">?  One way to describe which substring is
1951 actually matched is the concept of backtracking (see L<"Backtracking">).
1952 However, this description is too low-level and makes you think
1953 in terms of a particular implementation.
1954
1955 Another description starts with notions of "better"/"worse".  All the
1956 substrings which may be matched by the given regular expression can be
1957 sorted from the "best" match to the "worst" match, and it is the "best"
1958 match which is chosen.  This substitutes the question of "what is chosen?"
1959 by the question of "which matches are better, and which are worse?".
1960
1961 Again, for elementary pieces there is no such question, since at most
1962 one match at a given position is possible.  This section describes the
1963 notion of better/worse for combining operators.  In the description
1964 below C<S> and C<T> are regular subexpressions.
1965
1966 =over 4
1967
1968 =item C<ST>
1969
1970 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1971 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1972 which can be matched by C<T>.
1973
1974 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1975 match than C<A'B'>.
1976
1977 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1978 C<B> is better match for C<T> than C<B'>.
1979
1980 =item C<S|T>
1981
1982 When C<S> can match, it is a better match than when only C<T> can match.
1983
1984 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1985 two matches for C<T>.
1986
1987 =item C<S{REPEAT_COUNT}>
1988
1989 Matches as C<SSS...S> (repeated as many times as necessary).
1990
1991 =item C<S{min,max}>
1992
1993 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1994
1995 =item C<S{min,max}?>
1996
1997 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1998
1999 =item C<S?>, C<S*>, C<S+>
2000
2001 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2002
2003 =item C<S??>, C<S*?>, C<S+?>
2004
2005 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2006
2007 =item C<< (?>S) >>
2008
2009 Matches the best match for C<S> and only that.
2010
2011 =item C<(?=S)>, C<(?<=S)>
2012
2013 Only the best match for C<S> is considered.  (This is important only if
2014 C<S> has capturing parentheses, and backreferences are used somewhere
2015 else in the whole regular expression.)
2016
2017 =item C<(?!S)>, C<(?<!S)>
2018
2019 For this grouping operator there is no need to describe the ordering, since
2020 only whether or not C<S> can match is important.
2021
2022 =item C<(??{ EXPR })>, C<(?PARNO)>
2023
2024 The ordering is the same as for the regular expression which is
2025 the result of EXPR, or the pattern contained by capture buffer PARNO.
2026
2027 =item C<(?(condition)yes-pattern|no-pattern)>
2028
2029 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2030 already determined.  The ordering of the matches is the same as for the
2031 chosen subexpression.
2032
2033 =back
2034
2035 The above recipes describe the ordering of matches I<at a given position>.
2036 One more rule is needed to understand how a match is determined for the
2037 whole regular expression: a match at an earlier position is always better
2038 than a match at a later position.
2039
2040 =head2 Creating Custom RE Engines
2041
2042 Overloaded constants (see L<overload>) provide a simple way to extend
2043 the functionality of the RE engine.
2044
2045 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2046 matches at a boundary between whitespace characters and non-whitespace
2047 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2048 at these positions, so we want to have each C<\Y|> in the place of the
2049 more complicated version.  We can create a module C<customre> to do
2050 this:
2051
2052     package customre;
2053     use overload;
2054
2055     sub import {
2056       shift;
2057       die "No argument to customre::import allowed" if @_;
2058       overload::constant 'qr' => \&convert;
2059     }
2060
2061     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2062
2063     # We must also take care of not escaping the legitimate \\Y|
2064     # sequence, hence the presence of '\\' in the conversion rules.
2065     my %rules = ( '\\' => '\\\\',
2066                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2067     sub convert {
2068       my $re = shift;
2069       $re =~ s{
2070                 \\ ( \\ | Y . )
2071               }
2072               { $rules{$1} or invalid($re,$1) }sgex;
2073       return $re;
2074     }
2075
2076 Now C<use customre> enables the new escape in constant regular
2077 expressions, i.e., those without any runtime variable interpolations.
2078 As documented in L<overload>, this conversion will work only over
2079 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2080 part of this regular expression needs to be converted explicitly
2081 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2082
2083     use customre;
2084     $re = <>;
2085     chomp $re;
2086     $re = customre::convert $re;
2087     /\Y|$re\Y|/;
2088
2089 =head1 PCRE/Python Support
2090
2091 As of Perl 5.10 Perl supports several Python/PCRE specific extensions
2092 to the regex syntax. While Perl programmers are encouraged to use the
2093 Perl specific syntax, the following are legal in Perl 5.10:
2094
2095 =over 4
2096
2097 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2098
2099 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2100
2101 =item C<< (?P=NAME) >>
2102
2103 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2104
2105 =item C<< (?P>NAME) >>
2106
2107 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2108
2109 =back
2110
2111 =head1 BUGS
2112
2113 This document varies from difficult to understand to completely
2114 and utterly opaque.  The wandering prose riddled with jargon is
2115 hard to fathom in several places.
2116
2117 This document needs a rewrite that separates the tutorial content
2118 from the reference content.
2119
2120 =head1 SEE ALSO
2121
2122 L<perlrequick>.
2123
2124 L<perlretut>.
2125
2126 L<perlop/"Regexp Quote-Like Operators">.
2127
2128 L<perlop/"Gory details of parsing quoted constructs">.
2129
2130 L<perlfaq6>.
2131
2132 L<perlfunc/pos>.
2133
2134 L<perllocale>.
2135
2136 L<perlebcdic>.
2137
2138 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2139 by O'Reilly and Associates.