pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19
  20 =head2 The backslash
  21
  22 In a regular expression, the backslash can perform one of two tasks:
  23 it either takes away the special meaning of the character following it
  24 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  25 or it is the start of a backslash or escape sequence.
  26
  27 The rules determining what it is are quite simple: if the character
  28 following the backslash is an ASCII punctuation (non-word) character (that is,
  29 anything that is not a letter, digit or underscore), then the backslash just
  30 takes away the special meaning (if any) of the character following it.
  31
  32 If the character following the backslash is an ASCII letter or an ASCII digit,
  33 then the sequence may be special; if so, it's listed below. A few letters have
  34 not been used yet, and escaping them with a backslash is safe for now, but a
  35 future version of Perl may assign a special meaning to it. However, if you
  36 have warnings turned on, Perl will issue a warning if you use such a sequence.
  37 [1].
  38
  39 It is however guaranteed that backslash or escape sequences never have a
  40 punctuation character following the backslash, not now, and not in a future
  41 version of Perl 5. So it is safe to put a backslash in front of a non-word
  42 character.
  43
  44 Note that the backslash itself is special; if you want to match a backslash,
  45 you have to escape the backslash with a backslash: C</\\/> matches a single
  46 backslash.
  47
  48 =over 4
  49
  50 =item [1]
  51
  52 There is one exception. If you use an alphanumerical character as the
  53 delimiter of your pattern (which you probably shouldn't do for readability
  54 reasons), you will have to escape the delimiter if you want to match
  55 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  56 quoted constructs>.
  57
  58 =back
  59
  60
  61 =head2 All the sequences and escapes
  62
  63 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
  64 as C<Not in [].>
  65
  66  \000              Octal escape sequence.
  67  \1                Absolute backreference.  Not in [].
  68  \a                Alarm or bell.
  69  \A                Beginning of string.  Not in [].
  70  \b                Word/non-word boundary. (Backspace in []).
  71  \B                Not a word/non-word boundary.  Not in [].
  72  \cX               Control-X (X can be any ASCII character).
  73  \C                Single octet, even under UTF-8.  Not in [].
  74  \d                Character class for digits.
  75  \D                Character class for non-digits.
  76  \e                Escape character.
  77  \E                Turn off \Q, \L and \U processing.  Not in [].
  78  \f                Form feed.
  79  \g{}, \g1         Named, absolute or relative backreference.  Not in [].
  80  \G                Pos assertion.  Not in [].
  81  \h                Character class for horizontal whitespace.
  82  \H                Character class for non horizontal whitespace.
  83  \k{}, \k<>, \k''  Named backreference.  Not in [].
  84  \K                Keep the stuff left of \K.  Not in [].
  85  \l                Lowercase next character.  Not in [].
  86  \L                Lowercase till \E.  Not in [].
  87  \n                (Logical) newline character.
  88  \N                Any character but newline.  Experimental.  Not in [].
  89  \N{}              Named or numbered (Unicode) character.
  90  \p{}, \pP         Character with the given Unicode property.
  91  \P{}, \PP         Character without the given Unicode property.
  92  \Q                Quotemeta till \E.  Not in [].
  93  \r                Return character.
  94  \R                Generic new line.  Not in [].
  95  \s                Character class for whitespace.
  96  \S                Character class for non whitespace.
  97  \t                Tab character.
  98  \u                Titlecase next character.  Not in [].
  99  \U                Uppercase till \E.  Not in [].
 100  \v                Character class for vertical whitespace.
 101  \V                Character class for non vertical whitespace.
 102  \w                Character class for word characters.
 103  \W                Character class for non-word characters.
 104  \x{}, \x00        Hexadecimal escape sequence.
 105  \X                Unicode "extended grapheme cluster".  Not in [].
 106  \z                End of string.  Not in [].
 107  \Z                End of string.  Not in [].
 108
 109 =head2 Character Escapes
 110
 111 =head3  Fixed characters
 112
 113 A handful of characters have a dedicated I<character escape>. The following
 114 table shows them, along with their ASCII code points (in decimal and hex),
 115 their ASCII name, the control escape (see below) and a short description.
 116
 117  Seq.  Code Point  ASCII   Cntr    Description.
 118        Dec    Hex
 119   \a     7     07    BEL    \cG    alarm or bell
 120   \b     8     08     BS    \cH    backspace [1]
 121   \e    27     1B    ESC    \c[    escape character
 122   \f    12     0C     FF    \cL    form feed
 123   \n    10     0A     LF    \cJ    line feed [2]
 124   \r    13     0D     CR    \cM    carriage return
 125   \t     9     09    TAB    \cI    tab
 126
 127 =over 4
 128
 129 =item [1]
 130
 131 C<\b> is only the backspace character inside a character class. Outside a
 132 character class, C<\b> is a word/non-word boundary.
 133
 134 =item [2]
 135
 136 C<\n> matches a logical newline. Perl will convert between C<\n> and your
 137 OSses native newline character when reading from or writing to text files.
 138
 139 =back
 140
 141 =head4 Example
 142
 143  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 144
 145 =head3 Control characters
 146
 147 C<\c> is used to denote a control character; the character following C<\c>
 148 is the name of the control character. For instance, C</\cM/> matches the
 149 character I<control-M> (a carriage return, code point 13). The case of the
 150 character following C<\c> doesn't matter: C<\cM> and C<\cm> match the same
 151 character.
 152
 153 Mnemonic: I<c>ontrol character.
 154
 155 =head4 Example
 156
 157  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 158
 159 =head3 Named or numbered characters
 160
 161 All Unicode characters have a Unicode name and numeric ordinal value.  Use the
 162 C<\N{}> construct to specify a character by either of these values.
 163
 164 To specify by name, the name of the character goes between the curly braces.
 165 In this case, you have to C<use charnames> to load the Unicode names of the
 166 characters, otherwise Perl will complain.
 167
 168 To specify by Unicode ordinal number, use the form
 169 C<\N{U+I<wide hex character>}>, where I<wide hex character> is a number in
 170 hexadecimal that gives the ordinal number that Unicode has assigned to the
 171 desired character.  It is customary (but not required) to use leading zeros to
 172 pad the number to 4 digits.  Thus C<\N{U+0041}> means
 173 C<Latin Capital Letter A>, and you will rarely see it written without the two
 174 leading zeros.  C<\N{U+0041}> means C<A> even on EBCDIC machines (where the
 175 ordinal value of C<A> is not 0x41).
 176
 177 It is even possible to give your own names to characters, and even to short
 178 sequences of characters.  For details, see L<charnames>.
 179
 180 (There is an expanded internal form that you may see in debug output:
 181 C<\N{U+I<wide hex character>.I<wide hex character>...}>.
 182 The C<...> means any number of these I<wide hex character>s separated by dots.
 183 This represents the sequence formed by the characters.  This is an internal
 184 form only, subject to change, and you should not try to use it yourself.)
 185
 186 Mnemonic: I<N>amed character.
 187
 188 Note that a character that is expressed as a named or numbered character is
 189 considered as a character without special meaning by the regex engine, and will
 190 match "as is".
 191
 192 =head4 Example
 193
 194  use charnames ':full';               # Loads the Unicode names.
 195  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 196
 197  use charnames 'Cyrillic';            # Loads Cyrillic names.
 198  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 199
 200 =head3 Octal escapes
 201
 202 Octal escapes consist of a backslash followed by two or three octal digits
 203 matching the code point of the character you want to use. This allows for
 204 512 characters (C<\00> up to C<\777>) that can be expressed this way (but
 205 anything above C<\377> is deprecated).
 206 Enough in pre-Unicode days, but most Unicode characters cannot be escaped
 207 this way.
 208
 209 Note that a character that is expressed as an octal escape is considered
 210 as a character without special meaning by the regex engine, and will match
 211 "as is".
 212
 213 =head4 Examples (assuming an ASCII platform)
 214
 215  $str = "Perl";
 216  $str =~ /\120/;    # Match, "\120" is "P".
 217  $str =~ /\120+/;   # Match, "\120" is "P", it is repeated at least once.
 218  $str =~ /P\053/;   # No match, "\053" is "+" and taken literally.
 219
 220 =head4 Caveat
 221
 222 Octal escapes potentially clash with backreferences. They both consist
 223 of a backslash followed by numbers. So Perl has to use heuristics to
 224 determine whether it is a backreference or an octal escape. Perl uses
 225 the following rules:
 226
 227 =over 4
 228
 229 =item 1
 230
 231 If the backslash is followed by a single digit, it's a backreference.
 232
 233 =item 2
 234
 235 If the first digit following the backslash is a 0, it's an octal escape.
 236
 237 =item 3
 238
 239 If the number following the backslash is N (decimal), and Perl already has
 240 seen N capture groups, Perl will consider this to be a backreference.
 241 Otherwise, it will consider it to be an octal escape. Note that if N > 999,
 242 Perl only takes the first three digits for the octal escape; the rest is
 243 matched as is.
 244
 245  my $pat  = "(" x 999;
 246     $pat .= "a";
 247     $pat .= ")" x 999;
 248  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 249  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 250                     #    and \1000 is seen as \100 (a '@') and a '0'.
 251
 252 =back
 253
 254 =head3 Hexadecimal escapes
 255
 256 Hexadecimal escapes start with C<\x> and are then either followed by a
 257 two digit hexadecimal number, or a hexadecimal number of arbitrary length
 258 surrounded by curly braces. The hexadecimal number is the code point of
 259 the character you want to express.
 260
 261 Note that a character that is expressed as a hexadecimal escape is considered
 262 as a character without special meaning by the regex engine, and will match
 263 "as is".
 264
 265 Mnemonic: heI<x>adecimal.
 266
 267 =head4 Examples (assuming an ASCII platform)
 268
 269  $str = "Perl";
 270  $str =~ /\x50/;    # Match, "\x50" is "P".
 271  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once.
 272  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 273
 274  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 275                     # The Unicode character 2603 is a snowman,
 276                     # the Unicode character 2602 is an umbrella.
 277  /\x{263B}/         # Black smiling face.
 278  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 279
 280 =head2 Modifiers
 281
 282 A number of backslash sequences have to do with changing the character,
 283 or characters following them. C<\l> will lowercase the character following
 284 it, while C<\u> will uppercase (or, more accurately, titlecase) the
 285 character following it. (They perform similar functionality as the
 286 functions C<lcfirst> and C<ucfirst>).
 287
 288 To uppercase or lowercase several characters, one might want to use
 289 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 290 them, until either the end of the pattern, or the next occurrence of
 291 C<\E>, whatever comes first. They perform similar functionality as the
 292 functions C<lc> and C<uc> do.
 293
 294 C<\Q> is used to escape all characters following, up to the next C<\E>
 295 or the end of the pattern. C<\Q> adds a backslash to any character that
 296 isn't a letter, digit or underscore. This will ensure that any character
 297 between C<\Q> and C<\E> is matched literally, and will not be interpreted
 298 by the regexp engine.
 299
 300 Mnemonic: I<L>owercase, I<U>ppercase, I<Q>uotemeta, I<E>nd.
 301
 302 =head4 Examples
 303
 304  $sid     = "sid";
 305  $greg    = "GrEg";
 306  $miranda = "(Miranda)";
 307  $str     =~ /\u$sid/;        # Matches 'Sid'
 308  $str     =~ /\L$greg/;       # Matches 'greg'
 309  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 310                               #   had been written as /\(Miranda\)/
 311
 312 =head2 Character classes
 313
 314 Perl regular expressions have a large range of character classes. Some of
 315 the character classes are written as a backslash sequence. We will briefly
 316 discuss those here; full details of character classes can be found in
 317 L<perlrecharclass>.
 318
 319 C<\w> is a character class that matches any single I<word> character (letters,
 320 digits, underscore). C<\d> is a character class that matches any decimal digit,
 321 while the character class C<\s> matches any whitespace character.
 322 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 323 and vertical whitespace characters.
 324
 325 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 326 character classes that match any character that isn't a word character,
 327 digit, whitespace, horizontal whitespace nor vertical whitespace.
 328
 329 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 330
 331 =head3 Unicode classes
 332
 333 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 334 match a character that matches the given Unicode property; properties
 335 include things like "letter", or "thai character". Capitalizing the
 336 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 337 that doesn't match the given Unicode property. For more details, see
 338 L<perlrecharclass/Backslashed sequences> and
 339 L<perlunicode/Unicode Character Properties>.
 340
 341 Mnemonic: I<p>roperty.
 342
 343
 344 =head2 Referencing
 345
 346 If capturing parenthesis are used in a regular expression, we can refer
 347 to the part of the source string that was matched, and match exactly the
 348 same thing. There are three ways of referring to such I<backreference>:
 349 absolutely, relatively, and by name.
 350
 351 =for later add link to perlrecapture
 352
 353 =head3 Absolute referencing
 354
 355 A backslash sequence that starts with a backslash and is followed by a
 356 number is an absolute reference (but be aware of the caveat mentioned above).
 357 If the number is I<N>, it refers to the Nth set of parentheses - whatever
 358 has been matched by that set of parenthesis has to be matched by the C<\N>
 359 as well.
 360
 361 =head4 Examples
 362
 363  /(\w+) \1/;    # Finds a duplicated word, (e.g. "cat cat").
 364  /(.)(.)\2\1/;  # Match a four letter palindrome (e.g. "ABBA").
 365
 366
 367 =head3 Relative referencing
 368
 369 New in perl 5.10.0 is a different way of referring to capture buffers: C<\g>.
 370 C<\g> takes a number as argument, with the number in curly braces (the
 371 braces are optional). If the number (N) does not have a sign, it's a reference
 372 to the Nth capture group (so C<\g{2}> is equivalent to C<\2> - except that
 373 C<\g> always refers to a capture group and will never be seen as an octal
 374 escape). If the number is negative, the reference is relative, referring to
 375 the Nth group before the C<\g{-N}>.
 376
 377 The big advantage of C<\g{-N}> is that it makes it much easier to write
 378 patterns with references that can be interpolated in larger patterns,
 379 even if the larger pattern also contains capture groups.
 380
 381 Mnemonic: I<g>roup.
 382
 383 =head4 Examples
 384
 385  /(A)        # Buffer 1
 386   (          # Buffer 2
 387     (B)      # Buffer 3
 388     \g{-1}   # Refers to buffer 3 (B)
 389     \g{-3}   # Refers to buffer 1 (A)
 390   )
 391  /x;         # Matches "ABBA".
 392
 393  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 394  /$qr$qr/                           # Matches 'ababcdcd'.
 395
 396 =head3 Named referencing
 397
 398 Also new in perl 5.10.0 is the use of named capture buffers, which can be
 399 referred to by name. This is done with C<\g{name}>, which is a
 400 backreference to the capture buffer with the name I<name>.
 401
 402 To be compatible with .Net regular expressions, C<\g{name}> may also be
 403 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 404
 405 Note that C<\g{}> has the potential to be ambiguous, as it could be a named
 406 reference, or an absolute or relative reference (if its argument is numeric).
 407 However, names are not allowed to start with digits, nor are they allowed to
 408 contain a hyphen, so there is no ambiguity.
 409
 410 =head4 Examples
 411
 412  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 413  /(?<word>\w+) \k{word}/ # Same.
 414  /(?<word>\w+) \k<word>/ # Same.
 415  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 416                          # Match a four letter palindrome (e.g. "ABBA")
 417
 418 =head2 Assertions
 419
 420 Assertions are conditions that have to be true; they don't actually
 421 match parts of the substring. There are six assertions that are written as
 422 backslash sequences.
 423
 424 =over 4
 425
 426 =item \A
 427
 428 C<\A> only matches at the beginning of the string. If the C</m> modifier
 429 isn't used, then C</\A/> is equivalent with C</^/>. However, if the C</m>
 430 modifier is used, then C</^/> matches internal newlines, but the meaning
 431 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 432 of the string regardless whether the C</m> modifier is used.
 433
 434 =item \z, \Z
 435
 436 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 437 used, then C</\Z/> is equivalent with C</$/>, that is, it matches at the
 438 end of the string, or before the newline at the end of the string. If the
 439 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 440 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 441 the end of the string (or just before a trailing newline) regardless whether
 442 the C</m> modifier is used.
 443
 444 C<\z> is just like C<\Z>, except that it will not match before a trailing
 445 newline. C<\z> will only match at the end of the string - regardless of the
 446 modifiers used, and not before a newline.
 447
 448 =item \G
 449
 450 C<\G> is usually only used in combination with the C</g> modifier. If the
 451 C</g> modifier is used (and the match is done in scalar context), Perl will
 452 remember where in the source string the last match ended, and the next time,
 453 it will start the match from where it ended the previous time.
 454
 455 C<\G> matches the point where the previous match ended, or the beginning
 456 of the string if there was no previous match.
 457
 458 =for later add link to perlremodifiers
 459
 460 Mnemonic: I<G>lobal.
 461
 462 =item \b, \B
 463
 464 C<\b> matches at any place between a word and a non-word character; C<\B>
 465 matches at any place between characters where C<\b> doesn't match. C<\b>
 466 and C<\B> assume there's a non-word character before the beginning and after
 467 the end of the source string; so C<\b> will match at the beginning (or end)
 468 of the source string if the source string begins (or ends) with a word
 469 character. Otherwise, C<\B> will match.
 470
 471 Mnemonic: I<b>oundary.
 472
 473 =back
 474
 475 =head4 Examples
 476
 477   "cat"   =~ /\Acat/;     # Match.
 478   "cat"   =~ /cat\Z/;     # Match.
 479   "cat\n" =~ /cat\Z/;     # Match.
 480   "cat\n" =~ /cat\z/;     # No match.
 481
 482   "cat"   =~ /\bcat\b/;   # Matches.
 483   "cats"  =~ /\bcat\b/;   # No match.
 484   "cat"   =~ /\bcat\B/;   # No match.
 485   "cats"  =~ /\bcat\B/;   # Match.
 486
 487   while ("cat dog" =~ /(\w+)/g) {
 488       print $1;           # Prints 'catdog'
 489   }
 490   while ("cat dog" =~ /\G(\w+)/g) {
 491       print $1;           # Prints 'cat'
 492   }
 493
 494 =head2 Misc
 495
 496 Here we document the backslash sequences that don't fall in one of the
 497 categories above. They are:
 498
 499 =over 4
 500
 501 =item \C
 502
 503 C<\C> always matches a single octet, even if the source string is encoded
 504 in UTF-8 format, and the character to be matched is a multi-octet character.
 505 C<\C> was introduced in perl 5.6.
 506
 507 Mnemonic: oI<C>tet.
 508
 509 =item \K
 510
 511 This is new in perl 5.10.0. Anything that is matched left of C<\K> is
 512 not included in C<$&> - and will not be replaced if the pattern is
 513 used in a substitution. This will allow you to write C<s/PAT1 \K PAT2/REPL/x>
 514 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 515
 516 Mnemonic: I<K>eep.
 517
 518 =item \N
 519
 520 This is a new experimental feature in perl 5.12.0.  It matches any character
 521 that is not a newline.  It is a short-hand for writing C<[^\n]>, and is
 522 identical to the C<.> metasymbol, except under the C</s> flag, which changes
 523 the meaning of C<.>, but not C<\N>.
 524
 525 Note that C<\N{...}> can mean a
 526 L<named or numbered character|/Named or numbered characters>.
 527
 528 Mnemonic: Complement of I<\n>.
 529
 530 =item \R
 531
 532 C<\R> matches a I<generic newline>, that is, anything that is considered
 533 a newline by Unicode. This includes all characters matched by C<\v>
 534 (vertical whitespace), and the multi character sequence C<"\x0D\x0A">
 535 (carriage return followed by a line feed, aka the network newline, or
 536 the newline used in Windows text files). C<\R> is equivalent to
 537 C<< (?>\x0D\x0A)|\v) >>. Since C<\R> can match a sequence of more than one
 538 character, it cannot be put inside a bracketed character class; C</[\R]/> is an
 539 error; use C<\v> instead.  C<\R> was introduced in perl 5.10.0.
 540
 541 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 542 and more importantly because Unicode recommends such a regular expression
 543 metacharacter, and suggests C<\R> as the notation.
 544
 545 =item \X
 546
 547 This matches a Unicode I<extended grapheme cluster>.
 548
 549 C<\X> matches quite well what normal (non-Unicode-programmer) usage
 550 would consider a single character.  As an example, consider a G with some sort
 551 of diacritic mark, such as an arrow.  There is no such single character in
 552 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
 553 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
 554 were a single character.
 555
 556 Mnemonic: eI<X>tended Unicode character.
 557
 558 =back
 559
 560 =head4 Examples
 561
 562  "\x{256}" =~ /^\C\C$/;    # Match as chr (256) takes 2 octets in UTF-8.
 563
 564  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'.
 565  $str =~ s/(.)\K\1//g;     # Delete duplicated characters.
 566
 567  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 568  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 569  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 570
 571  "P\x{0307}" =~ /^\X$/     # \X matches a P with a dot above.
 572
 573 =cut