lib/ExtUtils.t

   1 #!./perl -w
   2
   3 print "1..27\n";
   4
   5 BEGIN {
   6     chdir 't' if -d 't';
   7     @INC = '../lib';
   8 }
   9
  10 # use warnings;
  11 use strict;
  12 use ExtUtils::MakeMaker;
  13 use ExtUtils::Constant qw (constant_types C_constant XS_constant autoload);
  14 use Config;
  15 use File::Spec::Functions qw(catfile rel2abs);
  16 # Because were are going to be changing directory before running Makefile.PL
  17 my $perl;
  18 $perl = rel2abs( $^X ) unless $] < 5.006; # Hack. Until 5.00503 has rel2abs
  19 # ExtUtils::Constant::C_constant uses $^X inside a comment, and we want to
  20 # compare output to ensure that it is the same. We were probably run as ./perl
  21 # whereas we will run the child with the full path in $perl. So make $^X for
  22 # us the same as our child will see.
  23 $^X = $perl;
  24
  25 print "# perl=$perl\n";
  26 my $runperl = "$perl -x \"-I../../lib\"";
  27
  28 $| = 1;
  29
  30 my $dir = "ext-$$";
  31 my @files;
  32
  33 print "# $dir being created...\n";
  34 mkdir $dir, 0777 or die "mkdir: $!\n";
  35
  36 my $output = "output";
  37
  38 END {
  39     use File::Path;
  40     print "# $dir being removed...\n";
  41     rmtree($dir);
  42 }
  43
  44 my $package = "ExtTest";
  45
  46 # Test the code that generates 1 and 2 letter name comparisons.
  47 my %compass = (
  48 N => 0, 'NE' => 45, E => 90, SE => 135, S => 180, SW => 225, W => 270, NW => 315
  49 );
  50
  51 my $parent_rfc1149 =
  52   'A Standard for the Transmission of IP Datagrams on Avian Carriers';
  53
  54 my @names = ("FIVE", {name=>"OK6", type=>"PV",},
  55              {name=>"OK7", type=>"PVN",
  56               value=>['"not ok 7\\n\\0ok 7\\n"', 15]},
  57              {name => "FARTHING", type=>"NV"},
  58              {name => "NOT_ZERO", type=>"UV", value=>"~(UV)0"},
  59              {name => "OPEN", type=>"PV", value=>'"/*"', macro=>1},
  60              {name => "CLOSE", type=>"PV", value=>'"*/"',
  61               macro=>["#if 1\n", "#endif\n"]},
  62              {name => "ANSWER", default=>["UV", 42]}, "NOTDEF",
  63              {name => "Yes", type=>"YES"},
  64              {name => "No", type=>"NO"},
  65              {name => "Undef", type=>"UNDEF"},
  66 # OK. It wasn't really designed to allow the creation of dual valued constants.
  67 # It was more for INADDR_ANY INADDR_BROADCAST INADDR_LOOPBACK INADDR_NONE
  68              {name=>"RFC1149", type=>"SV", value=>"sv_2mortal(temp_sv)",
  69               pre=>"SV *temp_sv = newSVpv(RFC1149, 0); "
  70                    . "(void) SvUPGRADE(temp_sv,SVt_PVIV); SvIOK_on(temp_sv); "
  71                    . "SvIVX(temp_sv) = 1149;"},
  72 );
  73
  74 push @names, $_ foreach keys %compass;
  75
  76 my @names_only = map {(ref $_) ? $_->{name} : $_} @names;
  77
  78 my $types = {};
  79 my $constant_types = constant_types(); # macro defs
  80 my $C_constant = join "\n",
  81   C_constant ($package, undef, "IV", $types, undef, undef, @names);
  82 my $XS_constant = XS_constant ($package, $types); # XS for ExtTest::constant
  83
  84 ################ Header
  85 my $header = catfile($dir, "test.h");
  86 push @files, "test.h";
  87 open FH, ">$header" or die "open >$header: $!\n";
  88 print FH <<"EOT";
  89 #define FIVE 5
  90 #define OK6 "ok 6\\n"
  91 #define OK7 1
  92 #define FARTHING 0.25
  93 #define NOT_ZERO 1
  94 #define Yes 0
  95 #define No 1
  96 #define Undef 1
  97 #define RFC1149 "$parent_rfc1149"
  98 #undef NOTDEF
  99
 100 EOT
 101
 102 while (my ($point, $bearing) = each %compass) {
 103   print FH "#define $point $bearing\n"
 104 }
 105 close FH or die "close $header: $!\n";
 106
 107 ################ XS
 108 my $xs = catfile($dir, "$package.xs");
 109 push @files, "$package.xs";
 110 open FH, ">$xs" or die "open >$xs: $!\n";
 111
 112 print FH <<'EOT';
 113 #include "EXTERN.h"
 114 #include "perl.h"
 115 #include "XSUB.h"
 116 EOT
 117
 118 print FH "#include \"test.h\"\n\n";
 119 print FH $constant_types;
 120 print FH $C_constant, "\n";
 121 print FH "MODULE = $package             PACKAGE = $package\n";
 122 print FH "PROTOTYPES: ENABLE\n";
 123 print FH $XS_constant;
 124 close FH or die "close $xs: $!\n";
 125
 126 ################ PM
 127 my $pm = catfile($dir, "$package.pm");
 128 push @files, "$package.pm";
 129 open FH, ">$pm" or die "open >$pm: $!\n";
 130 print FH "package $package;\n";
 131 print FH "use $];\n";
 132
 133 print FH <<'EOT';
 134
 135 use strict;
 136 EOT
 137 printf FH "use warnings;\n" unless $] < 5.006;
 138 print FH <<'EOT';
 139 use Carp;
 140
 141 require Exporter;
 142 require DynaLoader;
 143 use vars qw ($VERSION @ISA @EXPORT_OK $AUTOLOAD);
 144
 145 $VERSION = '0.01';
 146 @ISA = qw(Exporter DynaLoader);
 147 @EXPORT_OK = qw(
 148 EOT
 149
 150 print FH "\t$_\n" foreach (@names_only);
 151 print FH ");\n";
 152 print FH autoload ($package, $]);
 153 print FH "bootstrap $package \$VERSION;\n1;\n__END__\n";
 154 close FH or die "close $pm: $!\n";
 155
 156 ################ test.pl
 157 my $testpl = catfile($dir, "test.pl");
 158 push @files, "test.pl";
 159 open FH, ">$testpl" or die "open >$testpl: $!\n";
 160
 161 print FH "use strict;\n";
 162 print FH "use $package qw(@names_only);\n";
 163 print FH <<"EOT";
 164
 165 print "1..1\n";
 166 if (open OUTPUT, ">$output") {
 167   print "ok 1\n";
 168   select OUTPUT;
 169 } else {
 170   print "not ok 1 # Failed to open '$output': $!\n";
 171   exit 1;
 172 }
 173 EOT
 174
 175 print FH << 'EOT';
 176
 177 # What follows goes to the temporary file.
 178 # IV
 179 my $five = FIVE;
 180 if ($five == 5) {
 181   print "ok 5\n";
 182 } else {
 183   print "not ok 5 # $five\n";
 184 }
 185
 186 # PV
 187 print OK6;
 188
 189 # PVN containing embedded \0s
 190 $_ = OK7;
 191 s/.*\0//s;
 192 print;
 193
 194 # NV
 195 my $farthing = FARTHING;
 196 if ($farthing == 0.25) {
 197   print "ok 8\n";
 198 } else {
 199   print "not ok 8 # $farthing\n";
 200 }
 201
 202 # UV
 203 my $not_zero = NOT_ZERO;
 204 if ($not_zero > 0 && $not_zero == ~0) {
 205   print "ok 9\n";
 206 } else {
 207   print "not ok 9 # \$not_zero=$not_zero ~0=" . (~0) . "\n";
 208 }
 209
 210 # Value includes a "*/" in an attempt to bust out of a C comment.
 211 # Also tests custom cpp #if clauses
 212 my $close = CLOSE;
 213 if ($close eq '*/') {
 214   print "ok 10\n";
 215 } else {
 216   print "not ok 10 # \$close='$close'\n";
 217 }
 218
 219 # Default values if macro not defined.
 220 my $answer = ANSWER;
 221 if ($answer == 42) {
 222   print "ok 11\n";
 223 } else {
 224   print "not ok 11 # What do you get if you multiply six by nine? '$answer'\n";
 225 }
 226
 227 # not defined macro
 228 my $notdef = eval { NOTDEF; };
 229 if (defined $notdef) {
 230   print "not ok 12 # \$notdef='$notdef'\n";
 231 } elsif ($@ !~ /Your vendor has not defined ExtTest macro NOTDEF/) {
 232   print "not ok 12 # \$@='$@'\n";
 233 } else {
 234   print "ok 12\n";
 235 }
 236
 237 # not a macro
 238 my $notthere = eval { &ExtTest::NOTTHERE; };
 239 if (defined $notthere) {
 240   print "not ok 13 # \$notthere='$notthere'\n";
 241 } elsif ($@ !~ /NOTTHERE is not a valid ExtTest macro/) {
 242   chomp $@;
 243   print "not ok 13 # \$@='$@'\n";
 244 } else {
 245   print "ok 13\n";
 246 }
 247
 248 # Truth
 249 my $yes = Yes;
 250 if ($yes) {
 251   print "ok 14\n";
 252 } else {
 253   print "not ok 14 # $yes='\$yes'\n";
 254 }
 255
 256 # Falsehood
 257 my $no = No;
 258 if (defined $no and !$no) {
 259   print "ok 15\n";
 260 } else {
 261   print "not ok 15 # \$no=" . defined ($no) ? "'$no'\n" : "undef\n";
 262 }
 263
 264 # Undef
 265 my $undef = Undef;
 266 unless (defined $undef) {
 267   print "ok 16\n";
 268 } else {
 269   print "not ok 16 # \$undef='$undef'\n";
 270 }
 271
 272
 273 # invalid macro (chosen to look like a mix up between No and SW)
 274 $notdef = eval { &ExtTest::So };
 275 if (defined $notdef) {
 276   print "not ok 17 # \$notdef='$notdef'\n";
 277 } elsif ($@ !~ /^So is not a valid ExtTest macro/) {
 278   print "not ok 17 # \$@='$@'\n";
 279 } else {
 280   print "ok 17\n";
 281 }
 282
 283 # invalid defined macro
 284 $notdef = eval { &ExtTest::EW };
 285 if (defined $notdef) {
 286   print "not ok 18 # \$notdef='$notdef'\n";
 287 } elsif ($@ !~ /^EW is not a valid ExtTest macro/) {
 288   print "not ok 18 # \$@='$@'\n";
 289 } else {
 290   print "ok 18\n";
 291 }
 292
 293 my %compass = (
 294 EOT
 295
 296 while (my ($point, $bearing) = each %compass) {
 297   print FH "'$point' => $bearing, "
 298 }
 299
 300 print FH <<'EOT';
 301
 302 );
 303
 304 my $fail;
 305 while (my ($point, $bearing) = each %compass) {
 306   my $val = eval $point;
 307   if ($@) {
 308     print "# $point: \$@='$@'\n";
 309     $fail = 1;
 310   } elsif (!defined $bearing) {
 311     print "# $point: \$val=undef\n";
 312     $fail = 1;
 313   } elsif ($val != $bearing) {
 314     print "# $point: \$val=$val, not $bearing\n";
 315     $fail = 1;
 316   }
 317 }
 318 if ($fail) {
 319   print "not ok 19\n";
 320 } else {
 321   print "ok 19\n";
 322 }
 323
 324 EOT
 325
 326 print FH <<"EOT";
 327 my \$rfc1149 = RFC1149;
 328 if (\$rfc1149 ne "$parent_rfc1149") {
 329   print "not ok 20 # '\$rfc1149' ne '$parent_rfc1149'\n";
 330 } else {
 331   print "ok 20\n";
 332 }
 333
 334 if (\$rfc1149 != 1149) {
 335   printf "not ok 21 # %d != 1149\n", \$rfc1149;
 336 } else {
 337   print "ok 21\n";
 338 }
 339
 340 EOT
 341
 342 print FH <<'EOT';
 343 # test macro=>1
 344 my $open = OPEN;
 345 if ($open eq '/*') {
 346   print "ok 22\n";
 347 } else {
 348   print "not ok 22 # \$open='$open'\n";
 349 }
 350 EOT
 351 close FH or die "close $testpl: $!\n";
 352
 353 ################ Makefile.PL
 354 # We really need a Makefile.PL because make test for a no dynamic linking perl
 355 # will run Makefile.PL again as part of the "make perl" target.
 356 my $makefilePL = catfile($dir, "Makefile.PL");
 357 push @files, "Makefile.PL";
 358 open FH, ">$makefilePL" or die "open >$makefilePL: $!\n";
 359 print FH <<"EOT";
 360 #!$perl -w
 361 use ExtUtils::MakeMaker;
 362 WriteMakefile(
 363               'NAME'            => "$package",
 364               'VERSION_FROM'    => "$package.pm", # finds \$VERSION
 365               (\$] >= 5.005 ?
 366                (#ABSTRACT_FROM => "$package.pm", # XXX add this
 367                 AUTHOR     => "$0") : ())
 368              );
 369 EOT
 370
 371 close FH or die "close $makefilePL: $!\n";
 372
 373 chdir $dir or die $!; push @INC,  '../../lib';
 374 END {chdir ".." or warn $!};
 375
 376 my @perlout = `$runperl Makefile.PL PERL_CORE=1`;
 377 if ($?) {
 378   print "not ok 1 # $runperl Makefile.PL failed: $?\n";
 379   print "# $_" foreach @perlout;
 380   exit($?);
 381 } else {
 382   print "ok 1\n";
 383 }
 384
 385
 386 my $makefile = ($^O eq 'VMS' ? 'descrip' : 'Makefile');
 387 my $makefile_ext = ($^O eq 'VMS' ? '.mms' : '');
 388 if (-f "$makefile$makefile_ext") {
 389   print "ok 2\n";
 390 } else {
 391   print "not ok 2\n";
 392 }
 393 my $makefile_rename = ($^O eq 'VMS' ? '.mms' : '.old');
 394 push @files, "$makefile$makefile_rename"; # Renamed by make clean
 395
 396 my $make = $Config{make};
 397
 398 $make = $ENV{MAKE} if exists $ENV{MAKE};
 399
 400 if ($^O eq 'MSWin32' && $make eq 'nmake') { $make .= " -nologo"; }
 401
 402 my @makeout;
 403
 404 print "# make = '$make'\n";
 405 @makeout = `$make`;
 406 if ($?) {
 407   print "not ok 3 # $make failed: $?\n";
 408   print "# $_" foreach @makeout;
 409   exit($?);
 410 } else {
 411   print "ok 3\n";
 412 }
 413
 414 if ($Config{usedl}) {
 415   print "ok 4\n";
 416 } else {
 417   my $makeperl = "$make perl";
 418   print "# make = '$makeperl'\n";
 419   @makeout = `$makeperl`;
 420   if ($?) {
 421     print "not ok 4 # $makeperl failed: $?\n";
 422   print "# $_" foreach @makeout;
 423     exit($?);
 424   } else {
 425     print "ok 4\n";
 426   }
 427 }
 428
 429 push @files, $output;
 430
 431 my $maketest = "$make test";
 432 print "# make = '$maketest'\n";
 433
 434 @makeout = `$maketest`;
 435
 436 if (open OUTPUT, "<$output") {
 437   print while <OUTPUT>;
 438   close OUTPUT or print "# Close $output failed: $!\n";
 439 } else {
 440   # Harness will report missing test results at this point.
 441   print "# Open <$output failed: $!\n";
 442 }
 443
 444 my $test = 23;
 445
 446 if ($?) {
 447   print "not ok $test # $maketest failed: $?\n";
 448   print "# $_" foreach @makeout;
 449 } else {
 450   print "ok $test\n";
 451 }
 452 $test++;
 453
 454 my $regen = `$runperl $package.xs`;
 455 if ($?) {
 456   print "not ok $test # $runperl $package.xs failed: $?\n";
 457 } else {
 458   print "ok $test\n";
 459 }
 460 $test++;
 461
 462 my $expect = $constant_types . $C_constant .
 463   "\n#### XS Section:\n" . $XS_constant;
 464
 465 if ($expect eq $regen) {
 466   print "ok $test\n";
 467 } else {
 468   print "not ok $test\n";
 469   # open FOO, ">expect"; print FOO $expect;
 470   # open FOO, ">regen"; print FOO $regen; close FOO;
 471 }
 472 $test++;
 473
 474 my $makeclean = "$make clean";
 475 print "# make = '$makeclean'\n";
 476 @makeout = `$makeclean`;
 477 if ($?) {
 478   print "not ok $test # $make failed: $?\n";
 479   print "# $_" foreach @makeout;
 480 } else {
 481   print "ok $test\n";
 482 }
 483 $test++;
 484
 485 foreach (@files) {
 486   unlink $_ or warn "unlink $_: $!";
 487 }
 488
 489 my $fail;
 490 opendir DIR, "." or die "opendir '.': $!";
 491 while (defined (my $entry = readdir DIR)) {
 492   next if $entry =~ /^\.\.?$/;
 493   print "# Extra file '$entry'\n";
 494   $fail = 1;
 495 }
 496 closedir DIR or warn "closedir '.': $!";
 497 if ($fail) {
 498   print "not ok $test\n";
 499 } else {
 500   print "ok $test\n";
 501 }