lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 177 assignment) contains the text from C<$filename>, with each element
 178 corresponding to a single line of C<$filename>.
 179
 180 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 181 assignment) contains breakpoints and actions.  The keys are line numbers;
 182 you can set individual values, but not the whole hash. The Perl interpreter
 183 uses this hash to determine where breakpoints have been set. Any true value is
 184 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 185 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 186
 187 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 188 This is also the case for evaluated strings that contain subroutines, or
 189 which are currently being executed.  The $filename for C<eval>ed strings looks
 190 like C<(eval 34)> or C<(re_eval 19)>.
 191
 192 =head1 DEBUGGER STARTUP
 193
 194 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 195 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 196 of options. In addition, this file may define a subroutine C<&afterinit>
 197 that will be executed (in the debugger's context) after the debugger has
 198 initialized itself.
 199
 200 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 201 contents as the argument of a C<o> command in the debugger.
 202
 203 =head2 STARTUP-ONLY OPTIONS
 204
 205 The following options can only be specified at startup.
 206 To set them in your rcfile, add a call to
 207 C<&parse_options("optionName=new_value")>.
 208
 209 =over 4
 210
 211 =item * TTY
 212
 213 the TTY to use for debugging i/o.
 214
 215 =item * noTTY
 216
 217 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 218 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 219 Term::Rendezvous.  Current variant is to have the name of TTY in this
 220 file.
 221
 222 =item * ReadLine
 223
 224 If false, a dummy  ReadLine is used, so you can debug
 225 ReadLine applications.
 226
 227 =item * NonStop
 228
 229 if true, no i/o is performed until interrupt.
 230
 231 =item * LineInfo
 232
 233 file or pipe to print line number info to.  If it is a
 234 pipe, a short "emacs like" message is used.
 235
 236 =item * RemotePort
 237
 238 host:port to connect to on remote host for remote debugging.
 239
 240 =back
 241
 242 =head3 SAMPLE RCFILE
 243
 244  &parse_options("NonStop=1 LineInfo=db.out");
 245   sub afterinit { $trace = 1; }
 246
 247 The script will run without human intervention, putting trace
 248 information into C<db.out>.  (If you interrupt it, you had better
 249 reset C<LineInfo> to something I<interactive>!)
 250
 251 =head1 INTERNALS DESCRIPTION
 252
 253 =head2 DEBUGGER INTERFACE VARIABLES
 254
 255 Perl supplies the values for C<%sub>.  It effectively inserts
 256 a C<&DB::DB();> in front of each place that can have a
 257 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 258 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 259 {require 'perl5db.pl'}> before the first line.
 260
 261 After each C<require>d file is compiled, but before it is executed, a
 262 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 263 is the expanded name of the C<require>d file (as found via C<%INC>).
 264
 265 =head3 IMPORTANT INTERNAL VARIABLES
 266
 267 =head4 C<$CreateTTY>
 268
 269 Used to control when the debugger will attempt to acquire another TTY to be
 270 used for input.
 271
 272 =over
 273
 274 =item * 1 -  on C<fork()>
 275
 276 =item * 2 - debugger is started inside debugger
 277
 278 =item * 4 -  on startup
 279
 280 =back
 281
 282 =head4 C<$doret>
 283
 284 The value -2 indicates that no return value should be printed.
 285 Any other positive value causes C<DB::sub> to print return values.
 286
 287 =head4 C<$evalarg>
 288
 289 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 290 contents of C<@_> when C<DB::eval> is called.
 291
 292 =head4 C<$frame>
 293
 294 Determines what messages (if any) will get printed when a subroutine (or eval)
 295 is entered or exited.
 296
 297 =over 4
 298
 299 =item * 0 -  No enter/exit messages
 300
 301 =item * 1 - Print I<entering> messages on subroutine entry
 302
 303 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 304
 305 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 306
 307 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 308
 309 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 310
 311 =back
 312
 313 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 314 The debugger internally juggles the value of C<$frame> during execution to
 315 protect external modules that the debugger uses from getting traced.
 316
 317 =head4 C<$level>
 318
 319 Tracks current debugger nesting level. Used to figure out how many
 320 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 321 outputs a prompt. Also used to help determine if the program has finished
 322 during command parsing.
 323
 324 =head4 C<$onetimeDump>
 325
 326 Controls what (if anything) C<DB::eval()> will print after evaluating an
 327 expression.
 328
 329 =over 4
 330
 331 =item * C<undef> - don't print anything
 332
 333 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 334
 335 =item * C<methods> - print the methods callable on the first item returned
 336
 337 =back
 338
 339 =head4 C<$onetimeDumpDepth>
 340
 341 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 342 dumping a structure. Numeric. If C<undef>, print all levels.
 343
 344 =head4 C<$signal>
 345
 346 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 347 which is called before every statement, checks this and puts the user into
 348 command mode if it finds C<$signal> set to a true value.
 349
 350 =head4 C<$single>
 351
 352 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 353 each subroutine; popped again at the end of each subroutine.
 354
 355 =over 4
 356
 357 =item * 0 - run continuously.
 358
 359 =item * 1 - single-step, go into subs. The C<s> command.
 360
 361 =item * 2 - single-step, don't go into subs. The C<n> command.
 362
 363 =item * 4 - print current sub depth (turned on to force this when C<too much
 364 recursion> occurs.
 365
 366 =back
 367
 368 =head4 C<$trace>
 369
 370 Controls the output of trace information.
 371
 372 =over 4
 373
 374 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 375
 376 =item * 2 - watch expressions are active
 377
 378 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 379
 380 =back
 381
 382 =head4 C<$slave_editor>
 383
 384 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 385
 386 =head4 C<@cmdfhs>
 387
 388 Stack of filehandles that C<DB::readline()> will read commands from.
 389 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 390
 391 =head4 C<@dbline>
 392
 393 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 394 supplied by the Perl interpreter to the debugger. Contains the source.
 395
 396 =head4 C<@old_watch>
 397
 398 Previous values of watch expressions. First set when the expression is
 399 entered; reset whenever the watch expression changes.
 400
 401 =head4 C<@saved>
 402
 403 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 404 so that the debugger can substitute safe values while it's running, and
 405 restore them when it returns control.
 406
 407 =head4 C<@stack>
 408
 409 Saves the current value of C<$single> on entry to a subroutine.
 410 Manipulated by the C<c> command to turn off tracing in all subs above the
 411 current one.
 412
 413 =head4 C<@to_watch>
 414
 415 The 'watch' expressions: to be evaluated before each line is executed.
 416
 417 =head4 C<@typeahead>
 418
 419 The typeahead buffer, used by C<DB::readline>.
 420
 421 =head4 C<%alias>
 422
 423 Command aliases. Stored as character strings to be substituted for a command
 424 entered.
 425
 426 =head4 C<%break_on_load>
 427
 428 Keys are file names, values are 1 (break when this file is loaded) or undef
 429 (don't break when it is loaded).
 430
 431 =head4 C<%dbline>
 432
 433 Keys are line numbers, values are C<condition\0action>. If used in numeric
 434 context, values are 0 if not breakable, 1 if breakable, no matter what is
 435 in the actual hash entry.
 436
 437 =head4 C<%had_breakpoints>
 438
 439 Keys are file names; values are bitfields:
 440
 441 =over 4
 442
 443 =item * 1 - file has a breakpoint in it.
 444
 445 =item * 2 - file has an action in it.
 446
 447 =back
 448
 449 A zero or undefined value means this file has neither.
 450
 451 =head4 C<%option>
 452
 453 Stores the debugger options. These are character string values.
 454
 455 =head4 C<%postponed>
 456
 457 Saves breakpoints for code that hasn't been compiled yet.
 458 Keys are subroutine names, values are:
 459
 460 =over 4
 461
 462 =item * C<compile> - break when this sub is compiled
 463
 464 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 465
 466 =back
 467
 468 =head4 C<%postponed_file>
 469
 470 This hash keeps track of breakpoints that need to be set for files that have
 471 not yet been compiled. Keys are filenames; values are references to hashes.
 472 Each of these hashes is keyed by line number, and its values are breakpoint
 473 definitions (C<condition\0action>).
 474
 475 =head1 DEBUGGER INITIALIZATION
 476
 477 The debugger's initialization actually jumps all over the place inside this
 478 package. This is because there are several BEGIN blocks (which of course
 479 execute immediately) spread through the code. Why is that?
 480
 481 The debugger needs to be able to change some things and set some things up
 482 before the debugger code is compiled; most notably, the C<$deep> variable that
 483 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 484 debugger has to turn off warnings while the debugger code is compiled, but then
 485 restore them to their original setting before the program being debugged begins
 486 executing.
 487
 488 The first C<BEGIN> block simply turns off warnings by saving the current
 489 setting of C<$^W> and then setting it to zero. The second one initializes
 490 the debugger variables that are needed before the debugger begins executing.
 491 The third one puts C<$^X> back to its former value.
 492
 493 We'll detail the second C<BEGIN> block later; just remember that if you need
 494 to initialize something before the debugger starts really executing, that's
 495 where it has to go.
 496
 497 =cut
 498
 499 package DB;
 500
 501 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 502
 503 # Debugger for Perl 5.00x; perl5db.pl patch level:
 504 $VERSION = 1.29;
 505
 506 $header = "perl5db.pl version $VERSION";
 507
 508 =head1 DEBUGGER ROUTINES
 509
 510 =head2 C<DB::eval()>
 511
 512 This function replaces straight C<eval()> inside the debugger; it simplifies
 513 the process of evaluating code in the user's context.
 514
 515 The code to be evaluated is passed via the package global variable
 516 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 517
 518 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 519 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 520 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 521 user's current package, grabbed when C<DB::DB> got control.  This causes the
 522 proper context to be used when the eval is actually done.  Afterward, we
 523 restore C<$trace>, C<$single>, and C<$^D>.
 524
 525 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 526 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 527 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 528 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 529 considered sane by the debugger. If there was an C<eval()> error, we print
 530 it on the debugger's output. If C<$onetimedump> is defined, we call
 531 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 532 'methods'. Setting it to something else causes the debugger to do the eval
 533 but not print the result - handy if you want to do something else with it
 534 (the "watch expressions" code does this to get the value of the watch
 535 expression but not show it unless it matters).
 536
 537 In any case, we then return the list of output from C<eval> to the caller,
 538 and unwinding restores the former version of C<$@> in C<@saved> as well
 539 (the localization of C<$saved[0]> goes away at the end of this scope).
 540
 541 =head3 Parameters and variables influencing execution of DB::eval()
 542
 543 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 544 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 545 The variables listed below influence C<DB::eval()>'s execution directly.
 546
 547 =over 4
 548
 549 =item C<$evalarg> - the thing to actually be eval'ed
 550
 551 =item C<$trace> - Current state of execution tracing
 552
 553 =item C<$single> - Current state of single-stepping
 554
 555 =item C<$onetimeDump> - what is to be displayed after the evaluation
 556
 557 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 558
 559 =back
 560
 561 The following variables are altered by C<DB::eval()> during its execution. They
 562 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 563
 564 =over 4
 565
 566 =item C<@res> - used to capture output from actual C<eval>.
 567
 568 =item C<$otrace> - saved value of C<$trace>.
 569
 570 =item C<$osingle> - saved value of C<$single>.
 571
 572 =item C<$od> - saved value of C<$^D>.
 573
 574 =item C<$saved[0]> - saved value of C<$@>.
 575
 576 =item $\ - for output of C<$@> if there is an evaluation error.
 577
 578 =back
 579
 580 =head3 The problem of lexicals
 581
 582 The context of C<DB::eval()> presents us with some problems. Obviously,
 583 we want to be 'sandboxed' away from the debugger's internals when we do
 584 the eval, but we need some way to control how punctuation variables and
 585 debugger globals are used.
 586
 587 We can't use local, because the code inside C<DB::eval> can see localized
 588 variables; and we can't use C<my> either for the same reason. The code
 589 in this routine compromises and uses C<my>.
 590
 591 After this routine is over, we don't have user code executing in the debugger's
 592 context, so we can use C<my> freely.
 593
 594 =cut
 595
 596 ############################################## Begin lexical danger zone
 597
 598 # 'my' variables used here could leak into (that is, be visible in)
 599 # the context that the code being evaluated is executing in. This means that
 600 # the code could modify the debugger's variables.
 601 #
 602 # Fiddling with the debugger's context could be Bad. We insulate things as
 603 # much as we can.
 604
 605 sub eval {
 606
 607     # 'my' would make it visible from user code
 608     #    but so does local! --tchrist
 609     # Remember: this localizes @DB::res, not @main::res.
 610     local @res;
 611     {
 612
 613         # Try to keep the user code from messing  with us. Save these so that
 614         # even if the eval'ed code changes them, we can put them back again.
 615         # Needed because the user could refer directly to the debugger's
 616         # package globals (and any 'my' variables in this containing scope)
 617         # inside the eval(), and we want to try to stay safe.
 618         local $otrace  = $trace;
 619         local $osingle = $single;
 620         local $od      = $^D;
 621
 622         # Untaint the incoming eval() argument.
 623         { ($evalarg) = $evalarg =~ /(.*)/s; }
 624
 625         # $usercontext built in DB::DB near the comment
 626         # "set up the context for DB::eval ..."
 627         # Evaluate and save any results.
 628         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 629
 630         # Restore those old values.
 631         $trace  = $otrace;
 632         $single = $osingle;
 633         $^D     = $od;
 634     }
 635
 636     # Save the current value of $@, and preserve it in the debugger's copy
 637     # of the saved precious globals.
 638     my $at = $@;
 639
 640     # Since we're only saving $@, we only have to localize the array element
 641     # that it will be stored in.
 642     local $saved[0];    # Preserve the old value of $@
 643     eval { &DB::save };
 644
 645     # Now see whether we need to report an error back to the user.
 646     if ($at) {
 647         local $\ = '';
 648         print $OUT $at;
 649     }
 650
 651     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 652     # are package globals.
 653     elsif ($onetimeDump) {
 654         if ( $onetimeDump eq 'dump' ) {
 655             local $option{dumpDepth} = $onetimedumpDepth
 656               if defined $onetimedumpDepth;
 657             dumpit( $OUT, \@res );
 658         }
 659         elsif ( $onetimeDump eq 'methods' ) {
 660             methods( $res[0] );
 661         }
 662     } ## end elsif ($onetimeDump)
 663     @res;
 664 } ## end sub eval
 665
 666 ############################################## End lexical danger zone
 667
 668 # After this point it is safe to introduce lexicals.
 669 # The code being debugged will be executing in its own context, and
 670 # can't see the inside of the debugger.
 671 #
 672 # However, one should not overdo it: leave as much control from outside as
 673 # possible. If you make something a lexical, it's not going to be addressable
 674 # from outside the debugger even if you know its name.
 675
 676 # This file is automatically included if you do perl -d.
 677 # It's probably not useful to include this yourself.
 678 #
 679 # Before venturing further into these twisty passages, it is
 680 # wise to read the perldebguts man page or risk the ire of dragons.
 681 #
 682 # (It should be noted that perldebguts will tell you a lot about
 683 # the underlying mechanics of how the debugger interfaces into the
 684 # Perl interpreter, but not a lot about the debugger itself. The new
 685 # comments in this code try to address this problem.)
 686
 687 # Note that no subroutine call is possible until &DB::sub is defined
 688 # (for subroutines defined outside of the package DB). In fact the same is
 689 # true if $deep is not defined.
 690
 691 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 692
 693 # modified Perl debugger, to be run from Emacs in perldb-mode
 694 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 695 # Johan Vromans -- upgrade to 4.0 pl 10
 696 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 697
 698 # (We have made efforts to  clarify the comments in the change log
 699 # in other places; some of them may seem somewhat obscure as they
 700 # were originally written, and explaining them away from the code
 701 # in question seems conterproductive.. -JM)
 702
 703 ########################################################################
 704 # Changes: 0.94
 705 #   + A lot of things changed after 0.94. First of all, core now informs
 706 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 707 #     BEGIN and END. Handy with `O f=2'.
 708 #   + This can make debugger a little bit too verbose, please be patient
 709 #     and report your problems promptly.
 710 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 711 #   + Note that if DESTROY returns a reference to the object (or object),
 712 #     the deletion of data may be postponed until the next function call,
 713 #     due to the need to examine the return value.
 714 #
 715 # Changes: 0.95
 716 #   + `v' command shows versions.
 717 #
 718 # Changes: 0.96
 719 #   + `v' command shows version of readline.
 720 #     primitive completion works (dynamic variables, subs for `b' and `l',
 721 #     options). Can `p %var'
 722 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 723 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 724 #   + `c sub' documented.
 725 #   + At last enough magic combined to stop after the end of debuggee.
 726 #   + !! should work now (thanks to Emacs bracket matching an extra
 727 #     `]' in a regexp is caught).
 728 #   + `L', `D' and `A' span files now (as documented).
 729 #   + Breakpoints in `require'd code are possible (used in `R').
 730 #   +  Some additional words on internal work of debugger.
 731 #   + `b load filename' implemented.
 732 #   + `b postpone subr' implemented.
 733 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 734 #   + When restarting debugger breakpoints/actions persist.
 735 #   + Buglet: When restarting debugger only one breakpoint/action per
 736 #             autoloaded function persists.
 737 #
 738 # Changes: 0.97: NonStop will not stop in at_exit().
 739 #   + Option AutoTrace implemented.
 740 #   + Trace printed differently if frames are printed too.
 741 #   + new `inhibitExit' option.
 742 #   + printing of a very long statement interruptible.
 743 # Changes: 0.98: New command `m' for printing possible methods
 744 #   + 'l -' is a synonym for `-'.
 745 #   + Cosmetic bugs in printing stack trace.
 746 #   +  `frame' & 8 to print "expanded args" in stack trace.
 747 #   + Can list/break in imported subs.
 748 #   + new `maxTraceLen' option.
 749 #   + frame & 4 and frame & 8 granted.
 750 #   + new command `m'
 751 #   + nonstoppable lines do not have `:' near the line number.
 752 #   + `b compile subname' implemented.
 753 #   + Will not use $` any more.
 754 #   + `-' behaves sane now.
 755 # Changes: 0.99: Completion for `f', `m'.
 756 #   +  `m' will remove duplicate names instead of duplicate functions.
 757 #   + `b load' strips trailing whitespace.
 758 #     completion ignores leading `|'; takes into account current package
 759 #     when completing a subroutine name (same for `l').
 760 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 761 #   BUG FIXES:
 762 #   + Added bare minimal security checks on perldb rc files, plus
 763 #     comments on what else is needed.
 764 #   + Fixed the ornaments that made "|h" completely unusable.
 765 #     They are not used in print_help if they will hurt.  Strip pod
 766 #     if we're paging to less.
 767 #   + Fixed mis-formatting of help messages caused by ornaments
 768 #     to restore Larry's original formatting.
 769 #   + Fixed many other formatting errors.  The code is still suboptimal,
 770 #     and needs a lot of work at restructuring.  It's also misindented
 771 #     in many places.
 772 #   + Fixed bug where trying to look at an option like your pager
 773 #     shows "1".
 774 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 775 #     lose.  You should consider shell escapes not using their shell,
 776 #     or else not caring about detailed status.  This should really be
 777 #     unified into one place, too.
 778 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 779 #     tricking Perl into thinking you weren't calling a debugger command!
 780 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 781 #     suggests a leading semicolon or any other irrelevant non-whitespace
 782 #     to indicate literal Perl code.)
 783 #   + Fixed bugs that ate warnings due to wrong selected handle.
 784 #   + Fixed a precedence bug on signal stuff.
 785 #   + Fixed some unseemly wording.
 786 #   + Fixed bug in help command trying to call perl method code.
 787 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 788 #   ENHANCEMENTS:
 789 #   + Added some comments.  This code is still nasty spaghetti.
 790 #   + Added message if you clear your pre/post command stacks which was
 791 #     very easy to do if you just typed a bare >, <, or {.  (A command
 792 #     without an argument should *never* be a destructive action; this
 793 #     API is fundamentally screwed up; likewise option setting, which
 794 #     is equally buggered.)
 795 #   + Added command stack dump on argument of "?" for >, <, or {.
 796 #   + Added a semi-built-in doc viewer command that calls man with the
 797 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 798 #     or else perldoc on obstreperous platforms.
 799 #   + Added to and rearranged the help information.
 800 #   + Detected apparent misuse of { ... } to declare a block; this used
 801 #     to work but now is a command, and mysteriously gave no complaint.
 802 #
 803 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 804 #   BUG FIX:
 805 #   + This patch to perl5db.pl cleans up formatting issues on the help
 806 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 807 #     issues, plus converted the printed text to use all spaces, since
 808 #     tabs don't seem to help much here.
 809 #
 810 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 811 #   Minor bugs corrected;
 812 #   + Support for auto-creation of new TTY window on startup, either
 813 #     unconditionally, or if started as a kid of another debugger session;
 814 #   + New `O'ption CreateTTY
 815 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 816 #                         1: on fork()
 817 #                         2: debugger is started inside debugger
 818 #                         4: on startup
 819 #   + Code to auto-create a new TTY window on OS/2 (currently one
 820 #     extra window per session - need named pipes to have more...);
 821 #   + Simplified interface for custom createTTY functions (with a backward
 822 #     compatibility hack); now returns the TTY name to use; return of ''
 823 #     means that the function reset the I/O handles itself;
 824 #   + Better message on the semantic of custom createTTY function;
 825 #   + Convert the existing code to create a TTY into a custom createTTY
 826 #     function;
 827 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 828 #   + Switch line-tracing output too to the created TTY window;
 829 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 830 #   + High-level debugger API cmd_*():
 831 #      cmd_b_load($filenamepart)            # b load filenamepart
 832 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 833 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 834 #      cmd_stop()                           # Control-C
 835 #      cmd_d($lineno)                       # d lineno (B)
 836 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 837 #      the error message to the debugging output.
 838 #   + Low-level debugger API
 839 #      break_on_load($filename)             # b load filename
 840 #      @files = report_break_on_load()      # List files with load-breakpoints
 841 #      breakable_line_in_filename($name, $from [, $to])
 842 #                                           # First breakable line in the
 843 #                                           # range $from .. $to.  $to defaults
 844 #                                           # to $from, and may be less than
 845 #                                           # $to
 846 #      breakable_line($from [, $to])        # Same for the current file
 847 #      break_on_filename_line($name, $lineno [, $cond])
 848 #                                           # Set breakpoint,$cond defaults to
 849 #                                           # 1
 850 #      break_on_filename_line_range($name, $from, $to [, $cond])
 851 #                                           # As above, on the first
 852 #                                           # breakable line in range
 853 #      break_on_line($lineno [, $cond])     # As above, in the current file
 854 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 855 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 856 #                                           # The range of lines of the text
 857 #      The low-level API returns TRUE on success, and die()s on failure.
 858 #
 859 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 860 #   BUG FIXES:
 861 #   + Fixed warnings generated by "perl -dWe 42"
 862 #   + Corrected spelling errors
 863 #   + Squeezed Help (h) output into 80 columns
 864 #
 865 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 866 #   + Made "x @INC" work like it used to
 867 #
 868 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 869 #   + Fixed warnings generated by "O" (Show debugger options)
 870 #   + Fixed warnings generated by "p 42" (Print expression)
 871 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 872 #   + Added windowSize option
 873 # Changes: 1.14: Oct  9, 2001 multiple
 874 #   + Clean up after itself on VMS (Charles Lane in 12385)
 875 #   + Adding "@ file" syntax (Peter Scott in 12014)
 876 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 877 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 878 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 879 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 880 #   + Updated 1.14 change log
 881 #   + Added *dbline explainatory comments
 882 #   + Mentioning perldebguts man page
 883 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 884 #   + $onetimeDump improvements
 885 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 886 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 887 #   rationalised the following commands and added cmd_wrapper() to
 888 #   enable switching between old and frighteningly consistent new
 889 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 890 #     a(add),       A(del)            # action expr   (added del by line)
 891 #   + b(add),       B(del)            # break  [line] (was b,D)
 892 #   + w(add),       W(del)            # watch  expr   (was W,W)
 893 #                                     # added del by expr
 894 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 895 #   + m(methods),   M(modules)        # ...           (was m,v)
 896 #   + o(option)                       # lc            (was O)
 897 #   + v(view code), V(view Variables) # ...           (was w,V)
 898 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 899 #   + fixed missing cmd_O bug
 900 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 901 #   + Added missing local()s -- DB::DB is called recursively.
 902 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 903 #   + pre'n'post commands no longer trashed with no args
 904 #   + watch val joined out of eval()
 905 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 906 #   + Added comments and reformatted source. No bug fixes/enhancements.
 907 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 908 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 909 #   + Flush stdout/stderr before the debugger prompt is printed.
 910 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 911 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 912 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 913 #   + Added command to save all debugger commands for sourcing later.
 914 #   + Added command to display parent inheritance tree of given class.
 915 #   + Fixed minor newline in history bug.
 916 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 917 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 918 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 919 #   + unfork the 5.8.x and 5.9.x debuggers.
 920 #   + whitespace and assertions call cleanup across versions
 921 #   + H * deletes (resets) history
 922 #   + i now handles Class + blessed objects
 923 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 924 #   + updated pod page references - clunky.
 925 #   + removed windowid restriction for forking into an xterm.
 926 #   + more whitespace again.
 927 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 928 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 929 #   + Added threads support (inc. e and E commands)
 930 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com>
 931 #   + Added macosx_get_fork_TTY support
 932 ########################################################################
 933
 934 =head1 DEBUGGER INITIALIZATION
 935
 936 The debugger starts up in phases.
 937
 938 =head2 BASIC SETUP
 939
 940 First, it initializes the environment it wants to run in: turning off
 941 warnings during its own compilation, defining variables which it will need
 942 to avoid warnings later, setting itself up to not exit when the program
 943 terminates, and defaulting to printing return values for the C<r> command.
 944
 945 =cut
 946
 947 # Needed for the statement after exec():
 948 #
 949 # This BEGIN block is simply used to switch off warnings during debugger
 950 # compiliation. Probably it would be better practice to fix the warnings,
 951 # but this is how it's done at the moment.
 952
 953 BEGIN {
 954     $ini_warn = $^W;
 955     $^W       = 0;
 956 }    # Switch compilation warnings off until another BEGIN.
 957
 958 # test if assertions are supported and actived:
 959 BEGIN {
 960     $ini_assertion = eval "sub asserting_test : assertion {1}; 1";
 961
 962     # $ini_assertion = undef => assertions unsupported,
 963     #        "       = 1     => assertions supported
 964     # print "\$ini_assertion=$ini_assertion\n";
 965 }
 966
 967 local ($^W) = 0;    # Switch run-time warnings off during init.
 968
 969 =head2 THREADS SUPPORT
 970
 971 If we are running under a threaded Perl, we require threads and threads::shared
 972 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 973 threaded debugger control.  C<-dt> can also be used to set this.
 974
 975 Each new thread will be announced and the debugger prompt will always inform
 976 you of each new thread created.  It will also indicate the thread id in which
 977 we are currently running within the prompt like this:
 978
 979         [tid] DB<$i>
 980
 981 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 982 command prompt.  The prompt will show: C<[0]> when running under threads, but
 983 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 984
 985 While running under threads, when you set or delete a breakpoint (etc.), this
 986 will apply to all threads, not just the currently running one.  When you are
 987 in a currently executing thread, you will stay there until it completes.  With
 988 the current implementation it is not currently possible to hop from one thread
 989 to another.
 990
 991 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 992
 993 Note that threading support was built into the debugger as of Perl version
 994 C<5.8.6> and debugger version C<1.2.8>.
 995
 996 =cut
 997
 998 BEGIN {
 999   # ensure we can share our non-threaded variables or no-op
1000   if ($ENV{PERL5DB_THREADED}) {
1001         require threads;
1002         require threads::shared;
1003         import threads::shared qw(share);
1004         $DBGR;
1005         share(\$DBGR);
1006         lock($DBGR);
1007         print "Threads support enabled\n";
1008   } else {
1009         *lock  = sub(*) {};
1010         *share = sub(*) {};
1011   }
1012 }
1013
1014 # This would probably be better done with "use vars", but that wasn't around
1015 # when this code was originally written. (Neither was "use strict".) And on
1016 # the principle of not fiddling with something that was working, this was
1017 # left alone.
1018 warn(               # Do not ;-)
1019     # These variables control the execution of 'dumpvar.pl'.
1020     $dumpvar::hashDepth,
1021     $dumpvar::arrayDepth,
1022     $dumpvar::dumpDBFiles,
1023     $dumpvar::dumpPackages,
1024     $dumpvar::quoteHighBit,
1025     $dumpvar::printUndef,
1026     $dumpvar::globPrint,
1027     $dumpvar::usageOnly,
1028
1029     # used to save @ARGV and extract any debugger-related flags.
1030     @ARGS,
1031
1032     # used to control die() reporting in diesignal()
1033     $Carp::CarpLevel,
1034
1035     # used to prevent multiple entries to diesignal()
1036     # (if for instance diesignal() itself dies)
1037     $panic,
1038
1039     # used to prevent the debugger from running nonstop
1040     # after a restart
1041     $second_time,
1042   )
1043   if 0;
1044
1045 foreach my $k (keys (%INC)) {
1046         &share(\$main::{'_<'.$filename});
1047 };
1048
1049 # Command-line + PERLLIB:
1050 # Save the contents of @INC before they are modified elsewhere.
1051 @ini_INC = @INC;
1052
1053 # This was an attempt to clear out the previous values of various
1054 # trapped errors. Apparently it didn't help. XXX More info needed!
1055 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1056
1057 # We set these variables to safe values. We don't want to blindly turn
1058 # off warnings, because other packages may still want them.
1059 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1060                                    # (local $^W cannot help - other packages!).
1061
1062 # Default to not exiting when program finishes; print the return
1063 # value when the 'r' command is used to return from a subroutine.
1064 $inhibit_exit = $option{PrintRet} = 1;
1065
1066 =head1 OPTION PROCESSING
1067
1068 The debugger's options are actually spread out over the debugger itself and
1069 C<dumpvar.pl>; some of these are variables to be set, while others are
1070 subs to be called with a value. To try to make this a little easier to
1071 manage, the debugger uses a few data structures to define what options
1072 are legal and how they are to be processed.
1073
1074 First, the C<@options> array defines the I<names> of all the options that
1075 are to be accepted.
1076
1077 =cut
1078
1079 @options = qw(
1080   CommandSet
1081   hashDepth    arrayDepth    dumpDepth
1082   DumpDBFiles  DumpPackages  DumpReused
1083   compactDump  veryCompact   quote
1084   HighBit      undefPrint    globPrint
1085   PrintRet     UsageOnly     frame
1086   AutoTrace    TTY           noTTY
1087   ReadLine     NonStop       LineInfo
1088   maxTraceLen  recallCommand ShellBang
1089   pager        tkRunning     ornaments
1090   signalLevel  warnLevel     dieLevel
1091   inhibit_exit ImmediateStop bareStringify
1092   CreateTTY    RemotePort    windowSize
1093   DollarCaretP OnlyAssertions WarnAssertions
1094 );
1095
1096 @RememberOnROptions = qw(DollarCaretP OnlyAssertions);
1097
1098 =pod
1099
1100 Second, C<optionVars> lists the variables that each option uses to save its
1101 state.
1102
1103 =cut
1104
1105 %optionVars = (
1106     hashDepth     => \$dumpvar::hashDepth,
1107     arrayDepth    => \$dumpvar::arrayDepth,
1108     CommandSet    => \$CommandSet,
1109     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1110     DumpPackages  => \$dumpvar::dumpPackages,
1111     DumpReused    => \$dumpvar::dumpReused,
1112     HighBit       => \$dumpvar::quoteHighBit,
1113     undefPrint    => \$dumpvar::printUndef,
1114     globPrint     => \$dumpvar::globPrint,
1115     UsageOnly     => \$dumpvar::usageOnly,
1116     CreateTTY     => \$CreateTTY,
1117     bareStringify => \$dumpvar::bareStringify,
1118     frame         => \$frame,
1119     AutoTrace     => \$trace,
1120     inhibit_exit  => \$inhibit_exit,
1121     maxTraceLen   => \$maxtrace,
1122     ImmediateStop => \$ImmediateStop,
1123     RemotePort    => \$remoteport,
1124     windowSize    => \$window,
1125     WarnAssertions => \$warnassertions,
1126 );
1127
1128 =pod
1129
1130 Third, C<%optionAction> defines the subroutine to be called to process each
1131 option.
1132
1133 =cut
1134
1135 %optionAction = (
1136     compactDump   => \&dumpvar::compactDump,
1137     veryCompact   => \&dumpvar::veryCompact,
1138     quote         => \&dumpvar::quote,
1139     TTY           => \&TTY,
1140     noTTY         => \&noTTY,
1141     ReadLine      => \&ReadLine,
1142     NonStop       => \&NonStop,
1143     LineInfo      => \&LineInfo,
1144     recallCommand => \&recallCommand,
1145     ShellBang     => \&shellBang,
1146     pager         => \&pager,
1147     signalLevel   => \&signalLevel,
1148     warnLevel     => \&warnLevel,
1149     dieLevel      => \&dieLevel,
1150     tkRunning     => \&tkRunning,
1151     ornaments     => \&ornaments,
1152     RemotePort    => \&RemotePort,
1153     DollarCaretP  => \&DollarCaretP,
1154     OnlyAssertions=> \&OnlyAssertions,
1155 );
1156
1157 =pod
1158
1159 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1160 option is used.
1161
1162 =cut
1163
1164 # Note that this list is not complete: several options not listed here
1165 # actually require that dumpvar.pl be loaded for them to work, but are
1166 # not in the table. A subsequent patch will correct this problem; for
1167 # the moment, we're just recommenting, and we are NOT going to change
1168 # function.
1169 %optionRequire = (
1170     compactDump => 'dumpvar.pl',
1171     veryCompact => 'dumpvar.pl',
1172     quote       => 'dumpvar.pl',
1173 );
1174
1175 =pod
1176
1177 There are a number of initialization-related variables which can be set
1178 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1179 variable. These are:
1180
1181 =over 4
1182
1183 =item C<$rl> - readline control XXX needs more explanation
1184
1185 =item C<$warnLevel> - whether or not debugger takes over warning handling
1186
1187 =item C<$dieLevel> - whether or not debugger takes over die handling
1188
1189 =item C<$signalLevel> - whether or not debugger takes over signal handling
1190
1191 =item C<$pre> - preprompt actions (array reference)
1192
1193 =item C<$post> - postprompt actions (array reference)
1194
1195 =item C<$pretype>
1196
1197 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1198
1199 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1200
1201 =back
1202
1203 =cut
1204
1205 # These guys may be defined in $ENV{PERL5DB} :
1206 $rl          = 1     unless defined $rl;
1207 $warnLevel   = 1     unless defined $warnLevel;
1208 $dieLevel    = 1     unless defined $dieLevel;
1209 $signalLevel = 1     unless defined $signalLevel;
1210 $pre         = []    unless defined $pre;
1211 $post        = []    unless defined $post;
1212 $pretype     = []    unless defined $pretype;
1213 $CreateTTY   = 3     unless defined $CreateTTY;
1214 $CommandSet  = '580' unless defined $CommandSet;
1215
1216 share($rl);
1217 share($warnLevel);
1218 share($dieLevel);
1219 share($signalLevel);
1220 share($pre);
1221 share($post);
1222 share($pretype);
1223 share($rl);
1224 share($CreateTTY);
1225 share($CommandSet);
1226
1227 =pod
1228
1229 The default C<die>, C<warn>, and C<signal> handlers are set up.
1230
1231 =cut
1232
1233 warnLevel($warnLevel);
1234 dieLevel($dieLevel);
1235 signalLevel($signalLevel);
1236
1237 =pod
1238
1239 The pager to be used is needed next. We try to get it from the
1240 environment first.  if it's not defined there, we try to find it in
1241 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1242 then call the C<pager()> function to save the pager name.
1243
1244 =cut
1245
1246 # This routine makes sure $pager is set up so that '|' can use it.
1247 pager(
1248
1249     # If PAGER is defined in the environment, use it.
1250     defined $ENV{PAGER}
1251     ? $ENV{PAGER}
1252
1253       # If not, see if Config.pm defines it.
1254     : eval { require Config }
1255       && defined $Config::Config{pager}
1256     ? $Config::Config{pager}
1257
1258       # If not, fall back to 'more'.
1259     : 'more'
1260   )
1261   unless defined $pager;
1262
1263 =pod
1264
1265 We set up the command to be used to access the man pages, the command
1266 recall character (C<!> unless otherwise defined) and the shell escape
1267 character (C<!> unless otherwise defined). Yes, these do conflict, and
1268 neither works in the debugger at the moment.
1269
1270 =cut
1271
1272 setman();
1273
1274 # Set up defaults for command recall and shell escape (note:
1275 # these currently don't work in linemode debugging).
1276 &recallCommand("!") unless defined $prc;
1277 &shellBang("!")     unless defined $psh;
1278
1279 =pod
1280
1281 We then set up the gigantic string containing the debugger help.
1282 We also set the limit on the number of arguments we'll display during a
1283 trace.
1284
1285 =cut
1286
1287 sethelp();
1288
1289 # If we didn't get a default for the length of eval/stack trace args,
1290 # set it here.
1291 $maxtrace = 400 unless defined $maxtrace;
1292
1293 =head2 SETTING UP THE DEBUGGER GREETING
1294
1295 The debugger I<greeting> helps to inform the user how many debuggers are
1296 running, and whether the current debugger is the primary or a child.
1297
1298 If we are the primary, we just hang onto our pid so we'll have it when
1299 or if we start a child debugger. If we are a child, we'll set things up
1300 so we'll have a unique greeting and so the parent will give us our own
1301 TTY later.
1302
1303 We save the current contents of the C<PERLDB_PIDS> environment variable
1304 because we mess around with it. We'll also need to hang onto it because
1305 we'll need it if we restart.
1306
1307 Child debuggers make a label out of the current PID structure recorded in
1308 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1309 yet so the parent will give them one later via C<resetterm()>.
1310
1311 =cut
1312
1313 # Save the current contents of the environment; we're about to
1314 # much with it. We'll need this if we have to restart.
1315 $ini_pids = $ENV{PERLDB_PIDS};
1316
1317 if ( defined $ENV{PERLDB_PIDS} ) {
1318
1319     # We're a child. Make us a label out of the current PID structure
1320     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1321     # a term yet so the parent will give us one later via resetterm().
1322
1323     my $env_pids = $ENV{PERLDB_PIDS};
1324     $pids = "[$env_pids]";
1325
1326     # Unless we are on OpenVMS, all programs under the DCL shell run under
1327     # the same PID.
1328
1329     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1330         $term_pid         = $$;
1331     }
1332     else {
1333         $ENV{PERLDB_PIDS} .= "->$$";
1334         $term_pid = -1;
1335     }
1336
1337 } ## end if (defined $ENV{PERLDB_PIDS...
1338 else {
1339
1340     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1341     # child debugger, and mark us as the parent, so we'll know to set up
1342     # more TTY's is we have to.
1343     $ENV{PERLDB_PIDS} = "$$";
1344     $pids             = "[pid=$$]";
1345     $term_pid         = $$;
1346 }
1347
1348 $pidprompt = '';
1349
1350 # Sets up $emacs as a synonym for $slave_editor.
1351 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1352
1353 =head2 READING THE RC FILE
1354
1355 The debugger will read a file of initialization options if supplied. If
1356 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1357
1358 =cut
1359
1360 # As noted, this test really doesn't check accurately that the debugger
1361 # is running at a terminal or not.
1362
1363 if ( -e "/dev/tty" ) {                      # this is the wrong metric!
1364     $rcfile = ".perldb";
1365 }
1366 else {
1367     $rcfile = "perldb.ini";
1368 }
1369
1370 =pod
1371
1372 The debugger does a safety test of the file to be read. It must be owned
1373 either by the current user or root, and must only be writable by the owner.
1374
1375 =cut
1376
1377 # This wraps a safety test around "do" to read and evaluate the init file.
1378 #
1379 # This isn't really safe, because there's a race
1380 # between checking and opening.  The solution is to
1381 # open and fstat the handle, but then you have to read and
1382 # eval the contents.  But then the silly thing gets
1383 # your lexical scope, which is unfortunate at best.
1384 sub safe_do {
1385     my $file = shift;
1386
1387     # Just exactly what part of the word "CORE::" don't you understand?
1388     local $SIG{__WARN__};
1389     local $SIG{__DIE__};
1390
1391     unless ( is_safe_file($file) ) {
1392         CORE::warn <<EO_GRIPE;
1393 perldb: Must not source insecure rcfile $file.
1394         You or the superuser must be the owner, and it must not
1395         be writable by anyone but its owner.
1396 EO_GRIPE
1397         return;
1398     } ## end unless (is_safe_file($file...
1399
1400     do $file;
1401     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1402 } ## end sub safe_do
1403
1404 # This is the safety test itself.
1405 #
1406 # Verifies that owner is either real user or superuser and that no
1407 # one but owner may write to it.  This function is of limited use
1408 # when called on a path instead of upon a handle, because there are
1409 # no guarantees that filename (by dirent) whose file (by ino) is
1410 # eventually accessed is the same as the one tested.
1411 # Assumes that the file's existence is not in doubt.
1412 sub is_safe_file {
1413     my $path = shift;
1414     stat($path) || return;    # mysteriously vaporized
1415     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1416
1417     return 0 if $uid != 0 && $uid != $<;
1418     return 0 if $mode & 022;
1419     return 1;
1420 } ## end sub is_safe_file
1421
1422 # If the rcfile (whichever one we decided was the right one to read)
1423 # exists, we safely do it.
1424 if ( -f $rcfile ) {
1425     safe_do("./$rcfile");
1426 }
1427
1428 # If there isn't one here, try the user's home directory.
1429 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1430     safe_do("$ENV{HOME}/$rcfile");
1431 }
1432
1433 # Else try the login directory.
1434 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1435     safe_do("$ENV{LOGDIR}/$rcfile");
1436 }
1437
1438 # If the PERLDB_OPTS variable has options in it, parse those out next.
1439 if ( defined $ENV{PERLDB_OPTS} ) {
1440     parse_options( $ENV{PERLDB_OPTS} );
1441 }
1442
1443 =pod
1444
1445 The last thing we do during initialization is determine which subroutine is
1446 to be used to obtain a new terminal when a new debugger is started. Right now,
1447 the debugger only handles X Windows, OS/2, and Mac OS X (darwin).
1448
1449 =cut
1450
1451 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1452 # Works if you're running an xterm or xterm-like window, or you're on
1453 # OS/2, or on Mac OS X. This may need some expansion.
1454
1455 if (not defined &get_fork_TTY)       # only if no routine exists
1456 {
1457     if (defined $ENV{TERM}                       # If we know what kind
1458                                                  # of terminal this is,
1459         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1460         and defined $ENV{DISPLAY}                # and what display it's on,
1461       )
1462     {
1463         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1464     }
1465     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1466         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1467     }
1468     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1469             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1470             and $ENV{TERM_PROGRAM}
1471                 eq 'Apple_Terminal'              # Terminal.app
1472             )
1473     {
1474         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1475     }
1476 } ## end if (not defined &get_fork_TTY...
1477
1478 # untaint $^O, which may have been tainted by the last statement.
1479 # see bug [perl #24674]
1480 $^O =~ m/^(.*)\z/;
1481 $^O = $1;
1482
1483 # Here begin the unreadable code.  It needs fixing.
1484
1485 =head2 RESTART PROCESSING
1486
1487 This section handles the restart command. When the C<R> command is invoked, it
1488 tries to capture all of the state it can into environment variables, and
1489 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1490 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1491 the R command stuffed into the environment variables.
1492
1493   PERLDB_RESTART   - flag only, contains no restart data itself.
1494   PERLDB_HIST      - command history, if it's available
1495   PERLDB_ON_LOAD   - breakpoints set by the rc file
1496   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1497   PERLDB_VISITED   - files that had breakpoints
1498   PERLDB_FILE_...  - breakpoints for a file
1499   PERLDB_OPT       - active options
1500   PERLDB_INC       - the original @INC
1501   PERLDB_PRETYPE   - preprompt debugger actions
1502   PERLDB_PRE       - preprompt Perl code
1503   PERLDB_POST      - post-prompt Perl code
1504   PERLDB_TYPEAHEAD - typeahead captured by readline()
1505
1506 We chug through all these variables and plug the values saved in them
1507 back into the appropriate spots in the debugger.
1508
1509 =cut
1510
1511 if ( exists $ENV{PERLDB_RESTART} ) {
1512
1513     # We're restarting, so we don't need the flag that says to restart anymore.
1514     delete $ENV{PERLDB_RESTART};
1515
1516     # $restart = 1;
1517     @hist          = get_list('PERLDB_HIST');
1518     %break_on_load = get_list("PERLDB_ON_LOAD");
1519     %postponed     = get_list("PERLDB_POSTPONE");
1520
1521         share(@hist);
1522         share(@truehist);
1523         share(%break_on_load);
1524         share(%postponed);
1525
1526     # restore breakpoints/actions
1527     my @had_breakpoints = get_list("PERLDB_VISITED");
1528     for ( 0 .. $#had_breakpoints ) {
1529         my %pf = get_list("PERLDB_FILE_$_");
1530         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1531     }
1532
1533     # restore options
1534     my %opt = get_list("PERLDB_OPT");
1535     my ( $opt, $val );
1536     while ( ( $opt, $val ) = each %opt ) {
1537         $val =~ s/[\\\']/\\$1/g;
1538         parse_options("$opt'$val'");
1539     }
1540
1541     # restore original @INC
1542     @INC     = get_list("PERLDB_INC");
1543     @ini_INC = @INC;
1544
1545     # return pre/postprompt actions and typeahead buffer
1546     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1547     $pre       = [ get_list("PERLDB_PRE") ];
1548     $post      = [ get_list("PERLDB_POST") ];
1549     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1550 } ## end if (exists $ENV{PERLDB_RESTART...
1551
1552 =head2 SETTING UP THE TERMINAL
1553
1554 Now, we'll decide how the debugger is going to interact with the user.
1555 If there's no TTY, we set the debugger to run non-stop; there's not going
1556 to be anyone there to enter commands.
1557
1558 =cut
1559
1560 if ($notty) {
1561     $runnonstop = 1;
1562         share($runnonstop);
1563 }
1564
1565 =pod
1566
1567 If there is a TTY, we have to determine who it belongs to before we can
1568 proceed. If this is a slave editor or graphical debugger (denoted by
1569 the first command-line switch being '-emacs'), we shift this off and
1570 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1571
1572 =cut
1573
1574 else {
1575
1576     # Is Perl being run from a slave editor or graphical debugger?
1577     # If so, don't use readline, and set $slave_editor = 1.
1578     $slave_editor =
1579       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1580     $rl = 0, shift(@main::ARGV) if $slave_editor;
1581
1582     #require Term::ReadLine;
1583
1584 =pod
1585
1586 We then determine what the console should be on various systems:
1587
1588 =over 4
1589
1590 =item * Cygwin - We use C<stdin> instead of a separate device.
1591
1592 =cut
1593
1594     if ( $^O eq 'cygwin' ) {
1595
1596         # /dev/tty is binary. use stdin for textmode
1597         undef $console;
1598     }
1599
1600 =item * Unix - use C</dev/tty>.
1601
1602 =cut
1603
1604     elsif ( -e "/dev/tty" ) {
1605         $console = "/dev/tty";
1606     }
1607
1608 =item * Windows or MSDOS - use C<con>.
1609
1610 =cut
1611
1612     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1613         $console = "con";
1614     }
1615
1616 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1617 Console> if not.
1618
1619 Note that Mac OS X returns C<darwin>, not C<MacOS>. Also note that the debugger doesn't do anything special for C<darwin>. Maybe it should.
1620
1621 =cut
1622
1623     elsif ( $^O eq 'MacOS' ) {
1624         if ( $MacPerl::Version !~ /MPW/ ) {
1625             $console =
1626               "Dev:Console:Perl Debug";    # Separate window for application
1627         }
1628         else {
1629             $console = "Dev:Console";
1630         }
1631     } ## end elsif ($^O eq 'MacOS')
1632
1633 =item * VMS - use C<sys$command>.
1634
1635 =cut
1636
1637     else {
1638
1639         # everything else is ...
1640         $console = "sys\$command";
1641     }
1642
1643 =pod
1644
1645 =back
1646
1647 Several other systems don't use a specific console. We C<undef $console>
1648 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1649 with a slave editor, Epoc).
1650
1651 =cut
1652
1653     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1654
1655         # /dev/tty is binary. use stdin for textmode
1656         $console = undef;
1657     }
1658
1659     if ( $^O eq 'NetWare' ) {
1660
1661         # /dev/tty is binary. use stdin for textmode
1662         $console = undef;
1663     }
1664
1665     # In OS/2, we need to use STDIN to get textmode too, even though
1666     # it pretty much looks like Unix otherwise.
1667     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1668     {    # In OS/2
1669         $console = undef;
1670     }
1671
1672     # EPOC also falls into the 'got to use STDIN' camp.
1673     if ( $^O eq 'epoc' ) {
1674         $console = undef;
1675     }
1676
1677 =pod
1678
1679 If there is a TTY hanging around from a parent, we use that as the console.
1680
1681 =cut
1682
1683     $console = $tty if defined $tty;
1684
1685 =head2 SOCKET HANDLING
1686
1687 The debugger is capable of opening a socket and carrying out a debugging
1688 session over the socket.
1689
1690 If C<RemotePort> was defined in the options, the debugger assumes that it
1691 should try to start a debugging session on that port. It builds the socket
1692 and then tries to connect the input and output filehandles to it.
1693
1694 =cut
1695
1696     # Handle socket stuff.
1697
1698     if ( defined $remoteport ) {
1699
1700         # If RemotePort was defined in the options, connect input and output
1701         # to the socket.
1702         require IO::Socket;
1703         $OUT = new IO::Socket::INET(
1704             Timeout  => '10',
1705             PeerAddr => $remoteport,
1706             Proto    => 'tcp',
1707         );
1708         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1709         $IN = $OUT;
1710     } ## end if (defined $remoteport)
1711
1712 =pod
1713
1714 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1715 this is probably a situation where multiple debuggers are running (for example,
1716 a backticked command that starts up another debugger). We create a new IN and
1717 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1718 and if we can.
1719
1720 =cut
1721
1722     # Non-socket.
1723     else {
1724
1725         # Two debuggers running (probably a system or a backtick that invokes
1726         # the debugger itself under the running one). create a new IN and OUT
1727         # filehandle, and do the necessary mojo to create a new tty if we
1728         # know how, and we can.
1729         create_IN_OUT(4) if $CreateTTY & 4;
1730         if ($console) {
1731
1732             # If we have a console, check to see if there are separate ins and
1733             # outs to open. (They are assumed identical if not.)
1734
1735             my ( $i, $o ) = split /,/, $console;
1736             $o = $i unless defined $o;
1737
1738             # read/write on in, or just read, or read on STDIN.
1739             open( IN,      "+<$i" )
1740               || open( IN, "<$i" )
1741               || open( IN, "<&STDIN" );
1742
1743             # read/write/create/clobber out, or write/create/clobber out,
1744             # or merge with STDERR, or merge with STDOUT.
1745                  open( OUT, "+>$o" )
1746               || open( OUT, ">$o" )
1747               || open( OUT, ">&STDERR" )
1748               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1749
1750         } ## end if ($console)
1751         elsif ( not defined $console ) {
1752
1753             # No console. Open STDIN.
1754             open( IN, "<&STDIN" );
1755
1756             # merge with STDERR, or with STDOUT.
1757             open( OUT,      ">&STDERR" )
1758               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1759             $console = 'STDIN/OUT';
1760         } ## end elsif (not defined $console)
1761
1762         # Keep copies of the filehandles so that when the pager runs, it
1763         # can close standard input without clobbering ours.
1764         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1765     } ## end elsif (from if(defined $remoteport))
1766
1767     # Unbuffer DB::OUT. We need to see responses right away.
1768     my $previous = select($OUT);
1769     $| = 1;                                  # for DB::OUT
1770     select($previous);
1771
1772     # Line info goes to debugger output unless pointed elsewhere.
1773     # Pointing elsewhere makes it possible for slave editors to
1774     # keep track of file and position. We have both a filehandle
1775     # and a I/O description to keep track of.
1776     $LINEINFO = $OUT     unless defined $LINEINFO;
1777     $lineinfo = $console unless defined $lineinfo;
1778         # share($LINEINFO); # <- unable to share globs
1779         share($lineinfo);   #
1780
1781 =pod
1782
1783 To finish initialization, we show the debugger greeting,
1784 and then call the C<afterinit()> subroutine if there is one.
1785
1786 =cut
1787
1788     # Show the debugger greeting.
1789     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1790     unless ($runnonstop) {
1791         local $\ = '';
1792         local $, = '';
1793         if ( $term_pid eq '-1' ) {
1794             print $OUT "\nDaughter DB session started...\n";
1795         }
1796         else {
1797             print $OUT "\nLoading DB routines from $header\n";
1798             print $OUT (
1799                 "Editor support ",
1800                 $slave_editor ? "enabled" : "available", ".\n"
1801             );
1802             print $OUT
1803 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1804         } ## end else [ if ($term_pid eq '-1')
1805     } ## end unless ($runnonstop)
1806 } ## end else [ if ($notty)
1807
1808 # XXX This looks like a bug to me.
1809 # Why copy to @ARGS and then futz with @args?
1810 @ARGS = @ARGV;
1811 for (@args) {
1812     # Make sure backslashes before single quotes are stripped out, and
1813     # keep args unless they are numeric (XXX why?)
1814     # s/\'/\\\'/g;                      # removed while not justified understandably
1815     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1816 }
1817
1818 # If there was an afterinit() sub defined, call it. It will get
1819 # executed in our scope, so it can fiddle with debugger globals.
1820 if ( defined &afterinit ) {    # May be defined in $rcfile
1821     &afterinit();
1822 }
1823
1824 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1825 $I_m_init = 1;
1826
1827 ############################################################ Subroutines
1828
1829 =head1 SUBROUTINES
1830
1831 =head2 DB
1832
1833 This gigantic subroutine is the heart of the debugger. Called before every
1834 statement, its job is to determine if a breakpoint has been reached, and
1835 stop if so; read commands from the user, parse them, and execute
1836 them, and hen send execution off to the next statement.
1837
1838 Note that the order in which the commands are processed is very important;
1839 some commands earlier in the loop will actually alter the C<$cmd> variable
1840 to create other commands to be executed later. This is all highly I<optimized>
1841 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1842 see what's happening in any given command.
1843
1844 =cut
1845
1846 sub DB {
1847
1848     # lock the debugger and get the thread id for the prompt
1849         lock($DBGR);
1850         my $tid;
1851         if ($ENV{PERL5DB_THREADED}) {
1852                 $tid = eval { "[".threads->tid."]" };
1853         }
1854
1855     # Check for whether we should be running continuously or not.
1856     # _After_ the perl program is compiled, $single is set to 1:
1857     if ( $single and not $second_time++ ) {
1858
1859         # Options say run non-stop. Run until we get an interrupt.
1860         if ($runnonstop) {    # Disable until signal
1861                 # If there's any call stack in place, turn off single
1862                 # stepping into subs throughout the stack.
1863             for ( $i = 0 ; $i <= $stack_depth ; ) {
1864                 $stack[ $i++ ] &= ~1;
1865             }
1866
1867             # And we are now no longer in single-step mode.
1868             $single = 0;
1869
1870             # If we simply returned at this point, we wouldn't get
1871             # the trace info. Fall on through.
1872             # return;
1873         } ## end if ($runnonstop)
1874
1875         elsif ($ImmediateStop) {
1876
1877             # We are supposed to stop here; XXX probably a break.
1878             $ImmediateStop = 0;    # We've processed it; turn it off
1879             $signal        = 1;    # Simulate an interrupt to force
1880                                    # us into the command loop
1881         }
1882     } ## end if ($single and not $second_time...
1883
1884     # If we're in single-step mode, or an interrupt (real or fake)
1885     # has occurred, turn off non-stop mode.
1886     $runnonstop = 0 if $single or $signal;
1887
1888     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1889     # The code being debugged may have altered them.
1890     &save;
1891
1892     # Since DB::DB gets called after every line, we can use caller() to
1893     # figure out where we last were executing. Sneaky, eh? This works because
1894     # caller is returning all the extra information when called from the
1895     # debugger.
1896     local ( $package, $filename, $line ) = caller;
1897     local $filename_ini = $filename;
1898
1899     # set up the context for DB::eval, so it can properly execute
1900     # code on behalf of the user. We add the package in so that the
1901     # code is eval'ed in the proper package (not in the debugger!).
1902     local $usercontext =
1903       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1904
1905     # Create an alias to the active file magical array to simplify
1906     # the code here.
1907     local (*dbline) = $main::{ '_<' . $filename };
1908
1909     # we need to check for pseudofiles on Mac OS (these are files
1910     # not attached to a filename, but instead stored in Dev:Pseudo)
1911     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1912         $filename_ini = $filename = 'Dev:Pseudo';
1913         *dbline = $main::{ '_<' . $filename };
1914     }
1915
1916     # Last line in the program.
1917     local $max = $#dbline;
1918
1919     # if we have something here, see if we should break.
1920     if ( $dbline{$line}
1921         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1922     {
1923
1924         # Stop if the stop criterion says to just stop.
1925         if ( $stop eq '1' ) {
1926             $signal |= 1;
1927         }
1928
1929         # It's a conditional stop; eval it in the user's context and
1930         # see if we should stop. If so, remove the one-time sigil.
1931         elsif ($stop) {
1932             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1933             &eval;
1934             $dbline{$line} =~ s/;9($|\0)/$1/;
1935         }
1936     } ## end if ($dbline{$line} && ...
1937
1938     # Preserve the current stop-or-not, and see if any of the W
1939     # (watch expressions) has changed.
1940     my $was_signal = $signal;
1941
1942     # If we have any watch expressions ...
1943     if ( $trace & 2 ) {
1944         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1945             $evalarg = $to_watch[$n];
1946             local $onetimeDump;    # Tell DB::eval() to not output results
1947
1948             # Fix context DB::eval() wants to return an array, but
1949             # we need a scalar here.
1950             my ($val) = join( "', '", &eval );
1951             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1952
1953             # Did it change?
1954             if ( $val ne $old_watch[$n] ) {
1955
1956                 # Yep! Show the difference, and fake an interrupt.
1957                 $signal = 1;
1958                 print $OUT <<EOP;
1959 Watchpoint $n:\t$to_watch[$n] changed:
1960     old value:\t$old_watch[$n]
1961     new value:\t$val
1962 EOP
1963                 $old_watch[$n] = $val;
1964             } ## end if ($val ne $old_watch...
1965         } ## end for (my $n = 0 ; $n <= ...
1966     } ## end if ($trace & 2)
1967
1968 =head2 C<watchfunction()>
1969
1970 C<watchfunction()> is a function that can be defined by the user; it is a
1971 function which will be run on each entry to C<DB::DB>; it gets the
1972 current package, filename, and line as its parameters.
1973
1974 The watchfunction can do anything it likes; it is executing in the
1975 debugger's context, so it has access to all of the debugger's internal
1976 data structures and functions.
1977
1978 C<watchfunction()> can control the debugger's actions. Any of the following
1979 will cause the debugger to return control to the user's program after
1980 C<watchfunction()> executes:
1981
1982 =over 4
1983
1984 =item *
1985
1986 Returning a false value from the C<watchfunction()> itself.
1987
1988 =item *
1989
1990 Altering C<$single> to a false value.
1991
1992 =item *
1993
1994 Altering C<$signal> to a false value.
1995
1996 =item *
1997
1998 Turning off the C<4> bit in C<$trace> (this also disables the
1999 check for C<watchfunction()>. This can be done with
2000
2001     $trace &= ~4;
2002
2003 =back
2004
2005 =cut
2006
2007     # If there's a user-defined DB::watchfunction, call it with the
2008     # current package, filename, and line. The function executes in
2009     # the DB:: package.
2010     if ( $trace & 4 ) {    # User-installed watch
2011         return
2012           if watchfunction( $package, $filename, $line )
2013           and not $single
2014           and not $was_signal
2015           and not( $trace & ~4 );
2016     } ## end if ($trace & 4)
2017
2018     # Pick up any alteration to $signal in the watchfunction, and
2019     # turn off the signal now.
2020     $was_signal = $signal;
2021     $signal     = 0;
2022
2023 =head2 GETTING READY TO EXECUTE COMMANDS
2024
2025 The debugger decides to take control if single-step mode is on, the
2026 C<t> command was entered, or the user generated a signal. If the program
2027 has fallen off the end, we set things up so that entering further commands
2028 won't cause trouble, and we say that the program is over.
2029
2030 =cut
2031
2032     # Check to see if we should grab control ($single true,
2033     # trace set appropriately, or we got a signal).
2034     if ( $single || ( $trace & 1 ) || $was_signal ) {
2035
2036         # Yes, grab control.
2037         if ($slave_editor) {
2038
2039             # Tell the editor to update its position.
2040             $position = "\032\032$filename:$line:0\n";
2041             print_lineinfo($position);
2042         }
2043
2044 =pod
2045
2046 Special check: if we're in package C<DB::fake>, we've gone through the
2047 C<END> block at least once. We set up everything so that we can continue
2048 to enter commands and have a valid context to be in.
2049
2050 =cut
2051
2052         elsif ( $package eq 'DB::fake' ) {
2053
2054             # Fallen off the end already.
2055             $term || &setterm;
2056             print_help(<<EOP);
2057 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2058   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2059   B<h q>, B<h R> or B<h o> to get additional info.
2060 EOP
2061
2062             # Set the DB::eval context appropriately.
2063             $package     = 'main';
2064             $usercontext =
2065                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2066               . "package $package;";    # this won't let them modify, alas
2067         } ## end elsif ($package eq 'DB::fake')
2068
2069 =pod
2070
2071 If the program hasn't finished executing, we scan forward to the
2072 next executable line, print that out, build the prompt from the file and line
2073 number information, and print that.
2074
2075 =cut
2076
2077         else {
2078
2079             # Still somewhere in the midst of execution. Set up the
2080             #  debugger prompt.
2081             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2082                                  # Perl 5 ones (sorry, we don't print Klingon
2083                                  #module names)
2084
2085             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2086             $prefix .= "$sub($filename:";
2087             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2088
2089             # Break up the prompt if it's really long.
2090             if ( length($prefix) > 30 ) {
2091                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2092                 $prefix   = "";
2093                 $infix    = ":\t";
2094             }
2095             else {
2096                 $infix    = "):\t";
2097                 $position = "$prefix$line$infix$dbline[$line]$after";
2098             }
2099
2100             # Print current line info, indenting if necessary.
2101             if ($frame) {
2102                 print_lineinfo( ' ' x $stack_depth,
2103                     "$line:\t$dbline[$line]$after" );
2104             }
2105             else {
2106                 print_lineinfo($position);
2107             }
2108
2109             # Scan forward, stopping at either the end or the next
2110             # unbreakable line.
2111             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2112             {    #{ vi
2113
2114                 # Drop out on null statements, block closers, and comments.
2115                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2116
2117                 # Drop out if the user interrupted us.
2118                 last if $signal;
2119
2120                 # Append a newline if the line doesn't have one. Can happen
2121                 # in eval'ed text, for instance.
2122                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2123
2124                 # Next executable line.
2125                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2126                 $position .= $incr_pos;
2127                 if ($frame) {
2128
2129                     # Print it indented if tracing is on.
2130                     print_lineinfo( ' ' x $stack_depth,
2131                         "$i:\t$dbline[$i]$after" );
2132                 }
2133                 else {
2134                     print_lineinfo($incr_pos);
2135                 }
2136             } ## end for ($i = $line + 1 ; $i...
2137         } ## end else [ if ($slave_editor)
2138     } ## end if ($single || ($trace...
2139
2140 =pod
2141
2142 If there's an action to be executed for the line we stopped at, execute it.
2143 If there are any preprompt actions, execute those as well.
2144
2145 =cut
2146
2147     # If there's an action, do it now.
2148     $evalarg = $action, &eval if $action;
2149
2150     # Are we nested another level (e.g., did we evaluate a function
2151     # that had a breakpoint in it at the debugger prompt)?
2152     if ( $single || $was_signal ) {
2153
2154         # Yes, go down a level.
2155         local $level = $level + 1;
2156
2157         # Do any pre-prompt actions.
2158         foreach $evalarg (@$pre) {
2159             &eval;
2160         }
2161
2162         # Complain about too much recursion if we passed the limit.
2163         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2164           if $single & 4;
2165
2166         # The line we're currently on. Set $incr to -1 to stay here
2167         # until we get a command that tells us to advance.
2168         $start = $line;
2169         $incr  = -1;      # for backward motion.
2170
2171         # Tack preprompt debugger actions ahead of any actual input.
2172         @typeahead = ( @$pretype, @typeahead );
2173
2174 =head2 WHERE ARE WE?
2175
2176 XXX Relocate this section?
2177
2178 The debugger normally shows the line corresponding to the current line of
2179 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2180 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2181
2182 C<$incr> controls by how many lines the I<current> line should move forward
2183 after a command is executed. If set to -1, this indicates that the I<current>
2184 line shouldn't change.
2185
2186 C<$start> is the I<current> line. It is used for things like knowing where to
2187 move forwards or backwards from when doing an C<L> or C<-> command.
2188
2189 C<$max> tells the debugger where the last line of the current file is. It's
2190 used to terminate loops most often.
2191
2192 =head2 THE COMMAND LOOP
2193
2194 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2195 in two parts:
2196
2197 =over 4
2198
2199 =item *
2200
2201 The outer part of the loop, starting at the C<CMD> label. This loop
2202 reads a command and then executes it.
2203
2204 =item *
2205
2206 The inner part of the loop, starting at the C<PIPE> label. This part
2207 is wholly contained inside the C<CMD> block and only executes a command.
2208 Used to handle commands running inside a pager.
2209
2210 =back
2211
2212 So why have two labels to restart the loop? Because sometimes, it's easier to
2213 have a command I<generate> another command and then re-execute the loop to do
2214 the new command. This is faster, but perhaps a bit more convoluted.
2215
2216 =cut
2217
2218         # The big command dispatch loop. It keeps running until the
2219         # user yields up control again.
2220         #
2221         # If we have a terminal for input, and we get something back
2222         # from readline(), keep on processing.
2223       CMD:
2224         while (
2225
2226             # We have a terminal, or can get one ...
2227             ( $term || &setterm ),
2228
2229             # ... and it belogs to this PID or we get one for this PID ...
2230             ( $term_pid == $$ or resetterm(1) ),
2231
2232             # ... and we got a line of command input ...
2233             defined(
2234                 $cmd = &readline(
2235                         "$pidprompt $tid DB"
2236                       . ( '<' x $level )
2237                       . ( $#hist + 1 )
2238                       . ( '>' x $level ) . " "
2239                 )
2240             )
2241           )
2242         {
2243
2244                         share($cmd);
2245             # ... try to execute the input as debugger commands.
2246
2247             # Don't stop running.
2248             $single = 0;
2249
2250             # No signal is active.
2251             $signal = 0;
2252
2253             # Handle continued commands (ending with \):
2254             $cmd =~ s/\\$/\n/ && do {
2255                 $cmd .= &readline("  cont: ");
2256                 redo CMD;
2257             };
2258
2259 =head4 The null command
2260
2261 A newline entered by itself means I<re-execute the last command>. We grab the
2262 command out of C<$laststep> (where it was recorded previously), and copy it
2263 back into C<$cmd> to be executed below. If there wasn't any previous command,
2264 we'll do nothing below (no command will match). If there was, we also save it
2265 in the command history and fall through to allow the command parsing to pick
2266 it up.
2267
2268 =cut
2269
2270             # Empty input means repeat the last command.
2271             $cmd =~ /^$/ && ( $cmd = $laststep );
2272             chomp($cmd);    # get rid of the annoying extra newline
2273             push( @hist, $cmd ) if length($cmd) > 1;
2274             push( @truehist, $cmd );
2275                         share(@hist);
2276                         share(@truehist);
2277
2278             # This is a restart point for commands that didn't arrive
2279             # via direct user input. It allows us to 'redo PIPE' to
2280             # re-execute command processing without reading a new command.
2281           PIPE: {
2282                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2283                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2284                 ($i) = split( /\s+/, $cmd );
2285
2286 =head3 COMMAND ALIASES
2287
2288 The debugger can create aliases for commands (these are stored in the
2289 C<%alias> hash). Before a command is executed, the command loop looks it up
2290 in the alias hash and substitutes the contents of the alias for the command,
2291 completely replacing it.
2292
2293 =cut
2294
2295                 # See if there's an alias for the command, and set it up if so.
2296                 if ( $alias{$i} ) {
2297
2298                     # Squelch signal handling; we want to keep control here
2299                     # if something goes loco during the alias eval.
2300                     local $SIG{__DIE__};
2301                     local $SIG{__WARN__};
2302
2303                     # This is a command, so we eval it in the DEBUGGER's
2304                     # scope! Otherwise, we can't see the special debugger
2305                     # variables, or get to the debugger's subs. (Well, we
2306                     # _could_, but why make it even more complicated?)
2307                     eval "\$cmd =~ $alias{$i}";
2308                     if ($@) {
2309                         local $\ = '';
2310                         print $OUT "Couldn't evaluate `$i' alias: $@";
2311                         next CMD;
2312                     }
2313                 } ## end if ($alias{$i})
2314
2315 =head3 MAIN-LINE COMMANDS
2316
2317 All of these commands work up to and after the program being debugged has
2318 terminated.
2319
2320 =head4 C<q> - quit
2321
2322 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2323 try to execute further, cleaning any restart-related stuff out of the
2324 environment, and executing with the last value of C<$?>.
2325
2326 =cut
2327
2328                 $cmd =~ /^q$/ && do {
2329                     $fall_off_end = 1;
2330                     clean_ENV();
2331                     exit $?;
2332                 };
2333
2334 =head4 C<t> - trace
2335
2336 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2337
2338 =cut
2339
2340                 $cmd =~ /^t$/ && do {
2341                     $trace ^= 1;
2342                     local $\ = '';
2343                     print $OUT "Trace = "
2344                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2345                     next CMD;
2346                 };
2347
2348 =head4 C<S> - list subroutines matching/not matching a pattern
2349
2350 Walks through C<%sub>, checking to see whether or not to print the name.
2351
2352 =cut
2353
2354                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2355
2356                     $Srev     = defined $2;     # Reverse scan?
2357                     $Spatt    = $3;             # The pattern (if any) to use.
2358                     $Snocheck = !defined $1;    # No args - print all subs.
2359
2360                     # Need to make these sane here.
2361                     local $\ = '';
2362                     local $, = '';
2363
2364                     # Search through the debugger's magical hash of subs.
2365                     # If $nocheck is true, just print the sub name.
2366                     # Otherwise, check it against the pattern. We then use
2367                     # the XOR trick to reverse the condition as required.
2368                     foreach $subname ( sort( keys %sub ) ) {
2369                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2370                             print $OUT $subname, "\n";
2371                         }
2372                     }
2373                     next CMD;
2374                 };
2375
2376 =head4 C<X> - list variables in current package
2377
2378 Since the C<V> command actually processes this, just change this to the
2379 appropriate C<V> command and fall through.
2380
2381 =cut
2382
2383                 $cmd =~ s/^X\b/V $package/;
2384
2385 =head4 C<V> - list variables
2386
2387 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2388
2389 =cut
2390
2391                 # Bare V commands get the currently-being-debugged package
2392                 # added.
2393                 $cmd =~ /^V$/ && do {
2394                     $cmd = "V $package";
2395                 };
2396
2397                 # V - show variables in package.
2398                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2399
2400                     # Save the currently selected filehandle and
2401                     # force output to debugger's filehandle (dumpvar
2402                     # just does "print" for output).
2403                     local ($savout) = select($OUT);
2404
2405                     # Grab package name and variables to dump.
2406                     $packname = $1;
2407                     @vars     = split( ' ', $2 );
2408
2409                     # If main::dumpvar isn't here, get it.
2410                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2411                     if ( defined &main::dumpvar ) {
2412
2413                         # We got it. Turn off subroutine entry/exit messages
2414                         # for the moment, along with return values.
2415                         local $frame = 0;
2416                         local $doret = -2;
2417
2418                         # must detect sigpipe failures  - not catching
2419                         # then will cause the debugger to die.
2420                         eval {
2421                             &main::dumpvar(
2422                                 $packname,
2423                                 defined $option{dumpDepth}
2424                                 ? $option{dumpDepth}
2425                                 : -1,    # assume -1 unless specified
2426                                 @vars
2427                             );
2428                         };
2429
2430                         # The die doesn't need to include the $@, because
2431                         # it will automatically get propagated for us.
2432                         if ($@) {
2433                             die unless $@ =~ /dumpvar print failed/;
2434                         }
2435                     } ## end if (defined &main::dumpvar)
2436                     else {
2437
2438                         # Couldn't load dumpvar.
2439                         print $OUT "dumpvar.pl not available.\n";
2440                     }
2441
2442                     # Restore the output filehandle, and go round again.
2443                     select($savout);
2444                     next CMD;
2445                 };
2446
2447 =head4 C<x> - evaluate and print an expression
2448
2449 Hands the expression off to C<DB::eval>, setting it up to print the value
2450 via C<dumpvar.pl> instead of just printing it directly.
2451
2452 =cut
2453
2454                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2455                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2456
2457                     # handle special  "x 3 blah" syntax XXX propagate
2458                     # doc back to special variables.
2459                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2460                         $onetimedumpDepth = $1;
2461                     }
2462                 };
2463
2464 =head4 C<m> - print methods
2465
2466 Just uses C<DB::methods> to determine what methods are available.
2467
2468 =cut
2469
2470                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2471                     methods($1);
2472                     next CMD;
2473                 };
2474
2475                 # m expr - set up DB::eval to do the work
2476                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2477                     $onetimeDump = 'methods';   #  method output gets used there
2478                 };
2479
2480 =head4 C<f> - switch files
2481
2482 =cut
2483
2484                 $cmd =~ /^f\b\s*(.*)/ && do {
2485                     $file = $1;
2486                     $file =~ s/\s+$//;
2487
2488                     # help for no arguments (old-style was return from sub).
2489                     if ( !$file ) {
2490                         print $OUT
2491                           "The old f command is now the r command.\n";    # hint
2492                         print $OUT "The new f command switches filenames.\n";
2493                         next CMD;
2494                     } ## end if (!$file)
2495
2496                     # if not in magic file list, try a close match.
2497                     if ( !defined $main::{ '_<' . $file } ) {
2498                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2499                             {
2500                                 $try = substr( $try, 2 );
2501                                 print $OUT "Choosing $try matching `$file':\n";
2502                                 $file = $try;
2503                             }
2504                         } ## end if (($try) = grep(m#^_<.*$file#...
2505                     } ## end if (!defined $main::{ ...
2506
2507                     # If not successfully switched now, we failed.
2508                     if ( !defined $main::{ '_<' . $file } ) {
2509                         print $OUT "No file matching `$file' is loaded.\n";
2510                         next CMD;
2511                     }
2512
2513                     # We switched, so switch the debugger internals around.
2514                     elsif ( $file ne $filename ) {
2515                         *dbline   = $main::{ '_<' . $file };
2516                         $max      = $#dbline;
2517                         $filename = $file;
2518                         $start    = 1;
2519                         $cmd      = "l";
2520                     } ## end elsif ($file ne $filename)
2521
2522                     # We didn't switch; say we didn't.
2523                     else {
2524                         print $OUT "Already in $file.\n";
2525                         next CMD;
2526                     }
2527                 };
2528
2529 =head4 C<.> - return to last-executed line.
2530
2531 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2532 and then we look up the line in the magical C<%dbline> hash.
2533
2534 =cut
2535
2536                 # . command.
2537                 $cmd =~ /^\.$/ && do {
2538                     $incr = -1;    # stay at current line
2539
2540                     # Reset everything to the old location.
2541                     $start    = $line;
2542                     $filename = $filename_ini;
2543                     *dbline   = $main::{ '_<' . $filename };
2544                     $max      = $#dbline;
2545
2546                     # Now where are we?
2547                     print_lineinfo($position);
2548                     next CMD;
2549                 };
2550
2551 =head4 C<-> - back one window
2552
2553 We change C<$start> to be one window back; if we go back past the first line,
2554 we set it to be the first line. We ser C<$incr> to put us back at the
2555 currently-executing line, and then put a C<l $start +> (list one window from
2556 C<$start>) in C<$cmd> to be executed later.
2557
2558 =cut
2559
2560                 # - - back a window.
2561                 $cmd =~ /^-$/ && do {
2562
2563                     # back up by a window; go to 1 if back too far.
2564                     $start -= $incr + $window + 1;
2565                     $start = 1 if $start <= 0;
2566                     $incr  = $window - 1;
2567
2568                     # Generate and execute a "l +" command (handled below).
2569                     $cmd = 'l ' . ($start) . '+';
2570                 };
2571
2572 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2573
2574 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2575 problems, most notably that the default case of several commands destroying
2576 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2577 retain the old commands for those who were used to using them or who preferred
2578 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2579 deal with them instead of processing them in-line.
2580
2581 =cut
2582
2583                 # All of these commands were remapped in perl 5.8.0;
2584                 # we send them off to the secondary dispatcher (see below).
2585                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2586                     &cmd_wrapper( $1, $2, $line );
2587                     next CMD;
2588                 };
2589
2590 =head4 C<y> - List lexicals in higher scope
2591
2592 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2593 above the current one and then displays then using C<dumpvar.pl>.
2594
2595 =cut
2596
2597                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2598
2599                     # See if we've got the necessary support.
2600                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2601                       or &warn(
2602                         $@ =~ /locate/
2603                         ? "PadWalker module not found - please install\n"
2604                         : $@
2605                       )
2606                       and next CMD;
2607
2608                     # Load up dumpvar if we don't have it. If we can, that is.
2609                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2610                     defined &main::dumpvar
2611                       or print $OUT "dumpvar.pl not available.\n"
2612                       and next CMD;
2613
2614                     # Got all the modules we need. Find them and print them.
2615                     my @vars = split( ' ', $2 || '' );
2616
2617                     # Find the pad.
2618                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2619
2620                     # Oops. Can't find it.
2621                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2622
2623                     # Show the desired vars with dumplex().
2624                     my $savout = select($OUT);
2625
2626                     # Have dumplex dump the lexicals.
2627                     dumpvar::dumplex( $_, $h->{$_},
2628                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2629                         @vars )
2630                       for sort keys %$h;
2631                     select($savout);
2632                     next CMD;
2633                 };
2634
2635 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2636
2637 All of the commands below this point don't work after the program being
2638 debugged has ended. All of them check to see if the program has ended; this
2639 allows the commands to be relocated without worrying about a 'line of
2640 demarcation' above which commands can be entered anytime, and below which
2641 they can't.
2642
2643 =head4 C<n> - single step, but don't trace down into subs
2644
2645 Done by setting C<$single> to 2, which forces subs to execute straight through
2646 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2647 so a null command knows what to re-execute.
2648
2649 =cut
2650
2651                 # n - next
2652                 $cmd =~ /^n$/ && do {
2653                     end_report(), next CMD if $finished and $level <= 1;
2654
2655                     # Single step, but don't enter subs.
2656                     $single = 2;
2657
2658                     # Save for empty command (repeat last).
2659                     $laststep = $cmd;
2660                     last CMD;
2661                 };
2662
2663 =head4 C<s> - single-step, entering subs
2664
2665 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2666 subs. Also saves C<s> as C<$lastcmd>.
2667
2668 =cut
2669
2670                 # s - single step.
2671                 $cmd =~ /^s$/ && do {
2672
2673                     # Get out and restart the command loop if program
2674                     # has finished.
2675                     end_report(), next CMD if $finished and $level <= 1;
2676
2677                     # Single step should enter subs.
2678                     $single = 1;
2679
2680                     # Save for empty command (repeat last).
2681                     $laststep = $cmd;
2682                     last CMD;
2683                 };
2684
2685 =head4 C<c> - run continuously, setting an optional breakpoint
2686
2687 Most of the code for this command is taken up with locating the optional
2688 breakpoint, which is either a subroutine name or a line number. We set
2689 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2690 in this and all call levels above this one.
2691
2692 =cut
2693
2694                 # c - start continuous execution.
2695                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2696
2697                     # Hey, show's over. The debugged program finished
2698                     # executing already.
2699                     end_report(), next CMD if $finished and $level <= 1;
2700
2701                     # Capture the place to put a one-time break.
2702                     $subname = $i = $1;
2703
2704                     #  Probably not needed, since we finish an interactive
2705                     #  sub-session anyway...
2706                     # local $filename = $filename;
2707                     # local *dbline = *dbline; # XXX Would this work?!
2708                     #
2709                     # The above question wonders if localizing the alias
2710                     # to the magic array works or not. Since it's commented
2711                     # out, we'll just leave that to speculation for now.
2712
2713                     # If the "subname" isn't all digits, we'll assume it
2714                     # is a subroutine name, and try to find it.
2715                     if ( $subname =~ /\D/ ) {    # subroutine name
2716                             # Qualify it to the current package unless it's
2717                             # already qualified.
2718                         $subname = $package . "::" . $subname
2719                           unless $subname =~ /::/;
2720
2721                         # find_sub will return "file:line_number" corresponding
2722                         # to where the subroutine is defined; we call find_sub,
2723                         # break up the return value, and assign it in one
2724                         # operation.
2725                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2726
2727                         # Force the line number to be numeric.
2728                         $i += 0;
2729
2730                         # If we got a line number, we found the sub.
2731                         if ($i) {
2732
2733                             # Switch all the debugger's internals around so
2734                             # we're actually working with that file.
2735                             $filename = $file;
2736                             *dbline   = $main::{ '_<' . $filename };
2737
2738                             # Mark that there's a breakpoint in this file.
2739                             $had_breakpoints{$filename} |= 1;
2740
2741                             # Scan forward to the first executable line
2742                             # after the 'sub whatever' line.
2743                             $max = $#dbline;
2744                             ++$i while $dbline[$i] == 0 && $i < $max;
2745                         } ## end if ($i)
2746
2747                         # We didn't find a sub by that name.
2748                         else {
2749                             print $OUT "Subroutine $subname not found.\n";
2750                             next CMD;
2751                         }
2752                     } ## end if ($subname =~ /\D/)
2753
2754                     # At this point, either the subname was all digits (an
2755                     # absolute line-break request) or we've scanned through
2756                     # the code following the definition of the sub, looking
2757                     # for an executable, which we may or may not have found.
2758                     #
2759                     # If $i (which we set $subname from) is non-zero, we
2760                     # got a request to break at some line somewhere. On
2761                     # one hand, if there wasn't any real subroutine name
2762                     # involved, this will be a request to break in the current
2763                     # file at the specified line, so we have to check to make
2764                     # sure that the line specified really is breakable.
2765                     #
2766                     # On the other hand, if there was a subname supplied, the
2767                     # preceding block has moved us to the proper file and
2768                     # location within that file, and then scanned forward
2769                     # looking for the next executable line. We have to make
2770                     # sure that one was found.
2771                     #
2772                     # On the gripping hand, we can't do anything unless the
2773                     # current value of $i points to a valid breakable line.
2774                     # Check that.
2775                     if ($i) {
2776
2777                         # Breakable?
2778                         if ( $dbline[$i] == 0 ) {
2779                             print $OUT "Line $i not breakable.\n";
2780                             next CMD;
2781                         }
2782
2783                         # Yes. Set up the one-time-break sigil.
2784                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2785                     } ## end if ($i)
2786
2787                     # Turn off stack tracing from here up.
2788                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2789                         $stack[ $i++ ] &= ~1;
2790                     }
2791                     last CMD;
2792                 };
2793
2794 =head4 C<r> - return from a subroutine
2795
2796 For C<r> to work properly, the debugger has to stop execution again
2797 immediately after the return is executed. This is done by forcing
2798 single-stepping to be on in the call level above the current one. If
2799 we are printing return values when a C<r> is executed, set C<$doret>
2800 appropriately, and force us out of the command loop.
2801
2802 =cut
2803
2804                 # r - return from the current subroutine.
2805                 $cmd =~ /^r$/ && do {
2806
2807                     # Can't do anythign if the program's over.
2808                     end_report(), next CMD if $finished and $level <= 1;
2809
2810                     # Turn on stack trace.
2811                     $stack[$stack_depth] |= 1;
2812
2813                     # Print return value unless the stack is empty.
2814                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2815                     last CMD;
2816                 };
2817
2818 =head4 C<T> - stack trace
2819
2820 Just calls C<DB::print_trace>.
2821
2822 =cut
2823
2824                 $cmd =~ /^T$/ && do {
2825                     print_trace( $OUT, 1 );    # skip DB
2826                     next CMD;
2827                 };
2828
2829 =head4 C<w> - List window around current line.
2830
2831 Just calls C<DB::cmd_w>.
2832
2833 =cut
2834
2835                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2836
2837 =head4 C<W> - watch-expression processing.
2838
2839 Just calls C<DB::cmd_W>.
2840
2841 =cut
2842
2843                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2844
2845 =head4 C</> - search forward for a string in the source
2846
2847 We take the argument and treat it as a pattern. If it turns out to be a
2848 bad one, we return the error we got from trying to C<eval> it and exit.
2849 If not, we create some code to do the search and C<eval> it so it can't
2850 mess us up.
2851
2852 =cut
2853
2854                 $cmd =~ /^\/(.*)$/ && do {
2855
2856                     # The pattern as a string.
2857                     $inpat = $1;
2858
2859                     # Remove the final slash.
2860                     $inpat =~ s:([^\\])/$:$1:;
2861
2862                     # If the pattern isn't null ...
2863                     if ( $inpat ne "" ) {
2864
2865                         # Turn of warn and die procesing for a bit.
2866                         local $SIG{__DIE__};
2867                         local $SIG{__WARN__};
2868
2869                         # Create the pattern.
2870                         eval '$inpat =~ m' . "\a$inpat\a";
2871                         if ( $@ ne "" ) {
2872
2873                             # Oops. Bad pattern. No biscuit.
2874                             # Print the eval error and go back for more
2875                             # commands.
2876                             print $OUT "$@";
2877                             next CMD;
2878                         }
2879                         $pat = $inpat;
2880                     } ## end if ($inpat ne "")
2881
2882                     # Set up to stop on wrap-around.
2883                     $end = $start;
2884
2885                     # Don't move off the current line.
2886                     $incr = -1;
2887
2888                     # Done in eval so nothing breaks if the pattern
2889                     # does something weird.
2890                     eval '
2891                         for (;;) {
2892                             # Move ahead one line.
2893                             ++$start;
2894
2895                             # Wrap if we pass the last line.
2896                             $start = 1 if ($start > $max);
2897
2898                             # Stop if we have gotten back to this line again,
2899                             last if ($start == $end);
2900
2901                             # A hit! (Note, though, that we are doing
2902                             # case-insensitive matching. Maybe a qr//
2903                             # expression would be better, so the user could
2904                             # do case-sensitive matching if desired.
2905                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2906                                 if ($slave_editor) {
2907                                     # Handle proper escaping in the slave.
2908                                     print $OUT "\032\032$filename:$start:0\n";
2909                                 }
2910                                 else {
2911                                     # Just print the line normally.
2912                                     print $OUT "$start:\t",$dbline[$start],"\n";
2913                                 }
2914                                 # And quit since we found something.
2915                                 last;
2916                             }
2917                          } ';
2918
2919                     # If we wrapped, there never was a match.
2920                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2921                     next CMD;
2922                 };
2923
2924 =head4 C<?> - search backward for a string in the source
2925
2926 Same as for C</>, except the loop runs backwards.
2927
2928 =cut
2929
2930                 # ? - backward pattern search.
2931                 $cmd =~ /^\?(.*)$/ && do {
2932
2933                     # Get the pattern, remove trailing question mark.
2934                     $inpat = $1;
2935                     $inpat =~ s:([^\\])\?$:$1:;
2936
2937                     # If we've got one ...
2938                     if ( $inpat ne "" ) {
2939
2940                         # Turn off die & warn handlers.
2941                         local $SIG{__DIE__};
2942                         local $SIG{__WARN__};
2943                         eval '$inpat =~ m' . "\a$inpat\a";
2944
2945                         if ( $@ ne "" ) {
2946
2947                             # Ouch. Not good. Print the error.
2948                             print $OUT $@;
2949                             next CMD;
2950                         }
2951                         $pat = $inpat;
2952                     } ## end if ($inpat ne "")
2953
2954                     # Where we are now is where to stop after wraparound.
2955                     $end = $start;
2956
2957                     # Don't move away from this line.
2958                     $incr = -1;
2959
2960                     # Search inside the eval to prevent pattern badness
2961                     # from killing us.
2962                     eval '
2963                         for (;;) {
2964                             # Back up a line.
2965                             --$start;
2966
2967                             # Wrap if we pass the first line.
2968
2969                             $start = $max if ($start <= 0);
2970
2971                             # Quit if we get back where we started,
2972                             last if ($start == $end);
2973
2974                             # Match?
2975                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2976                                 if ($slave_editor) {
2977                                     # Yep, follow slave editor requirements.
2978                                     print $OUT "\032\032$filename:$start:0\n";
2979                                 }
2980                                 else {
2981                                     # Yep, just print normally.
2982                                     print $OUT "$start:\t",$dbline[$start],"\n";
2983                                 }
2984
2985                                 # Found, so done.
2986                                 last;
2987                             }
2988                         } ';
2989
2990                     # Say we failed if the loop never found anything,
2991                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2992                     next CMD;
2993                 };
2994
2995 =head4 C<$rc> - Recall command
2996
2997 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2998 that the terminal supports history). It find the the command required, puts it
2999 into C<$cmd>, and redoes the loop to execute it.
3000
3001 =cut
3002
3003                 # $rc - recall command.
3004                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3005
3006                     # No arguments, take one thing off history.
3007                     pop(@hist) if length($cmd) > 1;
3008
3009                     # Relative (- found)?
3010                     #  Y - index back from most recent (by 1 if bare minus)
3011                     #  N - go to that particular command slot or the last
3012                     #      thing if nothing following.
3013                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3014
3015                     # Pick out the command desired.
3016                     $cmd = $hist[$i];
3017
3018                     # Print the command to be executed and restart the loop
3019                     # with that command in the buffer.
3020                     print $OUT $cmd, "\n";
3021                     redo CMD;
3022                 };
3023
3024 =head4 C<$sh$sh> - C<system()> command
3025
3026 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3027 C<STDOUT> from getting messed up.
3028
3029 =cut
3030
3031                 # $sh$sh - run a shell command (if it's all ASCII).
3032                 # Can't run shell commands with Unicode in the debugger, hmm.
3033                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3034
3035                     # System it.
3036                     &system($1);
3037                     next CMD;
3038                 };
3039
3040 =head4 C<$rc I<pattern> $rc> - Search command history
3041
3042 Another command to manipulate C<@hist>: this one searches it with a pattern.
3043 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3044
3045 =cut
3046
3047                 # $rc pattern $rc - find a command in the history.
3048                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3049
3050                     # Create the pattern to use.
3051                     $pat = "^$1";
3052
3053                     # Toss off last entry if length is >1 (and it always is).
3054                     pop(@hist) if length($cmd) > 1;
3055
3056                     # Look backward through the history.
3057                     for ( $i = $#hist ; $i ; --$i ) {
3058
3059                         # Stop if we find it.
3060                         last if $hist[$i] =~ /$pat/;
3061                     }
3062
3063                     if ( !$i ) {
3064
3065                         # Never found it.
3066                         print $OUT "No such command!\n\n";
3067                         next CMD;
3068                     }
3069
3070                     # Found it. Put it in the buffer, print it, and process it.
3071                     $cmd = $hist[$i];
3072                     print $OUT $cmd, "\n";
3073                     redo CMD;
3074                 };
3075
3076 =head4 C<$sh> - Invoke a shell
3077
3078 Uses C<DB::system> to invoke a shell.
3079
3080 =cut
3081
3082                 # $sh - start a shell.
3083                 $cmd =~ /^$sh$/ && do {
3084
3085                     # Run the user's shell. If none defined, run Bourne.
3086                     # We resume execution when the shell terminates.
3087                     &system( $ENV{SHELL} || "/bin/sh" );
3088                     next CMD;
3089                 };
3090
3091 =head4 C<$sh I<command>> - Force execution of a command in a shell
3092
3093 Like the above, but the command is passed to the shell. Again, we use
3094 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3095
3096 =cut
3097
3098                 # $sh command - start a shell and run a command in it.
3099                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3100
3101                     # XXX: using csh or tcsh destroys sigint retvals!
3102                     #&system($1);  # use this instead
3103
3104                     # use the user's shell, or Bourne if none defined.
3105                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3106                     next CMD;
3107                 };
3108
3109 =head4 C<H> - display commands in history
3110
3111 Prints the contents of C<@hist> (if any).
3112
3113 =cut
3114
3115                 $cmd =~ /^H\b\s*\*/ && do {
3116                     @hist = @truehist = ();
3117                     print $OUT "History cleansed\n";
3118                     next CMD;
3119                 };
3120
3121                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3122
3123                     # Anything other than negative numbers is ignored by
3124                     # the (incorrect) pattern, so this test does nothing.
3125                     $end = $2 ? ( $#hist - $2 ) : 0;
3126
3127                     # Set to the minimum if less than zero.
3128                     $hist = 0 if $hist < 0;
3129
3130                     # Start at the end of the array.
3131                     # Stay in while we're still above the ending value.
3132                     # Tick back by one each time around the loop.
3133                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3134
3135                         # Print the command  unless it has no arguments.
3136                         print $OUT "$i: ", $hist[$i], "\n"
3137                           unless $hist[$i] =~ /^.?$/;
3138                     }
3139                     next CMD;
3140                 };
3141
3142 =head4 C<man, doc, perldoc> - look up documentation
3143
3144 Just calls C<runman()> to print the appropriate document.
3145
3146 =cut
3147
3148                 # man, perldoc, doc - show manual pages.
3149                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3150                     runman($1);
3151                     next CMD;
3152                 };
3153
3154 =head4 C<p> - print
3155
3156 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3157 the bottom of the loop.
3158
3159 =cut
3160
3161                 # p - print (no args): print $_.
3162                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3163
3164                 # p - print the given expression.
3165                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3166
3167 =head4 C<=> - define command alias
3168
3169 Manipulates C<%alias> to add or list command aliases.
3170
3171 =cut
3172
3173                 # = - set up a command alias.
3174                 $cmd =~ s/^=\s*// && do {
3175                     my @keys;
3176                     if ( length $cmd == 0 ) {
3177
3178                         # No args, get current aliases.
3179                         @keys = sort keys %alias;
3180                     }
3181                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3182
3183                         # Creating a new alias. $k is alias name, $v is
3184                         # alias value.
3185
3186                         # can't use $_ or kill //g state
3187                         for my $x ( $k, $v ) {
3188
3189                             # Escape "alarm" characters.
3190                             $x =~ s/\a/\\a/g;
3191                         }
3192
3193                         # Substitute key for value, using alarm chars
3194                         # as separators (which is why we escaped them in
3195                         # the command).
3196                         $alias{$k} = "s\a$k\a$v\a";
3197
3198                         # Turn off standard warn and die behavior.
3199                         local $SIG{__DIE__};
3200                         local $SIG{__WARN__};
3201
3202                         # Is it valid Perl?
3203                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3204
3205                             # Nope. Bad alias. Say so and get out.
3206                             print $OUT "Can't alias $k to $v: $@\n";
3207                             delete $alias{$k};
3208                             next CMD;
3209                         }
3210
3211                         # We'll only list the new one.
3212                         @keys = ($k);
3213                     } ## end elsif (my ($k, $v) = ($cmd...
3214
3215                     # The argument is the alias to list.
3216                     else {
3217                         @keys = ($cmd);
3218                     }
3219
3220                     # List aliases.
3221                     for my $k (@keys) {
3222
3223                         # Messy metaquoting: Trim the substiution code off.
3224                         # We use control-G as the delimiter because it's not
3225                         # likely to appear in the alias.
3226                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3227
3228                             # Print the alias.
3229                             print $OUT "$k\t= $1\n";
3230                         }
3231                         elsif ( defined $alias{$k} ) {
3232
3233                             # Couldn't trim it off; just print the alias code.
3234                             print $OUT "$k\t$alias{$k}\n";
3235                         }
3236                         else {
3237
3238                             # No such, dude.
3239                             print "No alias for $k\n";
3240                         }
3241                     } ## end for my $k (@keys)
3242                     next CMD;
3243                 };
3244
3245 =head4 C<source> - read commands from a file.
3246
3247 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3248 pick it up.
3249
3250 =cut
3251
3252                 # source - read commands from a file (or pipe!) and execute.
3253                 $cmd =~ /^source\s+(.*\S)/ && do {
3254                     if ( open my $fh, $1 ) {
3255
3256                         # Opened OK; stick it in the list of file handles.
3257                         push @cmdfhs, $fh;
3258                     }
3259                     else {
3260
3261                         # Couldn't open it.
3262                         &warn("Can't execute `$1': $!\n");
3263                     }
3264                     next CMD;
3265                 };
3266
3267 =head4 C<save> - send current history to a file
3268
3269 Takes the complete history, (not the shrunken version you see with C<H>),
3270 and saves it to the given filename, so it can be replayed using C<source>.
3271
3272 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3273
3274 =cut
3275
3276                 # save source - write commands to a file for later use
3277                 $cmd =~ /^save\s*(.*)$/ && do {
3278                     my $file = $1 || '.perl5dbrc';    # default?
3279                     if ( open my $fh, "> $file" ) {
3280
3281                        # chomp to remove extraneous newlines from source'd files
3282                         chomp( my @truelist =
3283                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3284                               @truehist );
3285                         print $fh join( "\n", @truelist );
3286                         print "commands saved in $file\n";
3287                     }
3288                     else {
3289                         &warn("Can't save debugger commands in '$1': $!\n");
3290                     }
3291                     next CMD;
3292                 };
3293
3294 =head4 C<R> - restart
3295
3296 Restart the debugger session.
3297
3298 =head4 C<rerun> - rerun the current session
3299
3300 Return to any given position in the B<true>-history list
3301
3302 =cut
3303
3304                 # R - restart execution.
3305                 # rerun - controlled restart execution.
3306                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3307                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3308
3309                     # Close all non-system fds for a clean restart.  A more
3310                     # correct method would be to close all fds that were not
3311                     # open when the process started, but this seems to be
3312                     # hard.  See "debugger 'R'estart and open database
3313                     # connections" on p5p.
3314
3315                     my $max_fd = 1024; # default if POSIX can't be loaded
3316                     if (eval { require POSIX }) {
3317                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3318                     }
3319
3320                     if (defined $max_fd) {
3321                         foreach ($^F+1 .. $max_fd-1) {
3322                             next unless open FD_TO_CLOSE, "<&=$_";
3323                             close(FD_TO_CLOSE);
3324                         }
3325                     }
3326
3327                     # And run Perl again.  We use exec() to keep the
3328                     # PID stable (and that way $ini_pids is still valid).
3329                     exec(@args) || print $OUT "exec failed: $!\n";
3330
3331                     last CMD;
3332                 };
3333
3334 =head4 C<|, ||> - pipe output through the pager.
3335
3336 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3337 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3338 pipe to the pager (restoring the output filehandles if this fails). If this
3339 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3340 set C<$signal>, sending us back into the debugger.
3341
3342 We then trim off the pipe symbols and C<redo> the command loop at the
3343 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3344 reading another.
3345
3346 =cut
3347
3348                 # || - run command in the pager, with output to DB::OUT.
3349                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3350                     if ( $pager =~ /^\|/ ) {
3351
3352                         # Default pager is into a pipe. Redirect I/O.
3353                         open( SAVEOUT, ">&STDOUT" )
3354                           || &warn("Can't save STDOUT");
3355                         open( STDOUT, ">&OUT" )
3356                           || &warn("Can't redirect STDOUT");
3357                     } ## end if ($pager =~ /^\|/)
3358                     else {
3359
3360                         # Not into a pipe. STDOUT is safe.
3361                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3362                     }
3363
3364                     # Fix up environment to record we have less if so.
3365                     fix_less();
3366
3367                     unless ( $piped = open( OUT, $pager ) ) {
3368
3369                         # Couldn't open pipe to pager.
3370                         &warn("Can't pipe output to `$pager'");
3371                         if ( $pager =~ /^\|/ ) {
3372
3373                             # Redirect I/O back again.
3374                             open( OUT, ">&STDOUT" )    # XXX: lost message
3375                               || &warn("Can't restore DB::OUT");
3376                             open( STDOUT, ">&SAVEOUT" )
3377                               || &warn("Can't restore STDOUT");
3378                             close(SAVEOUT);
3379                         } ## end if ($pager =~ /^\|/)
3380                         else {
3381
3382                             # Redirect I/O. STDOUT already safe.
3383                             open( OUT, ">&STDOUT" )    # XXX: lost message
3384                               || &warn("Can't restore DB::OUT");
3385                         }
3386                         next CMD;
3387                     } ## end unless ($piped = open(OUT,...
3388
3389                     # Set up broken-pipe handler if necessary.
3390                     $SIG{PIPE} = \&DB::catch
3391                       if $pager =~ /^\|/
3392                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3393
3394                     # Save current filehandle, unbuffer out, and put it back.
3395                     $selected = select(OUT);
3396                     $|        = 1;
3397
3398                     # Don't put it back if pager was a pipe.
3399                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3400
3401                     # Trim off the pipe symbols and run the command now.
3402                     $cmd =~ s/^\|+\s*//;
3403                     redo PIPE;
3404                 };
3405
3406 =head3 END OF COMMAND PARSING
3407
3408 Anything left in C<$cmd> at this point is a Perl expression that we want to
3409 evaluate. We'll always evaluate in the user's context, and fully qualify
3410 any variables we might want to address in the C<DB> package.
3411
3412 =cut
3413
3414                 # t - turn trace on.
3415                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3416
3417                 # s - single-step. Remember the last command was 's'.
3418                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3419
3420                 # n - single-step, but not into subs. Remember last command
3421                 # was 'n'.
3422                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3423
3424             }    # PIPE:
3425
3426             # Make sure the flag that says "the debugger's running" is
3427             # still on, to make sure we get control again.
3428             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3429
3430             # Run *our* eval that executes in the caller's context.
3431             &eval;
3432
3433             # Turn off the one-time-dump stuff now.
3434             if ($onetimeDump) {
3435                 $onetimeDump      = undef;
3436                 $onetimedumpDepth = undef;
3437             }
3438             elsif ( $term_pid == $$ ) {
3439                 eval {          # May run under miniperl, when not available...
3440                     STDOUT->flush();
3441                     STDERR->flush();
3442                 };
3443
3444                 # XXX If this is the master pid, print a newline.
3445                 print $OUT "\n";
3446             }
3447         } ## end while (($term || &setterm...
3448
3449 =head3 POST-COMMAND PROCESSING
3450
3451 After each command, we check to see if the command output was piped anywhere.
3452 If so, we go through the necessary code to unhook the pipe and go back to
3453 our standard filehandles for input and output.
3454
3455 =cut
3456
3457         continue {    # CMD:
3458
3459             # At the end of every command:
3460             if ($piped) {
3461
3462                 # Unhook the pipe mechanism now.
3463                 if ( $pager =~ /^\|/ ) {
3464
3465                     # No error from the child.
3466                     $? = 0;
3467
3468                     # we cannot warn here: the handle is missing --tchrist
3469                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3470
3471                     # most of the $? crud was coping with broken cshisms
3472                     # $? is explicitly set to 0, so this never runs.
3473                     if ($?) {
3474                         print SAVEOUT "Pager `$pager' failed: ";
3475                         if ( $? == -1 ) {
3476                             print SAVEOUT "shell returned -1\n";
3477                         }
3478                         elsif ( $? >> 8 ) {
3479                             print SAVEOUT ( $? & 127 )
3480                               ? " (SIG#" . ( $? & 127 ) . ")"
3481                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3482                         }
3483                         else {
3484                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3485                         }
3486                     } ## end if ($?)
3487
3488                     # Reopen filehandle for our output (if we can) and
3489                     # restore STDOUT (if we can).
3490                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3491                     open( STDOUT, ">&SAVEOUT" )
3492                       || &warn("Can't restore STDOUT");
3493
3494                     # Turn off pipe exception handler if necessary.
3495                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3496
3497                     # Will stop ignoring SIGPIPE if done like nohup(1)
3498                     # does SIGINT but Perl doesn't give us a choice.
3499                 } ## end if ($pager =~ /^\|/)
3500                 else {
3501
3502                     # Non-piped "pager". Just restore STDOUT.
3503                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3504                 }
3505
3506                 # Close filehandle pager was using, restore the normal one
3507                 # if necessary,
3508                 close(SAVEOUT);
3509                 select($selected), $selected = "" unless $selected eq "";
3510
3511                 # No pipes now.
3512                 $piped = "";
3513             } ## end if ($piped)
3514         }    # CMD:
3515
3516 =head3 COMMAND LOOP TERMINATION
3517
3518 When commands have finished executing, we come here. If the user closed the
3519 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3520 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3521 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3522 The interpreter will then execute the next line and then return control to us
3523 again.
3524
3525 =cut
3526
3527         # No more commands? Quit.
3528         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3529
3530         # Evaluate post-prompt commands.
3531         foreach $evalarg (@$post) {
3532             &eval;
3533         }
3534     }    # if ($single || $signal)
3535
3536     # Put the user's globals back where you found them.
3537     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3538     ();
3539 } ## end sub DB
3540
3541 # The following code may be executed now:
3542 # BEGIN {warn 4}
3543
3544 =head2 sub
3545
3546 C<sub> is called whenever a subroutine call happens in the program being
3547 debugged. The variable C<$DB::sub> contains the name of the subroutine
3548 being called.
3549
3550 The core function of this subroutine is to actually call the sub in the proper
3551 context, capturing its output. This of course causes C<DB::DB> to get called
3552 again, repeating until the subroutine ends and returns control to C<DB::sub>
3553 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3554 return value, and returns its captured copy of the return value as its own
3555 return value. The value then feeds back into the program being debugged as if
3556 C<DB::sub> hadn't been there at all.
3557
3558 C<sub> does all the work of printing the subroutine entry and exit messages
3559 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3560 and also prints the return value if needed (for the C<r> command and if
3561 the 16 bit is set in C<$frame>).
3562
3563 It also tracks the subroutine call depth by saving the current setting of
3564 C<$single> in the C<@stack> package global; if this exceeds the value in
3565 C<$deep>, C<sub> automatically turns on printing of the current depth by
3566 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3567 of stop/don't stop on entry to subs set as it currently is set.
3568
3569 =head3 C<caller()> support
3570
3571 If C<caller()> is called from the package C<DB>, it provides some
3572 additional data, in the following order:
3573
3574 =over 4
3575
3576 =item * C<$package>
3577
3578 The package name the sub was in
3579
3580 =item * C<$filename>
3581
3582 The filename it was defined in
3583
3584 =item * C<$line>
3585
3586 The line number it was defined on
3587
3588 =item * C<$subroutine>
3589
3590 The subroutine name; C<(eval)> if an C<eval>().
3591
3592 =item * C<$hasargs>
3593
3594 1 if it has arguments, 0 if not
3595
3596 =item * C<$wantarray>
3597
3598 1 if array context, 0 if scalar context
3599
3600 =item * C<$evaltext>
3601
3602 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3603
3604 =item * C<$is_require>
3605
3606 frame was created by a C<use> or C<require> statement
3607
3608 =item * C<$hints>
3609
3610 pragma information; subject to change between versions
3611
3612 =item * C<$bitmask>
3613
3614 pragma information; subject to change between versions
3615
3616 =item * C<@DB::args>
3617
3618 arguments with which the subroutine was invoked
3619
3620 =back
3621
3622 =cut
3623
3624 sub sub {
3625
3626         # lock ourselves under threads
3627         lock($DBGR);
3628
3629     # Whether or not the autoloader was running, a scalar to put the
3630     # sub's return value in (if needed), and an array to put the sub's
3631     # return value in (if needed).
3632     my ( $al, $ret, @ret ) = "";
3633         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3634                 print "creating new thread\n";
3635         }
3636
3637     # If the last ten characters are C'::AUTOLOAD', note we've traced
3638     # into AUTOLOAD for $sub.
3639     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3640         $al = " for $$sub";
3641     }
3642
3643     # We stack the stack pointer and then increment it to protect us
3644     # from a situation that might unwind a whole bunch of call frames
3645     # at once. Localizing the stack pointer means that it will automatically
3646     # unwind the same amount when multiple stack frames are unwound.
3647     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3648
3649     # Expand @stack.
3650     $#stack = $stack_depth;
3651
3652     # Save current single-step setting.
3653     $stack[-1] = $single;
3654
3655     # Turn off all flags except single-stepping.
3656     $single &= 1;
3657
3658     # If we've gotten really deeply recursed, turn on the flag that will
3659     # make us stop with the 'deep recursion' message.
3660     $single |= 4 if $stack_depth == $deep;
3661
3662     # If frame messages are on ...
3663     (
3664         $frame & 4    # Extended frame entry message
3665         ? (
3666             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3667
3668             # Why -1? But it works! :-(
3669             # Because print_trace will call add 1 to it and then call
3670             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3671             # in dump_trace.
3672             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3673           )
3674         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3675
3676           # standard frame entry message
3677       )
3678       if $frame;
3679
3680     # Determine the sub's return type,and capture approppriately.
3681     if (wantarray) {
3682
3683         # Called in array context. call sub and capture output.
3684         # DB::DB will recursively get control again if appropriate; we'll come
3685         # back here when the sub is finished.
3686         if ($assertion) {
3687             $assertion = 0;
3688             eval { @ret = &$sub; };
3689             if ($@) {
3690                 print $OUT $@;
3691                 $signal = 1 unless $warnassertions;
3692             }
3693         }
3694         else {
3695             @ret = &$sub;
3696         }
3697
3698         # Pop the single-step value back off the stack.
3699         $single |= $stack[ $stack_depth-- ];
3700
3701         # Check for exit trace messages...
3702         (
3703             $frame & 4    # Extended exit message
3704             ? (
3705                 print_lineinfo( ' ' x $stack_depth, "out " ),
3706                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3707               )
3708             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3709
3710               # Standard exit message
3711           )
3712           if $frame & 2;
3713
3714         # Print the return info if we need to.
3715         if ( $doret eq $stack_depth or $frame & 16 ) {
3716
3717             # Turn off output record separator.
3718             local $\ = '';
3719             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3720
3721             # Indent if we're printing because of $frame tracing.
3722             print $fh ' ' x $stack_depth if $frame & 16;
3723
3724             # Print the return value.
3725             print $fh "list context return from $sub:\n";
3726             dumpit( $fh, \@ret );
3727
3728             # And don't print it again.
3729             $doret = -2;
3730         } ## end if ($doret eq $stack_depth...
3731             # And we have to return the return value now.
3732         @ret;
3733     } ## end if (wantarray)
3734
3735     # Scalar context.
3736     else {
3737         if ($assertion) {
3738             $assertion = 0;
3739             eval {
3740
3741                 # Save the value if it's wanted at all.
3742                 $ret = &$sub;
3743             };
3744             if ($@) {
3745                 print $OUT $@;
3746                 $signal = 1 unless $warnassertions;
3747             }
3748             $ret = undef unless defined wantarray;
3749         }
3750         else {
3751             if ( defined wantarray ) {
3752
3753                 # Save the value if it's wanted at all.
3754                 $ret = &$sub;
3755             }
3756             else {
3757
3758                 # Void return, explicitly.
3759                 &$sub;
3760                 undef $ret;
3761             }
3762         }    # if assertion
3763
3764         # Pop the single-step value off the stack.
3765         $single |= $stack[ $stack_depth-- ];
3766
3767         # If we're doing exit messages...
3768         (
3769             $frame & 4    # Extended messsages
3770             ? (
3771                 print_lineinfo( ' ' x $stack_depth, "out " ),
3772                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3773               )
3774             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3775
3776               # Standard messages
3777           )
3778           if $frame & 2;
3779
3780         # If we are supposed to show the return value... same as before.
3781         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3782             local $\ = '';
3783             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3784             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3785             print $fh (
3786                 defined wantarray
3787                 ? "scalar context return from $sub: "
3788                 : "void context return from $sub\n"
3789             );
3790             dumpit( $fh, $ret ) if defined wantarray;
3791             $doret = -2;
3792         } ## end if ($doret eq $stack_depth...
3793
3794         # Return the appropriate scalar value.
3795         $ret;
3796     } ## end else [ if (wantarray)
3797 } ## end sub sub
3798
3799 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3800
3801 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3802 Most of the changes were to systematize the command structure and to eliminate
3803 commands that threw away user input without checking.
3804
3805 The following sections describe the code added to make it easy to support
3806 multiple command sets with conflicting command names. This section is a start
3807 at unifying all command processing to make it simpler to develop commands.
3808
3809 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3810 number, and C<$dbline> (the current line) as arguments.
3811
3812 Support functions in this section which have multiple modes of failure C<die>
3813 on error; the rest simply return a false value.
3814
3815 The user-interface functions (all of the C<cmd_*> functions) just output
3816 error messages.
3817
3818 =head2 C<%set>
3819
3820 The C<%set> hash defines the mapping from command letter to subroutine
3821 name suffix.
3822
3823 C<%set> is a two-level hash, indexed by set name and then by command name.
3824 Note that trying to set the CommandSet to C<foobar> simply results in the
3825 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3826
3827 =cut
3828
3829 ### The API section
3830
3831 my %set = (    #
3832     'pre580' => {
3833         'a' => 'pre580_a',
3834         'A' => 'pre580_null',
3835         'b' => 'pre580_b',
3836         'B' => 'pre580_null',
3837         'd' => 'pre580_null',
3838         'D' => 'pre580_D',
3839         'h' => 'pre580_h',
3840         'M' => 'pre580_null',
3841         'O' => 'o',
3842         'o' => 'pre580_null',
3843         'v' => 'M',
3844         'w' => 'v',
3845         'W' => 'pre580_W',
3846     },
3847     'pre590' => {
3848         '<'  => 'pre590_prepost',
3849         '<<' => 'pre590_prepost',
3850         '>'  => 'pre590_prepost',
3851         '>>' => 'pre590_prepost',
3852         '{'  => 'pre590_prepost',
3853         '{{' => 'pre590_prepost',
3854     },
3855 );
3856
3857 =head2 C<cmd_wrapper()> (API)
3858
3859 C<cmd_wrapper()> allows the debugger to switch command sets
3860 depending on the value of the C<CommandSet> option.
3861
3862 It tries to look up the command in the C<%set> package-level I<lexical>
3863 (which means external entities can't fiddle with it) and create the name of
3864 the sub to call based on the value found in the hash (if it's there). I<All>
3865 of the commands to be handled in a set have to be added to C<%set>; if they
3866 aren't found, the 5.8.0 equivalent is called (if there is one).
3867
3868 This code uses symbolic references.
3869
3870 =cut
3871
3872 sub cmd_wrapper {
3873     my $cmd      = shift;
3874     my $line     = shift;
3875     my $dblineno = shift;
3876
3877     # Assemble the command subroutine's name by looking up the
3878     # command set and command name in %set. If we can't find it,
3879     # default to the older version of the command.
3880     my $call = 'cmd_'
3881       . ( $set{$CommandSet}{$cmd}
3882           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3883
3884     # Call the command subroutine, call it by name.
3885     return &$call( $cmd, $line, $dblineno );
3886 } ## end sub cmd_wrapper
3887
3888 =head3 C<cmd_a> (command)
3889
3890 The C<a> command handles pre-execution actions. These are associated with a
3891 particular line, so they're stored in C<%dbline>. We default to the current
3892 line if none is specified.
3893
3894 =cut
3895
3896 sub cmd_a {
3897     my $cmd    = shift;
3898     my $line   = shift || '';    # [.|line] expr
3899     my $dbline = shift;
3900
3901     # If it's dot (here), or not all digits,  use the current line.
3902     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3903
3904     # Should be a line number followed by an expression.
3905     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3906         my ( $lineno, $expr ) = ( $1, $2 );
3907
3908         # If we have an expression ...
3909         if ( length $expr ) {
3910
3911             # ... but the line isn't breakable, complain.
3912             if ( $dbline[$lineno] == 0 ) {
3913                 print $OUT
3914                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3915             }
3916             else {
3917
3918                 # It's executable. Record that the line has an action.
3919                 $had_breakpoints{$filename} |= 2;
3920
3921                 # Remove any action, temp breakpoint, etc.
3922                 $dbline{$lineno} =~ s/\0[^\0]*//;
3923
3924                 # Add the action to the line.
3925                 $dbline{$lineno} .= "\0" . action($expr);
3926             }
3927         } ## end if (length $expr)
3928     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3929     else {
3930
3931         # Syntax wrong.
3932         print $OUT
3933           "Adding an action requires an optional lineno and an expression\n"
3934           ;    # hint
3935     }
3936 } ## end sub cmd_a
3937
3938 =head3 C<cmd_A> (command)
3939
3940 Delete actions. Similar to above, except the delete code is in a separate
3941 subroutine, C<delete_action>.
3942
3943 =cut
3944
3945 sub cmd_A {
3946     my $cmd    = shift;
3947     my $line   = shift || '';
3948     my $dbline = shift;
3949
3950     # Dot is this line.
3951     $line =~ s/^\./$dbline/;
3952
3953     # Call delete_action with a null param to delete them all.
3954     # The '1' forces the eval to be true. It'll be false only
3955     # if delete_action blows up for some reason, in which case
3956     # we print $@ and get out.
3957     if ( $line eq '*' ) {
3958         eval { &delete_action(); 1 } or print $OUT $@ and return;
3959     }
3960
3961     # There's a real line  number. Pass it to delete_action.
3962     # Error trapping is as above.
3963     elsif ( $line =~ /^(\S.*)/ ) {
3964         eval { &delete_action($1); 1 } or print $OUT $@ and return;
3965     }
3966
3967     # Swing and a miss. Bad syntax.
3968     else {
3969         print $OUT
3970           "Deleting an action requires a line number, or '*' for all\n" ; # hint
3971     }
3972 } ## end sub cmd_A
3973
3974 =head3 C<delete_action> (API)
3975
3976 C<delete_action> accepts either a line number or C<undef>. If a line number
3977 is specified, we check for the line being executable (if it's not, it
3978 couldn't have had an  action). If it is, we just take the action off (this
3979 will get any kind of an action, including breakpoints).
3980
3981 =cut
3982
3983 sub delete_action {
3984     my $i = shift;
3985     if ( defined($i) ) {
3986
3987         # Can there be one?
3988         die "Line $i has no action .\n" if $dbline[$i] == 0;
3989
3990         # Nuke whatever's there.
3991         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
3992         delete $dbline{$i} if $dbline{$i} eq '';
3993     }
3994     else {
3995         print $OUT "Deleting all actions...\n";
3996         for my $file ( keys %had_breakpoints ) {
3997             local *dbline = $main::{ '_<' . $file };
3998             my $max = $#dbline;
3999             my $was;
4000             for ( $i = 1 ; $i <= $max ; $i++ ) {
4001                 if ( defined $dbline{$i} ) {
4002                     $dbline{$i} =~ s/\0[^\0]*//;
4003                     delete $dbline{$i} if $dbline{$i} eq '';
4004                 }
4005                 unless ( $had_breakpoints{$file} &= ~2 ) {
4006                     delete $had_breakpoints{$file};
4007                 }
4008             } ## end for ($i = 1 ; $i <= $max...
4009         } ## end for my $file (keys %had_breakpoints)
4010     } ## end else [ if (defined($i))
4011 } ## end sub delete_action
4012
4013 =head3 C<cmd_b> (command)
4014
4015 Set breakpoints. Since breakpoints can be set in so many places, in so many
4016 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4017 we try to parse the command type, and then shuttle it off to an appropriate
4018 subroutine to actually do the work of setting the breakpoint in the right
4019 place.
4020
4021 =cut
4022
4023 sub cmd_b {
4024     my $cmd    = shift;
4025     my $line   = shift;    # [.|line] [cond]
4026     my $dbline = shift;
4027
4028     # Make . the current line number if it's there..
4029     $line =~ s/^\./$dbline/;
4030
4031     # No line number, no condition. Simple break on current line.
4032     if ( $line =~ /^\s*$/ ) {
4033         &cmd_b_line( $dbline, 1 );
4034     }
4035
4036     # Break on load for a file.
4037     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4038         my $file = $1;
4039         $file =~ s/\s+$//;
4040         &cmd_b_load($file);
4041     }
4042
4043     # b compile|postpone <some sub> [<condition>]
4044     # The interpreter actually traps this one for us; we just put the
4045     # necessary condition in the %postponed hash.
4046     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4047
4048         # Capture the condition if there is one. Make it true if none.
4049         my $cond = length $3 ? $3 : '1';
4050
4051         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4052         # if it was 'compile'.
4053         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4054
4055         # De-Perl4-ify the name - ' separators to ::.
4056         $subname =~ s/\'/::/g;
4057
4058         # Qualify it into the current package unless it's already qualified.
4059         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4060
4061         # Add main if it starts with ::.
4062         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4063
4064         # Save the break type for this sub.
4065         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4066     } ## end elsif ($line =~ ...
4067
4068     # b <sub name> [<condition>]
4069     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4070
4071         #
4072         $subname = $1;
4073         $cond = length $2 ? $2 : '1';
4074         &cmd_b_sub( $subname, $cond );
4075     }
4076
4077     # b <line> [<condition>].
4078     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4079
4080         # Capture the line. If none, it's the current line.
4081         $line = $1 || $dbline;
4082
4083         # If there's no condition, make it '1'.
4084         $cond = length $2 ? $2 : '1';
4085
4086         # Break on line.
4087         &cmd_b_line( $line, $cond );
4088     }
4089
4090     # Line didn't make sense.
4091     else {
4092         print "confused by line($line)?\n";
4093     }
4094 } ## end sub cmd_b
4095
4096 =head3 C<break_on_load> (API)
4097
4098 We want to break when this file is loaded. Mark this file in the
4099 C<%break_on_load> hash, and note that it has a breakpoint in
4100 C<%had_breakpoints>.
4101
4102 =cut
4103
4104 sub break_on_load {
4105     my $file = shift;
4106     $break_on_load{$file} = 1;
4107     $had_breakpoints{$file} |= 1;
4108 }
4109
4110 =head3 C<report_break_on_load> (API)
4111
4112 Gives us an array of filenames that are set to break on load. Note that
4113 only files with break-on-load are in here, so simply showing the keys
4114 suffices.
4115
4116 =cut
4117
4118 sub report_break_on_load {
4119     sort keys %break_on_load;
4120 }
4121
4122 =head3 C<cmd_b_load> (command)
4123
4124 We take the file passed in and try to find it in C<%INC> (which maps modules
4125 to files they came from). We mark those files for break-on-load via
4126 C<break_on_load> and then report that it was done.
4127
4128 =cut
4129
4130 sub cmd_b_load {
4131     my $file = shift;
4132     my @files;
4133
4134     # This is a block because that way we can use a redo inside it
4135     # even without there being any looping structure at all outside it.
4136     {
4137
4138         # Save short name and full path if found.
4139         push @files, $file;
4140         push @files, $::INC{$file} if $::INC{$file};
4141
4142         # Tack on .pm and do it again unless there was a '.' in the name
4143         # already.
4144         $file .= '.pm', redo unless $file =~ /\./;
4145     }
4146
4147     # Do the real work here.
4148     break_on_load($_) for @files;
4149
4150     # All the files that have break-on-load breakpoints.
4151     @files = report_break_on_load;
4152
4153     # Normalize for the purposes of our printing this.
4154     local $\ = '';
4155     local $" = ' ';
4156     print $OUT "Will stop on load of `@files'.\n";
4157 } ## end sub cmd_b_load
4158
4159 =head3 C<$filename_error> (API package global)
4160
4161 Several of the functions we need to implement in the API need to work both
4162 on the current file and on other files. We don't want to duplicate code, so
4163 C<$filename_error> is used to contain the name of the file that's being
4164 worked on (if it's not the current one).
4165
4166 We can now build functions in pairs: the basic function works on the current
4167 file, and uses C<$filename_error> as part of its error message. Since this is
4168 initialized to C<"">, no filename will appear when we are working on the
4169 current file.
4170
4171 The second function is a wrapper which does the following:
4172
4173 =over 4
4174
4175 =item *
4176
4177 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4178
4179 =item *
4180
4181 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4182
4183 =item *
4184
4185 Calls the first function.
4186
4187 The first function works on the I<current> file (i.e., the one we changed to),
4188 and prints C<$filename_error> in the error message (the name of the other file)
4189 if it needs to. When the functions return, C<*dbline> is restored to point
4190 to the actual current file (the one we're executing in) and
4191 C<$filename_error> is restored to C<"">. This restores everything to
4192 the way it was before the second function was called at all.
4193
4194 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4195 details.
4196
4197 =back
4198
4199 =cut
4200
4201 $filename_error = '';
4202
4203 =head3 breakable_line(from, to) (API)
4204
4205 The subroutine decides whether or not a line in the current file is breakable.
4206 It walks through C<@dbline> within the range of lines specified, looking for
4207 the first line that is breakable.
4208
4209 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4210 first line I<after> C<$to> that's breakable, if there is one.
4211
4212 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4213 first line I<before> C<$to> that's breakable, if there is one.
4214
4215 =cut
4216
4217 sub breakable_line {
4218
4219     my ( $from, $to ) = @_;
4220
4221     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4222     my $i = $from;
4223
4224     # If there are at least 2 arguments, we're trying to search a range.
4225     if ( @_ >= 2 ) {
4226
4227         # $delta is positive for a forward search, negative for a backward one.
4228         my $delta = $from < $to ? +1 : -1;
4229
4230         # Keep us from running off the ends of the file.
4231         my $limit = $delta > 0 ? $#dbline : 1;
4232
4233         # Clever test. If you're a mathematician, it's obvious why this
4234         # test works. If not:
4235         # If $delta is positive (going forward), $limit will be $#dbline.
4236         #    If $to is less than $limit, ($limit - $to) will be positive, times
4237         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4238         #    as the stopping point.
4239         #
4240         #    If $to is greater than $limit, ($limit - $to) is negative,
4241         #    times $delta of 1 (positive), so the result is < 0 and we should
4242         #    use $limit ($#dbline) as the stopping point.
4243         #
4244         # If $delta is negative (going backward), $limit will be 1.
4245         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4246         #    (negative) so the result is > 0, and we use $to as the stopping
4247         #    point.
4248         #
4249         #    If $to is less than zero, ($limit - $to) will be positive,
4250         #    times $delta of -1 (negative), so the result is not > 0, and
4251         #    we use $limit (1) as the stopping point.
4252         #
4253         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4254         #    (negative), still giving zero; the result is not > 0, and
4255         #    we use $limit (1) as the stopping point.
4256         #
4257         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4258         #    (negative), giving a positive (>0) value, so we'll set $limit to
4259         #    $to.
4260
4261         $limit = $to if ( $limit - $to ) * $delta > 0;
4262
4263         # The real search loop.
4264         # $i starts at $from (the point we want to start searching from).
4265         # We move through @dbline in the appropriate direction (determined
4266         # by $delta: either -1 (back) or +1 (ahead).
4267         # We stay in as long as we haven't hit an executable line
4268         # ($dbline[$i] == 0 means not executable) and we haven't reached
4269         # the limit yet (test similar to the above).
4270         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4271
4272     } ## end if (@_ >= 2)
4273
4274     # If $i points to a line that is executable, return that.
4275     return $i unless $dbline[$i] == 0;
4276
4277     # Format the message and print it: no breakable lines in range.
4278     my ( $pl, $upto ) = ( '', '' );
4279     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4280
4281     # If there's a filename in filename_error, we'll see it.
4282     # If not, not.
4283     die "Line$pl $from$upto$filename_error not breakable\n";
4284 } ## end sub breakable_line
4285
4286 =head3 breakable_line_in_filename(file, from, to) (API)
4287
4288 Like C<breakable_line>, but look in another file.
4289
4290 =cut
4291
4292 sub breakable_line_in_filename {
4293
4294     # Capture the file name.
4295     my ($f) = shift;
4296
4297     # Swap the magic line array over there temporarily.
4298     local *dbline = $main::{ '_<' . $f };
4299
4300     # If there's an error, it's in this other file.
4301     local $filename_error = " of `$f'";
4302
4303     # Find the breakable line.
4304     breakable_line(@_);
4305
4306     # *dbline and $filename_error get restored when this block ends.
4307
4308 } ## end sub breakable_line_in_filename
4309
4310 =head3 break_on_line(lineno, [condition]) (API)
4311
4312 Adds a breakpoint with the specified condition (or 1 if no condition was
4313 specified) to the specified line. Dies if it can't.
4314
4315 =cut
4316
4317 sub break_on_line {
4318     my ( $i, $cond ) = @_;
4319
4320     # Always true if no condition supplied.
4321     $cond = 1 unless @_ >= 2;
4322
4323     my $inii  = $i;
4324     my $after = '';
4325     my $pl    = '';
4326
4327     # Woops, not a breakable line. $filename_error allows us to say
4328     # if it was in a different file.
4329     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4330
4331     # Mark this file as having breakpoints in it.
4332     $had_breakpoints{$filename} |= 1;
4333
4334     # If there is an action or condition here already ...
4335     if ( $dbline{$i} ) {
4336
4337         # ... swap this condition for the existing one.
4338         $dbline{$i} =~ s/^[^\0]*/$cond/;
4339     }
4340     else {
4341
4342         # Nothing here - just add the condition.
4343         $dbline{$i} = $cond;
4344     }
4345 } ## end sub break_on_line
4346
4347 =head3 cmd_b_line(line, [condition]) (command)
4348
4349 Wrapper for C<break_on_line>. Prints the failure message if it
4350 doesn't work.
4351
4352 =cut
4353
4354 sub cmd_b_line {
4355     eval { break_on_line(@_); 1 } or do {
4356         local $\ = '';
4357         print $OUT $@ and return;
4358     };
4359 } ## end sub cmd_b_line
4360
4361 =head3 break_on_filename_line(file, line, [condition]) (API)
4362
4363 Switches to the file specified and then calls C<break_on_line> to set
4364 the breakpoint.
4365
4366 =cut
4367
4368 sub break_on_filename_line {
4369     my ( $f, $i, $cond ) = @_;
4370
4371     # Always true if condition left off.
4372     $cond = 1 unless @_ >= 3;
4373
4374     # Switch the magical hash temporarily.
4375     local *dbline = $main::{ '_<' . $f };
4376
4377     # Localize the variables that break_on_line uses to make its message.
4378     local $filename_error = " of `$f'";
4379     local $filename       = $f;
4380
4381     # Add the breakpoint.
4382     break_on_line( $i, $cond );
4383 } ## end sub break_on_filename_line
4384
4385 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4386
4387 Switch to another file, search the range of lines specified for an
4388 executable one, and put a breakpoint on the first one you find.
4389
4390 =cut
4391
4392 sub break_on_filename_line_range {
4393     my ( $f, $from, $to, $cond ) = @_;
4394
4395     # Find a breakable line if there is one.
4396     my $i = breakable_line_in_filename( $f, $from, $to );
4397
4398     # Always true if missing.
4399     $cond = 1 unless @_ >= 3;
4400
4401     # Add the breakpoint.
4402     break_on_filename_line( $f, $i, $cond );
4403 } ## end sub break_on_filename_line_range
4404
4405 =head3 subroutine_filename_lines(subname, [condition]) (API)
4406
4407 Search for a subroutine within a given file. The condition is ignored.
4408 Uses C<find_sub> to locate the desired subroutine.
4409
4410 =cut
4411
4412 sub subroutine_filename_lines {
4413     my ( $subname, $cond ) = @_;
4414
4415     # Returned value from find_sub() is fullpathname:startline-endline.
4416     # The match creates the list (fullpathname, start, end). Falling off
4417     # the end of the subroutine returns this implicitly.
4418     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4419 } ## end sub subroutine_filename_lines
4420
4421 =head3 break_subroutine(subname) (API)
4422
4423 Places a break on the first line possible in the specified subroutine. Uses
4424 C<subroutine_filename_lines> to find the subroutine, and
4425 C<break_on_filename_line_range> to place the break.
4426
4427 =cut
4428
4429 sub break_subroutine {
4430     my $subname = shift;
4431
4432     # Get filename, start, and end.
4433     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4434       or die "Subroutine $subname not found.\n";
4435
4436     # Null condition changes to '1' (always true).
4437     $cond = 1 unless @_ >= 2;
4438
4439     # Put a break the first place possible in the range of lines
4440     # that make up this subroutine.
4441     break_on_filename_line_range( $file, $s, $e, @_ );
4442 } ## end sub break_subroutine
4443