lib/blib.pm

   1 package blib;
   2
   3 =head1 NAME
   4
   5 blib - Use MakeMaker's uninstalled version of a package
   6
   7 =head1 SYNOPSIS
   8
   9  perl -Mblib script [args...]
  10
  11  perl -Mblib=dir script [args...]
  12
  13 =head1 DESCRIPTION
  14
  15 Looks for MakeMaker-like I<'blib'> directory structure starting in
  16 I<dir> (or current directory) and working back up to five levels of '..'.
  17
  18 Intended for use on command line with B<-M> option as a way of testing
  19 arbitary scripts against an uninstalled version of a package.
  20
  21 However it is possible to :
  22
  23  use blib;
  24  or
  25  use blib '..';
  26
  27 etc. if you really must.
  28
  29 =head1 BUGS
  30
  31 Pollutes global name space for development only task.
  32
  33 =head1 AUTHOR
  34
  35 Nick Ing-Simmons nik@tiuk.ti.com
  36
  37 =cut
  38
  39 use Cwd;
  40
  41 use vars qw($VERSION $Verbose);
  42 $VERSION = '1.00';
  43 $Verbose = 0;
  44
  45 sub import
  46 {
  47  my $package = shift;
  48  my $dir = getcwd;
  49  if ($^O eq 'VMS') { ($dir = VMS::Filespec::unixify($dir)) =~ s-/\z--; }
  50  if (@_)
  51   {
  52    $dir = shift;
  53    $dir =~ s/blib\z//;
  54    $dir =~ s,/+\z,,;
  55    $dir = '.' unless ($dir);
  56    die "$dir is not a directory\n" unless (-d $dir);
  57   }
  58  my $i   = 5;
  59  while ($i--)
  60   {
  61    my $blib = "${dir}/blib";
  62    if (-d $blib && -d "$blib/arch" && -d "$blib/lib")
  63     {
  64      unshift(@INC,"$blib/arch","$blib/lib");
  65      warn "Using $blib\n" if $Verbose;
  66      return;
  67     }
  68    $dir .= "/..";
  69   }
  70  die "Cannot find blib even in $dir\n";
  71 }
  72
  73 1;