autodoc.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Unconditionally regenerate:
   4 #
   5 #    pod/perlintern.pod
   6 #    pod/perlapi.pod
   7 #
   8 # from information stored in
   9 #
  10 #    embed.fnc
  11 #    plus all the .c and .h files listed in MANIFEST
  12 #
  13 # Has an optional arg, which is the directory to chdir to before reading
  14 # MANIFEST and *.[ch].
  15 #
  16 # This script is invoked as part of 'make all'
  17 #
  18 # '=head1' are the only headings looked for.  If the first non-blank line after
  19 # the heading begins with a word character, it is considered to be the first
  20 # line of documentation that applies to the heading itself.  That is, it is
  21 # output immediately after the heading, before the first function, and not
  22 # indented. The next input line that is a pod directive terminates this
  23 # heading-level documentation.
  24
  25 # The meanings of the flags fields in embed.fnc and the source code is
  26 # documented at the top of embed.fnc.
  27
  28 use strict;
  29
  30 if (@ARGV) {
  31     my $workdir = shift;
  32     chdir $workdir
  33         or die "Couldn't chdir to '$workdir': $!";
  34 }
  35 require './regen/regen_lib.pl';
  36 require './regen/embed_lib.pl';
  37
  38 my @specialized_docs = sort qw( perlguts
  39                                 perlxs
  40                                 perlxstut
  41                                 perlclib
  42                                 warnings
  43                               );
  44 my $other_places_api = join " ",    map { "L<$_>" } sort @specialized_docs, 'perlintern';
  45 my $other_places_intern = join " ", map { "L<$_>" } sort @specialized_docs, 'perlapi';
  46
  47 @specialized_docs = map { "L<$_>" } sort @specialized_docs;
  48 $specialized_docs[-1] =~ s/^/and /;
  49 my $specialized_docs = join ", ", @specialized_docs;
  50
  51 #
  52 # See database of global and static function prototypes in embed.fnc
  53 # This is used to generate prototype headers under various configurations,
  54 # export symbols lists for different platforms, and macros to provide an
  55 # implicit interpreter context argument.
  56 #
  57
  58 my %docs;
  59 my %funcflags;
  60 my %missing;
  61
  62 my $curheader = "Unknown section";
  63
  64 sub autodoc ($$) { # parse a file and extract documentation info
  65     my($fh,$file) = @_;
  66     my($in, $doc, $line, $header_doc);
  67
  68     # Count lines easier
  69     my $get_next_line = sub { $line++; return <$fh> };
  70
  71 FUNC:
  72     while (defined($in = $get_next_line->())) {
  73         if ($in=~ /^=head1 (.*)/) {
  74             $curheader = $1;
  75
  76             # If the next non-space line begins with a word char, then it is
  77             # the start of heading-level documentation.
  78             if (defined($doc = $get_next_line->())) {
  79                 # Skip over empty lines
  80                 while ($doc =~ /^\s+$/) {
  81                     if (! defined($doc = $get_next_line->())) {
  82                         next FUNC;
  83                     }
  84                 }
  85
  86                 if ($doc !~ /^\w/) {
  87                     $in = $doc;
  88                     redo FUNC;
  89                 }
  90                 $header_doc = $doc;
  91
  92                 # Continue getting the heading-level documentation until read
  93                 # in any pod directive (or as a fail-safe, find a closing
  94                 # comment to this pod in a C language file
  95 HDR_DOC:
  96                 while (defined($doc = $get_next_line->())) {
  97                     if ($doc =~ /^=\w/) {
  98                         $in = $doc;
  99                         redo FUNC;
 100                     }
 101
 102                     if ($doc =~ m:^\s*\*/$:) {
 103                         warn "=cut missing? $file:$line:$doc";;
 104                         last HDR_DOC;
 105                     }
 106                     $header_doc .= $doc;
 107                 }
 108             }
 109             next FUNC;
 110         }
 111         if ($in =~ /^=for\s+apidoc\s+(.*?)\s*\n/) {
 112             my $proto_in_file = $1;
 113             my $proto = $proto_in_file;
 114             $proto = "||$proto" unless $proto =~ /\|/;
 115             my($flags, $ret, $name, @args) = split /\s*\|\s*/, $proto;
 116             $name or die <<EOS;
 117 Bad apidoc at $file line $.:
 118   $in
 119 Expected:
 120   =for apidoc flags|returntype|name|arg|arg|...
 121   =for apidoc flags|returntype|name
 122   =for apidoc name
 123 EOS
 124             next FUNC if $flags =~ /h/;
 125
 126             warn ("'$name' not \\w+ in '$proto_in_file' in $file")
 127                         if $flags !~ /N/ && $name !~ / ^ [_[:alpha:]] \w* $ /x;
 128             my $docs = "";
 129 DOC:
 130             while (defined($doc = $get_next_line->())) {
 131
 132                 # Other pod commands are considered part of the current
 133                 # function's docs, so can have lists, etc.
 134                 last DOC if $doc =~ /^=(cut|for\s+apidoc|head)/;
 135                 if ($doc =~ m:^\*/$:) {
 136                     warn "=cut missing? $file:$line:$doc";;
 137                     last DOC;
 138                 }
 139                 $docs .= $doc;
 140             }
 141             $docs = "\n$docs" if $docs and $docs !~ /^\n/;
 142
 143             # If the entry is also in embed.fnc, it should be defined
 144             # completely there, but not here
 145             my $embed_docref = delete $funcflags{$name};
 146             if ($embed_docref and %$embed_docref) {
 147                 warn "embed.fnc entry overrides redundant information in"
 148                    . " '$proto_in_file' in $file" if $flags || $ret || @args;
 149                 $flags = $embed_docref->{'flags'};
 150                 warn "embed.fnc entry '$name' missing 'd' flag"
 151                                                             unless $flags =~ /d/;
 152                 next FUNC if $flags =~ /h/;
 153                 $ret = $embed_docref->{'retval'};
 154                 @args = @{$embed_docref->{args}};
 155             } elsif ($flags !~ /m/)  { # Not in embed.fnc, is missing if not a
 156                                        # macro
 157                 $missing{$name} = $file;
 158             }
 159
 160             my $inline_where = $flags =~ /A/ ? 'api' : 'guts';
 161
 162             if (exists $docs{$inline_where}{$curheader}{$name}) {
 163                 warn "$0: duplicate API entry for '$name' in $inline_where/$curheader\n";
 164                 next;
 165             }
 166             $docs{$inline_where}{$curheader}{$name}
 167                 = [$flags, $docs, $ret, $file, @args];
 168
 169             # Create a special entry with an empty-string name for the
 170             # heading-level documentation.
 171             if (defined $header_doc) {
 172                 $docs{$inline_where}{$curheader}{""} = $header_doc;
 173                 undef $header_doc;
 174             }
 175
 176             if (defined $doc) {
 177                 if ($doc =~ /^=(?:for|head)/) {
 178                     $in = $doc;
 179                     redo FUNC;
 180                 }
 181             } else {
 182                 warn "$file:$line:$in";
 183             }
 184         }
 185     }
 186 }
 187
 188 sub docout ($$$) { # output the docs for one function
 189     my($fh, $name, $docref) = @_;
 190     my($flags, $docs, $ret, $file, @args) = @$docref;
 191     $name =~ s/\s*$//;
 192
 193     if ($flags =~ /D/) {
 194         $docs = "\n\nDEPRECATED!  It is planned to remove this function from a
 195 future release of Perl.  Do not use it for new code; remove it from
 196 existing code.\n\n$docs";
 197     }
 198     else {
 199         $docs = "\n\nNOTE: this function is experimental and may change or be
 200 removed without notice.\n\n$docs" if $flags =~ /x/;
 201     }
 202
 203     # Is Perl_, but no #define foo # Perl_foo
 204     my $p = $flags =~ /p/ && $flags =~ /o/ && $flags !~ /M/;
 205
 206     $docs .= "NOTE: the perl_ form of this function is deprecated.\n\n"
 207          if $flags =~ /O/;
 208     if ($p) {
 209         $docs .= "NOTE: this function must be explicitly called as Perl_$name";
 210         $docs .= " with an aTHX_ parameter" if $flags !~ /T/;
 211         $docs .= ".\n\n"
 212     }
 213
 214     print $fh "=item $name\nX<$name>\n$docs";
 215
 216     if ($flags =~ /U/) { # no usage
 217         warn("U and s flags are incompatible") if $flags =~ /s/;
 218         # nothing
 219     } else {
 220         if ($flags =~ /n/) { # no args
 221             warn("n flag without m") unless $flags =~ /m/;
 222             warn("n flag but apparently has args") if @args;
 223             print $fh "\t$ret\t$name";
 224         } else { # full usage
 225             my $n            = "Perl_"x$p . $name;
 226             my $large_ret    = length $ret > 7;
 227             my $indent_size  = 7+8 # nroff: 7 under =head + 8 under =item
 228                             +8+($large_ret ? 1 + length $ret : 8)
 229                             +length($n) + 1;
 230             my $indent;
 231             print $fh "\t$ret" . ($large_ret ? ' ' : "\t") . "$n(";
 232             my $long_args;
 233             for (@args) {
 234                 if ($indent_size + 2 + length > 79) {
 235                     $long_args=1;
 236                     $indent_size -= length($n) - 3;
 237                     last;
 238                 }
 239             }
 240             my $args = '';
 241             if ($p && $flags !~ /T/) {
 242                 $args = @args ? "pTHX_ " : "pTHX";
 243                 if ($long_args) { print $fh $args; $args = '' }
 244             }
 245             $long_args and print $fh "\n";
 246             my $first = !$long_args;
 247             while () {
 248                 if (!@args or
 249                     length $args
 250                     && $indent_size + 3 + length($args[0]) + length $args > 79
 251                 ) {
 252                     print $fh
 253                     $first ? '' : (
 254                         $indent //=
 255                         "\t".($large_ret ? " " x (1+length $ret) : "\t")
 256                         ." "x($long_args ? 4 : 1 + length $n)
 257                     ),
 258                     $args, (","x($args ne 'pTHX_ ') . "\n")x!!@args;
 259                     $args = $first = '';
 260                 }
 261                 @args or last;
 262                 $args .= ", "x!!(length $args && $args ne 'pTHX_ ')
 263                     . shift @args;
 264             }
 265             if ($long_args) { print $fh "\n", substr $indent, 0, -4 }
 266             print $fh ")";
 267         }
 268         print $fh ";" if $flags =~ /s/; # semicolon "dTHR;"
 269         print $fh "\n\n";
 270     }
 271     print $fh "=for hackers\nFound in file $file\n\n";
 272 }
 273
 274 sub sort_helper {
 275     # Do a case-insensitive dictionary sort, with only alphabetics
 276     # significant, falling back to using everything for determinancy
 277     return (uc($a =~ s/[[:^alpha:]]//r) cmp uc($b =~ s/[[:^alpha:]]//r))
 278            || uc($a) cmp uc($b)
 279            || $a cmp $b;
 280 }
 281
 282 sub output {
 283     my ($podname, $header, $dochash, $missing, $footer) = @_;
 284     #
 285     # strip leading '|' from each line which had been used to hide
 286     # pod from pod checkers.
 287     s/^\|//gm for $header, $footer;
 288
 289     my $fh = open_new("pod/$podname.pod", undef,
 290                       {by => "$0 extracting documentation",
 291                        from => 'the C source files'}, 1);
 292
 293     print $fh $header;
 294
 295     my $key;
 296     for $key (sort sort_helper keys %$dochash) {
 297         my $section = $dochash->{$key};
 298         print $fh "\n=head1 $key\n\n";
 299
 300         # Output any heading-level documentation and delete so won't get in
 301         # the way later
 302         if (exists $section->{""}) {
 303             print $fh $section->{""} . "\n";
 304             delete $section->{""};
 305         }
 306         print $fh "=over 8\n\n";
 307
 308         for my $key (sort sort_helper keys %$section) {
 309             docout($fh, $key, $section->{$key});
 310         }
 311         print $fh "\n=back\n";
 312     }
 313
 314     if (@$missing) {
 315         print $fh "\n=head1 Undocumented functions\n\n";
 316     print $fh $podname eq 'perlapi' ? <<'_EOB_' : <<'_EOB_';
 317 The following functions have been flagged as part of the public API,
 318 but are currently undocumented.  Use them at your own risk, as the
 319 interfaces are subject to change.  Functions that are not listed in this
 320 document are not intended for public use, and should NOT be used under any
 321 circumstances.
 322
 323 If you feel you need to use one of these functions, first send email to
 324 L<perl5-porters@perl.org|mailto:perl5-porters@perl.org>.  It may be
 325 that there is a good reason for the function not being documented, and it
 326 should be removed from this list; or it may just be that no one has gotten
 327 around to documenting it.  In the latter case, you will be asked to submit a
 328 patch to document the function.  Once your patch is accepted, it will indicate
 329 that the interface is stable (unless it is explicitly marked otherwise) and
 330 usable by you.
 331 _EOB_
 332 The following functions are currently undocumented.  If you use one of
 333 them, you may wish to consider creating and submitting documentation for
 334 it.
 335 _EOB_
 336     print $fh "\n=over\n\n";
 337
 338     for my $missing (sort @$missing) {
 339         print $fh "=item $missing\nX<$missing>\n\n";
 340     }
 341     print $fh "=back\n\n";
 342 }
 343     print $fh $footer, "=cut\n";
 344
 345     read_only_bottom_close_and_rename($fh);
 346 }
 347
 348 foreach (@{(setup_embed())[0]}) {
 349     next if @$_ < 2;
 350     my ($flags, $retval, $func, @args) = @$_;
 351     s/\b(?:NN|NULLOK)\b\s+//g for @args;
 352
 353     $funcflags{$func} = {
 354                          flags => $flags,
 355                          retval => $retval,
 356                          args => \@args,
 357                         };
 358 }
 359
 360 # glob() picks up docs from extra .c or .h files that may be in unclean
 361 # development trees.
 362 open my $fh, '<', 'MANIFEST'
 363     or die "Can't open MANIFEST: $!";
 364 while (my $line = <$fh>) {
 365     next unless my ($file) = $line =~ /^(\S+\.(?:[ch]|pod))\t/;
 366
 367     open F, '<', $file or die "Cannot open $file for docs: $!\n";
 368     $curheader = "Functions in file $file\n";
 369     autodoc(\*F,$file);
 370     close F or die "Error closing $file: $!\n";
 371 }
 372 close $fh or die "Error whilst reading MANIFEST: $!";
 373
 374 for (sort keys %funcflags) {
 375     next unless $funcflags{$_}{flags} =~ /d/;
 376     next if $funcflags{$_}{flags} =~ /h/;
 377     warn "no docs for $_\n"
 378 }
 379
 380 foreach (sort keys %missing) {
 381     warn "Function '$_', documented in $missing{$_}, not listed in embed.fnc";
 382 }
 383
 384 # walk table providing an array of components in each line to
 385 # subroutine, printing the result
 386
 387 # List of funcs in the public API that aren't also marked as experimental nor
 388 # deprecated.
 389 my @missing_api = grep $funcflags{$_}{flags} =~ /A/
 390                     && $funcflags{$_}{flags} !~ /[xD]/
 391                     && !$docs{api}{$_}, keys %funcflags;
 392 output('perlapi', <<"_EOB_", $docs{api}, \@missing_api, <<"_EOE_");
 393 |=encoding UTF-8
 394 |
 395 |=head1 NAME
 396 |
 397 |perlapi - autogenerated documentation for the perl public API
 398 |
 399 |=head1 DESCRIPTION
 400 |X<Perl API> X<API> X<api>
 401 |
 402 |This file contains most of the documentation of the perl public API, as
 403 |generated by F<embed.pl>.  Specifically, it is a listing of functions,
 404 |macros, flags, and variables that may be used by extension writers.  Some
 405 |specialized items are instead documented in $specialized_docs.
 406 |
 407 |L<At the end|/Undocumented functions> is a list of functions which have yet
 408 |to be documented.  Patches welcome!  The interfaces of these are subject to
 409 |change without notice.
 410 |
 411 |Anything not listed here is not part of the public API, and should not be
 412 |used by extension writers at all.  For these reasons, blindly using functions
 413 |listed in proto.h is to be avoided when writing extensions.
 414 |
 415 |In Perl, unlike C, a string of characters may generally contain embedded
 416 |C<NUL> characters.  Sometimes in the documentation a Perl string is referred
 417 |to as a "buffer" to distinguish it from a C string, but sometimes they are
 418 |both just referred to as strings.
 419 |
 420 |Note that all Perl API global variables must be referenced with the C<PL_>
 421 |prefix.  Again, those not listed here are not to be used by extension writers,
 422 |and can be changed or removed without notice; same with macros.
 423 |Some macros are provided for compatibility with the older,
 424 |unadorned names, but this support may be disabled in a future release.
 425 |
 426 |Perl was originally written to handle US-ASCII only (that is characters
 427 |whose ordinal numbers are in the range 0 - 127).
 428 |And documentation and comments may still use the term ASCII, when
 429 |sometimes in fact the entire range from 0 - 255 is meant.
 430 |
 431 |The non-ASCII characters below 256 can have various meanings, depending on
 432 |various things.  (See, most notably, L<perllocale>.)  But usually the whole
 433 |range can be referred to as ISO-8859-1.  Often, the term "Latin-1" (or
 434 |"Latin1") is used as an equivalent for ISO-8859-1.  But some people treat
 435 |"Latin1" as referring just to the characters in the range 128 through 255, or
 436 |somethimes from 160 through 255.
 437 |This documentation uses "Latin1" and "Latin-1" to refer to all 256 characters.
 438 |
 439 |Note that Perl can be compiled and run under either ASCII or EBCDIC (See
 440 |L<perlebcdic>).  Most of the documentation (and even comments in the code)
 441 |ignore the EBCDIC possibility.
 442 |For almost all purposes the differences are transparent.
 443 |As an example, under EBCDIC,
 444 |instead of UTF-8, UTF-EBCDIC is used to encode Unicode strings, and so
 445 |whenever this documentation refers to C<utf8>
 446 |(and variants of that name, including in function names),
 447 |it also (essentially transparently) means C<UTF-EBCDIC>.
 448 |But the ordinals of characters differ between ASCII, EBCDIC, and
 449 |the UTF- encodings, and a string encoded in UTF-EBCDIC may occupy a different
 450 |number of bytes than in UTF-8.
 451 |
 452 |The listing below is alphabetical, case insensitive.
 453 |
 454 _EOB_
 455 |
 456 |=head1 AUTHORS
 457 |
 458 |Until May 1997, this document was maintained by Jeff Okamoto
 459 |<okamoto\@corp.hp.com>.  It is now maintained as part of Perl itself.
 460 |
 461 |With lots of help and suggestions from Dean Roehrich, Malcolm Beattie,
 462 |Andreas Koenig, Paul Hudson, Ilya Zakharevich, Paul Marquess, Neil
 463 |Bowers, Matthew Green, Tim Bunce, Spider Boardman, Ulrich Pfeifer,
 464 |Stephen McCamant, and Gurusamy Sarathy.
 465 |
 466 |API Listing originally by Dean Roehrich <roehrich\@cray.com>.
 467 |
 468 |Updated to be autogenerated from comments in the source by Benjamin Stuhl.
 469 |
 470 |=head1 SEE ALSO
 471 |
 472 $other_places_api
 473 _EOE_
 474
 475 # List of non-static internal functions
 476 my @missing_guts =
 477  grep $funcflags{$_}{flags} !~ /[AS]/ && !$docs{guts}{$_}, keys %funcflags;
 478
 479 output('perlintern', <<'_EOB_', $docs{guts}, \@missing_guts, <<"_EOE_");
 480 |=head1 NAME
 481 |
 482 |perlintern - autogenerated documentation of purely B<internal>
 483 |Perl functions
 484 |
 485 |=head1 DESCRIPTION
 486 |X<internal Perl functions> X<interpreter functions>
 487 |
 488 |This file is the autogenerated documentation of functions in the
 489 |Perl interpreter that are documented using Perl's internal documentation
 490 |format but are not marked as part of the Perl API.  In other words,
 491 |B<they are not for use in extensions>!
 492 |
 493 _EOB_
 494 |
 495 |=head1 AUTHORS
 496 |
 497 |The autodocumentation system was originally added to the Perl core by
 498 |Benjamin Stuhl.  Documentation is by whoever was kind enough to
 499 |document their functions.
 500 |
 501 |=head1 SEE ALSO
 502 |
 503 $other_places_intern
 504 _EOE_