This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Get split.t working under minitest
[perl5.git] / t / op / split.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     require './test.pl';
6     @INC = () unless is_miniperl();
7     unshift @INC, '../lib';
8 }
9
10 plan tests => 119;
11
12 $FS = ':';
13
14 $_ = 'a:b:c';
15
16 ($a,$b,$c) = split($FS,$_);
17
18 is(join(';',$a,$b,$c), 'a;b;c', 'Split a simple string into scalars.');
19
20 @ary = split(/:b:/);
21 $cnt = split(/:b:/);
22 is(join("$_",@ary), 'aa:b:cc');
23 is($cnt, scalar(@ary));
24
25 $_ = "abc\n";
26 my @xyz = (@ary = split(//));
27 $cnt = split(//);
28 is(join(".",@ary), "a.b.c.\n");
29 is($cnt, scalar(@ary));
30
31 $_ = "a:b:c::::";
32 @ary = split(/:/);
33 $cnt = split(/:/);
34 is(join(".",@ary), "a.b.c");
35 is($cnt, scalar(@ary));
36
37 $_ = join(':',split(' ',"    a b\tc \t d "));
38 is($_, 'a:b:c:d');
39 @ary = split(' ',"    a b\tc \t d ");
40 $cnt = split(' ',"    a b\tc \t d ");
41 is($cnt, scalar(@ary));
42
43 $_ = join(':',split(/ */,"foo  bar bie\tdoll"));
44 is($_ , "f:o:o:b:a:r:b:i:e:\t:d:o:l:l");
45 @ary = split(/ */,"foo  bar bie\tdoll");
46 $cnt = split(/ */,"foo  bar bie\tdoll");
47 is($cnt, scalar(@ary));
48
49 $_ = join(':', 'foo', split(/ /,'a b  c'), 'bar');
50 is($_, "foo:a:b::c:bar");
51 @ary = split(/ /,'a b  c');
52 $cnt = split(/ /,'a b  c');
53 is($cnt, scalar(@ary));
54
55 # Can we say how many fields to split to?
56 $_ = join(':', split(' ','1 2 3 4 5 6', 3));
57 is($_, '1:2:3 4 5 6', "Split into a specified number of fields, defined by a literal");
58 @ary = split(' ','1 2 3 4 5 6', 3);
59 $cnt = split(' ','1 2 3 4 5 6', 3);
60 is($cnt, scalar(@ary), "Check element count from previous test");
61
62 # Can we do it as a variable?
63 $x = 4;
64 $_ = join(':', split(' ','1 2 3 4 5 6', $x));
65 is($_, '1:2:3:4 5 6', "Split into a specified number of fields, defined by a scalar variable");
66 @ary = split(' ','1 2 3 4 5 6', $x);
67 $cnt = split(' ','1 2 3 4 5 6', $x);
68 is($cnt, scalar(@ary), "Check element count from previous test");
69
70 # Does the 999 suppress null field chopping?
71 $_ = join(':', split(/:/,'1:2:3:4:5:6:::', 999));
72 is($_ , '1:2:3:4:5:6:::');
73 @ary = split(/:/,'1:2:3:4:5:6:::', 999);
74 $cnt = split(/:/,'1:2:3:4:5:6:::', 999);
75 is($cnt, scalar(@ary));
76
77 # Splitting without pattern
78 $_ = "1 2 3 4";
79 $_ = join(':', split);
80 is($_ , '1:2:3:4', "Split and join without specifying a split pattern");
81
82 # Does assignment to a list imply split to one more field than that?
83 $foo = runperl( switches => ['-Dt'], stderr => 1, prog => '($a,$b)=split;' );
84 ok($foo =~ /DEBUGGING/ || $foo =~ /const\n?\Q(IV(3))\E/);
85
86 # Can we say how many fields to split to when assigning to a list?
87 ($a,$b) = split(' ','1 2 3 4 5 6', 2);
88 $_ = join(':',$a,$b);
89 is($_, '1:2 3 4 5 6', "Storing split output into list of scalars");
90
91 # do subpatterns generate additional fields (without trailing nulls)?
92 $_ = join '|', split(/,|(-)/, "1-10,20,,,");
93 is($_, "1|-|10||20");
94 @ary = split(/,|(-)/, "1-10,20,,,");
95 $cnt = split(/,|(-)/, "1-10,20,,,");
96 is($cnt, scalar(@ary));
97
98 # do subpatterns generate additional fields (with a limit)?
99 $_ = join '|', split(/,|(-)/, "1-10,20,,,", 10);
100 is($_, "1|-|10||20||||||");
101 @ary = split(/,|(-)/, "1-10,20,,,", 10);
102 $cnt = split(/,|(-)/, "1-10,20,,,", 10);
103 is($cnt, scalar(@ary));
104
105 # is the 'two undefs' bug fixed?
106 (undef, $a, undef, $b) = qw(1 2 3 4);
107 is("$a|$b", "2|4");
108
109 # .. even for locals?
110 {
111   local(undef, $a, undef, $b) = qw(1 2 3 4);
112   is("$a|$b", "2|4");
113 }
114
115 # check splitting of null string
116 $_ = join('|', split(/x/,   '',-1), 'Z');
117 is($_, "Z");
118 @ary = split(/x/,   '',-1);
119 $cnt = split(/x/,   '',-1);
120 is($cnt, scalar(@ary));
121
122 $_ = join('|', split(/x/,   '', 1), 'Z');
123 is($_, "Z");
124 @ary = split(/x/,   '', 1);
125 $cnt = split(/x/,   '', 1);
126 is($cnt, scalar(@ary));
127
128 $_ = join('|', split(/(p+)/,'',-1), 'Z');
129 is($_, "Z");
130 @ary = split(/(p+)/,'',-1);
131 $cnt = split(/(p+)/,'',-1);
132 is($cnt, scalar(@ary));
133
134 $_ = join('|', split(/.?/,  '',-1), 'Z');
135 is($_, "Z");
136 @ary = split(/.?/,  '',-1);
137 $cnt = split(/.?/,  '',-1);
138 is($cnt, scalar(@ary));
139
140
141 # Are /^/m patterns scanned?
142 $_ = join '|', split(/^a/m, "a b a\na d a", 20);
143 is($_, "| b a\n| d a");
144 @ary = split(/^a/m, "a b a\na d a", 20);
145 $cnt = split(/^a/m, "a b a\na d a", 20);
146 is($cnt, scalar(@ary));
147
148 # Are /$/m patterns scanned?
149 $_ = join '|', split(/a$/m, "a b a\na d a", 20);
150 is($_, "a b |\na d |");
151 @ary = split(/a$/m, "a b a\na d a", 20);
152 $cnt = split(/a$/m, "a b a\na d a", 20);
153 is($cnt, scalar(@ary));
154
155 # Are /^/m patterns scanned?
156 $_ = join '|', split(/^aa/m, "aa b aa\naa d aa", 20);
157 is($_, "| b aa\n| d aa");
158 @ary = split(/^aa/m, "aa b aa\naa d aa", 20);
159 $cnt = split(/^aa/m, "aa b aa\naa d aa", 20);
160 is($cnt, scalar(@ary));
161
162 # Are /$/m patterns scanned?
163 $_ = join '|', split(/aa$/m, "aa b aa\naa d aa", 20);
164 is($_, "aa b |\naa d |");
165 @ary = split(/aa$/m, "aa b aa\naa d aa", 20);
166 $cnt = split(/aa$/m, "aa b aa\naa d aa", 20);
167 is($cnt, scalar(@ary));
168
169 # Greedyness:
170 $_ = "a : b :c: d";
171 @ary = split(/\s*:\s*/);
172 $cnt = split(/\s*:\s*/);
173 is(($res = join(".",@ary)), "a.b.c.d", $res);
174 is($cnt, scalar(@ary));
175
176 # use of match result as pattern (!)
177 is('p:q:r:s', join ':', split('abc' =~ /b/, 'p1q1r1s'));
178 @ary = split('abc' =~ /b/, 'p1q1r1s');
179 $cnt = split('abc' =~ /b/, 'p1q1r1s');
180 is($cnt, scalar(@ary));
181
182 # /^/ treated as /^/m
183 $_ = join ':', split /^/, "ab\ncd\nef\n";
184 is($_, "ab\n:cd\n:ef\n");
185
186 # see if @a = @b = split(...) optimization works
187 @list1 = @list2 = split ('p',"a p b c p");
188 ok(@list1 == @list2 &&
189    "@list1" eq "@list2" &&
190    @list1 == 2 &&
191    "@list1" eq "a   b c ");
192
193 # zero-width assertion
194 $_ = join ':', split /(?=\w)/, "rm b";
195 is($_, "r:m :b");
196 @ary = split /(?=\w)/, "rm b";
197 $cnt = split /(?=\w)/, "rm b";
198 is($cnt, scalar(@ary));
199
200 # unicode splittage
201
202 @ary = map {ord} split //, v1.20.300.4000.50000.4000.300.20.1;
203 $cnt =           split //, v1.20.300.4000.50000.4000.300.20.1;
204 is("@ary", "1 20 300 4000 50000 4000 300 20 1");
205 is($cnt, scalar(@ary));
206
207 @ary = split(/\x{FE}/, "\x{FF}\x{FE}\x{FD}"); # bug id 20010105.016
208 $cnt = split(/\x{FE}/, "\x{FF}\x{FE}\x{FD}"); # bug id 20010105.016
209 ok(@ary == 2 &&
210    $ary[0] eq "\xFF"   && $ary[1] eq "\xFD" &&
211    $ary[0] eq "\x{FF}" && $ary[1] eq "\x{FD}");
212 is($cnt, scalar(@ary));
213
214 @ary = split(/(\x{FE}\xFE)/, "\xFF\x{FF}\xFE\x{FE}\xFD\x{FD}"); # variant of 31
215 $cnt = split(/(\x{FE}\xFE)/, "\xFF\x{FF}\xFE\x{FE}\xFD\x{FD}"); # variant of 31
216 ok(@ary == 3 &&
217    $ary[0] eq "\xFF\xFF"     &&
218    $ary[0] eq "\x{FF}\xFF"   &&
219    $ary[0] eq "\x{FF}\x{FF}" &&
220    $ary[1] eq "\xFE\xFE"     &&
221    $ary[1] eq "\x{FE}\xFE"   &&
222    $ary[1] eq "\x{FE}\x{FE}" &&
223    $ary[2] eq "\xFD\xFD"     &&
224    $ary[2] eq "\x{FD}\xFD"   &&
225    $ary[2] eq "\x{FD}\x{FD}");
226 is($cnt, scalar(@ary));
227
228 {
229     my @a = map ord, split(//, join("", map chr, (1234, 123, 2345)));
230     my $c =          split(//, join("", map chr, (1234, 123, 2345)));
231     is("@a", "1234 123 2345");
232     is($c, scalar(@a));
233 }
234
235 {
236     my $x = 'A';
237     my @a = map ord, split(/$x/, join("", map chr, (1234, ord($x), 2345)));
238     my $c =          split(/$x/, join("", map chr, (1234, ord($x), 2345)));
239     is("@a", "1234 2345");
240     is($c, scalar(@a));
241 }
242
243 {
244     # bug id 20000427.003 
245
246     use warnings;
247     use strict;
248
249     my $sushi = "\x{b36c}\x{5a8c}\x{ff5b}\x{5079}\x{505b}";
250
251     my @charlist = split //, $sushi;
252     my $charnum  = split //, $sushi;
253     is($charnum, scalar(@charlist));
254     my $r = '';
255     foreach my $ch (@charlist) {
256         $r = $r . " " . sprintf "U+%04X", ord($ch);
257     }
258
259     is($r, " U+B36C U+5A8C U+FF5B U+5079 U+505B");
260 }
261
262 {
263     my $s = "\x20\x40\x{80}\x{100}\x{80}\x40\x20";
264
265   SKIP: {
266     if (ord('A') == 193) {
267         skip("EBCDIC", 1);
268     } else {
269         # bug id 20000426.003
270
271         my ($a, $b, $c) = split(/\x40/, $s);
272         ok($a eq "\x20" && $b eq "\x{80}\x{100}\x{80}" && $c eq $a);
273     }
274   }
275
276     my ($a, $b) = split(/\x{100}/, $s);
277     ok($a eq "\x20\x40\x{80}" && $b eq "\x{80}\x40\x20");
278
279     my ($a, $b) = split(/\x{80}\x{100}\x{80}/, $s);
280     ok($a eq "\x20\x40" && $b eq "\x40\x20");
281
282   SKIP: {
283     if (ord('A') == 193) {
284         skip("EBCDIC", 1);
285     }  else {
286         my ($a, $b) = split(/\x40\x{80}/, $s);
287         ok($a eq "\x20" && $b eq "\x{100}\x{80}\x40\x20");
288     }
289   }
290
291     my ($a, $b, $c) = split(/[\x40\x{80}]+/, $s);
292     ok($a eq "\x20" && $b eq "\x{100}" && $c eq "\x20");
293 }
294
295 {
296     # 20001205.014
297
298     my $a = "ABC\x{263A}";
299
300     my @b = split( //, $a );
301     my $c = split( //, $a );
302     is($c, scalar(@b));
303
304     is(scalar @b, 4);
305
306     ok(length($b[3]) == 1 && $b[3] eq "\x{263A}");
307
308     $a =~ s/^A/Z/;
309     ok(length($a) == 4 && $a eq "ZBC\x{263A}");
310 }
311
312 {
313     my @a = split(/\xFE/, "\xFF\xFE\xFD");
314     my $b = split(/\xFE/, "\xFF\xFE\xFD");
315
316     ok(@a == 2 && $a[0] eq "\xFF" && $a[1] eq "\xFD");
317     is($b, scalar(@a));
318 }
319
320 {
321     # check that PMf_WHITE is cleared after \s+ is used
322     # reported in <20010627113312.RWGY6087.viemta06@localhost>
323     my $r;
324     foreach my $pat ( qr/\s+/, qr/ll/ ) {
325         $r = join ':' => split($pat, "hello cruel world");
326     }
327     is($r, "he:o cruel world");
328 }
329
330
331 {
332     # split /(A)|B/, "1B2" should return (1, undef, 2)
333     my @x = split /(A)|B/, "1B2";
334     my $y = split /(A)|B/, "1B2";
335     is($y, scalar(@x));
336     ok($x[0] eq '1' and (not defined $x[1]) and $x[2] eq '2');
337 }
338
339 {
340     # [perl #17064]
341     my $warn;
342     local $SIG{__WARN__} = sub { $warn = join '', @_; chomp $warn };
343     my $char = "\x{10f1ff}";
344     my @a = split /\r?\n/, "$char\n";
345     my $b = split /\r?\n/, "$char\n";
346     is($b, scalar(@a));
347     ok(@a == 1 && $a[0] eq $char && !defined($warn));
348 }
349
350 {
351     # [perl #18195]
352     for my $u (0, 1) {
353         for my $a (0, 1) {
354             $_ = 'readin,database,readout';
355             utf8::upgrade $_ if $u;
356             /(.+)/;
357             my @d = split /[,]/,$1;
358             my $e = split /[,]/,$1;
359             is($e, scalar(@d));
360             is(join (':',@d), 'readin:database:readout', "[perl #18195]");
361         }
362     }
363 }
364
365 {
366     $p="a,b";
367     utf8::upgrade $p;
368     eval { @a=split(/[, ]+/,$p) };
369     eval { $b=split(/[, ]+/,$p) };
370     is($b, scalar(@a));
371     is ("$@-@a-", '-a b-', '#20912 - split() to array with /[]+/ and utf8');
372 }
373
374 {
375     is (\@a, \@{"a"}, '@a must be global for following test');
376     $p="";
377     $n = @a = split /,/,$p;
378     is ($n, 0, '#21765 - pmreplroot hack used to return undef for 0 iters');
379 }
380
381 {
382     # [perl #28938]
383     # assigning off the end of the array after a split could leave garbage
384     # in the inner elements
385
386     my $x;
387     @a = split /,/, ',,,,,';
388     $a[3]=1;
389     $x = \$a[2];
390     is (ref $x, 'SCALAR', '#28938 - garbage after extend');
391 }
392
393 {
394     my $src = "ABC \0 FOO \0  XYZ";
395     my @s = split(" \0 ", $src);
396     my @r = split(/ \0 /, $src);
397     my $cs = split(" \0 ", $src);
398     my $cr = split(/ \0 /, $src);
399     is(scalar(@s), 3);
400     is($cs, 3);
401     is($cr, 3);
402     is($s[0], "ABC");
403     is($s[1], "FOO");
404     is($s[2]," XYZ");
405     is(join(':',@s), join(':',@r));
406 }
407
408 {
409     use constant BANG => {};
410     () = split m/,/, "", BANG;
411     ok(1);
412 }
413
414 {
415     # Bug #69875
416     # 'Hybrid' scalar-and-array context
417     scalar(our @PATH = split /::/, "Font::GlyphNames");
418            # 'my' doesn't trigger the bug
419     is "@PATH", "Font GlyphNames", "hybrid scalar-and-array context";
420 }
421
422 {
423     my @results;
424     my $expr= "foo  bar";
425     my $cond;
426
427     @results= split(0||" ", $expr);
428     is @results, 2, 'split(0||" ") is treated like split(" ")'; #'
429
430     $cond= 0;
431     @results= split $cond ? " " : qr/ /, $expr;
432     is @results, 3, 'split($cond ? " " : qr/ /, $expr) works as expected (like qr/ /)';
433     $cond= 1;
434     @results= split $cond ? " " : qr/ /, $expr;
435     is @results, 2, 'split($cond ? " " : qr/ /, $expr) works as expected (like " ")';
436
437     $expr = ' a b c ';
438     @results = split /\s/, $expr;
439     is @results, 4,
440         "split on regex of single space metacharacter: captured 4 elements";
441     is $results[0], '',
442         "split on regex of single space metacharacter: first element is empty string";
443
444     @results = split / /, $expr;
445     is @results, 4,
446         "split on regex of single whitespace: captured 4 elements";
447     is $results[0], '',
448         "split on regex of single whitespace: first element is empty string";
449
450     @results = split " ", $expr;
451     is @results, 3,
452         "split on string of single whitespace: captured 3 elements";
453     is $results[0], 'a',
454         "split on string of single whitespace: first element is non-empty";
455
456     $expr = " a \tb c ";
457     @results = split " ", $expr;
458     is @results, 3,
459         "split on string of single whitespace: captured 3 elements";
460     is $results[0], 'a',
461         "split on string of single whitespace: first element is non-empty; multiple contiguous space characters";
462
463     my @seq;
464     for my $cond (0,1,0,1,0) {
465         $expr = "  foo  ";
466         @results = split $cond ? qr/ / : " ", $expr;
467         push @seq, scalar(@results) . ":" . $results[-1];
468     }
469     is join(" ", @seq), "1:foo 3:foo 1:foo 3:foo 1:foo",
470         qq{split(\$cond ? qr/ / : " ", "$exp") behaves as expected over repeated similar patterns};
471 }
472
473 {
474     # 'RT #116086: split "\x20" does not work as documented';
475     my @results;
476     my $expr;
477     $expr = ' a b c ';
478     @results = split "\x20", $expr;
479     is @results, 3,
480         "RT #116086: split on string of single hex-20: captured 3 elements";
481     is $results[0], 'a',
482         "RT #116086: split on string of single hex-20: first element is non-empty";
483
484     $expr = " a \tb c ";
485     @results = split "\x20", $expr;
486     is @results, 3,
487         "RT #116086: split on string of single hex-20: captured 3 elements";
488     is $results[0], 'a',
489         "RT #116086: split on string of single hex-20: first element is non-empty; multiple contiguous space characters";
490 }
491
492 # Nasty interaction between split and use constant
493 use constant nought => 0;
494 ($a,$b,$c) = split //, $foo, nought;
495 is nought, 0, 'split does not mangle 0 constants';