This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[win32] merge changes#872,873 from maintbranch
[perl5.git] / pod / perlsec.pod
1 =head1 NAME
2
3 perlsec - Perl security
4
5 =head1 DESCRIPTION
6
7 Perl is designed to make it easy to program securely even when running
8 with extra privileges, like setuid or setgid programs.  Unlike most
9 command line shells, which are based on multiple substitution passes on
10 each line of the script, Perl uses a more conventional evaluation scheme
11 with fewer hidden snags.  Additionally, because the language has more
12 builtin functionality, it can rely less upon external (and possibly
13 untrustworthy) programs to accomplish its purposes.
14
15 Perl automatically enables a set of special security checks, called I<taint
16 mode>, when it detects its program running with differing real and effective
17 user or group IDs.  The setuid bit in Unix permissions is mode 04000, the
18 setgid bit mode 02000; either or both may be set.  You can also enable taint
19 mode explicitly by using the B<-T> command line flag. This flag is
20 I<strongly> suggested for server programs and any program run on behalf of
21 someone else, such as a CGI script. Once taint mode is on, it's on for
22 the remainder of your script.
23
24 While in this mode, Perl takes special precautions called I<taint
25 checks> to prevent both obvious and subtle traps.  Some of these checks
26 are reasonably simple, such as verifying that path directories aren't
27 writable by others; careful programmers have always used checks like
28 these.  Other checks, however, are best supported by the language itself,
29 and it is these checks especially that contribute to making a set-id Perl
30 program more secure than the corresponding C program.
31
32 You may not use data derived from outside your program to affect
33 something else outside your program--at least, not by accident.  All
34 command line arguments, environment variables, locale information (see
35 L<perllocale>), results of certain system calls (readdir, readlink,
36 the gecos field of getpw* calls), and all file input are marked as
37 "tainted".  Tainted data may not be used directly or indirectly in any
38 command that invokes a sub-shell, nor in any command that modifies
39 files, directories, or processes. (B<Important exception>: If you pass
40 a list of arguments to either C<system> or C<exec>, the elements of
41 that list are B<NOT> checked for taintedness.) Any variable set
42 to a value derived from tainted data will itself be tainted,
43 even if it is logically impossible for the tainted data
44 to alter the variable.  Because taintedness is associated with each
45 scalar value, some elements of an array can be tainted and others not.
46
47 For example:
48
49     $arg = shift;               # $arg is tainted
50     $hid = $arg, 'bar';         # $hid is also tainted
51     $line = <>;                 # Tainted
52     $line = <STDIN>;            # Also tainted
53     open FOO, "/home/me/bar" or die $!;
54     $line = <FOO>;              # Still tainted
55     $path = $ENV{'PATH'};       # Tainted, but see below
56     $data = 'abc';              # Not tainted
57
58     system "echo $arg";         # Insecure
59     system "/bin/echo", $arg;   # Secure (doesn't use sh)
60     system "echo $hid";         # Insecure
61     system "echo $data";        # Insecure until PATH set
62
63     $path = $ENV{'PATH'};       # $path now tainted
64
65     $ENV{'PATH'} = '/bin:/usr/bin';
66     delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
67
68     $path = $ENV{'PATH'};       # $path now NOT tainted
69     system "echo $data";        # Is secure now!
70
71     open(FOO, "< $arg");        # OK - read-only file
72     open(FOO, "> $arg");        # Not OK - trying to write
73
74     open(FOO,"echo $arg|");     # Not OK, but...
75     open(FOO,"-|")
76         or exec 'echo', $arg;   # OK
77
78     $shout = `echo $arg`;       # Insecure, $shout now tainted
79
80     unlink $data, $arg;         # Insecure
81     umask $arg;                 # Insecure
82
83     exec "echo $arg";           # Insecure
84     exec "echo", $arg;          # Secure (doesn't use the shell)
85     exec "sh", '-c', $arg;      # Considered secure, alas!
86
87     @files = <*.c>;             # Always insecure (uses csh)
88     @files = glob('*.c');       # Always insecure (uses csh)
89
90 If you try to do something insecure, you will get a fatal error saying
91 something like "Insecure dependency" or "Insecure PATH".  Note that you
92 can still write an insecure B<system> or B<exec>, but only by explicitly
93 doing something like the "considered secure" example above.
94
95 =head2 Laundering and Detecting Tainted Data
96
97 To test whether a variable contains tainted data, and whose use would thus
98 trigger an "Insecure dependency" message, check your nearby CPAN mirror
99 for the F<Taint.pm> module, which should become available around November
100 1997.  Or you may be able to use the following I<is_tainted()> function.
101
102     sub is_tainted {
103         return ! eval {
104             join('',@_), kill 0;
105             1;
106         };
107     }
108
109 This function makes use of the fact that the presence of tainted data
110 anywhere within an expression renders the entire expression tainted.  It
111 would be inefficient for every operator to test every argument for
112 taintedness.  Instead, the slightly more efficient and conservative
113 approach is used that if any tainted value has been accessed within the
114 same expression, the whole expression is considered tainted.
115
116 But testing for taintedness gets you only so far.  Sometimes you have just
117 to clear your data's taintedness.  The only way to bypass the tainting
118 mechanism is by referencing subpatterns from a regular expression match.
119 Perl presumes that if you reference a substring using $1, $2, etc., that
120 you knew what you were doing when you wrote the pattern.  That means using
121 a bit of thought--don't just blindly untaint anything, or you defeat the
122 entire mechanism.  It's better to verify that the variable has only good
123 characters (for certain values of "good") rather than checking whether it
124 has any bad characters.  That's because it's far too easy to miss bad
125 characters that you never thought of.
126
127 Here's a test to make sure that the data contains nothing but "word"
128 characters (alphabetics, numerics, and underscores), a hyphen, an at sign,
129 or a dot.
130
131     if ($data =~ /^([-\@\w.]+)$/) {
132         $data = $1;                     # $data now untainted
133     } else {
134         die "Bad data in $data";        # log this somewhere
135     }
136
137 This is fairly secure because C</\w+/> doesn't normally match shell
138 metacharacters, nor are dot, dash, or at going to mean something special
139 to the shell.  Use of C</.+/> would have been insecure in theory because
140 it lets everything through, but Perl doesn't check for that.  The lesson
141 is that when untainting, you must be exceedingly careful with your patterns.
142 Laundering data using regular expression is the I<ONLY> mechanism for
143 untainting dirty data, unless you use the strategy detailed below to fork
144 a child of lesser privilege.
145
146 The example does not untaint $data if C<use locale> is in effect,
147 because the characters matched by C<\w> are determined by the locale.
148 Perl considers that locale definitions are untrustworthy because they
149 contain data from outside the program.  If you are writing a
150 locale-aware program, and want to launder data with a regular expression
151 containing C<\w>, put C<no locale> ahead of the expression in the same
152 block.  See L<perllocale/SECURITY> for further discussion and examples.
153
154 =head2 Switches On the "#!" Line
155
156 When you make a script executable, in order to make it usable as a
157 command, the system will pass switches to perl from the script's #!
158 line.  Perl checks that any command line switches given to a setuid
159 (or setgid) script actually match the ones set on the #! line.  Some
160 Unix and Unix-like environments impose a one-switch limit on the #!
161 line, so you may need to use something like C<-wU> instead of C<-w -U>
162 under such systems.  (This issue should arise only in Unix or
163 Unix-like environments that support #! and setuid or setgid scripts.)
164
165 =head2 Cleaning Up Your Path
166
167 For "Insecure C<$ENV{PATH}>" messages, you need to set C<$ENV{'PATH'}> to a
168 known value, and each directory in the path must be non-writable by others
169 than its owner and group.  You may be surprised to get this message even
170 if the pathname to your executable is fully qualified.  This is I<not>
171 generated because you didn't supply a full path to the program; instead,
172 it's generated because you never set your PATH environment variable, or
173 you didn't set it to something that was safe.  Because Perl can't
174 guarantee that the executable in question isn't itself going to turn
175 around and execute some other program that is dependent on your PATH, it
176 makes sure you set the PATH.
177
178 The PATH isn't the only environment variable which can cause problems.
179 Because some shells may use the variables IFS, CDPATH, ENV, and
180 BASH_ENV, Perl checks that those are either empty or untainted when
181 starting subprocesses. You may wish to add something like this to your
182 setid and taint-checking scripts.
183
184     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};   # Make %ENV safer
185
186 It's also possible to get into trouble with other operations that don't
187 care whether they use tainted values.  Make judicious use of the file
188 tests in dealing with any user-supplied filenames.  When possible, do
189 opens and such B<after> properly dropping any special user (or group!)
190 privileges. Perl doesn't prevent you from opening tainted filenames for reading,
191 so be careful what you print out.  The tainting mechanism is intended to
192 prevent stupid mistakes, not to remove the need for thought.
193
194 Perl does not call the shell to expand wild cards when you pass B<system>
195 and B<exec> explicit parameter lists instead of strings with possible shell
196 wildcards in them.  Unfortunately, the B<open>, B<glob>, and
197 backtick functions provide no such alternate calling convention, so more
198 subterfuge will be required.
199
200 Perl provides a reasonably safe way to open a file or pipe from a setuid
201 or setgid program: just create a child process with reduced privilege who
202 does the dirty work for you.  First, fork a child using the special
203 B<open> syntax that connects the parent and child by a pipe.  Now the
204 child resets its ID set and any other per-process attributes, like
205 environment variables, umasks, current working directories, back to the
206 originals or known safe values.  Then the child process, which no longer
207 has any special permissions, does the B<open> or other system call.
208 Finally, the child passes the data it managed to access back to the
209 parent.  Because the file or pipe was opened in the child while running
210 under less privilege than the parent, it's not apt to be tricked into
211 doing something it shouldn't.
212
213 Here's a way to do backticks reasonably safely.  Notice how the B<exec> is
214 not called with a string that the shell could expand.  This is by far the
215 best way to call something that might be subjected to shell escapes: just
216 never call the shell at all.  
217
218     use English;
219     die "Can't fork: $!" unless defined $pid = open(KID, "-|");
220     if ($pid) {           # parent
221         while (<KID>) {
222             # do something
223         }
224         close KID;
225     } else {
226         my @temp = ($EUID, $EGID);
227         $EUID = $UID;
228         $EGID = $GID;    # XXX: initgroups() not called
229         # Make sure privs are really gone
230         ($EUID, $EGID) = @temp;
231         die "Can't drop privileges" unless
232             $UID == $EUID and
233             $GID eq $EGID;      # String test
234         $ENV{PATH} = "/bin:/usr/bin";
235         exec 'myprog', 'arg1', 'arg2' or
236         die "can't exec myprog: $!";
237     }
238
239 A similar strategy would work for wildcard expansion via C<glob>, although
240 you can use C<readdir> instead.
241
242 Taint checking is most useful when although you trust yourself not to have
243 written a program to give away the farm, you don't necessarily trust those
244 who end up using it not to try to trick it into doing something bad.  This
245 is the kind of security checking that's useful for set-id programs and
246 programs launched on someone else's behalf, like CGI programs.
247
248 This is quite different, however, from not even trusting the writer of the
249 code not to try to do something evil.  That's the kind of trust needed
250 when someone hands you a program you've never seen before and says, "Here,
251 run this."  For that kind of safety, check out the Safe module,
252 included standard in the Perl distribution.  This module allows the
253 programmer to set up special compartments in which all system operations
254 are trapped and namespace access is carefully controlled.
255
256 =head2 Security Bugs
257
258 Beyond the obvious problems that stem from giving special privileges to
259 systems as flexible as scripts, on many versions of Unix, set-id scripts
260 are inherently insecure right from the start.  The problem is a race
261 condition in the kernel.  Between the time the kernel opens the file to
262 see which interpreter to run and when the (now-set-id) interpreter turns
263 around and reopens the file to interpret it, the file in question may have
264 changed, especially if you have symbolic links on your system.
265
266 Fortunately, sometimes this kernel "feature" can be disabled.
267 Unfortunately, there are two ways to disable it.  The system can simply
268 outlaw scripts with any set-id bit set, which doesn't help much.
269 Alternately, it can simply ignore the set-id bits on scripts.  If the
270 latter is true, Perl can emulate the setuid and setgid mechanism when it
271 notices the otherwise useless setuid/gid bits on Perl scripts.  It does
272 this via a special executable called B<suidperl> that is automatically
273 invoked for you if it's needed.
274
275 However, if the kernel set-id script feature isn't disabled, Perl will
276 complain loudly that your set-id script is insecure.  You'll need to
277 either disable the kernel set-id script feature, or put a C wrapper around
278 the script.  A C wrapper is just a compiled program that does nothing
279 except call your Perl program.   Compiled programs are not subject to the
280 kernel bug that plagues set-id scripts.  Here's a simple wrapper, written
281 in C:
282
283     #define REAL_PATH "/path/to/script"
284     main(ac, av)
285         char **av;
286     {
287         execv(REAL_PATH, av);
288     }
289
290 Compile this wrapper into a binary executable and then make I<it> rather
291 than your script setuid or setgid.
292
293 See the program B<wrapsuid> in the F<eg> directory of your Perl
294 distribution for a convenient way to do this automatically for all your
295 setuid Perl programs.  It moves setuid scripts into files with the same
296 name plus a leading dot, and then compiles a wrapper like the one above
297 for each of them.
298
299 In recent years, vendors have begun to supply systems free of this
300 inherent security bug.  On such systems, when the kernel passes the name
301 of the set-id script to open to the interpreter, rather than using a
302 pathname subject to meddling, it instead passes I</dev/fd/3>.  This is a
303 special file already opened on the script, so that there can be no race
304 condition for evil scripts to exploit.  On these systems, Perl should be
305 compiled with C<-DSETUID_SCRIPTS_ARE_SECURE_NOW>.  The B<Configure>
306 program that builds Perl tries to figure this out for itself, so you
307 should never have to specify this yourself.  Most modern releases of
308 SysVr4 and BSD 4.4 use this approach to avoid the kernel race condition.
309
310 Prior to release 5.003 of Perl, a bug in the code of B<suidperl> could
311 introduce a security hole in systems compiled with strict POSIX
312 compliance.
313
314 =head2 Protecting Your Programs
315
316 There are a number of ways to hide the source to your Perl programs,
317 with varying levels of "security".
318
319 First of all, however, you I<can't> take away read permission, because
320 the source code has to be readable in order to be compiled and
321 interpreted.  (That doesn't mean that a CGI script's source is
322 readable by people on the web, though.)  So you have to leave the
323 permissions at the socially friendly 0755 level.
324
325 Some people regard this as a security problem.  If your program does
326 insecure things, and relies on people not knowing how to exploit those
327 insecurities, it is not secure.  It is often possible for someone to
328 determine the insecure things and exploit them without viewing the
329 source.  Security through obscurity, the name for hiding your bugs
330 instead of fixing them, is little security indeed.
331
332 You can try using encryption via source filters (Filter::* from CPAN).
333 But crackers might be able to decrypt it.  You can try using the
334 byte code compiler and interpreter described below, but crackers might
335 be able to de-compile it.  You can try using the native-code compiler
336 described below, but crackers might be able to disassemble it.  These
337 pose varying degrees of difficulty to people wanting to get at your
338 code, but none can definitively conceal it (this is true of every
339 language, not just Perl).
340
341 If you're concerned about people profiting from your code, then the
342 bottom line is that nothing but a restrictive licence will give you
343 legal security.  License your software and pepper it with threatening
344 statements like "This is unpublished proprietary software of XYZ Corp.
345 Your access to it does not give you permission to use it blah blah
346 blah."  You should see a lawyer to be sure your licence's wording will
347 stand up in court.