This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perldata: Fix too long verbatim lines
[perl5.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8 X<variable, name> X<variable name> X<data type> X<type>
9
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes".  A scalar is a 
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>).  Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0.  Hashes are unordered collections of scalar 
16 values indexed by their associated string key.
17
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers.  The rest of the name tells you the particular
21 value to which it refers.  Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits.  In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details).  For a more in-depth discussion
28 on identifiers, see L<Identifier parsing>.  It's possible to
29 substitute for a simple identifier, an expression that produces a reference
30 to the value at runtime.   This is described in more detail below
31 and in L<perlref>.
32 X<identifier>
33
34 Perl also has its own built-in variables whose names don't follow
35 these rules.  They have strange names so they don't accidentally
36 collide with one of your normal variables.  Strings that match
37 parenthesized parts of a regular expression are saved under names
38 containing only digits after the C<$> (see L<perlop> and L<perlre>).
39 In addition, several special variables that provide windows into
40 the inner working of Perl have names containing punctuation characters
41 and control characters.  These are documented in L<perlvar>.
42 X<variable, built-in>
43
44 Scalar values are always named with '$', even when referring to a
45 scalar that is part of an array or a hash.  The '$' symbol works
46 semantically like the English word "the" in that it indicates a
47 single value is expected.
48 X<scalar>
49
50     $days               # the simple scalar value "days"
51     $days[28]           # the 29th element of array @days
52     $days{'Feb'}        # the 'Feb' value from hash %days
53     $#days              # the last index of array @days
54
55 Entire arrays (and slices of arrays and hashes) are denoted by '@',
56 which works much as the word "these" or "those" does in English,
57 in that it indicates multiple values are expected.
58 X<array>
59
60     @days               # ($days[0], $days[1],... $days[n])
61     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
62     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
63
64 Entire hashes are denoted by '%':
65 X<hash>
66
67     %days               # (key1, val1, key2, val2 ...)
68
69 In addition, subroutines are named with an initial '&', though this
70 is optional when unambiguous, just as the word "do" is often redundant
71 in English.  Symbol table entries can be named with an initial '*',
72 but you don't really care about that yet (if ever :-).
73
74 Every variable type has its own namespace, as do several
75 non-variable identifiers.  This means that you can, without fear
76 of conflict, use the same name for a scalar variable, an array, or
77 a hash--or, for that matter, for a filehandle, a directory handle, a
78 subroutine name, a format name, or a label.  This means that $foo
79 and @foo are two different variables.  It also means that C<$foo[1]>
80 is a part of @foo, not a part of $foo.  This may seem a bit weird,
81 but that's okay, because it is weird.
82 X<namespace>
83
84 Because variable references always start with '$', '@', or '%', the
85 "reserved" words aren't in fact reserved with respect to variable
86 names.  They I<are> reserved with respect to labels and filehandles,
87 however, which don't have an initial special character.  You can't
88 have a filehandle named "log", for instance.  Hint: you could say
89 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
90 uppercase filehandles also improves readability and protects you
91 from conflict with future reserved words.  Case I<is> significant--"FOO",
92 "Foo", and "foo" are all different names.  Names that start with a
93 letter or underscore may also contain digits and underscores.
94 X<identifier, case sensitivity>
95 X<case>
96
97 It is possible to replace such an alphanumeric name with an expression
98 that returns a reference to the appropriate type.  For a description
99 of this, see L<perlref>.
100
101 Names that start with a digit may contain only more digits.  Names
102 that do not start with a letter, underscore, digit or a caret (i.e.
103 a control character) are limited to one character, e.g.,  C<$%> or
104 C<$$>.  (Most of these one character names have a predefined
105 significance to Perl.  For instance, C<$$> is the current process
106 id.)
107
108 =head2 Identifier parsing
109 X<identifiers>
110
111 Up until Perl 5.18, the actual rules of what a valid identifier
112 was were a bit fuzzy.  However, in general, anything defined here should
113 work on previous versions of Perl, while the opposite -- edge cases
114 that work in previous versions, but aren't defined here -- probably
115 won't work on newer versions.
116 As an important side note, please note that the following only applies
117 to bareword identifiers as found in Perl source code, not identifiers
118 introduced through symbolic references, which have much fewer
119 restrictions.
120 If working under the effect of the C<use utf8;> pragma, the following
121 rules apply:
122
123     / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ])
124       (?[ ( \p{Word} & \p{XID_Continue} ) ]) *    /x
125
126 That is, a "start" character followed by any number of "continue"
127 characters.  Perl requires every character in an identifier to also
128 match C<\w> (this prevents some problematic cases); and Perl
129 additionally accepts identfier names beginning with an underscore.
130
131 If not under C<use utf8>, the source is treated as ASCII + 128 extra
132 controls, and identifiers should match
133
134     / (?aa) (?!\d) \w+ /x
135
136 That is, any word character in the ASCII range, as long as the first
137 character is not a digit.
138
139 There are two package separators in Perl: A double colon (C<::>) and a single
140 quote (C<'>).  Normal identifiers can start or end with a double colon, and
141 can contain several parts delimited by double colons.
142 Single quotes have similar rules, but with the exception that they are not
143 legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
144 legal, but C<$foo'bar'> is not.
145
146 Additionally, if the identifier is preceded by a sigil --
147 that is, if the identifier is part of a variable name -- it
148 may optionally be enclosed in braces.
149
150 While you can mix double colons with singles quotes, the quotes must come
151 after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
152 and C<$foo'::bar> are not.
153
154 Put together, a grammar to match a basic identifier becomes
155
156  /
157   (?(DEFINE)
158       (?<variable>
159           (?&sigil)
160           (?:
161                   (?&normal_identifier)
162               |   \{ \s* (?&normal_identifier) \s* \}
163           )
164       )
165       (?<normal_identifier>
166           (?: :: )* '?
167            (?&basic_identifier)
168            (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
169           (?: :: )*
170       )
171       (?<basic_identifier>
172         # is use utf8 on?
173           (?(?{ (caller(0))[8] & $utf8::hint_bits })
174               (?&Perl_XIDS) (?&Perl_XIDC)*
175             | (?aa) (?!\d) \w+
176           )
177       )
178       (?<sigil> [&*\$\@\%])
179       (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
180       (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) )
181   )
182  /x
183
184 Meanwhile, special identifiers don't follow the above rules; For the most
185 part, all of the identifiers in this category have a special meaning given
186 by Perl.  Because they have special parsing rules, these generally can't be
187 fully-qualified.  They come in four forms:
188
189 =over
190
191 =item A sigil, followed solely by digits matching \p{POSIX_Digit}, like C<$0>,
192 C<$1>, or C<$10000>.
193
194 =item A sigil, followed by either a caret and a single POSIX uppercase letter,
195 like C<$^V> or C<$^W>, or a sigil followed by a literal control character
196 matching the C<\p{POSIX_Cntrl}> property.
197 Due to a historical oddity, if not
198 running under C<use utf8>, the 128 extra controls in the C<[0x80-0xff]> range
199 may also be used in length one variables.  The use of a literal control
200 character is deprecated.  Support for this form will be removed in a future
201 version of perl.
202
203 =item Similar to the above, a sigil, followed by bareword text in brackets,
204 where the first character is either a caret followed by an uppercase letter,
205 or a literal control, like C<${^GLOBAL_PHASE}> or C<${\7LOBAL_PHASE}>.  The use
206 of a literal control character is deprecated.  Support for this form will be
207 removed in a future version of perl.
208
209 =item A sigil followed by a single character matching the C<\p{POSIX_Punct}>
210 property, like C<$!> or C<%+>.
211
212 =back
213
214 Note that as of Perl 5.20, literal control characters in variable names
215 are deprecated.
216
217 =head2 Context
218 X<context> X<scalar context> X<list context>
219
220 The interpretation of operations and values in Perl sometimes depends
221 on the requirements of the context around the operation or value.
222 There are two major contexts: list and scalar.  Certain operations
223 return list values in contexts wanting a list, and scalar values
224 otherwise.  If this is true of an operation it will be mentioned in
225 the documentation for that operation.  In other words, Perl overloads
226 certain operations based on whether the expected return value is
227 singular or plural.  Some words in English work this way, like "fish"
228 and "sheep".
229
230 In a reciprocal fashion, an operation provides either a scalar or a
231 list context to each of its arguments.  For example, if you say
232
233     int( <STDIN> )
234
235 the integer operation provides scalar context for the <>
236 operator, which responds by reading one line from STDIN and passing it
237 back to the integer operation, which will then find the integer value
238 of that line and return that.  If, on the other hand, you say
239
240     sort( <STDIN> )
241
242 then the sort operation provides list context for <>, which
243 will proceed to read every line available up to the end of file, and
244 pass that list of lines back to the sort routine, which will then
245 sort those lines and return them as a list to whatever the context
246 of the sort was.
247
248 Assignment is a little bit special in that it uses its left argument
249 to determine the context for the right argument.  Assignment to a
250 scalar evaluates the right-hand side in scalar context, while
251 assignment to an array or hash evaluates the righthand side in list
252 context.  Assignment to a list (or slice, which is just a list
253 anyway) also evaluates the right-hand side in list context.
254
255 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
256 option, you may see warnings
257 about useless uses of constants or functions in "void context".
258 Void context just means the value has been discarded, such as a
259 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
260 counts as scalar context for functions that care whether or not
261 they're being called in list context.
262
263 User-defined subroutines may choose to care whether they are being
264 called in a void, scalar, or list context.  Most subroutines do not
265 need to bother, though.  That's because both scalars and lists are
266 automatically interpolated into lists.  See L<perlfunc/wantarray>
267 for how you would dynamically discern your function's calling
268 context.
269
270 =head2 Scalar values
271 X<scalar> X<number> X<string> X<reference>
272
273 All data in Perl is a scalar, an array of scalars, or a hash of
274 scalars.  A scalar may contain one single value in any of three
275 different flavors: a number, a string, or a reference.  In general,
276 conversion from one form to another is transparent.  Although a
277 scalar may not directly hold multiple values, it may contain a
278 reference to an array or hash which in turn contains multiple values.
279
280 Scalars aren't necessarily one thing or another.  There's no place
281 to declare a scalar variable to be of type "string", type "number",
282 type "reference", or anything else.  Because of the automatic
283 conversion of scalars, operations that return scalars don't need
284 to care (and in fact, cannot care) whether their caller is looking
285 for a string, a number, or a reference.  Perl is a contextually
286 polymorphic language whose scalars can be strings, numbers, or
287 references (which includes objects).  Although strings and numbers
288 are considered pretty much the same thing for nearly all purposes,
289 references are strongly-typed, uncastable pointers with builtin
290 reference-counting and destructor invocation.
291
292 A scalar value is interpreted as FALSE in the Boolean sense
293 if it is undefined, the null string or the number 0 (or its
294 string equivalent, "0"), and TRUE if it is anything else.  The
295 Boolean context is just a special kind of scalar context where no 
296 conversion to a string or a number is ever performed.
297 X<boolean> X<bool> X<true> X<false> X<truth>
298
299 There are actually two varieties of null strings (sometimes referred
300 to as "empty" strings), a defined one and an undefined one.  The
301 defined version is just a string of length zero, such as C<"">.
302 The undefined version is the value that indicates that there is
303 no real value for something, such as when there was an error, or
304 at end of file, or when you refer to an uninitialized variable or
305 element of an array or hash.  Although in early versions of Perl,
306 an undefined scalar could become defined when first used in a
307 place expecting a defined value, this no longer happens except for
308 rare cases of autovivification as explained in L<perlref>.  You can
309 use the defined() operator to determine whether a scalar value is
310 defined (this has no meaning on arrays or hashes), and the undef()
311 operator to produce an undefined value.
312 X<defined> X<undefined> X<undef> X<null> X<string, null>
313
314 To find out whether a given string is a valid non-zero number, it's
315 sometimes enough to test it against both numeric 0 and also lexical
316 "0" (although this will cause noises if warnings are on).  That's 
317 because strings that aren't numbers count as 0, just as they do in B<awk>:
318
319     if ($str == 0 && $str ne "0")  {
320         warn "That doesn't look like a number";
321     }
322
323 That method may be best because otherwise you won't treat IEEE
324 notations like C<NaN> or C<Infinity> properly.  At other times, you
325 might prefer to determine whether string data can be used numerically
326 by calling the POSIX::strtod() function or by inspecting your string
327 with a regular expression (as documented in L<perlre>).
328
329     warn "has nondigits"        if     /\D/;
330     warn "not a natural number" unless /^\d+$/;             # rejects -3
331     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
332     warn "not an integer"       unless /^[+-]?\d+$/;
333     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
334     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
335     warn "not a C float"
336         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
337
338 The length of an array is a scalar value.  You may find the length
339 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
340 isn't the length of the array; it's the subscript of the last element,
341 which is a different value since there is ordinarily a 0th element.
342 Assigning to C<$#days> actually changes the length of the array.
343 Shortening an array this way destroys intervening values.  Lengthening
344 an array that was previously shortened does not recover values
345 that were in those elements.
346 X<$#> X<array, length>
347
348 You can also gain some minuscule measure of efficiency by pre-extending
349 an array that is going to get big.  You can also extend an array
350 by assigning to an element that is off the end of the array.  You
351 can truncate an array down to nothing by assigning the null list
352 () to it.  The following are equivalent:
353
354     @whatever = ();
355     $#whatever = -1;
356
357 If you evaluate an array in scalar context, it returns the length
358 of the array.  (Note that this is not true of lists, which return
359 the last value, like the C comma operator, nor of built-in functions,
360 which return whatever they feel like returning.)  The following is
361 always true:
362 X<array, length>
363
364     scalar(@whatever) == $#whatever + 1;
365
366 Some programmers choose to use an explicit conversion so as to 
367 leave nothing to doubt:
368
369     $element_count = scalar(@whatever);
370
371 If you evaluate a hash in scalar context, it returns false if the
372 hash is empty.  If there are any key/value pairs, it returns true;
373 more precisely, the value returned is a string consisting of the
374 number of used buckets and the number of allocated buckets, separated
375 by a slash.  This is pretty much useful only to find out whether
376 Perl's internal hashing algorithm is performing poorly on your data
377 set.  For example, you stick 10,000 things in a hash, but evaluating
378 %HASH in scalar context reveals C<"1/16">, which means only one out
379 of sixteen buckets has been touched, and presumably contains all
380 10,000 of your items.  This isn't supposed to happen.  If a tied hash
381 is evaluated in scalar context, the C<SCALAR> method is called (with a
382 fallback to C<FIRSTKEY>).
383 X<hash, scalar context> X<hash, bucket> X<bucket>
384
385 You can preallocate space for a hash by assigning to the keys() function.
386 This rounds up the allocated buckets to the next power of two:
387
388     keys(%users) = 1000;                # allocate 1024 buckets
389
390 =head2 Scalar value constructors
391 X<scalar, literal> X<scalar, constant>
392
393 Numeric literals are specified in any of the following floating point or
394 integer formats:
395
396  12345
397  12345.67
398  .23E-10             # a very small number
399  3.14_15_92          # a very important number
400  4_294_967_296       # underscore for legibility
401  0xff                # hex
402  0xdead_beef         # more hex
403  0377                # octal (only numbers, begins with 0)
404  0b011011            # binary
405  0x1.999ap-4         # hexadecimal floating point (the 'p' is required)
406
407 You are allowed to use underscores (underbars) in numeric literals
408 between digits for legibility (but not multiple underscores in a row:
409 C<23__500> is not legal; C<23_500> is).
410 You could, for example, group binary
411 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
412 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
413 X<number, literal>
414
415 String literals are usually delimited by either single or double
416 quotes.  They work much like quotes in the standard Unix shells:
417 double-quoted string literals are subject to backslash and variable
418 substitution; single-quoted strings are not (except for C<\'> and
419 C<\\>).  The usual C-style backslash rules apply for making
420 characters such as newline, tab, etc., as well as some more exotic
421 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
422 X<string, literal>
423
424 Hexadecimal, octal, or binary, representations in string literals
425 (e.g. '0xff') are not automatically converted to their integer
426 representation.  The hex() and oct() functions make these conversions
427 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
428
429 Hexadecimal floating point can start just like a hexadecimal literal,
430 and it can be followed by an optional fractional hexadecimal part,
431 but it must be followed by C<p>, an optional sign, and a power of two.
432 The format is useful for accurately presenting floating point values,
433 avoiding conversions to or from decimal floating point, and therefore
434 avoiding possible loss in precision.  Notice that while most current
435 platforms use the 64-bit IEEE 754 floating point, not all do.
436
437 You can also embed newlines directly in your strings, i.e., they can end
438 on a different line than they begin.  This is nice, but if you forget
439 your trailing quote, the error will not be reported until Perl finds
440 another line containing the quote character, which may be much further
441 on in the script.  Variable substitution inside strings is limited to
442 scalar variables, arrays, and array or hash slices.  (In other words,
443 names beginning with $ or @, followed by an optional bracketed
444 expression as a subscript.)  The following code segment prints out "The
445 price is $Z<>100."
446 X<interpolation>
447
448     $Price = '$100';    # not interpolated
449     print "The price is $Price.\n";     # interpolated
450
451 There is no double interpolation in Perl, so the C<$100> is left as is.
452
453 By default floating point numbers substituted inside strings use the
454 dot (".")  as the decimal separator.  If C<use locale> is in effect,
455 and POSIX::setlocale() has been called, the character used for the
456 decimal separator is affected by the LC_NUMERIC locale.
457 See L<perllocale> and L<POSIX>.
458
459 As in some shells, you can enclose the variable name in braces to
460 disambiguate it from following alphanumerics (and underscores).
461 You must also do
462 this when interpolating a variable into a string to separate the
463 variable name from a following double-colon or an apostrophe, since
464 these would be otherwise treated as a package separator:
465 X<interpolation>
466
467     $who = "Larry";
468     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
469     print "We use ${who}speak when ${who}'s here.\n";
470
471 Without the braces, Perl would have looked for a $whospeak, a
472 C<$who::0>, and a C<$who's> variable.  The last two would be the
473 $0 and the $s variables in the (presumably) non-existent package
474 C<who>.
475
476 In fact, a simple identifier within such curlies is forced to be
477 a string, and likewise within a hash subscript.  Neither need
478 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
479 C<$days{Feb}> and the quotes will be assumed automatically.  But
480 anything more complicated in the subscript will be interpreted as an
481 expression.  This means for example that C<$version{2.0}++> is
482 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
483
484 =head3 Version Strings
485 X<version string> X<vstring> X<v-string>
486
487 A literal of the form C<v1.20.300.4000> is parsed as a string composed
488 of characters with the specified ordinals.  This form, known as
489 v-strings, provides an alternative, more readable way to construct
490 strings, rather than use the somewhat less readable interpolation form
491 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
492 Unicode strings, and for comparing version "numbers" using the string
493 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
494 more dots in the literal, the leading C<v> may be omitted.
495
496     print v9786;              # prints SMILEY, "\x{263a}"
497     print v102.111.111;       # prints "foo"
498     print 102.111.111;        # same
499
500 Such literals are accepted by both C<require> and C<use> for
501 doing a version check.  Note that using the v-strings for IPv4
502 addresses is not portable unless you also use the
503 inet_aton()/inet_ntoa() routines of the Socket package.
504
505 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
506 are not v-strings before the C<< => >> operator (which is usually used
507 to separate a hash key from a hash value); instead they are interpreted
508 as literal strings ('v65').  They were v-strings from Perl 5.6.0 to
509 Perl 5.8.0, but that caused more confusion and breakage than good.
510 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
511 be v-strings always.
512
513 =head3 Special Literals
514 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
515 X<end> X<data> X<^D> X<^Z>
516
517 The special literals __FILE__, __LINE__, and __PACKAGE__
518 represent the current filename, line number, and package name at that
519 point in your program.  __SUB__ gives a reference to the current
520 subroutine.  They may be used only as separate tokens; they
521 will not be interpolated into strings.  If there is no current package
522 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
523 value.  (But the empty C<package;> is no longer supported, as of version
524 5.10.)  Outside of a subroutine, __SUB__ is the undefined value.  __SUB__
525 is only available in 5.16 or higher, and only with a C<use v5.16> or
526 C<use feature "current_sub"> declaration.
527 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
528 X<line> X<file> X<package>
529
530 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
531 may be used to indicate the logical end of the script before the actual
532 end of file.  Any following text is ignored.
533
534 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
535 where C<PACKNAME> is the package that was current when the __DATA__
536 token was encountered.  The filehandle is left open pointing to the
537 line after __DATA__.  The program should C<close DATA> when it is done
538 reading from it.  (Leaving it open leaks filehandles if the module is
539 reloaded for any reason, so it's a safer practice to close it.)  For
540 compatibility with older scripts written before __DATA__ was
541 introduced, __END__ behaves like __DATA__ in the top level script (but
542 not in files loaded with C<require> or C<do>) and leaves the remaining
543 contents of the file accessible via C<main::DATA>.
544
545 See L<SelfLoader> for more description of __DATA__, and
546 an example of its use.  Note that you cannot read from the DATA
547 filehandle in a BEGIN block: the BEGIN block is executed as soon
548 as it is seen (during compilation), at which point the corresponding
549 __DATA__ (or __END__) token has not yet been seen.
550
551 =head3 Barewords
552 X<bareword>
553
554 A word that has no other interpretation in the grammar will
555 be treated as if it were a quoted string.  These are known as
556 "barewords".  As with filehandles and labels, a bareword that consists
557 entirely of lowercase letters risks conflict with future reserved
558 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
559 Perl will warn you about any such words.  Perl limits barewords (like
560 identifiers) to about 250 characters.  Future versions of Perl are likely
561 to eliminate these arbitrary limitations.
562
563 Some people may wish to outlaw barewords entirely.  If you
564 say
565
566     use strict 'subs';
567
568 then any bareword that would NOT be interpreted as a subroutine call
569 produces a compile-time error instead.  The restriction lasts to the
570 end of the enclosing block.  An inner block may countermand this
571 by saying C<no strict 'subs'>.
572
573 =head3 Array Interpolation
574 X<array, interpolation> X<interpolation, array> X<$">
575
576 Arrays and slices are interpolated into double-quoted strings
577 by joining the elements with the delimiter specified in the C<$">
578 variable (C<$LIST_SEPARATOR> if "use English;" is specified), 
579 space by default.  The following are equivalent:
580
581     $temp = join($", @ARGV);
582     system "echo $temp";
583
584     system "echo @ARGV";
585
586 Within search patterns (which also undergo double-quotish substitution)
587 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
588 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
589 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
590 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
591 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
592 and is almost always right.  If it does guess wrong, or if you're just
593 plain paranoid, you can force the correct interpretation with curly
594 braces as above.
595
596 If you're looking for the information on how to use here-documents,
597 which used to be here, that's been moved to
598 L<perlop/Quote and Quote-like Operators>.
599
600 =head2 List value constructors
601 X<list>
602
603 List values are denoted by separating individual values by commas
604 (and enclosing the list in parentheses where precedence requires it):
605
606     (LIST)
607
608 In a context not requiring a list value, the value of what appears
609 to be a list literal is simply the value of the final element, as
610 with the C comma operator.  For example,
611
612     @foo = ('cc', '-E', $bar);
613
614 assigns the entire list value to array @foo, but
615
616     $foo = ('cc', '-E', $bar);
617
618 assigns the value of variable $bar to the scalar variable $foo.
619 Note that the value of an actual array in scalar context is the
620 length of the array; the following assigns the value 3 to $foo:
621
622     @foo = ('cc', '-E', $bar);
623     $foo = @foo;                # $foo gets 3
624
625 You may have an optional comma before the closing parenthesis of a
626 list literal, so that you can say:
627
628     @foo = (
629         1,
630         2,
631         3,
632     );
633
634 To use a here-document to assign an array, one line per element,
635 you might use an approach like this:
636
637     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
638         normal tomato
639         spicy tomato
640         green chile
641         pesto
642         white wine
643     End_Lines
644
645 LISTs do automatic interpolation of sublists.  That is, when a LIST is
646 evaluated, each element of the list is evaluated in list context, and
647 the resulting list value is interpolated into LIST just as if each
648 individual element were a member of LIST.  Thus arrays and hashes lose their
649 identity in a LIST--the list
650
651     (@foo,@bar,&SomeSub,%glarch)
652
653 contains all the elements of @foo followed by all the elements of @bar,
654 followed by all the elements returned by the subroutine named SomeSub 
655 called in list context, followed by the key/value pairs of %glarch.
656 To make a list reference that does I<NOT> interpolate, see L<perlref>.
657
658 The null list is represented by ().  Interpolating it in a list
659 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
660 interpolating an array with no elements is the same as if no
661 array had been interpolated at that point.
662
663 This interpolation combines with the facts that the opening
664 and closing parentheses are optional (except when necessary for
665 precedence) and lists may end with an optional comma to mean that
666 multiple commas within lists are legal syntax.  The list C<1,,3> is a
667 concatenation of two lists, C<1,> and C<3>, the first of which ends
668 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
669 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
670 we'd advise you to use this obfuscation.
671
672 A list value may also be subscripted like a normal array.  You must
673 put the list in parentheses to avoid ambiguity.  For example:
674
675     # Stat returns list value.
676     $time = (stat($file))[8];
677
678     # SYNTAX ERROR HERE.
679     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
680
681     # Find a hex digit.
682     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
683
684     # A "reverse comma operator".
685     return (pop(@foo),pop(@foo))[0];
686
687 Lists may be assigned to only when each element of the list
688 is itself legal to assign to:
689
690     ($a, $b, $c) = (1, 2, 3);
691
692     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
693
694 An exception to this is that you may assign to C<undef> in a list.
695 This is useful for throwing away some of the return values of a
696 function:
697
698     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
699
700 List assignment in scalar context returns the number of elements
701 produced by the expression on the right side of the assignment:
702
703     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
704     $x = (($foo,$bar) = f());           # set $x to f()'s return count
705
706 This is handy when you want to do a list assignment in a Boolean
707 context, because most list functions return a null list when finished,
708 which when assigned produces a 0, which is interpreted as FALSE.
709
710 It's also the source of a useful idiom for executing a function or
711 performing an operation in list context and then counting the number of
712 return values, by assigning to an empty list and then using that
713 assignment in scalar context.  For example, this code:
714
715     $count = () = $string =~ /\d+/g;
716
717 will place into $count the number of digit groups found in $string.
718 This happens because the pattern match is in list context (since it
719 is being assigned to the empty list), and will therefore return a list
720 of all matching parts of the string.  The list assignment in scalar
721 context will translate that into the number of elements (here, the
722 number of times the pattern matched) and assign that to $count.  Note
723 that simply using
724
725     $count = $string =~ /\d+/g;
726
727 would not have worked, since a pattern match in scalar context will
728 only return true or false, rather than a count of matches.
729
730 The final element of a list assignment may be an array or a hash:
731
732     ($a, $b, @rest) = split;
733     my($a, $b, %rest) = @_;
734
735 You can actually put an array or hash anywhere in the list, but the first one
736 in the list will soak up all the values, and anything after it will become
737 undefined.  This may be useful in a my() or local().
738
739 A hash can be initialized using a literal list holding pairs of
740 items to be interpreted as a key and a value:
741
742     # same as map assignment above
743     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
744
745 While literal lists and named arrays are often interchangeable, that's
746 not the case for hashes.  Just because you can subscript a list value like
747 a normal array does not mean that you can subscript a list value as a
748 hash.  Likewise, hashes included as parts of other lists (including
749 parameters lists and return lists from functions) always flatten out into
750 key/value pairs.  That's why it's good to use references sometimes.
751
752 It is often more readable to use the C<< => >> operator between key/value
753 pairs.  The C<< => >> operator is mostly just a more visually distinctive
754 synonym for a comma, but it also arranges for its left-hand operand to be
755 interpreted as a string if it's a bareword that would be a legal simple
756 identifier.  C<< => >> doesn't quote compound identifiers, that contain
757 double colons.  This makes it nice for initializing hashes:
758
759     %map = (
760                  red   => 0x00f,
761                  blue  => 0x0f0,
762                  green => 0xf00,
763    );
764
765 or for initializing hash references to be used as records:
766
767     $rec = {
768                 witch => 'Mable the Merciless',
769                 cat   => 'Fluffy the Ferocious',
770                 date  => '10/31/1776',
771     };
772
773 or for using call-by-named-parameter to complicated functions:
774
775    $field = $query->radio_group(
776                name      => 'group_name',
777                values    => ['eenie','meenie','minie'],
778                default   => 'meenie',
779                linebreak => 'true',
780                labels    => \%labels
781    );
782
783 Note that just because a hash is initialized in that order doesn't
784 mean that it comes out in that order.  See L<perlfunc/sort> for examples
785 of how to arrange for an output ordering.
786
787 If a key appears more than once in the initializer list of a hash, the last
788 occurrence wins:
789
790     %circle = (
791                   center => [5, 10],
792                   center => [27, 9],
793                   radius => 100,
794                   color => [0xDF, 0xFF, 0x00],
795                   radius => 54,
796     );
797
798     # same as
799     %circle = (
800                   center => [27, 9],
801                   color => [0xDF, 0xFF, 0x00],
802                   radius => 54,
803     );
804
805 This can be used to provide overridable configuration defaults:
806
807     # values in %args take priority over %config_defaults
808     %config = (%config_defaults, %args);
809
810 =head2 Subscripts
811
812 An array can be accessed one scalar at a
813 time by specifying a dollar sign (C<$>), then the
814 name of the array (without the leading C<@>), then the subscript inside
815 square brackets.  For example:
816
817     @myarray = (5, 50, 500, 5000);
818     print "The Third Element is", $myarray[2], "\n";
819
820 The array indices start with 0.  A negative subscript retrieves its 
821 value from the end.  In our example, C<$myarray[-1]> would have been 
822 5000, and C<$myarray[-2]> would have been 500.
823
824 Hash subscripts are similar, only instead of square brackets curly brackets
825 are used.  For example:
826
827     %scientists = 
828     (
829         "Newton" => "Isaac",
830         "Einstein" => "Albert",
831         "Darwin" => "Charles",
832         "Feynman" => "Richard",
833     );
834
835     print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
836
837 You can also subscript a list to get a single element from it:
838
839     $dir = (getpwnam("daemon"))[7];
840
841 =head2 Multi-dimensional array emulation
842
843 Multidimensional arrays may be emulated by subscripting a hash with a
844 list.  The elements of the list are joined with the subscript separator
845 (see L<perlvar/$;>).
846
847     $foo{$a,$b,$c}
848
849 is equivalent to
850
851     $foo{join($;, $a, $b, $c)}
852
853 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
854
855 =head2 Slices
856 X<slice> X<array, slice> X<hash, slice>
857
858 A slice accesses several elements of a list, an array, or a hash
859 simultaneously using a list of subscripts.  It's more convenient
860 than writing out the individual elements as a list of separate
861 scalar values.
862
863     ($him, $her)   = @folks[0,-1];              # array slice
864     @them          = @folks[0 .. 3];            # array slice
865     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
866     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
867
868 Since you can assign to a list of variables, you can also assign to
869 an array or hash slice.
870
871     @days[3..5]    = qw/Wed Thu Fri/;
872     @colors{'red','blue','green'} 
873                    = (0xff0000, 0x0000ff, 0x00ff00);
874     @folks[0, -1]  = @folks[-1, 0];
875
876 The previous assignments are exactly equivalent to
877
878     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
879     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
880                    = (0xff0000, 0x0000ff, 0x00ff00);
881     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
882
883 Since changing a slice changes the original array or hash that it's
884 slicing, a C<foreach> construct will alter some--or even all--of the
885 values of the array or hash.
886
887     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
888
889     foreach (@hash{qw[key1 key2]}) {
890         s/^\s+//;           # trim leading whitespace
891         s/\s+$//;           # trim trailing whitespace
892         s/(\w+)/\u\L$1/g;   # "titlecase" words
893     }
894
895 A slice of an empty list is still an empty list.  Thus:
896
897     @a = ()[1,0];           # @a has no elements
898     @b = (@a)[0,1];         # @b has no elements
899
900 But:
901
902     @a = (1)[1,0];          # @a has two elements
903     @b = (1,undef)[1,0,2];  # @b has three elements
904
905 More generally, a slice yields the empty list if it indexes only
906 beyond the end of a list:
907
908     @a = (1)[  1,2];        # @a has no elements
909     @b = (1)[0,1,2];        # @b has three elements
910
911 This makes it easy to write loops that terminate when a null list
912 is returned:
913
914     while ( ($home, $user) = (getpwent)[7,0]) {
915         printf "%-8s %s\n", $user, $home;
916     }
917
918 As noted earlier in this document, the scalar sense of list assignment
919 is the number of elements on the right-hand side of the assignment.
920 The null list contains no elements, so when the password file is
921 exhausted, the result is 0, not 2.
922
923 Slices in scalar context return the last item of the slice.
924
925     @a = qw/first second third/;
926     %h = (first => 'A', second => 'B');
927     $t = @a[0, 1];                  # $t is now 'second'
928     $u = @h{'first', 'second'};     # $u is now 'B'
929
930 If you're confused about why you use an '@' there on a hash slice
931 instead of a '%', think of it like this.  The type of bracket (square
932 or curly) governs whether it's an array or a hash being looked at.
933 On the other hand, the leading symbol ('$' or '@') on the array or
934 hash indicates whether you are getting back a singular value (a
935 scalar) or a plural one (a list).
936
937 =head3 Key/Value Hash Slices
938
939 Starting in Perl 5.20, a hash slice operation
940 with the % symbol is a variant of slice operation
941 returning a list of key/value pairs rather than just values:
942
943     %h = (blonk => 2, foo => 3, squink => 5, bar => 8);
944     %subset = %h{'foo', 'bar'}; # key/value hash slice
945     # %subset is now (foo => 3, bar => 8)
946
947 However, the result of such a slice cannot be localized, deleted or used
948 in assignment.  These are otherwise very much consistent with hash slices
949 using the @ symbol.
950
951 =head3 Index/Value Array Slices
952
953 Similar to key/value hash slices (and also introduced
954 in Perl 5.20), the % array slice syntax returns a list
955 of index/value pairs:
956
957     @a = "a".."z";
958     @list = %a[3,4,6];
959     # @list is now (3, "d", 4, "e", 6, "g")
960
961 =head2 Typeglobs and Filehandles
962 X<typeglob> X<filehandle> X<*>
963
964 Perl uses an internal type called a I<typeglob> to hold an entire
965 symbol table entry.  The type prefix of a typeglob is a C<*>, because
966 it represents all types.  This used to be the preferred way to
967 pass arrays and hashes by reference into a function, but now that
968 we have real references, this is seldom needed.  
969
970 The main use of typeglobs in modern Perl is create symbol table aliases.
971 This assignment:
972
973     *this = *that;
974
975 makes $this an alias for $that, @this an alias for @that, %this an alias
976 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
977 This:
978
979     local *Here::blue = \$There::green;
980
981 temporarily makes $Here::blue an alias for $There::green, but doesn't
982 make @Here::blue an alias for @There::green, or %Here::blue an alias for
983 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
984 of this.  Strange though this may seem, this is the basis for the whole
985 module import/export system.
986
987 Another use for typeglobs is to pass filehandles into a function or
988 to create new filehandles.  If you need to use a typeglob to save away
989 a filehandle, do it this way:
990
991     $fh = *STDOUT;
992
993 or perhaps as a real reference, like this:
994
995     $fh = \*STDOUT;
996
997 See L<perlsub> for examples of using these as indirect filehandles
998 in functions.
999
1000 Typeglobs are also a way to create a local filehandle using the local()
1001 operator.  These last until their block is exited, but may be passed back.
1002 For example:
1003
1004     sub newopen {
1005         my $path = shift;
1006         local  *FH;  # not my!
1007         open   (FH, $path)          or  return undef;
1008         return *FH;
1009     }
1010     $fh = newopen('/etc/passwd');
1011
1012 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
1013 for filehandle manipulations, although they're still needed to pass brand
1014 new file and directory handles into or out of functions.  That's because
1015 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
1016 In other words, C<*FH> must be used to create new symbol table entries;
1017 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
1018
1019 All functions that are capable of creating filehandles (open(),
1020 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
1021 automatically create an anonymous filehandle if the handle passed to
1022 them is an uninitialized scalar variable.  This allows the constructs
1023 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
1024 create filehandles that will conveniently be closed automatically when
1025 the scope ends, provided there are no other references to them.  This
1026 largely eliminates the need for typeglobs when opening filehandles
1027 that must be passed around, as in the following example:
1028
1029     sub myopen {
1030         open my $fh, "@_"
1031              or die "Can't open '@_': $!";
1032         return $fh;
1033     }
1034
1035     {
1036         my $f = myopen("</etc/motd");
1037         print <$f>;
1038         # $f implicitly closed here
1039     }
1040
1041 Note that if an initialized scalar variable is used instead the
1042 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1043 to C<open( *{'zzz'}, ...)>.
1044 C<use strict 'refs'> forbids such practice.
1045
1046 Another way to create anonymous filehandles is with the Symbol
1047 module or with the IO::Handle module and its ilk.  These modules
1048 have the advantage of not hiding different types of the same name
1049 during the local().  See the bottom of L<perlfunc/open> for an
1050 example.
1051
1052 =head1 SEE ALSO
1053
1054 See L<perlvar> for a description of Perl's built-in variables and
1055 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
1056 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1057 the C<*foo{THING}> syntax.