This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[win32] merge changes#872,873 from maintbranch
[perl5.git] / pod / perlfunc.pod
1
2 =head1 NAME
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar and list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one list argument.)  For instance, splice() has three scalar
20 arguments followed by a list.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 For functions that can be used in either a scalar or list context,
52 nonabortive failure is generally indicated in a scalar context by
53 returning the undefined value, and in a list context by returning the
54 null list.
55
56 Remember the following rule:
57
58 =over 8
59
60 =item  I<THERE IS NO GENERAL RULE FOR CONVERTING A LIST INTO A SCALAR!>
61
62 =back
63
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in a scalar context.  Some operators return the
66 length of the list that would have been returned in a list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 =head2 Perl Functions by Category
73
74 Here are Perl's functions (including things that look like
75 functions, like some of the keywords and named operators)
76 arranged by category.  Some functions appear in more
77 than one place.
78
79 =over
80
81 =item Functions for SCALARs or strings
82
83 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
84 C<length>, C<oct>, C<ord>, C<pack>, C<q>/STRING/, C<qq>/STRING/, C<reverse>,
85 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y>///
86
87 =item Regular expressions and pattern matching
88
89 C<m>//, C<pos>, C<quotemeta>, C<s>///, C<split>, C<study>
90
91 =item Numeric functions
92
93 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
94 C<sin>, C<sqrt>, C<srand>
95
96 =item Functions for real @ARRAYs
97
98 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
99
100 =item Functions for list data
101
102 C<grep>, C<join>, C<map>, C<qw>/STRING/, C<reverse>, C<sort>, C<unpack>
103
104 =item Functions for real %HASHes
105
106 C<delete>, C<each>, C<exists>, C<keys>, C<values>
107
108 =item Input and output functions
109
110 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
111 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
112 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
113 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
114 C<warn>, C<write>
115
116 =item Functions for fixed length data or records
117
118 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
119
120 =item Functions for filehandles, files, or directories
121
122 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
123 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>, C<readlink>,
124 C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>, C<unlink>, C<utime>
125
126 =item Keywords related to the control flow of your perl program
127
128 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
129 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
130
131 =item Keywords related to scoping
132
133 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
134
135 =item Miscellaneous functions
136
137 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
138 C<scalar>, C<undef>, C<wantarray>
139
140 =item Functions for processes and process groups
141
142 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
143 C<pipe>, C<qx>/STRING/, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
144 C<times>, C<wait>, C<waitpid>
145
146 =item Keywords related to perl modules
147
148 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
149
150 =item Keywords related to classes and object-orientedness
151
152 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
153 C<untie>, C<use>
154
155 =item Low-level socket functions
156
157 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
158 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
159 C<socket>, C<socketpair>
160
161 =item System V interprocess communication functions
162
163 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
164 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
165
166 =item Fetching user and group info
167
168 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
169 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
170 C<getpwuid>, C<setgrent>, C<setpwent>
171
172 =item Fetching network info
173
174 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
175 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
176 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
177 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
178 C<setnetent>, C<setprotoent>, C<setservent>
179
180 =item Time-related functions
181
182 C<gmtime>, C<localtime>, C<time>, C<times>
183
184 =item Functions new in perl5
185
186 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
187 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
188 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
189 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
190
191 * - C<sub> was a keyword in perl4, but in perl5 it is an
192 operator which can be used in expressions.
193
194 =item Functions obsoleted in perl5
195
196 C<dbmclose>, C<dbmopen>
197
198 =back
199
200 =head2 Alphabetical Listing of Perl Functions
201
202 =over 8
203
204 =item I<-X> FILEHANDLE
205
206 =item I<-X> EXPR
207
208 =item I<-X>
209
210 A file test, where X is one of the letters listed below.  This unary
211 operator takes one argument, either a filename or a filehandle, and
212 tests the associated file to see if something is true about it.  If the
213 argument is omitted, tests $_, except for C<-t>, which tests STDIN.
214 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
215 the undefined value if the file doesn't exist.  Despite the funny
216 names, precedence is the same as any other named unary operator, and
217 the argument may be parenthesized like any other unary operator.  The
218 operator may be any of:
219
220     -r  File is readable by effective uid/gid.
221     -w  File is writable by effective uid/gid.
222     -x  File is executable by effective uid/gid.
223     -o  File is owned by effective uid.
224
225     -R  File is readable by real uid/gid.
226     -W  File is writable by real uid/gid.
227     -X  File is executable by real uid/gid.
228     -O  File is owned by real uid.
229
230     -e  File exists.
231     -z  File has zero size.
232     -s  File has nonzero size (returns size).
233
234     -f  File is a plain file.
235     -d  File is a directory.
236     -l  File is a symbolic link.
237     -p  File is a named pipe (FIFO).
238     -S  File is a socket.
239     -b  File is a block special file.
240     -c  File is a character special file.
241     -t  Filehandle is opened to a tty.
242
243     -u  File has setuid bit set.
244     -g  File has setgid bit set.
245     -k  File has sticky bit set.
246
247     -T  File is a text file.
248     -B  File is a binary file (opposite of -T).
249
250     -M  Age of file in days when script started.
251     -A  Same for access time.
252     -C  Same for inode change time.
253
254 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
255 C<-W>, C<-x>, and C<-X> is based solely on the mode of the file and the
256 uids and gids of the user.  There may be other reasons you can't actually
257 read, write or execute the file.  Also note that, for the superuser,
258 C<-r>, C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return
259 1 if any execute bit is set in the mode.  Scripts run by the superuser may
260 thus need to do a stat() to determine the actual mode of the
261 file, or temporarily set the uid to something else.
262
263 Example:
264
265     while (<>) {
266         chop;
267         next unless -f $_;      # ignore specials
268         ...
269     }
270
271 Note that C<-s/a/b/> does not do a negated substitution.  Saying
272 C<-exp($foo)> still works as expected, however--only single letters
273 following a minus are interpreted as file tests.
274
275 The C<-T> and C<-B> switches work as follows.  The first block or so of the
276 file is examined for odd characters such as strange control codes or
277 characters with the high bit set.  If too many odd characters (E<gt>30%)
278 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
279 containing null in the first block is considered a binary file.  If C<-T>
280 or C<-B> is used on a filehandle, the current stdio buffer is examined
281 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
282 file, or a file at EOF when testing a filehandle.  Because you have to
283 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
284 against the file first, as in C<next unless -f $file && -T $file>.
285
286 If any of the file tests (or either the stat() or lstat() operators) are given
287 the special filehandle consisting of a solitary underline, then the stat
288 structure of the previous file test (or stat operator) is used, saving
289 a system call.  (This doesn't work with C<-t>, and you need to remember
290 that lstat() and C<-l> will leave values in the stat structure for the
291 symbolic link, not the real file.)  Example:
292
293     print "Can do.\n" if -r $a || -w _ || -x _;
294
295     stat($filename);
296     print "Readable\n" if -r _;
297     print "Writable\n" if -w _;
298     print "Executable\n" if -x _;
299     print "Setuid\n" if -u _;
300     print "Setgid\n" if -g _;
301     print "Sticky\n" if -k _;
302     print "Text\n" if -T _;
303     print "Binary\n" if -B _;
304
305 =item abs VALUE
306
307 =item abs
308
309 Returns the absolute value of its argument.
310 If VALUE is omitted, uses $_.
311
312 =item accept NEWSOCKET,GENERICSOCKET
313
314 Accepts an incoming socket connect, just as the accept(2) system call
315 does.  Returns the packed address if it succeeded, FALSE otherwise.
316 See example in L<perlipc/"Sockets: Client/Server Communication">.
317
318 =item alarm SECONDS
319
320 =item alarm
321
322 Arranges to have a SIGALRM delivered to this process after the
323 specified number of seconds have elapsed.  If SECONDS is not specified,
324 the value stored in $_ is used. (On some machines,
325 unfortunately, the elapsed time may be up to one second less than you
326 specified because of how seconds are counted.)  Only one timer may be
327 counting at once.  Each call disables the previous timer, and an
328 argument of 0 may be supplied to cancel the previous timer without
329 starting a new one.  The returned value is the amount of time remaining
330 on the previous timer.
331
332 For delays of finer granularity than one second, you may use Perl's
333 syscall() interface to access setitimer(2) if your system supports it,
334 or else see L</select()>.  It is usually a mistake to intermix alarm()
335 and sleep() calls.
336
337 If you want to use alarm() to time out a system call you need to use an
338 eval/die pair.  You can't rely on the alarm causing the system call to
339 fail with $! set to EINTR because Perl sets up signal handlers to
340 restart system calls on some systems.  Using eval/die always works.
341
342     eval {
343         local $SIG{ALRM} = sub { die "alarm\n" };       # NB \n required
344         alarm $timeout;
345         $nread = sysread SOCKET, $buffer, $size;
346         alarm 0;
347     };
348     die if $@ && $@ ne "alarm\n";       # propagate errors
349     if ($@) {
350         # timed out
351     }
352     else {
353         # didn't
354     }
355
356 =item atan2 Y,X
357
358 Returns the arctangent of Y/X in the range -PI to PI.
359
360 For the tangent operation, you may use the POSIX::tan()
361 function, or use the familiar relation:
362
363     sub tan { sin($_[0]) / cos($_[0])  }
364
365 =item bind SOCKET,NAME
366
367 Binds a network address to a socket, just as the bind system call
368 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
369 packed address of the appropriate type for the socket.  See the examples in
370 L<perlipc/"Sockets: Client/Server Communication">.
371
372 =item binmode FILEHANDLE
373
374 Arranges for the file to be read or written in "binary" mode in operating
375 systems that distinguish between binary and text files.  Files that are
376 not in binary mode have CR LF sequences translated to LF on input and LF
377 translated to CR LF on output.  Binmode has no effect under Unix; in MS-DOS
378 and similarly archaic systems, it may be imperative--otherwise your
379 MS-DOS-damaged C library may mangle your file.  The key distinction between
380 systems that need binmode and those that don't is their text file
381 formats.  Systems like Unix and Plan9 that delimit lines with a single
382 character, and that encode that character in C as '\n', do not need
383 C<binmode>.  The rest need it.  If FILEHANDLE is an expression, the value
384 is taken as the name of the filehandle.
385
386 =item bless REF,CLASSNAME
387
388 =item bless REF
389
390 This function tells the thingy referenced by REF that it is now
391 an object in the CLASSNAME package--or the current package if no CLASSNAME
392 is specified, which is often the case.  It returns the reference for
393 convenience, because a bless() is often the last thing in a constructor.
394 Always use the two-argument version if the function doing the blessing
395 might be inherited by a derived class.  See L<perlobj> for more about the
396 blessing (and blessings) of objects.
397
398 =item caller EXPR
399
400 =item caller
401
402 Returns the context of the current subroutine call.  In a scalar context,
403 returns the caller's package name if there is a caller, that is, if
404 we're in a subroutine or eval() or require(), and the undefined value
405 otherwise.  In a list context, returns
406
407     ($package, $filename, $line) = caller;
408
409 With EXPR, it returns some extra information that the debugger uses to
410 print a stack trace.  The value of EXPR indicates how many call frames
411 to go back before the current one.
412
413     ($package, $filename, $line, $subroutine,
414      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
415
416 Here $subroutine may be C<"(eval)"> if the frame is not a subroutine
417 call, but an C<eval>.  In such a case additional elements $evaltext and
418 $is_require are set: $is_require is true if the frame is created by a
419 C<require> or C<use> statement, $evaltext contains the text of the
420 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
421 $filename is C<"(eval)">, but $evaltext is undefined.  (Note also that
422 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
423 frame.
424
425 Furthermore, when called from within the DB package, caller returns more
426 detailed information: it sets the list variable @DB::args to be the
427 arguments with which the subroutine was invoked.
428
429 =item chdir EXPR
430
431 Changes the working directory to EXPR, if possible.  If EXPR is
432 omitted, changes to home directory.  Returns TRUE upon success, FALSE
433 otherwise.  See example under die().
434
435 =item chmod LIST
436
437 Changes the permissions of a list of files.  The first element of the
438 list must be the numerical mode, which should probably be an octal
439 number, and which definitely should I<not> a string of octal digits:
440 C<0644> is okay, C<'0644'> is not.  Returns the number of files
441 successfully changed.  See also L</oct>, if all you have is a string.
442
443     $cnt = chmod 0755, 'foo', 'bar';
444     chmod 0755, @executables;
445     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to --w----r-T
446     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
447     $mode = 0644;   chmod $mode, 'foo';      # this is best
448
449 =item chomp VARIABLE
450
451 =item chomp LIST
452
453 =item chomp
454
455 This is a slightly safer version of L</chop>.  It removes any
456 line ending that corresponds to the current value of C<$/> (also known as
457 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
458 number of characters removed from all its arguments.  It's often used to
459 remove the newline from the end of an input record when you're worried
460 that the final record may be missing its newline.  When in paragraph mode
461 (C<$/ = "">), it removes all trailing newlines from the string.  If
462 VARIABLE is omitted, it chomps $_.  Example:
463
464     while (<>) {
465         chomp;  # avoid \n on last field
466         @array = split(/:/);
467         ...
468     }
469
470 You can actually chomp anything that's an lvalue, including an assignment:
471
472     chomp($cwd = `pwd`);
473     chomp($answer = <STDIN>);
474
475 If you chomp a list, each element is chomped, and the total number of
476 characters removed is returned.
477
478 =item chop VARIABLE
479
480 =item chop LIST
481
482 =item chop
483
484 Chops off the last character of a string and returns the character
485 chopped.  It's used primarily to remove the newline from the end of an
486 input record, but is much more efficient than C<s/\n//> because it neither
487 scans nor copies the string.  If VARIABLE is omitted, chops $_.
488 Example:
489
490     while (<>) {
491         chop;   # avoid \n on last field
492         @array = split(/:/);
493         ...
494     }
495
496 You can actually chop anything that's an lvalue, including an assignment:
497
498     chop($cwd = `pwd`);
499     chop($answer = <STDIN>);
500
501 If you chop a list, each element is chopped.  Only the value of the
502 last chop is returned.
503
504 Note that chop returns the last character.  To return all but the last
505 character, use C<substr($string, 0, -1)>.
506
507 =item chown LIST
508
509 Changes the owner (and group) of a list of files.  The first two
510 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
511 Returns the number of files successfully changed.
512
513     $cnt = chown $uid, $gid, 'foo', 'bar';
514     chown $uid, $gid, @filenames;
515
516 Here's an example that looks up nonnumeric uids in the passwd file:
517
518     print "User: ";
519     chop($user = <STDIN>);
520     print "Files: "
521     chop($pattern = <STDIN>);
522
523     ($login,$pass,$uid,$gid) = getpwnam($user)
524         or die "$user not in passwd file";
525
526     @ary = <${pattern}>;        # expand filenames
527     chown $uid, $gid, @ary;
528
529 On most systems, you are not allowed to change the ownership of the
530 file unless you're the superuser, although you should be able to change
531 the group to any of your secondary groups.  On insecure systems, these
532 restrictions may be relaxed, but this is not a portable assumption.
533
534 =item chr NUMBER
535
536 =item chr
537
538 Returns the character represented by that NUMBER in the character set.
539 For example, C<chr(65)> is "A" in ASCII.  For the reverse, use L</ord>.
540
541 If NUMBER is omitted, uses $_.
542
543 =item chroot FILENAME
544
545 =item chroot
546
547 This function works as the system call by the same name: it makes the
548 named directory the new root directory for all further pathnames that
549 begin with a "/" by your process and all of its children.  (It doesn't
550 change your current working directory, which is unaffected.)  For security
551 reasons, this call is restricted to the superuser.  If FILENAME is
552 omitted, does chroot to $_.
553
554 =item close FILEHANDLE
555
556 Closes the file or pipe associated with the file handle, returning TRUE
557 only if stdio successfully flushes buffers and closes the system file
558 descriptor.
559
560 You don't have to close FILEHANDLE if you are immediately going to do
561 another open() on it, because open() will close it for you.  (See
562 open().)  However, an explicit close on an input file resets the line
563 counter ($.), while the implicit close done by open() does not.
564
565 If the file handle came from a piped open C<close> will additionally
566 return FALSE if one of the other system calls involved fails or if the
567 program exits with non-zero status.  (If the only problem was that the
568 program exited non-zero $! will be set to 0.) Also, closing a pipe will
569 wait for the process executing on the pipe to complete, in case you
570 want to look at the output of the pipe afterwards.  Closing a pipe
571 explicitly also puts the exit status value of the command into C<$?>.
572 Example:
573
574     open(OUTPUT, '|sort >foo')  # pipe to sort
575         or die "Can't start sort: $!";
576     ...                         # print stuff to output
577     close OUTPUT                # wait for sort to finish
578         or warn $! ? "Error closing sort pipe: $!"
579                    : "Exit status $? from sort";
580     open(INPUT, 'foo')          # get sort's results
581         or die "Can't open 'foo' for input: $!";
582
583 FILEHANDLE may be an expression whose value gives the real filehandle name.
584
585 =item closedir DIRHANDLE
586
587 Closes a directory opened by opendir().
588
589 =item connect SOCKET,NAME
590
591 Attempts to connect to a remote socket, just as the connect system call
592 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
593 packed address of the appropriate type for the socket.  See the examples in
594 L<perlipc/"Sockets: Client/Server Communication">.
595
596 =item continue BLOCK
597
598 Actually a flow control statement rather than a function.  If there is a
599 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
600 C<foreach>), it is always executed just before the conditional is about to
601 be evaluated again, just like the third part of a C<for> loop in C.  Thus
602 it can be used to increment a loop variable, even when the loop has been
603 continued via the C<next> statement (which is similar to the C C<continue>
604 statement).
605
606 =item cos EXPR
607
608 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted
609 takes cosine of $_.
610
611 For the inverse cosine operation, you may use the POSIX::acos()
612 function, or use this relation:
613
614     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
615
616 =item crypt PLAINTEXT,SALT
617
618 Encrypts a string exactly like the crypt(3) function in the C library
619 (assuming that you actually have a version there that has not been
620 extirpated as a potential munition).  This can prove useful for checking
621 the password file for lousy passwords, amongst other things.  Only the
622 guys wearing white hats should do this.
623
624 Note that crypt is intended to be a one-way function, much like breaking
625 eggs to make an omelette.  There is no (known) corresponding decrypt
626 function.  As a result, this function isn't all that useful for
627 cryptography.  (For that, see your nearby CPAN mirror.)
628
629 Here's an example that makes sure that whoever runs this program knows
630 their own password:
631
632     $pwd = (getpwuid($<))[1];
633     $salt = substr($pwd, 0, 2);
634
635     system "stty -echo";
636     print "Password: ";
637     chop($word = <STDIN>);
638     print "\n";
639     system "stty echo";
640
641     if (crypt($word, $salt) ne $pwd) {
642         die "Sorry...\n";
643     } else {
644         print "ok\n";
645     }
646
647 Of course, typing in your own password to whoever asks you
648 for it is unwise.
649
650 =item dbmclose HASH
651
652 [This function has been superseded by the untie() function.]
653
654 Breaks the binding between a DBM file and a hash.
655
656 =item dbmopen HASH,DBNAME,MODE
657
658 [This function has been superseded by the tie() function.]
659
660 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(), or Berkeley DB file to a
661 hash.  HASH is the name of the hash.  (Unlike normal open, the first
662 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
663 is the name of the database (without the F<.dir> or F<.pag> extension if
664 any).  If the database does not exist, it is created with protection
665 specified by MODE (as modified by the umask()).  If your system supports
666 only the older DBM functions, you may perform only one dbmopen() in your
667 program.  In older versions of Perl, if your system had neither DBM nor
668 ndbm, calling dbmopen() produced a fatal error; it now falls back to
669 sdbm(3).
670
671 If you don't have write access to the DBM file, you can only read hash
672 variables, not set them.  If you want to test whether you can write,
673 either use file tests or try setting a dummy hash entry inside an eval(),
674 which will trap the error.
675
676 Note that functions such as keys() and values() may return huge array
677 values when used on large DBM files.  You may prefer to use the each()
678 function to iterate over large DBM files.  Example:
679
680     # print out history file offsets
681     dbmopen(%HIST,'/usr/lib/news/history',0666);
682     while (($key,$val) = each %HIST) {
683         print $key, ' = ', unpack('L',$val), "\n";
684     }
685     dbmclose(%HIST);
686
687 See also L<AnyDBM_File> for a more general description of the pros and
688 cons of the various dbm approaches, as well as L<DB_File> for a particularly
689 rich implementation.
690
691 =item defined EXPR
692
693 =item defined
694
695 Returns a Boolean value telling whether EXPR has a value other than
696 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
697 checked.
698
699 Many operations return C<undef> to indicate failure, end of file,
700 system error, uninitialized variable, and other exceptional
701 conditions.  This function allows you to distinguish C<undef> from
702 other values.  (A simple Boolean test will not distinguish among
703 C<undef>, zero, the empty string, and "0", which are all equally
704 false.)  Note that since C<undef> is a valid scalar, its presence
705 doesn't I<necessarily> indicate an exceptional condition: pop()
706 returns C<undef> when its argument is an empty array, I<or> when the
707 element to return happens to be C<undef>.
708
709 You may also use defined() to check whether a subroutine exists.  On
710 the other hand, use of defined() upon aggregates (hashes and arrays)
711 is not guaranteed to produce intuitive results, and should probably be
712 avoided.
713
714 When used on a hash element, it tells you whether the value is defined,
715 not whether the key exists in the hash.  Use L</exists> for the latter
716 purpose.
717
718 Examples:
719
720     print if defined $switch{'D'};
721     print "$val\n" while defined($val = pop(@ary));
722     die "Can't readlink $sym: $!"
723         unless defined($value = readlink $sym);
724     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
725     $debugging = 0 unless defined $debugging;
726
727 Note:  Many folks tend to overuse defined(), and then are surprised to
728 discover that the number 0 and "" (the zero-length string) are, in fact,
729 defined values.  For example, if you say
730
731     "ab" =~ /a(.*)b/;
732
733 the pattern match succeeds, and $1 is defined, despite the fact that it
734 matched "nothing".  But it didn't really match nothing--rather, it
735 matched something that happened to be 0 characters long.  This is all
736 very above-board and honest.  When a function returns an undefined value,
737 it's an admission that it couldn't give you an honest answer.  So you
738 should use defined() only when you're questioning the integrity of what
739 you're trying to do.  At other times, a simple comparison to 0 or "" is
740 what you want.
741
742 Currently, using defined() on an entire array or hash reports whether
743 memory for that aggregate has ever been allocated.  So an array you set
744 to the empty list appears undefined initially, and one that once was full
745 and that you then set to the empty list still appears defined.  You
746 should instead use a simple test for size:
747
748     if (@an_array) { print "has array elements\n" }
749     if (%a_hash)   { print "has hash members\n"   }
750
751 Using undef() on these, however, does clear their memory and then report
752 them as not defined anymore, but you shoudln't do that unless you don't
753 plan to use them again, because it saves time when you load them up
754 again to have memory already ready to be filled.
755
756 This counterintuitive behaviour of defined() on aggregates may be
757 changed, fixed, or broken in a future release of Perl.
758
759 See also L</undef>, L</exists>, L</ref>.
760
761 =item delete EXPR
762
763 Deletes the specified key(s) and their associated values from a hash.
764 For each key, returns the deleted value associated with that key, or
765 the undefined value if there was no such key.  Deleting from C<$ENV{}>
766 modifies the environment.  Deleting from a hash tied to a DBM file
767 deletes the entry from the DBM file.  (But deleting from a tie()d hash
768 doesn't necessarily return anything.)
769
770 The following deletes all the values of a hash:
771
772     foreach $key (keys %HASH) {
773         delete $HASH{$key};
774     }
775
776 And so does this:
777
778     delete @HASH{keys %HASH}
779
780 (But both of these are slower than the undef() command.)  Note that the
781 EXPR can be arbitrarily complicated as long as the final operation is a
782 hash element lookup or hash slice:
783
784     delete $ref->[$x][$y]{$key};
785     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
786
787 =item die LIST
788
789 Outside of an eval(), prints the value of LIST to C<STDERR> and exits with
790 the current value of C<$!> (errno).  If C<$!> is 0, exits with the value of
791 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)>
792 is 0, exits with 255.  Inside an eval(), the error message is stuffed into
793 C<$@>, and the eval() is terminated with the undefined value; this makes
794 die() the way to raise an exception.
795
796 Equivalent examples:
797
798     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
799     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
800
801 If the value of EXPR does not end in a newline, the current script line
802 number and input line number (if any) are also printed, and a newline
803 is supplied.  Hint: sometimes appending ", stopped" to your message
804 will cause it to make better sense when the string "at foo line 123" is
805 appended.  Suppose you are running script "canasta".
806
807     die "/etc/games is no good";
808     die "/etc/games is no good, stopped";
809
810 produce, respectively
811
812     /etc/games is no good at canasta line 123.
813     /etc/games is no good, stopped at canasta line 123.
814
815 See also exit() and warn().
816
817 If LIST is empty and $@ already contains a value (typically from a
818 previous eval) that value is reused after appending "\t...propagated".
819 This is useful for propagating exceptions:
820
821     eval { ... };
822     die unless $@ =~ /Expected exception/;
823
824 If $@ is empty then the string "Died" is used.
825
826 You can arrange for a callback to be called just before the die() does
827 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
828 will be called with the error text and can change the error message, if
829 it sees fit, by calling die() again.  See L<perlvar/$SIG{expr}> for details on
830 setting C<%SIG> entries, and L<"eval BLOCK"> for some examples.
831
832 Note that the C<$SIG{__DIE__}> hook is called even inside eval()ed
833 blocks/strings.  If one wants the hook to do nothing in such
834 situations, put
835
836         die @_ if $^S;
837
838 as the first line of the handler (see L<perlvar/$^S>).
839
840 =item do BLOCK
841
842 Not really a function.  Returns the value of the last command in the
843 sequence of commands indicated by BLOCK.  When modified by a loop
844 modifier, executes the BLOCK once before testing the loop condition.
845 (On other statements the loop modifiers test the conditional first.)
846
847 =item do SUBROUTINE(LIST)
848
849 A deprecated form of subroutine call.  See L<perlsub>.
850
851 =item do EXPR
852
853 Uses the value of EXPR as a filename and executes the contents of the
854 file as a Perl script.  Its primary use is to include subroutines
855 from a Perl subroutine library.
856
857     do 'stat.pl';
858
859 is just like
860
861     scalar eval `cat stat.pl`;
862
863 except that it's more efficient, more concise, keeps track of the
864 current filename for error messages, and searches all the B<-I>
865 libraries if the file isn't in the current directory (see also the @INC
866 array in L<perlvar/Predefined Names>).  It is also different in how
867 code evaluated with C<do FILENAME> doesn't see lexicals in the enclosing
868 scope like C<eval STRING> does.  It's the same, however, in that it does
869 reparse the file every time you call it, so you probably don't want to
870 do this inside a loop.
871
872 Note that inclusion of library modules is better done with the
873 use() and require() operators, which also do error checking
874 and raise an exception if there's a problem.
875
876 =item dump LABEL
877
878 This causes an immediate core dump.  Primarily this is so that you can
879 use the B<undump> program to turn your core dump into an executable binary
880 after having initialized all your variables at the beginning of the
881 program.  When the new binary is executed it will begin by executing a
882 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
883 it as a goto with an intervening core dump and reincarnation.  If LABEL
884 is omitted, restarts the program from the top.  WARNING: any files
885 opened at the time of the dump will NOT be open any more when the
886 program is reincarnated, with possible resulting confusion on the part
887 of Perl.  See also B<-u> option in L<perlrun>.
888
889 Example:
890
891     #!/usr/bin/perl
892     require 'getopt.pl';
893     require 'stat.pl';
894     %days = (
895         'Sun' => 1,
896         'Mon' => 2,
897         'Tue' => 3,
898         'Wed' => 4,
899         'Thu' => 5,
900         'Fri' => 6,
901         'Sat' => 7,
902     );
903
904     dump QUICKSTART if $ARGV[0] eq '-d';
905
906     QUICKSTART:
907     Getopt('f');
908
909 =item each HASH
910
911 When called in a list context, returns a 2-element array consisting of the
912 key and value for the next element of a hash, so that you can iterate over
913 it.  When called in a scalar context, returns the key for only the next
914 element in the hash.  (Note: Keys may be "0" or "", which are logically
915 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
916 for this reason.)
917
918 Entries are returned in an apparently random order.  When the hash is
919 entirely read, a null array is returned in list context (which when
920 assigned produces a FALSE (0) value), and C<undef> is returned in a
921 scalar context.  The next call to each() after that will start iterating
922 again.  There is a single iterator for each hash, shared by all each(),
923 keys(), and values() function calls in the program; it can be reset by
924 reading all the elements from the hash, or by evaluating C<keys HASH> or
925 C<values HASH>.  If you add or delete elements of a hash while you're
926 iterating over it, you may get entries skipped or duplicated, so don't.
927
928 The following prints out your environment like the printenv(1) program,
929 only in a different order:
930
931     while (($key,$value) = each %ENV) {
932         print "$key=$value\n";
933     }
934
935 See also keys() and values().
936
937 =item eof FILEHANDLE
938
939 =item eof ()
940
941 =item eof
942
943 Returns 1 if the next read on FILEHANDLE will return end of file, or if
944 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
945 gives the real filehandle name.  (Note that this function actually
946 reads a character and then ungetc()s it, so it is not very useful in an
947 interactive context.)  Do not read from a terminal file (or call
948 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
949 as terminals may lose the end-of-file condition if you do.
950
951 An C<eof> without an argument uses the last file read as argument.
952 Empty parentheses () may be used to indicate the pseudo file formed of
953 the files listed on the command line, i.e., C<eof()> is reasonable to
954 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
955 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
956 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
957
958     # reset line numbering on each input file
959     while (<>) {
960         print "$.\t$_";
961         close(ARGV) if (eof);   # Not eof().
962     }
963
964     # insert dashes just before last line of last file
965     while (<>) {
966         if (eof()) {
967             print "--------------\n";
968             close(ARGV);        # close or break; is needed if we
969                                 # are reading from the terminal
970         }
971         print;
972     }
973
974 Practical hint: you almost never need to use C<eof> in Perl, because the
975 input operators return undef when they run out of data.
976
977 =item eval EXPR
978
979 =item eval BLOCK
980
981 In the first form, the return value of EXPR is parsed and executed as if it
982 were a little Perl program.  The value of the expression (which is itself
983 determined within a scalar context) is first parsed, and if there are no
984 errors, executed in the context of the current Perl program, so that any
985 variable settings or subroutine and format definitions remain afterwards.
986 Note that the value is parsed every time the eval executes.  If EXPR is
987 omitted, evaluates C<$_>.  This form is typically used to delay parsing
988 and subsequent execution of the text of EXPR until run time.
989
990 In the second form, the code within the BLOCK is parsed only once--at the
991 same time the code surrounding the eval itself was parsed--and executed
992 within the context of the current Perl program.  This form is typically
993 used to trap exceptions more efficiently than the first (see below), while
994 also providing the benefit of checking the code within BLOCK at compile
995 time.
996
997 The final semicolon, if any, may be omitted from the value of EXPR or within
998 the BLOCK.
999
1000 In both forms, the value returned is the value of the last expression
1001 evaluated inside the mini-program, or a return statement may be used, just
1002 as with subroutines.  The expression providing the return value is evaluated
1003 in void, scalar or array context, depending on the context of the eval itself.
1004 See L</wantarray> for more on how the evaluation context can be determined.
1005
1006 If there is a syntax error or runtime error, or a die() statement is
1007 executed, an undefined value is returned by eval(), and C<$@> is set to the
1008 error message.  If there was no error, C<$@> is guaranteed to be a null
1009 string.  Beware that using eval() neither silences perl from printing
1010 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1011 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1012 L</warn> and L<perlvar>.
1013
1014 Note that, because eval() traps otherwise-fatal errors, it is useful for
1015 determining whether a particular feature (such as socket() or symlink())
1016 is implemented.  It is also Perl's exception trapping mechanism, where
1017 the die operator is used to raise exceptions.
1018
1019 If the code to be executed doesn't vary, you may use the eval-BLOCK
1020 form to trap run-time errors without incurring the penalty of
1021 recompiling each time.  The error, if any, is still returned in C<$@>.
1022 Examples:
1023
1024     # make divide-by-zero nonfatal
1025     eval { $answer = $a / $b; }; warn $@ if $@;
1026
1027     # same thing, but less efficient
1028     eval '$answer = $a / $b'; warn $@ if $@;
1029
1030     # a compile-time error
1031     eval { $answer = };
1032
1033     # a run-time error
1034     eval '$answer =';   # sets $@
1035
1036 When using the eval{} form as an exception trap in libraries, you may
1037 wish not to trigger any C<__DIE__> hooks that user code may have
1038 installed.  You can use the C<local $SIG{__DIE__}> construct for this
1039 purpose, as shown in this example:
1040
1041     # a very private exception trap for divide-by-zero
1042     eval { local $SIG{'__DIE__'}; $answer = $a / $b; }; warn $@ if $@;
1043
1044 This is especially significant, given that C<__DIE__> hooks can call
1045 die() again, which has the effect of changing their error messages:
1046
1047     # __DIE__ hooks may modify error messages
1048     {
1049        local $SIG{'__DIE__'} = sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1050        eval { die "foo lives here" };
1051        print $@ if $@;                # prints "bar lives here"
1052     }
1053
1054 With an eval(), you should be especially careful to remember what's
1055 being looked at when:
1056
1057     eval $x;            # CASE 1
1058     eval "$x";          # CASE 2
1059
1060     eval '$x';          # CASE 3
1061     eval { $x };        # CASE 4
1062
1063     eval "\$$x++"       # CASE 5
1064     $$x++;              # CASE 6
1065
1066 Cases 1 and 2 above behave identically: they run the code contained in
1067 the variable $x.  (Although case 2 has misleading double quotes making
1068 the reader wonder what else might be happening (nothing is).)  Cases 3
1069 and 4 likewise behave in the same way: they run the code '$x', which
1070 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1071 purely visual reasons, but it also has the advantage of compiling at
1072 compile-time instead of at run-time.)  Case 5 is a place where
1073 normally you I<WOULD> like to use double quotes, except that in this
1074 particular situation, you can just use symbolic references instead, as
1075 in case 6.
1076
1077 =item exec LIST
1078
1079 =item exec PROGRAM LIST
1080
1081 The exec() function executes a system command I<AND NEVER RETURNS> -
1082 use system() instead of exec() if you want it to return. It fails and
1083 returns FALSE only if the command does not exist I<and> it is executed
1084 directly instead of via your system's command shell (see below).
1085
1086 If there is more than one argument in LIST, or if LIST is an array with
1087 more than one value, calls execvp(3) with the arguments in LIST.  If
1088 there is only one scalar argument, the argument is checked for shell
1089 metacharacters, and if there are any, the entire argument is passed to
1090 the system's command shell for parsing (this is C</bin/sh -c> on Unix
1091 platforms, but varies on other platforms).  If there are no shell
1092 metacharacters in the argument, it is split into words and passed
1093 directly to execvp(), which is more efficient.  Note: exec() and
1094 system() do not flush your output buffer, so you may need to set C<$|>
1095 to avoid lost output.  Examples:
1096
1097     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1098     exec "sort $outfile | uniq";
1099
1100 If you don't really want to execute the first argument, but want to lie
1101 to the program you are executing about its own name, you can specify
1102 the program you actually want to run as an "indirect object" (without a
1103 comma) in front of the LIST.  (This always forces interpretation of the
1104 LIST as a multivalued list, even if there is only a single scalar in
1105 the list.)  Example:
1106
1107     $shell = '/bin/csh';
1108     exec $shell '-sh';          # pretend it's a login shell
1109
1110 or, more directly,
1111
1112     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1113
1114 When the arguments get executed via the system shell, results will
1115 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1116 for details.
1117
1118 =item exists EXPR
1119
1120 Returns TRUE if the specified hash key exists in its hash array, even
1121 if the corresponding value is undefined.
1122
1123     print "Exists\n" if exists $array{$key};
1124     print "Defined\n" if defined $array{$key};
1125     print "True\n" if $array{$key};
1126
1127 A hash element can be TRUE only if it's defined, and defined if
1128 it exists, but the reverse doesn't necessarily hold true.
1129
1130 Note that the EXPR can be arbitrarily complicated as long as the final
1131 operation is a hash key lookup:
1132
1133     if (exists $ref->[$x][$y]{$key}) { ... }
1134
1135 =item exit EXPR
1136
1137 Evaluates EXPR and exits immediately with that value.  (Actually, it
1138 calls any defined C<END> routines first, but the C<END> routines may not
1139 abort the exit.  Likewise any object destructors that need to be called
1140 are called before exit.)  Example:
1141
1142     $ans = <STDIN>;
1143     exit 0 if $ans =~ /^[Xx]/;
1144
1145 See also die().  If EXPR is omitted, exits with 0 status.  The only
1146 universally portable values for EXPR are 0 for success and 1 for error;
1147 all other values are subject to unpredictable interpretation depending
1148 on the environment in which the Perl program is running.
1149
1150 You shouldn't use exit() to abort a subroutine if there's any chance that
1151 someone might want to trap whatever error happened.  Use die() instead,
1152 which can be trapped by an eval().
1153
1154 =item exp EXPR
1155
1156 =item exp
1157
1158 Returns I<e> (the natural logarithm base) to the power of EXPR.
1159 If EXPR is omitted, gives C<exp($_)>.
1160
1161 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1162
1163 Implements the fcntl(2) function.  You'll probably have to say
1164
1165     use Fcntl;
1166
1167 first to get the correct function definitions.  Argument processing and
1168 value return works just like ioctl() below.  Note that fcntl() will produce
1169 a fatal error if used on a machine that doesn't implement fcntl(2).
1170 For example:
1171
1172     use Fcntl;
1173     fcntl($filehandle, F_GETLK, $packed_return_buffer);
1174
1175 =item fileno FILEHANDLE
1176
1177 Returns the file descriptor for a filehandle.  This is useful for
1178 constructing bitmaps for select().  If FILEHANDLE is an expression, the
1179 value is taken as the name of the filehandle.
1180
1181 =item flock FILEHANDLE,OPERATION
1182
1183 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1184 success, FALSE on failure.  Produces a fatal error if used on a machine
1185 that doesn't implement flock(2), fcntl(2) locking, or lockf(3).  flock()
1186 is Perl's portable file locking interface, although it locks only entire
1187 files, not records.
1188
1189 On many platforms (including most versions or clones of Unix), locks
1190 established by flock() are B<merely advisory>.  This means that files
1191 locked with flock() may be modified by programs which do not also use
1192 flock().  Windows NT and OS/2, however, are among the platforms which
1193 supply mandatory locking.  See your local documentation for details.
1194
1195 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1196 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1197 you can use the symbolic names if import them from the Fcntl module,
1198 either individually, or as a group using the ':flock' tag.  LOCK_SH
1199 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1200 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1201 LOCK_EX then flock() will return immediately rather than blocking
1202 waiting for the lock (check the return status to see if you got it).
1203
1204 To avoid the possibility of mis-coordination, Perl flushes FILEHANDLE
1205 before (un)locking it.
1206
1207 Note that the emulation built with lockf(3) doesn't provide shared
1208 locks, and it requires that FILEHANDLE be open with write intent.  These
1209 are the semantics that lockf(3) implements.  Most (all?) systems
1210 implement lockf(3) in terms of fcntl(2) locking, though, so the
1211 differing semantics shouldn't bite too many people.
1212
1213 Note also that some versions of flock() cannot lock things over the
1214 network; you would need to use the more system-specific fcntl() for
1215 that.  If you like you can force Perl to ignore your system's flock(2)
1216 function, and so provide its own fcntl(2)-based emulation, by passing
1217 the switch C<-Ud_flock> to the F<Configure> program when you configure
1218 perl.
1219
1220 Here's a mailbox appender for BSD systems.
1221
1222     use Fcntl ':flock'; # import LOCK_* constants
1223
1224     sub lock {
1225         flock(MBOX,LOCK_EX);
1226         # and, in case someone appended
1227         # while we were waiting...
1228         seek(MBOX, 0, 2);
1229     }
1230
1231     sub unlock {
1232         flock(MBOX,LOCK_UN);
1233     }
1234
1235     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1236             or die "Can't open mailbox: $!";
1237
1238     lock();
1239     print MBOX $msg,"\n\n";
1240     unlock();
1241
1242 See also L<DB_File> for other flock() examples.
1243
1244 =item fork
1245
1246 Does a fork(2) system call.  Returns the child pid to the parent process
1247 and 0 to the child process, or C<undef> if the fork is unsuccessful.
1248 Note: unflushed buffers remain unflushed in both processes, which means
1249 you may need to set C<$|> ($AUTOFLUSH in English) or call the autoflush()
1250 method of IO::Handle to avoid duplicate output.
1251
1252 If you fork() without ever waiting on your children, you will accumulate
1253 zombies:
1254
1255     $SIG{CHLD} = sub { wait };
1256
1257 There's also the double-fork trick (error checking on
1258 fork() returns omitted);
1259
1260     unless ($pid = fork) {
1261         unless (fork) {
1262             exec "what you really wanna do";
1263             die "no exec";
1264             # ... or ...
1265             ## (some_perl_code_here)
1266             exit 0;
1267         }
1268         exit 0;
1269     }
1270     waitpid($pid,0);
1271
1272 See also L<perlipc> for more examples of forking and reaping
1273 moribund children.
1274
1275 Note that if your forked child inherits system file descriptors like
1276 STDIN and STDOUT that are actually connected by a pipe or socket, even
1277 if you exit, the remote server (such as, say, httpd or rsh) won't think
1278 you're done.  You should reopen those to /dev/null if it's any issue.
1279
1280 =item format
1281
1282 Declare a picture format with use by the write() function.  For
1283 example:
1284
1285     format Something =
1286         Test: @<<<<<<<< @||||| @>>>>>
1287               $str,     $%,    '$' . int($num)
1288     .
1289
1290     $str = "widget";
1291     $num = $cost/$quantity;
1292     $~ = 'Something';
1293     write;
1294
1295 See L<perlform> for many details and examples.
1296
1297
1298 =item formline PICTURE,LIST
1299
1300 This is an internal function used by C<format>s, though you may call it
1301 too.  It formats (see L<perlform>) a list of values according to the
1302 contents of PICTURE, placing the output into the format output
1303 accumulator, C<$^A> (or $ACCUMULATOR in English).
1304 Eventually, when a write() is done, the contents of
1305 C<$^A> are written to some filehandle, but you could also read C<$^A>
1306 yourself and then set C<$^A> back to "".  Note that a format typically
1307 does one formline() per line of form, but the formline() function itself
1308 doesn't care how many newlines are embedded in the PICTURE.  This means
1309 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1310 You may therefore need to use multiple formlines to implement a single
1311 record format, just like the format compiler.
1312
1313 Be careful if you put double quotes around the picture, because an "C<@>"
1314 character may be taken to mean the beginning of an array name.
1315 formline() always returns TRUE.  See L<perlform> for other examples.
1316
1317 =item getc FILEHANDLE
1318
1319 =item getc
1320
1321 Returns the next character from the input file attached to FILEHANDLE,
1322 or a null string at end of file.  If FILEHANDLE is omitted, reads from STDIN.
1323 This is not particularly efficient.  It cannot be used to get unbuffered
1324 single-characters, however.  For that, try something more like:
1325
1326     if ($BSD_STYLE) {
1327         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1328     }
1329     else {
1330         system "stty", '-icanon', 'eol', "\001";
1331     }
1332
1333     $key = getc(STDIN);
1334
1335     if ($BSD_STYLE) {
1336         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1337     }
1338     else {
1339         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1340     }
1341     print "\n";
1342
1343 Determination of whether $BSD_STYLE should be set
1344 is left as an exercise to the reader.
1345
1346 The POSIX::getattr() function can do this more portably on systems
1347 alleging POSIX compliance.
1348 See also the C<Term::ReadKey> module from your nearest CPAN site;
1349 details on CPAN can be found on L<perlmod/CPAN>.
1350
1351 =item getlogin
1352
1353 Returns the current login from F</etc/utmp>, if any.  If null, use
1354 getpwuid().
1355
1356     $login = getlogin || getpwuid($<) || "Kilroy";
1357
1358 Do not consider getlogin() for authentication: it is not as
1359 secure as getpwuid().
1360
1361 =item getpeername SOCKET
1362
1363 Returns the packed sockaddr address of other end of the SOCKET connection.
1364
1365     use Socket;
1366     $hersockaddr    = getpeername(SOCK);
1367     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1368     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1369     $herstraddr     = inet_ntoa($iaddr);
1370
1371 =item getpgrp PID
1372
1373 Returns the current process group for the specified PID.  Use
1374 a PID of 0 to get the current process group for the
1375 current process.  Will raise an exception if used on a machine that
1376 doesn't implement getpgrp(2).  If PID is omitted, returns process
1377 group of current process.  Note that the POSIX version of getpgrp()
1378 does not accept a PID argument, so only PID==0 is truly portable.
1379
1380 =item getppid
1381
1382 Returns the process id of the parent process.
1383
1384 =item getpriority WHICH,WHO
1385
1386 Returns the current priority for a process, a process group, or a user.
1387 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1388 machine that doesn't implement getpriority(2).
1389
1390 =item getpwnam NAME
1391
1392 =item getgrnam NAME
1393
1394 =item gethostbyname NAME
1395
1396 =item getnetbyname NAME
1397
1398 =item getprotobyname NAME
1399
1400 =item getpwuid UID
1401
1402 =item getgrgid GID
1403
1404 =item getservbyname NAME,PROTO
1405
1406 =item gethostbyaddr ADDR,ADDRTYPE
1407
1408 =item getnetbyaddr ADDR,ADDRTYPE
1409
1410 =item getprotobynumber NUMBER
1411
1412 =item getservbyport PORT,PROTO
1413
1414 =item getpwent
1415
1416 =item getgrent
1417
1418 =item gethostent
1419
1420 =item getnetent
1421
1422 =item getprotoent
1423
1424 =item getservent
1425
1426 =item setpwent
1427
1428 =item setgrent
1429
1430 =item sethostent STAYOPEN
1431
1432 =item setnetent STAYOPEN
1433
1434 =item setprotoent STAYOPEN
1435
1436 =item setservent STAYOPEN
1437
1438 =item endpwent
1439
1440 =item endgrent
1441
1442 =item endhostent
1443
1444 =item endnetent
1445
1446 =item endprotoent
1447
1448 =item endservent
1449
1450 These routines perform the same functions as their counterparts in the
1451 system library.  Within a list context, the return values from the
1452 various get routines are as follows:
1453
1454     ($name,$passwd,$uid,$gid,
1455        $quota,$comment,$gcos,$dir,$shell) = getpw*
1456     ($name,$passwd,$gid,$members) = getgr*
1457     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1458     ($name,$aliases,$addrtype,$net) = getnet*
1459     ($name,$aliases,$proto) = getproto*
1460     ($name,$aliases,$port,$proto) = getserv*
1461
1462 (If the entry doesn't exist you get a null list.)
1463
1464 Within a scalar context, you get the name, unless the function was a
1465 lookup by name, in which case you get the other thing, whatever it is.
1466 (If the entry doesn't exist you get the undefined value.)  For example:
1467
1468     $uid = getpwnam
1469     $name = getpwuid
1470     $name = getpwent
1471     $gid = getgrnam
1472     $name = getgrgid
1473     $name = getgrent
1474     etc.
1475
1476 The $members value returned by I<getgr*()> is a space separated list of
1477 the login names of the members of the group.
1478
1479 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1480 C, it will be returned to you via C<$?> if the function call fails.  The
1481 @addrs value returned by a successful call is a list of the raw
1482 addresses returned by the corresponding system library call.  In the
1483 Internet domain, each address is four bytes long and you can unpack it
1484 by saying something like:
1485
1486     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1487
1488 =item getsockname SOCKET
1489
1490 Returns the packed sockaddr address of this end of the SOCKET connection.
1491
1492     use Socket;
1493     $mysockaddr = getsockname(SOCK);
1494     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1495
1496 =item getsockopt SOCKET,LEVEL,OPTNAME
1497
1498 Returns the socket option requested, or undefined if there is an error.
1499
1500 =item glob EXPR
1501
1502 =item glob
1503
1504 Returns the value of EXPR with filename expansions such as a shell would
1505 do.  This is the internal function implementing the C<E<lt>*.cE<gt>>
1506 operator, but you can use it directly.  If EXPR is omitted, $_ is used.
1507 The C<E<lt>*.cE<gt>> operator is discussed in more detail in
1508 L<perlop/"I/O Operators">.
1509
1510 =item gmtime EXPR
1511
1512 Converts a time as returned by the time function to a 9-element array
1513 with the time localized for the standard Greenwich time zone.
1514 Typically used as follows:
1515
1516     #  0    1    2     3     4    5     6     7     8
1517     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1518                                             gmtime(time);
1519
1520 All array elements are numeric, and come straight out of a struct tm.
1521 In particular this means that $mon has the range 0..11 and $wday has
1522 the range 0..6 with sunday as day 0.  Also, $year is the number of
1523 years since 1900, I<not> simply the last two digits of the year.
1524
1525 If EXPR is omitted, does C<gmtime(time())>.
1526
1527 In a scalar context, returns the ctime(3) value:
1528
1529     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1530
1531 Also see the timegm() function provided by the Time::Local module,
1532 and the strftime(3) function available via the POSIX module.
1533
1534 =item goto LABEL
1535
1536 =item goto EXPR
1537
1538 =item goto &NAME
1539
1540 The goto-LABEL form finds the statement labeled with LABEL and resumes
1541 execution there.  It may not be used to go into any construct that
1542 requires initialization, such as a subroutine or a foreach loop.  It
1543 also can't be used to go into a construct that is optimized away,
1544 or to get out of a block or subroutine given to sort().
1545 It can be used to go almost anywhere else within the dynamic scope,
1546 including out of subroutines, but it's usually better to use some other
1547 construct such as last or die.  The author of Perl has never felt the
1548 need to use this form of goto (in Perl, that is--C is another matter).
1549
1550 The goto-EXPR form expects a label name, whose scope will be resolved
1551 dynamically.  This allows for computed gotos per FORTRAN, but isn't
1552 necessarily recommended if you're optimizing for maintainability:
1553
1554     goto ("FOO", "BAR", "GLARCH")[$i];
1555
1556 The goto-&NAME form is highly magical, and substitutes a call to the
1557 named subroutine for the currently running subroutine.  This is used by
1558 AUTOLOAD subroutines that wish to load another subroutine and then
1559 pretend that the other subroutine had been called in the first place
1560 (except that any modifications to @_ in the current subroutine are
1561 propagated to the other subroutine.)  After the goto, not even caller()
1562 will be able to tell that this routine was called first.
1563
1564 =item grep BLOCK LIST
1565
1566 =item grep EXPR,LIST
1567
1568 This is similar in spirit to, but not the same as, grep(1)
1569 and its relatives.  In particular, it is not limited to using
1570 regular expressions.
1571
1572 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1573 $_ to each element) and returns the list value consisting of those
1574 elements for which the expression evaluated to TRUE.  In a scalar
1575 context, returns the number of times the expression was TRUE.
1576
1577     @foo = grep(!/^#/, @bar);    # weed out comments
1578
1579 or equivalently,
1580
1581     @foo = grep {!/^#/} @bar;    # weed out comments
1582
1583 Note that, because $_ is a reference into the list value, it can be used
1584 to modify the elements of the array.  While this is useful and
1585 supported, it can cause bizarre results if the LIST is not a named
1586 array.  Similarly, grep returns aliases into the original list,
1587 much like the way that L<Foreach Loops>'s index variable aliases the list
1588 elements.  That is, modifying an element of a list returned by grep
1589 (for example, in a C<foreach>, C<map> or another C<grep>)
1590 actually modifies the element in the original list.
1591
1592 See also L</map> for an array composed of the results of the BLOCK or EXPR.
1593
1594 =item hex EXPR
1595
1596 =item hex
1597
1598 Interprets EXPR as a hex string and returns the corresponding
1599 value.  (To convert strings that might start with either 0 or 0x
1600 see L</oct>.)  If EXPR is omitted, uses $_.
1601
1602     print hex '0xAf'; # prints '175'
1603     print hex 'aF';   # same
1604
1605 =item import
1606
1607 There is no builtin import() function.  It is merely an ordinary
1608 method (subroutine) defined (or inherited) by modules that wish to export
1609 names to another module.  The use() function calls the import() method
1610 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1611
1612 =item index STR,SUBSTR,POSITION
1613
1614 =item index STR,SUBSTR
1615
1616 Returns the position of the first occurrence of SUBSTR in STR at or after
1617 POSITION.  If POSITION is omitted, starts searching from the beginning of
1618 the string.  The return value is based at 0 (or whatever you've set the C<$[>
1619 variable to--but don't do that).  If the substring is not found, returns
1620 one less than the base, ordinarily -1.
1621
1622 =item int EXPR
1623
1624 =item int
1625
1626 Returns the integer portion of EXPR.  If EXPR is omitted, uses $_.
1627
1628 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1629
1630 Implements the ioctl(2) function.  You'll probably have to say
1631
1632     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1633
1634 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1635 exist or doesn't have the correct definitions you'll have to roll your
1636 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1637 (There is a Perl script called B<h2ph> that comes with the Perl kit which
1638 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
1639 written depending on the FUNCTION--a pointer to the string value of SCALAR
1640 will be passed as the third argument of the actual ioctl call.  (If SCALAR
1641 has no string value but does have a numeric value, that value will be
1642 passed rather than a pointer to the string value.  To guarantee this to be
1643 TRUE, add a 0 to the scalar before using it.)  The pack() and unpack()
1644 functions are useful for manipulating the values of structures used by
1645 ioctl().  The following example sets the erase character to DEL.
1646
1647     require 'ioctl.ph';
1648     $getp = &TIOCGETP;
1649     die "NO TIOCGETP" if $@ || !$getp;
1650     $sgttyb_t = "ccccs";                # 4 chars and a short
1651     if (ioctl(STDIN,$getp,$sgttyb)) {
1652         @ary = unpack($sgttyb_t,$sgttyb);
1653         $ary[2] = 127;
1654         $sgttyb = pack($sgttyb_t,@ary);
1655         ioctl(STDIN,&TIOCSETP,$sgttyb)
1656             || die "Can't ioctl: $!";
1657     }
1658
1659 The return value of ioctl (and fcntl) is as follows:
1660
1661         if OS returns:          then Perl returns:
1662             -1                    undefined value
1663              0                  string "0 but true"
1664         anything else               that number
1665
1666 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1667 still easily determine the actual value returned by the operating
1668 system:
1669
1670     ($retval = ioctl(...)) || ($retval = -1);
1671     printf "System returned %d\n", $retval;
1672
1673 =item join EXPR,LIST
1674
1675 Joins the separate strings of LIST into a single string with
1676 fields separated by the value of EXPR, and returns the string.
1677 Example:
1678
1679     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1680
1681 See L<perlfunc/split>.
1682
1683 =item keys HASH
1684
1685 Returns a normal array consisting of all the keys of the named hash.  (In
1686 a scalar context, returns the number of keys.)  The keys are returned in
1687 an apparently random order, but it is the same order as either the
1688 values() or each() function produces (given that the hash has not been
1689 modified).  As a side effect, it resets HASH's iterator.
1690
1691 Here is yet another way to print your environment:
1692
1693     @keys = keys %ENV;
1694     @values = values %ENV;
1695     while ($#keys >= 0) {
1696         print pop(@keys), '=', pop(@values), "\n";
1697     }
1698
1699 or how about sorted by key:
1700
1701     foreach $key (sort(keys %ENV)) {
1702         print $key, '=', $ENV{$key}, "\n";
1703     }
1704
1705 To sort an array by value, you'll need to use a C<sort> function.
1706 Here's a descending numeric sort of a hash by its values:
1707
1708     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash)) {
1709         printf "%4d %s\n", $hash{$key}, $key;
1710     }
1711
1712 As an lvalue C<keys> allows you to increase the number of hash buckets
1713 allocated for the given hash.  This can gain you a measure of efficiency if
1714 you know the hash is going to get big.  (This is similar to pre-extending
1715 an array by assigning a larger number to $#array.)  If you say
1716
1717     keys %hash = 200;
1718
1719 then C<%hash> will have at least 200 buckets allocated for it.  These
1720 buckets will be retained even if you do C<%hash = ()>, use C<undef
1721 %hash> if you want to free the storage while C<%hash> is still in scope.
1722 You can't shrink the number of buckets allocated for the hash using
1723 C<keys> in this way (but you needn't worry about doing this by accident,
1724 as trying has no effect).
1725
1726 =item kill LIST
1727
1728 Sends a signal to a list of processes.  The first element of
1729 the list must be the signal to send.  Returns the number of
1730 processes successfully signaled.
1731
1732     $cnt = kill 1, $child1, $child2;
1733     kill 9, @goners;
1734
1735 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1736 process groups instead of processes.  (On System V, a negative I<PROCESS>
1737 number will also kill process groups, but that's not portable.)  That
1738 means you usually want to use positive not negative signals.  You may also
1739 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1740
1741 =item last LABEL
1742
1743 =item last
1744
1745 The C<last> command is like the C<break> statement in C (as used in
1746 loops); it immediately exits the loop in question.  If the LABEL is
1747 omitted, the command refers to the innermost enclosing loop.  The
1748 C<continue> block, if any, is not executed:
1749
1750     LINE: while (<STDIN>) {
1751         last LINE if /^$/;      # exit when done with header
1752         ...
1753     }
1754
1755 =item lc EXPR
1756
1757 =item lc
1758
1759 Returns an lowercased version of EXPR.  This is the internal function
1760 implementing the \L escape in double-quoted strings.
1761 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1762
1763 If EXPR is omitted, uses $_.
1764
1765 =item lcfirst EXPR
1766
1767 =item lcfirst
1768
1769 Returns the value of EXPR with the first character lowercased.  This is
1770 the internal function implementing the \l escape in double-quoted strings.
1771 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1772
1773 If EXPR is omitted, uses $_.
1774
1775 =item length EXPR
1776
1777 =item length
1778
1779 Returns the length in characters of the value of EXPR.  If EXPR is
1780 omitted, returns length of $_.
1781
1782 =item link OLDFILE,NEWFILE
1783
1784 Creates a new filename linked to the old filename.  Returns 1 for
1785 success, 0 otherwise.
1786
1787 =item listen SOCKET,QUEUESIZE
1788
1789 Does the same thing that the listen system call does.  Returns TRUE if
1790 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1791
1792 =item local EXPR
1793
1794 A local modifies the listed variables to be local to the enclosing block,
1795 subroutine, C<eval{}>, or C<do>.  If more than one value is listed, the
1796 list must be placed in parentheses.  See L<perlsub/"Temporary Values via
1797 local()"> for details, including issues with tied arrays and hashes.
1798
1799 But you really probably want to be using my() instead, because local() isn't
1800 what most people think of as "local").  See L<perlsub/"Private Variables
1801 via my()"> for details.
1802
1803 =item localtime EXPR
1804
1805 Converts a time as returned by the time function to a 9-element array
1806 with the time analyzed for the local time zone.  Typically used as
1807 follows:
1808
1809     #  0    1    2     3     4    5     6     7     8
1810     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1811                                                 localtime(time);
1812
1813 All array elements are numeric, and come straight out of a struct tm.
1814 In particular this means that $mon has the range 0..11 and $wday has
1815 the range 0..6 with sunday as day 0.  Also, $year is the number of
1816 years since 1900, that is, $year is 123 in year 2023.
1817
1818 If EXPR is omitted, uses the current time (C<localtime(time)>).
1819
1820 In a scalar context, returns the ctime(3) value:
1821
1822     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1823
1824 This scalar value is B<not> locale dependent, see L<perllocale>, but
1825 instead a Perl builtin.  Also see the Time::Local module, and the
1826 strftime(3) and mktime(3) function available via the POSIX module.  To
1827 get somewhat similar but locale dependent date strings, set up your
1828 locale environment variables appropriately (please see L<perllocale>)
1829 and try for example
1830
1831         use POSIX qw(strftime)
1832         $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
1833
1834 Note that the C<%a> and C<%b>, the short forms of the day of the week
1835 and the month of the year, may not necessarily be three characters wide.
1836
1837 =item log EXPR
1838
1839 =item log
1840
1841 Returns logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
1842 of $_.
1843
1844 =item lstat FILEHANDLE
1845
1846 =item lstat EXPR
1847
1848 =item lstat
1849
1850 Does the same thing as the stat() function, but stats a symbolic link
1851 instead of the file the symbolic link points to.  If symbolic links are
1852 unimplemented on your system, a normal stat() is done.
1853
1854 If EXPR is omitted, stats $_.
1855
1856 =item m//
1857
1858 The match operator.  See L<perlop>.
1859
1860 =item map BLOCK LIST
1861
1862 =item map EXPR,LIST
1863
1864 Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each
1865 element) and returns the list value composed of the results of each such
1866 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
1867 may produce zero, one, or more elements in the returned value.
1868
1869     @chars = map(chr, @nums);
1870
1871 translates a list of numbers to the corresponding characters.  And
1872
1873     %hash = map { getkey($_) => $_ } @array;
1874
1875 is just a funny way to write
1876
1877     %hash = ();
1878     foreach $_ (@array) {
1879         $hash{getkey($_)} = $_;
1880     }
1881
1882 Note that, because $_ is a reference into the list value, it can be used
1883 to modify the elements of the array.  While this is useful and
1884 supported, it can cause bizarre results if the LIST is not a named
1885 array.  See also L</grep> for an array composed of those items of the 
1886 original list for which the BLOCK or EXPR evaluates to true.
1887
1888 =item mkdir FILENAME,MODE
1889
1890 Creates the directory specified by FILENAME, with permissions specified
1891 by MODE (as modified by umask).  If it succeeds it returns 1, otherwise
1892 it returns 0 and sets C<$!> (errno).
1893
1894 =item msgctl ID,CMD,ARG
1895
1896 Calls the System V IPC function msgctl(2).  If CMD is &IPC_STAT, then ARG
1897 must be a variable which will hold the returned msqid_ds structure.
1898 Returns like ioctl: the undefined value for error, "0 but true" for
1899 zero, or the actual return value otherwise.
1900
1901 =item msgget KEY,FLAGS
1902
1903 Calls the System V IPC function msgget(2).  Returns the message queue id,
1904 or the undefined value if there is an error.
1905
1906 =item msgsnd ID,MSG,FLAGS
1907
1908 Calls the System V IPC function msgsnd to send the message MSG to the
1909 message queue ID.  MSG must begin with the long integer message type,
1910 which may be created with C<pack("l", $type)>.  Returns TRUE if
1911 successful, or FALSE if there is an error.
1912
1913 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
1914
1915 Calls the System V IPC function msgrcv to receive a message from
1916 message queue ID into variable VAR with a maximum message size of
1917 SIZE.  Note that if a message is received, the message type will be the
1918 first thing in VAR, and the maximum length of VAR is SIZE plus the size
1919 of the message type.  Returns TRUE if successful, or FALSE if there is
1920 an error.
1921
1922 =item my EXPR
1923
1924 A "my" declares the listed variables to be local (lexically) to the
1925 enclosing block, subroutine, C<eval>, or C<do/require/use>'d file.  If
1926 more than one value is listed, the list must be placed in parentheses.  See
1927 L<perlsub/"Private Variables via my()"> for details.
1928
1929 =item next LABEL
1930
1931 =item next
1932
1933 The C<next> command is like the C<continue> statement in C; it starts
1934 the next iteration of the loop:
1935
1936     LINE: while (<STDIN>) {
1937         next LINE if /^#/;      # discard comments
1938         ...
1939     }
1940
1941 Note that if there were a C<continue> block on the above, it would get
1942 executed even on discarded lines.  If the LABEL is omitted, the command
1943 refers to the innermost enclosing loop.
1944
1945 =item no Module LIST
1946
1947 See the "use" function, which "no" is the opposite of.
1948
1949 =item oct EXPR
1950
1951 =item oct
1952
1953 Interprets EXPR as an octal string and returns the corresponding
1954 value.  (If EXPR happens to start off with 0x, interprets it as
1955 a hex string instead.)  The following will handle decimal, octal, and
1956 hex in the standard Perl or C notation:
1957
1958     $val = oct($val) if $val =~ /^0/;
1959
1960 If EXPR is omitted, uses $_.  This function is commonly used when
1961 a string such as "644" needs to be converted into a file mode, for
1962 example. (Although perl will automatically convert strings into
1963 numbers as needed, this automatic conversion assumes base 10.)
1964
1965 =item open FILEHANDLE,EXPR
1966
1967 =item open FILEHANDLE
1968
1969 Opens the file whose filename is given by EXPR, and associates it with
1970 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
1971 name of the real filehandle wanted.  If EXPR is omitted, the scalar
1972 variable of the same name as the FILEHANDLE contains the filename.
1973 (Note that lexical variables--those declared with C<my>--will not work
1974 for this purpose; so if you're using C<my>, specify EXPR in your call
1975 to open.)
1976
1977 If the filename begins with '<' or nothing, the file is opened for input.
1978 If the filename begins with '>', the file is truncated and opened for
1979 output.  If the filename begins with '>>', the file is opened for
1980 appending.  You can put a '+' in front of the '>' or '<' to indicate that
1981 you want both read and write access to the file; thus '+<' is almost
1982 always preferred for read/write updates--the '+>' mode would clobber the
1983 file first.  The prefix and the filename may be separated with spaces.
1984 These various prefixes correspond to the fopen(3) modes of 'r', 'r+', 'w',
1985 'w+', 'a', and 'a+'.
1986
1987 If the filename begins with "|", the filename is interpreted as a command
1988 to which output is to be piped, and if the filename ends with a "|", the
1989 filename is interpreted See L<perlipc/"Using open() for IPC"> for more
1990 examples of this.  as command which pipes input to us.  (You may not have
1991 a raw open() to a command that pipes both in I<and> out, but see
1992 L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
1993 for alternatives.)
1994
1995 Opening '-' opens STDIN and opening 'E<gt>-' opens STDOUT.  Open returns
1996 nonzero upon success, the undefined value otherwise.  If the open
1997 involved a pipe, the return value happens to be the pid of the
1998 subprocess.
1999
2000 If you're unfortunate enough to be running Perl on a system that
2001 distinguishes between text files and binary files (modern operating
2002 systems don't care), then you should check out L</binmode> for tips for
2003 dealing with this.  The key distinction between systems that need binmode
2004 and those that don't is their text file formats.  Systems like Unix and
2005 Plan9 that delimit lines with a single character, and that encode that
2006 character in C as '\n', do not need C<binmode>.  The rest need it.
2007
2008 When opening a file, it's usually a bad idea to continue normal execution
2009 if the request failed, so C<open> is frequently used in connection with
2010 C<die>. Even if C<die> won't do what you want (say, in a CGI script,
2011 where you want to make a nicely formatted error message (but there are
2012 modules which can help with that problem)) you should always check
2013 the return value from opening a file. The infrequent exception is when
2014 working with an unopened filehandle is actually what you want to do.
2015
2016 Examples:
2017
2018     $ARTICLE = 100;
2019     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2020     while (<ARTICLE>) {...
2021
2022     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
2023     # if the open fails, output is discarded
2024
2025     open(DBASE, '+<dbase.mine')             # open for update
2026         or die "Can't open 'dbase.mine' for update: $!";
2027
2028     open(ARTICLE, "caesar <$article |")     # decrypt article
2029         or die "Can't start caesar: $!";
2030
2031     open(EXTRACT, "|sort >/tmp/Tmp$$")      # $$ is our process id
2032         or die "Can't start sort: $!";
2033
2034     # process argument list of files along with any includes
2035
2036     foreach $file (@ARGV) {
2037         process($file, 'fh00');
2038     }
2039
2040     sub process {
2041         local($filename, $input) = @_;
2042         $input++;               # this is a string increment
2043         unless (open($input, $filename)) {
2044             print STDERR "Can't open $filename: $!\n";
2045             return;
2046         }
2047
2048         while (<$input>) {              # note use of indirection
2049             if (/^#include "(.*)"/) {
2050                 process($1, $input);
2051                 next;
2052             }
2053             ...         # whatever
2054         }
2055     }
2056
2057 You may also, in the Bourne shell tradition, specify an EXPR beginning
2058 with "E<gt>&", in which case the rest of the string is interpreted as the
2059 name of a filehandle (or file descriptor, if numeric) which is to be
2060 duped and opened.  You may use & after E<gt>, E<gt>E<gt>, E<lt>, +E<gt>,
2061 +E<gt>E<gt>, and +E<lt>.  The
2062 mode you specify should match the mode of the original filehandle.
2063 (Duping a filehandle does not take into account any existing contents of
2064 stdio buffers.)
2065 Here is a script that saves, redirects, and restores STDOUT and
2066 STDERR:
2067
2068     #!/usr/bin/perl
2069     open(SAVEOUT, ">&STDOUT");
2070     open(SAVEERR, ">&STDERR");
2071
2072     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
2073     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
2074
2075     select(STDERR); $| = 1;     # make unbuffered
2076     select(STDOUT); $| = 1;     # make unbuffered
2077
2078     print STDOUT "stdout 1\n";  # this works for
2079     print STDERR "stderr 1\n";  # subprocesses too
2080
2081     close(STDOUT);
2082     close(STDERR);
2083
2084     open(STDOUT, ">&SAVEOUT");
2085     open(STDERR, ">&SAVEERR");
2086
2087     print STDOUT "stdout 2\n";
2088     print STDERR "stderr 2\n";
2089
2090
2091 If you specify "E<lt>&=N", where N is a number, then Perl will do an
2092 equivalent of C's fdopen() of that file descriptor; this is more
2093 parsimonious of file descriptors.  For example:
2094
2095     open(FILEHANDLE, "<&=$fd")
2096
2097 If you open a pipe on the command "-", i.e., either "|-" or "-|", then
2098 there is an implicit fork done, and the return value of open is the pid
2099 of the child within the parent process, and 0 within the child
2100 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2101 The filehandle behaves normally for the parent, but i/o to that
2102 filehandle is piped from/to the STDOUT/STDIN of the child process.
2103 In the child process the filehandle isn't opened--i/o happens from/to
2104 the new STDOUT or STDIN.  Typically this is used like the normal
2105 piped open when you want to exercise more control over just how the
2106 pipe command gets executed, such as when you are running setuid, and
2107 don't want to have to scan shell commands for metacharacters.
2108 The following pairs are more or less equivalent:
2109
2110     open(FOO, "|tr '[a-z]' '[A-Z]'");
2111     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2112
2113     open(FOO, "cat -n '$file'|");
2114     open(FOO, "-|") || exec 'cat', '-n', $file;
2115
2116 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2117
2118 NOTE: On any operation which may do a fork, unflushed buffers remain
2119 unflushed in both processes, which means you may need to set C<$|> to
2120 avoid duplicate output.
2121
2122 Closing any piped filehandle causes the parent process to wait for the
2123 child to finish, and returns the status value in C<$?>.
2124
2125 Using the constructor from the IO::Handle package (or one of its
2126 subclasses, such as IO::File or IO::Socket),
2127 you can generate anonymous filehandles which have the scope of whatever
2128 variables hold references to them, and automatically close whenever
2129 and however you leave that scope:
2130
2131     use IO::File;
2132     ...
2133     sub read_myfile_munged {
2134         my $ALL = shift;
2135         my $handle = new IO::File;
2136         open($handle, "myfile") or die "myfile: $!";
2137         $first = <$handle>
2138             or return ();     # Automatically closed here.
2139         mung $first or die "mung failed";       # Or here.
2140         return $first, <$handle> if $ALL;       # Or here.
2141         $first;                                 # Or here.
2142     }
2143
2144 The filename that is passed to open will have leading and trailing
2145 whitespace deleted.  To open a file with arbitrary weird
2146 characters in it, it's necessary to protect any leading and trailing
2147 whitespace thusly:
2148
2149     $file =~ s#^(\s)#./$1#;
2150     open(FOO, "< $file\0");
2151
2152 If you want a "real" C open() (see L<open(2)> on your system), then
2153 you should use the sysopen() function.  This is another way to
2154 protect your filenames from interpretation.  For example:
2155
2156     use IO::Handle;
2157     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL, 0700)
2158         or die "sysopen $path: $!";
2159     HANDLE->autoflush(1);
2160     HANDLE->print("stuff $$\n");
2161     seek(HANDLE, 0, 0);
2162     print "File contains: ", <HANDLE>;
2163
2164 See L</seek()> for some details about mixing reading and writing.
2165
2166 =item opendir DIRHANDLE,EXPR
2167
2168 Opens a directory named EXPR for processing by readdir(), telldir(),
2169 seekdir(), rewinddir(), and closedir().  Returns TRUE if successful.
2170 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2171
2172 =item ord EXPR
2173
2174 =item ord
2175
2176 Returns the numeric ascii value of the first character of EXPR.  If
2177 EXPR is omitted, uses $_.  For the reverse, see L</chr>.
2178
2179 =item pack TEMPLATE,LIST
2180
2181 Takes an array or list of values and packs it into a binary structure,
2182 returning the string containing the structure.  The TEMPLATE is a
2183 sequence of characters that give the order and type of values, as
2184 follows:
2185
2186     A   An ascii string, will be space padded.
2187     a   An ascii string, will be null padded.
2188     b   A bit string (ascending bit order, like vec()).
2189     B   A bit string (descending bit order).
2190     h   A hex string (low nybble first).
2191     H   A hex string (high nybble first).
2192
2193     c   A signed char value.
2194     C   An unsigned char value.
2195
2196     s   A signed short value.
2197     S   An unsigned short value.
2198           (This 'short' is _exactly_ 16 bits, which may differ from
2199            what a local C compiler calls 'short'.)
2200
2201     i   A signed integer value.
2202     I   An unsigned integer value.
2203           (This 'integer' is _at_least_ 32 bits wide.  Its exact size
2204            depends on what a local C compiler calls 'int', and may
2205            even be larger than the 'long' described in the next item.)
2206
2207     l   A signed long value.
2208     L   An unsigned long value.
2209           (This 'long' is _exactly_ 32 bits, which may differ from
2210            what a local C compiler calls 'long'.)
2211
2212     n   A short in "network" (big-endian) order.
2213     N   A long in "network" (big-endian) order.
2214     v   A short in "VAX" (little-endian) order.
2215     V   A long in "VAX" (little-endian) order.
2216           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2217            _exactly_ 32 bits, respectively.)
2218
2219     f   A single-precision float in the native format.
2220     d   A double-precision float in the native format.
2221
2222     p   A pointer to a null-terminated string.
2223     P   A pointer to a structure (fixed-length string).
2224
2225     u   A uuencoded string.
2226
2227     w   A BER compressed integer.  Its bytes represent an unsigned
2228         integer in base 128, most significant digit first, with as few
2229         digits as possible.  Bit eight (the high bit) is set on each
2230         byte except the last.
2231
2232     x   A null byte.
2233     X   Back up a byte.
2234     @   Null fill to absolute position.
2235
2236 Each letter may optionally be followed by a number which gives a repeat
2237 count.  With all types except "a", "A", "b", "B", "h", "H", and "P" the
2238 pack function will gobble up that many values from the LIST.  A * for the
2239 repeat count means to use however many items are left.  The "a" and "A"
2240 types gobble just one value, but pack it as a string of length count,
2241 padding with nulls or spaces as necessary.  (When unpacking, "A" strips
2242 trailing spaces and nulls, but "a" does not.)  Likewise, the "b" and "B"
2243 fields pack a string that many bits long.  The "h" and "H" fields pack a
2244 string that many nybbles long.  The "p" type packs a pointer to a null-
2245 terminated string.  You are responsible for ensuring the string is not a
2246 temporary value (which can potentially get deallocated before you get
2247 around to using the packed result).  The "P" packs a pointer to a structure
2248 of the size indicated by the length. A NULL pointer is created if the 
2249 corresponding value for "p" or "P" is C<undef>.
2250 Real numbers (floats and doubles) are
2251 in the native machine format only; due to the multiplicity of floating
2252 formats around, and the lack of a standard "network" representation, no
2253 facility for interchange has been made.  This means that packed floating
2254 point data written on one machine may not be readable on another - even if
2255 both use IEEE floating point arithmetic (as the endian-ness of the memory
2256 representation is not part of the IEEE spec).  Note that Perl uses doubles
2257 internally for all numeric calculation, and converting from double into
2258 float and thence back to double again will lose precision (i.e.,
2259 C<unpack("f", pack("f", $foo)>) will not in general equal $foo).
2260
2261 Examples:
2262
2263     $foo = pack("cccc",65,66,67,68);
2264     # foo eq "ABCD"
2265     $foo = pack("c4",65,66,67,68);
2266     # same thing
2267
2268     $foo = pack("ccxxcc",65,66,67,68);
2269     # foo eq "AB\0\0CD"
2270
2271     $foo = pack("s2",1,2);
2272     # "\1\0\2\0" on little-endian
2273     # "\0\1\0\2" on big-endian
2274
2275     $foo = pack("a4","abcd","x","y","z");
2276     # "abcd"
2277
2278     $foo = pack("aaaa","abcd","x","y","z");
2279     # "axyz"
2280
2281     $foo = pack("a14","abcdefg");
2282     # "abcdefg\0\0\0\0\0\0\0"
2283
2284     $foo = pack("i9pl", gmtime);
2285     # a real struct tm (on my system anyway)
2286
2287     sub bintodec {
2288         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2289     }
2290
2291 The same template may generally also be used in the unpack function.
2292
2293 =item package NAMESPACE
2294
2295 Declares the compilation unit as being in the given namespace.  The scope
2296 of the package declaration is from the declaration itself through the end of
2297 the enclosing block (the same scope as the local() operator).  All further
2298 unqualified dynamic identifiers will be in this namespace.  A package
2299 statement affects only dynamic variables--including those you've used
2300 local() on--but I<not> lexical variables created with my().  Typically it
2301 would be the first declaration in a file to be included by the C<require>
2302 or C<use> operator.  You can switch into a package in more than one place;
2303 it influences merely which symbol table is used by the compiler for the
2304 rest of that block.  You can refer to variables and filehandles in other
2305 packages by prefixing the identifier with the package name and a double
2306 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2307 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2308
2309 See L<perlmod/"Packages"> for more information about packages, modules,
2310 and classes.  See L<perlsub> for other scoping issues.
2311
2312 =item pipe READHANDLE,WRITEHANDLE
2313
2314 Opens a pair of connected pipes like the corresponding system call.
2315 Note that if you set up a loop of piped processes, deadlock can occur
2316 unless you are very careful.  In addition, note that Perl's pipes use
2317 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2318 after each command, depending on the application.
2319
2320 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2321 for examples of such things.
2322
2323 =item pop ARRAY
2324
2325 =item pop
2326
2327 Pops and returns the last value of the array, shortening the array by
2328 1.  Has a similar effect to
2329
2330     $tmp = $ARRAY[$#ARRAY--];
2331
2332 If there are no elements in the array, returns the undefined value.
2333 If ARRAY is omitted, pops the
2334 @ARGV array in the main program, and the @_ array in subroutines, just
2335 like shift().
2336
2337 =item pos SCALAR
2338
2339 =item pos
2340
2341 Returns the offset of where the last C<m//g> search left off for the variable
2342 is in question ($_ is used when the variable is not specified).  May be
2343 modified to change that offset.  Such modification will also influence
2344 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2345 L<perlop>.
2346
2347 =item print FILEHANDLE LIST
2348
2349 =item print LIST
2350
2351 =item print
2352
2353 Prints a string or a comma-separated list of strings.  Returns TRUE
2354 if successful.  FILEHANDLE may be a scalar variable name, in which case
2355 the variable contains the name of or a reference to the filehandle, thus introducing one
2356 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2357 token is a term, it may be misinterpreted as an operator unless you
2358 interpose a + or put parentheses around the arguments.)  If FILEHANDLE is
2359 omitted, prints by default to standard output (or to the last selected
2360 output channel--see L</select>).  If LIST is also omitted, prints $_ to
2361 STDOUT.  To set the default output channel to something other than
2362 STDOUT use the select operation.  Note that, because print takes a
2363 LIST, anything in the LIST is evaluated in a list context, and any
2364 subroutine that you call will have one or more of its expressions
2365 evaluated in a list context.  Also be careful not to follow the print
2366 keyword with a left parenthesis unless you want the corresponding right
2367 parenthesis to terminate the arguments to the print--interpose a + or
2368 put parentheses around all the arguments.
2369
2370 Note that if you're storing FILEHANDLES in an array or other expression,
2371 you will have to use a block returning its value instead:
2372
2373     print { $files[$i] } "stuff\n";
2374     print { $OK ? STDOUT : STDERR } "stuff\n";
2375
2376 =item printf FILEHANDLE FORMAT, LIST
2377
2378 =item printf FORMAT, LIST
2379
2380 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that $\
2381 (the output record separator) is not appended.  The first argument
2382 of the list will be interpreted as the printf format.  If C<use locale> is
2383 in effect, the character used for the decimal point in formatted real numbers
2384 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2385
2386 Don't fall into the trap of using a printf() when a simple
2387 print() would do.  The print() is more efficient, and less
2388 error prone.
2389
2390 =item prototype FUNCTION
2391
2392 Returns the prototype of a function as a string (or C<undef> if the
2393 function has no prototype).  FUNCTION is a reference to, or the name of,
2394 the function whose prototype you want to retrieve.
2395
2396 If FUNCTION is a string starting with C<CORE::>, the rest is taken as
2397 a name for Perl builtin.  If builtin is not I<overridable> (such as
2398 C<qw>) or its arguments cannot be expressed by a prototype (such as
2399 C<system>) - in other words, the builtin does not behave like a Perl
2400 function - returns C<undef>.  Otherwise, the string describing the
2401 equivalent prototype is returned.
2402
2403 =item push ARRAY,LIST
2404
2405 Treats ARRAY as a stack, and pushes the values of LIST
2406 onto the end of ARRAY.  The length of ARRAY increases by the length of
2407 LIST.  Has the same effect as
2408
2409     for $value (LIST) {
2410         $ARRAY[++$#ARRAY] = $value;
2411     }
2412
2413 but is more efficient.  Returns the new number of elements in the array.
2414
2415 =item q/STRING/
2416
2417 =item qq/STRING/
2418
2419 =item qx/STRING/
2420
2421 =item qw/STRING/
2422
2423 Generalized quotes.  See L<perlop>.
2424
2425 =item quotemeta EXPR
2426
2427 =item quotemeta
2428
2429 Returns the value of EXPR with all non-alphanumeric
2430 characters backslashed.  (That is, all characters not matching
2431 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2432 returned string, regardless of any locale settings.)
2433 This is the internal function implementing
2434 the \Q escape in double-quoted strings.
2435
2436 If EXPR is omitted, uses $_.
2437
2438 =item rand EXPR
2439
2440 =item rand
2441
2442 Returns a random fractional number greater than or equal to 0 and less
2443 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
2444 omitted, the value 1 is used.  Automatically calls srand() unless
2445 srand() has already been called.  See also srand().
2446
2447 (Note: If your rand function consistently returns numbers that are too
2448 large or too small, then your version of Perl was probably compiled
2449 with the wrong number of RANDBITS.)
2450
2451 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2452
2453 =item read FILEHANDLE,SCALAR,LENGTH
2454
2455 Attempts to read LENGTH bytes of data into variable SCALAR from the
2456 specified FILEHANDLE.  Returns the number of bytes actually read, or
2457 undef if there was an error.  SCALAR will be grown or shrunk to the
2458 length actually read.  An OFFSET may be specified to place the read
2459 data at some other place than the beginning of the string.  This call
2460 is actually implemented in terms of stdio's fread call.  To get a true
2461 read system call, see sysread().
2462
2463 =item readdir DIRHANDLE
2464
2465 Returns the next directory entry for a directory opened by opendir().
2466 If used in a list context, returns all the rest of the entries in the
2467 directory.  If there are no more entries, returns an undefined value in
2468 a scalar context or a null list in a list context.
2469
2470 If you're planning to filetest the return values out of a readdir(), you'd
2471 better prepend the directory in question.  Otherwise, because we didn't
2472 chdir() there, it would have been testing the wrong file.
2473
2474     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2475     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2476     closedir DIR;
2477
2478 =item readline EXPR
2479
2480 Reads from the file handle EXPR.  In scalar context, a single line
2481 is read and returned.  In list context, reads until end-of-file is
2482 reached and returns a list of lines (however you've defined lines
2483 with $/ or $INPUT_RECORD_SEPARATOR).
2484 This is the internal function implementing the C<E<lt>EXPRE<gt>>
2485 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
2486 operator is discussed in more detail in L<perlop/"I/O Operators">.
2487
2488 =item readlink EXPR
2489
2490 =item readlink
2491
2492 Returns the value of a symbolic link, if symbolic links are
2493 implemented.  If not, gives a fatal error.  If there is some system
2494 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2495 omitted, uses $_.
2496
2497 =item readpipe EXPR
2498
2499 EXPR is interpolated and then executed as a system command.
2500 The collected standard output of the command is returned.
2501 In scalar context, it comes back as a single (potentially
2502 multi-line) string.  In list context, returns a list of lines
2503 (however you've defined lines with $/ or $INPUT_RECORD_SEPARATOR).
2504 This is the internal function implementing the C<qx/EXPR/>
2505 operator, but you can use it directly.  The C<qx/EXPR/>
2506 operator is discussed in more detail in L<perlop/"I/O Operators">.
2507
2508 =item recv SOCKET,SCALAR,LEN,FLAGS
2509
2510 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2511 data into variable SCALAR from the specified SOCKET filehandle.
2512 Actually does a C recvfrom(), so that it can return the address of the
2513 sender.  Returns the undefined value if there's an error.  SCALAR will
2514 be grown or shrunk to the length actually read.  Takes the same flags
2515 as the system call of the same name.
2516 See L<perlipc/"UDP: Message Passing"> for examples.
2517
2518 =item redo LABEL
2519
2520 =item redo
2521
2522 The C<redo> command restarts the loop block without evaluating the
2523 conditional again.  The C<continue> block, if any, is not executed.  If
2524 the LABEL is omitted, the command refers to the innermost enclosing
2525 loop.  This command is normally used by programs that want to lie to
2526 themselves about what was just input:
2527
2528     # a simpleminded Pascal comment stripper
2529     # (warning: assumes no { or } in strings)
2530     LINE: while (<STDIN>) {
2531         while (s|({.*}.*){.*}|$1 |) {}
2532         s|{.*}| |;
2533         if (s|{.*| |) {
2534             $front = $_;
2535             while (<STDIN>) {
2536                 if (/}/) {      # end of comment?
2537                     s|^|$front{|;
2538                     redo LINE;
2539                 }
2540             }
2541         }
2542         print;
2543     }
2544
2545 =item ref EXPR
2546
2547 =item ref
2548
2549 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2550 is not specified, $_ will be used.  The value returned depends on the
2551 type of thing the reference is a reference to.
2552 Builtin types include:
2553
2554     REF
2555     SCALAR
2556     ARRAY
2557     HASH
2558     CODE
2559     GLOB
2560
2561 If the referenced object has been blessed into a package, then that package
2562 name is returned instead.  You can think of ref() as a typeof() operator.
2563
2564     if (ref($r) eq "HASH") {
2565         print "r is a reference to a hash.\n";
2566     }
2567     if (!ref ($r) {
2568         print "r is not a reference at all.\n";
2569     }
2570
2571 See also L<perlref>.
2572
2573 =item rename OLDNAME,NEWNAME
2574
2575 Changes the name of a file.  Returns 1 for success, 0 otherwise.  Will
2576 not work across file system boundaries.
2577
2578 =item require EXPR
2579
2580 =item require
2581
2582 Demands some semantics specified by EXPR, or by $_ if EXPR is not
2583 supplied.  If EXPR is numeric, demands that the current version of Perl
2584 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2585
2586 Otherwise, demands that a library file be included if it hasn't already
2587 been included.  The file is included via the do-FILE mechanism, which is
2588 essentially just a variety of eval().  Has semantics similar to the following
2589 subroutine:
2590
2591     sub require {
2592         local($filename) = @_;
2593         return 1 if $INC{$filename};
2594         local($realfilename,$result);
2595         ITER: {
2596             foreach $prefix (@INC) {
2597                 $realfilename = "$prefix/$filename";
2598                 if (-f $realfilename) {
2599                     $result = do $realfilename;
2600                     last ITER;
2601                 }
2602             }
2603             die "Can't find $filename in \@INC";
2604         }
2605         die $@ if $@;
2606         die "$filename did not return true value" unless $result;
2607         $INC{$filename} = $realfilename;
2608         $result;
2609     }
2610
2611 Note that the file will not be included twice under the same specified
2612 name.  The file must return TRUE as the last statement to indicate
2613 successful execution of any initialization code, so it's customary to
2614 end such a file with "1;" unless you're sure it'll return TRUE
2615 otherwise.  But it's better just to put the "C<1;>", in case you add more
2616 statements.
2617
2618 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
2619 replaces "F<::>" with "F</>" in the filename for you,
2620 to make it easy to load standard modules.  This form of loading of
2621 modules does not risk altering your namespace.
2622
2623 For a yet-more-powerful import facility, see L</use> and
2624 L<perlmod>.
2625
2626 =item reset EXPR
2627
2628 =item reset
2629
2630 Generally used in a C<continue> block at the end of a loop to clear
2631 variables and reset ?? searches so that they work again.  The
2632 expression is interpreted as a list of single characters (hyphens
2633 allowed for ranges).  All variables and arrays beginning with one of
2634 those letters are reset to their pristine state.  If the expression is
2635 omitted, one-match searches (?pattern?) are reset to match again.  Resets
2636 only variables or searches in the current package.  Always returns
2637 1.  Examples:
2638
2639     reset 'X';          # reset all X variables
2640     reset 'a-z';        # reset lower case variables
2641     reset;              # just reset ?? searches
2642
2643 Resetting "A-Z" is not recommended because you'll wipe out your
2644 ARGV and ENV arrays.  Resets only package variables--lexical variables
2645 are unaffected, but they clean themselves up on scope exit anyway,
2646 so you'll probably want to use them instead.  See L</my>.
2647
2648 =item return EXPR
2649
2650 =item return
2651
2652 Returns from a subroutine, eval(), or do FILE with the value of the
2653 given EXPR.  Evaluation of EXPR may be in a list, scalar, or void
2654 context, depending on how the return value will be used, and the context
2655 may vary from one execution to the next (see wantarray()).  If no EXPR
2656 is given, returns an empty list in a list context, an undefined value in
2657 a scalar context, or nothing in a void context.
2658
2659 (Note that in the absence of a return, a subroutine, eval, or do FILE
2660 will automatically return the value of the last expression evaluated.)
2661
2662 =item reverse LIST
2663
2664 In a list context, returns a list value consisting of the elements
2665 of LIST in the opposite order.  In a scalar context, concatenates the
2666 elements of LIST, and returns a string value consisting of those bytes,
2667 but in the opposite order.
2668
2669     print reverse <>;           # line tac, last line first
2670
2671     undef $/;                   # for efficiency of <>
2672     print scalar reverse <>;    # byte tac, last line tsrif
2673
2674 This operator is also handy for inverting a hash, although there are some
2675 caveats.  If a value is duplicated in the original hash, only one of those
2676 can be represented as a key in the inverted hash.  Also, this has to
2677 unwind one hash and build a whole new one, which may take some time
2678 on a large hash.
2679
2680     %by_name = reverse %by_address;     # Invert the hash
2681
2682 =item rewinddir DIRHANDLE
2683
2684 Sets the current position to the beginning of the directory for the
2685 readdir() routine on DIRHANDLE.
2686
2687 =item rindex STR,SUBSTR,POSITION
2688
2689 =item rindex STR,SUBSTR
2690
2691 Works just like index except that it returns the position of the LAST
2692 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2693 last occurrence at or before that position.
2694
2695 =item rmdir FILENAME
2696
2697 =item rmdir
2698
2699 Deletes the directory specified by FILENAME if it is empty.  If it
2700 succeeds it returns 1, otherwise it returns 0 and sets C<$!> (errno).  If
2701 FILENAME is omitted, uses $_.
2702
2703 =item s///
2704
2705 The substitution operator.  See L<perlop>.
2706
2707 =item scalar EXPR
2708
2709 Forces EXPR to be interpreted in a scalar context and returns the value
2710 of EXPR.
2711
2712     @counts = ( scalar @a, scalar @b, scalar @c );
2713
2714 There is no equivalent operator to force an expression to
2715 be interpolated in a list context because it's in practice never
2716 needed.  If you really wanted to do so, however, you could use
2717 the construction C<@{[ (some expression) ]}>, but usually a simple
2718 C<(some expression)> suffices.
2719
2720 =item seek FILEHANDLE,POSITION,WHENCE
2721
2722 Sets FILEHANDLE's position, just like the fseek() call of stdio.
2723 FILEHANDLE may be an expression whose value gives the name of the
2724 filehandle.  The values for WHENCE are 0 to set the new position to
2725 POSITION, 1 to set it to the current position plus POSITION, and 2 to
2726 set it to EOF plus POSITION (typically negative).  For WHENCE you may
2727 use the constants SEEK_SET, SEEK_CUR, and SEEK_END from either the
2728 IO::Seekable or the POSIX module.  Returns 1 upon success, 0 otherwise.
2729
2730 If you want to position file for sysread() or syswrite(), don't use
2731 seek() -- buffering makes its effect on the file's system position
2732 unpredictable and non-portable.  Use sysseek() instead.
2733
2734 On some systems you have to do a seek whenever you switch between reading
2735 and writing.  Amongst other things, this may have the effect of calling
2736 stdio's clearerr(3).  A WHENCE of 1 (SEEK_CUR) is useful for not moving
2737 the file position:
2738
2739     seek(TEST,0,1);
2740
2741 This is also useful for applications emulating C<tail -f>.  Once you hit
2742 EOF on your read, and then sleep for a while, you might have to stick in a
2743 seek() to reset things.  The seek() doesn't change the current position,
2744 but it I<does> clear the end-of-file condition on the handle, so that the
2745 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
2746
2747 If that doesn't work (some stdios are particularly cantankerous), then
2748 you may need something more like this:
2749
2750     for (;;) {
2751         for ($curpos = tell(FILE); $_ = <FILE>; $curpos = tell(FILE)) {
2752             # search for some stuff and put it into files
2753         }
2754         sleep($for_a_while);
2755         seek(FILE, $curpos, 0);
2756     }
2757
2758 =item seekdir DIRHANDLE,POS
2759
2760 Sets the current position for the readdir() routine on DIRHANDLE.  POS
2761 must be a value returned by telldir().  Has the same caveats about
2762 possible directory compaction as the corresponding system library
2763 routine.
2764
2765 =item select FILEHANDLE
2766
2767 =item select
2768
2769 Returns the currently selected filehandle.  Sets the current default
2770 filehandle for output, if FILEHANDLE is supplied.  This has two
2771 effects: first, a C<write> or a C<print> without a filehandle will
2772 default to this FILEHANDLE.  Second, references to variables related to
2773 output will refer to this output channel.  For example, if you have to
2774 set the top of form format for more than one output channel, you might
2775 do the following:
2776
2777     select(REPORT1);
2778     $^ = 'report1_top';
2779     select(REPORT2);
2780     $^ = 'report2_top';
2781
2782 FILEHANDLE may be an expression whose value gives the name of the
2783 actual filehandle.  Thus:
2784
2785     $oldfh = select(STDERR); $| = 1; select($oldfh);
2786
2787 Some programmers may prefer to think of filehandles as objects with
2788 methods, preferring to write the last example as:
2789
2790     use IO::Handle;
2791     STDERR->autoflush(1);
2792
2793 =item select RBITS,WBITS,EBITS,TIMEOUT
2794
2795 This calls the select(2) system call with the bit masks specified, which
2796 can be constructed using fileno() and vec(), along these lines:
2797
2798     $rin = $win = $ein = '';
2799     vec($rin,fileno(STDIN),1) = 1;
2800     vec($win,fileno(STDOUT),1) = 1;
2801     $ein = $rin | $win;
2802
2803 If you want to select on many filehandles you might wish to write a
2804 subroutine:
2805
2806     sub fhbits {
2807         local(@fhlist) = split(' ',$_[0]);
2808         local($bits);
2809         for (@fhlist) {
2810             vec($bits,fileno($_),1) = 1;
2811         }
2812         $bits;
2813     }
2814     $rin = fhbits('STDIN TTY SOCK');
2815
2816 The usual idiom is:
2817
2818     ($nfound,$timeleft) =
2819       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
2820
2821 or to block until something becomes ready just do this
2822
2823     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
2824
2825 Most systems do not bother to return anything useful in $timeleft, so
2826 calling select() in a scalar context just returns $nfound.
2827
2828 Any of the bit masks can also be undef.  The timeout, if specified, is
2829 in seconds, which may be fractional.  Note: not all implementations are
2830 capable of returning the $timeleft.  If not, they always return
2831 $timeleft equal to the supplied $timeout.
2832
2833 You can effect a sleep of 250 milliseconds this way:
2834
2835     select(undef, undef, undef, 0.25);
2836
2837 B<WARNING>: Do not attempt to mix buffered I/O (like read() or E<lt>FHE<gt>)
2838 with select().  You have to use sysread() instead.
2839
2840 =item semctl ID,SEMNUM,CMD,ARG
2841
2842 Calls the System V IPC function semctl.  If CMD is &IPC_STAT or
2843 &GETALL, then ARG must be a variable which will hold the returned
2844 semid_ds structure or semaphore value array.  Returns like ioctl: the
2845 undefined value for error, "0 but true" for zero, or the actual return
2846 value otherwise.
2847
2848 =item semget KEY,NSEMS,FLAGS
2849
2850 Calls the System V IPC function semget.  Returns the semaphore id, or
2851 the undefined value if there is an error.
2852
2853 =item semop KEY,OPSTRING
2854
2855 Calls the System V IPC function semop to perform semaphore operations
2856 such as signaling and waiting.  OPSTRING must be a packed array of
2857 semop structures.  Each semop structure can be generated with
2858 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
2859 operations is implied by the length of OPSTRING.  Returns TRUE if
2860 successful, or FALSE if there is an error.  As an example, the
2861 following code waits on semaphore $semnum of semaphore id $semid:
2862
2863     $semop = pack("sss", $semnum, -1, 0);
2864     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
2865
2866 To signal the semaphore, replace "-1" with "1".
2867
2868 =item send SOCKET,MSG,FLAGS,TO
2869
2870 =item send SOCKET,MSG,FLAGS
2871
2872 Sends a message on a socket.  Takes the same flags as the system call
2873 of the same name.  On unconnected sockets you must specify a
2874 destination to send TO, in which case it does a C sendto().  Returns
2875 the number of characters sent, or the undefined value if there is an
2876 error.
2877 See L<perlipc/"UDP: Message Passing"> for examples.
2878
2879 =item setpgrp PID,PGRP
2880
2881 Sets the current process group for the specified PID, 0 for the current
2882 process.  Will produce a fatal error if used on a machine that doesn't
2883 implement setpgrp(2).  If the arguments are omitted, it defaults to
2884 0,0.  Note that the POSIX version of setpgrp() does not accept any
2885 arguments, so only setpgrp 0,0 is portable.
2886
2887 =item setpriority WHICH,WHO,PRIORITY
2888
2889 Sets the current priority for a process, a process group, or a user.
2890 (See setpriority(2).)  Will produce a fatal error if used on a machine
2891 that doesn't implement setpriority(2).
2892
2893 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
2894
2895 Sets the socket option requested.  Returns undefined if there is an
2896 error.  OPTVAL may be specified as undef if you don't want to pass an
2897 argument.
2898
2899 =item shift ARRAY
2900
2901 =item shift
2902
2903 Shifts the first value of the array off and returns it, shortening the
2904 array by 1 and moving everything down.  If there are no elements in the
2905 array, returns the undefined value.  If ARRAY is omitted, shifts the
2906 @_ array within the lexical scope of subroutines and formats, and the
2907 @ARGV array at file scopes or within the lexical scopes established by
2908 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
2909 See also unshift(), push(), and pop().  Shift() and unshift() do the
2910 same thing to the left end of an array that pop() and push() do to the
2911 right end.
2912
2913 =item shmctl ID,CMD,ARG
2914
2915 Calls the System V IPC function shmctl.  If CMD is &IPC_STAT, then ARG
2916 must be a variable which will hold the returned shmid_ds structure.
2917 Returns like ioctl: the undefined value for error, "0 but true" for
2918 zero, or the actual return value otherwise.
2919
2920 =item shmget KEY,SIZE,FLAGS
2921
2922 Calls the System V IPC function shmget.  Returns the shared memory
2923 segment id, or the undefined value if there is an error.
2924
2925 =item shmread ID,VAR,POS,SIZE
2926
2927 =item shmwrite ID,STRING,POS,SIZE
2928
2929 Reads or writes the System V shared memory segment ID starting at
2930 position POS for size SIZE by attaching to it, copying in/out, and
2931 detaching from it.  When reading, VAR must be a variable which will
2932 hold the data read.  When writing, if STRING is too long, only SIZE
2933 bytes are used; if STRING is too short, nulls are written to fill out
2934 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
2935
2936 =item shutdown SOCKET,HOW
2937
2938 Shuts down a socket connection in the manner indicated by HOW, which
2939 has the same interpretation as in the system call of the same name.
2940
2941 =item sin EXPR
2942
2943 =item sin
2944
2945 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
2946 returns sine of $_.
2947
2948 For the inverse sine operation, you may use the POSIX::asin()
2949 function, or use this relation:
2950
2951     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
2952
2953 =item sleep EXPR
2954
2955 =item sleep
2956
2957 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
2958 May be interrupted by sending the process a SIGALRM.  Returns the
2959 number of seconds actually slept.  You probably cannot mix alarm() and
2960 sleep() calls, because sleep() is often implemented using alarm().
2961
2962 On some older systems, it may sleep up to a full second less than what
2963 you requested, depending on how it counts seconds.  Most modern systems
2964 always sleep the full amount.
2965
2966 For delays of finer granularity than one second, you may use Perl's
2967 syscall() interface to access setitimer(2) if your system supports it,
2968 or else see L</select()> below.
2969
2970 See also the POSIX module's sigpause() function.
2971
2972 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
2973
2974 Opens a socket of the specified kind and attaches it to filehandle
2975 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
2976 system call of the same name.  You should "use Socket;" first to get
2977 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2978
2979 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
2980
2981 Creates an unnamed pair of sockets in the specified domain, of the
2982 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
2983 for the system call of the same name.  If unimplemented, yields a fatal
2984 error.  Returns TRUE if successful.
2985
2986 =item sort SUBNAME LIST
2987
2988 =item sort BLOCK LIST
2989
2990 =item sort LIST
2991
2992 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
2993 is omitted, sorts in standard string comparison order.  If SUBNAME is
2994 specified, it gives the name of a subroutine that returns an integer
2995 less than, equal to, or greater than 0, depending on how the elements
2996 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
2997 operators are extremely useful in such routines.)  SUBNAME may be a
2998 scalar variable name, in which case the value provides the name of the
2999 subroutine to use.  In place of a SUBNAME, you can provide a BLOCK as
3000 an anonymous, in-line sort subroutine.
3001
3002 In the interests of efficiency the normal calling code for subroutines is
3003 bypassed, with the following effects: the subroutine may not be a
3004 recursive subroutine, and the two elements to be compared are passed into
3005 the subroutine not via @_ but as the package global variables $a and
3006 $b (see example below).  They are passed by reference, so don't
3007 modify $a and $b.  And don't try to declare them as lexicals either.
3008
3009 You also cannot exit out of the sort block or subroutine using any of the
3010 loop control operators described in L<perlsyn> or with goto().
3011
3012 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3013 current collation locale.  See L<perllocale>.
3014
3015 Examples:
3016
3017     # sort lexically
3018     @articles = sort @files;
3019
3020     # same thing, but with explicit sort routine
3021     @articles = sort {$a cmp $b} @files;
3022
3023     # now case-insensitively
3024     @articles = sort {uc($a) cmp uc($b)} @files;
3025
3026     # same thing in reversed order
3027     @articles = sort {$b cmp $a} @files;
3028
3029     # sort numerically ascending
3030     @articles = sort {$a <=> $b} @files;
3031
3032     # sort numerically descending
3033     @articles = sort {$b <=> $a} @files;
3034
3035     # sort using explicit subroutine name
3036     sub byage {
3037         $age{$a} <=> $age{$b};  # presuming numeric
3038     }
3039     @sortedclass = sort byage @class;
3040
3041     # this sorts the %age hash by value instead of key
3042     # using an in-line function
3043     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3044
3045     sub backwards { $b cmp $a; }
3046     @harry = ('dog','cat','x','Cain','Abel');
3047     @george = ('gone','chased','yz','Punished','Axed');
3048     print sort @harry;
3049             # prints AbelCaincatdogx
3050     print sort backwards @harry;
3051             # prints xdogcatCainAbel
3052     print sort @george, 'to', @harry;
3053             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3054
3055     # inefficiently sort by descending numeric compare using
3056     # the first integer after the first = sign, or the
3057     # whole record case-insensitively otherwise
3058
3059     @new = sort {
3060         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3061                             ||
3062                     uc($a)  cmp  uc($b)
3063     } @old;
3064
3065     # same thing, but much more efficiently;
3066     # we'll build auxiliary indices instead
3067     # for speed
3068     @nums = @caps = ();
3069     for (@old) {
3070         push @nums, /=(\d+)/;
3071         push @caps, uc($_);
3072     }
3073
3074     @new = @old[ sort {
3075                         $nums[$b] <=> $nums[$a]
3076                                  ||
3077                         $caps[$a] cmp $caps[$b]
3078                        } 0..$#old
3079                ];
3080
3081     # same thing using a Schwartzian Transform (no temps)
3082     @new = map { $_->[0] }
3083         sort { $b->[1] <=> $a->[1]
3084                         ||
3085                $a->[2] cmp $b->[2]
3086         } map { [$_, /=(\d+)/, uc($_)] } @old;
3087
3088 If you're using strict, you I<MUST NOT> declare $a
3089 and $b as lexicals.  They are package globals.  That means
3090 if you're in the C<main> package, it's
3091
3092     @articles = sort {$main::b <=> $main::a} @files;
3093
3094 or just
3095
3096     @articles = sort {$::b <=> $::a} @files;
3097
3098 but if you're in the C<FooPack> package, it's
3099
3100     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3101
3102 The comparison function is required to behave.  If it returns
3103 inconsistent results (sometimes saying $x[1] is less than $x[2] and
3104 sometimes saying the opposite, for example) the Perl interpreter will
3105 probably crash and dump core.  This is entirely due to and dependent
3106 upon your system's qsort(3) library routine; this routine often avoids
3107 sanity checks in the interest of speed.
3108
3109 =item splice ARRAY,OFFSET,LENGTH,LIST
3110
3111 =item splice ARRAY,OFFSET,LENGTH
3112
3113 =item splice ARRAY,OFFSET
3114
3115 Removes the elements designated by OFFSET and LENGTH from an array, and
3116 replaces them with the elements of LIST, if any.  In a list context,
3117 returns the elements removed from the array.  In a scalar context,
3118 returns the last element removed, or C<undef> if no elements are
3119 removed.  The array grows or shrinks as necessary.  If LENGTH is
3120 omitted, removes everything from OFFSET onward.  The following
3121 equivalences hold (assuming C<$[ == 0>):
3122
3123     push(@a,$x,$y)      splice(@a,$#a+1,0,$x,$y)
3124     pop(@a)             splice(@a,-1)
3125     shift(@a)           splice(@a,0,1)
3126     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3127     $a[$x] = $y         splice(@a,$x,1,$y);
3128
3129 Example, assuming array lengths are passed before arrays:
3130
3131     sub aeq {   # compare two list values
3132         local(@a) = splice(@_,0,shift);
3133         local(@b) = splice(@_,0,shift);
3134         return 0 unless @a == @b;       # same len?
3135         while (@a) {
3136             return 0 if pop(@a) ne pop(@b);
3137         }
3138         return 1;
3139     }
3140     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3141
3142 =item split /PATTERN/,EXPR,LIMIT
3143
3144 =item split /PATTERN/,EXPR
3145
3146 =item split /PATTERN/
3147
3148 =item split
3149
3150 Splits a string into an array of strings, and returns it.
3151
3152 If not in a list context, returns the number of fields found and splits into
3153 the @_ array.  (In a list context, you can force the split into @_ by
3154 using C<??> as the pattern delimiters, but it still returns the array
3155 value.)  The use of implicit split to @_ is deprecated, however.
3156
3157 If EXPR is omitted, splits the $_ string.  If PATTERN is also omitted,
3158 splits on whitespace (after skipping any leading whitespace).  Anything
3159 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3160 that the delimiter may be longer than one character.)
3161
3162 If LIMIT is specified and is not negative, splits into no more than
3163 that many fields (though it may split into fewer).  If LIMIT is
3164 unspecified, trailing null fields are stripped (which potential users
3165 of pop() would do well to remember).  If LIMIT is negative, it is
3166 treated as if an arbitrarily large LIMIT had been specified.
3167
3168 A pattern matching the null string (not to be confused with
3169 a null pattern C<//>, which is just one member of the set of patterns
3170 matching a null string) will split the value of EXPR into separate
3171 characters at each point it matches that way.  For example:
3172
3173     print join(':', split(/ */, 'hi there'));
3174
3175 produces the output 'h:i:t:h:e:r:e'.
3176
3177 The LIMIT parameter can be used to split a line partially
3178
3179     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3180
3181 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3182 one larger than the number of variables in the list, to avoid
3183 unnecessary work.  For the list above LIMIT would have been 4 by
3184 default.  In time critical applications it behooves you not to split
3185 into more fields than you really need.
3186
3187 If the PATTERN contains parentheses, additional array elements are
3188 created from each matching substring in the delimiter.
3189
3190     split(/([,-])/, "1-10,20", 3);
3191
3192 produces the list value
3193
3194     (1, '-', 10, ',', 20)
3195
3196 If you had the entire header of a normal Unix email message in $header,
3197 you could split it up into fields and their values this way:
3198
3199     $header =~ s/\n\s+/ /g;  # fix continuation lines
3200     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
3201
3202 The pattern C</PATTERN/> may be replaced with an expression to specify
3203 patterns that vary at runtime.  (To do runtime compilation only once,
3204 use C</$variable/o>.)
3205
3206 As a special case, specifying a PATTERN of space (C<' '>) will split on
3207 white space just as split with no arguments does.  Thus, split(' ') can
3208 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3209 will give you as many null initial fields as there are leading spaces.
3210 A split on /\s+/ is like a split(' ') except that any leading
3211 whitespace produces a null first field.  A split with no arguments
3212 really does a C<split(' ', $_)> internally.
3213
3214 Example:
3215
3216     open(passwd, '/etc/passwd');
3217     while (<passwd>) {
3218         ($login, $passwd, $uid, $gid, $gcos,
3219             $home, $shell) = split(/:/);
3220         ...
3221     }
3222
3223 (Note that $shell above will still have a newline on it.  See L</chop>,
3224 L</chomp>, and L</join>.)
3225
3226 =item sprintf FORMAT, LIST
3227
3228 Returns a string formatted by the usual printf conventions of the
3229 C library function sprintf().  See L<sprintf(3)> or L<printf(3)>
3230 on your system for an explanation of the general principles.
3231
3232 Perl does all of its own sprintf() formatting -- it emulates the C
3233 function sprintf(), but it doesn't use it (except for floating-point
3234 numbers, and even then only the standard modifiers are allowed).  As a
3235 result, any non-standard extensions in your local sprintf() are not
3236 available from Perl.
3237
3238 Perl's sprintf() permits the following universally-known conversions:
3239
3240    %%   a percent sign
3241    %c   a character with the given number
3242    %s   a string
3243    %d   a signed integer, in decimal
3244    %u   an unsigned integer, in decimal
3245    %o   an unsigned integer, in octal
3246    %x   an unsigned integer, in hexadecimal
3247    %e   a floating-point number, in scientific notation
3248    %f   a floating-point number, in fixed decimal notation
3249    %g   a floating-point number, in %e or %f notation
3250
3251 In addition, Perl permits the following widely-supported conversions:
3252
3253    %X   like %x, but using upper-case letters
3254    %E   like %e, but using an upper-case "E"
3255    %G   like %g, but with an upper-case "E" (if applicable)
3256    %p   a pointer (outputs the Perl value's address in hexadecimal)
3257    %n   special: *stores* the number of characters output so far
3258         into the next variable in the parameter list 
3259
3260 Finally, for backward (and we do mean "backward") compatibility, Perl
3261 permits these unnecessary but widely-supported conversions:
3262
3263    %i   a synonym for %d
3264    %D   a synonym for %ld
3265    %U   a synonym for %lu
3266    %O   a synonym for %lo
3267    %F   a synonym for %f
3268
3269 Perl permits the following universally-known flags between the C<%>
3270 and the conversion letter:
3271
3272    space   prefix positive number with a space
3273    +       prefix positive number with a plus sign
3274    -       left-justify within the field
3275    0       use zeros, not spaces, to right-justify
3276    #       prefix non-zero octal with "0", non-zero hex with "0x"
3277    number  minimum field width
3278    .number "precision": digits after decimal point for floating-point,
3279            max length for string, minimum length for integer
3280    l       interpret integer as C type "long" or "unsigned long"
3281    h       interpret integer as C type "short" or "unsigned short"
3282
3283 There is also one Perl-specific flag:
3284
3285    V       interpret integer as Perl's standard integer type
3286
3287 Where a number would appear in the flags, an asterisk ("*") may be
3288 used instead, in which case Perl uses the next item in the parameter
3289 list as the given number (that is, as the field width or precision).
3290 If a field width obtained through "*" is negative, it has the same
3291 effect as the '-' flag: left-justification.
3292
3293 If C<use locale> is in effect, the character used for the decimal
3294 point in formatted real numbers is affected by the LC_NUMERIC locale.
3295 See L<perllocale>.
3296
3297 =item sqrt EXPR
3298
3299 =item sqrt
3300
3301 Return the square root of EXPR.  If EXPR is omitted, returns square
3302 root of $_.
3303
3304 =item srand EXPR
3305
3306 =item srand
3307
3308 Sets the random number seed for the C<rand> operator.  If EXPR is
3309 omitted, uses a semi-random value based on the current time and process
3310 ID, among other things.  In versions of Perl prior to 5.004 the default
3311 seed was just the current time().  This isn't a particularly good seed,
3312 so many old programs supply their own seed value (often C<time ^ $$> or
3313 C<time ^ ($$ + ($$ << 15))>), but that isn't necessary any more.
3314
3315 In fact, it's usually not necessary to call srand() at all, because if
3316 it is not called explicitly, it is called implicitly at the first use of
3317 the C<rand> operator.  However, this was not the case in version of Perl
3318 before 5.004, so if your script will run under older Perl versions, it
3319 should call srand().
3320
3321 Note that you need something much more random than the default seed for
3322 cryptographic purposes.  Checksumming the compressed output of one or more
3323 rapidly changing operating system status programs is the usual method.  For
3324 example:
3325
3326     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3327
3328 If you're particularly concerned with this, see the Math::TrulyRandom
3329 module in CPAN.
3330
3331 Do I<not> call srand() multiple times in your program unless you know
3332 exactly what you're doing and why you're doing it.  The point of the
3333 function is to "seed" the rand() function so that rand() can produce
3334 a different sequence each time you run your program.  Just do it once at the
3335 top of your program, or you I<won't> get random numbers out of rand()!
3336
3337 Frequently called programs (like CGI scripts) that simply use
3338
3339     time ^ $$
3340
3341 for a seed can fall prey to the mathematical property that
3342
3343     a^b == (a+1)^(b+1)
3344
3345 one-third of the time.  So don't do that.
3346
3347 =item stat FILEHANDLE
3348
3349 =item stat EXPR
3350
3351 =item stat
3352
3353 Returns a 13-element array giving the status info for a file, either the
3354 file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted, it
3355 stats $_.  Returns a null list if the stat fails.  Typically used as
3356 follows:
3357
3358
3359     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3360        $atime,$mtime,$ctime,$blksize,$blocks)
3361            = stat($filename);
3362
3363 Not all fields are supported on all filesystem types.  Here are the
3364 meaning of the fields:
3365
3366   0 dev      device number of filesystem
3367   1 ino      inode number
3368   2 mode     file mode  (type and permissions)
3369   3 nlink    number of (hard) links to the file
3370   4 uid      numeric user ID of file's owner
3371   5 gid      numeric group ID of file's owner
3372   6 rdev     the device identifier (special files only)
3373   7 size     total size of file, in bytes
3374   8 atime    last access time since the epoch
3375   9 mtime    last modify time since the epoch
3376  10 ctime    inode change time (NOT creation time!) since the epoch
3377  11 blksize  preferred block size for file system I/O
3378  12 blocks   actual number of blocks allocated
3379
3380 (The epoch was at 00:00 January 1, 1970 GMT.)
3381
3382 If stat is passed the special filehandle consisting of an underline, no
3383 stat is done, but the current contents of the stat structure from the
3384 last stat or filetest are returned.  Example:
3385
3386     if (-x $file && (($d) = stat(_)) && $d < 0) {
3387         print "$file is executable NFS file\n";
3388     }
3389
3390 (This works on machines only for which the device number is negative under NFS.)
3391
3392 =item study SCALAR
3393
3394 =item study
3395
3396 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3397 doing many pattern matches on the string before it is next modified.
3398 This may or may not save time, depending on the nature and number of
3399 patterns you are searching on, and on the distribution of character
3400 frequencies in the string to be searched -- you probably want to compare
3401 run times with and without it to see which runs faster.  Those loops
3402 which scan for many short constant strings (including the constant
3403 parts of more complex patterns) will benefit most.  You may have only
3404 one study active at a time -- if you study a different scalar the first
3405 is "unstudied".  (The way study works is this: a linked list of every
3406 character in the string to be searched is made, so we know, for
3407 example, where all the 'k' characters are.  From each search string,
3408 the rarest character is selected, based on some static frequency tables
3409 constructed from some C programs and English text.  Only those places
3410 that contain this "rarest" character are examined.)
3411
3412 For example, here is a loop which inserts index producing entries
3413 before any line containing a certain pattern:
3414
3415     while (<>) {
3416         study;
3417         print ".IX foo\n" if /\bfoo\b/;
3418         print ".IX bar\n" if /\bbar\b/;
3419         print ".IX blurfl\n" if /\bblurfl\b/;
3420         ...
3421         print;
3422     }
3423
3424 In searching for /\bfoo\b/, only those locations in $_ that contain "f"
3425 will be looked at, because "f" is rarer than "o".  In general, this is
3426 a big win except in pathological cases.  The only question is whether
3427 it saves you more time than it took to build the linked list in the
3428 first place.
3429
3430 Note that if you have to look for strings that you don't know till
3431 runtime, you can build an entire loop as a string and eval that to
3432 avoid recompiling all your patterns all the time.  Together with
3433 undefining $/ to input entire files as one record, this can be very
3434 fast, often faster than specialized programs like fgrep(1).  The following
3435 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3436 out the names of those files that contain a match:
3437
3438     $search = 'while (<>) { study;';
3439     foreach $word (@words) {
3440         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3441     }
3442     $search .= "}";
3443     @ARGV = @files;
3444     undef $/;
3445     eval $search;               # this screams
3446     $/ = "\n";          # put back to normal input delimiter
3447     foreach $file (sort keys(%seen)) {
3448         print $file, "\n";
3449     }
3450
3451 =item sub BLOCK
3452
3453 =item sub NAME
3454
3455 =item sub NAME BLOCK
3456
3457 This is subroutine definition, not a real function I<per se>.  With just a
3458 NAME (and possibly prototypes), it's just a forward declaration.  Without
3459 a NAME, it's an anonymous function declaration, and does actually return a
3460 value: the CODE ref of the closure you just created.  See L<perlsub> and
3461 L<perlref> for details.
3462
3463 =item substr EXPR,OFFSET,LEN
3464
3465 =item substr EXPR,OFFSET
3466
3467 Extracts a substring out of EXPR and returns it.  First character is at
3468 offset 0, or whatever you've set C<$[> to (but don't do that).
3469 If OFFSET is negative (or more precisely, less than C<$[>), starts
3470 that far from the end of the string.  If LEN is omitted, returns
3471 everything to the end of the string.  If LEN is negative, leaves that
3472 many characters off the end of the string.
3473
3474 If you specify a substring which is partly outside the string, the part
3475 within the string is returned.    If the substring is totally outside
3476 the string a warning is produced.
3477
3478 You can use the substr() function
3479 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3480 something shorter than LEN, the string will shrink, and if you assign
3481 something longer than LEN, the string will grow to accommodate it.  To
3482 keep the string the same length you may need to pad or chop your value
3483 using sprintf().
3484
3485 =item symlink OLDFILE,NEWFILE
3486
3487 Creates a new filename symbolically linked to the old filename.
3488 Returns 1 for success, 0 otherwise.  On systems that don't support
3489 symbolic links, produces a fatal error at run time.  To check for that,
3490 use eval:
3491
3492     $symlink_exists = (eval {symlink("","")};, $@ eq '');
3493
3494 =item syscall LIST
3495
3496 Calls the system call specified as the first element of the list,
3497 passing the remaining elements as arguments to the system call.  If
3498 unimplemented, produces a fatal error.  The arguments are interpreted
3499 as follows: if a given argument is numeric, the argument is passed as
3500 an int.  If not, the pointer to the string value is passed.  You are
3501 responsible to make sure a string is pre-extended long enough to
3502 receive any result that might be written into a string.  You can't use a
3503 string literal (or other read-only string) as an argument to syscall()
3504 because Perl has to assume that any string pointer might be written
3505 through.  If your
3506 integer arguments are not literals and have never been interpreted in a
3507 numeric context, you may need to add 0 to them to force them to look
3508 like numbers.
3509
3510     require 'syscall.ph';               # may need to run h2ph
3511     $s = "hi there\n";
3512     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
3513
3514 Note that Perl supports passing of up to only 14 arguments to your system call,
3515 which in practice should usually suffice.
3516
3517 Syscall returns whatever value returned by the system call it calls.
3518 If the system call fails, syscall returns -1 and sets C<$!> (errno).
3519 Note that some system calls can legitimately return -1.  The proper
3520 way to handle such calls is to assign C<$!=0;> before the call and
3521 check the value of <$!> if syscall returns -1.
3522
3523 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
3524 number of the read end of the pipe it creates.  There is no way
3525 to retrieve the file number of the other end.  You can avoid this 
3526 problem by using C<pipe> instead.
3527
3528 =item sysopen FILEHANDLE,FILENAME,MODE
3529
3530 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3531
3532 Opens the file whose filename is given by FILENAME, and associates it
3533 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3534 the name of the real filehandle wanted.  This function calls the
3535 underlying operating system's C<open> function with the parameters
3536 FILENAME, MODE, PERMS.
3537
3538 The possible values and flag bits of the MODE parameter are
3539 system-dependent; they are available via the standard module C<Fcntl>.
3540 However, for historical reasons, some values are universal: zero means
3541 read-only, one means write-only, and two means read/write.
3542
3543 If the file named by FILENAME does not exist and the C<open> call
3544 creates it (typically because MODE includes the O_CREAT flag), then
3545 the value of PERMS specifies the permissions of the newly created
3546 file.  If PERMS is omitted, the default value is 0666, which allows
3547 read and write for all.  This default is reasonable: see C<umask>.
3548
3549 The IO::File module provides a more object-oriented approach, if you're
3550 into that kind of thing.
3551
3552 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
3553
3554 =item sysread FILEHANDLE,SCALAR,LENGTH
3555
3556 Attempts to read LENGTH bytes of data into variable SCALAR from the
3557 specified FILEHANDLE, using the system call read(2).  It bypasses
3558 stdio, so mixing this with other kinds of reads, print(), write(),
3559 seek(), or tell() can cause confusion because stdio usually buffers
3560 data.  Returns the number of bytes actually read, or undef if there
3561 was an error.  SCALAR will be grown or shrunk so that the last byte
3562 actually read is the last byte of the scalar after the read.
3563
3564 An OFFSET may be specified to place the read data at some place in the
3565 string other than the beginning.  A negative OFFSET specifies
3566 placement at that many bytes counting backwards from the end of the
3567 string.  A positive OFFSET greater than the length of SCALAR results
3568 in the string being padded to the required size with "\0" bytes before
3569 the result of the read is appended.
3570
3571 =item sysseek FILEHANDLE,POSITION,WHENCE
3572
3573 Sets FILEHANDLE's system position using the system call lseek(2).  It
3574 bypasses stdio, so mixing this with reads (other than sysread()),
3575 print(), write(), seek(), or tell() may cause confusion.  FILEHANDLE may
3576 be an expression whose value gives the name of the filehandle.  The
3577 values for WHENCE are 0 to set the new position to POSITION, 1 to set
3578 the it to the current position plus POSITION, and 2 to set it to EOF
3579 plus POSITION (typically negative).  For WHENCE, you may use the
3580 constants SEEK_SET, SEEK_CUR, and SEEK_END from either the IO::Seekable
3581 or the POSIX module.
3582
3583 Returns the new position, or the undefined value on failure.  A position
3584 of zero is returned as the string "0 but true"; thus sysseek() returns
3585 TRUE on success and FALSE on failure, yet you can still easily determine
3586 the new position.
3587
3588 =item system LIST
3589
3590 =item system PROGRAM LIST
3591
3592 Does exactly the same thing as "exec LIST" except that a fork is done
3593 first, and the parent process waits for the child process to complete.
3594 Note that argument processing varies depending on the number of
3595 arguments.  The return value is the exit status of the program as
3596 returned by the wait() call.  To get the actual exit value divide by
3597 256.  See also L</exec>.  This is I<NOT> what you want to use to capture
3598 the output from a command, for that you should use merely backticks or
3599 qx//, as described in L<perlop/"`STRING`">.
3600
3601 Like exec(), system() allows you to lie to a program about its name if
3602 you use the "system PROGRAM LIST" syntax.  Again, see L</exec>.
3603
3604 Because system() and backticks block SIGINT and SIGQUIT, killing the
3605 program they're running doesn't actually interrupt your program.
3606
3607     @args = ("command", "arg1", "arg2");
3608     system(@args) == 0
3609          or die "system @args failed: $?"
3610
3611 Here's a more elaborate example of analysing the return value from
3612 system() on a Unix system to check for all possibilities, including for
3613 signals and core dumps.
3614
3615     $rc = 0xffff & system @args;
3616     printf "system(%s) returned %#04x: ", "@args", $rc;
3617     if ($rc == 0) {
3618         print "ran with normal exit\n";
3619     }
3620     elsif ($rc == 0xff00) {
3621         print "command failed: $!\n";
3622     }
3623     elsif ($rc > 0x80) {
3624         $rc >>= 8;
3625         print "ran with non-zero exit status $rc\n";
3626     }
3627     else {
3628         print "ran with ";
3629         if ($rc &   0x80) {
3630             $rc &= ~0x80;
3631             print "core dump from ";
3632         }
3633         print "signal $rc\n"
3634     }
3635     $ok = ($rc != 0);
3636
3637 When the arguments get executed via the system shell, results will
3638 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
3639 for details.
3640
3641 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
3642
3643 =item syswrite FILEHANDLE,SCALAR,LENGTH
3644
3645 Attempts to write LENGTH bytes of data from variable SCALAR to the
3646 specified FILEHANDLE, using the system call write(2).  It bypasses
3647 stdio, so mixing this with reads (other than sysread()), print(),
3648 write(), seek(), or tell() may cause confusion because stdio usually
3649 buffers data.  Returns the number of bytes actually written, or undef
3650 if there was an error.  If the LENGTH is greater than the available
3651 data in the SCALAR after the OFFSET, only as much data as is available
3652 will be written.
3653
3654 An OFFSET may be specified to write the data from some part of the
3655 string other than the beginning.  A negative OFFSET specifies writing
3656 that many bytes counting backwards from the end of the string.  In the
3657 case the SCALAR is empty you can use OFFSET but only zero offset.
3658
3659 =item tell FILEHANDLE
3660
3661 =item tell
3662
3663 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
3664 expression whose value gives the name of the actual filehandle.  If
3665 FILEHANDLE is omitted, assumes the file last read.
3666
3667 =item telldir DIRHANDLE
3668
3669 Returns the current position of the readdir() routines on DIRHANDLE.
3670 Value may be given to seekdir() to access a particular location in a
3671 directory.  Has the same caveats about possible directory compaction as
3672 the corresponding system library routine.
3673
3674 =item tie VARIABLE,CLASSNAME,LIST
3675
3676 This function binds a variable to a package class that will provide the
3677 implementation for the variable.  VARIABLE is the name of the variable
3678 to be enchanted.  CLASSNAME is the name of a class implementing objects
3679 of correct type.  Any additional arguments are passed to the "new"
3680 method of the class (meaning TIESCALAR, TIEARRAY, or TIEHASH).
3681 Typically these are arguments such as might be passed to the dbm_open()
3682 function of C.  The object returned by the "new" method is also
3683 returned by the tie() function, which would be useful if you want to
3684 access other methods in CLASSNAME.
3685
3686 Note that functions such as keys() and values() may return huge array
3687 values when used on large objects, like DBM files.  You may prefer to
3688 use the each() function to iterate over such.  Example:
3689
3690     # print out history file offsets
3691     use NDBM_File;
3692     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3693     while (($key,$val) = each %HIST) {
3694         print $key, ' = ', unpack('L',$val), "\n";
3695     }
3696     untie(%HIST);
3697
3698 A class implementing a hash should have the following methods:
3699
3700     TIEHASH classname, LIST
3701     DESTROY this
3702     FETCH this, key
3703     STORE this, key, value
3704     DELETE this, key
3705     EXISTS this, key
3706     FIRSTKEY this
3707     NEXTKEY this, lastkey
3708
3709 A class implementing an ordinary array should have the following methods:
3710
3711     TIEARRAY classname, LIST
3712     DESTROY this
3713     FETCH this, key
3714     STORE this, key, value
3715     [others TBD]
3716
3717 A class implementing a scalar should have the following methods:
3718
3719     TIESCALAR classname, LIST
3720     DESTROY this
3721     FETCH this,
3722     STORE this, value
3723
3724 Unlike dbmopen(), the tie() function will not use or require a module
3725 for you--you need to do that explicitly yourself.  See L<DB_File>
3726 or the F<Config> module for interesting tie() implementations.
3727
3728 For further details see L<perltie>, L<tied VARIABLE>.
3729
3730 =item tied VARIABLE
3731
3732 Returns a reference to the object underlying VARIABLE (the same value
3733 that was originally returned by the tie() call which bound the variable
3734 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
3735 package.
3736
3737 =item time
3738
3739 Returns the number of non-leap seconds since whatever time the system
3740 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
3741 and 00:00:00 UTC, January 1, 1970 for most other systems).
3742 Suitable for feeding to gmtime() and localtime().
3743
3744 =item times
3745
3746 Returns a four-element array giving the user and system times, in
3747 seconds, for this process and the children of this process.
3748
3749     ($user,$system,$cuser,$csystem) = times;
3750
3751 =item tr///
3752
3753 The transliteration operator.  Same as y///. See L<perlop>.
3754
3755 =item truncate FILEHANDLE,LENGTH
3756
3757 =item truncate EXPR,LENGTH
3758
3759 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
3760 specified length.  Produces a fatal error if truncate isn't implemented
3761 on your system.  Returns TRUE if successful, the undefined value
3762 otherwise.
3763
3764 =item uc EXPR
3765
3766 =item uc
3767
3768 Returns an uppercased version of EXPR.  This is the internal function
3769 implementing the \U escape in double-quoted strings.
3770 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3771
3772 If EXPR is omitted, uses $_.
3773
3774 =item ucfirst EXPR
3775
3776 =item ucfirst
3777
3778 Returns the value of EXPR with the first character uppercased.  This is
3779 the internal function implementing the \u escape in double-quoted strings.
3780 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3781
3782 If EXPR is omitted, uses $_.
3783
3784 =item umask EXPR
3785
3786 =item umask
3787
3788 Sets the umask for the process to EXPR and returns the previous value.
3789 If EXPR is omitted, merely returns the current umask.  Remember that a
3790 umask is a number, usually given in octal; it is I<not> a string of octal
3791 digits.  See also L</oct>, if all you have is a string.
3792
3793 =item undef EXPR
3794
3795 =item undef
3796
3797 Undefines the value of EXPR, which must be an lvalue.  Use only on a
3798 scalar value, an entire array, an entire hash, or a subroutine name (using
3799 "&").  (Using undef() will probably not do what you expect on most
3800 predefined variables or DBM list values, so don't do that.)  Always
3801 returns the undefined value.  You can omit the EXPR, in which case
3802 nothing is undefined, but you still get an undefined value that you
3803 could, for instance, return from a subroutine, assign to a variable or
3804 pass as a parameter.  Examples:
3805
3806     undef $foo;
3807     undef $bar{'blurfl'};             # Compare to: delete $bar{'blurfl'};
3808     undef @ary;
3809     undef %hash;
3810     undef &mysub;
3811     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
3812     select undef, undef, undef, 0.25;
3813     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
3814
3815 =item unlink LIST
3816
3817 =item unlink
3818
3819 Deletes a list of files.  Returns the number of files successfully
3820 deleted.
3821
3822     $cnt = unlink 'a', 'b', 'c';
3823     unlink @goners;
3824     unlink <*.bak>;
3825
3826 Note: unlink will not delete directories unless you are superuser and
3827 the B<-U> flag is supplied to Perl.  Even if these conditions are
3828 met, be warned that unlinking a directory can inflict damage on your
3829 filesystem.  Use rmdir instead.
3830
3831 If LIST is omitted, uses $_.
3832
3833 =item unpack TEMPLATE,EXPR
3834
3835 Unpack does the reverse of pack: it takes a string representing a
3836 structure and expands it out into a list value, returning the array
3837 value.  (In a scalar context, it returns merely the first value
3838 produced.)  The TEMPLATE has the same format as in the pack function.
3839 Here's a subroutine that does substring:
3840
3841     sub substr {
3842         local($what,$where,$howmuch) = @_;
3843         unpack("x$where a$howmuch", $what);
3844     }
3845
3846 and then there's
3847
3848     sub ordinal { unpack("c",$_[0]); } # same as ord()
3849
3850 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
3851 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
3852 themselves.  Default is a 16-bit checksum.  For example, the following
3853 computes the same number as the System V sum program:
3854
3855     while (<>) {
3856         $checksum += unpack("%16C*", $_);
3857     }
3858     $checksum %= 65536;
3859
3860 The following efficiently counts the number of set bits in a bit vector:
3861
3862     $setbits = unpack("%32b*", $selectmask);
3863
3864 =item untie VARIABLE
3865
3866 Breaks the binding between a variable and a package.  (See tie().)
3867
3868 =item unshift ARRAY,LIST
3869
3870 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
3871 depending on how you look at it.  Prepends list to the front of the
3872 array, and returns the new number of elements in the array.
3873
3874     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
3875
3876 Note the LIST is prepended whole, not one element at a time, so the
3877 prepended elements stay in the same order.  Use reverse to do the
3878 reverse.
3879
3880 =item use Module LIST
3881
3882 =item use Module
3883
3884 =item use Module VERSION LIST
3885
3886 =item use VERSION
3887
3888 Imports some semantics into the current package from the named module,
3889 generally by aliasing certain subroutine or variable names into your
3890 package.  It is exactly equivalent to
3891
3892     BEGIN { require Module; import Module LIST; }
3893
3894 except that Module I<must> be a bareword.
3895
3896 If the first argument to C<use> is a number, it is treated as a version
3897 number instead of a module name.  If the version of the Perl interpreter
3898 is less than VERSION, then an error message is printed and Perl exits
3899 immediately.  This is often useful if you need to check the current
3900 Perl version before C<use>ing library modules which have changed in
3901 incompatible ways from older versions of Perl.  (We try not to do
3902 this more than we have to.)
3903
3904 The BEGIN forces the require and import to happen at compile time.  The
3905 require makes sure the module is loaded into memory if it hasn't been
3906 yet.  The import is not a builtin--it's just an ordinary static method
3907 call into the "Module" package to tell the module to import the list of
3908 features back into the current package.  The module can implement its
3909 import method any way it likes, though most modules just choose to
3910 derive their import method via inheritance from the Exporter class that
3911 is defined in the Exporter module.  See L<Exporter>.  If no import
3912 method can be found then the error is currently silently ignored.  This
3913 may change to a fatal error in a future version.
3914
3915 If you don't want your namespace altered, explicitly supply an empty list:
3916
3917     use Module ();
3918
3919 That is exactly equivalent to
3920
3921     BEGIN { require Module; }
3922
3923 If the VERSION argument is present between Module and LIST, then the
3924 C<use> will call the VERSION method in class Module with the given
3925 version as an argument.  The default VERSION method, inherited from
3926 the Universal class, croaks if the given version is larger than the
3927 value of the variable $Module::VERSION.  (Note that there is not a
3928 comma after VERSION!)
3929
3930 Because this is a wide-open interface, pragmas (compiler directives)
3931 are also implemented this way.  Currently implemented pragmas are:
3932
3933     use integer;
3934     use diagnostics;
3935     use sigtrap qw(SEGV BUS);
3936     use strict  qw(subs vars refs);
3937     use subs    qw(afunc blurfl);
3938
3939 These pseudo-modules import semantics into the current block scope, unlike
3940 ordinary modules, which import symbols into the current package (which are
3941 effective through the end of the file).
3942
3943 There's a corresponding "no" command that unimports meanings imported
3944 by use, i.e., it calls C<unimport Module LIST> instead of C<import>.
3945
3946     no integer;
3947     no strict 'refs';
3948
3949 If no unimport method can be found the call fails with a fatal error.
3950
3951 See L<perlmod> for a list of standard modules and pragmas.
3952
3953 =item utime LIST
3954
3955 Changes the access and modification times on each file of a list of
3956 files.  The first two elements of the list must be the NUMERICAL access
3957 and modification times, in that order.  Returns the number of files
3958 successfully changed.  The inode modification time of each file is set
3959 to the current time.  This code has the same effect as the "touch"
3960 command if the files already exist:
3961
3962     #!/usr/bin/perl
3963     $now = time;
3964     utime $now, $now, @ARGV;
3965
3966 =item values HASH
3967
3968 Returns a normal array consisting of all the values of the named hash.
3969 (In a scalar context, returns the number of values.)  The values are
3970 returned in an apparently random order, but it is the same order as either
3971 the keys() or each() function would produce on the same hash.  As a side
3972 effect, it resets HASH's iterator.  See also keys(), each(), and sort().
3973
3974 =item vec EXPR,OFFSET,BITS
3975
3976 Treats the string in EXPR as a vector of unsigned integers, and
3977 returns the value of the bit field specified by OFFSET.  BITS specifies
3978 the number of bits that are reserved for each entry in the bit
3979 vector.  This must be a power of two from 1 to 32. vec() may also be
3980 assigned to, in which case parentheses are needed to give the expression
3981 the correct precedence as in
3982
3983     vec($image, $max_x * $x + $y, 8) = 3;
3984
3985 Vectors created with vec() can also be manipulated with the logical
3986 operators |, &, and ^, which will assume a bit vector operation is
3987 desired when both operands are strings.
3988
3989 To transform a bit vector into a string or array of 0's and 1's, use these:
3990
3991     $bits = unpack("b*", $vector);
3992     @bits = split(//, unpack("b*", $vector));
3993
3994 If you know the exact length in bits, it can be used in place of the *.
3995
3996 =item wait
3997
3998 Waits for a child process to terminate and returns the pid of the
3999 deceased process, or -1 if there are no child processes.  The status is
4000 returned in C<$?>.
4001
4002 =item waitpid PID,FLAGS
4003
4004 Waits for a particular child process to terminate and returns the pid
4005 of the deceased process, or -1 if there is no such child process.  The
4006 status is returned in C<$?>.  If you say
4007
4008     use POSIX ":sys_wait_h";
4009     ...
4010     waitpid(-1,&WNOHANG);
4011
4012 then you can do a non-blocking wait for any process.  Non-blocking wait
4013 is available on machines supporting either the waitpid(2) or
4014 wait4(2) system calls.  However, waiting for a particular pid with
4015 FLAGS of 0 is implemented everywhere.  (Perl emulates the system call
4016 by remembering the status values of processes that have exited but have
4017 not been harvested by the Perl script yet.)
4018
4019 =item wantarray
4020
4021 Returns TRUE if the context of the currently executing subroutine is
4022 looking for a list value.  Returns FALSE if the context is looking
4023 for a scalar.  Returns the undefined value if the context is looking
4024 for no value (void context).
4025
4026     return unless defined wantarray;    # don't bother doing more
4027     my @a = complex_calculation();
4028     return wantarray ? @a : "@a";
4029
4030 =item warn LIST
4031
4032 Produces a message on STDERR just like die(), but doesn't exit or throw
4033 an exception.
4034
4035 If LIST is empty and $@ already contains a value (typically from a
4036 previous eval) that value is used after appending "\t...caught"
4037 to $@. This is useful for staying almost, but not entirely similar to
4038 die().
4039
4040 If $@ is empty then the string "Warning: Something's wrong" is used.
4041
4042 No message is printed if there is a C<$SIG{__WARN__}> handler
4043 installed.  It is the handler's responsibility to deal with the message
4044 as it sees fit (like, for instance, converting it into a die()).  Most
4045 handlers must therefore make arrangements to actually display the
4046 warnings that they are not prepared to deal with, by calling warn()
4047 again in the handler.  Note that this is quite safe and will not
4048 produce an endless loop, since C<__WARN__> hooks are not called from
4049 inside one.
4050
4051 You will find this behavior is slightly different from that of
4052 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
4053 instead call die() again to change it).
4054
4055 Using a C<__WARN__> handler provides a powerful way to silence all
4056 warnings (even the so-called mandatory ones).  An example:
4057
4058     # wipe out *all* compile-time warnings
4059     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
4060     my $foo = 10;
4061     my $foo = 20;          # no warning about duplicate my $foo,
4062                            # but hey, you asked for it!
4063     # no compile-time or run-time warnings before here
4064     $DOWARN = 1;
4065
4066     # run-time warnings enabled after here
4067     warn "\$foo is alive and $foo!";     # does show up
4068
4069 See L<perlvar> for details on setting C<%SIG> entries, and for more
4070 examples.
4071
4072 =item write FILEHANDLE
4073
4074 =item write EXPR
4075
4076 =item write
4077
4078 Writes a formatted record (possibly multi-line) to the specified file,
4079 using the format associated with that file.  By default the format for
4080 a file is the one having the same name as the filehandle, but the
4081 format for the current output channel (see the select() function) may be set
4082 explicitly by assigning the name of the format to the C<$~> variable.
4083
4084 Top of form processing is handled automatically:  if there is
4085 insufficient room on the current page for the formatted record, the
4086 page is advanced by writing a form feed, a special top-of-page format
4087 is used to format the new page header, and then the record is written.
4088 By default the top-of-page format is the name of the filehandle with
4089 "_TOP" appended, but it may be dynamically set to the format of your
4090 choice by assigning the name to the C<$^> variable while the filehandle is
4091 selected.  The number of lines remaining on the current page is in
4092 variable C<$->, which can be set to 0 to force a new page.
4093
4094 If FILEHANDLE is unspecified, output goes to the current default output
4095 channel, which starts out as STDOUT but may be changed by the
4096 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
4097 is evaluated and the resulting string is used to look up the name of
4098 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
4099
4100 Note that write is I<NOT> the opposite of read.  Unfortunately.
4101
4102 =item y///
4103
4104 The transliteration operator.  Same as tr///.  See L<perlop>.
4105
4106 =back