t/porting/FindExt.t

   1 #!../miniperl -w
   2
   3 BEGIN {
   4     @INC = qw(../win32 ../lib);
   5     require './test.pl';
   6     skip_all('FindExt not portable')
   7         if $^O eq 'VMS';
   8 }
   9 use strict;
  10 use Config;
  11
  12 # Test that Win32/FindExt.pm is consistent with Configure in determining the
  13 # types of extensions.
  14
  15 if ($^O eq "MSWin32" && !defined $ENV{PERL_STATIC_EXT}) {
  16     skip_all "PERL_STATIC_EXT must be set to the list of static extensions";
  17 }
  18
  19 unless (defined $Config{usedl}) {
  20     skip_all "FindExt just plain broken for static perl.";
  21 }
  22
  23 plan tests => 12;
  24 use FindExt;
  25
  26 FindExt::apply_config(\%Config);
  27 FindExt::scan_ext('../cpan');
  28 FindExt::scan_ext('../dist');
  29 FindExt::scan_ext('../ext');
  30 FindExt::set_static_extensions(split ' ', $ENV{PERL_STATIC_EXT}) if $^O eq "MSWin32";
  31 FindExt::set_static_extensions(split ' ', $Config{static_ext}) unless $^O eq "MSWin32";
  32
  33 # Config.pm and FindExt.pm make different choices about what should be built
  34 my @config_built;
  35 my @found_built;
  36 {
  37     foreach my $type (qw(static dynamic nonxs)) {
  38         push @found_built, eval "FindExt::${type}_ext()";
  39         push @config_built, split ' ', $Config{"${type}_ext"};
  40     }
  41 }
  42 @config_built = sort @config_built;
  43 @found_built = sort @found_built;
  44
  45 foreach (['dynamic_ext',
  46           [FindExt::dynamic_ext()], $Config{dynamic_ext}],
  47          ['static_ext',
  48           [FindExt::static_ext()], $Config{static_ext}],
  49          ['nonxs_ext',
  50           [FindExt::nonxs_ext()], $Config{nonxs_ext}],
  51          ['known_extensions',
  52           [FindExt::known_extensions()], $Config{known_extensions}],
  53          ['"config" dynamic + static + nonxs',
  54           \@config_built, $Config{extensions}],
  55          ['"found" dynamic + static + nonxs',
  56           \@found_built, join " ", FindExt::extensions()],
  57         ) {
  58     my ($type, $found, $config) = @$_;
  59     my @config = sort split ' ', $config;
  60     is (scalar @$found, scalar @config,
  61         "We find the same number of $type");
  62     is ("@$found", "@config", "We find the same list of $type");
  63 }
  64
  65 # Local variables:
  66 # cperl-indent-level: 4
  67 # indent-tabs-mode: nil
  68 # End:
  69 #
  70 # ex: set ts=8 sts=4 sw=4 et: