ext/B/t/b.t

   1 #!./perl
   2
   3 BEGIN {
   4     unshift @INC, 't';
   5     require Config;
   6     if (($Config::Config{'extensions'} !~ /\bB\b/) ){
   7         print "1..0 # Skip -- Perl configured without B module\n";
   8         exit 0;
   9     }
  10 }
  11
  12 $|  = 1;
  13 use warnings;
  14 use strict;
  15 BEGIN  {
  16     eval { require threads; threads->import; }
  17 }
  18 use Test::More;
  19
  20 BEGIN { use_ok( 'B' ); }
  21
  22
  23 package Testing::Symtable;
  24 our ($This, @That, %wibble, $moo, %moo);
  25 my $not_a_sym = 'moo';
  26
  27 sub moo { 42 }
  28 sub car { 23 }
  29
  30
  31 package Testing::Symtable::Foo;
  32 sub yarrow { "Hock" }
  33
  34 package Testing::Symtable::Bar;
  35 sub hock { "yarrow" }
  36
  37 package main;
  38 our %Subs;
  39 local %Subs = ();
  40 B::walksymtable(\%Testing::Symtable::, 'find_syms', sub { $_[0] =~ /Foo/ },
  41                 'Testing::Symtable::');
  42
  43 sub B::GV::find_syms {
  44     my($symbol) = @_;
  45
  46     $main::Subs{$symbol->STASH->NAME . '::' . $symbol->NAME}++;
  47 }
  48
  49 my @syms = map { 'Testing::Symtable::'.$_ } qw(This That wibble moo car);
  50 push @syms, "Testing::Symtable::Foo::yarrow";
  51
  52 # Make sure we hit all the expected symbols.
  53 ok( join('', sort @syms) eq join('', sort keys %Subs), 'all symbols found' );
  54
  55 # Make sure we only hit them each once.
  56 ok( (!grep $_ != 1, values %Subs), '...and found once' );
  57
  58
  59 # Make sure method caches are not present when walking the sym tab
  60 @Testing::Method::Caches::Foo::ISA='Testing::Method::Caches::Bar';
  61 sub Testing::Method::Caches::Bar::foo{}
  62 Testing::Method::Caches::Foo->foo; # caches the sub in the *foo glob
  63
  64 my $have_cv;
  65 sub B::GV::method_cache_test { ${shift->CV} and ++$have_cv }
  66
  67 B::walksymtable(\%Testing::Method::Caches::, 'method_cache_test',
  68                  sub { 1 }, 'Testing::Method::Caches::');
  69 # $have_cv should only have been incremented for ::Bar::foo
  70 is $have_cv, 1, 'walksymtable clears cached methods';
  71
  72
  73 # Tests for MAGIC / MOREMAGIC
  74 ok( B::svref_2object(\$.)->MAGIC->TYPE eq "\0", '$. has \0 magic' );
  75 {
  76     my $e = '';
  77     local $SIG{__DIE__} = sub { $e = $_[0] };
  78     # Used to dump core, bug #16828
  79     eval { B::svref_2object(\$.)->MAGIC->MOREMAGIC->TYPE; };
  80     like( $e, qr/Can't call method "TYPE" on an undefined value/,
  81         '$. has no more magic' );
  82 }
  83
  84 {
  85     my $pie = 'Good';
  86     # This needs to be a package variable, as vars in the pad have some flags.
  87     my $r = B::svref_2object(\$::data2);
  88     is($r->FLAGS(), 0, "uninitialised package variable has flags of 0");
  89     is($r->SvTYPE(), 0, "uninitialised package variable has type 0");
  90     is($r->POK(), 0, "POK false");
  91     is($r->ROK(), 0, "ROK false");
  92     is($r->MAGICAL(), 0, "MAGICAL false");
  93     $::data2 = $pie;
  94     isnt($r->FLAGS(), 0, "initialised package variable has nonzero flags");
  95     isnt($r->SvTYPE(), 0, "initialised package variable has nonzero type");
  96     isnt($r->POK(), 0, "POK true");
  97     is($r->ROK(), 0, "ROK false");
  98     is($r->MAGICAL(), 0, "MAGICAL false");
  99
 100     $::data2 = substr $pie, 0, 1;
 101     isnt($r->FLAGS(), 0, "initialised package variable has nonzero flags");
 102     isnt($r->SvTYPE(), 0, "initialised package variable has nonzero type");
 103     isnt($r->POK(), 0, "POK true");
 104     is($r->ROK(), 0, "ROK false");
 105     is($r->MAGICAL(), 0, "MAGICAL true");
 106
 107     $::data2 = \$pie;
 108     isnt($r->FLAGS(), 0, "initialised package variable has nonzero flags");
 109     isnt($r->SvTYPE(), 0, "initialised package variable has nonzero type");
 110     is($r->POK(), 0, "POK false");
 111     isnt($r->ROK(), 0, "ROK true");
 112     is($r->MAGICAL(), 0, "MAGICAL false");
 113
 114     is($r->REFCNT(), 1, "Reference count is 1");
 115     {
 116         my $ref = \$::data2;
 117         is($r->REFCNT(), 2, "Second reference");
 118     }
 119     is($r->REFCNT(), 1, "Reference count is 1");
 120
 121 }
 122
 123 my $r = qr/foo/;
 124 my $regexp = B::svref_2object($r);
 125 ok($regexp->precomp() eq 'foo', 'Get string from qr//');
 126 like($regexp->REGEX(), qr/\d+/, "REGEX() returns numeric value");
 127 like($regexp->compflags, qr/^\d+\z/, "compflags returns numeric value");
 128 is B::svref_2object(qr/(?{time})/)->qr_anoncv->ROOT->first->name, 'qr',
 129   'qr_anoncv';
 130 my $iv = 1;
 131 my $iv_ref = B::svref_2object(\$iv);
 132 is(ref $iv_ref, "B::IV", "Test B:IV return from svref_2object");
 133 is($iv_ref->REFCNT, 1, "Test B::IV->REFCNT");
 134 # Flag tests are needed still
 135 #diag $iv_ref->FLAGS();
 136 my $iv_ret = $iv_ref->object_2svref();
 137 is(ref $iv_ret, "SCALAR", "Test object_2svref() return is SCALAR");
 138 is($$iv_ret, $iv, "Test object_2svref()");
 139 is($iv_ref->int_value, $iv, "Test int_value()");
 140 is($iv_ref->IV, $iv, "Test IV()");
 141 is($iv_ref->IVX(), $iv, "Test IVX()");
 142 is($iv_ref->UVX(), $iv, "Test UVX()");
 143 is(eval { $iv_ref->RV() }, undef, 'Test RV() on IV');
 144 like($@, qr/argument is not SvROK/, 'Test RV() IV');
 145 $iv = \"Pie";
 146 my $val = eval { $iv_ref->RV() };
 147 is(ref $val, 'B::PV', 'Test RV() on a reference');
 148 is($val->PV(), 'Pie', 'Value expected');
 149 is($@, '', "Test RV()");
 150
 151 my $pv = "Foo";
 152 my $pv_ref = B::svref_2object(\$pv);
 153 is(ref $pv_ref, "B::PV", "Test B::PV return from svref_2object");
 154 is($pv_ref->REFCNT, 1, "Test B::PV->REFCNT");
 155 # Flag tests are needed still
 156 #diag $pv_ref->FLAGS();
 157 my $pv_ret = $pv_ref->object_2svref();
 158 is(ref $pv_ret, "SCALAR", "Test object_2svref() return is SCALAR");
 159 is($$pv_ret, $pv, "Test object_2svref()");
 160 is($pv_ref->PV(), $pv, "Test PV()");
 161 is(eval { $pv_ref->RV() }, undef, 'Test RV() on PV');
 162 like($@, qr/argument is not SvROK/, 'Test RV() on PV');
 163 is($pv_ref->PVX(), $pv, "Test PVX()");
 164 $pv = \"Pie";
 165 $val = eval { $pv_ref->RV() };
 166 is(ref $val, 'B::PV', 'Test RV() on a reference');
 167 is($val->PV(), 'Pie', 'Value expected');
 168 is($@, '', "Test RV()");
 169
 170 my $nv = 1.1;
 171 my $nv_ref = B::svref_2object(\$nv);
 172 is(ref $nv_ref, "B::NV", "Test B::NV return from svref_2object");
 173 is($nv_ref->REFCNT, 1, "Test B::NV->REFCNT");
 174 # Flag tests are needed still
 175 #diag $nv_ref->FLAGS();
 176 my $nv_ret = $nv_ref->object_2svref();
 177 is(ref $nv_ret, "SCALAR", "Test object_2svref() return is SCALAR");
 178 is($$nv_ret, $nv, "Test object_2svref()");
 179 is($nv_ref->NV, $nv, "Test NV()");
 180 is($nv_ref->NVX(), $nv, "Test NVX()");
 181 is(eval { $nv_ref->RV() }, undef, 'Test RV() on NV');
 182 like($@, qr/Can't locate object method "RV" via package "B::NV"/,
 183      'Test RV() on NV');
 184
 185 my $null = undef;
 186 my $null_ref = B::svref_2object(\$null);
 187 is(ref $null_ref, "B::NULL", "Test B::NULL return from svref_2object");
 188 is($null_ref->REFCNT, 1, "Test B::NULL->REFCNT");
 189 # Flag tests are needed still
 190 #diag $null_ref->FLAGS();
 191 my $null_ret = $nv_ref->object_2svref();
 192 is(ref $null_ret, "SCALAR", "Test object_2svref() return is SCALAR");
 193 is($$null_ret, $nv, "Test object_2svref()");
 194
 195 my $cv = sub{ 1; };
 196 my $cv_ref = B::svref_2object(\$cv);
 197 is($cv_ref->REFCNT, 1, "Test B::IV->REFCNT");
 198 is(ref $cv_ref, "B::IV", "Test B::IV return from svref_2object - code");
 199 my $cv_ret = $cv_ref->object_2svref();
 200 is(ref $cv_ret, "REF", "Test object_2svref() return is REF");
 201 is($$cv_ret, $cv, "Test object_2svref()");
 202
 203 my $av = [];
 204 my $av_ref = B::svref_2object(\$av);
 205 is(ref $av_ref, "B::IV", "Test B::IV return from svref_2object - array");
 206
 207 my $hv = [];
 208 my $hv_ref = B::svref_2object(\$hv);
 209 is(ref $hv_ref, "B::IV", "Test B::IV return from svref_2object - hash");
 210
 211 local *gv = *STDOUT;
 212 my $gv_ref = B::svref_2object(\*gv);
 213 is(ref $gv_ref, "B::GV", "Test B::GV return from svref_2object");
 214 ok(! $gv_ref->is_empty(), "Test is_empty()");
 215 ok($gv_ref->isGV_with_GP(), "Test isGV_with_GP()");
 216 is($gv_ref->NAME(), "gv", "Test NAME()");
 217 is($gv_ref->SAFENAME(), "gv", "Test SAFENAME()");
 218 like($gv_ref->FILE(), qr/b\.t$/, "Testing FILE()");
 219 is($gv_ref->SvTYPE(), B::SVt_PVGV, "Test SvTYPE()");
 220 is($gv_ref->FLAGS() & B::SVTYPEMASK, B::SVt_PVGV, "Test SVTYPEMASK");
 221
 222 # The following return B::SPECIALs.
 223 is(ref B::sv_yes(), "B::SPECIAL", "B::sv_yes()");
 224 is(ref B::sv_no(), "B::SPECIAL", "B::sv_no()");
 225 is(ref B::sv_undef(), "B::SPECIAL", "B::sv_undef()");
 226 SKIP: {
 227     skip('no fork', 1)
 228         unless ($Config::Config{d_fork} or $Config::Config{d_pseudofork});
 229     my $pid;
 230     pipe my $r, my $w or die "Can't pipe: $!";;
 231     if ($pid = fork) {
 232         close $w;
 233         my $type = <$r>;
 234         close $r;
 235         waitpid($pid,0);
 236         is($type, "B::SPECIAL", "special SV table works after pseudofork");
 237     }
 238     else {
 239         close $r;
 240         $|++;
 241         print $w ref B::svref_2object(\(!!0));
 242         close $w;
 243         exit;
 244     }
 245 }
 246
 247 # More utility functions
 248 is(B::ppname(0), "pp_null", "Testing ppname (this might break if opnames.h is changed)");
 249 is(B::opnumber("null"), 0, "Testing opnumber with opname (null)");
 250 is(B::opnumber("pp_null"), 0, "Testing opnumber with opname (pp_null)");
 251 {
 252     my $hash = B::hash("wibble");
 253     like($hash, qr/\A0x[0-9a-f]+\z/, "Testing B::hash(\"wibble\")");
 254     unlike($hash, qr/\A0x0+\z/, "Testing B::hash(\"wibble\")");
 255
 256     SKIP: {
 257         skip "Nulls don't hash to the same bucket regardless of length with this PERL_HASH implementation", 20
 258             if B::hash("") ne B::hash("\0" x 19);
 259         like(B::hash("\0" x $_), qr/\A0x0+\z/, "Testing B::hash(\"0\" x $_)")
 260              for 0..19;
 261     }
 262
 263     $hash = eval {B::hash(chr 256)};
 264     is($hash, undef, "B::hash() refuses non-octets");
 265     like($@, qr/^Wide character in subroutine entry/);
 266
 267     $hash = B::hash(chr 163);
 268     my $str = chr(163) . chr 256;
 269     chop $str;
 270     is(B::hash($str), $hash, 'B::hash() with chr 128-256 is well-behaved');
 271 }
 272 {
 273     is(B::cstring(undef), '0', "Testing B::cstring(undef)");
 274     is(B::perlstring(undef), '0', "Testing B::perlstring(undef)");
 275
 276     my @common = map {eval $_, $_}
 277         '"wibble"', '"\""', '"\'"', '"\\\\"', '"\\n\\r\\t\\b\\a\\f"', '"\000"',
 278             '"\000\000"', '"\000Bing\000"', ord 'N' == 78 ? '"\\177"' : ();
 279
 280     my $oct = sprintf "\\%03o", ord '?';
 281     my @tests = (@common, '$_', '"$_"', '@_', '"@_"', '??N', qq{"$oct?N"},
 282                  ord 'N' == 78 ? (chr 11, '"\v"'): ());
 283     while (my ($test, $expect) = splice @tests, 0, 2) {
 284         is(B::cstring($test), $expect, "B::cstring($expect)");
 285     }
 286
 287     @tests = (@common, '$_', '"\$_"', '@_', '"\@_"', '??N', '"??N"',
 288               chr 256, '"\x{100}"', chr 65536, '"\x{10000}"',
 289               ord 'N' == 78 ? (chr 11, '"\013"'): ());
 290     while (my ($test, $expect) = splice @tests, 0, 2) {
 291         is(B::perlstring($test), $expect, "B::perlstring($expect)");
 292         utf8::upgrade $test;
 293         $expect =~ s/\\([0-7]{3})/sprintf "\\x\{%x\}", oct $1/eg;
 294         is(B::perlstring($test), $expect, "B::perlstring($expect) (Unicode)");
 295     }
 296 }
 297 {
 298     my @tests = ((map {eval(qq{"$_"}), $_} '\\n', '\\r', '\\t',
 299                   '\\b', '\\a', '\\f', '\\000', '\\\'', '?'), '"', '"',
 300                  ord 'N' == 78 ? (chr 11, '\v', "\177", '\\177') : ());
 301
 302     while (my ($test, $expect) = splice @tests, 0, 2) {
 303         is(B::cchar($test), "'${expect}'", "B::cchar(qq{$expect})");
 304     }
 305 }
 306
 307 is(B::class(bless {}, "Wibble::Bibble"), "Bibble", "Testing B::class()");
 308 is(B::cast_I32(3.14), 3, "Testing B::cast_I32()");
 309 is(B::opnumber("chop"), 39, "Testing opnumber with opname (chop)");
 310
 311 {
 312     no warnings 'once';
 313     my $sg = B::sub_generation();
 314     *UNIVERSAL::hand_waving = sub { };
 315     ok( $sg < B::sub_generation, "sub_generation increments" );
 316 }
 317
 318 like( B::amagic_generation, qr/^\d+\z/, "amagic_generation" );
 319
 320 is(B::svref_2object(sub {})->ROOT->ppaddr, 'PL_ppaddr[OP_LEAVESUB]',
 321    'OP->ppaddr');
 322
 323 B::svref_2object(sub{y/\x{100}//})->ROOT->first->first->sibling->sv;
 324 ok 1, 'B knows that UTF trans is a padop, not an svop';
 325
 326 {
 327     my $o = B::svref_2object(sub{0;0})->ROOT->first->first;
 328     # Make sure we are testing what we think we are testing.  If these two
 329     # fail, tweak the test to find a nulled cop a different way.
 330     is $o->name, "null", 'first op of sub{0;0} is a null';
 331     is B::ppname($o->targ),'pp_nextstate','first op of sub{0;0} was a cop';
 332     # Test its class
 333     is B::class($o), "COP", 'nulled cops are of class COP';
 334 }
 335
 336 {
 337     format FOO =
 338 foo
 339 .
 340     my $f = B::svref_2object(*FOO{FORMAT});
 341     isa_ok $f, 'B::FM';
 342     can_ok $f, 'LINES';
 343 }
 344
 345 is B::safename("\cLAST_FH"), "^LAST_FH", 'basic safename test';
 346
 347 my $sub1 = sub {die};
 348 { no warnings 'once'; no strict; *Peel:: = *{"Pe\0e\x{142}::"} }
 349 my $sub2 = eval 'package Peel; sub {die}';
 350 my $cop = B::svref_2object($sub1)->ROOT->first->first;
 351 my $bobby = B::svref_2object($sub2)->ROOT->first->first;
 352 is $cop->stash->object_2svref, \%main::, 'COP->stash';
 353 is $cop->stashpv, 'main', 'COP->stashpv';
 354
 355 is $bobby->stashpv, "Pe\0e\x{142}", 'COP->stashpv with utf8 and nulls';
 356
 357 SKIP: {
 358     skip "no stashoff", 2 unless $Config::Config{useithreads};
 359     like $cop->stashoff, qr/^[1-9]\d*\z/a, 'COP->stashoff';
 360     isnt $cop->stashoff, $bobby->stashoff,
 361         'different COP->stashoff for different stashes';
 362 }
 363
 364 my $pmop = B::svref_2object(sub{ qr/fit/ })->ROOT->first->first->sibling;
 365 $regexp = $pmop->pmregexp;
 366 is B::class($regexp), 'REGEXP', 'B::PMOP::pmregexp returns a regexp';
 367 is $regexp->precomp, 'fit', 'pmregexp returns the right regexp';
 368
 369
 370 # Test $B::overlay
 371 {
 372     my $methods = {
 373         BINOP =>  [ qw(last) ],
 374         COP   =>  [ qw(arybase cop_seq file filegv hints hints_hash io
 375                        label line stash stashpv
 376                        stashoff warnings) ],
 377         LISTOP => [ qw(children) ],
 378         LOGOP =>  [ qw(other) ],
 379         LOOP  =>  [ qw(lastop nextop redoop) ],
 380         OP    =>  [ qw(desc flags name next opt ppaddr private sibling
 381                        size spare targ type) ],
 382         PADOP =>  [ qw(gv padix sv) ],
 383         PMOP  =>  [ qw(code_list pmflags pmoffset pmreplroot pmreplstart pmstash pmstashpv precomp reflags) ],
 384         PVOP  =>  [ qw(pv) ],
 385         SVOP  =>  [ qw(gv sv) ],
 386         UNOP  =>  [ qw(first) ],
 387     };
 388
 389     my $overlay = {};
 390     my $op = B::svref_2object(sub { my $x = 1 })->ROOT;
 391
 392     for my $class (sort keys %$methods) {
 393         for my $meth (@{$methods->{$class}}) {
 394             my $full = "B::${class}::$meth";
 395             die "Duplicate method '$full'\n"
 396                 if grep $_ eq $full, @{$overlay->{$meth}};
 397             push @{$overlay->{$meth}}, "B::${class}::$meth";
 398         }
 399     }
 400
 401     {
 402         local $B::overlay; # suppress 'used once' warning
 403         local $B::overlay = { $$op => $overlay };
 404
 405         for my $class (sort keys %$methods) {
 406             bless $op, "B::$class"; # naughty
 407             for my $meth (@{$methods->{$class}}) {
 408                 if ($op->can($meth)) {
 409                     my $list = $op->$meth;
 410                     ok(defined $list
 411                             && ref($list) eq "ARRAY"
 412                             && grep($_ eq "B::${class}::$meth", @$list),
 413                         "overlay: B::$class $meth");
 414                 }
 415                 else {
 416                     pass("overlay: B::$class $meth (skipped; no method)");
 417                 }
 418             }
 419         }
 420     }
 421     # B::overlay should be disabled again here
 422     is($op->name, "leavesub", "overlay: orig name");
 423 }
 424
 425 { # [perl #118525]
 426     {
 427         sub foo {}
 428         my $cv = B::svref_2object(\&foo);
 429         ok($cv, "make a B::CV from a non-anon sub reference");
 430         isa_ok($cv, "B::CV");
 431         my $gv = $cv->GV;
 432         ok($gv, "we get a GV from a GV on a normal sub");
 433         isa_ok($gv, "B::GV");
 434         is($gv->NAME, "foo", "check the GV name");
 435         is($cv->NAME_HEK, undef, "no hek for a global sub");
 436     }
 437
 438     {
 439         use feature 'lexical_subs';
 440         no warnings 'experimental::lexical_subs';
 441         my sub bar {};
 442         my $cv = B::svref_2object(\&bar);
 443         ok($cv, "make a B::CV from a lexical sub reference");
 444         isa_ok($cv, "B::CV");
 445         my $hek = $cv->NAME_HEK;
 446         is($hek, "bar", "check the NAME_HEK");
 447         my $gv = $cv->GV;
 448         isa_ok($gv, "B::GV", "GV on a lexical sub");
 449     }
 450 }
 451
 452 { # [perl #120535]
 453     my %h = ( "\x{100}" => 1 );
 454     my $b = B::svref_2object(\%h);
 455     my ($k, $v) = $b->ARRAY;
 456     is($k, "\x{100}", "check utf8 preserved by B::HV::ARRAY");
 457 }
 458
 459 # test op_parent
 460
 461 SKIP: {
 462     ok($B::OP::does_parent, "does_parent always set");
 463     my $lineseq = B::svref_2object(sub{my $x = 1})->ROOT->first;
 464     is ($lineseq->type,  B::opnumber('lineseq'),
 465                                 'op_parent: top op is lineseq');
 466     my $first  = $lineseq->first;
 467     my $second = $first->sibling;
 468     is(ref $second->sibling, "B::NULL", 'op_parent: second sibling is null');
 469     is($first->moresib,  1 , 'op_parent: first  sibling: moresib');
 470     is($second->moresib, 0,  'op_parent: second sibling: !moresib');
 471     is($$lineseq,  ${$first->parent},   'op_parent: first  sibling okay');
 472     is($$lineseq,  ${$second->parent},  'op_parent: second sibling okay');
 473 }
 474
 475
 476 # make sure ->sv, -gv methods do the right thing on threaded builds
 477 {
 478
 479     # for some reason B::walkoptree only likes a sub name, not a code ref
 480     my ($gv, $sv);
 481     sub gvsv_const {
 482         # make the early pad slots something unlike a threaded const or
 483         # gvsv
 484         my ($dummy1, $dummy2, $dummy3, $dummy4) = qw(foo1 foo2 foo3 foo4);
 485         my $self = shift;
 486         if ($self->name eq 'gvsv') {
 487             $gv = $self->gv;
 488         }
 489         elsif ($self->name eq 'const') {
 490             $sv = $self->sv;
 491         }
 492     };
 493
 494     B::walkoptree(B::svref_2object(sub {our $x = 1})->ROOT, "::gvsv_const");
 495     ok(defined $gv, "gvsv->gv seen");
 496     ok(defined $sv, "const->sv seen");
 497     if ($Config::Config{useithreads}) {
 498         # should get NULLs
 499         is(ref($gv), "B::SPECIAL", "gvsv->gv is special");
 500         is(ref($sv), "B::SPECIAL", "const->sv is special");
 501         is($$gv, 0, "gvsv->gv special is 0 (NULL)");
 502         is($$sv, 0, "const->sv special is 0 (NULL)");
 503     }
 504     else {
 505         is(ref($gv), "B::GV", "gvsv->gv is GV");
 506         is(ref($sv), "B::IV", "const->sv is IV");
 507         pass();
 508         pass();
 509     }
 510
 511 }
 512
 513
 514 # Some pad tests
 515 {
 516     my $sub = sub { my main $a; CORE::state @b; our %c };
 517     my $padlist = B::svref_2object($sub)->PADLIST;
 518     is $padlist->MAX, 1, 'padlist MAX';
 519     my @array = $padlist->ARRAY;
 520     is @array, 2, 'two items from padlist ARRAY';
 521     is ${$padlist->ARRAYelt(0)}, ${$array[0]},
 522       'ARRAYelt(0) is first item from ARRAY';
 523     is ${$padlist->ARRAYelt(1)}, ${$array[1]},
 524       'ARRAYelt(1) is second item from ARRAY';
 525     is ${$padlist->NAMES}, ${$array[0]},
 526       'NAMES is first item from ARRAY';
 527     my @names = $array[0]->ARRAY;
 528     cmp_ok @names, ">=", 4, 'at least 4 pad names';
 529     is join(" ", map($_->PV//"undef",@names[0..3])), 'undef $a @b %c',
 530        'pad name PVs';
 531
 532     my @closures;
 533     for (1,2) { push @closures, sub { sub { @closures } } }
 534     my $sub1 = B::svref_2object($closures[0]);
 535     my $sub2 = B::svref_2object($closures[1]);
 536     is $sub2->PADLIST->id, $sub1->PADLIST->id, 'padlist id';
 537     $sub1 = B::svref_2object(my $lr = $closures[0]());
 538     $sub2 = B::svref_2object(my $lr2= $closures[1]());
 539     is $sub2->PADLIST->outid, $sub1->PADLIST->outid, 'padlist outid';
 540 }
 541
 542 # GH #17301 aux_list() sometimes returned wrong #args
 543
 544 {
 545     my $big = ($Config::Config{uvsize} > 4);
 546     my $self;
 547     my $sub = $big
 548             ? sub { $self->{h1}{h2}{h3}{h4}{h5}{h6}{h7}{h8}{h9} }
 549             : sub { $self->{h1}{h2}{h3}{h4} };
 550     my $cv = B::svref_2object($sub);
 551     my $op = $cv->ROOT->first->first->next;
 552     my @items = $op->aux_list($cv);
 553     is +@items, $big ? 11 : 6, 'GH #17301';
 554 }
 555
 556
 557 done_testing();