This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
a89be17ad44ed6c9a0f92a61f357f222f1926967
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34
35 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
36 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
37
38 ##########################################################################
39 #
40 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
41 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
42 # a pod file and a .t file
43 #
44 # The structure of this file is:
45 #   First these introductory comments; then
46 #   code needed for everywhere, such as debugging stuff; then
47 #   code to handle input parameters; then
48 #   data structures likely to be of external interest (some of which depend on
49 #       the input parameters, so follows them; then
50 #   more data structures and subroutine and package (class) definitions; then
51 #   the small actual loop to process the input files and finish up; then
52 #   a __DATA__ section, for the .t tests
53 #
54 # This program works on all releases of Unicode through at least 6.0.  The
55 # outputs have been scrutinized most intently for release 5.1.  The others
56 # have been checked for somewhat more than just sanity.  It can handle all
57 # existing Unicode character properties in those releases.
58 #
59 # This program is mostly about Unicode character (or code point) properties.
60 # A property describes some attribute or quality of a code point, like if it
61 # is lowercase or not, its name, what version of Unicode it was first defined
62 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
63 # possibilities by making all properties into mappings from each code point
64 # into some corresponding value.  In the case of it being lowercase or not,
65 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
66 # property maps each Unicode code point to a single value, called a "property
67 # value".  (Hence each Unicode property is a true mathematical function with
68 # exactly one value per code point.)
69 #
70 # When using a property in a regular expression, what is desired isn't the
71 # mapping of the code point to its property's value, but the reverse (or the
72 # mathematical "inverse relation"): starting with the property value, "Does a
73 # code point map to it?"  These are written in a "compound" form:
74 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
75 # files containing the lists of code points that map to each such regular
76 # expression property value, one file per list
77 #
78 # There is also a single form shortcut that Perl adds for many of the commonly
79 # used properties.  This happens for all binary properties, plus script,
80 # general_category, and block properties.
81 #
82 # Thus the outputs of this program are files.  There are map files, mostly in
83 # the 'To' directory; and there are list files for use in regular expression
84 # matching, all in subdirectories of the 'lib' directory, with each
85 # subdirectory being named for the property that the lists in it are for.
86 # Bookkeeping, test, and documentation files are also generated.
87
88 my $matches_directory = 'lib';   # Where match (\p{}) files go.
89 my $map_directory = 'To';        # Where map files go.
90
91 # DATA STRUCTURES
92 #
93 # The major data structures of this program are Property, of course, but also
94 # Table.  There are two kinds of tables, very similar to each other.
95 # "Match_Table" is the data structure giving the list of code points that have
96 # a particular property value, mentioned above.  There is also a "Map_Table"
97 # data structure which gives the property's mapping from code point to value.
98 # There are two structures because the match tables need to be combined in
99 # various ways, such as constructing unions, intersections, complements, etc.,
100 # and the map ones don't.  And there would be problems, perhaps subtle, if
101 # a map table were inadvertently operated on in some of those ways.
102 # The use of separate classes with operations defined on one but not the other
103 # prevents accidentally confusing the two.
104 #
105 # At the heart of each table's data structure is a "Range_List", which is just
106 # an ordered list of "Ranges", plus ancillary information, and methods to
107 # operate on them.  A Range is a compact way to store property information.
108 # Each range has a starting code point, an ending code point, and a value that
109 # is meant to apply to all the code points between the two end points,
110 # inclusive.  For a map table, this value is the property value for those
111 # code points.  Two such ranges could be written like this:
112 #   0x41 .. 0x5A, 'Upper',
113 #   0x61 .. 0x7A, 'Lower'
114 #
115 # Each range also has a type used as a convenience to classify the values.
116 # Most ranges in this program will be Type 0, or normal, but there are some
117 # ranges that have a non-zero type.  These are used only in map tables, and
118 # are for mappings that don't fit into the normal scheme of things.  Mappings
119 # that require a hash entry to communicate with utf8.c are one example;
120 # another example is mappings for charnames.pm to use which indicate a name
121 # that is algorithmically determinable from its code point (and vice-versa).
122 # These are used to significantly compact these tables, instead of listing
123 # each one of the tens of thousands individually.
124 #
125 # In a match table, the value of a range is irrelevant (and hence the type as
126 # well, which will always be 0), and arbitrarily set to the null string.
127 # Using the example above, there would be two match tables for those two
128 # entries, one named Upper would contain the 0x41..0x5A range, and the other
129 # named Lower would contain 0x61..0x7A.
130 #
131 # Actually, there are two types of range lists, "Range_Map" is the one
132 # associated with map tables, and "Range_List" with match tables.
133 # Again, this is so that methods can be defined on one and not the other so as
134 # to prevent operating on them in incorrect ways.
135 #
136 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
137 # in the perl core.  All tables could in theory be written, but some are
138 # suppressed because there is no current practical use for them.  It is easy
139 # to change which get written by changing various lists that are near the top
140 # of the actual code in this file.  The table data structures contain enough
141 # ancillary information to allow them to be treated as separate entities for
142 # writing, such as the path to each one's file.  There is a heading in each
143 # map table that gives the format of its entries, and what the map is for all
144 # the code points missing from it.  (This allows tables to be more compact.)
145 #
146 # The Property data structure contains one or more tables.  All properties
147 # contain a map table (except the $perl property which is a
148 # pseudo-property containing only match tables), and any properties that
149 # are usable in regular expression matches also contain various matching
150 # tables, one for each value the property can have.  A binary property can
151 # have two values, True and False (or Y and N, which are preferred by Unicode
152 # terminology).  Thus each of these properties will have a map table that
153 # takes every code point and maps it to Y or N (but having ranges cuts the
154 # number of entries in that table way down), and two match tables, one
155 # which has a list of all the code points that map to Y, and one for all the
156 # code points that map to N.  (For each of these, a third table is also
157 # generated for the pseudo Perl property.  It contains the identical code
158 # points as the Y table, but can be written, not in the compound form, but in
159 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
160 # properties have several possible values, some have many, and properties like
161 # Name have a different value for every named code point.  Those will not,
162 # unless the controlling lists are changed, have their match tables written
163 # out.  But all the ones which can be used in regular expression \p{} and \P{}
164 # constructs will.  Prior to 5.14, generally a property would have either its
165 # map table or its match tables written but not both.  Again, what gets
166 # written is controlled by lists which can easily be changed.  Starting in
167 # 5.14, advantage was taken of this, and all the map tables needed to
168 # reconstruct the Unicode db are now written out, while suppressing the
169 # Unicode .txt files that contain the data.  Our tables are much more compact
170 # than the .txt files, so a significant space savings was achieved.
171
172 # Properties have a 'Type', like binary, or string, or enum depending on how
173 # many match tables there are and the content of the maps.  This 'Type' is
174 # different than a range 'Type', so don't get confused by the two concepts
175 # having the same name.
176 #
177 # For information about the Unicode properties, see Unicode's UAX44 document:
178
179 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
180
181 # As stated earlier, this program will work on any release of Unicode so far.
182 # Most obvious problems in earlier data have NOT been corrected except when
183 # necessary to make Perl or this program work reasonably.  For example, no
184 # folding information was given in early releases, so this program substitutes
185 # lower case instead, just so that a regular expression with the /i option
186 # will do something that actually gives the right results in many cases.
187 # There are also a couple other corrections for version 1.1.5, commented at
188 # the point they are made.  As an example of corrections that weren't made
189 # (but could be) is this statement from DerivedAge.txt: "The supplementary
190 # private use code points and the non-character code points were assigned in
191 # version 2.0, but not specifically listed in the UCD until versions 3.0 and
192 # 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0) More information
193 # on Unicode version glitches is further down in these introductory comments.
194 #
195 # This program works on all non-provisional properties as of 6.0, though the
196 # files for some are suppressed from apparent lack of demand for them.  You
197 # can change which are output by changing lists in this program.
198 #
199 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
200 # loose matchings rules (from Unicode TR18):
201 #
202 #    The recommended names for UCD properties and property values are in
203 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
204 #    [PropValue]. There are both abbreviated names and longer, more
205 #    descriptive names. It is strongly recommended that both names be
206 #    recognized, and that loose matching of property names be used,
207 #    whereby the case distinctions, whitespace, hyphens, and underbar
208 #    are ignored.
209 # The program still allows Fuzzy to override its determination of if loose
210 # matching should be used, but it isn't currently used, as it is no longer
211 # needed; the calculations it makes are good enough.
212 #
213 # SUMMARY OF HOW IT WORKS:
214 #
215 #   Process arguments
216 #
217 #   A list is constructed containing each input file that is to be processed
218 #
219 #   Each file on the list is processed in a loop, using the associated handler
220 #   code for each:
221 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
222 #            first.  These files name the properties and property values.
223 #            Objects are created of all the property and property value names
224 #            that the rest of the input should expect, including all synonyms.
225 #        The other input files give mappings from properties to property
226 #           values.  That is, they list code points and say what the mapping
227 #           is under the given property.  Some files give the mappings for
228 #           just one property; and some for many.  This program goes through
229 #           each file and populates the properties from them.  Some properties
230 #           are listed in more than one file, and Unicode has set up a
231 #           precedence as to which has priority if there is a conflict.  Thus
232 #           the order of processing matters, and this program handles the
233 #           conflict possibility by processing the overriding input files
234 #           last, so that if necessary they replace earlier values.
235 #        After this is all done, the program creates the property mappings not
236 #            furnished by Unicode, but derivable from what it does give.
237 #        The tables of code points that match each property value in each
238 #            property that is accessible by regular expressions are created.
239 #        The Perl-defined properties are created and populated.  Many of these
240 #            require data determined from the earlier steps
241 #        Any Perl-defined synonyms are created, and name clashes between Perl
242 #            and Unicode are reconciled and warned about.
243 #        All the properties are written to files
244 #        Any other files are written, and final warnings issued.
245 #
246 # For clarity, a number of operators have been overloaded to work on tables:
247 #   ~ means invert (take all characters not in the set).  The more
248 #       conventional '!' is not used because of the possibility of confusing
249 #       it with the actual boolean operation.
250 #   + means union
251 #   - means subtraction
252 #   & means intersection
253 # The precedence of these is the order listed.  Parentheses should be
254 # copiously used.  These are not a general scheme.  The operations aren't
255 # defined for a number of things, deliberately, to avoid getting into trouble.
256 # Operations are done on references and affect the underlying structures, so
257 # that the copy constructors for them have been overloaded to not return a new
258 # clone, but the input object itself.
259 #
260 # The bool operator is deliberately not overloaded to avoid confusion with
261 # "should it mean if the object merely exists, or also is non-empty?".
262 #
263 # WHY CERTAIN DESIGN DECISIONS WERE MADE
264 #
265 # This program needs to be able to run under miniperl.  Therefore, it uses a
266 # minimum of other modules, and hence implements some things itself that could
267 # be gotten from CPAN
268 #
269 # This program uses inputs published by the Unicode Consortium.  These can
270 # change incompatibly between releases without the Perl maintainers realizing
271 # it.  Therefore this program is now designed to try to flag these.  It looks
272 # at the directories where the inputs are, and flags any unrecognized files.
273 # It keeps track of all the properties in the files it handles, and flags any
274 # that it doesn't know how to handle.  It also flags any input lines that
275 # don't match the expected syntax, among other checks.
276 #
277 # It is also designed so if a new input file matches one of the known
278 # templates, one hopefully just needs to add it to a list to have it
279 # processed.
280 #
281 # As mentioned earlier, some properties are given in more than one file.  In
282 # particular, the files in the extracted directory are supposedly just
283 # reformattings of the others.  But they contain information not easily
284 # derivable from the other files, including results for Unihan, which this
285 # program doesn't ordinarily look at, and for unassigned code points.  They
286 # also have historically had errors or been incomplete.  In an attempt to
287 # create the best possible data, this program thus processes them first to
288 # glean information missing from the other files; then processes those other
289 # files to override any errors in the extracted ones.  Much of the design was
290 # driven by this need to store things and then possibly override them.
291 #
292 # It tries to keep fatal errors to a minimum, to generate something usable for
293 # testing purposes.  It always looks for files that could be inputs, and will
294 # warn about any that it doesn't know how to handle (the -q option suppresses
295 # the warning).
296 #
297 # Why is there more than one type of range?
298 #   This simplified things.  There are some very specialized code points that
299 #   have to be handled specially for output, such as Hangul syllable names.
300 #   By creating a range type (done late in the development process), it
301 #   allowed this to be stored with the range, and overridden by other input.
302 #   Originally these were stored in another data structure, and it became a
303 #   mess trying to decide if a second file that was for the same property was
304 #   overriding the earlier one or not.
305 #
306 # Why are there two kinds of tables, match and map?
307 #   (And there is a base class shared by the two as well.)  As stated above,
308 #   they actually are for different things.  Development proceeded much more
309 #   smoothly when I (khw) realized the distinction.  Map tables are used to
310 #   give the property value for every code point (actually every code point
311 #   that doesn't map to a default value).  Match tables are used for regular
312 #   expression matches, and are essentially the inverse mapping.  Separating
313 #   the two allows more specialized methods, and error checks so that one
314 #   can't just take the intersection of two map tables, for example, as that
315 #   is nonsensical.
316 #
317 # DEBUGGING
318 #
319 # This program is written so it will run under miniperl.  Occasionally changes
320 # will cause an error where the backtrace doesn't work well under miniperl.
321 # To diagnose the problem, you can instead run it under regular perl, if you
322 # have one compiled.
323 #
324 # There is a good trace facility.  To enable it, first sub DEBUG must be set
325 # to return true.  Then a line like
326 #
327 # local $to_trace = 1 if main::DEBUG;
328 #
329 # can be added to enable tracing in its lexical scope or until you insert
330 # another line:
331 #
332 # local $to_trace = 0 if main::DEBUG;
333 #
334 # then use a line like "trace $a, @b, %c, ...;
335 #
336 # Some of the more complex subroutines already have trace statements in them.
337 # Permanent trace statements should be like:
338 #
339 # trace ... if main::DEBUG && $to_trace;
340 #
341 # If there is just one or a few files that you're debugging, you can easily
342 # cause most everything else to be skipped.  Change the line
343 #
344 # my $debug_skip = 0;
345 #
346 # to 1, and every file whose object is in @input_file_objects and doesn't have
347 # a, 'non_skip => 1,' in its constructor will be skipped.
348 #
349 # To compare the output tables, it may be useful to specify the -annotate
350 # flag.  This causes the tables to expand so there is one entry for each
351 # non-algorithmically named code point giving, currently its name, and its
352 # graphic representation if printable (and you have a font that knows about
353 # it).  This makes it easier to see what the particular code points are in
354 # each output table.  The tables are usable, but because they don't have
355 # ranges (for the most part), a Perl using them will run slower.  Non-named
356 # code points are annotated with a description of their status, and contiguous
357 # ones with the same description will be output as a range rather than
358 # individually.  Algorithmically named characters are also output as ranges,
359 # except when there are just a few contiguous ones.
360 #
361 # FUTURE ISSUES
362 #
363 # The program would break if Unicode were to change its names so that
364 # interior white space, underscores, or dashes differences were significant
365 # within property and property value names.
366 #
367 # It might be easier to use the xml versions of the UCD if this program ever
368 # would need heavy revision, and the ability to handle old versions was not
369 # required.
370 #
371 # There is the potential for name collisions, in that Perl has chosen names
372 # that Unicode could decide it also likes.  There have been such collisions in
373 # the past, with mostly Perl deciding to adopt the Unicode definition of the
374 # name.  However in the 5.2 Unicode beta testing, there were a number of such
375 # collisions, which were withdrawn before the final release, because of Perl's
376 # and other's protests.  These all involved new properties which began with
377 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
378 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
379 # Unicode document, so they are unlikely to be used by Unicode for another
380 # purpose.  However, they might try something beginning with 'In', or use any
381 # of the other Perl-defined properties.  This program will warn you of name
382 # collisions, and refuse to generate tables with them, but manual intervention
383 # will be required in this event.  One scheme that could be implemented, if
384 # necessary, would be to have this program generate another file, or add a
385 # field to mktables.lst that gives the date of first definition of a property.
386 # Each new release of Unicode would use that file as a basis for the next
387 # iteration.  And the Perl synonym addition code could sort based on the age
388 # of the property, so older properties get priority, and newer ones that clash
389 # would be refused; hence existing code would not be impacted, and some other
390 # synonym would have to be used for the new property.  This is ugly, and
391 # manual intervention would certainly be easier to do in the short run; lets
392 # hope it never comes to this.
393 #
394 # A NOTE ON UNIHAN
395 #
396 # This program can generate tables from the Unihan database.  But it doesn't
397 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
398 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
399 # database was split into 8 different files, all beginning with the letters
400 # 'Unihan'.  This program will read those file(s) if present, but it needs to
401 # know which of the many properties in the file(s) should have tables created
402 # for them.  It will create tables for any properties listed in
403 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
404 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
405 # property you want is not in those files of the release you are building
406 # against, you must add it to those two arrays.  Starting in 4.0, the
407 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
408 # is present in the directory, a table will be generated for that property.
409 # In 5.2, several more properties were added.  For your convenience, the two
410 # arrays are initialized with all the 6.0 listed properties that are also in
411 # earlier releases.  But these are commented out.  You can just uncomment the
412 # ones you want, or use them as a template for adding entries for other
413 # properties.
414 #
415 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
416 # and filter_unihan_line() are the functions where this is done.  This program
417 # already does some adjusting to make the lines look more like the rest of the
418 # Unicode DB;  You can see what that is in filter_unihan_line()
419 #
420 # There is a bug in the 3.2 data file in which some values for the
421 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
422 # could be added for these; or for a particular installation, the Unihan.txt
423 # file could be edited to fix them.
424 #
425 # HOW TO ADD A FILE TO BE PROCESSED
426 #
427 # A new file from Unicode needs to have an object constructed for it in
428 # @input_file_objects, probably at the end or at the end of the extracted
429 # ones.  The program should warn you if its name will clash with others on
430 # restrictive file systems, like DOS.  If so, figure out a better name, and
431 # add lines to the README.perl file giving that.  If the file is a character
432 # property, it should be in the format that Unicode has by default
433 # standardized for such files for the more recently introduced ones.
434 # If so, the Input_file constructor for @input_file_objects can just be the
435 # file name and release it first appeared in.  If not, then it should be
436 # possible to construct an each_line_handler() to massage the line into the
437 # standardized form.
438 #
439 # For non-character properties, more code will be needed.  You can look at
440 # the existing entries for clues.
441 #
442 # UNICODE VERSIONS NOTES
443 #
444 # The Unicode UCD has had a number of errors in it over the versions.  And
445 # these remain, by policy, in the standard for that version.  Therefore it is
446 # risky to correct them, because code may be expecting the error.  So this
447 # program doesn't generally make changes, unless the error breaks the Perl
448 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
449 # for U+1105, which causes real problems for the algorithms for Jamo
450 # calculations, so it is changed here.
451 #
452 # But it isn't so clear cut as to what to do about concepts that are
453 # introduced in a later release; should they extend back to earlier releases
454 # where the concept just didn't exist?  It was easier to do this than to not,
455 # so that's what was done.  For example, the default value for code points not
456 # in the files for various properties was probably undefined until changed by
457 # some version.  No_Block for blocks is such an example.  This program will
458 # assign No_Block even in Unicode versions that didn't have it.  This has the
459 # benefit that code being written doesn't have to special case earlier
460 # versions; and the detriment that it doesn't match the Standard precisely for
461 # the affected versions.
462 #
463 # Here are some observations about some of the issues in early versions:
464 #
465 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
466 # the reason is that the CJK block starting at 4E00 was removed from PropList,
467 # and was not put back in until 3.1.0
468 #
469 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
470 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
471 # reason is that 3.2 introduced U+205F=medium math space, which was not
472 # classed as white space, but Perl figured out that it should have been. 4.0
473 # reclassified it correctly.
474 #
475 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
476 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
477 # was left with no code points, as all the ones that mapped to 202 stayed
478 # mapped to 202.  Thus if your program used the numeric name for the class,
479 # it would not have been affected, but if it used the mnemonic, it would have
480 # been.
481 #
482 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
483 # points which eventually came to have this script property value, instead
484 # mapped to "Unknown".  But in the next release all these code points were
485 # moved to \p{sc=common} instead.
486 #
487 # The default for missing code points for BidiClass is complicated.  Starting
488 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
489 # tries to do the best it can for earlier releases.  It is done in
490 # process_PropertyAliases()
491 #
492 ##############################################################################
493
494 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
495                         # and errors
496 my $MAX_LINE_WIDTH = 78;
497
498 # Debugging aid to skip most files so as to not be distracted by them when
499 # concentrating on the ones being debugged.  Add
500 # non_skip => 1,
501 # to the constructor for those files you want processed when you set this.
502 # Files with a first version number of 0 are special: they are always
503 # processed regardless of the state of this flag.  Generally, Jamo.txt and
504 # UnicodeData.txt must not be skipped if you want this program to not die
505 # before normal completion.
506 my $debug_skip = 0;
507
508 # Set to 1 to enable tracing.
509 our $to_trace = 0;
510
511 { # Closure for trace: debugging aid
512     my $print_caller = 1;        # ? Include calling subroutine name
513     my $main_with_colon = 'main::';
514     my $main_colon_length = length($main_with_colon);
515
516     sub trace {
517         return unless $to_trace;        # Do nothing if global flag not set
518
519         my @input = @_;
520
521         local $DB::trace = 0;
522         $DB::trace = 0;          # Quiet 'used only once' message
523
524         my $line_number;
525
526         # Loop looking up the stack to get the first non-trace caller
527         my $caller_line;
528         my $caller_name;
529         my $i = 0;
530         do {
531             $line_number = $caller_line;
532             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
533             $caller = $main_with_colon unless defined $caller;
534
535             $caller_name = $caller;
536
537             # get rid of pkg
538             $caller_name =~ s/.*:://;
539             if (substr($caller_name, 0, $main_colon_length)
540                 eq $main_with_colon)
541             {
542                 $caller_name = substr($caller_name, $main_colon_length);
543             }
544
545         } until ($caller_name ne 'trace');
546
547         # If the stack was empty, we were called from the top level
548         $caller_name = 'main' if ($caller_name eq ""
549                                     || $caller_name eq 'trace');
550
551         my $output = "";
552         foreach my $string (@input) {
553             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
554             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
555                 $output .= simple_dumper($string);
556             }
557             else {
558                 $string = "$string" if ref $string;
559                 $string = $UNDEF unless defined $string;
560                 chomp $string;
561                 $string = '""' if $string eq "";
562                 $output .= " " if $output ne ""
563                                 && $string ne ""
564                                 && substr($output, -1, 1) ne " "
565                                 && substr($string, 0, 1) ne " ";
566                 $output .= $string;
567             }
568         }
569
570         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
571         print STDERR "$caller_name: " if $print_caller;
572         print STDERR $output, "\n";
573         return;
574     }
575 }
576
577 # This is for a rarely used development feature that allows you to compare two
578 # versions of the Unicode standard without having to deal with changes caused
579 # by the code points introduced in the later version.  Change the 0 to a
580 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
581 # code points introduced in that release and earlier will be used; later ones
582 # are thrown away.  You use the version number of the earliest one you want to
583 # compare; then run this program on directory structures containing each
584 # release, and compare the outputs.  These outputs will therefore include only
585 # the code points common to both releases, and you can see the changes caused
586 # just by the underlying release semantic changes.  For versions earlier than
587 # 3.2, you must copy a version of DAge.txt into the directory.
588 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
589 my $compare_versions = DEBUG
590                        && $string_compare_versions
591                        && pack "C*", split /\./, $string_compare_versions;
592
593 sub uniques {
594     # Returns non-duplicated input values.  From "Perl Best Practices:
595     # Encapsulated Cleverness".  p. 455 in first edition.
596
597     my %seen;
598     # Arguably this breaks encapsulation, if the goal is to permit multiple
599     # distinct objects to stringify to the same value, and be interchangeable.
600     # However, for this program, no two objects stringify identically, and all
601     # lists passed to this function are either objects or strings. So this
602     # doesn't affect correctness, but it does give a couple of percent speedup.
603     no overloading;
604     return grep { ! $seen{$_}++ } @_;
605 }
606
607 $0 = File::Spec->canonpath($0);
608
609 my $make_test_script = 0;      # ? Should we output a test script
610 my $write_unchanged_files = 0; # ? Should we update the output files even if
611                                #    we don't think they have changed
612 my $use_directory = "";        # ? Should we chdir somewhere.
613 my $pod_directory;             # input directory to store the pod file.
614 my $pod_file = 'perluniprops';
615 my $t_path;                     # Path to the .t test file
616 my $file_list = 'mktables.lst'; # File to store input and output file names.
617                                # This is used to speed up the build, by not
618                                # executing the main body of the program if
619                                # nothing on the list has changed since the
620                                # previous build
621 my $make_list = 1;             # ? Should we write $file_list.  Set to always
622                                # make a list so that when the pumpking is
623                                # preparing a release, s/he won't have to do
624                                # special things
625 my $glob_list = 0;             # ? Should we try to include unknown .txt files
626                                # in the input.
627 my $output_range_counts = $debugging_build;   # ? Should we include the number
628                                               # of code points in ranges in
629                                               # the output
630 my $annotate = 0;              # ? Should character names be in the output
631
632 # Verbosity levels; 0 is quiet
633 my $NORMAL_VERBOSITY = 1;
634 my $PROGRESS = 2;
635 my $VERBOSE = 3;
636
637 my $verbosity = $NORMAL_VERBOSITY;
638
639 # Process arguments
640 while (@ARGV) {
641     my $arg = shift @ARGV;
642     if ($arg eq '-v') {
643         $verbosity = $VERBOSE;
644     }
645     elsif ($arg eq '-p') {
646         $verbosity = $PROGRESS;
647         $| = 1;     # Flush buffers as we go.
648     }
649     elsif ($arg eq '-q') {
650         $verbosity = 0;
651     }
652     elsif ($arg eq '-w') {
653         $write_unchanged_files = 1; # update the files even if havent changed
654     }
655     elsif ($arg eq '-check') {
656         my $this = shift @ARGV;
657         my $ok = shift @ARGV;
658         if ($this ne $ok) {
659             print "Skipping as check params are not the same.\n";
660             exit(0);
661         }
662     }
663     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
664         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
665     }
666     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
667     {
668         $make_test_script = 1;
669     }
670     elsif ($arg eq '-makelist') {
671         $make_list = 1;
672     }
673     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
674         -d $use_directory or croak "Unknown directory '$use_directory'";
675     }
676     elsif ($arg eq '-L') {
677
678         # Existence not tested until have chdir'd
679         $file_list = shift;
680     }
681     elsif ($arg eq '-globlist') {
682         $glob_list = 1;
683     }
684     elsif ($arg eq '-c') {
685         $output_range_counts = ! $output_range_counts
686     }
687     elsif ($arg eq '-annotate') {
688         $annotate = 1;
689         $debugging_build = 1;
690         $output_range_counts = 1;
691     }
692     else {
693         my $with_c = 'with';
694         $with_c .= 'out' if $output_range_counts;   # Complements the state
695         croak <<END;
696 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
697           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
698           [-check A B ]
699   -c          : Output comments $with_c number of code points in ranges
700   -q          : Quiet Mode: Only output serious warnings.
701   -p          : Set verbosity level to normal plus show progress.
702   -v          : Set Verbosity level high:  Show progress and non-serious
703                 warnings
704   -w          : Write files regardless
705   -C dir      : Change to this directory before proceeding. All relative paths
706                 except those specified by the -P and -T options will be done
707                 with respect to this directory.
708   -P dir      : Output $pod_file file to directory 'dir'.
709   -T path     : Create a test script as 'path'; overrides -maketest
710   -L filelist : Use alternate 'filelist' instead of standard one
711   -globlist   : Take as input all non-Test *.txt files in current and sub
712                 directories
713   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
714                 overrides -T
715   -makelist   : Rewrite the file list $file_list based on current setup
716   -annotate   : Output an annotation for each character in the table files;
717                 useful for debugging mktables, looking at diffs; but is slow,
718                 memory intensive; resulting tables are usable but slow and
719                 very large.
720   -check A B  : Executes $0 only if A and B are the same
721 END
722     }
723 }
724
725 # Stores the most-recently changed file.  If none have changed, can skip the
726 # build
727 my $most_recent = (stat $0)[9];   # Do this before the chdir!
728
729 # Change directories now, because need to read 'version' early.
730 if ($use_directory) {
731     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
732         $pod_directory = File::Spec->rel2abs($pod_directory);
733     }
734     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
735         $t_path = File::Spec->rel2abs($t_path);
736     }
737     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
738     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
739         $pod_directory = File::Spec->abs2rel($pod_directory);
740     }
741     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
742         $t_path = File::Spec->abs2rel($t_path);
743     }
744 }
745
746 # Get Unicode version into regular and v-string.  This is done now because
747 # various tables below get populated based on it.  These tables are populated
748 # here to be near the top of the file, and so easily seeable by those needing
749 # to modify things.
750 open my $VERSION, "<", "version"
751                     or croak "$0: can't open required file 'version': $!\n";
752 my $string_version = <$VERSION>;
753 close $VERSION;
754 chomp $string_version;
755 my $v_version = pack "C*", split /\./, $string_version;        # v string
756
757 # The following are the complete names of properties with property values that
758 # are known to not match any code points in some versions of Unicode, but that
759 # may change in the future so they should be matchable, hence an empty file is
760 # generated for them.
761 my @tables_that_may_be_empty = (
762                                 'Joining_Type=Left_Joining',
763                                 );
764 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
765 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
766 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
767                                                     if $v_version ge v4.1.0;
768 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
769                                                     if $v_version ge v6.0.0;
770
771 # The lists below are hashes, so the key is the item in the list, and the
772 # value is the reason why it is in the list.  This makes generation of
773 # documentation easier.
774
775 my %why_suppressed;  # No file generated for these.
776
777 # Files aren't generated for empty extraneous properties.  This is arguable.
778 # Extraneous properties generally come about because a property is no longer
779 # used in a newer version of Unicode.  If we generated a file without code
780 # points, programs that used to work on that property will still execute
781 # without errors.  It just won't ever match (or will always match, with \P{}).
782 # This means that the logic is now likely wrong.  I (khw) think its better to
783 # find this out by getting an error message.  Just move them to the table
784 # above to change this behavior
785 my %why_suppress_if_empty_warn_if_not = (
786
787    # It is the only property that has ever officially been removed from the
788    # Standard.  The database never contained any code points for it.
789    'Special_Case_Condition' => 'Obsolete',
790
791    # Apparently never official, but there were code points in some versions of
792    # old-style PropList.txt
793    'Non_Break' => 'Obsolete',
794 );
795
796 # These would normally go in the warn table just above, but they were changed
797 # a long time before this program was written, so warnings about them are
798 # moot.
799 if ($v_version gt v3.2.0) {
800     push @tables_that_may_be_empty,
801                                 'Canonical_Combining_Class=Attached_Below_Left'
802 }
803
804 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
805 # unless explicitly added.
806 if ($v_version ge v5.2.0) {
807     my $unihan = 'Unihan; remove from list if using Unihan';
808     foreach my $table (qw (
809                            kAccountingNumeric
810                            kOtherNumeric
811                            kPrimaryNumeric
812                            kCompatibilityVariant
813                            kIICore
814                            kIRG_GSource
815                            kIRG_HSource
816                            kIRG_JSource
817                            kIRG_KPSource
818                            kIRG_MSource
819                            kIRG_KSource
820                            kIRG_TSource
821                            kIRG_USource
822                            kIRG_VSource
823                            kRSUnicode
824                         ))
825     {
826         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
827     }
828 }
829
830 # Enum values for to_output_map() method in the Map_Table package.
831 my $EXTERNAL_MAP = 1;
832 my $INTERNAL_MAP = 2;
833
834 # To override computed values for writing the map tables for these properties.
835 # The default for enum map tables is to write them out, so that the Unicode
836 # .txt files can be removed, but all the data to compute any property value
837 # for any code point is available in a more compact form.
838 my %global_to_output_map = (
839     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
840     # get stuck supporting it if things change.  Since it is a STRING
841     # property, it normally would be listed in the pod, but INTERNAL_MAP
842     # suppresses that.
843     Unicode_1_Name => $INTERNAL_MAP,
844
845     Present_In => 0,                # Suppress, as easily computed from Age
846     Block => 0,                     # Suppress, as Blocks.txt is retained.
847
848     # Suppress, as mapping can be found instead from the
849     # Perl_Decomposition_Mapping file
850     Decomposition_Type => 0,
851 );
852
853 # Properties that this program ignores.
854 my @unimplemented_properties = (
855 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
856 );
857
858 # There are several types of obsolete properties defined by Unicode.  These
859 # must be hand-edited for every new Unicode release.
860 my %why_deprecated;  # Generates a deprecated warning message if used.
861 my %why_stabilized;  # Documentation only
862 my %why_obsolete;    # Documentation only
863
864 {   # Closure
865     my $simple = 'Perl uses the more complete version of this property';
866     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
867
868     my $other_properties = 'other properties';
869     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
870     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
871
872     %why_deprecated = (
873         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
874         'Jamo_Short_Name' => $contributory,
875         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
876         'Other_Alphabetic' => $contributory,
877         'Other_Default_Ignorable_Code_Point' => $contributory,
878         'Other_Grapheme_Extend' => $contributory,
879         'Other_ID_Continue' => $contributory,
880         'Other_ID_Start' => $contributory,
881         'Other_Lowercase' => $contributory,
882         'Other_Math' => $contributory,
883         'Other_Uppercase' => $contributory,
884         'Expands_On_NFC' => $why_no_expand,
885         'Expands_On_NFD' => $why_no_expand,
886         'Expands_On_NFKC' => $why_no_expand,
887         'Expands_On_NFKD' => $why_no_expand,
888     );
889
890     %why_suppressed = (
891         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
892         # contains the same information, but without the algorithmically
893         # determinable Hangul syllables'.  This file is not published, so it's
894         # existence is not noted in the comment.
895         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
896
897         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
898
899         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
900         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
901         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
902         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
903
904         'Name' => "Accessible via 'use charnames;'",
905         'Name_Alias' => "Accessible via 'use charnames;'",
906
907         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
908     );
909
910     # The following are suppressed because they were made contributory or
911     # deprecated by Unicode before Perl ever thought about supporting them.
912     foreach my $property ('Jamo_Short_Name',
913                           'Grapheme_Link',
914                           'Expands_On_NFC',
915                           'Expands_On_NFD',
916                           'Expands_On_NFKC',
917                           'Expands_On_NFKD'
918     ) {
919         $why_suppressed{$property} = $why_deprecated{$property};
920     }
921
922     # Customize the message for all the 'Other_' properties
923     foreach my $property (keys %why_deprecated) {
924         next if (my $main_property = $property) !~ s/^Other_//;
925         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
926     }
927 }
928
929 if ($v_version ge 4.0.0) {
930     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
931     if ($v_version ge 6.0.0) {
932         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
933     }
934 }
935 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
936     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
937     if ($v_version ge 6.0.0) {
938         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
939     }
940 }
941
942 # Probably obsolete forever
943 if ($v_version ge v4.1.0) {
944     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
945 }
946 if ($v_version ge v6.0.0) {
947     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
948     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
949 }
950
951 # This program can create files for enumerated-like properties, such as
952 # 'Numeric_Type'.  This file would be the same format as for a string
953 # property, with a mapping from code point to its value, so you could look up,
954 # for example, the script a code point is in.  But no one so far wants this
955 # mapping, or they have found another way to get it since this is a new
956 # feature.  So no file is generated except if it is in this list.
957 my @output_mapped_properties = split "\n", <<END;
958 END
959
960 # If you are using the Unihan database in a Unicode version before 5.2, you
961 # need to add the properties that you want to extract from it to this table.
962 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
963 # listed, commented out
964 my @cjk_properties = split "\n", <<'END';
965 #cjkAccountingNumeric; kAccountingNumeric
966 #cjkOtherNumeric; kOtherNumeric
967 #cjkPrimaryNumeric; kPrimaryNumeric
968 #cjkCompatibilityVariant; kCompatibilityVariant
969 #cjkIICore ; kIICore
970 #cjkIRG_GSource; kIRG_GSource
971 #cjkIRG_HSource; kIRG_HSource
972 #cjkIRG_JSource; kIRG_JSource
973 #cjkIRG_KPSource; kIRG_KPSource
974 #cjkIRG_KSource; kIRG_KSource
975 #cjkIRG_TSource; kIRG_TSource
976 #cjkIRG_USource; kIRG_USource
977 #cjkIRG_VSource; kIRG_VSource
978 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
979 END
980
981 # Similarly for the property values.  For your convenience, the lines in the
982 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
983 # '#' marks (for Unicode versions before 5.2)
984 my @cjk_property_values = split "\n", <<'END';
985 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
986 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
987 ## @missing: 0000..10FFFF; cjkIICore; <none>
988 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
989 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
990 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
991 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
992 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
993 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
994 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
995 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
996 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
997 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
998 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
999 END
1000
1001 # The input files don't list every code point.  Those not listed are to be
1002 # defaulted to some value.  Below are hard-coded what those values are for
1003 # non-binary properties as of 5.1.  Starting in 5.0, there are
1004 # machine-parsable comment lines in the files the give the defaults; so this
1005 # list shouldn't have to be extended.  The claim is that all missing entries
1006 # for binary properties will default to 'N'.  Unicode tried to change that in
1007 # 5.2, but the beta period produced enough protest that they backed off.
1008 #
1009 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1010 # be in the form that it expects.  The others may be synonyms.
1011 my $CODE_POINT = '<code point>';
1012 my %default_mapping = (
1013     Age => "Unassigned",
1014     # Bidi_Class => Complicated; set in code
1015     Bidi_Mirroring_Glyph => "",
1016     Block => 'No_Block',
1017     Canonical_Combining_Class => 0,
1018     Case_Folding => $CODE_POINT,
1019     Decomposition_Mapping => $CODE_POINT,
1020     Decomposition_Type => 'None',
1021     East_Asian_Width => "Neutral",
1022     FC_NFKC_Closure => $CODE_POINT,
1023     General_Category => 'Cn',
1024     Grapheme_Cluster_Break => 'Other',
1025     Hangul_Syllable_Type => 'NA',
1026     ISO_Comment => "",
1027     Jamo_Short_Name => "",
1028     Joining_Group => "No_Joining_Group",
1029     # Joining_Type => Complicated; set in code
1030     kIICore => 'N',   #                       Is converted to binary
1031     #Line_Break => Complicated; set in code
1032     Lowercase_Mapping => $CODE_POINT,
1033     Name => "",
1034     Name_Alias => "",
1035     NFC_QC => 'Yes',
1036     NFD_QC => 'Yes',
1037     NFKC_QC => 'Yes',
1038     NFKD_QC => 'Yes',
1039     Numeric_Type => 'None',
1040     Numeric_Value => 'NaN',
1041     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1042     Sentence_Break => 'Other',
1043     Simple_Case_Folding => $CODE_POINT,
1044     Simple_Lowercase_Mapping => $CODE_POINT,
1045     Simple_Titlecase_Mapping => $CODE_POINT,
1046     Simple_Uppercase_Mapping => $CODE_POINT,
1047     Titlecase_Mapping => $CODE_POINT,
1048     Unicode_1_Name => "",
1049     Unicode_Radical_Stroke => "",
1050     Uppercase_Mapping => $CODE_POINT,
1051     Word_Break => 'Other',
1052 );
1053
1054 # Below are files that Unicode furnishes, but this program ignores, and why
1055 my %ignored_files = (
1056     'CJKRadicals.txt' => 'Unihan data',
1057     'Index.txt' => 'An index, not actual data',
1058     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1059     'NamesList.txt' => 'Just adds commentary',
1060     'NormalizationCorrections.txt' => 'Data is already in other files.',
1061     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1062     'ReadMe.txt' => 'Just comments',
1063     'README.TXT' => 'Just comments',
1064     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1065     'EmojiSources.txt' => 'Not of general utility: for Japanese legacy cell-phone applications',
1066     'IndicMatraCategory.txt' => 'Provisional',
1067     'IndicSyllabicCategory.txt' => 'Provisional',
1068 );
1069
1070 ### End of externally interesting definitions, except for @input_file_objects
1071
1072 my $HEADER=<<"EOF";
1073 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1074 # This file is machine-generated by $0 from the Unicode
1075 # database, Version $string_version.  Any changes made here will be lost!
1076 EOF
1077
1078 my $INTERNAL_ONLY=<<"EOF";
1079
1080 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1081 # This file is for internal use by core Perl only.  The format and even the
1082 # name or existence of this file are subject to change without notice.  Don't
1083 # use it directly.
1084 EOF
1085
1086 my $DEVELOPMENT_ONLY=<<"EOF";
1087 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1088 # This file contains information artificially constrained to code points
1089 # present in Unicode release $string_compare_versions.
1090 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1091 # not be used for production.
1092
1093 EOF
1094
1095 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1096 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1097 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1098
1099 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1100 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1101 # to decrease backtracking.  The first one allows the code point to be at the
1102 # end of a word, but to work properly, the word shouldn't end with a valid hex
1103 # character.  The second one won't match a code point at the end of a word,
1104 # and doesn't have the run-on issue
1105 my $run_on_code_point_re =
1106             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1107 my $code_point_re = qr/\b$run_on_code_point_re/;
1108
1109 # This matches the beginning of the line in the Unicode db files that give the
1110 # defaults for code points not listed (i.e., missing) in the file.  The code
1111 # depends on this ending with a semi-colon, so it can assume it is a valid
1112 # field when the line is split() by semi-colons
1113 my $missing_defaults_prefix =
1114             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1115
1116 # Property types.  Unicode has more types, but these are sufficient for our
1117 # purposes.
1118 my $UNKNOWN = -1;   # initialized to illegal value
1119 my $NON_STRING = 1; # Either binary or enum
1120 my $BINARY = 2;
1121 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1122                        # tables, additional true and false tables are
1123                        # generated so that false is anything matching the
1124                        # default value, and true is everything else.
1125 my $ENUM = 4;       # Include catalog
1126 my $STRING = 5;     # Anything else: string or misc
1127
1128 # Some input files have lines that give default values for code points not
1129 # contained in the file.  Sometimes these should be ignored.
1130 my $NO_DEFAULTS = 0;        # Must evaluate to false
1131 my $NOT_IGNORED = 1;
1132 my $IGNORED = 2;
1133
1134 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1135 # and will appear in the main body of the tables in the output files, but
1136 # there are other types of ranges as well, listed below, that are specially
1137 # handled.   There are pseudo-types as well that will never be stored as a
1138 # type, but will affect the calculation of the type.
1139
1140 # 0 is for normal, non-specials
1141 my $MULTI_CP = 1;           # Sequence of more than code point
1142 my $HANGUL_SYLLABLE = 2;
1143 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1144 my $NULL = 4;               # The map is to the null string; utf8.c can't
1145                             # handle these, nor is there an accepted syntax
1146                             # for them in \p{} constructs
1147 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1148                              # otherwise be $MULTI_CP type are instead type 0
1149
1150 # process_generic_property_file() can accept certain overrides in its input.
1151 # Each of these must begin AND end with $CMD_DELIM.
1152 my $CMD_DELIM = "\a";
1153 my $REPLACE_CMD = 'replace';    # Override the Replace
1154 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1155
1156 my $NO = 0;
1157 my $YES = 1;
1158
1159 # Values for the Replace argument to add_range.
1160 # $NO                      # Don't replace; add only the code points not
1161                            # already present.
1162 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1163                            # the comments at the subroutine definition.
1164 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1165 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1166                            # already there
1167 my $CROAK = 5;             # Die with an error if is already there
1168
1169 # Flags to give property statuses.  The phrases are to remind maintainers that
1170 # if the flag is changed, the indefinite article referring to it in the
1171 # documentation may need to be as well.
1172 my $NORMAL = "";
1173 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1174                         # it is suppressed
1175 my $PLACEHOLDER = 'P';  # A property that is defined as a placeholder in a
1176                         # Unicode version that doesn't have it, but we need it
1177                         # to be defined, if empty, to have things work.
1178                         # Implies no pod entry generated
1179 my $DEPRECATED = 'D';
1180 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1181 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1182 my $DISCOURAGED = 'X';
1183 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1184 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1185 my $STRICTER = 'T';
1186 my $a_bold_stricter = "a 'B<$STRICTER>'";
1187 my $A_bold_stricter = "A 'B<$STRICTER>'";
1188 my $STABILIZED = 'S';
1189 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1190 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1191 my $OBSOLETE = 'O';
1192 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1193 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1194
1195 my %status_past_participles = (
1196     $DISCOURAGED => 'discouraged',
1197     $SUPPRESSED => 'should never be generated',
1198     $STABILIZED => 'stabilized',
1199     $OBSOLETE => 'obsolete',
1200     $DEPRECATED => 'deprecated',
1201 );
1202
1203 # The format of the values of the tables:
1204 my $EMPTY_FORMAT = "";
1205 my $BINARY_FORMAT = 'b';
1206 my $DECIMAL_FORMAT = 'd';
1207 my $FLOAT_FORMAT = 'f';
1208 my $INTEGER_FORMAT = 'i';
1209 my $HEX_FORMAT = 'x';
1210 my $RATIONAL_FORMAT = 'r';
1211 my $STRING_FORMAT = 's';
1212 my $DECOMP_STRING_FORMAT = 'c';
1213 my $STRING_WHITE_SPACE_LIST = 'sw';
1214
1215 my %map_table_formats = (
1216     $BINARY_FORMAT => 'binary',
1217     $DECIMAL_FORMAT => 'single decimal digit',
1218     $FLOAT_FORMAT => 'floating point number',
1219     $INTEGER_FORMAT => 'integer',
1220     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1221     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1222     $STRING_FORMAT => 'string',
1223     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1224     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1225 );
1226
1227 # Unicode didn't put such derived files in a separate directory at first.
1228 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1229 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1230 my $AUXILIARY = 'auxiliary';
1231
1232 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1233 my %loose_to_file_of;       # loosely maps table names to their respective
1234                             # files
1235 my %stricter_to_file_of;    # same; but for stricter mapping.
1236 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1237                              # their rational equivalent
1238 my %loose_property_name_of; # Loosely maps (non_string) property names to
1239                             # standard form
1240
1241 # Most properties are immune to caseless matching, otherwise you would get
1242 # nonsensical results, as properties are a function of a code point, not
1243 # everything that is caselessly equivalent to that code point.  For example,
1244 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1245 # be true because 's' and 'S' are equivalent caselessly.  However,
1246 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1247 # extend that concept to those very few properties that are like this.  Each
1248 # such property will match the full range caselessly.  They are hard-coded in
1249 # the program; it's not worth trying to make it general as it's extremely
1250 # unlikely that they will ever change.
1251 my %caseless_equivalent_to;
1252
1253 # These constants names and values were taken from the Unicode standard,
1254 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1255 # syllables.  The '_string' versions are so generated tables can retain the
1256 # hex format, which is the more familiar value
1257 my $SBase_string = "0xAC00";
1258 my $SBase = CORE::hex $SBase_string;
1259 my $LBase_string = "0x1100";
1260 my $LBase = CORE::hex $LBase_string;
1261 my $VBase_string = "0x1161";
1262 my $VBase = CORE::hex $VBase_string;
1263 my $TBase_string = "0x11A7";
1264 my $TBase = CORE::hex $TBase_string;
1265 my $SCount = 11172;
1266 my $LCount = 19;
1267 my $VCount = 21;
1268 my $TCount = 28;
1269 my $NCount = $VCount * $TCount;
1270
1271 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1272 # with the above published constants.
1273 my %Jamo;
1274 my %Jamo_L;     # Leading consonants
1275 my %Jamo_V;     # Vowels
1276 my %Jamo_T;     # Trailing consonants
1277
1278 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1279 # The key is the base name of the code point, and the value is an
1280 # array giving all the ranges that use this base name.  Each range
1281 # is actually a hash giving the 'low' and 'high' values of it.
1282 my %names_ending_in_code_point;
1283 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1284                                         # removed from the names
1285 # Inverse mapping.  The list of ranges that have these kinds of
1286 # names.  Each element contains the low, high, and base names in an
1287 # anonymous hash.
1288 my @code_points_ending_in_code_point;
1289
1290 # Boolean: does this Unicode version have the hangul syllables, and are we
1291 # writing out a table for them?
1292 my $has_hangul_syllables = 0;
1293
1294 # Does this Unicode version have code points whose names end in their
1295 # respective code points, and are we writing out a table for them?  0 for no;
1296 # otherwise points to first property that a table is needed for them, so that
1297 # if multiple tables are needed, we don't create duplicates
1298 my $needing_code_points_ending_in_code_point = 0;
1299
1300 my @backslash_X_tests;     # List of tests read in for testing \X
1301 my @unhandled_properties;  # Will contain a list of properties found in
1302                            # the input that we didn't process.
1303 my @match_properties;      # Properties that have match tables, to be
1304                            # listed in the pod
1305 my @map_properties;        # Properties that get map files written
1306 my @named_sequences;       # NamedSequences.txt contents.
1307 my %potential_files;       # Generated list of all .txt files in the directory
1308                            # structure so we can warn if something is being
1309                            # ignored.
1310 my @files_actually_output; # List of files we generated.
1311 my @more_Names;            # Some code point names are compound; this is used
1312                            # to store the extra components of them.
1313 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1314                            # the minimum before we consider it equivalent to a
1315                            # candidate rational
1316 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1317
1318 # These store references to certain commonly used property objects
1319 my $gc;
1320 my $perl;
1321 my $block;
1322 my $perl_charname;
1323 my $print;
1324 my $Any;
1325 my $script;
1326
1327 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1328 my $has_In_conflicts = 0;
1329 my $has_Is_conflicts = 0;
1330
1331 sub internal_file_to_platform ($) {
1332     # Convert our file paths which have '/' separators to those of the
1333     # platform.
1334
1335     my $file = shift;
1336     return undef unless defined $file;
1337
1338     return File::Spec->join(split '/', $file);
1339 }
1340
1341 sub file_exists ($) {   # platform independent '-e'.  This program internally
1342                         # uses slash as a path separator.
1343     my $file = shift;
1344     return 0 if ! defined $file;
1345     return -e internal_file_to_platform($file);
1346 }
1347
1348 sub objaddr($) {
1349     # Returns the address of the blessed input object.
1350     # It doesn't check for blessedness because that would do a string eval
1351     # every call, and the program is structured so that this is never called
1352     # for a non-blessed object.
1353
1354     no overloading; # If overloaded, numifying below won't work.
1355
1356     # Numifying a ref gives its address.
1357     return pack 'J', $_[0];
1358 }
1359
1360 # These are used only if $annotate is true.
1361 # The entire range of Unicode characters is examined to populate these
1362 # after all the input has been processed.  But most can be skipped, as they
1363 # have the same descriptive phrases, such as being unassigned
1364 my @viacode;            # Contains the 1 million character names
1365 my @printable;          # boolean: And are those characters printable?
1366 my @annotate_char_type; # Contains a type of those characters, specifically
1367                         # for the purposes of annotation.
1368 my $annotate_ranges;    # A map of ranges of code points that have the same
1369                         # name for the purposes of annotation.  They map to the
1370                         # upper edge of the range, so that the end point can
1371                         # be immediately found.  This is used to skip ahead to
1372                         # the end of a range, and avoid processing each
1373                         # individual code point in it.
1374 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1375                                    # characters, but excluding those which are
1376                                    # also noncharacter code points
1377
1378 # The annotation types are an extension of the regular range types, though
1379 # some of the latter are folded into one.  Make the new types negative to
1380 # avoid conflicting with the regular types
1381 my $SURROGATE_TYPE = -1;
1382 my $UNASSIGNED_TYPE = -2;
1383 my $PRIVATE_USE_TYPE = -3;
1384 my $NONCHARACTER_TYPE = -4;
1385 my $CONTROL_TYPE = -5;
1386 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1387
1388 sub populate_char_info ($) {
1389     # Used only with the $annotate option.  Populates the arrays with the
1390     # input code point's info that are needed for outputting more detailed
1391     # comments.  If calling context wants a return, it is the end point of
1392     # any contiguous range of characters that share essentially the same info
1393
1394     my $i = shift;
1395     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1396
1397     $viacode[$i] = $perl_charname->value_of($i) || "";
1398
1399     # A character is generally printable if Unicode says it is,
1400     # but below we make sure that most Unicode general category 'C' types
1401     # aren't.
1402     $printable[$i] = $print->contains($i);
1403
1404     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1405
1406     # Only these two regular types are treated specially for annotations
1407     # purposes
1408     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1409                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1410
1411     # Give a generic name to all code points that don't have a real name.
1412     # We output ranges, if applicable, for these.  Also calculate the end
1413     # point of the range.
1414     my $end;
1415     if (! $viacode[$i]) {
1416         if ($gc-> table('Surrogate')->contains($i)) {
1417             $viacode[$i] = 'Surrogate';
1418             $annotate_char_type[$i] = $SURROGATE_TYPE;
1419             $printable[$i] = 0;
1420             $end = $gc->table('Surrogate')->containing_range($i)->end;
1421         }
1422         elsif ($gc-> table('Private_use')->contains($i)) {
1423             $viacode[$i] = 'Private Use';
1424             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1425             $printable[$i] = 0;
1426             $end = $gc->table('Private_Use')->containing_range($i)->end;
1427         }
1428         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1429                                                                 contains($i))
1430         {
1431             $viacode[$i] = 'Noncharacter';
1432             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1433             $printable[$i] = 0;
1434             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1435                                                     containing_range($i)->end;
1436         }
1437         elsif ($gc-> table('Control')->contains($i)) {
1438             $viacode[$i] = 'Control';
1439             $annotate_char_type[$i] = $CONTROL_TYPE;
1440             $printable[$i] = 0;
1441             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1442         }
1443         elsif ($gc-> table('Unassigned')->contains($i)) {
1444             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1445             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1446             $printable[$i] = 0;
1447
1448             # Because we name the unassigned by the blocks they are in, it
1449             # can't go past the end of that block, and it also can't go past
1450             # the unassigned range it is in.  The special table makes sure
1451             # that the non-characters, which are unassigned, are separated
1452             # out.
1453             $end = min($block->containing_range($i)->end,
1454                        $unassigned_sans_noncharacters-> containing_range($i)->
1455                                                                          end);
1456         }
1457         else {
1458             Carp::my_carp_bug("Can't figure out how to annotate "
1459                               . sprintf("U+%04X", $i)
1460                               . ".  Proceeding anyway.");
1461             $viacode[$i] = 'UNKNOWN';
1462             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1463             $printable[$i] = 0;
1464         }
1465     }
1466
1467     # Here, has a name, but if it's one in which the code point number is
1468     # appended to the name, do that.
1469     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1470         $viacode[$i] .= sprintf("-%04X", $i);
1471         $end = $perl_charname->containing_range($i)->end;
1472     }
1473
1474     # And here, has a name, but if it's a hangul syllable one, replace it with
1475     # the correct name from the Unicode algorithm
1476     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1477         use integer;
1478         my $SIndex = $i - $SBase;
1479         my $L = $LBase + $SIndex / $NCount;
1480         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1481         my $T = $TBase + $SIndex % $TCount;
1482         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1483         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1484         $end = $perl_charname->containing_range($i)->end;
1485     }
1486
1487     return if ! defined wantarray;
1488     return $i if ! defined $end;    # If not a range, return the input
1489
1490     # Save this whole range so can find the end point quickly
1491     $annotate_ranges->add_map($i, $end, $end);
1492
1493     return $end;
1494 }
1495
1496 # Commented code below should work on Perl 5.8.
1497 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1498 ## the native perl version of it (which is what would operate under miniperl)
1499 ## is extremely slow, as it does a string eval every call.
1500 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1501 #                            && defined eval "require Scalar::Util";
1502 #
1503 #sub objaddr($) {
1504 #    # Returns the address of the blessed input object.  Uses the XS version if
1505 #    # available.  It doesn't check for blessedness because that would do a
1506 #    # string eval every call, and the program is structured so that this is
1507 #    # never called for a non-blessed object.
1508 #
1509 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1510 #
1511 #    # Check at least that is a ref.
1512 #    my $pkg = ref($_[0]) or return undef;
1513 #
1514 #    # Change to a fake package to defeat any overloaded stringify
1515 #    bless $_[0], 'main::Fake';
1516 #
1517 #    # Numifying a ref gives its address.
1518 #    my $addr = pack 'J', $_[0];
1519 #
1520 #    # Return to original class
1521 #    bless $_[0], $pkg;
1522 #    return $addr;
1523 #}
1524
1525 sub max ($$) {
1526     my $a = shift;
1527     my $b = shift;
1528     return $a if $a >= $b;
1529     return $b;
1530 }
1531
1532 sub min ($$) {
1533     my $a = shift;
1534     my $b = shift;
1535     return $a if $a <= $b;
1536     return $b;
1537 }
1538
1539 sub clarify_number ($) {
1540     # This returns the input number with underscores inserted every 3 digits
1541     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1542     # checked.
1543
1544     my $number = shift;
1545     my $pos = length($number) - 3;
1546     return $number if $pos <= 1;
1547     while ($pos > 0) {
1548         substr($number, $pos, 0) = '_';
1549         $pos -= 3;
1550     }
1551     return $number;
1552 }
1553
1554
1555 package Carp;
1556
1557 # These routines give a uniform treatment of messages in this program.  They
1558 # are placed in the Carp package to cause the stack trace to not include them,
1559 # although an alternative would be to use another package and set @CARP_NOT
1560 # for it.
1561
1562 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1563
1564 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1565 # and overload trying to load Scalar:Util under miniperl.  See
1566 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1567 undef $overload::VERSION;
1568
1569 sub my_carp {
1570     my $message = shift || "";
1571     my $nofold = shift || 0;
1572
1573     if ($message) {
1574         $message = main::join_lines($message);
1575         $message =~ s/^$0: *//;     # Remove initial program name
1576         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1577         $message = "\n$0: $message;";
1578
1579         # Fold the message with program name, semi-colon end punctuation
1580         # (which looks good with the message that carp appends to it), and a
1581         # hanging indent for continuation lines.
1582         $message = main::simple_fold($message, "", 4) unless $nofold;
1583         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1584                                     # appends is to the same line
1585     }
1586
1587     return $message if defined wantarray;   # If a caller just wants the msg
1588
1589     carp $message;
1590     return;
1591 }
1592
1593 sub my_carp_bug {
1594     # This is called when it is clear that the problem is caused by a bug in
1595     # this program.
1596
1597     my $message = shift;
1598     $message =~ s/^$0: *//;
1599     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1600     carp $message;
1601     return;
1602 }
1603
1604 sub carp_too_few_args {
1605     if (@_ != 2) {
1606         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1607         return;
1608     }
1609
1610     my $args_ref = shift;
1611     my $count = shift;
1612
1613     my_carp_bug("Need at least $count arguments to "
1614         . (caller 1)[3]
1615         . ".  Instead got: '"
1616         . join ', ', @$args_ref
1617         . "'.  No action taken.");
1618     return;
1619 }
1620
1621 sub carp_extra_args {
1622     my $args_ref = shift;
1623     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1624
1625     unless (ref $args_ref) {
1626         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1627         return;
1628     }
1629     my ($package, $file, $line) = caller;
1630     my $subroutine = (caller 1)[3];
1631
1632     my $list;
1633     if (ref $args_ref eq 'HASH') {
1634         foreach my $key (keys %$args_ref) {
1635             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1636         }
1637         $list = join ', ', each %{$args_ref};
1638     }
1639     elsif (ref $args_ref eq 'ARRAY') {
1640         foreach my $arg (@$args_ref) {
1641             $arg = $UNDEF unless defined $arg;
1642         }
1643         $list = join ', ', @$args_ref;
1644     }
1645     else {
1646         my_carp_bug("Can't cope with ref "
1647                 . ref($args_ref)
1648                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1649         return;
1650     }
1651
1652     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1653     return;
1654 }
1655
1656 package main;
1657
1658 { # Closure
1659
1660     # This program uses the inside-out method for objects, as recommended in
1661     # "Perl Best Practices".  This closure aids in generating those.  There
1662     # are two routines.  setup_package() is called once per package to set
1663     # things up, and then set_access() is called for each hash representing a
1664     # field in the object.  These routines arrange for the object to be
1665     # properly destroyed when no longer used, and for standard accessor
1666     # functions to be generated.  If you need more complex accessors, just
1667     # write your own and leave those accesses out of the call to set_access().
1668     # More details below.
1669
1670     my %constructor_fields; # fields that are to be used in constructors; see
1671                             # below
1672
1673     # The values of this hash will be the package names as keys to other
1674     # hashes containing the name of each field in the package as keys, and
1675     # references to their respective hashes as values.
1676     my %package_fields;
1677
1678     sub setup_package {
1679         # Sets up the package, creating standard DESTROY and dump methods
1680         # (unless already defined).  The dump method is used in debugging by
1681         # simple_dumper().
1682         # The optional parameters are:
1683         #   a)  a reference to a hash, that gets populated by later
1684         #       set_access() calls with one of the accesses being
1685         #       'constructor'.  The caller can then refer to this, but it is
1686         #       not otherwise used by these two routines.
1687         #   b)  a reference to a callback routine to call during destruction
1688         #       of the object, before any fields are actually destroyed
1689
1690         my %args = @_;
1691         my $constructor_ref = delete $args{'Constructor_Fields'};
1692         my $destroy_callback = delete $args{'Destroy_Callback'};
1693         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1694
1695         my %fields;
1696         my $package = (caller)[0];
1697
1698         $package_fields{$package} = \%fields;
1699         $constructor_fields{$package} = $constructor_ref;
1700
1701         unless ($package->can('DESTROY')) {
1702             my $destroy_name = "${package}::DESTROY";
1703             no strict "refs";
1704
1705             # Use typeglob to give the anonymous subroutine the name we want
1706             *$destroy_name = sub {
1707                 my $self = shift;
1708                 my $addr = do { no overloading; pack 'J', $self; };
1709
1710                 $self->$destroy_callback if $destroy_callback;
1711                 foreach my $field (keys %{$package_fields{$package}}) {
1712                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1713                     delete $package_fields{$package}{$field}{$addr};
1714                 }
1715                 return;
1716             }
1717         }
1718
1719         unless ($package->can('dump')) {
1720             my $dump_name = "${package}::dump";
1721             no strict "refs";
1722             *$dump_name = sub {
1723                 my $self = shift;
1724                 return dump_inside_out($self, $package_fields{$package}, @_);
1725             }
1726         }
1727         return;
1728     }
1729
1730     sub set_access {
1731         # Arrange for the input field to be garbage collected when no longer
1732         # needed.  Also, creates standard accessor functions for the field
1733         # based on the optional parameters-- none if none of these parameters:
1734         #   'addable'    creates an 'add_NAME()' accessor function.
1735         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1736         #                function.
1737         #   'settable'   creates a 'set_NAME()' accessor function.
1738         #   'constructor' doesn't create an accessor function, but adds the
1739         #                field to the hash that was previously passed to
1740         #                setup_package();
1741         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1742         # 'add' etc. all mean 'addable'.
1743         # The read accessor function will work on both array and scalar
1744         # values.  If another accessor in the parameter list is 'a', the read
1745         # access assumes an array.  You can also force it to be array access
1746         # by specifying 'readable_array' instead of 'readable'
1747         #
1748         # A sort-of 'protected' access can be set-up by preceding the addable,
1749         # readable or settable with some initial portion of 'protected_' (but,
1750         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1751         # "protection" is only by convention.  All that happens is that the
1752         # accessor functions' names begin with an underscore.  So instead of
1753         # calling set_foo, the call is _set_foo.  (Real protection could be
1754         # accomplished by having a new subroutine, end_package, called at the
1755         # end of each package, and then storing the __LINE__ ranges and
1756         # checking them on every accessor.  But that is way overkill.)
1757
1758         # We create anonymous subroutines as the accessors and then use
1759         # typeglobs to assign them to the proper package and name
1760
1761         my $name = shift;   # Name of the field
1762         my $field = shift;  # Reference to the inside-out hash containing the
1763                             # field
1764
1765         my $package = (caller)[0];
1766
1767         if (! exists $package_fields{$package}) {
1768             croak "$0: Must call 'setup_package' before 'set_access'";
1769         }
1770
1771         # Stash the field so DESTROY can get it.
1772         $package_fields{$package}{$name} = $field;
1773
1774         # Remaining arguments are the accessors.  For each...
1775         foreach my $access (@_) {
1776             my $access = lc $access;
1777
1778             my $protected = "";
1779
1780             # Match the input as far as it goes.
1781             if ($access =~ /^(p[^_]*)_/) {
1782                 $protected = $1;
1783                 if (substr('protected_', 0, length $protected)
1784                     eq $protected)
1785                 {
1786
1787                     # Add 1 for the underscore not included in $protected
1788                     $access = substr($access, length($protected) + 1);
1789                     $protected = '_';
1790                 }
1791                 else {
1792                     $protected = "";
1793                 }
1794             }
1795
1796             if (substr('addable', 0, length $access) eq $access) {
1797                 my $subname = "${package}::${protected}add_$name";
1798                 no strict "refs";
1799
1800                 # add_ accessor.  Don't add if already there, which we
1801                 # determine using 'eq' for scalars and '==' otherwise.
1802                 *$subname = sub {
1803                     use strict "refs";
1804                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1805                     my $self = shift;
1806                     my $value = shift;
1807                     my $addr = do { no overloading; pack 'J', $self; };
1808                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1809                     if (ref $value) {
1810                         return if grep { $value == $_ } @{$field->{$addr}};
1811                     }
1812                     else {
1813                         return if grep { $value eq $_ } @{$field->{$addr}};
1814                     }
1815                     push @{$field->{$addr}}, $value;
1816                     return;
1817                 }
1818             }
1819             elsif (substr('constructor', 0, length $access) eq $access) {
1820                 if ($protected) {
1821                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1822                 }
1823                 else {
1824                     $constructor_fields{$package}{$name} = $field;
1825                 }
1826             }
1827             elsif (substr('readable_array', 0, length $access) eq $access) {
1828
1829                 # Here has read access.  If one of the other parameters for
1830                 # access is array, or this one specifies array (by being more
1831                 # than just 'readable_'), then create a subroutine that
1832                 # assumes the data is an array.  Otherwise just a scalar
1833                 my $subname = "${package}::${protected}$name";
1834                 if (grep { /^a/i } @_
1835                     or length($access) > length('readable_'))
1836                 {
1837                     no strict "refs";
1838                     *$subname = sub {
1839                         use strict "refs";
1840                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1841                         my $addr = do { no overloading; pack 'J', $_[0]; };
1842                         if (ref $field->{$addr} ne 'ARRAY') {
1843                             my $type = ref $field->{$addr};
1844                             $type = 'scalar' unless $type;
1845                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1846                             return;
1847                         }
1848                         return scalar @{$field->{$addr}} unless wantarray;
1849
1850                         # Make a copy; had problems with caller modifying the
1851                         # original otherwise
1852                         my @return = @{$field->{$addr}};
1853                         return @return;
1854                     }
1855                 }
1856                 else {
1857
1858                     # Here not an array value, a simpler function.
1859                     no strict "refs";
1860                     *$subname = sub {
1861                         use strict "refs";
1862                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1863                         no overloading;
1864                         return $field->{pack 'J', $_[0]};
1865                     }
1866                 }
1867             }
1868             elsif (substr('settable', 0, length $access) eq $access) {
1869                 my $subname = "${package}::${protected}set_$name";
1870                 no strict "refs";
1871                 *$subname = sub {
1872                     use strict "refs";
1873                     if (main::DEBUG) {
1874                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1875                         Carp::carp_extra_args(\@_) if @_ > 2;
1876                     }
1877                     # $self is $_[0]; $value is $_[1]
1878                     no overloading;
1879                     $field->{pack 'J', $_[0]} = $_[1];
1880                     return;
1881                 }
1882             }
1883             else {
1884                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1885             }
1886         }
1887         return;
1888     }
1889 }
1890
1891 package Input_file;
1892
1893 # All input files use this object, which stores various attributes about them,
1894 # and provides for convenient, uniform handling.  The run method wraps the
1895 # processing.  It handles all the bookkeeping of opening, reading, and closing
1896 # the file, returning only significant input lines.
1897 #
1898 # Each object gets a handler which processes the body of the file, and is
1899 # called by run().  Most should use the generic, default handler, which has
1900 # code scrubbed to handle things you might not expect.  A handler should
1901 # basically be a while(next_line()) {...} loop.
1902 #
1903 # You can also set up handlers to
1904 #   1) call before the first line is read for pre processing
1905 #   2) call to adjust each line of the input before the main handler gets them
1906 #   3) call upon EOF before the main handler exits its loop
1907 #   4) call at the end for post processing
1908 #
1909 # $_ is used to store the input line, and is to be filtered by the
1910 # each_line_handler()s.  So, if the format of the line is not in the desired
1911 # format for the main handler, these are used to do that adjusting.  They can
1912 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1913 # so the $_ output of one is used as the input to the next.  None of the other
1914 # handlers are stackable, but could easily be changed to be so.
1915 #
1916 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1917 # which insert the parameters as lines to be processed before the next input
1918 # file line is read.  This allows the EOF handler to flush buffers, for
1919 # example.  The difference between the two routines is that the lines inserted
1920 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1921 # called it from such a handler, you would get infinite recursion.)  Lines
1922 # inserted by insert_adjusted_lines() go directly to the main handler without
1923 # any adjustments.  If the  post-processing handler calls any of these, there
1924 # will be no effect.  Some error checking for these conditions could be added,
1925 # but it hasn't been done.
1926 #
1927 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1928 # to prevent further processing of the line.  This routine will output the
1929 # message as a warning once, and then keep a count of the lines that have the
1930 # same message, and output that count at the end of the file's processing.
1931 # This keeps the number of messages down to a manageable amount.
1932 #
1933 # get_missings() should be called to retrieve any @missing input lines.
1934 # Messages will be raised if this isn't done if the options aren't to ignore
1935 # missings.
1936
1937 sub trace { return main::trace(@_); }
1938
1939 { # Closure
1940     # Keep track of fields that are to be put into the constructor.
1941     my %constructor_fields;
1942
1943     main::setup_package(Constructor_Fields => \%constructor_fields);
1944
1945     my %file; # Input file name, required
1946     main::set_access('file', \%file, qw{ c r });
1947
1948     my %first_released; # Unicode version file was first released in, required
1949     main::set_access('first_released', \%first_released, qw{ c r });
1950
1951     my %handler;    # Subroutine to process the input file, defaults to
1952                     # 'process_generic_property_file'
1953     main::set_access('handler', \%handler, qw{ c });
1954
1955     my %property;
1956     # name of property this file is for.  defaults to none, meaning not
1957     # applicable, or is otherwise determinable, for example, from each line.
1958     main::set_access('property', \%property, qw{ c });
1959
1960     my %optional;
1961     # If this is true, the file is optional.  If not present, no warning is
1962     # output.  If it is present, the string given by this parameter is
1963     # evaluated, and if false the file is not processed.
1964     main::set_access('optional', \%optional, 'c', 'r');
1965
1966     my %non_skip;
1967     # This is used for debugging, to skip processing of all but a few input
1968     # files.  Add 'non_skip => 1' to the constructor for those files you want
1969     # processed when you set the $debug_skip global.
1970     main::set_access('non_skip', \%non_skip, 'c');
1971
1972     my %skip;
1973     # This is used to skip processing of this input file semi-permanently.
1974     # It is used for files that we aren't planning to process anytime soon,
1975     # but want to allow to be in the directory and not raise a message that we
1976     # are not handling.  Mostly for test files.  This is in contrast to the
1977     # non_skip element, which is supposed to be used very temporarily for
1978     # debugging.  Sets 'optional' to 1
1979     main::set_access('skip', \%skip, 'c');
1980
1981     my %each_line_handler;
1982     # list of subroutines to look at and filter each non-comment line in the
1983     # file.  defaults to none.  The subroutines are called in order, each is
1984     # to adjust $_ for the next one, and the final one adjusts it for
1985     # 'handler'
1986     main::set_access('each_line_handler', \%each_line_handler, 'c');
1987
1988     my %has_missings_defaults;
1989     # ? Are there lines in the file giving default values for code points
1990     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1991     # the norm, but IGNORED means it has such lines, but the handler doesn't
1992     # use them.  Having these three states allows us to catch changes to the
1993     # UCD that this program should track
1994     main::set_access('has_missings_defaults',
1995                                         \%has_missings_defaults, qw{ c r });
1996
1997     my %pre_handler;
1998     # Subroutine to call before doing anything else in the file.  If undef, no
1999     # such handler is called.
2000     main::set_access('pre_handler', \%pre_handler, qw{ c });
2001
2002     my %eof_handler;
2003     # Subroutine to call upon getting an EOF on the input file, but before
2004     # that is returned to the main handler.  This is to allow buffers to be
2005     # flushed.  The handler is expected to call insert_lines() or
2006     # insert_adjusted() with the buffered material
2007     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2008
2009     my %post_handler;
2010     # Subroutine to call after all the lines of the file are read in and
2011     # processed.  If undef, no such handler is called.
2012     main::set_access('post_handler', \%post_handler, qw{ c });
2013
2014     my %progress_message;
2015     # Message to print to display progress in lieu of the standard one
2016     main::set_access('progress_message', \%progress_message, qw{ c });
2017
2018     my %handle;
2019     # cache open file handle, internal.  Is undef if file hasn't been
2020     # processed at all, empty if has;
2021     main::set_access('handle', \%handle);
2022
2023     my %added_lines;
2024     # cache of lines added virtually to the file, internal
2025     main::set_access('added_lines', \%added_lines);
2026
2027     my %errors;
2028     # cache of errors found, internal
2029     main::set_access('errors', \%errors);
2030
2031     my %missings;
2032     # storage of '@missing' defaults lines
2033     main::set_access('missings', \%missings);
2034
2035     sub new {
2036         my $class = shift;
2037
2038         my $self = bless \do{ my $anonymous_scalar }, $class;
2039         my $addr = do { no overloading; pack 'J', $self; };
2040
2041         # Set defaults
2042         $handler{$addr} = \&main::process_generic_property_file;
2043         $non_skip{$addr} = 0;
2044         $skip{$addr} = 0;
2045         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2046         $handle{$addr} = undef;
2047         $added_lines{$addr} = [ ];
2048         $each_line_handler{$addr} = [ ];
2049         $errors{$addr} = { };
2050         $missings{$addr} = [ ];
2051
2052         # Two positional parameters.
2053         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2054         $file{$addr} = main::internal_file_to_platform(shift);
2055         $first_released{$addr} = shift;
2056
2057         # The rest of the arguments are key => value pairs
2058         # %constructor_fields has been set up earlier to list all possible
2059         # ones.  Either set or push, depending on how the default has been set
2060         # up just above.
2061         my %args = @_;
2062         foreach my $key (keys %args) {
2063             my $argument = $args{$key};
2064
2065             # Note that the fields are the lower case of the constructor keys
2066             my $hash = $constructor_fields{lc $key};
2067             if (! defined $hash) {
2068                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2069                 next;
2070             }
2071             if (ref $hash->{$addr} eq 'ARRAY') {
2072                 if (ref $argument eq 'ARRAY') {
2073                     foreach my $argument (@{$argument}) {
2074                         next if ! defined $argument;
2075                         push @{$hash->{$addr}}, $argument;
2076                     }
2077                 }
2078                 else {
2079                     push @{$hash->{$addr}}, $argument if defined $argument;
2080                 }
2081             }
2082             else {
2083                 $hash->{$addr} = $argument;
2084             }
2085             delete $args{$key};
2086         };
2087
2088         # If the file has a property for it, it means that the property is not
2089         # listed in the file's entries.  So add a handler to the list of line
2090         # handlers to insert the property name into the lines, to provide a
2091         # uniform interface to the final processing subroutine.
2092         # the final code doesn't have to worry about that.
2093         if ($property{$addr}) {
2094             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2095         }
2096
2097         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2098             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2099         }
2100
2101         $optional{$addr} = 1 if $skip{$addr};
2102
2103         return $self;
2104     }
2105
2106
2107     use overload
2108         fallback => 0,
2109         qw("") => "_operator_stringify",
2110         "." => \&main::_operator_dot,
2111     ;
2112
2113     sub _operator_stringify {
2114         my $self = shift;
2115
2116         return __PACKAGE__ . " object for " . $self->file;
2117     }
2118
2119     # flag to make sure extracted files are processed early
2120     my $seen_non_extracted_non_age = 0;
2121
2122     sub run {
2123         # Process the input object $self.  This opens and closes the file and
2124         # calls all the handlers for it.  Currently,  this can only be called
2125         # once per file, as it destroy's the EOF handler
2126
2127         my $self = shift;
2128         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2129
2130         my $addr = do { no overloading; pack 'J', $self; };
2131
2132         my $file = $file{$addr};
2133
2134         # Don't process if not expecting this file (because released later
2135         # than this Unicode version), and isn't there.  This means if someone
2136         # copies it into an earlier version's directory, we will go ahead and
2137         # process it.
2138         return if $first_released{$addr} gt $v_version && ! -e $file;
2139
2140         # If in debugging mode and this file doesn't have the non-skip
2141         # flag set, and isn't one of the critical files, skip it.
2142         if ($debug_skip
2143             && $first_released{$addr} ne v0
2144             && ! $non_skip{$addr})
2145         {
2146             print "Skipping $file in debugging\n" if $verbosity;
2147             return;
2148         }
2149
2150         # File could be optional
2151         if ($optional{$addr}) {
2152             return unless -e $file;
2153             my $result = eval $optional{$addr};
2154             if (! defined $result) {
2155                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2156                 return;
2157             }
2158             if (! $result) {
2159                 if ($verbosity) {
2160                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2161                 }
2162                 return;
2163             }
2164         }
2165
2166         if (! defined $file || ! -e $file) {
2167
2168             # If the file doesn't exist, see if have internal data for it
2169             # (based on first_released being 0).
2170             if ($first_released{$addr} eq v0) {
2171                 $handle{$addr} = 'pretend_is_open';
2172             }
2173             else {
2174                 if (! $optional{$addr}  # File could be optional
2175                     && $v_version ge $first_released{$addr})
2176                 {
2177                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2178                 }
2179                 return;
2180             }
2181         }
2182         else {
2183
2184             # Here, the file exists.  Some platforms may change the case of
2185             # its name
2186             if ($seen_non_extracted_non_age) {
2187                 if ($file =~ /$EXTRACTED/i) {
2188                     Carp::my_carp_bug(join_lines(<<END
2189 $file should be processed just after the 'Prop...Alias' files, and before
2190 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2191 have subtle problems
2192 END
2193                     ));
2194                 }
2195             }
2196             elsif ($EXTRACTED_DIR
2197                     && $first_released{$addr} ne v0
2198                     && $file !~ /$EXTRACTED/i
2199                     && lc($file) ne 'dage.txt')
2200             {
2201                 # We don't set this (by the 'if' above) if we have no
2202                 # extracted directory, so if running on an early version,
2203                 # this test won't work.  Not worth worrying about.
2204                 $seen_non_extracted_non_age = 1;
2205             }
2206
2207             # And mark the file as having being processed, and warn if it
2208             # isn't a file we are expecting.  As we process the files,
2209             # they are deleted from the hash, so any that remain at the
2210             # end of the program are files that we didn't process.
2211             my $fkey = File::Spec->rel2abs($file);
2212             my $expecting = delete $potential_files{$fkey};
2213             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2214             Carp::my_carp("Was not expecting '$file'.") if
2215                     ! $expecting
2216                     && ! defined $handle{$addr};
2217
2218             # Having deleted from expected files, we can quit if not to do
2219             # anything.  Don't print progress unless really want verbosity
2220             if ($skip{$addr}) {
2221                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2222                 return;
2223             }
2224
2225             # Open the file, converting the slashes used in this program
2226             # into the proper form for the OS
2227             my $file_handle;
2228             if (not open $file_handle, "<", $file) {
2229                 Carp::my_carp("Can't open $file.  Skipping: $!");
2230                 return 0;
2231             }
2232             $handle{$addr} = $file_handle; # Cache the open file handle
2233         }
2234
2235         if ($verbosity >= $PROGRESS) {
2236             if ($progress_message{$addr}) {
2237                 print "$progress_message{$addr}\n";
2238             }
2239             else {
2240                 # If using a virtual file, say so.
2241                 print "Processing ", (-e $file)
2242                                        ? $file
2243                                        : "substitute $file",
2244                                      "\n";
2245             }
2246         }
2247
2248
2249         # Call any special handler for before the file.
2250         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2251
2252         # Then the main handler
2253         &{$handler{$addr}}($self);
2254
2255         # Then any special post-file handler.
2256         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2257
2258         # If any errors have been accumulated, output the counts (as the first
2259         # error message in each class was output when it was encountered).
2260         if ($errors{$addr}) {
2261             my $total = 0;
2262             my $types = 0;
2263             foreach my $error (keys %{$errors{$addr}}) {
2264                 $total += $errors{$addr}->{$error};
2265                 delete $errors{$addr}->{$error};
2266                 $types++;
2267             }
2268             if ($total > 1) {
2269                 my $message
2270                         = "A total of $total lines had errors in $file.  ";
2271
2272                 $message .= ($types == 1)
2273                             ? '(Only the first one was displayed.)'
2274                             : '(Only the first of each type was displayed.)';
2275                 Carp::my_carp($message);
2276             }
2277         }
2278
2279         if (@{$missings{$addr}}) {
2280             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2281         }
2282
2283         # If a real file handle, close it.
2284         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2285                                                         ref $handle{$addr};
2286         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2287                                # the file, as opposed to undef
2288         return;
2289     }
2290
2291     sub next_line {
2292         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2293         # if such a line exists.  'logical' means that any lines that have
2294         # been added via insert_lines() will be returned in $_ before the file
2295         # is read again.
2296
2297         my $self = shift;
2298         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2299
2300         my $addr = do { no overloading; pack 'J', $self; };
2301
2302         # Here the file is open (or if the handle is not a ref, is an open
2303         # 'virtual' file).  Get the next line; any inserted lines get priority
2304         # over the file itself.
2305         my $adjusted;
2306
2307         LINE:
2308         while (1) { # Loop until find non-comment, non-empty line
2309             #local $to_trace = 1 if main::DEBUG;
2310             my $inserted_ref = shift @{$added_lines{$addr}};
2311             if (defined $inserted_ref) {
2312                 ($adjusted, $_) = @{$inserted_ref};
2313                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2314                 return 1 if $adjusted;
2315             }
2316             else {
2317                 last if ! ref $handle{$addr}; # Don't read unless is real file
2318                 last if ! defined ($_ = readline $handle{$addr});
2319             }
2320             chomp;
2321             trace $_ if main::DEBUG && $to_trace;
2322
2323             # See if this line is the comment line that defines what property
2324             # value that code points that are not listed in the file should
2325             # have.  The format or existence of these lines is not guaranteed
2326             # by Unicode since they are comments, but the documentation says
2327             # that this was added for machine-readability, so probably won't
2328             # change.  This works starting in Unicode Version 5.0.  They look
2329             # like:
2330             #
2331             # @missing: 0000..10FFFF; Not_Reordered
2332             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2333             # @missing: 0000..10FFFF; ; NaN
2334             #
2335             # Save the line for a later get_missings() call.
2336             if (/$missing_defaults_prefix/) {
2337                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2338                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2339                 }
2340                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2341                     my @defaults = split /\s* ; \s*/x, $_;
2342
2343                     # The first field is the @missing, which ends in a
2344                     # semi-colon, so can safely shift.
2345                     shift @defaults;
2346
2347                     # Some of these lines may have empty field placeholders
2348                     # which get in the way.  An example is:
2349                     # @missing: 0000..10FFFF; ; NaN
2350                     # Remove them.  Process starting from the top so the
2351                     # splice doesn't affect things still to be looked at.
2352                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2353                         next if $defaults[$i] ne "";
2354                         splice @defaults, $i, 1;
2355                     }
2356
2357                     # What's left should be just the property (maybe) and the
2358                     # default.  Having only one element means it doesn't have
2359                     # the property.
2360                     my $default;
2361                     my $property;
2362                     if (@defaults >= 1) {
2363                         if (@defaults == 1) {
2364                             $default = $defaults[0];
2365                         }
2366                         else {
2367                             $property = $defaults[0];
2368                             $default = $defaults[1];
2369                         }
2370                     }
2371
2372                     if (@defaults < 1
2373                         || @defaults > 2
2374                         || ($default =~ /^</
2375                             && $default !~ /^<code *point>$/i
2376                             && $default !~ /^<none>$/i))
2377                     {
2378                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2379                     }
2380                     else {
2381
2382                         # If the property is missing from the line, it should
2383                         # be the one for the whole file
2384                         $property = $property{$addr} if ! defined $property;
2385
2386                         # Change <none> to the null string, which is what it
2387                         # really means.  If the default is the code point
2388                         # itself, set it to <code point>, which is what
2389                         # Unicode uses (but sometimes they've forgotten the
2390                         # space)
2391                         if ($default =~ /^<none>$/i) {
2392                             $default = "";
2393                         }
2394                         elsif ($default =~ /^<code *point>$/i) {
2395                             $default = $CODE_POINT;
2396                         }
2397
2398                         # Store them as a sub-arrays with both components.
2399                         push @{$missings{$addr}}, [ $default, $property ];
2400                     }
2401                 }
2402
2403                 # There is nothing for the caller to process on this comment
2404                 # line.
2405                 next;
2406             }
2407
2408             # Remove comments and trailing space, and skip this line if the
2409             # result is empty
2410             s/#.*//;
2411             s/\s+$//;
2412             next if /^$/;
2413
2414             # Call any handlers for this line, and skip further processing of
2415             # the line if the handler sets the line to null.
2416             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2417                 &{$sub_ref}($self);
2418                 next LINE if /^$/;
2419             }
2420
2421             # Here the line is ok.  return success.
2422             return 1;
2423         } # End of looping through lines.
2424
2425         # If there is an EOF handler, call it (only once) and if it generates
2426         # more lines to process go back in the loop to handle them.
2427         if ($eof_handler{$addr}) {
2428             &{$eof_handler{$addr}}($self);
2429             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2430             goto LINE if $added_lines{$addr};
2431         }
2432
2433         # Return failure -- no more lines.
2434         return 0;
2435
2436     }
2437
2438 #   Not currently used, not fully tested.
2439 #    sub peek {
2440 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2441 #        # record.  Not callable from an each_line_handler(), nor does it call
2442 #        # an each_line_handler() on the line.
2443 #
2444 #        my $self = shift;
2445 #        my $addr = do { no overloading; pack 'J', $self; };
2446 #
2447 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2448 #            my ($adjusted, $line) = @{$inserted_ref};
2449 #            next if $adjusted;
2450 #
2451 #            # Remove comments and trailing space, and return a non-empty
2452 #            # resulting line
2453 #            $line =~ s/#.*//;
2454 #            $line =~ s/\s+$//;
2455 #            return $line if $line ne "";
2456 #        }
2457 #
2458 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2459 #        while (1) { # Loop until find non-comment, non-empty line
2460 #            local $to_trace = 1 if main::DEBUG;
2461 #            trace $_ if main::DEBUG && $to_trace;
2462 #            return if ! defined (my $line = readline $handle{$addr});
2463 #            chomp $line;
2464 #            push @{$added_lines{$addr}}, [ 0, $line ];
2465 #
2466 #            $line =~ s/#.*//;
2467 #            $line =~ s/\s+$//;
2468 #            return $line if $line ne "";
2469 #        }
2470 #
2471 #        return;
2472 #    }
2473
2474
2475     sub insert_lines {
2476         # Lines can be inserted so that it looks like they were in the input
2477         # file at the place it was when this routine is called.  See also
2478         # insert_adjusted_lines().  Lines inserted via this routine go through
2479         # any each_line_handler()
2480
2481         my $self = shift;
2482
2483         # Each inserted line is an array, with the first element being 0 to
2484         # indicate that this line hasn't been adjusted, and needs to be
2485         # processed.
2486         no overloading;
2487         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2488         return;
2489     }
2490
2491     sub insert_adjusted_lines {
2492         # Lines can be inserted so that it looks like they were in the input
2493         # file at the place it was when this routine is called.  See also
2494         # insert_lines().  Lines inserted via this routine are already fully
2495         # adjusted, ready to be processed; each_line_handler()s handlers will
2496         # not be called.  This means this is not a completely general
2497         # facility, as only the last each_line_handler on the stack should
2498         # call this.  It could be made more general, by passing to each of the
2499         # line_handlers their position on the stack, which they would pass on
2500         # to this routine, and that would replace the boolean first element in
2501         # the anonymous array pushed here, so that the next_line routine could
2502         # use that to call only those handlers whose index is after it on the
2503         # stack.  But this is overkill for what is needed now.
2504
2505         my $self = shift;
2506         trace $_[0] if main::DEBUG && $to_trace;
2507
2508         # Each inserted line is an array, with the first element being 1 to
2509         # indicate that this line has been adjusted
2510         no overloading;
2511         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2512         return;
2513     }
2514
2515     sub get_missings {
2516         # Returns the stored up @missings lines' values, and clears the list.
2517         # The values are in an array, consisting of the default in the first
2518         # element, and the property in the 2nd.  However, since these lines
2519         # can be stacked up, the return is an array of all these arrays.
2520
2521         my $self = shift;
2522         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2523
2524         my $addr = do { no overloading; pack 'J', $self; };
2525
2526         # If not accepting a list return, just return the first one.
2527         return shift @{$missings{$addr}} unless wantarray;
2528
2529         my @return = @{$missings{$addr}};
2530         undef @{$missings{$addr}};
2531         return @return;
2532     }
2533
2534     sub _insert_property_into_line {
2535         # Add a property field to $_, if this file requires it.
2536
2537         my $self = shift;
2538         my $addr = do { no overloading; pack 'J', $self; };
2539         my $property = $property{$addr};
2540         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2541
2542         $_ =~ s/(;|$)/; $property$1/;
2543         return;
2544     }
2545
2546     sub carp_bad_line {
2547         # Output consistent error messages, using either a generic one, or the
2548         # one given by the optional parameter.  To avoid gazillions of the
2549         # same message in case the syntax of a  file is way off, this routine
2550         # only outputs the first instance of each message, incrementing a
2551         # count so the totals can be output at the end of the file.
2552
2553         my $self = shift;
2554         my $message = shift;
2555         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2556
2557         my $addr = do { no overloading; pack 'J', $self; };
2558
2559         $message = 'Unexpected line' unless $message;
2560
2561         # No trailing punctuation so as to fit with our addenda.
2562         $message =~ s/[.:;,]$//;
2563
2564         # If haven't seen this exact message before, output it now.  Otherwise
2565         # increment the count of how many times it has occurred
2566         unless ($errors{$addr}->{$message}) {
2567             Carp::my_carp("$message in '$_' in "
2568                             . $file{$addr}
2569                             . " at line $..  Skipping this line;");
2570             $errors{$addr}->{$message} = 1;
2571         }
2572         else {
2573             $errors{$addr}->{$message}++;
2574         }
2575
2576         # Clear the line to prevent any further (meaningful) processing of it.
2577         $_ = "";
2578
2579         return;
2580     }
2581 } # End closure
2582
2583 package Multi_Default;
2584
2585 # Certain properties in early versions of Unicode had more than one possible
2586 # default for code points missing from the files.  In these cases, one
2587 # default applies to everything left over after all the others are applied,
2588 # and for each of the others, there is a description of which class of code
2589 # points applies to it.  This object helps implement this by storing the
2590 # defaults, and for all but that final default, an eval string that generates
2591 # the class that it applies to.
2592
2593
2594 {   # Closure
2595
2596     main::setup_package();
2597
2598     my %class_defaults;
2599     # The defaults structure for the classes
2600     main::set_access('class_defaults', \%class_defaults);
2601
2602     my %other_default;
2603     # The default that applies to everything left over.
2604     main::set_access('other_default', \%other_default, 'r');
2605
2606
2607     sub new {
2608         # The constructor is called with default => eval pairs, terminated by
2609         # the left-over default. e.g.
2610         # Multi_Default->new(
2611         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2612         #               -  0x200D',
2613         #        'R' => 'some other expression that evaluates to code points',
2614         #        .
2615         #        .
2616         #        .
2617         #        'U'));
2618
2619         my $class = shift;
2620
2621         my $self = bless \do{my $anonymous_scalar}, $class;
2622         my $addr = do { no overloading; pack 'J', $self; };
2623
2624         while (@_ > 1) {
2625             my $default = shift;
2626             my $eval = shift;
2627             $class_defaults{$addr}->{$default} = $eval;
2628         }
2629
2630         $other_default{$addr} = shift;
2631
2632         return $self;
2633     }
2634
2635     sub get_next_defaults {
2636         # Iterates and returns the next class of defaults.
2637         my $self = shift;
2638         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2639
2640         my $addr = do { no overloading; pack 'J', $self; };
2641
2642         return each %{$class_defaults{$addr}};
2643     }
2644 }
2645
2646 package Alias;
2647
2648 # An alias is one of the names that a table goes by.  This class defines them
2649 # including some attributes.  Everything is currently setup in the
2650 # constructor.
2651
2652
2653 {   # Closure
2654
2655     main::setup_package();
2656
2657     my %name;
2658     main::set_access('name', \%name, 'r');
2659
2660     my %loose_match;
2661     # Should this name match loosely or not.
2662     main::set_access('loose_match', \%loose_match, 'r');
2663
2664     my %make_pod_entry;
2665     # Some aliases should not get their own entries because they are covered
2666     # by a wild-card, and some we want to discourage use of.  Binary
2667     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2668
2669     my %status;
2670     # Aliases have a status, like deprecated, or even suppressed (which means
2671     # they don't appear in documentation).  Enum
2672     main::set_access('status', \%status, 'r');
2673
2674     my %externally_ok;
2675     # Similarly, some aliases should not be considered as usable ones for
2676     # external use, such as file names, or we don't want documentation to
2677     # recommend them.  Boolean
2678     main::set_access('externally_ok', \%externally_ok, 'r');
2679
2680     sub new {
2681         my $class = shift;
2682
2683         my $self = bless \do { my $anonymous_scalar }, $class;
2684         my $addr = do { no overloading; pack 'J', $self; };
2685
2686         $name{$addr} = shift;
2687         $loose_match{$addr} = shift;
2688         $make_pod_entry{$addr} = shift;
2689         $externally_ok{$addr} = shift;
2690         $status{$addr} = shift;
2691
2692         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2693
2694         # Null names are never ok externally
2695         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2696
2697         return $self;
2698     }
2699 }
2700
2701 package Range;
2702
2703 # A range is the basic unit for storing code points, and is described in the
2704 # comments at the beginning of the program.  Each range has a starting code
2705 # point; an ending code point (not less than the starting one); a value
2706 # that applies to every code point in between the two end-points, inclusive;
2707 # and an enum type that applies to the value.  The type is for the user's
2708 # convenience, and has no meaning here, except that a non-zero type is
2709 # considered to not obey the normal Unicode rules for having standard forms.
2710 #
2711 # The same structure is used for both map and match tables, even though in the
2712 # latter, the value (and hence type) is irrelevant and could be used as a
2713 # comment.  In map tables, the value is what all the code points in the range
2714 # map to.  Type 0 values have the standardized version of the value stored as
2715 # well, so as to not have to recalculate it a lot.
2716
2717 sub trace { return main::trace(@_); }
2718
2719 {   # Closure
2720
2721     main::setup_package();
2722
2723     my %start;
2724     main::set_access('start', \%start, 'r', 's');
2725
2726     my %end;
2727     main::set_access('end', \%end, 'r', 's');
2728
2729     my %value;
2730     main::set_access('value', \%value, 'r');
2731
2732     my %type;
2733     main::set_access('type', \%type, 'r');
2734
2735     my %standard_form;
2736     # The value in internal standard form.  Defined only if the type is 0.
2737     main::set_access('standard_form', \%standard_form);
2738
2739     # Note that if these fields change, the dump() method should as well
2740
2741     sub new {
2742         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2743         my $class = shift;
2744
2745         my $self = bless \do { my $anonymous_scalar }, $class;
2746         my $addr = do { no overloading; pack 'J', $self; };
2747
2748         $start{$addr} = shift;
2749         $end{$addr} = shift;
2750
2751         my %args = @_;
2752
2753         my $value = delete $args{'Value'};  # Can be 0
2754         $value = "" unless defined $value;
2755         $value{$addr} = $value;
2756
2757         $type{$addr} = delete $args{'Type'} || 0;
2758
2759         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2760
2761         if (! $type{$addr}) {
2762             $standard_form{$addr} = main::standardize($value);
2763         }
2764
2765         return $self;
2766     }
2767
2768     use overload
2769         fallback => 0,
2770         qw("") => "_operator_stringify",
2771         "." => \&main::_operator_dot,
2772     ;
2773
2774     sub _operator_stringify {
2775         my $self = shift;
2776         my $addr = do { no overloading; pack 'J', $self; };
2777
2778         # Output it like '0041..0065 (value)'
2779         my $return = sprintf("%04X", $start{$addr})
2780                         .  '..'
2781                         . sprintf("%04X", $end{$addr});
2782         my $value = $value{$addr};
2783         my $type = $type{$addr};
2784         $return .= ' (';
2785         $return .= "$value";
2786         $return .= ", Type=$type" if $type != 0;
2787         $return .= ')';
2788
2789         return $return;
2790     }
2791
2792     sub standard_form {
2793         # The standard form is the value itself if the standard form is
2794         # undefined (that is if the value is special)
2795
2796         my $self = shift;
2797         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2798
2799         my $addr = do { no overloading; pack 'J', $self; };
2800
2801         return $standard_form{$addr} if defined $standard_form{$addr};
2802         return $value{$addr};
2803     }
2804
2805     sub dump {
2806         # Human, not machine readable.  For machine readable, comment out this
2807         # entire routine and let the standard one take effect.
2808         my $self = shift;
2809         my $indent = shift;
2810         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2811
2812         my $addr = do { no overloading; pack 'J', $self; };
2813
2814         my $return = $indent
2815                     . sprintf("%04X", $start{$addr})
2816                     . '..'
2817                     . sprintf("%04X", $end{$addr})
2818                     . " '$value{$addr}';";
2819         if (! defined $standard_form{$addr}) {
2820             $return .= "(type=$type{$addr})";
2821         }
2822         elsif ($standard_form{$addr} ne $value{$addr}) {
2823             $return .= "(standard '$standard_form{$addr}')";
2824         }
2825         return $return;
2826     }
2827 } # End closure
2828
2829 package _Range_List_Base;
2830
2831 # Base class for range lists.  A range list is simply an ordered list of
2832 # ranges, so that the ranges with the lowest starting numbers are first in it.
2833 #
2834 # When a new range is added that is adjacent to an existing range that has the
2835 # same value and type, it merges with it to form a larger range.
2836 #
2837 # Ranges generally do not overlap, except that there can be multiple entries
2838 # of single code point ranges.  This is because of NameAliases.txt.
2839 #
2840 # In this program, there is a standard value such that if two different
2841 # values, have the same standard value, they are considered equivalent.  This
2842 # value was chosen so that it gives correct results on Unicode data
2843
2844 # There are a number of methods to manipulate range lists, and some operators
2845 # are overloaded to handle them.
2846
2847 sub trace { return main::trace(@_); }
2848
2849 { # Closure
2850
2851     our $addr;
2852
2853     main::setup_package();
2854
2855     my %ranges;
2856     # The list of ranges
2857     main::set_access('ranges', \%ranges, 'readable_array');
2858
2859     my %max;
2860     # The highest code point in the list.  This was originally a method, but
2861     # actual measurements said it was used a lot.
2862     main::set_access('max', \%max, 'r');
2863
2864     my %each_range_iterator;
2865     # Iterator position for each_range()
2866     main::set_access('each_range_iterator', \%each_range_iterator);
2867
2868     my %owner_name_of;
2869     # Name of parent this is attached to, if any.  Solely for better error
2870     # messages.
2871     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2872
2873     my %_search_ranges_cache;
2874     # A cache of the previous result from _search_ranges(), for better
2875     # performance
2876     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2877
2878     sub new {
2879         my $class = shift;
2880         my %args = @_;
2881
2882         # Optional initialization data for the range list.
2883         my $initialize = delete $args{'Initialize'};
2884
2885         my $self;
2886
2887         # Use _union() to initialize.  _union() returns an object of this
2888         # class, which means that it will call this constructor recursively.
2889         # But it won't have this $initialize parameter so that it won't
2890         # infinitely loop on this.
2891         return _union($class, $initialize, %args) if defined $initialize;
2892
2893         $self = bless \do { my $anonymous_scalar }, $class;
2894         my $addr = do { no overloading; pack 'J', $self; };
2895
2896         # Optional parent object, only for debug info.
2897         $owner_name_of{$addr} = delete $args{'Owner'};
2898         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2899
2900         # Stringify, in case it is an object.
2901         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2902
2903         # This is used only for error messages, and so a colon is added
2904         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2905
2906         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2907
2908         # Max is initialized to a negative value that isn't adjacent to 0,
2909         # for simpler tests
2910         $max{$addr} = -2;
2911
2912         $_search_ranges_cache{$addr} = 0;
2913         $ranges{$addr} = [];
2914
2915         return $self;
2916     }
2917
2918     use overload
2919         fallback => 0,
2920         qw("") => "_operator_stringify",
2921         "." => \&main::_operator_dot,
2922     ;
2923
2924     sub _operator_stringify {
2925         my $self = shift;
2926         my $addr = do { no overloading; pack 'J', $self; };
2927
2928         return "Range_List attached to '$owner_name_of{$addr}'"
2929                                                 if $owner_name_of{$addr};
2930         return "anonymous Range_List " . \$self;
2931     }
2932
2933     sub _union {
2934         # Returns the union of the input code points.  It can be called as
2935         # either a constructor or a method.  If called as a method, the result
2936         # will be a new() instance of the calling object, containing the union
2937         # of that object with the other parameter's code points;  if called as
2938         # a constructor, the first parameter gives the class the new object
2939         # should be, and the second parameter gives the code points to go into
2940         # it.
2941         # In either case, there are two parameters looked at by this routine;
2942         # any additional parameters are passed to the new() constructor.
2943         #
2944         # The code points can come in the form of some object that contains
2945         # ranges, and has a conventionally named method to access them; or
2946         # they can be an array of individual code points (as integers); or
2947         # just a single code point.
2948         #
2949         # If they are ranges, this routine doesn't make any effort to preserve
2950         # the range values of one input over the other.  Therefore this base
2951         # class should not allow _union to be called from other than
2952         # initialization code, so as to prevent two tables from being added
2953         # together where the range values matter.  The general form of this
2954         # routine therefore belongs in a derived class, but it was moved here
2955         # to avoid duplication of code.  The failure to overload this in this
2956         # class keeps it safe.
2957         #
2958
2959         my $self;
2960         my @args;   # Arguments to pass to the constructor
2961
2962         my $class = shift;
2963
2964         # If a method call, will start the union with the object itself, and
2965         # the class of the new object will be the same as self.
2966         if (ref $class) {
2967             $self = $class;
2968             $class = ref $self;
2969             push @args, $self;
2970         }
2971
2972         # Add the other required parameter.
2973         push @args, shift;
2974         # Rest of parameters are passed on to the constructor
2975
2976         # Accumulate all records from both lists.
2977         my @records;
2978         for my $arg (@args) {
2979             #local $to_trace = 0 if main::DEBUG;
2980             trace "argument = $arg" if main::DEBUG && $to_trace;
2981             if (! defined $arg) {
2982                 my $message = "";
2983                 if (defined $self) {
2984                     no overloading;
2985                     $message .= $owner_name_of{pack 'J', $self};
2986                 }
2987                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2988                 return;
2989             }
2990             $arg = [ $arg ] if ! ref $arg;
2991             my $type = ref $arg;
2992             if ($type eq 'ARRAY') {
2993                 foreach my $element (@$arg) {
2994                     push @records, Range->new($element, $element);
2995                 }
2996             }
2997             elsif ($arg->isa('Range')) {
2998                 push @records, $arg;
2999             }
3000             elsif ($arg->can('ranges')) {
3001                 push @records, $arg->ranges;
3002             }
3003             else {
3004                 my $message = "";
3005                 if (defined $self) {
3006                     no overloading;
3007                     $message .= $owner_name_of{pack 'J', $self};
3008                 }
3009                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3010                 return;
3011             }
3012         }
3013
3014         # Sort with the range containing the lowest ordinal first, but if
3015         # two ranges start at the same code point, sort with the bigger range
3016         # of the two first, because it takes fewer cycles.
3017         @records = sort { ($a->start <=> $b->start)
3018                                       or
3019                                     # if b is shorter than a, b->end will be
3020                                     # less than a->end, and we want to select
3021                                     # a, so want to return -1
3022                                     ($b->end <=> $a->end)
3023                                    } @records;
3024
3025         my $new = $class->new(@_);
3026
3027         # Fold in records so long as they add new information.
3028         for my $set (@records) {
3029             my $start = $set->start;
3030             my $end   = $set->end;
3031             my $value   = $set->value;
3032             if ($start > $new->max) {
3033                 $new->_add_delete('+', $start, $end, $value);
3034             }
3035             elsif ($end > $new->max) {
3036                 $new->_add_delete('+', $new->max +1, $end, $value);
3037             }
3038         }
3039
3040         return $new;
3041     }
3042
3043     sub range_count {        # Return the number of ranges in the range list
3044         my $self = shift;
3045         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3046
3047         no overloading;
3048         return scalar @{$ranges{pack 'J', $self}};
3049     }
3050
3051     sub min {
3052         # Returns the minimum code point currently in the range list, or if
3053         # the range list is empty, 2 beyond the max possible.  This is a
3054         # method because used so rarely, that not worth saving between calls,
3055         # and having to worry about changing it as ranges are added and
3056         # deleted.
3057
3058         my $self = shift;
3059         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3060
3061         my $addr = do { no overloading; pack 'J', $self; };
3062
3063         # If the range list is empty, return a large value that isn't adjacent
3064         # to any that could be in the range list, for simpler tests
3065         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3066         return $ranges{$addr}->[0]->start;
3067     }
3068
3069     sub contains {
3070         # Boolean: Is argument in the range list?  If so returns $i such that:
3071         #   range[$i]->end < $codepoint <= range[$i+1]->end
3072         # which is one beyond what you want; this is so that the 0th range
3073         # doesn't return false
3074         my $self = shift;
3075         my $codepoint = shift;
3076         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3077
3078         my $i = $self->_search_ranges($codepoint);
3079         return 0 unless defined $i;
3080
3081         # The search returns $i, such that
3082         #   range[$i-1]->end < $codepoint <= range[$i]->end
3083         # So is in the table if and only iff it is at least the start position
3084         # of range $i.
3085         no overloading;
3086         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3087         return $i + 1;
3088     }
3089
3090     sub containing_range {
3091         # Returns the range object that contains the code point, undef if none
3092
3093         my $self = shift;
3094         my $codepoint = shift;
3095         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3096
3097         my $i = $self->contains($codepoint);
3098         return unless $i;
3099
3100         # contains() returns 1 beyond where we should look
3101         no overloading;
3102         return $ranges{pack 'J', $self}->[$i-1];
3103     }
3104
3105     sub value_of {
3106         # Returns the value associated with the code point, undef if none
3107
3108         my $self = shift;
3109         my $codepoint = shift;
3110         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3111
3112         my $range = $self->containing_range($codepoint);
3113         return unless defined $range;
3114
3115         return $range->value;
3116     }
3117
3118     sub type_of {
3119         # Returns the type of the range containing the code point, undef if
3120         # the code point is not in the table
3121
3122         my $self = shift;
3123         my $codepoint = shift;
3124         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3125
3126         my $range = $self->containing_range($codepoint);
3127         return unless defined $range;
3128
3129         return $range->type;
3130     }
3131
3132     sub _search_ranges {
3133         # Find the range in the list which contains a code point, or where it
3134         # should go if were to add it.  That is, it returns $i, such that:
3135         #   range[$i-1]->end < $codepoint <= range[$i]->end
3136         # Returns undef if no such $i is possible (e.g. at end of table), or
3137         # if there is an error.
3138
3139         my $self = shift;
3140         my $code_point = shift;
3141         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3142
3143         my $addr = do { no overloading; pack 'J', $self; };
3144
3145         return if $code_point > $max{$addr};
3146         my $r = $ranges{$addr};                # The current list of ranges
3147         my $range_list_size = scalar @$r;
3148         my $i;
3149
3150         use integer;        # want integer division
3151
3152         # Use the cached result as the starting guess for this one, because,
3153         # an experiment on 5.1 showed that 90% of the time the cache was the
3154         # same as the result on the next call (and 7% it was one less).
3155         $i = $_search_ranges_cache{$addr};
3156         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3157                                             # from an intervening deletion
3158         #local $to_trace = 1 if main::DEBUG;
3159         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3160         return $i if $code_point <= $r->[$i]->end
3161                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3162
3163         # Here the cache doesn't yield the correct $i.  Try adding 1.
3164         if ($i < $range_list_size - 1
3165             && $r->[$i]->end < $code_point &&
3166             $code_point <= $r->[$i+1]->end)
3167         {
3168             $i++;
3169             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3170             $_search_ranges_cache{$addr} = $i;
3171             return $i;
3172         }
3173
3174         # Here, adding 1 also didn't work.  We do a binary search to
3175         # find the correct position, starting with current $i
3176         my $lower = 0;
3177         my $upper = $range_list_size - 1;
3178         while (1) {
3179             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3180
3181             if ($code_point <= $r->[$i]->end) {
3182
3183                 # Here we have met the upper constraint.  We can quit if we
3184                 # also meet the lower one.
3185                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3186
3187                 $upper = $i;        # Still too high.
3188
3189             }
3190             else {
3191
3192                 # Here, $r[$i]->end < $code_point, so look higher up.
3193                 $lower = $i;
3194             }
3195
3196             # Split search domain in half to try again.
3197             my $temp = ($upper + $lower) / 2;
3198
3199             # No point in continuing unless $i changes for next time
3200             # in the loop.
3201             if ($temp == $i) {
3202
3203                 # We can't reach the highest element because of the averaging.
3204                 # So if one below the upper edge, force it there and try one
3205                 # more time.
3206                 if ($i == $range_list_size - 2) {
3207
3208                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3209                     $i = $range_list_size - 1;
3210
3211                     # Change $lower as well so if fails next time through,
3212                     # taking the average will yield the same $i, and we will
3213                     # quit with the error message just below.
3214                     $lower = $i;
3215                     next;
3216                 }
3217                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3218                 return;
3219             }
3220             $i = $temp;
3221         } # End of while loop
3222
3223         if (main::DEBUG && $to_trace) {
3224             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3225             trace "i=  [ $i ]", $r->[$i];
3226             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3227         }
3228
3229         # Here we have found the offset.  Cache it as a starting point for the
3230         # next call.
3231         $_search_ranges_cache{$addr} = $i;
3232         return $i;
3233     }
3234
3235     sub _add_delete {
3236         # Add, replace or delete ranges to or from a list.  The $type
3237         # parameter gives which:
3238         #   '+' => insert or replace a range, returning a list of any changed
3239         #          ranges.
3240         #   '-' => delete a range, returning a list of any deleted ranges.
3241         #
3242         # The next three parameters give respectively the start, end, and
3243         # value associated with the range.  'value' should be null unless the
3244         # operation is '+';
3245         #
3246         # The range list is kept sorted so that the range with the lowest
3247         # starting position is first in the list, and generally, adjacent
3248         # ranges with the same values are merged into a single larger one (see
3249         # exceptions below).
3250         #
3251         # There are more parameters; all are key => value pairs:
3252         #   Type    gives the type of the value.  It is only valid for '+'.
3253         #           All ranges have types; if this parameter is omitted, 0 is
3254         #           assumed.  Ranges with type 0 are assumed to obey the
3255         #           Unicode rules for casing, etc; ranges with other types are
3256         #           not.  Otherwise, the type is arbitrary, for the caller's
3257         #           convenience, and looked at only by this routine to keep
3258         #           adjacent ranges of different types from being merged into
3259         #           a single larger range, and when Replace =>
3260         #           $IF_NOT_EQUIVALENT is specified (see just below).
3261         #   Replace  determines what to do if the range list already contains
3262         #            ranges which coincide with all or portions of the input
3263         #            range.  It is only valid for '+':
3264         #       => $NO            means that the new value is not to replace
3265         #                         any existing ones, but any empty gaps of the
3266         #                         range list coinciding with the input range
3267         #                         will be filled in with the new value.
3268         #       => $UNCONDITIONALLY  means to replace the existing values with
3269         #                         this one unconditionally.  However, if the
3270         #                         new and old values are identical, the
3271         #                         replacement is skipped to save cycles
3272         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3273         #                         with this one if they are not equivalent.
3274         #                         Ranges are equivalent if their types are the
3275         #                         same, and they are the same string; or if
3276         #                         both are type 0 ranges, if their Unicode
3277         #                         standard forms are identical.  In this last
3278         #                         case, the routine chooses the more "modern"
3279         #                         one to use.  This is because some of the
3280         #                         older files are formatted with values that
3281         #                         are, for example, ALL CAPs, whereas the
3282         #                         derived files have a more modern style,
3283         #                         which looks better.  By looking for this
3284         #                         style when the pre-existing and replacement
3285         #                         standard forms are the same, we can move to
3286         #                         the modern style
3287         #       => $MULTIPLE      means that if this range duplicates an
3288         #                         existing one, but has a different value,
3289         #                         don't replace the existing one, but insert
3290         #                         this, one so that the same range can occur
3291         #                         multiple times.  They are stored LIFO, so
3292         #                         that the final one inserted is the first one
3293         #                         returned in an ordered search of the table.
3294         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3295         #
3296         # "same value" means identical for non-type-0 ranges, and it means
3297         # having the same standard forms for type-0 ranges.
3298
3299         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3300
3301         my $self = shift;
3302         my $operation = shift;   # '+' for add/replace; '-' for delete;
3303         my $start = shift;
3304         my $end   = shift;
3305         my $value = shift;
3306
3307         my %args = @_;
3308
3309         $value = "" if not defined $value;        # warning: $value can be "0"
3310
3311         my $replace = delete $args{'Replace'};
3312         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3313
3314         my $type = delete $args{'Type'};
3315         $type = 0 unless defined $type;
3316
3317         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3318
3319         my $addr = do { no overloading; pack 'J', $self; };
3320
3321         if ($operation ne '+' && $operation ne '-') {
3322             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3323             return;
3324         }
3325         unless (defined $start && defined $end) {
3326             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3327             return;
3328         }
3329         unless ($end >= $start) {
3330             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3331             return;
3332         }
3333         #local $to_trace = 1 if main::DEBUG;
3334
3335         if ($operation eq '-') {
3336             if ($replace != $IF_NOT_EQUIVALENT) {
3337                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3338                 $replace = $IF_NOT_EQUIVALENT;
3339             }
3340             if ($type) {
3341                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3342                 $type = 0;
3343             }
3344             if ($value ne "") {
3345                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3346                 $value = "";
3347             }
3348         }
3349
3350         my $r = $ranges{$addr};               # The current list of ranges
3351         my $range_list_size = scalar @$r;     # And its size
3352         my $max = $max{$addr};                # The current high code point in
3353                                               # the list of ranges
3354
3355         # Do a special case requiring fewer machine cycles when the new range
3356         # starts after the current highest point.  The Unicode input data is
3357         # structured so this is common.
3358         if ($start > $max) {
3359
3360             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3361             return if $operation eq '-'; # Deleting a non-existing range is a
3362                                          # no-op
3363
3364             # If the new range doesn't logically extend the current final one
3365             # in the range list, create a new range at the end of the range
3366             # list.  (max cleverly is initialized to a negative number not
3367             # adjacent to 0 if the range list is empty, so even adding a range
3368             # to an empty range list starting at 0 will have this 'if'
3369             # succeed.)
3370             if ($start > $max + 1        # non-adjacent means can't extend.
3371                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3372                 || @{$r}[-1]->type != $type # types differ, can't extend.
3373             ) {
3374                 push @$r, Range->new($start, $end,
3375                                      Value => $value,
3376                                      Type => $type);
3377             }
3378             else {
3379
3380                 # Here, the new range starts just after the current highest in
3381                 # the range list, and they have the same type and value.
3382                 # Extend the current range to incorporate the new one.
3383                 @{$r}[-1]->set_end($end);
3384             }
3385
3386             # This becomes the new maximum.
3387             $max{$addr} = $end;
3388
3389             return;
3390         }
3391         #local $to_trace = 0 if main::DEBUG;
3392
3393         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3394
3395         # Here, the input range isn't after the whole rest of the range list.
3396         # Most likely 'splice' will be needed.  The rest of the routine finds
3397         # the needed splice parameters, and if necessary, does the splice.
3398         # First, find the offset parameter needed by the splice function for
3399         # the input range.  Note that the input range may span multiple
3400         # existing ones, but we'll worry about that later.  For now, just find
3401         # the beginning.  If the input range is to be inserted starting in a
3402         # position not currently in the range list, it must (obviously) come
3403         # just after the range below it, and just before the range above it.
3404         # Slightly less obviously, it will occupy the position currently
3405         # occupied by the range that is to come after it.  More formally, we
3406         # are looking for the position, $i, in the array of ranges, such that:
3407         #
3408         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3409         #
3410         # (The ordered relationships within existing ranges are also shown in
3411         # the equation above).  However, if the start of the input range is
3412         # within an existing range, the splice offset should point to that
3413         # existing range's position in the list; that is $i satisfies a
3414         # somewhat different equation, namely:
3415         #
3416         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3417         #
3418         # More briefly, $start can come before or after r[$i]->start, and at
3419         # this point, we don't know which it will be.  However, these
3420         # two equations share these constraints:
3421         #
3422         #   r[$i-1]->end < $start <= r[$i]->end
3423         #
3424         # And that is good enough to find $i.
3425
3426         my $i = $self->_search_ranges($start);
3427         if (! defined $i) {
3428             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3429             return;
3430         }
3431
3432         # The search function returns $i such that:
3433         #
3434         # r[$i-1]->end < $start <= r[$i]->end
3435         #
3436         # That means that $i points to the first range in the range list
3437         # that could possibly be affected by this operation.  We still don't
3438         # know if the start of the input range is within r[$i], or if it
3439         # points to empty space between r[$i-1] and r[$i].
3440         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3441
3442         # Special case the insertion of data that is not to replace any
3443         # existing data.
3444         if ($replace == $NO) {  # If $NO, has to be operation '+'
3445             #local $to_trace = 1 if main::DEBUG;
3446             trace "Doesn't replace" if main::DEBUG && $to_trace;
3447
3448             # Here, the new range is to take effect only on those code points
3449             # that aren't already in an existing range.  This can be done by
3450             # looking through the existing range list and finding the gaps in
3451             # the ranges that this new range affects, and then calling this
3452             # function recursively on each of those gaps, leaving untouched
3453             # anything already in the list.  Gather up a list of the changed
3454             # gaps first so that changes to the internal state as new ranges
3455             # are added won't be a problem.
3456             my @gap_list;
3457
3458             # First, if the starting point of the input range is outside an
3459             # existing one, there is a gap from there to the beginning of the
3460             # existing range -- add a span to fill the part that this new
3461             # range occupies
3462             if ($start < $r->[$i]->start) {
3463                 push @gap_list, Range->new($start,
3464                                            main::min($end,
3465                                                      $r->[$i]->start - 1),
3466                                            Type => $type);
3467                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3468             }
3469
3470             # Then look through the range list for other gaps until we reach
3471             # the highest range affected by the input one.
3472             my $j;
3473             for ($j = $i+1; $j < $range_list_size; $j++) {
3474                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3475                 last if $end < $r->[$j]->start;
3476
3477                 # If there is a gap between when this range starts and the
3478                 # previous one ends, add a span to fill it.  Note that just
3479                 # because there are two ranges doesn't mean there is a
3480                 # non-zero gap between them.  It could be that they have
3481                 # different values or types
3482                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3483                     push @gap_list,
3484                         Range->new($r->[$j-1]->end + 1,
3485                                    $r->[$j]->start - 1,
3486                                    Type => $type);
3487                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3488                 }
3489             }
3490
3491             # Here, we have either found an existing range in the range list,
3492             # beyond the area affected by the input one, or we fell off the
3493             # end of the loop because the input range affects the whole rest
3494             # of the range list.  In either case, $j is 1 higher than the
3495             # highest affected range.  If $j == $i, it means that there are no
3496             # affected ranges, that the entire insertion is in the gap between
3497             # r[$i-1], and r[$i], which we already have taken care of before
3498             # the loop.
3499             # On the other hand, if there are affected ranges, it might be
3500             # that there is a gap that needs filling after the final such
3501             # range to the end of the input range
3502             if ($r->[$j-1]->end < $end) {
3503                     push @gap_list, Range->new(main::max($start,
3504                                                          $r->[$j-1]->end + 1),
3505                                                $end,
3506                                                Type => $type);
3507                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3508             }
3509
3510             # Call recursively to fill in all the gaps.
3511             foreach my $gap (@gap_list) {
3512                 $self->_add_delete($operation,
3513                                    $gap->start,
3514                                    $gap->end,
3515                                    $value,
3516                                    Type => $type);
3517             }
3518
3519             return;
3520         }
3521
3522         # Here, we have taken care of the case where $replace is $NO.
3523         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3524         # If inserting a multiple record, this is where it goes, before the
3525         # first (if any) existing one.  This implies an insertion, and no
3526         # change to any existing ranges.  Note that $i can be -1 if this new
3527         # range doesn't actually duplicate any existing, and comes at the
3528         # beginning of the list.
3529         if ($replace == $MULTIPLE) {
3530
3531             if ($start != $end) {
3532                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3533                 return;
3534             }
3535
3536             # Don't add an exact duplicate, as it isn't really a multiple
3537             if ($end >= $r->[$i]->start) {
3538                 my $existing_value = $r->[$i]->value;
3539                 my $existing_type = $r->[$i]->type;
3540                 return if $value eq $existing_value && $type eq $existing_type;
3541
3542                 # If the multiple value is part of an existing range, we want
3543                 # to split up that range, so that only the single code point
3544                 # is affected.  To do this, we first call ourselves
3545                 # recursively to delete that code point from the table, having
3546                 # preserved its current data above.  Then we call ourselves
3547                 # recursively again to add the new multiple, which we know by
3548                 # the test just above is different than the current code
3549                 # point's value, so it will become a range containing a single
3550                 # code point: just itself.  Finally, we add back in the
3551                 # pre-existing code point, which will again be a single code
3552                 # point range.  Because 'i' likely will have changed as a
3553                 # result of these operations, we can't just continue on, but
3554                 # do this operation recursively as well.
3555                 if ($r->[$i]->start != $r->[$i]->end) {
3556                     $self->_add_delete('-', $start, $end, "");
3557                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3558                     return $self->_add_delete('+', $start, $end, $existing_value, Type => $existing_type, Replace => $MULTIPLE);
3559                 }
3560             }
3561
3562             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3563             my @return = splice @$r,
3564                                 $i,
3565                                 0,
3566                                 Range->new($start,
3567                                            $end,
3568                                            Value => $value,
3569                                            Type => $type);
3570             if (main::DEBUG && $to_trace) {
3571                 trace "After splice:";
3572                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3573                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3574                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3575                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3576                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3577                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3578             }
3579             return @return;
3580         }
3581
3582         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3583         # delete, insert, and replace either unconditionally or if not
3584         # equivalent.  $i still points to the first potential affected range.
3585         # Now find the highest range affected, which will determine the length
3586         # parameter to splice.  (The input range can span multiple existing
3587         # ones.)  If this isn't a deletion, while we are looking through the
3588         # range list, see also if this is a replacement rather than a clean
3589         # insertion; that is if it will change the values of at least one
3590         # existing range.  Start off assuming it is an insert, until find it
3591         # isn't.
3592         my $clean_insert = $operation eq '+';
3593         my $j;        # This will point to the highest affected range
3594
3595         # For non-zero types, the standard form is the value itself;
3596         my $standard_form = ($type) ? $value : main::standardize($value);
3597
3598         for ($j = $i; $j < $range_list_size; $j++) {
3599             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3600
3601             # If find a range that it doesn't overlap into, we can stop
3602             # searching
3603             last if $end < $r->[$j]->start;
3604
3605             # Here, overlaps the range at $j.  If the values don't match,
3606             # and so far we think this is a clean insertion, it becomes a
3607             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3608             if ($clean_insert) {
3609                 if ($r->[$j]->standard_form ne $standard_form) {
3610                     $clean_insert = 0;
3611                     if ($replace == $CROAK) {
3612                         main::croak("The range to add "
3613                         . sprintf("%04X", $start)
3614                         . '-'
3615                         . sprintf("%04X", $end)
3616                         . " with value '$value' overlaps an existing range $r->[$j]");
3617                     }
3618                 }
3619                 else {
3620
3621                     # Here, the two values are essentially the same.  If the
3622                     # two are actually identical, replacing wouldn't change
3623                     # anything so skip it.
3624                     my $pre_existing = $r->[$j]->value;
3625                     if ($pre_existing ne $value) {
3626
3627                         # Here the new and old standardized values are the
3628                         # same, but the non-standardized values aren't.  If
3629                         # replacing unconditionally, then replace
3630                         if( $replace == $UNCONDITIONALLY) {
3631                             $clean_insert = 0;
3632                         }
3633                         else {
3634
3635                             # Here, are replacing conditionally.  Decide to
3636                             # replace or not based on which appears to look
3637                             # the "nicest".  If one is mixed case and the
3638                             # other isn't, choose the mixed case one.
3639                             my $new_mixed = $value =~ /[A-Z]/
3640                                             && $value =~ /[a-z]/;
3641                             my $old_mixed = $pre_existing =~ /[A-Z]/
3642                                             && $pre_existing =~ /[a-z]/;
3643
3644                             if ($old_mixed != $new_mixed) {
3645                                 $clean_insert = 0 if $new_mixed;
3646                                 if (main::DEBUG && $to_trace) {
3647                                     if ($clean_insert) {
3648                                         trace "Retaining $pre_existing over $value";
3649                                     }
3650                                     else {
3651                                         trace "Replacing $pre_existing with $value";
3652                                     }
3653                                 }
3654                             }
3655                             else {
3656
3657                                 # Here casing wasn't different between the two.
3658                                 # If one has hyphens or underscores and the
3659                                 # other doesn't, choose the one with the
3660                                 # punctuation.
3661                                 my $new_punct = $value =~ /[-_]/;
3662                                 my $old_punct = $pre_existing =~ /[-_]/;
3663
3664                                 if ($old_punct != $new_punct) {
3665                                     $clean_insert = 0 if $new_punct;
3666                                     if (main::DEBUG && $to_trace) {
3667                                         if ($clean_insert) {
3668                                             trace "Retaining $pre_existing over $value";
3669                                         }
3670                                         else {
3671                                             trace "Replacing $pre_existing with $value";
3672                                         }
3673                                     }
3674                                 }   # else existing one is just as "good";
3675                                     # retain it to save cycles.
3676                             }
3677                         }
3678                     }
3679                 }
3680             }
3681         } # End of loop looking for highest affected range.
3682
3683         # Here, $j points to one beyond the highest range that this insertion
3684         # affects (hence to beyond the range list if that range is the final
3685         # one in the range list).
3686
3687         # The splice length is all the affected ranges.  Get it before
3688         # subtracting, for efficiency, so we don't have to later add 1.
3689         my $length = $j - $i;
3690
3691         $j--;        # $j now points to the highest affected range.
3692         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3693
3694         # Here, have taken care of $NO and $MULTIPLE replaces.
3695         # $j points to the highest affected range.  But it can be < $i or even
3696         # -1.  These happen only if the insertion is entirely in the gap
3697         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3698         # above exited first time through with $end < $r->[$i]->start.  (And
3699         # then we subtracted one from j)  This implies also that $start <
3700         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3701         # $start, so the entire input range is in the gap.
3702         if ($j < $i) {
3703
3704             # Here the entire input range is in the gap before $i.
3705
3706             if (main::DEBUG && $to_trace) {
3707                 if ($i) {
3708                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3709                 }
3710                 else {
3711                     trace "Entire range is before $r->[$i]";
3712                 }
3713             }
3714             return if $operation ne '+'; # Deletion of a non-existent range is
3715                                          # a no-op
3716         }
3717         else {
3718
3719             # Here part of the input range is not in the gap before $i.  Thus,
3720             # there is at least one affected one, and $j points to the highest
3721             # such one.
3722
3723             # At this point, here is the situation:
3724             # This is not an insertion of a multiple, nor of tentative ($NO)
3725             # data.
3726             #   $i  points to the first element in the current range list that
3727             #            may be affected by this operation.  In fact, we know
3728             #            that the range at $i is affected because we are in
3729             #            the else branch of this 'if'
3730             #   $j  points to the highest affected range.
3731             # In other words,
3732             #   r[$i-1]->end < $start <= r[$i]->end
3733             # And:
3734             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3735             #
3736             # Also:
3737             #   $clean_insert is a boolean which is set true if and only if
3738             #        this is a "clean insertion", i.e., not a change nor a
3739             #        deletion (multiple was handled above).
3740
3741             # We now have enough information to decide if this call is a no-op
3742             # or not.  It is a no-op if this is an insertion of already
3743             # existing data.
3744
3745             if (main::DEBUG && $to_trace && $clean_insert
3746                                          && $i == $j
3747                                          && $start >= $r->[$i]->start)
3748             {
3749                     trace "no-op";
3750             }
3751             return if $clean_insert
3752                       && $i == $j # more than one affected range => not no-op
3753
3754                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3755                       # Further, $start and/or $end is >= r[$i]->start
3756                       # The test below hence guarantees that
3757                       #     r[$i]->start < $start <= $end <= r[$i]->end
3758                       # This means the input range is contained entirely in
3759                       # the one at $i, so is a no-op
3760                       && $start >= $r->[$i]->start;
3761         }
3762
3763         # Here, we know that some action will have to be taken.  We have
3764         # calculated the offset and length (though adjustments may be needed)
3765         # for the splice.  Now start constructing the replacement list.
3766         my @replacement;
3767         my $splice_start = $i;
3768
3769         my $extends_below;
3770         my $extends_above;
3771
3772         # See if should extend any adjacent ranges.
3773         if ($operation eq '-') { # Don't extend deletions
3774             $extends_below = $extends_above = 0;
3775         }
3776         else {  # Here, should extend any adjacent ranges.  See if there are
3777                 # any.
3778             $extends_below = ($i > 0
3779                             # can't extend unless adjacent
3780                             && $r->[$i-1]->end == $start -1
3781                             # can't extend unless are same standard value
3782                             && $r->[$i-1]->standard_form eq $standard_form
3783                             # can't extend unless share type
3784                             && $r->[$i-1]->type == $type);
3785             $extends_above = ($j+1 < $range_list_size
3786                             && $r->[$j+1]->start == $end +1
3787                             && $r->[$j+1]->standard_form eq $standard_form
3788                             && $r->[$j+1]->type == $type);
3789         }
3790         if ($extends_below && $extends_above) { # Adds to both
3791             $splice_start--;     # start replace at element below
3792             $length += 2;        # will replace on both sides
3793             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3794
3795             # The result will fill in any gap, replacing both sides, and
3796             # create one large range.
3797             @replacement = Range->new($r->[$i-1]->start,
3798                                       $r->[$j+1]->end,
3799                                       Value => $value,
3800                                       Type => $type);
3801         }
3802         else {
3803
3804             # Here we know that the result won't just be the conglomeration of
3805             # a new range with both its adjacent neighbors.  But it could
3806             # extend one of them.
3807
3808             if ($extends_below) {
3809
3810                 # Here the new element adds to the one below, but not to the
3811                 # one above.  If inserting, and only to that one range,  can
3812                 # just change its ending to include the new one.
3813                 if ($length == 0 && $clean_insert) {
3814                     $r->[$i-1]->set_end($end);
3815                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3816                     return;
3817                 }
3818                 else {
3819                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3820                     $splice_start--;        # start replace at element below
3821                     $length++;              # will replace the element below
3822                     $start = $r->[$i-1]->start;
3823                 }
3824             }
3825             elsif ($extends_above) {
3826
3827                 # Here the new element adds to the one above, but not below.
3828                 # Mirror the code above
3829                 if ($length == 0 && $clean_insert) {
3830                     $r->[$j+1]->set_start($start);
3831                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3832                     return;
3833                 }
3834                 else {
3835                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3836                     $length++;        # will replace the element above
3837                     $end = $r->[$j+1]->end;
3838                 }
3839             }
3840
3841             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3842
3843             # Finally, here we know there will have to be a splice.
3844             # If the change or delete affects only the highest portion of the
3845             # first affected range, the range will have to be split.  The
3846             # splice will remove the whole range, but will replace it by a new
3847             # range containing just the unaffected part.  So, in this case,
3848             # add to the replacement list just this unaffected portion.
3849             if (! $extends_below
3850                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3851             {
3852                 push @replacement,
3853                     Range->new($r->[$i]->start,
3854                                $start - 1,
3855                                Value => $r->[$i]->value,
3856                                Type => $r->[$i]->type);
3857             }
3858
3859             # In the case of an insert or change, but not a delete, we have to
3860             # put in the new stuff;  this comes next.
3861             if ($operation eq '+') {
3862                 push @replacement, Range->new($start,
3863                                               $end,
3864                                               Value => $value,
3865                                               Type => $type);
3866             }
3867
3868             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3869             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3870
3871             # And finally, if we're changing or deleting only a portion of the
3872             # highest affected range, it must be split, as the lowest one was.
3873             if (! $extends_above
3874                 && $j >= 0  # Remember that j can be -1 if before first
3875                             # current element
3876                 && $end >= $r->[$j]->start
3877                 && $end < $r->[$j]->end)
3878             {
3879                 push @replacement,
3880                     Range->new($end + 1,
3881                                $r->[$j]->end,
3882                                Value => $r->[$j]->value,
3883                                Type => $r->[$j]->type);
3884             }
3885         }
3886
3887         # And do the splice, as calculated above
3888         if (main::DEBUG && $to_trace) {
3889             trace "replacing $length element(s) at $i with ";
3890             foreach my $replacement (@replacement) {
3891                 trace "    $replacement";
3892             }
3893             trace "Before splice:";
3894             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3895             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3896             trace "i  =[", $i, "]", $r->[$i];
3897             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3898             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3899         }
3900
3901         my @return = splice @$r, $splice_start, $length, @replacement;
3902
3903         if (main::DEBUG && $to_trace) {
3904             trace "After splice:";
3905             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3906             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3907             trace "i  =[", $i, "]", $r->[$i];
3908             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3909             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3910             trace "removed ", @return if @return;
3911         }
3912
3913         # An actual deletion could have changed the maximum in the list.
3914         # There was no deletion if the splice didn't return something, but
3915         # otherwise recalculate it.  This is done too rarely to worry about
3916         # performance.
3917         if ($operation eq '-' && @return) {
3918             $max{$addr} = $r->[-1]->end;
3919         }
3920         return @return;
3921     }
3922
3923     sub reset_each_range {  # reset the iterator for each_range();
3924         my $self = shift;
3925         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3926
3927         no overloading;
3928         undef $each_range_iterator{pack 'J', $self};
3929         return;
3930     }
3931
3932     sub each_range {
3933         # Iterate over each range in a range list.  Results are undefined if
3934         # the range list is changed during the iteration.
3935
3936         my $self = shift;
3937         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3938
3939         my $addr = do { no overloading; pack 'J', $self; };
3940
3941         return if $self->is_empty;
3942
3943         $each_range_iterator{$addr} = -1
3944                                 if ! defined $each_range_iterator{$addr};
3945         $each_range_iterator{$addr}++;
3946         return $ranges{$addr}->[$each_range_iterator{$addr}]
3947                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3948         undef $each_range_iterator{$addr};
3949         return;
3950     }
3951
3952     sub count {        # Returns count of code points in range list
3953         my $self = shift;
3954         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3955
3956         my $addr = do { no overloading; pack 'J', $self; };
3957
3958         my $count = 0;
3959         foreach my $range (@{$ranges{$addr}}) {
3960             $count += $range->end - $range->start + 1;
3961         }
3962         return $count;
3963     }
3964
3965     sub delete_range {    # Delete a range
3966         my $self = shift;
3967         my $start = shift;
3968         my $end = shift;