This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
a48d943397b6ed2b24102f5a9f4e4a23bc8b345e
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program.  This will alias all the short names to the
17 long names in the current package.  Some even have medium names,
18 generally borrowed from B<awk>.
19
20 If you don't mind the performance hit, variables that depend on the
21 currently selected filehandle may instead be set by calling an
22 appropriate object method on the IO::Handle object.  (Summary lines
23 below for this contain the word HANDLE.)  First you must say
24
25     use IO::Handle;
26
27 after which you may use either
28
29     method HANDLE EXPR
30
31 or more safely,
32
33     HANDLE->method(EXPR)
34
35 Each method returns the old value of the IO::Handle attribute.
36 The methods each take an optional EXPR, which if supplied specifies the
37 new value for the IO::Handle attribute in question.  If not supplied,
38 most methods do nothing to the current value--except for
39 autoflush(), which will assume a 1 for you, just to be different.
40 Because loading in the IO::Handle class is an expensive operation, you should
41 learn how to use the regular built-in variables.
42
43 A few of these variables are considered "read-only".  This means that if
44 you try to assign to this variable, either directly or indirectly through
45 a reference, you'll raise a run-time exception.
46
47 You should be very careful when modifying the default values of most
48 special variables described in this document. In most cases you want
49 to localize these variables before changing them, since if you don't,
50 the change may affect other modules which rely on the default values
51 of the special variables that you have changed. This is one of the
52 correct ways to read the whole file at once:
53
54     open my $fh, "foo" or die $!;
55     local $/; # enable localized slurp mode
56     my $content = <$fh>;
57     close $fh;
58
59 But the following code is quite bad:
60
61     open my $fh, "foo" or die $!;
62     undef $/; # enable slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 since some other module, may want to read data from some file in the
67 default "line mode", so if the code we have just presented has been
68 executed, the global value of C<$/> is now changed for any other code
69 running inside the same Perl interpreter.
70
71 Usually when a variable is localized you want to make sure that this
72 change affects the shortest scope possible. So unless you are already
73 inside some short C<{}> block, you should create one yourself. For
74 example:
75
76     my $content = '';
77     open my $fh, "foo" or die $!;
78     {
79         local $/;
80         $content = <$fh>;
81     }
82     close $fh;
83
84 Here is an example of how your own code can go broken:
85
86     for (1..5){
87         nasty_break();
88         print "$_ ";
89     }
90     sub nasty_break {
91         $_ = 5;
92         # do something with $_
93     }
94
95 You probably expect this code to print:
96
97     1 2 3 4 5
98
99 but instead you get:
100
101     5 5 5 5 5
102
103 Why? Because nasty_break() modifies C<$_> without localizing it
104 first. The fix is to add local():
105
106         local $_ = 5;
107
108 It's easy to notice the problem in such a short example, but in more
109 complicated code you are looking for trouble if you don't localize
110 changes to the special variables.
111
112 The following list is ordered by scalar variables first, then the
113 arrays, then the hashes.
114
115 =over 8
116
117 =item $ARG
118
119 =item $_
120
121 The default input and pattern-searching space.  The following pairs are
122 equivalent:
123
124     while (<>) {...}    # equivalent only in while!
125     while (defined($_ = <>)) {...}
126
127     /^Subject:/
128     $_ =~ /^Subject:/
129
130     tr/a-z/A-Z/
131     $_ =~ tr/a-z/A-Z/
132
133     chomp
134     chomp($_)
135
136 Here are the places where Perl will assume $_ even if you
137 don't use it:
138
139 =over 3
140
141 =item *
142
143 Various unary functions, including functions like ord() and int(), as well
144 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
145 STDIN.
146
147 =item *
148
149 Various list functions like print() and unlink().
150
151 =item *
152
153 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
154 without an C<=~> operator.
155
156 =item *
157
158 The default iterator variable in a C<foreach> loop if no other
159 variable is supplied.
160
161 =item *
162
163 The implicit iterator variable in the grep() and map() functions.
164
165 =item *
166
167 The default place to put an input record when a C<< <FH> >>
168 operation's result is tested by itself as the sole criterion of a C<while>
169 test.  Outside a C<while> test, this will not happen.
170
171 =back
172
173 (Mnemonic: underline is understood in certain operations.)
174
175 =back
176
177 =over 8
178
179 =item $a
180
181 =item $b
182
183 Special package variables when using sort(), see L<perlfunc/sort>.
184 Because of this specialness $a and $b don't need to be declared
185 (using local(), use vars, or our()) even when using the strict
186 vars pragma.  Don't lexicalize them with C<my $a> or C<my $b>
187 if you want to be able to use them in the sort() comparison block
188 or function.
189
190 =back
191
192 =over 8
193
194 =item $<I<digits>>
195
196 Contains the subpattern from the corresponding set of capturing
197 parentheses from the last pattern match, not counting patterns
198 matched in nested blocks that have been exited already.  (Mnemonic:
199 like \digits.)  These variables are all read-only and dynamically
200 scoped to the current BLOCK.
201
202 =item $MATCH
203
204 =item $&
205
206 The string matched by the last successful pattern match (not counting
207 any matches hidden within a BLOCK or eval() enclosed by the current
208 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
209 and dynamically scoped to the current BLOCK.
210
211 The use of this variable anywhere in a program imposes a considerable
212 performance penalty on all regular expression matches.  See L<BUGS>.
213
214 =item $PREMATCH
215
216 =item $`
217
218 The string preceding whatever was matched by the last successful
219 pattern match (not counting any matches hidden within a BLOCK or eval
220 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
221 string.)  This variable is read-only.
222
223 The use of this variable anywhere in a program imposes a considerable
224 performance penalty on all regular expression matches.  See L<BUGS>.
225
226 =item $POSTMATCH
227
228 =item $'
229
230 The string following whatever was matched by the last successful
231 pattern match (not counting any matches hidden within a BLOCK or eval()
232 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
233 string.)  Example:
234
235     local $_ = 'abcdefghi';
236     /def/;
237     print "$`:$&:$'\n";         # prints abc:def:ghi
238
239 This variable is read-only and dynamically scoped to the current BLOCK.
240
241 The use of this variable anywhere in a program imposes a considerable
242 performance penalty on all regular expression matches.  See L<BUGS>.
243
244 =item $LAST_PAREN_MATCH
245
246 =item $+
247
248 The text matched by the last bracket of the last successful search pattern.
249 This is useful if you don't know which one of a set of alternative patterns
250 matched. For example:
251
252     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
253
254 (Mnemonic: be positive and forward looking.)
255 This variable is read-only and dynamically scoped to the current BLOCK.
256
257 =item $^N
258
259 The text matched by the used group most-recently closed (i.e. the group
260 with the rightmost closing parenthesis) of the last successful search
261 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
262 recently closed.)
263
264 This is primarily used inside C<(?{...})> blocks for examining text
265 recently matched. For example, to effectively capture text to a variable
266 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
267
268      (?:(...)(?{ $var = $^N }))
269
270 By setting and then using C<$var> in this way relieves you from having to
271 worry about exactly which numbered set of parentheses they are.
272
273 This variable is dynamically scoped to the current BLOCK.
274
275 =item @LAST_MATCH_END
276
277 =item @+
278
279 This array holds the offsets of the ends of the last successful
280 submatches in the currently active dynamic scope.  C<$+[0]> is
281 the offset into the string of the end of the entire match.  This
282 is the same value as what the C<pos> function returns when called
283 on the variable that was matched against.  The I<n>th element
284 of this array holds the offset of the I<n>th submatch, so
285 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
286 past where $2 ends, and so on.  You can use C<$#+> to determine
287 how many subgroups were in the last successful match.  See the
288 examples given for the C<@-> variable.
289
290 =item $MULTILINE_MATCHING
291
292 =item $*
293
294 Set to a non-zero integer value to do multi-line matching within a
295 string, 0 (or undefined) to tell Perl that it can assume that strings
296 contain a single line, for the purpose of optimizing pattern matches.
297 Pattern matches on strings containing multiple newlines can produce
298 confusing results when C<$*> is 0 or undefined. Default is undefined.
299 (Mnemonic: * matches multiple things.) This variable influences the
300 interpretation of only C<^> and C<$>. A literal newline can be searched
301 for even when C<$* == 0>.
302
303 Use of C<$*> is deprecated in modern Perl, supplanted by 
304 the C</s> and C</m> modifiers on pattern matching.
305
306 Assigning a non-numerical value to C<$*> triggers a warning (and makes
307 C<$*> act if C<$* == 0>), while assigning a numerical value to C<$*>
308 makes that an implicit C<int> is applied on the value.
309
310 =item HANDLE->input_line_number(EXPR)
311
312 =item $INPUT_LINE_NUMBER
313
314 =item $NR
315
316 =item $.
317
318 Current line number for the last filehandle accessed. 
319
320 Each filehandle in Perl counts the number of lines that have been read
321 from it.  (Depending on the value of C<$/>, Perl's idea of what
322 constitutes a line may not match yours.)  When a line is read from a
323 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
324 called on it, C<$.> becomes an alias to the line counter for that
325 filehandle.
326
327 You can adjust the counter by assigning to C<$.>, but this will not
328 actually move the seek pointer.  I<Localizing C<$.> will not localize
329 the filehandle's line count>.  Instead, it will localize perl's notion
330 of which filehandle C<$.> is currently aliased to.
331
332 C<$.> is reset when the filehandle is closed, but B<not> when an open
333 filehandle is reopened without an intervening close().  For more
334 details, see L<perlop/"I/O Operators">.  Because C<< <> >> never does
335 an explicit close, line numbers increase across ARGV files (but see
336 examples in L<perlfunc/eof>).
337
338 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
339 line counter for a given filehandle without having to worry about
340 which handle you last accessed.
341
342 (Mnemonic: many programs use "." to mean the current line number.)
343
344 =item IO::Handle->input_record_separator(EXPR)
345
346 =item $INPUT_RECORD_SEPARATOR
347
348 =item $RS
349
350 =item $/
351
352 The input record separator, newline by default.  This 
353 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
354 variable, including treating empty lines as a terminator if set to
355 the null string.  (An empty line cannot contain any spaces
356 or tabs.)  You may set it to a multi-character string to match a
357 multi-character terminator, or to C<undef> to read through the end
358 of file.  Setting it to C<"\n\n"> means something slightly
359 different than setting to C<"">, if the file contains consecutive
360 empty lines.  Setting to C<""> will treat two or more consecutive
361 empty lines as a single empty line.  Setting to C<"\n\n"> will
362 blindly assume that the next input character belongs to the next
363 paragraph, even if it's a newline.  (Mnemonic: / delimits
364 line boundaries when quoting poetry.)
365
366     local $/;           # enable "slurp" mode
367     local $_ = <FH>;    # whole file now here
368     s/\n[ \t]+/ /g;
369
370 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
371 better for something. :-)
372
373 Setting C<$/> to a reference to an integer, scalar containing an integer, or
374 scalar that's convertible to an integer will attempt to read records
375 instead of lines, with the maximum record size being the referenced
376 integer.  So this:
377
378     local $/ = \32768; # or \"32768", or \$var_containing_32768
379     open my $fh, $myfile or die $!;
380     local $_ = <$fh>;
381
382 will read a record of no more than 32768 bytes from FILE.  If you're
383 not reading from a record-oriented file (or your OS doesn't have
384 record-oriented files), then you'll likely get a full chunk of data
385 with every read.  If a record is larger than the record size you've
386 set, you'll get the record back in pieces.
387
388 On VMS, record reads are done with the equivalent of C<sysread>,
389 so it's best not to mix record and non-record reads on the same
390 file.  (This is unlikely to be a problem, because any file you'd
391 want to read in record mode is probably unusable in line mode.)
392 Non-VMS systems do normal I/O, so it's safe to mix record and
393 non-record reads of a file.
394
395 See also L<perlport/"Newlines">.  Also see C<$.>.
396
397 =item HANDLE->autoflush(EXPR)
398
399 =item $OUTPUT_AUTOFLUSH
400
401 =item $|
402
403 If set to nonzero, forces a flush right away and after every write
404 or print on the currently selected output channel.  Default is 0
405 (regardless of whether the channel is really buffered by the
406 system or not; C<$|> tells you only whether you've asked Perl
407 explicitly to flush after each write).  STDOUT will
408 typically be line buffered if output is to the terminal and block
409 buffered otherwise.  Setting this variable is useful primarily when
410 you are outputting to a pipe or socket, such as when you are running
411 a Perl program under B<rsh> and want to see the output as it's
412 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
413 for that.  (Mnemonic: when you want your pipes to be piping hot.)
414
415 =item IO::Handle->output_field_separator EXPR
416
417 =item $OUTPUT_FIELD_SEPARATOR
418
419 =item $OFS
420
421 =item $,
422
423 The output field separator for the print operator.  Ordinarily the
424 print operator simply prints out its arguments without further
425 adornment.  To get behavior more like B<awk>, set this variable as
426 you would set B<awk>'s OFS variable to specify what is printed
427 between fields.  (Mnemonic: what is printed when there is a "," in
428 your print statement.)
429
430 =item IO::Handle->output_record_separator EXPR
431
432 =item $OUTPUT_RECORD_SEPARATOR
433
434 =item $ORS
435
436 =item $\
437
438 The output record separator for the print operator.  Ordinarily the
439 print operator simply prints out its arguments as is, with no
440 trailing newline or other end-of-record string added.  To get
441 behavior more like B<awk>, set this variable as you would set
442 B<awk>'s ORS variable to specify what is printed at the end of the
443 print.  (Mnemonic: you set C<$\> instead of adding "\n" at the
444 end of the print.  Also, it's just like C<$/>, but it's what you
445 get "back" from Perl.)
446
447 =item $LIST_SEPARATOR
448
449 =item $"
450
451 This is like C<$,> except that it applies to array and slice values
452 interpolated into a double-quoted string (or similar interpreted
453 string).  Default is a space.  (Mnemonic: obvious, I think.)
454
455 =item $SUBSCRIPT_SEPARATOR
456
457 =item $SUBSEP
458
459 =item $;
460
461 The subscript separator for multidimensional array emulation.  If you
462 refer to a hash element as
463
464     $foo{$a,$b,$c}
465
466 it really means
467
468     $foo{join($;, $a, $b, $c)}
469
470 But don't put
471
472     @foo{$a,$b,$c}      # a slice--note the @
473
474 which means
475
476     ($foo{$a},$foo{$b},$foo{$c})
477
478 Default is "\034", the same as SUBSEP in B<awk>.  If your
479 keys contain binary data there might not be any safe value for C<$;>.
480 (Mnemonic: comma (the syntactic subscript separator) is a
481 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
482 taken for something more important.)
483
484 Consider using "real" multidimensional arrays as described
485 in L<perllol>.
486
487 =item $OFMT
488
489 =item $#
490
491 The output format for printed numbers.  This variable is a half-hearted
492 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
493 when B<awk> and Perl have differing notions of what counts as 
494 numeric.  The initial value is "%.I<n>g", where I<n> is the value
495 of the macro DBL_DIG from your system's F<float.h>.  This is different from
496 B<awk>'s default OFMT setting of "%.6g", so you need to set C<$#>
497 explicitly to get B<awk>'s value.  (Mnemonic: # is the number sign.)
498
499 Use of C<$#> is deprecated.
500
501 =item HANDLE->format_page_number(EXPR)
502
503 =item $FORMAT_PAGE_NUMBER
504
505 =item $%
506
507 The current page number of the currently selected output channel.
508 Used with formats.
509 (Mnemonic: % is page number in B<nroff>.)
510
511 =item HANDLE->format_lines_per_page(EXPR)
512
513 =item $FORMAT_LINES_PER_PAGE
514
515 =item $=
516
517 The current page length (printable lines) of the currently selected
518 output channel.  Default is 60.  
519 Used with formats.
520 (Mnemonic: = has horizontal lines.)
521
522 =item HANDLE->format_lines_left(EXPR)
523
524 =item $FORMAT_LINES_LEFT
525
526 =item $-
527
528 The number of lines left on the page of the currently selected output
529 channel.  
530 Used with formats.
531 (Mnemonic: lines_on_page - lines_printed.)
532
533 =item @LAST_MATCH_START
534
535 =item @-
536
537 $-[0] is the offset of the start of the last successful match.
538 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
539 I<n>-th subpattern, or undef if the subpattern did not match.
540
541 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
542 $+[0] - $-[0]>.  Similarly, C<$>I<n> coincides with C<substr $_, $-[>I<n>C<],
543 $+[>I<n>C<] - $-[>I<n>C<]> if C<$-[>I<n>C<]> is defined, and $+ coincides with
544 C<substr $_, $-[$#-], $+[$#-]>.  One can use C<$#-> to find the last
545 matched subgroup in the last successful match.  Contrast with
546 C<$#+>, the number of subgroups in the regular expression.  Compare
547 with C<@+>.
548
549 This array holds the offsets of the beginnings of the last
550 successful submatches in the currently active dynamic scope.
551 C<$-[0]> is the offset into the string of the beginning of the
552 entire match.  The I<n>th element of this array holds the offset
553 of the I<n>th submatch, so C<$-[1]> is the offset where $1
554 begins, C<$-[2]> the offset where $2 begins, and so on.
555
556 After a match against some variable $var:
557
558 =over 5
559
560 =item C<$`> is the same as C<substr($var, 0, $-[0])>
561
562 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
563
564 =item C<$'> is the same as C<substr($var, $+[0])>
565
566 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
567
568 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
569
570 =item C<$3> is the same as C<substr $var, $-[3], $+[3] - $-[3])>
571
572 =back
573
574 =item HANDLE->format_name(EXPR)
575
576 =item $FORMAT_NAME
577
578 =item $~
579
580 The name of the current report format for the currently selected output
581 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
582 C<$^>.)
583
584 =item HANDLE->format_top_name(EXPR)
585
586 =item $FORMAT_TOP_NAME
587
588 =item $^
589
590 The name of the current top-of-page format for the currently selected
591 output channel.  Default is the name of the filehandle with _TOP
592 appended.  (Mnemonic: points to top of page.)
593
594 =item IO::Handle->format_line_break_characters EXPR
595
596 =item $FORMAT_LINE_BREAK_CHARACTERS
597
598 =item $:
599
600 The current set of characters after which a string may be broken to
601 fill continuation fields (starting with ^) in a format.  Default is
602 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
603 poetry is a part of a line.)
604
605 =item IO::Handle->format_formfeed EXPR
606
607 =item $FORMAT_FORMFEED
608
609 =item $^L
610
611 What formats output as a form feed.  Default is \f.
612
613 =item $ACCUMULATOR
614
615 =item $^A
616
617 The current value of the write() accumulator for format() lines.  A format
618 contains formline() calls that put their result into C<$^A>.  After
619 calling its format, write() prints out the contents of C<$^A> and empties.
620 So you never really see the contents of C<$^A> unless you call
621 formline() yourself and then look at it.  See L<perlform> and
622 L<perlfunc/formline()>.
623
624 =item $CHILD_ERROR
625
626 =item $?
627
628 The status returned by the last pipe close, backtick (C<``>) command,
629 successful call to wait() or waitpid(), or from the system()
630 operator.  This is just the 16-bit status word returned by the
631 wait() system call (or else is made up to look like it).  Thus, the
632 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
633 C<$? & 127> gives which signal, if any, the process died from, and
634 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
635 similar to B<sh> and B<ksh>.)
636
637 Additionally, if the C<h_errno> variable is supported in C, its value
638 is returned via $? if any C<gethost*()> function fails.
639
640 If you have installed a signal handler for C<SIGCHLD>, the
641 value of C<$?> will usually be wrong outside that handler.
642
643 Inside an C<END> subroutine C<$?> contains the value that is going to be
644 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
645 change the exit status of your program.  For example:
646
647     END {
648         $? = 1 if $? == 255;  # die would make it 255
649     } 
650
651 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
652 actual VMS exit status, instead of the default emulation of POSIX
653 status; see L<perlvms/$?> for details.
654
655 Also see L<Error Indicators>.
656
657 =item ${^ENCODING}
658
659 The encoding used to interpret native eight-bit encodings to Unicode,
660 see L<encode>.  An opaque C<Encode::XS> object.
661
662 =item $OS_ERROR
663
664 =item $ERRNO
665
666 =item $!
667
668 If used numerically, yields the current value of the C C<errno>
669 variable, with all the usual caveats.  (This means that you shouldn't
670 depend on the value of C<$!> to be anything in particular unless
671 you've gotten a specific error return indicating a system error.)
672 If used an a string, yields the corresponding system error string.
673 You can assign a number to C<$!> to set I<errno> if, for instance,
674 you want C<"$!"> to return the string for error I<n>, or you want
675 to set the exit value for the die() operator.  (Mnemonic: What just
676 went bang?)
677
678 Also see L<Error Indicators>.
679
680 =item $EXTENDED_OS_ERROR
681
682 =item $^E
683
684 Error information specific to the current operating system.  At
685 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
686 (and for MacPerl).  On all other platforms, C<$^E> is always just
687 the same as C<$!>.
688
689 Under VMS, C<$^E> provides the VMS status value from the last
690 system error.  This is more specific information about the last
691 system error than that provided by C<$!>.  This is particularly
692 important when C<$!> is set to B<EVMSERR>.
693
694 Under OS/2, C<$^E> is set to the error code of the last call to
695 OS/2 API either via CRT, or directly from perl.
696
697 Under Win32, C<$^E> always returns the last error information
698 reported by the Win32 call C<GetLastError()> which describes
699 the last error from within the Win32 API.  Most Win32-specific
700 code will report errors via C<$^E>.  ANSI C and Unix-like calls
701 set C<errno> and so most portable Perl code will report errors
702 via C<$!>. 
703
704 Caveats mentioned in the description of C<$!> generally apply to
705 C<$^E>, also.  (Mnemonic: Extra error explanation.)
706
707 Also see L<Error Indicators>.
708
709 =item $EVAL_ERROR
710
711 =item $@
712
713 The Perl syntax error message from the last eval() operator.
714 If $@ is the null string, the last eval() parsed and executed
715 correctly (although the operations you invoked may have failed in the
716 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
717
718 Warning messages are not collected in this variable.  You can,
719 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
720 as described below.
721
722 Also see L<Error Indicators>.
723
724 =item $PROCESS_ID
725
726 =item $PID
727
728 =item $$
729
730 The process number of the Perl running this script.  You should
731 consider this variable read-only, although it will be altered
732 across fork() calls.  (Mnemonic: same as shells.)
733
734 =item $REAL_USER_ID
735
736 =item $UID
737
738 =item $<
739
740 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
741 if you're running setuid.)  You can change both the real uid and
742 the effective uid at the same time by using POSIX::setuid().
743
744 =item $EFFECTIVE_USER_ID
745
746 =item $EUID
747
748 =item $>
749
750 The effective uid of this process.  Example:
751
752     $< = $>;            # set real to effective uid
753     ($<,$>) = ($>,$<);  # swap real and effective uid
754
755 You can change both the effective uid and the real uid at the same
756 time by using POSIX::setuid().
757
758 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
759 C<< $< >> and C<< $> >> can be swapped only on machines
760 supporting setreuid().
761
762 =item $REAL_GROUP_ID
763
764 =item $GID
765
766 =item $(
767
768 The real gid of this process.  If you are on a machine that supports
769 membership in multiple groups simultaneously, gives a space separated
770 list of groups you are in.  The first number is the one returned by
771 getgid(), and the subsequent ones by getgroups(), one of which may be
772 the same as the first number.
773
774 However, a value assigned to C<$(> must be a single number used to
775 set the real gid.  So the value given by C<$(> should I<not> be assigned
776 back to C<$(> without being forced numeric, such as by adding zero.
777
778 You can change both the real gid and the effective gid at the same
779 time by using POSIX::setgid().
780
781 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
782 group you I<left>, if you're running setgid.)
783
784 =item $EFFECTIVE_GROUP_ID
785
786 =item $EGID
787
788 =item $)
789
790 The effective gid of this process.  If you are on a machine that
791 supports membership in multiple groups simultaneously, gives a space
792 separated list of groups you are in.  The first number is the one
793 returned by getegid(), and the subsequent ones by getgroups(), one of
794 which may be the same as the first number.
795
796 Similarly, a value assigned to C<$)> must also be a space-separated
797 list of numbers.  The first number sets the effective gid, and
798 the rest (if any) are passed to setgroups().  To get the effect of an
799 empty list for setgroups(), just repeat the new effective gid; that is,
800 to force an effective gid of 5 and an effectively empty setgroups()
801 list, say C< $) = "5 5" >.
802
803 You can change both the effective gid and the real gid at the same
804 time by using POSIX::setgid() (use only a single numeric argument).
805
806 (Mnemonic: parentheses are used to I<group> things.  The effective gid
807 is the group that's I<right> for you, if you're running setgid.)
808
809 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
810 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
811 and C<$)> can be swapped only on machines supporting setregid().
812
813 =item $PROGRAM_NAME
814
815 =item $0
816
817 Contains the name of the program being executed.  On some operating
818 systems assigning to C<$0> modifies the argument area that the B<ps>
819 program sees.  This is more useful as a way of indicating the current
820 program state than it is for hiding the program you're running.
821 (Mnemonic: same as B<sh> and B<ksh>.)
822
823 Note for BSD users: setting C<$0> does not completely remove "perl"
824 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> will
825 result in C<"perl: foobar (perl)">.  This is an operating system
826 feature.
827
828 =item $[
829
830 The index of the first element in an array, and of the first character
831 in a substring.  Default is 0, but you could theoretically set it
832 to 1 to make Perl behave more like B<awk> (or Fortran) when
833 subscripting and when evaluating the index() and substr() functions.
834 (Mnemonic: [ begins subscripts.)
835
836 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
837 directive, and cannot influence the behavior of any other file.
838 Its use is highly discouraged.
839
840 =item $]
841
842 The version + patchlevel / 1000 of the Perl interpreter.  This variable
843 can be used to determine whether the Perl interpreter executing a
844 script is in the right range of versions.  (Mnemonic: Is this version
845 of perl in the right bracket?)  Example:
846
847     warn "No checksumming!\n" if $] < 3.019;
848
849 See also the documentation of C<use VERSION> and C<require VERSION>
850 for a convenient way to fail if the running Perl interpreter is too old.
851
852 The floating point representation can sometimes lead to inaccurate
853 numeric comparisons.  See C<$^V> for a more modern representation of
854 the Perl version that allows accurate string comparisons.
855
856 =item $COMPILING
857
858 =item $^C
859
860 The current value of the flag associated with the B<-c> switch.
861 Mainly of use with B<-MO=...> to allow code to alter its behavior
862 when being compiled, such as for example to AUTOLOAD at compile
863 time rather than normal, deferred loading.  See L<perlcc>.  Setting
864 C<$^C = 1> is similar to calling C<B::minus_c>.
865
866 =item $DEBUGGING
867
868 =item $^D
869
870 The current value of the debugging flags.  (Mnemonic: value of B<-D>
871 switch.)
872
873 =item $SYSTEM_FD_MAX
874
875 =item $^F
876
877 The maximum system file descriptor, ordinarily 2.  System file
878 descriptors are passed to exec()ed processes, while higher file
879 descriptors are not.  Also, during an open(), system file descriptors are
880 preserved even if the open() fails.  (Ordinary file descriptors are
881 closed before the open() is attempted.)  The close-on-exec
882 status of a file descriptor will be decided according to the value of
883 C<$^F> when the corresponding file, pipe, or socket was opened, not the
884 time of the exec().
885
886 =item $^H
887
888 WARNING: This variable is strictly for internal use only.  Its availability,
889 behavior, and contents are subject to change without notice.
890
891 This variable contains compile-time hints for the Perl interpreter.  At the
892 end of compilation of a BLOCK the value of this variable is restored to the
893 value when the interpreter started to compile the BLOCK.
894
895 When perl begins to parse any block construct that provides a lexical scope
896 (e.g., eval body, required file, subroutine body, loop body, or conditional
897 block), the existing value of $^H is saved, but its value is left unchanged.
898 When the compilation of the block is completed, it regains the saved value.
899 Between the points where its value is saved and restored, code that
900 executes within BEGIN blocks is free to change the value of $^H.
901
902 This behavior provides the semantic of lexical scoping, and is used in,
903 for instance, the C<use strict> pragma.
904
905 The contents should be an integer; different bits of it are used for
906 different pragmatic flags.  Here's an example:
907
908     sub add_100 { $^H |= 0x100 }
909
910     sub foo {
911         BEGIN { add_100() }
912         bar->baz($boon);
913     }
914
915 Consider what happens during execution of the BEGIN block.  At this point
916 the BEGIN block has already been compiled, but the body of foo() is still
917 being compiled.  The new value of $^H will therefore be visible only while
918 the body of foo() is being compiled.
919
920 Substitution of the above BEGIN block with:
921
922     BEGIN { require strict; strict->import('vars') }
923
924 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
925 version of the same lexical pragma:
926
927     BEGIN { require strict; strict->import('vars') if $condition }
928
929 =item %^H
930
931 WARNING: This variable is strictly for internal use only.  Its availability,
932 behavior, and contents are subject to change without notice.
933
934 The %^H hash provides the same scoping semantic as $^H.  This makes it
935 useful for implementation of lexically scoped pragmas.
936
937 =item $INPLACE_EDIT
938
939 =item $^I
940
941 The current value of the inplace-edit extension.  Use C<undef> to disable
942 inplace editing.  (Mnemonic: value of B<-i> switch.)
943
944 =item $^M
945
946 By default, running out of memory is an untrappable, fatal error.
947 However, if suitably built, Perl can use the contents of C<$^M>
948 as an emergency memory pool after die()ing.  Suppose that your Perl
949 were compiled with -DPERL_EMERGENCY_SBRK and used Perl's malloc.
950 Then
951
952     $^M = 'a' x (1 << 16);
953
954 would allocate a 64K buffer for use in an emergency.  See the
955 F<INSTALL> file in the Perl distribution for information on how to
956 enable this option.  To discourage casual use of this advanced
957 feature, there is no L<English|English> long name for this variable.
958
959 =item $OSNAME
960
961 =item $^O
962
963 The name of the operating system under which this copy of Perl was
964 built, as determined during the configuration process.  The value
965 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
966 B<-V> command-line switch documented in L<perlrun>.
967
968 =item ${^OPEN}
969
970 An internal variable used by PerlIO.  A string in two parts, separated
971 by a C<\0> byte, the first part is the input disciplines, the second
972 part is the output disciplines.
973
974 =item $PERLDB
975
976 =item $^P
977
978 The internal variable for debugging support.  The meanings of the
979 various bits are subject to change, but currently indicate:
980
981 =over 6
982
983 =item 0x01
984
985 Debug subroutine enter/exit.
986
987 =item 0x02
988
989 Line-by-line debugging.
990
991 =item 0x04
992
993 Switch off optimizations.
994
995 =item 0x08
996
997 Preserve more data for future interactive inspections.
998
999 =item 0x10
1000
1001 Keep info about source lines on which a subroutine is defined.
1002
1003 =item 0x20
1004
1005 Start with single-step on.
1006
1007 =item 0x40
1008
1009 Use subroutine address instead of name when reporting.
1010
1011 =item 0x80
1012
1013 Report C<goto &subroutine> as well.
1014
1015 =item 0x100
1016
1017 Provide informative "file" names for evals based on the place they were compiled.
1018
1019 =item 0x200
1020
1021 Provide informative names to anonymous subroutines based on the place they
1022 were compiled.
1023
1024 =back
1025
1026 Some bits may be relevant at compile-time only, some at
1027 run-time only.  This is a new mechanism and the details may change.
1028
1029 =item $LAST_REGEXP_CODE_RESULT
1030
1031 =item $^R
1032
1033 The result of evaluation of the last successful C<(?{ code })>
1034 regular expression assertion (see L<perlre>).  May be written to.
1035
1036 =item $EXCEPTIONS_BEING_CAUGHT
1037
1038 =item $^S
1039
1040 Current state of the interpreter.  Undefined if parsing of the current
1041 module/eval is not finished (may happen in $SIG{__DIE__} and
1042 $SIG{__WARN__} handlers).  True if inside an eval(), otherwise false.
1043
1044 =item $BASETIME
1045
1046 =item $^T
1047
1048 The time at which the program began running, in seconds since the
1049 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1050 and B<-C> filetests are based on this value.
1051
1052 =item ${^TAINT}
1053
1054 Reflects if taint mode is on or off (i.e. if the program was run with
1055 B<-T> or not).  True for on, false for off.
1056
1057 =item $PERL_VERSION
1058
1059 =item $^V
1060
1061 The revision, version, and subversion of the Perl interpreter, represented
1062 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1063 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1064 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1065 potentially be in Unicode range.
1066
1067 This can be used to determine whether the Perl interpreter executing a
1068 script is in the right range of versions.  (Mnemonic: use ^V for Version
1069 Control.)  Example:
1070
1071     warn "No \"our\" declarations!\n" if $^V and $^V lt v5.6.0;
1072
1073 See the documentation of C<use VERSION> and C<require VERSION>
1074 for a convenient way to fail if the running Perl interpreter is too old.
1075
1076 See also C<$]> for an older representation of the Perl version.
1077
1078 =item $WARNING
1079
1080 =item $^W
1081
1082 The current value of the warning switch, initially true if B<-w>
1083 was used, false otherwise, but directly modifiable.  (Mnemonic:
1084 related to the B<-w> switch.)  See also L<warnings>.
1085
1086 =item ${^WARNING_BITS}
1087
1088 The current set of warning checks enabled by the C<use warnings> pragma.
1089 See the documentation of C<warnings> for more details.
1090
1091 =item ${^WIDE_SYSTEM_CALLS}
1092
1093 Global flag that enables system calls made by Perl to use wide character
1094 APIs native to the system, if available.  This is currently only implemented
1095 on the Windows platform.
1096
1097 This can also be enabled from the command line using the C<-C> switch.
1098
1099 The initial value is typically C<0> for compatibility with Perl versions
1100 earlier than 5.6, but may be automatically set to C<1> by Perl if the system
1101 provides a user-settable default (e.g., C<$ENV{LC_CTYPE}>).
1102
1103 The C<bytes> pragma always overrides the effect of this flag in the current
1104 lexical scope.  See L<bytes>.
1105
1106 =item $EXECUTABLE_NAME
1107
1108 =item $^X
1109
1110 The name that the Perl binary itself was executed as, from C's C<argv[0]>.
1111 This may not be a full pathname, nor even necessarily in your path.
1112
1113 =item ARGV
1114
1115 The special filehandle that iterates over command-line filenames in
1116 C<@ARGV>. Usually written as the null filehandle in the angle operator
1117 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1118 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1119 corresponding to the last file opened by C<< <> >>. In particular,
1120 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1121 may not cause your function to automatically read the contents of all the
1122 files in C<@ARGV>.
1123
1124 =item $ARGV
1125
1126 contains the name of the current file when reading from <>.
1127
1128 =item @ARGV
1129
1130 The array @ARGV contains the command-line arguments intended for
1131 the script.  C<$#ARGV> is generally the number of arguments minus
1132 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1133 command name itself.  See C<$0> for the command name.
1134
1135 =item @F
1136
1137 The array @F contains the fields of each line read in when autosplit
1138 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1139 is package-specific, and must be declared or given a full package name
1140 if not in package main when running under C<strict 'vars'>.
1141
1142 =item @INC
1143
1144 The array @INC contains the list of places that the C<do EXPR>,
1145 C<require>, or C<use> constructs look for their library files.  It
1146 initially consists of the arguments to any B<-I> command-line
1147 switches, followed by the default Perl library, probably
1148 F</usr/local/lib/perl>, followed by ".", to represent the current
1149 directory.  If you need to modify this at runtime, you should use
1150 the C<use lib> pragma to get the machine-dependent library properly
1151 loaded also:
1152
1153     use lib '/mypath/libdir/';
1154     use SomeMod;
1155
1156 You can also insert hooks into the file inclusion system by putting Perl
1157 code directly into @INC.  Those hooks may be subroutine references, array
1158 references or blessed objects.  See L<perlfunc/require> for details.
1159
1160 =item @_
1161
1162 Within a subroutine the array @_ contains the parameters passed to that
1163 subroutine.  See L<perlsub>.
1164
1165 =item %INC
1166
1167 The hash %INC contains entries for each filename included via the
1168 C<do>, C<require>, or C<use> operators.  The key is the filename
1169 you specified (with module names converted to pathnames), and the
1170 value is the location of the file found.  The C<require>
1171 operator uses this hash to determine whether a particular file has
1172 already been included.
1173
1174 If the file was loaded via a hook (e.g. a subroutine reference, see
1175 L<perlfunc/require> for a description of these hooks), this hook is
1176 by default inserted into %INC in place of a filename.  Note, however,
1177 that the hook may have set the %INC entry by itself to provide some more
1178 specific info.
1179
1180 =item %ENV
1181
1182 =item $ENV{expr}
1183
1184 The hash %ENV contains your current environment.  Setting a
1185 value in C<ENV> changes the environment for any child processes
1186 you subsequently fork() off.
1187
1188 =item %SIG
1189
1190 =item $SIG{expr}
1191
1192 The hash %SIG contains signal handlers for signals.  For example:
1193
1194     sub handler {       # 1st argument is signal name
1195         my($sig) = @_;
1196         print "Caught a SIG$sig--shutting down\n";
1197         close(LOG);
1198         exit(0);
1199     }
1200
1201     $SIG{'INT'}  = \&handler;
1202     $SIG{'QUIT'} = \&handler;
1203     ...
1204     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1205     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1206
1207 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1208 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1209 this special case.
1210
1211 Here are some other examples:
1212
1213     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1214     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1215     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1216     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1217
1218 Be sure not to use a bareword as the name of a signal handler,
1219 lest you inadvertently call it. 
1220
1221 If your system has the sigaction() function then signal handlers are
1222 installed using it.  This means you get reliable signal handling.  If
1223 your system has the SA_RESTART flag it is used when signals handlers are
1224 installed.  This means that system calls for which restarting is supported
1225 continue rather than returning when a signal arrives.  If you want your
1226 system calls to be interrupted by signal delivery then do something like
1227 this:
1228
1229     use POSIX ':signal_h';
1230
1231     my $alarm = 0;
1232     sigaction SIGALRM, new POSIX::SigAction sub { $alarm = 1 }
1233         or die "Error setting SIGALRM handler: $!\n";
1234
1235 See L<POSIX>.
1236
1237 Certain internal hooks can be also set using the %SIG hash.  The
1238 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1239 about to be printed.  The warning message is passed as the first
1240 argument.  The presence of a __WARN__ hook causes the ordinary printing
1241 of warnings to STDERR to be suppressed.  You can use this to save warnings
1242 in a variable, or turn warnings into fatal errors, like this:
1243
1244     local $SIG{__WARN__} = sub { die $_[0] };
1245     eval $proggie;
1246
1247 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1248 is about to be thrown.  The error message is passed as the first
1249 argument.  When a __DIE__ hook routine returns, the exception
1250 processing continues as it would have in the absence of the hook,
1251 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
1252 The C<__DIE__> handler is explicitly disabled during the call, so that you
1253 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1254
1255 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1256 even inside an eval().  Do not use this to rewrite a pending exception
1257 in C<$@>, or as a bizarre substitute for overriding CORE::GLOBAL::die().
1258 This strange action at a distance may be fixed in a future release
1259 so that C<$SIG{__DIE__}> is only called if your program is about
1260 to exit, as was the original intent.  Any other use is deprecated.
1261
1262 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1263 they may be called to report (probable) errors found by the parser.
1264 In such a case the parser may be in inconsistent state, so any
1265 attempt to evaluate Perl code from such a handler will probably
1266 result in a segfault.  This means that warnings or errors that
1267 result from parsing Perl should be used with extreme caution, like
1268 this:
1269
1270     require Carp if defined $^S;
1271     Carp::confess("Something wrong") if defined &Carp::confess;
1272     die "Something wrong, but could not load Carp to give backtrace...
1273          To see backtrace try starting Perl with -MCarp switch";
1274
1275 Here the first line will load Carp I<unless> it is the parser who
1276 called the handler.  The second line will print backtrace and die if
1277 Carp was available.  The third line will be executed only if Carp was
1278 not available.
1279
1280 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1281 L<warnings> for additional information.
1282
1283 =back
1284
1285 =head2 Error Indicators
1286
1287 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1288 about different types of error conditions that may appear during
1289 execution of a Perl program.  The variables are shown ordered by
1290 the "distance" between the subsystem which reported the error and
1291 the Perl process.  They correspond to errors detected by the Perl
1292 interpreter, C library, operating system, or an external program,
1293 respectively.
1294
1295 To illustrate the differences between these variables, consider the 
1296 following Perl expression, which uses a single-quoted string:
1297
1298     eval q{
1299         open my $pipe, "/cdrom/install |" or die $!;
1300         my @res = <$pipe>;
1301         close $pipe or die "bad pipe: $?, $!";
1302     };
1303
1304 After execution of this statement all 4 variables may have been set.  
1305
1306 C<$@> is set if the string to be C<eval>-ed did not compile (this
1307 may happen if C<open> or C<close> were imported with bad prototypes),
1308 or if Perl code executed during evaluation die()d .  In these cases
1309 the value of $@ is the compile error, or the argument to C<die>
1310 (which will interpolate C<$!> and C<$?>!).  (See also L<Fatal>,
1311 though.)
1312
1313 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1314 and C<close> are translated to calls in the C run-time library and
1315 thence to the operating system kernel.  C<$!> is set to the C library's
1316 C<errno> if one of these calls fails. 
1317
1318 Under a few operating systems, C<$^E> may contain a more verbose
1319 error indicator, such as in this case, "CDROM tray not closed."
1320 Systems that do not support extended error messages leave C<$^E>
1321 the same as C<$!>.
1322
1323 Finally, C<$?> may be set to non-0 value if the external program
1324 F</cdrom/install> fails.  The upper eight bits reflect specific
1325 error conditions encountered by the program (the program's exit()
1326 value).   The lower eight bits reflect mode of failure, like signal
1327 death and core dump information  See wait(2) for details.  In
1328 contrast to C<$!> and C<$^E>, which are set only if error condition
1329 is detected, the variable C<$?> is set on each C<wait> or pipe
1330 C<close>, overwriting the old value.  This is more like C<$@>, which
1331 on every eval() is always set on failure and cleared on success.
1332
1333 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1334 and C<$?>.
1335
1336 =head2 Technical Note on the Syntax of Variable Names
1337
1338 Variable names in Perl can have several formats.  Usually, they
1339 must begin with a letter or underscore, in which case they can be
1340 arbitrarily long (up to an internal limit of 251 characters) and
1341 may contain letters, digits, underscores, or the special sequence
1342 C<::> or C<'>.  In this case, the part before the last C<::> or
1343 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1344
1345 Perl variable names may also be a sequence of digits or a single
1346 punctuation or control character.  These names are all reserved for
1347 special uses by Perl; for example, the all-digits names are used
1348 to hold data captured by backreferences after a regular expression
1349 match.  Perl has a special syntax for the single-control-character
1350 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1351 character.  For example, the notation C<$^W> (dollar-sign caret
1352 C<W>) is the scalar variable whose name is the single character
1353 control-C<W>.  This is better than typing a literal control-C<W>
1354 into your program.
1355
1356 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1357 strings that begin with control characters (or better yet, a caret).
1358 These variables must be written in the form C<${^Foo}>; the braces
1359 are not optional.  C<${^Foo}> denotes the scalar variable whose
1360 name is a control-C<F> followed by two C<o>'s.  These variables are
1361 reserved for future special uses by Perl, except for the ones that
1362 begin with C<^_> (control-underscore or caret-underscore).  No
1363 control-character name that begins with C<^_> will acquire a special
1364 meaning in any future version of Perl; such names may therefore be
1365 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1366
1367 Perl identifiers that begin with digits, control characters, or
1368 punctuation characters are exempt from the effects of the C<package>
1369 declaration and are always forced to be in package C<main>.  A few
1370 other names are also exempt:
1371
1372         ENV             STDIN
1373         INC             STDOUT
1374         ARGV            STDERR
1375         ARGVOUT
1376         SIG
1377
1378 In particular, the new special C<${^_XYZ}> variables are always taken
1379 to be in package C<main>, regardless of any C<package> declarations
1380 presently in scope.
1381
1382 =head1 BUGS
1383
1384 Due to an unfortunate accident of Perl's implementation, C<use
1385 English> imposes a considerable performance penalty on all regular
1386 expression matches in a program, regardless of whether they occur
1387 in the scope of C<use English>.  For that reason, saying C<use
1388 English> in libraries is strongly discouraged.  See the
1389 Devel::SawAmpersand module documentation from CPAN
1390 (http://www.cpan.org/modules/by-module/Devel/)
1391 for more information.
1392
1393 Having to even think about the C<$^S> variable in your exception
1394 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1395 invites grievous and difficult to track down errors.  Avoid it
1396 and use an C<END{}> or CORE::GLOBAL::die override instead.