This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
a86557e6d6cb2b060606cad2ee052be1ece2acb2
[perl5.git] / ext / DynaLoader / DynaLoader_pm.PL
1 use Config;
2
3 sub to_string {
4     my ($value) = @_;
5     $value =~ s/\\/\\\\/g;
6     $value =~ s/'/\\'/g;
7     return "'$value'";
8 }
9
10 #
11 # subroutine expand_os_specific expands $^O-specific preprocessing information
12 # so that it will not be re-calculated at runtime in Dynaloader.pm
13 #
14 # Syntax of preprocessor should be kept extremely simple:
15 #  - directives are in double angle brackets <<...>>
16 #  - <<=string>> will be just evaluated
17 #  - for $^O-specific there are two forms:
18 #   <<$^O-eq-osname>>
19 #   <<$^O-ne-osname>>
20 #  this directive should be closed with respectively
21 #   <</$^O-eq-osname>>
22 #   <</$^O-ne-osname>>
23 #  construct <<|$^O-ne-osname>> means #else
24 #  nested <<$^O...>>-constructs are allowed but nested values must be for 
25 #   different OS-names!
26 #   
27 #  -- added by VKON, 03-10-2004 to separate $^O-specific between OSes
28 #     (so that Win32 never checks for $^O eq 'VMS' for example)
29 #
30 # The $^O tests test both for $^O and for $Config{osname}.
31 # The latter is better for some for cross-compilation setups.
32 #
33 sub expand_os_specific {
34     my $s = shift;
35     for ($s) {
36         s/<<=(.*?)>>/$1/gee;
37         s/<<\$\^O-(eq|ne)-(\w+)>>(.*?)<<\/\$\^O-\1-\2>>/
38           my ($op, $os, $expr) = ($1,$2,$3);
39           if ($op ne 'eq' and $op ne 'ne') {die "wrong eq-ne arg in $&"};
40           if ($expr =~ m[^(.*?)<<\|\$\^O-$op-$os>>(.*?)$]s) {
41               # #if;#else;#endif
42               my ($if,$el) = ($1,$2);
43               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
44                   $if
45               }
46               else {
47                   $el
48               }
49           }
50           else {
51               # #if;#endif
52               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
53                   $expr
54               }
55               else {
56                   ""
57               }
58           }
59         /ges;
60         if (/<<(=|\$\^O-)/) {die "bad <<\$^O-eq/ne-osname>> expression.".
61             " Unclosed brackets?";
62         }
63     }
64     $s;
65 }
66
67 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
68 open OUT, ">DynaLoader.pm" or die $!;
69 print OUT <<'EOT';
70
71 # Generated from DynaLoader_pm.PL
72
73 package DynaLoader;
74
75 #   And Gandalf said: 'Many folk like to know beforehand what is to
76 #   be set on the table; but those who have laboured to prepare the
77 #   feast like to keep their secret; for wonder makes the words of
78 #   praise louder.'
79
80 #   (Quote from Tolkien suggested by Anno Siegel.)
81 #
82 # See pod text at end of file for documentation.
83 # See also ext/DynaLoader/README in source tree for other information.
84 #
85 # Tim.Bunce@ig.co.uk, August 1994
86
87 BEGIN {
88     $VERSION = '1.12';
89 }
90
91 require AutoLoader;
92 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
93
94 use Config;
95
96 # enable debug/trace messages from DynaLoader perl code
97 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
98
99 #
100 # Flags to alter dl_load_file behaviour.  Assigned bits:
101 #   0x01  make symbols available for linking later dl_load_file's.
102 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
103 #         (ignored under VMS; effect is built-in to image linking)
104 #
105 # This is called as a class method $module->dl_load_flags.  The
106 # definition here will be inherited and result on "default" loading
107 # behaviour unless a sub-class of DynaLoader defines its own version.
108 #
109
110 sub dl_load_flags { 0x00 }
111
112 EOT
113
114 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
115     print OUT "(\$dl_dlext, \$dl_so, \$dlsrc) = (",
116               to_string($Config{'dlext'}), ",",
117               to_string($Config{'so'}), ",",
118               to_string($Config{'dlsrc'}), ")\n;" ;
119 }
120 else {
121     print OUT <<'EOT';
122 ($dl_dlext, $dl_so, $dlsrc) = @Config::Config{qw(dlext so dlsrc)};
123 EOT
124 }
125
126 print OUT expand_os_specific(<<'EOT');
127
128 <<$^O-eq-VMS>>
129 # Some systems need special handling to expand file specifications
130 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
131 # See dl_expandspec() for more details. Should be harmless but
132 # inefficient to define on systems that don't need it.
133 $Is_VMS    = $^O eq 'VMS';
134 <</$^O-eq-VMS>>
135 $do_expand = <<$^O-eq-VMS>>1<<|$^O-eq-VMS>>0<</$^O-eq-VMS>>;
136
137 @dl_require_symbols = ();       # names of symbols we need
138 @dl_resolve_using   = ();       # names of files to link with
139 @dl_library_path    = ();       # path to look for files
140
141 #XSLoader.pm may have added elements before we were required
142 #@dl_shared_objects  = ();       # shared objects for symbols we have 
143 #@dl_librefs         = ();       # things we have loaded
144 #@dl_modules         = ();       # Modules we have loaded
145
146 # This is a fix to support DLD's unfortunate desire to relink -lc
147 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
148
149 EOT
150
151 my $cfg_dl_library_path = <<'EOT';
152 push(@dl_library_path, split(' ', $Config::Config{libpth}));
153 EOT
154
155 sub dquoted_comma_list {
156     join(", ", map {'"'.quotemeta($_).'"'} @_);
157 }
158
159 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
160     eval $cfg_dl_library_path;
161     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
162         my $dl_library_path = dquoted_comma_list(@dl_library_path);
163         print OUT <<EOT;
164 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
165
166 \@dl_library_path = ($dl_library_path);
167
168 EOT
169     }
170 }
171 else {
172     print OUT <<EOT;
173 # Initialise \@dl_library_path with the 'standard' library path
174 # for this platform as determined by Configure.
175
176 $cfg_dl_library_path
177
178 EOT
179 }
180
181 my $ldlibpthname;
182 my $ldlibpthname_defined;
183 my $pthsep;
184
185 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
186     $ldlibpthname         = to_string($Config::Config{ldlibpthname});
187     $ldlibpthname_defined = to_string(defined $Config::Config{ldlibpthname} ? 1 : 0);
188     $pthsep               = to_string($Config::Config{path_sep});
189 }
190 else {
191     $ldlibpthname         = q($Config::Config{ldlibpthname});
192     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
193     $pthsep               = q($Config::Config{path_sep});
194 }
195 print OUT <<EOT;
196 my \$ldlibpthname         = $ldlibpthname;
197 my \$ldlibpthname_defined = $ldlibpthname_defined;
198 my \$pthsep               = $pthsep;
199
200 EOT
201
202 my $env_dl_library_path = <<'EOT';
203 if ($ldlibpthname_defined &&
204     exists $ENV{$ldlibpthname}) {
205     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
206 }
207
208 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
209
210 if ($ldlibpthname_defined &&
211     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
212     exists $ENV{LD_LIBRARY_PATH}) {
213     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
214 }
215 EOT
216
217 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
218     eval $env_dl_library_path;
219 }
220 else {
221     print OUT <<EOT;
222 # Add to \@dl_library_path any extra directories we can gather from environment
223 # during runtime.
224
225 $env_dl_library_path
226
227 EOT
228 }
229
230 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
231     my $dl_library_path = dquoted_comma_list(@dl_library_path);
232     print OUT <<EOT;
233 # The below \@dl_library_path has been expanded (%Config, %ENV)
234 # in Perl build time.
235
236 \@dl_library_path = ($dl_library_path);
237
238 EOT
239 }
240
241
242 # following long string contains $^O-specific stuff, which is factored out
243 print OUT expand_os_specific(<<'EOT');
244 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
245 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
246 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
247                                 !defined(&dl_error);
248
249 if ($dl_debug) {
250     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
251     print STDERR "DynaLoader not linked into this perl\n"
252             unless defined(&boot_DynaLoader);
253 }
254
255 1; # End of main code
256
257
258 sub croak   { require Carp; Carp::croak(@_)   }
259
260 sub bootstrap_inherit {
261     my $module = $_[0];
262     local *isa = *{"$module\::ISA"};
263     local @isa = (@isa, 'DynaLoader');
264     # Cannot goto due to delocalization.  Will report errors on a wrong line?
265     bootstrap(@_);
266 }
267
268 # The bootstrap function cannot be autoloaded (without complications)
269 # so we define it here:
270
271 sub bootstrap {
272     # use local vars to enable $module.bs script to edit values
273     local(@args) = @_;
274     local($module) = $args[0];
275     local(@dirs, $file);
276
277     unless ($module) {
278         require Carp;
279         Carp::confess("Usage: DynaLoader::bootstrap(module)");
280     }
281
282     # A common error on platforms which don't support dynamic loading.
283     # Since it's fatal and potentially confusing we give a detailed message.
284     croak("Can't load module $module, dynamic loading not available in this perl.\n".
285         "  (You may need to build a new perl executable which either supports\n".
286         "  dynamic loading or has the $module module statically linked into it.)\n")
287         unless defined(&dl_load_file);
288
289
290     <<$^O-eq-os2>>
291     # Can dynaload, but cannot dynaload Perl modules...
292     die 'Dynaloaded Perl modules are not available in this build of Perl' if $OS2::is_static;
293
294     <</$^O-eq-os2>>
295     my @modparts = split(/::/,$module);
296     my $modfname = $modparts[-1];
297
298     # Some systems have restrictions on files names for DLL's etc.
299     # mod2fname returns appropriate file base name (typically truncated)
300     # It may also edit @modparts if required.
301     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
302
303     <<$^O-eq-NetWare>>
304     # Truncate the module name to 8.3 format for NetWare
305         if ((length($modfname) > 8)) {
306                 $modfname = substr($modfname, 0, 8);
307         }
308     <</$^O-eq-NetWare>>
309
310     my $modpname = join('/',@modparts);
311
312     print STDERR "DynaLoader::bootstrap for $module ",
313                        "(auto/$modpname/$modfname.$dl_dlext)\n"
314         if $dl_debug;
315
316     foreach (@INC) {
317         <<$^O-eq-VMS>>chop($_ = VMS::Filespec::unixpath($_));<</$^O-eq-VMS>>
318             my $dir = "$_/auto/$modpname";
319         
320         next unless -d $dir; # skip over uninteresting directories
321         
322         # check for common cases to avoid autoload of dl_findfile
323         my $try = "$dir/$modfname.$dl_dlext";
324         last if $file = ($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
325         
326         # no luck here, save dir for possible later dl_findfile search
327         push @dirs, $dir;
328     }
329     # last resort, let dl_findfile have a go in all known locations
330     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
331
332     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
333         unless $file;   # wording similar to error from 'require'
334
335     <<$^O-eq-VMS>>$file = uc($file) if $Config::Config{d_vms_case_sensitive_symbols};<</$^O-eq-VMS>>
336     my $bootname = "boot_$module";
337     $bootname =~ s/\W/_/g;
338     @dl_require_symbols = ($bootname);
339
340     # Execute optional '.bootstrap' perl script for this module.
341     # The .bs file can be used to configure @dl_resolve_using etc to
342     # match the needs of the individual module on this architecture.
343     my $bs = $file;
344     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
345     if (-s $bs) { # only read file if it's not empty
346         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
347         eval { do $bs; };
348         warn "$bs: $@\n" if $@;
349     }
350
351     my $boot_symbol_ref;
352
353     <<$^O-eq-darwin>>
354     if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
355         goto boot; #extension library has already been loaded, e.g. darwin
356     }
357     <</$^O-eq-darwin>>
358
359     # Many dynamic extension loading problems will appear to come from
360     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
361     # Often these errors are actually occurring in the initialisation
362     # C code of the extension XS file. Perl reports the error as being
363     # in this perl code simply because this was the last perl code
364     # it executed.
365
366     my $libref = dl_load_file($file, $module->dl_load_flags) or
367         croak("Can't load '$file' for module $module: ".dl_error());
368
369     push(@dl_librefs,$libref);  # record loaded object
370
371     my @unresolved = dl_undef_symbols();
372     if (@unresolved) {
373         require Carp;
374         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
375     }
376
377     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
378          croak("Can't find '$bootname' symbol in $file\n");
379
380     push(@dl_modules, $module); # record loaded module
381
382   boot:
383     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
384
385     # See comment block above
386
387         push(@dl_shared_objects, $file); # record files loaded
388
389     &$xs(@args);
390 }
391
392
393 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
394 #    my($file) = @_;
395 #    return $file if (!$do_expand && -f $file); # the common case
396 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
397 #    return undef;
398 #}
399
400
401 # Let autosplit and the autoloader deal with these functions:
402 __END__
403
404
405 sub dl_findfile {
406     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
407     # This function does not automatically consider the architecture
408     # or the perl library auto directories.
409     my (@args) = @_;
410     my (@dirs,  $dir);   # which directories to search
411     my (@found);         # full paths to real files we have found
412     #my $dl_ext= <<=to_string($Config::Config{'dlext'})>>; # $Config::Config{'dlext'} suffix for perl extensions
413     #my $dl_so = <<=to_string($Config::Config{'so'})>>; # $Config::Config{'so'} suffix for shared libraries
414
415     print STDERR "dl_findfile(@args)\n" if $dl_debug;
416
417     # accumulate directories but process files as they appear
418     arg: foreach(@args) {
419         #  Special fast case: full filepath requires no search
420         <<$^O-eq-VMS>>
421         if (m%[:>/\]]% && -f $_) {
422             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
423             last arg unless wantarray;
424             next;
425         }
426         <</$^O-eq-VMS>>
427         <<$^O-ne-VMS>>
428         if (m:/: && -f $_) {
429             push(@found,$_);
430             last arg unless wantarray;
431             next;
432         }
433         <</$^O-ne-VMS>>
434
435         # Deal with directories first:
436         #  Using a -L prefix is the preferred option (faster and more robust)
437         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
438
439         #  Otherwise we try to try to spot directories by a heuristic
440         #  (this is a more complicated issue than it first appears)
441         if (m:/: && -d $_) {   push(@dirs, $_); next; }
442
443         <<$^O-eq-VMS>>
444         # VMS: we may be using native VMS directory syntax instead of
445         # Unix emulation, so check this as well
446         if (/[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
447         <</$^O-eq-VMS>>
448
449         #  Only files should get this far...
450         my(@names, $name);    # what filenames to look for
451         if (m:-l: ) {          # convert -lname to appropriate library name
452             s/-l//;
453             push(@names,"lib$_.$dl_so");
454             push(@names,"lib$_.a");
455         } else {                # Umm, a bare name. Try various alternatives:
456             # these should be ordered with the most likely first
457             push(@names,"$_.$dl_dlext")    unless m/\.$dl_dlext$/o;
458             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
459             <<$^O-eq-cygwin>>
460             push(@names,"cyg$_.$dl_so")  unless m:/:;
461             <</$^O-eq-cygwin>>
462             push(@names,"lib$_.$dl_so")  unless m:/:;
463             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
464             push(@names, $_);
465         }
466         my $dirsep = '/';
467         <<$^O-eq-symbian>>
468         $dirsep = '\\';
469         if ($0 =~ /^([a-z]):/i) {
470             my $drive = $1;
471             @dirs = map { "$drive:$_" } @dirs;
472             @dl_library_path = map { "$drive:$_" } @dl_library_path;
473         }
474         <</$^O-eq-symbian>>
475         foreach $dir (@dirs, @dl_library_path) {
476             next unless -d $dir;
477             <<$^O-eq-VMS>>
478             chop($dir = VMS::Filespec::unixpath($dir));
479             <</$^O-eq-VMS>>
480             foreach $name (@names) {
481                 my($file) = "$dir$dirsep$name";
482                 print STDERR " checking in $dir for $name\n" if $dl_debug;
483                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
484                 #$file = _check_file($file);
485                 if ($file) {
486                     push(@found, $file);
487                     next arg; # no need to look any further
488                 }
489             }
490         }
491     }
492     if ($dl_debug) {
493         foreach(@dirs) {
494             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
495         }
496         print STDERR "dl_findfile found: @found\n";
497     }
498     return $found[0] unless wantarray;
499     @found;
500 }
501
502
503 sub dl_expandspec {
504     my($spec) = @_;
505     # Optional function invoked if DynaLoader.pm sets $do_expand.
506     # Most systems do not require or use this function.
507     # Some systems may implement it in the dl_*.xs file in which case
508     # this autoload version will not be called but is harmless.
509
510     # This function is designed to deal with systems which treat some
511     # 'filenames' in a special way. For example VMS 'Logical Names'
512     # (something like unix environment variables - but different).
513     # This function should recognise such names and expand them into
514     # full file paths.
515     # Must return undef if $spec is invalid or file does not exist.
516
517     my $file = $spec; # default output to input
518
519     <<$^O-eq-VMS>>
520         # dl_expandspec should be defined in dl_vms.xs
521         require Carp;
522         Carp::croak("dl_expandspec: should be defined in XS file!\n");
523     <<|$^O-eq-VMS>>
524         return undef unless -f $file;
525     <</$^O-eq-VMS>>
526     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
527     $file;
528 }
529
530 sub dl_find_symbol_anywhere
531 {
532     my $sym = shift;
533     my $libref;
534     foreach $libref (@dl_librefs) {
535         my $symref = dl_find_symbol($libref,$sym);
536         return $symref if $symref;
537     }
538     return undef;
539 }
540
541 =head1 NAME
542
543 DynaLoader - Dynamically load C libraries into Perl code
544
545 =head1 SYNOPSIS
546
547     package YourPackage;
548     require DynaLoader;
549     @ISA = qw(... DynaLoader ...);
550     bootstrap YourPackage;
551
552     # optional method for 'global' loading
553     sub dl_load_flags { 0x01 }     
554
555
556 =head1 DESCRIPTION
557
558 This document defines a standard generic interface to the dynamic
559 linking mechanisms available on many platforms.  Its primary purpose is
560 to implement automatic dynamic loading of Perl modules.
561
562 This document serves as both a specification for anyone wishing to
563 implement the DynaLoader for a new platform and as a guide for
564 anyone wishing to use the DynaLoader directly in an application.
565
566 The DynaLoader is designed to be a very simple high-level
567 interface that is sufficiently general to cover the requirements
568 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
569
570 It is also hoped that the interface will cover the needs of OS/2, NT
571 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
572
573 It must be stressed that the DynaLoader, by itself, is practically
574 useless for accessing non-Perl libraries because it provides almost no
575 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
576 library function or supplying arguments.  A C::DynaLib module
577 is available from CPAN sites which performs that function for some
578 common system types.  And since the year 2000, there's also Inline::C,
579 a module that allows you to write Perl subroutines in C.  Also available
580 from your local CPAN site.
581
582 DynaLoader Interface Summary
583
584   @dl_library_path
585   @dl_resolve_using
586   @dl_require_symbols
587   $dl_debug
588   @dl_librefs
589   @dl_modules
590   @dl_shared_objects
591                                                   Implemented in:
592   bootstrap($modulename)                               Perl
593   @filepaths = dl_findfile(@names)                     Perl
594   $flags = $modulename->dl_load_flags                  Perl
595   $symref  = dl_find_symbol_anywhere($symbol)          Perl
596
597   $libref  = dl_load_file($filename, $flags)           C
598   $status  = dl_unload_file($libref)                   C
599   $symref  = dl_find_symbol($libref, $symbol)          C
600   @symbols = dl_undef_symbols()                        C
601   dl_install_xsub($name, $symref [, $filename])        C
602   $message = dl_error                                  C
603
604 =over 4
605
606 =item @dl_library_path
607
608 The standard/default list of directories in which dl_findfile() will
609 search for libraries etc.  Directories are searched in order:
610 $dl_library_path[0], [1], ... etc
611
612 @dl_library_path is initialised to hold the list of 'normal' directories
613 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
614 ensure portability across a wide range of platforms.
615
616 @dl_library_path should also be initialised with any other directories
617 that can be determined from the environment at runtime (such as
618 LD_LIBRARY_PATH for SunOS).
619
620 After initialisation @dl_library_path can be manipulated by an
621 application using push and unshift before calling dl_findfile().
622 Unshift can be used to add directories to the front of the search order
623 either to save search time or to override libraries with the same name
624 in the 'normal' directories.
625
626 The load function that dl_load_file() calls may require an absolute
627 pathname.  The dl_findfile() function and @dl_library_path can be
628 used to search for and return the absolute pathname for the
629 library/object that you wish to load.
630
631 =item @dl_resolve_using
632
633 A list of additional libraries or other shared objects which can be
634 used to resolve any undefined symbols that might be generated by a
635 later call to load_file().
636
637 This is only required on some platforms which do not handle dependent
638 libraries automatically.  For example the Socket Perl extension
639 library (F<auto/Socket/Socket.so>) contains references to many socket
640 functions which need to be resolved when it's loaded.  Most platforms
641 will automatically know where to find the 'dependent' library (e.g.,
642 F</usr/lib/libsocket.so>).  A few platforms need to be told the
643 location of the dependent library explicitly.  Use @dl_resolve_using
644 for this.
645
646 Example usage:
647
648     @dl_resolve_using = dl_findfile('-lsocket');
649
650 =item @dl_require_symbols
651
652 A list of one or more symbol names that are in the library/object file
653 to be dynamically loaded.  This is only required on some platforms.
654
655 =item @dl_librefs
656
657 An array of the handles returned by successful calls to dl_load_file(),
658 made by bootstrap, in the order in which they were loaded.
659 Can be used with dl_find_symbol() to look for a symbol in any of
660 the loaded files.
661
662 =item @dl_modules
663
664 An array of module (package) names that have been bootstrap'ed.
665
666 =item @dl_shared_objects
667
668 An array of file names for the shared objects that were loaded.
669
670 =item dl_error()
671
672 Syntax:
673
674     $message = dl_error();
675
676 Error message text from the last failed DynaLoader function.  Note
677 that, similar to errno in unix, a successful function call does not
678 reset this message.
679
680 Implementations should detect the error as soon as it occurs in any of
681 the other functions and save the corresponding message for later
682 retrieval.  This will avoid problems on some platforms (such as SunOS)
683 where the error message is very temporary (e.g., dlerror()).
684
685 =item $dl_debug
686
687 Internal debugging messages are enabled when $dl_debug is set true.
688 Currently setting $dl_debug only affects the Perl side of the
689 DynaLoader.  These messages should help an application developer to
690 resolve any DynaLoader usage problems.
691
692 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
693
694 For the DynaLoader developer/porter there is a similar debugging
695 variable added to the C code (see dlutils.c) and enabled if Perl was
696 built with the B<-DDEBUGGING> flag.  This can also be set via the
697 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
698 higher for more.
699
700 =item dl_findfile()
701
702 Syntax:
703
704     @filepaths = dl_findfile(@names)
705
706 Determine the full paths (including file suffix) of one or more
707 loadable files given their generic names and optionally one or more
708 directories.  Searches directories in @dl_library_path by default and
709 returns an empty list if no files were found.
710
711 Names can be specified in a variety of platform independent forms.  Any
712 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
713 an appropriate suffix for the platform.
714
715 If a name does not already have a suitable prefix and/or suffix then
716 the corresponding file will be searched for by trying combinations of
717 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
718 and "$name".
719
720 If any directories are included in @names they are searched before
721 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
722 names are treated as filenames to be searched for.
723
724 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
725
726 Example: 
727
728     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
729
730
731 =item dl_expandspec()
732
733 Syntax:
734
735     $filepath = dl_expandspec($spec)
736
737 Some unusual systems, such as VMS, require special filename handling in
738 order to deal with symbolic names for files (i.e., VMS's Logical Names).
739
740 To support these systems a dl_expandspec() function can be implemented
741 either in the F<dl_*.xs> file or code can be added to the autoloadable
742 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
743 more information.
744
745 =item dl_load_file()
746
747 Syntax:
748
749     $libref = dl_load_file($filename, $flags)
750
751 Dynamically load $filename, which must be the path to a shared object
752 or library.  An opaque 'library reference' is returned as a handle for
753 the loaded object.  Returns undef on error.
754
755 The $flags argument to alters dl_load_file behaviour.  
756 Assigned bits:
757
758  0x01  make symbols available for linking later dl_load_file's.
759        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
760        (ignored under VMS; this is a normal part of image linking)
761
762 (On systems that provide a handle for the loaded object such as SunOS
763 and HPUX, $libref will be that handle.  On other systems $libref will
764 typically be $filename or a pointer to a buffer containing $filename.
765 The application should not examine or alter $libref in any way.)
766
767 This is the function that does the real work.  It should use the
768 current values of @dl_require_symbols and @dl_resolve_using if required.
769
770     SunOS: dlopen($filename)
771     HP-UX: shl_load($filename)
772     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
773     NeXT:  rld_load($filename, @dl_resolve_using)
774     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
775
776 (The dlopen() function is also used by Solaris and some versions of
777 Linux, and is a common choice when providing a "wrapper" on other
778 mechanisms as is done in the OS/2 port.)
779
780 =item dl_unload_file()
781
782 Syntax:
783
784     $status = dl_unload_file($libref)
785
786 Dynamically unload $libref, which must be an opaque 'library reference' as
787 returned from dl_load_file.  Returns one on success and zero on failure.
788
789 This function is optional and may not necessarily be provided on all platforms.
790 If it is defined, it is called automatically when the interpreter exits for
791 every shared object or library loaded by DynaLoader::bootstrap.  All such
792 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
793 loads the libraries.  The files are unloaded in last-in, first-out order.
794
795 This unloading is usually necessary when embedding a shared-object perl (e.g.
796 one configured with -Duseshrplib) within a larger application, and the perl
797 interpreter is created and destroyed several times within the lifetime of the
798 application.  In this case it is possible that the system dynamic linker will
799 unload and then subsequently reload the shared libperl without relocating any
800 references to it from any files DynaLoaded by the previous incarnation of the
801 interpreter.  As a result, any shared objects opened by DynaLoader may point to
802 a now invalid 'ghost' of the libperl shared object, causing apparently random
803 memory corruption and crashes.  This behaviour is most commonly seen when using
804 Apache and mod_perl built with the APXS mechanism.
805
806     SunOS: dlclose($libref)
807     HP-UX: ???
808     Linux: ???
809     NeXT:  ???
810     VMS:   ???
811
812 (The dlclose() function is also used by Solaris and some versions of
813 Linux, and is a common choice when providing a "wrapper" on other
814 mechanisms as is done in the OS/2 port.)
815
816 =item dl_load_flags()
817
818 Syntax:
819
820     $flags = dl_load_flags $modulename;
821
822 Designed to be a method call, and to be overridden by a derived class
823 (i.e. a class which has DynaLoader in its @ISA).  The definition in
824 DynaLoader itself returns 0, which produces standard behavior from
825 dl_load_file().
826
827 =item dl_find_symbol()
828
829 Syntax:
830
831     $symref = dl_find_symbol($libref, $symbol)
832
833 Return the address of the symbol $symbol or C<undef> if not found.  If the
834 target system has separate functions to search for symbols of different
835 types then dl_find_symbol() should search for function symbols first and
836 then other types.
837
838 The exact manner in which the address is returned in $symref is not
839 currently defined.  The only initial requirement is that $symref can
840 be passed to, and understood by, dl_install_xsub().
841
842     SunOS: dlsym($libref, $symbol)
843     HP-UX: shl_findsym($libref, $symbol)
844     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
845     NeXT:  rld_lookup("_$symbol")
846     VMS:   lib$find_image_symbol($libref,$symbol)
847
848
849 =item dl_find_symbol_anywhere()
850
851 Syntax:
852
853     $symref = dl_find_symbol_anywhere($symbol)
854
855 Applies dl_find_symbol() to the members of @dl_librefs and returns
856 the first match found.
857
858 =item dl_undef_symbols()
859
860 Example
861
862     @symbols = dl_undef_symbols()
863
864 Return a list of symbol names which remain undefined after load_file().
865 Returns C<()> if not known.  Don't worry if your platform does not provide
866 a mechanism for this.  Most do not need it and hence do not provide it,
867 they just return an empty list.
868
869
870 =item dl_install_xsub()
871
872 Syntax:
873
874     dl_install_xsub($perl_name, $symref [, $filename])
875
876 Create a new Perl external subroutine named $perl_name using $symref as
877 a pointer to the function which implements the routine.  This is simply
878 a direct call to newXSUB().  Returns a reference to the installed
879 function.
880
881 The $filename parameter is used by Perl to identify the source file for
882 the function if required by die(), caller() or the debugger.  If
883 $filename is not defined then "DynaLoader" will be used.
884
885
886 =item bootstrap()
887
888 Syntax:
889
890 bootstrap($module [...])
891
892 This is the normal entry point for automatic dynamic loading in Perl.
893
894 It performs the following actions:
895
896 =over 8
897
898 =item *
899
900 locates an auto/$module directory by searching @INC
901
902 =item *
903
904 uses dl_findfile() to determine the filename to load
905
906 =item *
907
908 sets @dl_require_symbols to C<("boot_$module")>
909
910 =item *
911
912 executes an F<auto/$module/$module.bs> file if it exists
913 (typically used to add to @dl_resolve_using any files which
914 are required to load the module on the current platform)
915
916 =item *
917
918 calls dl_load_flags() to determine how to load the file.
919
920 =item *
921
922 calls dl_load_file() to load the file
923
924 =item *
925
926 calls dl_undef_symbols() and warns if any symbols are undefined
927
928 =item *
929
930 calls dl_find_symbol() for "boot_$module"
931
932 =item *
933
934 calls dl_install_xsub() to install it as "${module}::bootstrap"
935
936 =item *
937
938 calls &{"${module}::bootstrap"} to bootstrap the module (actually
939 it uses the function reference returned by dl_install_xsub for speed)
940
941 =back
942
943 All arguments to bootstrap() are passed to the module's bootstrap function.
944 The default code generated by F<xsubpp> expects $module [, $version]
945 If the optional $version argument is not given, it defaults to
946 C<$XS_VERSION // $VERSION> in the module's symbol table. The default code
947 compares the Perl-space version with the version of the compiled XS code,
948 and croaks with an error if they do not match.
949
950 =back
951
952
953 =head1 AUTHOR
954
955 Tim Bunce, 11 August 1994.
956
957 This interface is based on the work and comments of (in no particular
958 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
959 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
960
961 Larry Wall designed the elegant inherited bootstrap mechanism and
962 implemented the first Perl 5 dynamic loader using it.
963
964 Solaris global loading added by Nick Ing-Simmons with design/coding
965 assistance from Tim Bunce, January 1996.
966
967 =cut
968 EOT
969
970 close OUT or die $!;
971