This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Fix occasional failures in svleak.t and DosGlob.t
[perl5.git] / t / op / svleak.t
1 #!./perl
2
3 # A place to put some simple leak tests. Uses XS::APItest to make
4 # PL_sv_count available, allowing us to run a bit of code multiple times and
5 # see if the count increases.
6
7 BEGIN {
8     chdir 't';
9     @INC = '../lib';
10     require './test.pl';
11
12     eval { require XS::APItest; XS::APItest->import('sv_count'); 1 }
13         or skip_all("XS::APItest not available");
14 }
15
16 use Config;
17
18 plan tests => 112;
19
20 # run some code N times. If the number of SVs at the end of loop N is
21 # greater than (N-1)*delta at the end of loop 1, we've got a leak
22 #
23 sub leak {
24     my ($n, $delta, $code, @rest) = @_;
25     my $sv0 = 0;
26     my $sv1 = 0;
27     for my $i (1..$n) {
28         &$code();
29         $sv1 = sv_count();
30         $sv0 = $sv1 if $i == 1;
31     }
32     cmp_ok($sv1-$sv0, '<=', ($n-1)*$delta, @rest);
33 }
34
35 # Like leak, but run a string eval instead.
36 # The code is used instead of the test name
37 # if the name is absent.
38 sub eleak {
39     my ($n,$delta,$code,@rest) = @_;
40     leak $n, $delta, sub { eval $code },
41          @rest ? @rest : $code
42 }
43
44 # run some expression N times. The expr is concatenated N times and then
45 # evaled, ensuring that that there are no scope exits between executions.
46 # If the number of SVs at the end of expr N is greater than (N-1)*delta at
47 # the end of expr 1, we've got a leak
48 #
49 sub leak_expr {
50     my ($n, $delta, $expr, @rest) = @_;
51     my $sv0 = 0;
52     my $sv1 = 0;
53     my $true = 1; # avoid stuff being optimised away
54     my $code1 = "($expr || \$true)";
55     my $code = "$code1 && (\$sv0 = sv_count())" . ("&& $code1" x 4)
56                 . " && (\$sv1 = sv_count())";
57     if (eval $code) {
58         cmp_ok($sv1-$sv0, '<=', ($n-1)*$delta, @rest);
59     }
60     else {
61         fail("eval @rest: $@");
62     }
63 }
64
65
66 my @a;
67
68 leak(5, 0, sub {},                 "basic check 1 of leak test infrastructure");
69 leak(5, 0, sub {push @a,1;pop @a}, "basic check 2 of leak test infrastructure");
70 leak(5, 1, sub {push @a,1;},       "basic check 3 of leak test infrastructure");
71
72 # Fatal warnings
73 my $f = "use warnings FATAL =>";
74 my $all = "$f 'all';";
75 eleak(2, 0, "$f 'deprecated'; qq|\\c\{|", 'qq|\c{| with fatal warnings');
76 eleak(2, 0, "$f 'syntax'; qq|\\c`|", 'qq|\c`| with fatal warnings');
77 eleak(2, 0, "$all /\$\\ /", '/$\ / with fatal warnings');
78 eleak(2, 0, "$all s//\\1/", 's//\1/ with fatal warnings');
79 eleak(2, 0, "$all qq|\\i|", 'qq|\i| with fatal warnings');
80 eleak(2, 0, "$f 'digit'; qq|\\o{9}|", 'qq|\o{9}| with fatal warnings');
81 eleak(2, 0, "$f 'misc'; sub foo{} sub foo:lvalue",
82      'ignored :lvalue with fatal warnings');
83 eleak(2, 0, "no warnings; use feature ':all'; $f 'misc';
84              my sub foo{} sub foo:lvalue",
85      'ignored mysub :lvalue with fatal warnings');
86 eleak(2, 0, "no warnings; use feature ':all'; $all
87              my sub foo{} sub foo:lvalue{}",
88      'fatal mysub redef warning');
89 eleak(2, 0, "$all sub foo{} sub foo{}", 'fatal sub redef warning');
90 eleak(2, 0, "$all *x=sub {}",
91      'fatal sub redef warning with sub-to-glob assignment');
92 eleak(2, 0, "$all *x=sub() {1}",
93      'fatal const sub redef warning with sub-to-glob assignment');
94 eleak(2, 0, "$all XS::APItest::newCONSTSUB(\\%main::=>name=>0=>1)",
95      'newCONSTSUB sub redefinition with fatal warnings');
96 eleak(2, 0, "$f 'misc'; my\$a,my\$a", 'double my with fatal warnings');
97 eleak(2, 0, "$f 'misc'; our\$a,our\$a", 'double our with fatal warnings');
98 eleak(2, 0, "$f 'closure';
99              sub foo { my \$x; format=\n\@\n\$x\n.\n} write; ",
100      'format closing over unavailable var with fatal warnings');
101 eleak(2, 0, "$all /(?{})?/ ", '(?{})? with fatal warnings');
102 eleak(2, 0, "$all /(?{})+/ ", '(?{})+ with fatal warnings');
103 eleak(2, 0, "$all /[\\i]/ ", 'invalid charclass escape with fatal warns');
104 eleak(2, 0, "$all /[:foo:]/ ", '/[:foo:]/ with fatal warnings');
105 eleak(2, 0, "$all /[a-\\d]/ ", '[a-\d] char class with fatal warnings');
106 eleak(2, 0, "$all v111111111111111111111111111111111111111111111111",
107      'vstring num overflow with fatal warnings');
108
109 eleak(2, 0, 'sub{<*>}');
110 # Use a random number of ops, so that the glob op does not reuse the same
111 # address each time, giving us false passes.
112 leak(2, 0, sub { eval '$x+'x(1 + rand() * 100) . '<*>'; },
113     'freeing partly iterated glob');
114
115 eleak(2, 0, 'goto sub {}', 'goto &sub in eval');
116 eleak(2, 0, '() = sort { goto sub {} } 1,2', 'goto &sub in sort');
117 eleak(2, 0, '/(?{ goto sub {} })/', 'goto &sub in regexp');
118
119 sub TIEARRAY    { bless [], $_[0] }
120 sub FETCH       { $_[0]->[$_[1]] }
121 sub STORE       { $_[0]->[$_[1]] = $_[2] }
122
123 # local $tied_elem[..] leaks <20020502143736.N16831@dansat.data-plan.com>"
124 {
125     tie my @a, 'main';
126     leak(5, 0, sub {local $a[0]}, "local \$tied[0]");
127 }
128
129 # Overloading
130 require overload;
131 eleak(2, 0, "BEGIN{overload::constant integer=>sub{}} 1,1,1,1,1,1,1,1,1,1",
132      '"too many errors" from constant overloading returning undef');
133 # getting this one to leak was complicated; we have to unset LOCALIZE_HH:
134 eleak(2, 0, 'BEGIN{overload::constant integer=>sub{}; $^H &= ~ 0x00020000}
135              1,1,1,1,1,1,1,1,1,1',
136      '"too many errors" from constant overloading with $^H sabotaged');
137 eleak(2, 0, "BEGIN{overload::constant integer=>sub{}; undef %^H}
138              1,1,1,1,1,1,1,1,1,1",
139      '"too many errors" from constant overloading with %^H undefined');
140
141
142 # [perl #74484]  repeated tries leaked SVs on the tmps stack
143
144 leak_expr(5, 0, q{"YYYYYa" =~ /.+?(a(.+?)|b)/ }, "trie leak");
145
146 # [perl #48004] map/grep didn't free tmps till the end
147
148 {
149     # qr/1/ just creates tmps that are hopefully freed per iteration
150
151     my $s;
152     my @a;
153     my @count = (0) x 4; # pre-allocate
154
155     grep qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
156     is(@count[3] - @count[0], 0, "void   grep expr:  no new tmps per iter");
157     grep { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
158     is(@count[3] - @count[0], 0, "void   grep block: no new tmps per iter");
159
160     $s = grep qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
161     is(@count[3] - @count[0], 0, "scalar grep expr:  no new tmps per iter");
162     $s = grep { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
163     is(@count[3] - @count[0], 0, "scalar grep block: no new tmps per iter");
164
165     @a = grep qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
166     is(@count[3] - @count[0], 0, "list   grep expr:  no new tmps per iter");
167     @a = grep { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
168     is(@count[3] - @count[0], 0, "list   grep block: no new tmps per iter");
169
170
171     map qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
172     is(@count[3] - @count[0], 0, "void   map expr:  no new tmps per iter");
173     map { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
174     is(@count[3] - @count[0], 0, "void   map block: no new tmps per iter");
175
176     $s = map qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
177     is(@count[3] - @count[0], 0, "scalar map expr:  no new tmps per iter");
178     $s = map { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
179     is(@count[3] - @count[0], 0, "scalar map block: no new tmps per iter");
180
181     @a = map qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
182     is(@count[3] - @count[0], 3, "list   map expr:  one new tmp per iter");
183     @a = map { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
184     is(@count[3] - @count[0], 3, "list   map block: one new tmp per iter");
185
186 }
187
188 SKIP:
189 { # broken by 304474c3, fixed by cefd5c7c, but didn't seem to cause
190   # any other test failures
191   # base test case from ribasushi (Peter Rabbitson)
192   eval { require Scalar::Util; Scalar::Util->import("weaken"); 1; }
193     or skip "no weaken", 1;
194   my $weak;
195   {
196     $weak = my $in = {};
197     weaken($weak);
198     my $out = { in => $in, in => undef }
199   }
200   ok(!$weak, "hash referenced weakened SV released");
201 }
202
203 # prototype() errors
204 leak(2,0, sub { eval { prototype "CORE::fu" } }, 'prototype errors');
205
206 # RT #72246: rcatline memory leak on bad $/
207
208 leak(2, 0,
209     sub {
210         my $f;
211         open CATLINE, '<', \$f;
212         local $/ = "\x{262E}";
213         my $str = "\x{2622}";
214         eval { $str .= <CATLINE> };
215     },
216     "rcatline leak"
217 );
218
219 {
220     my $RE = qr/
221       (?:
222         <(?<tag>
223           \s*
224           [^>\s]+
225         )>
226       )??
227     /xis;
228
229     "<html><body></body></html>" =~ m/$RE/gcs;
230
231     leak(5, 0, sub {
232         my $tag = $+{tag};
233     }, "named regexp captures");
234 }
235
236 eleak(2,0,'/[:]/');
237 eleak(2,0,'/[\xdf]/i');
238 eleak(2,0,'s![^/]!!');
239 eleak(2,0,'/[pp]/');
240 eleak(2,0,'/[[:ascii:]]/');
241 eleak(2,0,'/[[.zog.]]/');
242 eleak(2,0,'/[.zog.]/');
243 eleak(2,0,'chr(0x100) =~ /[[:punct:]]/');
244 eleak(2,0,'chr(0x100) =~ /[[:^punct:]]/');
245 eleak(2,0,'chr(0x100) =~ /\P{Assigned}/');
246 leak(2,0,sub { /(??{})/ }, '/(??{})/');
247
248 leak(2,0,sub { !$^V }, '[perl #109762] version object in boolean context');
249
250
251 # [perl #114356] run-time rexexp with unchanging pattern got
252 # inflated refcounts
253 eleak(2, 0, q{ my $x = "x"; "abc" =~ /$x/ for 1..5 }, '#114356');
254
255 eleak(2, 0, 'sub', '"sub" with nothing following');
256 eleak(2, 0, '+sub:a{}', 'anon subs with invalid attributes');
257 eleak(2, 0, 'no warnings; sub a{1 1}', 'sub with syntax error');
258 eleak(2, 0, 'no warnings; sub {1 1}', 'anon sub with syntax error');
259 eleak(2, 0, 'no warnings; use feature ":all"; my sub a{1 1}',
260      'my sub with syntax error');
261
262 # Reification (or lack thereof)
263 leak(2, 0, sub { sub { local $_[0]; shift }->(1) },
264     'local $_[0] on surreal @_, followed by shift');
265 leak(2, 0, sub { sub { local $_[0]; \@_ }->(1) },
266     'local $_[0] on surreal @_, followed by reification');
267
268 # Syntax errors
269 eleak(2, 0, '"${<<END}"
270                  ', 'unterminated here-doc in quotes in multiline eval');
271 eleak(2, 0, '"${<<END
272                }"', 'unterminated here-doc in multiline quotes in eval');
273 leak(2, 0, sub { eval { do './op/svleak.pl' } },
274         'unterminated here-doc in file');
275 eleak(2, 0, 'tr/9-0//');
276 eleak(2, 0, 'tr/a-z-0//');
277 eleak(2, 0, 'no warnings; nonexistent_function 33838',
278         'bareword followed by number');
279 eleak(2, 0, '//dd;'x20, '"too many errors" when parsing m// flags');
280 eleak(2, 0, 's///dd;'x20, '"too many errors" when parsing s/// flags');
281 eleak(2, 0, 'no warnings; 2 2;BEGIN{}',
282       'BEGIN block after syntax error');
283 {
284     local %INC; # in case Errno is already loaded
285     eleak(2, 0, 'no warnings; 2@!{',
286                 'implicit "use Errno" after syntax error');
287 }
288 eleak(2, 0, "\"\$\0\356\"", 'qq containing $ <null> something');
289 eleak(2, 0, 'END OF TERMS AND CONDITIONS', 'END followed by words');
290 eleak(2, 0, "+ + +;qq|\\N{a}|"x10,'qq"\N{a}" after errors');
291 eleak(2, 0, "qq|\\N{%}|",      'qq"\N{%}" (invalid charname)');
292 eleak(2, 0, "qq|\\N{au}|;",    'qq"\N{invalid}"');
293 eleak(2, 0, "qq|\\c|;"x10,     '"too many errors" from qq"\c"');
294 eleak(2, 0, "qq|\\o|;"x10,     '"too many errors" from qq"\o"');
295 eleak(2, 0, "qq|\\x{|;"x10,    '"too many errors" from qq"\x{"');
296 eleak(2, 0, "qq|\\N|;"x10,     '"too many errors" from qq"\N"');
297 eleak(2, 0, "qq|\\N{|;"x10,    '"too many errors" from qq"\N{"');
298 eleak(2, 0, "qq|\\N{U+GETG}|;"x10,'"too many errors" from qq"\N{U+JUNK}"');
299
300
301 # [perl #114764] Attributes leak scalars
302 leak(2, 0, sub { eval 'my $x : shared' }, 'my $x :shared used to leak');
303
304 eleak(2, 0, 'ref: 1', 'labels');
305
306 # Tied hash iteration was leaking if the hash was freed before itera-
307 # tion was over.
308 package t {
309     sub TIEHASH { bless [] }
310     sub FIRSTKEY { 0 }
311 }
312 leak(2, 0, sub {
313     my $h = {};
314     tie %$h, t;
315     each %$h;
316     undef $h;
317 }, 'tied hash iteration does not leak');
318
319 package explosive_scalar {
320     sub TIESCALAR { my $self = shift; bless [undef, {@_}], $self  }
321     sub FETCH     { die 'FETCH' if $_[0][1]{FETCH}; $_[0][0] }
322     sub STORE     { die 'STORE' if $_[0][1]{STORE}; $_[0][0] = $_[1] }
323 }
324 tie my $die_on_fetch, 'explosive_scalar', FETCH => 1;
325
326 # List assignment was leaking when assigning explosive scalars to
327 # aggregates.
328 leak(2, 0, sub {
329     eval {%a = ($die_on_fetch, 0)}; # key
330     eval {%a = (0, $die_on_fetch)}; # value
331     eval {%a = ($die_on_fetch, $die_on_fetch)}; # both
332     eval {%a = ($die_on_fetch)}; # key, odd elements
333 }, 'hash assignment does not leak');
334 leak(2, 0, sub {
335     eval {@a = ($die_on_fetch)};
336     eval {($die_on_fetch, $b) = ($b, $die_on_fetch)};
337     # restore
338     tie $die_on_fetch, 'explosive_scalar', FETCH => 1;
339 }, 'array assignment does not leak');
340
341 # [perl #107000]
342 package hhtie {
343     sub TIEHASH { bless [] }
344     sub STORE    { $_[0][0]{$_[1]} = $_[2] }
345     sub FETCH    { die if $explosive; $_[0][0]{$_[1]} }
346     sub FIRSTKEY { keys %{$_[0][0]}; each %{$_[0][0]} }
347     sub NEXTKEY  { each %{$_[0][0]} }
348 }
349 leak(2, 0, sub {
350     eval q`
351         BEGIN {
352             $hhtie::explosive = 0;
353             tie %^H, hhtie;
354             $^H{foo} = bar;
355             $hhtie::explosive = 1;
356         }
357         { 1; }
358     `;
359 }, 'hint-hash copying does not leak');
360
361 package explosive_array {
362     sub TIEARRAY  { bless [[], {}], $_[0]  }
363     sub FETCH     { die if $_[0]->[1]{FETCH}; $_[0]->[0][$_[1]]  }
364     sub FETCHSIZE { die if $_[0]->[1]{FETCHSIZE}; scalar @{ $_[0]->[0]  }  }
365     sub STORE     { die if $_[0]->[1]{STORE}; $_[0]->[0][$_[1]] = $_[2]  }
366     sub CLEAR     { die if $_[0]->[1]{CLEAR}; @{$_[0]->[0]} = ()  }
367     sub EXTEND    { die if $_[0]->[1]{EXTEND}; return  }
368     sub explode   { my $self = shift; $self->[1] = {@_} }
369 }
370
371 leak(2, 0, sub {
372     tie my @a, 'explosive_array';
373     tied(@a)->explode( STORE => 1 );
374     my $x = 0;
375     eval { @a = ($x)  };
376 }, 'explosive array assignment does not leak');
377
378 leak(2, 0, sub {
379     my ($a, $b);
380     eval { warn $die_on_fetch };
381 }, 'explosive warn argument');
382
383 leak(2, 0, sub {
384     my $foo = sub { return $die_on_fetch };
385     my $res = eval { $foo->() };
386     my @res = eval { $foo->() };
387 }, 'function returning explosive does not leak');
388
389 leak(2, 0, sub {
390     my $res = eval { {$die_on_fetch, 0} };
391     $res = eval { {0, $die_on_fetch} };
392 }, 'building anon hash with explosives does not leak');
393
394 leak(2, 0, sub {
395     my $res = eval { [$die_on_fetch] };
396 }, 'building anon array with explosives does not leak');
397
398 leak(2, 0, sub {
399     my @a;
400     eval { push @a, $die_on_fetch };
401 }, 'pushing exploding scalar does not leak');
402
403 leak(2, 0, sub {
404     eval { push @-, '' };
405 }, 'pushing onto read-only array does not leak');
406
407
408 # Run-time regexp code blocks
409 {
410     use re 'eval';
411     my @tests = ('[(?{})]','(?{})');
412     for my $t (@tests) {
413         leak(2, 0, sub {
414             / $t/;
415         }, "/ \$x/ where \$x is $t does not leak");
416         leak(2, 0, sub {
417             /(?{})$t/;
418         }, "/(?{})\$x/ where \$x is $t does not leak");
419     }
420 }
421
422
423 {
424     use warnings FATAL => 'all';
425     leak(2, 0, sub {
426         no warnings 'once';
427         eval { printf uNopened 42 };
428     }, 'printfing to bad handle under fatal warnings does not leak');
429     open my $fh, ">", \my $buf;
430     leak(2, 0, sub {
431         eval { printf $fh chr 2455 };
432     }, 'wide fatal warning does not make printf leak');
433     close $fh or die $!;
434 }
435
436
437 leak(2,0,sub{eval{require untohunothu}}, 'requiring nonexistent module');