This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: New Module::Build released
[perl5.git] / lib / Module / Build / Base.pm
1 package Module::Build::Base;
2
3 use strict;
4 BEGIN { require 5.00503 }
5 use Config;
6 use File::Copy ();
7 use File::Find ();
8 use File::Path ();
9 use File::Basename ();
10 use File::Spec 0.82 ();
11 use File::Compare ();
12 use Data::Dumper ();
13 use IO::File ();
14 use Text::ParseWords ();
15
16 use Module::Build::ModuleInfo;
17 use Module::Build::Notes;
18
19
20 #################### Constructors ###########################
21 sub new {
22   my $self = shift()->_construct(@_);
23
24   $self->{invoked_action} = $self->{action} ||= 'Build_PL';
25   $self->cull_args(@ARGV);
26   
27   die "Too early to specify a build action '$self->{action}'.  Do 'Build $self->{action}' instead.\n"
28     if $self->{action} && $self->{action} ne 'Build_PL';
29
30   $self->dist_name;
31   $self->dist_version;
32
33   $self->check_manifest;
34   $self->check_prereq;
35   $self->check_autofeatures;
36
37   $self->_set_install_paths;
38   $self->_find_nested_builds;
39
40   return $self;
41 }
42
43 sub resume {
44   my $package = shift;
45   my $self = $package->_construct(@_);
46   $self->read_config;
47
48   # If someone called Module::Build->current() or
49   # Module::Build->new_from_context() and the correct class to use is
50   # actually a *subclass* of Module::Build, we may need to load that
51   # subclass here and re-delegate the resume() method to it.
52   unless ( UNIVERSAL::isa($package, $self->build_class) ) {
53     my $build_class = $self->build_class;
54     my $config_dir = $self->config_dir || '_build';
55     my $build_lib = File::Spec->catdir( $config_dir, 'lib' );
56     unshift( @INC, $build_lib );
57     unless ( $build_class->can('new') ) {
58       eval "require $build_class; 1" or die "Failed to re-load '$build_class': $@";
59     }
60     return $build_class->resume(@_);
61   }
62
63   unless ($self->_perl_is_same($self->{properties}{perl})) {
64     my $perl = $self->find_perl_interpreter;
65     $self->log_warn(" * WARNING: Configuration was initially created with '$self->{properties}{perl}',\n".
66                     "   but we are now using '$perl'.\n");
67   }
68   
69   my $mb_version = $Module::Build::VERSION;
70   die(" * ERROR: Configuration was initially created with Module::Build version '$self->{properties}{mb_version}',\n".
71       "   but we are now using version '$mb_version'.  Please re-run the Build.PL or Makefile.PL script.\n")
72     unless $mb_version eq $self->{properties}{mb_version};
73   
74   $self->cull_args(@ARGV);
75   $self->{invoked_action} = $self->{action} ||= 'build';
76   
77   return $self;
78 }
79
80 sub new_from_context {
81   my ($package, %args) = @_;
82   
83   # XXX Read the META.yml and see whether we need to run the Build.PL?
84   
85   # Run the Build.PL.  We use do() rather than run_perl_script() so
86   # that it runs in this process rather than a subprocess, because we
87   # need to make sure that the environment is the same during Build.PL
88   # as it is during resume() (and thereafter).
89   {
90     local @ARGV = $package->unparse_args(\%args);
91     do 'Build.PL';
92     die $@ if $@;
93   }
94   return $package->resume;
95 }
96
97 sub current {
98   # hmm, wonder what the right thing to do here is
99   local @ARGV;
100   return shift()->resume;
101 }
102
103 sub _construct {
104   my ($package, %input) = @_;
105
106   my $args   = delete $input{args}   || {};
107   my $config = delete $input{config} || {};
108
109   my $self = bless {
110                     args => {%$args},
111                     config => {%Config, %$config},
112                     properties => {
113                                    base_dir        => $package->cwd,
114                                    mb_version      => $Module::Build::VERSION,
115                                    %input,
116                                   },
117                     phash => {},
118                    }, $package;
119
120   $self->_set_defaults;
121   my ($p, $c, $ph) = ($self->{properties}, $self->{config}, $self->{phash});
122
123   foreach (qw(notes config_data features runtime_params cleanup auto_features)) {
124     my $file = File::Spec->catfile($self->config_dir, $_);
125     $ph->{$_} = Module::Build::Notes->new(file => $file);
126     $ph->{$_}->restore if -e $file;
127     if (exists $p->{$_}) {
128       my $vals = delete $p->{$_};
129       while (my ($k, $v) = each %$vals) {
130         $self->$_($k, $v);
131       }
132     }
133   }
134
135   # The following warning could be unnecessary if the user is running
136   # an embedded perl, but there aren't too many of those around, and
137   # embedded perls aren't usually used to install modules, and the
138   # installation process sometimes needs to run external scripts
139   # (e.g. to run tests).
140   $p->{perl} = $self->find_perl_interpreter
141     or $self->log_warn("Warning: Can't locate your perl binary");
142
143   my $blibdir = sub { File::Spec->catdir($p->{blib}, @_) };
144   $p->{bindoc_dirs} ||= [ $blibdir->("script") ];
145   $p->{libdoc_dirs} ||= [ $blibdir->("lib"), $blibdir->("arch") ];
146
147   $p->{dist_author} = [ $p->{dist_author} ] if defined $p->{dist_author} and not ref $p->{dist_author};
148
149   # Synonyms
150   $p->{requires} = delete $p->{prereq} if defined $p->{prereq};
151   $p->{script_files} = delete $p->{scripts} if defined $p->{scripts};
152
153   # Convert to arrays
154   for ('extra_compiler_flags', 'extra_linker_flags') {
155     $p->{$_} = [ $self->split_like_shell($p->{$_}) ] if exists $p->{$_};
156   }
157
158   $self->add_to_cleanup( @{delete $p->{add_to_cleanup}} )
159     if $p->{add_to_cleanup};
160
161   return $self;
162 }
163
164 ################## End constructors #########################
165
166 sub log_info { print @_ unless shift()->quiet }
167 sub log_verbose { shift()->log_info(@_) if $_[0]->verbose }
168 sub log_warn {
169   # Try to make our call stack invisible
170   shift;
171   if (@_ and $_[-1] !~ /\n$/) {
172     my (undef, $file, $line) = caller();
173     warn @_, " at $file line $line.\n";
174   } else {
175     warn @_;
176   }
177 }
178
179
180 sub _set_install_paths {
181   my $self = shift;
182   my $c = $self->config;
183   my $p = $self->{properties};
184
185   my @libstyle = $c->{installstyle} ?
186       File::Spec->splitdir($c->{installstyle}) : qw(lib perl5);
187   my $arch     = $c->{archname};
188   my $version  = $c->{version};
189
190   my $bindoc  = $c->{installman1dir} || undef;
191   my $libdoc  = $c->{installman3dir} || undef;
192
193   my $binhtml = $c->{installhtml1dir} || $c->{installhtmldir} || undef;
194   my $libhtml = $c->{installhtml3dir} || $c->{installhtmldir} || undef;
195
196   $p->{install_sets} =
197     {
198      core   => {
199                 lib     => $c->{installprivlib},
200                 arch    => $c->{installarchlib},
201                 bin     => $c->{installbin},
202                 script  => $c->{installscript},
203                 bindoc  => $bindoc,
204                 libdoc  => $libdoc,
205                 binhtml => $binhtml,
206                 libhtml => $libhtml,
207                },
208      site   => {
209                 lib     => $c->{installsitelib},
210                 arch    => $c->{installsitearch},
211                 bin     => $c->{installsitebin} || $c->{installbin},
212                 script  => $c->{installsitescript} ||
213                            $c->{installsitebin} || $c->{installscript},
214                 bindoc  => $c->{installsiteman1dir} || $bindoc,
215                 libdoc  => $c->{installsiteman3dir} || $libdoc,
216                 binhtml => $c->{installsitehtml1dir} || $binhtml,
217                 libhtml => $c->{installsitehtml3dir} || $libhtml,
218                },
219      vendor => {
220                 lib     => $c->{installvendorlib},
221                 arch    => $c->{installvendorarch},
222                 bin     => $c->{installvendorbin} || $c->{installbin},
223                 script  => $c->{installvendorscript} ||
224                            $c->{installvendorbin} || $c->{installscript},
225                 bindoc  => $c->{installvendorman1dir} || $bindoc,
226                 libdoc  => $c->{installvendorman3dir} || $libdoc,
227                 binhtml => $c->{installvendorhtml1dir} || $binhtml,
228                 libhtml => $c->{installvendorhtml3dir} || $libhtml,
229                },
230     };
231
232   $p->{original_prefix} =
233     {
234      core   => $c->{installprefixexp} || $c->{installprefix} ||
235                $c->{prefixexp}        || $c->{prefix} || '',
236      site   => $c->{siteprefixexp},
237      vendor => $c->{usevendorprefix} ? $c->{vendorprefixexp} : '',
238     };
239   $p->{original_prefix}{site} ||= $p->{original_prefix}{core};
240
241   # Note: you might be tempted to use $Config{installstyle} here
242   # instead of hard-coding lib/perl5, but that's been considered and
243   # (at least for now) rejected.  `perldoc Config` has some wisdom
244   # about it.
245   $p->{install_base_relpaths} =
246     {
247      lib     => ['lib', 'perl5'],
248      arch    => ['lib', 'perl5', $arch],
249      bin     => ['bin'],
250      script  => ['bin'],
251      bindoc  => ['man', 'man1'],
252      libdoc  => ['man', 'man3'],
253      binhtml => ['html'],
254      libhtml => ['html'],
255     };
256
257   $p->{prefix_relpaths} =
258     {
259      core => {
260               lib        => [@libstyle],
261               arch       => [@libstyle, $version, $arch],
262               bin        => ['bin'],
263               script     => ['bin'],
264               bindoc     => ['man', 'man1'],
265               libdoc     => ['man', 'man3'],
266               binhtml    => ['html'],
267               libhtml    => ['html'],
268              },
269      vendor => {
270                 lib        => [@libstyle],
271                 arch       => [@libstyle, $version, $arch],
272                 bin        => ['bin'],
273                 script     => ['bin'],
274                 bindoc     => ['man', 'man1'],
275                 libdoc     => ['man', 'man3'],
276                 binhtml    => ['html'],
277                 libhtml    => ['html'],
278                },
279      site => {
280               lib        => [@libstyle, 'site_perl'],
281               arch       => [@libstyle, 'site_perl', $version, $arch],
282               bin        => ['bin'],
283               script     => ['bin'],
284               bindoc     => ['man', 'man1'],
285               libdoc     => ['man', 'man3'],
286               binhtml    => ['html'],
287               libhtml    => ['html'],
288              },
289     };
290
291 }
292
293 sub _find_nested_builds {
294   my $self = shift;
295   my $r = $self->recurse_into or return;
296
297   my ($file, @r);
298   if (!ref($r) && $r eq 'auto') {
299     local *DH;
300     opendir DH, $self->base_dir
301       or die "Can't scan directory " . $self->base_dir . " for nested builds: $!";
302     while (defined($file = readdir DH)) {
303       my $subdir = File::Spec->catdir( $self->base_dir, $file );
304       next unless -d $subdir;
305       push @r, $subdir if -e File::Spec->catfile( $subdir, 'Build.PL' );
306     }
307   }
308
309   $self->recurse_into(\@r);
310 }
311
312 sub cwd {
313   require Cwd;
314   return Cwd::cwd();
315 }
316
317 sub _quote_args {
318   # Returns a string that can become [part of] a command line with
319   # proper quoting so that the subprocess sees this same list of args.
320   my ($self, @args) = @_;
321
322   my $return_args = '';
323   my @quoted;
324
325   for (@args) {
326     if ( /^[^\s*?!$<>;\\|'"\[\]\{\}]+$/ ) {
327       # Looks pretty safe
328       push @quoted, $_;
329     } else {
330       # XXX this will obviously have to improve - is there already a
331       # core module lying around that does proper quoting?
332       s/"/"'"'"/g;
333       push @quoted, qq("$_");
334     }
335   }
336
337   return join " ", @quoted;
338 }
339
340 sub _backticks {
341   # Tries to avoid using true backticks, when possible, so that we
342   # don't have to worry about shell args.
343
344   my ($self, @cmd) = @_;
345   if ($self->have_multiarg_pipeopen) {
346     local *FH;
347     open FH, "-|", @cmd or die "Can't run @cmd: $!";
348     return wantarray ? <FH> : join '', <FH>;
349   } else {
350     my $cmd = $self->_quote_args(@cmd);
351     return `$cmd`;
352   }
353 }
354
355 sub have_multiarg_pipeopen { $] >= 5.008 }
356
357 # Determine whether a given binary is the same as the perl
358 # (configuration) that started this process.
359 sub _perl_is_same {
360   my ($self, $perl) = @_;
361
362   my @cmd = ($perl);
363
364   # When run from the perl core, @INC will include the directories
365   # where perl is yet to be installed. We need to reference the
366   # absolute path within the source distribution where it can find
367   # it's Config.pm This also prevents us from picking up a Config.pm
368   # from a different configuration that happens to be already
369   # installed in @INC.
370   if ($ENV{PERL_CORE}) {
371     push @cmd, '-I' . File::Spec->catdir(File::Basename::dirname($perl), 'lib');
372   }
373
374   push @cmd, qw(-MConfig=myconfig -e print -e myconfig);
375   return $self->_backticks(@cmd) eq Config->myconfig;
376 }
377
378 # Returns the absolute path of the perl interperter used to invoke
379 # this process. The path is derived from $^X or $Config{perlpath}. On
380 # some platforms $^X contains the complete absolute path of the
381 # interpreter, on other it may contain a relative path, or simply
382 # 'perl'. This can also vary depending on whether a path was supplied
383 # when perl was invoked. Additionally, the value in $^X may omit the
384 # executable extension on platforms that use one. It's a fatal error
385 # if the interpreter can't be found because it can result in undefined
386 # behavior by routines that depend on it (generating errors or
387 # invoking the wrong perl.
388 sub find_perl_interpreter {
389   my $proto = shift;
390   my $c     = ref($proto) ? $proto->config : \%Config::Config;
391
392   my $perl  = $^X;
393   my $perl_basename = File::Basename::basename($perl);
394
395   my @potential_perls;
396
397   # Try 1, Check $^X for absolute path
398   push( @potential_perls, $perl )
399       if File::Spec->file_name_is_absolute($perl);
400
401   # Try 2, Check $^X for a valid relative path
402   my $abs_perl = File::Spec->rel2abs($perl);
403   push( @potential_perls, $abs_perl );
404
405   # Try 3, Last ditch effort: These two option use hackery to try to locate
406   # a suitable perl. The hack varies depending on whether we are running
407   # from an installed perl or an uninstalled perl in the perl source dist.
408   if ($ENV{PERL_CORE}) {
409
410     # Try 3.A, If we are in a perl source tree, running an uninstalled
411     # perl, we can keep moving up the directory tree until we find our
412     # binary. We wouldn't do this under any other circumstances.
413
414     # CBuilder is also in the core, so it should be available here
415     require ExtUtils::CBuilder;
416     my $perl_src = ExtUtils::CBuilder->perl_src;
417     if ( defined($perl_src) && length($perl_src) ) {
418       my $uninstperl =
419         File::Spec->rel2abs(File::Spec->catfile( $perl_src, $perl_basename ));
420       push( @potential_perls, $uninstperl );
421     }
422
423   } else {
424
425     # Try 3.B, First look in $Config{perlpath}, then search the users
426     # PATH. We do not want to do either if we are running from an
427     # uninstalled perl in a perl source tree.
428
429     push( @potential_perls, $c->{perlpath} );
430
431     push( @potential_perls,
432           map File::Spec->catfile($_, $perl_basename), File::Spec->path() );
433   }
434
435   # Now that we've enumerated the potential perls, it's time to test
436   # them to see if any of them match our configuration, returning the
437   # absolute path of the first successful match.
438   my $exe = $c->{exe_ext};
439   foreach my $thisperl ( @potential_perls ) {
440
441     if ($proto->os_type eq 'VMS') {
442       # VMS might have a file version at the end
443       $thisperl .= $exe unless $thisperl =~ m/$exe(;\d+)?$/i;
444     } elsif (defined $exe) {
445       $thisperl .= $exe unless $thisperl =~ m/$exe$/i;
446     }
447
448     if ( -f $thisperl && $proto->_perl_is_same($thisperl) ) {
449       return $thisperl;
450     }
451   }
452
453   # We've tried all alternatives, and didn't find a perl that matches
454   # our configuration. Throw an exception, and list alternatives we tried.
455   my @paths = map File::Basename::dirname($_), @potential_perls;
456   die "Can't locate the perl binary used to run this script " .
457       "in (@paths)\n";
458 }
459
460 sub _is_interactive {
461   return -t STDIN && (-t STDOUT || !(-f STDOUT || -c STDOUT)) ;   # Pipe?
462 }
463
464 sub prompt {
465   my $self = shift;
466   my ($mess, $def) = @_;
467   die "prompt() called without a prompt message" unless @_;
468   
469   ($def, my $dispdef) = defined $def ? ($def, "[$def] ") : ('', ' ');
470
471   {
472     local $|=1;
473     print "$mess $dispdef";
474   }
475   my $ans;
476   if ( ! $ENV{PERL_MM_USE_DEFAULT} &&
477        ( $self->_is_interactive || ! eof STDIN ) ) {
478     $ans = <STDIN>;
479     if ( defined $ans ) {
480       chomp $ans;
481     } else { # user hit ctrl-D
482       print "\n";
483     }
484   }
485   
486   unless (defined($ans) and length($ans)) {
487     print "$def\n";
488     $ans = $def;
489   }
490   
491   return $ans;
492 }
493
494 sub y_n {
495   my $self = shift;
496   die "y_n() called without a prompt message" unless @_;
497   die "y_n() called without y or n default" unless ($_[1]||"")=~/^[yn]/i;
498
499   my $interactive = $self->_is_interactive;
500   my $answer;
501   while (1) {
502     $answer = $self->prompt(@_);
503     return 1 if $answer =~ /^y/i;
504     return 0 if $answer =~ /^n/i;
505     print "Please answer 'y' or 'n'.\n";
506   }
507 }
508
509 sub current_action { shift->{action} }
510 sub invoked_action { shift->{invoked_action} }
511
512 sub notes        { shift()->{phash}{notes}->access(@_) }
513 sub config_data  { shift()->{phash}{config_data}->access(@_) }
514 sub runtime_params { shift->{phash}{runtime_params}->read( @_ ? shift : () ) }  # Read-only
515 sub auto_features  { shift()->{phash}{auto_features}->access(@_) }
516
517 sub features     {
518   my $self = shift;
519   my $ph = $self->{phash};
520
521   if (@_) {
522     my $key = shift;
523     if ($ph->{features}->exists($key)) {
524       return $ph->{features}->access($key, @_);
525     }
526
527     if (my $info = $ph->{auto_features}->access($key)) {
528       my $failures = $self->prereq_failures($info);
529       my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
530                            keys %$failures ) ? 1 : 0;
531       return !$disabled;
532     }
533
534     return $ph->{features}->access($key, @_);
535   }
536
537   # No args - get the auto_features & overlay the regular features
538   my %features;
539   my %auto_features = $ph->{auto_features}->access();
540   while (my ($name, $info) = each %auto_features) {
541     my $failures = $self->prereq_failures($info);
542     my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
543                          keys %$failures ) ? 1 : 0;
544     $features{$name} = $disabled ? 0 : 1;
545   }
546   %features = (%features, $ph->{features}->access());
547
548   return wantarray ? %features : \%features;
549 }
550 BEGIN { *feature = \&features }
551
552 sub _mb_feature {
553   my $self = shift;
554   
555   if (($self->module_name || '') eq 'Module::Build') {
556     # We're building Module::Build itself, so ...::ConfigData isn't
557     # valid, but $self->features() should be.
558     return $self->feature(@_);
559   } else {
560     require Module::Build::ConfigData;
561     return Module::Build::ConfigData->feature(@_);
562   }
563 }
564
565
566 sub add_build_element {
567     my ($self, $elem) = @_;
568     my $elems = $self->build_elements;
569     push @$elems, $elem unless grep { $_ eq $elem } @$elems;
570 }
571
572 sub ACTION_config_data {
573   my $self = shift;
574   return unless $self->has_config_data;
575   
576   my $module_name = $self->module_name
577     or die "The config_data feature requires that 'module_name' be set";
578   my $notes_name = $module_name . '::ConfigData'; # TODO: Customize name ???
579   my $notes_pm = File::Spec->catfile($self->blib, 'lib', split /::/, "$notes_name.pm");
580
581   return if $self->up_to_date(['Build.PL',
582                                $self->config_file('config_data'),
583                                $self->config_file('features')
584                               ], $notes_pm);
585
586   $self->log_info("Writing config notes to $notes_pm\n");
587   File::Path::mkpath(File::Basename::dirname($notes_pm));
588
589   Module::Build::Notes->write_config_data
590       (
591        file => $notes_pm,
592        module => $module_name,
593        config_module => $notes_name,
594        config_data => scalar $self->config_data,
595        feature => scalar $self->{phash}{features}->access(),
596        auto_features => scalar $self->auto_features,
597       );
598 }
599
600 {
601     my %valid_properties = ( __PACKAGE__,  {} );
602     my %additive_properties;
603
604     sub _mb_classes {
605       my $class = ref($_[0]) || $_[0];
606       return ($class, $class->mb_parents);
607     }
608
609     sub valid_property {
610       my ($class, $prop) = @_;
611       return grep exists( $valid_properties{$_}{$prop} ), $class->_mb_classes;
612     }
613
614     sub valid_properties {
615       return keys %{ shift->valid_properties_defaults() };
616     }
617
618     sub valid_properties_defaults {
619       my %out;
620       for (reverse shift->_mb_classes) {
621         @out{ keys %{ $valid_properties{$_} } } = values %{ $valid_properties{$_} };
622       }
623       return \%out;
624     }
625
626     sub array_properties {
627       for (shift->_mb_classes) {
628         return @{$additive_properties{$_}->{ARRAY}}
629           if exists $additive_properties{$_}->{ARRAY};
630       }
631     }
632
633     sub hash_properties {
634       for (shift->_mb_classes) {
635         return @{$additive_properties{$_}->{'HASH'}}
636           if exists $additive_properties{$_}->{'HASH'};
637       }
638     }
639
640     sub add_property {
641       my ($class, $property, $default) = @_;
642       die "Property '$property' already exists" if $class->valid_property($property);
643
644       $valid_properties{$class}{$property} = $default;
645
646       my $type = ref $default;
647       if ($type) {
648         push @{$additive_properties{$class}->{$type}}, $property;
649       }
650
651       unless ($class->can($property)) {
652         no strict 'refs';
653         if ( $type eq 'HASH' ) {
654           *{"$class\::$property"} = sub {
655             my $self = shift;
656             my $x = ( $property eq 'config' ) ? $self : $self->{properties};
657             return $x->{$property} unless @_;
658
659             if ( defined($_[0]) && !ref($_[0]) ) {
660               if ( @_ == 1 ) {
661                 return exists( $x->{$property}{$_[0]} ) ?
662                          $x->{$property}{$_[0]} : undef;
663               } elsif ( @_ % 2 == 0 ) {
664                 my %args = @_;
665                 while ( my($k, $v) = each %args ) {
666                   $x->{$property}{$k} = $v;
667                 }
668               } else {
669                 die "Unexpected arguments for property '$property'\n";
670               }
671             } else {
672               $x->{$property} = $_[0];
673             }
674           };
675
676         } else {
677           *{"$class\::$property"} = sub {
678             my $self = shift;
679             $self->{properties}{$property} = shift if @_;
680             return $self->{properties}{$property};
681           }
682         }
683
684       }
685       return $class;
686     }
687
688     sub _set_defaults {
689       my $self = shift;
690
691       # Set the build class.
692       $self->{properties}{build_class} ||= ref $self;
693
694       # If there was no orig_dir, set to the same as base_dir
695       $self->{properties}{orig_dir} ||= $self->{properties}{base_dir};
696
697       my $defaults = $self->valid_properties_defaults;
698       
699       foreach my $prop (keys %$defaults) {
700         $self->{properties}{$prop} = $defaults->{$prop}
701           unless exists $self->{properties}{$prop};
702       }
703       
704       # Copy defaults for arrays any arrays.
705       for my $prop ($self->array_properties) {
706         $self->{properties}{$prop} = [@{$defaults->{$prop}}]
707           unless exists $self->{properties}{$prop};
708       }
709       # Copy defaults for arrays any hashes.
710       for my $prop ($self->hash_properties) {
711         $self->{properties}{$prop} = {%{$defaults->{$prop}}}
712           unless exists $self->{properties}{$prop};
713       }
714     }
715
716 }
717
718 # Add the default properties.
719 __PACKAGE__->add_property(blib => 'blib');
720 __PACKAGE__->add_property(build_class => 'Module::Build');
721 __PACKAGE__->add_property(build_elements => [qw(PL support pm xs pod script)]);
722 __PACKAGE__->add_property(build_script => 'Build');
723 __PACKAGE__->add_property(build_bat => 0);
724 __PACKAGE__->add_property(config_dir => '_build');
725 __PACKAGE__->add_property(include_dirs => []);
726 __PACKAGE__->add_property(installdirs => 'site');
727 __PACKAGE__->add_property(metafile => 'META.yml');
728 __PACKAGE__->add_property(recurse_into => []);
729 __PACKAGE__->add_property(use_rcfile => 1);
730 __PACKAGE__->add_property(create_packlist => 1);
731
732 {
733   my $Is_ActivePerl = eval {require ActivePerl::DocTools};
734   __PACKAGE__->add_property(html_css => $Is_ActivePerl ? 'Active.css' : '');
735 }
736
737 {
738   my @prereq_action_types = qw(requires build_requires conflicts recommends);
739   foreach my $type (@prereq_action_types) {
740     __PACKAGE__->add_property($type => {});
741   }
742   __PACKAGE__->add_property(prereq_action_types => \@prereq_action_types);
743 }
744
745 __PACKAGE__->add_property($_ => {}) for qw(
746   config
747   get_options
748   install_base_relpaths
749   install_path
750   install_sets
751   meta_add
752   meta_merge
753   original_prefix
754   prefix_relpaths
755 );
756
757 __PACKAGE__->add_property($_) for qw(
758   PL_files
759   autosplit
760   base_dir
761   bindoc_dirs
762   c_source
763   create_makefile_pl
764   create_readme
765   debugger
766   destdir
767   dist_abstract
768   dist_author
769   dist_name
770   dist_version
771   dist_version_from
772   extra_compiler_flags
773   extra_linker_flags
774   has_config_data
775   install_base
776   libdoc_dirs
777   license
778   magic_number
779   mb_version
780   module_name
781   orig_dir
782   perl
783   pm_files
784   pod_files
785   pollute
786   prefix
787   quiet
788   recursive_test_files
789   script_files
790   scripts
791   test_files
792   verbose
793   xs_files
794 );
795
796
797 sub mb_parents {
798     # Code borrowed from Class::ISA.
799     my @in_stack = (shift);
800     my %seen = ($in_stack[0] => 1);
801
802     my ($current, @out);
803     while (@in_stack) {
804         next unless defined($current = shift @in_stack)
805           && $current->isa('Module::Build::Base');
806         push @out, $current;
807         next if $current eq 'Module::Build::Base';
808         no strict 'refs';
809         unshift @in_stack,
810           map {
811               my $c = $_; # copy, to avoid being destructive
812               substr($c,0,2) = "main::" if substr($c,0,2) eq '::';
813               # Canonize the :: -> main::, ::foo -> main::foo thing.
814               # Should I ever canonize the Foo'Bar = Foo::Bar thing?
815               $seen{$c}++ ? () : $c;
816           } @{"$current\::ISA"};
817
818         # I.e., if this class has any parents (at least, ones I've never seen
819         # before), push them, in order, onto the stack of classes I need to
820         # explore.
821     }
822     shift @out;
823     return @out;
824 }
825
826 sub extra_linker_flags   { shift->_list_accessor('extra_linker_flags',   @_) }
827 sub extra_compiler_flags { shift->_list_accessor('extra_compiler_flags', @_) }
828
829 sub _list_accessor {
830   (my $self, local $_) = (shift, shift);
831   my $p = $self->{properties};
832   $p->{$_} = [@_] if @_;
833   $p->{$_} = [] unless exists $p->{$_};
834   return ref($p->{$_}) ? $p->{$_} : [$p->{$_}];
835 }
836
837 # XXX Problem - if Module::Build is loaded from a different directory,
838 # it'll look for (and perhaps destroy/create) a _build directory.
839 sub subclass {
840   my ($pack, %opts) = @_;
841
842   my $build_dir = '_build'; # XXX The _build directory is ostensibly settable by the user.  Shouldn't hard-code here.
843   $pack->delete_filetree($build_dir) if -e $build_dir;
844
845   die "Must provide 'code' or 'class' option to subclass()\n"
846     unless $opts{code} or $opts{class};
847
848   $opts{code}  ||= '';
849   $opts{class} ||= 'MyModuleBuilder';
850   
851   my $filename = File::Spec->catfile($build_dir, 'lib', split '::', $opts{class}) . '.pm';
852   my $filedir  = File::Basename::dirname($filename);
853   $pack->log_info("Creating custom builder $filename in $filedir\n");
854   
855   File::Path::mkpath($filedir);
856   die "Can't create directory $filedir: $!" unless -d $filedir;
857   
858   my $fh = IO::File->new("> $filename") or die "Can't create $filename: $!";
859   print $fh <<EOF;
860 package $opts{class};
861 use $pack;
862 \@ISA = qw($pack);
863 $opts{code}
864 1;
865 EOF
866   close $fh;
867   
868   unshift @INC, File::Spec->catdir(File::Spec->rel2abs($build_dir), 'lib');
869   eval "use $opts{class}";
870   die $@ if $@;
871
872   return $opts{class};
873 }
874
875 sub dist_name {
876   my $self = shift;
877   my $p = $self->{properties};
878   return $p->{dist_name} if defined $p->{dist_name};
879   
880   die "Can't determine distribution name, must supply either 'dist_name' or 'module_name' parameter"
881     unless $self->module_name;
882   
883   ($p->{dist_name} = $self->module_name) =~ s/::/-/g;
884   
885   return $p->{dist_name};
886 }
887
888 sub dist_version_from {
889   my ($self) = @_;
890   my $p = $self->{properties};
891   if ($self->module_name) {
892     $p->{dist_version_from} ||=
893         join( '/', 'lib', split(/::/, $self->module_name) ) . '.pm';
894   }
895   return $p->{dist_version_from} || undef;
896 }
897
898 sub dist_version {
899   my ($self) = @_;
900   my $p = $self->{properties};
901
902   return $p->{dist_version} if defined $p->{dist_version};
903
904   if ( my $dist_version_from = $self->dist_version_from ) {
905     my $version_from = File::Spec->catfile( split( qr{/}, $dist_version_from ) );
906     my $pm_info = Module::Build::ModuleInfo->new_from_file( $version_from )
907       or die "Can't find file $version_from to determine version";
908     $p->{dist_version} = $pm_info->version();
909   }
910
911   die ("Can't determine distribution version, must supply either 'dist_version',\n".
912        "'dist_version_from', or 'module_name' parameter")
913     unless $p->{dist_version};
914
915   return $p->{dist_version};
916 }
917
918 sub dist_author   { shift->_pod_parse('author')   }
919 sub dist_abstract { shift->_pod_parse('abstract') }
920
921 sub _pod_parse {
922   my ($self, $part) = @_;
923   my $p = $self->{properties};
924   my $member = "dist_$part";
925   return $p->{$member} if defined $p->{$member};
926   
927   my $docfile = $self->_main_docfile
928     or return;
929   my $fh = IO::File->new($docfile)
930     or return;
931   
932   require Module::Build::PodParser;
933   my $parser = Module::Build::PodParser->new(fh => $fh);
934   my $method = "get_$part";
935   return $p->{$member} = $parser->$method();
936 }
937
938 sub version_from_file { # Method provided for backwards compatability
939   return Module::Build::ModuleInfo->new_from_file($_[1])->version();
940 }
941
942 sub find_module_by_name { # Method provided for backwards compatability
943   return Module::Build::ModuleInfo->find_module_by_name(@_[1,2]);
944 }
945
946 sub add_to_cleanup {
947   my $self = shift;
948   my %files = map {$self->localize_file_path($_), 1} @_;
949   $self->{phash}{cleanup}->write(\%files);
950 }
951
952 sub cleanup {
953   my $self = shift;
954   my $all = $self->{phash}{cleanup}->read;
955   return keys %$all;
956 }
957
958 sub config_file {
959   my $self = shift;
960   return unless -d $self->config_dir;
961   return File::Spec->catfile($self->config_dir, @_);
962 }
963
964 sub read_config {
965   my ($self) = @_;
966   
967   my $file = $self->config_file('build_params')
968     or die "No build_params?";
969   my $fh = IO::File->new($file) or die "Can't read '$file': $!";
970   my $ref = eval do {local $/; <$fh>};
971   die if $@;
972   ($self->{args}, $self->{config}, $self->{properties}) = @$ref;
973   close $fh;
974 }
975
976 sub has_config_data {
977   my $self = shift;
978   return scalar grep $self->{phash}{$_}->has_data(), qw(config_data features auto_features);
979 }
980
981 sub _write_data {
982   my ($self, $filename, $data) = @_;
983   
984   my $file = $self->config_file($filename);
985   my $fh = IO::File->new("> $file") or die "Can't create '$file': $!";
986   local $Data::Dumper::Terse = 1;
987   print $fh ref($data) ? Data::Dumper::Dumper($data) : $data;
988 }
989
990 sub write_config {
991   my ($self) = @_;
992   
993   File::Path::mkpath($self->{properties}{config_dir});
994   -d $self->{properties}{config_dir} or die "Can't mkdir $self->{properties}{config_dir}: $!";
995   
996   my @items = @{ $self->prereq_action_types };
997   $self->_write_data('prereqs', { map { $_, $self->$_() } @items });
998   $self->_write_data('build_params', [$self->{args}, $self->{config}, $self->{properties}]);
999
1000   # Set a new magic number and write it to a file
1001   $self->_write_data('magicnum', $self->magic_number(int rand 1_000_000));
1002
1003   $self->{phash}{$_}->write() foreach qw(notes cleanup features auto_features config_data runtime_params);
1004 }
1005
1006 sub check_autofeatures {
1007   my ($self) = @_;
1008   my $features = $self->auto_features;
1009   
1010   return unless %$features;
1011
1012   $self->log_info("Checking features:\n");
1013
1014   my $max_name_len;
1015   $max_name_len = ( length($_) > $max_name_len ) ?
1016                     length($_) : $max_name_len
1017     for keys %$features;
1018
1019   while (my ($name, $info) = each %$features) {
1020     $self->log_info("  $name" . '.' x ($max_name_len - length($name) + 4));
1021
1022     if ( my $failures = $self->prereq_failures($info) ) {
1023       my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
1024                            keys %$failures ) ? 1 : 0;
1025       $self->log_info( $disabled ? "disabled\n" : "enabled\n" );
1026
1027       my $log_text;
1028       while (my ($type, $prereqs) = each %$failures) {
1029         while (my ($module, $status) = each %$prereqs) {
1030           my $required =
1031             ($type =~ /^(?:\w+_)?(?:requires|conflicts)$/) ? 1 : 0;
1032           my $prefix = ($required) ? '-' : '*';
1033           $log_text .= "    $prefix $status->{message}\n";
1034         }
1035       }
1036       $self->log_warn("$log_text") unless $self->quiet;
1037     } else {
1038       $self->log_info("enabled\n");
1039     }
1040   }
1041
1042   $self->log_warn("\n");
1043 }
1044
1045 sub prereq_failures {
1046   my ($self, $info) = @_;
1047
1048   my @types = @{ $self->prereq_action_types };
1049   $info ||= {map {$_, $self->$_()} @types};
1050
1051   my $out;
1052
1053   foreach my $type (@types) {
1054     my $prereqs = $info->{$type};
1055     while ( my ($modname, $spec) = each %$prereqs ) {
1056       my $status = $self->check_installed_status($modname, $spec);
1057
1058       if ($type =~ /^(?:\w+_)?conflicts$/) {
1059         next if !$status->{ok};
1060         $status->{conflicts} = delete $status->{need};
1061         $status->{message} = "$modname ($status->{have}) conflicts with this distribution";
1062
1063       } elsif ($type =~ /^(?:\w+_)?recommends$/) {
1064         next if $status->{ok};
1065         $status->{message} = ($status->{have} eq '<none>'
1066                               ? "Optional prerequisite $modname is not installed"
1067                               : "$modname ($status->{have}) is installed, but we prefer to have $spec");
1068       } else {
1069         next if $status->{ok};
1070       }
1071
1072       $out->{$type}{$modname} = $status;
1073     }
1074   }
1075
1076   return $out;
1077 }
1078
1079 # returns a hash of defined prerequisites; i.e. only prereq types with values
1080 sub _enum_prereqs {
1081   my $self = shift;
1082   my %prereqs;
1083   foreach my $type ( @{ $self->prereq_action_types } ) {
1084     if ( $self->can( $type ) ) {
1085       my $prereq = $self->$type() || {};
1086       $prereqs{$type} = $prereq if %$prereq;
1087     }
1088   }
1089   return \%prereqs;
1090 }
1091
1092 sub check_prereq {
1093   my $self = shift;
1094
1095   # If we have XS files, make sure we can process them.
1096   my $xs_files = $self->find_xs_files;
1097   if (keys %$xs_files && !$self->_mb_feature('C_support')) {
1098     $self->log_warn("Warning: this distribution contains XS files, ".
1099                     "but Module::Build is not configured with C_support");
1100   }
1101
1102   # Check to see if there are any prereqs to check
1103   my $info = $self->_enum_prereqs;
1104   return 1 unless $info;
1105
1106   $self->log_info("Checking prerequisites...\n");
1107
1108   my $failures = $self->prereq_failures($info);
1109
1110   if ( $failures ) {
1111
1112     while (my ($type, $prereqs) = each %$failures) {
1113       while (my ($module, $status) = each %$prereqs) {
1114         my $prefix = ($type =~ /^(?:\w+_)?recommends$/) ? '*' : '- ERROR:';
1115         $self->log_warn(" $prefix $status->{message}\n");
1116       }
1117     }
1118
1119     $self->log_warn(<<EOF);
1120
1121 ERRORS/WARNINGS FOUND IN PREREQUISITES.  You may wish to install the versions
1122 of the modules indicated above before proceeding with this installation
1123
1124 EOF
1125     return 0;
1126
1127   } else {
1128
1129     $self->log_info("Looks good\n\n");
1130     return 1;
1131
1132   }
1133 }
1134
1135 sub perl_version {
1136   my ($self) = @_;
1137   # Check the current perl interpreter
1138   # It's much more convenient to use $] here than $^V, but 'man
1139   # perlvar' says I'm not supposed to.  Bloody tyrant.
1140   return $^V ? $self->perl_version_to_float(sprintf "%vd", $^V) : $];
1141 }
1142
1143 sub perl_version_to_float {
1144   my ($self, $version) = @_;
1145   $version =~ s/\./../;
1146   $version =~ s/\.(\d+)/sprintf '%03d', $1/eg;
1147   return $version;
1148 }
1149
1150 sub _parse_conditions {
1151   my ($self, $spec) = @_;
1152
1153   if ($spec =~ /^\s*([\w.]+)\s*$/) { # A plain number, maybe with dots, letters, and underscores
1154     return (">= $spec");
1155   } else {
1156     return split /\s*,\s*/, $spec;
1157   }
1158 }
1159
1160 sub check_installed_status {
1161   my ($self, $modname, $spec) = @_;
1162   my %status = (need => $spec);
1163   
1164   if ($modname eq 'perl') {
1165     $status{have} = $self->perl_version;
1166   
1167   } elsif (eval { no strict; $status{have} = ${"${modname}::VERSION"} }) {
1168     # Don't try to load if it's already loaded
1169     
1170   } else {
1171     my $pm_info = Module::Build::ModuleInfo->new_from_module( $modname );
1172     unless (defined( $pm_info )) {
1173       @status{ qw(have message) } = ('<none>', "$modname is not installed");
1174       return \%status;
1175     }
1176     
1177     $status{have} = $pm_info->version();
1178     if ($spec and !$status{have}) {
1179       @status{ qw(have message) } = (undef, "Couldn't find a \$VERSION in prerequisite $modname");
1180       return \%status;
1181     }
1182   }
1183   
1184   my @conditions = $self->_parse_conditions($spec);
1185   
1186   foreach (@conditions) {
1187     my ($op, $version) = /^\s*  (<=?|>=?|==|!=)  \s*  ([\w.]+)  \s*$/x
1188       or die "Invalid prerequisite condition '$_' for $modname";
1189     
1190     $version = $self->perl_version_to_float($version)
1191       if $modname eq 'perl';
1192     
1193     next if $op eq '>=' and !$version;  # Module doesn't have to actually define a $VERSION
1194     
1195     unless ($self->compare_versions( $status{have}, $op, $version )) {
1196       $status{message} = "$modname ($status{have}) is installed, but we need version $op $version";
1197       return \%status;
1198     }
1199   }
1200   
1201   $status{ok} = 1;
1202   return \%status;
1203 }
1204
1205 sub compare_versions {
1206   my $self = shift;
1207   my ($v1, $op, $v2) = @_;
1208
1209   # for alpha versions - this doesn't cover all cases, but should work for most:
1210   $v1 =~ s/_(\d+)\z/$1/;
1211   $v2 =~ s/_(\d+)\z/$1/;
1212
1213   my $eval_str = "\$v1 $op \$v2";
1214   my $result   = eval $eval_str;
1215   $self->log_warn("error comparing versions: '$eval_str' $@") if $@;
1216
1217   return $result;
1218 }
1219
1220 # I wish I could set $! to a string, but I can't, so I use $@
1221 sub check_installed_version {
1222   my ($self, $modname, $spec) = @_;
1223   
1224   my $status = $self->check_installed_status($modname, $spec);
1225   
1226   if ($status->{ok}) {
1227     return $status->{have} if $status->{have} and $status->{have} ne '<none>';
1228     return '0 but true';
1229   }
1230   
1231   $@ = $status->{message};
1232   return 0;
1233 }
1234
1235 sub make_executable {
1236   # Perl's chmod() is mapped to useful things on various non-Unix
1237   # platforms, so we use it in the base class even though it looks
1238   # Unixish.
1239
1240   my $self = shift;
1241   foreach (@_) {
1242     my $current_mode = (stat $_)[2];
1243     chmod $current_mode | 0111, $_;
1244   }
1245 }
1246
1247 sub _startperl { shift()->config('startperl') }
1248
1249 # Return any directories in @INC which are not in the default @INC for
1250 # this perl.  For example, stuff passed in with -I or loaded with "use lib".
1251 sub _added_to_INC {
1252   my $self = shift;
1253
1254   my %seen;
1255   $seen{$_}++ foreach $self->_default_INC;
1256   return grep !$seen{$_}++, @INC;
1257 }
1258
1259 # Determine the default @INC for this Perl
1260 {
1261   my @default_inc; # Memoize
1262   sub _default_INC {
1263     my $self = shift;
1264     return @default_inc if @default_inc;
1265     
1266     local $ENV{PERL5LIB};  # this is not considered part of the default.
1267     
1268     my $perl = ref($self) ? $self->perl : $self->find_perl_interpreter;
1269     
1270     my @inc = $self->_backticks($perl, '-le', 'print for @INC');
1271     chomp @inc;
1272     
1273     return @default_inc = @inc;
1274   }
1275 }
1276
1277 sub print_build_script {
1278   my ($self, $fh) = @_;
1279   
1280   my $build_package = $self->build_class;
1281   
1282   my $closedata="";
1283
1284   my %q = map {$_, $self->$_()} qw(config_dir base_dir);
1285
1286   my $case_tolerant = 0+(File::Spec->can('case_tolerant')
1287                          && File::Spec->case_tolerant);
1288   $q{base_dir} = uc $q{base_dir} if $case_tolerant;
1289   $q{base_dir} = Win32::GetShortPathName($q{base_dir}) if $^O eq 'MSWin32';
1290
1291   $q{magic_numfile} = $self->config_file('magicnum');
1292
1293   my @myINC = $self->_added_to_INC;
1294   for (@myINC, values %q) {
1295     $_ = File::Spec->canonpath( $_ );
1296     s/([\\\'])/\\$1/g;
1297   }
1298
1299   my $quoted_INC = join ",\n", map "     '$_'", @myINC;
1300   my $shebang = $self->_startperl;
1301   my $magic_number = $self->magic_number;
1302
1303   print $fh <<EOF;
1304 $shebang
1305
1306 use strict;
1307 use Cwd;
1308 use File::Basename;
1309 use File::Spec;
1310
1311 sub magic_number_matches {
1312   return 0 unless -e '$q{magic_numfile}';
1313   local *FH;
1314   open FH, '$q{magic_numfile}' or return 0;
1315   my \$filenum = <FH>;
1316   close FH;
1317   return \$filenum == $magic_number;
1318 }
1319
1320 my \$progname;
1321 my \$orig_dir;
1322 BEGIN {
1323   \$^W = 1;  # Use warnings
1324   \$progname = basename(\$0);
1325   \$orig_dir = Cwd::cwd();
1326   my \$base_dir = '$q{base_dir}';
1327   if (!magic_number_matches()) {
1328     unless (chdir(\$base_dir)) {
1329       die ("Couldn't chdir(\$base_dir), aborting\\n");
1330     }
1331     unless (magic_number_matches()) {
1332       die ("Configuration seems to be out of date, please re-run 'perl Build.PL' again.\\n");
1333     }
1334   }
1335   unshift \@INC,
1336     (
1337 $quoted_INC
1338     );
1339 }
1340
1341 close(*DATA) unless eof(*DATA); # ensure no open handles to this script
1342
1343 use $build_package;
1344
1345 # Some platforms have problems setting \$^X in shebang contexts, fix it up here
1346 \$^X = Module::Build->find_perl_interpreter;
1347
1348 if (-e 'Build.PL' and not $build_package->up_to_date('Build.PL', \$progname)) {
1349    warn "Warning: Build.PL has been altered.  You may need to run 'perl Build.PL' again.\\n";
1350 }
1351
1352 # This should have just enough arguments to be able to bootstrap the rest.
1353 my \$build = $build_package->resume (
1354   properties => {
1355     config_dir => '$q{config_dir}',
1356     orig_dir => \$orig_dir,
1357   },
1358 );
1359
1360 \$build->dispatch;
1361 EOF
1362 }
1363
1364 sub create_build_script {
1365   my ($self) = @_;
1366   $self->write_config;
1367   
1368   my ($build_script, $dist_name, $dist_version)
1369     = map $self->$_(), qw(build_script dist_name dist_version);
1370   
1371   if ( $self->delete_filetree($build_script) ) {
1372     $self->log_info("Removed previous script '$build_script'\n\n");
1373   }
1374
1375   $self->log_info("Creating new '$build_script' script for ",
1376                   "'$dist_name' version '$dist_version'\n");
1377   my $fh = IO::File->new(">$build_script") or die "Can't create '$build_script': $!";
1378   $self->print_build_script($fh);
1379   close $fh;
1380   
1381   $self->make_executable($build_script);
1382
1383   return 1;
1384 }
1385
1386 sub check_manifest {
1387   my $self = shift;
1388   return unless -e 'MANIFEST';
1389   
1390   # Stolen nearly verbatim from MakeMaker.  But ExtUtils::Manifest
1391   # could easily be re-written into a modern Perl dialect.
1392
1393   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
1394   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
1395   
1396   $self->log_info("Checking whether your kit is complete...\n");
1397   if (my @missed = ExtUtils::Manifest::manicheck()) {
1398     $self->log_warn("WARNING: the following files are missing in your kit:\n",
1399                     "\t", join("\n\t", @missed), "\n",
1400                     "Please inform the author.\n\n");
1401   } else {
1402     $self->log_info("Looks good\n\n");
1403   }
1404 }
1405
1406 sub dispatch {
1407   my $self = shift;
1408   local $self->{_completed_actions} = {};
1409
1410   if (@_) {
1411     my ($action, %p) = @_;
1412     my $args = $p{args} ? delete($p{args}) : {};
1413
1414     local $self->{invoked_action} = $action;
1415     local $self->{args} = {%{$self->{args}}, %$args};
1416     local $self->{properties} = {%{$self->{properties}}, %p};
1417     return $self->_call_action($action);
1418   }
1419
1420   die "No build action specified" unless $self->{action};
1421   local $self->{invoked_action} = $self->{action};
1422   $self->_call_action($self->{action});
1423 }
1424
1425 sub _call_action {
1426   my ($self, $action) = @_;
1427
1428   return if $self->{_completed_actions}{$action}++;
1429
1430   local $self->{action} = $action;
1431   my $method = "ACTION_$action";
1432   die "No action '$action' defined, try running the 'help' action.\n" unless $self->can($method);
1433   return $self->$method();
1434 }
1435
1436 sub cull_options {
1437     my $self = shift;
1438     my $specs = $self->get_options or return ({}, @_);
1439     require Getopt::Long;
1440     # XXX Should we let Getopt::Long handle M::B's options? That would
1441     # be easy-ish to add to @specs right here, but wouldn't handle options
1442     # passed without "--" as M::B currently allows. We might be able to
1443     # get around this by setting the "prefix_pattern" Configure option.
1444     my @specs;
1445     my $args = {};
1446     # Construct the specifications for GetOptions.
1447     while (my ($k, $v) = each %$specs) {
1448         # Throw an error if specs conflict with our own.
1449         die "Option specification '$k' conflicts with a " . ref $self
1450           . " option of the same name"
1451           if $self->valid_property($k);
1452         push @specs, $k . (defined $v->{type} ? $v->{type} : '');
1453         push @specs, $v->{store} if exists $v->{store};
1454         $args->{$k} = $v->{default} if exists $v->{default};
1455     }
1456
1457     local @ARGV = @_; # No other way to dupe Getopt::Long
1458
1459     # Get the options values and return them.
1460     # XXX Add option to allow users to set options?
1461     if ( @specs ) {
1462       Getopt::Long::Configure('pass_through');
1463       Getopt::Long::GetOptions($args, @specs);
1464     }
1465
1466     return $args, @ARGV;
1467 }
1468
1469 sub unparse_args {
1470   my ($self, $args) = @_;
1471   my @out;
1472   while (my ($k, $v) = each %$args) {
1473     push @out, (UNIVERSAL::isa($v, 'HASH')  ? map {+"--$k", "$_=$v->{$_}"} keys %$v :
1474                 UNIVERSAL::isa($v, 'ARRAY') ? map {+"--$k", $_} @$v :
1475                 ("--$k", $v));
1476   }
1477   return @out;
1478 }
1479
1480 sub args {
1481     my $self = shift;
1482     return wantarray ? %{ $self->{args} } : $self->{args} unless @_;
1483     my $key = shift;
1484     $self->{args}{$key} = shift if @_;
1485     return $self->{args}{$key};
1486 }
1487
1488 sub _translate_option {
1489   my $self = shift;
1490   my $opt  = shift;
1491
1492   (my $tr_opt = $opt) =~ tr/-/_/;
1493
1494   return $tr_opt if grep $tr_opt =~ /^(?:no_?)?$_$/, qw(
1495     create_makefile_pl
1496     create_readme
1497     extra_compiler_flags
1498     extra_linker_flags
1499     html_css
1500     install_base
1501     install_path
1502     meta_add
1503     meta_merge
1504     test_files
1505     use_rcfile
1506   ); # normalize only selected option names
1507
1508   return $opt;
1509 }
1510
1511 sub _read_arg {
1512   my ($self, $args, $key, $val) = @_;
1513
1514   $key = $self->_translate_option($key);
1515
1516   if ( exists $args->{$key} ) {
1517     $args->{$key} = [ $args->{$key} ] unless ref $args->{$key};
1518     push @{$args->{$key}}, $val;
1519   } else {
1520     $args->{$key} = $val;
1521   }
1522 }
1523
1524 sub _optional_arg {
1525   my $self = shift;
1526   my $opt  = shift;
1527   my $argv = shift;
1528
1529   $opt = $self->_translate_option($opt);
1530
1531   my @bool_opts = qw(
1532     build_bat
1533     create_readme
1534     pollute
1535     quiet
1536     uninst
1537     use_rcfile
1538     verbose
1539   );
1540
1541   # inverted boolean options; eg --noverbose or --no-verbose
1542   # converted to proper name & returned with false value (verbose, 0)
1543   if ( grep $opt =~ /^no[-_]?$_$/, @bool_opts ) {
1544     $opt =~ s/^no-?//;
1545     return ($opt, 0);
1546   }
1547
1548   # non-boolean option; return option unchanged along with its argument
1549   return ($opt, shift(@$argv)) unless grep $_ eq $opt, @bool_opts;
1550
1551   # we're punting a bit here, if an option appears followed by a digit
1552   # we take the digit as the argument for the option. If there is
1553   # nothing that looks like a digit, we pretent the option is a flag
1554   # that is being set and has no argument.
1555   my $arg = 1;
1556   $arg = shift(@$argv) if @$argv && $argv->[0] =~ /^\d+$/;
1557
1558   return ($opt, $arg);
1559 }
1560
1561 sub read_args {
1562   my $self = shift;
1563   my ($action, @argv);
1564   (my $args, @_) = $self->cull_options(@_);
1565   my %args = %$args;
1566
1567   my $opt_re = qr/[\w\-]+/;
1568
1569   while (@_) {
1570     local $_ = shift;
1571     if ( /^(?:--)?($opt_re)=(.*)$/ ) {
1572       $self->_read_arg(\%args, $1, $2);
1573     } elsif ( /^--($opt_re)$/ ) {
1574       my($opt, $arg) = $self->_optional_arg($1, \@_);
1575       $self->_read_arg(\%args, $opt, $arg);
1576     } elsif ( /^($opt_re)$/ and !defined($action)) {
1577       $action = $1;
1578     } else {
1579       push @argv, $_;
1580     }
1581   }
1582   $args{ARGV} = \@argv;
1583
1584   # Hashify these parameters
1585   for ($self->hash_properties) {
1586     next unless exists $args{$_};
1587     my %hash;
1588     $args{$_} ||= [];
1589     $args{$_} = [ $args{$_} ] unless ref $args{$_};
1590     foreach my $arg ( @{$args{$_}} ) {
1591       $arg =~ /(\w+)=(.*)/
1592         or die "Malformed '$_' argument: '$arg' should be something like 'foo=bar'";
1593       $hash{$1} = $2;
1594     }
1595     $args{$_} = \%hash;
1596   }
1597
1598   # De-tilde-ify any path parameters
1599   for my $key (qw(prefix install_base destdir)) {
1600     next if !defined $args{$key};
1601     $args{$key} = _detildefy($args{$key});
1602   }
1603
1604   for my $key (qw(install_path)) {
1605     next if !defined $args{$key};
1606
1607     for my $subkey (keys %{$args{$key}}) {
1608       next if !defined $args{$key}{$subkey};
1609       my $subkey_ext = _detildefy($args{$key}{$subkey});
1610       if ( $subkey eq 'html' ) { # translate for compatability
1611         $args{$key}{binhtml} = $subkey_ext;
1612         $args{$key}{libhtml} = $subkey_ext;
1613       } else {
1614         $args{$key}{$subkey} = $subkey_ext;
1615       }
1616     }
1617   }
1618
1619   if ($args{makefile_env_macros}) {
1620     require Module::Build::Compat;
1621     %args = (%args, Module::Build::Compat->makefile_to_build_macros);
1622   }
1623   
1624   return \%args, $action;
1625 }
1626
1627
1628 sub _detildefy {
1629     my $arg = shift;
1630
1631     my($new_arg) = glob($arg) if $arg =~ /^~/;
1632
1633     return defined($new_arg) ? $new_arg : $arg;
1634 }
1635
1636
1637 # merge Module::Build argument lists that have already been parsed
1638 # by read_args(). Takes two references to option hashes and merges
1639 # the contents, giving priority to the first.
1640 sub _merge_arglist {
1641   my( $self, $opts1, $opts2 ) = @_;
1642
1643   my %new_opts = %$opts1;
1644   while (my ($key, $val) = each %$opts2) {
1645     if ( exists( $opts1->{$key} ) ) {
1646       if ( ref( $val ) eq 'HASH' ) {
1647         while (my ($k, $v) = each %$val) {
1648           $new_opts{$key}{$k} = $v unless exists( $opts1->{$key}{$k} );
1649         }
1650       }
1651     } else {
1652       $new_opts{$key} = $val
1653     }
1654   }
1655
1656   return %new_opts;
1657 }
1658
1659 # Look for a home directory on various systems.  CPANPLUS does something like this.
1660 sub _home_dir {
1661   my @os_home_envs = qw( APPDATA HOME USERPROFILE WINDIR SYS$LOGIN );
1662   
1663   foreach ( @os_home_envs ) {
1664     return $ENV{$_} if exists $ENV{$_} && defined $ENV{$_} && length $ENV{$_} && -d $ENV{$_};
1665   }
1666   
1667   return;
1668 }
1669
1670 # read ~/.modulebuildrc returning global options '*' and
1671 # options specific to the currently executing $action.
1672 sub read_modulebuildrc {
1673   my( $self, $action ) = @_;
1674
1675   return () unless $self->use_rcfile;
1676
1677   my $modulebuildrc;
1678   if ( exists($ENV{MODULEBUILDRC}) && $ENV{MODULEBUILDRC} eq 'NONE' ) {
1679     return ();
1680   } elsif ( exists($ENV{MODULEBUILDRC}) && -e $ENV{MODULEBUILDRC} ) {
1681     $modulebuildrc = $ENV{MODULEBUILDRC};
1682   } elsif ( exists($ENV{MODULEBUILDRC}) ) {
1683     $self->log_warn("WARNING: Can't find resource file " .
1684                     "'$ENV{MODULEBUILDRC}' defined in environment.\n" .
1685                     "No options loaded\n");
1686     return ();
1687   } else {
1688     my $home = $self->_home_dir;
1689     return () unless defined $home;
1690     $modulebuildrc = File::Spec->catfile( $home, '.modulebuildrc' );
1691     return () unless -e $modulebuildrc;
1692   }
1693
1694   my $fh = IO::File->new( $modulebuildrc )
1695       or die "Can't open $modulebuildrc: $!";
1696
1697   my %options; my $buffer = '';
1698   while (defined( my $line = <$fh> )) {
1699     chomp( $line );
1700     $line =~ s/#.*$//;
1701     next unless length( $line );
1702
1703     if ( $line =~ /^\S/ ) {
1704       if ( $buffer ) {
1705         my( $action, $options ) = split( /\s+/, $buffer, 2 );
1706         $options{$action} .= $options . ' ';
1707         $buffer = '';
1708       }
1709       $buffer = $line;
1710     } else {
1711       $buffer .= $line;
1712     }
1713   }
1714
1715   if ( $buffer ) { # anything left in $buffer ?
1716     my( $action, $options ) = split( /\s+/, $buffer, 2 );
1717     $options{$action} .= $options . ' '; # merge if more than one line
1718   }
1719
1720   my ($global_opts) =
1721     $self->read_args( $self->split_like_shell( $options{'*'} || '' ) );
1722   my ($action_opts) =
1723     $self->read_args( $self->split_like_shell( $options{$action} || '' ) );
1724
1725   # specific $action options take priority over global options '*'
1726   return $self->_merge_arglist( $action_opts, $global_opts );
1727 }
1728
1729 # merge the relevant options in ~/.modulebuildrc into Module::Build's
1730 # option list where they do not conflict with commandline options.
1731 sub merge_modulebuildrc {
1732   my( $self, $action, %cmdline_opts ) = @_;
1733   my %rc_opts = $self->read_modulebuildrc( $action || $self->{action} || 'build' );
1734   my %new_opts = $self->_merge_arglist( \%cmdline_opts, \%rc_opts );
1735   $self->merge_args( $action, %new_opts );
1736 }
1737
1738 sub merge_args {
1739   my ($self, $action, %args) = @_;
1740   $self->{action} = $action if defined $action;
1741
1742   my %additive = map { $_ => 1 } $self->hash_properties;
1743
1744   # Extract our 'properties' from $cmd_args, the rest are put in 'args'.
1745   while (my ($key, $val) = each %args) {
1746     $self->{phash}{runtime_params}->access( $key => $val )
1747       if $self->valid_property($key);
1748     my $add_to = ( $key eq 'config' ? $self->{config}
1749                   : $additive{$key} ? $self->{properties}{$key}
1750                   : $self->valid_property($key) ? $self->{properties}
1751                   : $self->{args});
1752
1753     if ($additive{$key}) {
1754       $add_to->{$_} = $val->{$_} foreach keys %$val;
1755     } else {
1756       $add_to->{$key} = $val;
1757     }
1758   }
1759 }
1760
1761 sub cull_args {
1762   my $self = shift;
1763   my ($args, $action) = $self->read_args(@_);
1764   $self->merge_args($action, %$args);
1765   $self->merge_modulebuildrc( $action, %$args );
1766 }
1767
1768 sub super_classes {
1769   my ($self, $class, $seen) = @_;
1770   $class ||= ref($self) || $self;
1771   $seen  ||= {};
1772   
1773   no strict 'refs';
1774   my @super = grep {not $seen->{$_}++} $class, @{ $class . '::ISA' };
1775   return @super, map {$self->super_classes($_,$seen)} @super;
1776 }
1777
1778 sub known_actions {
1779   my ($self) = @_;
1780
1781   my %actions;
1782   no strict 'refs';
1783   
1784   foreach my $class ($self->super_classes) {
1785     foreach ( keys %{ $class . '::' } ) {
1786       $actions{$1}++ if /^ACTION_(\w+)/;
1787     }
1788   }
1789
1790   return wantarray ? sort keys %actions : \%actions;
1791 }
1792
1793 sub get_action_docs {
1794   my ($self, $action, $actions) = @_;
1795   $actions ||= $self->known_actions;
1796   $@ = '';
1797   ($@ = "No known action '$action'\n"), return
1798     unless $actions->{$action};
1799   
1800   my ($files_found, @docs) = (0);
1801   foreach my $class ($self->super_classes) {
1802     (my $file = $class) =~ s{::}{/}g;
1803     $file = $INC{$file . '.pm'} or next;
1804     my $fh = IO::File->new("< $file") or next;
1805     $files_found++;
1806     
1807     # Code below modified from /usr/bin/perldoc
1808     
1809     # Skip to ACTIONS section
1810     local $_;
1811     while (<$fh>) {
1812       last if /^=head1 ACTIONS\s/;
1813     }
1814     
1815     # Look for our action
1816     my ($found, $inlist) = (0, 0);
1817     while (<$fh>) {
1818       if (/^=item\s+\Q$action\E\b/)  {
1819         $found = 1;
1820       } elsif (/^=(item|back)/) {
1821         last if $found > 1 and not $inlist;
1822       }
1823       next unless $found;
1824       push @docs, $_;
1825       ++$inlist if /^=over/;
1826       --$inlist if /^=back/;
1827       ++$found  if /^\w/; # Found descriptive text
1828     }
1829   }
1830
1831   unless ($files_found) {
1832     $@ = "Couldn't find any documentation to search";
1833     return;
1834   }
1835   unless (@docs) {
1836     $@ = "Couldn't find any docs for action '$action'";
1837     return;
1838   }
1839   
1840   return join '', @docs;
1841 }
1842
1843 sub ACTION_prereq_report {
1844   my $self = shift;
1845   $self->log_info( $self->prereq_report );
1846 }
1847
1848 sub prereq_report {
1849   my $self = shift;
1850   my @types = @{ $self->prereq_action_types };
1851   my $info = { map { $_ => $self->$_() } @types };
1852
1853   my $output = '';
1854   foreach my $type (@types) {
1855     my $prereqs = $info->{$type};
1856     next unless %$prereqs;
1857     $output .= "\n$type:\n";
1858     my $mod_len = 2;
1859     my $ver_len = 4;
1860     my %mods;
1861     while ( my ($modname, $spec) = each %$prereqs ) {
1862       my $len  = length $modname;
1863       $mod_len = $len if $len > $mod_len;
1864       $spec    ||= '0';
1865       $len     = length $spec;
1866       $ver_len = $len if $len > $ver_len;
1867
1868       my $mod = $self->check_installed_status($modname, $spec);
1869       $mod->{name} = $modname;
1870       $mod->{ok} ||= 0;
1871       $mod->{ok} = ! $mod->{ok} if $type =~ /^(\w+_)?conflicts$/;
1872
1873       $mods{lc $modname} = $mod;
1874     }
1875
1876     my $space  = q{ } x ($mod_len - 3);
1877     my $vspace = q{ } x ($ver_len - 3);
1878     my $sline  = q{-} x ($mod_len - 3);
1879     my $vline  = q{-} x ($ver_len - 3);
1880     my $disposition = ($type =~ /^(\w+_)?conflicts$/) ?
1881                         'Clash' : 'Need';
1882     $output .=
1883       "    Module $space  $disposition $vspace  Have\n".
1884       "    ------$sline+------$vline-+----------\n";
1885
1886
1887     for my $k (sort keys %mods) {
1888       my $mod = $mods{$k};
1889       my $space  = q{ } x ($mod_len - length $k);
1890       my $vspace = q{ } x ($ver_len - length $mod->{need});
1891       my $f = $mod->{ok} ? ' ' : '!';
1892       $output .=
1893         "  $f $mod->{name} $space     $mod->{need}  $vspace   $mod->{have}\n";
1894     }
1895   }
1896   return $output;
1897 }
1898
1899 sub ACTION_help {
1900   my ($self) = @_;
1901   my $actions = $self->known_actions;
1902   
1903   if (@{$self->{args}{ARGV}}) {
1904     my $msg = $self->get_action_docs($self->{args}{ARGV}[0], $actions) || "$@\n";
1905     print $msg;
1906     return;
1907   }
1908
1909   print <<EOF;
1910
1911  Usage: $0 <action> arg1=value arg2=value ...
1912  Example: $0 test verbose=1
1913  
1914  Actions defined:
1915 EOF
1916   
1917   print $self->_action_listing($actions);
1918
1919   print "\nRun `Build help <action>` for details on an individual action.\n";
1920   print "See `perldoc Module::Build` for complete documentation.\n";
1921 }
1922
1923 sub _action_listing {
1924   my ($self, $actions) = @_;
1925
1926   # Flow down columns, not across rows
1927   my @actions = sort keys %$actions;
1928   @actions = map $actions[($_ + ($_ % 2) * @actions) / 2],  0..$#actions;
1929   
1930   my $out = '';
1931   while (my ($one, $two) = splice @actions, 0, 2) {
1932     $out .= sprintf("  %-12s                   %-12s\n", $one, $two||'');
1933   }
1934   return $out;
1935 }
1936
1937 sub ACTION_test {
1938   my ($self) = @_;
1939   my $p = $self->{properties};
1940   require Test::Harness;
1941   
1942   $self->depends_on('code');
1943   
1944   # Do everything in our power to work with all versions of Test::Harness
1945   my @harness_switches = $p->{debugger} ? qw(-w -d) : ();
1946   local $Test::Harness::switches    = join ' ', grep defined, $Test::Harness::switches, @harness_switches;
1947   local $Test::Harness::Switches    = join ' ', grep defined, $Test::Harness::Switches, @harness_switches;
1948   local $ENV{HARNESS_PERL_SWITCHES} = join ' ', grep defined, $ENV{HARNESS_PERL_SWITCHES}, @harness_switches;
1949   
1950   $Test::Harness::switches = undef   unless length $Test::Harness::switches;
1951   $Test::Harness::Switches = undef   unless length $Test::Harness::Switches;
1952   delete $ENV{HARNESS_PERL_SWITCHES} unless length $ENV{HARNESS_PERL_SWITCHES};
1953   
1954   local ($Test::Harness::verbose,
1955          $Test::Harness::Verbose,
1956          $ENV{TEST_VERBOSE},
1957          $ENV{HARNESS_VERBOSE}) = ($p->{verbose} || 0) x 4;
1958
1959   # Make sure we test the module in blib/
1960   local @INC = (File::Spec->catdir($p->{base_dir}, $self->blib, 'lib'),
1961                 File::Spec->catdir($p->{base_dir}, $self->blib, 'arch'),
1962                 @INC);
1963
1964   # Filter out nonsensical @INC entries - some versions of
1965   # Test::Harness will really explode the number of entries here
1966   @INC = grep {ref() || -d} @INC if @INC > 100;
1967   
1968   my $tests = $self->find_test_files;
1969
1970   if (@$tests) {
1971     # Work around a Test::Harness bug that loses the particular perl
1972     # we're running under.  $self->perl is trustworthy, but $^X isn't.
1973     local $^X = $self->perl;
1974     Test::Harness::runtests(@$tests);
1975   } else {
1976     $self->log_info("No tests defined.\n");
1977   }
1978
1979   # This will get run and the user will see the output.  It doesn't
1980   # emit Test::Harness-style output.
1981   if (-e 'visual.pl') {
1982     $self->run_perl_script('visual.pl', '-Mblib='.$self->blib);
1983   }
1984 }
1985
1986 sub test_files {
1987   my $self = shift;
1988   my $p = $self->{properties};
1989   if (@_) {
1990     return $p->{test_files} = (@_ == 1 ? shift : [@_]);
1991   }
1992   return $self->find_test_files;
1993 }
1994
1995 sub expand_test_dir {
1996   my ($self, $dir) = @_;
1997   return sort @{$self->rscan_dir($dir, qr{^[^.].*\.t$})} if $self->recursive_test_files;
1998   return sort glob File::Spec->catfile($dir, "*.t");
1999 }
2000
2001 sub ACTION_testdb {
2002   my ($self) = @_;
2003   local $self->{properties}{debugger} = 1;
2004   $self->depends_on('test');
2005 }
2006
2007 sub ACTION_testcover {
2008   my ($self) = @_;
2009
2010   unless (Module::Build::ModuleInfo->find_module_by_name('Devel::Cover')) {
2011     warn("Cannot run testcover action unless Devel::Cover is installed.\n");
2012     return;
2013   }
2014
2015   $self->add_to_cleanup('coverage', 'cover_db');
2016   $self->depends_on('code');
2017
2018   # See whether any of the *.pm files have changed since last time
2019   # testcover was run.  If so, start over.
2020   if (-e 'cover_db') {
2021     my $pm_files = $self->rscan_dir(File::Spec->catdir($self->blib, 'lib'), qr{\.pm$} );
2022     my $cover_files = $self->rscan_dir('cover_db', sub {-f $_ and not /\.html$/});
2023     
2024     $self->do_system(qw(cover -delete))
2025       unless $self->up_to_date($pm_files, $cover_files);
2026   }
2027
2028   local $Test::Harness::switches    = 
2029   local $Test::Harness::Switches    = 
2030   local $ENV{HARNESS_PERL_SWITCHES} = "-MDevel::Cover";
2031
2032   $self->depends_on('test');
2033   $self->do_system('cover');
2034 }
2035
2036 sub ACTION_code {
2037   my ($self) = @_;
2038   
2039   # All installable stuff gets created in blib/ .
2040   # Create blib/arch to keep blib.pm happy
2041   my $blib = $self->blib;
2042   $self->add_to_cleanup($blib);
2043   File::Path::mkpath( File::Spec->catdir($blib, 'arch') );
2044   
2045   if (my $split = $self->autosplit) {
2046     $self->autosplit_file($_, $blib) for ref($split) ? @$split : ($split);
2047   }
2048   
2049   foreach my $element (@{$self->build_elements}) {
2050     my $method = "process_${element}_files";
2051     $method = "process_files_by_extension" unless $self->can($method);
2052     $self->$method($element);
2053   }
2054
2055   $self->depends_on('config_data');
2056 }
2057
2058 sub ACTION_build {
2059   my $self = shift;
2060   $self->depends_on('code');
2061   $self->depends_on('docs');
2062 }
2063
2064 sub process_files_by_extension {
2065   my ($self, $ext) = @_;
2066   
2067   my $method = "find_${ext}_files";
2068   my $files = $self->can($method) ? $self->$method() : $self->_find_file_by_type($ext,  'lib');
2069   
2070   while (my ($file, $dest) = each %$files) {
2071     $self->copy_if_modified(from => $file, to => File::Spec->catfile($self->blib, $dest) );
2072   }
2073 }
2074
2075 sub process_support_files {
2076   my $self = shift;
2077   my $p = $self->{properties};
2078   return unless $p->{c_source};
2079   
2080   push @{$p->{include_dirs}}, $p->{c_source};
2081   
2082   my $files = $self->rscan_dir($p->{c_source}, qr{\.c(pp)?$});
2083   foreach my $file (@$files) {
2084     push @{$p->{objects}}, $self->compile_c($file);
2085   }
2086 }
2087
2088 sub process_PL_files {
2089   my ($self) = @_;
2090   my $files = $self->find_PL_files;
2091   
2092   while (my ($file, $to) = each %$files) {
2093     unless ($self->up_to_date( $file, $to )) {
2094       $self->run_perl_script($file, [], [@$to]);
2095       $self->add_to_cleanup(@$to);
2096     }
2097   }
2098 }
2099
2100 sub process_xs_files {
2101   my $self = shift;
2102   my $files = $self->find_xs_files;
2103   while (my ($from, $to) = each %$files) {
2104     unless ($from eq $to) {
2105       $self->add_to_cleanup($to);
2106       $self->copy_if_modified( from => $from, to => $to );
2107     }
2108     $self->process_xs($to);
2109   }
2110 }
2111
2112 sub process_pod_files { shift()->process_files_by_extension(shift()) }
2113 sub process_pm_files  { shift()->process_files_by_extension(shift()) }
2114
2115 sub process_script_files {
2116   my $self = shift;
2117   my $files = $self->find_script_files;
2118   return unless keys %$files;
2119
2120   my $script_dir = File::Spec->catdir($self->blib, 'script');
2121   File::Path::mkpath( $script_dir );
2122   
2123   foreach my $file (keys %$files) {
2124     my $result = $self->copy_if_modified($file, $script_dir, 'flatten') or next;
2125     $self->fix_shebang_line($result) unless $self->os_type eq 'VMS';
2126     $self->make_executable($result);
2127   }
2128 }
2129
2130 sub find_PL_files {
2131   my $self = shift;
2132   if (my $files = $self->{properties}{PL_files}) {
2133     # 'PL_files' is given as a Unix file spec, so we localize_file_path().
2134     
2135     if (UNIVERSAL::isa($files, 'ARRAY')) {
2136       return { map {$_, [/^(.*)\.PL$/]}
2137                map $self->localize_file_path($_),
2138                @$files };
2139
2140     } elsif (UNIVERSAL::isa($files, 'HASH')) {
2141       my %out;
2142       while (my ($file, $to) = each %$files) {
2143         $out{ $self->localize_file_path($file) } = [ map $self->localize_file_path($_),
2144                                                      ref $to ? @$to : ($to) ];
2145       }
2146       return \%out;
2147
2148     } else {
2149       die "'PL_files' must be a hash reference or array reference";
2150     }
2151   }
2152   
2153   return unless -d 'lib';
2154   return { map {$_, [/^(.*)\.PL$/]} @{ $self->rscan_dir('lib', qr{\.PL$}) } };
2155 }
2156
2157 sub find_pm_files  { shift->_find_file_by_type('pm',  'lib') }
2158 sub find_pod_files { shift->_find_file_by_type('pod', 'lib') }
2159 sub find_xs_files  { shift->_find_file_by_type('xs',  'lib') }
2160
2161 sub find_script_files {
2162   my $self = shift;
2163   if (my $files = $self->script_files) {
2164     # Always given as a Unix file spec.  Values in the hash are
2165     # meaningless, but we preserve if present.
2166     return { map {$self->localize_file_path($_), $files->{$_}} keys %$files };
2167   }
2168   
2169   # No default location for script files
2170   return {};
2171 }
2172
2173 sub find_test_files {
2174   my $self = shift;
2175   my $p = $self->{properties};
2176   
2177   if (my $files = $p->{test_files}) {
2178     $files = [keys %$files] if UNIVERSAL::isa($files, 'HASH');
2179     $files = [map { -d $_ ? $self->expand_test_dir($_) : $_ }
2180               map glob,
2181               $self->split_like_shell($files)];
2182     
2183     # Always given as a Unix file spec.
2184     return [ map $self->localize_file_path($_), @$files ];
2185     
2186   } else {
2187     # Find all possible tests in t/ or test.pl
2188     my @tests;
2189     push @tests, 'test.pl'                          if -e 'test.pl';
2190     push @tests, $self->expand_test_dir('t')        if -e 't' and -d _;
2191     return \@tests;
2192   }
2193 }
2194
2195 sub _find_file_by_type {
2196   my ($self, $type, $dir) = @_;
2197   
2198   if (my $files = $self->{properties}{"${type}_files"}) {
2199     # Always given as a Unix file spec
2200     return { map $self->localize_file_path($_), %$files };
2201   }
2202   
2203   return {} unless -d $dir;
2204   return { map {$_, $_}
2205            map $self->localize_file_path($_),
2206            grep !/\.\#/,
2207            @{ $self->rscan_dir($dir, qr{\.$type$}) } };
2208 }
2209
2210 sub localize_file_path {
2211   my ($self, $path) = @_;
2212   $path =~ s/\.\z// if $self->os_type eq 'VMS';
2213   return File::Spec->catfile( split m{/}, $path );
2214 }
2215
2216 sub localize_dir_path {
2217   my ($self, $path) = @_;
2218   return File::Spec->catdir( split m{/}, $path );
2219 }
2220
2221 sub fix_shebang_line { # Adapted from fixin() in ExtUtils::MM_Unix 1.35
2222   my ($self, @files) = @_;
2223   my $c = $self->config;
2224   
2225   my ($does_shbang) = $c->{sharpbang} =~ /^\s*\#\!/;
2226   for my $file (@files) {
2227     my $FIXIN = IO::File->new($file) or die "Can't process '$file': $!";
2228     local $/ = "\n";
2229     chomp(my $line = <$FIXIN>);
2230     next unless $line =~ s/^\s*\#!\s*//;     # Not a shbang file.
2231     
2232     my ($cmd, $arg) = (split(' ', $line, 2), '');
2233     next unless $cmd =~ /perl/i;
2234     my $interpreter = $self->{properties}{perl};
2235     
2236     $self->log_verbose("Changing sharpbang in $file to $interpreter");
2237     my $shb = '';
2238     $shb .= "$c->{sharpbang}$interpreter $arg\n" if $does_shbang;
2239     
2240     # I'm not smart enough to know the ramifications of changing the
2241     # embedded newlines here to \n, so I leave 'em in.
2242     $shb .= qq{
2243 eval 'exec $interpreter $arg -S \$0 \${1+"\$\@"}'
2244     if 0; # not running under some shell
2245 } unless $self->os_type eq 'Windows'; # this won't work on win32, so don't
2246     
2247     my $FIXOUT = IO::File->new(">$file.new")
2248       or die "Can't create new $file: $!\n";
2249     
2250     # Print out the new #! line (or equivalent).
2251     local $\;
2252     undef $/; # Was localized above
2253     print $FIXOUT $shb, <$FIXIN>;
2254     close $FIXIN;
2255     close $FIXOUT;
2256     
2257     rename($file, "$file.bak")
2258       or die "Can't rename $file to $file.bak: $!";
2259     
2260     rename("$file.new", $file)
2261       or die "Can't rename $file.new to $file: $!";
2262     
2263     unlink "$file.bak"
2264       or $self->log_warn("Couldn't clean up $file.bak, leaving it there");
2265     
2266     $self->do_system($c->{eunicefix}, $file) if $c->{eunicefix} ne ':';
2267   }
2268 }
2269
2270
2271 sub ACTION_testpod {
2272   my $self = shift;
2273   $self->depends_on('docs');
2274   
2275   eval q{use Test::Pod 0.95; 1}
2276     or die "The 'testpod' action requires Test::Pod version 0.95";
2277
2278   my @files = sort keys %{$self->_find_pods($self->libdoc_dirs)},
2279                    keys %{$self->_find_pods($self->bindoc_dirs, exclude => [ qr/\.bat$/ ])}
2280     or die "Couldn't find any POD files to test\n";
2281
2282   { package Module::Build::PodTester;  # Don't want to pollute the main namespace
2283     Test::Pod->import( tests => scalar @files );
2284     pod_file_ok($_) foreach @files;
2285   }
2286 }
2287
2288 sub ACTION_testpodcoverage {
2289   my $self = shift;
2290
2291   $self->depends_on('docs');
2292   
2293   eval q{use Test::Pod::Coverage 1.00; 1}
2294     or die "The 'testpodcoverage' action requires ",
2295            "Test::Pod::Coverage version 1.00";
2296
2297   all_pod_coverage_ok();
2298 }
2299
2300 sub ACTION_docs {
2301   my $self = shift;
2302
2303   $self->depends_on('code');
2304   $self->depends_on('manpages', 'html');
2305 }
2306
2307 # Given a file type, will return true if the file type would normally
2308 # be installed when neither install-base nor prefix has been set.
2309 # I.e. it will be true only if the path is set from Config.pm or
2310 # set explicitly by the user via install-path.
2311 sub _is_default_installable {
2312   my $self = shift;
2313   my $type = shift;
2314   return ( $self->install_destination($type) &&
2315            ( $self->install_path($type) ||
2316              $self->install_sets($self->installdirs)->{$type} )
2317          ) ? 1 : 0;
2318 }
2319
2320 sub ACTION_manpages {
2321   my $self = shift;
2322
2323   return unless $self->_mb_feature('manpage_support');
2324
2325   $self->depends_on('code');
2326
2327   foreach my $type ( qw(bin lib) ) {
2328     my $files = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2329                                    exclude => [ qr/\.bat$/ ] );
2330     next unless %$files;
2331
2332     my $sub = $self->can("manify_${type}_pods");
2333     next unless defined( $sub );
2334
2335     if ( $self->invoked_action eq 'manpages' ) {
2336       $self->$sub();
2337     } elsif ( $self->_is_default_installable("${type}doc") ) {
2338       $self->$sub();
2339     }
2340   }
2341
2342 }
2343
2344 sub manify_bin_pods {
2345   my $self    = shift;
2346
2347   my $files   = $self->_find_pods( $self->{properties}{bindoc_dirs},
2348                                    exclude => [ qr/\.bat$/ ] );
2349   return unless keys %$files;
2350
2351   my $mandir = File::Spec->catdir( $self->blib, 'bindoc' );
2352   File::Path::mkpath( $mandir, 0, 0777 );
2353
2354   require Pod::Man;
2355   foreach my $file (keys %$files) {
2356     # Pod::Simple based parsers only support one document per instance.
2357     # This is expected to change in a future version (Pod::Simple > 3.03).
2358     my $parser  = Pod::Man->new( section => 1 ); # binaries go in section 1
2359     my $manpage = $self->man1page_name( $file ) . '.' .
2360                   $self->config( 'man1ext' );
2361     my $outfile = File::Spec->catfile($mandir, $manpage);
2362     next if $self->up_to_date( $file, $outfile );
2363     $self->log_info("Manifying $file -> $outfile\n");
2364     $parser->parse_from_file( $file, $outfile );
2365     $files->{$file} = $outfile;
2366   }
2367 }
2368
2369 sub manify_lib_pods {
2370   my $self    = shift;
2371
2372   my $files   = $self->_find_pods($self->{properties}{libdoc_dirs});
2373   return unless keys %$files;
2374
2375   my $mandir = File::Spec->catdir( $self->blib, 'libdoc' );
2376   File::Path::mkpath( $mandir, 0, 0777 );
2377
2378   require Pod::Man;
2379   while (my ($file, $relfile) = each %$files) {
2380     # Pod::Simple based parsers only support one document per instance.
2381     # This is expected to change in a future version (Pod::Simple > 3.03).
2382     my $parser  = Pod::Man->new( section => 3 ); # libraries go in section 3
2383     my $manpage = $self->man3page_name( $relfile ) . '.' .
2384                   $self->config( 'man3ext' );
2385     my $outfile = File::Spec->catfile( $mandir, $manpage);
2386     next if $self->up_to_date( $file, $outfile );
2387     $self->log_info("Manifying $file -> $outfile\n");
2388     $parser->parse_from_file( $file, $outfile );
2389     $files->{$file} = $outfile;
2390   }
2391 }
2392
2393 sub _find_pods {
2394   my ($self, $dirs, %args) = @_;
2395   my %files;
2396   foreach my $spec (@$dirs) {
2397     my $dir = $self->localize_dir_path($spec);
2398     next unless -e $dir;
2399     FILE: foreach my $file ( @{ $self->rscan_dir( $dir ) } ) {
2400       foreach my $regexp ( @{ $args{exclude} } ) {
2401         next FILE if $file =~ $regexp;
2402       }
2403       $files{$file} = File::Spec->abs2rel($file, $dir) if $self->contains_pod( $file )
2404     }
2405   }
2406   return \%files;
2407 }
2408
2409 sub contains_pod {
2410   my ($self, $file) = @_;
2411   return '' unless -T $file;  # Only look at text files
2412   
2413   my $fh = IO::File->new( $file ) or die "Can't open $file: $!";
2414   while (my $line = <$fh>) {
2415     return 1 if $line =~ /^\=(?:head|pod|item)/;
2416   }
2417   
2418   return '';
2419 }
2420
2421 sub ACTION_html {
2422   my $self = shift;
2423
2424   return unless $self->_mb_feature('HTML_support');
2425
2426   $self->depends_on('code');
2427
2428   foreach my $type ( qw(bin lib) ) {
2429     my $files = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2430                                    exclude => [ qr/\.(?:bat|com|html)$/ ] );
2431     next unless %$files;
2432
2433     if ( $self->invoked_action eq 'html' ) {
2434       $self->htmlify_pods( $type );
2435     } elsif ( $self->_is_default_installable("${type}html") ) {
2436       $self->htmlify_pods( $type );
2437     }
2438   }
2439
2440 }
2441
2442
2443 # 1) If it's an ActiveState perl install, we need to run
2444 #    ActivePerl::DocTools->UpdateTOC;
2445 # 2) Links to other modules are not being generated
2446 sub htmlify_pods {
2447   my $self = shift;
2448   my $type = shift;
2449   my $htmldir = shift || File::Spec->catdir($self->blib, "${type}html");
2450
2451   require Module::Build::PodParser;
2452   require Pod::Html;
2453
2454   $self->add_to_cleanup('pod2htm*');
2455
2456   my $pods = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2457                                 exclude => [ qr/\.(?:bat|com|html)$/ ] );
2458   next unless %$pods;  # nothing to do
2459
2460   unless ( -d $htmldir ) {
2461     File::Path::mkpath($htmldir, 0, 0755)
2462       or die "Couldn't mkdir $htmldir: $!";
2463   }
2464
2465   my @rootdirs = ($type eq 'bin') ? qw(bin) :
2466       $self->installdirs eq 'core' ? qw(lib) : qw(site lib);
2467
2468   my $podpath = join ':',
2469                 map  $_->[1],
2470                 grep -e $_->[0],
2471                 map  [File::Spec->catdir($self->blib, $_), $_],
2472                 qw( script lib );
2473
2474   foreach my $pod ( keys %$pods ) {
2475
2476     my ($name, $path) = File::Basename::fileparse($pods->{$pod},
2477                                                   qr{\.(?:pm|plx?|pod)$});
2478     my @dirs = File::Spec->splitdir( File::Spec->canonpath( $path ) );
2479     pop( @dirs ) if $dirs[-1] eq File::Spec->curdir;
2480
2481     my $fulldir = File::Spec->catfile($htmldir, @rootdirs, @dirs);
2482     my $outfile = File::Spec->catfile($fulldir, "${name}.html");
2483     my $infile  = File::Spec->abs2rel($pod);
2484
2485     next if $self->up_to_date($infile, $outfile);
2486
2487     unless ( -d $fulldir ){
2488       File::Path::mkpath($fulldir, 0, 0755)
2489         or die "Couldn't mkdir $fulldir: $!";
2490     }
2491
2492     my $path2root = join( '/', ('..') x (@rootdirs+@dirs) );
2493     my $htmlroot = join( '/',
2494                          ($path2root,
2495                           $self->installdirs eq 'core' ? () : qw(site) ) );
2496
2497     my $fh = IO::File->new($infile) or die "Can't read $infile: $!";
2498     my $abstract = Module::Build::PodParser->new(fh => $fh)->get_abstract();
2499
2500     my $title = join( '::', (@dirs, $name) );
2501     $title .= " - $abstract" if $abstract;
2502
2503     my @opts = (
2504                 '--flush',
2505                 "--title=$title",
2506                 "--podpath=$podpath",
2507                 "--infile=$infile",
2508                 "--outfile=$outfile",
2509                 '--podroot=' . $self->blib,
2510                 "--htmlroot=$htmlroot",
2511                );
2512
2513     if ( eval{Pod::Html->VERSION(1.03)} ) {
2514       push( @opts, ('--header', '--backlink=Back to Top') );
2515       push( @opts, "--css=$path2root/" . $self->html_css) if $self->html_css;
2516     }
2517
2518     $self->log_info("HTMLifying $infile -> $outfile\n");
2519     $self->log_verbose("pod2html @opts\n");
2520     Pod::Html::pod2html(@opts); # or warn "pod2html @opts failed: $!";
2521   }
2522
2523 }
2524
2525 # Adapted from ExtUtils::MM_Unix
2526 sub man1page_name {
2527   my $self = shift;
2528   return File::Basename::basename( shift );
2529 }
2530
2531 # Adapted from ExtUtils::MM_Unix and Pod::Man
2532 # Depending on M::B's dependency policy, it might make more sense to refactor
2533 # Pod::Man::begin_pod() to extract a name() methods, and use them...
2534 #    -spurkis
2535 sub man3page_name {
2536   my $self = shift;
2537   my ($vol, $dirs, $file) = File::Spec->splitpath( shift );
2538   my @dirs = File::Spec->splitdir( File::Spec->canonpath($dirs) );
2539   
2540   # Remove known exts from the base name
2541   $file =~ s/\.p(?:od|m|l)\z//i;
2542   
2543   return join( $self->manpage_separator, @dirs, $file );
2544 }
2545
2546 sub manpage_separator {
2547   return '::';
2548 }
2549
2550 # For systems that don't have 'diff' executable, should use Algorithm::Diff
2551 sub ACTION_diff {
2552   my $self = shift;
2553   $self->depends_on('build');
2554   my $local_lib = File::Spec->rel2abs('lib');
2555   my @myINC = grep {$_ ne $local_lib} @INC;
2556
2557   # The actual install destination might not be in @INC, so check there too.
2558   push @myINC, map $self->install_destination($_), qw(lib arch);
2559
2560   my @flags = @{$self->{args}{ARGV}};
2561   @flags = $self->split_like_shell($self->{args}{flags} || '') unless @flags;
2562   
2563   my $installmap = $self->install_map;
2564   delete $installmap->{read};
2565   delete $installmap->{write};
2566
2567   my $text_suffix = qr{\.(pm|pod)$};
2568
2569   while (my $localdir = each %$installmap) {
2570     my @localparts = File::Spec->splitdir($localdir);
2571     my $files = $self->rscan_dir($localdir, sub {-f});
2572     
2573     foreach my $file (@$files) {
2574       my @parts = File::Spec->splitdir($file);
2575       @parts = @parts[@localparts .. $#parts]; # Get rid of blib/lib or similar
2576       
2577       my $installed = Module::Build::ModuleInfo->find_module_by_name(
2578                         join('::', @parts), \@myINC );
2579       if (not $installed) {
2580         print "Only in lib: $file\n";
2581         next;
2582       }
2583       
2584       my $status = File::Compare::compare($installed, $file);
2585       next if $status == 0;  # Files are the same
2586       die "Can't compare $installed and $file: $!" if $status == -1;
2587       
2588       if ($file =~ $text_suffix) {
2589         $self->do_system('diff', @flags, $installed, $file);
2590       } else {
2591         print "Binary files $file and $installed differ\n";
2592       }
2593     }
2594   }
2595 }
2596
2597 sub ACTION_pure_install {
2598   shift()->depends_on('install');
2599 }
2600
2601 sub ACTION_install {
2602   my ($self) = @_;
2603   require ExtUtils::Install;
2604   $self->depends_on('build');
2605   ExtUtils::Install::install($self->install_map, !$self->quiet, 0, $self->{args}{uninst}||0);
2606 }
2607
2608 sub ACTION_fakeinstall {
2609   my ($self) = @_;
2610   require ExtUtils::Install;
2611   $self->depends_on('build');
2612   ExtUtils::Install::install($self->install_map, !$self->quiet, 1, $self->{args}{uninst}||0);
2613 }
2614
2615 sub ACTION_versioninstall {
2616   my ($self) = @_;
2617   
2618   die "You must have only.pm 0.25 or greater installed for this operation: $@\n"
2619     unless eval { require only; 'only'->VERSION(0.25); 1 };
2620   
2621   $self->depends_on('build');
2622   
2623   my %onlyargs = map {exists($self->{args}{$_}) ? ($_ => $self->{args}{$_}) : ()}
2624     qw(version versionlib);
2625   only::install::install(%onlyargs);
2626 }
2627
2628 sub ACTION_clean {
2629   my ($self) = @_;
2630   foreach my $item (map glob($_), $self->cleanup) {
2631     $self->delete_filetree($item);
2632   }
2633 }
2634
2635 sub ACTION_realclean {
2636   my ($self) = @_;
2637   $self->depends_on('clean');
2638   $self->delete_filetree($self->config_dir, $self->build_script);
2639 }
2640
2641 sub ACTION_ppd {
2642   my ($self) = @_;
2643   require Module::Build::PPMMaker;
2644   my $ppd = Module::Build::PPMMaker->new();
2645   my $file = $ppd->make_ppd(%{$self->{args}}, build => $self);
2646   $self->add_to_cleanup($file);
2647 }
2648
2649 sub ACTION_ppmdist {
2650   my ($self) = @_;
2651
2652   $self->depends_on( 'build' );
2653
2654   my $ppm = $self->ppm_name;
2655   $self->delete_filetree( $ppm );
2656   $self->log_info( "Creating $ppm\n" );
2657   $self->add_to_cleanup( $ppm, "$ppm.tar.gz" );
2658
2659   my %types = ( # translate types/dirs to those expected by ppm
2660     lib     => 'lib',
2661     arch    => 'arch',
2662     bin     => 'bin',
2663     script  => 'script',
2664     bindoc  => 'man1',
2665     libdoc  => 'man3',
2666     binhtml => undef,
2667     libhtml => undef,
2668   );
2669
2670   foreach my $type ($self->install_types) {
2671     next if exists( $types{$type} ) && !defined( $types{$type} );
2672
2673     my $dir = File::Spec->catdir( $self->blib, $type );
2674     next unless -e $dir;
2675
2676     my $files = $self->rscan_dir( $dir );
2677     foreach my $file ( @$files ) {
2678       next unless -f $file;
2679       my $rel_file =
2680         File::Spec->abs2rel( File::Spec->rel2abs( $file ),
2681                              File::Spec->rel2abs( $dir  ) );
2682       my $to_file  =
2683         File::Spec->catdir( $ppm, 'blib',
2684                             exists( $types{$type} ) ? $types{$type} : $type,
2685                             $rel_file );
2686       $self->copy_if_modified( from => $file, to => $to_file );
2687     }
2688   }
2689
2690   foreach my $type ( qw(bin lib) ) {
2691     local $self->{properties}{html_css} = 'Active.css';
2692     $self->htmlify_pods( $type, File::Spec->catdir($ppm, 'blib', 'html') );
2693   }
2694
2695   # create a tarball;
2696   # the directory tar'ed must be blib so we need to do a chdir first
2697   my $start_wd = $self->cwd;
2698   chdir( $ppm ) or die "Can't chdir to $ppm";
2699   $self->make_tarball( 'blib', File::Spec->catfile( $start_wd, $ppm ) );
2700   chdir( $start_wd ) or die "Can't chdir to $start_wd";
2701
2702   $self->depends_on( 'ppd' );
2703
2704   $self->delete_filetree( $ppm );
2705 }
2706
2707 sub ACTION_dist {
2708   my ($self) = @_;
2709   
2710   $self->depends_on('distdir');
2711   
2712   my $dist_dir = $self->dist_dir;
2713   
2714   $self->make_tarball($dist_dir);
2715   $self->delete_filetree($dist_dir);
2716 }
2717
2718 sub ACTION_distcheck {
2719   my ($self) = @_;
2720
2721   require ExtUtils::Manifest;
2722   local $^W; # ExtUtils::Manifest is not warnings clean.
2723   my ($missing, $extra) = ExtUtils::Manifest::fullcheck();
2724
2725   return unless @$missing || @$extra;
2726
2727   my $msg = "MANIFEST appears to be out of sync with the distribution\n";
2728   if ( $self->invoked_action eq 'distcheck' ) {
2729     die $msg;
2730   } else {
2731     warn $msg;
2732   }
2733 }
2734
2735 sub _add_to_manifest {
2736   my ($self, $manifest, $lines) = @_;
2737   $lines = [$lines] unless ref $lines;
2738
2739   my $existing_files = $self->_read_manifest($manifest);
2740   return unless defined( $existing_files );
2741
2742   @$lines = grep {!exists $existing_files->{$_}} @$lines
2743     or return;
2744
2745   my $mode = (stat $manifest)[2];
2746   chmod($mode | 0222, $manifest) or die "Can't make $manifest writable: $!";
2747   
2748   my $fh = IO::File->new("< $manifest") or die "Can't read $manifest: $!";
2749   my $last_line = (<$fh>)[-1] || "\n";
2750   my $has_newline = $last_line =~ /\n$/;
2751   $fh->close;
2752
2753   $fh = IO::File->new(">> $manifest") or die "Can't write to $manifest: $!";
2754   print $fh "\n" unless $has_newline;
2755   print $fh map "$_\n", @$lines;
2756   close $fh;
2757   chmod($mode, $manifest);
2758
2759   $self->log_info(map "Added to $manifest: $_\n", @$lines);
2760 }
2761
2762 sub _sign_dir {
2763   my ($self, $dir) = @_;
2764
2765   unless (eval { require Module::Signature; 1 }) {
2766     $self->log_warn("Couldn't load Module::Signature for 'distsign' action:\n $@\n");
2767     return;
2768   }
2769   
2770   # Add SIGNATURE to the MANIFEST
2771   {
2772     my $manifest = File::Spec->catfile($dir, 'MANIFEST');
2773     die "Signing a distribution requires a MANIFEST file" unless -e $manifest;
2774     $self->_add_to_manifest($manifest, "SIGNATURE    Added here by Module::Build");
2775   }
2776   
2777   # We protect the signing with an eval{} to make sure we get back to
2778   # the right directory after a signature failure.  Would be nice if
2779   # Module::Signature took a directory argument.
2780   
2781   my $start_dir = $self->cwd;
2782   chdir $dir or die "Can't chdir() to $dir: $!";
2783   eval {local $Module::Signature::Quiet = 1; Module::Signature::sign()};
2784   my @err = $@ ? ($@) : ();
2785   chdir $start_dir or push @err, "Can't chdir() back to $start_dir: $!";
2786   die join "\n", @err if @err;
2787 }
2788
2789 sub ACTION_distsign {
2790   my ($self) = @_;
2791   {
2792     local $self->{properties}{sign} = 0;  # We'll sign it ourselves
2793     $self->depends_on('distdir') unless -d $self->dist_dir;
2794   }
2795   $self->_sign_dir($self->dist_dir);
2796 }
2797
2798 sub ACTION_skipcheck {
2799   my ($self) = @_;
2800   
2801   require ExtUtils::Manifest;
2802   local $^W; # ExtUtils::Manifest is not warnings clean.
2803   ExtUtils::Manifest::skipcheck();
2804 }
2805
2806 sub ACTION_distclean {
2807   my ($self) = @_;
2808   
2809   $self->depends_on('realclean');
2810   $self->depends_on('distcheck');
2811 }
2812
2813 sub do_create_makefile_pl {
2814   my $self = shift;
2815   require Module::Build::Compat;
2816   $self->delete_filetree('Makefile.PL');
2817   $self->log_info("Creating Makefile.PL\n");
2818   Module::Build::Compat->create_makefile_pl($self->create_makefile_pl, $self, @_);
2819   $self->_add_to_manifest('MANIFEST', 'Makefile.PL');
2820 }
2821
2822 sub do_create_readme {
2823   my $self = shift;
2824   $self->delete_filetree('README');
2825
2826   my $docfile = $self->_main_docfile;
2827   unless ( $docfile ) {
2828     $self->log_warn(<<EOF);
2829 Cannot create README: can't determine which file contains documentation;
2830 Must supply either 'dist_version_from', or 'module_name' parameter.
2831 EOF
2832     return;
2833   }
2834
2835   if ( eval {require Pod::Readme; 1} ) {
2836     $self->log_info("Creating README using Pod::Readme\n");
2837
2838     my $parser = Pod::Readme->new;
2839     $parser->parse_from_file($docfile, 'README', @_);
2840
2841   } elsif ( eval {require Pod::Text; 1} ) {
2842     $self->log_info("Creating README using Pod::Text\n");
2843
2844     my $fh = IO::File->new('> README');
2845     if ( defined($fh) ) {
2846       local $^W = 0;
2847       no strict "refs";
2848
2849       # work around bug in Pod::Text 3.01, which expects
2850       # Pod::Simple::parse_file to take input and output filehandles
2851       # when it actually only takes an input filehandle
2852
2853       my $old_parse_file;
2854       $old_parse_file = \&{"Pod::Simple::parse_file"}
2855         and
2856       local *{"Pod::Simple::parse_file"} = sub {
2857         my $self = shift;
2858         $self->output_fh($_[1]) if $_[1];
2859         $self->$old_parse_file($_[0]);
2860       }
2861         if $Pod::Text::VERSION
2862           == 3.01; # Split line to avoid evil version-finder
2863
2864       Pod::Text::pod2text( $docfile, $fh );
2865
2866       $fh->close;
2867     } else {
2868       $self->log_warn(
2869         "Cannot create 'README' file: Can't open file for writing\n" );
2870       return;
2871     }
2872
2873   } else {
2874     $self->log_warn("Can't load Pod::Readme or Pod::Text to create README\n");
2875     return;
2876   }
2877
2878   $self->_add_to_manifest('MANIFEST', 'README');
2879 }
2880
2881 sub _main_docfile {
2882   my $self = shift;
2883   if ( my $pm_file = $self->dist_version_from ) {
2884     (my $pod_file = $pm_file) =~ s/.pm$/.pod/;
2885     return (-e $pod_file ? $pod_file : $pm_file);
2886   } else {
2887     return undef;
2888   }
2889 }
2890
2891 sub ACTION_distdir {
2892   my ($self) = @_;
2893
2894   $self->depends_on('distmeta');
2895
2896   my $dist_files = $self->_read_manifest('MANIFEST')
2897     or die "Can't create distdir without a MANIFEST file - run 'manifest' action first";
2898   delete $dist_files->{SIGNATURE};  # Don't copy, create a fresh one
2899   die "No files found in MANIFEST - try running 'manifest' action?\n"
2900     unless ($dist_files and keys %$dist_files);
2901   my $metafile = $self->metafile;
2902   $self->log_warn("*** Did you forget to add $metafile to the MANIFEST?\n")
2903     unless exists $dist_files->{$metafile};
2904   
2905   my $dist_dir = $self->dist_dir;
2906   $self->delete_filetree($dist_dir);
2907   $self->log_info("Creating $dist_dir\n");
2908   $self->add_to_cleanup($dist_dir);
2909   
2910   foreach my $file (keys %$dist_files) {
2911     my $new = $self->copy_if_modified(from => $file, to_dir => $dist_dir, verbose => 0);
2912     chmod +(stat $file)[2], $new
2913       or $self->log_warn("Couldn't set permissions on $new: $!");
2914   }
2915   
2916   $self->_sign_dir($dist_dir) if $self->{properties}{sign};
2917 }
2918
2919 sub ACTION_disttest {
2920   my ($self) = @_;
2921
2922   $self->depends_on('distdir');
2923
2924   my $start_dir = $self->cwd;
2925   my $dist_dir = $self->dist_dir;
2926   chdir $dist_dir or die "Cannot chdir to $dist_dir: $!";
2927   # XXX could be different names for scripts
2928
2929   $self->run_perl_script('Build.PL') # XXX Should this be run w/ --nouse-rcfile
2930       or die "Error executing 'Build.PL' in dist directory: $!";
2931   $self->run_perl_script('Build')
2932       or die "Error executing 'Build' in dist directory: $!";
2933   $self->run_perl_script('Build', [], ['test'])
2934       or die "Error executing 'Build test' in dist directory";
2935   chdir $start_dir;
2936 }
2937
2938 sub _write_default_maniskip {
2939   my $self = shift;
2940   my $file = shift || 'MANIFEST.SKIP';
2941   my $fh = IO::File->new("> $file")
2942     or die "Can't open $file: $!";
2943
2944   # This is derived from MakeMaker's default MANIFEST.SKIP file with
2945   # some new entries
2946
2947   print $fh <<'EOF';
2948 # Avoid version control files.
2949 \bRCS\b
2950 \bCVS\b
2951 ,v$
2952 \B\.svn\b
2953 \B\.cvsignore$
2954
2955 # Avoid Makemaker generated and utility files.
2956 \bMakefile$
2957 \bblib
2958 \bMakeMaker-\d
2959 \bpm_to_blib$
2960 \bblibdirs$
2961 ^MANIFEST\.SKIP$
2962
2963 # Avoid Module::Build generated and utility files.
2964 \bBuild$
2965 \bBuild.bat$
2966 \b_build
2967
2968 # Avoid Devel::Cover generated files
2969 \bcover_db
2970
2971 # Avoid temp and backup files.
2972 ~$
2973 \.tmp$
2974 \.old$
2975 \.bak$
2976 \#$
2977 \.#
2978 \.rej$
2979
2980 # Avoid OS-specific files/dirs
2981 #   Mac OSX metadata
2982 \B\.DS_Store
2983 #   Mac OSX SMB mount metadata files
2984 \B\._
2985 # Avoid archives of this distribution
2986 EOF
2987
2988   # Skip, for example, 'Module-Build-0.27.tar.gz'
2989   print $fh '\b'.$self->dist_name.'-[\d\.\_]+'."\n";
2990
2991   $fh->close();
2992 }
2993
2994 sub ACTION_manifest {
2995   my ($self) = @_;
2996
2997   my $maniskip = 'MANIFEST.SKIP';
2998   unless ( -e 'MANIFEST' || -e $maniskip ) {
2999     $self->log_warn("File '$maniskip' does not exist: Creating a default '$maniskip'\n");
3000     $self->_write_default_maniskip($maniskip);
3001   }
3002
3003   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
3004   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
3005   ExtUtils::Manifest::mkmanifest();
3006 }
3007
3008 sub dist_dir {
3009   my ($self) = @_;
3010   return "$self->{properties}{dist_name}-$self->{properties}{dist_version}";
3011 }
3012
3013 sub ppm_name {
3014   my $self = shift;
3015   return 'PPM-' . $self->dist_dir;
3016 }
3017
3018 sub _files_in {
3019   my ($self, $dir) = @_;
3020   return unless -d $dir;
3021
3022   local *DH;
3023   opendir DH, $dir or die "Can't read directory $dir: $!";
3024
3025   my @files;
3026   while (defined (my $file = readdir DH)) {
3027     my $full_path = File::Spec->catfile($dir, $file);
3028     next if -d $full_path;
3029     push @files, $full_path;
3030   }
3031   return @files;
3032 }
3033
3034 sub script_files {
3035   my $self = shift;
3036   
3037   for ($self->{properties}{script_files}) {
3038     $_ = shift if @_;
3039     next unless $_;
3040     
3041     # Always coerce into a hash
3042     return $_ if UNIVERSAL::isa($_, 'HASH');
3043     return $_ = { map {$_,1} @$_ } if UNIVERSAL::isa($_, 'ARRAY');
3044     
3045     die "'script_files' must be a hashref, arrayref, or string" if ref();
3046     
3047     return $_ = { map {$_,1} $self->_files_in( $_ ) } if -d $_;
3048     return $_ = {$_ => 1};
3049   }
3050   
3051   return $_ = { map {$_,1} $self->_files_in( File::Spec->catdir( $self->base_dir, 'bin' ) ) };
3052 }
3053 BEGIN { *scripts = \&script_files; }
3054
3055 {
3056   my %licenses =
3057     (
3058      perl => 'http://dev.perl.org/licenses/',
3059      gpl => 'http://www.opensource.org/licenses/gpl-license.php',
3060      apache => 'http://apache.org/licenses/LICENSE-2.0',
3061      artistic => 'http://opensource.org/licenses/artistic-license.php',
3062      lgpl => 'http://opensource.org/licenses/artistic-license.php',
3063      bsd => 'http://www.opensource.org/licenses/bsd-license.php',
3064      gpl => 'http://www.opensource.org/licenses/gpl-license.php',
3065      mit => 'http://opensource.org/licenses/mit-license.php',
3066      mozilla => 'http://opensource.org/licenses/mozilla1.1.php',
3067      open_source => undef,
3068      unrestricted => undef,
3069      restrictive => undef,
3070      unknown => undef,
3071     );
3072   sub valid_licenses {
3073     return \%licenses;
3074   }
3075 }
3076
3077 sub _hash_merge {
3078   my ($self, $h, $k, $v) = @_;
3079   if (ref $h->{$k} eq 'ARRAY') {
3080     push @{$h->{$k}}, ref $v ? @$v : $v;
3081   } elsif (ref $h->{$k} eq 'HASH') {
3082     $h->{$k}{$_} = $v->{$_} foreach keys %$v;
3083   } else {
3084     $h->{$k} = $v;
3085   }
3086 }
3087
3088 sub ACTION_distmeta {
3089   my ($self) = @_;
3090
3091   $self->do_create_makefile_pl if $self->create_makefile_pl;
3092   $self->do_create_readme if $self->create_readme;
3093   $self->do_create_metafile;
3094 }
3095
3096 sub do_create_metafile {
3097   my $self = shift;
3098   return if $self->{wrote_metadata};
3099   
3100   my $p = $self->{properties};
3101   my $metafile = $self->metafile;
3102   
3103   unless ($p->{license}) {
3104     $self->log_warn("No license specified, setting license = 'unknown'\n");
3105     $p->{license} = 'unknown';
3106   }
3107   unless (exists $self->valid_licenses->{ $p->{license} }) {
3108     die "Unknown license type '$p->{license}'";
3109   }
3110
3111   # If we're in the distdir, the metafile may exist and be non-writable.
3112   $self->delete_filetree($metafile);
3113   $self->log_info("Creating $metafile\n");
3114
3115   # Since we're building ourself, we have to do some special stuff
3116   # here: the ConfigData module is found in blib/lib.
3117   local @INC = @INC;
3118   if (($self->module_name || '') eq 'Module::Build') {
3119     $self->depends_on('config_data');
3120     push @INC, File::Spec->catdir($self->blib, 'lib');
3121   }
3122
3123   $self->write_metafile;
3124 }
3125
3126 sub write_metafile {
3127   my $self = shift;
3128   my $metafile = $self->metafile;
3129
3130   if ($self->_mb_feature('YAML_support')) {
3131     require YAML;
3132     require YAML::Node;
3133
3134     # We use YAML::Node to get the order nice in the YAML file.
3135     $self->prepare_metadata( my $node = YAML::Node->new({}) );
3136     
3137     # YAML API changed after version 0.30
3138     my $yaml_sub = $YAML::VERSION le '0.30' ? \&YAML::StoreFile : \&YAML::DumpFile;
3139     $self->{wrote_metadata} = $yaml_sub->($metafile, $node );
3140
3141   } else {
3142     require Module::Build::YAML;
3143     my (%node, @order_keys);
3144     $self->prepare_metadata(\%node, \@order_keys);
3145     $node{_order} = \@order_keys;
3146     &Module::Build::YAML::DumpFile($metafile, \%node);
3147     $self->{wrote_metadata} = 1;
3148   }
3149
3150   $self->_add_to_manifest('MANIFEST', $metafile);
3151 }
3152
3153 sub prepare_metadata {
3154   my ($self, $node, $keys) = @_;
3155   my $p = $self->{properties};
3156
3157   # A little helper sub
3158   my $add_node = sub {
3159     my ($name, $val) = @_;
3160     $node->{$name} = $val;
3161     push @$keys, $name if $keys;
3162   };
3163
3164   foreach (qw(dist_name dist_version dist_author dist_abstract license)) {
3165     (my $name = $_) =~ s/^dist_//;
3166     $add_node->($name, $self->$_());
3167     die "ERROR: Missing required field '$_' for META.yml\n"
3168       unless defined($node->{$name}) && length($node->{$name});
3169   }
3170
3171   if (defined( $self->license ) &&
3172       defined( my $url = $self->valid_licenses->{ $self->license } )) {
3173     $node->{resources}{license} = $url;
3174   }
3175
3176   foreach ( @{$self->prereq_action_types} ) {
3177     if (exists $p->{$_} and keys %{ $p->{$_} }) {
3178       $add_node->($_, $p->{$_});
3179     }
3180   }
3181
3182   if (exists $p->{dynamic_config}) {
3183     $add_node->('dynamic_config', $p->{dynamic_config});
3184   }
3185   my $pkgs = eval { $self->find_dist_packages };
3186   if ($@) {
3187     $self->log_warn("WARNING: Possible missing or corrupt 'MANIFEST' file.\n" .
3188                     "Nothing to enter for 'provides' field in META.yml\n");
3189   } else {
3190     $node->{provides} = $pkgs if %$pkgs;
3191   }
3192 ;
3193   if (exists $p->{no_index}) {
3194     $add_node->('no_index', $p->{no_index});
3195   }
3196
3197   $add_node->('generated_by', "Module::Build version $Module::Build::VERSION");
3198
3199   $add_node->('meta-spec', 
3200               {version => '1.2',
3201                url     => 'http://module-build.sourceforge.net/META-spec-v1.2.html',
3202               });
3203
3204   while (my($k, $v) = each %{$self->meta_add}) {
3205     $add_node->($k, $v);
3206   }
3207
3208   while (my($k, $v) = each %{$self->meta_merge}) {
3209     $self->_hash_merge($node, $k, $v);
3210   }
3211
3212   return $node;
3213 }
3214
3215 sub _read_manifest {
3216   my ($self, $file) = @_;
3217   return undef unless -e $file;
3218
3219   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
3220   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
3221   return scalar ExtUtils::Manifest::maniread($file);
3222 }
3223
3224 sub find_dist_packages {
3225   my $self = shift;
3226
3227   # Only packages in .pm files are candidates for inclusion here.
3228   # Only include things in the MANIFEST, not things in developer's
3229   # private stock.
3230
3231   my $manifest = $self->_read_manifest('MANIFEST')
3232     or die "Can't find dist packages without a MANIFEST file - run 'manifest' action first";
3233
3234   # Localize
3235   my %dist_files = map { $self->localize_file_path($_) => $_ }
3236                        keys %$manifest;
3237
3238   my @pm_files = grep {exists $dist_files{$_}} keys %{ $self->find_pm_files };
3239
3240   # First, we enumerate all packages & versions,
3241   # seperating into primary & alternative candidates
3242   my( %prime, %alt );
3243   foreach my $file (@pm_files) {
3244     next if $dist_files{$file} =~ m{^t/};  # Skip things in t/
3245
3246     my @path = split( /\//, $dist_files{$file} );
3247     (my $prime_package = join( '::', @path[1..$#path] )) =~ s/\.pm$//;
3248
3249     my $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
3250
3251     foreach my $package ( $pm_info->packages_inside ) {
3252       next if $package eq 'main';  # main can appear numerous times, ignore
3253       next if grep /^_/, split( /::/, $package ); # private package, ignore
3254
3255       my $version = $pm_info->version( $package );
3256
3257       if ( $package eq $prime_package ) {
3258         if ( exists( $prime{$package} ) ) {
3259           # M::B::ModuleInfo will handle this conflict
3260           die "Unexpected conflict in '$package'; multiple versions found.\n";
3261         } else {
3262           $prime{$package}{file} = $dist_files{$file};
3263           $prime{$package}{version} = $version if defined( $version );
3264         }
3265       } else {
3266         push( @{$alt{$package}}, {
3267                                   file    => $dist_files{$file},
3268                                   version => $version,
3269                                  } );
3270       }
3271     }
3272   }
3273
3274   # Then we iterate over all the packages found above, identifying conflicts
3275   # and selecting the "best" candidate for recording the file & version
3276   # for each package.
3277   foreach my $package ( keys( %alt ) ) {
3278     my $result = $self->_resolve_module_versions( $alt{$package} );
3279
3280     if ( exists( $prime{$package} ) ) { # primary package selected
3281
3282       if ( $result->{err} ) {
3283         # Use the selected primary package, but there are conflicting
3284         # errors amoung multiple alternative packages that need to be
3285         # reported
3286         $self->log_warn(
3287           "Found conflicting versions for package '$package'\n" .
3288           "  $prime{$package}{file} ($prime{$package}{version})\n" .
3289           $result->{err}
3290         );
3291
3292       } elsif ( defined( $result->{version} ) ) {
3293         # There is a primary package selected, and exactly one
3294         # alternative package
3295
3296         if ( exists( $prime{$package}{version} ) &&
3297              defined( $prime{$package}{version} ) ) {
3298           # Unless the version of the primary package agrees with the
3299           # version of the alternative package, report a conflict
3300           if ( $self->compare_versions( $prime{$package}{version}, '!=',
3301                                         $result->{version} ) ) {
3302             $self->log_warn(
3303               "Found conflicting versions for package '$package'\n" .
3304               "  $prime{$package}{file} ($prime{$package}{version})\n" .
3305               "  $result->{file} ($result->{version})\n"
3306             );
3307           }
3308
3309         } else {
3310           # The prime package selected has no version so, we choose to
3311           # use any alternative package that does have a version
3312           $prime{$package}{file}    = $result->{file};
3313           $prime{$package}{version} = $result->{version};
3314         }
3315
3316       } else {
3317         # no alt package found with a version, but we have a prime
3318         # package so we use it whether it has a version or not
3319       }
3320
3321     } else { # No primary package was selected, use the best alternative
3322
3323       if ( $result->{err} ) {
3324         $self->log_warn(
3325           "Found conflicting versions for package '$package'\n" .
3326           $result->{err}
3327         );
3328       }
3329
3330       # Despite possible conflicting versions, we choose to record
3331       # something rather than nothing
3332       $prime{$package}{file}    = $result->{file};
3333       $prime{$package}{version} = $result->{version}
3334           if defined( $result->{version} );
3335     }
3336   }
3337
3338   return \%prime;
3339 }
3340
3341 # seperate out some of the conflict resolution logic from
3342 # $self->find_dist_packages(), above, into a helper function.
3343 #
3344 sub _resolve_module_versions {
3345   my $self = shift;
3346
3347   my $packages = shift;
3348
3349   my( $file, $version );
3350   my $err = '';
3351     foreach my $p ( @$packages ) {
3352       if ( defined( $p->{version} ) ) {
3353         if ( defined( $version ) ) {
3354           if ( $self->compare_versions( $version, '!=', $p->{version} ) ) {
3355             $err .= "  $p->{file} ($p->{version})\n";
3356           } else {
3357             # same version declared multiple times, ignore
3358           }
3359         } else {
3360           $file    = $p->{file};
3361           $version = $p->{version};
3362         }
3363       }
3364       $file ||= $p->{file} if defined( $p->{file} );
3365     }
3366
3367   if ( $err ) {
3368     $err = "  $file ($version)\n" . $err;
3369   }
3370
3371   my %result = (
3372     file    => $file,
3373     version => $version,
3374     err     => $err
3375   );
3376
3377   return \%result;
3378 }
3379
3380 sub make_tarball {
3381   my ($self, $dir, $file) = @_;
3382   $file ||= $dir;
3383   
3384   $self->log_info("Creating $file.tar.gz\n");
3385   
3386   if ($self->{args}{tar}) {
3387     my $tar_flags = $self->verbose ? 'cvf' : 'cf';
3388     $self->do_system($self->split_like_shell($self->{args}{tar}), $tar_flags, "$file.tar", $dir);
3389     $self->do_system($self->split_like_shell($self->{args}{gzip}), "$file.tar") if $self->{args}{gzip};
3390   } else {
3391     require Archive::Tar;
3392     # Archive::Tar versions >= 1.09 use the following to enable a compatibility
3393     # hack so that the resulting archive is compatible with older clients.
3394     $Archive::Tar::DO_NOT_USE_PREFIX = 0;
3395     my $files = $self->rscan_dir($dir);
3396     Archive::Tar->create_archive("$file.tar.gz", 1, @$files);
3397   }
3398 }
3399
3400 sub install_base_relpaths {
3401   # Usage: install_base_relpaths('lib')  or install_base_relpaths();
3402   my $self = shift;
3403   my $map = $self->{properties}{install_base_relpaths};
3404   return $map unless @_;
3405   
3406   my $type = shift;
3407   return unless exists $map->{$type};
3408   return File::Spec->catdir(@{$map->{$type}});
3409 }
3410
3411
3412 # Translated from ExtUtils::MM_Any::init_INSTALL_from_PREFIX
3413 sub prefix_relative {
3414   my ($self, $type) = @_;
3415   my $installdirs = $self->installdirs;
3416
3417   my $relpath = $self->install_sets($installdirs)->{$type};
3418
3419   return $self->_prefixify($relpath,
3420                            $self->original_prefix($installdirs),
3421                            $type,
3422                           );
3423 }
3424
3425
3426 # Defaults to use in case the config install paths cannot be prefixified.
3427 sub prefix_relpaths {
3428   # Usage: prefix_relpaths('site', 'lib')  or prefix_relpaths('site');
3429   my $self = shift;
3430   my $installdirs = shift || $self->installdirs;
3431   my $map = $self->{properties}{prefix_relpaths}{$installdirs};
3432   return $map unless @_;
3433   
3434   my $type = shift;
3435   return unless exists $map->{$type};
3436   return File::Spec->catdir(@{$map->{$type}});
3437 }
3438
3439
3440 # Translated from ExtUtils::MM_Unix::prefixify()
3441 sub _prefixify {
3442   my($self, $path, $sprefix, $type) = @_;
3443
3444   my $rprefix = $self->prefix;
3445   $rprefix .= '/' if $sprefix =~ m|/$|;
3446
3447   $self->log_verbose("  prefixify $path from $sprefix to $rprefix\n")
3448     if defined( $path ) && length( $path );
3449
3450   if( !defined( $path ) || ( length( $path ) == 0 ) ) {
3451     $self->log_verbose("  no path to prefixify, falling back to default.\n");
3452     return $self->_prefixify_default( $type, $rprefix );
3453   } elsif( !File::Spec->file_name_is_absolute($path) ) {
3454     $self->log_verbose("    path is relative, not prefixifying.\n");
3455   } elsif( $sprefix eq $rprefix ) {
3456     $self->log_verbose("  no new prefix.\n");
3457   } elsif( $path !~ s{^\Q$sprefix\E\b}{}s ) {
3458     $self->log_verbose("    cannot prefixify, falling back to default.\n");
3459     return $self->_prefixify_default( $type, $rprefix );
3460   }
3461
3462   $self->log_verbose("    now $path in $rprefix\n");
3463
3464   return $path;
3465 }
3466
3467 sub _prefixify_default {
3468   my $self = shift;
3469   my $type = shift;
3470   my $rprefix = shift;
3471
3472   my $default = $self->prefix_relpaths($self->installdirs, $type);
3473   if( !$default ) {
3474     $self->log_verbose("    no default install location for type '$type', using prefix '$rprefix'.\n");
3475     return $rprefix;
3476   } else {
3477     return $default;
3478   }
3479 }
3480
3481 sub install_destination {
3482   my ($self, $type) = @_;
3483
3484   return $self->install_path($type) if $self->install_path($type);
3485
3486   if ( $self->install_base ) {
3487     my $relpath = $self->install_base_relpaths($type);
3488     return $relpath ? File::Spec->catdir($self->install_base, $relpath) : undef;
3489   }
3490
3491   if ( $self->prefix ) {
3492     my $relpath = $self->prefix_relative($type);
3493     return $relpath ? File::Spec->catdir($self->prefix, $relpath) : undef;
3494   }
3495
3496   return $self->install_sets($self->installdirs)->{$type};
3497 }
3498
3499 sub install_types {
3500   my $self = shift;
3501   my %types = (%{$self->install_path}, %{ $self->install_sets($self->installdirs) });
3502   return sort keys %types;
3503 }
3504
3505 sub install_map {
3506   my ($self, $blib) = @_;
3507   $blib ||= $self->blib;
3508
3509   my( %map, @skipping );
3510   foreach my $type ($self->install_types) {
3511     my $localdir = File::Spec->catdir( $blib, $type );
3512     next unless -e $localdir;
3513
3514     if (my $dest = $self->install_destination($type)) {
3515       $map{$localdir} = $dest;
3516     } else {
3517       push( @skipping, $type );
3518     }
3519   }
3520
3521   $self->log_warn(
3522     "WARNING: Can't figure out install path for types: @skipping\n" .
3523     "Files will not be installed.\n"
3524   ) if @skipping;
3525
3526   # Write the packlist into the same place as ExtUtils::MakeMaker.
3527   if ($self->create_packlist and my $module_name = $self->module_name) {
3528     my $archdir = $self->install_destination('arch');
3529     my @ext = split /::/, $module_name;
3530     $map{write} = File::Spec->catdir($archdir, 'auto', @ext, '.packlist');
3531   }
3532
3533   # Handle destdir
3534   if (length(my $destdir = $self->destdir || '')) {
3535     foreach (keys %map) {
3536       # Need to remove volume from $map{$_} using splitpath, or else
3537       # we'll create something crazy like C:\Foo\Bar\E:\Baz\Quux
3538       my ($volume, $path) = File::Spec->splitpath( $map{$_}, 1 );
3539       $map{$_} = File::Spec->catdir($destdir, $path);
3540     }
3541   }
3542   
3543   $map{read} = '';  # To keep ExtUtils::Install quiet
3544
3545   return \%map;
3546 }
3547
3548 sub depends_on {
3549   my $self = shift;
3550   foreach my $action (@_) {
3551     $self->_call_action($action);
3552   }
3553 }
3554
3555 sub rscan_dir {
3556   my ($self, $dir, $pattern) = @_;
3557   my @result;
3558   local $_; # find() can overwrite $_, so protect ourselves
3559   my $subr = !$pattern ? sub {push @result, $File::Find::name} :
3560              !ref($pattern) || (ref $pattern eq 'Regexp') ? sub {push @result, $File::Find::name if /$pattern/} :
3561              ref($pattern) eq 'CODE' ? sub {push @result, $File::Find::name if $pattern->()} :
3562              die "Unknown pattern type";
3563   
3564   File::Find::find({wanted => $subr, no_chdir => 1}, $dir);
3565   return \@result;
3566 }
3567
3568 sub delete_filetree {
3569   my $self = shift;
3570   my $deleted = 0;
3571   foreach (@_) {
3572     next unless -e $_;
3573     $self->log_info("Deleting $_\n");
3574     File::Path::rmtree($_, 0, 0);
3575     die "Couldn't remove '$_': $!\n" if -e $_;
3576     $deleted++;
3577   }
3578   return $deleted;
3579 }
3580
3581 sub autosplit_file {
3582   my ($self, $file, $to) = @_;
3583   require AutoSplit;
3584   my $dir = File::Spec->catdir($to, 'lib', 'auto');
3585   AutoSplit::autosplit($file, $dir);
3586 }
3587
3588 sub _cbuilder {
3589   # Returns a CBuilder object
3590
3591   my $self = shift;
3592   my $p = $self->{properties};
3593   return $p->{_cbuilder} if $p->{_cbuilder};
3594   return unless $self->_mb_feature('C_support');
3595
3596   require ExtUtils::CBuilder;
3597   return $p->{_cbuilder} = ExtUtils::CBuilder->new(config => $self->config);
3598 }
3599
3600 sub have_c_compiler {
3601   my ($self) = @_;
3602   
3603   my $p = $self->{properties};
3604   return $p->{have_compiler} if defined $p->{have_compiler};
3605   
3606   $self->log_verbose("Checking if compiler tools configured... ");
3607   my $b = $self->_cbuilder;
3608   my $have = $b && $b->have_compiler;
3609   $self->log_verbose($have ? "ok.\n" : "failed.\n");
3610   return $p->{have_compiler} = $have;
3611 }
3612
3613 sub compile_c {
3614   my ($self, $file, %args) = @_;
3615   my $b = $self->_cbuilder
3616     or die "Module::Build is not configured with C_support";
3617
3618   my $obj_file = $b->object_file($file);
3619   $self->add_to_cleanup($obj_file);
3620   return $obj_file if $self->up_to_date($file, $obj_file);
3621
3622   $b->compile(source => $file,
3623               defines => $args{defines},
3624               object_file => $obj_file,
3625               include_dirs => $self->include_dirs,
3626               extra_compiler_flags => $self->extra_compiler_flags,
3627              );
3628
3629   return $obj_file;
3630 }
3631
3632 sub link_c {
3633   my ($self, $to, $file_base) = @_;
3634   my $p = $self->{properties}; # For convenience
3635
3636   my $spec = $self->_infer_xs_spec($file_base);
3637
3638   $self->add_to_cleanup($spec->{lib_file});
3639
3640   my $objects = $p->{objects} || [];
3641
3642   return $spec->{lib_file}
3643     if $self->up_to_date([$spec->{obj_file}, @$objects],
3644                          $spec->{lib_file});
3645
3646   my $module_name = $self->module_name;
3647   $module_name  ||= $spec->{module_name};
3648
3649   my $b = $self->_cbuilder
3650     or die "Module::Build is not configured with C_support";
3651   $b->link(
3652     module_name => $module_name,
3653     objects     => [$spec->{obj_file}, @$objects],
3654     lib_file    => $spec->{lib_file},
3655     extra_linker_flags => $p->{extra_linker_flags} );
3656
3657   return $spec->{lib_file};
3658 }
3659
3660 sub compile_xs {
3661   my ($self, $file, %args) = @_;
3662   
3663   $self->log_info("$file -> $args{outfile}\n");
3664
3665   if (eval {require ExtUtils::ParseXS; 1}) {
3666     
3667     ExtUtils::ParseXS::process_file(
3668                                     filename => $file,
3669                                     prototypes => 0,
3670                                     output => $args{outfile},
3671                                    );
3672   } else {
3673     # Ok, I give up.  Just use backticks.
3674     
3675     my $xsubpp = Module::Build::ModuleInfo->find_module_by_name('ExtUtils::xsubpp')
3676       or die "Can't find ExtUtils::xsubpp in INC (@INC)";
3677     
3678     my @typemaps;
3679     push @typemaps, Module::Build::ModuleInfo->find_module_by_name('ExtUtils::typemap', \@INC);
3680     my $lib_typemap = Module::Build::ModuleInfo->find_module_by_name('typemap', ['lib']);
3681     if (defined $lib_typemap and -e $lib_typemap) {
3682       push @typemaps, 'typemap';
3683     }
3684     @typemaps = map {+'-typemap', $_} @typemaps;
3685
3686     my $cf = $self->config;
3687     my $perl = $self->{properties}{perl};
3688     
3689     my @command = ($perl, "-I$cf->{installarchlib}", "-I$cf->{installprivlib}", $xsubpp, '-noprototypes',
3690                    @typemaps, $file);
3691     
3692     $self->log_info("@command\n");
3693     my $fh = IO::File->new("> $args{outfile}") or die "Couldn't write $args{outfile}: $!";
3694     print {$fh} $self->_backticks(@command);
3695     close $fh;
3696   }
3697 }
3698
3699 sub split_like_shell {
3700   my ($self, $string) = @_;
3701   
3702   return () unless defined($string);
3703   return @$string if UNIVERSAL::isa($string, 'ARRAY');
3704   $string =~ s/^\s+|\s+$//g;
3705   return () unless length($string);
3706   
3707   return Text::ParseWords::shellwords($string);
3708 }
3709
3710 sub run_perl_script {
3711   my ($self, $script, $preargs, $postargs) = @_;
3712   foreach ($preargs, $postargs) {
3713     $_ = [ $self->split_like_shell($_) ] unless ref();
3714   }
3715   return $self->run_perl_command([@$preargs, $script, @$postargs]);
3716 }
3717
3718 sub run_perl_command {
3719   # XXX Maybe we should accept @args instead of $args?  Must resolve
3720   # this before documenting.
3721   my ($self, $args) = @_;
3722   $args = [ $self->split_like_shell($args) ] unless ref($args);
3723   $args = [ split(/\s+/, $self->_quote_args($args)) ] if $self->os_type eq 'VMS';
3724   my $perl = ref($self) ? $self->perl : $self->find_perl_interpreter;
3725
3726   # Make sure our local additions to @INC are propagated to the subprocess
3727   my $c = ref $self ? $self->config : \%Config::Config;
3728   local $ENV{PERL5LIB} = join $c->{path_sep}, $self->_added_to_INC;
3729
3730   return $self->do_system($perl, @$args);
3731 }
3732
3733 # Infer various data from the path of the input filename
3734 # that is needed to create output files.
3735 # The input filename is expected to be of the form:
3736 #   lib/Module/Name.ext or Module/Name.ext
3737 sub _infer_xs_spec {
3738   my $self = shift;
3739   my $file = shift;
3740
3741   my $cf = $self->{config};
3742
3743   my %spec;
3744
3745   my( $v, $d, $f ) = File::Spec->splitpath( $file );
3746   my @d = File::Spec->splitdir( $d );
3747   (my $file_base = $f) =~ s/\.[^.]+$//i;
3748
3749   $spec{base_name} = $file_base;
3750
3751   $spec{src_dir} = File::Spec->catpath( $v, $d, '' );
3752
3753   # the module name
3754   shift( @d ) while @d && ($d[0] eq 'lib' || $d[0] eq '');
3755   pop( @d ) while @d && $d[-1] eq '';
3756   $spec{module_name} = join( '::', (@d, $file_base) );
3757
3758   $spec{archdir} = File::Spec->catdir($self->blib, 'arch', 'auto',
3759                                       @d, $file_base);
3760
3761   $spec{bs_file} = File::Spec->catfile($spec{archdir}, "${file_base}.bs");
3762
3763   $spec{lib_file} = File::Spec->catfile($spec{archdir},
3764                                         "${file_base}.$cf->{dlext}");
3765
3766   $spec{c_file} = File::Spec->catfile( $spec{src_dir},
3767                                        "${file_base}.c" );
3768
3769   $spec{obj_file} = File::Spec->catfile( $spec{src_dir},
3770                                          "${file_base}$cf->{obj_ext}" );
3771
3772   return \%spec;
3773 }
3774
3775 sub process_xs {
3776   my ($self, $file) = @_;
3777   my $cf = $self->config; # For convenience
3778
3779   my $spec = $self->_infer_xs_spec($file);
3780
3781   # File name, minus the suffix
3782   (my $file_base = $file) =~ s/\.[^.]+$//;
3783
3784   # .xs -> .c
3785   $self->add_to_cleanup($spec->{c_file});
3786
3787   unless ($self->up_to_date($file, $spec->{c_file})) {
3788     $self->compile_xs($file, outfile => $spec->{c_file});
3789   }
3790
3791   # .c -> .o
3792   my $v = $self->dist_version;
3793   $self->compile_c($spec->{c_file},
3794                    defines => {VERSION => qq{"$v"}, XS_VERSION => qq{"$v"}});
3795
3796   # archdir
3797   File::Path::mkpath($spec->{archdir}, 0, 0777) unless -d $spec->{archdir};
3798
3799   # .xs -> .bs
3800   $self->add_to_cleanup($spec->{bs_file});
3801   unless ($self->up_to_date($file, $spec->{bs_file})) {
3802     require ExtUtils::Mkbootstrap;
3803     $self->log_info("ExtUtils::Mkbootstrap::Mkbootstrap('$spec->{bs_file}')\n");
3804     ExtUtils::Mkbootstrap::Mkbootstrap($spec->{bs_file});  # Original had $BSLOADLIBS - what's that?
3805     {my $fh = IO::File->new(">> $spec->{bs_file}")}  # create
3806     utime((time)x2, $spec->{bs_file});  # touch
3807   }
3808
3809   # .o -> .(a|bundle)
3810   $self->link_c($spec->{archdir}, $file_base);
3811 }
3812
3813 sub do_system {
3814   my ($self, @cmd) = @_;
3815   $self->log_info("@cmd\n");
3816   return !system(@cmd);
3817 }
3818
3819 sub copy_if_modified {
3820   my $self = shift;
3821   my %args = (@_ > 3
3822               ? ( @_ )
3823               : ( from => shift, to_dir => shift, flatten => shift )
3824              );
3825   $args{verbose} = !$self->quiet
3826     unless exists $args{verbose};
3827   
3828   my $file = $args{from};
3829   unless (defined $file and length $file) {
3830     die "No 'from' parameter given to copy_if_modified";
3831   }
3832   
3833   my $to_path;
3834   if (defined $args{to} and length $args{to}) {
3835     $to_path = $args{to};
3836   } elsif (defined $args{to_dir} and length $args{to_dir}) {
3837     $to_path = File::Spec->catfile( $args{to_dir}, $args{flatten}
3838                                     ? File::Basename::basename($file)
3839                                     : $file );
3840   } else {
3841     die "No 'to' or 'to_dir' parameter given to copy_if_modified";
3842   }
3843   
3844   return if $self->up_to_date($file, $to_path); # Already fresh
3845   
3846   # Create parent directories
3847   File::Path::mkpath(File::Basename::dirname($to_path), 0, 0777);
3848   
3849   $self->log_info("$file -> $to_path\n") if $args{verbose};
3850   File::Copy::copy($file, $to_path) or die "Can't copy('$file', '$to_path'): $!";
3851   return $to_path;
3852 }
3853
3854 sub up_to_date {
3855   my ($self, $source, $derived) = @_;
3856   $source  = [$source]  unless ref $source;
3857   $derived = [$derived] unless ref $derived;
3858
3859   return 0 if grep {not -e} @$derived;
3860
3861   my $most_recent_source = time / (24*60*60);
3862   foreach my $file (@$source) {
3863     unless (-e $file) {
3864       $self->log_warn("Can't find source file $file for up-to-date check");
3865       next;
3866     }
3867     $most_recent_source = -M _ if -M _ < $most_recent_source;
3868   }
3869   
3870   foreach my $derived (@$derived) {
3871     return 0 if -M $derived > $most_recent_source;
3872   }
3873   return 1;
3874 }
3875
3876 sub dir_contains {
3877   my ($self, $first, $second) = @_;
3878   # File::Spec doesn't have an easy way to check whether one directory
3879   # is inside another, unfortunately.
3880   
3881   ($first, $second) = map File::Spec->canonpath($_), ($first, $second);
3882   my @first_dirs = File::Spec->splitdir($first);
3883   my @second_dirs = File::Spec->splitdir($second);
3884
3885   return 0 if @second_dirs < @first_dirs;
3886   
3887   my $is_same = ( File::Spec->case_tolerant
3888                   ? sub {lc(shift()) eq lc(shift())}
3889                   : sub {shift() eq shift()} );
3890   
3891   while (@first_dirs) {
3892     return 0 unless $is_same->(shift @first_dirs, shift @second_dirs);
3893   }
3894   
3895   return 1;
3896 }
3897
3898 1;
3899 __END__
3900
3901
3902 =head1 NAME
3903
3904 Module::Build::Base - Default methods for Module::Build
3905
3906 =head1 SYNOPSIS
3907
3908   Please see the Module::Build documentation.
3909
3910 =head1 DESCRIPTION
3911
3912 The C<Module::Build::Base> module defines the core functionality of
3913 C<Module::Build>.  Its methods may be overridden by any of the
3914 platform-dependent modules in the C<Module::Build::Platform::>
3915 namespace, but the intention here is to make this base module as
3916 platform-neutral as possible.  Nicely enough, Perl has several core
3917 tools available in the C<File::> namespace for doing this, so the task
3918 isn't very difficult.
3919
3920 Please see the C<Module::Build> documentation for more details.
3921
3922 =head1 AUTHOR
3923
3924 Ken Williams <ken@cpan.org>
3925
3926 =head1 COPYRIGHT
3927
3928 Copyright (c) 2001-2005 Ken Williams.  All rights reserved.
3929
3930 This library is free software; you can redistribute it and/or
3931 modify it under the same terms as Perl itself.
3932
3933 =head1 SEE ALSO
3934
3935 perl(1), Module::Build(3)
3936
3937 =cut