This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
rt #72232 - ignore wday/yday in mini_mktime as indirectly documented
[perl5.git] / ext / POSIX / t / posix.t
1 #!./perl
2
3 BEGIN {
4     require Config; import Config;
5     if ($^O ne 'VMS' and $Config{'extensions'} !~ /\bPOSIX\b/) {
6         print "1..0\n";
7         exit 0;
8     }
9 }
10
11 use Test::More tests => 109;
12
13 use POSIX qw(fcntl_h signal_h limits_h _exit getcwd open read strftime write
14              errno localeconv dup dup2 lseek access);
15 use strict 'subs';
16
17 sub next_test {
18     my $builder = Test::More->builder;
19     $builder->current_test($builder->current_test() + 1);
20 }
21
22 $| = 1;
23
24 $Is_W32     = $^O eq 'MSWin32';
25 $Is_Dos     = $^O eq 'dos';
26 $Is_MPE     = $^O eq 'mpeix';
27 $Is_MacOS   = $^O eq 'MacOS';
28 $Is_VMS     = $^O eq 'VMS';
29 $Is_OS2     = $^O eq 'os2';
30 $Is_UWin    = $^O eq 'uwin';
31 $Is_OS390   = $^O eq 'os390';
32
33 my $vms_unix_rpt = 0;
34 my $vms_efs = 0;
35 my $unix_mode = 1;
36
37 if ($Is_VMS) {
38     $unix_mode = 0;
39     if (eval 'require VMS::Feature') {
40         $vms_unix_rpt = VMS::Feature::current("filename_unix_report");
41         $vms_efs = VMS::Feature::current("efs_charset");
42     } else {
43         my $unix_rpt = $ENV{'DECC$FILENAME_UNIX_REPORT'} || '';
44         my $efs_charset = $ENV{'DECC$EFS_CHARSET'} || '';
45         $vms_unix_rpt = $unix_rpt =~ /^[ET1]/i;
46         $vms_efs = $efs_charset =~ /^[ET1]/i;
47     }
48
49     # Traditional VMS mode only if VMS is not in UNIX compatible mode.
50     $unix_mode = ($vms_efs && $vms_unix_rpt);
51
52 }
53
54 my $testfd = open("Makefile.PL", O_RDONLY, 0);
55 like($testfd, qr/\A\d+\z/, 'O_RDONLY with open');
56 read($testfd, $buffer, 4) if $testfd > 2;
57 is( $buffer, "# Ex",                      '    with read' );
58
59 TODO:
60 {
61     local $TODO = "read to array element not working";
62
63     read($testfd, $buffer[1], 5) if $testfd > 2;
64     is( $buffer[1], "perl\n",                  '    read to array element' );
65 }
66
67 my $test = next_test();
68 write(1,"ok $test\nnot ok $test\n", 5);
69
70 SKIP: {
71     skip("no pipe() support on DOS", 2) if $Is_Dos;
72
73     @fds = POSIX::pipe();
74     cmp_ok($fds[0], '>', $testfd, 'POSIX::pipe');
75
76     CORE::open($reader = \*READER, "<&=".$fds[0]);
77     CORE::open($writer = \*WRITER, ">&=".$fds[1]);
78     my $test = next_test();
79     print $writer "ok $test\n";
80     close $writer;
81     print <$reader>;
82     close $reader;
83 }
84
85 SKIP: {
86     skip("no sigaction support on win32/dos", 6) if $Is_W32 || $Is_Dos;
87
88     my $sigset = new POSIX::SigSet 1, 3;
89     $sigset->delset(1);
90     ok(! $sigset->ismember(1),  'POSIX::SigSet->delset' );
91     ok(  $sigset->ismember(3),  'POSIX::SigSet->ismember' );
92
93     SKIP: {
94         skip("no kill() support on Mac OS", 4) if $Is_MacOS;
95
96         my $sigint_called = 0;
97
98         my $mask   = new POSIX::SigSet &SIGINT;
99         my $action = new POSIX::SigAction 'main::SigHUP', $mask, 0;
100         sigaction(&SIGHUP, $action);
101         $SIG{'INT'} = 'SigINT';
102
103         # At least OpenBSD/i386 3.3 is okay, as is NetBSD 1.5.
104         # But not NetBSD 1.6 & 1.6.1: the test makes perl crash.
105         # So the kill() must not be done with this config in order to
106         # finish the test.
107         # For others (darwin & freebsd), let the test fail without crashing.
108         my $todo = $^O eq 'netbsd' && $Config{osvers}=~/^1\.6/;
109         my $why_todo = "# TODO $^O $Config{osvers} seems to lose blocked signals";
110         if (!$todo) { 
111           kill 'HUP', $$; 
112         } else {
113           print "not ok 9 - sigaction SIGHUP ",$why_todo,"\n";
114           print "not ok 10 - sig mask delayed SIGINT ",$why_todo,"\n";
115         }
116         sleep 1;
117
118         $todo = 1 if ($^O eq 'freebsd')
119                   || ($^O eq 'darwin' && $Config{osvers} < '6.6');
120         printf "%s 11 - masked SIGINT received %s\n",
121             $sigint_called ? "ok" : "not ok",
122             $todo ? $why_todo : '';
123
124         print "ok 12 - signal masks successful\n";
125         
126         sub SigHUP {
127             print "ok 9 - sigaction SIGHUP\n";
128             kill 'INT', $$;
129             sleep 2;
130             print "ok 10 - sig mask delayed SIGINT\n";
131         }
132
133         sub SigINT {
134             $sigint_called++;
135         }
136
137         # The order of the above tests is very important, so
138         # we use literal prints and hard coded numbers.
139         next_test() for 1..4;
140     }
141 }
142
143 SKIP: {
144     skip("_POSIX_OPEN_MAX is inaccurate on MPE", 1) if $Is_MPE;
145     skip("_POSIX_OPEN_MAX undefined ($fds[1])",  1) unless &_POSIX_OPEN_MAX;
146
147     cmp_ok(&_POSIX_OPEN_MAX, '>=', 16,
148            "The minimum allowed values according to susv2" );
149
150 }
151
152 my $pat;
153 if ( $unix_mode ) {
154     $pat = qr#[\\/]POSIX$#i;
155 }
156 else {
157     $pat = qr/\.POSIX]/i;
158 }
159 like( getcwd(), qr/$pat/, 'getcwd' );
160
161 # Check string conversion functions.
162
163 SKIP: { 
164     skip("strtod() not present", 2) unless $Config{d_strtod};
165
166     $lc = &POSIX::setlocale(&POSIX::LC_NUMERIC, 'C') if $Config{d_setlocale};
167
168     # we're just checking that strtod works, not how accurate it is
169     ($n, $x) = &POSIX::strtod('3.14159_OR_SO');
170     cmp_ok(abs("3.14159" - $n), '<', 1e-6, 'strtod works');
171     is($x, 6, 'strtod works');
172
173     &POSIX::setlocale(&POSIX::LC_NUMERIC, $lc) if $Config{d_setlocale};
174 }
175
176 SKIP: {
177     skip("strtol() not present", 2) unless $Config{d_strtol};
178
179     ($n, $x) = &POSIX::strtol('21_PENGUINS');
180     is($n, 21, 'strtol() number');
181     is($x, 9,  '         unparsed chars');
182 }
183
184 SKIP: {
185     skip("strtoul() not present", 2) unless $Config{d_strtoul};
186
187     ($n, $x) = &POSIX::strtoul('88_TEARS');
188     is($n, 88, 'strtoul() number');
189     is($x, 6,  '          unparsed chars');
190 }
191
192 # Pick up whether we're really able to dynamically load everything.
193 cmp_ok(&POSIX::acos(1.0), '==', 0.0, 'dynamic loading');
194
195 # This can coredump if struct tm has a timezone field and we
196 # didn't detect it.  If this fails, try adding
197 # -DSTRUCT_TM_HASZONE to your cflags when compiling ext/POSIX/POSIX.c.
198 # See ext/POSIX/hints/sunos_4.pl and ext/POSIX/hints/linux.pl 
199 $test = next_test();
200 print POSIX::strftime("ok $test # %H:%M, on %m/%d/%y\n", localtime());
201
202 # If that worked, validate the mini_mktime() routine's normalisation of
203 # input fields to strftime().
204 sub try_strftime {
205     my $expect = shift;
206     my $got = POSIX::strftime("%a %b %d %H:%M:%S %Y %j", @_);
207     is($got, $expect, "validating mini_mktime() and strftime(): $expect");
208 }
209
210 $lc = &POSIX::setlocale(&POSIX::LC_TIME, 'C') if $Config{d_setlocale};
211 try_strftime("Wed Feb 28 00:00:00 1996 059", 0,0,0, 28,1,96);
212 SKIP: {
213     skip("VC++ 8 and Vista's CRTs regard 60 seconds as an invalid parameter", 1)
214         if ($Is_W32 and (($Config{cc} eq 'cl' and
215                          $Config{ccversion} =~ /^(\d+)/ and $1 >= 14) or
216                          (Win32::GetOSVersion())[1] >= 6));
217
218     try_strftime("Thu Feb 29 00:00:60 1996 060", 60,0,-24, 30,1,96);
219 }
220 try_strftime("Fri Mar 01 00:00:00 1996 061", 0,0,-24, 31,1,96);
221 try_strftime("Sun Feb 28 00:00:00 1999 059", 0,0,0, 28,1,99);
222 try_strftime("Mon Mar 01 00:00:00 1999 060", 0,0,24, 28,1,99);
223 try_strftime("Mon Feb 28 00:00:00 2000 059", 0,0,0, 28,1,100);
224 try_strftime("Tue Feb 29 00:00:00 2000 060", 0,0,0, 0,2,100);
225 try_strftime("Wed Mar 01 00:00:00 2000 061", 0,0,0, 1,2,100);
226 try_strftime("Fri Mar 31 00:00:00 2000 091", 0,0,0, 31,2,100);
227
228 { # rt 72232
229
230   # Std C/POSIX allows day/month to be negative and requires that
231   # wday/yday be adjusted as needed
232   # previously mini_mktime() would allow yday to dominate if mday and
233   # month were both non-positive
234   # check that yday doesn't dominate
235   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100);
236   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100,-1,10);
237   # it would also allow a positive wday to override the calculated value
238   # check that wday is recalculated too
239   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100,0,10);
240 }
241
242 &POSIX::setlocale(&POSIX::LC_TIME, $lc) if $Config{d_setlocale};
243
244 {
245     for my $test (0, 1) {
246         $! = 0;
247         # POSIX::errno is autoloaded. 
248         # Autoloading requires many system calls.
249         # errno() looks at $! to generate its result.
250         # Autoloading should not munge the value.
251         my $foo  = $!;
252         my $errno = POSIX::errno();
253
254         # Force numeric context.
255         is( $errno + 0, $foo + 0,     'autoloading and errno() mix' );
256     }
257 }
258
259 SKIP: {
260   skip("no kill() support on Mac OS", 1) if $Is_MacOS;
261   is (eval "kill 0", 0, "check we have CORE::kill")
262     or print "\$\@ is " . _qq($@) . "\n";
263 }
264
265 # Check that we can import the POSIX kill routine
266 POSIX->import ('kill');
267 my $result = eval "kill 0";
268 is ($result, undef, "we should now have POSIX::kill");
269 # Check usage.
270 like ($@, qr/^Usage: POSIX::kill\(pid, sig\)/, "check its usage message");
271
272 # Check unimplemented.
273 $result = eval {POSIX::offsetof};
274 is ($result, undef, "offsetof should fail");
275 like ($@, qr/^Unimplemented: POSIX::offsetof\(\) is C-specific/,
276       "check its unimplemented message");
277
278 # Check reimplemented.
279 $result = eval {POSIX::fgets};
280 is ($result, undef, "fgets should fail");
281 like ($@, qr/^Use method IO::Handle::gets\(\) instead/,
282       "check its redef message");
283
284 # Simplistic tests for the isXXX() functions (bug #16799)
285 ok( POSIX::isalnum('1'),  'isalnum' );
286 ok(!POSIX::isalnum('*'),  'isalnum' );
287 ok( POSIX::isalpha('f'),  'isalpha' );
288 ok(!POSIX::isalpha('7'),  'isalpha' );
289 ok( POSIX::iscntrl("\cA"),'iscntrl' );
290 ok(!POSIX::iscntrl("A"),  'iscntrl' );
291 ok( POSIX::isdigit('1'),  'isdigit' );
292 ok(!POSIX::isdigit('z'),  'isdigit' );
293 ok( POSIX::isgraph('@'),  'isgraph' );
294 ok(!POSIX::isgraph(' '),  'isgraph' );
295 ok( POSIX::islower('l'),  'islower' );
296 ok(!POSIX::islower('L'),  'islower' );
297 ok( POSIX::isupper('U'),  'isupper' );
298 ok(!POSIX::isupper('u'),  'isupper' );
299 ok( POSIX::isprint('$'),  'isprint' );
300 ok(!POSIX::isprint("\n"), 'isprint' );
301 ok( POSIX::ispunct('%'),  'ispunct' );
302 ok(!POSIX::ispunct('u'),  'ispunct' );
303 ok( POSIX::isspace("\t"), 'isspace' );
304 ok(!POSIX::isspace('_'),  'isspace' );
305 ok( POSIX::isxdigit('f'), 'isxdigit' );
306 ok(!POSIX::isxdigit('g'), 'isxdigit' );
307 # metaphysical question : what should be returned for an empty string ?
308 # anyway this shouldn't segfault (bug #24554)
309 ok( POSIX::isalnum(''),   'isalnum empty string' );
310 ok( POSIX::isalnum(undef),'isalnum undef' );
311 # those functions should stringify their arguments
312 ok(!POSIX::isalpha([]),   'isalpha []' );
313 ok( POSIX::isprint([]),   'isprint []' );
314
315 eval { use strict; POSIX->import("S_ISBLK"); my $x = S_ISBLK };
316 unlike( $@, qr/Can't use string .* as a symbol ref/, "Can import autoloaded constants" );
317
318 SKIP: {
319     skip("localeconv() not present", 20) unless $Config{d_locconv};
320     my $conv = localeconv;
321     is(ref $conv, 'HASH', 'localconv returns a hash reference');
322
323     foreach (qw(decimal_point thousands_sep grouping int_curr_symbol
324                 currency_symbol mon_decimal_point mon_thousands_sep
325                 mon_grouping positive_sign negative_sign)) {
326     SKIP: {
327             skip("localeconv has no result for $_", 1)
328                 unless exists $conv->{$_};
329             unlike(delete $conv->{$_}, qr/\A\z/,
330                    "localeconv returned a non-empty string for $_");
331         }
332     }
333
334     foreach (qw(int_frac_digits frac_digits p_cs_precedes p_sep_by_space
335                 n_cs_precedes n_sep_by_space p_sign_posn n_sign_posn)) {
336     SKIP: {
337             skip("localeconv has no result for $_", 1)
338                 unless exists $conv->{$_};
339             like(delete $conv->{$_}, qr/\A-?\d+\z/,
340                  "localeconv returned an integer for $_");
341         }
342     }
343     is_deeply([%$conv], [], 'no unexpected keys returned by localeconv');
344 }
345
346 my $fd1 = open("Makefile.PL", O_RDONLY, 0);
347 like($fd1, qr/\A\d+\z/, 'O_RDONLY with open');
348 cmp_ok($fd1, '>', $testfd);
349 my $fd2 = dup($fd1);
350 like($fd2, qr/\A\d+\z/, 'dup');
351 cmp_ok($fd2, '>', $fd1);
352 is(POSIX::close($fd1), '0 but true', 'close');
353 is(POSIX::close($testfd), '0 but true', 'close');
354 $! = 0;
355 undef $buffer;
356 is(read($fd1, $buffer, 4), undef, 'read on closed file handle fails');
357 cmp_ok($!, '==', POSIX::EBADF);
358 undef $buffer;
359 read($fd2, $buffer, 4) if $fd2 > 2;
360 is($buffer, "# Ex", 'read');
361 # The descriptor $testfd was using is now free, and is lower than that which
362 # $fd1 was using. Hence if dup2() behaves as dup(), we'll know :-)
363 {
364     $testfd = dup2($fd2, $fd1);
365     is($testfd, $fd1, 'dup2');
366     undef $buffer;
367     read($testfd, $buffer, 4) if $testfd > 2;
368     is($buffer, 'pect', 'read');
369     is(lseek($testfd, 0, 0), 0, 'lseek back');
370     # The two should share file position:
371     undef $buffer;
372     read($fd2, $buffer, 4) if $fd2 > 2;
373     is($buffer, "# Ex", 'read');
374 }
375
376 # The FreeBSD man page warns:
377 # The access() system call is a potential security hole due to race
378 # conditions and should never be used.
379 is(access('Makefile.PL', POSIX::F_OK), '0 but true', 'access');
380 is(access('Makefile.PL', POSIX::R_OK), '0 but true', 'access');
381 $! = 0;
382 is(access('no such file', POSIX::F_OK), undef, 'access on missing file');
383 cmp_ok($!, '==', POSIX::ENOENT);
384 is(access('Makefile.PL/nonsense', POSIX::F_OK), undef,
385    'access on not-a-directory');
386 SKIP: {
387     skip("$^O is insufficiently POSIX", 1)
388         if $Is_W32 || $Is_VMS;
389     cmp_ok($!, '==', POSIX::ENOTDIR);
390 }
391
392 # Check that output is not flushed by _exit. This test should be last
393 # in the file, and is not counted in the total number of tests.
394 if ($^O eq 'vos') {
395  print "# TODO - hit VOS bug posix-885 - _exit flushes output buffers.\n";
396 } else {
397  $| = 0;
398  # The following line assumes buffered output, which may be not true:
399  print '@#!*$@(!@#$' unless ($Is_MacOS || $Is_OS2 || $Is_UWin || $Is_OS390 ||
400                             $Is_VMS ||
401                             (defined $ENV{PERLIO} &&
402                              $ENV{PERLIO} eq 'unix' &&
403                              $Config::Config{useperlio}));
404  _exit(0);
405 }