This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
a1c9f3c5975cb9f556096f23502033ecadc80696
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 my $start_time;
12 BEGIN { # Get the time the script started running; do it at compilation to
13         # get it as close as possible
14     $start_time= time;
15 }
16
17 require 5.010_001;
18 use strict;
19 use warnings;
20 use Carp;
21 use Config;
22 use File::Find;
23 use File::Path;
24 use File::Spec;
25 use Text::Tabs;
26 use re "/aa";
27 use feature 'state';
28
29 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
30 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
31
32 sub NON_ASCII_PLATFORM { ord("A") != 65 }
33
34 ##########################################################################
35 #
36 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
37 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
38 # a pod file and .t files, depending on option parameters.
39 #
40 # The structure of this file is:
41 #   First these introductory comments; then
42 #   code needed for everywhere, such as debugging stuff; then
43 #   code to handle input parameters; then
44 #   data structures likely to be of external interest (some of which depend on
45 #       the input parameters, so follows them; then
46 #   more data structures and subroutine and package (class) definitions; then
47 #   the small actual loop to process the input files and finish up; then
48 #   a __DATA__ section, for the .t tests
49 #
50 # This program works on all releases of Unicode so far.  The outputs have been
51 # scrutinized most intently for release 5.1.  The others have been checked for
52 # somewhat more than just sanity.  It can handle all non-provisional Unicode
53 # character properties in those releases.
54 #
55 # This program is mostly about Unicode character (or code point) properties.
56 # A property describes some attribute or quality of a code point, like if it
57 # is lowercase or not, its name, what version of Unicode it was first defined
58 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
59 # possibilities by making all properties into mappings from each code point
60 # into some corresponding value.  In the case of it being lowercase or not,
61 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
62 # property maps each Unicode code point to a single value, called a "property
63 # value".  (Some more recently defined properties, map a code point to a set
64 # of values.)
65 #
66 # When using a property in a regular expression, what is desired isn't the
67 # mapping of the code point to its property's value, but the reverse (or the
68 # mathematical "inverse relation"): starting with the property value, "Does a
69 # code point map to it?"  These are written in a "compound" form:
70 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
71 # files containing the lists of code points that map to each such regular
72 # expression property value, one file per list
73 #
74 # There is also a single form shortcut that Perl adds for many of the commonly
75 # used properties.  This happens for all binary properties, plus script,
76 # general_category, and block properties.
77 #
78 # Thus the outputs of this program are files.  There are map files, mostly in
79 # the 'To' directory; and there are list files for use in regular expression
80 # matching, all in subdirectories of the 'lib' directory, with each
81 # subdirectory being named for the property that the lists in it are for.
82 # Bookkeeping, test, and documentation files are also generated.
83
84 my $matches_directory = 'lib';   # Where match (\p{}) files go.
85 my $map_directory = 'To';        # Where map files go.
86
87 # DATA STRUCTURES
88 #
89 # The major data structures of this program are Property, of course, but also
90 # Table.  There are two kinds of tables, very similar to each other.
91 # "Match_Table" is the data structure giving the list of code points that have
92 # a particular property value, mentioned above.  There is also a "Map_Table"
93 # data structure which gives the property's mapping from code point to value.
94 # There are two structures because the match tables need to be combined in
95 # various ways, such as constructing unions, intersections, complements, etc.,
96 # and the map ones don't.  And there would be problems, perhaps subtle, if
97 # a map table were inadvertently operated on in some of those ways.
98 # The use of separate classes with operations defined on one but not the other
99 # prevents accidentally confusing the two.
100 #
101 # At the heart of each table's data structure is a "Range_List", which is just
102 # an ordered list of "Ranges", plus ancillary information, and methods to
103 # operate on them.  A Range is a compact way to store property information.
104 # Each range has a starting code point, an ending code point, and a value that
105 # is meant to apply to all the code points between the two end points,
106 # inclusive.  For a map table, this value is the property value for those
107 # code points.  Two such ranges could be written like this:
108 #   0x41 .. 0x5A, 'Upper',
109 #   0x61 .. 0x7A, 'Lower'
110 #
111 # Each range also has a type used as a convenience to classify the values.
112 # Most ranges in this program will be Type 0, or normal, but there are some
113 # ranges that have a non-zero type.  These are used only in map tables, and
114 # are for mappings that don't fit into the normal scheme of things.  Mappings
115 # that require a hash entry to communicate with utf8.c are one example;
116 # another example is mappings for charnames.pm to use which indicate a name
117 # that is algorithmically determinable from its code point (and the reverse).
118 # These are used to significantly compact these tables, instead of listing
119 # each one of the tens of thousands individually.
120 #
121 # In a match table, the value of a range is irrelevant (and hence the type as
122 # well, which will always be 0), and arbitrarily set to the null string.
123 # Using the example above, there would be two match tables for those two
124 # entries, one named Upper would contain the 0x41..0x5A range, and the other
125 # named Lower would contain 0x61..0x7A.
126 #
127 # Actually, there are two types of range lists, "Range_Map" is the one
128 # associated with map tables, and "Range_List" with match tables.
129 # Again, this is so that methods can be defined on one and not the others so
130 # as to prevent operating on them in incorrect ways.
131 #
132 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
133 # in the perl core.  All tables could in theory be written, but some are
134 # suppressed because there is no current practical use for them.  It is easy
135 # to change which get written by changing various lists that are near the top
136 # of the actual code in this file.  The table data structures contain enough
137 # ancillary information to allow them to be treated as separate entities for
138 # writing, such as the path to each one's file.  There is a heading in each
139 # map table that gives the format of its entries, and what the map is for all
140 # the code points missing from it.  (This allows tables to be more compact.)
141 #
142 # The Property data structure contains one or more tables.  All properties
143 # contain a map table (except the $perl property which is a
144 # pseudo-property containing only match tables), and any properties that
145 # are usable in regular expression matches also contain various matching
146 # tables, one for each value the property can have.  A binary property can
147 # have two values, True and False (or Y and N, which are preferred by Unicode
148 # terminology).  Thus each of these properties will have a map table that
149 # takes every code point and maps it to Y or N (but having ranges cuts the
150 # number of entries in that table way down), and two match tables, one
151 # which has a list of all the code points that map to Y, and one for all the
152 # code points that map to N.  (For each binary property, a third table is also
153 # generated for the pseudo Perl property.  It contains the identical code
154 # points as the Y table, but can be written in regular expressions, not in the
155 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
156 # properties are binary, but some properties have several possible values,
157 # some have many, and properties like Name have a different value for every
158 # named code point.  Those will not, unless the controlling lists are changed,
159 # have their match tables written out.  But all the ones which can be used in
160 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
161 # a property would have either its map table or its match tables written but
162 # not both.  Again, what gets written is controlled by lists which can easily
163 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
164 # tables needed to reconstruct the Unicode db are now written out, while
165 # suppressing the Unicode .txt files that contain the data.  Our tables are
166 # much more compact than the .txt files, so a significant space savings was
167 # achieved.  Also, tables are not written out that are trivially derivable
168 # from tables that do get written.  So, there typically is no file containing
169 # the code points not matched by a binary property (the table for \P{} versus
170 # lowercase \p{}), since you just need to invert the True table to get the
171 # False table.
172
173 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
174 # how many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably, and to keep out
185 # potential security issues.  For example, no folding information was given in
186 # early releases, so this program substitutes lower case instead, just so that
187 # a regular expression with the /i option will do something that actually
188 # gives the right results in many cases.  There are also a couple other
189 # corrections for version 1.1.5, commented at the point they are made.  As an
190 # example of corrections that weren't made (but could be) is this statement
191 # from DerivedAge.txt: "The supplementary private use code points and the
192 # non-character code points were assigned in version 2.0, but not specifically
193 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
194 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
195 # further down in these introductory comments.
196 #
197 # This program works on all non-provisional properties as of the current
198 # Unicode release, though the files for some are suppressed for various
199 # reasons.  You can change which are output by changing lists in this program.
200 #
201 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
202 # loose matchings rules (from Unicode TR18):
203 #
204 #    The recommended names for UCD properties and property values are in
205 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
206 #    [PropValue]. There are both abbreviated names and longer, more
207 #    descriptive names. It is strongly recommended that both names be
208 #    recognized, and that loose matching of property names be used,
209 #    whereby the case distinctions, whitespace, hyphens, and underbar
210 #    are ignored.
211 #
212 # The program still allows Fuzzy to override its determination of if loose
213 # matching should be used, but it isn't currently used, as it is no longer
214 # needed; the calculations it makes are good enough.
215 #
216 # SUMMARY OF HOW IT WORKS:
217 #
218 #   Process arguments
219 #
220 #   A list is constructed containing each input file that is to be processed
221 #
222 #   Each file on the list is processed in a loop, using the associated handler
223 #   code for each:
224 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
225 #            first.  These files name the properties and property values.
226 #            Objects are created of all the property and property value names
227 #            that the rest of the input should expect, including all synonyms.
228 #        The other input files give mappings from properties to property
229 #           values.  That is, they list code points and say what the mapping
230 #           is under the given property.  Some files give the mappings for
231 #           just one property; and some for many.  This program goes through
232 #           each file and populates the properties and their map tables from
233 #           them.  Some properties are listed in more than one file, and
234 #           Unicode has set up a precedence as to which has priority if there
235 #           is a conflict.  Thus the order of processing matters, and this
236 #           program handles the conflict possibility by processing the
237 #           overriding input files last, so that if necessary they replace
238 #           earlier values.
239 #        After this is all done, the program creates the property mappings not
240 #            furnished by Unicode, but derivable from what it does give.
241 #        The tables of code points that match each property value in each
242 #            property that is accessible by regular expressions are created.
243 #        The Perl-defined properties are created and populated.  Many of these
244 #            require data determined from the earlier steps
245 #        Any Perl-defined synonyms are created, and name clashes between Perl
246 #            and Unicode are reconciled and warned about.
247 #        All the properties are written to files
248 #        Any other files are written, and final warnings issued.
249 #
250 # For clarity, a number of operators have been overloaded to work on tables:
251 #   ~ means invert (take all characters not in the set).  The more
252 #       conventional '!' is not used because of the possibility of confusing
253 #       it with the actual boolean operation.
254 #   + means union
255 #   - means subtraction
256 #   & means intersection
257 # The precedence of these is the order listed.  Parentheses should be
258 # copiously used.  These are not a general scheme.  The operations aren't
259 # defined for a number of things, deliberately, to avoid getting into trouble.
260 # Operations are done on references and affect the underlying structures, so
261 # that the copy constructors for them have been overloaded to not return a new
262 # clone, but the input object itself.
263 #
264 # The bool operator is deliberately not overloaded to avoid confusion with
265 # "should it mean if the object merely exists, or also is non-empty?".
266 #
267 # WHY CERTAIN DESIGN DECISIONS WERE MADE
268 #
269 # This program needs to be able to run under miniperl.  Therefore, it uses a
270 # minimum of other modules, and hence implements some things itself that could
271 # be gotten from CPAN
272 #
273 # This program uses inputs published by the Unicode Consortium.  These can
274 # change incompatibly between releases without the Perl maintainers realizing
275 # it.  Therefore this program is now designed to try to flag these.  It looks
276 # at the directories where the inputs are, and flags any unrecognized files.
277 # It keeps track of all the properties in the files it handles, and flags any
278 # that it doesn't know how to handle.  It also flags any input lines that
279 # don't match the expected syntax, among other checks.
280 #
281 # It is also designed so if a new input file matches one of the known
282 # templates, one hopefully just needs to add it to a list to have it
283 # processed.
284 #
285 # As mentioned earlier, some properties are given in more than one file.  In
286 # particular, the files in the extracted directory are supposedly just
287 # reformattings of the others.  But they contain information not easily
288 # derivable from the other files, including results for Unihan (which isn't
289 # usually available to this program) and for unassigned code points.  They
290 # also have historically had errors or been incomplete.  In an attempt to
291 # create the best possible data, this program thus processes them first to
292 # glean information missing from the other files; then processes those other
293 # files to override any errors in the extracted ones.  Much of the design was
294 # driven by this need to store things and then possibly override them.
295 #
296 # It tries to keep fatal errors to a minimum, to generate something usable for
297 # testing purposes.  It always looks for files that could be inputs, and will
298 # warn about any that it doesn't know how to handle (the -q option suppresses
299 # the warning).
300 #
301 # Why is there more than one type of range?
302 #   This simplified things.  There are some very specialized code points that
303 #   have to be handled specially for output, such as Hangul syllable names.
304 #   By creating a range type (done late in the development process), it
305 #   allowed this to be stored with the range, and overridden by other input.
306 #   Originally these were stored in another data structure, and it became a
307 #   mess trying to decide if a second file that was for the same property was
308 #   overriding the earlier one or not.
309 #
310 # Why are there two kinds of tables, match and map?
311 #   (And there is a base class shared by the two as well.)  As stated above,
312 #   they actually are for different things.  Development proceeded much more
313 #   smoothly when I (khw) realized the distinction.  Map tables are used to
314 #   give the property value for every code point (actually every code point
315 #   that doesn't map to a default value).  Match tables are used for regular
316 #   expression matches, and are essentially the inverse mapping.  Separating
317 #   the two allows more specialized methods, and error checks so that one
318 #   can't just take the intersection of two map tables, for example, as that
319 #   is nonsensical.
320 #
321 # What about 'fate' and 'status'.  The concept of a table's fate was created
322 #   late when it became clear that something more was needed.  The difference
323 #   between this and 'status' is unclean, and could be improved if someone
324 #   wanted to spend the effort.
325 #
326 # DEBUGGING
327 #
328 # This program is written so it will run under miniperl.  Occasionally changes
329 # will cause an error where the backtrace doesn't work well under miniperl.
330 # To diagnose the problem, you can instead run it under regular perl, if you
331 # have one compiled.
332 #
333 # There is a good trace facility.  To enable it, first sub DEBUG must be set
334 # to return true.  Then a line like
335 #
336 # local $to_trace = 1 if main::DEBUG;
337 #
338 # can be added to enable tracing in its lexical scope (plus dynamic) or until
339 # you insert another line:
340 #
341 # local $to_trace = 0 if main::DEBUG;
342 #
343 # To actually trace, use a line like "trace $a, @b, %c, ...;
344 #
345 # Some of the more complex subroutines already have trace statements in them.
346 # Permanent trace statements should be like:
347 #
348 # trace ... if main::DEBUG && $to_trace;
349 #
350 # If there is just one or a few files that you're debugging, you can easily
351 # cause most everything else to be skipped.  Change the line
352 #
353 # my $debug_skip = 0;
354 #
355 # to 1, and every file whose object is in @input_file_objects and doesn't have
356 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
357 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
358 #
359 # To compare the output tables, it may be useful to specify the -annotate
360 # flag.  (As of this writing, this can't be done on a clean workspace, due to
361 # requirements in Text::Tabs used in this option; so first run mktables
362 # without this option.)  This option adds comment lines to each table, one for
363 # each non-algorithmically named character giving, currently its code point,
364 # name, and graphic representation if printable (and you have a font that
365 # knows about it).  This makes it easier to see what the particular code
366 # points are in each output table.  Non-named code points are annotated with a
367 # description of their status, and contiguous ones with the same description
368 # will be output as a range rather than individually.  Algorithmically named
369 # characters are also output as ranges, except when there are just a few
370 # contiguous ones.
371 #
372 # FUTURE ISSUES
373 #
374 # The program would break if Unicode were to change its names so that
375 # interior white space, underscores, or dashes differences were significant
376 # within property and property value names.
377 #
378 # It might be easier to use the xml versions of the UCD if this program ever
379 # would need heavy revision, and the ability to handle old versions was not
380 # required.
381 #
382 # There is the potential for name collisions, in that Perl has chosen names
383 # that Unicode could decide it also likes.  There have been such collisions in
384 # the past, with mostly Perl deciding to adopt the Unicode definition of the
385 # name.  However in the 5.2 Unicode beta testing, there were a number of such
386 # collisions, which were withdrawn before the final release, because of Perl's
387 # and other's protests.  These all involved new properties which began with
388 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
389 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
390 # Unicode document, so they are unlikely to be used by Unicode for another
391 # purpose.  However, they might try something beginning with 'In', or use any
392 # of the other Perl-defined properties.  This program will warn you of name
393 # collisions, and refuse to generate tables with them, but manual intervention
394 # will be required in this event.  One scheme that could be implemented, if
395 # necessary, would be to have this program generate another file, or add a
396 # field to mktables.lst that gives the date of first definition of a property.
397 # Each new release of Unicode would use that file as a basis for the next
398 # iteration.  And the Perl synonym addition code could sort based on the age
399 # of the property, so older properties get priority, and newer ones that clash
400 # would be refused; hence existing code would not be impacted, and some other
401 # synonym would have to be used for the new property.  This is ugly, and
402 # manual intervention would certainly be easier to do in the short run; lets
403 # hope it never comes to this.
404 #
405 # A NOTE ON UNIHAN
406 #
407 # This program can generate tables from the Unihan database.  But it doesn't
408 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
409 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
410 # database was split into 8 different files, all beginning with the letters
411 # 'Unihan'.  This program will read those file(s) if present, but it needs to
412 # know which of the many properties in the file(s) should have tables created
413 # for them.  It will create tables for any properties listed in
414 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
415 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
416 # property you want is not in those files of the release you are building
417 # against, you must add it to those two arrays.  Starting in 4.0, the
418 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
419 # is present in the directory, a table will be generated for that property.
420 # In 5.2, several more properties were added.  For your convenience, the two
421 # arrays are initialized with all the 6.0 listed properties that are also in
422 # earlier releases.  But these are commented out.  You can just uncomment the
423 # ones you want, or use them as a template for adding entries for other
424 # properties.
425 #
426 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
427 # and filter_unihan_line() are the functions where this is done.  This program
428 # already does some adjusting to make the lines look more like the rest of the
429 # Unicode DB;  You can see what that is in filter_unihan_line()
430 #
431 # There is a bug in the 3.2 data file in which some values for the
432 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
433 # could be added to correct these; or for a particular installation, the
434 # Unihan.txt file could be edited to fix them.
435 #
436 # HOW TO ADD A FILE TO BE PROCESSED
437 #
438 # A new file from Unicode needs to have an object constructed for it in
439 # @input_file_objects, probably at the end or at the end of the extracted
440 # ones.  The program should warn you if its name will clash with others on
441 # restrictive file systems, like DOS.  If so, figure out a better name, and
442 # add lines to the README.perl file giving that.  If the file is a character
443 # property, it should be in the format that Unicode has implicitly
444 # standardized for such files for the more recently introduced ones.
445 # If so, the Input_file constructor for @input_file_objects can just be the
446 # file name and release it first appeared in.  If not, then it should be
447 # possible to construct an each_line_handler() to massage the line into the
448 # standardized form.
449 #
450 # For non-character properties, more code will be needed.  You can look at
451 # the existing entries for clues.
452 #
453 # UNICODE VERSIONS NOTES
454 #
455 # The Unicode UCD has had a number of errors in it over the versions.  And
456 # these remain, by policy, in the standard for that version.  Therefore it is
457 # risky to correct them, because code may be expecting the error.  So this
458 # program doesn't generally make changes, unless the error breaks the Perl
459 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
460 # for U+1105, which causes real problems for the algorithms for Jamo
461 # calculations, so it is changed here.
462 #
463 # But it isn't so clear cut as to what to do about concepts that are
464 # introduced in a later release; should they extend back to earlier releases
465 # where the concept just didn't exist?  It was easier to do this than to not,
466 # so that's what was done.  For example, the default value for code points not
467 # in the files for various properties was probably undefined until changed by
468 # some version.  No_Block for blocks is such an example.  This program will
469 # assign No_Block even in Unicode versions that didn't have it.  This has the
470 # benefit that code being written doesn't have to special case earlier
471 # versions; and the detriment that it doesn't match the Standard precisely for
472 # the affected versions.
473 #
474 # Here are some observations about some of the issues in early versions:
475 #
476 # Prior to version 3.0, there were 3 character decompositions.  These are not
477 # handled by Unicode::Normalize, nor will it compile when presented a version
478 # that has them.  However, you can trivially get it to compile by simply
479 # ignoring those decompositions, by changing the croak to a carp.  At the time
480 # of this writing, the line (in cpan/Unicode-Normalize/Normalize.pm or
481 # cpan/Unicode-Normalize/mkheader) reads
482 #
483 #   croak("Weird Canonical Decomposition of U+$h");
484 #
485 # Simply comment it out.  It will compile, but will not know about any three
486 # character decompositions.
487
488 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
489 # that the reason is that the CJK block starting at 4E00 was removed from
490 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
491 # single property name \p{alpha}) has the correct values.  But the compound
492 # form is simply not generated until 3.1, as it can be argued that prior to
493 # this release, this was not an official property.  The comments for
494 # filter_old_style_proplist() give more details.
495 #
496 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
497 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
498 # reason is that 3.2 introduced U+205F=medium math space, which was not
499 # classed as white space, but Perl figured out that it should have been. 4.0
500 # reclassified it correctly.
501 #
502 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
503 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
504 # became 202, and ATBL was left with no code points, as all the ones that
505 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
506 # name for the class, it would not have been affected, but if it used the
507 # mnemonic, it would have been.
508 #
509 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
510 # points which eventually came to have this script property value, instead
511 # mapped to "Unknown".  But in the next release all these code points were
512 # moved to \p{sc=common} instead.
513
514 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
515 # generate errors in 5.0 and earlier.
516 #
517 # The default for missing code points for BidiClass is complicated.  Starting
518 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
519 # tries to do the best it can for earlier releases.  It is done in
520 # process_PropertyAliases()
521 #
522 # In version 2.1.2, the entry in UnicodeData.txt:
523 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
524 # should instead be
525 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
526 # Without this change, there are casing problems for this character.
527 #
528 # Search for $string_compare_versions to see how to compare changes to
529 # properties between Unicode versions
530 #
531 ##############################################################################
532
533 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
534                         # and errors
535 my $MAX_LINE_WIDTH = 78;
536
537 # Debugging aid to skip most files so as to not be distracted by them when
538 # concentrating on the ones being debugged.  Add
539 # non_skip => 1,
540 # to the constructor for those files you want processed when you set this.
541 # Files with a first version number of 0 are special: they are always
542 # processed regardless of the state of this flag.  Generally, Jamo.txt and
543 # UnicodeData.txt must not be skipped if you want this program to not die
544 # before normal completion.
545 my $debug_skip = 0;
546
547
548 # Normally these are suppressed.
549 my $write_Unicode_deprecated_tables = 0;
550
551 # Set to 1 to enable tracing.
552 our $to_trace = 0;
553
554 { # Closure for trace: debugging aid
555     my $print_caller = 1;        # ? Include calling subroutine name
556     my $main_with_colon = 'main::';
557     my $main_colon_length = length($main_with_colon);
558
559     sub trace {
560         return unless $to_trace;        # Do nothing if global flag not set
561
562         my @input = @_;
563
564         local $DB::trace = 0;
565         $DB::trace = 0;          # Quiet 'used only once' message
566
567         my $line_number;
568
569         # Loop looking up the stack to get the first non-trace caller
570         my $caller_line;
571         my $caller_name;
572         my $i = 0;
573         do {
574             $line_number = $caller_line;
575             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
576             $caller = $main_with_colon unless defined $caller;
577
578             $caller_name = $caller;
579
580             # get rid of pkg
581             $caller_name =~ s/.*:://;
582             if (substr($caller_name, 0, $main_colon_length)
583                 eq $main_with_colon)
584             {
585                 $caller_name = substr($caller_name, $main_colon_length);
586             }
587
588         } until ($caller_name ne 'trace');
589
590         # If the stack was empty, we were called from the top level
591         $caller_name = 'main' if ($caller_name eq ""
592                                     || $caller_name eq 'trace');
593
594         my $output = "";
595         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
596         foreach my $string (@input) {
597             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
598                 $output .= simple_dumper($string);
599             }
600             else {
601                 $string = "$string" if ref $string;
602                 $string = $UNDEF unless defined $string;
603                 chomp $string;
604                 $string = '""' if $string eq "";
605                 $output .= " " if $output ne ""
606                                 && $string ne ""
607                                 && substr($output, -1, 1) ne " "
608                                 && substr($string, 0, 1) ne " ";
609                 $output .= $string;
610             }
611         }
612
613         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
614         print STDERR "$caller_name: " if $print_caller;
615         print STDERR $output, "\n";
616         return;
617     }
618 }
619
620 # This is for a rarely used development feature that allows you to compare two
621 # versions of the Unicode standard without having to deal with changes caused
622 # by the code points introduced in the later version.  You probably also want
623 # to use the -annotate option when using this.  Change the 0 to a string
624 # containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only code
625 # points introduced in that release and earlier will be used; later ones are
626 # thrown away.  You use the version number of the earliest one you want to
627 # compare; then run this program on directory structures containing each
628 # release, and compare the outputs.  These outputs will therefore include only
629 # the code points common to both releases, and you can see the changes caused
630 # just by the underlying release semantic changes.  For versions earlier than
631 # 3.2, you must copy a version of DAge.txt into the directory.
632 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
633 my $compare_versions = DEBUG
634                        && $string_compare_versions
635                        && pack "C*", split /\./, $string_compare_versions;
636
637 sub uniques {
638     # Returns non-duplicated input values.  From "Perl Best Practices:
639     # Encapsulated Cleverness".  p. 455 in first edition.
640
641     my %seen;
642     # Arguably this breaks encapsulation, if the goal is to permit multiple
643     # distinct objects to stringify to the same value, and be interchangeable.
644     # However, for this program, no two objects stringify identically, and all
645     # lists passed to this function are either objects or strings. So this
646     # doesn't affect correctness, but it does give a couple of percent speedup.
647     no overloading;
648     return grep { ! $seen{$_}++ } @_;
649 }
650
651 $0 = File::Spec->canonpath($0);
652
653 my $make_test_script = 0;      # ? Should we output a test script
654 my $make_norm_test_script = 0; # ? Should we output a normalization test script
655 my $write_unchanged_files = 0; # ? Should we update the output files even if
656                                #    we don't think they have changed
657 my $use_directory = "";        # ? Should we chdir somewhere.
658 my $pod_directory;             # input directory to store the pod file.
659 my $pod_file = 'perluniprops';
660 my $t_path;                     # Path to the .t test file
661 my $file_list = 'mktables.lst'; # File to store input and output file names.
662                                # This is used to speed up the build, by not
663                                # executing the main body of the program if
664                                # nothing on the list has changed since the
665                                # previous build
666 my $make_list = 1;             # ? Should we write $file_list.  Set to always
667                                # make a list so that when the pumpking is
668                                # preparing a release, s/he won't have to do
669                                # special things
670 my $glob_list = 0;             # ? Should we try to include unknown .txt files
671                                # in the input.
672 my $output_range_counts = $debugging_build;   # ? Should we include the number
673                                               # of code points in ranges in
674                                               # the output
675 my $annotate = 0;              # ? Should character names be in the output
676
677 # Verbosity levels; 0 is quiet
678 my $NORMAL_VERBOSITY = 1;
679 my $PROGRESS = 2;
680 my $VERBOSE = 3;
681
682 my $verbosity = $NORMAL_VERBOSITY;
683
684 # Stored in mktables.lst so that if this program is called with different
685 # options, will regenerate even if the files otherwise look like they're
686 # up-to-date.
687 my $command_line_arguments = join " ", @ARGV;
688
689 # Process arguments
690 while (@ARGV) {
691     my $arg = shift @ARGV;
692     if ($arg eq '-v') {
693         $verbosity = $VERBOSE;
694     }
695     elsif ($arg eq '-p') {
696         $verbosity = $PROGRESS;
697         $| = 1;     # Flush buffers as we go.
698     }
699     elsif ($arg eq '-q') {
700         $verbosity = 0;
701     }
702     elsif ($arg eq '-w') {
703         $write_unchanged_files = 1; # update the files even if havent changed
704     }
705     elsif ($arg eq '-check') {
706         my $this = shift @ARGV;
707         my $ok = shift @ARGV;
708         if ($this ne $ok) {
709             print "Skipping as check params are not the same.\n";
710             exit(0);
711         }
712     }
713     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
714         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
715     }
716     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
717     {
718         $make_test_script = 1;
719     }
720     elsif ($arg eq '-makenormtest')
721     {
722         $make_norm_test_script = 1;
723     }
724     elsif ($arg eq '-makelist') {
725         $make_list = 1;
726     }
727     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
728         -d $use_directory or croak "Unknown directory '$use_directory'";
729     }
730     elsif ($arg eq '-L') {
731
732         # Existence not tested until have chdir'd
733         $file_list = shift;
734     }
735     elsif ($arg eq '-globlist') {
736         $glob_list = 1;
737     }
738     elsif ($arg eq '-c') {
739         $output_range_counts = ! $output_range_counts
740     }
741     elsif ($arg eq '-annotate') {
742         $annotate = 1;
743         $debugging_build = 1;
744         $output_range_counts = 1;
745     }
746     else {
747         my $with_c = 'with';
748         $with_c .= 'out' if $output_range_counts;   # Complements the state
749         croak <<END;
750 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
751           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
752           [-check A B ]
753   -c          : Output comments $with_c number of code points in ranges
754   -q          : Quiet Mode: Only output serious warnings.
755   -p          : Set verbosity level to normal plus show progress.
756   -v          : Set Verbosity level high:  Show progress and non-serious
757                 warnings
758   -w          : Write files regardless
759   -C dir      : Change to this directory before proceeding. All relative paths
760                 except those specified by the -P and -T options will be done
761                 with respect to this directory.
762   -P dir      : Output $pod_file file to directory 'dir'.
763   -T path     : Create a test script as 'path'; overrides -maketest
764   -L filelist : Use alternate 'filelist' instead of standard one
765   -globlist   : Take as input all non-Test *.txt files in current and sub
766                 directories
767   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
768                 overrides -T
769   -makelist   : Rewrite the file list $file_list based on current setup
770   -annotate   : Output an annotation for each character in the table files;
771                 useful for debugging mktables, looking at diffs; but is slow
772                 and memory intensive
773   -check A B  : Executes $0 only if A and B are the same
774 END
775     }
776 }
777
778 # Stores the most-recently changed file.  If none have changed, can skip the
779 # build
780 my $most_recent = (stat $0)[9];   # Do this before the chdir!
781
782 # Change directories now, because need to read 'version' early.
783 if ($use_directory) {
784     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
785         $pod_directory = File::Spec->rel2abs($pod_directory);
786     }
787     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
788         $t_path = File::Spec->rel2abs($t_path);
789     }
790     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
791     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
792         $pod_directory = File::Spec->abs2rel($pod_directory);
793     }
794     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
795         $t_path = File::Spec->abs2rel($t_path);
796     }
797 }
798
799 # Get Unicode version into regular and v-string.  This is done now because
800 # various tables below get populated based on it.  These tables are populated
801 # here to be near the top of the file, and so easily seeable by those needing
802 # to modify things.
803 open my $VERSION, "<", "version"
804                     or croak "$0: can't open required file 'version': $!\n";
805 my $string_version = <$VERSION>;
806 close $VERSION;
807 chomp $string_version;
808 my $v_version = pack "C*", split /\./, $string_version;        # v string
809
810 # The following are the complete names of properties with property values that
811 # are known to not match any code points in some versions of Unicode, but that
812 # may change in the future so they should be matchable, hence an empty file is
813 # generated for them.
814 my @tables_that_may_be_empty;
815 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
816                                                     if $v_version lt v6.3.0;
817 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
818 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
819 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
820                                                     if $v_version ge v4.1.0;
821 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
822                                                     if $v_version ge v6.0.0;
823 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
824                                                     if $v_version ge v6.1.0;
825 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
826                                                     if $v_version ge v6.2.0;
827
828 # The lists below are hashes, so the key is the item in the list, and the
829 # value is the reason why it is in the list.  This makes generation of
830 # documentation easier.
831
832 my %why_suppressed;  # No file generated for these.
833
834 # Files aren't generated for empty extraneous properties.  This is arguable.
835 # Extraneous properties generally come about because a property is no longer
836 # used in a newer version of Unicode.  If we generated a file without code
837 # points, programs that used to work on that property will still execute
838 # without errors.  It just won't ever match (or will always match, with \P{}).
839 # This means that the logic is now likely wrong.  I (khw) think its better to
840 # find this out by getting an error message.  Just move them to the table
841 # above to change this behavior
842 my %why_suppress_if_empty_warn_if_not = (
843
844    # It is the only property that has ever officially been removed from the
845    # Standard.  The database never contained any code points for it.
846    'Special_Case_Condition' => 'Obsolete',
847
848    # Apparently never official, but there were code points in some versions of
849    # old-style PropList.txt
850    'Non_Break' => 'Obsolete',
851 );
852
853 # These would normally go in the warn table just above, but they were changed
854 # a long time before this program was written, so warnings about them are
855 # moot.
856 if ($v_version gt v3.2.0) {
857     push @tables_that_may_be_empty,
858                                 'Canonical_Combining_Class=Attached_Below_Left'
859 }
860
861 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
862 # unless explicitly added.
863 if ($v_version ge v5.2.0 && ! $write_Unicode_deprecated_tables) {
864     my $unihan = 'Unihan; remove from list if using Unihan';
865     foreach my $table (qw (
866                            kAccountingNumeric
867                            kOtherNumeric
868                            kPrimaryNumeric
869                            kCompatibilityVariant
870                            kIICore
871                            kIRG_GSource
872                            kIRG_HSource
873                            kIRG_JSource
874                            kIRG_KPSource
875                            kIRG_MSource
876                            kIRG_KSource
877                            kIRG_TSource
878                            kIRG_USource
879                            kIRG_VSource
880                            kRSUnicode
881                         ))
882     {
883         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
884     }
885 }
886
887 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
888 # output)
889 my $EXTERNAL_MAP = 1;
890 my $INTERNAL_MAP = 2;
891 my $OUTPUT_ADJUSTED = 3;
892
893 # To override computed values for writing the map tables for these properties.
894 # The default for enum map tables is to write them out, so that the Unicode
895 # .txt files can be removed, but all the data to compute any property value
896 # for any code point is available in a more compact form.
897 my %global_to_output_map = (
898     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
899     # get stuck supporting it if things change.  Since it is a STRING
900     # property, it normally would be listed in the pod, but INTERNAL_MAP
901     # suppresses that.
902     Unicode_1_Name => $INTERNAL_MAP,
903
904     Present_In => 0,                # Suppress, as easily computed from Age
905     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
906                                             # retained, but needed for
907                                             # non-ASCII
908
909     # Suppress, as mapping can be found instead from the
910     # Perl_Decomposition_Mapping file
911     Decomposition_Type => 0,
912 );
913
914 # Properties that this program ignores.
915 my @unimplemented_properties;
916
917 # With this release, it is automatically handled if the Unihan db is
918 # downloaded
919 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version lt v5.2.0;
920
921 # There are several types of obsolete properties defined by Unicode.  These
922 # must be hand-edited for every new Unicode release.
923 my %why_deprecated;  # Generates a deprecated warning message if used.
924 my %why_stabilized;  # Documentation only
925 my %why_obsolete;    # Documentation only
926
927 {   # Closure
928     my $simple = 'Perl uses the more complete version';
929     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
930
931     my $other_properties = 'other properties';
932     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
933     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
934
935     %why_deprecated = (
936         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
937         'Jamo_Short_Name' => $contributory,
938         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
939         'Other_Alphabetic' => $contributory,
940         'Other_Default_Ignorable_Code_Point' => $contributory,
941         'Other_Grapheme_Extend' => $contributory,
942         'Other_ID_Continue' => $contributory,
943         'Other_ID_Start' => $contributory,
944         'Other_Lowercase' => $contributory,
945         'Other_Math' => $contributory,
946         'Other_Uppercase' => $contributory,
947         'Expands_On_NFC' => $why_no_expand,
948         'Expands_On_NFD' => $why_no_expand,
949         'Expands_On_NFKC' => $why_no_expand,
950         'Expands_On_NFKD' => $why_no_expand,
951     );
952
953     %why_suppressed = (
954         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
955         # contains the same information, but without the algorithmically
956         # determinable Hangul syllables'.  This file is not published, so it's
957         # existence is not noted in the comment.
958         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
959
960         'Indic_Matra_Category' => "Withdrawn by Unicode while still provisional",
961
962         # Don't suppress ISO_Comment, as otherwise special handling is needed
963         # to differentiate between it and gc=c, which can be written as 'isc',
964         # which is the same characters as ISO_Comment's short name.
965
966         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
967
968         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
969         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
970         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
971         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
972
973         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
974     );
975
976     foreach my $property (
977
978             # The following are suppressed because they were made contributory
979             # or deprecated by Unicode before Perl ever thought about
980             # supporting them.
981             'Jamo_Short_Name',
982             'Grapheme_Link',
983             'Expands_On_NFC',
984             'Expands_On_NFD',
985             'Expands_On_NFKC',
986             'Expands_On_NFKD',
987
988             # The following are suppressed because they have been marked
989             # as deprecated for a sufficient amount of time
990             'Other_Alphabetic',
991             'Other_Default_Ignorable_Code_Point',
992             'Other_Grapheme_Extend',
993             'Other_ID_Continue',
994             'Other_ID_Start',
995             'Other_Lowercase',
996             'Other_Math',
997             'Other_Uppercase',
998     ) {
999         $why_suppressed{$property} = $why_deprecated{$property};
1000     }
1001
1002     # Customize the message for all the 'Other_' properties
1003     foreach my $property (keys %why_deprecated) {
1004         next if (my $main_property = $property) !~ s/^Other_//;
1005         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1006     }
1007 }
1008
1009 if ($write_Unicode_deprecated_tables) {
1010     foreach my $property (keys %why_suppressed) {
1011         delete $why_suppressed{$property} if $property =~
1012                                                     / ^ Other | Grapheme /x;
1013     }
1014 }
1015
1016 if ($v_version ge 4.0.0) {
1017     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1018     if ($v_version ge 6.0.0) {
1019         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1020     }
1021 }
1022 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1023     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1024     if ($v_version ge 6.0.0) {
1025         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1026     }
1027 }
1028
1029 # Probably obsolete forever
1030 if ($v_version ge v4.1.0) {
1031     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1032 }
1033 if ($v_version ge v6.0.0) {
1034     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1035     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1036 }
1037
1038 # This program can create files for enumerated-like properties, such as
1039 # 'Numeric_Type'.  This file would be the same format as for a string
1040 # property, with a mapping from code point to its value, so you could look up,
1041 # for example, the script a code point is in.  But no one so far wants this
1042 # mapping, or they have found another way to get it since this is a new
1043 # feature.  So no file is generated except if it is in this list.
1044 my @output_mapped_properties = split "\n", <<END;
1045 END
1046
1047 # If you are using the Unihan database in a Unicode version before 5.2, you
1048 # need to add the properties that you want to extract from it to this table.
1049 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
1050 # listed, commented out
1051 my @cjk_properties = split "\n", <<'END';
1052 #cjkAccountingNumeric; kAccountingNumeric
1053 #cjkOtherNumeric; kOtherNumeric
1054 #cjkPrimaryNumeric; kPrimaryNumeric
1055 #cjkCompatibilityVariant; kCompatibilityVariant
1056 #cjkIICore ; kIICore
1057 #cjkIRG_GSource; kIRG_GSource
1058 #cjkIRG_HSource; kIRG_HSource
1059 #cjkIRG_JSource; kIRG_JSource
1060 #cjkIRG_KPSource; kIRG_KPSource
1061 #cjkIRG_KSource; kIRG_KSource
1062 #cjkIRG_TSource; kIRG_TSource
1063 #cjkIRG_USource; kIRG_USource
1064 #cjkIRG_VSource; kIRG_VSource
1065 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1066 END
1067
1068 # Similarly for the property values.  For your convenience, the lines in the
1069 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1070 # '#' marks (for Unicode versions before 5.2)
1071 my @cjk_property_values = split "\n", <<'END';
1072 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1073 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1074 ## @missing: 0000..10FFFF; cjkIICore; <none>
1075 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1076 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1077 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1078 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1079 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1080 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1081 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1082 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1083 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1084 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1085 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1086 END
1087
1088 # The input files don't list every code point.  Those not listed are to be
1089 # defaulted to some value.  Below are hard-coded what those values are for
1090 # non-binary properties as of 5.1.  Starting in 5.0, there are
1091 # machine-parsable comment lines in the files that give the defaults; so this
1092 # list shouldn't have to be extended.  The claim is that all missing entries
1093 # for binary properties will default to 'N'.  Unicode tried to change that in
1094 # 5.2, but the beta period produced enough protest that they backed off.
1095 #
1096 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1097 # be in the form that it expects.  The others may be synonyms.
1098 my $CODE_POINT = '<code point>';
1099 my %default_mapping = (
1100     Age => "Unassigned",
1101     # Bidi_Class => Complicated; set in code
1102     Bidi_Mirroring_Glyph => "",
1103     Block => 'No_Block',
1104     Canonical_Combining_Class => 0,
1105     Case_Folding => $CODE_POINT,
1106     Decomposition_Mapping => $CODE_POINT,
1107     Decomposition_Type => 'None',
1108     East_Asian_Width => "Neutral",
1109     FC_NFKC_Closure => $CODE_POINT,
1110     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1111     Grapheme_Cluster_Break => 'Other',
1112     Hangul_Syllable_Type => 'NA',
1113     ISO_Comment => "",
1114     Jamo_Short_Name => "",
1115     Joining_Group => "No_Joining_Group",
1116     # Joining_Type => Complicated; set in code
1117     kIICore => 'N',   #                       Is converted to binary
1118     #Line_Break => Complicated; set in code
1119     Lowercase_Mapping => $CODE_POINT,
1120     Name => "",
1121     Name_Alias => "",
1122     NFC_QC => 'Yes',
1123     NFD_QC => 'Yes',
1124     NFKC_QC => 'Yes',
1125     NFKD_QC => 'Yes',
1126     Numeric_Type => 'None',
1127     Numeric_Value => 'NaN',
1128     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1129     Sentence_Break => 'Other',
1130     Simple_Case_Folding => $CODE_POINT,
1131     Simple_Lowercase_Mapping => $CODE_POINT,
1132     Simple_Titlecase_Mapping => $CODE_POINT,
1133     Simple_Uppercase_Mapping => $CODE_POINT,
1134     Titlecase_Mapping => $CODE_POINT,
1135     Unicode_1_Name => "",
1136     Unicode_Radical_Stroke => "",
1137     Uppercase_Mapping => $CODE_POINT,
1138     Word_Break => 'Other',
1139 );
1140
1141 # Below are files that Unicode furnishes, but this program ignores, and why.
1142 # NormalizationCorrections.txt requires some more explanation.  It documents
1143 # the cumulative fixes to erroneous normalizations in earlier Unicode
1144 # versions.  Its main purpose is so that someone running on an earlier version
1145 # can use this file to override what got published in that earlier release.
1146 # It would be easy for mktables to read and handle this file.  But all the
1147 # corrections in it should already be in the other files for the release it
1148 # is.  To get it to actually mean something useful, someone would have to be
1149 # using an earlier Unicode release, and copy it to the files for that release
1150 # and recomplile.  So far there has been no demand to do that, so this hasn't
1151 # been implemented.
1152 my %ignored_files = (
1153     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1154     'Index.txt' => 'Alphabetical index of Unicode characters',
1155     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1156     'NamesList.txt' => 'Annotated list of characters',
1157     'NamesList.html' => 'Describes the format and contents of F<NamesList.txt>',
1158     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1159     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1160     'ReadMe.txt' => 'Documentation',
1161     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1162     'StandardizedVariants.html' => 'Provides a visual display of the standard variant sequences derived from F<StandardizedVariants.txt>.',
1163     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1164     'USourceData.txt' => 'Documentation of status and cross reference of proposals for encoding by Unicode of Unihan characters',
1165     'USourceGlyphs.pdf' => 'Pictures of the characters in F<USourceData.txt>',
1166     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1167     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1168     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1169     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1170 );
1171
1172 my %skipped_files;  # List of files that we skip
1173
1174 ### End of externally interesting definitions, except for @input_file_objects
1175
1176 my $HEADER=<<"EOF";
1177 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1178 # This file is machine-generated by $0 from the Unicode
1179 # database, Version $string_version.  Any changes made here will be lost!
1180 EOF
1181
1182 my $INTERNAL_ONLY_HEADER = <<"EOF";
1183
1184 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1185 # This file is for internal use by core Perl only.  The format and even the
1186 # name or existence of this file are subject to change without notice.  Don't
1187 # use it directly.  Use Unicode::UCD to access the Unicode character data
1188 # base.
1189 EOF
1190
1191 my $DEVELOPMENT_ONLY=<<"EOF";
1192 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1193 # This file contains information artificially constrained to code points
1194 # present in Unicode release $string_compare_versions.
1195 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1196 # not be used for production.
1197
1198 EOF
1199
1200 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1201                                    ? "10FFFF"
1202                                    : "FFFF";
1203 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1204 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1205
1206 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1207 # that high, above IV_MAX, some operations don't work, and you can easily get
1208 # overflow.  Therefore for internal use, we use a much smaller number,
1209 # translating it to UV_MAX only for output.  The exact number is immaterial
1210 # (all Unicode code points are treated exactly the same), but the algorithm
1211 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1212 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1213 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1214 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1215
1216 my $MAX_PLATFORM_CODEPOINT = ~0;
1217
1218 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1219 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1220 # to decrease backtracking.  The first regex allows the code point to be at
1221 # the end of a word, but to work properly, the word shouldn't end with a valid
1222 # hex character.  The second one won't match a code point at the end of a
1223 # word, and doesn't have the run-on issue
1224 my $run_on_code_point_re =
1225             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1226 my $code_point_re = qr/\b$run_on_code_point_re/;
1227
1228 # This matches the beginning of the line in the Unicode db files that give the
1229 # defaults for code points not listed (i.e., missing) in the file.  The code
1230 # depends on this ending with a semi-colon, so it can assume it is a valid
1231 # field when the line is split() by semi-colons
1232 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1233
1234 # Property types.  Unicode has more types, but these are sufficient for our
1235 # purposes.
1236 my $UNKNOWN = -1;   # initialized to illegal value
1237 my $NON_STRING = 1; # Either binary or enum
1238 my $BINARY = 2;
1239 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1240                        # tables, additional true and false tables are
1241                        # generated so that false is anything matching the
1242                        # default value, and true is everything else.
1243 my $ENUM = 4;       # Include catalog
1244 my $STRING = 5;     # Anything else: string or misc
1245
1246 # Some input files have lines that give default values for code points not
1247 # contained in the file.  Sometimes these should be ignored.
1248 my $NO_DEFAULTS = 0;        # Must evaluate to false
1249 my $NOT_IGNORED = 1;
1250 my $IGNORED = 2;
1251
1252 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1253 # and will appear in the main body of the tables in the output files, but
1254 # there are other types of ranges as well, listed below, that are specially
1255 # handled.   There are pseudo-types as well that will never be stored as a
1256 # type, but will affect the calculation of the type.
1257
1258 # 0 is for normal, non-specials
1259 my $MULTI_CP = 1;           # Sequence of more than code point
1260 my $HANGUL_SYLLABLE = 2;
1261 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1262 my $NULL = 4;               # The map is to the null string; utf8.c can't
1263                             # handle these, nor is there an accepted syntax
1264                             # for them in \p{} constructs
1265 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1266                              # otherwise be $MULTI_CP type are instead type 0
1267
1268 # process_generic_property_file() can accept certain overrides in its input.
1269 # Each of these must begin AND end with $CMD_DELIM.
1270 my $CMD_DELIM = "\a";
1271 my $REPLACE_CMD = 'replace';    # Override the Replace
1272 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1273
1274 my $NO = 0;
1275 my $YES = 1;
1276
1277 # Values for the Replace argument to add_range.
1278 # $NO                      # Don't replace; add only the code points not
1279                            # already present.
1280 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1281                            # the comments at the subroutine definition.
1282 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1283 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1284                            # already there
1285 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1286                            # already there
1287 my $CROAK = 6;             # Die with an error if is already there
1288
1289 # Flags to give property statuses.  The phrases are to remind maintainers that
1290 # if the flag is changed, the indefinite article referring to it in the
1291 # documentation may need to be as well.
1292 my $NORMAL = "";
1293 my $DEPRECATED = 'D';
1294 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1295 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1296 my $DISCOURAGED = 'X';
1297 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1298 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1299 my $STRICTER = 'T';
1300 my $a_bold_stricter = "a 'B<$STRICTER>'";
1301 my $A_bold_stricter = "A 'B<$STRICTER>'";
1302 my $STABILIZED = 'S';
1303 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1304 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1305 my $OBSOLETE = 'O';
1306 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1307 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1308
1309 # Aliases can also have an extra status:
1310 my $INTERNAL_ALIAS = 'P';
1311
1312 my %status_past_participles = (
1313     $DISCOURAGED => 'discouraged',
1314     $STABILIZED => 'stabilized',
1315     $OBSOLETE => 'obsolete',
1316     $DEPRECATED => 'deprecated',
1317     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1318 );
1319
1320 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1321 # externally documented.
1322 my $ORDINARY = 0;       # The normal fate.
1323 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1324                         # but there is a file written that can be used to
1325                         # reconstruct this table
1326 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1327                         # for Perl's internal use only
1328 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1329                         # Is for backwards compatibility for applications that
1330                         # read the file directly, so it's format is
1331                         # unchangeable.
1332 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1333                         # result, we don't bother to do many computations on
1334                         # it.
1335 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1336                         # computations anyway, as the values are needed for
1337                         # things to work.  This happens when we have Perl
1338                         # extensions that depend on Unicode tables that
1339                         # wouldn't normally be in a given Unicode version.
1340
1341 # The format of the values of the tables:
1342 my $EMPTY_FORMAT = "";
1343 my $BINARY_FORMAT = 'b';
1344 my $DECIMAL_FORMAT = 'd';
1345 my $FLOAT_FORMAT = 'f';
1346 my $INTEGER_FORMAT = 'i';
1347 my $HEX_FORMAT = 'x';
1348 my $RATIONAL_FORMAT = 'r';
1349 my $STRING_FORMAT = 's';
1350 my $ADJUST_FORMAT = 'a';
1351 my $HEX_ADJUST_FORMAT = 'ax';
1352 my $DECOMP_STRING_FORMAT = 'c';
1353 my $STRING_WHITE_SPACE_LIST = 'sw';
1354
1355 my %map_table_formats = (
1356     $BINARY_FORMAT => 'binary',
1357     $DECIMAL_FORMAT => 'single decimal digit',
1358     $FLOAT_FORMAT => 'floating point number',
1359     $INTEGER_FORMAT => 'integer',
1360     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1361     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1362     $STRING_FORMAT => 'string',
1363     $ADJUST_FORMAT => 'some entries need adjustment',
1364     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1365     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1366     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1367 );
1368
1369 # Unicode didn't put such derived files in a separate directory at first.
1370 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1371 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1372 my $AUXILIARY = 'auxiliary';
1373
1374 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1375 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1376 my %loose_to_file_of;       # loosely maps table names to their respective
1377                             # files
1378 my %stricter_to_file_of;    # same; but for stricter mapping.
1379 my %loose_property_to_file_of; # Maps a loose property name to its map file
1380 my %strict_property_to_file_of; # Same, but strict
1381 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1382                             # inversion list.  When a definition is inlined,
1383                             # its value in the hash it's in (one of the two
1384                             # defined just above) will include an index into
1385                             # this array.  The 0th element is initialized to
1386                             # the definition for a zero length inversion list
1387 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1388                             # in the hash %utf8::SwashInfo
1389 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1390                              # their rational equivalent
1391 my %loose_property_name_of; # Loosely maps (non_string) property names to
1392                             # standard form
1393 my %strict_property_name_of; # Strictly maps (non_string) property names to
1394                             # standard form
1395 my %string_property_loose_to_name; # Same, for string properties.
1396 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1397                             # the property name in standard loose form, and
1398                             # 'value' is the default value for that property,
1399                             # also in standard loose form.
1400 my %loose_to_standard_value; # loosely maps table names to the canonical
1401                             # alias for them
1402 my %ambiguous_names;        # keys are alias names (in standard form) that
1403                             # have more than one possible meaning.
1404 my %combination_property;   # keys are alias names (in standard form) that
1405                             # have both a map table, and a binary one that
1406                             # yields true for all non-null maps.
1407 my %prop_aliases;           # Keys are standard property name; values are each
1408                             # one's aliases
1409 my %prop_value_aliases;     # Keys of top level are standard property name;
1410                             # values are keys to another hash,  Each one is
1411                             # one of the property's values, in standard form.
1412                             # The values are that prop-val's aliases.
1413 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1414
1415 # Most properties are immune to caseless matching, otherwise you would get
1416 # nonsensical results, as properties are a function of a code point, not
1417 # everything that is caselessly equivalent to that code point.  For example,
1418 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1419 # be true because 's' and 'S' are equivalent caselessly.  However,
1420 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1421 # extend that concept to those very few properties that are like this.  Each
1422 # such property will match the full range caselessly.  They are hard-coded in
1423 # the program; it's not worth trying to make it general as it's extremely
1424 # unlikely that they will ever change.
1425 my %caseless_equivalent_to;
1426
1427 # These constants names and values were taken from the Unicode standard,
1428 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1429 # syllables.  The '_string' versions are so generated tables can retain the
1430 # hex format, which is the more familiar value
1431 my $SBase_string = "0xAC00";
1432 my $SBase = CORE::hex $SBase_string;
1433 my $LBase_string = "0x1100";
1434 my $LBase = CORE::hex $LBase_string;
1435 my $VBase_string = "0x1161";
1436 my $VBase = CORE::hex $VBase_string;
1437 my $TBase_string = "0x11A7";
1438 my $TBase = CORE::hex $TBase_string;
1439 my $SCount = 11172;
1440 my $LCount = 19;
1441 my $VCount = 21;
1442 my $TCount = 28;
1443 my $NCount = $VCount * $TCount;
1444
1445 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1446 # with the above published constants.
1447 my %Jamo;
1448 my %Jamo_L;     # Leading consonants
1449 my %Jamo_V;     # Vowels
1450 my %Jamo_T;     # Trailing consonants
1451
1452 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1453 # The key is the base name of the code point, and the value is an
1454 # array giving all the ranges that use this base name.  Each range
1455 # is actually a hash giving the 'low' and 'high' values of it.
1456 my %names_ending_in_code_point;
1457 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1458                                         # removed from the names
1459 # Inverse mapping.  The list of ranges that have these kinds of
1460 # names.  Each element contains the low, high, and base names in an
1461 # anonymous hash.
1462 my @code_points_ending_in_code_point;
1463
1464 # To hold Unicode's normalization test suite
1465 my @normalization_tests;
1466
1467 # Boolean: does this Unicode version have the hangul syllables, and are we
1468 # writing out a table for them?
1469 my $has_hangul_syllables = 0;
1470
1471 # Does this Unicode version have code points whose names end in their
1472 # respective code points, and are we writing out a table for them?  0 for no;
1473 # otherwise points to first property that a table is needed for them, so that
1474 # if multiple tables are needed, we don't create duplicates
1475 my $needing_code_points_ending_in_code_point = 0;
1476
1477 my @backslash_X_tests;     # List of tests read in for testing \X
1478 my @SB_tests;              # List of tests read in for testing \b{sb}
1479 my @WB_tests;              # List of tests read in for testing \b{wb}
1480 my @unhandled_properties;  # Will contain a list of properties found in
1481                            # the input that we didn't process.
1482 my @match_properties;      # Properties that have match tables, to be
1483                            # listed in the pod
1484 my @map_properties;        # Properties that get map files written
1485 my @named_sequences;       # NamedSequences.txt contents.
1486 my %potential_files;       # Generated list of all .txt files in the directory
1487                            # structure so we can warn if something is being
1488                            # ignored.
1489 my @files_actually_output; # List of files we generated.
1490 my @more_Names;            # Some code point names are compound; this is used
1491                            # to store the extra components of them.
1492 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1493                            # the minimum before we consider it equivalent to a
1494                            # candidate rational
1495 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1496
1497 # These store references to certain commonly used property objects
1498 my $ccc;
1499 my $gc;
1500 my $perl;
1501 my $block;
1502 my $perl_charname;
1503 my $print;
1504 my $All;
1505 my $Assigned;   # All assigned characters in this Unicode release
1506 my $script;
1507
1508 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1509 my $has_In_conflicts = 0;
1510 my $has_Is_conflicts = 0;
1511
1512 sub internal_file_to_platform ($) {
1513     # Convert our file paths which have '/' separators to those of the
1514     # platform.
1515
1516     my $file = shift;
1517     return undef unless defined $file;
1518
1519     return File::Spec->join(split '/', $file);
1520 }
1521
1522 sub file_exists ($) {   # platform independent '-e'.  This program internally
1523                         # uses slash as a path separator.
1524     my $file = shift;
1525     return 0 if ! defined $file;
1526     return -e internal_file_to_platform($file);
1527 }
1528
1529 sub objaddr($) {
1530     # Returns the address of the blessed input object.
1531     # It doesn't check for blessedness because that would do a string eval
1532     # every call, and the program is structured so that this is never called
1533     # for a non-blessed object.
1534
1535     no overloading; # If overloaded, numifying below won't work.
1536
1537     # Numifying a ref gives its address.
1538     return pack 'J', $_[0];
1539 }
1540
1541 # These are used only if $annotate is true.
1542 # The entire range of Unicode characters is examined to populate these
1543 # after all the input has been processed.  But most can be skipped, as they
1544 # have the same descriptive phrases, such as being unassigned
1545 my @viacode;            # Contains the 1 million character names
1546 my @printable;          # boolean: And are those characters printable?
1547 my @annotate_char_type; # Contains a type of those characters, specifically
1548                         # for the purposes of annotation.
1549 my $annotate_ranges;    # A map of ranges of code points that have the same
1550                         # name for the purposes of annotation.  They map to the
1551                         # upper edge of the range, so that the end point can
1552                         # be immediately found.  This is used to skip ahead to
1553                         # the end of a range, and avoid processing each
1554                         # individual code point in it.
1555 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1556                                    # characters, but excluding those which are
1557                                    # also noncharacter code points
1558
1559 # The annotation types are an extension of the regular range types, though
1560 # some of the latter are folded into one.  Make the new types negative to
1561 # avoid conflicting with the regular types
1562 my $SURROGATE_TYPE = -1;
1563 my $UNASSIGNED_TYPE = -2;
1564 my $PRIVATE_USE_TYPE = -3;
1565 my $NONCHARACTER_TYPE = -4;
1566 my $CONTROL_TYPE = -5;
1567 my $ABOVE_UNICODE_TYPE = -6;
1568 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1569
1570 sub populate_char_info ($) {
1571     # Used only with the $annotate option.  Populates the arrays with the
1572     # input code point's info that are needed for outputting more detailed
1573     # comments.  If calling context wants a return, it is the end point of
1574     # any contiguous range of characters that share essentially the same info
1575
1576     my $i = shift;
1577     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1578
1579     $viacode[$i] = $perl_charname->value_of($i) || "";
1580
1581     # A character is generally printable if Unicode says it is,
1582     # but below we make sure that most Unicode general category 'C' types
1583     # aren't.
1584     $printable[$i] = $print->contains($i);
1585
1586     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1587
1588     # Only these two regular types are treated specially for annotations
1589     # purposes
1590     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1591                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1592
1593     # Give a generic name to all code points that don't have a real name.
1594     # We output ranges, if applicable, for these.  Also calculate the end
1595     # point of the range.
1596     my $end;
1597     if (! $viacode[$i]) {
1598         my $nonchar;
1599         if ($i > $MAX_UNICODE_CODEPOINT) {
1600             $viacode[$i] = 'Above-Unicode';
1601             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1602             $printable[$i] = 0;
1603             $end = $MAX_WORKING_CODEPOINT;
1604         }
1605         elsif ($gc-> table('Private_use')->contains($i)) {
1606             $viacode[$i] = 'Private Use';
1607             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1608             $printable[$i] = 0;
1609             $end = $gc->table('Private_Use')->containing_range($i)->end;
1610         }
1611         elsif ((defined ($nonchar =
1612                             Property::property_ref('Noncharacter_Code_Point'))
1613                && $nonchar->table('Y')->contains($i)))
1614         {
1615             $viacode[$i] = 'Noncharacter';
1616             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1617             $printable[$i] = 0;
1618             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1619                                                     containing_range($i)->end;
1620         }
1621         elsif ($gc-> table('Control')->contains($i)) {
1622             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1623             $annotate_char_type[$i] = $CONTROL_TYPE;
1624             $printable[$i] = 0;
1625         }
1626         elsif ($gc-> table('Unassigned')->contains($i)) {
1627             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1628             $printable[$i] = 0;
1629             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1630                 $viacode[$i] = 'Unassigned';
1631                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1632             }
1633             else {
1634                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1635
1636                 # Because we name the unassigned by the blocks they are in, it
1637                 # can't go past the end of that block, and it also can't go
1638                 # past the unassigned range it is in.  The special table makes
1639                 # sure that the non-characters, which are unassigned, are
1640                 # separated out.
1641                 $end = min($block->containing_range($i)->end,
1642                            $unassigned_sans_noncharacters->
1643                                                     containing_range($i)->end);
1644             }
1645         }
1646         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1647             $viacode[$i] = 'Surrogate';
1648             $annotate_char_type[$i] = $SURROGATE_TYPE;
1649             $printable[$i] = 0;
1650             $end = $gc->table('Surrogate')->containing_range($i)->end;
1651         }
1652         else {
1653             Carp::my_carp_bug("Can't figure out how to annotate "
1654                               . sprintf("U+%04X", $i)
1655                               . ".  Proceeding anyway.");
1656             $viacode[$i] = 'UNKNOWN';
1657             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1658             $printable[$i] = 0;
1659         }
1660     }
1661
1662     # Here, has a name, but if it's one in which the code point number is
1663     # appended to the name, do that.
1664     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1665         $viacode[$i] .= sprintf("-%04X", $i);
1666         $end = $perl_charname->containing_range($i)->end;
1667     }
1668
1669     # And here, has a name, but if it's a hangul syllable one, replace it with
1670     # the correct name from the Unicode algorithm
1671     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1672         use integer;
1673         my $SIndex = $i - $SBase;
1674         my $L = $LBase + $SIndex / $NCount;
1675         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1676         my $T = $TBase + $SIndex % $TCount;
1677         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1678         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1679         $end = $perl_charname->containing_range($i)->end;
1680     }
1681
1682     return if ! defined wantarray;
1683     return $i if ! defined $end;    # If not a range, return the input
1684
1685     # Save this whole range so can find the end point quickly
1686     $annotate_ranges->add_map($i, $end, $end);
1687
1688     return $end;
1689 }
1690
1691 # Commented code below should work on Perl 5.8.
1692 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1693 ## the native perl version of it (which is what would operate under miniperl)
1694 ## is extremely slow, as it does a string eval every call.
1695 #my $has_fast_scalar_util = $^X !~ /miniperl/
1696 #                            && defined eval "require Scalar::Util";
1697 #
1698 #sub objaddr($) {
1699 #    # Returns the address of the blessed input object.  Uses the XS version if
1700 #    # available.  It doesn't check for blessedness because that would do a
1701 #    # string eval every call, and the program is structured so that this is
1702 #    # never called for a non-blessed object.
1703 #
1704 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1705 #
1706 #    # Check at least that is a ref.
1707 #    my $pkg = ref($_[0]) or return undef;
1708 #
1709 #    # Change to a fake package to defeat any overloaded stringify
1710 #    bless $_[0], 'main::Fake';
1711 #
1712 #    # Numifying a ref gives its address.
1713 #    my $addr = pack 'J', $_[0];
1714 #
1715 #    # Return to original class
1716 #    bless $_[0], $pkg;
1717 #    return $addr;
1718 #}
1719
1720 sub max ($$) {
1721     my $a = shift;
1722     my $b = shift;
1723     return $a if $a >= $b;
1724     return $b;
1725 }
1726
1727 sub min ($$) {
1728     my $a = shift;
1729     my $b = shift;
1730     return $a if $a <= $b;
1731     return $b;
1732 }
1733
1734 sub clarify_number ($) {
1735     # This returns the input number with underscores inserted every 3 digits
1736     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1737     # checked.
1738
1739     my $number = shift;
1740     my $pos = length($number) - 3;
1741     return $number if $pos <= 1;
1742     while ($pos > 0) {
1743         substr($number, $pos, 0) = '_';
1744         $pos -= 3;
1745     }
1746     return $number;
1747 }
1748
1749 sub clarify_code_point_count ($) {
1750     # This is like clarify_number(), but the input is assumed to be a count of
1751     # code points, rather than a generic number.
1752
1753     my $append = "";
1754
1755     my $number = shift;
1756     if ($number > $MAX_UNICODE_CODEPOINTS) {
1757         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1758         return "All above-Unicode code points" if $number == 0;
1759         $append = " + all above-Unicode code points";
1760     }
1761     return clarify_number($number) . $append;
1762 }
1763
1764 package Carp;
1765
1766 # These routines give a uniform treatment of messages in this program.  They
1767 # are placed in the Carp package to cause the stack trace to not include them,
1768 # although an alternative would be to use another package and set @CARP_NOT
1769 # for it.
1770
1771 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1772
1773 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1774 # and overload trying to load Scalar:Util under miniperl.  See
1775 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1776 undef $overload::VERSION;
1777
1778 sub my_carp {
1779     my $message = shift || "";
1780     my $nofold = shift || 0;
1781
1782     if ($message) {
1783         $message = main::join_lines($message);
1784         $message =~ s/^$0: *//;     # Remove initial program name
1785         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1786         $message = "\n$0: $message;";
1787
1788         # Fold the message with program name, semi-colon end punctuation
1789         # (which looks good with the message that carp appends to it), and a
1790         # hanging indent for continuation lines.
1791         $message = main::simple_fold($message, "", 4) unless $nofold;
1792         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1793                                     # appends is to the same line
1794     }
1795
1796     return $message if defined wantarray;   # If a caller just wants the msg
1797
1798     carp $message;
1799     return;
1800 }
1801
1802 sub my_carp_bug {
1803     # This is called when it is clear that the problem is caused by a bug in
1804     # this program.
1805
1806     my $message = shift;
1807     $message =~ s/^$0: *//;
1808     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1809     carp $message;
1810     return;
1811 }
1812
1813 sub carp_too_few_args {
1814     if (@_ != 2) {
1815         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1816         return;
1817     }
1818
1819     my $args_ref = shift;
1820     my $count = shift;
1821
1822     my_carp_bug("Need at least $count arguments to "
1823         . (caller 1)[3]
1824         . ".  Instead got: '"
1825         . join ', ', @$args_ref
1826         . "'.  No action taken.");
1827     return;
1828 }
1829
1830 sub carp_extra_args {
1831     my $args_ref = shift;
1832     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1833
1834     unless (ref $args_ref) {
1835         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1836         return;
1837     }
1838     my ($package, $file, $line) = caller;
1839     my $subroutine = (caller 1)[3];
1840
1841     my $list;
1842     if (ref $args_ref eq 'HASH') {
1843         foreach my $key (keys %$args_ref) {
1844             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1845         }
1846         $list = join ', ', each %{$args_ref};
1847     }
1848     elsif (ref $args_ref eq 'ARRAY') {
1849         foreach my $arg (@$args_ref) {
1850             $arg = $UNDEF unless defined $arg;
1851         }
1852         $list = join ', ', @$args_ref;
1853     }
1854     else {
1855         my_carp_bug("Can't cope with ref "
1856                 . ref($args_ref)
1857                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1858         return;
1859     }
1860
1861     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1862     return;
1863 }
1864
1865 package main;
1866
1867 { # Closure
1868
1869     # This program uses the inside-out method for objects, as recommended in
1870     # "Perl Best Practices".  (This is the best solution still, since this has
1871     # to run under miniperl.)  This closure aids in generating those.  There
1872     # are two routines.  setup_package() is called once per package to set
1873     # things up, and then set_access() is called for each hash representing a
1874     # field in the object.  These routines arrange for the object to be
1875     # properly destroyed when no longer used, and for standard accessor
1876     # functions to be generated.  If you need more complex accessors, just
1877     # write your own and leave those accesses out of the call to set_access().
1878     # More details below.
1879
1880     my %constructor_fields; # fields that are to be used in constructors; see
1881                             # below
1882
1883     # The values of this hash will be the package names as keys to other
1884     # hashes containing the name of each field in the package as keys, and
1885     # references to their respective hashes as values.
1886     my %package_fields;
1887
1888     sub setup_package {
1889         # Sets up the package, creating standard DESTROY and dump methods
1890         # (unless already defined).  The dump method is used in debugging by
1891         # simple_dumper().
1892         # The optional parameters are:
1893         #   a)  a reference to a hash, that gets populated by later
1894         #       set_access() calls with one of the accesses being
1895         #       'constructor'.  The caller can then refer to this, but it is
1896         #       not otherwise used by these two routines.
1897         #   b)  a reference to a callback routine to call during destruction
1898         #       of the object, before any fields are actually destroyed
1899
1900         my %args = @_;
1901         my $constructor_ref = delete $args{'Constructor_Fields'};
1902         my $destroy_callback = delete $args{'Destroy_Callback'};
1903         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1904
1905         my %fields;
1906         my $package = (caller)[0];
1907
1908         $package_fields{$package} = \%fields;
1909         $constructor_fields{$package} = $constructor_ref;
1910
1911         unless ($package->can('DESTROY')) {
1912             my $destroy_name = "${package}::DESTROY";
1913             no strict "refs";
1914
1915             # Use typeglob to give the anonymous subroutine the name we want
1916             *$destroy_name = sub {
1917                 my $self = shift;
1918                 my $addr = do { no overloading; pack 'J', $self; };
1919
1920                 $self->$destroy_callback if $destroy_callback;
1921                 foreach my $field (keys %{$package_fields{$package}}) {
1922                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1923                     delete $package_fields{$package}{$field}{$addr};
1924                 }
1925                 return;
1926             }
1927         }
1928
1929         unless ($package->can('dump')) {
1930             my $dump_name = "${package}::dump";
1931             no strict "refs";
1932             *$dump_name = sub {
1933                 my $self = shift;
1934                 return dump_inside_out($self, $package_fields{$package}, @_);
1935             }
1936         }
1937         return;
1938     }
1939
1940     sub set_access {
1941         # Arrange for the input field to be garbage collected when no longer
1942         # needed.  Also, creates standard accessor functions for the field
1943         # based on the optional parameters-- none if none of these parameters:
1944         #   'addable'    creates an 'add_NAME()' accessor function.
1945         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1946         #                function.
1947         #   'settable'   creates a 'set_NAME()' accessor function.
1948         #   'constructor' doesn't create an accessor function, but adds the
1949         #                field to the hash that was previously passed to
1950         #                setup_package();
1951         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1952         # 'add' etc. all mean 'addable'.
1953         # The read accessor function will work on both array and scalar
1954         # values.  If another accessor in the parameter list is 'a', the read
1955         # access assumes an array.  You can also force it to be array access
1956         # by specifying 'readable_array' instead of 'readable'
1957         #
1958         # A sort-of 'protected' access can be set-up by preceding the addable,
1959         # readable or settable with some initial portion of 'protected_' (but,
1960         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1961         # "protection" is only by convention.  All that happens is that the
1962         # accessor functions' names begin with an underscore.  So instead of
1963         # calling set_foo, the call is _set_foo.  (Real protection could be
1964         # accomplished by having a new subroutine, end_package, called at the
1965         # end of each package, and then storing the __LINE__ ranges and
1966         # checking them on every accessor.  But that is way overkill.)
1967
1968         # We create anonymous subroutines as the accessors and then use
1969         # typeglobs to assign them to the proper package and name
1970
1971         my $name = shift;   # Name of the field
1972         my $field = shift;  # Reference to the inside-out hash containing the
1973                             # field
1974
1975         my $package = (caller)[0];
1976
1977         if (! exists $package_fields{$package}) {
1978             croak "$0: Must call 'setup_package' before 'set_access'";
1979         }
1980
1981         # Stash the field so DESTROY can get it.
1982         $package_fields{$package}{$name} = $field;
1983
1984         # Remaining arguments are the accessors.  For each...
1985         foreach my $access (@_) {
1986             my $access = lc $access;
1987
1988             my $protected = "";
1989
1990             # Match the input as far as it goes.
1991             if ($access =~ /^(p[^_]*)_/) {
1992                 $protected = $1;
1993                 if (substr('protected_', 0, length $protected)
1994                     eq $protected)
1995                 {
1996
1997                     # Add 1 for the underscore not included in $protected
1998                     $access = substr($access, length($protected) + 1);
1999                     $protected = '_';
2000                 }
2001                 else {
2002                     $protected = "";
2003                 }
2004             }
2005
2006             if (substr('addable', 0, length $access) eq $access) {
2007                 my $subname = "${package}::${protected}add_$name";
2008                 no strict "refs";
2009
2010                 # add_ accessor.  Don't add if already there, which we
2011                 # determine using 'eq' for scalars and '==' otherwise.
2012                 *$subname = sub {
2013                     use strict "refs";
2014                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2015                     my $self = shift;
2016                     my $value = shift;
2017                     my $addr = do { no overloading; pack 'J', $self; };
2018                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2019                     if (ref $value) {
2020                         return if grep { $value == $_ } @{$field->{$addr}};
2021                     }
2022                     else {
2023                         return if grep { $value eq $_ } @{$field->{$addr}};
2024                     }
2025                     push @{$field->{$addr}}, $value;
2026                     return;
2027                 }
2028             }
2029             elsif (substr('constructor', 0, length $access) eq $access) {
2030                 if ($protected) {
2031                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2032                 }
2033                 else {
2034                     $constructor_fields{$package}{$name} = $field;
2035                 }
2036             }
2037             elsif (substr('readable_array', 0, length $access) eq $access) {
2038
2039                 # Here has read access.  If one of the other parameters for
2040                 # access is array, or this one specifies array (by being more
2041                 # than just 'readable_'), then create a subroutine that
2042                 # assumes the data is an array.  Otherwise just a scalar
2043                 my $subname = "${package}::${protected}$name";
2044                 if (grep { /^a/i } @_
2045                     or length($access) > length('readable_'))
2046                 {
2047                     no strict "refs";
2048                     *$subname = sub {
2049                         use strict "refs";
2050                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2051                         my $addr = do { no overloading; pack 'J', $_[0]; };
2052                         if (ref $field->{$addr} ne 'ARRAY') {
2053                             my $type = ref $field->{$addr};
2054                             $type = 'scalar' unless $type;
2055                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2056                             return;
2057                         }
2058                         return scalar @{$field->{$addr}} unless wantarray;
2059
2060                         # Make a copy; had problems with caller modifying the
2061                         # original otherwise
2062                         my @return = @{$field->{$addr}};
2063                         return @return;
2064                     }
2065                 }
2066                 else {
2067
2068                     # Here not an array value, a simpler function.
2069                     no strict "refs";
2070                     *$subname = sub {
2071                         use strict "refs";
2072                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2073                         no overloading;
2074                         return $field->{pack 'J', $_[0]};
2075                     }
2076                 }
2077             }
2078             elsif (substr('settable', 0, length $access) eq $access) {
2079                 my $subname = "${package}::${protected}set_$name";
2080                 no strict "refs";
2081                 *$subname = sub {
2082                     use strict "refs";
2083                     if (main::DEBUG) {
2084                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2085                         Carp::carp_extra_args(\@_) if @_ > 2;
2086                     }
2087                     # $self is $_[0]; $value is $_[1]
2088                     no overloading;
2089                     $field->{pack 'J', $_[0]} = $_[1];
2090                     return;
2091                 }
2092             }
2093             else {
2094                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2095             }
2096         }
2097         return;
2098     }
2099 }
2100
2101 package Input_file;
2102
2103 # All input files use this object, which stores various attributes about them,
2104 # and provides for convenient, uniform handling.  The run method wraps the
2105 # processing.  It handles all the bookkeeping of opening, reading, and closing
2106 # the file, returning only significant input lines.
2107 #
2108 # Each object gets a handler which processes the body of the file, and is
2109 # called by run().  All character property files must use the generic,
2110 # default handler, which has code scrubbed to handle things you might not
2111 # expect, including automatic EBCDIC handling.  For files that don't deal with
2112 # mapping code points to a property value, such as test files,
2113 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2114 # handler to be a custom one.  Such a handler should basically be a
2115 # while(next_line()) {...} loop.
2116 #
2117 # You can also set up handlers to
2118 #   1) call before the first line is read, for pre processing
2119 #   2) call to adjust each line of the input before the main handler gets
2120 #      them.  This can be automatically generated, if appropriately simple
2121 #      enough, by specifiying a Properties parameter in the constructor.
2122 #   3) call upon EOF before the main handler exits its loop
2123 #   4) call at the end, for post processing
2124 #
2125 # $_ is used to store the input line, and is to be filtered by the
2126 # each_line_handler()s.  So, if the format of the line is not in the desired
2127 # format for the main handler, these are used to do that adjusting.  They can
2128 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2129 # so the $_ output of one is used as the input to the next.  The eof handler
2130 # is also stackable, but none of the others are, but could easily be changed
2131 # to be so.
2132 #
2133 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2134 # which insert the parameters as lines to be processed before the next input
2135 # file line is read.  This allows the EOF handler(s) to flush buffers, for
2136 # example.  The difference between the two routines is that the lines inserted
2137 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2138 # called it from such a handler, you would get infinite recursion without some
2139 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2140 # directly to the main handler without any adjustments.  If the
2141 # post-processing handler calls any of these, there will be no effect.  Some
2142 # error checking for these conditions could be added, but it hasn't been done.
2143 #
2144 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2145 # to prevent further processing of the line.  This routine will output the
2146 # message as a warning once, and then keep a count of the lines that have the
2147 # same message, and output that count at the end of the file's processing.
2148 # This keeps the number of messages down to a manageable amount.
2149 #
2150 # get_missings() should be called to retrieve any @missing input lines.
2151 # Messages will be raised if this isn't done if the options aren't to ignore
2152 # missings.
2153
2154 sub trace { return main::trace(@_); }
2155
2156 { # Closure
2157     # Keep track of fields that are to be put into the constructor.
2158     my %constructor_fields;
2159
2160     main::setup_package(Constructor_Fields => \%constructor_fields);
2161
2162     my %file; # Input file name, required
2163     main::set_access('file', \%file, qw{ c r });
2164
2165     my %first_released; # Unicode version file was first released in, required
2166     main::set_access('first_released', \%first_released, qw{ c r });
2167
2168     my %handler;    # Subroutine to process the input file, defaults to
2169                     # 'process_generic_property_file'
2170     main::set_access('handler', \%handler, qw{ c });
2171
2172     my %property;
2173     # name of property this file is for.  defaults to none, meaning not
2174     # applicable, or is otherwise determinable, for example, from each line.
2175     main::set_access('property', \%property, qw{ c r });
2176
2177     my %optional;
2178     # If this is true, the file is optional.  If not present, no warning is
2179     # output.  If it is present, the string given by this parameter is
2180     # evaluated, and if false the file is not processed.
2181     main::set_access('optional', \%optional, 'c', 'r');
2182
2183     my %non_skip;
2184     # This is used for debugging, to skip processing of all but a few input
2185     # files.  Add 'non_skip => 1' to the constructor for those files you want
2186     # processed when you set the $debug_skip global.
2187     main::set_access('non_skip', \%non_skip, 'c');
2188
2189     my %skip;
2190     # This is used to skip processing of this input file (semi-) permanently.
2191     # The value should be the reason the file is being skipped.  It is used
2192     # for files that we aren't planning to process anytime soon, but want to
2193     # allow to be in the directory and be checked for their names not
2194     # conflicting with any other files on a DOS 8.3 name filesystem, but to
2195     # not otherwise be processed, and to not raise a warning about not being
2196     # handled.  In the constructor call, any value that evaluates to a numeric
2197     # 0 or undef means don't skip.  Any other value is a string giving the
2198     # reason it is being skippped, and this will appear in generated pod.
2199     # However, an empty string reason will suppress the pod entry.
2200     # Internally, calls that evaluate to numeric 0 are changed into undef to
2201     # distinguish them from an empty string call.
2202     main::set_access('skip', \%skip, 'c', 'r');
2203
2204     my %each_line_handler;
2205     # list of subroutines to look at and filter each non-comment line in the
2206     # file.  defaults to none.  The subroutines are called in order, each is
2207     # to adjust $_ for the next one, and the final one adjusts it for
2208     # 'handler'
2209     main::set_access('each_line_handler', \%each_line_handler, 'c');
2210
2211     my %properties; # Optional ordered list of the properties that occur in each
2212     # meaningful line of the input file.  If present, an appropriate
2213     # each_line_handler() is automatically generated and pushed onto the stack
2214     # of such handlers.  This is useful when a file contains multiple
2215     # proerties per line, but no other special considerations are necessary.
2216     # The special value "<ignored>" means to discard the corresponding input
2217     # field.
2218     # Any @missing lines in the file should also match this syntax; no such
2219     # files exist as of 6.3.  But if it happens in a future release, the code
2220     # could be expanded to properly parse them.
2221     main::set_access('properties', \%properties, qw{ c r });
2222
2223     my %has_missings_defaults;
2224     # ? Are there lines in the file giving default values for code points
2225     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2226     # the norm, but IGNORED means it has such lines, but the handler doesn't
2227     # use them.  Having these three states allows us to catch changes to the
2228     # UCD that this program should track.  XXX This could be expanded to
2229     # specify the syntax for such lines, like %properties above.
2230     main::set_access('has_missings_defaults',
2231                                         \%has_missings_defaults, qw{ c r });
2232
2233     my %pre_handler;
2234     # Subroutine to call before doing anything else in the file.  If undef, no
2235     # such handler is called.
2236     main::set_access('pre_handler', \%pre_handler, qw{ c });
2237
2238     my %eof_handler;
2239     # Subroutines to call upon getting an EOF on the input file, but before
2240     # that is returned to the main handler.  This is to allow buffers to be
2241     # flushed.  The handler is expected to call insert_lines() or
2242     # insert_adjusted() with the buffered material
2243     main::set_access('eof_handler', \%eof_handler, qw{ c });
2244
2245     my %post_handler;
2246     # Subroutine to call after all the lines of the file are read in and
2247     # processed.  If undef, no such handler is called.  Note that this cannot
2248     # add lines to be processed; instead use eof_handler
2249     main::set_access('post_handler', \%post_handler, qw{ c });
2250
2251     my %progress_message;
2252     # Message to print to display progress in lieu of the standard one
2253     main::set_access('progress_message', \%progress_message, qw{ c });
2254
2255     my %handle;
2256     # cache open file handle, internal.  Is undef if file hasn't been
2257     # processed at all, empty if has;
2258     main::set_access('handle', \%handle);
2259
2260     my %added_lines;
2261     # cache of lines added virtually to the file, internal
2262     main::set_access('added_lines', \%added_lines);
2263
2264     my %remapped_lines;
2265     # cache of lines added virtually to the file, internal
2266     main::set_access('remapped_lines', \%remapped_lines);
2267
2268     my %errors;
2269     # cache of errors found, internal
2270     main::set_access('errors', \%errors);
2271
2272     my %missings;
2273     # storage of '@missing' defaults lines
2274     main::set_access('missings', \%missings);
2275
2276     my %required_even_in_debug_skip;
2277     # debug_skip is used to speed up compilation during debugging by skipping
2278     # processing files that are not needed for the task at hand.  However,
2279     # some files pretty much can never be skipped, and this is used to specify
2280     # that this is one of them.  In order to skip this file, the call to the
2281     # constructor must be edited to comment out this parameter.
2282     main::set_access('required_even_in_debug_skip',
2283                      \%required_even_in_debug_skip, 'c');
2284
2285     my %withdrawn;
2286     # Some files get removed from the Unicode DB.  This is a version object
2287     # giving the first release without this file.
2288     main::set_access('withdrawn', \%withdrawn, 'c');
2289
2290     my %in_this_release;
2291     # Calculated value from %first_released and %withdrawn.  Are we compiling
2292     # a Unicode release which includes this file?
2293     main::set_access('in_this_release', \%in_this_release);
2294
2295     sub _next_line;
2296     sub _next_line_with_remapped_range;
2297
2298     sub new {
2299         my $class = shift;
2300
2301         my $self = bless \do{ my $anonymous_scalar }, $class;
2302         my $addr = do { no overloading; pack 'J', $self; };
2303
2304         # Set defaults
2305         $handler{$addr} = \&main::process_generic_property_file;
2306         $non_skip{$addr} = 0;
2307         $skip{$addr} = undef;
2308         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2309         $handle{$addr} = undef;
2310         $added_lines{$addr} = [ ];
2311         $remapped_lines{$addr} = [ ];
2312         $each_line_handler{$addr} = [ ];
2313         $eof_handler{$addr} = [ ];
2314         $errors{$addr} = { };
2315         $missings{$addr} = [ ];
2316
2317         # Two positional parameters.
2318         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2319         $file{$addr} = main::internal_file_to_platform(shift);
2320         $first_released{$addr} = shift;
2321
2322         # The rest of the arguments are key => value pairs
2323         # %constructor_fields has been set up earlier to list all possible
2324         # ones.  Either set or push, depending on how the default has been set
2325         # up just above.
2326         my %args = @_;
2327         foreach my $key (keys %args) {
2328             my $argument = $args{$key};
2329
2330             # Note that the fields are the lower case of the constructor keys
2331             my $hash = $constructor_fields{lc $key};
2332             if (! defined $hash) {
2333                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2334                 next;
2335             }
2336             if (ref $hash->{$addr} eq 'ARRAY') {
2337                 if (ref $argument eq 'ARRAY') {
2338                     foreach my $argument (@{$argument}) {
2339                         next if ! defined $argument;
2340                         push @{$hash->{$addr}}, $argument;
2341                     }
2342                 }
2343                 else {
2344                     push @{$hash->{$addr}}, $argument if defined $argument;
2345                 }
2346             }
2347             else {
2348                 $hash->{$addr} = $argument;
2349             }
2350             delete $args{$key};
2351         };
2352
2353         $non_skip{$addr} = 1 if $required_even_in_debug_skip{$addr};
2354
2355         # Convert 0 (meaning don't skip) to undef
2356         undef $skip{$addr} unless $skip{$addr};
2357
2358         my $progress;
2359
2360         if ($first_released{$addr} le $v_version) {
2361             $progress = $file{$addr};
2362         }
2363
2364         my $file = $file{$addr};
2365         $progress_message{$addr} = "Processing $progress"
2366                                             unless $progress_message{$addr};
2367
2368         # A file should be there if it is within the window of versions for
2369         # which Unicode supplies it
2370         if ($withdrawn{$addr} && $withdrawn{$addr} le $v_version) {
2371             $in_this_release{$addr} = 0;
2372             $skip{$addr} = "";
2373         }
2374         else {
2375             $in_this_release{$addr} = $first_released{$addr} le $v_version;
2376
2377             # Check that the file for this object exists
2378             if (! main::file_exists($file))
2379             {
2380                 # Here there is nothing available for this release.  This is
2381                 # fine if we aren't expecting anything in this release.
2382                 if (! $in_this_release{$addr}) {
2383                     $skip{$addr} = "";  # Don't remark since we expected
2384                                         # nothing and got nothing
2385                 }
2386                 elsif ($optional{$addr}) {
2387
2388                     # Here the file is optional in this release.
2389                     $skip{$addr} = "";
2390                 }
2391                 elsif (   $in_this_release{$addr}
2392                        && ! defined $skip{$addr}
2393                        && defined $file)
2394                 { # Doesn't exist but should.
2395                     $skip{$addr} = "'$file' not found.  Possibly Big problems";
2396                     Carp::my_carp($skip{$addr});
2397                 }
2398             }
2399             elsif ($debug_skip && ! defined $skip{$addr} && ! $non_skip{$addr})
2400             {
2401
2402                 # The file exists; if not skipped for another reason, and we are
2403                 # skipping most everything during debugging builds, use that as
2404                 # the skip reason.
2405                 $skip{$addr} = '$debug_skip is on'
2406             }
2407         }
2408
2409         if (   ! $debug_skip
2410             && $non_skip{$addr}
2411             && ! $required_even_in_debug_skip{$addr}
2412             && $verbosity)
2413         {
2414             print "Warning: " . __PACKAGE__ . " constructor for $file has useless 'non_skip' in it\n";
2415         }
2416
2417         # Here, we have figured out if we will be skipping this file or not.
2418         if (defined $skip{$addr}) {
2419         }
2420         elsif ($property{$addr}) {
2421
2422             # If the file has a property defined in the constructor for it, it
2423             # means that the property is not listed in the file's entries.  So
2424             # add a handler (to the list of line handlers) to insert the
2425             # property name into the lines, to provide a uniform interface to
2426             # the final processing subroutine.
2427             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2428         }
2429         elsif ($properties{$addr}) {
2430
2431             # Similarly, there may be more than one property represented on
2432             # each line, with no clue but the constructor input what those
2433             # might be.  Add a handler for each line in the input so that it
2434             # creates a separate input line for each property in those input
2435             # lines, thus making them suitable to handle generically.
2436
2437             push @{$each_line_handler{$addr}},
2438                  sub {
2439                     my $file = shift;
2440                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2441
2442                     my @fields = split /\s*;\s*/, $_, -1;
2443
2444                     if (@fields - 1 > @{$properties{$addr}}) {
2445                         $file->carp_bad_line('Extra fields');
2446                         $_ = "";
2447                         return;
2448                     }
2449                     my $range = shift @fields;  # 0th element is always the
2450                                                 # range
2451
2452                     # The next fields in the input line correspond
2453                     # respectively to the stored properties.
2454                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2455                         my $property_name = $properties{$addr}[$i];
2456                         next if $property_name eq '<ignored>';
2457                         $file->insert_adjusted_lines(
2458                               "$range; $property_name; $fields[$i]");
2459                     }
2460                     $_ = "";
2461
2462                     return;
2463                 };
2464         }
2465
2466         {   # On non-ascii platforms, we use a special pre-handler
2467             no strict;
2468             no warnings 'once';
2469             *next_line = (main::NON_ASCII_PLATFORM)
2470                          ? *_next_line_with_remapped_range
2471                          : *_next_line;
2472         }
2473
2474         return $self;
2475     }
2476
2477
2478     use overload
2479         fallback => 0,
2480         qw("") => "_operator_stringify",
2481         "." => \&main::_operator_dot,
2482         ".=" => \&main::_operator_dot_equal,
2483     ;
2484
2485     sub _operator_stringify {
2486         my $self = shift;
2487
2488         return __PACKAGE__ . " object for " . $self->file;
2489     }
2490
2491     sub run {
2492         # Process the input object $self.  This opens and closes the file and
2493         # calls all the handlers for it.  Currently,  this can only be called
2494         # once per file, as it destroy's the EOF handlers
2495
2496         # flag to make sure extracted files are processed early
2497         state $seen_non_extracted_non_age = 0;
2498
2499         my $self = shift;
2500         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2501
2502         my $addr = do { no overloading; pack 'J', $self; };
2503
2504         my $file = $file{$addr};
2505
2506         if (! $file) {
2507             $handle{$addr} = 'pretend_is_open';
2508         }
2509         else {
2510             if ($seen_non_extracted_non_age) {
2511                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2512                                             # case of the file's name
2513                 {
2514                     Carp::my_carp_bug(main::join_lines(<<END
2515 $file should be processed just after the 'Prop...Alias' files, and before
2516 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2517 have subtle problems
2518 END
2519                     ));
2520                 }
2521             }
2522             elsif ($EXTRACTED_DIR
2523
2524                     # We only do this check for generic property files
2525                     && $handler{$addr} == \&main::process_generic_property_file
2526
2527                     && $file !~ /$EXTRACTED/i
2528                     && lc($file) ne 'dage.txt')
2529             {
2530                 # We don't set this (by the 'if' above) if we have no
2531                 # extracted directory, so if running on an early version,
2532                 # this test won't work.  Not worth worrying about.
2533                 $seen_non_extracted_non_age = 1;
2534             }
2535
2536             # Mark the file as having being processed, and warn if it
2537             # isn't a file we are expecting.  As we process the files,
2538             # they are deleted from the hash, so any that remain at the
2539             # end of the program are files that we didn't process.
2540             my $fkey = File::Spec->rel2abs($file);
2541             my $exists = delete $potential_files{lc($fkey)};
2542
2543             Carp::my_carp("Was not expecting '$file'.")
2544                                     if $exists && ! $in_this_release{$addr};
2545
2546             # We may be skipping this file ...
2547             if (defined $skip{$addr}) {
2548
2549                 # If the file isn't supposed to be in this release, there is
2550                 # nothing to do
2551                 if ($in_this_release{$addr}) {
2552
2553                     # But otherwise, we may print a message
2554                     if ($debug_skip) {
2555                         print STDERR "Skipping input file '$file'",
2556                                      " because '$skip{$addr}'\n";
2557                     }
2558
2559                     # And add it to the list of skipped files, which is later
2560                     # used to make the pod
2561                     $skipped_files{$file} = $skip{$addr};
2562                 }
2563
2564                 return;
2565             }
2566
2567             # Here, we are going to process the file.  Open it, converting the
2568             # slashes used in this program into the proper form for the OS
2569             my $file_handle;
2570             if (not open $file_handle, "<", $file) {
2571                 Carp::my_carp("Can't open $file.  Skipping: $!");
2572                 return;
2573             }
2574             $handle{$addr} = $file_handle; # Cache the open file handle
2575
2576             # If possible, make sure that the file is the correct version.
2577             # (This data isn't available on early Unicode releases or in
2578             # UnicodeData.txt.)  We don't do this check if we are using a
2579             # substitute file instead of the official one (though the code
2580             # could be extended to do so).
2581             if ($in_this_release{$addr}
2582                 && lc($file) ne 'unicodedata.txt')
2583             {
2584                 if ($file !~ /^Unihan/i) {
2585
2586                     # The non-Unihan files started getting version numbers in
2587                     # 3.2, but some files in 4.0 are unchanged from 3.2, and
2588                     # marked as 3.2.  4.0.1 is the first version where there
2589                     # are no files marked as being from less than 4.0, though
2590                     # some are marked as 4.0.  In versions after that, the
2591                     # numbers are correct.
2592                     if ($v_version ge v4.0.1) {
2593                         $_ = <$file_handle>;    # The version number is in the
2594                                                 # very first line
2595                         if ($_ !~ / - $string_version \. /x) {
2596                             chomp;
2597                             $_ =~ s/^#\s*//;
2598
2599                             # 4.0.1 had some valid files that weren't updated.
2600                             if (! ($v_version eq v4.0.1 && $_ =~ /4\.0\.0/)) {
2601                                 die Carp::my_carp("File '$file' is version "
2602                                                 . "'$_'.  It should be "
2603                                                 . "version $string_version");
2604                             }
2605                         }
2606                     }
2607                 }
2608                 elsif ($v_version ge v6.0.0) { # Unihan
2609
2610                     # Unihan files didn't get accurate version numbers until
2611                     # 6.0.  The version is somewhere in the first comment
2612                     # block
2613                     while (<$file_handle>) {
2614                         if ($_ !~ /^#/) {
2615                             Carp::my_carp_bug("Could not find the expected "
2616                                             . "version info in file '$file'");
2617                             last;
2618                         }
2619                         chomp;
2620                         $_ =~ s/^#\s*//;
2621                         next if $_ !~ / version: /x;
2622                         last if $_ =~ /$string_version/;
2623                         die Carp::my_carp("File '$file' is version "
2624                                         . "'$_'.  It should be "
2625                                         . "version $string_version");
2626                     }
2627                 }
2628             }
2629         }
2630
2631         print "$progress_message{$addr}\n" if $verbosity >= $PROGRESS;
2632
2633         # Call any special handler for before the file.
2634         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2635
2636         # Then the main handler
2637         &{$handler{$addr}}($self);
2638
2639         # Then any special post-file handler.
2640         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2641
2642         # If any errors have been accumulated, output the counts (as the first
2643         # error message in each class was output when it was encountered).
2644         if ($errors{$addr}) {
2645             my $total = 0;
2646             my $types = 0;
2647             foreach my $error (keys %{$errors{$addr}}) {
2648                 $total += $errors{$addr}->{$error};
2649                 delete $errors{$addr}->{$error};
2650                 $types++;
2651             }
2652             if ($total > 1) {
2653                 my $message
2654                         = "A total of $total lines had errors in $file.  ";
2655
2656                 $message .= ($types == 1)
2657                             ? '(Only the first one was displayed.)'
2658                             : '(Only the first of each type was displayed.)';
2659                 Carp::my_carp($message);
2660             }
2661         }
2662
2663         if (@{$missings{$addr}}) {
2664             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2665         }
2666
2667         # If a real file handle, close it.
2668         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2669                                                         ref $handle{$addr};
2670         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2671                                # the file, as opposed to undef
2672         return;
2673     }
2674
2675     sub _next_line {
2676         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2677         # if such a line exists.  'logical' means that any lines that have
2678         # been added via insert_lines() will be returned in $_ before the file
2679         # is read again.
2680
2681         my $self = shift;
2682         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2683
2684         my $addr = do { no overloading; pack 'J', $self; };
2685
2686         # Here the file is open (or if the handle is not a ref, is an open
2687         # 'virtual' file).  Get the next line; any inserted lines get priority
2688         # over the file itself.
2689         my $adjusted;
2690
2691         LINE:
2692         while (1) { # Loop until find non-comment, non-empty line
2693             #local $to_trace = 1 if main::DEBUG;
2694             my $inserted_ref = shift @{$added_lines{$addr}};
2695             if (defined $inserted_ref) {
2696                 ($adjusted, $_) = @{$inserted_ref};
2697                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2698                 return 1 if $adjusted;
2699             }
2700             else {
2701                 last if ! ref $handle{$addr}; # Don't read unless is real file
2702                 last if ! defined ($_ = readline $handle{$addr});
2703             }
2704             chomp;
2705             trace $_ if main::DEBUG && $to_trace;
2706
2707             # See if this line is the comment line that defines what property
2708             # value that code points that are not listed in the file should
2709             # have.  The format or existence of these lines is not guaranteed
2710             # by Unicode since they are comments, but the documentation says
2711             # that this was added for machine-readability, so probably won't
2712             # change.  This works starting in Unicode Version 5.0.  They look
2713             # like:
2714             #
2715             # @missing: 0000..10FFFF; Not_Reordered
2716             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2717             # @missing: 0000..10FFFF; ; NaN
2718             #
2719             # Save the line for a later get_missings() call.
2720             if (/$missing_defaults_prefix/) {
2721                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2722                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2723                 }
2724                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2725                     my @defaults = split /\s* ; \s*/x, $_;
2726
2727                     # The first field is the @missing, which ends in a
2728                     # semi-colon, so can safely shift.
2729                     shift @defaults;
2730
2731                     # Some of these lines may have empty field placeholders
2732                     # which get in the way.  An example is:
2733                     # @missing: 0000..10FFFF; ; NaN
2734                     # Remove them.  Process starting from the top so the
2735                     # splice doesn't affect things still to be looked at.
2736                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2737                         next if $defaults[$i] ne "";
2738                         splice @defaults, $i, 1;
2739                     }
2740
2741                     # What's left should be just the property (maybe) and the
2742                     # default.  Having only one element means it doesn't have
2743                     # the property.
2744                     my $default;
2745                     my $property;
2746                     if (@defaults >= 1) {
2747                         if (@defaults == 1) {
2748                             $default = $defaults[0];
2749                         }
2750                         else {
2751                             $property = $defaults[0];
2752                             $default = $defaults[1];
2753                         }
2754                     }
2755
2756                     if (@defaults < 1
2757                         || @defaults > 2
2758                         || ($default =~ /^</
2759                             && $default !~ /^<code *point>$/i
2760                             && $default !~ /^<none>$/i
2761                             && $default !~ /^<script>$/i))
2762                     {
2763                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2764                     }
2765                     else {
2766
2767                         # If the property is missing from the line, it should
2768                         # be the one for the whole file
2769                         $property = $property{$addr} if ! defined $property;
2770
2771                         # Change <none> to the null string, which is what it
2772                         # really means.  If the default is the code point
2773                         # itself, set it to <code point>, which is what
2774                         # Unicode uses (but sometimes they've forgotten the
2775                         # space)
2776                         if ($default =~ /^<none>$/i) {
2777                             $default = "";
2778                         }
2779                         elsif ($default =~ /^<code *point>$/i) {
2780                             $default = $CODE_POINT;
2781                         }
2782                         elsif ($default =~ /^<script>$/i) {
2783
2784                             # Special case this one.  Currently is from
2785                             # ScriptExtensions.txt, and means for all unlisted
2786                             # code points, use their Script property values.
2787                             # For the code points not listed in that file, the
2788                             # default value is 'Unknown'.
2789                             $default = "Unknown";
2790                         }
2791
2792                         # Store them as a sub-arrays with both components.
2793                         push @{$missings{$addr}}, [ $default, $property ];
2794                     }
2795                 }
2796
2797                 # There is nothing for the caller to process on this comment
2798                 # line.
2799                 next;
2800             }
2801
2802             # Remove comments and trailing space, and skip this line if the
2803             # result is empty
2804             s/#.*//;
2805             s/\s+$//;
2806             next if /^$/;
2807
2808             # Call any handlers for this line, and skip further processing of
2809             # the line if the handler sets the line to null.
2810             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2811                 &{$sub_ref}($self);
2812                 next LINE if /^$/;
2813             }
2814
2815             # Here the line is ok.  return success.
2816             return 1;
2817         } # End of looping through lines.
2818
2819         # If there are EOF handlers, call each (only once) and if it generates
2820         # more lines to process go back in the loop to handle them.
2821         while ($eof_handler{$addr}->@*) {
2822             &{$eof_handler{$addr}[0]}($self);
2823             shift $eof_handler{$addr}->@*;   # Currently only get one shot at it.
2824             goto LINE if $added_lines{$addr};
2825         }
2826
2827         # Return failure -- no more lines.
2828         return 0;
2829
2830     }
2831
2832     sub _next_line_with_remapped_range {
2833         my $self = shift;
2834         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2835
2836         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2837         # to be the next logical input line, if any.  Returns non-zero if such
2838         # a line exists.  'logical' means that any lines that have been added
2839         # via insert_lines() will be returned in $_ before the file is read
2840         # again.
2841         #
2842         # The difference from _next_line() is that this remaps the Unicode
2843         # code points in the input to those of the native platform.  Each
2844         # input line contains a single code point, or a single contiguous
2845         # range of them  This routine splits each range into its individual
2846         # code points and caches them.  It returns the cached values,
2847         # translated into their native equivalents, one at a time, for each
2848         # call, before reading the next line.  Since native values can only be
2849         # a single byte wide, no translation is needed for code points above
2850         # 0xFF, and ranges that are entirely above that number are not split.
2851         # If an input line contains the range 254-1000, it would be split into
2852         # three elements: 254, 255, and 256-1000.  (The downstream table
2853         # insertion code will sort and coalesce the individual code points
2854         # into appropriate ranges.)
2855
2856         my $addr = do { no overloading; pack 'J', $self; };
2857
2858         while (1) {
2859
2860             # Look in cache before reading the next line.  Return any cached
2861             # value, translated
2862             my $inserted = shift @{$remapped_lines{$addr}};
2863             if (defined $inserted) {
2864                 trace $inserted if main::DEBUG && $to_trace;
2865                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
2866                 trace $_ if main::DEBUG && $to_trace;
2867                 return 1;
2868             }
2869
2870             # Get the next line.
2871             return 0 unless _next_line($self);
2872
2873             # If there is a special handler for it, return the line,
2874             # untranslated.  This should happen only for files that are
2875             # special, not being code-point related, such as property names.
2876             return 1 if $handler{$addr}
2877                                     != \&main::process_generic_property_file;
2878
2879             my ($range, $property_name, $map, @remainder)
2880                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
2881
2882             if (@remainder
2883                 || ! defined $property_name
2884                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
2885             {
2886                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
2887             }
2888
2889             my $low = hex $1;
2890             my $high = (defined $2) ? hex $2 : $low;
2891
2892             # If the input maps the range to another code point, remap the
2893             # target if it is between 0 and 255.
2894             my $tail;
2895             if (defined $map) {
2896                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
2897                 $tail = "$property_name; $map";
2898                 $_ = "$range; $tail";
2899             }
2900             else {
2901                 $tail = $property_name;
2902             }
2903
2904             # If entire range is above 255, just return it, unchanged (except
2905             # any mapped-to code point, already changed above)
2906             return 1 if $low > 255;
2907
2908             # Cache an entry for every code point < 255.  For those in the
2909             # range above 255, return a dummy entry for just that portion of
2910             # the range.  Note that this will be out-of-order, but that is not
2911             # a problem.
2912             foreach my $code_point ($low .. $high) {
2913                 if ($code_point > 255) {
2914                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
2915                     return 1;
2916                 }
2917                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
2918             }
2919         } # End of looping through lines.
2920
2921         # NOTREACHED
2922     }
2923
2924 #   Not currently used, not fully tested.
2925 #    sub peek {
2926 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2927 #        # record.  Not callable from an each_line_handler(), nor does it call
2928 #        # an each_line_handler() on the line.
2929 #
2930 #        my $self = shift;
2931 #        my $addr = do { no overloading; pack 'J', $self; };
2932 #
2933 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2934 #            my ($adjusted, $line) = @{$inserted_ref};
2935 #            next if $adjusted;
2936 #
2937 #            # Remove comments and trailing space, and return a non-empty
2938 #            # resulting line
2939 #            $line =~ s/#.*//;
2940 #            $line =~ s/\s+$//;
2941 #            return $line if $line ne "";
2942 #        }
2943 #
2944 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2945 #        while (1) { # Loop until find non-comment, non-empty line
2946 #            local $to_trace = 1 if main::DEBUG;
2947 #            trace $_ if main::DEBUG && $to_trace;
2948 #            return if ! defined (my $line = readline $handle{$addr});
2949 #            chomp $line;
2950 #            push @{$added_lines{$addr}}, [ 0, $line ];
2951 #
2952 #            $line =~ s/#.*//;
2953 #            $line =~ s/\s+$//;
2954 #            return $line if $line ne "";
2955 #        }
2956 #
2957 #        return;
2958 #    }
2959
2960
2961     sub insert_lines {
2962         # Lines can be inserted so that it looks like they were in the input
2963         # file at the place it was when this routine is called.  See also
2964         # insert_adjusted_lines().  Lines inserted via this routine go through
2965         # any each_line_handler()
2966
2967         my $self = shift;
2968
2969         # Each inserted line is an array, with the first element being 0 to
2970         # indicate that this line hasn't been adjusted, and needs to be
2971         # processed.
2972         no overloading;
2973         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2974         return;
2975     }
2976
2977     sub insert_adjusted_lines {
2978         # Lines can be inserted so that it looks like they were in the input
2979         # file at the place it was when this routine is called.  See also
2980         # insert_lines().  Lines inserted via this routine are already fully
2981         # adjusted, ready to be processed; each_line_handler()s handlers will
2982         # not be called.  This means this is not a completely general
2983         # facility, as only the last each_line_handler on the stack should
2984         # call this.  It could be made more general, by passing to each of the
2985         # line_handlers their position on the stack, which they would pass on
2986         # to this routine, and that would replace the boolean first element in
2987         # the anonymous array pushed here, so that the next_line routine could
2988         # use that to call only those handlers whose index is after it on the
2989         # stack.  But this is overkill for what is needed now.
2990
2991         my $self = shift;
2992         trace $_[0] if main::DEBUG && $to_trace;
2993
2994         # Each inserted line is an array, with the first element being 1 to
2995         # indicate that this line has been adjusted
2996         no overloading;
2997         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2998         return;
2999     }
3000
3001     sub get_missings {
3002         # Returns the stored up @missings lines' values, and clears the list.
3003         # The values are in an array, consisting of the default in the first
3004         # element, and the property in the 2nd.  However, since these lines
3005         # can be stacked up, the return is an array of all these arrays.
3006
3007         my $self = shift;
3008         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3009
3010         my $addr = do { no overloading; pack 'J', $self; };
3011
3012         # If not accepting a list return, just return the first one.
3013         return shift @{$missings{$addr}} unless wantarray;
3014
3015         my @return = @{$missings{$addr}};
3016         undef @{$missings{$addr}};
3017         return @return;
3018     }
3019
3020     sub _insert_property_into_line {
3021         # Add a property field to $_, if this file requires it.
3022
3023         my $self = shift;
3024         my $addr = do { no overloading; pack 'J', $self; };
3025         my $property = $property{$addr};
3026         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3027
3028         $_ =~ s/(;|$)/; $property$1/;
3029         return;
3030     }
3031
3032     sub carp_bad_line {
3033         # Output consistent error messages, using either a generic one, or the
3034         # one given by the optional parameter.  To avoid gazillions of the
3035         # same message in case the syntax of a  file is way off, this routine
3036         # only outputs the first instance of each message, incrementing a
3037         # count so the totals can be output at the end of the file.
3038
3039         my $self = shift;
3040         my $message = shift;
3041         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3042
3043         my $addr = do { no overloading; pack 'J', $self; };
3044
3045         $message = 'Unexpected line' unless $message;
3046
3047         # No trailing punctuation so as to fit with our addenda.
3048         $message =~ s/[.:;,]$//;
3049
3050         # If haven't seen this exact message before, output it now.  Otherwise
3051         # increment the count of how many times it has occurred
3052         unless ($errors{$addr}->{$message}) {
3053             Carp::my_carp("$message in '$_' in "
3054                             . $file{$addr}
3055                             . " at line $..  Skipping this line;");
3056             $errors{$addr}->{$message} = 1;
3057         }
3058         else {
3059             $errors{$addr}->{$message}++;
3060         }
3061
3062         # Clear the line to prevent any further (meaningful) processing of it.
3063         $_ = "";
3064
3065         return;
3066     }
3067 } # End closure
3068
3069 package Multi_Default;
3070
3071 # Certain properties in early versions of Unicode had more than one possible
3072 # default for code points missing from the files.  In these cases, one
3073 # default applies to everything left over after all the others are applied,
3074 # and for each of the others, there is a description of which class of code
3075 # points applies to it.  This object helps implement this by storing the
3076 # defaults, and for all but that final default, an eval string that generates
3077 # the class that it applies to.
3078
3079
3080 {   # Closure
3081
3082     main::setup_package();
3083
3084     my %class_defaults;
3085     # The defaults structure for the classes
3086     main::set_access('class_defaults', \%class_defaults);
3087
3088     my %other_default;
3089     # The default that applies to everything left over.
3090     main::set_access('other_default', \%other_default, 'r');
3091
3092
3093     sub new {
3094         # The constructor is called with default => eval pairs, terminated by
3095         # the left-over default. e.g.
3096         # Multi_Default->new(
3097         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3098         #               -  0x200D',
3099         #        'R' => 'some other expression that evaluates to code points',
3100         #        .
3101         #        .
3102         #        .
3103         #        'U'));
3104
3105         my $class = shift;
3106
3107         my $self = bless \do{my $anonymous_scalar}, $class;
3108         my $addr = do { no overloading; pack 'J', $self; };
3109
3110         while (@_ > 1) {
3111             my $default = shift;
3112             my $eval = shift;
3113             $class_defaults{$addr}->{$default} = $eval;
3114         }
3115
3116         $other_default{$addr} = shift;
3117
3118         return $self;
3119     }
3120
3121     sub get_next_defaults {
3122         # Iterates and returns the next class of defaults.
3123         my $self = shift;
3124         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3125
3126         my $addr = do { no overloading; pack 'J', $self; };
3127
3128         return each %{$class_defaults{$addr}};
3129     }
3130 }
3131
3132 package Alias;
3133
3134 # An alias is one of the names that a table goes by.  This class defines them
3135 # including some attributes.  Everything is currently setup in the
3136 # constructor.
3137
3138
3139 {   # Closure
3140
3141     main::setup_package();
3142
3143     my %name;
3144     main::set_access('name', \%name, 'r');
3145
3146     my %loose_match;
3147     # Should this name match loosely or not.
3148     main::set_access('loose_match', \%loose_match, 'r');
3149
3150     my %make_re_pod_entry;
3151     # Some aliases should not get their own entries in the re section of the
3152     # pod, because they are covered by a wild-card, and some we want to
3153     # discourage use of.  Binary
3154     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3155
3156     my %ucd;
3157     # Is this documented to be accessible via Unicode::UCD
3158     main::set_access('ucd', \%ucd, 'r', 's');
3159
3160     my %status;
3161     # Aliases have a status, like deprecated, or even suppressed (which means
3162     # they don't appear in documentation).  Enum
3163     main::set_access('status', \%status, 'r');
3164
3165     my %ok_as_filename;
3166     # Similarly, some aliases should not be considered as usable ones for
3167     # external use, such as file names, or we don't want documentation to
3168     # recommend them.  Boolean
3169     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3170
3171     sub new {
3172         my $class = shift;
3173
3174         my $self = bless \do { my $anonymous_scalar }, $class;
3175         my $addr = do { no overloading; pack 'J', $self; };
3176
3177         $name{$addr} = shift;
3178         $loose_match{$addr} = shift;
3179         $make_re_pod_entry{$addr} = shift;
3180         $ok_as_filename{$addr} = shift;
3181         $status{$addr} = shift;
3182         $ucd{$addr} = shift;
3183
3184         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3185
3186         # Null names are never ok externally
3187         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3188
3189         return $self;
3190     }
3191 }
3192
3193 package Range;
3194
3195 # A range is the basic unit for storing code points, and is described in the
3196 # comments at the beginning of the program.  Each range has a starting code
3197 # point; an ending code point (not less than the starting one); a value
3198 # that applies to every code point in between the two end-points, inclusive;
3199 # and an enum type that applies to the value.  The type is for the user's
3200 # convenience, and has no meaning here, except that a non-zero type is
3201 # considered to not obey the normal Unicode rules for having standard forms.
3202 #
3203 # The same structure is used for both map and match tables, even though in the
3204 # latter, the value (and hence type) is irrelevant and could be used as a
3205 # comment.  In map tables, the value is what all the code points in the range
3206 # map to.  Type 0 values have the standardized version of the value stored as
3207 # well, so as to not have to recalculate it a lot.
3208
3209 sub trace { return main::trace(@_); }
3210
3211 {   # Closure
3212
3213     main::setup_package();
3214
3215     my %start;
3216     main::set_access('start', \%start, 'r', 's');
3217
3218     my %end;
3219     main::set_access('end', \%end, 'r', 's');
3220
3221     my %value;
3222     main::set_access('value', \%value, 'r');
3223
3224     my %type;
3225     main::set_access('type', \%type, 'r');
3226
3227     my %standard_form;
3228     # The value in internal standard form.  Defined only if the type is 0.
3229     main::set_access('standard_form', \%standard_form);
3230
3231     # Note that if these fields change, the dump() method should as well
3232
3233     sub new {
3234         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3235         my $class = shift;
3236
3237         my $self = bless \do { my $anonymous_scalar }, $class;
3238         my $addr = do { no overloading; pack 'J', $self; };
3239
3240         $start{$addr} = shift;
3241         $end{$addr} = shift;
3242
3243         my %args = @_;
3244
3245         my $value = delete $args{'Value'};  # Can be 0
3246         $value = "" unless defined $value;
3247         $value{$addr} = $value;
3248
3249         $type{$addr} = delete $args{'Type'} || 0;
3250
3251         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3252
3253         return $self;
3254     }
3255
3256     use overload
3257         fallback => 0,
3258         qw("") => "_operator_stringify",
3259         "." => \&main::_operator_dot,
3260         ".=" => \&main::_operator_dot_equal,
3261     ;
3262
3263     sub _operator_stringify {
3264         my $self = shift;
3265         my $addr = do { no overloading; pack 'J', $self; };
3266
3267         # Output it like '0041..0065 (value)'
3268         my $return = sprintf("%04X", $start{$addr})
3269                         .  '..'
3270                         . sprintf("%04X", $end{$addr});
3271         my $value = $value{$addr};
3272         my $type = $type{$addr};
3273         $return .= ' (';
3274         $return .= "$value";
3275         $return .= ", Type=$type" if $type != 0;
3276         $return .= ')';
3277
3278         return $return;
3279     }
3280
3281     sub standard_form {
3282         # Calculate the standard form only if needed, and cache the result.
3283         # The standard form is the value itself if the type is special.
3284         # This represents a considerable CPU and memory saving - at the time
3285         # of writing there are 368676 non-special objects, but the standard
3286         # form is only requested for 22047 of them - ie about 6%.
3287
3288         my $self = shift;
3289         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3290
3291         my $addr = do { no overloading; pack 'J', $self; };
3292
3293         return $standard_form{$addr} if defined $standard_form{$addr};
3294
3295         my $value = $value{$addr};
3296         return $value if $type{$addr};
3297         return $standard_form{$addr} = main::standardize($value);
3298     }
3299
3300     sub dump {
3301         # Human, not machine readable.  For machine readable, comment out this
3302         # entire routine and let the standard one take effect.
3303         my $self = shift;
3304         my $indent = shift;
3305         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3306
3307         my $addr = do { no overloading; pack 'J', $self; };
3308
3309         my $return = $indent
3310                     . sprintf("%04X", $start{$addr})
3311                     . '..'
3312                     . sprintf("%04X", $end{$addr})
3313                     . " '$value{$addr}';";
3314         if (! defined $standard_form{$addr}) {
3315             $return .= "(type=$type{$addr})";
3316         }
3317         elsif ($standard_form{$addr} ne $value{$addr}) {
3318             $return .= "(standard '$standard_form{$addr}')";
3319         }
3320         return $return;
3321     }
3322 } # End closure
3323
3324 package _Range_List_Base;
3325
3326 # Base class for range lists.  A range list is simply an ordered list of
3327 # ranges, so that the ranges with the lowest starting numbers are first in it.
3328 #
3329 # When a new range is added that is adjacent to an existing range that has the
3330 # same value and type, it merges with it to form a larger range.
3331 #
3332 # Ranges generally do not overlap, except that there can be multiple entries
3333 # of single code point ranges.  This is because of NameAliases.txt.
3334 #
3335 # In this program, there is a standard value such that if two different
3336 # values, have the same standard value, they are considered equivalent.  This
3337 # value was chosen so that it gives correct results on Unicode data
3338
3339 # There are a number of methods to manipulate range lists, and some operators
3340 # are overloaded to handle them.
3341
3342 sub trace { return main::trace(@_); }
3343
3344 { # Closure
3345
3346     our $addr;
3347
3348     # Max is initialized to a negative value that isn't adjacent to 0, for
3349     # simpler tests
3350     my $max_init = -2;
3351
3352     main::setup_package();
3353
3354     my %ranges;
3355     # The list of ranges
3356     main::set_access('ranges', \%ranges, 'readable_array');
3357
3358     my %max;
3359     # The highest code point in the list.  This was originally a method, but
3360     # actual measurements said it was used a lot.
3361     main::set_access('max', \%max, 'r');
3362
3363     my %each_range_iterator;
3364     # Iterator position for each_range()
3365     main::set_access('each_range_iterator', \%each_range_iterator);
3366
3367     my %owner_name_of;
3368     # Name of parent this is attached to, if any.  Solely for better error
3369     # messages.
3370     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3371
3372     my %_search_ranges_cache;
3373     # A cache of the previous result from _search_ranges(), for better
3374     # performance
3375     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3376
3377     sub new {
3378         my $class = shift;
3379         my %args = @_;
3380
3381         # Optional initialization data for the range list.
3382         my $initialize = delete $args{'Initialize'};
3383
3384         my $self;
3385
3386         # Use _union() to initialize.  _union() returns an object of this
3387         # class, which means that it will call this constructor recursively.
3388         # But it won't have this $initialize parameter so that it won't
3389         # infinitely loop on this.
3390         return _union($class, $initialize, %args) if defined $initialize;
3391
3392         $self = bless \do { my $anonymous_scalar }, $class;
3393         my $addr = do { no overloading; pack 'J', $self; };
3394
3395         # Optional parent object, only for debug info.
3396         $owner_name_of{$addr} = delete $args{'Owner'};
3397         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3398
3399         # Stringify, in case it is an object.
3400         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3401
3402         # This is used only for error messages, and so a colon is added
3403         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3404
3405         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3406
3407         $max{$addr} = $max_init;
3408
3409         $_search_ranges_cache{$addr} = 0;
3410         $ranges{$addr} = [];
3411
3412         return $self;
3413     }
3414
3415     use overload
3416         fallback => 0,
3417         qw("") => "_operator_stringify",
3418         "." => \&main::_operator_dot,
3419         ".=" => \&main::_operator_dot_equal,
3420     ;
3421
3422     sub _operator_stringify {
3423         my $self = shift;
3424         my $addr = do { no overloading; pack 'J', $self; };
3425
3426         return "Range_List attached to '$owner_name_of{$addr}'"
3427                                                 if $owner_name_of{$addr};
3428         return "anonymous Range_List " . \$self;
3429     }
3430
3431     sub _union {
3432         # Returns the union of the input code points.  It can be called as
3433         # either a constructor or a method.  If called as a method, the result
3434         # will be a new() instance of the calling object, containing the union
3435         # of that object with the other parameter's code points;  if called as
3436         # a constructor, the first parameter gives the class that the new object
3437         # should be, and the second parameter gives the code points to go into
3438         # it.
3439         # In either case, there are two parameters looked at by this routine;
3440         # any additional parameters are passed to the new() constructor.
3441         #
3442         # The code points can come in the form of some object that contains
3443         # ranges, and has a conventionally named method to access them; or
3444         # they can be an array of individual code points (as integers); or
3445         # just a single code point.
3446         #
3447         # If they are ranges, this routine doesn't make any effort to preserve
3448         # the range values and types of one input over the other.  Therefore
3449         # this base class should not allow _union to be called from other than
3450         # initialization code, so as to prevent two tables from being added
3451         # together where the range values matter.  The general form of this
3452         # routine therefore belongs in a derived class, but it was moved here
3453         # to avoid duplication of code.  The failure to overload this in this
3454         # class keeps it safe.
3455         #
3456         # It does make the effort during initialization to accept tables with
3457         # multiple values for the same code point, and to preserve the order
3458         # of these.  If there is only one input range or range set, it doesn't
3459         # sort (as it should already be sorted to the desired order), and will
3460         # accept multiple values per code point.  Otherwise it will merge
3461         # multiple values into a single one.
3462
3463         my $self;
3464         my @args;   # Arguments to pass to the constructor
3465
3466         my $class = shift;
3467
3468         # If a method call, will start the union with the object itself, and
3469         # the class of the new object will be the same as self.
3470         if (ref $class) {
3471             $self = $class;
3472             $class = ref $self;
3473             push @args, $self;
3474         }
3475
3476         # Add the other required parameter.
3477         push @args, shift;
3478         # Rest of parameters are passed on to the constructor
3479
3480         # Accumulate all records from both lists.
3481         my @records;
3482         my $input_count = 0;
3483         for my $arg (@args) {
3484             #local $to_trace = 0 if main::DEBUG;
3485             trace "argument = $arg" if main::DEBUG && $to_trace;
3486             if (! defined $arg) {
3487                 my $message = "";
3488                 if (defined $self) {
3489                     no overloading;
3490                     $message .= $owner_name_of{pack 'J', $self};
3491                 }
3492                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3493                 return;
3494             }
3495
3496             $arg = [ $arg ] if ! ref $arg;
3497             my $type = ref $arg;
3498             if ($type eq 'ARRAY') {
3499                 foreach my $element (@$arg) {
3500                     push @records, Range->new($element, $element);
3501                     $input_count++;
3502                 }
3503             }
3504             elsif ($arg->isa('Range')) {
3505                 push @records, $arg;
3506                 $input_count++;
3507             }
3508             elsif ($arg->can('ranges')) {
3509                 push @records, $arg->ranges;
3510                 $input_count++;
3511             }
3512             else {
3513                 my $message = "";
3514                 if (defined $self) {
3515                     no overloading;
3516                     $message .= $owner_name_of{pack 'J', $self};
3517                 }
3518                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3519                 return;
3520             }
3521         }
3522
3523         # Sort with the range containing the lowest ordinal first, but if
3524         # two ranges start at the same code point, sort with the bigger range
3525         # of the two first, because it takes fewer cycles.
3526         if ($input_count > 1) {
3527             @records = sort { ($a->start <=> $b->start)
3528                                       or
3529                                     # if b is shorter than a, b->end will be
3530                                     # less than a->end, and we want to select
3531                                     # a, so want to return -1
3532                                     ($b->end <=> $a->end)
3533                                    } @records;
3534         }
3535
3536         my $new = $class->new(@_);
3537
3538         # Fold in records so long as they add new information.
3539         for my $set (@records) {
3540             my $start = $set->start;
3541             my $end   = $set->end;
3542             my $value = $set->value;
3543             my $type  = $set->type;
3544             if ($start > $new->max) {
3545                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3546             }
3547             elsif ($end > $new->max) {
3548                 $new->_add_delete('+', $new->max +1, $end, $value,
3549                                                                 Type => $type);
3550             }
3551             elsif ($input_count == 1) {
3552                 # Here, overlaps existing range, but is from a single input,
3553                 # so preserve the multiple values from that input.
3554                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3555                                                 Replace => $MULTIPLE_AFTER);
3556             }
3557         }
3558
3559         return $new;
3560     }
3561
3562     sub range_count {        # Return the number of ranges in the range list
3563         my $self = shift;
3564         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3565
3566         no overloading;
3567         return scalar @{$ranges{pack 'J', $self}};
3568     }
3569
3570     sub min {
3571         # Returns the minimum code point currently in the range list, or if
3572         # the range list is empty, 2 beyond the max possible.  This is a
3573         # method because used so rarely, that not worth saving between calls,
3574         # and having to worry about changing it as ranges are added and
3575         # deleted.
3576
3577         my $self = shift;
3578         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3579
3580         my $addr = do { no overloading; pack 'J', $self; };
3581
3582         # If the range list is empty, return a large value that isn't adjacent
3583         # to any that could be in the range list, for simpler tests
3584         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3585         return $ranges{$addr}->[0]->start;
3586     }
3587
3588     sub contains {
3589         # Boolean: Is argument in the range list?  If so returns $i such that:
3590         #   range[$i]->end < $codepoint <= range[$i+1]->end
3591         # which is one beyond what you want; this is so that the 0th range
3592         # doesn't return false
3593         my $self = shift;
3594         my $codepoint = shift;
3595         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3596
3597         my $i = $self->_search_ranges($codepoint);
3598         return 0 unless defined $i;
3599
3600         # The search returns $i, such that
3601         #   range[$i-1]->end < $codepoint <= range[$i]->end
3602         # So is in the table if and only iff it is at least the start position
3603         # of range $i.
3604         no overloading;
3605         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3606         return $i + 1;
3607     }
3608
3609     sub containing_range {
3610         # Returns the range object that contains the code point, undef if none
3611
3612         my $self = shift;
3613         my $codepoint = shift;
3614         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3615
3616         my $i = $self->contains($codepoint);
3617         return unless $i;
3618
3619         # contains() returns 1 beyond where we should look
3620         no overloading;
3621         return $ranges{pack 'J', $self}->[$i-1];
3622     }
3623
3624     sub value_of {
3625         # Returns the value associated with the code point, undef if none
3626
3627         my $self = shift;
3628         my $codepoint = shift;
3629         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3630
3631         my $range = $self->containing_range($codepoint);
3632         return unless defined $range;
3633
3634         return $range->value;
3635     }
3636
3637     sub type_of {
3638         # Returns the type of the range containing the code point, undef if
3639         # the code point is not in the table
3640
3641         my $self = shift;
3642         my $codepoint = shift;
3643         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3644
3645         my $range = $self->containing_range($codepoint);
3646         return unless defined $range;
3647
3648         return $range->type;
3649     }
3650
3651     sub _search_ranges {
3652         # Find the range in the list which contains a code point, or where it
3653         # should go if were to add it.  That is, it returns $i, such that:
3654         #   range[$i-1]->end < $codepoint <= range[$i]->end
3655         # Returns undef if no such $i is possible (e.g. at end of table), or
3656         # if there is an error.
3657
3658         my $self = shift;
3659         my $code_point = shift;
3660         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3661
3662         my $addr = do { no overloading; pack 'J', $self; };
3663
3664         return if $code_point > $max{$addr};
3665         my $r = $ranges{$addr};                # The current list of ranges
3666         my $range_list_size = scalar @$r;
3667         my $i;
3668
3669         use integer;        # want integer division
3670
3671         # Use the cached result as the starting guess for this one, because,
3672         # an experiment on 5.1 showed that 90% of the time the cache was the
3673         # same as the result on the next call (and 7% it was one less).
3674         $i = $_search_ranges_cache{$addr};
3675         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3676                                             # from an intervening deletion
3677         #local $to_trace = 1 if main::DEBUG;
3678         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3679         return $i if $code_point <= $r->[$i]->end
3680                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3681
3682         # Here the cache doesn't yield the correct $i.  Try adding 1.
3683         if ($i < $range_list_size - 1
3684             && $r->[$i]->end < $code_point &&
3685             $code_point <= $r->[$i+1]->end)
3686         {
3687             $i++;
3688             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3689             $_search_ranges_cache{$addr} = $i;
3690             return $i;
3691         }
3692
3693         # Here, adding 1 also didn't work.  We do a binary search to
3694         # find the correct position, starting with current $i
3695         my $lower = 0;
3696         my $upper = $range_list_size - 1;
3697         while (1) {
3698             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3699
3700             if ($code_point <= $r->[$i]->end) {
3701
3702                 # Here we have met the upper constraint.  We can quit if we
3703                 # also meet the lower one.
3704                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3705
3706                 $upper = $i;        # Still too high.
3707
3708             }
3709             else {
3710
3711                 # Here, $r[$i]->end < $code_point, so look higher up.
3712                 $lower = $i;
3713             }
3714
3715             # Split search domain in half to try again.
3716             my $temp = ($upper + $lower) / 2;
3717
3718             # No point in continuing unless $i changes for next time
3719             # in the loop.
3720             if ($temp == $i) {
3721
3722                 # We can't reach the highest element because of the averaging.
3723                 # So if one below the upper edge, force it there and try one
3724                 # more time.
3725                 if ($i == $range_list_size - 2) {
3726
3727                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3728                     $i = $range_list_size - 1;
3729
3730                     # Change $lower as well so if fails next time through,
3731                     # taking the average will yield the same $i, and we will
3732                     # quit with the error message just below.
3733                     $lower = $i;
3734                     next;
3735                 }
3736                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3737                 return;
3738             }
3739             $i = $temp;
3740         } # End of while loop
3741
3742         if (main::DEBUG && $to_trace) {
3743             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3744             trace "i=  [ $i ]", $r->[$i];
3745             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3746         }
3747
3748         # Here we have found the offset.  Cache it as a starting point for the
3749         # next call.
3750         $_search_ranges_cache{$addr} = $i;
3751         return $i;
3752     }
3753
3754     sub _add_delete {
3755         # Add, replace or delete ranges to or from a list.  The $type
3756         # parameter gives which:
3757         #   '+' => insert or replace a range, returning a list of any changed
3758         #          ranges.
3759         #   '-' => delete a range, returning a list of any deleted ranges.
3760         #
3761         # The next three parameters give respectively the start, end, and
3762         # value associated with the range.  'value' should be null unless the
3763         # operation is '+';
3764         #
3765         # The range list is kept sorted so that the range with the lowest
3766         # starting position is first in the list, and generally, adjacent
3767         # ranges with the same values are merged into a single larger one (see
3768         # exceptions below).
3769         #
3770         # There are more parameters; all are key => value pairs:
3771         #   Type    gives the type of the value.  It is only valid for '+'.
3772         #           All ranges have types; if this parameter is omitted, 0 is
3773         #           assumed.  Ranges with type 0 are assumed to obey the
3774         #           Unicode rules for casing, etc; ranges with other types are
3775         #           not.  Otherwise, the type is arbitrary, for the caller's
3776         #           convenience, and looked at only by this routine to keep
3777         #           adjacent ranges of different types from being merged into
3778         #           a single larger range, and when Replace =>
3779         #           $IF_NOT_EQUIVALENT is specified (see just below).
3780         #   Replace  determines what to do if the range list already contains
3781         #            ranges which coincide with all or portions of the input
3782         #            range.  It is only valid for '+':
3783         #       => $NO            means that the new value is not to replace
3784         #                         any existing ones, but any empty gaps of the
3785         #                         range list coinciding with the input range
3786         #                         will be filled in with the new value.
3787         #       => $UNCONDITIONALLY  means to replace the existing values with
3788         #                         this one unconditionally.  However, if the
3789         #                         new and old values are identical, the
3790         #                         replacement is skipped to save cycles
3791         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3792         #          (the default)  with this one if they are not equivalent.
3793         #                         Ranges are equivalent if their types are the
3794         #                         same, and they are the same string; or if
3795         #                         both are type 0 ranges, if their Unicode
3796         #                         standard forms are identical.  In this last
3797         #                         case, the routine chooses the more "modern"
3798         #                         one to use.  This is because some of the
3799         #                         older files are formatted with values that
3800         #                         are, for example, ALL CAPs, whereas the
3801         #                         derived files have a more modern style,
3802         #                         which looks better.  By looking for this
3803         #                         style when the pre-existing and replacement
3804         #                         standard forms are the same, we can move to
3805         #                         the modern style
3806         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3807         #                         existing one, but has a different value,
3808         #                         don't replace the existing one, but insert
3809         #                         this one so that the same range can occur
3810         #                         multiple times.  They are stored LIFO, so
3811         #                         that the final one inserted is the first one
3812         #                         returned in an ordered search of the table.
3813         #                         If this is an exact duplicate, including the
3814         #                         value, the original will be moved to be
3815         #                         first, before any other duplicate ranges
3816         #                         with different values.
3817         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3818         #                         FIFO, so that this one is inserted after all
3819         #                         others that currently exist.  If this is an
3820         #                         exact duplicate, including value, of an
3821         #                         existing range, this one is discarded
3822         #                         (leaving the existing one in its original,
3823         #                         higher priority position
3824         #       => $CROAK         Die with an error if is already there
3825         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3826         #
3827         # "same value" means identical for non-type-0 ranges, and it means
3828         # having the same standard forms for type-0 ranges.
3829
3830         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3831
3832         my $self = shift;
3833         my $operation = shift;   # '+' for add/replace; '-' for delete;
3834         my $start = shift;
3835         my $end   = shift;
3836         my $value = shift;
3837
3838         my %args = @_;
3839
3840         $value = "" if not defined $value;        # warning: $value can be "0"
3841
3842         my $replace = delete $args{'Replace'};
3843         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3844
3845         my $type = delete $args{'Type'};
3846         $type = 0 unless defined $type;
3847
3848         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3849
3850         my $addr = do { no overloading; pack 'J', $self; };
3851
3852         if ($operation ne '+' && $operation ne '-') {
3853             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3854             return;
3855         }
3856         unless (defined $start && defined $end) {
3857             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3858             return;
3859         }
3860         unless ($end >= $start) {
3861             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3862             return;
3863         }
3864         #local $to_trace = 1 if main::DEBUG;
3865
3866         if ($operation eq '-') {
3867             if ($replace != $IF_NOT_EQUIVALENT) {
3868                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3869                 $replace = $IF_NOT_EQUIVALENT;
3870             }
3871             if ($type) {
3872                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3873                 $type = 0;
3874             }
3875             if ($value ne "") {
3876                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3877                 $value = "";
3878             }
3879         }
3880
3881         my $r = $ranges{$addr};               # The current list of ranges
3882         my $range_list_size = scalar @$r;     # And its size
3883         my $max = $max{$addr};                # The current high code point in
3884                                               # the list of ranges
3885
3886         # Do a special case requiring fewer machine cycles when the new range
3887         # starts after the current highest point.  The Unicode input data is
3888         # structured so this is common.
3889         if ($start > $max) {
3890
3891             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3892             return if $operation eq '-'; # Deleting a non-existing range is a
3893                                          # no-op
3894
3895             # If the new range doesn't logically extend the current final one
3896             # in the range list, create a new range at the end of the range
3897             # list.  (max cleverly is initialized to a negative number not
3898             # adjacent to 0 if the range list is empty, so even adding a range
3899             # to an empty range list starting at 0 will have this 'if'
3900             # succeed.)
3901             if ($start > $max + 1        # non-adjacent means can't extend.
3902                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3903                 || @{$r}[-1]->type != $type # types differ, can't extend.
3904             ) {
3905                 push @$r, Range->new($start, $end,
3906                                      Value => $value,
3907                                      Type => $type);
3908             }
3909             else {
3910
3911                 # Here, the new range starts just after the current highest in
3912                 # the range list, and they have the same type and value.
3913                 # Extend the existing range to incorporate the new one.
3914                 @{$r}[-1]->set_end($end);
3915             }
3916
3917             # This becomes the new maximum.
3918             $max{$addr} = $end;
3919
3920             return;
3921         }
3922         #local $to_trace = 0 if main::DEBUG;
3923
3924         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3925
3926         # Here, the input range isn't after the whole rest of the range list.
3927         # Most likely 'splice' will be needed.  The rest of the routine finds
3928         # the needed splice parameters, and if necessary, does the splice.
3929         # First, find the offset parameter needed by the splice function for
3930         # the input range.  Note that the input range may span multiple
3931         # existing ones, but we'll worry about that later.  For now, just find
3932         # the beginning.  If the input range is to be inserted starting in a
3933         # position not currently in the range list, it must (obviously) come
3934         # just after the range below it, and just before the range above it.
3935         # Slightly less obviously, it will occupy the position currently
3936         # occupied by the range that is to come after it.  More formally, we
3937         # are looking for the position, $i, in the array of ranges, such that:
3938         #
3939         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3940         #
3941         # (The ordered relationships within existing ranges are also shown in
3942         # the equation above).  However, if the start of the input range is
3943         # within an existing range, the splice offset should point to that
3944         # existing range's position in the list; that is $i satisfies a
3945         # somewhat different equation, namely:
3946         #
3947         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3948         #
3949         # More briefly, $start can come before or after r[$i]->start, and at
3950         # this point, we don't know which it will be.  However, these
3951         # two equations share these constraints:
3952         #
3953         #   r[$i-1]->end < $start <= r[$i]->end
3954         #
3955         # And that is good enough to find $i.
3956
3957         my $i = $self->_search_ranges($start);
3958         if (! defined $i) {
3959             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3960             return;
3961         }
3962
3963         # The search function returns $i such that:
3964         #
3965         # r[$i-1]->end < $start <= r[$i]->end
3966         #
3967         # That means that $i points to the first range in the range list
3968         # that could possibly be affected by this operation.  We still don't
3969         # know if the start of the input range is within r[$i], or if it
3970         # points to empty space between r[$i-1] and r[$i].
3971         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3972
3973         # Special case the insertion of data that is not to replace any
3974         # existing data.
3975         if ($replace == $NO) {  # If $NO, has to be operation '+'
3976             #local $to_trace = 1 if main::DEBUG;
3977             trace "Doesn't replace" if main::DEBUG && $to_trace;
3978
3979             # Here, the new range is to take effect only on those code points
3980             # that aren't already in an existing range.  This can be done by
3981             # looking through the existing range list and finding the gaps in
3982             # the ranges that this new range affects, and then calling this
3983             # function recursively on each of those gaps, leaving untouched
3984             # anything already in the list.  Gather up a list of the changed
3985             # gaps first so that changes to the internal state as new ranges
3986             # are added won't be a problem.
3987             my @gap_list;
3988
3989             # First, if the starting point of the input range is outside an
3990             # existing one, there is a gap from there to the beginning of the
3991             # existing range -- add a span to fill the part that this new
3992             # range occupies
3993             if ($start < $r->[$i]->start) {
3994                 push @gap_list, Range->new($start,
3995                                            main::min($end,
3996                                                      $r->[$i]->start - 1),
3997                                            Type => $type);
3998                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3999             }
4000
4