This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Do better locale collation in UTF-8 locales
[perl5.git] / pod / perllocale.pod
1 =encoding utf8
2
3 =head1 NAME
4
5 perllocale - Perl locale handling (internationalization and localization)
6
7 =head1 DESCRIPTION
8
9 In the beginning there was ASCII, the "American Standard Code for
10 Information Interchange", which works quite well for Americans with
11 their English alphabet and dollar-denominated currency.  But it doesn't
12 work so well even for other English speakers, who may use different
13 currencies, such as the pound sterling (as the symbol for that currency
14 is not in ASCII); and it's hopelessly inadequate for many of the
15 thousands of the world's other languages.
16
17 To address these deficiencies, the concept of locales was invented
18 (formally the ISO C, XPG4, POSIX 1.c "locale system").  And applications
19 were and are being written that use the locale mechanism.  The process of
20 making such an application take account of its users' preferences in
21 these kinds of matters is called B<internationalization> (often
22 abbreviated as B<i18n>); telling such an application about a particular
23 set of preferences is known as B<localization> (B<l10n>).
24
25 Perl has been extended to support the locale system.  This
26 is controlled per application by using one pragma, one function call,
27 and several environment variables.
28
29 Unfortunately, there are quite a few deficiencies with the design (and
30 often, the implementations) of locales.  Unicode was invented (see
31 L<perlunitut> for an introduction to that) in part to address these
32 design deficiencies, and nowadays, there is a series of "UTF-8
33 locales", based on Unicode.  These are locales whose character set is
34 Unicode, encoded in UTF-8.  Starting in v5.20, Perl fully supports
35 UTF-8 locales, except for sorting and string comparisons like C<lt> and
36 C<ge>.  Starting in v5.26, Perl can handle these reasonably as well,
37 depending on the platform's implementation.  However, for earlier
38 releases or for better control, use L<Unicode::Collate> .  Perl continues to
39 support the old non UTF-8 locales as well.  There are currently no UTF-8
40 locales for EBCDIC platforms.
41
42 (Unicode is also creating C<CLDR>, the "Common Locale Data Repository",
43 L<http://cldr.unicode.org/> which includes more types of information than
44 are available in the POSIX locale system.  At the time of this writing,
45 there was no CPAN module that provides access to this XML-encoded data.
46 However, it is possible to compute the POSIX locale data from them, and
47 earlier CLDR versions had these already extracted for you as UTF-8 locales
48 L<http://unicode.org/Public/cldr/2.0.1/>.)
49
50 =head1 WHAT IS A LOCALE
51
52 A locale is a set of data that describes various aspects of how various
53 communities in the world categorize their world.  These categories are
54 broken down into the following types (some of which include a brief
55 note here):
56
57 =over
58
59 =item Category C<LC_NUMERIC>: Numeric formatting
60
61 This indicates how numbers should be formatted for human readability,
62 for example the character used as the decimal point.
63
64 =item Category C<LC_MONETARY>: Formatting of monetary amounts
65
66 =for comment
67 The nbsp below makes this look better (though not great)
68
69 E<160>
70
71 =item Category C<LC_TIME>: Date/Time formatting
72
73 =for comment
74 The nbsp below makes this look better (though not great)
75
76 E<160>
77
78 =item Category C<LC_MESSAGES>: Error and other messages
79
80 This is used by Perl itself only for accessing operating system error
81 messages via L<$!|perlvar/$ERRNO> and L<$^E|perlvar/$EXTENDED_OS_ERROR>.
82
83 =item Category C<LC_COLLATE>: Collation
84
85 This indicates the ordering of letters for comparison and sorting.
86 In Latin alphabets, for example, "b", generally follows "a".
87
88 =item Category C<LC_CTYPE>: Character Types
89
90 This indicates, for example if a character is an uppercase letter.
91
92 =item Other categories
93
94 Some platforms have other categories, dealing with such things as
95 measurement units and paper sizes.  None of these are used directly by
96 Perl, but outside operations that Perl interacts with may use
97 these.  See L</Not within the scope of "use locale"> below.
98
99 =back
100
101 More details on the categories used by Perl are given below in L</LOCALE
102 CATEGORIES>.
103
104 Together, these categories go a long way towards being able to customize
105 a single program to run in many different locations.  But there are
106 deficiencies, so keep reading.
107
108 =head1 PREPARING TO USE LOCALES
109
110 Perl itself (outside the L<POSIX> module) will not use locales unless
111 specifically requested to (but
112 again note that Perl may interact with code that does use them).  Even
113 if there is such a request, B<all> of the following must be true
114 for it to work properly:
115
116 =over 4
117
118 =item *
119
120 B<Your operating system must support the locale system>.  If it does,
121 you should find that the C<setlocale()> function is a documented part of
122 its C library.
123
124 =item *
125
126 B<Definitions for locales that you use must be installed>.  You, or
127 your system administrator, must make sure that this is the case. The
128 available locales, the location in which they are kept, and the manner
129 in which they are installed all vary from system to system.  Some systems
130 provide only a few, hard-wired locales and do not allow more to be
131 added.  Others allow you to add "canned" locales provided by the system
132 supplier.  Still others allow you or the system administrator to define
133 and add arbitrary locales.  (You may have to ask your supplier to
134 provide canned locales that are not delivered with your operating
135 system.)  Read your system documentation for further illumination.
136
137 =item *
138
139 B<Perl must believe that the locale system is supported>.  If it does,
140 C<perl -V:d_setlocale> will say that the value for C<d_setlocale> is
141 C<define>.
142
143 =back
144
145 If you want a Perl application to process and present your data
146 according to a particular locale, the application code should include
147 the S<C<use locale>> pragma (see L<The "use locale" pragma>) where
148 appropriate, and B<at least one> of the following must be true:
149
150 =over 4
151
152 =item 1
153
154 B<The locale-determining environment variables (see L</"ENVIRONMENT">)
155 must be correctly set up> at the time the application is started, either
156 by yourself or by whomever set up your system account; or
157
158 =item 2
159
160 B<The application must set its own locale> using the method described in
161 L<The setlocale function>.
162
163 =back
164
165 =head1 USING LOCALES
166
167 =head2 The C<"use locale"> pragma
168
169 WARNING!  Do NOT use this pragma in scripts that have multiple
170 L<threads|threads> active.  The locale is not local to a single thread.
171 Another thread may change the locale at any time, which could cause at a
172 minimum that a given thread is operating in a locale it isn't expecting
173 to be in.  On some platforms, segfaults can also occur.  The locale
174 change need not be explicit; some operations cause perl to change the
175 locale itself.  You are vulnerable simply by having done a C<"use
176 locale">.
177
178 By default, Perl itself (outside the L<POSIX> module)
179 ignores the current locale.  The S<C<use locale>>
180 pragma tells Perl to use the current locale for some operations.
181 Starting in v5.16, there are optional parameters to this pragma,
182 described below, which restrict which operations are affected by it.
183
184 The current locale is set at execution time by
185 L<setlocale()|/The setlocale function> described below.  If that function
186 hasn't yet been called in the course of the program's execution, the
187 current locale is that which was determined by the L</"ENVIRONMENT"> in
188 effect at the start of the program.
189 If there is no valid environment, the current locale is whatever the
190 system default has been set to.   On POSIX systems, it is likely, but
191 not necessarily, the "C" locale.  On Windows, the default is set via the
192 computer's S<C<Control Panel-E<gt>Regional and Language Options>> (or its
193 current equivalent).
194
195 The operations that are affected by locale are:
196
197 =over 4
198
199 =item B<Not within the scope of C<"use locale">>
200
201 Only certain operations originating outside Perl should be affected, as
202 follows:
203
204 =over 4
205
206 =item *
207
208 The current locale is used when going outside of Perl with
209 operations like L<system()|perlfunc/system LIST> or
210 L<qxE<sol>E<sol>|perlop/qxE<sol>STRINGE<sol>>, if those operations are
211 locale-sensitive.
212
213 =item *
214
215 Also Perl gives access to various C library functions through the
216 L<POSIX> module.  Some of those functions are always affected by the
217 current locale.  For example, C<POSIX::strftime()> uses C<LC_TIME>;
218 C<POSIX::strtod()> uses C<LC_NUMERIC>; C<POSIX::strcoll()> and
219 C<POSIX::strxfrm()> use C<LC_COLLATE>.  All such functions
220 will behave according to the current underlying locale, even if that
221 locale isn't exposed to Perl space.
222
223 =item *
224
225 XS modules for all categories but C<LC_NUMERIC> get the underlying
226 locale, and hence any C library functions they call will use that
227 underlying locale.  For more discussion, see L<perlxs/CAVEATS>.
228
229 =back
230
231 Note that all C programs (including the perl interpreter, which is
232 written in C) always have an underlying locale.  That locale is the "C"
233 locale unless changed by a call to L<setlocale()|/The setlocale
234 function>.  When Perl starts up, it changes the underlying locale to the
235 one which is indicated by the L</ENVIRONMENT>.  When using the L<POSIX>
236 module or writing XS code, it is important to keep in mind that the
237 underlying locale may be something other than "C", even if the program
238 hasn't explicitly changed it.
239
240 =for comment
241 The nbsp below makes this look better (though not great)
242
243 E<160>
244
245 =item B<Lingering effects of C<S<use locale>>>
246
247 Certain Perl operations that are set-up within the scope of a
248 C<use locale> retain that effect even outside the scope.
249 These include:
250
251 =over 4
252
253 =item *
254
255 The output format of a L<write()|perlfunc/write> is determined by an
256 earlier format declaration (L<perlfunc/format>), so whether or not the
257 output is affected by locale is determined by if the C<format()> is
258 within the scope of a C<use locale>, not whether the C<write()>
259 is.
260
261 =item *
262
263 Regular expression patterns can be compiled using
264 L<qrE<sol>E<sol>|perlop/qrE<sol>STRINGE<sol>msixpodualn> with actual
265 matching deferred to later.  Again, it is whether or not the compilation
266 was done within the scope of C<use locale> that determines the match
267 behavior, not if the matches are done within such a scope or not.
268
269 =back
270
271 =for comment
272 The nbsp below makes this look better (though not great)
273
274
275 E<160>
276
277 =item B<Under C<"use locale";>>
278
279 =over 4
280
281 =item *
282
283 All the above operations
284
285 =item *
286
287 B<Format declarations> (L<perlfunc/format>) and hence any subsequent
288 C<write()>s use C<LC_NUMERIC>.
289
290 =item *
291
292 B<stringification and output> use C<LC_NUMERIC>.
293 These include the results of
294 C<print()>,
295 C<printf()>,
296 C<say()>,
297 and
298 C<sprintf()>.
299
300 =item *
301
302 B<The comparison operators> (C<lt>, C<le>, C<cmp>, C<ge>, and C<gt>) use
303 C<LC_COLLATE>.  C<sort()> is also affected if used without an
304 explicit comparison function, because it uses C<cmp> by default.
305
306 B<Note:> C<eq> and C<ne> are unaffected by locale: they always
307 perform a char-by-char comparison of their scalar operands.  What's
308 more, if C<cmp> finds that its operands are equal according to the
309 collation sequence specified by the current locale, it goes on to
310 perform a char-by-char comparison, and only returns I<0> (equal) if the
311 operands are char-for-char identical.  If you really want to know whether
312 two strings--which C<eq> and C<cmp> may consider different--are equal
313 as far as collation in the locale is concerned, see the discussion in
314 L<Category C<LC_COLLATE>: Collation>.
315
316 =item *
317
318 B<Regular expressions and case-modification functions> (C<uc()>, C<lc()>,
319 C<ucfirst()>, and C<lcfirst()>) use C<LC_CTYPE>
320
321 =item *
322
323 B<The variables L<$!|perlvar/$ERRNO>> (and its synonyms C<$ERRNO> and
324 C<$OS_ERROR>) B<and L<$^E|perlvar/$EXTENDED_OS_ERROR>> (and its synonym
325 C<$EXTENDED_OS_ERROR>) when used as strings use C<LC_MESSAGES>.
326
327 =back
328
329 =back
330
331 The default behavior is restored with the S<C<no locale>> pragma, or
332 upon reaching the end of the block enclosing C<use locale>.
333 Note that C<use locale> calls may be
334 nested, and that what is in effect within an inner scope will revert to
335 the outer scope's rules at the end of the inner scope.
336
337 The string result of any operation that uses locale
338 information is tainted, as it is possible for a locale to be
339 untrustworthy.  See L<"SECURITY">.
340
341 Starting in Perl v5.16 in a very limited way, and more generally in
342 v5.22, you can restrict which category or categories are enabled by this
343 particular instance of the pragma by adding parameters to it.  For
344 example,
345
346  use locale qw(:ctype :numeric);
347
348 enables locale awareness within its scope of only those operations
349 (listed above) that are affected by C<LC_CTYPE> and C<LC_NUMERIC>.
350
351 The possible categories are: C<:collate>, C<:ctype>, C<:messages>,
352 C<:monetary>, C<:numeric>, C<:time>, and the pseudo category
353 C<:characters> (described below).
354
355 Thus you can say
356
357  use locale ':messages';
358
359 and only L<$!|perlvar/$ERRNO> and L<$^E|perlvar/$EXTENDED_OS_ERROR>
360 will be locale aware.  Everything else is unaffected.
361
362 Since Perl doesn't currently do anything with the C<LC_MONETARY>
363 category, specifying C<:monetary> does effectively nothing.  Some
364 systems have other categories, such as C<LC_PAPER_SIZE>, but Perl
365 also doesn't know anything about them, and there is no way to specify
366 them in this pragma's arguments.
367
368 You can also easily say to use all categories but one, by either, for
369 example,
370
371  use locale ':!ctype';
372  use locale ':not_ctype';
373
374 both of which mean to enable locale awarness of all categories but
375 C<LC_CTYPE>.  Only one category argument may be specified in a
376 S<C<use locale>> if it is of the negated form.
377
378 Prior to v5.22 only one form of the pragma with arguments is available:
379
380  use locale ':not_characters';
381
382 (and you have to say C<not_>; you can't use the bang C<!> form).  This
383 pseudo category is a shorthand for specifying both C<:collate> and
384 C<:ctype>.  Hence, in the negated form, it is nearly the same thing as
385 saying
386
387  use locale qw(:messages :monetary :numeric :time);
388
389 We use the term "nearly", because C<:not_characters> also turns on
390 S<C<use feature 'unicode_strings'>> within its scope.  This form is
391 less useful in v5.20 and later, and is described fully in
392 L</Unicode and UTF-8>, but briefly, it tells Perl to not use the
393 character portions of the locale definition, that is the C<LC_CTYPE> and
394 C<LC_COLLATE> categories.  Instead it will use the native character set
395 (extended by Unicode).  When using this parameter, you are responsible
396 for getting the external character set translated into the
397 native/Unicode one (which it already will be if it is one of the
398 increasingly popular UTF-8 locales).  There are convenient ways of doing
399 this, as described in L</Unicode and UTF-8>.
400
401 =head2 The setlocale function
402
403 WARNING!  Do NOT use this function in a L<thread|threads>.  The locale
404 will change in all other threads at the same time, and should your
405 thread get paused by the operating system, and another started, that
406 thread will not have the locale it is expecting.  On some platforms,
407 there can be a race leading to segfaults if two threads call this
408 function nearly simultaneously.
409
410 You can switch locales as often as you wish at run time with the
411 C<POSIX::setlocale()> function:
412
413         # Import locale-handling tool set from POSIX module.
414         # This example uses: setlocale -- the function call
415         #                    LC_CTYPE -- explained below
416         # (Showing the testing for success/failure of operations is
417         # omitted in these examples to avoid distracting from the main
418         # point)
419
420         use POSIX qw(locale_h);
421         use locale;
422         my $old_locale;
423
424         # query and save the old locale
425         $old_locale = setlocale(LC_CTYPE);
426
427         setlocale(LC_CTYPE, "fr_CA.ISO8859-1");
428         # LC_CTYPE now in locale "French, Canada, codeset ISO 8859-1"
429
430         setlocale(LC_CTYPE, "");
431         # LC_CTYPE now reset to the default defined by the
432         # LC_ALL/LC_CTYPE/LANG environment variables, or to the system
433         # default.  See below for documentation.
434
435         # restore the old locale
436         setlocale(LC_CTYPE, $old_locale);
437
438 The first argument of C<setlocale()> gives the B<category>, the second the
439 B<locale>.  The category tells in what aspect of data processing you
440 want to apply locale-specific rules.  Category names are discussed in
441 L</LOCALE CATEGORIES> and L</"ENVIRONMENT">.  The locale is the name of a
442 collection of customization information corresponding to a particular
443 combination of language, country or territory, and codeset.  Read on for
444 hints on the naming of locales: not all systems name locales as in the
445 example.
446
447 If no second argument is provided and the category is something other
448 than C<LC_ALL>, the function returns a string naming the current locale
449 for the category.  You can use this value as the second argument in a
450 subsequent call to C<setlocale()>, B<but> on some platforms the string
451 is opaque, not something that most people would be able to decipher as
452 to what locale it means.
453
454 If no second argument is provided and the category is C<LC_ALL>, the
455 result is implementation-dependent.  It may be a string of
456 concatenated locale names (separator also implementation-dependent)
457 or a single locale name.  Please consult your L<setlocale(3)> man page for
458 details.
459
460 If a second argument is given and it corresponds to a valid locale,
461 the locale for the category is set to that value, and the function
462 returns the now-current locale value.  You can then use this in yet
463 another call to C<setlocale()>.  (In some implementations, the return
464 value may sometimes differ from the value you gave as the second
465 argument--think of it as an alias for the value you gave.)
466
467 As the example shows, if the second argument is an empty string, the
468 category's locale is returned to the default specified by the
469 corresponding environment variables.  Generally, this results in a
470 return to the default that was in force when Perl started up: changes
471 to the environment made by the application after startup may or may not
472 be noticed, depending on your system's C library.
473
474 Note that when a form of C<use locale> that doesn't include all
475 categories is specified, Perl ignores the excluded categories.
476
477 If C<set_locale()> fails for some reason (for example, an attempt to set
478 to a locale unknown to the system), the locale for the category is not
479 changed, and the function returns C<undef>.
480
481
482 For further information about the categories, consult L<setlocale(3)>.
483
484 =head2 Finding locales
485
486 For locales available in your system, consult also L<setlocale(3)> to
487 see whether it leads to the list of available locales (search for the
488 I<SEE ALSO> section).  If that fails, try the following command lines:
489
490         locale -a
491
492         nlsinfo
493
494         ls /usr/lib/nls/loc
495
496         ls /usr/lib/locale
497
498         ls /usr/lib/nls
499
500         ls /usr/share/locale
501
502 and see whether they list something resembling these
503
504         en_US.ISO8859-1     de_DE.ISO8859-1     ru_RU.ISO8859-5
505         en_US.iso88591      de_DE.iso88591      ru_RU.iso88595
506         en_US               de_DE               ru_RU
507         en                  de                  ru
508         english             german              russian
509         english.iso88591    german.iso88591     russian.iso88595
510         english.roman8                          russian.koi8r
511
512 Sadly, even though the calling interface for C<setlocale()> has been
513 standardized, names of locales and the directories where the
514 configuration resides have not been.  The basic form of the name is
515 I<language_territory>B<.>I<codeset>, but the latter parts after
516 I<language> are not always present.  The I<language> and I<country>
517 are usually from the standards B<ISO 3166> and B<ISO 639>, the
518 two-letter abbreviations for the countries and the languages of the
519 world, respectively.  The I<codeset> part often mentions some B<ISO
520 8859> character set, the Latin codesets.  For example, C<ISO 8859-1>
521 is the so-called "Western European codeset" that can be used to encode
522 most Western European languages adequately.  Again, there are several
523 ways to write even the name of that one standard.  Lamentably.
524
525 Two special locales are worth particular mention: "C" and "POSIX".
526 Currently these are effectively the same locale: the difference is
527 mainly that the first one is defined by the C standard, the second by
528 the POSIX standard.  They define the B<default locale> in which
529 every program starts in the absence of locale information in its
530 environment.  (The I<default> default locale, if you will.)  Its language
531 is (American) English and its character codeset ASCII or, rarely, a
532 superset thereof (such as the "DEC Multinational Character Set
533 (DEC-MCS)").  B<Warning>. The C locale delivered by some vendors
534 may not actually exactly match what the C standard calls for.  So
535 beware.
536
537 B<NOTE>: Not all systems have the "POSIX" locale (not all systems are
538 POSIX-conformant), so use "C" when you need explicitly to specify this
539 default locale.
540
541 =head2 LOCALE PROBLEMS
542
543 You may encounter the following warning message at Perl startup:
544
545         perl: warning: Setting locale failed.
546         perl: warning: Please check that your locale settings:
547                 LC_ALL = "En_US",
548                 LANG = (unset)
549             are supported and installed on your system.
550         perl: warning: Falling back to the standard locale ("C").
551
552 This means that your locale settings had C<LC_ALL> set to "En_US" and
553 LANG exists but has no value.  Perl tried to believe you but could not.
554 Instead, Perl gave up and fell back to the "C" locale, the default locale
555 that is supposed to work no matter what.  (On Windows, it first tries
556 falling back to the system default locale.)  This usually means your
557 locale settings were wrong, they mention locales your system has never
558 heard of, or the locale installation in your system has problems (for
559 example, some system files are broken or missing).  There are quick and
560 temporary fixes to these problems, as well as more thorough and lasting
561 fixes.
562
563 =head2 Testing for broken locales
564
565 If you are building Perl from source, the Perl test suite file
566 F<lib/locale.t> can be used to test the locales on your system.
567 Setting the environment variable C<PERL_DEBUG_FULL_TEST> to 1
568 will cause it to output detailed results.  For example, on Linux, you
569 could say
570
571  PERL_DEBUG_FULL_TEST=1 ./perl -T -Ilib lib/locale.t > locale.log 2>&1
572
573 Besides many other tests, it will test every locale it finds on your
574 system to see if they conform to the POSIX standard.  If any have
575 errors, it will include a summary near the end of the output of which
576 locales passed all its tests, and which failed, and why.
577
578 =head2 Temporarily fixing locale problems
579
580 The two quickest fixes are either to render Perl silent about any
581 locale inconsistencies or to run Perl under the default locale "C".
582
583 Perl's moaning about locale problems can be silenced by setting the
584 environment variable C<PERL_BADLANG> to "0" or "".
585 This method really just sweeps the problem under the carpet: you tell
586 Perl to shut up even when Perl sees that something is wrong.  Do not
587 be surprised if later something locale-dependent misbehaves.
588
589 Perl can be run under the "C" locale by setting the environment
590 variable C<LC_ALL> to "C".  This method is perhaps a bit more civilized
591 than the C<PERL_BADLANG> approach, but setting C<LC_ALL> (or
592 other locale variables) may affect other programs as well, not just
593 Perl.  In particular, external programs run from within Perl will see
594 these changes.  If you make the new settings permanent (read on), all
595 programs you run see the changes.  See L<"ENVIRONMENT"> for
596 the full list of relevant environment variables and L<USING LOCALES>
597 for their effects in Perl.  Effects in other programs are
598 easily deducible.  For example, the variable C<LC_COLLATE> may well affect
599 your B<sort> program (or whatever the program that arranges "records"
600 alphabetically in your system is called).
601
602 You can test out changing these variables temporarily, and if the
603 new settings seem to help, put those settings into your shell startup
604 files.  Consult your local documentation for the exact details.  For
605 Bourne-like shells (B<sh>, B<ksh>, B<bash>, B<zsh>):
606
607         LC_ALL=en_US.ISO8859-1
608         export LC_ALL
609
610 This assumes that we saw the locale "en_US.ISO8859-1" using the commands
611 discussed above.  We decided to try that instead of the above faulty
612 locale "En_US"--and in Cshish shells (B<csh>, B<tcsh>)
613
614         setenv LC_ALL en_US.ISO8859-1
615
616 or if you have the "env" application you can do (in any shell)
617
618         env LC_ALL=en_US.ISO8859-1 perl ...
619
620 If you do not know what shell you have, consult your local
621 helpdesk or the equivalent.
622
623 =head2 Permanently fixing locale problems
624
625 The slower but superior fixes are when you may be able to yourself
626 fix the misconfiguration of your own environment variables.  The
627 mis(sing)configuration of the whole system's locales usually requires
628 the help of your friendly system administrator.
629
630 First, see earlier in this document about L<Finding locales>.  That tells
631 how to find which locales are really supported--and more importantly,
632 installed--on your system.  In our example error message, environment
633 variables affecting the locale are listed in the order of decreasing
634 importance (and unset variables do not matter).  Therefore, having
635 LC_ALL set to "En_US" must have been the bad choice, as shown by the
636 error message.  First try fixing locale settings listed first.
637
638 Second, if using the listed commands you see something B<exactly>
639 (prefix matches do not count and case usually counts) like "En_US"
640 without the quotes, then you should be okay because you are using a
641 locale name that should be installed and available in your system.
642 In this case, see L<Permanently fixing your system's locale configuration>.
643
644 =head2 Permanently fixing your system's locale configuration
645
646 This is when you see something like:
647
648         perl: warning: Please check that your locale settings:
649                 LC_ALL = "En_US",
650                 LANG = (unset)
651             are supported and installed on your system.
652
653 but then cannot see that "En_US" listed by the above-mentioned
654 commands.  You may see things like "en_US.ISO8859-1", but that isn't
655 the same.  In this case, try running under a locale
656 that you can list and which somehow matches what you tried.  The
657 rules for matching locale names are a bit vague because
658 standardization is weak in this area.  See again the
659 L<Finding locales> about general rules.
660
661 =head2 Fixing system locale configuration
662
663 Contact a system administrator (preferably your own) and report the exact
664 error message you get, and ask them to read this same documentation you
665 are now reading.  They should be able to check whether there is something
666 wrong with the locale configuration of the system.  The L<Finding locales>
667 section is unfortunately a bit vague about the exact commands and places
668 because these things are not that standardized.
669
670 =head2 The localeconv function
671
672 The C<POSIX::localeconv()> function allows you to get particulars of the
673 locale-dependent numeric formatting information specified by the current
674 underlying C<LC_NUMERIC> and C<LC_MONETARY> locales (regardless of
675 whether called from within the scope of C<S<use locale>> or not).  (If
676 you just want the name of
677 the current locale for a particular category, use C<POSIX::setlocale()>
678 with a single parameter--see L<The setlocale function>.)
679
680         use POSIX qw(locale_h);
681
682         # Get a reference to a hash of locale-dependent info
683         $locale_values = localeconv();
684
685         # Output sorted list of the values
686         for (sort keys %$locale_values) {
687             printf "%-20s = %s\n", $_, $locale_values->{$_}
688         }
689
690 C<localeconv()> takes no arguments, and returns B<a reference to> a hash.
691 The keys of this hash are variable names for formatting, such as
692 C<decimal_point> and C<thousands_sep>.  The values are the
693 corresponding, er, values.  See L<POSIX/localeconv> for a longer
694 example listing the categories an implementation might be expected to
695 provide; some provide more and others fewer.  You don't need an
696 explicit C<use locale>, because C<localeconv()> always observes the
697 current locale.
698
699 Here's a simple-minded example program that rewrites its command-line
700 parameters as integers correctly formatted in the current locale:
701
702     use POSIX qw(locale_h);
703
704     # Get some of locale's numeric formatting parameters
705     my ($thousands_sep, $grouping) =
706             @{localeconv()}{'thousands_sep', 'grouping'};
707
708     # Apply defaults if values are missing
709     $thousands_sep = ',' unless $thousands_sep;
710
711     # grouping and mon_grouping are packed lists
712     # of small integers (characters) telling the
713     # grouping (thousand_seps and mon_thousand_seps
714     # being the group dividers) of numbers and
715     # monetary quantities.  The integers' meanings:
716     # 255 means no more grouping, 0 means repeat
717     # the previous grouping, 1-254 means use that
718     # as the current grouping.  Grouping goes from
719     # right to left (low to high digits).  In the
720     # below we cheat slightly by never using anything
721     # else than the first grouping (whatever that is).
722     if ($grouping) {
723         @grouping = unpack("C*", $grouping);
724     } else {
725         @grouping = (3);
726     }
727
728     # Format command line params for current locale
729     for (@ARGV) {
730         $_ = int;    # Chop non-integer part
731         1 while
732         s/(\d)(\d{$grouping[0]}($|$thousands_sep))/$1$thousands_sep$2/;
733         print "$_";
734     }
735     print "\n";
736
737 Note that if the platform doesn't have C<LC_NUMERIC> and/or
738 C<LC_MONETARY> available or enabled, the corresponding elements of the
739 hash will be missing.
740
741 =head2 I18N::Langinfo
742
743 Another interface for querying locale-dependent information is the
744 C<I18N::Langinfo::langinfo()> function, available at least in Unix-like
745 systems and VMS.
746
747 The following example will import the C<langinfo()> function itself and
748 three constants to be used as arguments to C<langinfo()>: a constant for
749 the abbreviated first day of the week (the numbering starts from
750 Sunday = 1) and two more constants for the affirmative and negative
751 answers for a yes/no question in the current locale.
752
753     use I18N::Langinfo qw(langinfo ABDAY_1 YESSTR NOSTR);
754
755     my ($abday_1, $yesstr, $nostr)
756                 = map { langinfo } qw(ABDAY_1 YESSTR NOSTR);
757
758     print "$abday_1? [$yesstr/$nostr] ";
759
760 In other words, in the "C" (or English) locale the above will probably
761 print something like:
762
763     Sun? [yes/no]
764
765 See L<I18N::Langinfo> for more information.
766
767 =head1 LOCALE CATEGORIES
768
769 The following subsections describe basic locale categories.  Beyond these,
770 some combination categories allow manipulation of more than one
771 basic category at a time.  See L<"ENVIRONMENT"> for a discussion of these.
772
773 =head2 Category C<LC_COLLATE>: Collation: Text Comparisons and Sorting
774
775 In the scope of a S<C<use locale>> form that includes collation, Perl
776 looks to the C<LC_COLLATE>
777 environment variable to determine the application's notions on collation
778 (ordering) of characters.  For example, "b" follows "a" in Latin
779 alphabets, but where do "E<aacute>" and "E<aring>" belong?  And while
780 "color" follows "chocolate" in English, what about in traditional Spanish?
781
782 The following collations all make sense and you may meet any of them
783 if you C<"use locale">.
784
785         A B C D E a b c d e
786         A a B b C c D d E e
787         a A b B c C d D e E
788         a b c d e A B C D E
789
790 Here is a code snippet to tell what "word"
791 characters are in the current locale, in that locale's order:
792
793         use locale;
794         print +(sort grep /\w/, map { chr } 0..255), "\n";
795
796 Compare this with the characters that you see and their order if you
797 state explicitly that the locale should be ignored:
798
799         no locale;
800         print +(sort grep /\w/, map { chr } 0..255), "\n";
801
802 This machine-native collation (which is what you get unless S<C<use
803 locale>> has appeared earlier in the same block) must be used for
804 sorting raw binary data, whereas the locale-dependent collation of the
805 first example is useful for natural text.
806
807 As noted in L<USING LOCALES>, C<cmp> compares according to the current
808 collation locale when C<use locale> is in effect, but falls back to a
809 char-by-char comparison for strings that the locale says are equal. You
810 can use C<POSIX::strcoll()> if you don't want this fall-back:
811
812         use POSIX qw(strcoll);
813         $equal_in_locale =
814             !strcoll("space and case ignored", "SpaceAndCaseIgnored");
815
816 C<$equal_in_locale> will be true if the collation locale specifies a
817 dictionary-like ordering that ignores space characters completely and
818 which folds case.
819
820 Perl uses the platform's C library collation functions C<strcoll()> and
821 C<strxfrm()>.  That means you get whatever they give.  On some
822 platforms, these functions work well on UTF-8 locales, giving
823 a reasonable default collation for the code points that are important in
824 that locale.  (And if they aren't working well, the problem may only be
825 that the locale definition is deficient, so can be fixed by using a
826 better definition file.  Unicode's definitions (see L</Freely available
827 locale definitions>) provide reasonable UTF-8 locale collation
828 definitions.)  Starting in Perl v5.26, Perl's use of these functions has
829 been made more seamless.  This may be sufficient for your needs.  For
830 more control, and to make sure strings containing any code point (not
831 just the ones important in the locale) collate properly, the
832 L<Unicode::Collate> module is suggested.
833
834 In non-UTF-8 locales (hence single byte), code points above 0xFF are
835 technically invalid.  But if present, again starting in v5.26, they will
836 collate to the same position as the highest valid code point does.  This
837 generally gives good results, but the collation order may be skewed if
838 the valid code point gets special treatment when it forms particular
839 sequences with other characters as defined by the locale.
840 When two strings collate identically, the code point order is used as a
841 tie breaker.
842
843 If Perl detects that there are problems with the locale collation order,
844 it reverts to using non-locale collation rules for that locale.
845
846 If Perl detects that there are problems with the locale collation order,
847 it reverts to using non-locale collation rules for that locale.
848
849 If you have a single string that you want to check for "equality in
850 locale" against several others, you might think you could gain a little
851 efficiency by using C<POSIX::strxfrm()> in conjunction with C<eq>:
852
853         use POSIX qw(strxfrm);
854         $xfrm_string = strxfrm("Mixed-case string");
855         print "locale collation ignores spaces\n"
856             if $xfrm_string eq strxfrm("Mixed-casestring");
857         print "locale collation ignores hyphens\n"
858             if $xfrm_string eq strxfrm("Mixedcase string");
859         print "locale collation ignores case\n"
860             if $xfrm_string eq strxfrm("mixed-case string");
861
862 C<strxfrm()> takes a string and maps it into a transformed string for use
863 in char-by-char comparisons against other transformed strings during
864 collation.  "Under the hood", locale-affected Perl comparison operators
865 call C<strxfrm()> for both operands, then do a char-by-char
866 comparison of the transformed strings.  By calling C<strxfrm()> explicitly
867 and using a non locale-affected comparison, the example attempts to save
868 a couple of transformations.  But in fact, it doesn't save anything: Perl
869 magic (see L<perlguts/Magic Variables>) creates the transformed version of a
870 string the first time it's needed in a comparison, then keeps this version around
871 in case it's needed again.  An example rewritten the easy way with
872 C<cmp> runs just about as fast.  It also copes with null characters
873 embedded in strings; if you call C<strxfrm()> directly, it treats the first
874 null it finds as a terminator.  don't expect the transformed strings
875 it produces to be portable across systems--or even from one revision
876 of your operating system to the next.  In short, don't call C<strxfrm()>
877 directly: let Perl do it for you.
878
879 Note: C<use locale> isn't shown in some of these examples because it isn't
880 needed: C<strcoll()> and C<strxfrm()> are POSIX functions
881 which use the standard system-supplied C<libc> functions that
882 always obey the current C<LC_COLLATE> locale.
883
884 =head2 Category C<LC_CTYPE>: Character Types
885
886 In the scope of a S<C<use locale>> form that includes C<LC_CTYPE>, Perl
887 obeys the C<LC_CTYPE> locale
888 setting.  This controls the application's notion of which characters are
889 alphabetic, numeric, punctuation, I<etc>.  This affects Perl's C<\w>
890 regular expression metanotation,
891 which stands for alphanumeric characters--that is, alphabetic,
892 numeric, and the platform's native underscore.
893 (Consult L<perlre> for more information about
894 regular expressions.)  Thanks to C<LC_CTYPE>, depending on your locale
895 setting, characters like "E<aelig>", "E<eth>", "E<szlig>", and
896 "E<oslash>" may be understood as C<\w> characters.
897 It also affects things like C<\s>, C<\D>, and the POSIX character
898 classes, like C<[[:graph:]]>.  (See L<perlrecharclass> for more
899 information on all these.)
900
901 The C<LC_CTYPE> locale also provides the map used in transliterating
902 characters between lower and uppercase.  This affects the case-mapping
903 functions--C<fc()>, C<lc()>, C<lcfirst()>, C<uc()>, and C<ucfirst()>;
904 case-mapping
905 interpolation with C<\F>, C<\l>, C<\L>, C<\u>, or C<\U> in double-quoted
906 strings and C<s///> substitutions; and case-independent regular expression
907 pattern matching using the C<i> modifier.
908
909 Starting in v5.20, Perl supports UTF-8 locales for C<LC_CTYPE>, but
910 otherwise Perl only supports single-byte locales, such as the ISO 8859
911 series.  This means that wide character locales, for example for Asian
912 languages, are not well-supported.  (If the platform has the capability
913 for Perl to detect such a locale, starting in Perl v5.22,
914 L<Perl will warn, default enabled|warnings/Category Hierarchy>,
915 using the C<locale> warning category, whenever such a locale is switched
916 into.)  The UTF-8 locale support is actually a
917 superset of POSIX locales, because it is really full Unicode behavior
918 as if no C<LC_CTYPE> locale were in effect at all (except for tainting;
919 see L</SECURITY>).  POSIX locales, even UTF-8 ones,
920 are lacking certain concepts in Unicode, such as the idea that changing
921 the case of a character could expand to be more than one character.
922 Perl in a UTF-8 locale, will give you that expansion.  Prior to v5.20,
923 Perl treated a UTF-8 locale on some platforms like an ISO 8859-1 one,
924 with some restrictions, and on other platforms more like the "C" locale.
925 For releases v5.16 and v5.18, C<S<use locale 'not_characters>> could be
926 used as a workaround for this (see L</Unicode and UTF-8>).
927
928 Note that there are quite a few things that are unaffected by the
929 current locale.  Any literal character is the native character for the
930 given platform.  Hence 'A' means the character at code point 65 on ASCII
931 platforms, and 193 on EBCDIC.  That may or may not be an 'A' in the
932 current locale, if that locale even has an 'A'.
933 Similarly, all the escape sequences for particular characters,
934 C<\n> for example, always mean the platform's native one.  This means,
935 for example, that C<\N> in regular expressions (every character
936 but new-line) works on the platform character set.
937
938 Starting in v5.22, Perl will by default warn when switching into a
939 locale that redefines any ASCII printable character (plus C<\t> and
940 C<\n>) into a different class than expected.  This is likely to
941 happen on modern locales only on EBCDIC platforms, where, for example,
942 a CCSID 0037 locale on a CCSID 1047 machine moves C<"[">, but it can
943 happen on ASCII platforms with the ISO 646 and other
944 7-bit locales that are essentially obsolete.  Things may still work,
945 depending on what features of Perl are used by the program.  For
946 example, in the example from above where C<"|"> becomes a C<\w>, and
947 there are no regular expressions where this matters, the program may
948 still work properly.  The warning lists all the characters that
949 it can determine could be adversely affected.
950
951 B<Note:> A broken or malicious C<LC_CTYPE> locale definition may result
952 in clearly ineligible characters being considered to be alphanumeric by
953 your application.  For strict matching of (mundane) ASCII letters and
954 digits--for example, in command strings--locale-aware applications
955 should use C<\w> with the C</a> regular expression modifier.  See L<"SECURITY">.
956
957 =head2 Category C<LC_NUMERIC>: Numeric Formatting
958
959 After a proper C<POSIX::setlocale()> call, and within the scope of
960 of a C<use locale> form that includes numerics, Perl obeys the
961 C<LC_NUMERIC> locale information, which controls an application's idea
962 of how numbers should be formatted for human readability.
963 In most implementations the only effect is to
964 change the character used for the decimal point--perhaps from "."  to ",".
965 The functions aren't aware of such niceties as thousands separation and
966 so on. (See L<The localeconv function> if you care about these things.)
967
968  use POSIX qw(strtod setlocale LC_NUMERIC);
969  use locale;
970
971  setlocale LC_NUMERIC, "";
972
973  $n = 5/2;   # Assign numeric 2.5 to $n
974
975  $a = " $n"; # Locale-dependent conversion to string
976
977  print "half five is $n\n";       # Locale-dependent output
978
979  printf "half five is %g\n", $n;  # Locale-dependent output
980
981  print "DECIMAL POINT IS COMMA\n"
982           if $n == (strtod("2,5"))[0]; # Locale-dependent conversion
983
984 See also L<I18N::Langinfo> and C<RADIXCHAR>.
985
986 =head2 Category C<LC_MONETARY>: Formatting of monetary amounts
987
988 The C standard defines the C<LC_MONETARY> category, but not a function
989 that is affected by its contents.  (Those with experience of standards
990 committees will recognize that the working group decided to punt on the
991 issue.)  Consequently, Perl essentially takes no notice of it.  If you
992 really want to use C<LC_MONETARY>, you can query its contents--see
993 L<The localeconv function>--and use the information that it returns in your
994 application's own formatting of currency amounts.  However, you may well
995 find that the information, voluminous and complex though it may be, still
996 does not quite meet your requirements: currency formatting is a hard nut
997 to crack.
998
999 See also L<I18N::Langinfo> and C<CRNCYSTR>.
1000
1001 =head2 Category C<LC_TIME>: Respresentation of time
1002
1003 Output produced by C<POSIX::strftime()>, which builds a formatted
1004 human-readable date/time string, is affected by the current C<LC_TIME>
1005 locale.  Thus, in a French locale, the output produced by the C<%B>
1006 format element (full month name) for the first month of the year would
1007 be "janvier".  Here's how to get a list of long month names in the
1008 current locale:
1009
1010         use POSIX qw(strftime);
1011         for (0..11) {
1012             $long_month_name[$_] =
1013                 strftime("%B", 0, 0, 0, 1, $_, 96);
1014         }
1015
1016 Note: C<use locale> isn't needed in this example: C<strftime()> is a POSIX
1017 function which uses the standard system-supplied C<libc> function that
1018 always obeys the current C<LC_TIME> locale.
1019
1020 See also L<I18N::Langinfo> and C<ABDAY_1>..C<ABDAY_7>, C<DAY_1>..C<DAY_7>,
1021 C<ABMON_1>..C<ABMON_12>, and C<ABMON_1>..C<ABMON_12>.
1022
1023 =head2 Other categories
1024
1025 The remaining locale categories are not currently used by Perl itself.
1026 But again note that things Perl interacts with may use these, including
1027 extensions outside the standard Perl distribution, and by the
1028 operating system and its utilities.  Note especially that the string
1029 value of C<$!> and the error messages given by external utilities may
1030 be changed by C<LC_MESSAGES>.  If you want to have portable error
1031 codes, use C<%!>.  See L<Errno>.
1032
1033 =head1 SECURITY
1034
1035 Although the main discussion of Perl security issues can be found in
1036 L<perlsec>, a discussion of Perl's locale handling would be incomplete
1037 if it did not draw your attention to locale-dependent security issues.
1038 Locales--particularly on systems that allow unprivileged users to
1039 build their own locales--are untrustworthy.  A malicious (or just plain
1040 broken) locale can make a locale-aware application give unexpected
1041 results.  Here are a few possibilities:
1042
1043 =over 4
1044
1045 =item *
1046
1047 Regular expression checks for safe file names or mail addresses using
1048 C<\w> may be spoofed by an C<LC_CTYPE> locale that claims that
1049 characters such as C<"E<gt>"> and C<"|"> are alphanumeric.
1050
1051 =item *
1052
1053 String interpolation with case-mapping, as in, say, C<$dest =
1054 "C:\U$name.$ext">, may produce dangerous results if a bogus C<LC_CTYPE>
1055 case-mapping table is in effect.
1056
1057 =item *
1058
1059 A sneaky C<LC_COLLATE> locale could result in the names of students with
1060 "D" grades appearing ahead of those with "A"s.
1061
1062 =item *
1063
1064 An application that takes the trouble to use information in
1065 C<LC_MONETARY> may format debits as if they were credits and vice versa
1066 if that locale has been subverted.  Or it might make payments in US
1067 dollars instead of Hong Kong dollars.
1068
1069 =item *
1070
1071 The date and day names in dates formatted by C<strftime()> could be
1072 manipulated to advantage by a malicious user able to subvert the
1073 C<LC_DATE> locale.  ("Look--it says I wasn't in the building on
1074 Sunday.")
1075
1076 =back
1077
1078 Such dangers are not peculiar to the locale system: any aspect of an
1079 application's environment which may be modified maliciously presents
1080 similar challenges.  Similarly, they are not specific to Perl: any
1081 programming language that allows you to write programs that take
1082 account of their environment exposes you to these issues.
1083
1084 Perl cannot protect you from all possibilities shown in the
1085 examples--there is no substitute for your own vigilance--but, when
1086 C<use locale> is in effect, Perl uses the tainting mechanism (see
1087 L<perlsec>) to mark string results that become locale-dependent, and
1088 which may be untrustworthy in consequence.  Here is a summary of the
1089 tainting behavior of operators and functions that may be affected by
1090 the locale:
1091
1092 =over 4
1093
1094 =item  *
1095
1096 B<Comparison operators> (C<lt>, C<le>, C<ge>, C<gt> and C<cmp>):
1097
1098 Scalar true/false (or less/equal/greater) result is never tainted.
1099
1100 =item  *
1101
1102 B<Case-mapping interpolation> (with C<\l>, C<\L>, C<\u>, C<\U>, or C<\F>)
1103
1104 The result string containing interpolated material is tainted if
1105 a C<use locale> form that includes C<LC_CTYPE> is in effect.
1106
1107 =item  *
1108
1109 B<Matching operator> (C<m//>):
1110
1111 Scalar true/false result never tainted.
1112
1113 All subpatterns, either delivered as a list-context result or as C<$1>
1114 I<etc>., are tainted if a C<use locale> form that includes
1115 C<LC_CTYPE> is in effect, and the subpattern
1116 regular expression contains a locale-dependent construct.  These
1117 constructs include C<\w> (to match an alphanumeric character), C<\W>
1118 (non-alphanumeric character), C<\b> and C<\B> (word-boundary and
1119 non-boundardy, which depend on what C<\w> and C<\W> match), C<\s>
1120 (whitespace character), C<\S> (non whitespace character), C<\d> and
1121 C<\D> (digits and non-digits), and the POSIX character classes, such as
1122 C<[:alpha:]> (see L<perlrecharclass/POSIX Character Classes>).
1123
1124 Tainting is also likely if the pattern is to be matched
1125 case-insensitively (via C</i>).  The exception is if all the code points
1126 to be matched this way are above 255 and do not have folds under Unicode
1127 rules to below 256.  Tainting is not done for these because Perl
1128 only uses Unicode rules for such code points, and those rules are the
1129 same no matter what the current locale.
1130
1131 The matched-pattern variables, C<$&>, C<$`> (pre-match), C<$'>
1132 (post-match), and C<$+> (last match) also are tainted.
1133
1134 =item  *
1135
1136 B<Substitution operator> (C<s///>):
1137
1138 Has the same behavior as the match operator.  Also, the left
1139 operand of C<=~> becomes tainted when a C<use locale>
1140 form that includes C<LC_CTYPE> is in effect, if modified as
1141 a result of a substitution based on a regular
1142 expression match involving any of the things mentioned in the previous
1143 item, or of case-mapping, such as C<\l>, C<\L>,C<\u>, C<\U>, or C<\F>.
1144
1145 =item *
1146
1147 B<Output formatting functions> (C<printf()> and C<write()>):
1148
1149 Results are never tainted because otherwise even output from print,
1150 for example C<print(1/7)>, should be tainted if C<use locale> is in
1151 effect.
1152
1153 =item *
1154
1155 B<Case-mapping functions> (C<lc()>, C<lcfirst()>, C<uc()>, C<ucfirst()>):
1156
1157 Results are tainted if a C<use locale> form that includes C<LC_CTYPE> is
1158 in effect.
1159
1160 =item *
1161
1162 B<POSIX locale-dependent functions> (C<localeconv()>, C<strcoll()>,
1163 C<strftime()>, C<strxfrm()>):
1164
1165 Results are never tainted.
1166
1167 =back
1168
1169 Three examples illustrate locale-dependent tainting.
1170 The first program, which ignores its locale, won't run: a value taken
1171 directly from the command line may not be used to name an output file
1172 when taint checks are enabled.
1173
1174         #/usr/local/bin/perl -T
1175         # Run with taint checking
1176
1177         # Command line sanity check omitted...
1178         $tainted_output_file = shift;
1179
1180         open(F, ">$tainted_output_file")
1181             or warn "Open of $tainted_output_file failed: $!\n";
1182
1183 The program can be made to run by "laundering" the tainted value through
1184 a regular expression: the second example--which still ignores locale
1185 information--runs, creating the file named on its command line
1186 if it can.
1187
1188         #/usr/local/bin/perl -T
1189
1190         $tainted_output_file = shift;
1191         $tainted_output_file =~ m%[\w/]+%;
1192         $untainted_output_file = $&;
1193
1194         open(F, ">$untainted_output_file")
1195             or warn "Open of $untainted_output_file failed: $!\n";
1196
1197 Compare this with a similar but locale-aware program:
1198
1199         #/usr/local/bin/perl -T
1200
1201         $tainted_output_file = shift;
1202         use locale;
1203         $tainted_output_file =~ m%[\w/]+%;
1204         $localized_output_file = $&;
1205
1206         open(F, ">$localized_output_file")
1207             or warn "Open of $localized_output_file failed: $!\n";
1208
1209 This third program fails to run because C<$&> is tainted: it is the result
1210 of a match involving C<\w> while C<use locale> is in effect.
1211
1212 =head1 ENVIRONMENT
1213
1214 =over 12
1215
1216 =item PERL_SKIP_LOCALE_INIT
1217
1218 This environment variable, available starting in Perl v5.20, if set
1219 (to any value), tells Perl to not use the rest of the
1220 environment variables to initialize with.  Instead, Perl uses whatever
1221 the current locale settings are.  This is particularly useful in
1222 embedded environments, see
1223 L<perlembed/Using embedded Perl with POSIX locales>.
1224
1225 =item PERL_BADLANG
1226
1227 A string that can suppress Perl's warning about failed locale settings
1228 at startup.  Failure can occur if the locale support in the operating
1229 system is lacking (broken) in some way--or if you mistyped the name of
1230 a locale when you set up your environment.  If this environment
1231 variable is absent, or has a value other than "0" or "", Perl will
1232 complain about locale setting failures.
1233
1234 B<NOTE>: C<PERL_BADLANG> only gives you a way to hide the warning message.
1235 The message tells about some problem in your system's locale support,
1236 and you should investigate what the problem is.
1237
1238 =back
1239
1240 The following environment variables are not specific to Perl: They are
1241 part of the standardized (ISO C, XPG4, POSIX 1.c) C<setlocale()> method
1242 for controlling an application's opinion on data.  Windows is non-POSIX,
1243 but Perl arranges for the following to work as described anyway.
1244 If the locale given by an environment variable is not valid, Perl tries
1245 the next lower one in priority.  If none are valid, on Windows, the
1246 system default locale is then tried.  If all else fails, the C<"C">
1247 locale is used.  If even that doesn't work, something is badly broken,
1248 but Perl tries to forge ahead with whatever the locale settings might
1249 be.
1250
1251 =over 12
1252
1253 =item C<LC_ALL>
1254
1255 C<LC_ALL> is the "override-all" locale environment variable. If
1256 set, it overrides all the rest of the locale environment variables.
1257
1258 =item C<LANGUAGE>
1259
1260 B<NOTE>: C<LANGUAGE> is a GNU extension, it affects you only if you
1261 are using the GNU libc.  This is the case if you are using e.g. Linux.
1262 If you are using "commercial" Unixes you are most probably I<not>
1263 using GNU libc and you can ignore C<LANGUAGE>.
1264
1265 However, in the case you are using C<LANGUAGE>: it affects the
1266 language of informational, warning, and error messages output by
1267 commands (in other words, it's like C<LC_MESSAGES>) but it has higher
1268 priority than C<LC_ALL>.  Moreover, it's not a single value but
1269 instead a "path" (":"-separated list) of I<languages> (not locales).
1270 See the GNU C<gettext> library documentation for more information.
1271
1272 =item C<LC_CTYPE>
1273
1274 In the absence of C<LC_ALL>, C<LC_CTYPE> chooses the character type
1275 locale.  In the absence of both C<LC_ALL> and C<LC_CTYPE>, C<LANG>
1276 chooses the character type locale.
1277
1278 =item C<LC_COLLATE>
1279
1280 In the absence of C<LC_ALL>, C<LC_COLLATE> chooses the collation
1281 (sorting) locale.  In the absence of both C<LC_ALL> and C<LC_COLLATE>,
1282 C<LANG> chooses the collation locale.
1283
1284 =item C<LC_MONETARY>
1285
1286 In the absence of C<LC_ALL>, C<LC_MONETARY> chooses the monetary
1287 formatting locale.  In the absence of both C<LC_ALL> and C<LC_MONETARY>,
1288 C<LANG> chooses the monetary formatting locale.
1289
1290 =item C<LC_NUMERIC>
1291
1292 In the absence of C<LC_ALL>, C<LC_NUMERIC> chooses the numeric format
1293 locale.  In the absence of both C<LC_ALL> and C<LC_NUMERIC>, C<LANG>
1294 chooses the numeric format.
1295
1296 =item C<LC_TIME>
1297
1298 In the absence of C<LC_ALL>, C<LC_TIME> chooses the date and time
1299 formatting locale.  In the absence of both C<LC_ALL> and C<LC_TIME>,
1300 C<LANG> chooses the date and time formatting locale.
1301
1302 =item C<LANG>
1303
1304 C<LANG> is the "catch-all" locale environment variable. If it is set, it
1305 is used as the last resort after the overall C<LC_ALL> and the
1306 category-specific C<LC_I<foo>>.
1307
1308 =back
1309
1310 =head2 Examples
1311
1312 The C<LC_NUMERIC> controls the numeric output:
1313
1314    use locale;
1315    use POSIX qw(locale_h); # Imports setlocale() and the LC_ constants.
1316    setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
1317    printf "%g\n", 1.23; # If the "fr_FR" succeeded, probably shows 1,23.
1318
1319 and also how strings are parsed by C<POSIX::strtod()> as numbers:
1320
1321    use locale;
1322    use POSIX qw(locale_h strtod);
1323    setlocale(LC_NUMERIC, "de_DE") or die "Entschuldigung";
1324    my $x = strtod("2,34") + 5;
1325    print $x, "\n"; # Probably shows 7,34.
1326
1327 =head1 NOTES
1328
1329 =head2 String C<eval> and C<LC_NUMERIC>
1330
1331 A string L<eval|perlfunc/eval EXPR> parses its expression as standard
1332 Perl.  It is therefore expecting the decimal point to be a dot.  If
1333 C<LC_NUMERIC> is set to have this be a comma instead, the parsing will
1334 be confused, perhaps silently.
1335
1336  use locale;
1337  use POSIX qw(locale_h);
1338  setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
1339  my $a = 1.2;
1340  print eval "$a + 1.5";
1341  print "\n";
1342
1343 prints C<13,5>.  This is because in that locale, the comma is the
1344 decimal point character.  The C<eval> thus expands to:
1345
1346  eval "1,2 + 1.5"
1347
1348 and the result is not what you likely expected.  No warnings are
1349 generated.  If you do string C<eval>'s within the scope of
1350 S<C<use locale>>, you should instead change the C<eval> line to do
1351 something like:
1352
1353  print eval "no locale; $a + 1.5";
1354
1355 This prints C<2.7>.
1356
1357 You could also exclude C<LC_NUMERIC>, if you don't need it, by
1358
1359  use locale ':!numeric';
1360
1361 =head2 Backward compatibility
1362
1363 Versions of Perl prior to 5.004 B<mostly> ignored locale information,
1364 generally behaving as if something similar to the C<"C"> locale were
1365 always in force, even if the program environment suggested otherwise
1366 (see L<The setlocale function>).  By default, Perl still behaves this
1367 way for backward compatibility.  If you want a Perl application to pay
1368 attention to locale information, you B<must> use the S<C<use locale>>
1369 pragma (see L<The "use locale" pragma>) or, in the unlikely event
1370 that you want to do so for just pattern matching, the
1371 C</l> regular expression modifier (see L<perlre/Character set
1372 modifiers>) to instruct it to do so.
1373
1374 Versions of Perl from 5.002 to 5.003 did use the C<LC_CTYPE>
1375 information if available; that is, C<\w> did understand what
1376 were the letters according to the locale environment variables.
1377 The problem was that the user had no control over the feature:
1378 if the C library supported locales, Perl used them.
1379
1380 =head2 I18N:Collate obsolete
1381
1382 In versions of Perl prior to 5.004, per-locale collation was possible
1383 using the C<I18N::Collate> library module.  This module is now mildly
1384 obsolete and should be avoided in new applications.  The C<LC_COLLATE>
1385 functionality is now integrated into the Perl core language: One can
1386 use locale-specific scalar data completely normally with C<use locale>,
1387 so there is no longer any need to juggle with the scalar references of
1388 C<I18N::Collate>.
1389
1390 =head2 Sort speed and memory use impacts
1391
1392 Comparing and sorting by locale is usually slower than the default
1393 sorting; slow-downs of two to four times have been observed.  It will
1394 also consume more memory: once a Perl scalar variable has participated
1395 in any string comparison or sorting operation obeying the locale
1396 collation rules, it will take 3-15 times more memory than before.  (The
1397 exact multiplier depends on the string's contents, the operating system
1398 and the locale.) These downsides are dictated more by the operating
1399 system's implementation of the locale system than by Perl.
1400
1401 =head2 Freely available locale definitions
1402
1403 The Unicode CLDR project extracts the POSIX portion of many of its
1404 locales, available at
1405
1406   http://unicode.org/Public/cldr/2.0.1/
1407
1408 (Newer versions of CLDR require you to compute the POSIX data yourself.
1409 See L<http://unicode.org/Public/cldr/latest/>.)
1410
1411 There is a large collection of locale definitions at:
1412
1413   http://std.dkuug.dk/i18n/WG15-collection/locales/
1414
1415 You should be aware that it is
1416 unsupported, and is not claimed to be fit for any purpose.  If your
1417 system allows installation of arbitrary locales, you may find the
1418 definitions useful as they are, or as a basis for the development of
1419 your own locales.
1420
1421 =head2 I18n and l10n
1422
1423 "Internationalization" is often abbreviated as B<i18n> because its first
1424 and last letters are separated by eighteen others.  (You may guess why
1425 the internalin ... internaliti ... i18n tends to get abbreviated.)  In
1426 the same way, "localization" is often abbreviated to B<l10n>.
1427
1428 =head2 An imperfect standard
1429
1430 Internationalization, as defined in the C and POSIX standards, can be
1431 criticized as incomplete, ungainly, and having too large a granularity.
1432 (Locales apply to a whole process, when it would arguably be more useful
1433 to have them apply to a single thread, window group, or whatever.)  They
1434 also have a tendency, like standards groups, to divide the world into
1435 nations, when we all know that the world can equally well be divided
1436 into bankers, bikers, gamers, and so on.
1437
1438 =head1 Unicode and UTF-8
1439
1440 The support of Unicode is new starting from Perl version v5.6, and more fully
1441 implemented in versions v5.8 and later.  See L<perluniintro>.
1442
1443 Starting in Perl v5.20, UTF-8 locales are supported in Perl, except
1444 C<LC_COLLATE> is only partially supported; collation support is improved
1445 in Perl v5.26 to a level that may be sufficient for your needs
1446 (see L</Category C<LC_COLLATE>: Collation: Text Comparisons and Sorting>).
1447
1448 If you have Perl v5.16 or v5.18 and can't upgrade, you can use
1449
1450     use locale ':not_characters';
1451
1452 When this form of the pragma is used, only the non-character portions of
1453 locales are used by Perl, for example C<LC_NUMERIC>.  Perl assumes that
1454 you have translated all the characters it is to operate on into Unicode
1455 (actually the platform's native character set (ASCII or EBCDIC) plus
1456 Unicode).  For data in files, this can conveniently be done by also
1457 specifying
1458
1459     use open ':locale';
1460
1461 This pragma arranges for all inputs from files to be translated into
1462 Unicode from the current locale as specified in the environment (see
1463 L</ENVIRONMENT>), and all outputs to files to be translated back
1464 into the locale.  (See L<open>).  On a per-filehandle basis, you can
1465 instead use the L<PerlIO::locale> module, or the L<Encode::Locale>
1466 module, both available from CPAN.  The latter module also has methods to
1467 ease the handling of C<ARGV> and environment variables, and can be used
1468 on individual strings.  If you know that all your locales will be
1469 UTF-8, as many are these days, you can use the L<B<-C>|perlrun/-C>
1470 command line switch.
1471
1472 This form of the pragma allows essentially seamless handling of locales
1473 with Unicode.  The collation order will be by Unicode code point order.
1474 L<Unicode::Collate> can be used to get Unicode rules collation.
1475
1476 All the modules and switches just described can be used in v5.20 with
1477 just plain C<use locale>, and, should the input locales not be UTF-8,
1478 you'll get the less than ideal behavior, described below, that you get
1479 with pre-v5.16 Perls, or when you use the locale pragma without the
1480 C<:not_characters> parameter in v5.16 and v5.18.  If you are using
1481 exclusively UTF-8 locales in v5.20 and higher, the rest of this section
1482 does not apply to you.
1483
1484 There are two cases, multi-byte and single-byte locales.  First
1485 multi-byte:
1486
1487 The only multi-byte (or wide character) locale that Perl is ever likely
1488 to support is UTF-8.  This is due to the difficulty of implementation,
1489 the fact that high quality UTF-8 locales are now published for every
1490 area of the world (L<http://unicode.org/Public/cldr/2.0.1/> for
1491 ones that are already set-up, but from an earlier version;
1492 L<http://unicode.org/Public/cldr/latest/> for the most up-to-date, but
1493 you have to extract the POSIX information yourself), and that
1494 failing all that you can use the L<Encode> module to translate to/from
1495 your locale.  So, you'll have to do one of those things if you're using
1496 one of these locales, such as Big5 or Shift JIS.  For UTF-8 locales, in
1497 Perls (pre v5.20) that don't have full UTF-8 locale support, they may
1498 work reasonably well (depending on your C library implementation)
1499 simply because both
1500 they and Perl store characters that take up multiple bytes the same way.
1501 However, some, if not most, C library implementations may not process
1502 the characters in the upper half of the Latin-1 range (128 - 255)
1503 properly under C<LC_CTYPE>.  To see if a character is a particular type
1504 under a locale, Perl uses the functions like C<isalnum()>.  Your C
1505 library may not work for UTF-8 locales with those functions, instead
1506 only working under the newer wide library functions like C<iswalnum()>,
1507 which Perl does not use.
1508 These multi-byte locales are treated like single-byte locales, and will
1509 have the restrictions described below.  Starting in Perl v5.22 a warning
1510 message is raised when Perl detects a multi-byte locale that it doesn't
1511 fully support.
1512
1513 For single-byte locales,
1514 Perl generally takes the tack to use locale rules on code points that can fit
1515 in a single byte, and Unicode rules for those that can't (though this
1516 isn't uniformly applied, see the note at the end of this section).  This
1517 prevents many problems in locales that aren't UTF-8.  Suppose the locale
1518 is ISO8859-7, Greek.  The character at 0xD7 there is a capital Chi. But
1519 in the ISO8859-1 locale, Latin1, it is a multiplication sign.  The POSIX
1520 regular expression character class C<[[:alpha:]]> will magically match
1521 0xD7 in the Greek locale but not in the Latin one.
1522
1523 However, there are places where this breaks down.  Certain Perl constructs are
1524 for Unicode only, such as C<\p{Alpha}>.  They assume that 0xD7 always has its
1525 Unicode meaning (or the equivalent on EBCDIC platforms).  Since Latin1 is a
1526 subset of Unicode and 0xD7 is the multiplication sign in both Latin1 and
1527 Unicode, C<\p{Alpha}> will never match it, regardless of locale.  A similar
1528 issue occurs with C<\N{...}>.  Prior to v5.20, It is therefore a bad
1529 idea to use C<\p{}> or
1530 C<\N{}> under plain C<use locale>--I<unless> you can guarantee that the
1531 locale will be ISO8859-1.  Use POSIX character classes instead.
1532
1533 Another problem with this approach is that operations that cross the
1534 single byte/multiple byte boundary are not well-defined, and so are
1535 disallowed.  (This boundary is between the codepoints at 255/256.)
1536 For example, lower casing LATIN CAPITAL LETTER Y WITH DIAERESIS (U+0178)
1537 should return LATIN SMALL LETTER Y WITH DIAERESIS (U+00FF).  But in the
1538 Greek locale, for example, there is no character at 0xFF, and Perl
1539 has no way of knowing what the character at 0xFF is really supposed to
1540 represent.  Thus it disallows the operation.  In this mode, the
1541 lowercase of U+0178 is itself.
1542
1543 The same problems ensue if you enable automatic UTF-8-ification of your
1544 standard file handles, default C<open()> layer, and C<@ARGV> on non-ISO8859-1,
1545 non-UTF-8 locales (by using either the B<-C> command line switch or the
1546 C<PERL_UNICODE> environment variable; see L<perlrun>).
1547 Things are read in as UTF-8, which would normally imply a Unicode
1548 interpretation, but the presence of a locale causes them to be interpreted
1549 in that locale instead.  For example, a 0xD7 code point in the Unicode
1550 input, which should mean the multiplication sign, won't be interpreted by
1551 Perl that way under the Greek locale.  This is not a problem
1552 I<provided> you make certain that all locales will always and only be either
1553 an ISO8859-1, or, if you don't have a deficient C library, a UTF-8 locale.
1554
1555 Still another problem is that this approach can lead to two code
1556 points meaning the same character.  Thus in a Greek locale, both U+03A7
1557 and U+00D7 are GREEK CAPITAL LETTER CHI.
1558
1559 Because of all these problems, starting in v5.22, Perl will raise a
1560 warning if a multi-byte (hence Unicode) code point is used when a
1561 single-byte locale is in effect.  (Although it doesn't check for this if
1562 doing so would unreasonably slow execution down.)
1563
1564 Vendor locales are notoriously buggy, and it is difficult for Perl to test
1565 its locale-handling code because this interacts with code that Perl has no
1566 control over; therefore the locale-handling code in Perl may be buggy as
1567 well.  (However, the Unicode-supplied locales should be better, and
1568 there is a feed back mechanism to correct any problems.  See
1569 L</Freely available locale definitions>.)
1570
1571 If you have Perl v5.16, the problems mentioned above go away if you use
1572 the C<:not_characters> parameter to the locale pragma (except for vendor
1573 bugs in the non-character portions).  If you don't have v5.16, and you
1574 I<do> have locales that work, using them may be worthwhile for certain
1575 specific purposes, as long as you keep in mind the gotchas already
1576 mentioned.  For example, if the collation for your locales works, it
1577 runs faster under locales than under L<Unicode::Collate>; and you gain
1578 access to such things as the local currency symbol and the names of the
1579 months and days of the week.  (But to hammer home the point, in v5.16,
1580 you get this access without the downsides of locales by using the
1581 C<:not_characters> form of the pragma.)
1582
1583 Note: The policy of using locale rules for code points that can fit in a
1584 byte, and Unicode rules for those that can't is not uniformly applied.
1585 Pre-v5.12, it was somewhat haphazard; in v5.12 it was applied fairly
1586 consistently to regular expression matching except for bracketed
1587 character classes; in v5.14 it was extended to all regex matches; and in
1588 v5.16 to the casing operations such as C<\L> and C<uc()>.  For
1589 collation, in all releases so far, the system's C<strxfrm()> function is
1590 called, and whatever it does is what you get.  Starting in v5.26, various
1591 bugs are fixed with the way perl uses this function.
1592
1593 =head1 BUGS
1594
1595 =head2 Collation of strings containing embedded C<NUL> characters
1596
1597 C<NUL> characters will sort the same as the lowest collating control
1598 character does, or to C<"\001"> in the unlikely event that there are no
1599 control characters at all in the locale.  In cases where the strings
1600 don't contain this non-C<NUL> control, the results will be correct, and
1601 in many locales, this control, whatever it might be, will rarely be
1602 encountered.  But there are cases where a C<NUL> should sort before this
1603 control, but doesn't.  If two strings do collate identically, the one
1604 containing the C<NUL> will sort to earlier.
1605
1606 =head2 Broken systems
1607
1608 In certain systems, the operating system's locale support
1609 is broken and cannot be fixed or used by Perl.  Such deficiencies can
1610 and will result in mysterious hangs and/or Perl core dumps when
1611 C<use locale> is in effect.  When confronted with such a system,
1612 please report in excruciating detail to <F<perlbug@perl.org>>, and
1613 also contact your vendor: bug fixes may exist for these problems
1614 in your operating system.  Sometimes such bug fixes are called an
1615 operating system upgrade.  If you have the source for Perl, include in
1616 the perlbug email the output of the test described above in L</Testing
1617 for broken locales>.
1618
1619 =head1 SEE ALSO
1620
1621 L<I18N::Langinfo>, L<perluniintro>, L<perlunicode>, L<open>,
1622 L<POSIX/isalnum>, L<POSIX/isalpha>,
1623 L<POSIX/isdigit>, L<POSIX/isgraph>, L<POSIX/islower>,
1624 L<POSIX/isprint>, L<POSIX/ispunct>, L<POSIX/isspace>,
1625 L<POSIX/isupper>, L<POSIX/isxdigit>, L<POSIX/localeconv>,
1626 L<POSIX/setlocale>, L<POSIX/strcoll>, L<POSIX/strftime>,
1627 L<POSIX/strtod>, L<POSIX/strxfrm>.
1628
1629 For special considerations when Perl is embedded in a C program,
1630 see L<perlembed/Using embedded Perl with POSIX locales>.
1631
1632 =head1 HISTORY
1633
1634 Jarkko Hietaniemi's original F<perli18n.pod> heavily hacked by Dominic
1635 Dunlop, assisted by the perl5-porters.  Prose worked over a bit by
1636 Tom Christiansen, and updated by Perl 5 porters.