dist/Devel-PPPort/Makefile.PL

   1 ################################################################################
   2 #
   3 #  Makefile.PL -- generate Makefile
   4 #
   5 ################################################################################
   6 #
   7 #  Version 3.x, Copyright (C) 2004-2013, Marcus Holland-Moritz.
   8 #  Version 2.x, Copyright (C) 2001, Paul Marquess.
   9 #  Version 1.x, Copyright (C) 1999, Kenneth Albanowski.
  10 #
  11 #  This program is free software; you can redistribute it and/or
  12 #  modify it under the same terms as Perl itself.
  13 #
  14 ################################################################################
  15
  16 require 5.003;
  17
  18 use strict;
  19 BEGIN { $^W = 1; }
  20
  21 use ExtUtils::MakeMaker;
  22 use Config;
  23
  24 use vars '%opt';  # needs to be global, and we can't use 'our'
  25
  26 unless ($ENV{'PERL_CORE'}) {
  27   $ENV{'PERL_CORE'} = 1 if grep { $_ eq 'PERL_CORE=1' } @ARGV;
  28 }
  29
  30 @ARGV = map { /^--with-(apicheck)$/ && ++$opt{$1} ? () : $_ } @ARGV;
  31
  32 my %mf = (
  33   NAME          => 'Devel::PPPort',
  34   VERSION_FROM  => 'PPPort_pm.PL',
  35   PM            => { 'PPPort.pm' => '$(INST_LIBDIR)/PPPort.pm' },
  36   H             => [ qw(ppport.h) ],
  37   OBJECT        => 'RealPPPort$(OBJ_EXT) $(O_FILES)',
  38   XSPROTOARG    => '-noprototypes',
  39   CONFIGURE     => \&configure,
  40 );
  41 WriteMakefile(%mf);
  42
  43 sub configure
  44 {
  45   my @clean    = qw{ $(H_FILES) RealPPPort.xs RealPPPort.c PPPort.pm };
  46   my %depend   = ('$(OBJECT)' => '$(H_FILES)');
  47   my @C_FILES  = qw{ module2.c module3.c },
  48   my %PL_FILES = (
  49     'ppport_h.PL'  => 'ppport.h',
  50     'PPPort_pm.PL' => 'PPPort.pm',
  51     'RealPPPort_xs.PL' => 'RealPPPort.xs',
  52     'mktests.PL' => 't/01_test.t',
  53   );
  54   my @moreopts;
  55
  56   if (eval $ExtUtils::MakeMaker::VERSION >= 6) {
  57     push @moreopts, AUTHOR => 'Marcus Holland-Moritz <mhx@cpan.org>';
  58     push @moreopts, ABSTRACT_FROM => 'PPPort_pm.PL';
  59   }
  60
  61   if (eval $ExtUtils::MakeMaker::VERSION >= 6.30_01) {
  62     print "Setting license tag...\n";
  63     push @moreopts, LICENSE => 'perl';
  64   }
  65
  66   if (eval { ExtUtils::MakeMaker->VERSION (6.46) }) {
  67     open FH, '<PPPort_pm.PL' or die "cannot open PPPort_pm.PL for reading: $!";
  68     my $version;
  69     while (my $line = <FH>) {
  70       ($version) = $line =~ /^\$VERSION = '([\d.]+)';$/ and last;
  71     };
  72     die 'failed to extract $VERSION from PPPort_pm.PL' if not $version;
  73     close FH;
  74     print "Adding META_MERGE...\n";
  75     push @moreopts, META_MERGE => {
  76       'meta-spec' => { version => 2 },
  77       provides => {
  78         'Devel::PPPort' => {
  79           file    => 'PPPort_pm.PL',
  80           version => $version,
  81         },
  82       },
  83       resources => {
  84         bugtracker => {
  85           web => 'https://rt.perl.org/rt3/',
  86         },
  87         repository => {
  88           type => 'git',
  89           url  => 'git://perl5.git.perl.org/perl.git',
  90           web  => 'https://perl5.git.perl.org/perl.git',
  91         },
  92       },
  93     };
  94   }
  95
  96   if (not $ENV{'PERL_CORE'}) {
  97     # Devel::PPPort is in the core since 5.7.3
  98     # 5.11.0+ has site before perl
  99     push @moreopts, INSTALLDIRS => (
 100       ("$]" >= 5.007003 and "$]" < 5.011)
 101         ? 'perl'
 102         : 'site'
 103     );
 104   }
 105
 106   if ($opt{'apicheck'}) {
 107     $PL_FILES{'apicheck_c.PL'} = 'apicheck.c';
 108     push @C_FILES, qw{ apicheck.c };
 109     push @clean,   qw{ apicheck.c apicheck.i };
 110     $depend{'apicheck.i'} = 'ppport.h';
 111   }
 112
 113   if ($Config{gccversion}) {
 114     my $define = '-W -Wall';
 115     $define .= ' -Wdeclaration-after-statement' if $Config{gccversion} =~ /^(\d+\.\d+)\./ && $1 >= 3.4;
 116     push @moreopts, DEFINE => $define;
 117   }
 118
 119   return {
 120     C        => \@C_FILES,
 121     XS       => { 'RealPPPort.xs' => 'RealPPPort.c' },
 122     PL_FILES => \%PL_FILES,
 123     depend   => \%depend,
 124     clean    => { FILES => "@clean" },
 125     @moreopts,
 126   };
 127 }
 128
 129 sub MY::postamble
 130 {
 131   package MY;
 132   my $post = shift->SUPER::postamble(@_);
 133   $post .= <<'POSTAMBLE';
 134
 135 purge_all: realclean
 136         @$(RM_F) PPPort.pm t/*.t
 137
 138 regen_pm:
 139         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) PPPort_pm.PL
 140
 141 regen_xs:
 142         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) RealPPPort_xs.PL
 143
 144 regen_tests:
 145         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) mktests.PL
 146
 147 regen_h:
 148         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) ppport_h.PL
 149
 150 regen: regen_pm regen_xs regen_tests regen_h
 151
 152 POSTAMBLE
 153   return $post;
 154 }
 155
 156 sub MY::processPL
 157 {
 158   package MY;
 159   my $original = shift->SUPER::processPL(@_);
 160
 161   require "./parts/ppptools.pl";
 162   my $includes = join ' ', all_files_in_dir('parts/inc');
 163
 164   my $updated = '';
 165   my @rules = split( m{^\s*$}m, $original );
 166   foreach my $rule ( @rules ) {
 167     if ( $rule =~ m{^\s*^PPPort\.pm\s+:}m ) {
 168       $rule =~ s{^(\s*^PPPort\.pm\s+:.*)}{$1 $includes}m; # PPPort.pm depends on all files from parts/inc
 169       $rule =~ s{pm_to_blib}{}m; # PPPort.pm must not depend on built PPPort.pm in blib/
 170     } elsif ( $rule =~ m{^\s*^ppport\.h\s+:}m ) {
 171       $rule =~ s{^(\s*^ppport\.h\s+:.*)}{$1 PPPort.pm}m; # ppport.h depends on PPPort.pm
 172       $rule =~ s{pm_to_blib}{}m; # ppport.h is used to build RealPPPort.xs so cannot depend on built PPPort in blib/
 173     } elsif ( $rule =~ m{^\s*^RealPPPort\.xs\s+:}m ) {
 174       $rule =~ s{^(\s*^RealPPPort\.xs\s+:.*)}{$1 ppport.h}m; # RealPPPort.xs depends on ppport.h
 175       $rule =~ s{pm_to_blib}{}m; # RealPPPort.xs is used to build PPPort binary, so it cannot depend on it
 176     } elsif ( $rule =~ m{^\s*\S+\b01_test\.t\s+:}m ) {
 177       $rule =~ s{^(\s*^\S+\b01_test\.t\s+:.*)}{$1 $includes}m; # all tests in t/ depends on all files from parts/inc
 178       $rule =~ s{pm_to_blib}{}m; # Generating test files does not depend on built PPPort in blib/
 179     }
 180     $updated .= $rule;
 181   }
 182
 183   return $updated;
 184 }
 185
 186 sub MY::dist_core
 187 {
 188   package MY;
 189   my $dist = shift->SUPER::dist_core(@_);
 190
 191   my $updated = '';
 192   my @rules = split( m{^\s*$}m, $dist );
 193   foreach my $rule ( @rules ) {
 194     if ( $rule =~ m{^\s*^dist\s+:}m ) {
 195         $rule =~ s{:}{: manifest}; # make sure we regenerate the manifest
 196         $rule .= qq[\t].q[$(NOECHO) $(ECHO) "Warning: Please check '__MAX_PERL__' value in PPPort_pm.PL"].qq[\n];
 197     }
 198     $updated .= $rule;
 199   }
 200
 201   return $updated;
 202 }
 203
 204
 205 sub MY::c_o
 206 {
 207   package MY;
 208   my $co = shift->SUPER::c_o(@_);
 209
 210   if ($::opt{'apicheck'} && $co !~ /^\.c\.i:/m) {
 211     print "Adding custom rule for preprocessed apicheck file...\n";
 212
 213     $co .= <<'CO'
 214
 215 .SUFFIXES: .i
 216
 217 .c.i:
 218         $(CCCMD) -E -I$(PERL_INC) $(DEFINE) $*.c > $*.i
 219 CO
 220   }
 221
 222   return $co;
 223 }