This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlfunc.pod: ioctl.ph
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy : if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds have elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 =item bind SOCKET,NAME
450
451 Binds a network address to a socket, just as the bind system call
452 does.  Returns true if it succeeded, false otherwise.  NAME should be a
453 packed address of the appropriate type for the socket.  See the examples in
454 L<perlipc/"Sockets: Client/Server Communication">.
455
456 =item binmode FILEHANDLE, LAYER
457
458 =item binmode FILEHANDLE
459
460 Arranges for FILEHANDLE to be read or written in "binary" or "text"
461 mode on systems where the run-time libraries distinguish between
462 binary and text files.  If FILEHANDLE is an expression, the value is
463 taken as the name of the filehandle.  Returns true on success,
464 otherwise it returns C<undef> and sets C<$!> (errno).
465
466 On some systems (in general, DOS and Windows-based systems) binmode()
467 is necessary when you're not working with a text file.  For the sake
468 of portability it is a good idea to always use it when appropriate,
469 and to never use it when it isn't appropriate.  Also, people can
470 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
471
472 In other words: regardless of platform, use binmode() on binary data,
473 like for example images.
474
475 If LAYER is present it is a single string, but may contain multiple
476 directives. The directives alter the behaviour of the file handle.
477 When LAYER is present using binmode on text file makes sense.
478
479 If LAYER is omitted or specified as C<:raw> the filehandle is made
480 suitable for passing binary data. This includes turning off possible CRLF
481 translation and marking it as bytes (as opposed to Unicode characters).
482 Note that, despite what may be implied in I<"Programming Perl"> (the
483 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
484 -- other layers which would affect binary nature of the stream are
485 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
486 PERLIO environment variable.
487
488 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
489 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
490 establish default I/O layers.  See L<open>.
491
492 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
493 in "Programming Perl, 3rd Edition".  However, since the publishing of this
494 book, by many known as "Camel III", the consensus of the naming of this
495 functionality has moved from "discipline" to "layer".  All documentation
496 of this version of Perl therefore refers to "layers" rather than to
497 "disciplines".  Now back to the regularly scheduled documentation...>
498
499 To mark FILEHANDLE as UTF-8, use C<:utf8>.
500
501 In general, binmode() should be called after open() but before any I/O
502 is done on the filehandle.  Calling binmode() will normally flush any
503 pending buffered output data (and perhaps pending input data) on the
504 handle.  An exception to this is the C<:encoding> layer that
505 changes the default character encoding of the handle, see L<open>.
506 The C<:encoding> layer sometimes needs to be called in
507 mid-stream, and it doesn't flush the stream.  The C<:encoding>
508 also implicitly pushes on top of itself the C<:utf8> layer because
509 internally Perl will operate on UTF-8 encoded Unicode characters.
510
511 The operating system, device drivers, C libraries, and Perl run-time
512 system all work together to let the programmer treat a single
513 character (C<\n>) as the line terminator, irrespective of the external
514 representation.  On many operating systems, the native text file
515 representation matches the internal representation, but on some
516 platforms the external representation of C<\n> is made up of more than
517 one character.
518
519 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
520 character to end each line in the external representation of text (even
521 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
522 on Unix and most VMS files). In other systems like OS/2, DOS and the
523 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
524 but what's stored in text files are the two characters C<\cM\cJ>.  That
525 means that, if you don't use binmode() on these systems, C<\cM\cJ>
526 sequences on disk will be converted to C<\n> on input, and any C<\n> in
527 your program will be converted back to C<\cM\cJ> on output.  This is what
528 you want for text files, but it can be disastrous for binary files.
529
530 Another consequence of using binmode() (on some systems) is that
531 special end-of-file markers will be seen as part of the data stream.
532 For systems from the Microsoft family this means that if your binary
533 data contains C<\cZ>, the I/O subsystem will regard it as the end of
534 the file, unless you use binmode().
535
536 binmode() is not only important for readline() and print() operations,
537 but also when using read(), seek(), sysread(), syswrite() and tell()
538 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
539 in L<perlvar> for how to manually set your input and output
540 line-termination sequences.
541
542 =item bless REF,CLASSNAME
543
544 =item bless REF
545
546 This function tells the thingy referenced by REF that it is now an object
547 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
548 is used.  Because a C<bless> is often the last thing in a constructor,
549 it returns the reference for convenience.  Always use the two-argument
550 version if the function doing the blessing might be inherited by a
551 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
552 (and blessings) of objects.
553
554 Consider always blessing objects in CLASSNAMEs that are mixed case.
555 Namespaces with all lowercase names are considered reserved for
556 Perl pragmata.  Builtin types have all uppercase names, so to prevent
557 confusion, you may wish to avoid such package names as well.  Make sure
558 that CLASSNAME is a true value.
559
560 See L<perlmod/"Perl Modules">.
561
562 =item caller EXPR
563
564 =item caller
565
566 Returns the context of the current subroutine call.  In scalar context,
567 returns the caller's package name if there is a caller, that is, if
568 we're in a subroutine or C<eval> or C<require>, and the undefined value
569 otherwise.  In list context, returns
570
571     ($package, $filename, $line) = caller;
572
573 With EXPR, it returns some extra information that the debugger uses to
574 print a stack trace.  The value of EXPR indicates how many call frames
575 to go back before the current one.
576
577     ($package, $filename, $line, $subroutine, $hasargs,
578     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
579
580 Here $subroutine may be C<(eval)> if the frame is not a subroutine
581 call, but an C<eval>.  In such a case additional elements $evaltext and
582 C<$is_require> are set: C<$is_require> is true if the frame is created by a
583 C<require> or C<use> statement, $evaltext contains the text of the
584 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
585 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
586 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
587 frame.)  $subroutine may also be C<(unknown)> if this particular
588 subroutine happens to have been deleted from the symbol table.
589 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
590 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
591 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
592 between versions of Perl, and are not meant for external use.
593
594 Furthermore, when called from within the DB package, caller returns more
595 detailed information: it sets the list variable C<@DB::args> to be the
596 arguments with which the subroutine was invoked.
597
598 Be aware that the optimizer might have optimized call frames away before
599 C<caller> had a chance to get the information.  That means that C<caller(N)>
600 might not return information about the call frame you expect it do, for
601 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
602 previous time C<caller> was called.
603
604 =item chdir EXPR
605
606 Changes the working directory to EXPR, if possible. If EXPR is omitted,
607 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
608 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
609 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
610 neither is set, C<chdir> does nothing. It returns true upon success,
611 false otherwise. See the example under C<die>.
612
613 =item chmod LIST
614
615 Changes the permissions of a list of files.  The first element of the
616 list must be the numerical mode, which should probably be an octal
617 number, and which definitely should I<not> be a string of octal digits:
618 C<0644> is okay, C<'0644'> is not.  Returns the number of files
619 successfully changed.  See also L</oct>, if all you have is a string.
620
621     $cnt = chmod 0755, 'foo', 'bar';
622     chmod 0755, @executables;
623     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
624                                              # --w----r-T
625     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
626     $mode = 0644;   chmod $mode, 'foo';      # this is best
627
628 You can also import the symbolic C<S_I*> constants from the Fcntl
629 module:
630
631     use Fcntl ':mode';
632
633     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
634     # This is identical to the chmod 0755 of the above example.
635
636 =item chomp VARIABLE
637
638 =item chomp( LIST )
639
640 =item chomp
641
642 This safer version of L</chop> removes any trailing string
643 that corresponds to the current value of C<$/> (also known as
644 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
645 number of characters removed from all its arguments.  It's often used to
646 remove the newline from the end of an input record when you're worried
647 that the final record may be missing its newline.  When in paragraph
648 mode (C<$/ = "">), it removes all trailing newlines from the string.
649 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
650 a reference to an integer or the like, see L<perlvar>) chomp() won't
651 remove anything.
652 If VARIABLE is omitted, it chomps C<$_>.  Example:
653
654     while (<>) {
655         chomp;  # avoid \n on last field
656         @array = split(/:/);
657         # ...
658     }
659
660 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
661
662 You can actually chomp anything that's an lvalue, including an assignment:
663
664     chomp($cwd = `pwd`);
665     chomp($answer = <STDIN>);
666
667 If you chomp a list, each element is chomped, and the total number of
668 characters removed is returned.
669
670 If the C<encoding> pragma is in scope then the lengths returned are
671 calculated from the length of C<$/> in Unicode characters, which is not
672 always the same as the length of C<$/> in the native encoding.
673
674 Note that parentheses are necessary when you're chomping anything
675 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
676 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
677 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
678 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
679 as C<chomp($a, $b)>.
680
681 =item chop VARIABLE
682
683 =item chop( LIST )
684
685 =item chop
686
687 Chops off the last character of a string and returns the character
688 chopped.  It is much more efficient than C<s/.$//s> because it neither
689 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
690 If VARIABLE is a hash, it chops the hash's values, but not its keys.
691
692 You can actually chop anything that's an lvalue, including an assignment.
693
694 If you chop a list, each element is chopped.  Only the value of the
695 last C<chop> is returned.
696
697 Note that C<chop> returns the last character.  To return all but the last
698 character, use C<substr($string, 0, -1)>.
699
700 See also L</chomp>.
701
702 =item chown LIST
703
704 Changes the owner (and group) of a list of files.  The first two
705 elements of the list must be the I<numeric> uid and gid, in that
706 order.  A value of -1 in either position is interpreted by most
707 systems to leave that value unchanged.  Returns the number of files
708 successfully changed.
709
710     $cnt = chown $uid, $gid, 'foo', 'bar';
711     chown $uid, $gid, @filenames;
712
713 Here's an example that looks up nonnumeric uids in the passwd file:
714
715     print "User: ";
716     chomp($user = <STDIN>);
717     print "Files: ";
718     chomp($pattern = <STDIN>);
719
720     ($login,$pass,$uid,$gid) = getpwnam($user)
721         or die "$user not in passwd file";
722
723     @ary = glob($pattern);      # expand filenames
724     chown $uid, $gid, @ary;
725
726 On most systems, you are not allowed to change the ownership of the
727 file unless you're the superuser, although you should be able to change
728 the group to any of your secondary groups.  On insecure systems, these
729 restrictions may be relaxed, but this is not a portable assumption.
730 On POSIX systems, you can detect this condition this way:
731
732     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
733     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
734
735 =item chr NUMBER
736
737 =item chr
738
739 Returns the character represented by that NUMBER in the character set.
740 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
741 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
742 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
743 backward compatibility reasons (but see L<encoding>).
744
745 Negative values give the Unicode replacement character (chr(0xfffd)),
746 except under the L</bytes> pragma, where low eight bits of the value
747 (truncated to an integer) are used.
748
749 If NUMBER is omitted, uses C<$_>.
750
751 For the reverse, use L</ord>.
752
753 Note that under the C<bytes> pragma the NUMBER is masked to
754 the low eight bits.
755
756 See L<perlunicode> and L<encoding> for more about Unicode.
757
758 =item chroot FILENAME
759
760 =item chroot
761
762 This function works like the system call by the same name: it makes the
763 named directory the new root directory for all further pathnames that
764 begin with a C</> by your process and all its children.  (It doesn't
765 change your current working directory, which is unaffected.)  For security
766 reasons, this call is restricted to the superuser.  If FILENAME is
767 omitted, does a C<chroot> to C<$_>.
768
769 =item close FILEHANDLE
770
771 =item close
772
773 Closes the file or pipe associated with the file handle, returning
774 true only if IO buffers are successfully flushed and closes the system
775 file descriptor.  Closes the currently selected filehandle if the
776 argument is omitted.
777
778 You don't have to close FILEHANDLE if you are immediately going to do
779 another C<open> on it, because C<open> will close it for you.  (See
780 C<open>.)  However, an explicit C<close> on an input file resets the line
781 counter (C<$.>), while the implicit close done by C<open> does not.
782
783 If the file handle came from a piped open, C<close> will additionally
784 return false if one of the other system calls involved fails, or if the
785 program exits with non-zero status.  (If the only problem was that the
786 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
787 also waits for the process executing on the pipe to complete, in case you
788 want to look at the output of the pipe afterwards, and
789 implicitly puts the exit status value of that command into C<$?> and
790 C<${^CHILD_ERROR_NATIVE}>.
791
792 Prematurely closing the read end of a pipe (i.e. before the process
793 writing to it at the other end has closed it) will result in a
794 SIGPIPE being delivered to the writer.  If the other end can't
795 handle that, be sure to read all the data before closing the pipe.
796
797 Example:
798
799     open(OUTPUT, '|sort >foo')  # pipe to sort
800         or die "Can't start sort: $!";
801     #...                        # print stuff to output
802     close OUTPUT                # wait for sort to finish
803         or warn $! ? "Error closing sort pipe: $!"
804                    : "Exit status $? from sort";
805     open(INPUT, 'foo')          # get sort's results
806         or die "Can't open 'foo' for input: $!";
807
808 FILEHANDLE may be an expression whose value can be used as an indirect
809 filehandle, usually the real filehandle name.
810
811 =item closedir DIRHANDLE
812
813 Closes a directory opened by C<opendir> and returns the success of that
814 system call.
815
816 =item connect SOCKET,NAME
817
818 Attempts to connect to a remote socket, just as the connect system call
819 does.  Returns true if it succeeded, false otherwise.  NAME should be a
820 packed address of the appropriate type for the socket.  See the examples in
821 L<perlipc/"Sockets: Client/Server Communication">.
822
823 =item continue BLOCK
824
825 Actually a flow control statement rather than a function.  If there is a
826 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
827 C<foreach>), it is always executed just before the conditional is about to
828 be evaluated again, just like the third part of a C<for> loop in C.  Thus
829 it can be used to increment a loop variable, even when the loop has been
830 continued via the C<next> statement (which is similar to the C C<continue>
831 statement).
832
833 C<last>, C<next>, or C<redo> may appear within a C<continue>
834 block.  C<last> and C<redo> will behave as if they had been executed within
835 the main block.  So will C<next>, but since it will execute a C<continue>
836 block, it may be more entertaining.
837
838     while (EXPR) {
839         ### redo always comes here
840         do_something;
841     } continue {
842         ### next always comes here
843         do_something_else;
844         # then back the top to re-check EXPR
845     }
846     ### last always comes here
847
848 Omitting the C<continue> section is semantically equivalent to using an
849 empty one, logically enough.  In that case, C<next> goes directly back
850 to check the condition at the top of the loop.
851
852 =item cos EXPR
853
854 =item cos
855
856 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
857 takes cosine of C<$_>.
858
859 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
860 function, or use this relation:
861
862     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
863
864 =item crypt PLAINTEXT,SALT
865
866 Encrypts a string exactly like the crypt(3) function in the C library
867 (assuming that you actually have a version there that has not been
868 extirpated as a potential munition).  This can prove useful for checking
869 the password file for lousy passwords, amongst other things.  Only the
870 guys wearing white hats should do this.
871
872 Note that L<crypt|/crypt> is intended to be a one-way function, much like
873 breaking eggs to make an omelette.  There is no (known) corresponding
874 decrypt function (in other words, the crypt() is a one-way hash
875 function).  As a result, this function isn't all that useful for
876 cryptography.  (For that, see your nearby CPAN mirror.)
877
878 When verifying an existing encrypted string you should use the
879 encrypted text as the salt (like C<crypt($plain, $crypted) eq
880 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
881 and with more exotic implementations.  In other words, do not assume
882 anything about the returned string itself, or how many bytes in
883 the encrypted string matter.
884
885 Traditionally the result is a string of 13 bytes: two first bytes of
886 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
887 the first eight bytes of the encrypted string mattered, but
888 alternative hashing schemes (like MD5), higher level security schemes
889 (like C2), and implementations on non-UNIX platforms may produce
890 different strings.
891
892 When choosing a new salt create a random two character string whose
893 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
894 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
895 characters is just a recommendation; the characters allowed in
896 the salt depend solely on your system's crypt library, and Perl can't
897 restrict what salts C<crypt()> accepts.
898
899 Here's an example that makes sure that whoever runs this program knows
900 their own password:
901
902     $pwd = (getpwuid($<))[1];
903
904     system "stty -echo";
905     print "Password: ";
906     chomp($word = <STDIN>);
907     print "\n";
908     system "stty echo";
909
910     if (crypt($word, $pwd) ne $pwd) {
911         die "Sorry...\n";
912     } else {
913         print "ok\n";
914     }
915
916 Of course, typing in your own password to whoever asks you
917 for it is unwise.
918
919 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
920 of data, not least of all because you can't get the information
921 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
922 on your favorite CPAN mirror for a slew of potentially useful
923 modules.
924
925 If using crypt() on a Unicode string (which I<potentially> has
926 characters with codepoints above 255), Perl tries to make sense
927 of the situation by trying to downgrade (a copy of the string)
928 the string back to an eight-bit byte string before calling crypt()
929 (on that copy).  If that works, good.  If not, crypt() dies with
930 C<Wide character in crypt>.
931
932 =item dbmclose HASH
933
934 [This function has been largely superseded by the C<untie> function.]
935
936 Breaks the binding between a DBM file and a hash.
937
938 =item dbmopen HASH,DBNAME,MASK
939
940 [This function has been largely superseded by the C<tie> function.]
941
942 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
943 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
944 argument is I<not> a filehandle, even though it looks like one).  DBNAME
945 is the name of the database (without the F<.dir> or F<.pag> extension if
946 any).  If the database does not exist, it is created with protection
947 specified by MASK (as modified by the C<umask>).  If your system supports
948 only the older DBM functions, you may perform only one C<dbmopen> in your
949 program.  In older versions of Perl, if your system had neither DBM nor
950 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
951 sdbm(3).
952
953 If you don't have write access to the DBM file, you can only read hash
954 variables, not set them.  If you want to test whether you can write,
955 either use file tests or try setting a dummy hash entry inside an C<eval>,
956 which will trap the error.
957
958 Note that functions such as C<keys> and C<values> may return huge lists
959 when used on large DBM files.  You may prefer to use the C<each>
960 function to iterate over large DBM files.  Example:
961
962     # print out history file offsets
963     dbmopen(%HIST,'/usr/lib/news/history',0666);
964     while (($key,$val) = each %HIST) {
965         print $key, ' = ', unpack('L',$val), "\n";
966     }
967     dbmclose(%HIST);
968
969 See also L<AnyDBM_File> for a more general description of the pros and
970 cons of the various dbm approaches, as well as L<DB_File> for a particularly
971 rich implementation.
972
973 You can control which DBM library you use by loading that library
974 before you call dbmopen():
975
976     use DB_File;
977     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
978         or die "Can't open netscape history file: $!";
979
980 =item defined EXPR
981
982 =item defined
983
984 Returns a Boolean value telling whether EXPR has a value other than
985 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
986 checked.
987
988 Many operations return C<undef> to indicate failure, end of file,
989 system error, uninitialized variable, and other exceptional
990 conditions.  This function allows you to distinguish C<undef> from
991 other values.  (A simple Boolean test will not distinguish among
992 C<undef>, zero, the empty string, and C<"0">, which are all equally
993 false.)  Note that since C<undef> is a valid scalar, its presence
994 doesn't I<necessarily> indicate an exceptional condition: C<pop>
995 returns C<undef> when its argument is an empty array, I<or> when the
996 element to return happens to be C<undef>.
997
998 You may also use C<defined(&func)> to check whether subroutine C<&func>
999 has ever been defined.  The return value is unaffected by any forward
1000 declarations of C<&func>.  Note that a subroutine which is not defined
1001 may still be callable: its package may have an C<AUTOLOAD> method that
1002 makes it spring into existence the first time that it is called -- see
1003 L<perlsub>.
1004
1005 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1006 used to report whether memory for that aggregate has ever been
1007 allocated.  This behavior may disappear in future versions of Perl.
1008 You should instead use a simple test for size:
1009
1010     if (@an_array) { print "has array elements\n" }
1011     if (%a_hash)   { print "has hash members\n"   }
1012
1013 When used on a hash element, it tells you whether the value is defined,
1014 not whether the key exists in the hash.  Use L</exists> for the latter
1015 purpose.
1016
1017 Examples:
1018
1019     print if defined $switch{'D'};
1020     print "$val\n" while defined($val = pop(@ary));
1021     die "Can't readlink $sym: $!"
1022         unless defined($value = readlink $sym);
1023     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1024     $debugging = 0 unless defined $debugging;
1025
1026 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1027 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1028 defined values.  For example, if you say
1029
1030     "ab" =~ /a(.*)b/;
1031
1032 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1033 matched "nothing".  But it didn't really match nothing--rather, it
1034 matched something that happened to be zero characters long.  This is all
1035 very above-board and honest.  When a function returns an undefined value,
1036 it's an admission that it couldn't give you an honest answer.  So you
1037 should use C<defined> only when you're questioning the integrity of what
1038 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1039 what you want.
1040
1041 See also L</undef>, L</exists>, L</ref>.
1042
1043 =item delete EXPR
1044
1045 Given an expression that specifies a hash element, array element, hash slice,
1046 or array slice, deletes the specified element(s) from the hash or array.
1047 In the case of an array, if the array elements happen to be at the end,
1048 the size of the array will shrink to the highest element that tests
1049 true for exists() (or 0 if no such element exists).
1050
1051 Returns a list with the same number of elements as the number of elements
1052 for which deletion was attempted.  Each element of that list consists of
1053 either the value of the element deleted, or the undefined value.  In scalar
1054 context, this means that you get the value of the last element deleted (or
1055 the undefined value if that element did not exist).
1056
1057     %hash = (foo => 11, bar => 22, baz => 33);
1058     $scalar = delete $hash{foo};             # $scalar is 11
1059     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1060     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1061
1062 Deleting from C<%ENV> modifies the environment.  Deleting from
1063 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1064 from a C<tie>d hash or array may not necessarily return anything.
1065
1066 Deleting an array element effectively returns that position of the array
1067 to its initial, uninitialized state.  Subsequently testing for the same
1068 element with exists() will return false.  Note that deleting array
1069 elements in the middle of an array will not shift the index of the ones
1070 after them down--use splice() for that.  See L</exists>.
1071
1072 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1073
1074     foreach $key (keys %HASH) {
1075         delete $HASH{$key};
1076     }
1077
1078     foreach $index (0 .. $#ARRAY) {
1079         delete $ARRAY[$index];
1080     }
1081
1082 And so do these:
1083
1084     delete @HASH{keys %HASH};
1085
1086     delete @ARRAY[0 .. $#ARRAY];
1087
1088 But both of these are slower than just assigning the empty list
1089 or undefining %HASH or @ARRAY:
1090
1091     %HASH = ();         # completely empty %HASH
1092     undef %HASH;        # forget %HASH ever existed
1093
1094     @ARRAY = ();        # completely empty @ARRAY
1095     undef @ARRAY;       # forget @ARRAY ever existed
1096
1097 Note that the EXPR can be arbitrarily complicated as long as the final
1098 operation is a hash element, array element,  hash slice, or array slice
1099 lookup:
1100
1101     delete $ref->[$x][$y]{$key};
1102     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1103
1104     delete $ref->[$x][$y][$index];
1105     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1106
1107 =item die LIST
1108
1109 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1110 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1111 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1112 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1113 an C<eval(),> the error message is stuffed into C<$@> and the
1114 C<eval> is terminated with the undefined value.  This makes
1115 C<die> the way to raise an exception.
1116
1117 Equivalent examples:
1118
1119     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1120     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1121
1122 If the last element of LIST does not end in a newline, the current
1123 script line number and input line number (if any) are also printed,
1124 and a newline is supplied.  Note that the "input line number" (also
1125 known as "chunk") is subject to whatever notion of "line" happens to
1126 be currently in effect, and is also available as the special variable
1127 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1128
1129 Hint: sometimes appending C<", stopped"> to your message will cause it
1130 to make better sense when the string C<"at foo line 123"> is appended.
1131 Suppose you are running script "canasta".
1132
1133     die "/etc/games is no good";
1134     die "/etc/games is no good, stopped";
1135
1136 produce, respectively
1137
1138     /etc/games is no good at canasta line 123.
1139     /etc/games is no good, stopped at canasta line 123.
1140
1141 See also exit(), warn(), and the Carp module.
1142
1143 If LIST is empty and C<$@> already contains a value (typically from a
1144 previous eval) that value is reused after appending C<"\t...propagated">.
1145 This is useful for propagating exceptions:
1146
1147     eval { ... };
1148     die unless $@ =~ /Expected exception/;
1149
1150 If LIST is empty and C<$@> contains an object reference that has a
1151 C<PROPAGATE> method, that method will be called with additional file
1152 and line number parameters.  The return value replaces the value in
1153 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1154 were called.
1155
1156 If C<$@> is empty then the string C<"Died"> is used.
1157
1158 die() can also be called with a reference argument.  If this happens to be
1159 trapped within an eval(), $@ contains the reference.  This behavior permits
1160 a more elaborate exception handling implementation using objects that
1161 maintain arbitrary state about the nature of the exception.  Such a scheme
1162 is sometimes preferable to matching particular string values of $@ using
1163 regular expressions.  Here's an example:
1164
1165     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1166     if ($@) {
1167         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1168             # handle Some::Module::Exception
1169         }
1170         else {
1171             # handle all other possible exceptions
1172         }
1173     }
1174
1175 Because perl will stringify uncaught exception messages before displaying
1176 them, you may want to overload stringification operations on such custom
1177 exception objects.  See L<overload> for details about that.
1178
1179 You can arrange for a callback to be run just before the C<die>
1180 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1181 handler will be called with the error text and can change the error
1182 message, if it sees fit, by calling C<die> again.  See
1183 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1184 L<"eval BLOCK"> for some examples.  Although this feature was meant
1185 to be run only right before your program was to exit, this is not
1186 currently the case--the C<$SIG{__DIE__}> hook is currently called
1187 even inside eval()ed blocks/strings!  If one wants the hook to do
1188 nothing in such situations, put
1189
1190         die @_ if $^S;
1191
1192 as the first line of the handler (see L<perlvar/$^S>).  Because
1193 this promotes strange action at a distance, this counterintuitive
1194 behavior may be fixed in a future release.
1195
1196 =item do BLOCK
1197
1198 Not really a function.  Returns the value of the last command in the
1199 sequence of commands indicated by BLOCK.  When modified by a loop
1200 modifier, executes the BLOCK once before testing the loop condition.
1201 (On other statements the loop modifiers test the conditional first.)
1202
1203 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1204 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1205 See L<perlsyn> for alternative strategies.
1206
1207 =item do SUBROUTINE(LIST)
1208
1209 A deprecated form of subroutine call.  See L<perlsub>.
1210
1211 =item do EXPR
1212
1213 Uses the value of EXPR as a filename and executes the contents of the
1214 file as a Perl script.
1215
1216     do 'stat.pl';
1217
1218 is just like
1219
1220     eval `cat stat.pl`;
1221
1222 except that it's more efficient and concise, keeps track of the current
1223 filename for error messages, searches the @INC directories, and updates
1224 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1225 variables.  It also differs in that code evaluated with C<do FILENAME>
1226 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1227 same, however, in that it does reparse the file every time you call it,
1228 so you probably don't want to do this inside a loop.
1229
1230 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1231 error.  If C<do> can read the file but cannot compile it, it
1232 returns undef and sets an error message in C<$@>.   If the file is
1233 successfully compiled, C<do> returns the value of the last expression
1234 evaluated.
1235
1236 Note that inclusion of library modules is better done with the
1237 C<use> and C<require> operators, which also do automatic error checking
1238 and raise an exception if there's a problem.
1239
1240 You might like to use C<do> to read in a program configuration
1241 file.  Manual error checking can be done this way:
1242
1243     # read in config files: system first, then user
1244     for $file ("/share/prog/defaults.rc",
1245                "$ENV{HOME}/.someprogrc")
1246    {
1247         unless ($return = do $file) {
1248             warn "couldn't parse $file: $@" if $@;
1249             warn "couldn't do $file: $!"    unless defined $return;
1250             warn "couldn't run $file"       unless $return;
1251         }
1252     }
1253
1254 =item dump LABEL
1255
1256 =item dump
1257
1258 This function causes an immediate core dump.  See also the B<-u>
1259 command-line switch in L<perlrun>, which does the same thing.
1260 Primarily this is so that you can use the B<undump> program (not
1261 supplied) to turn your core dump into an executable binary after
1262 having initialized all your variables at the beginning of the
1263 program.  When the new binary is executed it will begin by executing
1264 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1265 Think of it as a goto with an intervening core dump and reincarnation.
1266 If C<LABEL> is omitted, restarts the program from the top.
1267
1268 B<WARNING>: Any files opened at the time of the dump will I<not>
1269 be open any more when the program is reincarnated, with possible
1270 resulting confusion on the part of Perl.
1271
1272 This function is now largely obsolete, partly because it's very
1273 hard to convert a core file into an executable, and because the
1274 real compiler backends for generating portable bytecode and compilable
1275 C code have superseded it.  That's why you should now invoke it as
1276 C<CORE::dump()>, if you don't want to be warned against a possible
1277 typo.
1278
1279 If you're looking to use L<dump> to speed up your program, consider
1280 generating bytecode or native C code as described in L<perlcc>.  If
1281 you're just trying to accelerate a CGI script, consider using the
1282 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1283 You might also consider autoloading or selfloading, which at least
1284 make your program I<appear> to run faster.
1285
1286 =item each HASH
1287
1288 When called in list context, returns a 2-element list consisting of the
1289 key and value for the next element of a hash, so that you can iterate over
1290 it.  When called in scalar context, returns only the key for the next
1291 element in the hash.
1292
1293 Entries are returned in an apparently random order.  The actual random
1294 order is subject to change in future versions of perl, but it is
1295 guaranteed to be in the same order as either the C<keys> or C<values>
1296 function would produce on the same (unmodified) hash.  Since Perl
1297 5.8.1 the ordering is different even between different runs of Perl
1298 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1299
1300 When the hash is entirely read, a null array is returned in list context
1301 (which when assigned produces a false (C<0>) value), and C<undef> in
1302 scalar context.  The next call to C<each> after that will start iterating
1303 again.  There is a single iterator for each hash, shared by all C<each>,
1304 C<keys>, and C<values> function calls in the program; it can be reset by
1305 reading all the elements from the hash, or by evaluating C<keys HASH> or
1306 C<values HASH>.  If you add or delete elements of a hash while you're
1307 iterating over it, you may get entries skipped or duplicated, so
1308 don't.  Exception: It is always safe to delete the item most recently
1309 returned by C<each()>, which means that the following code will work:
1310
1311         while (($key, $value) = each %hash) {
1312           print $key, "\n";
1313           delete $hash{$key};   # This is safe
1314         }
1315
1316 The following prints out your environment like the printenv(1) program,
1317 only in a different order:
1318
1319     while (($key,$value) = each %ENV) {
1320         print "$key=$value\n";
1321     }
1322
1323 See also C<keys>, C<values> and C<sort>.
1324
1325 =item eof FILEHANDLE
1326
1327 =item eof ()
1328
1329 =item eof
1330
1331 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1332 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1333 gives the real filehandle.  (Note that this function actually
1334 reads a character and then C<ungetc>s it, so isn't very useful in an
1335 interactive context.)  Do not read from a terminal file (or call
1336 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1337 as terminals may lose the end-of-file condition if you do.
1338
1339 An C<eof> without an argument uses the last file read.  Using C<eof()>
1340 with empty parentheses is very different.  It refers to the pseudo file
1341 formed from the files listed on the command line and accessed via the
1342 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1343 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1344 used will cause C<@ARGV> to be examined to determine if input is
1345 available.   Similarly, an C<eof()> after C<< <> >> has returned
1346 end-of-file will assume you are processing another C<@ARGV> list,
1347 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1348 see L<perlop/"I/O Operators">.
1349
1350 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1351 detect the end of each file, C<eof()> will only detect the end of the
1352 last file.  Examples:
1353
1354     # reset line numbering on each input file
1355     while (<>) {
1356         next if /^\s*#/;        # skip comments
1357         print "$.\t$_";
1358     } continue {
1359         close ARGV  if eof;     # Not eof()!
1360     }
1361
1362     # insert dashes just before last line of last file
1363     while (<>) {
1364         if (eof()) {            # check for end of last file
1365             print "--------------\n";
1366         }
1367         print;
1368         last if eof();          # needed if we're reading from a terminal
1369     }
1370
1371 Practical hint: you almost never need to use C<eof> in Perl, because the
1372 input operators typically return C<undef> when they run out of data, or if
1373 there was an error.
1374
1375 =item eval EXPR
1376
1377 =item eval BLOCK
1378
1379 In the first form, the return value of EXPR is parsed and executed as if it
1380 were a little Perl program.  The value of the expression (which is itself
1381 determined within scalar context) is first parsed, and if there weren't any
1382 errors, executed in the lexical context of the current Perl program, so
1383 that any variable settings or subroutine and format definitions remain
1384 afterwards.  Note that the value is parsed every time the eval executes.
1385 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1386 delay parsing and subsequent execution of the text of EXPR until run time.
1387
1388 In the second form, the code within the BLOCK is parsed only once--at the
1389 same time the code surrounding the eval itself was parsed--and executed
1390 within the context of the current Perl program.  This form is typically
1391 used to trap exceptions more efficiently than the first (see below), while
1392 also providing the benefit of checking the code within BLOCK at compile
1393 time.
1394
1395 The final semicolon, if any, may be omitted from the value of EXPR or within
1396 the BLOCK.
1397
1398 In both forms, the value returned is the value of the last expression
1399 evaluated inside the mini-program; a return statement may be also used, just
1400 as with subroutines.  The expression providing the return value is evaluated
1401 in void, scalar, or list context, depending on the context of the eval itself.
1402 See L</wantarray> for more on how the evaluation context can be determined.
1403
1404 If there is a syntax error or runtime error, or a C<die> statement is
1405 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1406 error message.  If there was no error, C<$@> is guaranteed to be a null
1407 string.  Beware that using C<eval> neither silences perl from printing
1408 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1409 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1410 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1411 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1412
1413 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1414 determining whether a particular feature (such as C<socket> or C<symlink>)
1415 is implemented.  It is also Perl's exception trapping mechanism, where
1416 the die operator is used to raise exceptions.
1417
1418 If the code to be executed doesn't vary, you may use the eval-BLOCK
1419 form to trap run-time errors without incurring the penalty of
1420 recompiling each time.  The error, if any, is still returned in C<$@>.
1421 Examples:
1422
1423     # make divide-by-zero nonfatal
1424     eval { $answer = $a / $b; }; warn $@ if $@;
1425
1426     # same thing, but less efficient
1427     eval '$answer = $a / $b'; warn $@ if $@;
1428
1429     # a compile-time error
1430     eval { $answer = };                 # WRONG
1431
1432     # a run-time error
1433     eval '$answer =';   # sets $@
1434
1435 Due to the current arguably broken state of C<__DIE__> hooks, when using
1436 the C<eval{}> form as an exception trap in libraries, you may wish not
1437 to trigger any C<__DIE__> hooks that user code may have installed.
1438 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1439 as shown in this example:
1440
1441     # a very private exception trap for divide-by-zero
1442     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1443     warn $@ if $@;
1444
1445 This is especially significant, given that C<__DIE__> hooks can call
1446 C<die> again, which has the effect of changing their error messages:
1447
1448     # __DIE__ hooks may modify error messages
1449     {
1450        local $SIG{'__DIE__'} =
1451               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1452        eval { die "foo lives here" };
1453        print $@ if $@;                # prints "bar lives here"
1454     }
1455
1456 Because this promotes action at a distance, this counterintuitive behavior
1457 may be fixed in a future release.
1458
1459 With an C<eval>, you should be especially careful to remember what's
1460 being looked at when:
1461
1462     eval $x;            # CASE 1
1463     eval "$x";          # CASE 2
1464
1465     eval '$x';          # CASE 3
1466     eval { $x };        # CASE 4
1467
1468     eval "\$$x++";      # CASE 5
1469     $$x++;              # CASE 6
1470
1471 Cases 1 and 2 above behave identically: they run the code contained in
1472 the variable $x.  (Although case 2 has misleading double quotes making
1473 the reader wonder what else might be happening (nothing is).)  Cases 3
1474 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1475 does nothing but return the value of $x.  (Case 4 is preferred for
1476 purely visual reasons, but it also has the advantage of compiling at
1477 compile-time instead of at run-time.)  Case 5 is a place where
1478 normally you I<would> like to use double quotes, except that in this
1479 particular situation, you can just use symbolic references instead, as
1480 in case 6.
1481
1482 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1483 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1484
1485 Note that as a very special case, an C<eval ''> executed within the C<DB>
1486 package doesn't see the usual surrounding lexical scope, but rather the
1487 scope of the first non-DB piece of code that called it. You don't normally
1488 need to worry about this unless you are writing a Perl debugger.
1489
1490 =item exec LIST
1491
1492 =item exec PROGRAM LIST
1493
1494 The C<exec> function executes a system command I<and never returns>--
1495 use C<system> instead of C<exec> if you want it to return.  It fails and
1496 returns false only if the command does not exist I<and> it is executed
1497 directly instead of via your system's command shell (see below).
1498
1499 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1500 warns you if there is a following statement which isn't C<die>, C<warn>,
1501 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1502 I<really> want to follow an C<exec> with some other statement, you
1503 can use one of these styles to avoid the warning:
1504
1505     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1506     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1507
1508 If there is more than one argument in LIST, or if LIST is an array
1509 with more than one value, calls execvp(3) with the arguments in LIST.
1510 If there is only one scalar argument or an array with one element in it,
1511 the argument is checked for shell metacharacters, and if there are any,
1512 the entire argument is passed to the system's command shell for parsing
1513 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1514 If there are no shell metacharacters in the argument, it is split into
1515 words and passed directly to C<execvp>, which is more efficient.
1516 Examples:
1517
1518     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1519     exec "sort $outfile | uniq";
1520
1521 If you don't really want to execute the first argument, but want to lie
1522 to the program you are executing about its own name, you can specify
1523 the program you actually want to run as an "indirect object" (without a
1524 comma) in front of the LIST.  (This always forces interpretation of the
1525 LIST as a multivalued list, even if there is only a single scalar in
1526 the list.)  Example:
1527
1528     $shell = '/bin/csh';
1529     exec $shell '-sh';          # pretend it's a login shell
1530
1531 or, more directly,
1532
1533     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1534
1535 When the arguments get executed via the system shell, results will
1536 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1537 for details.
1538
1539 Using an indirect object with C<exec> or C<system> is also more
1540 secure.  This usage (which also works fine with system()) forces
1541 interpretation of the arguments as a multivalued list, even if the
1542 list had just one argument.  That way you're safe from the shell
1543 expanding wildcards or splitting up words with whitespace in them.
1544
1545     @args = ( "echo surprise" );
1546
1547     exec @args;               # subject to shell escapes
1548                                 # if @args == 1
1549     exec { $args[0] } @args;  # safe even with one-arg list
1550
1551 The first version, the one without the indirect object, ran the I<echo>
1552 program, passing it C<"surprise"> an argument.  The second version
1553 didn't--it tried to run a program literally called I<"echo surprise">,
1554 didn't find it, and set C<$?> to a non-zero value indicating failure.
1555
1556 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1557 output before the exec, but this may not be supported on some platforms
1558 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1559 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1560 open handles in order to avoid lost output.
1561
1562 Note that C<exec> will not call your C<END> blocks, nor will it call
1563 any C<DESTROY> methods in your objects.
1564
1565 =item exists EXPR
1566
1567 Given an expression that specifies a hash element or array element,
1568 returns true if the specified element in the hash or array has ever
1569 been initialized, even if the corresponding value is undefined.  The
1570 element is not autovivified if it doesn't exist.
1571
1572     print "Exists\n"    if exists $hash{$key};
1573     print "Defined\n"   if defined $hash{$key};
1574     print "True\n"      if $hash{$key};
1575
1576     print "Exists\n"    if exists $array[$index];
1577     print "Defined\n"   if defined $array[$index];
1578     print "True\n"      if $array[$index];
1579
1580 A hash or array element can be true only if it's defined, and defined if
1581 it exists, but the reverse doesn't necessarily hold true.
1582
1583 Given an expression that specifies the name of a subroutine,
1584 returns true if the specified subroutine has ever been declared, even
1585 if it is undefined.  Mentioning a subroutine name for exists or defined
1586 does not count as declaring it.  Note that a subroutine which does not
1587 exist may still be callable: its package may have an C<AUTOLOAD>
1588 method that makes it spring into existence the first time that it is
1589 called -- see L<perlsub>.
1590
1591     print "Exists\n"    if exists &subroutine;
1592     print "Defined\n"   if defined &subroutine;
1593
1594 Note that the EXPR can be arbitrarily complicated as long as the final
1595 operation is a hash or array key lookup or subroutine name:
1596
1597     if (exists $ref->{A}->{B}->{$key})  { }
1598     if (exists $hash{A}{B}{$key})       { }
1599
1600     if (exists $ref->{A}->{B}->[$ix])   { }
1601     if (exists $hash{A}{B}[$ix])        { }
1602
1603     if (exists &{$ref->{A}{B}{$key}})   { }
1604
1605 Although the deepest nested array or hash will not spring into existence
1606 just because its existence was tested, any intervening ones will.
1607 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1608 into existence due to the existence test for the $key element above.
1609 This happens anywhere the arrow operator is used, including even:
1610
1611     undef $ref;
1612     if (exists $ref->{"Some key"})      { }
1613     print $ref;             # prints HASH(0x80d3d5c)
1614
1615 This surprising autovivification in what does not at first--or even
1616 second--glance appear to be an lvalue context may be fixed in a future
1617 release.
1618
1619 Use of a subroutine call, rather than a subroutine name, as an argument
1620 to exists() is an error.
1621
1622     exists &sub;        # OK
1623     exists &sub();      # Error
1624
1625 =item exit EXPR
1626
1627 Evaluates EXPR and exits immediately with that value.    Example:
1628
1629     $ans = <STDIN>;
1630     exit 0 if $ans =~ /^[Xx]/;
1631
1632 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1633 universally recognized values for EXPR are C<0> for success and C<1>
1634 for error; other values are subject to interpretation depending on the
1635 environment in which the Perl program is running.  For example, exiting
1636 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1637 the mailer to return the item undelivered, but that's not true everywhere.
1638
1639 Don't use C<exit> to abort a subroutine if there's any chance that
1640 someone might want to trap whatever error happened.  Use C<die> instead,
1641 which can be trapped by an C<eval>.
1642
1643 The exit() function does not always exit immediately.  It calls any
1644 defined C<END> routines first, but these C<END> routines may not
1645 themselves abort the exit.  Likewise any object destructors that need to
1646 be called are called before the real exit.  If this is a problem, you
1647 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1648 See L<perlmod> for details.
1649
1650 =item exp EXPR
1651
1652 =item exp
1653
1654 Returns I<e> (the natural logarithm base) to the power of EXPR.
1655 If EXPR is omitted, gives C<exp($_)>.
1656
1657 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1658
1659 Implements the fcntl(2) function.  You'll probably have to say
1660
1661     use Fcntl;
1662
1663 first to get the correct constant definitions.  Argument processing and
1664 value return works just like C<ioctl> below.
1665 For example:
1666
1667     use Fcntl;
1668     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1669         or die "can't fcntl F_GETFL: $!";
1670
1671 You don't have to check for C<defined> on the return from C<fcntl>.
1672 Like C<ioctl>, it maps a C<0> return from the system call into
1673 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1674 in numeric context.  It is also exempt from the normal B<-w> warnings
1675 on improper numeric conversions.
1676
1677 Note that C<fcntl> will produce a fatal error if used on a machine that
1678 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1679 manpage to learn what functions are available on your system.
1680
1681 Here's an example of setting a filehandle named C<REMOTE> to be
1682 non-blocking at the system level.  You'll have to negotiate C<$|>
1683 on your own, though.
1684
1685     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1686
1687     $flags = fcntl(REMOTE, F_GETFL, 0)
1688                 or die "Can't get flags for the socket: $!\n";
1689
1690     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1691                 or die "Can't set flags for the socket: $!\n";
1692
1693 =item fileno FILEHANDLE
1694
1695 Returns the file descriptor for a filehandle, or undefined if the
1696 filehandle is not open.  This is mainly useful for constructing
1697 bitmaps for C<select> and low-level POSIX tty-handling operations.
1698 If FILEHANDLE is an expression, the value is taken as an indirect
1699 filehandle, generally its name.
1700
1701 You can use this to find out whether two handles refer to the
1702 same underlying descriptor:
1703
1704     if (fileno(THIS) == fileno(THAT)) {
1705         print "THIS and THAT are dups\n";
1706     }
1707
1708 (Filehandles connected to memory objects via new features of C<open> may
1709 return undefined even though they are open.)
1710
1711
1712 =item flock FILEHANDLE,OPERATION
1713
1714 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1715 for success, false on failure.  Produces a fatal error if used on a
1716 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1717 C<flock> is Perl's portable file locking interface, although it locks
1718 only entire files, not records.
1719
1720 Two potentially non-obvious but traditional C<flock> semantics are
1721 that it waits indefinitely until the lock is granted, and that its locks
1722 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1723 fewer guarantees.  This means that files locked with C<flock> may be
1724 modified by programs that do not also use C<flock>.  See L<perlport>,
1725 your port's specific documentation, or your system-specific local manpages
1726 for details.  It's best to assume traditional behavior if you're writing
1727 portable programs.  (But if you're not, you should as always feel perfectly
1728 free to write for your own system's idiosyncrasies (sometimes called
1729 "features").  Slavish adherence to portability concerns shouldn't get
1730 in the way of your getting your job done.)
1731
1732 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1733 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1734 you can use the symbolic names if you import them from the Fcntl module,
1735 either individually, or as a group using the ':flock' tag.  LOCK_SH
1736 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1737 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1738 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1739 waiting for the lock (check the return status to see if you got it).
1740
1741 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1742 before locking or unlocking it.
1743
1744 Note that the emulation built with lockf(3) doesn't provide shared
1745 locks, and it requires that FILEHANDLE be open with write intent.  These
1746 are the semantics that lockf(3) implements.  Most if not all systems
1747 implement lockf(3) in terms of fcntl(2) locking, though, so the
1748 differing semantics shouldn't bite too many people.
1749
1750 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1751 be open with read intent to use LOCK_SH and requires that it be open
1752 with write intent to use LOCK_EX.
1753
1754 Note also that some versions of C<flock> cannot lock things over the
1755 network; you would need to use the more system-specific C<fcntl> for
1756 that.  If you like you can force Perl to ignore your system's flock(2)
1757 function, and so provide its own fcntl(2)-based emulation, by passing
1758 the switch C<-Ud_flock> to the F<Configure> program when you configure
1759 perl.
1760
1761 Here's a mailbox appender for BSD systems.
1762
1763     use Fcntl ':flock'; # import LOCK_* constants
1764
1765     sub lock {
1766         flock(MBOX,LOCK_EX);
1767         # and, in case someone appended
1768         # while we were waiting...
1769         seek(MBOX, 0, 2);
1770     }
1771
1772     sub unlock {
1773         flock(MBOX,LOCK_UN);
1774     }
1775
1776     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1777             or die "Can't open mailbox: $!";
1778
1779     lock();
1780     print MBOX $msg,"\n\n";
1781     unlock();
1782
1783 On systems that support a real flock(), locks are inherited across fork()
1784 calls, whereas those that must resort to the more capricious fcntl()
1785 function lose the locks, making it harder to write servers.
1786
1787 See also L<DB_File> for other flock() examples.
1788
1789 =item fork
1790
1791 Does a fork(2) system call to create a new process running the
1792 same program at the same point.  It returns the child pid to the
1793 parent process, C<0> to the child process, or C<undef> if the fork is
1794 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1795 are shared, while everything else is copied.  On most systems supporting
1796 fork(), great care has gone into making it extremely efficient (for
1797 example, using copy-on-write technology on data pages), making it the
1798 dominant paradigm for multitasking over the last few decades.
1799
1800 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1801 output before forking the child process, but this may not be supported
1802 on some platforms (see L<perlport>).  To be safe, you may need to set
1803 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1804 C<IO::Handle> on any open handles in order to avoid duplicate output.
1805
1806 If you C<fork> without ever waiting on your children, you will
1807 accumulate zombies.  On some systems, you can avoid this by setting
1808 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1809 forking and reaping moribund children.
1810
1811 Note that if your forked child inherits system file descriptors like
1812 STDIN and STDOUT that are actually connected by a pipe or socket, even
1813 if you exit, then the remote server (such as, say, a CGI script or a
1814 backgrounded job launched from a remote shell) won't think you're done.
1815 You should reopen those to F</dev/null> if it's any issue.
1816
1817 =item format
1818
1819 Declare a picture format for use by the C<write> function.  For
1820 example:
1821
1822     format Something =
1823         Test: @<<<<<<<< @||||| @>>>>>
1824               $str,     $%,    '$' . int($num)
1825     .
1826
1827     $str = "widget";
1828     $num = $cost/$quantity;
1829     $~ = 'Something';
1830     write;
1831
1832 See L<perlform> for many details and examples.
1833
1834 =item formline PICTURE,LIST
1835
1836 This is an internal function used by C<format>s, though you may call it,
1837 too.  It formats (see L<perlform>) a list of values according to the
1838 contents of PICTURE, placing the output into the format output
1839 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1840 Eventually, when a C<write> is done, the contents of
1841 C<$^A> are written to some filehandle, but you could also read C<$^A>
1842 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1843 does one C<formline> per line of form, but the C<formline> function itself
1844 doesn't care how many newlines are embedded in the PICTURE.  This means
1845 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1846 You may therefore need to use multiple formlines to implement a single
1847 record format, just like the format compiler.
1848
1849 Be careful if you put double quotes around the picture, because an C<@>
1850 character may be taken to mean the beginning of an array name.
1851 C<formline> always returns true.  See L<perlform> for other examples.
1852
1853 =item getc FILEHANDLE
1854
1855 =item getc
1856
1857 Returns the next character from the input file attached to FILEHANDLE,
1858 or the undefined value at end of file, or if there was an error (in
1859 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1860 STDIN.  This is not particularly efficient.  However, it cannot be
1861 used by itself to fetch single characters without waiting for the user
1862 to hit enter.  For that, try something more like:
1863
1864     if ($BSD_STYLE) {
1865         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1866     }
1867     else {
1868         system "stty", '-icanon', 'eol', "\001";
1869     }
1870
1871     $key = getc(STDIN);
1872
1873     if ($BSD_STYLE) {
1874         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1875     }
1876     else {
1877         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1878     }
1879     print "\n";
1880
1881 Determination of whether $BSD_STYLE should be set
1882 is left as an exercise to the reader.
1883
1884 The C<POSIX::getattr> function can do this more portably on
1885 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1886 module from your nearest CPAN site; details on CPAN can be found on
1887 L<perlmodlib/CPAN>.
1888
1889 =item getlogin
1890
1891 Implements the C library function of the same name, which on most
1892 systems returns the current login from F</etc/utmp>, if any.  If null,
1893 use C<getpwuid>.
1894
1895     $login = getlogin || getpwuid($<) || "Kilroy";
1896
1897 Do not consider C<getlogin> for authentication: it is not as
1898 secure as C<getpwuid>.
1899
1900 =item getpeername SOCKET
1901
1902 Returns the packed sockaddr address of other end of the SOCKET connection.
1903
1904     use Socket;
1905     $hersockaddr    = getpeername(SOCK);
1906     ($port, $iaddr) = sockaddr_in($hersockaddr);
1907     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1908     $herstraddr     = inet_ntoa($iaddr);
1909
1910 =item getpgrp PID
1911
1912 Returns the current process group for the specified PID.  Use
1913 a PID of C<0> to get the current process group for the
1914 current process.  Will raise an exception if used on a machine that
1915 doesn't implement getpgrp(2).  If PID is omitted, returns process
1916 group of current process.  Note that the POSIX version of C<getpgrp>
1917 does not accept a PID argument, so only C<PID==0> is truly portable.
1918
1919 =item getppid
1920
1921 Returns the process id of the parent process.
1922
1923 Note for Linux users: on Linux, the C functions C<getpid()> and
1924 C<getppid()> return different values from different threads. In order to
1925 be portable, this behavior is not reflected by the perl-level function
1926 C<getppid()>, that returns a consistent value across threads. If you want
1927 to call the underlying C<getppid()>, you may use the CPAN module
1928 C<Linux::Pid>.
1929
1930 =item getpriority WHICH,WHO
1931
1932 Returns the current priority for a process, a process group, or a user.
1933 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1934 machine that doesn't implement getpriority(2).
1935
1936 =item getpwnam NAME
1937
1938 =item getgrnam NAME
1939
1940 =item gethostbyname NAME
1941
1942 =item getnetbyname NAME
1943
1944 =item getprotobyname NAME
1945
1946 =item getpwuid UID
1947
1948 =item getgrgid GID
1949
1950 =item getservbyname NAME,PROTO
1951
1952 =item gethostbyaddr ADDR,ADDRTYPE
1953
1954 =item getnetbyaddr ADDR,ADDRTYPE
1955
1956 =item getprotobynumber NUMBER
1957
1958 =item getservbyport PORT,PROTO
1959
1960 =item getpwent
1961
1962 =item getgrent
1963
1964 =item gethostent
1965
1966 =item getnetent
1967
1968 =item getprotoent
1969
1970 =item getservent
1971
1972 =item setpwent
1973
1974 =item setgrent
1975
1976 =item sethostent STAYOPEN
1977
1978 =item setnetent STAYOPEN
1979
1980 =item setprotoent STAYOPEN
1981
1982 =item setservent STAYOPEN
1983
1984 =item endpwent
1985
1986 =item endgrent
1987
1988 =item endhostent
1989
1990 =item endnetent
1991
1992 =item endprotoent
1993
1994 =item endservent
1995
1996 These routines perform the same functions as their counterparts in the
1997 system library.  In list context, the return values from the
1998 various get routines are as follows:
1999
2000     ($name,$passwd,$uid,$gid,
2001        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2002     ($name,$passwd,$gid,$members) = getgr*
2003     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2004     ($name,$aliases,$addrtype,$net) = getnet*
2005     ($name,$aliases,$proto) = getproto*
2006     ($name,$aliases,$port,$proto) = getserv*
2007
2008 (If the entry doesn't exist you get a null list.)
2009
2010 The exact meaning of the $gcos field varies but it usually contains
2011 the real name of the user (as opposed to the login name) and other
2012 information pertaining to the user.  Beware, however, that in many
2013 system users are able to change this information and therefore it
2014 cannot be trusted and therefore the $gcos is tainted (see
2015 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2016 login shell, are also tainted, because of the same reason.
2017
2018 In scalar context, you get the name, unless the function was a
2019 lookup by name, in which case you get the other thing, whatever it is.
2020 (If the entry doesn't exist you get the undefined value.)  For example:
2021
2022     $uid   = getpwnam($name);
2023     $name  = getpwuid($num);
2024     $name  = getpwent();
2025     $gid   = getgrnam($name);
2026     $name  = getgrgid($num);
2027     $name  = getgrent();
2028     #etc.
2029
2030 In I<getpw*()> the fields $quota, $comment, and $expire are special
2031 cases in the sense that in many systems they are unsupported.  If the
2032 $quota is unsupported, it is an empty scalar.  If it is supported, it
2033 usually encodes the disk quota.  If the $comment field is unsupported,
2034 it is an empty scalar.  If it is supported it usually encodes some
2035 administrative comment about the user.  In some systems the $quota
2036 field may be $change or $age, fields that have to do with password
2037 aging.  In some systems the $comment field may be $class.  The $expire
2038 field, if present, encodes the expiration period of the account or the
2039 password.  For the availability and the exact meaning of these fields
2040 in your system, please consult your getpwnam(3) documentation and your
2041 F<pwd.h> file.  You can also find out from within Perl what your
2042 $quota and $comment fields mean and whether you have the $expire field
2043 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2044 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2045 files are only supported if your vendor has implemented them in the
2046 intuitive fashion that calling the regular C library routines gets the
2047 shadow versions if you're running under privilege or if there exists
2048 the shadow(3) functions as found in System V ( this includes Solaris
2049 and Linux.)  Those systems which implement a proprietary shadow password
2050 facility are unlikely to be supported.
2051
2052 The $members value returned by I<getgr*()> is a space separated list of
2053 the login names of the members of the group.
2054
2055 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2056 C, it will be returned to you via C<$?> if the function call fails.  The
2057 C<@addrs> value returned by a successful call is a list of the raw
2058 addresses returned by the corresponding system library call.  In the
2059 Internet domain, each address is four bytes long and you can unpack it
2060 by saying something like:
2061
2062     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2063
2064 The Socket library makes this slightly easier:
2065
2066     use Socket;
2067     $iaddr = inet_aton("127.1"); # or whatever address
2068     $name  = gethostbyaddr($iaddr, AF_INET);
2069
2070     # or going the other way
2071     $straddr = inet_ntoa($iaddr);
2072
2073 If you get tired of remembering which element of the return list
2074 contains which return value, by-name interfaces are provided
2075 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2076 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2077 and C<User::grent>.  These override the normal built-ins, supplying
2078 versions that return objects with the appropriate names
2079 for each field.  For example:
2080
2081    use File::stat;
2082    use User::pwent;
2083    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2084
2085 Even though it looks like they're the same method calls (uid),
2086 they aren't, because a C<File::stat> object is different from
2087 a C<User::pwent> object.
2088
2089 =item getsockname SOCKET
2090
2091 Returns the packed sockaddr address of this end of the SOCKET connection,
2092 in case you don't know the address because you have several different
2093 IPs that the connection might have come in on.
2094
2095     use Socket;
2096     $mysockaddr = getsockname(SOCK);
2097     ($port, $myaddr) = sockaddr_in($mysockaddr);
2098     printf "Connect to %s [%s]\n",
2099        scalar gethostbyaddr($myaddr, AF_INET),
2100        inet_ntoa($myaddr);
2101
2102 =item getsockopt SOCKET,LEVEL,OPTNAME
2103
2104 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2105 Options may exist at multiple protocol levels depending on the socket
2106 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2107 C<Socket> module) will exist. To query options at another level the
2108 protocol number of the appropriate protocol controlling the option
2109 should be supplied. For example, to indicate that an option is to be
2110 interpreted by the TCP protocol, LEVEL should be set to the protocol
2111 number of TCP, which you can get using getprotobyname.
2112
2113 The call returns a packed string representing the requested socket option,
2114 or C<undef> if there is an error (the error reason will be in $!). What
2115 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2116 your system documentation for details. A very common case however is that
2117 the option is an integer, in which case the result will be an packed
2118 integer which you can decode using unpack with the C<i> (or C<I>) format.
2119
2120 An example testing if Nagle's algorithm is turned on on a socket:
2121
2122     use Socket qw(:all);
2123
2124     defined(my $tcp = getprotobyname("tcp"))
2125         or die "Could not determine the protocol number for tcp";
2126     # my $tcp = IPPROTO_TCP; # Alternative
2127     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2128         or die "Could not query TCP_NODELAY socket option: $!";
2129     my $nodelay = unpack("I", $packed);
2130     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2131
2132
2133 =item glob EXPR
2134
2135 =item glob
2136
2137 In list context, returns a (possibly empty) list of filename expansions on
2138 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2139 scalar context, glob iterates through such filename expansions, returning
2140 undef when the list is exhausted. This is the internal function
2141 implementing the C<< <*.c> >> operator, but you can use it directly. If
2142 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2143 more detail in L<perlop/"I/O Operators">.
2144
2145 Beginning with v5.6.0, this operator is implemented using the standard
2146 C<File::Glob> extension.  See L<File::Glob> for details.
2147
2148 =item gmtime EXPR
2149
2150 Converts a time as returned by the time function to an 8-element list
2151 with the time localized for the standard Greenwich time zone.
2152 Typically used as follows:
2153
2154     #  0    1    2     3     4    5     6     7
2155     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2156                                             gmtime(time);
2157
2158 All list elements are numeric, and come straight out of the C `struct
2159 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2160 specified time.  $mday is the day of the month, and $mon is the month
2161 itself, in the range C<0..11> with 0 indicating January and 11
2162 indicating December.  $year is the number of years since 1900.  That
2163 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2164 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2165 the year, in the range C<0..364> (or C<0..365> in leap years.)
2166
2167 Note that the $year element is I<not> simply the last two digits of
2168 the year.  If you assume it is, then you create non-Y2K-compliant
2169 programs--and you wouldn't want to do that, would you?
2170
2171 The proper way to get a complete 4-digit year is simply:
2172
2173         $year += 1900;
2174
2175 And to get the last two digits of the year (e.g., '01' in 2001) do:
2176
2177         $year = sprintf("%02d", $year % 100);
2178
2179 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2180
2181 In scalar context, C<gmtime()> returns the ctime(3) value:
2182
2183     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2184
2185 If you need local time instead of GMT use the L</localtime> builtin. 
2186 See also the C<timegm> function provided by the C<Time::Local> module,
2187 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2188
2189 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2190 instead a Perl builtin.  To get somewhat similar but locale dependent date
2191 strings, see the example in L</localtime>.
2192
2193 See L<perlport/gmtime> for portability concerns.
2194
2195 =item goto LABEL
2196
2197 =item goto EXPR
2198
2199 =item goto &NAME
2200
2201 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2202 execution there.  It may not be used to go into any construct that
2203 requires initialization, such as a subroutine or a C<foreach> loop.  It
2204 also can't be used to go into a construct that is optimized away,
2205 or to get out of a block or subroutine given to C<sort>.
2206 It can be used to go almost anywhere else within the dynamic scope,
2207 including out of subroutines, but it's usually better to use some other
2208 construct such as C<last> or C<die>.  The author of Perl has never felt the
2209 need to use this form of C<goto> (in Perl, that is--C is another matter).
2210 (The difference being that C does not offer named loops combined with
2211 loop control.  Perl does, and this replaces most structured uses of C<goto>
2212 in other languages.)
2213
2214 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2215 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2216 necessarily recommended if you're optimizing for maintainability:
2217
2218     goto ("FOO", "BAR", "GLARCH")[$i];
2219
2220 The C<goto-&NAME> form is quite different from the other forms of
2221 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2222 doesn't have the stigma associated with other gotos.  Instead, it
2223 exits the current subroutine (losing any changes set by local()) and
2224 immediately calls in its place the named subroutine using the current
2225 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2226 load another subroutine and then pretend that the other subroutine had
2227 been called in the first place (except that any modifications to C<@_>
2228 in the current subroutine are propagated to the other subroutine.)
2229 After the C<goto>, not even C<caller> will be able to tell that this
2230 routine was called first.
2231
2232 NAME needn't be the name of a subroutine; it can be a scalar variable
2233 containing a code reference, or a block which evaluates to a code
2234 reference.
2235
2236 =item grep BLOCK LIST
2237
2238 =item grep EXPR,LIST
2239
2240 This is similar in spirit to, but not the same as, grep(1) and its
2241 relatives.  In particular, it is not limited to using regular expressions.
2242
2243 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2244 C<$_> to each element) and returns the list value consisting of those
2245 elements for which the expression evaluated to true.  In scalar
2246 context, returns the number of times the expression was true.
2247
2248     @foo = grep(!/^#/, @bar);    # weed out comments
2249
2250 or equivalently,
2251
2252     @foo = grep {!/^#/} @bar;    # weed out comments
2253
2254 Note that C<$_> is an alias to the list value, so it can be used to
2255 modify the elements of the LIST.  While this is useful and supported,
2256 it can cause bizarre results if the elements of LIST are not variables.
2257 Similarly, grep returns aliases into the original list, much as a for
2258 loop's index variable aliases the list elements.  That is, modifying an
2259 element of a list returned by grep (for example, in a C<foreach>, C<map>
2260 or another C<grep>) actually modifies the element in the original list.
2261 This is usually something to be avoided when writing clear code.
2262
2263 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2264 been declared with C<my $_>) then, in addition the be locally aliased to
2265 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2266 can't be seen from the outside, avoiding any potential side-effects.
2267
2268 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2269
2270 =item hex EXPR
2271
2272 =item hex
2273
2274 Interprets EXPR as a hex string and returns the corresponding value.
2275 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2276 L</oct>.)  If EXPR is omitted, uses C<$_>.
2277
2278     print hex '0xAf'; # prints '175'
2279     print hex 'aF';   # same
2280
2281 Hex strings may only represent integers.  Strings that would cause
2282 integer overflow trigger a warning.  Leading whitespace is not stripped,
2283 unlike oct(). To present something as hex, look into L</printf>,
2284 L</sprintf>, or L</unpack>.
2285
2286 =item import
2287
2288 There is no builtin C<import> function.  It is just an ordinary
2289 method (subroutine) defined (or inherited) by modules that wish to export
2290 names to another module.  The C<use> function calls the C<import> method
2291 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2292
2293 =item index STR,SUBSTR,POSITION
2294
2295 =item index STR,SUBSTR
2296
2297 The index function searches for one string within another, but without
2298 the wildcard-like behavior of a full regular-expression pattern match.
2299 It returns the position of the first occurrence of SUBSTR in STR at
2300 or after POSITION.  If POSITION is omitted, starts searching from the
2301 beginning of the string.  The return value is based at C<0> (or whatever
2302 you've set the C<$[> variable to--but don't do that).  If the substring
2303 is not found, returns one less than the base, ordinarily C<-1>.
2304
2305 =item int EXPR
2306
2307 =item int
2308
2309 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2310 You should not use this function for rounding: one because it truncates
2311 towards C<0>, and two because machine representations of floating point
2312 numbers can sometimes produce counterintuitive results.  For example,
2313 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2314 because it's really more like -268.99999999999994315658 instead.  Usually,
2315 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2316 functions will serve you better than will int().
2317
2318 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2319
2320 Implements the ioctl(2) function.  You'll probably first have to say
2321
2322     require "sys/ioctl.ph";     # probably in $Config{archlib}/ioctl.ph
2323
2324 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2325 exist or doesn't have the correct definitions you'll have to roll your
2326 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2327 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2328 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2329 written depending on the FUNCTION--a pointer to the string value of SCALAR
2330 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2331 has no string value but does have a numeric value, that value will be
2332 passed rather than a pointer to the string value.  To guarantee this to be
2333 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2334 functions may be needed to manipulate the values of structures used by
2335 C<ioctl>.
2336
2337 The return value of C<ioctl> (and C<fcntl>) is as follows:
2338
2339         if OS returns:          then Perl returns:
2340             -1                    undefined value
2341              0                  string "0 but true"
2342         anything else               that number
2343
2344 Thus Perl returns true on success and false on failure, yet you can
2345 still easily determine the actual value returned by the operating
2346 system:
2347
2348     $retval = ioctl(...) || -1;
2349     printf "System returned %d\n", $retval;
2350
2351 The special string C<"0 but true"> is exempt from B<-w> complaints
2352 about improper numeric conversions.
2353
2354 =item join EXPR,LIST
2355
2356 Joins the separate strings of LIST into a single string with fields
2357 separated by the value of EXPR, and returns that new string.  Example:
2358
2359     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2360
2361 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2362 first argument.  Compare L</split>.
2363
2364 =item keys HASH
2365
2366 Returns a list consisting of all the keys of the named hash.
2367 (In scalar context, returns the number of keys.)
2368
2369 The keys are returned in an apparently random order.  The actual
2370 random order is subject to change in future versions of perl, but it
2371 is guaranteed to be the same order as either the C<values> or C<each>
2372 function produces (given that the hash has not been modified).  Since
2373 Perl 5.8.1 the ordering is different even between different runs of
2374 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2375 Attacks">).
2376
2377 As a side effect, calling keys() resets the HASH's internal iterator,
2378 see L</each>. (In particular, calling keys() in void context resets
2379 the iterator with no other overhead.)
2380
2381 Here is yet another way to print your environment:
2382
2383     @keys = keys %ENV;
2384     @values = values %ENV;
2385     while (@keys) {
2386         print pop(@keys), '=', pop(@values), "\n";
2387     }
2388
2389 or how about sorted by key:
2390
2391     foreach $key (sort(keys %ENV)) {
2392         print $key, '=', $ENV{$key}, "\n";
2393     }
2394
2395 The returned values are copies of the original keys in the hash, so
2396 modifying them will not affect the original hash.  Compare L</values>.
2397
2398 To sort a hash by value, you'll need to use a C<sort> function.
2399 Here's a descending numeric sort of a hash by its values:
2400
2401     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2402         printf "%4d %s\n", $hash{$key}, $key;
2403     }
2404
2405 As an lvalue C<keys> allows you to increase the number of hash buckets
2406 allocated for the given hash.  This can gain you a measure of efficiency if
2407 you know the hash is going to get big.  (This is similar to pre-extending
2408 an array by assigning a larger number to $#array.)  If you say
2409
2410     keys %hash = 200;
2411
2412 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2413 in fact, since it rounds up to the next power of two.  These
2414 buckets will be retained even if you do C<%hash = ()>, use C<undef
2415 %hash> if you want to free the storage while C<%hash> is still in scope.
2416 You can't shrink the number of buckets allocated for the hash using
2417 C<keys> in this way (but you needn't worry about doing this by accident,
2418 as trying has no effect).
2419
2420 See also C<each>, C<values> and C<sort>.
2421
2422 =item kill SIGNAL, LIST
2423
2424 Sends a signal to a list of processes.  Returns the number of
2425 processes successfully signaled (which is not necessarily the
2426 same as the number actually killed).
2427
2428     $cnt = kill 1, $child1, $child2;
2429     kill 9, @goners;
2430
2431 If SIGNAL is zero, no signal is sent to the process.  This is a
2432 useful way to check that a child process is alive and hasn't changed
2433 its UID.  See L<perlport> for notes on the portability of this
2434 construct.
2435
2436 Unlike in the shell, if SIGNAL is negative, it kills
2437 process groups instead of processes.  (On System V, a negative I<PROCESS>
2438 number will also kill process groups, but that's not portable.)  That
2439 means you usually want to use positive not negative signals.  You may also
2440 use a signal name in quotes.
2441
2442 See L<perlipc/"Signals"> for more details.
2443
2444 =item last LABEL
2445
2446 =item last
2447
2448 The C<last> command is like the C<break> statement in C (as used in
2449 loops); it immediately exits the loop in question.  If the LABEL is
2450 omitted, the command refers to the innermost enclosing loop.  The
2451 C<continue> block, if any, is not executed:
2452
2453     LINE: while (<STDIN>) {
2454         last LINE if /^$/;      # exit when done with header
2455         #...
2456     }
2457
2458 C<last> cannot be used to exit a block which returns a value such as
2459 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2460 a grep() or map() operation.
2461
2462 Note that a block by itself is semantically identical to a loop
2463 that executes once.  Thus C<last> can be used to effect an early
2464 exit out of such a block.
2465
2466 See also L</continue> for an illustration of how C<last>, C<next>, and
2467 C<redo> work.
2468
2469 =item lc EXPR
2470
2471 =item lc
2472
2473 Returns a lowercased version of EXPR.  This is the internal function
2474 implementing the C<\L> escape in double-quoted strings.  Respects
2475 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2476 and L<perlunicode> for more details about locale and Unicode support.
2477
2478 If EXPR is omitted, uses C<$_>.
2479
2480 =item lcfirst EXPR
2481
2482 =item lcfirst
2483
2484 Returns the value of EXPR with the first character lowercased.  This
2485 is the internal function implementing the C<\l> escape in
2486 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2487 locale> in force.  See L<perllocale> and L<perlunicode> for more
2488 details about locale and Unicode support.
2489
2490 If EXPR is omitted, uses C<$_>.
2491
2492 =item length EXPR
2493
2494 =item length
2495
2496 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2497 omitted, returns length of C<$_>.  Note that this cannot be used on
2498 an entire array or hash to find out how many elements these have.
2499 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2500
2501 Note the I<characters>: if the EXPR is in Unicode, you will get the
2502 number of characters, not the number of bytes.  To get the length
2503 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2504
2505 =item link OLDFILE,NEWFILE
2506
2507 Creates a new filename linked to the old filename.  Returns true for
2508 success, false otherwise.
2509
2510 =item listen SOCKET,QUEUESIZE
2511
2512 Does the same thing that the listen system call does.  Returns true if
2513 it succeeded, false otherwise.  See the example in
2514 L<perlipc/"Sockets: Client/Server Communication">.
2515
2516 =item local EXPR
2517
2518 You really probably want to be using C<my> instead, because C<local> isn't
2519 what most people think of as "local".  See
2520 L<perlsub/"Private Variables via my()"> for details.
2521
2522 A local modifies the listed variables to be local to the enclosing
2523 block, file, or eval.  If more than one value is listed, the list must
2524 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2525 for details, including issues with tied arrays and hashes.
2526
2527 =item localtime EXPR
2528
2529 =item localtime
2530
2531 Converts a time as returned by the time function to a 9-element list
2532 with the time analyzed for the local time zone.  Typically used as
2533 follows:
2534
2535     #  0    1    2     3     4    5     6     7     8
2536     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2537                                                 localtime(time);
2538
2539 All list elements are numeric, and come straight out of the C `struct
2540 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2541 of the specified time.
2542
2543 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2544 the range C<0..11> with 0 indicating January and 11 indicating December.
2545 This makes it easy to get a month name from a list:
2546
2547     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2548     print "$abbr[$mon] $mday";
2549     # $mon=9, $mday=18 gives "Oct 18"
2550
2551 C<$year> is the number of years since 1900, not just the last two digits
2552 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2553 to get a complete 4-digit year is simply:
2554
2555     $year += 1900;
2556
2557 To get the last two digits of the year (e.g., '01' in 2001) do:
2558
2559     $year = sprintf("%02d", $year % 100);
2560
2561 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2562 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2563 (or C<0..365> in leap years.)
2564
2565 C<$isdst> is true if the specified time occurs during Daylight Saving
2566 Time, false otherwise.
2567
2568 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2569
2570 In scalar context, C<localtime()> returns the ctime(3) value:
2571
2572     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2573
2574 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2575 instead of local time use the L</gmtime> builtin. See also the
2576 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2577 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2578 and mktime(3) functions.
2579
2580 To get somewhat similar but locale dependent date strings, set up your
2581 locale environment variables appropriately (please see L<perllocale>) and
2582 try for example:
2583
2584     use POSIX qw(strftime);
2585     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2586     # or for GMT formatted appropriately for your locale:
2587     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2588
2589 Note that the C<%a> and C<%b>, the short forms of the day of the week
2590 and the month of the year, may not necessarily be three characters wide.
2591
2592 See L<perlport/localtime> for portability concerns.
2593
2594 =item lock THING
2595
2596 This function places an advisory lock on a shared variable, or referenced
2597 object contained in I<THING> until the lock goes out of scope.
2598
2599 lock() is a "weak keyword" : this means that if you've defined a function
2600 by this name (before any calls to it), that function will be called
2601 instead. (However, if you've said C<use threads>, lock() is always a
2602 keyword.) See L<threads>.
2603
2604 =item log EXPR
2605
2606 =item log
2607
2608 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2609 returns log of C<$_>.  To get the log of another base, use basic algebra:
2610 The base-N log of a number is equal to the natural log of that number
2611 divided by the natural log of N.  For example:
2612
2613     sub log10 {
2614         my $n = shift;
2615         return log($n)/log(10);
2616     }
2617
2618 See also L</exp> for the inverse operation.
2619
2620 =item lstat EXPR
2621
2622 =item lstat
2623
2624 Does the same thing as the C<stat> function (including setting the
2625 special C<_> filehandle) but stats a symbolic link instead of the file
2626 the symbolic link points to.  If symbolic links are unimplemented on
2627 your system, a normal C<stat> is done.  For much more detailed
2628 information, please see the documentation for C<stat>.
2629
2630 If EXPR is omitted, stats C<$_>.
2631
2632 =item m//
2633
2634 The match operator.  See L<perlop>.
2635
2636 =item map BLOCK LIST
2637
2638 =item map EXPR,LIST
2639
2640 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2641 C<$_> to each element) and returns the list value composed of the
2642 results of each such evaluation.  In scalar context, returns the
2643 total number of elements so generated.  Evaluates BLOCK or EXPR in
2644 list context, so each element of LIST may produce zero, one, or
2645 more elements in the returned value.
2646
2647     @chars = map(chr, @nums);
2648
2649 translates a list of numbers to the corresponding characters.  And
2650
2651     %hash = map { getkey($_) => $_ } @array;
2652
2653 is just a funny way to write
2654
2655     %hash = ();
2656     foreach $_ (@array) {
2657         $hash{getkey($_)} = $_;
2658     }
2659
2660 Note that C<$_> is an alias to the list value, so it can be used to
2661 modify the elements of the LIST.  While this is useful and supported,
2662 it can cause bizarre results if the elements of LIST are not variables.
2663 Using a regular C<foreach> loop for this purpose would be clearer in
2664 most cases.  See also L</grep> for an array composed of those items of
2665 the original list for which the BLOCK or EXPR evaluates to true.
2666
2667 If C<$_> is lexical in the scope where the C<map> appears (because it has
2668 been declared with C<my $_>) then, in addition the be locally aliased to
2669 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2670 can't be seen from the outside, avoiding any potential side-effects.
2671
2672 C<{> starts both hash references and blocks, so C<map { ...> could be either
2673 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2674 ahead for the closing C<}> it has to take a guess at which its dealing with
2675 based what it finds just after the C<{>. Usually it gets it right, but if it
2676 doesn't it won't realize something is wrong until it gets to the C<}> and
2677 encounters the missing (or unexpected) comma. The syntax error will be
2678 reported close to the C<}> but you'll need to change something near the C<{>
2679 such as using a unary C<+> to give perl some help:
2680
2681     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2682     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2683     %hash = map { ("\L$_", 1) } @array  # this also works
2684     %hash = map {  lc($_), 1  } @array  # as does this.
2685     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2686
2687     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2688
2689 or to force an anon hash constructor use C<+{>
2690
2691    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2692
2693 and you get list of anonymous hashes each with only 1 entry.
2694
2695 =item mkdir FILENAME,MASK
2696
2697 =item mkdir FILENAME
2698
2699 =item mkdir
2700
2701 Creates the directory specified by FILENAME, with permissions
2702 specified by MASK (as modified by C<umask>).  If it succeeds it
2703 returns true, otherwise it returns false and sets C<$!> (errno).
2704 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2705 to C<$_>.
2706
2707 In general, it is better to create directories with permissive MASK,
2708 and let the user modify that with their C<umask>, than it is to supply
2709 a restrictive MASK and give the user no way to be more permissive.
2710 The exceptions to this rule are when the file or directory should be
2711 kept private (mail files, for instance).  The perlfunc(1) entry on
2712 C<umask> discusses the choice of MASK in more detail.
2713
2714 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2715 number of trailing slashes.  Some operating and filesystems do not get
2716 this right, so Perl automatically removes all trailing slashes to keep
2717 everyone happy.
2718
2719 =item msgctl ID,CMD,ARG
2720
2721 Calls the System V IPC function msgctl(2).  You'll probably have to say
2722
2723     use IPC::SysV;
2724
2725 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2726 then ARG must be a variable which will hold the returned C<msqid_ds>
2727 structure.  Returns like C<ioctl>: the undefined value for error,
2728 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2729 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2730
2731 =item msgget KEY,FLAGS
2732
2733 Calls the System V IPC function msgget(2).  Returns the message queue
2734 id, or the undefined value if there is an error.  See also
2735 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2736
2737 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2738
2739 Calls the System V IPC function msgrcv to receive a message from
2740 message queue ID into variable VAR with a maximum message size of
2741 SIZE.  Note that when a message is received, the message type as a
2742 native long integer will be the first thing in VAR, followed by the
2743 actual message.  This packing may be opened with C<unpack("l! a*")>.
2744 Taints the variable.  Returns true if successful, or false if there is
2745 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2746 C<IPC::SysV::Msg> documentation.
2747
2748 =item msgsnd ID,MSG,FLAGS
2749
2750 Calls the System V IPC function msgsnd to send the message MSG to the
2751 message queue ID.  MSG must begin with the native long integer message
2752 type, and be followed by the length of the actual message, and finally
2753 the message itself.  This kind of packing can be achieved with
2754 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2755 or false if there is an error.  See also C<IPC::SysV>
2756 and C<IPC::SysV::Msg> documentation.
2757
2758 =item my EXPR
2759
2760 =item my TYPE EXPR
2761
2762 =item my EXPR : ATTRS
2763
2764 =item my TYPE EXPR : ATTRS
2765
2766 A C<my> declares the listed variables to be local (lexically) to the
2767 enclosing block, file, or C<eval>.  If more than one value is listed,
2768 the list must be placed in parentheses.
2769
2770 The exact semantics and interface of TYPE and ATTRS are still
2771 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2772 and attributes are handled using the C<attributes> pragma, or starting
2773 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2774 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2775 L<attributes>, and L<Attribute::Handlers>.
2776
2777 =item next LABEL
2778
2779 =item next
2780
2781 The C<next> command is like the C<continue> statement in C; it starts
2782 the next iteration of the loop:
2783
2784     LINE: while (<STDIN>) {
2785         next LINE if /^#/;      # discard comments
2786         #...
2787     }
2788
2789 Note that if there were a C<continue> block on the above, it would get
2790 executed even on discarded lines.  If the LABEL is omitted, the command
2791 refers to the innermost enclosing loop.
2792
2793 C<next> cannot be used to exit a block which returns a value such as
2794 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2795 a grep() or map() operation.
2796
2797 Note that a block by itself is semantically identical to a loop
2798 that executes once.  Thus C<next> will exit such a block early.
2799
2800 See also L</continue> for an illustration of how C<last>, C<next>, and
2801 C<redo> work.
2802
2803 =item no Module VERSION LIST
2804
2805 =item no Module VERSION
2806
2807 =item no Module LIST
2808
2809 =item no Module
2810
2811 See the C<use> function, of which C<no> is the opposite.
2812
2813 =item oct EXPR
2814
2815 =item oct
2816
2817 Interprets EXPR as an octal string and returns the corresponding
2818 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2819 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2820 binary string.  Leading whitespace is ignored in all three cases.)
2821 The following will handle decimal, binary, octal, and hex in the standard
2822 Perl or C notation:
2823
2824     $val = oct($val) if $val =~ /^0/;
2825
2826 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2827 in octal), use sprintf() or printf():
2828
2829     $perms = (stat("filename"))[2] & 07777;
2830     $oct_perms = sprintf "%lo", $perms;
2831
2832 The oct() function is commonly used when a string such as C<644> needs
2833 to be converted into a file mode, for example. (Although perl will
2834 automatically convert strings into numbers as needed, this automatic
2835 conversion assumes base 10.)
2836
2837 =item open FILEHANDLE,EXPR
2838
2839 =item open FILEHANDLE,MODE,EXPR
2840
2841 =item open FILEHANDLE,MODE,EXPR,LIST
2842
2843 =item open FILEHANDLE,MODE,REFERENCE
2844
2845 =item open FILEHANDLE
2846
2847 Opens the file whose filename is given by EXPR, and associates it with
2848 FILEHANDLE.
2849
2850 (The following is a comprehensive reference to open(): for a gentler
2851 introduction you may consider L<perlopentut>.)
2852
2853 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2854 the variable is assigned a reference to a new anonymous filehandle,
2855 otherwise if FILEHANDLE is an expression, its value is used as the name of
2856 the real filehandle wanted.  (This is considered a symbolic reference, so
2857 C<use strict 'refs'> should I<not> be in effect.)
2858
2859 If EXPR is omitted, the scalar variable of the same name as the
2860 FILEHANDLE contains the filename.  (Note that lexical variables--those
2861 declared with C<my>--will not work for this purpose; so if you're
2862 using C<my>, specify EXPR in your call to open.)
2863
2864 If three or more arguments are specified then the mode of opening and
2865 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2866 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2867 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2868 the file is opened for appending, again being created if necessary.
2869
2870 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2871 indicate that you want both read and write access to the file; thus
2872 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2873 '+>' >> mode would clobber the file first.  You can't usually use
2874 either read-write mode for updating textfiles, since they have
2875 variable length records.  See the B<-i> switch in L<perlrun> for a
2876 better approach.  The file is created with permissions of C<0666>
2877 modified by the process' C<umask> value.
2878
2879 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2880 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2881
2882 In the 2-arguments (and 1-argument) form of the call the mode and
2883 filename should be concatenated (in this order), possibly separated by
2884 spaces.  It is possible to omit the mode in these forms if the mode is
2885 C<< '<' >>.
2886
2887 If the filename begins with C<'|'>, the filename is interpreted as a
2888 command to which output is to be piped, and if the filename ends with a
2889 C<'|'>, the filename is interpreted as a command which pipes output to
2890 us.  See L<perlipc/"Using open() for IPC">
2891 for more examples of this.  (You are not allowed to C<open> to a command
2892 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2893 and L<perlipc/"Bidirectional Communication with Another Process">
2894 for alternatives.)
2895
2896 For three or more arguments if MODE is C<'|-'>, the filename is
2897 interpreted as a command to which output is to be piped, and if MODE
2898 is C<'-|'>, the filename is interpreted as a command which pipes
2899 output to us.  In the 2-arguments (and 1-argument) form one should
2900 replace dash (C<'-'>) with the command.
2901 See L<perlipc/"Using open() for IPC"> for more examples of this.
2902 (You are not allowed to C<open> to a command that pipes both in I<and>
2903 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2904 L<perlipc/"Bidirectional Communication"> for alternatives.)
2905
2906 In the three-or-more argument form of pipe opens, if LIST is specified
2907 (extra arguments after the command name) then LIST becomes arguments
2908 to the command invoked if the platform supports it.  The meaning of
2909 C<open> with more than three arguments for non-pipe modes is not yet
2910 specified. Experimental "layers" may give extra LIST arguments
2911 meaning.
2912
2913 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2914 and opening C<< '>-' >> opens STDOUT.
2915
2916 You may use the three-argument form of open to specify IO "layers"
2917 (sometimes also referred to as "disciplines") to be applied to the handle
2918 that affect how the input and output are processed (see L<open> and
2919 L<PerlIO> for more details). For example
2920
2921   open(FH, "<:utf8", "file")
2922
2923 will open the UTF-8 encoded file containing Unicode characters,
2924 see L<perluniintro>. (Note that if layers are specified in the
2925 three-arg form then default layers set by the C<open> pragma are
2926 ignored.)
2927
2928 Open returns nonzero upon success, the undefined value otherwise.  If
2929 the C<open> involved a pipe, the return value happens to be the pid of
2930 the subprocess.
2931
2932 If you're running Perl on a system that distinguishes between text
2933 files and binary files, then you should check out L</binmode> for tips
2934 for dealing with this.  The key distinction between systems that need
2935 C<binmode> and those that don't is their text file formats.  Systems
2936 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2937 character, and which encode that character in C as C<"\n">, do not
2938 need C<binmode>.  The rest need it.
2939
2940 When opening a file, it's usually a bad idea to continue normal execution
2941 if the request failed, so C<open> is frequently used in connection with
2942 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2943 where you want to make a nicely formatted error message (but there are
2944 modules that can help with that problem)) you should always check
2945 the return value from opening a file.  The infrequent exception is when
2946 working with an unopened filehandle is actually what you want to do.
2947
2948 As a special case the 3 arg form with a read/write mode and the third
2949 argument being C<undef>:
2950
2951     open(TMP, "+>", undef) or die ...
2952
2953 opens a filehandle to an anonymous temporary file.  Also using "+<"
2954 works for symmetry, but you really should consider writing something
2955 to the temporary file first.  You will need to seek() to do the
2956 reading.
2957
2958 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
2959 changed this (ie Configure -Uuseperlio), you can open file handles to
2960 "in memory" files held in Perl scalars via:
2961
2962     open($fh, '>', \$variable) || ..
2963
2964 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2965 file, you have to close it first:
2966
2967     close STDOUT;
2968     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2969
2970 Examples:
2971
2972     $ARTICLE = 100;
2973     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2974     while (<ARTICLE>) {...
2975
2976     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2977     # if the open fails, output is discarded
2978
2979     open(DBASE, '+<', 'dbase.mine')             # open for update
2980         or die "Can't open 'dbase.mine' for update: $!";
2981
2982     open(DBASE, '+<dbase.mine')                 # ditto
2983         or die "Can't open 'dbase.mine' for update: $!";
2984
2985     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2986         or die "Can't start caesar: $!";
2987
2988     open(ARTICLE, "caesar <$article |")         # ditto
2989         or die "Can't start caesar: $!";
2990
2991     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
2992         or die "Can't start sort: $!";
2993
2994     # in memory files
2995     open(MEMORY,'>', \$var)
2996         or die "Can't open memory file: $!";
2997     print MEMORY "foo!\n";                      # output will end up in $var
2998
2999     # process argument list of files along with any includes
3000
3001     foreach $file (@ARGV) {
3002         process($file, 'fh00');
3003     }
3004
3005     sub process {
3006         my($filename, $input) = @_;
3007         $input++;               # this is a string increment
3008         unless (open($input, $filename)) {
3009             print STDERR "Can't open $filename: $!\n";
3010             return;
3011         }
3012
3013         local $_;
3014         while (<$input>) {              # note use of indirection
3015             if (/^#include "(.*)"/) {
3016                 process($1, $input);
3017                 next;
3018             }
3019             #...                # whatever
3020         }
3021     }
3022
3023 See L<perliol> for detailed info on PerlIO.
3024
3025 You may also, in the Bourne shell tradition, specify an EXPR beginning
3026 with C<< '>&' >>, in which case the rest of the string is interpreted
3027 as the name of a filehandle (or file descriptor, if numeric) to be
3028 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3029 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3030 The mode you specify should match the mode of the original filehandle.
3031 (Duping a filehandle does not take into account any existing contents
3032 of IO buffers.) If you use the 3 arg form then you can pass either a
3033 number, the name of a filehandle or the normal "reference to a glob".
3034
3035 Here is a script that saves, redirects, and restores C<STDOUT> and
3036 C<STDERR> using various methods:
3037
3038     #!/usr/bin/perl
3039     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3040     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3041
3042     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3043     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3044
3045     select STDERR; $| = 1;      # make unbuffered
3046     select STDOUT; $| = 1;      # make unbuffered
3047
3048     print STDOUT "stdout 1\n";  # this works for
3049     print STDERR "stderr 1\n";  # subprocesses too
3050
3051     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3052     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3053
3054     print STDOUT "stdout 2\n";
3055     print STDERR "stderr 2\n";
3056
3057 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3058 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3059 that file descriptor (and not call L<dup(2)>); this is more
3060 parsimonious of file descriptors.  For example:
3061
3062     # open for input, reusing the fileno of $fd
3063     open(FILEHANDLE, "<&=$fd")
3064
3065 or
3066
3067     open(FILEHANDLE, "<&=", $fd)
3068
3069 or
3070
3071     # open for append, using the fileno of OLDFH
3072     open(FH, ">>&=", OLDFH)
3073
3074 or
3075
3076     open(FH, ">>&=OLDFH")
3077
3078 Being parsimonious on filehandles is also useful (besides being
3079 parsimonious) for example when something is dependent on file
3080 descriptors, like for example locking using flock().  If you do just
3081 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3082 descriptor as B, and therefore flock(A) will not flock(B), and vice
3083 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3084 the same file descriptor.
3085
3086 Note that if you are using Perls older than 5.8.0, Perl will be using
3087 the standard C libraries' fdopen() to implement the "=" functionality.
3088 On many UNIX systems fdopen() fails when file descriptors exceed a
3089 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3090 most often the default.
3091
3092 You can see whether Perl has been compiled with PerlIO or not by
3093 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3094 is C<define>, you have PerlIO, otherwise you don't.
3095
3096 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3097 with 2-arguments (or 1-argument) form of open(), then
3098 there is an implicit fork done, and the return value of open is the pid
3099 of the child within the parent process, and C<0> within the child
3100 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3101 The filehandle behaves normally for the parent, but i/o to that
3102 filehandle is piped from/to the STDOUT/STDIN of the child process.
3103 In the child process the filehandle isn't opened--i/o happens from/to
3104 the new STDOUT or STDIN.  Typically this is used like the normal
3105 piped open when you want to exercise more control over just how the
3106 pipe command gets executed, such as when you are running setuid, and
3107 don't want to have to scan shell commands for metacharacters.
3108 The following triples are more or less equivalent:
3109
3110     open(FOO, "|tr '[a-z]' '[A-Z]'");
3111     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3112     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3113     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3114
3115     open(FOO, "cat -n '$file'|");
3116     open(FOO, '-|', "cat -n '$file'");
3117     open(FOO, '-|') || exec 'cat', '-n', $file;
3118     open(FOO, '-|', "cat", '-n', $file);
3119
3120 The last example in each block shows the pipe as "list form", which is
3121 not yet supported on all platforms.  A good rule of thumb is that if
3122 your platform has true C<fork()> (in other words, if your platform is
3123 UNIX) you can use the list form.
3124
3125 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3126
3127 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3128 output before any operation that may do a fork, but this may not be
3129 supported on some platforms (see L<perlport>).  To be safe, you may need
3130 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3131 of C<IO::Handle> on any open handles.
3132
3133 On systems that support a close-on-exec flag on files, the flag will
3134 be set for the newly opened file descriptor as determined by the value
3135 of $^F.  See L<perlvar/$^F>.
3136
3137 Closing any piped filehandle causes the parent process to wait for the
3138 child to finish, and returns the status value in C<$?> and
3139 C<${^CHILD_ERROR_NATIVE}>.
3140
3141 The filename passed to 2-argument (or 1-argument) form of open() will
3142 have leading and trailing whitespace deleted, and the normal
3143 redirection characters honored.  This property, known as "magic open",
3144 can often be used to good effect.  A user could specify a filename of
3145 F<"rsh cat file |">, or you could change certain filenames as needed:
3146
3147     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3148     open(FH, $filename) or die "Can't open $filename: $!";
3149
3150 Use 3-argument form to open a file with arbitrary weird characters in it,
3151
3152     open(FOO, '<', $file);
3153
3154 otherwise it's necessary to protect any leading and trailing whitespace:
3155
3156     $file =~ s#^(\s)#./$1#;
3157     open(FOO, "< $file\0");
3158
3159 (this may not work on some bizarre filesystems).  One should
3160 conscientiously choose between the I<magic> and 3-arguments form
3161 of open():
3162
3163     open IN, $ARGV[0];
3164
3165 will allow the user to specify an argument of the form C<"rsh cat file |">,
3166 but will not work on a filename which happens to have a trailing space, while
3167
3168     open IN, '<', $ARGV[0];
3169
3170 will have exactly the opposite restrictions.
3171
3172 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3173 should use the C<sysopen> function, which involves no such magic (but
3174 may use subtly different filemodes than Perl open(), which is mapped
3175 to C fopen()).  This is
3176 another way to protect your filenames from interpretation.  For example:
3177
3178     use IO::Handle;
3179     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3180         or die "sysopen $path: $!";
3181     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3182     print HANDLE "stuff $$\n";
3183     seek(HANDLE, 0, 0);
3184     print "File contains: ", <HANDLE>;
3185
3186 Using the constructor from the C<IO::Handle> package (or one of its
3187 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3188 filehandles that have the scope of whatever variables hold references to
3189 them, and automatically close whenever and however you leave that scope:
3190
3191     use IO::File;
3192     #...
3193     sub read_myfile_munged {
3194         my $ALL = shift;
3195         my $handle = new IO::File;
3196         open($handle, "myfile") or die "myfile: $!";
3197         $first = <$handle>
3198             or return ();     # Automatically closed here.
3199         mung $first or die "mung failed";       # Or here.
3200         return $first, <$handle> if $ALL;       # Or here.
3201         $first;                                 # Or here.
3202     }
3203
3204 See L</seek> for some details about mixing reading and writing.
3205
3206 =item opendir DIRHANDLE,EXPR
3207
3208 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3209 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3210 DIRHANDLE may be an expression whose value can be used as an indirect
3211 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3212 scalar variable (or array or hash element), the variable is assigned a
3213 reference to a new anonymous dirhandle.
3214 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3215
3216 =item ord EXPR
3217
3218 =item ord
3219
3220 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3221 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3222 uses C<$_>.
3223
3224 For the reverse, see L</chr>.
3225 See L<perlunicode> and L<encoding> for more about Unicode.
3226
3227 =item our EXPR
3228
3229 =item our EXPR TYPE
3230
3231 =item our EXPR : ATTRS
3232
3233 =item our TYPE EXPR : ATTRS
3234
3235 An C<our> declares the listed variables to be valid globals within
3236 the enclosing block, file, or C<eval>.  That is, it has the same
3237 scoping rules as a "my" declaration, but does not create a local
3238 variable.  If more than one value is listed, the list must be placed
3239 in parentheses.  The C<our> declaration has no semantic effect unless
3240 "use strict vars" is in effect, in which case it lets you use the
3241 declared global variable without qualifying it with a package name.
3242 (But only within the lexical scope of the C<our> declaration.  In this
3243 it differs from "use vars", which is package scoped.)
3244
3245 An C<our> declaration declares a global variable that will be visible
3246 across its entire lexical scope, even across package boundaries.  The
3247 package in which the variable is entered is determined at the point
3248 of the declaration, not at the point of use.  This means the following
3249 behavior holds:
3250
3251     package Foo;
3252     our $bar;           # declares $Foo::bar for rest of lexical scope
3253     $bar = 20;
3254
3255     package Bar;
3256     print $bar;         # prints 20
3257
3258 Multiple C<our> declarations in the same lexical scope are allowed
3259 if they are in different packages.  If they happened to be in the same
3260 package, Perl will emit warnings if you have asked for them.
3261
3262     use warnings;
3263     package Foo;
3264     our $bar;           # declares $Foo::bar for rest of lexical scope
3265     $bar = 20;
3266
3267     package Bar;
3268     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3269     print $bar;         # prints 30
3270
3271     our $bar;           # emits warning
3272
3273 An C<our> declaration may also have a list of attributes associated
3274 with it.
3275
3276 The exact semantics and interface of TYPE and ATTRS are still
3277 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3278 and attributes are handled using the C<attributes> pragma, or starting
3279 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3280 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3281 L<attributes>, and L<Attribute::Handlers>.
3282
3283 The only currently recognized C<our()> attribute is C<unique> which
3284 indicates that a single copy of the global is to be used by all
3285 interpreters should the program happen to be running in a
3286 multi-interpreter environment. (The default behaviour would be for
3287 each interpreter to have its own copy of the global.)  Examples:
3288
3289     our @EXPORT : unique = qw(foo);
3290     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3291     our $VERSION : unique = "1.00";
3292
3293 Note that this attribute also has the effect of making the global
3294 readonly when the first new interpreter is cloned (for example,
3295 when the first new thread is created).
3296
3297 Multi-interpreter environments can come to being either through the
3298 fork() emulation on Windows platforms, or by embedding perl in a
3299 multi-threaded application.  The C<unique> attribute does nothing in
3300 all other environments.
3301
3302 Warning: the current implementation of this attribute operates on the
3303 typeglob associated with the variable; this means that C<our $x : unique>
3304 also has the effect of C<our @x : unique; our %x : unique>. This may be
3305 subject to change.
3306
3307 =item pack TEMPLATE,LIST
3308
3309 Takes a LIST of values and converts it into a string using the rules
3310 given by the TEMPLATE.  The resulting string is the concatenation of
3311 the converted values.  Typically, each converted value looks
3312 like its machine-level representation.  For example, on 32-bit machines
3313 an integer may be represented by a sequence of 4 bytes which will be 
3314 converted to a sequence of 4 characters.
3315
3316 The TEMPLATE is a sequence of characters that give the order and type
3317 of values, as follows:
3318
3319     a   A string with arbitrary binary data, will be null padded.
3320     A   A text (ASCII) string, will be space padded.
3321     Z   A null terminated (ASCIZ) string, will be null padded.
3322
3323     b   A bit string (ascending bit order inside each byte, like vec()).
3324     B   A bit string (descending bit order inside each byte).
3325     h   A hex string (low nybble first).
3326     H   A hex string (high nybble first).
3327
3328     c   A signed char (8-bit) value.
3329     C   An unsigned C char (octet) even under Unicode. Should normally not
3330         be used. See U and W instead.
3331     W   An unsigned char value (can be greater than 255).
3332
3333     s   A signed short (16-bit) value.
3334     S   An unsigned short value.
3335
3336     l   A signed long (32-bit) value.
3337     L   An unsigned long value.
3338
3339     q   A signed quad (64-bit) value.
3340     Q   An unsigned quad value.
3341           (Quads are available only if your system supports 64-bit
3342            integer values _and_ if Perl has been compiled to support those.
3343            Causes a fatal error otherwise.)
3344
3345     i   A signed integer value.
3346     I   A unsigned integer value.
3347           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3348            size depends on what a local C compiler calls 'int'.)
3349  
3350     n   An unsigned short (16-bit) in "network" (big-endian) order.
3351     N   An unsigned long (32-bit) in "network" (big-endian) order.
3352     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3353     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3354
3355     j   A Perl internal signed integer value (IV).
3356     J   A Perl internal unsigned integer value (UV).
3357
3358     f   A single-precision float in the native format.
3359     d   A double-precision float in the native format.
3360
3361     F   A Perl internal floating point value (NV) in the native format
3362     D   A long double-precision float in the native format.
3363           (Long doubles are available only if your system supports long
3364            double values _and_ if Perl has been compiled to support those.
3365            Causes a fatal error otherwise.)
3366
3367     p   A pointer to a null-terminated string.
3368     P   A pointer to a structure (fixed-length string).
3369
3370     u   A uuencoded string.
3371     U   A Unicode character number.  Encodes to UTF-8 internally
3372         (or UTF-EBCDIC in EBCDIC platforms).
3373
3374     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3375         details).  Its bytes represent an unsigned integer in base 128,
3376         most significant digit first, with as few digits as possible.  Bit
3377         eight (the high bit) is set on each byte except the last.
3378
3379     x   A null byte.
3380     X   Back up a byte.
3381     @   Null fill or truncate to absolute position, counted from the
3382         start of the innermost ()-group.
3383     .   Null fill or truncate to absolute position specified by value.
3384     (   Start of a ()-group.
3385
3386 Some letters in the TEMPLATE may optionally be followed by one or
3387 more of these modifiers (the second column lists the letters for
3388 which the modifier is valid):
3389
3390     !   sSlLiI     Forces native (short, long, int) sizes instead
3391                    of fixed (16-/32-bit) sizes.
3392
3393         xX         Make x and X act as alignment commands.
3394
3395         nNvV       Treat integers as signed instead of unsigned.
3396
3397         @.         Specify position as byte offset in the internal
3398                    representation of the packed string. Efficient but
3399                    dangerous.
3400
3401     >   sSiIlLqQ   Force big-endian byte-order on the type.
3402         jJfFdDpP   (The "big end" touches the construct.)
3403
3404     <   sSiIlLqQ   Force little-endian byte-order on the type.
3405         jJfFdDpP   (The "little end" touches the construct.)
3406
3407 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3408 in which case they force a certain byte-order on all components of
3409 that group, including subgroups.
3410
3411 The following rules apply:
3412
3413 =over 8
3414
3415 =item *
3416
3417 Each letter may optionally be followed by a number giving a repeat
3418 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3419 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3420 that many values from the LIST.  A C<*> for the repeat count means to
3421 use however many items are left, except for C<@>, C<x>, C<X>, where it
3422 is equivalent to C<0>, for <.> where it means relative to string start
3423 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3424 A numeric repeat count may optionally be enclosed in brackets, as in
3425 C<pack 'C[80]', @arr>.
3426
3427 One can replace the numeric repeat count by a template enclosed in brackets;
3428 then the packed length of this template in bytes is used as a count.
3429 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3430 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3431 If the template in brackets contains alignment commands (such as C<x![d]>),
3432 its packed length is calculated as if the start of the template has the maximal
3433 possible alignment.
3434
3435 When used with C<Z>, C<*> results in the addition of a trailing null
3436 byte (so the packed result will be one longer than the byte C<length>
3437 of the item).
3438
3439 When used with C<@>, the repeat count represents an offset from the start
3440 of the innermost () group.
3441
3442 When used with C<.>, the repeat count is used to determine the starting
3443 position from where the value offset is calculated. If the repeat count
3444 is 0, it's relative to the current position. If the repeat count is C<*>,
3445 the offset is relative to the start of the packed string. And if its an
3446 integer C<n> the offset is relative to the start of the n-th innermost
3447 () group (or the start of the string if C<n> is bigger then the group
3448 level).
3449
3450 The repeat count for C<u> is interpreted as the maximal number of bytes
3451 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3452 count should not be more than 65.
3453
3454 =item *
3455
3456 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3457 string of length count, padding with nulls or spaces as necessary.  When
3458 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3459 after the first null, and C<a> returns data verbatim.
3460
3461 If the value-to-pack is too long, it is truncated.  If too long and an
3462 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3463 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3464 count is 0).
3465
3466 =item *
3467
3468 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3469 Each character of the input field of pack() generates 1 bit of the result.
3470 Each result bit is based on the least-significant bit of the corresponding
3471 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3472 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3473
3474 Starting from the beginning of the input string of pack(), each 8-tuple
3475 of characters is converted to 1 character of output.  With format C<b>
3476 the first character of the 8-tuple determines the least-significant bit of a
3477 character, and with format C<B> it determines the most-significant bit of
3478 a character.
3479
3480 If the length of the input string is not exactly divisible by 8, the
3481 remainder is packed as if the input string were padded by null characters
3482 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3483
3484 If the input string of pack() is longer than needed, extra characters are 
3485 ignored. A C<*> for the repeat count of pack() means to use all the 
3486 characters of the input field.  On unpack()ing the bits are converted to a 
3487 string of C<"0">s and C<"1">s.
3488
3489 =item *
3490
3491 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3492 representable as hexadecimal digits, 0-9a-f) long.
3493
3494 Each character of the input field of pack() generates 4 bits of the result.
3495 For non-alphabetical characters the result is based on the 4 least-significant
3496 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3497 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3498 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3499 is compatible with the usual hexadecimal digits, so that C<"a"> and
3500 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3501 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3502
3503 Starting from the beginning of the input string of pack(), each pair
3504 of characters is converted to 1 character of output.  With format C<h> the
3505 first character of the pair determines the least-significant nybble of the
3506 output character, and with format C<H> it determines the most-significant
3507 nybble.
3508
3509 If the length of the input string is not even, it behaves as if padded
3510 by a null character at the end.  Similarly, during unpack()ing the "extra"
3511 nybbles are ignored.
3512
3513 If the input string of pack() is longer than needed, extra characters are
3514 ignored.
3515 A C<*> for the repeat count of pack() means to use all the characters of
3516 the input field.  On unpack()ing the nybbles are converted to a string
3517 of hexadecimal digits.
3518
3519 =item *
3520
3521 The C<p> type packs a pointer to a null-terminated string.  You are
3522 responsible for ensuring the string is not a temporary value (which can
3523 potentially get deallocated before you get around to using the packed result).
3524 The C<P> type packs a pointer to a structure of the size indicated by the
3525 length.  A NULL pointer is created if the corresponding value for C<p> or
3526 C<P> is C<undef>, similarly for unpack().
3527
3528 If your system has a strange pointer size (i.e. a pointer is neither as
3529 big as an int nor as big as a long), it may not be possible to pack or
3530 unpack pointers in big- or little-endian byte order.  Attempting to do
3531 so will result in a fatal error.
3532
3533 =item *
3534
3535 The C</> template character allows packing and unpacking of a sequence of
3536 items where the packed structure contains a packed item count followed by 
3537 the packed items themselves.
3538 You write I<length-item>C</>I<sequence-item>.
3539
3540 The I<length-item> can be any C<pack> template letter, and describes
3541 how the length value is packed.  The ones likely to be of most use are
3542 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3543 SNMP) and C<N> (for Sun XDR).
3544
3545 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3546 the minimum of that and the number of available items is used as argument
3547 for the I<length-item>. If it has no repeat count or uses a '*', the number
3548 of available items is used. For C<unpack> the repeat count is always obtained
3549 by decoding the packed item count, and the I<sequence-item> must not have a
3550 repeat count.
3551
3552 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3553 the I<length-item> is a string length, not a number of strings. If there is
3554 an explicit repeat count for pack, the packed string will be adjusted to that
3555 given length.
3556
3557     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3558     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3559     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3560     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3561
3562 The I<length-item> is not returned explicitly from C<unpack>.
3563
3564 Adding a count to the I<length-item> letter is unlikely to do anything
3565 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3566 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3567 which Perl does not regard as legal in numeric strings.
3568
3569 =item *
3570
3571 The integer types C<s>, C<S>, C<l>, and C<L> may be
3572 followed by a C<!> modifier to signify native shorts or
3573 longs--as you can see from above for example a bare C<l> does mean
3574 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3575 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3576 see whether using C<!> makes any difference by
3577
3578         print length(pack("s")), " ", length(pack("s!")), "\n";
3579         print length(pack("l")), " ", length(pack("l!")), "\n";
3580
3581 C<i!> and C<I!> also work but only because of completeness;
3582 they are identical to C<i> and C<I>.
3583
3584 The actual sizes (in bytes) of native shorts, ints, longs, and long
3585 longs on the platform where Perl was built are also available via
3586 L<Config>:
3587
3588        use Config;
3589        print $Config{shortsize},    "\n";
3590        print $Config{intsize},      "\n";
3591        print $Config{longsize},     "\n";
3592        print $Config{longlongsize}, "\n";
3593
3594 (The C<$Config{longlongsize}> will be undefined if your system does
3595 not support long longs.)
3596
3597 =item *
3598
3599 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3600 are inherently non-portable between processors and operating systems
3601 because they obey the native byteorder and endianness.  For example a
3602 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3603 (arranged in and handled by the CPU registers) into bytes as
3604
3605         0x12 0x34 0x56 0x78     # big-endian
3606         0x78 0x56 0x34 0x12     # little-endian
3607
3608 Basically, the Intel and VAX CPUs are little-endian, while everybody
3609 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3610 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3611 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3612 mode.
3613
3614 The names `big-endian' and `little-endian' are comic references to
3615 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3616 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3617 the egg-eating habits of the Lilliputians.
3618
3619 Some systems may have even weirder byte orders such as
3620
3621         0x56 0x78 0x12 0x34
3622         0x34 0x12 0x78 0x56
3623
3624 You can see your system's preference with
3625
3626         print join(" ", map { sprintf "%#02x", $_ }
3627                             unpack("W*",pack("L",0x12345678))), "\n";
3628
3629 The byteorder on the platform where Perl was built is also available
3630 via L<Config>:
3631
3632         use Config;
3633         print $Config{byteorder}, "\n";
3634
3635 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3636 and C<'87654321'> are big-endian.
3637
3638 If you want portable packed integers you can either use the formats
3639 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3640 modifiers.  These modifiers are only available as of perl 5.9.2.
3641 See also L<perlport>.
3642
3643 =item *
3644
3645 All integer and floating point formats as well as C<p> and C<P> and
3646 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3647 to force big- or little- endian byte-order, respectively.
3648 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3649 signed integers, 64-bit integers and floating point values.  However,
3650 there are some things to keep in mind.
3651
3652 Exchanging signed integers between different platforms only works
3653 if all platforms store them in the same format.  Most platforms store
3654 signed integers in two's complement, so usually this is not an issue.
3655
3656 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3657 formats on big- or little-endian machines.  Otherwise, attempting to
3658 do so will result in a fatal error.
3659
3660 Forcing big- or little-endian byte-order on floating point values for
3661 data exchange can only work if all platforms are using the same
3662 binary representation (e.g. IEEE floating point format).  Even if all
3663 platforms are using IEEE, there may be subtle differences.  Being able
3664 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3665 but also very dangerous if you don't know exactly what you're doing.
3666 It is definetely not a general way to portably store floating point
3667 values.
3668
3669 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3670 all types inside the group that accept the byte-order modifiers,
3671 including all subgroups.  It will silently be ignored for all other
3672 types.  You are not allowed to override the byte-order within a group
3673 that already has a byte-order modifier suffix.
3674
3675 =item *
3676
3677 Real numbers (floats and doubles) are in the native machine format only;
3678 due to the multiplicity of floating formats around, and the lack of a
3679 standard "network" representation, no facility for interchange has been
3680 made.  This means that packed floating point data written on one machine
3681 may not be readable on another - even if both use IEEE floating point
3682 arithmetic (as the endian-ness of the memory representation is not part
3683 of the IEEE spec).  See also L<perlport>.
3684
3685 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3686 modifiers to force big- or little-endian byte-order on floating point values.
3687
3688 Note that Perl uses doubles (or long doubles, if configured) internally for
3689 all numeric calculation, and converting from double into float and thence back
3690 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3691 will not in general equal $foo).
3692
3693 =item *
3694
3695 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3696 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3697 where the packed string is processed in its UTF-8-encoded Unicode form on
3698 a byte by byte basis. Character mode is the default unless the format string 
3699 starts with an C<U>. You can switch mode at any moment with an explicit 
3700 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3701 or until the end of the ()-group in which it was entered.
3702
3703 =item *
3704
3705 You must yourself do any alignment or padding by inserting for example
3706 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3707 could know where the characters are going to or coming from.  Therefore
3708 C<pack> (and C<unpack>) handle their output and input as flat
3709 sequences of characters.
3710
3711 =item *
3712
3713 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3714 take a repeat count, both as postfix, and for unpack() also via the C</>
3715 template character. Within each repetition of a group, positioning with
3716 C<@> starts again at 0. Therefore, the result of
3717
3718     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3719
3720 is the string "\0a\0\0bc".
3721
3722 =item *
3723
3724 C<x> and C<X> accept C<!> modifier.  In this case they act as
3725 alignment commands: they jump forward/back to the closest position
3726 aligned at a multiple of C<count> characters. For example, to pack() or
3727 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3728 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3729 aligned on the double's size.
3730
3731 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3732 both result in no-ops.
3733
3734 =item *
3735
3736 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3737 will represent signed 16-/32-bit integers in big-/little-endian order.
3738 This is only portable if all platforms sharing the packed data use the
3739 same binary representation for signed integers (e.g. all platforms are
3740 using two's complement representation).
3741
3742 =item *
3743
3744 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3745 White space may be used to separate pack codes from each other, but
3746 modifiers and a repeat count must follow immediately.
3747
3748 =item *
3749
3750 If TEMPLATE requires more arguments to pack() than actually given, pack()
3751 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3752 to pack() than actually given, extra arguments are ignored.
3753
3754 =back
3755
3756 Examples:
3757
3758     $foo = pack("WWWW",65,66,67,68);
3759     # foo eq "ABCD"
3760     $foo = pack("W4",65,66,67,68);
3761     # same thing
3762     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3763     # same thing with Unicode circled letters.
3764     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3765     # same thing with Unicode circled letters. You don't get the UTF-8
3766     # bytes because the U at the start of the format caused a switch to
3767     # U0-mode, so the UTF-8 bytes get joined into characters
3768     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3769     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3770     # This is the UTF-8 encoding of the string in the previous example
3771
3772     $foo = pack("ccxxcc",65,66,67,68);
3773     # foo eq "AB\0\0CD"
3774
3775     # note: the above examples featuring "W" and "c" are true
3776     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3777     # and UTF-8.  In EBCDIC the first example would be
3778     # $foo = pack("WWWW",193,194,195,196);
3779
3780     $foo = pack("s2",1,2);
3781     # "\1\0\2\0" on little-endian
3782     # "\0\1\0\2" on big-endian
3783
3784     $foo = pack("a4","abcd","x","y","z");
3785     # "abcd"
3786
3787     $foo = pack("aaaa","abcd","x","y","z");
3788     # "axyz"
3789
3790     $foo = pack("a14","abcdefg");
3791     # "abcdefg\0\0\0\0\0\0\0"
3792
3793     $foo = pack("i9pl", gmtime);
3794     # a real struct tm (on my system anyway)
3795
3796     $utmp_template = "Z8 Z8 Z16 L";
3797     $utmp = pack($utmp_template, @utmp1);
3798     # a struct utmp (BSDish)
3799
3800     @utmp2 = unpack($utmp_template, $utmp);
3801     # "@utmp1" eq "@utmp2"
3802
3803     sub bintodec {
3804         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3805     }
3806
3807     $foo = pack('sx2l', 12, 34);
3808     # short 12, two zero bytes padding, long 34
3809     $bar = pack('s@4l', 12, 34);
3810     # short 12, zero fill to position 4, long 34
3811     # $foo eq $bar
3812     $baz = pack('s.l', 12, 4, 34);
3813     # short 12, zero fill to position 4, long 34
3814
3815     $foo = pack('nN', 42, 4711);
3816     # pack big-endian 16- and 32-bit unsigned integers
3817     $foo = pack('S>L>', 42, 4711);
3818     # exactly the same
3819     $foo = pack('s<l<', -42, 4711);
3820     # pack little-endian 16- and 32-bit signed integers
3821     $foo = pack('(sl)<', -42, 4711);
3822     # exactly the same
3823
3824 The same template may generally also be used in unpack().
3825
3826 =item package NAMESPACE
3827
3828 =item package
3829
3830 Declares the compilation unit as being in the given namespace.  The scope
3831 of the package declaration is from the declaration itself through the end
3832 of the enclosing block, file, or eval (the same as the C<my> operator).
3833 All further unqualified dynamic identifiers will be in this namespace.
3834 A package statement affects only dynamic variables--including those
3835 you've used C<local> on--but I<not> lexical variables, which are created
3836 with C<my>.  Typically it would be the first declaration in a file to
3837 be included by the C<require> or C<use> operator.  You can switch into a
3838 package in more than one place; it merely influences which symbol table
3839 is used by the compiler for the rest of that block.  You can refer to
3840 variables and filehandles in other packages by prefixing the identifier
3841 with the package name and a double colon:  C<$Package::Variable>.
3842 If the package name is null, the C<main> package as assumed.  That is,
3843 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3844 still seen in older code).
3845
3846 If NAMESPACE is omitted, then there is no current package, and all
3847 identifiers must be fully qualified or lexicals.  However, you are
3848 strongly advised not to make use of this feature. Its use can cause
3849 unexpected behaviour, even crashing some versions of Perl. It is
3850 deprecated, and will be removed from a future release.
3851
3852 See L<perlmod/"Packages"> for more information about packages, modules,
3853 and classes.  See L<perlsub> for other scoping issues.
3854
3855 =item pipe READHANDLE,WRITEHANDLE
3856
3857 Opens a pair of connected pipes like the corresponding system call.
3858 Note that if you set up a loop of piped processes, deadlock can occur
3859 unless you are very careful.  In addition, note that Perl's pipes use
3860 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3861 after each command, depending on the application.
3862
3863 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3864 for examples of such things.
3865
3866 On systems that support a close-on-exec flag on files, the flag will be set
3867 for the newly opened file descriptors as determined by the value of $^F.
3868 See L<perlvar/$^F>.
3869
3870 =item pop ARRAY
3871
3872 =item pop
3873
3874 Pops and returns the last value of the array, shortening the array by
3875 one element.  Has an effect similar to
3876
3877     $ARRAY[$#ARRAY--]
3878
3879 If there are no elements in the array, returns the undefined value
3880 (although this may happen at other times as well).  If ARRAY is
3881 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3882 array in subroutines, just like C<shift>.
3883
3884 =item pos SCALAR
3885
3886 =item pos
3887
3888 Returns the offset of where the last C<m//g> search left off for the variable
3889 in question (C<$_> is used when the variable is not specified).  Note that
3890 0 is a valid match offset, while C<undef> indicates that the search position
3891 is reset (usually due to match failure, but can also be because no match has
3892 yet been performed on the scalar). C<pos> directly accesses the location used
3893 by the regexp engine to store the offset, so assigning to C<pos> will change
3894 that offset, and so will also influence the C<\G> zero-width assertion in
3895 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
3896 the return from C<pos> won't change either in this case.  See L<perlre> and
3897 L<perlop>.
3898
3899 =item print FILEHANDLE LIST
3900
3901 =item print LIST
3902
3903 =item print
3904
3905 Prints a string or a list of strings.  Returns true if successful.
3906 FILEHANDLE may be a scalar variable name, in which case the variable
3907 contains the name of or a reference to the filehandle, thus introducing
3908 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3909 the next token is a term, it may be misinterpreted as an operator
3910 unless you interpose a C<+> or put parentheses around the arguments.)
3911 If FILEHANDLE is omitted, prints by default to standard output (or
3912 to the last selected output channel--see L</select>).  If LIST is
3913 also omitted, prints C<$_> to the currently selected output channel.
3914 To set the default output channel to something other than STDOUT
3915 use the select operation.  The current value of C<$,> (if any) is
3916 printed between each LIST item.  The current value of C<$\> (if
3917 any) is printed after the entire LIST has been printed.  Because
3918 print takes a LIST, anything in the LIST is evaluated in list
3919 context, and any subroutine that you call will have one or more of
3920 its expressions evaluated in list context.  Also be careful not to
3921 follow the print keyword with a left parenthesis unless you want
3922 the corresponding right parenthesis to terminate the arguments to
3923 the print--interpose a C<+> or put parentheses around all the
3924 arguments.
3925
3926 Note that if you're storing FILEHANDLES in an array or other expression,
3927 you will have to use a block returning its value instead:
3928
3929     print { $files[$i] } "stuff\n";
3930     print { $OK ? STDOUT : STDERR } "stuff\n";
3931
3932 =item printf FILEHANDLE FORMAT, LIST
3933
3934 =item printf FORMAT, LIST
3935
3936 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3937 (the output record separator) is not appended.  The first argument
3938 of the list will be interpreted as the C<printf> format. See C<sprintf>
3939 for an explanation of the format argument. If C<use locale> is in effect,
3940 the character used for the decimal point in formatted real numbers is
3941 affected by the LC_NUMERIC locale.  See L<perllocale>.
3942
3943 Don't fall into the trap of using a C<printf> when a simple
3944 C<print> would do.  The C<print> is more efficient and less
3945 error prone.
3946
3947 =item prototype FUNCTION
3948
3949 Returns the prototype of a function as a string (or C<undef> if the
3950 function has no prototype).  FUNCTION is a reference to, or the name of,
3951 the function whose prototype you want to retrieve.
3952
3953 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3954 name for Perl builtin.  If the builtin is not I<overridable> (such as
3955 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3956 C<system>) returns C<undef> because the builtin does not really behave
3957 like a Perl function.  Otherwise, the string describing the equivalent
3958 prototype is returned.
3959
3960 =item push ARRAY,LIST
3961
3962 Treats ARRAY as a stack, and pushes the values of LIST
3963 onto the end of ARRAY.  The length of ARRAY increases by the length of
3964 LIST.  Has the same effect as
3965
3966     for $value (LIST) {
3967         $ARRAY[++$#ARRAY] = $value;
3968     }
3969
3970 but is more efficient.  Returns the new number of elements in the array.
3971
3972 =item q/STRING/
3973
3974 =item qq/STRING/
3975
3976 =item qr/STRING/
3977
3978 =item qx/STRING/
3979
3980 =item qw/STRING/
3981
3982 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3983
3984 =item quotemeta EXPR
3985
3986 =item quotemeta
3987
3988 Returns the value of EXPR with all non-"word"
3989 characters backslashed.  (That is, all characters not matching
3990 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3991 returned string, regardless of any locale settings.)
3992 This is the internal function implementing
3993 the C<\Q> escape in double-quoted strings.
3994
3995 If EXPR is omitted, uses C<$_>.
3996
3997 =item rand EXPR
3998
3999 =item rand
4000
4001 Returns a random fractional number greater than or equal to C<0> and less
4002 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4003 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4004 also special-cased as C<1> - this has not been documented before perl 5.8.0
4005 and is subject to change in future versions of perl.  Automatically calls
4006 C<srand> unless C<srand> has already been called.  See also C<srand>.
4007
4008 Apply C<int()> to the value returned by C<rand()> if you want random
4009 integers instead of random fractional numbers.  For example,
4010
4011     int(rand(10))
4012
4013 returns a random integer between C<0> and C<9>, inclusive.
4014
4015 (Note: If your rand function consistently returns numbers that are too
4016 large or too small, then your version of Perl was probably compiled
4017 with the wrong number of RANDBITS.)
4018
4019 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4020
4021 =item read FILEHANDLE,SCALAR,LENGTH
4022
4023 Attempts to read LENGTH I<characters> of data into variable SCALAR
4024 from the specified FILEHANDLE.  Returns the number of characters
4025 actually read, C<0> at end of file, or undef if there was an error (in
4026 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4027 so that the last character actually read is the last character of the
4028 scalar after the read.
4029
4030 An OFFSET may be specified to place the read data at some place in the
4031 string other than the beginning.  A negative OFFSET specifies
4032 placement at that many characters counting backwards from the end of
4033 the string.  A positive OFFSET greater than the length of SCALAR
4034 results in the string being padded to the required size with C<"\0">
4035 bytes before the result of the read is appended.
4036
4037 The call is actually implemented in terms of either Perl's or system's
4038 fread() call.  To get a true read(2) system call, see C<sysread>.
4039
4040 Note the I<characters>: depending on the status of the filehandle,
4041 either (8-bit) bytes or characters are read.  By default all
4042 filehandles operate on bytes, but for example if the filehandle has
4043 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4044 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4045 characters, not bytes.  Similarly for the C<:encoding> pragma:
4046 in that case pretty much any characters can be read.
4047
4048 =item readdir DIRHANDLE
4049
4050 Returns the next directory entry for a directory opened by C<opendir>.
4051 If used in list context, returns all the rest of the entries in the
4052 directory.  If there are no more entries, returns an undefined value in
4053 scalar context or a null list in list context.
4054
4055 If you're planning to filetest the return values out of a C<readdir>, you'd
4056 better prepend the directory in question.  Otherwise, because we didn't
4057 C<chdir> there, it would have been testing the wrong file.
4058
4059     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4060     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4061     closedir DIR;
4062
4063 =item readline EXPR
4064
4065 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4066 context, each call reads and returns the next line, until end-of-file is
4067 reached, whereupon the subsequent call returns undef.  In list context,
4068 reads until end-of-file is reached and returns a list of lines.  Note that
4069 the notion of "line" used here is however you may have defined it
4070 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4071
4072 When C<$/> is set to C<undef>, when readline() is in scalar
4073 context (i.e. file slurp mode), and when an empty file is read, it
4074 returns C<''> the first time, followed by C<undef> subsequently.
4075
4076 This is the internal function implementing the C<< <EXPR> >>
4077 operator, but you can use it directly.  The C<< <EXPR> >>
4078 operator is discussed in more detail in L<perlop/"I/O Operators">.
4079
4080     $line = <STDIN>;
4081     $line = readline(*STDIN);           # same thing
4082
4083 If readline encounters an operating system error, C<$!> will be set with the
4084 corresponding error message.  It can be helpful to check C<$!> when you are
4085 reading from filehandles you don't trust, such as a tty or a socket.  The
4086 following example uses the operator form of C<readline>, and takes the necessary
4087 steps to ensure that C<readline> was successful.
4088
4089     for (;;) {
4090         undef $!;
4091         unless (defined( $line = <> )) {
4092             die $! if $!;
4093             last; # reached EOF
4094         }
4095         # ...
4096     }
4097
4098 =item readlink EXPR
4099
4100 =item readlink
4101
4102 Returns the value of a symbolic link, if symbolic links are
4103 implemented.  If not, gives a fatal error.  If there is some system
4104 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4105 omitted, uses C<$_>.
4106
4107 =item readpipe EXPR
4108
4109 EXPR is executed as a system command.
4110 The collected standard output of the command is returned.
4111 In scalar context, it comes back as a single (potentially
4112 multi-line) string.  In list context, returns a list of lines
4113 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4114 This is the internal function implementing the C<qx/EXPR/>
4115 operator, but you can use it directly.  The C<qx/EXPR/>
4116 operator is discussed in more detail in L<perlop/"I/O Operators">.
4117
4118 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4119
4120 Receives a message on a socket.  Attempts to receive LENGTH characters
4121 of data into variable SCALAR from the specified SOCKET filehandle.
4122 SCALAR will be grown or shrunk to the length actually read.  Takes the
4123 same flags as the system call of the same name.  Returns the address
4124 of the sender if SOCKET's protocol supports this; returns an empty
4125 string otherwise.  If there's an error, returns the undefined value.
4126 This call is actually implemented in terms of recvfrom(2) system call.
4127 See L<perlipc/"UDP: Message Passing"> for examples.
4128
4129 Note the I<characters>: depending on the status of the socket, either
4130 (8-bit) bytes or characters are received.  By default all sockets
4131 operate on bytes, but for example if the socket has been changed using
4132 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4133 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4134 characters, not bytes.  Similarly for the C<:encoding> pragma:
4135 in that case pretty much any characters can be read.
4136
4137 =item redo LABEL
4138
4139 =item redo
4140
4141 The C<redo> command restarts the loop block without evaluating the
4142 conditional again.  The C<continue> block, if any, is not executed.  If
4143 the LABEL is omitted, the command refers to the innermost enclosing
4144 loop.  This command is normally used by programs that want to lie to
4145 themselves about what was just input:
4146
4147     # a simpleminded Pascal comment stripper
4148     # (warning: assumes no { or } in strings)
4149     LINE: while (<STDIN>) {
4150         while (s|({.*}.*){.*}|$1 |) {}
4151         s|{.*}| |;
4152         if (s|{.*| |) {
4153             $front = $_;
4154             while (<STDIN>) {
4155                 if (/}/) {      # end of comment?
4156                     s|^|$front\{|;
4157                     redo LINE;
4158                 }
4159             }
4160         }
4161         print;
4162     }
4163
4164 C<redo> cannot be used to retry a block which returns a value such as
4165 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4166 a grep() or map() operation.
4167
4168 Note that a block by itself is semantically identical to a loop
4169 that executes once.  Thus C<redo> inside such a block will effectively
4170 turn it into a looping construct.
4171
4172 See also L</continue> for an illustration of how C<last>, C<next>, and
4173 C<redo> work.
4174
4175 =item ref EXPR
4176
4177 =item ref
4178
4179 Returns a non-empty string if EXPR is a reference, the empty
4180 string otherwise. If EXPR
4181 is not specified, C<$_> will be used.  The value returned depends on the
4182 type of thing the reference is a reference to.
4183 Builtin types include:
4184
4185     SCALAR
4186     ARRAY
4187     HASH
4188     CODE
4189     REF
4190     GLOB
4191     LVALUE
4192
4193 If the referenced object has been blessed into a package, then that package
4194 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4195
4196     if (ref($r) eq "HASH") {
4197         print "r is a reference to a hash.\n";
4198     }
4199     unless (ref($r)) {
4200         print "r is not a reference at all.\n";
4201     }
4202     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
4203         print "r is a reference to something that isa hash.\n";
4204     }
4205
4206 See also L<perlref>.
4207
4208 =item rename OLDNAME,NEWNAME
4209
4210 Changes the name of a file; an existing file NEWNAME will be
4211 clobbered.  Returns true for success, false otherwise.
4212
4213 Behavior of this function varies wildly depending on your system
4214 implementation.  For example, it will usually not work across file system
4215 boundaries, even though the system I<mv> command sometimes compensates
4216 for this.  Other restrictions include whether it works on directories,
4217 open files, or pre-existing files.  Check L<perlport> and either the
4218 rename(2) manpage or equivalent system documentation for details.
4219
4220 =item require VERSION
4221
4222 =item require EXPR
4223
4224 =item require
4225
4226 Demands a version of Perl specified by VERSION, or demands some semantics
4227 specified by EXPR or by C<$_> if EXPR is not supplied.
4228
4229 VERSION may be either a numeric argument such as 5.006, which will be
4230 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4231 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4232 VERSION is greater than the version of the current Perl interpreter.
4233 Compare with L</use>, which can do a similar check at compile time.
4234
4235 Specifying VERSION as a literal of the form v5.6.1 should generally be
4236 avoided, because it leads to misleading error messages under earlier
4237 versions of Perl which do not support this syntax.  The equivalent numeric
4238 version should be used instead.
4239
4240     require v5.6.1;     # run time version check
4241     require 5.6.1;      # ditto
4242     require 5.006_001;  # ditto; preferred for backwards compatibility
4243
4244 Otherwise, demands that a library file be included if it hasn't already
4245 been included.  The file is included via the do-FILE mechanism, which is
4246 essentially just a variety of C<eval>.  Has semantics similar to the
4247 following subroutine:
4248
4249     sub require {
4250        my ($filename) = @_;
4251        if (exists $INC{$filename}) {
4252            return 1 if $INC{$filename};
4253            die "Compilation failed in require";
4254        }
4255        my ($realfilename,$result);
4256        ITER: {
4257            foreach $prefix (@INC) {
4258                $realfilename = "$prefix/$filename";
4259                if (-f $realfilename) {
4260                    $INC{$filename} = $realfilename;
4261                    $result = do $realfilename;
4262                    last ITER;
4263                }
4264            }
4265            die "Can't find $filename in \@INC";
4266        }
4267        if ($@) {
4268            $INC{$filename} = undef;
4269            die $@;
4270        } elsif (!$result) {
4271            delete $INC{$filename};
4272            die "$filename did not return true value";
4273        } else {
4274            return $result;
4275        }
4276     }
4277
4278 Note that the file will not be included twice under the same specified
4279 name.
4280
4281 The file must return true as the last statement to indicate
4282 successful execution of any initialization code, so it's customary to
4283 end such a file with C<1;> unless you're sure it'll return true
4284 otherwise.  But it's better just to put the C<1;>, in case you add more
4285 statements.
4286
4287 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4288 replaces "F<::>" with "F</>" in the filename for you,
4289 to make it easy to load standard modules.  This form of loading of
4290 modules does not risk altering your namespace.
4291
4292 In other words, if you try this:
4293
4294         require Foo::Bar;    # a splendid bareword
4295
4296 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4297 directories specified in the C<@INC> array.
4298
4299 But if you try this:
4300
4301         $class = 'Foo::Bar';
4302         require $class;      # $class is not a bareword
4303     #or
4304         require "Foo::Bar";  # not a bareword because of the ""
4305
4306 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4307 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4308
4309         eval "require $class";
4310
4311 Now that you understand how C<require> looks for files in the case of
4312 a bareword argument, there is a little extra functionality going on
4313 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4314 it will first look for a filename with a "F<.pmc>" extension.  A file
4315 with this extension is assumed to be Perl bytecode generated by
4316 L<B::Bytecode|B::Bytecode>.  If this file is found, and its modification
4317 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4318 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4319
4320 You can also insert hooks into the import facility, by putting directly
4321 Perl code into the @INC array.  There are three forms of hooks: subroutine
4322 references, array references and blessed objects.
4323
4324 Subroutine references are the simplest case.  When the inclusion system
4325 walks through @INC and encounters a subroutine, this subroutine gets
4326 called with two parameters, the first being a reference to itself, and the
4327 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4328 subroutine should return C<undef> or a filehandle, from which the file to
4329 include will be read.  If C<undef> is returned, C<require> will look at
4330 the remaining elements of @INC.
4331
4332 If the hook is an array reference, its first element must be a subroutine
4333 reference.  This subroutine is called as above, but the first parameter is
4334 the array reference.  This enables to pass indirectly some arguments to
4335 the subroutine.
4336
4337 In other words, you can write:
4338
4339     push @INC, \&my_sub;
4340     sub my_sub {
4341         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4342         ...
4343     }
4344
4345 or:
4346
4347     push @INC, [ \&my_sub, $x, $y, ... ];
4348     sub my_sub {
4349         my ($arrayref, $filename) = @_;
4350         # Retrieve $x, $y, ...
4351         my @parameters = @$arrayref[1..$#$arrayref];
4352         ...
4353     }
4354
4355 If the hook is an object, it must provide an INC method, that will be
4356 called as above, the first parameter being the object itself.  (Note that
4357 you must fully qualify the sub's name, as it is always forced into package
4358 C<main>.)  Here is a typical code layout:
4359
4360     # In Foo.pm
4361     package Foo;
4362     sub new { ... }
4363     sub Foo::INC {
4364         my ($self, $filename) = @_;
4365         ...
4366     }
4367
4368     # In the main program
4369     push @INC, new Foo(...);
4370
4371 Note that these hooks are also permitted to set the %INC entry
4372 corresponding to the files they have loaded. See L<perlvar/%INC>.
4373
4374 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4375
4376 =item reset EXPR
4377
4378 =item reset
4379
4380 Generally used in a C<continue> block at the end of a loop to clear
4381 variables and reset C<??> searches so that they work again.  The
4382 expression is interpreted as a list of single characters (hyphens
4383 allowed for ranges).  All variables and arrays beginning with one of
4384 those letters are reset to their pristine state.  If the expression is
4385 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4386 only variables or searches in the current package.  Always returns
4387 1.  Examples:
4388
4389     reset 'X';          # reset all X variables
4390     reset 'a-z';        # reset lower case variables
4391     reset;              # just reset ?one-time? searches
4392
4393 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4394 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4395 variables--lexical variables are unaffected, but they clean themselves
4396 up on scope exit anyway, so you'll probably want to use them instead.
4397 See L</my>.
4398
4399 =item return EXPR
4400
4401 =item return
4402
4403 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4404 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4405 context, depending on how the return value will be used, and the context
4406 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4407 is given, returns an empty list in list context, the undefined value in
4408 scalar context, and (of course) nothing at all in a void context.
4409
4410 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4411 or do FILE will automatically return the value of the last expression
4412 evaluated.)
4413
4414 =item reverse LIST
4415
4416 In list context, returns a list value consisting of the elements
4417 of LIST in the opposite order.  In scalar context, concatenates the
4418 elements of LIST and returns a string value with all characters
4419 in the opposite order.
4420
4421     print reverse <>;           # line tac, last line first
4422
4423     undef $/;                   # for efficiency of <>
4424     print scalar reverse <>;    # character tac, last line tsrif
4425
4426 Used without arguments in scalar context, reverse() reverses C<$_>.
4427
4428 This operator is also handy for inverting a hash, although there are some
4429 caveats.  If a value is duplicated in the original hash, only one of those
4430 can be represented as a key in the inverted hash.  Also, this has to
4431 unwind one hash and build a whole new one, which may take some time
4432 on a large hash, such as from a DBM file.
4433
4434     %by_name = reverse %by_address;     # Invert the hash
4435
4436 =item rewinddir DIRHANDLE
4437
4438 Sets the current position to the beginning of the directory for the
4439 C<readdir> routine on DIRHANDLE.
4440
4441 =item rindex STR,SUBSTR,POSITION
4442
4443 =item rindex STR,SUBSTR
4444
4445 Works just like index() except that it returns the position of the LAST
4446 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4447 last occurrence at or before that position.
4448
4449 =item rmdir FILENAME
4450
4451 =item rmdir
4452
4453 Deletes the directory specified by FILENAME if that directory is
4454 empty.  If it succeeds it returns true, otherwise it returns false and
4455 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4456
4457 =item s///
4458
4459 The substitution operator.  See L<perlop>.
4460
4461 =item scalar EXPR
4462
4463 Forces EXPR to be interpreted in scalar context and returns the value
4464 of EXPR.
4465
4466     @counts = ( scalar @a, scalar @b, scalar @c );
4467
4468 There is no equivalent operator to force an expression to
4469 be interpolated in list context because in practice, this is never
4470 needed.  If you really wanted to do so, however, you could use
4471 the construction C<@{[ (some expression) ]}>, but usually a simple
4472 C<(some expression)> suffices.
4473
4474 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4475 parenthesized list, this behaves as a scalar comma expression, evaluating
4476 all but the last element in void context and returning the final element
4477 evaluated in scalar context.  This is seldom what you want.
4478
4479 The following single statement:
4480
4481         print uc(scalar(&foo,$bar)),$baz;
4482
4483 is the moral equivalent of these two:
4484
4485         &foo;
4486         print(uc($bar),$baz);
4487
4488 See L<perlop> for more details on unary operators and the comma operator.
4489
4490 =item seek FILEHANDLE,POSITION,WHENCE
4491
4492 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4493 FILEHANDLE may be an expression whose value gives the name of the
4494 filehandle.  The values for WHENCE are C<0> to set the new position
4495 I<in bytes> to POSITION, C<1> to set it to the current position plus
4496 POSITION, and C<2> to set it to EOF plus POSITION (typically
4497 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4498 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4499 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4500 otherwise.
4501
4502 Note the I<in bytes>: even if the filehandle has been set to
4503 operate on characters (for example by using the C<:utf8> open
4504 layer), tell() will return byte offsets, not character offsets
4505 (because implementing that would render seek() and tell() rather slow).
4506
4507 If you want to position file for C<sysread> or C<syswrite>, don't use
4508 C<seek>--buffering makes its effect on the file's system position
4509 unpredictable and non-portable.  Use C<sysseek> instead.
4510
4511 Due to the rules and rigors of ANSI C, on some systems you have to do a
4512 seek whenever you switch between reading and writing.  Amongst other
4513 things, this may have the effect of calling stdio's clearerr(3).
4514 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4515
4516     seek(TEST,0,1);
4517
4518 This is also useful for applications emulating C<tail -f>.  Once you hit
4519 EOF on your read, and then sleep for a while, you might have to stick in a
4520 seek() to reset things.  The C<seek> doesn't change the current position,
4521 but it I<does> clear the end-of-file condition on the handle, so that the
4522 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4523
4524 If that doesn't work (some IO implementations are particularly
4525 cantankerous), then you may need something more like this:
4526
4527     for (;;) {
4528         for ($curpos = tell(FILE); $_ = <FILE>;
4529              $curpos = tell(FILE)) {
4530             # search for some stuff and put it into files
4531         }
4532         sleep($for_a_while);
4533         seek(FILE, $curpos, 0);
4534     }
4535
4536 =item seekdir DIRHANDLE,POS
4537
4538 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4539 must be a value returned by C<telldir>.  Has the same caveats about
4540 possible directory compaction as the corresponding system library
4541 routine.
4542
4543 =item select FILEHANDLE
4544
4545 =item select
4546
4547 Returns the currently selected filehandle.  Sets the current default
4548 filehandle for output, if FILEHANDLE is supplied.  This has two
4549 effects: first, a C<write> or a C<print> without a filehandle will
4550 default to this FILEHANDLE.  Second, references to variables related to
4551 output will refer to this output channel.  For example, if you have to
4552 set the top of form format for more than one output channel, you might
4553 do the following:
4554
4555     select(REPORT1);
4556     $^ = 'report1_top';
4557     select(REPORT2);
4558     $^ = 'report2_top';
4559
4560 FILEHANDLE may be an expression whose value gives the name of the
4561 actual filehandle.  Thus:
4562
4563     $oldfh = select(STDERR); $| = 1; select($oldfh);
4564
4565 Some programmers may prefer to think of filehandles as objects with
4566 methods, preferring to write the last example as:
4567
4568     use IO::Handle;
4569     STDERR->autoflush(1);
4570
4571 =item select RBITS,WBITS,EBITS,TIMEOUT
4572
4573 This calls the select(2) system call with the bit masks specified, which
4574 can be constructed using C<fileno> and C<vec>, along these lines:
4575
4576     $rin = $win = $ein = '';
4577     vec($rin,fileno(STDIN),1) = 1;
4578     vec($win,fileno(STDOUT),1) = 1;
4579     $ein = $rin | $win;
4580
4581 If you want to select on many filehandles you might wish to write a
4582 subroutine:
4583
4584     sub fhbits {
4585         my(@fhlist) = split(' ',$_[0]);
4586         my($bits);
4587         for (@fhlist) {
4588             vec($bits,fileno($_),1) = 1;
4589         }
4590         $bits;
4591     }
4592     $rin = fhbits('STDIN TTY SOCK');
4593
4594 The usual idiom is:
4595
4596     ($nfound,$timeleft) =
4597       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4598
4599 or to block until something becomes ready just do this
4600
4601     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4602
4603 Most systems do not bother to return anything useful in $timeleft, so
4604 calling select() in scalar context just returns $nfound.
4605
4606 Any of the bit masks can also be undef.  The timeout, if specified, is
4607 in seconds, which may be fractional.  Note: not all implementations are
4608 capable of returning the $timeleft.  If not, they always return
4609 $timeleft equal to the supplied $timeout.
4610
4611 You can effect a sleep of 250 milliseconds this way:
4612
4613     select(undef, undef, undef, 0.25);
4614
4615 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4616 is implementation-dependent.  See also L<perlport> for notes on the
4617 portability of C<select>.
4618
4619 On error, C<select> returns C<undef> and sets C<$!>.
4620