This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Document the new shift behaviors.
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in S<C<2 + 4 * 5>>, the multiplication has higher
32 precedence so S<C<4 * 5>> is evaluated first yielding S<C<2 + 20 ==
33 22>> and not S<C<6 * 5 == 30>>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first, or the right first.  For example, in
38 S<C<8 - 4 - 2>>, subtraction is left associative so Perl evaluates the
39 expression left to right.  S<C<8 - 4>> is evaluated first making the
40 expression S<C<4 - 2 == 2>> and not S<C<8 - 2 == 6>>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in precedence order.
75
76 Many operators can be overloaded for objects.  See L<overload>.
77
78 =head2 Terms and List Operators (Leftward)
79 X<list operator> X<operator, list> X<term>
80
81 A TERM has the highest precedence in Perl.  They include variables,
82 quote and quote-like operators, any expression in parentheses,
83 and any function whose arguments are parenthesized.  Actually, there
84 aren't really functions in this sense, just list operators and unary
85 operators behaving as functions because you put parentheses around
86 the arguments.  These are all documented in L<perlfunc>.
87
88 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
89 is followed by a left parenthesis as the next token, the operator and
90 arguments within parentheses are taken to be of highest precedence,
91 just like a normal function call.
92
93 In the absence of parentheses, the precedence of list operators such as
94 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
95 whether you are looking at the left side or the right side of the operator.
96 For example, in
97
98     @ary = (1, 3, sort 4, 2);
99     print @ary;         # prints 1324
100
101 the commas on the right of the C<sort> are evaluated before the C<sort>,
102 but the commas on the left are evaluated after.  In other words,
103 list operators tend to gobble up all arguments that follow, and
104 then act like a simple TERM with regard to the preceding expression.
105 Be careful with parentheses:
106
107     # These evaluate exit before doing the print:
108     print($foo, exit);  # Obviously not what you want.
109     print $foo, exit;   # Nor is this.
110
111     # These do the print before evaluating exit:
112     (print $foo), exit; # This is what you want.
113     print($foo), exit;  # Or this.
114     print ($foo), exit; # Or even this.
115
116 Also note that
117
118     print ($foo & 255) + 1, "\n";
119
120 probably doesn't do what you expect at first glance.  The parentheses
121 enclose the argument list for C<print> which is evaluated (printing
122 the result of S<C<$foo & 255>>).  Then one is added to the return value
123 of C<print> (usually 1).  The result is something like this:
124
125     1 + 1, "\n";    # Obviously not what you meant.
126
127 To do what you meant properly, you must write:
128
129     print(($foo & 255) + 1, "\n");
130
131 See L<Named Unary Operators> for more discussion of this.
132
133 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
134 well as subroutine and method calls, and the anonymous
135 constructors C<[]> and C<{}>.
136
137 See also L<Quote and Quote-like Operators> toward the end of this section,
138 as well as L</"I/O Operators">.
139
140 =head2 The Arrow Operator
141 X<arrow> X<dereference> X<< -> >>
142
143 "C<< -> >>" is an infix dereference operator, just as it is in C
144 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
145 C<(...)> subscript, then the left side must be either a hard or
146 symbolic reference to an array, a hash, or a subroutine respectively.
147 (Or technically speaking, a location capable of holding a hard
148 reference, if it's an array or hash reference being used for
149 assignment.)  See L<perlreftut> and L<perlref>.
150
151 Otherwise, the right side is a method name or a simple scalar
152 variable containing either the method name or a subroutine reference,
153 and the left side must be either an object (a blessed reference)
154 or a class name (that is, a package name).  See L<perlobj>.
155
156 The dereferencing cases (as opposed to method-calling cases) are
157 somewhat extended by the C<postderef> feature.  For the
158 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
159
160 =head2 Auto-increment and Auto-decrement
161 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
162
163 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
164 they increment or decrement the variable by one before returning the
165 value, and if placed after, increment or decrement after returning the
166 value.
167
168     $i = 0;  $j = 0;
169     print $i++;  # prints 0
170     print ++$j;  # prints 1
171
172 Note that just as in C, Perl doesn't define B<when> the variable is
173 incremented or decremented.  You just know it will be done sometime
174 before or after the value is returned.  This also means that modifying
175 a variable twice in the same statement will lead to undefined behavior.
176 Avoid statements like:
177
178     $i = $i ++;
179     print ++ $i + $i ++;
180
181 Perl will not guarantee what the result of the above statements is.
182
183 The auto-increment operator has a little extra builtin magic to it.  If
184 you increment a variable that is numeric, or that has ever been used in
185 a numeric context, you get a normal increment.  If, however, the
186 variable has been used in only string contexts since it was set, and
187 has a value that is not the empty string and matches the pattern
188 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
189 character within its range, with carry:
190
191     print ++($foo = "99");      # prints "100"
192     print ++($foo = "a0");      # prints "a1"
193     print ++($foo = "Az");      # prints "Ba"
194     print ++($foo = "zz");      # prints "aaa"
195
196 C<undef> is always treated as numeric, and in particular is changed
197 to C<0> before incrementing (so that a post-increment of an undef value
198 will return C<0> rather than C<undef>).
199
200 The auto-decrement operator is not magical.
201
202 =head2 Exponentiation
203 X<**> X<exponentiation> X<power>
204
205 Binary C<"**"> is the exponentiation operator.  It binds even more
206 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
207 (This is
208 implemented using C's C<pow(3)> function, which actually works on doubles
209 internally.)
210
211 Note that certain exponentiation expressions are ill-defined:
212 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
213 any particular results from these special cases, the results
214 are platform-dependent.
215
216 =head2 Symbolic Unary Operators
217 X<unary operator> X<operator, unary>
218
219 Unary C<"!"> performs logical negation, that is, "not".  See also C<not> for a lower
220 precedence version of this.
221 X<!>
222
223 Unary C<"-"> performs arithmetic negation if the operand is numeric,
224 including any string that looks like a number.  If the operand is
225 an identifier, a string consisting of a minus sign concatenated
226 with the identifier is returned.  Otherwise, if the string starts
227 with a plus or minus, a string starting with the opposite sign is
228 returned.  One effect of these rules is that C<-bareword> is equivalent
229 to the string C<"-bareword">.  If, however, the string begins with a
230 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
231 to convert
232 the string to a numeric, and the arithmetic negation is performed.  If the
233 string cannot be cleanly converted to a numeric, Perl will give the warning
234 B<Argument "the string" isn't numeric in negation (-) at ...>.
235 X<-> X<negation, arithmetic>
236
237 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
238 example, S<C<0666 & ~027>> is 0640.  (See also L<Integer Arithmetic> and
239 L<Bitwise String Operators>.)  Note that the width of the result is
240 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
241 bits wide on a 64-bit platform, so if you are expecting a certain bit
242 width, remember to use the C<"&"> operator to mask off the excess bits.
243 X<~> X<negation, binary>
244
245 When complementing strings, if all characters have ordinal values under
246 256, then their complements will, also.  But if they do not, all
247 characters will be in either 32- or 64-bit complements, depending on your
248 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
249 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
250
251 If the experimental "bitwise" feature is enabled via S<C<use feature
252 'bitwise'>>, then unary C<"~"> always treats its argument as a number, and an
253 alternate form of the operator, C<"~.">, always treats its argument as a
254 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
255 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  This feature
256 produces a warning unless you use S<C<no warnings 'experimental::bitwise'>>.
257
258 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
259 syntactically for separating a function name from a parenthesized expression
260 that would otherwise be interpreted as the complete list of function
261 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
262 X<+>
263
264 Unary C<"\"> creates a reference to whatever follows it.  See L<perlreftut>
265 and L<perlref>.  Do not confuse this behavior with the behavior of
266 backslash within a string, although both forms do convey the notion
267 of protecting the next thing from interpolation.
268 X<\> X<reference> X<backslash>
269
270 =head2 Binding Operators
271 X<binding> X<operator, binding> X<=~> X<!~>
272
273 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
274 search or modify the string C<$_> by default.  This operator makes that kind
275 of operation work on some other string.  The right argument is a search
276 pattern, substitution, or transliteration.  The left argument is what is
277 supposed to be searched, substituted, or transliterated instead of the default
278 C<$_>.  When used in scalar context, the return value generally indicates the
279 success of the operation.  The exceptions are substitution (C<s///>)
280 and transliteration (C<y///>) with the C</r> (non-destructive) option,
281 which cause the B<r>eturn value to be the result of the substitution.
282 Behavior in list context depends on the particular operator.
283 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
284 examples using these operators.
285
286 If the right argument is an expression rather than a search pattern,
287 substitution, or transliteration, it is interpreted as a search pattern at run
288 time.  Note that this means that its
289 contents will be interpolated twice, so
290
291     '\\' =~ q'\\';
292
293 is not ok, as the regex engine will end up trying to compile the
294 pattern C<\>, which it will consider a syntax error.
295
296 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
297 the logical sense.
298
299 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
300 (C<y///r>) is a syntax error.
301
302 =head2 Multiplicative Operators
303 X<operator, multiplicative>
304
305 Binary C<"*"> multiplies two numbers.
306 X<*>
307
308 Binary C<"/"> divides two numbers.
309 X</> X<slash>
310
311 Binary C<"%"> is the modulo operator, which computes the division
312 remainder of its first argument with respect to its second argument.
313 Given integer
314 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
315 C<$m> minus the largest multiple of C<$n> less than or equal to
316 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
317 smallest multiple of C<$n> that is not less than C<$m> (that is, the
318 result will be less than or equal to zero).  If the operands
319 C<$m> and C<$n> are floating point values and the absolute value of
320 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
321 the integer portion of C<$m> and C<$n> will be used in the operation
322 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
323 If the absolute value of the right operand (C<abs($n)>) is greater than
324 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
325 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
326 integer that makes C<$r> have the same sign as the right operand
327 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
328 and the absolute value less than that of C<$n>.
329 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
330 to the modulo operator as implemented by your C compiler.  This
331 operator is not as well defined for negative operands, but it will
332 execute faster.
333 X<%> X<remainder> X<modulo> X<mod>
334
335 Binary C<"x"> is the repetition operator.  In scalar context or if the left
336 operand is not enclosed in parentheses, it returns a string consisting
337 of the left operand repeated the number of times specified by the right
338 operand.  In list context, if the left operand is enclosed in
339 parentheses or is a list formed by C<qw/I<STRING>/>, it repeats the list.
340 If the right operand is zero or negative (raising a warning on
341 negative), it returns an empty string
342 or an empty list, depending on the context.
343 X<x>
344
345     print '-' x 80;             # print row of dashes
346
347     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
348
349     @ones = (1) x 80;           # a list of 80 1's
350     @ones = (5) x @ones;        # set all elements to 5
351
352
353 =head2 Additive Operators
354 X<operator, additive>
355
356 Binary C<"+"> returns the sum of two numbers.
357 X<+>
358
359 Binary C<"-"> returns the difference of two numbers.
360 X<->
361
362 Binary C<"."> concatenates two strings.
363 X<string, concatenation> X<concatenation>
364 X<cat> X<concat> X<concatenate> X<.>
365
366 =head2 Shift Operators
367 X<shift operator> X<operator, shift> X<<< << >>>
368 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
369 X<shl> X<shr> X<shift, right> X<shift, left>
370
371 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
372 number of bits specified by the right argument.  Arguments should be
373 integers.  (See also L<Integer Arithmetic>.)
374
375 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
376 the number of bits specified by the right argument.  Arguments should
377 be integers.  (See also L<Integer Arithmetic>.)
378
379 If S<C<use integer>> (see L<Integer Arithmetic>) is in force then
380 signed C integers are used (I<arithmetic shift>), otherwise unsigned C
381 integers are used (I<logical shift>), even for negative shiftees.
382 In arithmetic right shift the sign bit is replicated on the left,
383 in logical shift zero bits come in from the left.
384
385 Either way, the implementation isn't going to generate results larger
386 than the size of the integer type Perl was built with (32 bits or 64 bits).
387
388 Shifting by negative number of bits means the reverse shift: left
389 shift becomes right shift, right shift becomes left shift.  This is
390 unlike in C, where negative shift is undefined.
391
392 Shifting by more bits than the size of the integers means most of the
393 time zero (all bits fall off), except that under S<C<use integer>>
394 right overshifting a negative shiftee results in -1.  This is unlike
395 in C, where shifting by too many bits is undefined.  A common C
396 behavior is "shift by modulo wordbits", so that for example
397
398     1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1  # Common C behavior.
399
400 but that is completely accidental.
401
402 If you get tired of being subject to your platform's native integers,
403 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
404
405     print 20 << 20;  # 20971520
406     print 20 << 40;  # 5120 on 32-bit machines, 
407                      # 21990232555520 on 64-bit machines
408     use bigint;
409     print 20 << 100; # 25353012004564588029934064107520
410
411 =head2 Named Unary Operators
412 X<operator, named unary>
413
414 The various named unary operators are treated as functions with one
415 argument, with optional parentheses.
416
417 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
418 is followed by a left parenthesis as the next token, the operator and
419 arguments within parentheses are taken to be of highest precedence,
420 just like a normal function call.  For example,
421 because named unary operators are higher precedence than C<||>:
422
423     chdir $foo    || die;       # (chdir $foo) || die
424     chdir($foo)   || die;       # (chdir $foo) || die
425     chdir ($foo)  || die;       # (chdir $foo) || die
426     chdir +($foo) || die;       # (chdir $foo) || die
427
428 but, because C<"*"> is higher precedence than named operators:
429
430     chdir $foo * 20;    # chdir ($foo * 20)
431     chdir($foo) * 20;   # (chdir $foo) * 20
432     chdir ($foo) * 20;  # (chdir $foo) * 20
433     chdir +($foo) * 20; # chdir ($foo * 20)
434
435     rand 10 * 20;       # rand (10 * 20)
436     rand(10) * 20;      # (rand 10) * 20
437     rand (10) * 20;     # (rand 10) * 20
438     rand +(10) * 20;    # rand (10 * 20)
439
440 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
441 treated like named unary operators, but they don't follow this functional
442 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
443 equivalent to S<C<-f "$file.bak">>.
444 X<-X> X<filetest> X<operator, filetest>
445
446 See also L<"Terms and List Operators (Leftward)">.
447
448 =head2 Relational Operators
449 X<relational operator> X<operator, relational>
450
451 Perl operators that return true or false generally return values 
452 that can be safely used as numbers.  For example, the relational
453 operators in this section and the equality operators in the next
454 one return C<1> for true and a special version of the defined empty
455 string, C<"">, which counts as a zero but is exempt from warnings
456 about improper numeric conversions, just as S<C<"0 but true">> is.
457
458 Binary C<< "<" >> returns true if the left argument is numerically less than
459 the right argument.
460 X<< < >>
461
462 Binary C<< ">" >> returns true if the left argument is numerically greater
463 than the right argument.
464 X<< > >>
465
466 Binary C<< "<=" >> returns true if the left argument is numerically less than
467 or equal to the right argument.
468 X<< <= >>
469
470 Binary C<< ">=" >> returns true if the left argument is numerically greater
471 than or equal to the right argument.
472 X<< >= >>
473
474 Binary C<"lt"> returns true if the left argument is stringwise less than
475 the right argument.
476 X<< lt >>
477
478 Binary C<"gt"> returns true if the left argument is stringwise greater
479 than the right argument.
480 X<< gt >>
481
482 Binary C<"le"> returns true if the left argument is stringwise less than
483 or equal to the right argument.
484 X<< le >>
485
486 Binary C<"ge"> returns true if the left argument is stringwise greater
487 than or equal to the right argument.
488 X<< ge >>
489
490 =head2 Equality Operators
491 X<equality> X<equal> X<equals> X<operator, equality>
492
493 Binary C<< "==" >> returns true if the left argument is numerically equal to
494 the right argument.
495 X<==>
496
497 Binary C<< "!=" >> returns true if the left argument is numerically not equal
498 to the right argument.
499 X<!=>
500
501 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
502 argument is numerically less than, equal to, or greater than the right
503 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
504 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
505 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
506 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
507 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
508 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
509 X<< <=> >>
510 X<spaceship>
511
512     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
513     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
514
515 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
516 support C<"NaN">.)
517
518 Binary C<"eq"> returns true if the left argument is stringwise equal to
519 the right argument.
520 X<eq>
521
522 Binary C<"ne"> returns true if the left argument is stringwise not equal
523 to the right argument.
524 X<ne>
525
526 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
527 argument is stringwise less than, equal to, or greater than the right
528 argument.
529 X<cmp>
530
531 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
532 is described in the next section.
533 X<~~>
534
535 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
536 order specified by the current C<LC_COLLATE> locale if a S<C<use
537 locale>> form that includes collation is in effect.  See L<perllocale>.
538 Do not mix these with Unicode,
539 only use them with legacy 8-bit locale encodings.
540 The standard C<L<Unicode::Collate>> and
541 C<L<Unicode::Collate::Locale>> modules offer much more powerful
542 solutions to collation issues.
543
544 For case-insensitive comparisions, look at the L<perlfunc/fc> case-folding
545 function, available in Perl v5.16 or later:
546
547     if ( fc($x) eq fc($y) ) { ... }
548
549 =head2 Smartmatch Operator
550
551 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
552 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
553 used implicitly in the C<when> construct described in L<perlsyn>, although
554 not all C<when> clauses call the smartmatch operator.  Unique among all of
555 Perl's operators, the smartmatch operator can recurse.  The smartmatch
556 operator is L<experimental|perlpolicy/experimental> and its behavior is
557 subject to change.
558
559 It is also unique in that all other Perl operators impose a context
560 (usually string or numeric context) on their operands, autoconverting
561 those operands to those imposed contexts.  In contrast, smartmatch
562 I<infers> contexts from the actual types of its operands and uses that
563 type information to select a suitable comparison mechanism.
564
565 The C<~~> operator compares its operands "polymorphically", determining how
566 to compare them according to their actual types (numeric, string, array,
567 hash, etc.)  Like the equality operators with which it shares the same
568 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
569 read aloud as "in", "inside of", or "is contained in", because the left
570 operand is often looked for I<inside> the right operand.  That makes the
571 order of the operands to the smartmatch operand often opposite that of
572 the regular match operator.  In other words, the "smaller" thing is usually
573 placed in the left operand and the larger one in the right.
574
575 The behavior of a smartmatch depends on what type of things its arguments
576 are, as determined by the following table.  The first row of the table
577 whose types apply determines the smartmatch behavior.  Because what
578 actually happens is mostly determined by the type of the second operand,
579 the table is sorted on the right operand instead of on the left.
580
581  Left      Right      Description and pseudocode                               
582  ===============================================================
583  Any       undef      check whether Any is undefined                    
584                 like: !defined Any
585
586  Any       Object     invoke ~~ overloading on Object, or die
587
588  Right operand is an ARRAY:
589
590  Left      Right      Description and pseudocode                               
591  ===============================================================
592  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
593                 like: (ARRAY1[0] ~~ ARRAY2[0])
594                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
595  HASH      ARRAY      any ARRAY elements exist as HASH keys             
596                 like: grep { exists HASH->{$_} } ARRAY
597  Regexp    ARRAY      any ARRAY elements pattern match Regexp
598                 like: grep { /Regexp/ } ARRAY
599  undef     ARRAY      undef in ARRAY                                    
600                 like: grep { !defined } ARRAY
601  Any       ARRAY      smartmatch each ARRAY element[3]                   
602                 like: grep { Any ~~ $_ } ARRAY
603
604  Right operand is a HASH:
605
606  Left      Right      Description and pseudocode                               
607  ===============================================================
608  HASH1     HASH2      all same keys in both HASHes                      
609                 like: keys HASH1 ==
610                          grep { exists HASH2->{$_} } keys HASH1
611  ARRAY     HASH       any ARRAY elements exist as HASH keys             
612                 like: grep { exists HASH->{$_} } ARRAY
613  Regexp    HASH       any HASH keys pattern match Regexp                
614                 like: grep { /Regexp/ } keys HASH
615  undef     HASH       always false (undef can't be a key)               
616                 like: 0 == 1
617  Any       HASH       HASH key existence                                
618                 like: exists HASH->{Any}
619
620  Right operand is CODE:
621
622  Left      Right      Description and pseudocode                               
623  ===============================================================
624  ARRAY     CODE       sub returns true on all ARRAY elements[1]
625                 like: !grep { !CODE->($_) } ARRAY
626  HASH      CODE       sub returns true on all HASH keys[1]
627                 like: !grep { !CODE->($_) } keys HASH
628  Any       CODE       sub passed Any returns true              
629                 like: CODE->(Any)
630
631 Right operand is a Regexp:
632
633  Left      Right      Description and pseudocode                               
634  ===============================================================
635  ARRAY     Regexp     any ARRAY elements match Regexp                   
636                 like: grep { /Regexp/ } ARRAY
637  HASH      Regexp     any HASH keys match Regexp                        
638                 like: grep { /Regexp/ } keys HASH
639  Any       Regexp     pattern match                                     
640                 like: Any =~ /Regexp/
641
642  Other:
643
644  Left      Right      Description and pseudocode                               
645  ===============================================================
646  Object    Any        invoke ~~ overloading on Object,
647                       or fall back to...
648
649  Any       Num        numeric equality                                  
650                  like: Any == Num
651  Num       nummy[4]    numeric equality
652                  like: Num == nummy
653  undef     Any        check whether undefined
654                  like: !defined(Any)
655  Any       Any        string equality                                   
656                  like: Any eq Any
657
658
659 Notes:
660
661 =over
662
663 =item 1.
664 Empty hashes or arrays match. 
665
666 =item 2.
667 That is, each element smartmatches the element of the same index in the other array.[3]
668
669 =item 3.
670 If a circular reference is found, fall back to referential equality. 
671
672 =item 4.
673 Either an actual number, or a string that looks like one.
674
675 =back
676
677 The smartmatch implicitly dereferences any non-blessed hash or array
678 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
679 For blessed references, the C<I<Object>> entries apply.  Smartmatches
680 involving hashes only consider hash keys, never hash values.
681
682 The "like" code entry is not always an exact rendition.  For example, the
683 smartmatch operator short-circuits whenever possible, but C<grep> does
684 not.  Also, C<grep> in scalar context returns the number of matches, but
685 C<~~> returns only true or false.
686
687 Unlike most operators, the smartmatch operator knows to treat C<undef>
688 specially:
689
690     use v5.10.1;
691     @array = (1, 2, 3, undef, 4, 5);
692     say "some elements undefined" if undef ~~ @array;
693
694 Each operand is considered in a modified scalar context, the modification
695 being that array and hash variables are passed by reference to the
696 operator, which implicitly dereferences them.  Both elements
697 of each pair are the same:
698
699     use v5.10.1;
700
701     my %hash = (red    => 1, blue   => 2, green  => 3,
702                 orange => 4, yellow => 5, purple => 6,
703                 black  => 7, grey   => 8, white  => 9);
704
705     my @array = qw(red blue green);
706
707     say "some array elements in hash keys" if  @array ~~  %hash;
708     say "some array elements in hash keys" if \@array ~~ \%hash;
709
710     say "red in array" if "red" ~~  @array;
711     say "red in array" if "red" ~~ \@array;
712
713     say "some keys end in e" if /e$/ ~~  %hash;
714     say "some keys end in e" if /e$/ ~~ \%hash;
715
716 Two arrays smartmatch if each element in the first array smartmatches
717 (that is, is "in") the corresponding element in the second array,
718 recursively.
719
720     use v5.10.1;
721     my @little = qw(red blue green);
722     my @bigger = ("red", "blue", [ "orange", "green" ] );
723     if (@little ~~ @bigger) {  # true!
724         say "little is contained in bigger";
725     } 
726
727 Because the smartmatch operator recurses on nested arrays, this
728 will still report that "red" is in the array.
729
730     use v5.10.1;
731     my @array = qw(red blue green);
732     my $nested_array = [[[[[[[ @array ]]]]]]];
733     say "red in array" if "red" ~~ $nested_array;
734
735 If two arrays smartmatch each other, then they are deep
736 copies of each others' values, as this example reports:
737
738     use v5.12.0;
739     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
740     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
741
742     if (@a ~~ @b && @b ~~ @a) {
743         say "a and b are deep copies of each other";
744     } 
745     elsif (@a ~~ @b) {
746         say "a smartmatches in b";
747     } 
748     elsif (@b ~~ @a) {
749         say "b smartmatches in a";
750     } 
751     else {
752         say "a and b don't smartmatch each other at all";
753     } 
754
755
756 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
757 are deep copies of each other", it now reports that C<"b smartmatches in a">.
758 That's because the corresponding position in C<@a> contains an array that
759 (eventually) has a 4 in it.
760
761 Smartmatching one hash against another reports whether both contain the
762 same keys, no more and no less.  This could be used to see whether two
763 records have the same field names, without caring what values those fields
764 might have.  For example:
765
766     use v5.10.1;
767     sub make_dogtag {
768         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
769
770         my ($class, $init_fields) = @_;
771
772         die "Must supply (only) name, rank, and serial number"
773             unless $init_fields ~~ $REQUIRED_FIELDS;
774
775         ...
776     }
777
778 or, if other non-required fields are allowed, use ARRAY ~~ HASH:
779
780     use v5.10.1;
781     sub make_dogtag {
782         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
783
784         my ($class, $init_fields) = @_;
785
786         die "Must supply (at least) name, rank, and serial number"
787             unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS;
788
789         ...
790     }
791
792 The smartmatch operator is most often used as the implicit operator of a
793 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
794
795 =head3 Smartmatching of Objects
796
797 To avoid relying on an object's underlying representation, if the
798 smartmatch's right operand is an object that doesn't overload C<~~>,
799 it raises the exception "C<Smartmatching a non-overloaded object
800 breaks encapsulation>".  That's because one has no business digging
801 around to see whether something is "in" an object.  These are all
802 illegal on objects without a C<~~> overload:
803
804     %hash ~~ $object
805        42 ~~ $object
806    "fred" ~~ $object
807
808 However, you can change the way an object is smartmatched by overloading
809 the C<~~> operator.  This is allowed to
810 extend the usual smartmatch semantics.
811 For objects that do have an C<~~> overload, see L<overload>.
812
813 Using an object as the left operand is allowed, although not very useful.
814 Smartmatching rules take precedence over overloading, so even if the
815 object in the left operand has smartmatch overloading, this will be
816 ignored.  A left operand that is a non-overloaded object falls back on a
817 string or numeric comparison of whatever the C<ref> operator returns.  That
818 means that
819
820     $object ~~ X
821
822 does I<not> invoke the overload method with C<I<X>> as an argument.
823 Instead the above table is consulted as normal, and based on the type of
824 C<I<X>>, overloading may or may not be invoked.  For simple strings or
825 numbers, "in" becomes equivalent to this:
826
827     $object ~~ $number          ref($object) == $number
828     $object ~~ $string          ref($object) eq $string 
829
830 For example, this reports that the handle smells IOish
831 (but please don't really do this!):
832
833     use IO::Handle;
834     my $fh = IO::Handle->new();
835     if ($fh ~~ /\bIO\b/) {
836         say "handle smells IOish";
837     } 
838
839 That's because it treats C<$fh> as a string like
840 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
841
842 =head2 Bitwise And
843 X<operator, bitwise, and> X<bitwise and> X<&>
844
845 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
846 warning is currently raised, the result is not well defined when this operation
847 is performed on operands that aren't either numbers (see
848 L<Integer Arithmetic>) nor bitstrings (see L<Bitwise String Operators>).
849
850 Note that C<"&"> has lower priority than relational operators, so for example
851 the parentheses are essential in a test like
852
853     print "Even\n" if ($x & 1) == 0;
854
855 If the experimental "bitwise" feature is enabled via S<C<use feature
856 'bitwise'>>, then this operator always treats its operand as numbers.  This
857 feature produces a warning unless you also use C<S<no warnings
858 'experimental::bitwise'>>.
859
860 =head2 Bitwise Or and Exclusive Or
861 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
862 X<bitwise xor> X<^>
863
864 Binary C<"|"> returns its operands ORed together bit by bit.
865
866 Binary C<"^"> returns its operands XORed together bit by bit.
867
868 Although no warning is currently raised, the results are not well
869 defined when these operations are performed on operands that aren't either
870 numbers (see L<Integer Arithmetic>) nor bitstrings (see L<Bitwise String
871 Operators>).
872
873 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
874 for example the parentheses are essential in a test like
875
876     print "false\n" if (8 | 2) != 10;
877
878 If the experimental "bitwise" feature is enabled via S<C<use feature
879 'bitwise'>>, then this operator always treats its operand as numbers.  This
880 feature produces a warning unless you also use S<C<no warnings
881 'experimental::bitwise'>>.
882
883 =head2 C-style Logical And
884 X<&&> X<logical and> X<operator, logical, and>
885
886 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
887 if the left operand is false, the right operand is not even evaluated.
888 Scalar or list context propagates down to the right operand if it
889 is evaluated.
890
891 =head2 C-style Logical Or
892 X<||> X<operator, logical, or>
893
894 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
895 if the left operand is true, the right operand is not even evaluated.
896 Scalar or list context propagates down to the right operand if it
897 is evaluated.
898
899 =head2 Logical Defined-Or
900 X<//> X<operator, logical, defined-or>
901
902 Although it has no direct equivalent in C, Perl's C<//> operator is related
903 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
904 tests the left hand side's definedness instead of its truth.  Thus,
905 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
906 otherwise, the value of C<< EXPR2 >> is returned.
907 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
908 in the context of C<< // >> itself).  Usually,
909 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
910 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
911 cannot).  This is very useful for
912 providing default values for variables.  If you actually want to test if
913 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
914
915 The C<||>, C<//> and C<&&> operators return the last value evaluated
916 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
917 portable way to find out the home directory might be:
918
919     $home =  $ENV{HOME}
920           // $ENV{LOGDIR}
921           // (getpwuid($<))[7]
922           // die "You're homeless!\n";
923
924 In particular, this means that you shouldn't use this
925 for selecting between two aggregates for assignment:
926
927     @a = @b || @c;              # this is wrong
928     @a = scalar(@b) || @c;      # really meant this
929     @a = @b ? @b : @c;          # this works fine, though
930
931 As alternatives to C<&&> and C<||> when used for
932 control flow, Perl provides the C<and> and C<or> operators (see below).
933 The short-circuit behavior is identical.  The precedence of C<"and">
934 and C<"or"> is much lower, however, so that you can safely use them after a
935 list operator without the need for parentheses:
936
937     unlink "alpha", "beta", "gamma"
938             or gripe(), next LINE;
939
940 With the C-style operators that would have been written like this:
941
942     unlink("alpha", "beta", "gamma")
943             || (gripe(), next LINE);
944
945 It would be even more readable to write that this way:
946
947     unless(unlink("alpha", "beta", "gamma")) {
948         gripe();
949         next LINE;
950     } 
951
952 Using C<"or"> for assignment is unlikely to do what you want; see below.
953
954 =head2 Range Operators
955 X<operator, range> X<range> X<..> X<...>
956
957 Binary C<".."> is the range operator, which is really two different
958 operators depending on the context.  In list context, it returns a
959 list of values counting (up by ones) from the left value to the right
960 value.  If the left value is greater than the right value then it
961 returns the empty list.  The range operator is useful for writing
962 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
963 the current implementation, no temporary array is created when the
964 range operator is used as the expression in C<foreach> loops, but older
965 versions of Perl might burn a lot of memory when you write something
966 like this:
967
968     for (1 .. 1_000_000) {
969         # code
970     }
971
972 The range operator also works on strings, using the magical
973 auto-increment, see below.
974
975 In scalar context, C<".."> returns a boolean value.  The operator is
976 bistable, like a flip-flop, and emulates the line-range (comma)
977 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
978 maintains its own boolean state, even across calls to a subroutine
979 that contains it.  It is false as long as its left operand is false.
980 Once the left operand is true, the range operator stays true until the
981 right operand is true, I<AFTER> which the range operator becomes false
982 again.  It doesn't become false till the next time the range operator
983 is evaluated.  It can test the right operand and become false on the
984 same evaluation it became true (as in B<awk>), but it still returns
985 true once.  If you don't want it to test the right operand until the
986 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
987 two.  In all other regards, C<"..."> behaves just like C<".."> does.
988
989 The right operand is not evaluated while the operator is in the
990 "false" state, and the left operand is not evaluated while the
991 operator is in the "true" state.  The precedence is a little lower
992 than || and &&.  The value returned is either the empty string for
993 false, or a sequence number (beginning with 1) for true.  The sequence
994 number is reset for each range encountered.  The final sequence number
995 in a range has the string C<"E0"> appended to it, which doesn't affect
996 its numeric value, but gives you something to search for if you want
997 to exclude the endpoint.  You can exclude the beginning point by
998 waiting for the sequence number to be greater than 1.
999
1000 If either operand of scalar C<".."> is a constant expression,
1001 that operand is considered true if it is equal (C<==>) to the current
1002 input line number (the C<$.> variable).
1003
1004 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
1005 but that is only an issue if you use a floating point expression; when
1006 implicitly using C<$.> as described in the previous paragraph, the
1007 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
1008 is set to a floating point value and you are not reading from a file.
1009 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
1010 you want in scalar context because each of the operands are evaluated
1011 using their integer representation.
1012
1013 Examples:
1014
1015 As a scalar operator:
1016
1017     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1018                                #  if ($. == 101 .. $. == 200) { print; }
1019
1020     next LINE if (1 .. /^$/);  # skip header lines, short for
1021                                #   next LINE if ($. == 1 .. /^$/);
1022                                # (typically in a loop labeled LINE)
1023
1024     s/^/> / if (/^$/ .. eof());  # quote body
1025
1026     # parse mail messages
1027     while (<>) {
1028         $in_header =   1  .. /^$/;
1029         $in_body   = /^$/ .. eof;
1030         if ($in_header) {
1031             # do something
1032         } else { # in body
1033             # do something else
1034         }
1035     } continue {
1036         close ARGV if eof;             # reset $. each file
1037     }
1038
1039 Here's a simple example to illustrate the difference between
1040 the two range operators:
1041
1042     @lines = ("   - Foo",
1043               "01 - Bar",
1044               "1  - Baz",
1045               "   - Quux");
1046
1047     foreach (@lines) {
1048         if (/0/ .. /1/) {
1049             print "$_\n";
1050         }
1051     }
1052
1053 This program will print only the line containing "Bar".  If
1054 the range operator is changed to C<...>, it will also print the
1055 "Baz" line.
1056
1057 And now some examples as a list operator:
1058
1059     for (101 .. 200) { print }      # print $_ 100 times
1060     @foo = @foo[0 .. $#foo];        # an expensive no-op
1061     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1062
1063 The range operator (in list context) makes use of the magical
1064 auto-increment algorithm if the operands are strings.  You
1065 can say
1066
1067     @alphabet = ("A" .. "Z");
1068
1069 to get all normal letters of the English alphabet, or
1070
1071     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1072
1073 to get a hexadecimal digit, or
1074
1075     @z2 = ("01" .. "31");
1076     print $z2[$mday];
1077
1078 to get dates with leading zeros.
1079
1080 If the final value specified is not in the sequence that the magical
1081 increment would produce, the sequence goes until the next value would
1082 be longer than the final value specified.
1083
1084 If the initial value specified isn't part of a magical increment
1085 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1086 only the initial value will be returned.  So the following will only
1087 return an alpha:
1088
1089     use charnames "greek";
1090     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1091
1092 To get the 25 traditional lowercase Greek letters, including both sigmas,
1093 you could use this instead:
1094
1095     use charnames "greek";
1096     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1097                                         ..
1098                                      ord("\N{omega}") 
1099                                    );
1100
1101 However, because there are I<many> other lowercase Greek characters than
1102 just those, to match lowercase Greek characters in a regular expression,
1103 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1104 L<experimental feature|perlrecharclass/Extended Bracketed Character
1105 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1106
1107 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1108 return two elements in list context.
1109
1110     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1111
1112 =head2 Conditional Operator
1113 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1114
1115 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1116 like an if-then-else.  If the argument before the C<?> is true, the
1117 argument before the C<:> is returned, otherwise the argument after the
1118 C<:> is returned.  For example:
1119
1120     printf "I have %d dog%s.\n", $n,
1121             ($n == 1) ? "" : "s";
1122
1123 Scalar or list context propagates downward into the 2nd
1124 or 3rd argument, whichever is selected.
1125
1126     $x = $ok ? $y : $z;  # get a scalar
1127     @x = $ok ? @y : @z;  # get an array
1128     $x = $ok ? @y : @z;  # oops, that's just a count!
1129
1130 The operator may be assigned to if both the 2nd and 3rd arguments are
1131 legal lvalues (meaning that you can assign to them):
1132
1133     ($x_or_y ? $x : $y) = $z;
1134
1135 Because this operator produces an assignable result, using assignments
1136 without parentheses will get you in trouble.  For example, this:
1137
1138     $x % 2 ? $x += 10 : $x += 2
1139
1140 Really means this:
1141
1142     (($x % 2) ? ($x += 10) : $x) += 2
1143
1144 Rather than this:
1145
1146     ($x % 2) ? ($x += 10) : ($x += 2)
1147
1148 That should probably be written more simply as:
1149
1150     $x += ($x % 2) ? 10 : 2;
1151
1152 =head2 Assignment Operators
1153 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1154 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1155 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1156
1157 C<"="> is the ordinary assignment operator.
1158
1159 Assignment operators work as in C.  That is,
1160
1161     $x += 2;
1162
1163 is equivalent to
1164
1165     $x = $x + 2;
1166
1167 although without duplicating any side effects that dereferencing the lvalue
1168 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1169 The following are recognized:
1170
1171     **=    +=    *=    &=    &.=    <<=    &&=
1172            -=    /=    |=    |.=    >>=    ||=
1173            .=    %=    ^=    ^.=           //=
1174                  x=
1175
1176 Although these are grouped by family, they all have the precedence
1177 of assignment.  These combined assignment operators can only operate on
1178 scalars, whereas the ordinary assignment operator can assign to arrays,
1179 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1180 and L<perldata/List value constructors>, and L<perlref/Assigning to
1181 References>.)
1182
1183 Unlike in C, the scalar assignment operator produces a valid lvalue.
1184 Modifying an assignment is equivalent to doing the assignment and
1185 then modifying the variable that was assigned to.  This is useful
1186 for modifying a copy of something, like this:
1187
1188     ($tmp = $global) =~ tr/13579/24680/;
1189
1190 Although as of 5.14, that can be also be accomplished this way:
1191
1192     use v5.14;
1193     $tmp = ($global =~  tr/13579/24680/r);
1194
1195 Likewise,
1196
1197     ($x += 2) *= 3;
1198
1199 is equivalent to
1200
1201     $x += 2;
1202     $x *= 3;
1203
1204 Similarly, a list assignment in list context produces the list of
1205 lvalues assigned to, and a list assignment in scalar context returns
1206 the number of elements produced by the expression on the right hand
1207 side of the assignment.
1208
1209 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1210 Perl 5.22 and experimental.  See L</Bitwise String Operators>.
1211
1212 =head2 Comma Operator
1213 X<comma> X<operator, comma> X<,>
1214
1215 Binary C<","> is the comma operator.  In scalar context it evaluates
1216 its left argument, throws that value away, then evaluates its right
1217 argument and returns that value.  This is just like C's comma operator.
1218
1219 In list context, it's just the list argument separator, and inserts
1220 both its arguments into the list.  These arguments are also evaluated
1221 from left to right.
1222
1223 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1224 for the comma except that it causes a
1225 word on its left to be interpreted as a string if it begins with a letter
1226 or underscore and is composed only of letters, digits and underscores.
1227 This includes operands that might otherwise be interpreted as operators,
1228 constants, single number v-strings or function calls.  If in doubt about
1229 this behavior, the left operand can be quoted explicitly.
1230
1231 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1232 or list argument separator, according to context.
1233
1234 For example:
1235
1236     use constant FOO => "something";
1237
1238     my %h = ( FOO => 23 );
1239
1240 is equivalent to:
1241
1242     my %h = ("FOO", 23);
1243
1244 It is I<NOT>:
1245
1246     my %h = ("something", 23);
1247
1248 The C<< => >> operator is helpful in documenting the correspondence
1249 between keys and values in hashes, and other paired elements in lists.
1250
1251     %hash = ( $key => $value );
1252     login( $username => $password );
1253
1254 The special quoting behavior ignores precedence, and hence may apply to
1255 I<part> of the left operand:
1256
1257     print time.shift => "bbb";
1258
1259 That example prints something like C<"1314363215shiftbbb">, because the
1260 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1261 the fact that C<time.shift> is the entire left operand.
1262
1263 =head2 List Operators (Rightward)
1264 X<operator, list, rightward> X<list operator>
1265
1266 On the right side of a list operator, the comma has very low precedence,
1267 such that it controls all comma-separated expressions found there.
1268 The only operators with lower precedence are the logical operators
1269 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1270 operators without the need for parentheses:
1271
1272     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1273
1274 However, some people find that code harder to read than writing
1275 it with parentheses:
1276
1277     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1278
1279 in which case you might as well just use the more customary C<"||"> operator:
1280
1281     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1282
1283 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
1284
1285 =head2 Logical Not
1286 X<operator, logical, not> X<not>
1287
1288 Unary C<"not"> returns the logical negation of the expression to its right.
1289 It's the equivalent of C<"!"> except for the very low precedence.
1290
1291 =head2 Logical And
1292 X<operator, logical, and> X<and>
1293
1294 Binary C<"and"> returns the logical conjunction of the two surrounding
1295 expressions.  It's equivalent to C<&&> except for the very low
1296 precedence.  This means that it short-circuits: the right
1297 expression is evaluated only if the left expression is true.
1298
1299 =head2 Logical or and Exclusive Or
1300 X<operator, logical, or> X<operator, logical, xor>
1301 X<operator, logical, exclusive or>
1302 X<or> X<xor>
1303
1304 Binary C<"or"> returns the logical disjunction of the two surrounding
1305 expressions.  It's equivalent to C<||> except for the very low precedence.
1306 This makes it useful for control flow:
1307
1308     print FH $data              or die "Can't write to FH: $!";
1309
1310 This means that it short-circuits: the right expression is evaluated
1311 only if the left expression is false.  Due to its precedence, you must
1312 be careful to avoid using it as replacement for the C<||> operator.
1313 It usually works out better for flow control than in assignments:
1314
1315     $x = $y or $z;              # bug: this is wrong
1316     ($x = $y) or $z;            # really means this
1317     $x = $y || $z;              # better written this way
1318
1319 However, when it's a list-context assignment and you're trying to use
1320 C<||> for control flow, you probably need C<"or"> so that the assignment
1321 takes higher precedence.
1322
1323     @info = stat($file) || die;     # oops, scalar sense of stat!
1324     @info = stat($file) or die;     # better, now @info gets its due
1325
1326 Then again, you could always use parentheses.
1327
1328 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1329 It cannot short-circuit (of course).
1330
1331 There is no low precedence operator for defined-OR.
1332
1333 =head2 C Operators Missing From Perl
1334 X<operator, missing from perl> X<&> X<*>
1335 X<typecasting> X<(TYPE)>
1336
1337 Here is what C has that Perl doesn't:
1338
1339 =over 8
1340
1341 =item unary &
1342
1343 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1344
1345 =item unary *
1346
1347 Dereference-address operator.  (Perl's prefix dereferencing
1348 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1349
1350 =item (TYPE)
1351
1352 Type-casting operator.
1353
1354 =back
1355
1356 =head2 Quote and Quote-like Operators
1357 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1358 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1359 X<escape sequence> X<escape>
1360
1361 While we usually think of quotes as literal values, in Perl they
1362 function as operators, providing various kinds of interpolating and
1363 pattern matching capabilities.  Perl provides customary quote characters
1364 for these behaviors, but also provides a way for you to choose your
1365 quote character for any of them.  In the following table, a C<{}> represents
1366 any pair of delimiters you choose.
1367
1368     Customary  Generic        Meaning        Interpolates
1369         ''       q{}          Literal             no
1370         ""      qq{}          Literal             yes
1371         ``      qx{}          Command             yes*
1372                 qw{}         Word list            no
1373         //       m{}       Pattern match          yes*
1374                 qr{}          Pattern             yes*
1375                  s{}{}      Substitution          yes*
1376                 tr{}{}    Transliteration         no (but see below)
1377                  y{}{}    Transliteration         no (but see below)
1378         <<EOF                 here-doc            yes*
1379
1380         * unless the delimiter is ''.
1381
1382 Non-bracketing delimiters use the same character fore and aft, but the four
1383 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1384 that
1385
1386     q{foo{bar}baz}
1387
1388 is the same as
1389
1390     'foo{bar}baz'
1391
1392 Note, however, that this does not always work for quoting Perl code:
1393
1394     $s = q{ if($x eq "}") ... }; # WRONG
1395
1396 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1397 and from CPAN before then) is able to do this properly.
1398
1399 There can be whitespace between the operator and the quoting
1400 characters, except when C<#> is being used as the quoting character.
1401 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1402 operator C<q> followed by a comment.  Its argument will be taken
1403 from the next line.  This allows you to write:
1404
1405     s {foo}  # Replace foo
1406       {bar}  # with bar.
1407
1408 The following escape sequences are available in constructs that interpolate,
1409 and in transliterations:
1410 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1411 X<\o{}>
1412
1413     Sequence     Note  Description
1414     \t                  tab               (HT, TAB)
1415     \n                  newline           (NL)
1416     \r                  return            (CR)
1417     \f                  form feed         (FF)
1418     \b                  backspace         (BS)
1419     \a                  alarm (bell)      (BEL)
1420     \e                  escape            (ESC)
1421     \x{263A}     [1,8]  hex char          (example: SMILEY)
1422     \x1b         [2,8]  restricted range hex char (example: ESC)
1423     \N{name}     [3]    named Unicode character or character sequence
1424     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1425     \c[          [5]    control char      (example: chr(27))
1426     \o{23072}    [6,8]  octal char        (example: SMILEY)
1427     \033         [7,8]  restricted range octal char  (example: ESC)
1428
1429 =over 4
1430
1431 =item [1]
1432
1433 The result is the character specified by the hexadecimal number between
1434 the braces.  See L</[8]> below for details on which character.
1435
1436 Only hexadecimal digits are valid between the braces.  If an invalid
1437 character is encountered, a warning will be issued and the invalid
1438 character and all subsequent characters (valid or invalid) within the
1439 braces will be discarded.
1440
1441 If there are no valid digits between the braces, the generated character is
1442 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1443 will not cause a warning (currently).
1444
1445 =item [2]
1446
1447 The result is the character specified by the hexadecimal number in the range
1448 0x00 to 0xFF.  See L</[8]> below for details on which character.
1449
1450 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1451 by fewer than two valid digits, any valid digits will be zero-padded.  This
1452 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1453 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1454 two valid digits will result in a warning.  Note that although the warning
1455 says the illegal character is ignored, it is only ignored as part of the
1456 escape and will still be used as the subsequent character in the string.
1457 For example:
1458
1459   Original    Result    Warns?
1460   "\x7"       "\x07"    no
1461   "\x"        "\x00"    no
1462   "\x7q"      "\x07q"   yes
1463   "\xq"       "\x00q"   yes
1464
1465 =item [3]
1466
1467 The result is the Unicode character or character sequence given by I<name>.
1468 See L<charnames>.
1469
1470 =item [4]
1471
1472 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1473 point is I<hexadecimal number>.
1474
1475 =item [5]
1476
1477 The character following C<\c> is mapped to some other character as shown in the
1478 table:
1479
1480  Sequence   Value
1481    \c@      chr(0)
1482    \cA      chr(1)
1483    \ca      chr(1)
1484    \cB      chr(2)
1485    \cb      chr(2)
1486    ...
1487    \cZ      chr(26)
1488    \cz      chr(26)
1489    \c[      chr(27)
1490                      # See below for chr(28)
1491    \c]      chr(29)
1492    \c^      chr(30)
1493    \c_      chr(31)
1494    \c?      chr(127) # (on ASCII platforms; see below for link to
1495                      #  EBCDIC discussion)
1496
1497 In other words, it's the character whose code point has had 64 xor'd with
1498 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1499 S<C<ord("?") ^ 64>> is 127, and
1500 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1501
1502 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1503 end of a string, because the backslash would be parsed as escaping the end
1504 quote.
1505
1506 On ASCII platforms, the resulting characters from the list above are the
1507 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1508 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1509 differences between these for ASCII versus EBCDIC platforms.
1510
1511 Use of any other character following the C<"c"> besides those listed above is
1512 discouraged, and as of Perl v5.20, the only characters actually allowed
1513 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1514 for any of the allowed other characters is that the value is derived by
1515 xor'ing with the seventh bit, which is 64, and a warning raised if
1516 enabled.  Using the non-allowed characters generates a fatal error.
1517
1518 To get platform independent controls, you can use C<\N{...}>.
1519
1520 =item [6]
1521
1522 The result is the character specified by the octal number between the braces.
1523 See L</[8]> below for details on which character.
1524
1525 If a character that isn't an octal digit is encountered, a warning is raised,
1526 and the value is based on the octal digits before it, discarding it and all
1527 following characters up to the closing brace.  It is a fatal error if there are
1528 no octal digits at all.
1529
1530 =item [7]
1531
1532 The result is the character specified by the three-digit octal number in the
1533 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1534 L</[8]> below for details on which character.
1535
1536 Some contexts allow 2 or even 1 digit, but any usage without exactly
1537 three digits, the first being a zero, may give unintended results.  (For
1538 example, in a regular expression it may be confused with a backreference;
1539 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1540 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1541 use this construct only for ordinals C<\077> and below, remembering to pad to
1542 the left with zeros to make three digits.  For larger ordinals, either use
1543 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1544 (which is portable between platforms with different character sets) or
1545 C<\x{}> instead.
1546
1547 =item [8]
1548
1549 Several constructs above specify a character by a number.  That number
1550 gives the character's position in the character set encoding (indexed from 0).
1551 This is called synonymously its ordinal, code position, or code point.  Perl
1552 works on platforms that have a native encoding currently of either ASCII/Latin1
1553 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1554 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1555 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1556 it as a Unicode code point and the result is the corresponding Unicode
1557 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1558 decimal, which is less than 256, so the number is interpreted in the native
1559 character set encoding.  In ASCII the character in the 80th position (indexed
1560 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1561 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1562 as a Unicode code point no matter what the native encoding is.  The name of the
1563 character in the 256th position (indexed by 0) in Unicode is
1564 C<LATIN CAPITAL LETTER A WITH MACRON>.
1565
1566 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1567 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1568 on EBCDIC platforms.  And if C<S<L<use encoding|encoding>>> is in effect, the
1569 number is considered to be in that encoding, and is translated from that into
1570 the platform's native encoding if there is a corresponding native character;
1571 otherwise to Unicode.
1572
1573 =back
1574
1575 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1576 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1577 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1578 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1579
1580 The following escape sequences are available in constructs that interpolate,
1581 but not in transliterations.
1582 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1583
1584     \l          lowercase next character only
1585     \u          titlecase (not uppercase!) next character only
1586     \L          lowercase all characters till \E or end of string
1587     \U          uppercase all characters till \E or end of string
1588     \F          foldcase all characters till \E or end of string
1589     \Q          quote (disable) pattern metacharacters till \E or
1590                 end of string
1591     \E          end either case modification or quoted section
1592                 (whichever was last seen)
1593
1594 See L<perlfunc/quotemeta> for the exact definition of characters that
1595 are quoted by C<\Q>.
1596
1597 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1598 C<\E> for each.  For example:
1599
1600  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1601  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1602
1603 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1604 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1605 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1606 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1607 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1608 case-mapping a single character can sometimes produce a sequence of
1609 several characters.
1610 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1611 for all locales but a UTF-8 one, where it instead uses the Unicode
1612 definition.
1613
1614 All systems use the virtual C<"\n"> to represent a line terminator,
1615 called a "newline".  There is no such thing as an unvarying, physical
1616 newline character.  It is only an illusion that the operating system,
1617 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1618 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1619 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1620 and on systems without a line terminator,
1621 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1622 you mean a "newline" for your system, but use the literal ASCII when you
1623 need an exact character.  For example, most networking protocols expect
1624 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1625 and although they often accept just C<"\012">, they seldom tolerate just
1626 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1627 you may be burned some day.
1628 X<newline> X<line terminator> X<eol> X<end of line>
1629 X<\n> X<\r> X<\r\n>
1630
1631 For constructs that do interpolate, variables beginning with "C<$>"
1632 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1633 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1634 But method calls such as C<< $obj->meth >> are not.
1635
1636 Interpolating an array or slice interpolates the elements in order,
1637 separated by the value of C<$">, so is equivalent to interpolating
1638 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1639 interpolated only if the name is enclosed in braces C<@{*}>, but the
1640 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1641
1642 For double-quoted strings, the quoting from C<\Q> is applied after
1643 interpolation and escapes are processed.
1644
1645     "abc\Qfoo\tbar$s\Exyz"
1646
1647 is equivalent to
1648
1649     "abc" . quotemeta("foo\tbar$s") . "xyz"
1650
1651 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1652 the quoting from C<\Q> is applied after interpolation is processed,
1653 but before escapes are processed.  This allows the pattern to match
1654 literally (except for C<$> and C<@>).  For example, the following matches:
1655
1656     '\s\t' =~ /\Q\s\t/
1657
1658 Because C<$> or C<@> trigger interpolation, you'll need to use something
1659 like C</\Quser\E\@\Qhost/> to match them literally.
1660
1661 Patterns are subject to an additional level of interpretation as a
1662 regular expression.  This is done as a second pass, after variables are
1663 interpolated, so that regular expressions may be incorporated into the
1664 pattern from the variables.  If this is not what you want, use C<\Q> to
1665 interpolate a variable literally.
1666
1667 Apart from the behavior described above, Perl does not expand
1668 multiple levels of interpolation.  In particular, contrary to the
1669 expectations of shell programmers, back-quotes do I<NOT> interpolate
1670 within double quotes, nor do single quotes impede evaluation of
1671 variables when used within double quotes.
1672
1673 =head2 Regexp Quote-Like Operators
1674 X<operator, regexp>
1675
1676 Here are the quote-like operators that apply to pattern
1677 matching and related activities.
1678
1679 =over 8
1680
1681 =item C<qr/I<STRING>/msixpodualn>
1682 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1683
1684 This operator quotes (and possibly compiles) its I<STRING> as a regular
1685 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1686 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no interpolation
1687 is done.  Returns a Perl value which may be used instead of the
1688 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1689 normalized version of the original pattern.  It magically differs from
1690 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1691 however, dereferencing it is not well defined (you currently get the 
1692 normalized version of the original pattern, but this may change).
1693
1694
1695 For example,
1696
1697     $rex = qr/my.STRING/is;
1698     print $rex;                 # prints (?si-xm:my.STRING)
1699     s/$rex/foo/;
1700
1701 is equivalent to
1702
1703     s/my.STRING/foo/is;
1704
1705 The result may be used as a subpattern in a match:
1706
1707     $re = qr/$pattern/;
1708     $string =~ /foo${re}bar/;   # can be interpolated in other
1709                                 # patterns
1710     $string =~ $re;             # or used standalone
1711     $string =~ /$re/;           # or this way
1712
1713 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1714 operator, using C<qr()> may have speed advantages in some situations,
1715 notably if the result of C<qr()> is used standalone:
1716
1717     sub match {
1718         my $patterns = shift;
1719         my @compiled = map qr/$_/i, @$patterns;
1720         grep {
1721             my $success = 0;
1722             foreach my $pat (@compiled) {
1723                 $success = 1, last if /$pat/;
1724             }
1725             $success;
1726         } @_;
1727     }
1728
1729 Precompilation of the pattern into an internal representation at
1730 the moment of C<qr()> avoids the need to recompile the pattern every
1731 time a match C</$pat/> is attempted.  (Perl has many other internal
1732 optimizations, but none would be triggered in the above example if
1733 we did not use C<qr()> operator.)
1734
1735 Options (specified by the following modifiers) are:
1736
1737     m   Treat string as multiple lines.
1738     s   Treat string as single line. (Make . match a newline)
1739     i   Do case-insensitive pattern matching.
1740     x   Use extended regular expressions.
1741     p   When matching preserve a copy of the matched string so
1742         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1743         defined (ignored starting in v5.20) as these are always
1744         defined starting in that relese
1745     o   Compile pattern only once.
1746     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1747         a's further restricts things to that that no ASCII
1748         character will match a non-ASCII one under /i.
1749     l   Use the current run-time locale's rules.
1750     u   Use Unicode rules.
1751     d   Use Unicode or native charset, as in 5.12 and earlier.
1752     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1753
1754 If a precompiled pattern is embedded in a larger pattern then the effect
1755 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1756 C</o> modifier has is not propagated, being restricted to those patterns
1757 explicitly using it.
1758
1759 The last four modifiers listed above, added in Perl 5.14,
1760 control the character set rules, but C</a> is the only one you are likely
1761 to want to specify explicitly; the other three are selected
1762 automatically by various pragmas.
1763
1764 See L<perlre> for additional information on valid syntax for I<STRING>, and
1765 for a detailed look at the semantics of regular expressions.  In
1766 particular, all modifiers except the largely obsolete C</o> are further
1767 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1768
1769 =item C<m/I<PATTERN>/msixpodualngc>
1770 X<m> X<operator, match>
1771 X<regexp, options> X<regexp> X<regex, options> X<regex>
1772 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1773
1774 =item C</I<PATTERN>/msixpodualngc>
1775
1776 Searches a string for a pattern match, and in scalar context returns
1777 true if it succeeds, false if it fails.  If no string is specified
1778 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1779 string specified with C<=~> need not be an lvalue--it may be the
1780 result of an expression evaluation, but remember the C<=~> binds
1781 rather tightly.)  See also L<perlre>.
1782
1783 Options are as described in C<qr//> above; in addition, the following match
1784 process modifiers are available:
1785
1786  g  Match globally, i.e., find all occurrences.
1787  c  Do not reset search position on a failed match when /g is
1788     in effect.
1789
1790 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
1791 you can use any pair of non-whitespace (ASCII) characters
1792 as delimiters.  This is particularly useful for matching path names
1793 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
1794 the delimiter, then a match-only-once rule applies,
1795 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
1796 no interpolation is performed on the I<PATTERN>.
1797 When using a delimiter character valid in an identifier, whitespace is required
1798 after the C<m>.
1799
1800 I<PATTERN> may contain variables, which will be interpolated
1801 every time the pattern search is evaluated, except
1802 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1803 C<$|> are not interpolated because they look like end-of-string tests.)
1804 Perl will not recompile the pattern unless an interpolated
1805 variable that it contains changes.  You can force Perl to skip the
1806 test and never recompile by adding a C</o> (which stands for "once")
1807 after the trailing delimiter.
1808 Once upon a time, Perl would recompile regular expressions
1809 unnecessarily, and this modifier was useful to tell it not to do so, in the
1810 interests of speed.  But now, the only reasons to use C</o> are one of:
1811
1812 =over
1813
1814 =item 1
1815
1816 The variables are thousands of characters long and you know that they
1817 don't change, and you need to wring out the last little bit of speed by
1818 having Perl skip testing for that.  (There is a maintenance penalty for
1819 doing this, as mentioning C</o> constitutes a promise that you won't
1820 change the variables in the pattern.  If you do change them, Perl won't
1821 even notice.)
1822
1823 =item 2
1824
1825 you want the pattern to use the initial values of the variables
1826 regardless of whether they change or not.  (But there are saner ways
1827 of accomplishing this than using C</o>.)
1828
1829 =item 3
1830
1831 If the pattern contains embedded code, such as
1832
1833     use re 'eval';
1834     $code = 'foo(?{ $x })';
1835     /$code/
1836
1837 then perl will recompile each time, even though the pattern string hasn't
1838 changed, to ensure that the current value of C<$x> is seen each time.
1839 Use C</o> if you want to avoid this.
1840
1841 =back
1842
1843 The bottom line is that using C</o> is almost never a good idea.
1844
1845 =item The empty pattern C<//>
1846
1847 If the I<PATTERN> evaluates to the empty string, the last
1848 I<successfully> matched regular expression is used instead.  In this
1849 case, only the C<g> and C<c> flags on the empty pattern are honored;
1850 the other flags are taken from the original pattern.  If no match has
1851 previously succeeded, this will (silently) act instead as a genuine
1852 empty pattern (which will always match).
1853
1854 Note that it's possible to confuse Perl into thinking C<//> (the empty
1855 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1856 good about this, but some pathological cases might trigger this, such as
1857 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
1858 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
1859 will assume you meant defined-or.  If you meant the empty regex, just
1860 use parentheses or spaces to disambiguate, or even prefix the empty
1861 regex with an C<m> (so C<//> becomes C<m//>).
1862
1863 =item Matching in list context
1864
1865 If the C</g> option is not used, C<m//> in list context returns a
1866 list consisting of the subexpressions matched by the parentheses in the
1867 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1868 also set).  When there are no parentheses in the pattern, the return
1869 value is the list C<(1)> for success.  
1870 With or without parentheses, an empty list is returned upon failure.
1871
1872 Examples:
1873
1874  open(TTY, "+</dev/tty")
1875     || die "can't access /dev/tty: $!";
1876
1877  <TTY> =~ /^y/i && foo();       # do foo if desired
1878
1879  if (/Version: *([0-9.]*)/) { $version = $1; }
1880
1881  next if m#^/usr/spool/uucp#;
1882
1883  # poor man's grep
1884  $arg = shift;
1885  while (<>) {
1886     print if /$arg/o; # compile only once (no longer needed!)
1887  }
1888
1889  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1890
1891 This last example splits C<$foo> into the first two words and the
1892 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
1893 C<$Etc>.  The conditional is true if any variables were assigned; that is,
1894 if the pattern matched.
1895
1896 The C</g> modifier specifies global pattern matching--that is,
1897 matching as many times as possible within the string.  How it behaves
1898 depends on the context.  In list context, it returns a list of the
1899 substrings matched by any capturing parentheses in the regular
1900 expression.  If there are no parentheses, it returns a list of all
1901 the matched strings, as if there were parentheses around the whole
1902 pattern.
1903
1904 In scalar context, each execution of C<m//g> finds the next match,
1905 returning true if it matches, and false if there is no further match.
1906 The position after the last match can be read or set using the C<pos()>
1907 function; see L<perlfunc/pos>.  A failed match normally resets the
1908 search position to the beginning of the string, but you can avoid that
1909 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1910 string also resets the search position.
1911
1912 =item C<\G I<assertion>>
1913
1914 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1915 zero-width assertion that matches the exact position where the
1916 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1917 C<\G> assertion still anchors at C<pos()> as it was at the start of
1918 the operation (see L<perlfunc/pos>), but the match is of course only
1919 attempted once.  Using C<\G> without C</g> on a target string that has
1920 not previously had a C</g> match applied to it is the same as using
1921 the C<\A> assertion to match the beginning of the string.  Note also
1922 that, currently, C<\G> is only properly supported when anchored at the
1923 very beginning of the pattern.
1924
1925 Examples:
1926
1927     # list context
1928     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1929
1930     # scalar context
1931     local $/ = "";
1932     while ($paragraph = <>) {
1933         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1934             $sentences++;
1935         }
1936     }
1937     say $sentences;
1938
1939 Here's another way to check for sentences in a paragraph:
1940
1941  my $sentence_rx = qr{
1942     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1943                                 # whitespace
1944     \p{Lu}                      # capital letter
1945     .*?                         # a bunch of anything
1946     (?<= \S )                   # that ends in non-
1947                                 # whitespace
1948     (?<! \b [DMS]r  )           # but isn't a common abbr.
1949     (?<! \b Mrs )
1950     (?<! \b Sra )
1951     (?<! \b St  )
1952     [.?!]                       # followed by a sentence
1953                                 # ender
1954     (?= $ | \s )                # in front of end-of-string
1955                                 # or whitespace
1956  }sx;
1957  local $/ = "";
1958  while (my $paragraph = <>) {
1959     say "NEW PARAGRAPH";
1960     my $count = 0;
1961     while ($paragraph =~ /($sentence_rx)/g) {
1962         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1963     }
1964  }
1965
1966 Here's how to use C<m//gc> with C<\G>:
1967
1968     $_ = "ppooqppqq";
1969     while ($i++ < 2) {
1970         print "1: '";
1971         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1972         print "2: '";
1973         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1974         print "3: '";
1975         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1976     }
1977     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1978
1979 The last example should print:
1980
1981     1: 'oo', pos=4
1982     2: 'q', pos=5
1983     3: 'pp', pos=7
1984     1: '', pos=7
1985     2: 'q', pos=8
1986     3: '', pos=8
1987     Final: 'q', pos=8
1988
1989 Notice that the final match matched C<q> instead of C<p>, which a match
1990 without the C<\G> anchor would have done.  Also note that the final match
1991 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
1992 final match did indeed match C<p>, it's a good bet that you're running a
1993 very old (pre-5.6.0) version of Perl.
1994
1995 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1996 combine several regexps like this to process a string part-by-part,
1997 doing different actions depending on which regexp matched.  Each
1998 regexp tries to match where the previous one leaves off.
1999
2000  $_ = <<'EOL';
2001     $url = URI::URL->new( "http://example.com/" );
2002     die if $url eq "xXx";
2003  EOL
2004
2005  LOOP: {
2006      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
2007      print(" lowercase"),    redo LOOP
2008                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
2009      print(" UPPERCASE"),    redo LOOP
2010                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2011      print(" Capitalized"),  redo LOOP
2012                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2013      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2014      print(" alphanumeric"), redo LOOP
2015                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2016      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2017      print ". That's all!\n";
2018  }
2019
2020 Here is the output (split into several lines):
2021
2022  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2023  line-noise lowercase line-noise lowercase line-noise lowercase
2024  lowercase line-noise lowercase lowercase line-noise lowercase
2025  lowercase line-noise MiXeD line-noise. That's all!
2026
2027 =item C<m?I<PATTERN>?msixpodualngc>
2028 X<?> X<operator, match-once>
2029
2030 =item C<?I<PATTERN>?msixpodualngc>
2031
2032 This is just like the C<m/I<PATTERN>/> search, except that it matches
2033 only once between calls to the C<reset()> operator.  This is a useful
2034 optimization when you want to see only the first occurrence of
2035 something in each file of a set of files, for instance.  Only C<m??>
2036 patterns local to the current package are reset.
2037
2038     while (<>) {
2039         if (m?^$?) {
2040                             # blank line between header and body
2041         }
2042     } continue {
2043         reset if eof;       # clear m?? status for next file
2044     }
2045
2046 Another example switched the first "latin1" encoding it finds
2047 to "utf8" in a pod file:
2048
2049     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2050
2051 The match-once behavior is controlled by the match delimiter being
2052 C<?>; with any other delimiter this is the normal C<m//> operator.
2053
2054 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2055 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2056 syntax error.  If you encounter this construct in older code, you can just add
2057 C<m>.
2058
2059 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2060 X<substitute> X<substitution> X<replace> X<regexp, replace>
2061 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2062
2063 Searches a string for a pattern, and if found, replaces that pattern
2064 with the replacement text and returns the number of substitutions
2065 made.  Otherwise it returns false (specifically, the empty string).
2066
2067 If the C</r> (non-destructive) option is used then it runs the
2068 substitution on a copy of the string and instead of returning the
2069 number of substitutions, it returns the copy whether or not a
2070 substitution occurred.  The original string is never changed when
2071 C</r> is used.  The copy will always be a plain string, even if the
2072 input is an object or a tied variable.
2073
2074 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2075 variable is searched and modified.  Unless the C</r> option is used,
2076 the string specified must be a scalar variable, an array element, a
2077 hash element, or an assignment to one of those; that is, some sort of
2078 scalar lvalue.
2079
2080 If the delimiter chosen is a single quote, no interpolation is
2081 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2082 I<PATTERN> contains a C<$> that looks like a variable rather than an
2083 end-of-string test, the variable will be interpolated into the pattern
2084 at run-time.  If you want the pattern compiled only once the first time
2085 the variable is interpolated, use the C</o> option.  If the pattern
2086 evaluates to the empty string, the last successfully executed regular
2087 expression is used instead.  See L<perlre> for further explanation on these.
2088
2089 Options are as with C<m//> with the addition of the following replacement
2090 specific options:
2091
2092     e   Evaluate the right side as an expression.
2093     ee  Evaluate the right side as a string then eval the
2094         result.
2095     r   Return substitution and leave the original string
2096         untouched.
2097
2098 Any non-whitespace delimiter may replace the slashes.  Add space after
2099 the C<s> when using a character allowed in identifiers.  If single quotes
2100 are used, no interpretation is done on the replacement string (the C</e>
2101 modifier overrides this, however).  Note that Perl treats backticks
2102 as normal delimiters; the replacement text is not evaluated as a command.
2103 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2104 its own pair of quotes, which may or may not be bracketing quotes, for example,
2105 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2106 replacement portion to be treated as a full-fledged Perl expression
2107 and evaluated right then and there.  It is, however, syntax checked at
2108 compile-time.  A second C<e> modifier will cause the replacement portion
2109 to be C<eval>ed before being run as a Perl expression.
2110
2111 Examples:
2112
2113     s/\bgreen\b/mauve/g;              # don't change wintergreen
2114
2115     $path =~ s|/usr/bin|/usr/local/bin|;
2116
2117     s/Login: $foo/Login: $bar/; # run-time pattern
2118
2119     ($foo = $bar) =~ s/this/that/;      # copy first, then
2120                                         # change
2121     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2122                                         # copy, then change
2123     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2124     $foo = $bar =~ s/this/that/r
2125                 =~ s/that/the other/r;  # Chained substitutes
2126                                         # using /r
2127     @foo = map { s/this/that/r } @bar   # /r is very useful in
2128                                         # maps
2129
2130     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2131
2132     $_ = 'abc123xyz';
2133     s/\d+/$&*2/e;               # yields 'abc246xyz'
2134     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2135     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2136
2137     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2138     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2139     s/^=(\w+)/pod($1)/ge;       # use function call
2140
2141     $_ = 'abc123xyz';
2142     $x = s/abc/def/r;           # $x is 'def123xyz' and
2143                                 # $_ remains 'abc123xyz'.
2144
2145     # expand variables in $_, but dynamics only, using
2146     # symbolic dereferencing
2147     s/\$(\w+)/${$1}/g;
2148
2149     # Add one to the value of any numbers in the string
2150     s/(\d+)/1 + $1/eg;
2151
2152     # Titlecase words in the last 30 characters only
2153     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2154
2155     # This will expand any embedded scalar variable
2156     # (including lexicals) in $_ : First $1 is interpolated
2157     # to the variable name, and then evaluated
2158     s/(\$\w+)/$1/eeg;
2159
2160     # Delete (most) C comments.
2161     $program =~ s {
2162         /\*     # Match the opening delimiter.
2163         .*?     # Match a minimal number of characters.
2164         \*/     # Match the closing delimiter.
2165     } []gsx;
2166
2167     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2168                                 # expensively
2169
2170     for ($variable) {           # trim whitespace in $variable,
2171                                 # cheap
2172         s/^\s+//;
2173         s/\s+$//;
2174     }
2175
2176     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2177
2178 Note the use of C<$> instead of C<\> in the last example.  Unlike
2179 B<sed>, we use the \<I<digit>> form only in the left hand side.
2180 Anywhere else it's $<I<digit>>.
2181
2182 Occasionally, you can't use just a C</g> to get all the changes
2183 to occur that you might want.  Here are two common cases:
2184
2185     # put commas in the right places in an integer
2186     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2187
2188     # expand tabs to 8-column spacing
2189     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2190
2191 =back
2192
2193 =head2 Quote-Like Operators
2194 X<operator, quote-like>
2195
2196 =over 4
2197
2198 =item C<q/I<STRING>/>
2199 X<q> X<quote, single> X<'> X<''>
2200
2201 =item C<'I<STRING>'>
2202
2203 A single-quoted, literal string.  A backslash represents a backslash
2204 unless followed by the delimiter or another backslash, in which case
2205 the delimiter or backslash is interpolated.
2206
2207     $foo = q!I said, "You said, 'She said it.'"!;
2208     $bar = q('This is it.');
2209     $baz = '\n';                # a two-character string
2210
2211 =item C<qq/I<STRING>/>
2212 X<qq> X<quote, double> X<"> X<"">
2213
2214 =item "I<STRING>"
2215
2216 A double-quoted, interpolated string.
2217
2218     $_ .= qq
2219      (*** The previous line contains the naughty word "$1".\n)
2220                 if /\b(tcl|java|python)\b/i;      # :-)
2221     $baz = "\n";                # a one-character string
2222
2223 =item C<qx/I<STRING>/>
2224 X<qx> X<`> X<``> X<backtick>
2225
2226 =item C<`I<STRING>`>
2227
2228 A string which is (possibly) interpolated and then executed as a
2229 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2230 pipes, and redirections will be honored.  The collected standard
2231 output of the command is returned; standard error is unaffected.  In
2232 scalar context, it comes back as a single (potentially multi-line)
2233 string, or C<undef> if the command failed.  In list context, returns a
2234 list of lines (however you've defined lines with C<$/> or
2235 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the command failed.
2236
2237 Because backticks do not affect standard error, use shell file descriptor
2238 syntax (assuming the shell supports this) if you care to address this.
2239 To capture a command's STDERR and STDOUT together:
2240
2241     $output = `cmd 2>&1`;
2242
2243 To capture a command's STDOUT but discard its STDERR:
2244
2245     $output = `cmd 2>/dev/null`;
2246
2247 To capture a command's STDERR but discard its STDOUT (ordering is
2248 important here):
2249
2250     $output = `cmd 2>&1 1>/dev/null`;
2251
2252 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2253 but leave its STDOUT to come out the old STDERR:
2254
2255     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2256
2257 To read both a command's STDOUT and its STDERR separately, it's easiest
2258 to redirect them separately to files, and then read from those files
2259 when the program is done:
2260
2261     system("program args 1>program.stdout 2>program.stderr");
2262
2263 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2264 For example:
2265
2266     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2267     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2268     print STDOUT `sort`;
2269
2270 will print the sorted contents of the file named F<"stuff">.
2271
2272 Using single-quote as a delimiter protects the command from Perl's
2273 double-quote interpolation, passing it on to the shell instead:
2274
2275     $perl_info  = qx(ps $$);            # that's Perl's $$
2276     $shell_info = qx'ps $$';            # that's the new shell's $$
2277
2278 How that string gets evaluated is entirely subject to the command
2279 interpreter on your system.  On most platforms, you will have to protect
2280 shell metacharacters if you want them treated literally.  This is in
2281 practice difficult to do, as it's unclear how to escape which characters.
2282 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2283 to emulate backticks safely.
2284
2285 On some platforms (notably DOS-like ones), the shell may not be
2286 capable of dealing with multiline commands, so putting newlines in
2287 the string may not get you what you want.  You may be able to evaluate
2288 multiple commands in a single line by separating them with the command
2289 separator character, if your shell supports that (for example, C<;> on 
2290 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2291
2292 Perl will attempt to flush all files opened for
2293 output before starting the child process, but this may not be supported
2294 on some platforms (see L<perlport>).  To be safe, you may need to set
2295 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2296 C<L<IO::Handle>> on any open handles.
2297
2298 Beware that some command shells may place restrictions on the length
2299 of the command line.  You must ensure your strings don't exceed this
2300 limit after any necessary interpolations.  See the platform-specific
2301 release notes for more details about your particular environment.
2302
2303 Using this operator can lead to programs that are difficult to port,
2304 because the shell commands called vary between systems, and may in
2305 fact not be present at all.  As one example, the C<type> command under
2306 the POSIX shell is very different from the C<type> command under DOS.
2307 That doesn't mean you should go out of your way to avoid backticks
2308 when they're the right way to get something done.  Perl was made to be
2309 a glue language, and one of the things it glues together is commands.
2310 Just understand what you're getting yourself into.
2311
2312 See L</"I/O Operators"> for more discussion.
2313
2314 =item C<qw/I<STRING>/>
2315 X<qw> X<quote, list> X<quote, words>
2316
2317 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2318 whitespace as the word delimiters.  It can be understood as being roughly
2319 equivalent to:
2320
2321     split(" ", q/STRING/);
2322
2323 the differences being that it generates a real list at compile time, and
2324 in scalar context it returns the last element in the list.  So
2325 this expression:
2326
2327     qw(foo bar baz)
2328
2329 is semantically equivalent to the list:
2330
2331     "foo", "bar", "baz"
2332
2333 Some frequently seen examples:
2334
2335     use POSIX qw( setlocale localeconv )
2336     @EXPORT = qw( foo bar baz );
2337
2338 A common mistake is to try to separate the words with commas or to
2339 put comments into a multi-line C<qw>-string.  For this reason, the
2340 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2341 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2342
2343 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2344 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2345
2346 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2347
2348 Transliterates all occurrences of the characters found in the search list
2349 with the corresponding character in the replacement list.  It returns
2350 the number of characters replaced or deleted.  If no string is
2351 specified via the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2352
2353 If the C</r> (non-destructive) option is present, a new copy of the string
2354 is made and its characters transliterated, and this copy is returned no
2355 matter whether it was modified or not: the original string is always
2356 left unchanged.  The new copy is always a plain string, even if the input
2357 string is an object or a tied variable.
2358
2359 Unless the C</r> option is used, the string specified with C<=~> must be a
2360 scalar variable, an array element, a hash element, or an assignment to one
2361 of those; in other words, an lvalue.
2362
2363 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2364 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2365 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2366 I<SEARCHLIST> is delimited by bracketing quotes, the I<REPLACEMENTLIST> has
2367 its own pair of quotes, which may or may not be bracketing quotes;
2368 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2369
2370 Characters may be literals or any of the escape sequences accepted in
2371 double-quoted strings.  But there is no interpolation, so C<"$"> and
2372 C<"@"> are treated as literals.  A hyphen at the beginning or end, or
2373 preceded by a backslash is considered a literal.  Escape sequence
2374 details are in L<the table near the beginning of this section|/Quote and
2375 Quote-like Operators>.  It is a bug in Perl v5.22 that something like
2376
2377  tr/\N{U+20}-\N{U+7E}foobar//
2378
2379 does not treat that range as fully Unicode.
2380
2381 Note that C<tr> does B<not> do regular expression character classes such as
2382 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2383 utility.  If you want to map strings between lower/upper cases, see
2384 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2385 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2386 C<\l> string-interpolation escapes on the right side of a substitution
2387 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2388 (except sometimes on legacy 7-bit data).
2389
2390 Note also that the whole range idea is rather unportable between
2391 character sets--and even within character sets they may cause results
2392 you probably didn't expect.  A sound principle is to use only ranges
2393 that begin from and end at either alphabets of equal case (a-e, A-E),
2394 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
2395 character sets in full.
2396
2397 Options:
2398
2399     c   Complement the SEARCHLIST.
2400     d   Delete found but unreplaced characters.
2401     s   Squash duplicate replaced characters.
2402     r   Return the modified string and leave the original string
2403         untouched.
2404
2405 If the C</c> modifier is specified, the I<SEARCHLIST> character set
2406 is complemented.  If the C</d> modifier is specified, any characters
2407 specified by I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted.
2408 (Note that this is slightly more flexible than the behavior of some
2409 B<tr> programs, which delete anything they find in the I<SEARCHLIST>,
2410 period.)  If the C</s> modifier is specified, sequences of characters
2411 that were transliterated to the same character are squashed down
2412 to a single instance of the character.
2413
2414 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2415 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2416 than the I<SEARCHLIST>, the final character is replicated till it is long
2417 enough.  If the I<REPLACEMENTLIST> is empty, the I<SEARCHLIST> is replicated.
2418 This latter is useful for counting characters in a class or for
2419 squashing character sequences in a class.
2420
2421 Examples:
2422
2423     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2424
2425     $cnt = tr/*/*/;             # count the stars in $_
2426
2427     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2428
2429     $cnt = tr/0-9//;            # count the digits in $_
2430
2431     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2432
2433     ($HOST = $host) =~ tr/a-z/A-Z/;
2434      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2435
2436     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2437                   =~ s/:/ -p/r;
2438
2439     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2440
2441     @stripped = map tr/a-zA-Z/ /csr, @original;
2442                                 # /r with map
2443
2444     tr [\200-\377]
2445        [\000-\177];             # wickedly delete 8th bit
2446
2447 If multiple transliterations are given for a character, only the
2448 first one is used:
2449
2450     tr/AAA/XYZ/
2451
2452 will transliterate any A to X.
2453
2454 Because the transliteration table is built at compile time, neither
2455 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2456 interpolation.  That means that if you want to use variables, you
2457 must use an C<eval()>:
2458
2459     eval "tr/$oldlist/$newlist/";
2460     die $@ if $@;
2461
2462     eval "tr/$oldlist/$newlist/, 1" or die $@;
2463
2464 =item C<< <<I<EOF> >>
2465 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2466
2467 A line-oriented form of quoting is based on the shell "here-document"
2468 syntax.  Following a C<< << >> you specify a string to terminate
2469 the quoted material, and all lines following the current line down to
2470 the terminating string are the value of the item.
2471
2472 The terminating string may be either an identifier (a word), or some
2473 quoted text.  An unquoted identifier works like double quotes.
2474 There may not be a space between the C<< << >> and the identifier,
2475 unless the identifier is explicitly quoted.  (If you put a space it
2476 will be treated as a null identifier, which is valid, and matches the
2477 first empty line.)  The terminating string must appear by itself
2478 (unquoted and with no surrounding whitespace) on the terminating line.
2479
2480 If the terminating string is quoted, the type of quotes used determine
2481 the treatment of the text.
2482
2483 =over 4
2484
2485 =item Double Quotes
2486
2487 Double quotes indicate that the text will be interpolated using exactly
2488 the same rules as normal double quoted strings.
2489
2490        print <<EOF;
2491     The price is $Price.
2492     EOF
2493
2494        print << "EOF"; # same as above
2495     The price is $Price.
2496     EOF
2497
2498
2499 =item Single Quotes
2500
2501 Single quotes indicate the text is to be treated literally with no
2502 interpolation of its content.  This is similar to single quoted
2503 strings except that backslashes have no special meaning, with C<\\>
2504 being treated as two backslashes and not one as they would in every
2505 other quoting construct.
2506
2507 Just as in the shell, a backslashed bareword following the C<<< << >>>
2508 means the same thing as a single-quoted string does:
2509
2510         $cost = <<'VISTA';  # hasta la ...
2511     That'll be $10 please, ma'am.
2512     VISTA
2513
2514         $cost = <<\VISTA;   # Same thing!
2515     That'll be $10 please, ma'am.
2516     VISTA
2517
2518 This is the only form of quoting in perl where there is no need
2519 to worry about escaping content, something that code generators
2520 can and do make good use of.
2521
2522 =item Backticks
2523
2524 The content of the here doc is treated just as it would be if the
2525 string were embedded in backticks.  Thus the content is interpolated
2526 as though it were double quoted and then executed via the shell, with
2527 the results of the execution returned.
2528
2529        print << `EOC`; # execute command and get results
2530     echo hi there
2531     EOC
2532
2533 =back
2534
2535 It is possible to stack multiple here-docs in a row:
2536
2537        print <<"foo", <<"bar"; # you can stack them
2538     I said foo.
2539     foo
2540     I said bar.
2541     bar
2542
2543        myfunc(<< "THIS", 23, <<'THAT');
2544     Here's a line
2545     or two.
2546     THIS
2547     and here's another.
2548     THAT
2549
2550 Just don't forget that you have to put a semicolon on the end
2551 to finish the statement, as Perl doesn't know you're not going to
2552 try to do this:
2553
2554        print <<ABC
2555     179231
2556     ABC
2557        + 20;
2558
2559 If you want to remove the line terminator from your here-docs,
2560 use C<chomp()>.
2561
2562     chomp($string = <<'END');
2563     This is a string.
2564     END
2565
2566 If you want your here-docs to be indented with the rest of the code,
2567 you'll need to remove leading whitespace from each line manually:
2568
2569     ($quote = <<'FINIS') =~ s/^\s+//gm;
2570        The Road goes ever on and on,
2571        down from the door where it began.
2572     FINIS
2573
2574 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2575 the quoted material must still come on the line following the
2576 C<<< <<FOO >>> marker, which means it may be inside the delimited
2577 construct:
2578
2579     s/this/<<E . 'that'
2580     the other
2581     E
2582      . 'more '/eg;
2583
2584 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2585 you would have to write
2586
2587     s/this/<<E . 'that'
2588      . 'more '/eg;
2589     the other
2590     E
2591
2592 outside of string evals.
2593
2594 Additionally, quoting rules for the end-of-string identifier are
2595 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2596 supported in place of C<''> and C<"">, and the only interpolation is for
2597 backslashing the quoting character:
2598
2599     print << "abc\"def";
2600     testing...
2601     abc"def
2602
2603 Finally, quoted strings cannot span multiple lines.  The general rule is
2604 that the identifier must be a string literal.  Stick with that, and you
2605 should be safe.
2606
2607 =back
2608
2609 =head2 Gory details of parsing quoted constructs
2610 X<quote, gory details>
2611
2612 When presented with something that might have several different
2613 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2614 principle to pick the most probable interpretation.  This strategy
2615 is so successful that Perl programmers often do not suspect the
2616 ambivalence of what they write.  But from time to time, Perl's
2617 notions differ substantially from what the author honestly meant.
2618
2619 This section hopes to clarify how Perl handles quoted constructs.
2620 Although the most common reason to learn this is to unravel labyrinthine
2621 regular expressions, because the initial steps of parsing are the
2622 same for all quoting operators, they are all discussed together.
2623
2624 The most important Perl parsing rule is the first one discussed
2625 below: when processing a quoted construct, Perl first finds the end
2626 of that construct, then interprets its contents.  If you understand
2627 this rule, you may skip the rest of this section on the first
2628 reading.  The other rules are likely to contradict the user's
2629 expectations much less frequently than this first one.
2630
2631 Some passes discussed below are performed concurrently, but because
2632 their results are the same, we consider them individually.  For different
2633 quoting constructs, Perl performs different numbers of passes, from
2634 one to four, but these passes are always performed in the same order.
2635
2636 =over 4
2637
2638 =item Finding the end
2639
2640 The first pass is finding the end of the quoted construct.  This results
2641 in saving to a safe location a copy of the text (between the starting
2642 and ending delimiters), normalized as necessary to avoid needing to know
2643 what the original delimiters were.
2644
2645 If the construct is a here-doc, the ending delimiter is a line
2646 that has a terminating string as the content.  Therefore C<<<EOF> is
2647 terminated by C<EOF> immediately followed by C<"\n"> and starting
2648 from the first column of the terminating line.
2649 When searching for the terminating line of a here-doc, nothing
2650 is skipped.  In other words, lines after the here-doc syntax
2651 are compared with the terminating string line by line.
2652
2653 For the constructs except here-docs, single characters are used as starting
2654 and ending delimiters.  If the starting delimiter is an opening punctuation
2655 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2656 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2657 If the starting delimiter is an unpaired character like C</> or a closing
2658 punctuation, the ending delimiter is the same as the starting delimiter.
2659 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2660 both C<qq[]> and C<qq]]> constructs.
2661
2662 When searching for single-character delimiters, escaped delimiters
2663 and C<\\> are skipped.  For example, while searching for terminating C</>,
2664 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2665 bracketing, nested pairs are also skipped.  For example, while searching
2666 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2667 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2668 However, when backslashes are used as the delimiters (like C<qq\\> and
2669 C<tr\\\>), nothing is skipped.
2670 During the search for the end, backslashes that escape delimiters or
2671 other backslashes are removed (exactly speaking, they are not copied to the
2672 safe location).
2673
2674 For constructs with three-part delimiters (C<s///>, C<y///>, and
2675 C<tr///>), the search is repeated once more.
2676 If the first delimiter is not an opening punctuation, the three delimiters must
2677 be the same, such as C<s!!!> and C<tr)))>,
2678 in which case the second delimiter
2679 terminates the left part and starts the right part at once.
2680 If the left part is delimited by bracketing punctuation (that is C<()>,
2681 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2682 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2683 and comments are allowed between the two parts, although the comment must follow
2684 at least one whitespace character; otherwise a character expected as the 
2685 start of the comment may be regarded as the starting delimiter of the right part.
2686
2687 During this search no attention is paid to the semantics of the construct.
2688 Thus:
2689
2690     "$hash{"$foo/$bar"}"
2691
2692 or:
2693
2694     m/
2695       bar       # NOT a comment, this slash / terminated m//!
2696      /x
2697
2698 do not form legal quoted expressions.   The quoted part ends on the
2699 first C<"> and C</>, and the rest happens to be a syntax error.
2700 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2701 the example above is not C<m//x>, but rather C<m//> with no C</x>
2702 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2703
2704 Also no attention is paid to C<\c\> (multichar control char syntax) during
2705 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2706 of C<\/>, and the following C</> is not recognized as a delimiter.
2707 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2708
2709 =item Interpolation
2710 X<interpolation>
2711
2712 The next step is interpolation in the text obtained, which is now
2713 delimiter-independent.  There are multiple cases.
2714
2715 =over 4
2716
2717 =item C<<<'EOF'>
2718
2719 No interpolation is performed.
2720 Note that the combination C<\\> is left intact, since escaped delimiters
2721 are not available for here-docs.
2722
2723 =item  C<m''>, the pattern of C<s'''>
2724
2725 No interpolation is performed at this stage.
2726 Any backslashed sequences including C<\\> are treated at the stage
2727 to L</"parsing regular expressions">.
2728
2729 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2730
2731 The only interpolation is removal of C<\> from pairs of C<\\>.
2732 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
2733 as a hyphen and no character range is available.
2734 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2735
2736 =item C<tr///>, C<y///>
2737
2738 No variable interpolation occurs.  String modifying combinations for
2739 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2740 The other escape sequences such as C<\200> and C<\t> and backslashed
2741 characters such as C<\\> and C<\-> are converted to appropriate literals.
2742 The character C<"-"> is treated specially and therefore C<\-> is treated
2743 as a literal C<"-">.
2744
2745 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2746
2747 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2748 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2749 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
2750 The other escape sequences such as C<\200> and C<\t> and backslashed
2751 characters such as C<\\> and C<\-> are replaced with appropriate
2752 expansions.
2753
2754 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2755 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2756 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2757 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2758 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2759 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2760 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2761
2762   $str = '\t';
2763   return "\Q$str";
2764
2765 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2766
2767 Interpolated scalars and arrays are converted internally to the C<join> and
2768 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
2769
2770   $foo . " XXX '" . (join $", @arr) . "'";
2771
2772 All operations above are performed simultaneously, left to right.
2773
2774 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
2775 quoted, there is no way to insert a literal C<$> or C<@> inside a
2776 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
2777 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2778 scalar.
2779
2780 Note also that the interpolation code needs to make a decision on
2781 where the interpolated scalar ends.  For instance, whether
2782 S<C<< "a $x -> {c}" >>> really means:
2783
2784   "a " . $x . " -> {c}";
2785
2786 or:
2787
2788   "a " . $x -> {c};
2789
2790 Most of the time, the longest possible text that does not include
2791 spaces between components and which contains matching braces or
2792 brackets.  because the outcome may be determined by voting based
2793 on heuristic estimators, the result is not strictly predictable.
2794 Fortunately, it's usually correct for ambiguous cases.
2795
2796 =item the replacement of C<s///>
2797
2798 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2799 happens as with C<qq//> constructs.
2800
2801 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2802 the replacement text of C<s///>, in order to correct the incorrigible
2803 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2804 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
2805 (that is, the C<$^W> variable) was set.
2806
2807 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2808
2809 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2810 and interpolation happens (almost) as with C<qq//> constructs.
2811
2812 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2813 form for the regex compiler.  (This is because, as mentioned below, the regex
2814 compilation may be done at execution time, and C<\N{...}> is a compile-time
2815 construct.)
2816
2817 However any other combinations of C<\> followed by a character
2818 are not substituted but only skipped, in order to parse them
2819 as regular expressions at the following step.
2820 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2821 treated as an array symbol (for example C<@foo>),
2822 even though the same text in C<qq//> gives interpolation of C<\c@>.
2823
2824 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2825 back to the perl parser, in a similar way that an interpolated array
2826 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2827
2828 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
2829 a C<#>-comment in a C</x>-regular expression, no processing is
2830 performed whatsoever.  This is the first step at which the presence
2831 of the C</x> modifier is relevant.
2832
2833 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2834 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2835 voted (by several different estimators) to be either an array element
2836 or C<$var> followed by an RE alternative.  This is where the notation
2837 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2838 array element C<-9>, not as a regular expression from the variable
2839 C<$arr> followed by a digit, which would be the interpretation of
2840 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2841 the result is not predictable.
2842
2843 The lack of processing of C<\\> creates specific restrictions on
2844 the post-processed text.  If the delimiter is C</>, one cannot get
2845 the combination C<\/> into the result of this step.  C</> will
2846 finish the regular expression, C<\/> will be stripped to C</> on
2847 the previous step, and C<\\/> will be left as is.  Because C</> is
2848 equivalent to C<\/> inside a regular expression, this does not
2849 matter unless the delimiter happens to be character special to the
2850 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2851 alphanumeric char, as in:
2852
2853   m m ^ a \s* b mmx;
2854
2855 In the RE above, which is intentionally obfuscated for illustration, the
2856 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2857 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
2858 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2859 non-whitespace choices.
2860
2861 =back
2862
2863 This step is the last one for all constructs except regular expressions,
2864 which are processed further.
2865
2866 =item parsing regular expressions
2867 X<regexp, parse>
2868
2869 Previous steps were performed during the compilation of Perl code,
2870 but this one happens at run time, although it may be optimized to
2871 be calculated at compile time if appropriate.  After preprocessing
2872 described above, and possibly after evaluation if concatenation,
2873 joining, casing translation, or metaquoting are involved, the
2874 resulting I<string> is passed to the RE engine for compilation.
2875
2876 Whatever happens in the RE engine might be better discussed in L<perlre>,
2877 but for the sake of continuity, we shall do so here.
2878
2879 This is another step where the presence of the C</x> modifier is
2880 relevant.  The RE engine scans the string from left to right and
2881 converts it into a finite automaton.
2882
2883 Backslashed characters are either replaced with corresponding
2884 literal strings (as with C<\{>), or else they generate special nodes
2885 in the finite automaton (as with C<\b>).  Characters special to the
2886 RE engine (such as C<|>) generate corresponding nodes or groups of
2887 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2888 converted to literal strings to match, or else is ignored (as is
2889 whitespace and C<#>-style comments if C</x> is present).
2890
2891 Parsing of the bracketed character class construct, C<[...]>, is
2892 rather different than the rule used for the rest of the pattern.
2893 The terminator of this construct is found using the same rules as
2894 for finding the terminator of a C<{}>-delimited construct, the only
2895 exception being that C<]> immediately following C<[> is treated as
2896 though preceded by a backslash.
2897
2898 The terminator of runtime C<(?{...})> is found by temporarily switching
2899 control to the perl parser, which should stop at the point where the
2900 logically balancing terminating C<}> is found.
2901
2902 It is possible to inspect both the string given to RE engine and the
2903 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2904 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
2905 switch documented in L<perlrun/"Command Switches">.
2906
2907 =item Optimization of regular expressions
2908 X<regexp, optimization>
2909
2910 This step is listed for completeness only.  Since it does not change
2911 semantics, details of this step are not documented and are subject
2912 to change without notice.  This step is performed over the finite
2913 automaton that was generated during the previous pass.
2914
2915 It is at this stage that C<split()> silently optimizes C</^/> to
2916 mean C</^/m>.
2917
2918 =back
2919
2920 =head2 I/O Operators
2921 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2922 X<< <> >> X<< <<>> >> X<@ARGV>
2923
2924 There are several I/O operators you should know about.
2925
2926 A string enclosed by backticks (grave accents) first undergoes
2927 double-quote interpolation.  It is then interpreted as an external
2928 command, and the output of that command is the value of the
2929 backtick string, like in a shell.  In scalar context, a single string
2930 consisting of all output is returned.  In list context, a list of
2931 values is returned, one per line of output.  (You can set C<$/> to use
2932 a different line terminator.)  The command is executed each time the
2933 pseudo-literal is evaluated.  The status value of the command is
2934 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2935 Unlike in B<csh>, no translation is done on the return data--newlines
2936 remain newlines.  Unlike in any of the shells, single quotes do not
2937 hide variable names in the command from interpretation.  To pass a
2938 literal dollar-sign through to the shell you need to hide it with a
2939 backslash.  The generalized form of backticks is C<qx//>.  (Because
2940 backticks always undergo shell expansion as well, see L<perlsec> for
2941 security concerns.)
2942 X<qx> X<`> X<``> X<backtick> X<glob>
2943
2944 In scalar context, evaluating a filehandle in angle brackets yields
2945 the next line from that file (the newline, if any, included), or
2946 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2947 (sometimes known as file-slurp mode) and the file is empty, it
2948 returns C<''> the first time, followed by C<undef> subsequently.
2949
2950 Ordinarily you must assign the returned value to a variable, but
2951 there is one situation where an automatic assignment happens.  If
2952 and only if the input symbol is the only thing inside the conditional
2953 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2954 the value is automatically assigned to the global variable C<$_>,
2955 destroying whatever was there previously.  (This may seem like an
2956 odd thing to you, but you'll use the construct in almost every Perl
2957 script you write.)  The C<$_> variable is not implicitly localized.
2958 You'll have to put a S<C<local $_;>> before the loop if you want that
2959 to happen.
2960
2961 The following lines are equivalent:
2962
2963     while (defined($_ = <STDIN>)) { print; }
2964     while ($_ = <STDIN>) { print; }
2965     while (<STDIN>) { print; }
2966     for (;<STDIN>;) { print; }
2967     print while defined($_ = <STDIN>);
2968     print while ($_ = <STDIN>);
2969     print while <STDIN>;
2970
2971 This also behaves similarly, but assigns to a lexical variable 
2972 instead of to C<$_>:
2973
2974     while (my $line = <STDIN>) { print $line }
2975
2976 In these loop constructs, the assigned value (whether assignment
2977 is automatic or explicit) is then tested to see whether it is
2978 defined.  The defined test avoids problems where the line has a string
2979 value that would be treated as false by Perl; for example a "" or
2980 a C<"0"> with no trailing newline.  If you really mean for such values
2981 to terminate the loop, they should be tested for explicitly:
2982
2983     while (($_ = <STDIN>) ne '0') { ... }
2984     while (<STDIN>) { last unless $_; ... }
2985
2986 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
2987 explicit C<defined> test or comparison elicits a warning if the
2988 S<C<use warnings>> pragma or the B<-w>
2989 command-line switch (the C<$^W> variable) is in effect.
2990
2991 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2992 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2993 in packages, where they would be interpreted as local identifiers
2994 rather than global.)  Additional filehandles may be created with
2995 the C<open()> function, amongst others.  See L<perlopentut> and
2996 L<perlfunc/open> for details on this.
2997 X<stdin> X<stdout> X<sterr>
2998
2999 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
3000 a list, a list comprising all input lines is returned, one line per
3001 list element.  It's easy to grow to a rather large data space this
3002 way, so use with care.
3003
3004 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
3005 See L<perlfunc/readline>.
3006
3007 The null filehandle C<< <> >> is special: it can be used to emulate the
3008 behavior of B<sed> and B<awk>, and any other Unix filter program
3009 that takes a list of filenames, doing the same to each line
3010 of input from all of them.  Input from C<< <> >> comes either from
3011 standard input, or from each file listed on the command line.  Here's
3012 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3013 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3014 gives you standard input.  The C<@ARGV> array is then processed as a list
3015 of filenames.  The loop
3016
3017     while (<>) {
3018         ...                     # code for each line
3019     }
3020
3021 is equivalent to the following Perl-like pseudo code:
3022
3023     unshift(@ARGV, '-') unless @ARGV;
3024     while ($ARGV = shift) {
3025         open(ARGV, $ARGV);
3026         while (<ARGV>) {
3027             ...         # code for each line
3028         }
3029     }
3030
3031 except that it isn't so cumbersome to say, and will actually work.
3032 It really does shift the C<@ARGV> array and put the current filename
3033 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3034 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3035 is magical.  (The pseudo code above doesn't work because it treats
3036 C<< <ARGV> >> as non-magical.)
3037
3038 Since the null filehandle uses the two argument form of L<perlfunc/open>
3039 it interprets special characters, so if you have a script like this:
3040
3041     while (<>) {
3042         print;
3043     }
3044
3045 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3046 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3047 If you want all items in C<@ARGV> to be interpreted as file names, you
3048 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3049
3050     while (<<>>) {
3051         print;
3052     }
3053
3054 Using double angle brackets inside of a while causes the open to use the
3055 three argument form (with the second argument being C<< < >>), so all
3056 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3057 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3058 empty, it will still read from the standard input.)
3059
3060 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3061 containing the list of filenames you really want.  Line numbers (C<$.>)
3062 continue as though the input were one big happy file.  See the example
3063 in L<perlfunc/eof> for how to reset line numbers on each file.
3064
3065 If you want to set C<@ARGV> to your own list of files, go right ahead.
3066 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3067
3068     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3069
3070 You can even set them to pipe commands.  For example, this automatically
3071 filters compressed arguments through B<gzip>:
3072
3073     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3074
3075 If you want to pass switches into your script, you can use one of the
3076 C<Getopts> modules or put a loop on the front like this:
3077
3078     while ($_ = $ARGV[0], /^-/) {
3079         shift;
3080         last if /^--$/;
3081         if (/^-D(.*)/) { $debug = $1 }
3082         if (/^-v/)     { $verbose++  }
3083         # ...           # other switches
3084     }
3085
3086     while (<>) {
3087         # ...           # code for each line
3088     }
3089
3090 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3091 If you call it again after this, it will assume you are processing another
3092 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3093
3094 If what the angle brackets contain is a simple scalar variable (for example,
3095 C<$foo>), then that variable contains the name of the
3096 filehandle to input from, or its typeglob, or a reference to the
3097 same.  For example:
3098
3099     $fh = \*STDIN;
3100     $line = <$fh>;
3101
3102 If what's within the angle brackets is neither a filehandle nor a simple
3103 scalar variable containing a filehandle name, typeglob, or typeglob
3104 reference, it is interpreted as a filename pattern to be globbed, and
3105 either a list of filenames or the next filename in the list is returned,
3106 depending on context.  This distinction is determined on syntactic
3107 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3108 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3109 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3110 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3111 is treated as C<glob("$x ")>, not C<readline($x)>.
3112
3113 One level of double-quote interpretation is done first, but you can't
3114 say C<< <$foo> >> because that's an indirect filehandle as explained
3115 in the previous paragraph.  (In older versions of Perl, programmers
3116 would insert curly brackets to force interpretation as a filename glob:
3117 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3118 internal function directly as C<glob($foo)>, which is probably the right
3119 way to have done it in the first place.)  For example:
3120
3121     while (<*.c>) {
3122         chmod 0644, $_;
3123     }
3124
3125 is roughly equivalent to:
3126
3127     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3128     while (<FOO>) {
3129         chomp;
3130         chmod 0644, $_;
3131     }
3132
3133 except that the globbing is actually done internally using the standard
3134 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3135
3136     chmod 0644, <*.c>;
3137
3138 A (file)glob evaluates its (embedded) argument only when it is
3139 starting a new list.  All values must be read before it will start
3140 over.  In list context, this isn't important because you automatically
3141 get them all anyway.  However, in scalar context the operator returns
3142 the next value each time it's called, or C<undef> when the list has
3143 run out.  As with filehandle reads, an automatic C<defined> is
3144 generated when the glob occurs in the test part of a C<while>,
3145 because legal glob returns (for example,
3146 a file called F<0>) would otherwise
3147 terminate the loop.  Again, C<undef> is returned only once.  So if
3148 you're expecting a single value from a glob, it is much better to
3149 say
3150
3151     ($file) = <blurch*>;
3152
3153 than
3154
3155     $file = <blurch*>;
3156
3157 because the latter will alternate between returning a filename and
3158 returning false.
3159
3160 If you're trying to do variable interpolation, it's definitely better
3161 to use the C<glob()> function, because the older notation can cause people
3162 to become confused with the indirect filehandle notation.
3163
3164     @files = glob("$dir/*.[ch]");
3165     @files = glob($files[$i]);
3166
3167 =head2 Constant Folding
3168 X<constant folding> X<folding>
3169
3170 Like C, Perl does a certain amount of expression evaluation at
3171 compile time whenever it determines that all arguments to an
3172 operator are static and have no side effects.  In particular, string
3173 concatenation happens at compile time between literals that don't do
3174 variable substitution.  Backslash interpolation also happens at
3175 compile time.  You can say
3176
3177       'Now is the time for all'
3178     . "\n" 
3179     .  'good men to come to.'
3180
3181 and this all reduces to one string internally.  Likewise, if
3182 you say
3183
3184     foreach $file (@filenames) {
3185         if (-s $file > 5 + 100 * 2**16) {  }
3186     }
3187
3188 the compiler precomputes the number which that expression
3189 represents so that the interpreter won't have to.
3190
3191 =head2 No-ops
3192 X<no-op> X<nop>
3193
3194 Perl doesn't officially have a no-op operator, but the bare constants
3195 C<0> and C<1> are special-cased not to produce a warning in void
3196 context, so you can for example safely do
3197
3198     1 while foo();
3199
3200 =head2 Bitwise String Operators
3201 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3202
3203 Bitstrings of any size may be manipulated by the bitwise operators
3204 (C<~ | & ^>).
3205
3206 If the operands to a binary bitwise op are strings of different
3207 sizes, B<|> and B<^> ops act as though the shorter operand had
3208 additional zero bits on the right, while the B<&> op acts as though
3209 the longer operand were truncated to the length of the shorter.
3210 The granularity for such extension or truncation is one or more
3211 bytes.
3212
3213     # ASCII-based examples
3214     print "j p \n" ^ " a h";            # prints "JAPH\n"
3215     print "JA" | "  ph\n";              # prints "japh\n"
3216     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3217     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3218
3219 If you are intending to manipulate bitstrings, be certain that
3220 you're supplying bitstrings: If an operand is a number, that will imply
3221 a B<numeric> bitwise operation.  You may explicitly show which type of
3222 operation you intend by using C<""> or C<0+>, as in the examples below.
3223
3224     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3225     $foo = '150' |  105;        # yields 255
3226     $foo =  150  | '105';       # yields 255
3227     $foo = '150' | '105';       # yields string '155' (under ASCII)
3228
3229     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3230     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3231
3232 This somewhat unpredictable behavior can be avoided with the experimental
3233 "bitwise" feature, new in Perl 5.22.  You can enable it via S<C<use feature
3234 'bitwise'>>.  By default, it will warn unless the C<"experimental::bitwise">
3235 warnings category has been disabled.  (S<C<use experimental 'bitwise'>> will
3236 enable the feature and disable the warning.)  Under this feature, the four
3237 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3238 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3239 strings:
3240
3241     use experimental "bitwise";
3242     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3243     $foo = '150' |  105;        # yields 255
3244     $foo =  150  | '105';       # yields 255
3245     $foo = '150' | '105';       # yields 255
3246     $foo =  150  |. 105;        # yields string '155'
3247     $foo = '150' |. 105;        # yields string '155'
3248     $foo =  150  |.'105';       # yields string '155'
3249     $foo = '150' |.'105';       # yields string '155'
3250
3251     $baz = $foo &  $bar;        # both operands numeric
3252     $biz = $foo ^. $bar;        # both operands stringy
3253
3254 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3255 behave likewise under the feature.
3256
3257 The behavior of these operators is problematic (and subject to change)
3258 if either or both of the strings are encoded in UTF-8 (see
3259 L<perlunicode/Byte and Character Semantics>.
3260
3261 See L<perlfunc/vec> for information on how to manipulate individual bits
3262 in a bit vector.
3263
3264 =head2 Integer Arithmetic
3265 X<integer>
3266
3267 By default, Perl assumes that it must do most of its arithmetic in
3268 floating point.  But by saying
3269
3270     use integer;
3271
3272 you may tell the compiler to use integer operations
3273 (see L<integer> for a detailed explanation) from here to the end of
3274 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3275
3276     no integer;
3277
3278 which lasts until the end of that BLOCK.  Note that this doesn't
3279 mean everything is an integer, merely that Perl will use integer
3280 operations for arithmetic, comparison, and bitwise operators.  For
3281 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3282 still get C<1.4142135623731> or so.
3283
3284 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3285 C<< >> >>) always produce integral results.  (But see also
3286 L<Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3287 them.  By default, their results are interpreted as unsigned integers, but
3288 if S<C<use integer>> is in effect, their results are interpreted
3289 as signed integers.  For example, C<~0> usually evaluates to a large
3290 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3291 machines.
3292
3293 =head2 Floating-point Arithmetic
3294
3295 X<floating-point> X<floating point> X<float> X<real>
3296
3297 While S<C<use integer>> provides integer-only arithmetic, there is no
3298 analogous mechanism to provide automatic rounding or truncation to a
3299 certain number of decimal places.  For rounding to a certain number
3300 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3301 See L<perlfaq4>.
3302
3303 Floating-point numbers are only approximations to what a mathematician
3304 would call real numbers.  There are infinitely more reals than floats,
3305 so some corners must be cut.  For example:
3306
3307     printf "%.20g\n", 123456789123456789;
3308     #        produces 123456789123456784
3309
3310 Testing for exact floating-point equality or inequality is not a
3311 good idea.  Here's a (relatively expensive) work-around to compare
3312 whether two floating-point numbers are equal to a particular number of
3313 decimal places.  See Knuth, volume II, for a more robust treatment of
3314 this topic.
3315
3316     sub fp_equal {
3317         my ($X, $Y, $POINTS) = @_;
3318         my ($tX, $tY);
3319         $tX = sprintf("%.${POINTS}g", $X);
3320         $tY = sprintf("%.${POINTS}g", $Y);
3321         return $tX eq $tY;
3322     }
3323
3324 The POSIX module (part of the standard perl distribution) implements
3325 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3326 The C<L<Math::Complex>> module (part of the standard perl distribution)
3327 defines mathematical functions that work on both the reals and the
3328 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3329 POSIX can't work with complex numbers.
3330
3331 Rounding in financial applications can have serious implications, and
3332 the rounding method used should be specified precisely.  In these
3333 cases, it probably pays not to trust whichever system rounding is
3334 being used by Perl, but to instead implement the rounding function you
3335 need yourself.
3336
3337 =head2 Bigger Numbers
3338 X<number, arbitrary precision>
3339
3340 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3341 C<L<Math::BigFloat>> modules,
3342 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3343 variable-precision arithmetic and overloaded operators, although
3344 they're currently pretty slow.  At the cost of some space and
3345 considerable speed, they avoid the normal pitfalls associated with
3346 limited-precision representations.
3347
3348         use 5.010;
3349         use bigint;  # easy interface to Math::BigInt
3350         $x = 123456789123456789;
3351         say $x * $x;
3352     +15241578780673678515622620750190521
3353
3354 Or with rationals:
3355
3356         use 5.010;
3357         use bigrat;
3358         $x = 3/22;
3359         $y = 4/6;
3360         say "x/y is ", $x/$y;
3361         say "x*y is ", $x*$y;
3362         x/y is 9/44
3363         x*y is 1/11
3364
3365 Several modules let you calculate with unlimited or fixed precision
3366 (bound only by memory and CPU time).  There
3367 are also some non-standard modules that
3368 provide faster implementations via external C libraries.
3369
3370 Here is a short, but incomplete summary:
3371
3372   Math::String           treat string sequences like numbers
3373   Math::FixedPrecision   calculate with a fixed precision
3374   Math::Currency         for currency calculations
3375   Bit::Vector            manipulate bit vectors fast (uses C)
3376   Math::BigIntFast       Bit::Vector wrapper for big numbers
3377   Math::Pari             provides access to the Pari C library
3378   Math::Cephes           uses the external Cephes C library (no
3379                          big numbers)
3380   Math::Cephes::Fraction fractions via the Cephes library
3381   Math::GMP              another one using an external C library
3382   Math::GMPz             an alternative interface to libgmp's big ints
3383   Math::GMPq             an interface to libgmp's fraction numbers
3384   Math::GMPf             an interface to libgmp's floating point numbers
3385
3386 Choose wisely.
3387
3388 =cut