This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[win32] merge changes#872,873 from maintbranch
[perl5.git] / pod / perlrun.pod
1 =head1 NAME
2
3 perlrun - how to execute the Perl interpreter
4
5 =head1 SYNOPSIS
6
7 B<perl> S<[ B<-sTuU> ]>
8         S<[ B<-hv> ] [ B<-V>[:I<configvar>] ]>
9         S<[ B<-cw> ] [ B<-d>[:I<debugger>] ] [ B<-D>[I<number/list>] ]>
10         S<[ B<-pna> ] [ B<-F>I<pattern> ] [ B<-l>[I<octal>] ] [ B<-0>[I<octal>] ]>
11         S<[ B<-I>I<dir> ] [ B<-m>[B<->]I<module> ] [ B<-M>[B<->]I<'module...'> ]>
12         S<[ B<-P> ]>
13         S<[ B<-S> ]>
14         S<[ B<-x>[I<dir>] ]>
15         S<[ B<-i>[I<extension>] ]>
16         S<[ B<-e> I<'command'> ] [ B<--> ] [ I<programfile> ] [ I<argument> ]...>
17
18 =head1 DESCRIPTION
19
20 Upon startup, Perl looks for your script in one of the following
21 places:
22
23 =over 4
24
25 =item 1.
26
27 Specified line by line via B<-e> switches on the command line.
28
29 =item 2.
30
31 Contained in the file specified by the first filename on the command line.
32 (Note that systems supporting the #! notation invoke interpreters this
33 way. See L<Location of Perl>.)
34
35 =item 3.
36
37 Passed in implicitly via standard input.  This works only if there are
38 no filename arguments--to pass arguments to a STDIN script you
39 must explicitly specify a "-" for the script name.
40
41 =back
42
43 With methods 2 and 3, Perl starts parsing the input file from the
44 beginning, unless you've specified a B<-x> switch, in which case it
45 scans for the first line starting with #! and containing the word
46 "perl", and starts there instead.  This is useful for running a script
47 embedded in a larger message.  (In this case you would indicate the end
48 of the script using the C<__END__> token.)
49
50 The #! line is always examined for switches as the line is being
51 parsed.  Thus, if you're on a machine that allows only one argument
52 with the #! line, or worse, doesn't even recognize the #! line, you
53 still can get consistent switch behavior regardless of how Perl was
54 invoked, even if B<-x> was used to find the beginning of the script.
55
56 Because many operating systems silently chop off kernel interpretation of
57 the #! line after 32 characters, some switches may be passed in on the
58 command line, and some may not; you could even get a "-" without its
59 letter, if you're not careful.  You probably want to make sure that all
60 your switches fall either before or after that 32 character boundary.
61 Most switches don't actually care if they're processed redundantly, but
62 getting a - instead of a complete switch could cause Perl to try to
63 execute standard input instead of your script.  And a partial B<-I> switch
64 could also cause odd results.
65
66 Some switches do care if they are processed twice, for instance combinations
67 of B<-l> and B<-0>.  Either put all the switches after the 32 character
68 boundary (if applicable), or replace the use of B<-0>I<digits> by 
69 C<BEGIN{ $/ = "\0digits"; }>.
70
71 Parsing of the #! switches starts wherever "perl" is mentioned in the line.
72 The sequences "-*" and "- " are specifically ignored so that you could,
73 if you were so inclined, say
74
75     #!/bin/sh -- # -*- perl -*- -p
76     eval 'exec /usr/bin/perl -wS $0 ${1+"$@"}'
77         if $running_under_some_shell;
78
79 to let Perl see the B<-p> switch.
80
81 If the #! line does not contain the word "perl", the program named after
82 the #! is executed instead of the Perl interpreter.  This is slightly
83 bizarre, but it helps people on machines that don't do #!, because they
84 can tell a program that their SHELL is /usr/bin/perl, and Perl will then
85 dispatch the program to the correct interpreter for them.
86
87 After locating your script, Perl compiles the entire script to an
88 internal form.  If there are any compilation errors, execution of the
89 script is not attempted.  (This is unlike the typical shell script,
90 which might run part-way through before finding a syntax error.)
91
92 If the script is syntactically correct, it is executed.  If the script
93 runs off the end without hitting an exit() or die() operator, an implicit
94 C<exit(0)> is provided to indicate successful completion.
95
96 =head2 #! and quoting on non-Unix systems
97
98 Unix's #! technique can be simulated on other systems:
99
100 =over 4
101
102 =item OS/2
103
104 Put
105
106     extproc perl -S -your_switches
107
108 as the first line in C<*.cmd> file (C<-S> due to a bug in cmd.exe's
109 `extproc' handling).
110
111 =item MS-DOS
112
113 Create a batch file to run your script, and codify it in
114 C<ALTERNATIVE_SHEBANG> (see the F<dosish.h> file in the source
115 distribution for more information).
116
117 =item Win95/NT
118
119 The Win95/NT installation, when using the Activeware port of Perl,
120 will modify the Registry to associate the .pl extension with the perl
121 interpreter.  If you install another port of Perl, including the one
122 in the Win32 directory of the Perl distribution, then you'll have to
123 modify the Registry yourself.
124
125 =item Macintosh
126
127 Macintosh perl scripts will have the appropriate Creator and
128 Type, so that double-clicking them will invoke the perl application.
129
130 =back
131
132 Command-interpreters on non-Unix systems have rather different ideas
133 on quoting than Unix shells.  You'll need to learn the special
134 characters in your command-interpreter (C<*>, C<\> and C<"> are
135 common) and how to protect whitespace and these characters to run
136 one-liners (see C<-e> below).
137
138 On some systems, you may have to change single-quotes to double ones,
139 which you must I<NOT> do on Unix or Plan9 systems.  You might also
140 have to change a single % to a %%.
141
142 For example:
143
144     # Unix
145     perl -e 'print "Hello world\n"'
146
147     # MS-DOS, etc.
148     perl -e "print \"Hello world\n\""
149
150     # Macintosh
151     print "Hello world\n"
152      (then Run "Myscript" or Shift-Command-R)
153
154     # VMS
155     perl -e "print ""Hello world\n"""
156
157 The problem is that none of this is reliable: it depends on the command
158 and it is entirely possible neither works.  If 4DOS was the command shell, this would
159 probably work better:
160
161     perl -e "print <Ctrl-x>"Hello world\n<Ctrl-x>""
162
163 CMD.EXE in Windows NT slipped a lot of standard Unix functionality in
164 when nobody was looking, but just try to find documentation for its
165 quoting rules.
166
167 Under the Macintosh, it depends which environment you are using.  The MacPerl
168 shell, or MPW, is much like Unix shells in its support for several
169 quoting variants, except that it makes free use of the Macintosh's non-ASCII
170 characters as control characters.
171
172 There is no general solution to all of this.  It's just a mess.
173
174 =head2 Location of Perl
175
176 It may seem obvious to say, but Perl is useful only when users can
177 easily find it. When possible, it's good for both B</usr/bin/perl> and
178 B</usr/local/bin/perl> to be symlinks to the actual binary. If that
179 can't be done, system administrators are strongly encouraged to put
180 (symlinks to) perl and its accompanying utilities, such as perldoc, into
181 a directory typically found along a user's PATH, or in another obvious
182 and convenient place.
183
184 In this documentation, C<#!/usr/bin/perl> on the first line of the script
185 will stand in for whatever method works on your system.
186
187 =head2 Switches
188
189 A single-character switch may be combined with the following switch, if
190 any.
191
192     #!/usr/bin/perl -spi.bak    # same as -s -p -i.bak
193
194 Switches include:
195
196 =over 5
197
198 =item B<-0>[I<digits>]
199
200 specifies the input record separator (C<$/>) as an octal number.  If there are
201 no digits, the null character is the separator.  Other switches may
202 precede or follow the digits.  For example, if you have a version of
203 B<find> which can print filenames terminated by the null character, you
204 can say this:
205
206     find . -name '*.bak' -print0 | perl -n0e unlink
207
208 The special value 00 will cause Perl to slurp files in paragraph mode.
209 The value 0777 will cause Perl to slurp files whole because there is no
210 legal character with that value.
211
212 =item B<-a>
213
214 turns on autosplit mode when used with a B<-n> or B<-p>.  An implicit
215 split command to the @F array is done as the first thing inside the
216 implicit while loop produced by the B<-n> or B<-p>.
217
218     perl -ane 'print pop(@F), "\n";'
219
220 is equivalent to
221
222     while (<>) {
223         @F = split(' ');
224         print pop(@F), "\n";
225     }
226
227 An alternate delimiter may be specified using B<-F>.
228
229 =item B<-c>
230
231 causes Perl to check the syntax of the script and then exit without
232 executing it.  Actually, it I<will> execute C<BEGIN>, C<END>, and C<use> blocks,
233 because these are considered as occurring outside the execution of
234 your program.
235
236 =item B<-d>
237
238 runs the script under the Perl debugger.  See L<perldebug>.
239
240 =item B<-d:>I<foo>
241
242 runs the script under the control of a debugging or tracing module
243 installed as Devel::foo. E.g., B<-d:DProf> executes the script using the
244 Devel::DProf profiler.  See L<perldebug>.
245
246 =item B<-D>I<letters>
247
248 =item B<-D>I<number>
249
250 sets debugging flags.  To watch how it executes your script, use
251 B<-Dtls>.  (This works only if debugging is compiled into your
252 Perl.)  Another nice value is B<-Dx>, which lists your compiled
253 syntax tree.  And B<-Dr> displays compiled regular expressions. As an
254 alternative, specify a number instead of list of letters (e.g., B<-D14> is
255 equivalent to B<-Dtls>):
256
257         1  p  Tokenizing and parsing
258         2  s  Stack snapshots
259         4  l  Context (loop) stack processing
260         8  t  Trace execution
261        16  o  Method and overloading resolution
262        32  c  String/numeric conversions
263        64  P  Print preprocessor command for -P
264       128  m  Memory allocation
265       256  f  Format processing
266       512  r  Regular expression parsing and execution
267      1024  x  Syntax tree dump
268      2048  u  Tainting checks
269      4096  L  Memory leaks (needs C<-DLEAKTEST> when compiling Perl)
270      8192  H  Hash dump -- usurps values()
271     16384  X  Scratchpad allocation
272     32768  D  Cleaning up
273
274 All these flags require C<-DDEBUGGING> when you compile the Perl
275 executable.  This flag is automatically set if you include C<-g>
276 option when C<Configure> asks you about optimizer/debugger flags.
277
278 =item B<-e> I<commandline>
279
280 may be used to enter one line of script.
281 If B<-e> is given, Perl
282 will not look for a script filename in the argument list.
283 Multiple B<-e> commands may
284 be given to build up a multi-line script.
285 Make sure to use semicolons where you would in a normal program.
286
287 =item B<-F>I<pattern>
288
289 specifies the pattern to split on if B<-a> is also in effect.  The
290 pattern may be surrounded by C<//>, C<"">, or C<''>, otherwise it will be
291 put in single quotes.
292
293 =item B<-h>
294
295 prints a summary of the options.
296
297 =item B<-i>[I<extension>]
298
299 specifies that files processed by the C<E<lt>E<gt>> construct are to be edited
300 in-place.  It does this by renaming the input file, opening the output
301 file by the original name, and selecting that output file as the default
302 for print() statements.  The extension, if supplied, is added to the name
303 of the old file to make a backup copy.  If no extension is supplied, no
304 backup is made.  From the shell, saying
305
306     $ perl -p -i.bak -e "s/foo/bar/; ... "
307
308 is the same as using the script:
309
310     #!/usr/bin/perl -pi.bak
311     s/foo/bar/;
312
313 which is equivalent to
314
315     #!/usr/bin/perl
316     while (<>) {
317         if ($ARGV ne $oldargv) {
318             rename($ARGV, $ARGV . '.bak');
319             open(ARGVOUT, ">$ARGV");
320             select(ARGVOUT);
321             $oldargv = $ARGV;
322         }
323         s/foo/bar/;
324     }
325     continue {
326         print;  # this prints to original filename
327     }
328     select(STDOUT);
329
330 except that the B<-i> form doesn't need to compare $ARGV to $oldargv to
331 know when the filename has changed.  It does, however, use ARGVOUT for
332 the selected filehandle.  Note that STDOUT is restored as the
333 default output filehandle after the loop.
334
335 You can use C<eof> without parenthesis to locate the end of each input file,
336 in case you want to append to each file, or reset line numbering (see
337 example in L<perlfunc/eof>).
338
339 =item B<-I>I<directory>
340
341 Directories specified by B<-I> are prepended to the search path for
342 modules (C<@INC>), and also tells the C preprocessor where to search for
343 include files.  The C preprocessor is invoked with B<-P>; by default it
344 searches /usr/include and /usr/lib/perl.
345
346 =item B<-l>[I<octnum>]
347
348 enables automatic line-ending processing.  It has two effects:  first,
349 it automatically chomps "C<$/>" (the input record separator) when used
350 with B<-n> or B<-p>, and second, it assigns "C<$\>"
351 (the output record separator) to have the value of I<octnum> so that
352 any print statements will have that separator added back on.  If
353 I<octnum> is omitted, sets "C<$\>" to the current value of "C<$/>".  For
354 instance, to trim lines to 80 columns:
355
356     perl -lpe 'substr($_, 80) = ""'
357
358 Note that the assignment C<$\ = $/> is done when the switch is processed,
359 so the input record separator can be different than the output record
360 separator if the B<-l> switch is followed by a B<-0> switch:
361
362     gnufind / -print0 | perl -ln0e 'print "found $_" if -p'
363
364 This sets C<$\> to newline and then sets C<$/> to the null character.
365
366 =item B<-m>[B<->]I<module>
367
368 =item B<-M>[B<->]I<module>
369
370 =item B<-M>[B<->]I<'module ...'>
371
372 =item B<-[mM]>[B<->]I<module=arg[,arg]...>
373
374 C<-m>I<module> executes C<use> I<module> C<();> before executing your
375 script.
376
377 C<-M>I<module> executes C<use> I<module> C<;> before executing your
378 script.  You can use quotes to add extra code after the module name,
379 e.g., C<-M'module qw(foo bar)'>.
380
381 If the first character after the C<-M> or C<-m> is a dash (C<->)
382 then the 'use' is replaced with 'no'.
383
384 A little builtin syntactic sugar means you can also say
385 C<-mmodule=foo,bar> or C<-Mmodule=foo,bar> as a shortcut for
386 C<-M'module qw(foo bar)'>.  This avoids the need to use quotes when
387 importing symbols.  The actual code generated by C<-Mmodule=foo,bar> is
388 C<use module split(/,/,q{foo,bar})>.  Note that the C<=> form
389 removes the distinction between C<-m> and C<-M>.
390
391 =item B<-n>
392
393 causes Perl to assume the following loop around your script, which
394 makes it iterate over filename arguments somewhat like B<sed -n> or
395 B<awk>:
396
397     while (<>) {
398         ...             # your script goes here
399     }
400
401 Note that the lines are not printed by default.  See B<-p> to have
402 lines printed.  If a file named by an argument cannot be opened for
403 some reason, Perl warns you about it, and moves on to the next file.
404
405 Here is an efficient way to delete all files older than a week:
406
407     find . -mtime +7 -print | perl -nle 'unlink;'
408
409 This is faster than using the C<-exec> switch of B<find> because you don't
410 have to start a process on every filename found.
411
412 C<BEGIN> and C<END> blocks may be used to capture control before or after
413 the implicit loop, just as in B<awk>.
414
415 =item B<-p>
416
417 causes Perl to assume the following loop around your script, which
418 makes it iterate over filename arguments somewhat like B<sed>:
419
420
421     while (<>) {
422         ...             # your script goes here
423     } continue {
424         print or die "-p destination: $!\n";
425     }
426
427 If a file named by an argument cannot be opened for some reason, Perl
428 warns you about it, and moves on to the next file.  Note that the
429 lines are printed automatically.  An error occuring during printing is
430 treated as fatal.  To suppress printing use the B<-n> switch.  A B<-p>
431 overrides a B<-n> switch.
432
433 C<BEGIN> and C<END> blocks may be used to capture control before or after
434 the implicit loop, just as in awk.
435
436 =item B<-P>
437
438 causes your script to be run through the C preprocessor before
439 compilation by Perl.  (Because both comments and cpp directives begin
440 with the # character, you should avoid starting comments with any words
441 recognized by the C preprocessor such as "if", "else", or "define".)
442
443 =item B<-s>
444
445 enables some rudimentary switch parsing for switches on the command
446 line after the script name but before any filename arguments (or before
447 a B<-->).  Any switch found there is removed from @ARGV and sets the
448 corresponding variable in the Perl script.  The following script
449 prints "true" if and only if the script is invoked with a B<-xyz> switch.
450
451     #!/usr/bin/perl -s
452     if ($xyz) { print "true\n"; }
453
454 =item B<-S>
455
456 makes Perl use the PATH environment variable to search for the
457 script (unless the name of the script contains directory separators).
458 On some platforms, this also makes Perl append suffixes to the
459 filename while searching for it.  For example, on Win32 platforms,
460 the ".bat" and ".cmd" suffixes are appended if a lookup for the
461 original name fails, and if the name does not already end in one
462 of those suffixes.  If your Perl was compiled with DEBUGGING turned
463 on, using the -Dp switch to Perl shows how the search progresses.
464
465 If the filename supplied contains directory separators (i.e. it is an
466 absolute or relative pathname), and if the file is not found,
467 platforms that append file extensions will do so and try to look
468 for the file with those extensions added, one by one.
469
470 On DOS-like platforms, if the script does not contain directory
471 separators, it will first be searched for in the current directory
472 before being searched for on the PATH.  On Unix platforms, the
473 script will be searched for strictly on the PATH.
474
475 Typically this is used to emulate #! startup on platforms that
476 don't support #!.  This example works on many platforms that
477 have a shell compatible with Bourne shell:
478
479     #!/usr/bin/perl
480     eval 'exec /usr/bin/perl -wS $0 ${1+"$@"}'
481             if $running_under_some_shell;
482
483 The system ignores the first line and feeds the script to /bin/sh,
484 which proceeds to try to execute the Perl script as a shell script.
485 The shell executes the second line as a normal shell command, and thus
486 starts up the Perl interpreter.  On some systems $0 doesn't always
487 contain the full pathname, so the B<-S> tells Perl to search for the
488 script if necessary.  After Perl locates the script, it parses the
489 lines and ignores them because the variable $running_under_some_shell
490 is never true. If the script will be interpreted by csh, you will need
491 to replace C<${1+"$@"}> with C<$*>, even though that doesn't understand
492 embedded spaces (and such) in the argument list.  To start up sh rather
493 than csh, some systems may have to replace the #! line with a line
494 containing just a colon, which will be politely ignored by Perl.  Other
495 systems can't control that, and need a totally devious construct that
496 will work under any of csh, sh, or Perl, such as the following:
497
498         eval '(exit $?0)' && eval 'exec /usr/bin/perl -wS $0 ${1+"$@"}'
499         & eval 'exec /usr/bin/perl -wS $0 $argv:q'
500                 if $running_under_some_shell;
501
502 =item B<-T>
503
504 forces "taint" checks to be turned on so you can test them.  Ordinarily
505 these checks are done only when running setuid or setgid.  It's a good
506 idea to turn them on explicitly for programs run on another's behalf,
507 such as CGI programs.  See L<perlsec>.  Note that (for security reasons)
508 this option must be seen by Perl quite early; usually this means it must
509 appear early on the command line or in the #! line (for systems which
510 support that).
511
512 =item B<-u>
513
514 causes Perl to dump core after compiling your script.  You can then
515 take this core dump and turn it into an executable file by using the
516 B<undump> program (not supplied).  This speeds startup at the expense of
517 some disk space (which you can minimize by stripping the executable).
518 (Still, a "hello world" executable comes out to about 200K on my
519 machine.)  If you want to execute a portion of your script before dumping,
520 use the dump() operator instead.  Note: availability of B<undump> is
521 platform specific and may not be available for a specific port of
522 Perl.
523
524 =item B<-U>
525
526 allows Perl to do unsafe operations.  Currently the only "unsafe"
527 operations are the unlinking of directories while running as superuser,
528 and running setuid programs with fatal taint checks turned into
529 warnings. Note that the B<-w> switch (or the C<$^W> variable) must
530 be used along with this option to actually B<generate> the
531 taint-check warnings.
532
533 =item B<-v>
534
535 prints the version and patchlevel of your Perl executable.
536
537 =item B<-V>
538
539 prints summary of the major perl configuration values and the current
540 value of @INC.
541
542 =item B<-V:>I<name>
543
544 Prints to STDOUT the value of the named configuration variable.
545
546 =item B<-w>
547
548 prints warnings about variable names that are mentioned only once, and
549 scalar variables that are used before being set.  Also warns about
550 redefined subroutines, and references to undefined filehandles or
551 filehandles opened read-only that you are attempting to write on.  Also
552 warns you if you use values as a number that doesn't look like numbers,
553 using an array as though it were a scalar, if your subroutines recurse
554 more than 100 deep, and innumerable other things.
555
556 You can disable specific warnings using C<__WARN__> hooks, as described
557 in L<perlvar> and L<perlfunc/warn>. See also L<perldiag> and L<perltrap>.
558
559 =item B<-x> I<directory>
560
561 tells Perl that the script is embedded in a message.  Leading
562 garbage will be discarded until the first line that starts with #! and
563 contains the string "perl".  Any meaningful switches on that line will
564 be applied.  If a directory name is specified, Perl will switch to
565 that directory before running the script.  The B<-x> switch controls
566 only the disposal of leading garbage.  The script must be
567 terminated with C<__END__> if there is trailing garbage to be ignored (the
568 script can process any or all of the trailing garbage via the DATA
569 filehandle if desired).
570
571 =back
572
573 =head1 ENVIRONMENT
574
575 =over 12
576
577 =item HOME
578
579 Used if chdir has no argument.
580
581 =item LOGDIR
582
583 Used if chdir has no argument and HOME is not set.
584
585 =item PATH
586
587 Used in executing subprocesses, and in finding the script if B<-S> is
588 used.
589
590 =item PERL5LIB
591
592 A colon-separated list of directories in which to look for Perl library
593 files before looking in the standard library and the current
594 directory.  If PERL5LIB is not defined, PERLLIB is used.  When running
595 taint checks (because the script was running setuid or setgid, or the
596 B<-T> switch was used), neither variable is used.  The script should
597 instead say
598
599     use lib "/my/directory";
600
601 =item PERL5OPT
602
603 Command-line options (switches).  Switches in this variable are taken
604 as if they were on every Perl command line.  Only the B<-[DIMUdmw]>
605 switches are allowed.  When running taint checks (because the script
606 was running setuid or setgid, or the B<-T> switch was used), this
607 variable is ignored.
608
609 =item PERLLIB
610
611 A colon-separated list of directories in which to look for Perl library
612 files before looking in the standard library and the current directory.
613 If PERL5LIB is defined, PERLLIB is not used.
614
615 =item PERL5DB
616
617 The command used to load the debugger code.  The default is:
618
619         BEGIN { require 'perl5db.pl' }
620
621 =item PERL5SHELL (specific to WIN32 port)
622
623 May be set to an alternative shell that perl must use internally for
624 executing "backtick" commands or system().  Default is C<cmd.exe /x/c>
625 on WindowsNT and C<command.com /c> on Windows95.  The value is considered
626 to be space delimited.  Precede any character that needs to be protected
627 (like a space or backslash) with a backslash.
628
629 Note that Perl doesn't use COMSPEC for this purpose because
630 COMSPEC has a high degree of variability among users, leading to
631 portability concerns.  Besides, perl can use a shell that may not be
632 fit for interactive use, and setting COMSPEC to such a shell may
633 interfere with the proper functioning of other programs (which usually
634 look in COMSPEC to find a shell fit for interactive use).
635
636 =item PERL_DEBUG_MSTATS
637
638 Relevant only if perl is compiled with the malloc included with the perl
639 distribution (that is, if C<perl -V:d_mymalloc> is 'define').
640 If set, this causes memory statistics to be dumped after execution.  If set
641 to an integer greater than one, also causes memory statistics to be dumped
642 after compilation.
643
644 =item PERL_DESTRUCT_LEVEL
645
646 Relevant only if your perl executable was built with B<-DDEBUGGING>,
647 this controls the behavior of global destruction of objects and other
648 references.
649
650 =back
651
652 Perl also has environment variables that control how Perl handles data
653 specific to particular natural languages.  See L<perllocale>.
654
655 Apart from these, Perl uses no other environment variables, except
656 to make them available to the script being executed, and to child
657 processes.  However, scripts running setuid would do well to execute
658 the following lines before doing anything else, just to keep people
659 honest:
660
661     $ENV{PATH} = '/bin:/usr/bin';    # or whatever you need
662     $ENV{SHELL} = '/bin/sh' if exists $ENV{SHELL};
663     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
664