This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
pod: Do not suggest to use insecure :utf8 PerlIO layer when reading files
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in S<C<2 + 4 * 5>>, the multiplication has higher
32 precedence so S<C<4 * 5>> is evaluated first yielding S<C<2 + 20 ==
33 22>> and not S<C<6 * 5 == 30>>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first, or the right first.  For example, in
38 S<C<8 - 4 - 2>>, subtraction is left associative so Perl evaluates the
39 expression left to right.  S<C<8 - 4>> is evaluated first making the
40 expression S<C<4 - 2 == 2>> and not S<C<8 - 2 == 6>>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in detail, in the
75 same order in which they appear in the table above.
76
77 Many operators can be overloaded for objects.  See L<overload>.
78
79 =head2 Terms and List Operators (Leftward)
80 X<list operator> X<operator, list> X<term>
81
82 A TERM has the highest precedence in Perl.  They include variables,
83 quote and quote-like operators, any expression in parentheses,
84 and any function whose arguments are parenthesized.  Actually, there
85 aren't really functions in this sense, just list operators and unary
86 operators behaving as functions because you put parentheses around
87 the arguments.  These are all documented in L<perlfunc>.
88
89 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
90 is followed by a left parenthesis as the next token, the operator and
91 arguments within parentheses are taken to be of highest precedence,
92 just like a normal function call.
93
94 In the absence of parentheses, the precedence of list operators such as
95 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
96 whether you are looking at the left side or the right side of the operator.
97 For example, in
98
99     @ary = (1, 3, sort 4, 2);
100     print @ary;         # prints 1324
101
102 the commas on the right of the C<sort> are evaluated before the C<sort>,
103 but the commas on the left are evaluated after.  In other words,
104 list operators tend to gobble up all arguments that follow, and
105 then act like a simple TERM with regard to the preceding expression.
106 Be careful with parentheses:
107
108     # These evaluate exit before doing the print:
109     print($foo, exit);  # Obviously not what you want.
110     print $foo, exit;   # Nor is this.
111
112     # These do the print before evaluating exit:
113     (print $foo), exit; # This is what you want.
114     print($foo), exit;  # Or this.
115     print ($foo), exit; # Or even this.
116
117 Also note that
118
119     print ($foo & 255) + 1, "\n";
120
121 probably doesn't do what you expect at first glance.  The parentheses
122 enclose the argument list for C<print> which is evaluated (printing
123 the result of S<C<$foo & 255>>).  Then one is added to the return value
124 of C<print> (usually 1).  The result is something like this:
125
126     1 + 1, "\n";    # Obviously not what you meant.
127
128 To do what you meant properly, you must write:
129
130     print(($foo & 255) + 1, "\n");
131
132 See L</Named Unary Operators> for more discussion of this.
133
134 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
135 well as subroutine and method calls, and the anonymous
136 constructors C<[]> and C<{}>.
137
138 See also L</Quote and Quote-like Operators> toward the end of this section,
139 as well as L</"I/O Operators">.
140
141 =head2 The Arrow Operator
142 X<arrow> X<dereference> X<< -> >>
143
144 "C<< -> >>" is an infix dereference operator, just as it is in C
145 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
146 C<(...)> subscript, then the left side must be either a hard or
147 symbolic reference to an array, a hash, or a subroutine respectively.
148 (Or technically speaking, a location capable of holding a hard
149 reference, if it's an array or hash reference being used for
150 assignment.)  See L<perlreftut> and L<perlref>.
151
152 Otherwise, the right side is a method name or a simple scalar
153 variable containing either the method name or a subroutine reference,
154 and the left side must be either an object (a blessed reference)
155 or a class name (that is, a package name).  See L<perlobj>.
156
157 The dereferencing cases (as opposed to method-calling cases) are
158 somewhat extended by the C<postderef> feature.  For the
159 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
160
161 =head2 Auto-increment and Auto-decrement
162 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
163
164 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
165 they increment or decrement the variable by one before returning the
166 value, and if placed after, increment or decrement after returning the
167 value.
168
169     $i = 0;  $j = 0;
170     print $i++;  # prints 0
171     print ++$j;  # prints 1
172
173 Note that just as in C, Perl doesn't define B<when> the variable is
174 incremented or decremented.  You just know it will be done sometime
175 before or after the value is returned.  This also means that modifying
176 a variable twice in the same statement will lead to undefined behavior.
177 Avoid statements like:
178
179     $i = $i ++;
180     print ++ $i + $i ++;
181
182 Perl will not guarantee what the result of the above statements is.
183
184 The auto-increment operator has a little extra builtin magic to it.  If
185 you increment a variable that is numeric, or that has ever been used in
186 a numeric context, you get a normal increment.  If, however, the
187 variable has been used in only string contexts since it was set, and
188 has a value that is not the empty string and matches the pattern
189 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
190 character within its range, with carry:
191
192     print ++($foo = "99");      # prints "100"
193     print ++($foo = "a0");      # prints "a1"
194     print ++($foo = "Az");      # prints "Ba"
195     print ++($foo = "zz");      # prints "aaa"
196
197 C<undef> is always treated as numeric, and in particular is changed
198 to C<0> before incrementing (so that a post-increment of an undef value
199 will return C<0> rather than C<undef>).
200
201 The auto-decrement operator is not magical.
202
203 =head2 Exponentiation
204 X<**> X<exponentiation> X<power>
205
206 Binary C<"**"> is the exponentiation operator.  It binds even more
207 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
208 (This is
209 implemented using C's C<pow(3)> function, which actually works on doubles
210 internally.)
211
212 Note that certain exponentiation expressions are ill-defined:
213 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
214 any particular results from these special cases, the results
215 are platform-dependent.
216
217 =head2 Symbolic Unary Operators
218 X<unary operator> X<operator, unary>
219
220 Unary C<"!"> performs logical negation, that is, "not".  See also C<not> for a lower
221 precedence version of this.
222 X<!>
223
224 Unary C<"-"> performs arithmetic negation if the operand is numeric,
225 including any string that looks like a number.  If the operand is
226 an identifier, a string consisting of a minus sign concatenated
227 with the identifier is returned.  Otherwise, if the string starts
228 with a plus or minus, a string starting with the opposite sign is
229 returned.  One effect of these rules is that C<-bareword> is equivalent
230 to the string C<"-bareword">.  If, however, the string begins with a
231 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
232 to convert
233 the string to a numeric, and the arithmetic negation is performed.  If the
234 string cannot be cleanly converted to a numeric, Perl will give the warning
235 B<Argument "the string" isn't numeric in negation (-) at ...>.
236 X<-> X<negation, arithmetic>
237
238 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
239 example, S<C<0666 & ~027>> is 0640.  (See also L</Integer Arithmetic> and
240 L</Bitwise String Operators>.)  Note that the width of the result is
241 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
242 bits wide on a 64-bit platform, so if you are expecting a certain bit
243 width, remember to use the C<"&"> operator to mask off the excess bits.
244 X<~> X<negation, binary>
245
246 When complementing strings, if all characters have ordinal values under
247 256, then their complements will, also.  But if they do not, all
248 characters will be in either 32- or 64-bit complements, depending on your
249 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
250 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
251
252 If the experimental "bitwise" feature is enabled via S<C<use feature
253 'bitwise'>>, then unary C<"~"> always treats its argument as a number, and an
254 alternate form of the operator, C<"~.">, always treats its argument as a
255 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
256 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  This feature
257 produces a warning unless you use S<C<no warnings 'experimental::bitwise'>>.
258
259 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
260 syntactically for separating a function name from a parenthesized expression
261 that would otherwise be interpreted as the complete list of function
262 arguments.  (See examples above under L</Terms and List Operators (Leftward)>.)
263 X<+>
264
265 Unary C<"\"> creates a reference to whatever follows it.  See L<perlreftut>
266 and L<perlref>.  Do not confuse this behavior with the behavior of
267 backslash within a string, although both forms do convey the notion
268 of protecting the next thing from interpolation.
269 X<\> X<reference> X<backslash>
270
271 =head2 Binding Operators
272 X<binding> X<operator, binding> X<=~> X<!~>
273
274 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
275 search or modify the string C<$_> by default.  This operator makes that kind
276 of operation work on some other string.  The right argument is a search
277 pattern, substitution, or transliteration.  The left argument is what is
278 supposed to be searched, substituted, or transliterated instead of the default
279 C<$_>.  When used in scalar context, the return value generally indicates the
280 success of the operation.  The exceptions are substitution (C<s///>)
281 and transliteration (C<y///>) with the C</r> (non-destructive) option,
282 which cause the B<r>eturn value to be the result of the substitution.
283 Behavior in list context depends on the particular operator.
284 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
285 examples using these operators.
286
287 If the right argument is an expression rather than a search pattern,
288 substitution, or transliteration, it is interpreted as a search pattern at run
289 time.  Note that this means that its
290 contents will be interpolated twice, so
291
292     '\\' =~ q'\\';
293
294 is not ok, as the regex engine will end up trying to compile the
295 pattern C<\>, which it will consider a syntax error.
296
297 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
298 the logical sense.
299
300 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
301 (C<y///r>) is a syntax error.
302
303 =head2 Multiplicative Operators
304 X<operator, multiplicative>
305
306 Binary C<"*"> multiplies two numbers.
307 X<*>
308
309 Binary C<"/"> divides two numbers.
310 X</> X<slash>
311
312 Binary C<"%"> is the modulo operator, which computes the division
313 remainder of its first argument with respect to its second argument.
314 Given integer
315 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
316 C<$m> minus the largest multiple of C<$n> less than or equal to
317 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
318 smallest multiple of C<$n> that is not less than C<$m> (that is, the
319 result will be less than or equal to zero).  If the operands
320 C<$m> and C<$n> are floating point values and the absolute value of
321 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
322 the integer portion of C<$m> and C<$n> will be used in the operation
323 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
324 If the absolute value of the right operand (C<abs($n)>) is greater than
325 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
326 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
327 integer that makes C<$r> have the same sign as the right operand
328 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
329 and the absolute value less than that of C<$n>.
330 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
331 to the modulo operator as implemented by your C compiler.  This
332 operator is not as well defined for negative operands, but it will
333 execute faster.
334 X<%> X<remainder> X<modulo> X<mod>
335
336 Binary C<"x"> is the repetition operator.  In scalar context or if the left
337 operand is not enclosed in parentheses, it returns a string consisting
338 of the left operand repeated the number of times specified by the right
339 operand.  In list context, if the left operand is enclosed in
340 parentheses or is a list formed by C<qw/I<STRING>/>, it repeats the list.
341 If the right operand is zero or negative (raising a warning on
342 negative), it returns an empty string
343 or an empty list, depending on the context.
344 X<x>
345
346     print '-' x 80;             # print row of dashes
347
348     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
349
350     @ones = (1) x 80;           # a list of 80 1's
351     @ones = (5) x @ones;        # set all elements to 5
352
353
354 =head2 Additive Operators
355 X<operator, additive>
356
357 Binary C<"+"> returns the sum of two numbers.
358 X<+>
359
360 Binary C<"-"> returns the difference of two numbers.
361 X<->
362
363 Binary C<"."> concatenates two strings.
364 X<string, concatenation> X<concatenation>
365 X<cat> X<concat> X<concatenate> X<.>
366
367 =head2 Shift Operators
368 X<shift operator> X<operator, shift> X<<< << >>>
369 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
370 X<shl> X<shr> X<shift, right> X<shift, left>
371
372 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
373 number of bits specified by the right argument.  Arguments should be
374 integers.  (See also L</Integer Arithmetic>.)
375
376 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
377 the number of bits specified by the right argument.  Arguments should
378 be integers.  (See also L</Integer Arithmetic>.)
379
380 If S<C<use integer>> (see L</Integer Arithmetic>) is in force then
381 signed C integers are used (I<arithmetic shift>), otherwise unsigned C
382 integers are used (I<logical shift>), even for negative shiftees.
383 In arithmetic right shift the sign bit is replicated on the left,
384 in logical shift zero bits come in from the left.
385
386 Either way, the implementation isn't going to generate results larger
387 than the size of the integer type Perl was built with (32 bits or 64 bits).
388
389 Shifting by negative number of bits means the reverse shift: left
390 shift becomes right shift, right shift becomes left shift.  This is
391 unlike in C, where negative shift is undefined.
392
393 Shifting by more bits than the size of the integers means most of the
394 time zero (all bits fall off), except that under S<C<use integer>>
395 right overshifting a negative shiftee results in -1.  This is unlike
396 in C, where shifting by too many bits is undefined.  A common C
397 behavior is "shift by modulo wordbits", so that for example
398
399     1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1  # Common C behavior.
400
401 but that is completely accidental.
402
403 If you get tired of being subject to your platform's native integers,
404 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
405
406     print 20 << 20;  # 20971520
407     print 20 << 40;  # 5120 on 32-bit machines, 
408                      # 21990232555520 on 64-bit machines
409     use bigint;
410     print 20 << 100; # 25353012004564588029934064107520
411
412 =head2 Named Unary Operators
413 X<operator, named unary>
414
415 The various named unary operators are treated as functions with one
416 argument, with optional parentheses.
417
418 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
419 is followed by a left parenthesis as the next token, the operator and
420 arguments within parentheses are taken to be of highest precedence,
421 just like a normal function call.  For example,
422 because named unary operators are higher precedence than C<||>:
423
424     chdir $foo    || die;       # (chdir $foo) || die
425     chdir($foo)   || die;       # (chdir $foo) || die
426     chdir ($foo)  || die;       # (chdir $foo) || die
427     chdir +($foo) || die;       # (chdir $foo) || die
428
429 but, because C<"*"> is higher precedence than named operators:
430
431     chdir $foo * 20;    # chdir ($foo * 20)
432     chdir($foo) * 20;   # (chdir $foo) * 20
433     chdir ($foo) * 20;  # (chdir $foo) * 20
434     chdir +($foo) * 20; # chdir ($foo * 20)
435
436     rand 10 * 20;       # rand (10 * 20)
437     rand(10) * 20;      # (rand 10) * 20
438     rand (10) * 20;     # (rand 10) * 20
439     rand +(10) * 20;    # rand (10 * 20)
440
441 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
442 treated like named unary operators, but they don't follow this functional
443 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
444 equivalent to S<C<-f "$file.bak">>.
445 X<-X> X<filetest> X<operator, filetest>
446
447 See also L</"Terms and List Operators (Leftward)">.
448
449 =head2 Relational Operators
450 X<relational operator> X<operator, relational>
451
452 Perl operators that return true or false generally return values 
453 that can be safely used as numbers.  For example, the relational
454 operators in this section and the equality operators in the next
455 one return C<1> for true and a special version of the defined empty
456 string, C<"">, which counts as a zero but is exempt from warnings
457 about improper numeric conversions, just as S<C<"0 but true">> is.
458
459 Binary C<< "<" >> returns true if the left argument is numerically less than
460 the right argument.
461 X<< < >>
462
463 Binary C<< ">" >> returns true if the left argument is numerically greater
464 than the right argument.
465 X<< > >>
466
467 Binary C<< "<=" >> returns true if the left argument is numerically less than
468 or equal to the right argument.
469 X<< <= >>
470
471 Binary C<< ">=" >> returns true if the left argument is numerically greater
472 than or equal to the right argument.
473 X<< >= >>
474
475 Binary C<"lt"> returns true if the left argument is stringwise less than
476 the right argument.
477 X<< lt >>
478
479 Binary C<"gt"> returns true if the left argument is stringwise greater
480 than the right argument.
481 X<< gt >>
482
483 Binary C<"le"> returns true if the left argument is stringwise less than
484 or equal to the right argument.
485 X<< le >>
486
487 Binary C<"ge"> returns true if the left argument is stringwise greater
488 than or equal to the right argument.
489 X<< ge >>
490
491 =head2 Equality Operators
492 X<equality> X<equal> X<equals> X<operator, equality>
493
494 Binary C<< "==" >> returns true if the left argument is numerically equal to
495 the right argument.
496 X<==>
497
498 Binary C<< "!=" >> returns true if the left argument is numerically not equal
499 to the right argument.
500 X<!=>
501
502 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
503 argument is numerically less than, equal to, or greater than the right
504 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
505 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
506 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
507 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
508 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
509 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
510 X<< <=> >>
511 X<spaceship>
512
513     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
514     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
515
516 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
517 support C<"NaN">.)
518
519 Binary C<"eq"> returns true if the left argument is stringwise equal to
520 the right argument.
521 X<eq>
522
523 Binary C<"ne"> returns true if the left argument is stringwise not equal
524 to the right argument.
525 X<ne>
526
527 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
528 argument is stringwise less than, equal to, or greater than the right
529 argument.
530 X<cmp>
531
532 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
533 is described in the next section.
534 X<~~>
535
536 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
537 order specified by the current C<LC_COLLATE> locale if a S<C<use
538 locale>> form that includes collation is in effect.  See L<perllocale>.
539 Do not mix these with Unicode,
540 only use them with legacy 8-bit locale encodings.
541 The standard C<L<Unicode::Collate>> and
542 C<L<Unicode::Collate::Locale>> modules offer much more powerful
543 solutions to collation issues.
544
545 For case-insensitive comparisions, look at the L<perlfunc/fc> case-folding
546 function, available in Perl v5.16 or later:
547
548     if ( fc($x) eq fc($y) ) { ... }
549
550 =head2 Smartmatch Operator
551
552 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
553 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
554 used implicitly in the C<when> construct described in L<perlsyn>, although
555 not all C<when> clauses call the smartmatch operator.  Unique among all of
556 Perl's operators, the smartmatch operator can recurse.  The smartmatch
557 operator is L<experimental|perlpolicy/experimental> and its behavior is
558 subject to change.
559
560 It is also unique in that all other Perl operators impose a context
561 (usually string or numeric context) on their operands, autoconverting
562 those operands to those imposed contexts.  In contrast, smartmatch
563 I<infers> contexts from the actual types of its operands and uses that
564 type information to select a suitable comparison mechanism.
565
566 The C<~~> operator compares its operands "polymorphically", determining how
567 to compare them according to their actual types (numeric, string, array,
568 hash, etc.)  Like the equality operators with which it shares the same
569 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
570 read aloud as "in", "inside of", or "is contained in", because the left
571 operand is often looked for I<inside> the right operand.  That makes the
572 order of the operands to the smartmatch operand often opposite that of
573 the regular match operator.  In other words, the "smaller" thing is usually
574 placed in the left operand and the larger one in the right.
575
576 The behavior of a smartmatch depends on what type of things its arguments
577 are, as determined by the following table.  The first row of the table
578 whose types apply determines the smartmatch behavior.  Because what
579 actually happens is mostly determined by the type of the second operand,
580 the table is sorted on the right operand instead of on the left.
581
582  Left      Right      Description and pseudocode                               
583  ===============================================================
584  Any       undef      check whether Any is undefined                    
585                 like: !defined Any
586
587  Any       Object     invoke ~~ overloading on Object, or die
588
589  Right operand is an ARRAY:
590
591  Left      Right      Description and pseudocode                               
592  ===============================================================
593  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
594                 like: (ARRAY1[0] ~~ ARRAY2[0])
595                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
596  HASH      ARRAY      any ARRAY elements exist as HASH keys             
597                 like: grep { exists HASH->{$_} } ARRAY
598  Regexp    ARRAY      any ARRAY elements pattern match Regexp
599                 like: grep { /Regexp/ } ARRAY
600  undef     ARRAY      undef in ARRAY                                    
601                 like: grep { !defined } ARRAY
602  Any       ARRAY      smartmatch each ARRAY element[3]                   
603                 like: grep { Any ~~ $_ } ARRAY
604
605  Right operand is a HASH:
606
607  Left      Right      Description and pseudocode                               
608  ===============================================================
609  HASH1     HASH2      all same keys in both HASHes                      
610                 like: keys HASH1 ==
611                          grep { exists HASH2->{$_} } keys HASH1
612  ARRAY     HASH       any ARRAY elements exist as HASH keys             
613                 like: grep { exists HASH->{$_} } ARRAY
614  Regexp    HASH       any HASH keys pattern match Regexp                
615                 like: grep { /Regexp/ } keys HASH
616  undef     HASH       always false (undef can't be a key)               
617                 like: 0 == 1
618  Any       HASH       HASH key existence                                
619                 like: exists HASH->{Any}
620
621  Right operand is CODE:
622
623  Left      Right      Description and pseudocode                               
624  ===============================================================
625  ARRAY     CODE       sub returns true on all ARRAY elements[1]
626                 like: !grep { !CODE->($_) } ARRAY
627  HASH      CODE       sub returns true on all HASH keys[1]
628                 like: !grep { !CODE->($_) } keys HASH
629  Any       CODE       sub passed Any returns true              
630                 like: CODE->(Any)
631
632 Right operand is a Regexp:
633
634  Left      Right      Description and pseudocode                               
635  ===============================================================
636  ARRAY     Regexp     any ARRAY elements match Regexp                   
637                 like: grep { /Regexp/ } ARRAY
638  HASH      Regexp     any HASH keys match Regexp                        
639                 like: grep { /Regexp/ } keys HASH
640  Any       Regexp     pattern match                                     
641                 like: Any =~ /Regexp/
642
643  Other:
644
645  Left      Right      Description and pseudocode                               
646  ===============================================================
647  Object    Any        invoke ~~ overloading on Object,
648                       or fall back to...
649
650  Any       Num        numeric equality                                  
651                  like: Any == Num
652  Num       nummy[4]    numeric equality
653                  like: Num == nummy
654  undef     Any        check whether undefined
655                  like: !defined(Any)
656  Any       Any        string equality                                   
657                  like: Any eq Any
658
659
660 Notes:
661
662 =over
663
664 =item 1.
665 Empty hashes or arrays match. 
666
667 =item 2.
668 That is, each element smartmatches the element of the same index in the other array.[3]
669
670 =item 3.
671 If a circular reference is found, fall back to referential equality. 
672
673 =item 4.
674 Either an actual number, or a string that looks like one.
675
676 =back
677
678 The smartmatch implicitly dereferences any non-blessed hash or array
679 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
680 For blessed references, the C<I<Object>> entries apply.  Smartmatches
681 involving hashes only consider hash keys, never hash values.
682
683 The "like" code entry is not always an exact rendition.  For example, the
684 smartmatch operator short-circuits whenever possible, but C<grep> does
685 not.  Also, C<grep> in scalar context returns the number of matches, but
686 C<~~> returns only true or false.
687
688 Unlike most operators, the smartmatch operator knows to treat C<undef>
689 specially:
690
691     use v5.10.1;
692     @array = (1, 2, 3, undef, 4, 5);
693     say "some elements undefined" if undef ~~ @array;
694
695 Each operand is considered in a modified scalar context, the modification
696 being that array and hash variables are passed by reference to the
697 operator, which implicitly dereferences them.  Both elements
698 of each pair are the same:
699
700     use v5.10.1;
701
702     my %hash = (red    => 1, blue   => 2, green  => 3,
703                 orange => 4, yellow => 5, purple => 6,
704                 black  => 7, grey   => 8, white  => 9);
705
706     my @array = qw(red blue green);
707
708     say "some array elements in hash keys" if  @array ~~  %hash;
709     say "some array elements in hash keys" if \@array ~~ \%hash;
710
711     say "red in array" if "red" ~~  @array;
712     say "red in array" if "red" ~~ \@array;
713
714     say "some keys end in e" if /e$/ ~~  %hash;
715     say "some keys end in e" if /e$/ ~~ \%hash;
716
717 Two arrays smartmatch if each element in the first array smartmatches
718 (that is, is "in") the corresponding element in the second array,
719 recursively.
720
721     use v5.10.1;
722     my @little = qw(red blue green);
723     my @bigger = ("red", "blue", [ "orange", "green" ] );
724     if (@little ~~ @bigger) {  # true!
725         say "little is contained in bigger";
726     } 
727
728 Because the smartmatch operator recurses on nested arrays, this
729 will still report that "red" is in the array.
730
731     use v5.10.1;
732     my @array = qw(red blue green);
733     my $nested_array = [[[[[[[ @array ]]]]]]];
734     say "red in array" if "red" ~~ $nested_array;
735
736 If two arrays smartmatch each other, then they are deep
737 copies of each others' values, as this example reports:
738
739     use v5.12.0;
740     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
741     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
742
743     if (@a ~~ @b && @b ~~ @a) {
744         say "a and b are deep copies of each other";
745     } 
746     elsif (@a ~~ @b) {
747         say "a smartmatches in b";
748     } 
749     elsif (@b ~~ @a) {
750         say "b smartmatches in a";
751     } 
752     else {
753         say "a and b don't smartmatch each other at all";
754     } 
755
756
757 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
758 are deep copies of each other", it now reports that C<"b smartmatches in a">.
759 That's because the corresponding position in C<@a> contains an array that
760 (eventually) has a 4 in it.
761
762 Smartmatching one hash against another reports whether both contain the
763 same keys, no more and no less.  This could be used to see whether two
764 records have the same field names, without caring what values those fields
765 might have.  For example:
766
767     use v5.10.1;
768     sub make_dogtag {
769         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
770
771         my ($class, $init_fields) = @_;
772
773         die "Must supply (only) name, rank, and serial number"
774             unless $init_fields ~~ $REQUIRED_FIELDS;
775
776         ...
777     }
778
779 However, this only does what you mean if C<$init_fields> is indeed a hash
780 reference. The condition C<$init_fields ~~ $REQUIRED_FIELDS> also allows the
781 strings C<"name">, C<"rank">, C<"serial_num"> as well as any array reference
782 that contains C<"name"> or C<"rank"> or C<"serial_num"> anywhere to pass
783 through.
784
785 The smartmatch operator is most often used as the implicit operator of a
786 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
787
788 =head3 Smartmatching of Objects
789
790 To avoid relying on an object's underlying representation, if the
791 smartmatch's right operand is an object that doesn't overload C<~~>,
792 it raises the exception "C<Smartmatching a non-overloaded object
793 breaks encapsulation>".  That's because one has no business digging
794 around to see whether something is "in" an object.  These are all
795 illegal on objects without a C<~~> overload:
796
797     %hash ~~ $object
798        42 ~~ $object
799    "fred" ~~ $object
800
801 However, you can change the way an object is smartmatched by overloading
802 the C<~~> operator.  This is allowed to
803 extend the usual smartmatch semantics.
804 For objects that do have an C<~~> overload, see L<overload>.
805
806 Using an object as the left operand is allowed, although not very useful.
807 Smartmatching rules take precedence over overloading, so even if the
808 object in the left operand has smartmatch overloading, this will be
809 ignored.  A left operand that is a non-overloaded object falls back on a
810 string or numeric comparison of whatever the C<ref> operator returns.  That
811 means that
812
813     $object ~~ X
814
815 does I<not> invoke the overload method with C<I<X>> as an argument.
816 Instead the above table is consulted as normal, and based on the type of
817 C<I<X>>, overloading may or may not be invoked.  For simple strings or
818 numbers, "in" becomes equivalent to this:
819
820     $object ~~ $number          ref($object) == $number
821     $object ~~ $string          ref($object) eq $string 
822
823 For example, this reports that the handle smells IOish
824 (but please don't really do this!):
825
826     use IO::Handle;
827     my $fh = IO::Handle->new();
828     if ($fh ~~ /\bIO\b/) {
829         say "handle smells IOish";
830     } 
831
832 That's because it treats C<$fh> as a string like
833 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
834
835 =head2 Bitwise And
836 X<operator, bitwise, and> X<bitwise and> X<&>
837
838 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
839 warning is currently raised, the result is not well defined when this operation
840 is performed on operands that aren't either numbers (see
841 L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String Operators>).
842
843 Note that C<"&"> has lower priority than relational operators, so for example
844 the parentheses are essential in a test like
845
846     print "Even\n" if ($x & 1) == 0;
847
848 If the experimental "bitwise" feature is enabled via S<C<use feature
849 'bitwise'>>, then this operator always treats its operand as numbers.  This
850 feature produces a warning unless you also use C<S<no warnings
851 'experimental::bitwise'>>.
852
853 =head2 Bitwise Or and Exclusive Or
854 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
855 X<bitwise xor> X<^>
856
857 Binary C<"|"> returns its operands ORed together bit by bit.
858
859 Binary C<"^"> returns its operands XORed together bit by bit.
860
861 Although no warning is currently raised, the results are not well
862 defined when these operations are performed on operands that aren't either
863 numbers (see L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String
864 Operators>).
865
866 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
867 for example the parentheses are essential in a test like
868
869     print "false\n" if (8 | 2) != 10;
870
871 If the experimental "bitwise" feature is enabled via S<C<use feature
872 'bitwise'>>, then this operator always treats its operand as numbers.  This
873 feature produces a warning unless you also use S<C<no warnings
874 'experimental::bitwise'>>.
875
876 =head2 C-style Logical And
877 X<&&> X<logical and> X<operator, logical, and>
878
879 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
880 if the left operand is false, the right operand is not even evaluated.
881 Scalar or list context propagates down to the right operand if it
882 is evaluated.
883
884 =head2 C-style Logical Or
885 X<||> X<operator, logical, or>
886
887 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
888 if the left operand is true, the right operand is not even evaluated.
889 Scalar or list context propagates down to the right operand if it
890 is evaluated.
891
892 =head2 Logical Defined-Or
893 X<//> X<operator, logical, defined-or>
894
895 Although it has no direct equivalent in C, Perl's C<//> operator is related
896 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
897 tests the left hand side's definedness instead of its truth.  Thus,
898 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
899 otherwise, the value of C<< EXPR2 >> is returned.
900 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
901 in the context of C<< // >> itself).  Usually,
902 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
903 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
904 cannot).  This is very useful for
905 providing default values for variables.  If you actually want to test if
906 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
907
908 The C<||>, C<//> and C<&&> operators return the last value evaluated
909 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
910 portable way to find out the home directory might be:
911
912     $home =  $ENV{HOME}
913           // $ENV{LOGDIR}
914           // (getpwuid($<))[7]
915           // die "You're homeless!\n";
916
917 In particular, this means that you shouldn't use this
918 for selecting between two aggregates for assignment:
919
920     @a = @b || @c;            # This doesn't do the right thing
921     @a = scalar(@b) || @c;    # because it really means this.
922     @a = @b ? @b : @c;        # This works fine, though.
923
924 As alternatives to C<&&> and C<||> when used for
925 control flow, Perl provides the C<and> and C<or> operators (see below).
926 The short-circuit behavior is identical.  The precedence of C<"and">
927 and C<"or"> is much lower, however, so that you can safely use them after a
928 list operator without the need for parentheses:
929
930     unlink "alpha", "beta", "gamma"
931             or gripe(), next LINE;
932
933 With the C-style operators that would have been written like this:
934
935     unlink("alpha", "beta", "gamma")
936             || (gripe(), next LINE);
937
938 It would be even more readable to write that this way:
939
940     unless(unlink("alpha", "beta", "gamma")) {
941         gripe();
942         next LINE;
943     } 
944
945 Using C<"or"> for assignment is unlikely to do what you want; see below.
946
947 =head2 Range Operators
948 X<operator, range> X<range> X<..> X<...>
949
950 Binary C<".."> is the range operator, which is really two different
951 operators depending on the context.  In list context, it returns a
952 list of values counting (up by ones) from the left value to the right
953 value.  If the left value is greater than the right value then it
954 returns the empty list.  The range operator is useful for writing
955 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
956 the current implementation, no temporary array is created when the
957 range operator is used as the expression in C<foreach> loops, but older
958 versions of Perl might burn a lot of memory when you write something
959 like this:
960
961     for (1 .. 1_000_000) {
962         # code
963     }
964
965 The range operator also works on strings, using the magical
966 auto-increment, see below.
967
968 In scalar context, C<".."> returns a boolean value.  The operator is
969 bistable, like a flip-flop, and emulates the line-range (comma)
970 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
971 maintains its own boolean state, even across calls to a subroutine
972 that contains it.  It is false as long as its left operand is false.
973 Once the left operand is true, the range operator stays true until the
974 right operand is true, I<AFTER> which the range operator becomes false
975 again.  It doesn't become false till the next time the range operator
976 is evaluated.  It can test the right operand and become false on the
977 same evaluation it became true (as in B<awk>), but it still returns
978 true once.  If you don't want it to test the right operand until the
979 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
980 two.  In all other regards, C<"..."> behaves just like C<".."> does.
981
982 The right operand is not evaluated while the operator is in the
983 "false" state, and the left operand is not evaluated while the
984 operator is in the "true" state.  The precedence is a little lower
985 than || and &&.  The value returned is either the empty string for
986 false, or a sequence number (beginning with 1) for true.  The sequence
987 number is reset for each range encountered.  The final sequence number
988 in a range has the string C<"E0"> appended to it, which doesn't affect
989 its numeric value, but gives you something to search for if you want
990 to exclude the endpoint.  You can exclude the beginning point by
991 waiting for the sequence number to be greater than 1.
992
993 If either operand of scalar C<".."> is a constant expression,
994 that operand is considered true if it is equal (C<==>) to the current
995 input line number (the C<$.> variable).
996
997 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
998 but that is only an issue if you use a floating point expression; when
999 implicitly using C<$.> as described in the previous paragraph, the
1000 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
1001 is set to a floating point value and you are not reading from a file.
1002 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
1003 you want in scalar context because each of the operands are evaluated
1004 using their integer representation.
1005
1006 Examples:
1007
1008 As a scalar operator:
1009
1010     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1011                                #  if ($. == 101 .. $. == 200) { print; }
1012
1013     next LINE if (1 .. /^$/);  # skip header lines, short for
1014                                #   next LINE if ($. == 1 .. /^$/);
1015                                # (typically in a loop labeled LINE)
1016
1017     s/^/> / if (/^$/ .. eof());  # quote body
1018
1019     # parse mail messages
1020     while (<>) {
1021         $in_header =   1  .. /^$/;
1022         $in_body   = /^$/ .. eof;
1023         if ($in_header) {
1024             # do something
1025         } else { # in body
1026             # do something else
1027         }
1028     } continue {
1029         close ARGV if eof;             # reset $. each file
1030     }
1031
1032 Here's a simple example to illustrate the difference between
1033 the two range operators:
1034
1035     @lines = ("   - Foo",
1036               "01 - Bar",
1037               "1  - Baz",
1038               "   - Quux");
1039
1040     foreach (@lines) {
1041         if (/0/ .. /1/) {
1042             print "$_\n";
1043         }
1044     }
1045
1046 This program will print only the line containing "Bar".  If
1047 the range operator is changed to C<...>, it will also print the
1048 "Baz" line.
1049
1050 And now some examples as a list operator:
1051
1052     for (101 .. 200) { print }      # print $_ 100 times
1053     @foo = @foo[0 .. $#foo];        # an expensive no-op
1054     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1055
1056 The range operator (in list context) makes use of the magical
1057 auto-increment algorithm if the operands are strings.  You
1058 can say
1059
1060     @alphabet = ("A" .. "Z");
1061
1062 to get all normal letters of the English alphabet, or
1063
1064     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1065
1066 to get a hexadecimal digit, or
1067
1068     @z2 = ("01" .. "31");
1069     print $z2[$mday];
1070
1071 to get dates with leading zeros.
1072
1073 If the final value specified is not in the sequence that the magical
1074 increment would produce, the sequence goes until the next value would
1075 be longer than the final value specified.
1076
1077 As of Perl 5.26, the list-context range operator on strings works as expected
1078 in the scope of L<< S<C<"use feature 'unicode_strings">>|feature/The
1079 'unicode_strings' feature >>. In previous versions, and outside the scope of
1080 that feature, it exhibits L<perlunicode/The "Unicode Bug">: its behavior
1081 depends on the internal encoding of the range endpoint.
1082
1083 If the initial value specified isn't part of a magical increment
1084 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1085 only the initial value will be returned.  So the following will only
1086 return an alpha:
1087
1088     use charnames "greek";
1089     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1090
1091 To get the 25 traditional lowercase Greek letters, including both sigmas,
1092 you could use this instead:
1093
1094     use charnames "greek";
1095     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1096                                         ..
1097                                      ord("\N{omega}") 
1098                                    );
1099
1100 However, because there are I<many> other lowercase Greek characters than
1101 just those, to match lowercase Greek characters in a regular expression,
1102 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1103 L<experimental feature|perlrecharclass/Extended Bracketed Character
1104 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1105
1106 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1107 return two elements in list context.
1108
1109     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1110
1111 =head2 Conditional Operator
1112 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1113
1114 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1115 like an if-then-else.  If the argument before the C<?> is true, the
1116 argument before the C<:> is returned, otherwise the argument after the
1117 C<:> is returned.  For example:
1118
1119     printf "I have %d dog%s.\n", $n,
1120             ($n == 1) ? "" : "s";
1121
1122 Scalar or list context propagates downward into the 2nd
1123 or 3rd argument, whichever is selected.
1124
1125     $x = $ok ? $y : $z;  # get a scalar
1126     @x = $ok ? @y : @z;  # get an array
1127     $x = $ok ? @y : @z;  # oops, that's just a count!
1128
1129 The operator may be assigned to if both the 2nd and 3rd arguments are
1130 legal lvalues (meaning that you can assign to them):
1131
1132     ($x_or_y ? $x : $y) = $z;
1133
1134 Because this operator produces an assignable result, using assignments
1135 without parentheses will get you in trouble.  For example, this:
1136
1137     $x % 2 ? $x += 10 : $x += 2
1138
1139 Really means this:
1140
1141     (($x % 2) ? ($x += 10) : $x) += 2
1142
1143 Rather than this:
1144
1145     ($x % 2) ? ($x += 10) : ($x += 2)
1146
1147 That should probably be written more simply as:
1148
1149     $x += ($x % 2) ? 10 : 2;
1150
1151 =head2 Assignment Operators
1152 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1153 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1154 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1155
1156 C<"="> is the ordinary assignment operator.
1157
1158 Assignment operators work as in C.  That is,
1159
1160     $x += 2;
1161
1162 is equivalent to
1163
1164     $x = $x + 2;
1165
1166 although without duplicating any side effects that dereferencing the lvalue
1167 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1168 The following are recognized:
1169
1170     **=    +=    *=    &=    &.=    <<=    &&=
1171            -=    /=    |=    |.=    >>=    ||=
1172            .=    %=    ^=    ^.=           //=
1173                  x=
1174
1175 Although these are grouped by family, they all have the precedence
1176 of assignment.  These combined assignment operators can only operate on
1177 scalars, whereas the ordinary assignment operator can assign to arrays,
1178 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1179 and L<perldata/List value constructors>, and L<perlref/Assigning to
1180 References>.)
1181
1182 Unlike in C, the scalar assignment operator produces a valid lvalue.
1183 Modifying an assignment is equivalent to doing the assignment and
1184 then modifying the variable that was assigned to.  This is useful
1185 for modifying a copy of something, like this:
1186
1187     ($tmp = $global) =~ tr/13579/24680/;
1188
1189 Although as of 5.14, that can be also be accomplished this way:
1190
1191     use v5.14;
1192     $tmp = ($global =~  tr/13579/24680/r);
1193
1194 Likewise,
1195
1196     ($x += 2) *= 3;
1197
1198 is equivalent to
1199
1200     $x += 2;
1201     $x *= 3;
1202
1203 Similarly, a list assignment in list context produces the list of
1204 lvalues assigned to, and a list assignment in scalar context returns
1205 the number of elements produced by the expression on the right hand
1206 side of the assignment.
1207
1208 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1209 Perl 5.22 and experimental.  See L</Bitwise String Operators>.
1210
1211 =head2 Comma Operator
1212 X<comma> X<operator, comma> X<,>
1213
1214 Binary C<","> is the comma operator.  In scalar context it evaluates
1215 its left argument, throws that value away, then evaluates its right
1216 argument and returns that value.  This is just like C's comma operator.
1217
1218 In list context, it's just the list argument separator, and inserts
1219 both its arguments into the list.  These arguments are also evaluated
1220 from left to right.
1221
1222 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1223 for the comma except that it causes a
1224 word on its left to be interpreted as a string if it begins with a letter
1225 or underscore and is composed only of letters, digits and underscores.
1226 This includes operands that might otherwise be interpreted as operators,
1227 constants, single number v-strings or function calls.  If in doubt about
1228 this behavior, the left operand can be quoted explicitly.
1229
1230 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1231 or list argument separator, according to context.
1232
1233 For example:
1234
1235     use constant FOO => "something";
1236
1237     my %h = ( FOO => 23 );
1238
1239 is equivalent to:
1240
1241     my %h = ("FOO", 23);
1242
1243 It is I<NOT>:
1244
1245     my %h = ("something", 23);
1246
1247 The C<< => >> operator is helpful in documenting the correspondence
1248 between keys and values in hashes, and other paired elements in lists.
1249
1250     %hash = ( $key => $value );
1251     login( $username => $password );
1252
1253 The special quoting behavior ignores precedence, and hence may apply to
1254 I<part> of the left operand:
1255
1256     print time.shift => "bbb";
1257
1258 That example prints something like C<"1314363215shiftbbb">, because the
1259 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1260 the fact that C<time.shift> is the entire left operand.
1261
1262 =head2 List Operators (Rightward)
1263 X<operator, list, rightward> X<list operator>
1264
1265 On the right side of a list operator, the comma has very low precedence,
1266 such that it controls all comma-separated expressions found there.
1267 The only operators with lower precedence are the logical operators
1268 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1269 operators without the need for parentheses:
1270
1271     open HANDLE, "< :encoding(UTF-8)", "filename"
1272         or die "Can't open: $!\n";
1273
1274 However, some people find that code harder to read than writing
1275 it with parentheses:
1276
1277     open(HANDLE, "< :encoding(UTF-8)", "filename")
1278         or die "Can't open: $!\n";
1279
1280 in which case you might as well just use the more customary C<"||"> operator:
1281
1282     open(HANDLE, "< :encoding(UTF-8)", "filename")
1283         || die "Can't open: $!\n";
1284
1285 See also discussion of list operators in L</Terms and List Operators (Leftward)>.
1286
1287 =head2 Logical Not
1288 X<operator, logical, not> X<not>
1289
1290 Unary C<"not"> returns the logical negation of the expression to its right.
1291 It's the equivalent of C<"!"> except for the very low precedence.
1292
1293 =head2 Logical And
1294 X<operator, logical, and> X<and>
1295
1296 Binary C<"and"> returns the logical conjunction of the two surrounding
1297 expressions.  It's equivalent to C<&&> except for the very low
1298 precedence.  This means that it short-circuits: the right
1299 expression is evaluated only if the left expression is true.
1300
1301 =head2 Logical or and Exclusive Or
1302 X<operator, logical, or> X<operator, logical, xor>
1303 X<operator, logical, exclusive or>
1304 X<or> X<xor>
1305
1306 Binary C<"or"> returns the logical disjunction of the two surrounding
1307 expressions.  It's equivalent to C<||> except for the very low precedence.
1308 This makes it useful for control flow:
1309
1310     print FH $data              or die "Can't write to FH: $!";
1311
1312 This means that it short-circuits: the right expression is evaluated
1313 only if the left expression is false.  Due to its precedence, you must
1314 be careful to avoid using it as replacement for the C<||> operator.
1315 It usually works out better for flow control than in assignments:
1316
1317     $x = $y or $z;              # bug: this is wrong
1318     ($x = $y) or $z;            # really means this
1319     $x = $y || $z;              # better written this way
1320
1321 However, when it's a list-context assignment and you're trying to use
1322 C<||> for control flow, you probably need C<"or"> so that the assignment
1323 takes higher precedence.
1324
1325     @info = stat($file) || die;     # oops, scalar sense of stat!
1326     @info = stat($file) or die;     # better, now @info gets its due
1327
1328 Then again, you could always use parentheses.
1329
1330 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1331 It cannot short-circuit (of course).
1332
1333 There is no low precedence operator for defined-OR.
1334
1335 =head2 C Operators Missing From Perl
1336 X<operator, missing from perl> X<&> X<*>
1337 X<typecasting> X<(TYPE)>
1338
1339 Here is what C has that Perl doesn't:
1340
1341 =over 8
1342
1343 =item unary &
1344
1345 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1346
1347 =item unary *
1348
1349 Dereference-address operator.  (Perl's prefix dereferencing
1350 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1351
1352 =item (TYPE)
1353
1354 Type-casting operator.
1355
1356 =back
1357
1358 =head2 Quote and Quote-like Operators
1359 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1360 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1361 X<escape sequence> X<escape>
1362
1363 While we usually think of quotes as literal values, in Perl they
1364 function as operators, providing various kinds of interpolating and
1365 pattern matching capabilities.  Perl provides customary quote characters
1366 for these behaviors, but also provides a way for you to choose your
1367 quote character for any of them.  In the following table, a C<{}> represents
1368 any pair of delimiters you choose.
1369
1370     Customary  Generic        Meaning        Interpolates
1371         ''       q{}          Literal             no
1372         ""      qq{}          Literal             yes
1373         ``      qx{}          Command             yes*
1374                 qw{}         Word list            no
1375         //       m{}       Pattern match          yes*
1376                 qr{}          Pattern             yes*
1377                  s{}{}      Substitution          yes*
1378                 tr{}{}    Transliteration         no (but see below)
1379                  y{}{}    Transliteration         no (but see below)
1380         <<EOF                 here-doc            yes*
1381
1382         * unless the delimiter is ''.
1383
1384 Non-bracketing delimiters use the same character fore and aft, but the four
1385 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1386 that
1387
1388     q{foo{bar}baz}
1389
1390 is the same as
1391
1392     'foo{bar}baz'
1393
1394 Note, however, that this does not always work for quoting Perl code:
1395
1396     $s = q{ if($x eq "}") ... }; # WRONG
1397
1398 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1399 and from CPAN before then) is able to do this properly.
1400
1401 There can (and in some cases, must) be whitespace between the operator
1402 and the quoting
1403 characters, except when C<#> is being used as the quoting character.
1404 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1405 operator C<q> followed by a comment.  Its argument will be taken
1406 from the next line.  This allows you to write:
1407
1408     s {foo}  # Replace foo
1409       {bar}  # with bar.
1410
1411 The cases where whitespace must be used are when the quoting character
1412 is a word character (meaning it matches C</\w/>):
1413
1414     q XfooX # Works: means the string 'foo'
1415     qXfooX  # WRONG!
1416
1417 The following escape sequences are available in constructs that interpolate,
1418 and in transliterations:
1419 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1420 X<\o{}>
1421
1422     Sequence     Note  Description
1423     \t                  tab               (HT, TAB)
1424     \n                  newline           (NL)
1425     \r                  return            (CR)
1426     \f                  form feed         (FF)
1427     \b                  backspace         (BS)
1428     \a                  alarm (bell)      (BEL)
1429     \e                  escape            (ESC)
1430     \x{263A}     [1,8]  hex char          (example: SMILEY)
1431     \x1b         [2,8]  restricted range hex char (example: ESC)
1432     \N{name}     [3]    named Unicode character or character sequence
1433     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1434     \c[          [5]    control char      (example: chr(27))
1435     \o{23072}    [6,8]  octal char        (example: SMILEY)
1436     \033         [7,8]  restricted range octal char  (example: ESC)
1437
1438 =over 4
1439
1440 =item [1]
1441
1442 The result is the character specified by the hexadecimal number between
1443 the braces.  See L</[8]> below for details on which character.
1444
1445 Only hexadecimal digits are valid between the braces.  If an invalid
1446 character is encountered, a warning will be issued and the invalid
1447 character and all subsequent characters (valid or invalid) within the
1448 braces will be discarded.
1449
1450 If there are no valid digits between the braces, the generated character is
1451 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1452 will not cause a warning (currently).
1453
1454 =item [2]
1455
1456 The result is the character specified by the hexadecimal number in the range
1457 0x00 to 0xFF.  See L</[8]> below for details on which character.
1458
1459 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1460 by fewer than two valid digits, any valid digits will be zero-padded.  This
1461 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1462 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1463 two valid digits will result in a warning.  Note that although the warning
1464 says the illegal character is ignored, it is only ignored as part of the
1465 escape and will still be used as the subsequent character in the string.
1466 For example:
1467
1468   Original    Result    Warns?
1469   "\x7"       "\x07"    no
1470   "\x"        "\x00"    no
1471   "\x7q"      "\x07q"   yes
1472   "\xq"       "\x00q"   yes
1473
1474 =item [3]
1475
1476 The result is the Unicode character or character sequence given by I<name>.
1477 See L<charnames>.
1478
1479 =item [4]
1480
1481 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1482 point is I<hexadecimal number>.
1483
1484 =item [5]
1485
1486 The character following C<\c> is mapped to some other character as shown in the
1487 table:
1488
1489  Sequence   Value
1490    \c@      chr(0)
1491    \cA      chr(1)
1492    \ca      chr(1)
1493    \cB      chr(2)
1494    \cb      chr(2)
1495    ...
1496    \cZ      chr(26)
1497    \cz      chr(26)
1498    \c[      chr(27)
1499                      # See below for chr(28)
1500    \c]      chr(29)
1501    \c^      chr(30)
1502    \c_      chr(31)
1503    \c?      chr(127) # (on ASCII platforms; see below for link to
1504                      #  EBCDIC discussion)
1505
1506 In other words, it's the character whose code point has had 64 xor'd with
1507 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1508 S<C<ord("?") ^ 64>> is 127, and
1509 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1510
1511 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1512 end of a string, because the backslash would be parsed as escaping the end
1513 quote.
1514
1515 On ASCII platforms, the resulting characters from the list above are the
1516 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1517 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1518 differences between these for ASCII versus EBCDIC platforms.
1519
1520 Use of any other character following the C<"c"> besides those listed above is
1521 discouraged, and as of Perl v5.20, the only characters actually allowed
1522 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1523 for any of the allowed other characters is that the value is derived by
1524 xor'ing with the seventh bit, which is 64, and a warning raised if
1525 enabled.  Using the non-allowed characters generates a fatal error.
1526
1527 To get platform independent controls, you can use C<\N{...}>.
1528
1529 =item [6]
1530
1531 The result is the character specified by the octal number between the braces.
1532 See L</[8]> below for details on which character.
1533
1534 If a character that isn't an octal digit is encountered, a warning is raised,
1535 and the value is based on the octal digits before it, discarding it and all
1536 following characters up to the closing brace.  It is a fatal error if there are
1537 no octal digits at all.
1538
1539 =item [7]
1540
1541 The result is the character specified by the three-digit octal number in the
1542 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1543 L</[8]> below for details on which character.
1544
1545 Some contexts allow 2 or even 1 digit, but any usage without exactly
1546 three digits, the first being a zero, may give unintended results.  (For
1547 example, in a regular expression it may be confused with a backreference;
1548 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1549 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1550 use this construct only for ordinals C<\077> and below, remembering to pad to
1551 the left with zeros to make three digits.  For larger ordinals, either use
1552 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1553 (which is portable between platforms with different character sets) or
1554 C<\x{}> instead.
1555
1556 =item [8]
1557
1558 Several constructs above specify a character by a number.  That number
1559 gives the character's position in the character set encoding (indexed from 0).
1560 This is called synonymously its ordinal, code position, or code point.  Perl
1561 works on platforms that have a native encoding currently of either ASCII/Latin1
1562 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1563 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1564 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1565 it as a Unicode code point and the result is the corresponding Unicode
1566 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1567 decimal, which is less than 256, so the number is interpreted in the native
1568 character set encoding.  In ASCII the character in the 80th position (indexed
1569 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1570 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1571 as a Unicode code point no matter what the native encoding is.  The name of the
1572 character in the 256th position (indexed by 0) in Unicode is
1573 C<LATIN CAPITAL LETTER A WITH MACRON>.
1574
1575 An exception to the above rule is that S<C<\N{U+I<hex number>}>> is
1576 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1577 on EBCDIC platforms.
1578
1579 =back
1580
1581 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1582 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1583 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1584 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1585
1586 The following escape sequences are available in constructs that interpolate,
1587 but not in transliterations.
1588 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1589
1590     \l          lowercase next character only
1591     \u          titlecase (not uppercase!) next character only
1592     \L          lowercase all characters till \E or end of string
1593     \U          uppercase all characters till \E or end of string
1594     \F          foldcase all characters till \E or end of string
1595     \Q          quote (disable) pattern metacharacters till \E or
1596                 end of string
1597     \E          end either case modification or quoted section
1598                 (whichever was last seen)
1599
1600 See L<perlfunc/quotemeta> for the exact definition of characters that
1601 are quoted by C<\Q>.
1602
1603 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1604 C<\E> for each.  For example:
1605
1606  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1607  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1608
1609 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1610 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1611 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1612 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1613 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1614 case-mapping a single character can sometimes produce a sequence of
1615 several characters.
1616 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1617 for all locales but a UTF-8 one, where it instead uses the Unicode
1618 definition.
1619
1620 All systems use the virtual C<"\n"> to represent a line terminator,
1621 called a "newline".  There is no such thing as an unvarying, physical
1622 newline character.  It is only an illusion that the operating system,
1623 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1624 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1625 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1626 and on systems without a line terminator,
1627 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1628 you mean a "newline" for your system, but use the literal ASCII when you
1629 need an exact character.  For example, most networking protocols expect
1630 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1631 and although they often accept just C<"\012">, they seldom tolerate just
1632 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1633 you may be burned some day.
1634 X<newline> X<line terminator> X<eol> X<end of line>
1635 X<\n> X<\r> X<\r\n>
1636
1637 For constructs that do interpolate, variables beginning with "C<$>"
1638 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1639 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1640 But method calls such as C<< $obj->meth >> are not.
1641
1642 Interpolating an array or slice interpolates the elements in order,
1643 separated by the value of C<$">, so is equivalent to interpolating
1644 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1645 interpolated only if the name is enclosed in braces C<@{*}>, but the
1646 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1647
1648 For double-quoted strings, the quoting from C<\Q> is applied after
1649 interpolation and escapes are processed.
1650
1651     "abc\Qfoo\tbar$s\Exyz"
1652
1653 is equivalent to
1654
1655     "abc" . quotemeta("foo\tbar$s") . "xyz"
1656
1657 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1658 the quoting from C<\Q> is applied after interpolation is processed,
1659 but before escapes are processed.  This allows the pattern to match
1660 literally (except for C<$> and C<@>).  For example, the following matches:
1661
1662     '\s\t' =~ /\Q\s\t/
1663
1664 Because C<$> or C<@> trigger interpolation, you'll need to use something
1665 like C</\Quser\E\@\Qhost/> to match them literally.
1666
1667 Patterns are subject to an additional level of interpretation as a
1668 regular expression.  This is done as a second pass, after variables are
1669 interpolated, so that regular expressions may be incorporated into the
1670 pattern from the variables.  If this is not what you want, use C<\Q> to
1671 interpolate a variable literally.
1672
1673 Apart from the behavior described above, Perl does not expand
1674 multiple levels of interpolation.  In particular, contrary to the
1675 expectations of shell programmers, back-quotes do I<NOT> interpolate
1676 within double quotes, nor do single quotes impede evaluation of
1677 variables when used within double quotes.
1678
1679 =head2 Regexp Quote-Like Operators
1680 X<operator, regexp>
1681
1682 Here are the quote-like operators that apply to pattern
1683 matching and related activities.
1684
1685 =over 8
1686
1687 =item C<qr/I<STRING>/msixpodualn>
1688 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1689
1690 This operator quotes (and possibly compiles) its I<STRING> as a regular
1691 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1692 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no variable
1693 interpolation is done.  Returns a Perl value which may be used instead of the
1694 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1695 normalized version of the original pattern.  It magically differs from
1696 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1697 however, dereferencing it is not well defined (you currently get the 
1698 normalized version of the original pattern, but this may change).
1699
1700
1701 For example,
1702
1703     $rex = qr/my.STRING/is;
1704     print $rex;                 # prints (?si-xm:my.STRING)
1705     s/$rex/foo/;
1706
1707 is equivalent to
1708
1709     s/my.STRING/foo/is;
1710
1711 The result may be used as a subpattern in a match:
1712
1713     $re = qr/$pattern/;
1714     $string =~ /foo${re}bar/;   # can be interpolated in other
1715                                 # patterns
1716     $string =~ $re;             # or used standalone
1717     $string =~ /$re/;           # or this way
1718
1719 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1720 operator, using C<qr()> may have speed advantages in some situations,
1721 notably if the result of C<qr()> is used standalone:
1722
1723     sub match {
1724         my $patterns = shift;
1725         my @compiled = map qr/$_/i, @$patterns;
1726         grep {
1727             my $success = 0;
1728             foreach my $pat (@compiled) {
1729                 $success = 1, last if /$pat/;
1730             }
1731             $success;
1732         } @_;
1733     }
1734
1735 Precompilation of the pattern into an internal representation at
1736 the moment of C<qr()> avoids the need to recompile the pattern every
1737 time a match C</$pat/> is attempted.  (Perl has many other internal
1738 optimizations, but none would be triggered in the above example if
1739 we did not use C<qr()> operator.)
1740
1741 Options (specified by the following modifiers) are:
1742
1743     m   Treat string as multiple lines.
1744     s   Treat string as single line. (Make . match a newline)
1745     i   Do case-insensitive pattern matching.
1746     x   Use extended regular expressions; specifying two
1747         x's means \t and the SPACE character are ignored within
1748         square-bracketed character classes
1749     p   When matching preserve a copy of the matched string so
1750         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1751         defined (ignored starting in v5.20) as these are always
1752         defined starting in that relese
1753     o   Compile pattern only once.
1754     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1755         a's further restricts things to that that no ASCII
1756         character will match a non-ASCII one under /i.
1757     l   Use the current run-time locale's rules.
1758     u   Use Unicode rules.
1759     d   Use Unicode or native charset, as in 5.12 and earlier.
1760     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1761
1762 If a precompiled pattern is embedded in a larger pattern then the effect
1763 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1764 C</o> modifier has is not propagated, being restricted to those patterns
1765 explicitly using it.
1766
1767 The last four modifiers listed above, added in Perl 5.14,
1768 control the character set rules, but C</a> is the only one you are likely
1769 to want to specify explicitly; the other three are selected
1770 automatically by various pragmas.
1771
1772 See L<perlre> for additional information on valid syntax for I<STRING>, and
1773 for a detailed look at the semantics of regular expressions.  In
1774 particular, all modifiers except the largely obsolete C</o> are further
1775 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1776
1777 =item C<m/I<PATTERN>/msixpodualngc>
1778 X<m> X<operator, match>
1779 X<regexp, options> X<regexp> X<regex, options> X<regex>
1780 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1781
1782 =item C</I<PATTERN>/msixpodualngc>
1783
1784 Searches a string for a pattern match, and in scalar context returns
1785 true if it succeeds, false if it fails.  If no string is specified
1786 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1787 string specified with C<=~> need not be an lvalue--it may be the
1788 result of an expression evaluation, but remember the C<=~> binds
1789 rather tightly.)  See also L<perlre>.
1790
1791 Options are as described in C<qr//> above; in addition, the following match
1792 process modifiers are available:
1793
1794  g  Match globally, i.e., find all occurrences.
1795  c  Do not reset search position on a failed match when /g is
1796     in effect.
1797
1798 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
1799 you can use any pair of non-whitespace (ASCII) characters
1800 as delimiters.  This is particularly useful for matching path names
1801 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
1802 the delimiter, then a match-only-once rule applies,
1803 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
1804 no variable interpolation is performed on the I<PATTERN>.
1805 When using a delimiter character valid in an identifier, whitespace is required
1806 after the C<m>.
1807
1808 I<PATTERN> may contain variables, which will be interpolated
1809 every time the pattern search is evaluated, except
1810 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1811 C<$|> are not interpolated because they look like end-of-string tests.)
1812 Perl will not recompile the pattern unless an interpolated
1813 variable that it contains changes.  You can force Perl to skip the
1814 test and never recompile by adding a C</o> (which stands for "once")
1815 after the trailing delimiter.
1816 Once upon a time, Perl would recompile regular expressions
1817 unnecessarily, and this modifier was useful to tell it not to do so, in the
1818 interests of speed.  But now, the only reasons to use C</o> are one of:
1819
1820 =over
1821
1822 =item 1
1823
1824 The variables are thousands of characters long and you know that they
1825 don't change, and you need to wring out the last little bit of speed by
1826 having Perl skip testing for that.  (There is a maintenance penalty for
1827 doing this, as mentioning C</o> constitutes a promise that you won't
1828 change the variables in the pattern.  If you do change them, Perl won't
1829 even notice.)
1830
1831 =item 2
1832
1833 you want the pattern to use the initial values of the variables
1834 regardless of whether they change or not.  (But there are saner ways
1835 of accomplishing this than using C</o>.)
1836
1837 =item 3
1838
1839 If the pattern contains embedded code, such as
1840
1841     use re 'eval';
1842     $code = 'foo(?{ $x })';
1843     /$code/
1844
1845 then perl will recompile each time, even though the pattern string hasn't
1846 changed, to ensure that the current value of C<$x> is seen each time.
1847 Use C</o> if you want to avoid this.
1848
1849 =back
1850
1851 The bottom line is that using C</o> is almost never a good idea.
1852
1853 =item The empty pattern C<//>
1854
1855 If the I<PATTERN> evaluates to the empty string, the last
1856 I<successfully> matched regular expression is used instead.  In this
1857 case, only the C<g> and C<c> flags on the empty pattern are honored;
1858 the other flags are taken from the original pattern.  If no match has
1859 previously succeeded, this will (silently) act instead as a genuine
1860 empty pattern (which will always match).
1861
1862 Note that it's possible to confuse Perl into thinking C<//> (the empty
1863 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1864 good about this, but some pathological cases might trigger this, such as
1865 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
1866 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
1867 will assume you meant defined-or.  If you meant the empty regex, just
1868 use parentheses or spaces to disambiguate, or even prefix the empty
1869 regex with an C<m> (so C<//> becomes C<m//>).
1870
1871 =item Matching in list context
1872
1873 If the C</g> option is not used, C<m//> in list context returns a
1874 list consisting of the subexpressions matched by the parentheses in the
1875 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1876 also set).  When there are no parentheses in the pattern, the return
1877 value is the list C<(1)> for success.  
1878 With or without parentheses, an empty list is returned upon failure.
1879
1880 Examples:
1881
1882  open(TTY, "+</dev/tty")
1883     || die "can't access /dev/tty: $!";
1884
1885  <TTY> =~ /^y/i && foo();       # do foo if desired
1886
1887  if (/Version: *([0-9.]*)/) { $version = $1; }
1888
1889  next if m#^/usr/spool/uucp#;
1890
1891  # poor man's grep
1892  $arg = shift;
1893  while (<>) {
1894     print if /$arg/o; # compile only once (no longer needed!)
1895  }
1896
1897  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1898
1899 This last example splits C<$foo> into the first two words and the
1900 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
1901 C<$Etc>.  The conditional is true if any variables were assigned; that is,
1902 if the pattern matched.
1903
1904 The C</g> modifier specifies global pattern matching--that is,
1905 matching as many times as possible within the string.  How it behaves
1906 depends on the context.  In list context, it returns a list of the
1907 substrings matched by any capturing parentheses in the regular
1908 expression.  If there are no parentheses, it returns a list of all
1909 the matched strings, as if there were parentheses around the whole
1910 pattern.
1911
1912 In scalar context, each execution of C<m//g> finds the next match,
1913 returning true if it matches, and false if there is no further match.
1914 The position after the last match can be read or set using the C<pos()>
1915 function; see L<perlfunc/pos>.  A failed match normally resets the
1916 search position to the beginning of the string, but you can avoid that
1917 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1918 string also resets the search position.
1919
1920 =item C<\G I<assertion>>
1921
1922 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1923 zero-width assertion that matches the exact position where the
1924 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1925 C<\G> assertion still anchors at C<pos()> as it was at the start of
1926 the operation (see L<perlfunc/pos>), but the match is of course only
1927 attempted once.  Using C<\G> without C</g> on a target string that has
1928 not previously had a C</g> match applied to it is the same as using
1929 the C<\A> assertion to match the beginning of the string.  Note also
1930 that, currently, C<\G> is only properly supported when anchored at the
1931 very beginning of the pattern.
1932
1933 Examples:
1934
1935     # list context
1936     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1937
1938     # scalar context
1939     local $/ = "";
1940     while ($paragraph = <>) {
1941         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1942             $sentences++;
1943         }
1944     }
1945     say $sentences;
1946
1947 Here's another way to check for sentences in a paragraph:
1948
1949  my $sentence_rx = qr{
1950     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1951                                 # whitespace
1952     \p{Lu}                      # capital letter
1953     .*?                         # a bunch of anything
1954     (?<= \S )                   # that ends in non-
1955                                 # whitespace
1956     (?<! \b [DMS]r  )           # but isn't a common abbr.
1957     (?<! \b Mrs )
1958     (?<! \b Sra )
1959     (?<! \b St  )
1960     [.?!]                       # followed by a sentence
1961                                 # ender
1962     (?= $ | \s )                # in front of end-of-string
1963                                 # or whitespace
1964  }sx;
1965  local $/ = "";
1966  while (my $paragraph = <>) {
1967     say "NEW PARAGRAPH";
1968     my $count = 0;
1969     while ($paragraph =~ /($sentence_rx)/g) {
1970         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1971     }
1972  }
1973
1974 Here's how to use C<m//gc> with C<\G>:
1975
1976     $_ = "ppooqppqq";
1977     while ($i++ < 2) {
1978         print "1: '";
1979         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1980         print "2: '";
1981         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1982         print "3: '";
1983         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1984     }
1985     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1986
1987 The last example should print:
1988
1989     1: 'oo', pos=4
1990     2: 'q', pos=5
1991     3: 'pp', pos=7
1992     1: '', pos=7
1993     2: 'q', pos=8
1994     3: '', pos=8
1995     Final: 'q', pos=8
1996
1997 Notice that the final match matched C<q> instead of C<p>, which a match
1998 without the C<\G> anchor would have done.  Also note that the final match
1999 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
2000 final match did indeed match C<p>, it's a good bet that you're running a
2001 very old (pre-5.6.0) version of Perl.
2002
2003 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
2004 combine several regexps like this to process a string part-by-part,
2005 doing different actions depending on which regexp matched.  Each
2006 regexp tries to match where the previous one leaves off.
2007
2008  $_ = <<'EOL';
2009     $url = URI::URL->new( "http://example.com/" );
2010     die if $url eq "xXx";
2011  EOL
2012
2013  LOOP: {
2014      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
2015      print(" lowercase"),    redo LOOP
2016                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
2017      print(" UPPERCASE"),    redo LOOP
2018                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2019      print(" Capitalized"),  redo LOOP
2020                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2021      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2022      print(" alphanumeric"), redo LOOP
2023                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2024      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2025      print ". That's all!\n";
2026  }
2027
2028 Here is the output (split into several lines):
2029
2030  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2031  line-noise lowercase line-noise lowercase line-noise lowercase
2032  lowercase line-noise lowercase lowercase line-noise lowercase
2033  lowercase line-noise MiXeD line-noise. That's all!
2034
2035 =item C<m?I<PATTERN>?msixpodualngc>
2036 X<?> X<operator, match-once>
2037
2038 =item C<?I<PATTERN>?msixpodualngc>
2039
2040 This is just like the C<m/I<PATTERN>/> search, except that it matches
2041 only once between calls to the C<reset()> operator.  This is a useful
2042 optimization when you want to see only the first occurrence of
2043 something in each file of a set of files, for instance.  Only C<m??>
2044 patterns local to the current package are reset.
2045
2046     while (<>) {
2047         if (m?^$?) {
2048                             # blank line between header and body
2049         }
2050     } continue {
2051         reset if eof;       # clear m?? status for next file
2052     }
2053
2054 Another example switched the first "latin1" encoding it finds
2055 to "utf8" in a pod file:
2056
2057     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2058
2059 The match-once behavior is controlled by the match delimiter being
2060 C<?>; with any other delimiter this is the normal C<m//> operator.
2061
2062 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2063 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2064 syntax error.  If you encounter this construct in older code, you can just add
2065 C<m>.
2066
2067 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2068 X<substitute> X<substitution> X<replace> X<regexp, replace>
2069 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2070
2071 Searches a string for a pattern, and if found, replaces that pattern
2072 with the replacement text and returns the number of substitutions
2073 made.  Otherwise it returns false (specifically, the empty string).
2074
2075 If the C</r> (non-destructive) option is used then it runs the
2076 substitution on a copy of the string and instead of returning the
2077 number of substitutions, it returns the copy whether or not a
2078 substitution occurred.  The original string is never changed when
2079 C</r> is used.  The copy will always be a plain string, even if the
2080 input is an object or a tied variable.
2081
2082 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2083 variable is searched and modified.  Unless the C</r> option is used,
2084 the string specified must be a scalar variable, an array element, a
2085 hash element, or an assignment to one of those; that is, some sort of
2086 scalar lvalue.
2087
2088 If the delimiter chosen is a single quote, no variable interpolation is
2089 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2090 I<PATTERN> contains a C<$> that looks like a variable rather than an
2091 end-of-string test, the variable will be interpolated into the pattern
2092 at run-time.  If you want the pattern compiled only once the first time
2093 the variable is interpolated, use the C</o> option.  If the pattern
2094 evaluates to the empty string, the last successfully executed regular
2095 expression is used instead.  See L<perlre> for further explanation on these.
2096
2097 Options are as with C<m//> with the addition of the following replacement
2098 specific options:
2099
2100     e   Evaluate the right side as an expression.
2101     ee  Evaluate the right side as a string then eval the
2102         result.
2103     r   Return substitution and leave the original string
2104         untouched.
2105
2106 Any non-whitespace delimiter may replace the slashes.  Add space after
2107 the C<s> when using a character allowed in identifiers.  If single quotes
2108 are used, no interpretation is done on the replacement string (the C</e>
2109 modifier overrides this, however).  Note that Perl treats backticks
2110 as normal delimiters; the replacement text is not evaluated as a command.
2111 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2112 its own pair of quotes, which may or may not be bracketing quotes, for example,
2113 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2114 replacement portion to be treated as a full-fledged Perl expression
2115 and evaluated right then and there.  It is, however, syntax checked at
2116 compile-time.  A second C<e> modifier will cause the replacement portion
2117 to be C<eval>ed before being run as a Perl expression.
2118
2119 Examples:
2120
2121     s/\bgreen\b/mauve/g;              # don't change wintergreen
2122
2123     $path =~ s|/usr/bin|/usr/local/bin|;
2124
2125     s/Login: $foo/Login: $bar/; # run-time pattern
2126
2127     ($foo = $bar) =~ s/this/that/;      # copy first, then
2128                                         # change
2129     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2130                                         # copy, then change
2131     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2132     $foo = $bar =~ s/this/that/r
2133                 =~ s/that/the other/r;  # Chained substitutes
2134                                         # using /r
2135     @foo = map { s/this/that/r } @bar   # /r is very useful in
2136                                         # maps
2137
2138     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2139
2140     $_ = 'abc123xyz';
2141     s/\d+/$&*2/e;               # yields 'abc246xyz'
2142     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2143     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2144
2145     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2146     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2147     s/^=(\w+)/pod($1)/ge;       # use function call
2148
2149     $_ = 'abc123xyz';
2150     $x = s/abc/def/r;           # $x is 'def123xyz' and
2151                                 # $_ remains 'abc123xyz'.
2152
2153     # expand variables in $_, but dynamics only, using
2154     # symbolic dereferencing
2155     s/\$(\w+)/${$1}/g;
2156
2157     # Add one to the value of any numbers in the string
2158     s/(\d+)/1 + $1/eg;
2159
2160     # Titlecase words in the last 30 characters only
2161     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2162
2163     # This will expand any embedded scalar variable
2164     # (including lexicals) in $_ : First $1 is interpolated
2165     # to the variable name, and then evaluated
2166     s/(\$\w+)/$1/eeg;
2167
2168     # Delete (most) C comments.
2169     $program =~ s {
2170         /\*     # Match the opening delimiter.
2171         .*?     # Match a minimal number of characters.
2172         \*/     # Match the closing delimiter.
2173     } []gsx;
2174
2175     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2176                                 # expensively
2177
2178     for ($variable) {           # trim whitespace in $variable,
2179                                 # cheap
2180         s/^\s+//;
2181         s/\s+$//;
2182     }
2183
2184     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2185
2186 Note the use of C<$> instead of C<\> in the last example.  Unlike
2187 B<sed>, we use the \<I<digit>> form only in the left hand side.
2188 Anywhere else it's $<I<digit>>.
2189
2190 Occasionally, you can't use just a C</g> to get all the changes
2191 to occur that you might want.  Here are two common cases:
2192
2193     # put commas in the right places in an integer
2194     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2195
2196     # expand tabs to 8-column spacing
2197     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2198
2199 =back
2200
2201 =head2 Quote-Like Operators
2202 X<operator, quote-like>
2203
2204 =over 4
2205
2206 =item C<q/I<STRING>/>
2207 X<q> X<quote, single> X<'> X<''>
2208
2209 =item C<'I<STRING>'>
2210
2211 A single-quoted, literal string.  A backslash represents a backslash
2212 unless followed by the delimiter or another backslash, in which case
2213 the delimiter or backslash is interpolated.
2214
2215     $foo = q!I said, "You said, 'She said it.'"!;
2216     $bar = q('This is it.');
2217     $baz = '\n';                # a two-character string
2218
2219 =item C<qq/I<STRING>/>
2220 X<qq> X<quote, double> X<"> X<"">
2221
2222 =item "I<STRING>"
2223
2224 A double-quoted, interpolated string.
2225
2226     $_ .= qq
2227      (*** The previous line contains the naughty word "$1".\n)
2228                 if /\b(tcl|java|python)\b/i;      # :-)
2229     $baz = "\n";                # a one-character string
2230
2231 =item C<qx/I<STRING>/>
2232 X<qx> X<`> X<``> X<backtick>
2233
2234 =item C<`I<STRING>`>
2235
2236 A string which is (possibly) interpolated and then executed as a
2237 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2238 pipes, and redirections will be honored.  The collected standard
2239 output of the command is returned; standard error is unaffected.  In
2240 scalar context, it comes back as a single (potentially multi-line)
2241 string, or C<undef> if the command failed.  In list context, returns a
2242 list of lines (however you've defined lines with C<$/> or
2243 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the command failed.
2244
2245 Because backticks do not affect standard error, use shell file descriptor
2246 syntax (assuming the shell supports this) if you care to address this.
2247 To capture a command's STDERR and STDOUT together:
2248
2249     $output = `cmd 2>&1`;
2250
2251 To capture a command's STDOUT but discard its STDERR:
2252
2253     $output = `cmd 2>/dev/null`;
2254
2255 To capture a command's STDERR but discard its STDOUT (ordering is
2256 important here):
2257
2258     $output = `cmd 2>&1 1>/dev/null`;
2259
2260 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2261 but leave its STDOUT to come out the old STDERR:
2262
2263     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2264
2265 To read both a command's STDOUT and its STDERR separately, it's easiest
2266 to redirect them separately to files, and then read from those files
2267 when the program is done:
2268
2269     system("program args 1>program.stdout 2>program.stderr");
2270
2271 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2272 For example:
2273
2274     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2275     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2276     print STDOUT `sort`;
2277
2278 will print the sorted contents of the file named F<"stuff">.
2279
2280 Using single-quote as a delimiter protects the command from Perl's
2281 double-quote interpolation, passing it on to the shell instead:
2282
2283     $perl_info  = qx(ps $$);            # that's Perl's $$
2284     $shell_info = qx'ps $$';            # that's the new shell's $$
2285
2286 How that string gets evaluated is entirely subject to the command
2287 interpreter on your system.  On most platforms, you will have to protect
2288 shell metacharacters if you want them treated literally.  This is in
2289 practice difficult to do, as it's unclear how to escape which characters.
2290 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2291 to emulate backticks safely.
2292
2293 On some platforms (notably DOS-like ones), the shell may not be
2294 capable of dealing with multiline commands, so putting newlines in
2295 the string may not get you what you want.  You may be able to evaluate
2296 multiple commands in a single line by separating them with the command
2297 separator character, if your shell supports that (for example, C<;> on 
2298 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2299
2300 Perl will attempt to flush all files opened for
2301 output before starting the child process, but this may not be supported
2302 on some platforms (see L<perlport>).  To be safe, you may need to set
2303 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2304 C<L<IO::Handle>> on any open handles.
2305
2306 Beware that some command shells may place restrictions on the length
2307 of the command line.  You must ensure your strings don't exceed this
2308 limit after any necessary interpolations.  See the platform-specific
2309 release notes for more details about your particular environment.
2310
2311 Using this operator can lead to programs that are difficult to port,
2312 because the shell commands called vary between systems, and may in
2313 fact not be present at all.  As one example, the C<type> command under
2314 the POSIX shell is very different from the C<type> command under DOS.
2315 That doesn't mean you should go out of your way to avoid backticks
2316 when they're the right way to get something done.  Perl was made to be
2317 a glue language, and one of the things it glues together is commands.
2318 Just understand what you're getting yourself into.
2319
2320 Like C<system>, backticks put the child process exit code in C<$?>.
2321 If you'd like to manually inspect failure, you can check all possible
2322 failure modes by inspecting C<$?> like this:
2323
2324     if ($? == -1) {
2325         print "failed to execute: $!\n";
2326     }
2327     elsif ($? & 127) {
2328         printf "child died with signal %d, %s coredump\n",
2329             ($? & 127),  ($? & 128) ? 'with' : 'without';
2330     }
2331     else {
2332         printf "child exited with value %d\n", $? >> 8;
2333     }
2334
2335 Use the L<open> pragma to control the I/O layers used when reading the
2336 output of the command, for example:
2337
2338   use open IN => ":encoding(UTF-8)";
2339   my $x = `cmd-producing-utf-8`;
2340
2341 See L</"I/O Operators"> for more discussion.
2342
2343 =item C<qw/I<STRING>/>
2344 X<qw> X<quote, list> X<quote, words>
2345
2346 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2347 whitespace as the word delimiters.  It can be understood as being roughly
2348 equivalent to:
2349
2350     split(" ", q/STRING/);
2351
2352 the differences being that it generates a real list at compile time, and
2353 in scalar context it returns the last element in the list.  So
2354 this expression:
2355
2356     qw(foo bar baz)
2357
2358 is semantically equivalent to the list:
2359
2360     "foo", "bar", "baz"
2361
2362 Some frequently seen examples:
2363
2364     use POSIX qw( setlocale localeconv )
2365     @EXPORT = qw( foo bar baz );
2366
2367 A common mistake is to try to separate the words with commas or to
2368 put comments into a multi-line C<qw>-string.  For this reason, the
2369 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2370 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2371
2372 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2373 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2374
2375 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2376
2377 Transliterates all occurrences of the characters found in the search list
2378 with the corresponding character in the replacement list.  It returns
2379 the number of characters replaced or deleted.  If no string is
2380 specified via the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2381
2382 If the C</r> (non-destructive) option is present, a new copy of the string
2383 is made and its characters transliterated, and this copy is returned no
2384 matter whether it was modified or not: the original string is always
2385 left unchanged.  The new copy is always a plain string, even if the input
2386 string is an object or a tied variable.
2387
2388 Unless the C</r> option is used, the string specified with C<=~> must be a
2389 scalar variable, an array element, a hash element, or an assignment to one
2390 of those; in other words, an lvalue.
2391
2392 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2393 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2394 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2395 I<SEARCHLIST> is delimited by bracketing quotes, the I<REPLACEMENTLIST>
2396 must have its own pair of quotes, which may or may not be bracketing
2397 quotes; for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2398
2399 Characters may be literals or any of the escape sequences accepted in
2400 double-quoted strings.  But there is no variable interpolation, so C<"$">
2401 and C<"@"> are treated as literals.  A hyphen at the beginning or end, or
2402 preceded by a backslash is considered a literal.  Escape sequence
2403 details are in L<the table near the beginning of this section|/Quote and
2404 Quote-like Operators>.
2405
2406 Note that C<tr> does B<not> do regular expression character classes such as
2407 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2408 utility.  C<tr[a-z][A-Z]> will uppercase the 26 letters "a" through "z",
2409 but for case changing not confined to ASCII, use
2410 L<C<lc>|perlfunc/lc>, L<C<uc>|perlfunc/uc>,
2411 L<C<lcfirst>|perlfunc/lcfirst>, L<C<ucfirst>|perlfunc/ucfirst>
2412 (all documented in L<perlfunc>), or the
2413 L<substitution operator C<sE<sol>I<PATTERN>E<sol>I<REPLACEMENT>E<sol>>|/sE<sol>PATTERNE<sol>REPLACEMENTE<sol>msixpodualngcer>
2414 (with C<\U>, C<\u>, C<\L>, and C<\l> string-interpolation escapes in the
2415 I<REPLACEMENT> portion).
2416
2417 Most ranges are unportable between character sets, but certain ones
2418 signal Perl to do special handling to make them portable.  There are two
2419 classes of portable ranges.  The first are any subsets of the ranges
2420 C<A-Z>, C<a-z>, and C<0-9>, when expressed as literal characters.
2421
2422   tr/h-k/H-K/
2423
2424 capitalizes the letters C<"h">, C<"i">, C<"j">, and C<"k"> and nothing
2425 else, no matter what the platform's character set is.  In contrast, all
2426 of
2427
2428   tr/\x68-\x6B/\x48-\x4B/
2429   tr/h-\x6B/H-\x4B/
2430   tr/\x68-k/\x48-K/
2431
2432 do the same capitalizations as the previous example when run on ASCII
2433 platforms, but something completely different on EBCDIC ones.
2434
2435 The second class of portable ranges is invoked when one or both of the
2436 range's end points are expressed as C<\N{...}>
2437
2438  $string =~ tr/\N{U+20}-\N{U+7E}//d;
2439
2440 removes from C<$string> all the platform's characters which are
2441 equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E.  This
2442 is a portable range, and has the same effect on every platform it is
2443 run on.  It turns out that in this example, these are the ASCII
2444 printable characters.  So after this is run, C<$string> has only
2445 controls and characters which have no ASCII equivalents.
2446
2447 But, even for portable ranges, it is not generally obvious what is
2448 included without having to look things up.  A sound principle is to use
2449 only ranges that begin from and end at either ASCII alphabetics of equal
2450 case (C<b-e>, C<B-E>), or digits (C<1-4>).  Anything else is unclear
2451 (and unportable unless C<\N{...}> is used).  If in doubt, spell out the
2452 character sets in full.
2453
2454 Options:
2455
2456     c   Complement the SEARCHLIST.
2457     d   Delete found but unreplaced characters.
2458     s   Squash duplicate replaced characters.
2459     r   Return the modified string and leave the original string
2460         untouched.
2461
2462 If the C</c> modifier is specified, the I<SEARCHLIST> character set
2463 is complemented.  If the C</d> modifier is specified, any characters
2464 specified by I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted.
2465 (Note that this is slightly more flexible than the behavior of some
2466 B<tr> programs, which delete anything they find in the I<SEARCHLIST>,
2467 period.)  If the C</s> modifier is specified, sequences of characters
2468 that were transliterated to the same character are squashed down
2469 to a single instance of the character.
2470
2471 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2472 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2473 than the I<SEARCHLIST>, the final character is replicated till it is long
2474 enough.  If the I<REPLACEMENTLIST> is empty, the I<SEARCHLIST> is replicated.
2475 This latter is useful for counting characters in a class or for
2476 squashing character sequences in a class.
2477
2478 Examples:
2479
2480     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2481
2482     $cnt = tr/*/*/;             # count the stars in $_
2483
2484     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2485
2486     $cnt = tr/0-9//;            # count the digits in $_
2487
2488     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2489
2490     ($HOST = $host) =~ tr/a-z/A-Z/;
2491      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2492
2493     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2494                   =~ s/:/ -p/r;
2495
2496     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2497
2498     @stripped = map tr/a-zA-Z/ /csr, @original;
2499                                 # /r with map
2500
2501     tr [\200-\377]
2502        [\000-\177];             # wickedly delete 8th bit
2503
2504 If multiple transliterations are given for a character, only the
2505 first one is used:
2506
2507     tr/AAA/XYZ/
2508
2509 will transliterate any A to X.
2510
2511 Because the transliteration table is built at compile time, neither
2512 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2513 interpolation.  That means that if you want to use variables, you
2514 must use an C<eval()>:
2515
2516     eval "tr/$oldlist/$newlist/";
2517     die $@ if $@;
2518
2519     eval "tr/$oldlist/$newlist/, 1" or die $@;
2520
2521 =item C<< <<I<EOF> >>
2522 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2523
2524 A line-oriented form of quoting is based on the shell "here-document"
2525 syntax.  Following a C<< << >> you specify a string to terminate
2526 the quoted material, and all lines following the current line down to
2527 the terminating string are the value of the item.
2528
2529 Prefixing the terminating string with a C<~> specifies that you
2530 want to use L</Indented Here-docs> (see below).
2531
2532 The terminating string may be either an identifier (a word), or some
2533 quoted text.  An unquoted identifier works like double quotes.
2534 There may not be a space between the C<< << >> and the identifier,
2535 unless the identifier is explicitly quoted.  (If you put a space it
2536 will be treated as a null identifier, which is valid, and matches the
2537 first empty line.)  The terminating string must appear by itself
2538 (unquoted and with no surrounding whitespace) on the terminating line.
2539
2540 If the terminating string is quoted, the type of quotes used determine
2541 the treatment of the text.
2542
2543 =over 4
2544
2545 =item Double Quotes
2546
2547 Double quotes indicate that the text will be interpolated using exactly
2548 the same rules as normal double quoted strings.
2549
2550        print <<EOF;
2551     The price is $Price.
2552     EOF
2553
2554        print << "EOF"; # same as above
2555     The price is $Price.
2556     EOF
2557
2558
2559 =item Single Quotes
2560
2561 Single quotes indicate the text is to be treated literally with no
2562 interpolation of its content.  This is similar to single quoted
2563 strings except that backslashes have no special meaning, with C<\\>
2564 being treated as two backslashes and not one as they would in every
2565 other quoting construct.
2566
2567 Just as in the shell, a backslashed bareword following the C<<< << >>>
2568 means the same thing as a single-quoted string does:
2569
2570         $cost = <<'VISTA';  # hasta la ...
2571     That'll be $10 please, ma'am.
2572     VISTA
2573
2574         $cost = <<\VISTA;   # Same thing!
2575     That'll be $10 please, ma'am.
2576     VISTA
2577
2578 This is the only form of quoting in perl where there is no need
2579 to worry about escaping content, something that code generators
2580 can and do make good use of.
2581
2582 =item Backticks
2583
2584 The content of the here doc is treated just as it would be if the
2585 string were embedded in backticks.  Thus the content is interpolated
2586 as though it were double quoted and then executed via the shell, with
2587 the results of the execution returned.
2588
2589        print << `EOC`; # execute command and get results
2590     echo hi there
2591     EOC
2592
2593 =back
2594
2595 =over 4
2596
2597 =item Indented Here-docs
2598
2599 The here-doc modifier C<~> allows you to indent your here-docs to make
2600 the code more readable:
2601
2602     if ($some_var) {
2603       print <<~EOF;
2604         This is a here-doc
2605         EOF
2606     }
2607
2608 This will print...
2609
2610     This is a here-doc
2611
2612 ...with no leading whitespace.
2613
2614 The delimiter is used to determine the B<exact> whitespace to
2615 remove from the beginning of each line.  All lines B<must> have
2616 at least the same starting whitespace (except lines only
2617 containing a newline) or perl will croak.  Tabs and spaces can
2618 be mixed, but are matched exactly.  One tab will not be equal to
2619 8 spaces!
2620
2621 Additional beginning whitespace (beyond what preceded the
2622 delimiter) will be preserved:
2623
2624     print <<~EOF;
2625       This text is not indented
2626         This text is indented with two spaces
2627                 This text is indented with two tabs
2628       EOF
2629
2630 Finally, the modifier may be used with all of the forms
2631 mentioned above:
2632
2633     <<~\EOF;
2634     <<~'EOF'
2635     <<~"EOF"
2636     <<~`EOF`
2637
2638 And whitespace may be used between the C<~> and quoted delimiters:
2639
2640     <<~ 'EOF'; # ... "EOF", `EOF`
2641
2642 =back
2643
2644 It is possible to stack multiple here-docs in a row:
2645
2646        print <<"foo", <<"bar"; # you can stack them
2647     I said foo.
2648     foo
2649     I said bar.
2650     bar
2651
2652        myfunc(<< "THIS", 23, <<'THAT');
2653     Here's a line
2654     or two.
2655     THIS
2656     and here's another.
2657     THAT
2658
2659 Just don't forget that you have to put a semicolon on the end
2660 to finish the statement, as Perl doesn't know you're not going to
2661 try to do this:
2662
2663        print <<ABC
2664     179231
2665     ABC
2666        + 20;
2667
2668 If you want to remove the line terminator from your here-docs,
2669 use C<chomp()>.
2670
2671     chomp($string = <<'END');
2672     This is a string.
2673     END
2674
2675 If you want your here-docs to be indented with the rest of the code,
2676 you'll need to remove leading whitespace from each line manually:
2677
2678     ($quote = <<'FINIS') =~ s/^\s+//gm;
2679        The Road goes ever on and on,
2680        down from the door where it began.
2681     FINIS
2682
2683 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2684 the quoted material must still come on the line following the
2685 C<<< <<FOO >>> marker, which means it may be inside the delimited
2686 construct:
2687
2688     s/this/<<E . 'that'
2689     the other
2690     E
2691      . 'more '/eg;
2692
2693 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2694 you would have to write
2695
2696     s/this/<<E . 'that'
2697      . 'more '/eg;
2698     the other
2699     E
2700
2701 outside of string evals.
2702
2703 Additionally, quoting rules for the end-of-string identifier are
2704 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2705 supported in place of C<''> and C<"">, and the only interpolation is for
2706 backslashing the quoting character:
2707
2708     print << "abc\"def";
2709     testing...
2710     abc"def
2711
2712 Finally, quoted strings cannot span multiple lines.  The general rule is
2713 that the identifier must be a string literal.  Stick with that, and you
2714 should be safe.
2715
2716 =back
2717
2718 =head2 Gory details of parsing quoted constructs
2719 X<quote, gory details>
2720
2721 When presented with something that might have several different
2722 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2723 principle to pick the most probable interpretation.  This strategy
2724 is so successful that Perl programmers often do not suspect the
2725 ambivalence of what they write.  But from time to time, Perl's
2726 notions differ substantially from what the author honestly meant.
2727
2728 This section hopes to clarify how Perl handles quoted constructs.
2729 Although the most common reason to learn this is to unravel labyrinthine
2730 regular expressions, because the initial steps of parsing are the
2731 same for all quoting operators, they are all discussed together.
2732
2733 The most important Perl parsing rule is the first one discussed
2734 below: when processing a quoted construct, Perl first finds the end
2735 of that construct, then interprets its contents.  If you understand
2736 this rule, you may skip the rest of this section on the first
2737 reading.  The other rules are likely to contradict the user's
2738 expectations much less frequently than this first one.
2739
2740 Some passes discussed below are performed concurrently, but because
2741 their results are the same, we consider them individually.  For different
2742 quoting constructs, Perl performs different numbers of passes, from
2743 one to four, but these passes are always performed in the same order.
2744
2745 =over 4
2746
2747 =item Finding the end
2748
2749 The first pass is finding the end of the quoted construct.  This results
2750 in saving to a safe location a copy of the text (between the starting
2751 and ending delimiters), normalized as necessary to avoid needing to know
2752 what the original delimiters were.
2753
2754 If the construct is a here-doc, the ending delimiter is a line
2755 that has a terminating string as the content.  Therefore C<<<EOF> is
2756 terminated by C<EOF> immediately followed by C<"\n"> and starting
2757 from the first column of the terminating line.
2758 When searching for the terminating line of a here-doc, nothing
2759 is skipped.  In other words, lines after the here-doc syntax
2760 are compared with the terminating string line by line.
2761
2762 For the constructs except here-docs, single characters are used as starting
2763 and ending delimiters.  If the starting delimiter is an opening punctuation
2764 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2765 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2766 If the starting delimiter is an unpaired character like C</> or a closing
2767 punctuation, the ending delimiter is the same as the starting delimiter.
2768 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2769 both C<qq[]> and C<qq]]> constructs.
2770
2771 When searching for single-character delimiters, escaped delimiters
2772 and C<\\> are skipped.  For example, while searching for terminating C</>,
2773 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2774 bracketing, nested pairs are also skipped.  For example, while searching
2775 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2776 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2777 However, when backslashes are used as the delimiters (like C<qq\\> and
2778 C<tr\\\>), nothing is skipped.
2779 During the search for the end, backslashes that escape delimiters or
2780 other backslashes are removed (exactly speaking, they are not copied to the
2781 safe location).
2782
2783 For constructs with three-part delimiters (C<s///>, C<y///>, and
2784 C<tr///>), the search is repeated once more.
2785 If the first delimiter is not an opening punctuation, the three delimiters must
2786 be the same, such as C<s!!!> and C<tr)))>,
2787 in which case the second delimiter
2788 terminates the left part and starts the right part at once.
2789 If the left part is delimited by bracketing punctuation (that is C<()>,
2790 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2791 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2792 and comments are allowed between the two parts, although the comment must follow
2793 at least one whitespace character; otherwise a character expected as the 
2794 start of the comment may be regarded as the starting delimiter of the right part.
2795
2796 During this search no attention is paid to the semantics of the construct.
2797 Thus:
2798
2799     "$hash{"$foo/$bar"}"
2800
2801 or:
2802
2803     m/
2804       bar       # NOT a comment, this slash / terminated m//!
2805      /x
2806
2807 do not form legal quoted expressions.   The quoted part ends on the
2808 first C<"> and C</>, and the rest happens to be a syntax error.
2809 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2810 the example above is not C<m//x>, but rather C<m//> with no C</x>
2811 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2812
2813 Also no attention is paid to C<\c\> (multichar control char syntax) during
2814 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2815 of C<\/>, and the following C</> is not recognized as a delimiter.
2816 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2817
2818 =item Interpolation
2819 X<interpolation>
2820
2821 The next step is interpolation in the text obtained, which is now
2822 delimiter-independent.  There are multiple cases.
2823
2824 =over 4
2825
2826 =item C<<<'EOF'>
2827
2828 No interpolation is performed.
2829 Note that the combination C<\\> is left intact, since escaped delimiters
2830 are not available for here-docs.
2831
2832 =item  C<m''>, the pattern of C<s'''>
2833
2834 No interpolation is performed at this stage.
2835 Any backslashed sequences including C<\\> are treated at the stage
2836 to L</"parsing regular expressions">.
2837
2838 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2839
2840 The only interpolation is removal of C<\> from pairs of C<\\>.
2841 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
2842 as a hyphen and no character range is available.
2843 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2844
2845 =item C<tr///>, C<y///>
2846
2847 No variable interpolation occurs.  String modifying combinations for
2848 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2849 The other escape sequences such as C<\200> and C<\t> and backslashed
2850 characters such as C<\\> and C<\-> are converted to appropriate literals.
2851 The character C<"-"> is treated specially and therefore C<\-> is treated
2852 as a literal C<"-">.
2853
2854 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2855
2856 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2857 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2858 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
2859 The other escape sequences such as C<\200> and C<\t> and backslashed
2860 characters such as C<\\> and C<\-> are replaced with appropriate
2861 expansions.
2862
2863 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2864 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2865 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2866 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2867 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2868 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2869 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2870
2871   $str = '\t';
2872   return "\Q$str";
2873
2874 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2875
2876 Interpolated scalars and arrays are converted internally to the C<join> and
2877 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
2878
2879   $foo . " XXX '" . (join $", @arr) . "'";
2880
2881 All operations above are performed simultaneously, left to right.
2882
2883 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
2884 quoted, there is no way to insert a literal C<$> or C<@> inside a
2885 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
2886 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2887 scalar.
2888
2889 Note also that the interpolation code needs to make a decision on
2890 where the interpolated scalar ends.  For instance, whether
2891 S<C<< "a $x -> {c}" >>> really means:
2892
2893   "a " . $x . " -> {c}";
2894
2895 or:
2896
2897   "a " . $x -> {c};
2898
2899 Most of the time, the longest possible text that does not include
2900 spaces between components and which contains matching braces or
2901 brackets.  because the outcome may be determined by voting based
2902 on heuristic estimators, the result is not strictly predictable.
2903 Fortunately, it's usually correct for ambiguous cases.
2904
2905 =item the replacement of C<s///>
2906
2907 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2908 happens as with C<qq//> constructs.
2909
2910 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2911 the replacement text of C<s///>, in order to correct the incorrigible
2912 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2913 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
2914 (that is, the C<$^W> variable) was set.
2915
2916 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2917
2918 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2919 and interpolation happens (almost) as with C<qq//> constructs.
2920
2921 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2922 form for the regex compiler.  (This is because, as mentioned below, the regex
2923 compilation may be done at execution time, and C<\N{...}> is a compile-time
2924 construct.)
2925
2926 However any other combinations of C<\> followed by a character
2927 are not substituted but only skipped, in order to parse them
2928 as regular expressions at the following step.
2929 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2930 treated as an array symbol (for example C<@foo>),
2931 even though the same text in C<qq//> gives interpolation of C<\c@>.
2932
2933 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2934 back to the perl parser, in a similar way that an interpolated array
2935 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2936
2937 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
2938 a C<#>-comment in a C</x>-regular expression, no processing is
2939 performed whatsoever.  This is the first step at which the presence
2940 of the C</x> modifier is relevant.
2941
2942 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2943 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2944 voted (by several different estimators) to be either an array element
2945 or C<$var> followed by an RE alternative.  This is where the notation
2946 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2947 array element C<-9>, not as a regular expression from the variable
2948 C<$arr> followed by a digit, which would be the interpretation of
2949 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2950 the result is not predictable.
2951
2952 The lack of processing of C<\\> creates specific restrictions on
2953 the post-processed text.  If the delimiter is C</>, one cannot get
2954 the combination C<\/> into the result of this step.  C</> will
2955 finish the regular expression, C<\/> will be stripped to C</> on
2956 the previous step, and C<\\/> will be left as is.  Because C</> is
2957 equivalent to C<\/> inside a regular expression, this does not
2958 matter unless the delimiter happens to be character special to the
2959 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2960 alphanumeric char, as in:
2961
2962   m m ^ a \s* b mmx;
2963
2964 In the RE above, which is intentionally obfuscated for illustration, the
2965 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2966 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
2967 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2968 non-whitespace choices.
2969
2970 =back
2971
2972 This step is the last one for all constructs except regular expressions,
2973 which are processed further.
2974
2975 =item parsing regular expressions
2976 X<regexp, parse>
2977
2978 Previous steps were performed during the compilation of Perl code,
2979 but this one happens at run time, although it may be optimized to
2980 be calculated at compile time if appropriate.  After preprocessing
2981 described above, and possibly after evaluation if concatenation,
2982 joining, casing translation, or metaquoting are involved, the
2983 resulting I<string> is passed to the RE engine for compilation.
2984
2985 Whatever happens in the RE engine might be better discussed in L<perlre>,
2986 but for the sake of continuity, we shall do so here.
2987
2988 This is another step where the presence of the C</x> modifier is
2989 relevant.  The RE engine scans the string from left to right and
2990 converts it into a finite automaton.
2991
2992 Backslashed characters are either replaced with corresponding
2993 literal strings (as with C<\{>), or else they generate special nodes
2994 in the finite automaton (as with C<\b>).  Characters special to the
2995 RE engine (such as C<|>) generate corresponding nodes or groups of
2996 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2997 converted to literal strings to match, or else is ignored (as is
2998 whitespace and C<#>-style comments if C</x> is present).
2999
3000 Parsing of the bracketed character class construct, C<[...]>, is
3001 rather different than the rule used for the rest of the pattern.
3002 The terminator of this construct is found using the same rules as
3003 for finding the terminator of a C<{}>-delimited construct, the only
3004 exception being that C<]> immediately following C<[> is treated as
3005 though preceded by a backslash.
3006
3007 The terminator of runtime C<(?{...})> is found by temporarily switching
3008 control to the perl parser, which should stop at the point where the
3009 logically balancing terminating C<}> is found.
3010
3011 It is possible to inspect both the string given to RE engine and the
3012 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
3013 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
3014 switch documented in L<perlrun/"Command Switches">.
3015
3016 =item Optimization of regular expressions
3017 X<regexp, optimization>
3018
3019 This step is listed for completeness only.  Since it does not change
3020 semantics, details of this step are not documented and are subject
3021 to change without notice.  This step is performed over the finite
3022 automaton that was generated during the previous pass.
3023
3024 It is at this stage that C<split()> silently optimizes C</^/> to
3025 mean C</^/m>.
3026
3027 =back
3028
3029 =head2 I/O Operators
3030 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
3031 X<< <> >> X<< <<>> >> X<@ARGV>
3032
3033 There are several I/O operators you should know about.
3034
3035 A string enclosed by backticks (grave accents) first undergoes
3036 double-quote interpolation.  It is then interpreted as an external
3037 command, and the output of that command is the value of the
3038 backtick string, like in a shell.  In scalar context, a single string
3039 consisting of all output is returned.  In list context, a list of
3040 values is returned, one per line of output.  (You can set C<$/> to use
3041 a different line terminator.)  The command is executed each time the
3042 pseudo-literal is evaluated.  The status value of the command is
3043 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
3044 Unlike in B<csh>, no translation is done on the return data--newlines
3045 remain newlines.  Unlike in any of the shells, single quotes do not
3046 hide variable names in the command from interpretation.  To pass a
3047 literal dollar-sign through to the shell you need to hide it with a
3048 backslash.  The generalized form of backticks is C<qx//>.  (Because
3049 backticks always undergo shell expansion as well, see L<perlsec> for
3050 security concerns.)
3051 X<qx> X<`> X<``> X<backtick> X<glob>
3052
3053 In scalar context, evaluating a filehandle in angle brackets yields
3054 the next line from that file (the newline, if any, included), or
3055 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
3056 (sometimes known as file-slurp mode) and the file is empty, it
3057 returns C<''> the first time, followed by C<undef> subsequently.
3058
3059 Ordinarily you must assign the returned value to a variable, but
3060 there is one situation where an automatic assignment happens.  If
3061 and only if the input symbol is the only thing inside the conditional
3062 of a C<while> statement (even if disguised as a C<for(;;)> loop),
3063 the value is automatically assigned to the global variable C<$_>,
3064 destroying whatever was there previously.  (This may seem like an
3065 odd thing to you, but you'll use the construct in almost every Perl
3066 script you write.)  The C<$_> variable is not implicitly localized.
3067 You'll have to put a S<C<local $_;>> before the loop if you want that
3068 to happen.
3069
3070 The following lines are equivalent:
3071
3072     while (defined($_ = <STDIN>)) { print; }
3073     while ($_ = <STDIN>) { print; }
3074     while (<STDIN>) { print; }
3075     for (;<STDIN>;) { print; }
3076     print while defined($_ = <STDIN>);
3077     print while ($_ = <STDIN>);
3078     print while <STDIN>;
3079
3080 This also behaves similarly, but assigns to a lexical variable 
3081 instead of to C<$_>:
3082
3083     while (my $line = <STDIN>) { print $line }
3084
3085 In these loop constructs, the assigned value (whether assignment
3086 is automatic or explicit) is then tested to see whether it is
3087 defined.  The defined test avoids problems where the line has a string
3088 value that would be treated as false by Perl; for example a "" or
3089 a C<"0"> with no trailing newline.  If you really mean for such values
3090 to terminate the loop, they should be tested for explicitly:
3091
3092     while (($_ = <STDIN>) ne '0') { ... }
3093     while (<STDIN>) { last unless $_; ... }
3094
3095 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
3096 explicit C<defined> test or comparison elicits a warning if the
3097 S<C<use warnings>> pragma or the B<-w>
3098 command-line switch (the C<$^W> variable) is in effect.
3099
3100 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
3101 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
3102 in packages, where they would be interpreted as local identifiers
3103 rather than global.)  Additional filehandles may be created with
3104 the C<open()> function, amongst others.  See L<perlopentut> and
3105 L<perlfunc/open> for details on this.
3106 X<stdin> X<stdout> X<sterr>
3107
3108 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
3109 a list, a list comprising all input lines is returned, one line per
3110 list element.  It's easy to grow to a rather large data space this
3111 way, so use with care.
3112
3113 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
3114 See L<perlfunc/readline>.
3115
3116 The null filehandle C<< <> >> is special: it can be used to emulate the
3117 behavior of B<sed> and B<awk>, and any other Unix filter program
3118 that takes a list of filenames, doing the same to each line
3119 of input from all of them.  Input from C<< <> >> comes either from
3120 standard input, or from each file listed on the command line.  Here's
3121 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3122 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3123 gives you standard input.  The C<@ARGV> array is then processed as a list
3124 of filenames.  The loop
3125
3126     while (<>) {
3127         ...                     # code for each line
3128     }
3129
3130 is equivalent to the following Perl-like pseudo code:
3131
3132     unshift(@ARGV, '-') unless @ARGV;
3133     while ($ARGV = shift) {
3134         open(ARGV, $ARGV);
3135         while (<ARGV>) {
3136             ...         # code for each line
3137         }
3138     }
3139
3140 except that it isn't so cumbersome to say, and will actually work.
3141 It really does shift the C<@ARGV> array and put the current filename
3142 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3143 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3144 is magical.  (The pseudo code above doesn't work because it treats
3145 C<< <ARGV> >> as non-magical.)
3146
3147 Since the null filehandle uses the two argument form of L<perlfunc/open>
3148 it interprets special characters, so if you have a script like this:
3149
3150     while (<>) {
3151         print;
3152     }
3153
3154 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3155 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3156 If you want all items in C<@ARGV> to be interpreted as file names, you
3157 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3158
3159     while (<<>>) {
3160         print;
3161     }
3162
3163 Using double angle brackets inside of a while causes the open to use the
3164 three argument form (with the second argument being C<< < >>), so all
3165 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3166 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3167 empty, it will still read from the standard input.)
3168
3169 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3170 containing the list of filenames you really want.  Line numbers (C<$.>)
3171 continue as though the input were one big happy file.  See the example
3172 in L<perlfunc/eof> for how to reset line numbers on each file.
3173
3174 If you want to set C<@ARGV> to your own list of files, go right ahead.
3175 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3176
3177     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3178
3179 You can even set them to pipe commands.  For example, this automatically
3180 filters compressed arguments through B<gzip>:
3181
3182     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3183
3184 If you want to pass switches into your script, you can use one of the
3185 C<Getopts> modules or put a loop on the front like this:
3186
3187     while ($_ = $ARGV[0], /^-/) {
3188         shift;
3189         last if /^--$/;
3190         if (/^-D(.*)/) { $debug = $1 }
3191         if (/^-v/)     { $verbose++  }
3192         # ...           # other switches
3193     }
3194
3195     while (<>) {
3196         # ...           # code for each line
3197     }
3198
3199 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3200 If you call it again after this, it will assume you are processing another
3201 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3202
3203 If what the angle brackets contain is a simple scalar variable (for example,
3204 C<$foo>), then that variable contains the name of the
3205 filehandle to input from, or its typeglob, or a reference to the
3206 same.  For example:
3207
3208     $fh = \*STDIN;
3209     $line = <$fh>;
3210
3211 If what's within the angle brackets is neither a filehandle nor a simple
3212 scalar variable containing a filehandle name, typeglob, or typeglob
3213 reference, it is interpreted as a filename pattern to be globbed, and
3214 either a list of filenames or the next filename in the list is returned,
3215 depending on context.  This distinction is determined on syntactic
3216 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3217 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3218 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3219 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3220 is treated as C<glob("$x ")>, not C<readline($x)>.
3221
3222 One level of double-quote interpretation is done first, but you can't
3223 say C<< <$foo> >> because that's an indirect filehandle as explained
3224 in the previous paragraph.  (In older versions of Perl, programmers
3225 would insert curly brackets to force interpretation as a filename glob:
3226 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3227 internal function directly as C<glob($foo)>, which is probably the right
3228 way to have done it in the first place.)  For example:
3229
3230     while (<*.c>) {
3231         chmod 0644, $_;
3232     }
3233
3234 is roughly equivalent to:
3235
3236     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3237     while (<FOO>) {
3238         chomp;
3239         chmod 0644, $_;
3240     }
3241
3242 except that the globbing is actually done internally using the standard
3243 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3244
3245     chmod 0644, <*.c>;
3246
3247 A (file)glob evaluates its (embedded) argument only when it is
3248 starting a new list.  All values must be read before it will start
3249 over.  In list context, this isn't important because you automatically
3250 get them all anyway.  However, in scalar context the operator returns
3251 the next value each time it's called, or C<undef> when the list has
3252 run out.  As with filehandle reads, an automatic C<defined> is
3253 generated when the glob occurs in the test part of a C<while>,
3254 because legal glob returns (for example,
3255 a file called F<0>) would otherwise
3256 terminate the loop.  Again, C<undef> is returned only once.  So if
3257 you're expecting a single value from a glob, it is much better to
3258 say
3259
3260     ($file) = <blurch*>;
3261
3262 than
3263
3264     $file = <blurch*>;
3265
3266 because the latter will alternate between returning a filename and
3267 returning false.
3268
3269 If you're trying to do variable interpolation, it's definitely better
3270 to use the C<glob()> function, because the older notation can cause people
3271 to become confused with the indirect filehandle notation.
3272
3273     @files = glob("$dir/*.[ch]");
3274     @files = glob($files[$i]);
3275
3276 =head2 Constant Folding
3277 X<constant folding> X<folding>
3278
3279 Like C, Perl does a certain amount of expression evaluation at
3280 compile time whenever it determines that all arguments to an
3281 operator are static and have no side effects.  In particular, string
3282 concatenation happens at compile time between literals that don't do
3283 variable substitution.  Backslash interpolation also happens at
3284 compile time.  You can say
3285
3286       'Now is the time for all'
3287     . "\n" 
3288     .  'good men to come to.'
3289
3290 and this all reduces to one string internally.  Likewise, if
3291 you say
3292
3293     foreach $file (@filenames) {
3294         if (-s $file > 5 + 100 * 2**16) {  }
3295     }
3296
3297 the compiler precomputes the number which that expression
3298 represents so that the interpreter won't have to.
3299
3300 =head2 No-ops
3301 X<no-op> X<nop>
3302
3303 Perl doesn't officially have a no-op operator, but the bare constants
3304 C<0> and C<1> are special-cased not to produce a warning in void
3305 context, so you can for example safely do
3306
3307     1 while foo();
3308
3309 =head2 Bitwise String Operators
3310 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3311
3312 Bitstrings of any size may be manipulated by the bitwise operators
3313 (C<~ | & ^>).
3314
3315 If the operands to a binary bitwise op are strings of different
3316 sizes, B<|> and B<^> ops act as though the shorter operand had
3317 additional zero bits on the right, while the B<&> op acts as though
3318 the longer operand were truncated to the length of the shorter.
3319 The granularity for such extension or truncation is one or more
3320 bytes.
3321
3322     # ASCII-based examples
3323     print "j p \n" ^ " a h";            # prints "JAPH\n"
3324     print "JA" | "  ph\n";              # prints "japh\n"
3325     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3326     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3327
3328 If you are intending to manipulate bitstrings, be certain that
3329 you're supplying bitstrings: If an operand is a number, that will imply
3330 a B<numeric> bitwise operation.  You may explicitly show which type of
3331 operation you intend by using C<""> or C<0+>, as in the examples below.
3332
3333     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3334     $foo = '150' |  105;        # yields 255
3335     $foo =  150  | '105';       # yields 255
3336     $foo = '150' | '105';       # yields string '155' (under ASCII)
3337
3338     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3339     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3340
3341 This somewhat unpredictable behavior can be avoided with the experimental
3342 "bitwise" feature, new in Perl 5.22.  You can enable it via S<C<use feature
3343 'bitwise'>>.  By default, it will warn unless the C<"experimental::bitwise">
3344 warnings category has been disabled.  (S<C<use experimental 'bitwise'>> will
3345 enable the feature and disable the warning.)  Under this feature, the four
3346 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3347 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3348 strings:
3349
3350     use experimental "bitwise";
3351     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3352     $foo = '150' |  105;        # yields 255
3353     $foo =  150  | '105';       # yields 255
3354     $foo = '150' | '105';       # yields 255
3355     $foo =  150  |. 105;        # yields string '155'
3356     $foo = '150' |. 105;        # yields string '155'
3357     $foo =  150  |.'105';       # yields string '155'
3358     $foo = '150' |.'105';       # yields string '155'
3359
3360     $baz = $foo &  $bar;        # both operands numeric
3361     $biz = $foo ^. $bar;        # both operands stringy
3362
3363 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3364 behave likewise under the feature.
3365
3366 The behavior of these operators is problematic (and subject to change)
3367 if either or both of the strings are encoded in UTF-8 (see
3368 L<perlunicode/Byte and Character Semantics>.
3369
3370 See L<perlfunc/vec> for information on how to manipulate individual bits
3371 in a bit vector.
3372
3373 =head2 Integer Arithmetic
3374 X<integer>
3375
3376 By default, Perl assumes that it must do most of its arithmetic in
3377 floating point.  But by saying
3378
3379     use integer;
3380
3381 you may tell the compiler to use integer operations
3382 (see L<integer> for a detailed explanation) from here to the end of
3383 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3384
3385     no integer;
3386
3387 which lasts until the end of that BLOCK.  Note that this doesn't
3388 mean everything is an integer, merely that Perl will use integer
3389 operations for arithmetic, comparison, and bitwise operators.  For
3390 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3391 still get C<1.4142135623731> or so.
3392
3393 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3394 C<< >> >>) always produce integral results.  (But see also
3395 L</Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3396 them.  By default, their results are interpreted as unsigned integers, but
3397 if S<C<use integer>> is in effect, their results are interpreted
3398 as signed integers.  For example, C<~0> usually evaluates to a large
3399 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3400 machines.
3401
3402 =head2 Floating-point Arithmetic
3403
3404 X<floating-point> X<floating point> X<float> X<real>
3405
3406 While S<C<use integer>> provides integer-only arithmetic, there is no
3407 analogous mechanism to provide automatic rounding or truncation to a
3408 certain number of decimal places.  For rounding to a certain number
3409 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3410 See L<perlfaq4>.
3411
3412 Floating-point numbers are only approximations to what a mathematician
3413 would call real numbers.  There are infinitely more reals than floats,
3414 so some corners must be cut.  For example:
3415
3416     printf "%.20g\n", 123456789123456789;
3417     #        produces 123456789123456784
3418
3419 Testing for exact floating-point equality or inequality is not a
3420 good idea.  Here's a (relatively expensive) work-around to compare
3421 whether two floating-point numbers are equal to a particular number of
3422 decimal places.  See Knuth, volume II, for a more robust treatment of
3423 this topic.
3424
3425     sub fp_equal {
3426         my ($X, $Y, $POINTS) = @_;
3427         my ($tX, $tY);
3428         $tX = sprintf("%.${POINTS}g", $X);
3429         $tY = sprintf("%.${POINTS}g", $Y);
3430         return $tX eq $tY;
3431     }
3432
3433 The POSIX module (part of the standard perl distribution) implements
3434 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3435 The C<L<Math::Complex>> module (part of the standard perl distribution)
3436 defines mathematical functions that work on both the reals and the
3437 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3438 POSIX can't work with complex numbers.
3439
3440 Rounding in financial applications can have serious implications, and
3441 the rounding method used should be specified precisely.  In these
3442 cases, it probably pays not to trust whichever system rounding is
3443 being used by Perl, but to instead implement the rounding function you
3444 need yourself.
3445
3446 =head2 Bigger Numbers
3447 X<number, arbitrary precision>
3448
3449 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3450 C<L<Math::BigFloat>> modules,
3451 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3452 variable-precision arithmetic and overloaded operators, although
3453 they're currently pretty slow.  At the cost of some space and
3454 considerable speed, they avoid the normal pitfalls associated with
3455 limited-precision representations.
3456
3457         use 5.010;
3458         use bigint;  # easy interface to Math::BigInt
3459         $x = 123456789123456789;
3460         say $x * $x;
3461     +15241578780673678515622620750190521
3462
3463 Or with rationals:
3464
3465         use 5.010;
3466         use bigrat;
3467         $x = 3/22;
3468         $y = 4/6;
3469         say "x/y is ", $x/$y;
3470         say "x*y is ", $x*$y;
3471         x/y is 9/44
3472         x*y is 1/11
3473
3474 Several modules let you calculate with unlimited or fixed precision
3475 (bound only by memory and CPU time).  There
3476 are also some non-standard modules that
3477 provide faster implementations via external C libraries.
3478
3479 Here is a short, but incomplete summary:
3480
3481   Math::String           treat string sequences like numbers
3482   Math::FixedPrecision   calculate with a fixed precision
3483   Math::Currency         for currency calculations
3484   Bit::Vector            manipulate bit vectors fast (uses C)
3485   Math::BigIntFast       Bit::Vector wrapper for big numbers
3486   Math::Pari             provides access to the Pari C library
3487   Math::Cephes           uses the external Cephes C library (no
3488                          big numbers)
3489   Math::Cephes::Fraction fractions via the Cephes library
3490   Math::GMP              another one using an external C library
3491   Math::GMPz             an alternative interface to libgmp's big ints
3492   Math::GMPq             an interface to libgmp's fraction numbers
3493   Math::GMPf             an interface to libgmp's floating point numbers
3494
3495 Choose wisely.
3496
3497 =cut