lib/Benchmark.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6 }
   7
   8 use warnings;
   9 use strict;
  10 use vars qw($foo $bar $baz $ballast);
  11 use Test::More tests => 173;
  12
  13 use Benchmark qw(:all);
  14
  15 my $delta = 0.4;
  16
  17 # Some timing ballast
  18 sub fib {
  19   my $n = shift;
  20   return $n if $n < 2;
  21   fib($n-1) + fib($n-2);
  22 }
  23 $ballast = 15;
  24
  25 my $all_pattern =
  26     qr/(\d+) +wallclock secs? +\( *(-?\d+\.\d\d) +usr +(-?\d+\.\d\d) +sys +\+ +(-?\d+\.\d\d) +cusr +(-?\d+\.\d\d) +csys += +(-?\d+\.\d\d) +CPU\)/;
  27 my $noc_pattern =
  28     qr/(\d+) +wallclock secs? +\( *(-?\d+\.\d\d) +usr +\+ +(-?\d+\.\d\d) +sys += +(-?\d+\.\d\d) +CPU\)/;
  29 my $nop_pattern =
  30     qr/(\d+) +wallclock secs? +\( *(-?\d+\.\d\d) +cusr +\+ +(-?\d+\.\d\d) +csys += +\d+\.\d\d +CPU\)/;
  31 # Please don't trust the matching parenthises to be useful in this :-)
  32 my $default_pattern = qr/$all_pattern|$noc_pattern/;
  33
  34 my $t0 = new Benchmark;
  35 isa_ok ($t0, 'Benchmark', "Ensure we can create a benchmark object");
  36
  37 # We use the benchmark object once we've done some work:
  38
  39 isa_ok(timeit(5, sub {++$foo}), 'Benchmark', "timeit CODEREF");
  40 is ($foo, 5, "benchmarked code was run 5 times");
  41
  42 isa_ok(timeit(5, '++$bar'), 'Benchmark', "timeit eval");
  43 is ($bar, 5, "benchmarked code was run 5 times");
  44
  45 print "# Burning CPU to benchmark things will take time...\n";
  46
  47
  48
  49 # We need to do something fairly slow in the coderef.
  50 # Same coderef. Same place in memory.
  51 my $coderef = sub {$baz += fib($ballast)};
  52
  53 # The default is three.
  54 $baz = 0;
  55 my $threesecs = countit(0, $coderef);
  56 isa_ok($threesecs, 'Benchmark', "countit 0, CODEREF");
  57 isnt ($baz, 0, "benchmarked code was run");
  58 my $in_threesecs = $threesecs->iters;
  59 print "# $in_threesecs iterations\n";
  60 ok ($in_threesecs > 0, "iters returned positive iterations");
  61
  62 my $estimate = int (100 * $in_threesecs / 3) / 100;
  63 print "# from the 3 second run estimate $estimate iterations in 1 second...\n";
  64 $baz = 0;
  65 my $onesec = countit(1, $coderef);
  66 isa_ok($onesec, 'Benchmark', "countit 1, CODEREF");
  67 isnt ($baz, 0, "benchmarked code was run");
  68 my $in_onesec = $onesec->iters;
  69 print "# $in_onesec iterations\n";
  70 ok ($in_onesec > 0, "iters returned positive iterations");
  71
  72 {
  73   my $difference = $in_onesec - $estimate;
  74   my $actual = abs ($difference / $in_onesec);
  75   ok ($actual < $delta, "is $in_onesec within $delta of estimate ($estimate)");
  76   print "# $in_onesec is between " . ($delta / 2) .
  77     " and $delta of estimate. Not that safe.\n" if $actual > $delta/2;
  78 }
  79
  80 # I found that the eval'ed version was 3 times faster than the coderef.
  81 # (now it has a different ballast value)
  82 $baz = 0;
  83 my $again = countit(1, '$baz += fib($ballast)');
  84 isa_ok($onesec, 'Benchmark', "countit 1, eval");
  85 isnt ($baz, 0, "benchmarked code was run");
  86 my $in_again = $again->iters;
  87 print "# $in_again iterations\n";
  88 ok ($in_again > 0, "iters returned positive iterations");
  89
  90
  91 my $t1 = new Benchmark;
  92 isa_ok ($t1, 'Benchmark', "Create another benchmark object now we're finished");
  93
  94 my $diff = timediff ($t1, $t0);
  95 isa_ok ($diff, 'Benchmark', "Get the time difference");
  96 isa_ok (timesum ($t0, $t1), 'Benchmark', "check timesum");
  97
  98 my $default = timestr ($diff);
  99 isnt ($default, '', 'timestr ($diff)');
 100 my $auto = timestr ($diff, 'auto');
 101 is ($auto, $default, 'timestr ($diff, "auto") matches timestr ($diff)');
 102
 103 {
 104     my $all = timestr ($diff, 'all');
 105     like ($all, $all_pattern, 'timestr ($diff, "all")');
 106     print "# $all\n";
 107
 108     my ($wallclock, $usr, $sys, $cusr, $csys, $cpu) = $all =~ $all_pattern;
 109
 110     is (timestr ($diff, 'none'), '', "none supresses output");
 111
 112     my $noc = timestr ($diff, 'noc');
 113     like ($noc, qr/$wallclock +wallclock secs? +\( *$usr +usr +\+ +$sys +sys += +$cpu +CPU\)/, 'timestr ($diff, "noc")');
 114
 115     my $nop = timestr ($diff, 'nop');
 116     like ($nop, qr/$wallclock +wallclock secs? +\( *$cusr +cusr +\+ +$csys +csys += +\d+\.\d\d +CPU\)/, 'timestr ($diff, "nop")');
 117
 118     if ($auto eq $noc) {
 119         pass ('"auto" is "noc"');
 120     } else {
 121         is ($auto, $all, '"auto" isn\'t "noc", so should be eq to "all"');
 122     }
 123
 124     like (timestr ($diff, 'all', 'E'),
 125           qr/(\d+) +wallclock secs? +\( *\d\.\d+E[-+]?\d\d\d? +usr +\d\.\d+E[-+]?\d\d\d? +sys +\+ +\d\.\d+E[-+]?\d\d\d? +cusr +\d\.\d+E[-+]?\d\d\d? +csys += +\d\.\d+E[-+]?\d\d\d? +CPU\)/, 'timestr ($diff, "all", "E") [sprintf format of "E"]');
 126 }
 127
 128 my $out = tie *OUT, 'TieOut';
 129
 130 my $iterations = 3;
 131
 132 $foo = 0;
 133 select(OUT);
 134 my $got = timethis($iterations, sub {++$foo});
 135 select(STDOUT);
 136 isa_ok($got, 'Benchmark', "timethis CODEREF");
 137 is ($foo, $iterations, "benchmarked code was run $iterations times");
 138
 139 $got = $out->read();
 140 like ($got, qr/^timethis $iterations/, 'default title');
 141 like ($got, $default_pattern, 'default format is all or noc');
 142
 143 $bar = 0;
 144 select(OUT);
 145 $got = timethis($iterations, '++$bar');
 146 select(STDOUT);
 147 isa_ok($got, 'Benchmark', "timethis eval");
 148 is ($bar, $iterations, "benchmarked code was run $iterations times");
 149
 150 $got = $out->read();
 151 like ($got, qr/^timethis $iterations/, 'default title');
 152 like ($got, $default_pattern, 'default format is all or noc');
 153
 154 my $title = 'lies, damn lies and benchmarks';
 155 $foo = 0;
 156 select(OUT);
 157 $got = timethis($iterations, sub {++$foo}, $title);
 158 select(STDOUT);
 159 isa_ok($got, 'Benchmark', "timethis with title");
 160 is ($foo, $iterations, "benchmarked code was run $iterations times");
 161
 162 $got = $out->read();
 163 like ($got, qr/^$title:/, 'specify title');
 164 like ($got, $default_pattern, 'default format is all or noc');
 165
 166 # default is auto, which is all or noc. nop can never match the default
 167 $foo = 0;
 168 select(OUT);
 169 $got = timethis($iterations, sub {++$foo}, $title, 'nop');
 170 select(STDOUT);
 171 isa_ok($got, 'Benchmark', "timethis with format");
 172 is ($foo, $iterations, "benchmarked code was run $iterations times");
 173
 174 $got = $out->read();
 175 like ($got, qr/^$title:/, 'specify title');
 176 like ($got, $nop_pattern, 'specify format as nop');
 177
 178 {
 179     $foo = 0;
 180     select(OUT);
 181     my $start = time;
 182     $got = timethis(-2, sub {$foo+= fib($ballast)}, $title, 'none');
 183     my $end = time;
 184     select(STDOUT);
 185     isa_ok($got, 'Benchmark',
 186            "timethis, at least 2 seconds with format 'none'");
 187     ok ($foo > 0, "benchmarked code was run");
 188     ok ($end - $start > 1, "benchmarked code ran for over 1 second");
 189
 190     $got = $out->read();
 191     # Remove any warnings about having too few iterations.
 192     $got =~ s/\(warning:[^\)]+\)//gs;
 193     $got =~ s/^[ \t\n]+//s; # Remove all the whitespace from the beginning
 194
 195     is ($got, '', "format 'none' should suppress output");
 196 }
 197
 198 $foo = $bar = $baz = 0;
 199 select(OUT);
 200 $got = timethese($iterations, { Foo => sub {++$foo}, Bar => '++$bar',
 201                                 Baz => sub {++$baz} });
 202 select(STDOUT);
 203 is(ref ($got), 'HASH', "timethese should return a hashref");
 204 isa_ok($got->{Foo}, 'Benchmark', "Foo value");
 205 isa_ok($got->{Bar}, 'Benchmark', "Bar value");
 206 isa_ok($got->{Baz}, 'Benchmark', "Baz value");
 207 eq_set([keys %$got], [qw(Foo Bar Baz)], 'should be exactly three objects');
 208 is ($foo, $iterations, "Foo code was run $iterations times");
 209 is ($bar, $iterations, "Bar code was run $iterations times");
 210 is ($baz, $iterations, "Baz code was run $iterations times");
 211
 212 $got = $out->read();
 213 # Remove any warnings about having too few iterations.
 214 $got =~ s/\(warning:[^\)]+\)//gs;
 215
 216 like ($got, qr/timing $iterations iterations of\s+Bar\W+Baz\W+Foo\W*?\.\.\./s,
 217       'check title');
 218 # Remove the title
 219 $got =~ s/.*\.\.\.//s;
 220 like ($got, qr/\bBar\b.*\bBaz\b.*\bFoo\b/s, 'check output is in sorted order');
 221 like ($got, $default_pattern, 'should find default format somewhere');
 222
 223 my $code_to_test =  { Foo => sub {$foo+=fib($ballast-2)},
 224                       Bar => sub {$bar+=fib($ballast)}};
 225 # Keep these for later.
 226 my $results;
 227 {
 228     $foo = $bar = 0;
 229     select(OUT);
 230     my $start = times;
 231     $results = timethese(-0.1, $code_to_test, 'none');
 232     my $end = times;
 233     select(STDOUT);
 234
 235     is(ref ($results), 'HASH', "timethese should return a hashref");
 236     isa_ok($results->{Foo}, 'Benchmark', "Foo value");
 237     isa_ok($results->{Bar}, 'Benchmark', "Bar value");
 238     eq_set([keys %$results], [qw(Foo Bar)], 'should be exactly two objects');
 239     ok ($foo > 0, "Foo code was run");
 240     ok ($bar > 0, "Bar code was run");
 241
 242     ok (($end - $start) > 0.1, "benchmarked code ran for over 0.1 seconds");
 243
 244     $got = $out->read();
 245     # Remove any warnings about having too few iterations.
 246     $got =~ s/\(warning:[^\)]+\)//gs;
 247     is ($got =~ tr/ \t\n//c, 0, "format 'none' should suppress output");
 248 }
 249 my $graph_dissassembly =
 250     qr!^[ \t]+(\S+)[ \t]+(\w+)[ \t]+(\w+)[ \t]*         # Title line
 251     \n[ \t]*(\w+)[ \t]+([0-9.]+(?:/s)?)[ \t]+(-+)[ \t]+(-?\d+%)[ \t]*
 252     \n[ \t]*(\w+)[ \t]+([0-9.]+(?:/s)?)[ \t]+(-?\d+%)[ \t]+(-+)[ \t]*$!xm;
 253
 254 sub check_graph_consistency {
 255     my (        $ratetext, $slowc, $fastc,
 256         $slowr, $slowratet, $slowslow, $slowfastt,
 257         $fastr, $fastratet, $fastslowt, $fastfast)
 258         = @_;
 259     my $all_passed = 1;
 260     $all_passed
 261       &= is ($slowc, $slowr, "left col tag should be top row tag");
 262     $all_passed
 263       &= is ($fastc, $fastr, "right col tag should be bottom row tag");
 264     $all_passed &=
 265       like ($slowslow, qr/^-+/, "should be dash for comparing slow with slow");
 266     $all_passed
 267       &= is ($slowslow, $fastfast, "slow v slow should be same as fast v fast");
 268     my $slowrate = $slowratet;
 269     my $fastrate = $fastratet;
 270     my ($slow_is_rate, $fast_is_rate);
 271     unless ($slow_is_rate = $slowrate =~ s!/s!!) {
 272         # Slow is expressed as iters per second.
 273         $slowrate = 1/$slowrate if $slowrate;
 274     }
 275     unless ($fast_is_rate = $fastrate =~ s!/s!!) {
 276         # Fast is expressed as iters per second.
 277         $fastrate = 1/$fastrate if $fastrate;
 278     }
 279     if ($ratetext =~ /rate/i) {
 280         $all_passed
 281           &= ok ($slow_is_rate, "slow should be expressed as a rate");
 282         $all_passed
 283           &= ok ($fast_is_rate, "fast should be expressed as a rate");
 284     } else {
 285         $all_passed &=
 286           ok (!$slow_is_rate, "slow should be expressed as a iters per second");
 287         $all_passed &=
 288           ok (!$fast_is_rate, "fast should be expressed as a iters per second");
 289     }
 290
 291     (my $slowfast = $slowfastt) =~ s!%!!;
 292     (my $fastslow = $fastslowt) =~ s!%!!;
 293     if ($slowrate < $fastrate) {
 294         pass ("slow rate is less than fast rate");
 295         unless (ok ($slowfast < 0 && $slowfast >= -100,
 296                     "slowfast should be less than zero, and >= -100")) {
 297           print STDERR "# slowfast $slowfast\n";
 298           $all_passed = 0;
 299         }
 300         unless (ok ($fastslow > 0, "fastslow should be > 0")) {
 301           print STDERR "# fastslow $fastslow\n";
 302           $all_passed = 0;
 303         }
 304     } else {
 305         $all_passed
 306           &= is ($slowrate, $fastrate,
 307                  "slow rate isn't less than fast rate, so should be the same");
 308         $all_passed
 309           &= is ($slowfast, 0, "slowfast should be zero");
 310         $all_passed
 311           &= is ($fastslow, 0, "fastslow should be zero");
 312     }
 313     return $all_passed;
 314 }
 315
 316 sub check_graph_vs_output {
 317     my ($chart, $got) = @_;
 318     my (        $ratetext, $slowc, $fastc,
 319         $slowr, $slowratet, $slowslow, $slowfastt,
 320         $fastr, $fastratet, $fastslowt, $fastfast)
 321         = $got =~ $graph_dissassembly;
 322     my $all_passed
 323       = check_graph_consistency (        $ratetext, $slowc, $fastc,
 324                                  $slowr, $slowratet, $slowslow, $slowfastt,
 325                                  $fastr, $fastratet, $fastslowt, $fastfast);
 326     $all_passed
 327       &= is_deeply ($chart, [['', $ratetext, $slowc, $fastc],
 328                              [$slowr, $slowratet, $slowslow, $slowfastt],
 329                              [$fastr, $fastratet, $fastslowt, $fastfast]],
 330                     "check the chart layout matches the formatted output");
 331     unless ($all_passed) {
 332       print STDERR "# Something went wrong there. I got this chart:\n";
 333       print STDERR "# $_\n" foreach split /\n/, $got;
 334     }
 335 }
 336
 337 sub check_graph {
 338     my ($title, $row1, $row2) = @_;
 339     is (scalar @$title, 4, "Four entries in title row");
 340     is (scalar @$row1, 4, "Four entries in first row");
 341     is (scalar @$row2, 4, "Four entries in second row");
 342     is (shift @$title, '', "First entry of output graph should be ''");
 343     check_graph_consistency (@$title, @$row1, @$row2);
 344 }
 345
 346 {
 347     select(OUT);
 348     my $start = times;
 349     my $chart = cmpthese( -0.1, { a => "++\$i", b => "\$i = sqrt(\$i++)" }, "auto" ) ;
 350     my $end = times;
 351     select(STDOUT);
 352     ok (($end - $start) > 0.05, "benchmarked code ran for over 0.05 seconds");
 353
 354     $got = $out->read();
 355     # Remove any warnings about having too few iterations.
 356     $got =~ s/\(warning:[^\)]+\)//gs;
 357
 358     like ($got, qr/running\W+a\W+b.*?for at least 0\.1 CPU second/s,
 359           'check title');
 360     # Remove the title
 361     $got =~ s/.*\.\.\.//s;
 362     like ($got, $default_pattern, 'should find default format somewhere');
 363     like ($got, $graph_dissassembly, "Should find the output graph somewhere");
 364     check_graph_vs_output ($chart, $got);
 365 }
 366
 367 # Not giving auto should suppress timethese results.
 368 {
 369     select(OUT);
 370     my $start = times;
 371     my $chart = cmpthese( -0.1, { a => "++\$i", b => "\$i = sqrt(\$i++)" } ) ;
 372     my $end = times;
 373     select(STDOUT);
 374     ok (($end - $start) > 0.05, "benchmarked code ran for over 0.05 seconds");
 375
 376     $got = $out->read();
 377     # Remove any warnings about having too few iterations.
 378     $got =~ s/\(warning:[^\)]+\)//gs;
 379
 380     unlike ($got, qr/running\W+a\W+b.*?for at least 0\.1 CPU second/s,
 381           'should not have title');
 382     # Remove the title
 383     $got =~ s/.*\.\.\.//s;
 384     unlike ($got, $default_pattern, 'should not find default format somewhere');
 385     like ($got, $graph_dissassembly, "Should find the output graph somewhere");
 386     check_graph_vs_output ($chart, $got);
 387 }
 388
 389 {
 390     $foo = $bar = 0;
 391     select(OUT);
 392     my $chart = cmpthese( 10, $code_to_test, 'nop' ) ;
 393     select(STDOUT);
 394     ok ($foo > 0, "Foo code was run");
 395     ok ($bar > 0, "Bar code was run");
 396
 397     $got = $out->read();
 398     # Remove any warnings about having too few iterations.
 399     $got =~ s/\(warning:[^\)]+\)//gs;
 400     like ($got, qr/timing 10 iterations of\s+Bar\W+Foo\W*?\.\.\./s,
 401       'check title');
 402     # Remove the title
 403     $got =~ s/.*\.\.\.//s;
 404     like ($got, $nop_pattern, 'specify format as nop');
 405     like ($got, $graph_dissassembly, "Should find the output graph somewhere");
 406     check_graph_vs_output ($chart, $got);
 407 }
 408
 409 {
 410     $foo = $bar = 0;
 411     select(OUT);
 412     my $chart = cmpthese( 10, $code_to_test, 'none' ) ;
 413     select(STDOUT);
 414     ok ($foo > 0, "Foo code was run");
 415     ok ($bar > 0, "Bar code was run");
 416
 417     $got = $out->read();
 418     # Remove any warnings about having too few iterations.
 419     $got =~ s/\(warning:[^\)]+\)//gs;
 420     $got =~ s/^[ \t\n]+//s; # Remove all the whitespace from the beginning
 421     is ($got, '', "format 'none' should suppress output");
 422     is (ref $chart, 'ARRAY', "output should be an array ref");
 423     # Some of these will go bang if the preceding test fails. There will be
 424     # a big clue as to why, from the previous test's diagnostic
 425     is (ref $chart->[0], 'ARRAY', "output should be an array of arrays");
 426     check_graph (@$chart);
 427 }
 428
 429 {
 430     $foo = $bar = 0;
 431     select(OUT);
 432     my $chart = cmpthese( $results ) ;
 433     select(STDOUT);
 434     is ($foo, 0, "Foo code was not run");
 435     is ($bar, 0, "Bar code was not run");
 436
 437     $got = $out->read();
 438     ok ($got !~ /\.\.\./s, 'check that there is no title');
 439     like ($got, $graph_dissassembly, "Should find the output graph somewhere");
 440     check_graph_vs_output ($chart, $got);
 441 }
 442
 443 {
 444     $foo = $bar = 0;
 445     select(OUT);
 446     my $chart = cmpthese( $results, 'none' ) ;
 447     select(STDOUT);
 448     is ($foo, 0, "Foo code was not run");
 449     is ($bar, 0, "Bar code was not run");
 450
 451     $got = $out->read();
 452     is ($got, '', "'none' should suppress all output");
 453     is (ref $chart, 'ARRAY', "output should be an array ref");
 454     # Some of these will go bang if the preceding test fails. There will be
 455     # a big clue as to why, from the previous test's diagnostic
 456     is (ref $chart->[0], 'ARRAY', "output should be an array of arrays");
 457     check_graph (@$chart);
 458 }
 459
 460 ###}my $out = tie *OUT, 'TieOut'; my ($got); ###
 461
 462 my $debug = tie *STDERR, 'TieOut';
 463
 464 $bar = 0;
 465 isa_ok(timeit(5, '++$bar'), 'Benchmark', "timeit eval");
 466 is ($bar, 5, "benchmarked code was run 5 times");
 467 is ($debug->read(), '', "There was no debug output");
 468
 469 Benchmark->debug(1);
 470
 471 $bar = 0;
 472 select(OUT);
 473 $got = timeit(5, '++$bar');
 474 select(STDOUT);
 475 isa_ok($got, 'Benchmark', "timeit eval");
 476 is ($bar, 5, "benchmarked code was run 5 times");
 477 is ($out->read(), '', "There was no STDOUT output with debug enabled");
 478 isnt ($debug->read(), '', "There was STDERR debug output with debug enabled");
 479
 480 Benchmark->debug(0);
 481
 482 $bar = 0;
 483 isa_ok(timeit(5, '++$bar'), 'Benchmark', "timeit eval");
 484 is ($bar, 5, "benchmarked code was run 5 times");
 485 is ($debug->read(), '', "There was no debug output debug disabled");
 486
 487 undef $debug;
 488 untie *STDERR;
 489
 490 # To check the cache we are poking where we don't belong, inside the namespace.
 491 # The way benchmark is written We can't actually check whehter the cache is
 492 # being used, merely what's become cached.
 493
 494 clearallcache();
 495 my @before_keys = keys %Benchmark::cache;
 496 $bar = 0;
 497 isa_ok(timeit(5, '++$bar'), 'Benchmark', "timeit eval");
 498 is ($bar, 5, "benchmarked code was run 5 times");
 499 my @after5_keys = keys %Benchmark::cache;
 500 $bar = 0;
 501 isa_ok(timeit(10, '++$bar'), 'Benchmark', "timeit eval");
 502 is ($bar, 10, "benchmarked code was run 10 times");
 503 ok (!eq_array ([keys %Benchmark::cache], \@after5_keys), "10 differs from 5");
 504
 505 clearcache(10);
 506 # Hash key order will be the same if there are the same keys.
 507 is_deeply ([keys %Benchmark::cache], \@after5_keys,
 508            "cleared 10, only cached results for 5 should remain");
 509
 510 clearallcache();
 511 is_deeply ([keys %Benchmark::cache], \@before_keys,
 512            "back to square 1 when we clear the cache again?");
 513
 514
 515 package TieOut;
 516
 517 sub TIEHANDLE {
 518     my $class = shift;
 519     bless(\( my $ref = ''), $class);
 520 }
 521
 522 sub PRINT {
 523     my $self = shift;
 524     $$self .= join('', @_);
 525 }
 526
 527 sub PRINTF {
 528     my $self = shift;
 529     $$self .= sprintf shift, @_;
 530 }
 531
 532 sub read {
 533     my $self = shift;
 534     return substr($$self, 0, length($$self), '');
 535 }