This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update Socket to CPAN version 2.010
[perl5.git] / cpan / Socket / Makefile.PL
1 #!perl
2 use strict;
3 use warnings;
4
5 use ExtUtils::MakeMaker;
6 use ExtUtils::Constant 0.23 'WriteConstants';
7 use Config;
8
9 my @DEFINES;
10
11 my $cb;
12 my $seq = 0;
13 sub check_for
14 {
15     my %args = @_;
16     return if $ENV{PERL_CORE};
17     return if defined $Config{$args{confkey}};
18
19     require ExtUtils::CBuilder;
20     $cb ||= ExtUtils::CBuilder->new( quiet => 1 );
21
22     my $main   = $args{main}   || "";
23     my $header = $args{header} || "";
24
25     print "Checking $args{define}...\n";
26
27     my $file_base = "test-$seq"; $seq++;
28
29     my $file_source = "$file_base.c";
30
31     {
32         open( my $file_source_fh, ">", $file_source ) or die "Cannot write $file_source - $!";
33         print $file_source_fh <<"EOF";
34 #include <sys/types.h>
35 #ifdef WIN32
36 # include <ws2tcpip.h>
37 # include <winsock.h>
38 #else
39 # include <sys/socket.h>
40 # include <netdb.h>
41 # include <netinet/in.h>
42 # include <arpa/inet.h>
43 #endif
44 $header
45 int main(int argc, char *argv[])
46   {
47     (void)argc;
48     (void)argv;
49     $main
50     return 0;
51   }
52 EOF
53     }
54
55     my $file_obj = eval { $cb->compile( source => $file_source ) };
56     unlink $file_source;
57
58     return 0 unless defined $file_obj;
59
60     my $file_exe = eval { $cb->link_executable( objects => $file_obj ) };
61     unlink $file_obj;
62
63     return 0 unless defined $file_exe;
64
65     # Don't need to try running it
66     unlink $file_exe;
67
68     push @DEFINES, $args{define};
69 }
70
71 sub check_for_func
72 {
73     my %args = @_;
74     my $func = delete $args{func};
75     check_for( %args, main => "void *p = &$func; if(p == NULL) return 1;" );
76 }
77
78 my %defines = (
79     # -Dfoo               func()        $Config{key}
80     HAS_GETADDRINFO => [ "getaddrinfo", "d_getaddrinfo" ],
81     HAS_GETNAMEINFO => [ "getnameinfo", "d_getnameinfo" ],
82     HAS_INET_ATON   => [ "inet_aton",   "d_inetaton" ],
83     HAS_INETNTOP    => [ "inet_ntop",   "d_inetntop" ],
84     HAS_INETPTON    => [ "inet_pton",   "d_inetpton" ],
85 );
86
87 foreach my $define ( sort keys %defines ) {
88     my ( $func, $key ) = @{$defines{$define}};
89     check_for_func( 
90         confkey => $key,
91         define  => $define,
92         func    => $func
93     );
94 }
95
96 check_for(
97     confkey => "d_sockaddr_sa_len",
98     define  => "HAS_SOCKADDR_SA_LEN",
99     main    => "struct sockaddr sa; sa.sa_len = 0;"
100 );
101
102 check_for(
103     confkey => "d_sockaddr_in6",
104     define  => "HAS_SOCKADDR_IN6",
105     main    => "struct sockaddr_in6 sin6; sin6.sin6_family = AF_INET6;"
106 );
107
108 check_for(
109     confkey => "d_sin6_scope_id",
110     define  => "HAS_SIN6_SCOPE_ID",
111     main    => "struct sockaddr_in6 sin6; sin6.sin6_scope_id = 0;"
112 );
113
114 check_for(
115     confkey => "d_ip_mreq",
116     define  => "HAS_IP_MREQ",
117     main    => "struct ip_mreq mreq; mreq.imr_multiaddr.s_addr = INADDR_ANY;"
118 );
119
120 check_for(
121     confkey => "d_ip_mreq_source",
122     define  => "HAS_IP_MREQ_SOURCE",
123     main    => "struct ip_mreq_source mreq; mreq.imr_multiaddr.s_addr = INADDR_ANY;"
124 );
125
126 check_for(
127     confkey => "d_ipv6_mreq",
128     define  => "HAS_IPV6_MREQ",
129     main    => "struct ipv6_mreq mreq; mreq.ipv6mr_interface = 0;"
130 );
131
132 # TODO: Needs adding to perl5 core before importing dual-life again
133 check_for(
134     confkey => "i_netinet_ip",
135     define  => "I_NETINET_IP",
136     header  => "#include <netinet/ip.h>",
137 );
138
139 my %makefile_args;
140
141 # Since we're providing a later version of a core module, before 5.12 the
142 # @INC order is wrong so we'll have to go in perl rather than site dirs
143 $makefile_args{INSTALLDIRS} = "perl" if $] < 5.012;
144
145 WriteMakefile(
146     NAME          => 'Socket',
147     VERSION_FROM  => 'Socket.pm',
148     # ABSTRACT_FROM gets confused by C<Socket>
149     ABSTRACT      => 'networking constants and support functions',
150    ($Config{libs} =~ /(-lsocks\S*)/ ? (LIBS => [ "$1" ] ) : ()),
151     XSPROTOARG    => '-noprototypes',           # XXX remove later?
152     realclean     => {FILES=> 'const-c.inc const-xs.inc'},
153     DEFINE        => join( " ", map { "-D$_" } @DEFINES ),
154     CONFIGURE_REQUIRES => {
155         'ExtUtils::CBuilder' => 0,
156         'ExtUtils::Constant' => '0.23',
157     },
158     MIN_PERL_VERSION => '5.006001',
159     LICENSE       => 'perl',
160     %makefile_args,
161 );
162 my @names = (
163     qw(
164         AF_802 AF_AAL AF_APPLETALK AF_CCITT AF_CHAOS AF_CTF AF_DATAKIT
165         AF_DECnet AF_DLI AF_ECMA AF_GOSIP AF_HYLINK AF_IMPLINK AF_INET AF_INET6
166         AF_ISO AF_KEY AF_LAST AF_LAT AF_LINK AF_MAX AF_NBS AF_NIT AF_NS AF_OSI
167         AF_OSINET AF_PUP AF_ROUTE AF_SNA AF_UNIX AF_UNSPEC AF_USER AF_WAN
168         AF_X25
169
170         AI_ADDRCONFIG AI_ALL AI_CANONIDN AI_CANONNAME AI_IDN
171         AI_IDN_ALLOW_UNASSIGNED AI_IDN_USE_STD3_ASCII_RULES AI_NUMERICHOST
172         AI_NUMERICSERV AI_PASSIVE AI_V4MAPPED
173
174         EAI_ADDRFAMILY EAI_AGAIN EAI_BADFLAGS EAI_BADHINTS EAI_FAIL EAI_FAMILY
175         EAI_NODATA EAI_NONAME EAI_PROTOCOL EAI_SERVICE EAI_SOCKTYPE EAI_SYSTEM
176
177         IOV_MAX
178
179         IP_ADD_MEMBERSHIP IP_ADD_SOURCE_MEMBERSHIP IP_DROP_MEMBERSHIP
180         IP_DROP_SOURCE_MEMBERSHIP IP_HDRINCL IP_MULTICAST_IF IP_MULTICAST_LOOP
181         IP_MULTICAST_TTL IP_OPTIONS IP_RECVOPTS IP_RECVRETOPTS IP_RETOPTS IP_TOS
182         IP_TTL
183
184         IPTOS_LOWDELAY IPTOS_THROUGHPUT IPTOS_RELIABILITY IPTOS_MINCOST
185
186         IPV6_ADD_MEMBERSHIP IPV6_DROP_MEMBERSHIP IPV6_JOIN_GROUP
187         IPV6_LEAVE_GROUP IPV6_MTU IPV6_MTU_DISCOVER IPV6_MULTICAST_HOPS
188         IPV6_MULTICAST_IF IPV6_MULTICAST_LOOP IPV6_UNICAST_HOPS IPV6_V6ONLY
189
190         MSG_BCAST MSG_BTAG MSG_CTLFLAGS MSG_CTLIGNORE MSG_DONTWAIT MSG_EOF
191         MSG_EOR MSG_ERRQUEUE MSG_ETAG MSG_FIN MSG_MAXIOVLEN MSG_MCAST
192         MSG_NOSIGNAL MSG_RST MSG_SYN MSG_TRUNC MSG_URG MSG_WAITALL MSG_WIRE
193
194         NI_DGRAM NI_IDN NI_IDN_ALLOW_UNASSIGNED NI_IDN_USE_STD3_ASCII_RULES
195         NI_NAMEREQD NI_NOFQDN NI_NUMERICHOST NI_NUMERICSERV
196
197         PF_802 PF_AAL PF_APPLETALK PF_CCITT PF_CHAOS PF_CTF PF_DATAKIT
198         PF_DECnet PF_DLI PF_ECMA PF_GOSIP PF_HYLINK PF_IMPLINK PF_INET PF_INET6
199         PF_ISO PF_KEY PF_LAST PF_LAT PF_LINK PF_MAX PF_NBS PF_NIT PF_NS PF_OSI
200         PF_OSINET PF_PUP PF_ROUTE PF_SNA PF_UNIX PF_UNSPEC PF_USER PF_WAN
201         PF_X25
202
203         SCM_CONNECT SCM_CREDENTIALS SCM_CREDS SCM_TIMESTAMP
204
205         SOCK_DGRAM SOCK_RAW SOCK_RDM SOCK_SEQPACKET SOCK_STREAM
206         SOCK_NONBLOCK SOCK_CLOEXEC
207
208         SOL_SOCKET 
209
210         SOMAXCONN
211
212         SO_ACCEPTCONN SO_ATTACH_FILTER SO_BACKLOG SO_BROADCAST SO_CHAMELEON
213         SO_DEBUG SO_DETACH_FILTER SO_DGRAM_ERRIND SO_DOMAIN SO_DONTLINGER
214         SO_DONTROUTE SO_ERROR SO_FAMILY SO_KEEPALIVE SO_LINGER SO_OOBINLINE
215         SO_PASSCRED SO_PASSIFNAME SO_PEERCRED SO_PROTOCOL SO_PROTOTYPE
216         SO_RCVBUF SO_RCVLOWAT SO_RCVTIMEO SO_REUSEADDR SO_REUSEPORT
217         SO_SECURITY_AUTHENTICATION SO_SECURITY_ENCRYPTION_NETWORK
218         SO_SECURITY_ENCRYPTION_TRANSPORT SO_SNDBUF SO_SNDLOWAT SO_SNDTIMEO
219         SO_STATE SO_TYPE SO_USELOOPBACK SO_XOPEN SO_XSE
220
221         TCP_CONGESTION TCP_CONNECTIONTIMEOUT TCP_CORK TCP_DEFER_ACCEPT TCP_INFO
222         TCP_INIT_CWND TCP_KEEPALIVE TCP_KEEPCNT TCP_KEEPIDLE TCP_KEEPINTVL
223         TCP_LINGER2 TCP_MAXRT TCP_MAXSEG TCP_MD5SIG TCP_NODELAY TCP_NOOPT
224         TCP_NOPUSH TCP_QUICKACK TCP_SACK_ENABLE TCP_STDURG TCP_SYNCNT
225         TCP_WINDOW_CLAMP
226
227         UIO_MAXIOV
228     ),
229     {name=>"IPPROTO_IP",   type=>"IV", default=>["IV",   0]},
230     {name=>"IPPROTO_IPV6", type=>"IV", default=>["IV",  41]},
231     {name=>"IPPROTO_RAW",  type=>"IV", default=>["IV", 255]},
232     {name=>"IPPROTO_ICMP", type=>"IV", default=>["IV",  1]},
233     {name=>"IPPROTO_TCP",  type=>"IV", default=>["IV",  6]},
234     {name=>"IPPROTO_UDP",  type=>"IV", default=>["IV", 17]},
235     {name=>"SHUT_RD",   type=>"IV", default=>["IV", "0"]},
236     {name=>"SHUT_WR",   type=>"IV", default=>["IV", "1"]},
237     {name=>"SHUT_RDWR", type=>"IV", default=>["IV", "2"]},
238 );
239
240 push @names, {
241     name  => $_,
242     type  => "IV",
243     macro => [ "#if defined($_) || defined(HAS_$_) /* might be an enum */\n",
244                "#endif\n" ]
245 } foreach qw (MSG_CTRUNC MSG_DONTROUTE MSG_OOB MSG_PEEK MSG_PROXY SCM_RIGHTS);
246
247 push @names, {
248     name  => $_,
249     type  => "SV",
250     pre   => "struct in_addr ip_address; ip_address.s_addr = htonl($_);",
251     value => "newSVpvn_flags((char *)&ip_address,sizeof(ip_address), SVs_TEMP)",
252 } foreach qw(INADDR_ANY INADDR_LOOPBACK INADDR_NONE INADDR_BROADCAST);
253
254 push @names, {
255     name  => $_,
256     type  => "SV",
257     macro => [ "#ifdef ${_}_INIT\n",
258                "#endif\n" ],
259     pre   => "struct in6_addr ip6_address = ${_}_INIT;",
260     value => "newSVpvn_flags((char *)&ip6_address,sizeof(ip6_address), SVs_TEMP)",
261 } foreach qw(IN6ADDR_ANY IN6ADDR_LOOPBACK);
262
263 # Work around an old Perl core bug that affects ExtUtils::Constants on
264 # pre-5.8.2 Perls.  EU:C should be amended to work around this itself.
265 if("$]" < 5.008002) {
266     require ExtUtils::Constant::ProxySubs;
267     no warnings "once";
268     $ExtUtils::Constant::ProxySubs::type_to_C_value{$_} = sub { () }
269         foreach qw(YES NO UNDEF), "";
270 }
271
272 WriteConstants(
273     PROXYSUBS => {autoload => 1},
274     NAME => 'Socket',
275     NAMES => \@names,
276 );