This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl #119807] Deparse s//\(3)/e in a way that does not warn
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          CVf_METHOD CVf_LVALUE
21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
23 $VERSION = '1.23';
24 use strict;
25 use vars qw/$AUTOLOAD/;
26 use warnings ();
27 require feature;
28
29 BEGIN {
30     # List version-specific constants here.
31     # Easiest way to keep this code portable between version looks to
32     # be to fake up a dummy constant that will never actually be true.
33     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
34                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
35                 RXf_PMf_CHARSET RXf_PMf_KEEPCOPY
36                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
37                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES)) {
38         eval { import B $_ };
39         no strict 'refs';
40         *{$_} = sub () {0} unless *{$_}{CODE};
41     }
42 }
43
44 # Changes between 0.50 and 0.51:
45 # - fixed nulled leave with live enter in sort { }
46 # - fixed reference constants (\"str")
47 # - handle empty programs gracefully
48 # - handle infinite loops (for (;;) {}, while (1) {})
49 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
50 # - various minor cleanups
51 # - moved globals into an object
52 # - added '-u', like B::C
53 # - package declarations using cop_stash
54 # - subs, formats and code sorted by cop_seq
55 # Changes between 0.51 and 0.52:
56 # - added pp_threadsv (special variables under USE_5005THREADS)
57 # - added documentation
58 # Changes between 0.52 and 0.53:
59 # - many changes adding precedence contexts and associativity
60 # - added '-p' and '-s' output style options
61 # - various other minor fixes
62 # Changes between 0.53 and 0.54:
63 # - added support for new 'for (1..100)' optimization,
64 #   thanks to Gisle Aas
65 # Changes between 0.54 and 0.55:
66 # - added support for new qr// construct
67 # - added support for new pp_regcreset OP
68 # Changes between 0.55 and 0.56:
69 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
70 # - fixed $# on non-lexicals broken in last big rewrite
71 # - added temporary fix for change in opcode of OP_STRINGIFY
72 # - fixed problem in 0.54's for() patch in 'for (@ary)'
73 # - fixed precedence in conditional of ?:
74 # - tweaked list paren elimination in 'my($x) = @_'
75 # - made continue-block detection trickier wrt. null ops
76 # - fixed various prototype problems in pp_entersub
77 # - added support for sub prototypes that never get GVs
78 # - added unquoting for special filehandle first arg in truncate
79 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
80 # - added semicolons at the ends of blocks
81 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
82 # Changes between 0.56 and 0.561:
83 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
84 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
85 # Changes between 0.561 and 0.57:
86 # - stylistic changes to symbolic constant stuff
87 # - handled scope in s///e replacement code
88 # - added unquote option for expanding "" into concats, etc.
89 # - split method and proto parts of pp_entersub into separate functions
90 # - various minor cleanups
91 # Changes after 0.57:
92 # - added parens in \&foo (patch by Albert Dvornik)
93 # Changes between 0.57 and 0.58:
94 # - fixed '0' statements that weren't being printed
95 # - added methods for use from other programs
96 #   (based on patches from James Duncan and Hugo van der Sanden)
97 # - added -si and -sT to control indenting (also based on a patch from Hugo)
98 # - added -sv to print something else instead of '???'
99 # - preliminary version of utf8 tr/// handling
100 # Changes after 0.58:
101 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
102 # - added support for Hugo's new OP_SETSTATE (like nextstate)
103 # Changes between 0.58 and 0.59
104 # - added support for Chip's OP_METHOD_NAMED
105 # - added support for Ilya's OPpTARGET_MY optimization
106 # - elided arrows before '()' subscripts when possible
107 # Changes between 0.59 and 0.60
108 # - support for method attributes was added
109 # - some warnings fixed
110 # - separate recognition of constant subs
111 # - rewrote continue block handling, now recognizing for loops
112 # - added more control of expanding control structures
113 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
114 # - many bug-fixes
115 # - support for pragmas and 'use'
116 # - support for the little-used $[ variable
117 # - support for __DATA__ sections
118 # - UTF8 support
119 # - BEGIN, CHECK, INIT and END blocks
120 # - scoping of subroutine declarations fixed
121 # - compile-time output from the input program can be suppressed, so that the
122 #   output is just the deparsed code. (a change to O.pm in fact)
123 # - our() declarations
124 # - *all* the known bugs are now listed in the BUGS section
125 # - comprehensive test mechanism (TEST -deparse)
126 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
127 # - bug-fixes
128 # - new switch -P
129 # - support for command-line switches (-l, -0, etc.)
130 # Changes between 0.63 and 0.64
131 # - support for //, CHECK blocks, and assertions
132 # - improved handling of foreach loops and lexicals
133 # - option to use Data::Dumper for constants
134 # - more bug fixes
135 # - discovered lots more bugs not yet fixed
136 #
137 # ...
138 #
139 # Changes between 0.72 and 0.73
140 # - support new switch constructs
141
142 # Todo:
143 #  (See also BUGS section at the end of this file)
144 #
145 # - finish tr/// changes
146 # - add option for even more parens (generalize \&foo change)
147 # - left/right context
148 # - copy comments (look at real text with $^P?)
149 # - avoid semis in one-statement blocks
150 # - associativity of &&=, ||=, ?:
151 # - ',' => '=>' (auto-unquote?)
152 # - break long lines ("\r" as discretionary break?)
153 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
154 # - more style options: brace style, hex vs. octal, quotes, ...
155 # - print big ints as hex/octal instead of decimal (heuristic?)
156 # - handle 'my $x if 0'?
157 # - version using op_next instead of op_first/sibling?
158 # - avoid string copies (pass arrays, one big join?)
159 # - here-docs?
160
161 # Current test.deparse failures
162 # comp/hints 6 - location of BEGIN blocks wrt. block openings
163 # run/switchI 1 - missing -I switches entirely
164 #    perl -Ifoo -e 'print @INC'
165 # op/caller 2 - warning mask propagates backwards before warnings::register
166 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
167 # op/getpid 2 - can't assign to shared my() declaration (threads only)
168 #    'my $x : shared = 5'
169 # op/override 7 - parens on overridden require change v-string interpretation
170 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
171 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
172 # op/pat 774 - losing Unicode-ness of Latin1-only strings
173 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
174 # op/recurse 12 - missing parens on recursive call makes it look like method
175 #    'sub f { f($x) }'
176 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
177 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
178 # op/tiehandle compile - "use strict" deparsed in the wrong place
179 # uni/tr_ several
180 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
181 # ext/Data/Dumper/t/dumper compile
182 # ext/DB_file/several
183 # ext/Encode/several
184 # ext/Ernno/Errno warnings
185 # ext/IO/lib/IO/t/io_sel 23
186 # ext/PerlIO/t/encoding compile
187 # ext/POSIX/t/posix 6
188 # ext/Socket/Socket 8
189 # ext/Storable/t/croak compile
190 # lib/Attribute/Handlers/t/multi compile
191 # lib/bignum/ several
192 # lib/charnames 35
193 # lib/constant 32
194 # lib/English 40
195 # lib/ExtUtils/t/bytes 4
196 # lib/File/DosGlob compile
197 # lib/Filter/Simple/t/data 1
198 # lib/Math/BigInt/t/constant 1
199 # lib/Net/t/config Deparse-warning
200 # lib/overload compile
201 # lib/Switch/ several
202 # lib/Symbol 4
203 # lib/Test/Simple several
204 # lib/Term/Complete
205 # lib/Tie/File/t/29_downcopy 5
206 # lib/vars 22
207
208 # Object fields (were globals):
209 #
210 # avoid_local:
211 # (local($a), local($b)) and local($a, $b) have the same internal
212 # representation but the short form looks better. We notice we can
213 # use a large-scale local when checking the list, but need to prevent
214 # individual locals too. This hash holds the addresses of OPs that
215 # have already had their local-ness accounted for. The same thing
216 # is done with my().
217 #
218 # curcv:
219 # CV for current sub (or main program) being deparsed
220 #
221 # curcvlex:
222 # Cached hash of lexical variables for curcv: keys are
223 # names prefixed with "m" or "o" (representing my/our), and
224 # each value is an array of pairs, indicating the cop_seq of scopes
225 # in which a var of that name is valid.
226 #
227 # curcop:
228 # COP for statement being deparsed
229 #
230 # curstash:
231 # name of the current package for deparsed code
232 #
233 # subs_todo:
234 # array of [cop_seq, CV, is_format?] for subs and formats we still
235 # want to deparse
236 #
237 # protos_todo:
238 # as above, but [name, prototype] for subs that never got a GV
239 #
240 # subs_done, forms_done:
241 # keys are addresses of GVs for subs and formats we've already
242 # deparsed (or at least put into subs_todo)
243 #
244 # subs_declared
245 # keys are names of subs for which we've printed declarations.
246 # That means we can omit parentheses from the arguments. It also means we
247 # need to put CORE:: on core functions of the same name.
248 #
249 # subs_deparsed
250 # Keeps track of fully qualified names of all deparsed subs.
251 #
252 # in_subst_repl
253 # True when deparsing the replacement part of a substitution.
254 #
255 # parens: -p
256 # linenums: -l
257 # unquote: -q
258 # cuddle: ' ' or '\n', depending on -sC
259 # indent_size: -si
260 # use_tabs: -sT
261 # ex_const: -sv
262
263 # A little explanation of how precedence contexts and associativity
264 # work:
265 #
266 # deparse() calls each per-op subroutine with an argument $cx (short
267 # for context, but not the same as the cx* in the perl core), which is
268 # a number describing the op's parents in terms of precedence, whether
269 # they're inside an expression or at statement level, etc.  (see
270 # chart below). When ops with children call deparse on them, they pass
271 # along their precedence. Fractional values are used to implement
272 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
273 # parentheses hacks. The major disadvantage of this scheme is that
274 # it doesn't know about right sides and left sides, so say if you
275 # assign a listop to a variable, it can't tell it's allowed to leave
276 # the parens off the listop.
277
278 # Precedences:
279 # 26             [TODO] inside interpolation context ("")
280 # 25 left        terms and list operators (leftward)
281 # 24 left        ->
282 # 23 nonassoc    ++ --
283 # 22 right       **
284 # 21 right       ! ~ \ and unary + and -
285 # 20 left        =~ !~
286 # 19 left        * / % x
287 # 18 left        + - .
288 # 17 left        << >>
289 # 16 nonassoc    named unary operators
290 # 15 nonassoc    < > <= >= lt gt le ge
291 # 14 nonassoc    == != <=> eq ne cmp
292 # 13 left        &
293 # 12 left        | ^
294 # 11 left        &&
295 # 10 left        ||
296 #  9 nonassoc    ..  ...
297 #  8 right       ?:
298 #  7 right       = += -= *= etc.
299 #  6 left        , =>
300 #  5 nonassoc    list operators (rightward)
301 #  4 right       not
302 #  3 left        and
303 #  2 left        or xor
304 #  1             statement modifiers
305 #  0.5           statements, but still print scopes as do { ... }
306 #  0             statement level
307 # -1             format body
308
309 # Nonprinting characters with special meaning:
310 # \cS - steal parens (see maybe_parens_unop)
311 # \n - newline and indent
312 # \t - increase indent
313 # \b - decrease indent ('outdent')
314 # \f - flush left (no indent)
315 # \cK - kill following semicolon, if any
316
317
318
319
320 # _pessimise_walk(): recursively walk the optree of a sub,
321 # possibly undoing optimisations along the way.
322
323 sub _pessimise_walk {
324     my ($self, $startop) = @_;
325
326     return unless $$startop;
327     my ($op, $prevop);
328     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
329         my $ppname = $op->name;
330
331         # pessimisations start here
332
333         if ($ppname eq "padrange") {
334             # remove PADRANGE:
335             # the original optimisation either (1) changed this:
336             #    pushmark -> (various pad and list and null ops) -> the_rest
337             # or (2), for the = @_ case, changed this:
338             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
339             # into this:
340             #    padrange ----------------------------------------> the_rest
341             # so we just need to convert the padrange back into a
342             # pushmark, and in case (1), set its op_next to op_sibling,
343             # which is the head of the original chain of optimised-away
344             # pad ops, or for (2), set it to sibling->first, which is
345             # the original gv[_].
346
347             $B::overlay->{$$op} = {
348                     name => 'pushmark',
349                     private => ($op->private & OPpLVAL_INTRO),
350                     next    => ($op->flags & OPf_SPECIAL)
351                                     ? $op->sibling->first
352                                     : $op->sibling,
353             };
354         }
355
356         # pessimisations end here
357
358         if (class($op) eq 'PMOP'
359             && ref($op->pmreplroot)
360             && ${$op->pmreplroot}
361             && $op->pmreplroot->isa( 'B::OP' ))
362         {
363             $self-> _pessimise_walk($op->pmreplroot);
364         }
365
366         if ($op->flags & OPf_KIDS) {
367             $self-> _pessimise_walk($op->first);
368         }
369
370     }
371 }
372
373
374 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
375 # possibly undoing optimisations along the way.
376
377 sub _pessimise_walk_exe {
378     my ($self, $startop, $visited) = @_;
379
380     return unless $$startop;
381     return if $visited->{$$startop};
382     my ($op, $prevop);
383     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
384         last if $visited->{$$op};
385         $visited->{$$op} = 1;
386         my $ppname = $op->name;
387         if ($ppname =~
388             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
389             # entertry is also a logop, but its op_other invariably points
390             # into the same chain as the main execution path, so we skip it
391         ) {
392             $self->_pessimise_walk_exe($op->other, $visited);
393         }
394         elsif ($ppname eq "subst") {
395             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
396         }
397         elsif ($ppname =~ /^(enter(loop|iter))$/) {
398             # redoop and nextop will already be covered by the main block
399             # of the loop
400             $self->_pessimise_walk_exe($op->lastop, $visited);
401         }
402
403         # pessimisations start here
404     }
405 }
406
407 # Go through an optree and "remove" some optimisations by using an
408 # overlay to selectively modify or un-null some ops. Deparsing in the
409 # absence of those optimisations is then easier.
410 #
411 # Note that older optimisations are not removed, as Deparse was already
412 # written to recognise them before the pessimise/overlay system was added.
413
414 sub pessimise {
415     my ($self, $root, $start) = @_;
416
417     # walk tree in root-to-branch order
418     $self->_pessimise_walk($root);
419
420     my %visited;
421     # walk tree in execution order
422     $self->_pessimise_walk_exe($start, \%visited);
423 }
424
425
426 sub null {
427     my $op = shift;
428     return class($op) eq "NULL";
429 }
430
431 sub todo {
432     my $self = shift;
433     my($cv, $is_form) = @_;
434     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
435     my $seq;
436     if ($cv->OUTSIDE_SEQ) {
437         $seq = $cv->OUTSIDE_SEQ;
438     } elsif (!null($cv->START) and is_state($cv->START)) {
439         $seq = $cv->START->cop_seq;
440     } else {
441         $seq = 0;
442     }
443     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
444     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
445         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
446     }
447 }
448
449 sub next_todo {
450     my $self = shift;
451     my $ent = shift @{$self->{'subs_todo'}};
452     my $cv = $ent->[1];
453     my $gv = $cv->GV;
454     my $name = $self->gv_name($gv);
455     if ($ent->[2]) {
456         return "format $name =\n"
457             . $self->deparse_format($ent->[1]). "\n";
458     } else {
459         $self->{'subs_declared'}{$name} = 1;
460         if ($name eq "BEGIN") {
461             my $use_dec = $self->begin_is_use($cv);
462             if (defined ($use_dec) and $self->{'expand'} < 5) {
463                 return () if 0 == length($use_dec);
464                 return $use_dec;
465             }
466         }
467         my $l = '';
468         if ($self->{'linenums'}) {
469             my $line = $gv->LINE;
470             my $file = $gv->FILE;
471             $l = "\n\f#line $line \"$file\"\n";
472         }
473         my $p = '';
474         if (class($cv->STASH) ne "SPECIAL") {
475             my $stash = $cv->STASH->NAME;
476             if ($stash ne $self->{'curstash'}) {
477                 $p = "package $stash;\n";
478                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
479                 $self->{'curstash'} = $stash;
480             }
481             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
482         }
483         return "${p}${l}sub $name " . $self->deparse_sub($cv);
484     }
485 }
486
487 # Return a "use" declaration for this BEGIN block, if appropriate
488 sub begin_is_use {
489     my ($self, $cv) = @_;
490     my $root = $cv->ROOT;
491     local @$self{qw'curcv curcvlex'} = ($cv);
492     local $B::overlay = {};
493     $self->pessimise($root, $cv->START);
494 #require B::Debug;
495 #B::walkoptree($cv->ROOT, "debug");
496     my $lineseq = $root->first;
497     return if $lineseq->name ne "lineseq";
498
499     my $req_op = $lineseq->first->sibling;
500     return if $req_op->name ne "require";
501
502     my $module;
503     if ($req_op->first->private & OPpCONST_BARE) {
504         # Actually it should always be a bareword
505         $module = $self->const_sv($req_op->first)->PV;
506         $module =~ s[/][::]g;
507         $module =~ s/.pm$//;
508     }
509     else {
510         $module = $self->const($self->const_sv($req_op->first), 6);
511     }
512
513     my $version;
514     my $version_op = $req_op->sibling;
515     return if class($version_op) eq "NULL";
516     if ($version_op->name eq "lineseq") {
517         # We have a version parameter; skip nextstate & pushmark
518         my $constop = $version_op->first->next->next;
519
520         return unless $self->const_sv($constop)->PV eq $module;
521         $constop = $constop->sibling;
522         $version = $self->const_sv($constop);
523         if (class($version) eq "IV") {
524             $version = $version->int_value;
525         } elsif (class($version) eq "NV") {
526             $version = $version->NV;
527         } elsif (class($version) ne "PVMG") {
528             # Includes PVIV and PVNV
529             $version = $version->PV;
530         } else {
531             # version specified as a v-string
532             $version = 'v'.join '.', map ord, split //, $version->PV;
533         }
534         $constop = $constop->sibling;
535         return if $constop->name ne "method_named";
536         return if $self->const_sv($constop)->PV ne "VERSION";
537     }
538
539     $lineseq = $version_op->sibling;
540     return if $lineseq->name ne "lineseq";
541     my $entersub = $lineseq->first->sibling;
542     if ($entersub->name eq "stub") {
543         return "use $module $version ();\n" if defined $version;
544         return "use $module ();\n";
545     }
546     return if $entersub->name ne "entersub";
547
548     # See if there are import arguments
549     my $args = '';
550
551     my $svop = $entersub->first->sibling; # Skip over pushmark
552     return unless $self->const_sv($svop)->PV eq $module;
553
554     # Pull out the arguments
555     for ($svop=$svop->sibling; $svop->name ne "method_named";
556                 $svop = $svop->sibling) {
557         $args .= ", " if length($args);
558         $args .= $self->deparse($svop, 6);
559     }
560
561     my $use = 'use';
562     my $method_named = $svop;
563     return if $method_named->name ne "method_named";
564     my $method_name = $self->const_sv($method_named)->PV;
565
566     if ($method_name eq "unimport") {
567         $use = 'no';
568     }
569
570     # Certain pragmas are dealt with using hint bits,
571     # so we ignore them here
572     if ($module eq 'strict' || $module eq 'integer'
573         || $module eq 'bytes' || $module eq 'warnings'
574         || $module eq 'feature') {
575         return "";
576     }
577
578     if (defined $version && length $args) {
579         return "$use $module $version ($args);\n";
580     } elsif (defined $version) {
581         return "$use $module $version;\n";
582     } elsif (length $args) {
583         return "$use $module ($args);\n";
584     } else {
585         return "$use $module;\n";
586     }
587 }
588
589 sub stash_subs {
590     my ($self, $pack, $seen) = @_;
591     my (@ret, $stash);
592     if (!defined $pack) {
593         $pack = '';
594         $stash = \%::;
595     }
596     else {
597         $pack =~ s/(::)?$/::/;
598         no strict 'refs';
599         $stash = \%{"main::$pack"};
600     }
601     return
602         if ($seen ||= {})->{
603             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
604            }++;
605     my %stash = svref_2object($stash)->ARRAY;
606     while (my ($key, $val) = each %stash) {
607         my $class = class($val);
608         if ($class eq "PV") {
609             # Just a prototype. As an ugly but fairly effective way
610             # to find out if it belongs here is to see if the AUTOLOAD
611             # (if any) for the stash was defined in one of our files.
612             my $A = $stash{"AUTOLOAD"};
613             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
614                 && class($A->CV) eq "CV") {
615                 my $AF = $A->FILE;
616                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
617             }
618             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
619         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
620             # Just a name. As above.
621             # But skip proxy constant subroutines, as some form of perl-space
622             # visible code must have created them, be it a use statement, or
623             # some direct symbol-table manipulation code that we will Deparse
624             my $A = $stash{"AUTOLOAD"};
625             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
626                 && class($A->CV) eq "CV") {
627                 my $AF = $A->FILE;
628                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
629             }
630             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
631         } elsif ($class eq "GV") {
632             if (class(my $cv = $val->CV) ne "SPECIAL") {
633                 next if $self->{'subs_done'}{$$val}++;
634                 next if $$val != ${$cv->GV};   # Ignore imposters
635                 $self->todo($cv, 0);
636             }
637             if (class(my $cv = $val->FORM) ne "SPECIAL") {
638                 next if $self->{'forms_done'}{$$val}++;
639                 next if $$val != ${$cv->GV};   # Ignore imposters
640                 $self->todo($cv, 1);
641             }
642             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
643                 $self->stash_subs($pack . $key, $seen);
644             }
645         }
646     }
647 }
648
649 sub print_protos {
650     my $self = shift;
651     my $ar;
652     my @ret;
653     foreach $ar (@{$self->{'protos_todo'}}) {
654         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
655         push @ret, "sub " . $ar->[0] .  "$proto;\n";
656     }
657     delete $self->{'protos_todo'};
658     return @ret;
659 }
660
661 sub style_opts {
662     my $self = shift;
663     my $opts = shift;
664     my $opt;
665     while (length($opt = substr($opts, 0, 1))) {
666         if ($opt eq "C") {
667             $self->{'cuddle'} = " ";
668             $opts = substr($opts, 1);
669         } elsif ($opt eq "i") {
670             $opts =~ s/^i(\d+)//;
671             $self->{'indent_size'} = $1;
672         } elsif ($opt eq "T") {
673             $self->{'use_tabs'} = 1;
674             $opts = substr($opts, 1);
675         } elsif ($opt eq "v") {
676             $opts =~ s/^v([^.]*)(.|$)//;
677             $self->{'ex_const'} = $1;
678         }
679     }
680 }
681
682 sub new {
683     my $class = shift;
684     my $self = bless {}, $class;
685     $self->{'cuddle'} = "\n";
686     $self->{'curcop'} = undef;
687     $self->{'curstash'} = "main";
688     $self->{'ex_const'} = "'???'";
689     $self->{'expand'} = 0;
690     $self->{'files'} = {};
691     $self->{'indent_size'} = 4;
692     $self->{'linenums'} = 0;
693     $self->{'parens'} = 0;
694     $self->{'subs_todo'} = [];
695     $self->{'unquote'} = 0;
696     $self->{'use_dumper'} = 0;
697     $self->{'use_tabs'} = 0;
698
699     $self->{'ambient_arybase'} = 0;
700     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
701     $self->{'ambient_hints'} = 0;
702     $self->{'ambient_hinthash'} = undef;
703     $self->init();
704
705     while (my $arg = shift @_) {
706         if ($arg eq "-d") {
707             $self->{'use_dumper'} = 1;
708             require Data::Dumper;
709         } elsif ($arg =~ /^-f(.*)/) {
710             $self->{'files'}{$1} = 1;
711         } elsif ($arg eq "-l") {
712             $self->{'linenums'} = 1;
713         } elsif ($arg eq "-p") {
714             $self->{'parens'} = 1;
715         } elsif ($arg eq "-P") {
716             $self->{'noproto'} = 1;
717         } elsif ($arg eq "-q") {
718             $self->{'unquote'} = 1;
719         } elsif (substr($arg, 0, 2) eq "-s") {
720             $self->style_opts(substr $arg, 2);
721         } elsif ($arg =~ /^-x(\d)$/) {
722             $self->{'expand'} = $1;
723         }
724     }
725     return $self;
726 }
727
728 {
729     # Mask out the bits that L<warnings::register> uses
730     my $WARN_MASK;
731     BEGIN {
732         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
733     }
734     sub WARN_MASK () {
735         return $WARN_MASK;
736     }
737 }
738
739 # Initialise the contextual information, either from
740 # defaults provided with the ambient_pragmas method,
741 # or from perl's own defaults otherwise.
742 sub init {
743     my $self = shift;
744
745     $self->{'arybase'}  = $self->{'ambient_arybase'};
746     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
747                                 ? $self->{'ambient_warnings'} & WARN_MASK
748                                 : undef;
749     $self->{'hints'}    = $self->{'ambient_hints'};
750     $self->{'hints'} &= 0xFF if $] < 5.009;
751     $self->{'hinthash'} = $self->{'ambient_hinthash'};
752
753     # also a convenient place to clear out subs_declared
754     delete $self->{'subs_declared'};
755 }
756
757 sub compile {
758     my(@args) = @_;
759     return sub {
760         my $self = B::Deparse->new(@args);
761         # First deparse command-line args
762         if (defined $^I) { # deparse -i
763             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
764         }
765         if ($^W) { # deparse -w
766             print qq(BEGIN { \$^W = $^W; }\n);
767         }
768         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
769             my $fs = perlstring($/) || 'undef';
770             my $bs = perlstring($O::savebackslash) || 'undef';
771             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
772         }
773         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
774         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
775             ? B::unitcheck_av->ARRAY
776             : ();
777         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
778         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
779         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
780         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
781             $self->todo($block, 0);
782         }
783         $self->stash_subs();
784         local($SIG{"__DIE__"}) =
785           sub {
786               if ($self->{'curcop'}) {
787                   my $cop = $self->{'curcop'};
788                   my($line, $file) = ($cop->line, $cop->file);
789                   print STDERR "While deparsing $file near line $line,\n";
790               }
791             };
792         $self->{'curcv'} = main_cv;
793         $self->{'curcvlex'} = undef;
794         print $self->print_protos;
795         @{$self->{'subs_todo'}} =
796           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
797         my $root = main_root;
798         local $B::overlay = {};
799         unless (null $root) {
800             $self->pessimise($root, main_start);
801             print $self->indent($self->deparse_root($root)), "\n";
802         }
803         my @text;
804         while (scalar(@{$self->{'subs_todo'}})) {
805             push @text, $self->next_todo;
806         }
807         print $self->indent(join("", @text)), "\n" if @text;
808
809         # Print __DATA__ section, if necessary
810         no strict 'refs';
811         my $laststash = defined $self->{'curcop'}
812             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
813         if (defined *{$laststash."::DATA"}{IO}) {
814             print "package $laststash;\n"
815                 unless $laststash eq $self->{'curstash'};
816             print "__DATA__\n";
817             print readline(*{$laststash."::DATA"});
818         }
819     }
820 }
821
822 sub coderef2text {
823     my $self = shift;
824     my $sub = shift;
825     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
826
827     $self->init();
828     return $self->indent($self->deparse_sub(svref_2object($sub)));
829 }
830
831 my %strict_bits = do {
832     local $^H;
833     map +($_ => strict::bits($_)), qw/refs subs vars/
834 };
835
836 sub ambient_pragmas {
837     my $self = shift;
838     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
839
840     while (@_ > 1) {
841         my $name = shift();
842         my $val  = shift();
843
844         if ($name eq 'strict') {
845             require strict;
846
847             if ($val eq 'none') {
848                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
849                 next();
850             }
851
852             my @names;
853             if ($val eq "all") {
854                 @names = qw/refs subs vars/;
855             }
856             elsif (ref $val) {
857                 @names = @$val;
858             }
859             else {
860                 @names = split' ', $val;
861             }
862             $hint_bits |= $strict_bits{$_} for @names;
863         }
864
865         elsif ($name eq '$[') {
866             if (OPpCONST_ARYBASE) {
867                 $arybase = $val;
868             } else {
869                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
870             }
871         }
872
873         elsif ($name eq 'integer'
874             || $name eq 'bytes'
875             || $name eq 'utf8') {
876             require "$name.pm";
877             if ($val) {
878                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
879             }
880             else {
881                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
882             }
883         }
884
885         elsif ($name eq 're') {
886             require re;
887             if ($val eq 'none') {
888                 $hint_bits &= ~re::bits(qw/taint eval/);
889                 next();
890             }
891
892             my @names;
893             if ($val eq 'all') {
894                 @names = qw/taint eval/;
895             }
896             elsif (ref $val) {
897                 @names = @$val;
898             }
899             else {
900                 @names = split' ',$val;
901             }
902             $hint_bits |= re::bits(@names);
903         }
904
905         elsif ($name eq 'warnings') {
906             if ($val eq 'none') {
907                 $warning_bits = $warnings::NONE;
908                 next();
909             }
910
911             my @names;
912             if (ref $val) {
913                 @names = @$val;
914             }
915             else {
916                 @names = split/\s+/, $val;
917             }
918
919             $warning_bits = $warnings::NONE if !defined ($warning_bits);
920             $warning_bits |= warnings::bits(@names);
921         }
922
923         elsif ($name eq 'warning_bits') {
924             $warning_bits = $val;
925         }
926
927         elsif ($name eq 'hint_bits') {
928             $hint_bits = $val;
929         }
930
931         elsif ($name eq '%^H') {
932             $hinthash = $val;
933         }
934
935         else {
936             croak "Unknown pragma type: $name";
937         }
938     }
939     if (@_) {
940         croak "The ambient_pragmas method expects an even number of args";
941     }
942
943     $self->{'ambient_arybase'} = $arybase;
944     $self->{'ambient_warnings'} = $warning_bits;
945     $self->{'ambient_hints'} = $hint_bits;
946     $self->{'ambient_hinthash'} = $hinthash;
947 }
948
949 # This method is the inner loop, so try to keep it simple
950 sub deparse {
951     my $self = shift;
952     my($op, $cx) = @_;
953
954     Carp::confess("Null op in deparse") if !defined($op)
955                                         || class($op) eq "NULL";
956     my $meth = "pp_" . $op->name;
957     return $self->$meth($op, $cx);
958 }
959
960 sub indent {
961     my $self = shift;
962     my $txt = shift;
963     my @lines = split(/\n/, $txt);
964     my $leader = "";
965     my $level = 0;
966     my $line;
967     for $line (@lines) {
968         my $cmd = substr($line, 0, 1);
969         if ($cmd eq "\t" or $cmd eq "\b") {
970             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
971             if ($self->{'use_tabs'}) {
972                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
973             } else {
974                 $leader = " " x $level;
975             }
976             $line = substr($line, 1);
977         }
978         if (index($line, "\f") > 0) {
979                 $line =~ s/\f/\n/;
980         }
981         if (substr($line, 0, 1) eq "\f") {
982             $line = substr($line, 1); # no indent
983         } else {
984             $line = $leader . $line;
985         }
986         $line =~ s/\cK;?//g;
987     }
988     return join("\n", @lines);
989 }
990
991 sub deparse_sub {
992     my $self = shift;
993     my $cv = shift;
994     my $proto = "";
995 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
996 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
997     local $self->{'curcop'} = $self->{'curcop'};
998     if ($cv->FLAGS & SVf_POK) {
999         $proto = "(". $cv->PV . ") ";
1000     }
1001     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
1002         $proto .= ": ";
1003         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
1004         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
1005         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
1006     }
1007
1008     local($self->{'curcv'}) = $cv;
1009     local($self->{'curcvlex'});
1010     local(@$self{qw'curstash warnings hints hinthash'})
1011                 = @$self{qw'curstash warnings hints hinthash'};
1012     my $body;
1013     my $root = $cv->ROOT;
1014     local $B::overlay = {};
1015     if (not null $root) {
1016         $self->pessimise($root, $cv->START);
1017         my $lineseq = $root->first;
1018         if ($lineseq->name eq "lineseq") {
1019             my @ops;
1020             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
1021                 push @ops, $o;
1022             }
1023             $body = $self->lineseq(undef, 0, @ops).";";
1024             my $scope_en = $self->find_scope_en($lineseq);
1025             if (defined $scope_en) {
1026                 my $subs = join"", $self->seq_subs($scope_en);
1027                 $body .= ";\n$subs" if length($subs);
1028             }
1029         }
1030         else {
1031             $body = $self->deparse($root->first, 0);
1032         }
1033     }
1034     else {
1035         my $sv = $cv->const_sv;
1036         if ($$sv) {
1037             # uh-oh. inlinable sub... format it differently
1038             return $proto . "{ " . $self->const($sv, 0) . " }\n";
1039         } else { # XSUB? (or just a declaration)
1040             return "$proto;\n";
1041         }
1042     }
1043     return $proto ."{\n\t$body\n\b}" ."\n";
1044 }
1045
1046 sub deparse_format {
1047     my $self = shift;
1048     my $form = shift;
1049     my @text;
1050     local($self->{'curcv'}) = $form;
1051     local($self->{'curcvlex'});
1052     local($self->{'in_format'}) = 1;
1053     local(@$self{qw'curstash warnings hints hinthash'})
1054                 = @$self{qw'curstash warnings hints hinthash'};
1055     my $op = $form->ROOT;
1056     local $B::overlay = {};
1057     $self->pessimise($op, $form->START);
1058     my $kid;
1059     return "\f." if $op->first->name eq 'stub'
1060                 || $op->first->name eq 'nextstate';
1061     $op = $op->first->first; # skip leavewrite, lineseq
1062     while (not null $op) {
1063         $op = $op->sibling; # skip nextstate
1064         my @exprs;
1065         $kid = $op->first->sibling; # skip pushmark
1066         push @text, "\f".$self->const_sv($kid)->PV;
1067         $kid = $kid->sibling;
1068         for (; not null $kid; $kid = $kid->sibling) {
1069             push @exprs, $self->deparse($kid, -1);
1070             $exprs[-1] =~ s/;\z//;
1071         }
1072         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1073         $op = $op->sibling;
1074     }
1075     return join("", @text) . "\f.";
1076 }
1077
1078 sub is_scope {
1079     my $op = shift;
1080     return $op->name eq "leave" || $op->name eq "scope"
1081       || $op->name eq "lineseq"
1082         || ($op->name eq "null" && class($op) eq "UNOP"
1083             && (is_scope($op->first) || $op->first->name eq "enter"));
1084 }
1085
1086 sub is_state {
1087     my $name = $_[0]->name;
1088     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1089 }
1090
1091 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1092     my $op = shift;
1093     return (!null($op) and null($op->sibling)
1094             and $op->name eq "null" and class($op) eq "UNOP"
1095             and (($op->first->name =~ /^(and|or)$/
1096                   and $op->first->first->sibling->name eq "lineseq")
1097                  or ($op->first->name eq "lineseq"
1098                      and not null $op->first->first->sibling
1099                      and $op->first->first->sibling->name eq "unstack")
1100                  ));
1101 }
1102
1103 # Check if the op and its sibling are the initialization and the rest of a
1104 # for (..;..;..) { ... } loop
1105 sub is_for_loop {
1106     my $op = shift;
1107     # This OP might be almost anything, though it won't be a
1108     # nextstate. (It's the initialization, so in the canonical case it
1109     # will be an sassign.) The sibling is (old style) a lineseq whose
1110     # first child is a nextstate and whose second is a leaveloop, or
1111     # (new style) an unstack whose sibling is a leaveloop.
1112     my $lseq = $op->sibling;
1113     return 0 unless !is_state($op) and !null($lseq);
1114     if ($lseq->name eq "lineseq") {
1115         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1116             && (my $sib = $lseq->first->sibling)) {
1117             return (!null($sib) && $sib->name eq "leaveloop");
1118         }
1119     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1120         my $sib = $lseq->sibling;
1121         return $sib && !null($sib) && $sib->name eq "leaveloop";
1122     }
1123     return 0;
1124 }
1125
1126 sub is_scalar {
1127     my $op = shift;
1128     return ($op->name eq "rv2sv" or
1129             $op->name eq "padsv" or
1130             $op->name eq "gv" or # only in array/hash constructs
1131             $op->flags & OPf_KIDS && !null($op->first)
1132               && $op->first->name eq "gvsv");
1133 }
1134
1135 sub maybe_parens {
1136     my $self = shift;
1137     my($text, $cx, $prec) = @_;
1138     if ($prec < $cx              # unary ops nest just fine
1139         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1140         or $self->{'parens'})
1141     {
1142         $text = "($text)";
1143         # In a unop, let parent reuse our parens; see maybe_parens_unop
1144         $text = "\cS" . $text if $cx == 16;
1145         return $text;
1146     } else {
1147         return $text;
1148     }
1149 }
1150
1151 # same as above, but get around the 'if it looks like a function' rule
1152 sub maybe_parens_unop {
1153     my $self = shift;
1154     my($name, $kid, $cx) = @_;
1155     if ($cx > 16 or $self->{'parens'}) {
1156         $kid =  $self->deparse($kid, 1);
1157         if ($name eq "umask" && $kid =~ /^\d+$/) {
1158             $kid = sprintf("%#o", $kid);
1159         }
1160         return $self->keyword($name) . "($kid)";
1161     } else {
1162         $kid = $self->deparse($kid, 16);
1163         if ($name eq "umask" && $kid =~ /^\d+$/) {
1164             $kid = sprintf("%#o", $kid);
1165         }
1166         $name = $self->keyword($name);
1167         if (substr($kid, 0, 1) eq "\cS") {
1168             # use kid's parens
1169             return $name . substr($kid, 1);
1170         } elsif (substr($kid, 0, 1) eq "(") {
1171             # avoid looks-like-a-function trap with extra parens
1172             # ('+' can lead to ambiguities)
1173             return "$name(" . $kid  . ")";
1174         } else {
1175             return "$name $kid";
1176         }
1177     }
1178 }
1179
1180 sub maybe_parens_func {
1181     my $self = shift;
1182     my($func, $text, $cx, $prec) = @_;
1183     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1184         return "$func($text)";
1185     } else {
1186         return "$func $text";
1187     }
1188 }
1189
1190 sub maybe_local {
1191     my $self = shift;
1192     my($op, $cx, $text) = @_;
1193     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1194     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1195         and not $self->{'avoid_local'}{$$op}) {
1196         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1197         if( $our_local eq 'our' ) {
1198             if ( $text !~ /^\W(\w+::)*\w+\z/
1199              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1200             ) {
1201                 die "Unexpected our($text)\n";
1202             }
1203             $text =~ s/(\w+::)+//;
1204         }
1205         if (want_scalar($op)) {
1206             return "$our_local $text";
1207         } else {
1208             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1209         }
1210     } else {
1211         return $text;
1212     }
1213 }
1214
1215 sub maybe_targmy {
1216     my $self = shift;
1217     my($op, $cx, $func, @args) = @_;
1218     if ($op->private & OPpTARGET_MY) {
1219         my $var = $self->padname($op->targ);
1220         my $val = $func->($self, $op, 7, @args);
1221         return $self->maybe_parens("$var = $val", $cx, 7);
1222     } else {
1223         return $func->($self, $op, $cx, @args);
1224     }
1225 }
1226
1227 sub padname_sv {
1228     my $self = shift;
1229     my $targ = shift;
1230     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1231 }
1232
1233 sub maybe_my {
1234     my $self = shift;
1235     my($op, $cx, $text, $forbid_parens) = @_;
1236     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1237         my $my = $op->private & OPpPAD_STATE
1238             ? $self->keyword("state")
1239             : "my";
1240         if ($forbid_parens || want_scalar($op)) {
1241             return "$my $text";
1242         } else {
1243             return $self->maybe_parens_func($my, $text, $cx, 16);
1244         }
1245     } else {
1246         return $text;
1247     }
1248 }
1249
1250 # The following OPs don't have functions:
1251
1252 # pp_padany -- does not exist after parsing
1253
1254 sub AUTOLOAD {
1255     if ($AUTOLOAD =~ s/^.*::pp_//) {
1256         warn "unexpected OP_".uc $AUTOLOAD;
1257         return "XXX";
1258     } else {
1259         die "Undefined subroutine $AUTOLOAD called";
1260     }
1261 }
1262
1263 sub DESTROY {}  #       Do not AUTOLOAD
1264
1265 # $root should be the op which represents the root of whatever
1266 # we're sequencing here. If it's undefined, then we don't append
1267 # any subroutine declarations to the deparsed ops, otherwise we
1268 # append appropriate declarations.
1269 sub lineseq {
1270     my($self, $root, $cx, @ops) = @_;
1271     my($expr, @exprs);
1272
1273     my $out_cop = $self->{'curcop'};
1274     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1275     my $limit_seq;
1276     if (defined $root) {
1277         $limit_seq = $out_seq;
1278         my $nseq;
1279         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1280         $limit_seq = $nseq if !defined($limit_seq)
1281                            or defined($nseq) && $nseq < $limit_seq;
1282     }
1283     $limit_seq = $self->{'limit_seq'}
1284         if defined($self->{'limit_seq'})
1285         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1286     local $self->{'limit_seq'} = $limit_seq;
1287
1288     $self->walk_lineseq($root, \@ops,
1289                        sub { push @exprs, $_[0]} );
1290
1291     my $sep = $cx ? '; ' : ";\n";
1292     my $body = join($sep, grep {length} @exprs);
1293     my $subs = "";
1294     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1295         $subs = join "\n", $self->seq_subs($limit_seq);
1296     }
1297     return join($sep, grep {length} $body, $subs);
1298 }
1299
1300 sub scopeop {
1301     my($real_block, $self, $op, $cx) = @_;
1302     my $kid;
1303     my @kids;
1304
1305     local(@$self{qw'curstash warnings hints hinthash'})
1306                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1307     if ($real_block) {
1308         $kid = $op->first->sibling; # skip enter
1309         if (is_miniwhile($kid)) {
1310             my $top = $kid->first;
1311             my $name = $top->name;
1312             if ($name eq "and") {
1313                 $name = "while";
1314             } elsif ($name eq "or") {
1315                 $name = "until";
1316             } else { # no conditional -> while 1 or until 0
1317                 return $self->deparse($top->first, 1) . " while 1";
1318             }
1319             my $cond = $top->first;
1320             my $body = $cond->sibling->first; # skip lineseq
1321             $cond = $self->deparse($cond, 1);
1322             $body = $self->deparse($body, 1);
1323             return "$body $name $cond";
1324         }
1325     } else {
1326         $kid = $op->first;
1327     }
1328     for (; !null($kid); $kid = $kid->sibling) {
1329         push @kids, $kid;
1330     }
1331     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1332         my $body = $self->lineseq($op, 0, @kids);
1333         return is_lexical_subs(@kids) ? $body : "do {\n\t$body\n\b}";
1334     } else {
1335         my $lineseq = $self->lineseq($op, $cx, @kids);
1336         return (length ($lineseq) ? "$lineseq;" : "");
1337     }
1338 }
1339
1340 sub pp_scope { scopeop(0, @_); }
1341 sub pp_lineseq { scopeop(0, @_); }
1342 sub pp_leave { scopeop(1, @_); }
1343
1344 # This is a special case of scopeop and lineseq, for the case of the
1345 # main_root. The difference is that we print the output statements as
1346 # soon as we get them, for the sake of impatient users.
1347 sub deparse_root {
1348     my $self = shift;
1349     my($op) = @_;
1350     local(@$self{qw'curstash warnings hints hinthash'})
1351       = @$self{qw'curstash warnings hints hinthash'};
1352     my @kids;
1353     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1354     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1355         push @kids, $kid;
1356     }
1357     $self->walk_lineseq($op, \@kids,
1358                         sub { print $self->indent($_[0].';');
1359                               print "\n" unless $_[1] == $#kids;
1360                           });
1361 }
1362
1363 sub walk_lineseq {
1364     my ($self, $op, $kids, $callback) = @_;
1365     my @kids = @$kids;
1366     for (my $i = 0; $i < @kids; $i++) {
1367         my $expr = "";
1368         if (is_state $kids[$i]) {
1369             $expr = $self->deparse($kids[$i++], 0);
1370             if ($i > $#kids) {
1371                 $callback->($expr, $i);
1372                 last;
1373             }
1374         }
1375         if (is_for_loop($kids[$i])) {
1376             $callback->($expr . $self->for_loop($kids[$i], 0),
1377                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1378             next;
1379         }
1380         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1381         $expr =~ s/;\n?\z//;
1382         $callback->($expr, $i);
1383     }
1384 }
1385
1386 # The BEGIN {} is used here because otherwise this code isn't executed
1387 # when you run B::Deparse on itself.
1388 my %globalnames;
1389 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1390             "ENV", "ARGV", "ARGVOUT", "_"); }
1391
1392 sub gv_name {
1393     my $self = shift;
1394     my $gv = shift;
1395     my $raw = shift;
1396 Carp::confess() unless ref($gv) eq "B::GV";
1397     my $stash = $gv->STASH->NAME;
1398     my $name = $raw ? $gv->NAME : $gv->SAFENAME;
1399     if ($stash eq 'main' && $name =~ /^::/) {
1400         $stash = '::';
1401     }
1402     elsif (($stash eq 'main'
1403             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1404         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1405             && ($stash eq 'main' || $name !~ /::/))
1406           )
1407     {
1408         $stash = "";
1409     } else {
1410         $stash = $stash . "::";
1411     }
1412     if (!$raw and $name =~ /^(\^..|{)/) {
1413         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1414     }
1415     return $stash . $name;
1416 }
1417
1418 # Return the name to use for a stash variable.
1419 # If a lexical with the same name is in scope, or
1420 # if strictures are enabled, it may need to be
1421 # fully-qualified.
1422 sub stash_variable {
1423     my ($self, $prefix, $name, $cx) = @_;
1424
1425     return "$prefix$name" if $name =~ /::/;
1426
1427     unless ($prefix eq '$' || $prefix eq '@' || #'
1428             $prefix eq '%' || $prefix eq '$#') {
1429         return "$prefix$name";
1430     }
1431
1432     if ($name =~ /^[^\w+-]$/) {
1433       if (defined $cx && $cx == 26) {
1434         if ($prefix eq '@') {
1435             return "$prefix\{$name}";
1436         }
1437         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1438       }
1439       if ($prefix eq '$#') {
1440         return "\$#{$name}";
1441       }
1442     }
1443
1444     return $prefix . $self->maybe_qualify($prefix, $name);
1445 }
1446
1447 # Return just the name, without the prefix.  It may be returned as a quoted
1448 # string.  The second return value is a boolean indicating that.
1449 sub stash_variable_name {
1450     my($self, $prefix, $gv) = @_;
1451     my $name = $self->gv_name($gv, 1);
1452     $name = $self->maybe_qualify($prefix,$name);
1453     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1454         $name =~ s/^([\ca-\cz])/'^'.($1|'@')/e;
1455         $name =~ /^(\^..|{)/ and $name = "{$name}";
1456         return $name, 0; # not quoted
1457     }
1458     else {
1459         single_delim("q", "'", $name), 1;
1460     }
1461 }
1462
1463 sub maybe_qualify {
1464     my ($self,$prefix,$name) = @_;
1465     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1466     return $name if !$prefix || $name =~ /::/;
1467     return $self->{'curstash'}.'::'. $name
1468         if
1469             $name =~ /^(?!\d)\w/         # alphabetic
1470          && $v    !~ /^\$[ab]\z/         # not $a or $b
1471          && !$globalnames{$name}         # not a global name
1472          && $self->{hints} & $strict_bits{vars}  # strict vars
1473          && !$self->lex_in_scope($v,1)   # no "our"
1474       or $self->lex_in_scope($v);        # conflicts with "my" variable
1475     return $name;
1476 }
1477
1478 sub lex_in_scope {
1479     my ($self, $name, $our) = @_;
1480     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1481     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1482
1483     return 0 if !defined($self->{'curcop'});
1484     my $seq = $self->{'curcop'}->cop_seq;
1485     return 0 if !exists $self->{'curcvlex'}{$name};
1486     for my $a (@{$self->{'curcvlex'}{$name}}) {
1487         my ($st, $en) = @$a;
1488         return 1 if $seq > $st && $seq <= $en;
1489     }
1490     return 0;
1491 }
1492
1493 sub populate_curcvlex {
1494     my $self = shift;
1495     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1496         my $padlist = $cv->PADLIST;
1497         # an undef CV still in lexical chain
1498         next if class($padlist) eq "SPECIAL";
1499         my @padlist = $padlist->ARRAY;
1500         my @ns = $padlist[0]->ARRAY;
1501
1502         for (my $i=0; $i<@ns; ++$i) {
1503             next if class($ns[$i]) eq "SPECIAL";
1504             if (class($ns[$i]) eq "PV") {
1505                 # Probably that pesky lexical @_
1506                 next;
1507             }
1508             my $name = $ns[$i]->PVX;
1509             my ($seq_st, $seq_en) =
1510                 ($ns[$i]->FLAGS & SVf_FAKE)
1511                     ? (0, 999999)
1512                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1513
1514             push @{$self->{'curcvlex'}{
1515                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1516                   }}, [$seq_st, $seq_en];
1517         }
1518     }
1519 }
1520
1521 sub find_scope_st { ((find_scope(@_))[0]); }
1522 sub find_scope_en { ((find_scope(@_))[1]); }
1523
1524 # Recurses down the tree, looking for pad variable introductions and COPs
1525 sub find_scope {
1526     my ($self, $op, $scope_st, $scope_en) = @_;
1527     carp("Undefined op in find_scope") if !defined $op;
1528     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1529
1530     my @queue = ($op);
1531     while(my $op = shift @queue ) {
1532         for (my $o=$op->first; $$o; $o=$o->sibling) {
1533             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1534                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1535                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1536                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1537                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1538                 return ($scope_st, $scope_en);
1539             }
1540             elsif (is_state($o)) {
1541                 my $c = $o->cop_seq;
1542                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1543                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1544                 return ($scope_st, $scope_en);
1545             }
1546             elsif ($o->flags & OPf_KIDS) {
1547                 unshift (@queue, $o);
1548             }
1549         }
1550     }
1551
1552     return ($scope_st, $scope_en);
1553 }
1554
1555 # Returns a list of subs which should be inserted before the COP
1556 sub cop_subs {
1557     my ($self, $op, $out_seq) = @_;
1558     my $seq = $op->cop_seq;
1559     # If we have nephews, then our sequence number indicates
1560     # the cop_seq of the end of some sort of scope.
1561     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1562         and my $nseq = $self->find_scope_st($op->sibling) ) {
1563         $seq = $nseq;
1564     }
1565     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1566     return $self->seq_subs($seq);
1567 }
1568
1569 sub seq_subs {
1570     my ($self, $seq) = @_;
1571     my @text;
1572 #push @text, "# ($seq)\n";
1573
1574     return "" if !defined $seq;
1575     while (scalar(@{$self->{'subs_todo'}})
1576            and $seq > $self->{'subs_todo'}[0][0]) {
1577         push @text, $self->next_todo;
1578     }
1579     return @text;
1580 }
1581
1582 sub _features_from_bundle {
1583     my ($hints, $hh) = @_;
1584     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
1585         $hh->{$feature::feature{$_}} = 1;
1586     }
1587     return $hh;
1588 }
1589
1590 # Notice how subs and formats are inserted between statements here;
1591 # also $[ assignments and pragmas.
1592 sub pp_nextstate {
1593     my $self = shift;
1594     my($op, $cx) = @_;
1595     $self->{'curcop'} = $op;
1596     my @text;
1597     push @text, $self->cop_subs($op);
1598     my $stash = $op->stashpv;
1599     if ($stash ne $self->{'curstash'}) {
1600         push @text, "package $stash;\n";
1601         $self->{'curstash'} = $stash;
1602     }
1603
1604     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1605         push @text, '$[ = '. $op->arybase .";\n";
1606         $self->{'arybase'} = $op->arybase;
1607     }
1608
1609     my $warnings = $op->warnings;
1610     my $warning_bits;
1611     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1612         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1613     }
1614     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1615         $warning_bits = $warnings::NONE;
1616     }
1617     elsif ($warnings->isa("B::SPECIAL")) {
1618         $warning_bits = undef;
1619     }
1620     else {
1621         $warning_bits = $warnings->PV & WARN_MASK;
1622     }
1623
1624     if (defined ($warning_bits) and
1625        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1626         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1627         $self->{'warnings'} = $warning_bits;
1628     }
1629
1630     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1631     my $old_hints = $self->{'hints'};
1632     if ($self->{'hints'} != $hints) {
1633         push @text, declare_hints($self->{'hints'}, $hints);
1634         $self->{'hints'} = $hints;
1635     }
1636
1637     my $newhh;
1638     if ($] > 5.009) {
1639         $newhh = $op->hints_hash->HASH;
1640     }
1641
1642     if ($] >= 5.015006) {
1643         # feature bundle hints
1644         my $from = $old_hints & $feature::hint_mask;
1645         my $to   = $    hints & $feature::hint_mask;
1646         if ($from != $to) {
1647             if ($to == $feature::hint_mask) {
1648                 if ($self->{'hinthash'}) {
1649                     delete $self->{'hinthash'}{$_}
1650                         for grep /^feature_/, keys %{$self->{'hinthash'}};
1651                 }
1652                 else { $self->{'hinthash'} = {} }
1653                 $self->{'hinthash'}
1654                     = _features_from_bundle($from, $self->{'hinthash'});
1655             }
1656             else {
1657                 my $bundle =
1658                     $feature::hint_bundles[$to >> $feature::hint_shift];
1659                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
1660                 push @text, "no feature;\n",
1661                             "use feature ':$bundle';\n";
1662             }
1663         }
1664     }
1665
1666     if ($] > 5.009) {
1667         push @text, declare_hinthash(
1668             $self->{'hinthash'}, $newhh,
1669             $self->{indent_size}, $self->{hints},
1670         );
1671         $self->{'hinthash'} = $newhh;
1672     }
1673
1674     # This should go after of any branches that add statements, to
1675     # increase the chances that it refers to the same line it did in
1676     # the original program.
1677     if ($self->{'linenums'}) {
1678         push @text, "\f#line " . $op->line .
1679           ' "' . $op->file, qq'"\n';
1680     }
1681
1682     push @text, $op->label . ": " if $op->label;
1683
1684     return join("", @text);
1685 }
1686
1687 sub declare_warnings {
1688     my ($from, $to) = @_;
1689     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1690         return "use warnings;\n";
1691     }
1692     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1693         return "no warnings;\n";
1694     }
1695     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1696 }
1697
1698 sub declare_hints {
1699     my ($from, $to) = @_;
1700     my $use = $to   & ~$from;
1701     my $no  = $from & ~$to;
1702     my $decls = "";
1703     for my $pragma (hint_pragmas($use)) {
1704         $decls .= "use $pragma;\n";
1705     }
1706     for my $pragma (hint_pragmas($no)) {
1707         $decls .= "no $pragma;\n";
1708     }
1709     return $decls;
1710 }
1711
1712 # Internal implementation hints that the core sets automatically, so don't need
1713 # (or want) to be passed back to the user
1714 my %ignored_hints = (
1715     'open<' => 1,
1716     'open>' => 1,
1717     ':'     => 1,
1718     'strict/refs' => 1,
1719     'strict/subs' => 1,
1720     'strict/vars' => 1,
1721 );
1722
1723 my %rev_feature;
1724
1725 sub declare_hinthash {
1726     my ($from, $to, $indent, $hints) = @_;
1727     my $doing_features =
1728         ($hints & $feature::hint_mask) == $feature::hint_mask;
1729     my @decls;
1730     my @features;
1731     my @unfeatures; # bugs?
1732     for my $key (sort keys %$to) {
1733         next if $ignored_hints{$key};
1734         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1735         next if $is_feature and not $doing_features;
1736         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1737             push(@features, $key), next if $is_feature;
1738             push @decls,
1739                 qq(\$^H{) . single_delim("q", "'", $key) . qq(} = )
1740               . (
1741                    defined $to->{$key}
1742                         ? single_delim("q", "'", $to->{$key})
1743                         : 'undef'
1744                 )
1745               . qq(;);
1746         }
1747     }
1748     for my $key (sort keys %$from) {
1749         next if $ignored_hints{$key};
1750         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1751         next if $is_feature and not $doing_features;
1752         if (!exists $to->{$key}) {
1753             push(@unfeatures, $key), next if $is_feature;
1754             push @decls, qq(delete \$^H{'$key'};);
1755         }
1756     }
1757     my @ret;
1758     if (@features || @unfeatures) {
1759         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
1760     }
1761     if (@features) {
1762         push @ret, "use feature "
1763                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
1764     }
1765     if (@unfeatures) {
1766         push @ret, "no feature "
1767                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
1768                  . ";\n";
1769     }
1770     @decls and
1771         push @ret,
1772              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1773     return @ret;
1774 }
1775
1776 sub hint_pragmas {
1777     my ($bits) = @_;
1778     my (@pragmas, @strict);
1779     push @pragmas, "integer" if $bits & 0x1;
1780     for (sort keys %strict_bits) {
1781         push @strict, "'$_'" if $bits & $strict_bits{$_};
1782     }
1783     if (@strict == keys %strict_bits) {
1784         push @pragmas, "strict";
1785     }
1786     elsif (@strict) {
1787         push @pragmas, "strict " . join ', ', @strict;
1788     }
1789     push @pragmas, "bytes" if $bits & 0x8;
1790     return @pragmas;
1791 }
1792
1793 sub pp_dbstate { pp_nextstate(@_) }
1794 sub pp_setstate { pp_nextstate(@_) }
1795
1796 sub pp_unstack { return "" } # see also leaveloop
1797
1798 my %feature_keywords = (
1799   # keyword => 'feature',
1800     state   => 'state',
1801     say     => 'say',
1802     given   => 'switch',
1803     when    => 'switch',
1804     default => 'switch',
1805     break   => 'switch',
1806     evalbytes=>'evalbytes',
1807     __SUB__ => '__SUB__',
1808    fc       => 'fc',
1809 );
1810
1811 # keywords that are strong and also have a prototype
1812 #
1813 my %strong_proto_keywords = map { $_ => 1 } qw(
1814     glob
1815     pos
1816     prototype
1817     scalar
1818     study
1819     undef
1820 );
1821
1822 sub keyword {
1823     my $self = shift;
1824     my $name = shift;
1825     return $name if $name =~ /^CORE::/; # just in case
1826     if (exists $feature_keywords{$name}) {
1827         my $hh;
1828         my $hints = $self->{hints} & $feature::hint_mask;
1829         if ($hints && $hints != $feature::hint_mask) {
1830             $hh = _features_from_bundle($hints);
1831         }
1832         elsif ($hints) { $hh = $self->{'hinthash'} }
1833         return "CORE::$name"
1834          if !$hh
1835          || !$hh->{"feature_$feature_keywords{$name}"}
1836     }
1837     if ($strong_proto_keywords{$name}
1838         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1839             && !defined eval{prototype "CORE::$name"})
1840     ) { return $name }
1841     if (
1842         exists $self->{subs_declared}{$name}
1843          or
1844         exists &{"$self->{curstash}::$name"}
1845     ) {
1846         return "CORE::$name"
1847     }
1848     return $name;
1849 }
1850
1851 sub baseop {
1852     my $self = shift;
1853     my($op, $cx, $name) = @_;
1854     return $self->keyword($name);
1855 }
1856
1857 sub pp_stub {
1858     my $self = shift;
1859     my($op, $cx, $name) = @_;
1860     if ($cx >= 1) {
1861         return "()";
1862     }
1863     else {
1864         return "();";
1865     }
1866 }
1867 sub pp_wantarray { baseop(@_, "wantarray") }
1868 sub pp_fork { baseop(@_, "fork") }
1869 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1870 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1871 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1872 sub pp_tms { baseop(@_, "times") }
1873 sub pp_ghostent { baseop(@_, "gethostent") }
1874 sub pp_gnetent { baseop(@_, "getnetent") }
1875 sub pp_gprotoent { baseop(@_, "getprotoent") }
1876 sub pp_gservent { baseop(@_, "getservent") }
1877 sub pp_ehostent { baseop(@_, "endhostent") }
1878 sub pp_enetent { baseop(@_, "endnetent") }
1879 sub pp_eprotoent { baseop(@_, "endprotoent") }
1880 sub pp_eservent { baseop(@_, "endservent") }
1881 sub pp_gpwent { baseop(@_, "getpwent") }
1882 sub pp_spwent { baseop(@_, "setpwent") }
1883 sub pp_epwent { baseop(@_, "endpwent") }
1884 sub pp_ggrent { baseop(@_, "getgrent") }
1885 sub pp_sgrent { baseop(@_, "setgrent") }
1886 sub pp_egrent { baseop(@_, "endgrent") }
1887 sub pp_getlogin { baseop(@_, "getlogin") }
1888
1889 sub POSTFIX () { 1 }
1890
1891 # I couldn't think of a good short name, but this is the category of
1892 # symbolic unary operators with interesting precedence
1893
1894 sub pfixop {
1895     my $self = shift;
1896     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1897     my $kid = $op->first;
1898     $kid = $self->deparse($kid, $prec);
1899     return $self->maybe_parens(($flags & POSTFIX)
1900                                  ? "$kid$name"
1901                                    # avoid confusion with filetests
1902                                  : $name eq '-'
1903                                    && $kid =~ /^[a-zA-Z](?!\w)/
1904                                         ? "$name($kid)"
1905                                         : "$name$kid",
1906                                $cx, $prec);
1907 }
1908
1909 sub pp_preinc { pfixop(@_, "++", 23) }
1910 sub pp_predec { pfixop(@_, "--", 23) }
1911 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1912 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1913 sub pp_i_preinc { pfixop(@_, "++", 23) }
1914 sub pp_i_predec { pfixop(@_, "--", 23) }
1915 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1916 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1917 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1918
1919 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1920 sub real_negate {
1921     my $self = shift;
1922     my($op, $cx) = @_;
1923     if ($op->first->name =~ /^(i_)?negate$/) {
1924         # avoid --$x
1925         $self->pfixop($op, $cx, "-", 21.5);
1926     } else {
1927         $self->pfixop($op, $cx, "-", 21);       
1928     }
1929 }
1930 sub pp_i_negate { pp_negate(@_) }
1931
1932 sub pp_not {
1933     my $self = shift;
1934     my($op, $cx) = @_;
1935     if ($cx <= 4) {
1936         $self->listop($op, $cx, "not", $op->first);
1937     } else {
1938         $self->pfixop($op, $cx, "!", 21);       
1939     }
1940 }
1941
1942 sub unop {
1943     my $self = shift;
1944     my($op, $cx, $name, $nollafr) = @_;
1945     my $kid;
1946     if ($op->flags & OPf_KIDS) {
1947         $kid = $op->first;
1948         if (not $name) {
1949             # this deals with 'boolkeys' right now
1950             return $self->deparse($kid,$cx);
1951         }
1952         my $builtinname = $name;
1953         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1954         if (defined prototype($builtinname)
1955            && prototype($builtinname) =~ /^;?\*/
1956            && $kid->name eq "rv2gv") {
1957             $kid = $kid->first;
1958         }
1959
1960         if ($nollafr) {
1961             ($kid = $self->deparse($kid, 16)) =~ s/^\cS//;
1962             return $self->maybe_parens(
1963                         $self->keyword($name) . " $kid", $cx, 16
1964                    );
1965         }   
1966         return $self->maybe_parens_unop($name, $kid, $cx);
1967     } else {
1968         return $self->maybe_parens(
1969             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
1970             $cx, 16,
1971         );
1972     }
1973 }
1974
1975 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1976 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1977 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1978 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1979 sub pp_defined { unop(@_, "defined") }
1980 sub pp_undef { unop(@_, "undef") }
1981 sub pp_study { unop(@_, "study") }
1982 sub pp_ref { unop(@_, "ref") }
1983 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1984
1985 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1986 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1987 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1988 sub pp_srand { unop(@_, "srand") }
1989 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1990 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1991 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1992 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1993 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1994 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1995 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1996
1997 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1998 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1999 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2000
2001 sub pp_each { unop(@_, "each") }
2002 sub pp_values { unop(@_, "values") }
2003 sub pp_keys { unop(@_, "keys") }
2004 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2005 sub pp_boolkeys { 
2006     # no name because its an optimisation op that has no keyword
2007     unop(@_,"");
2008 }
2009 sub pp_aeach { unop(@_, "each") }
2010 sub pp_avalues { unop(@_, "values") }
2011 sub pp_akeys { unop(@_, "keys") }
2012 sub pp_pop { unop(@_, "pop") }
2013 sub pp_shift { unop(@_, "shift") }
2014
2015 sub pp_caller { unop(@_, "caller") }
2016 sub pp_reset { unop(@_, "reset") }
2017 sub pp_exit { unop(@_, "exit") }
2018 sub pp_prototype { unop(@_, "prototype") }
2019
2020 sub pp_close { unop(@_, "close") }
2021 sub pp_fileno { unop(@_, "fileno") }
2022 sub pp_umask { unop(@_, "umask") }
2023 sub pp_untie { unop(@_, "untie") }
2024 sub pp_tied { unop(@_, "tied") }
2025 sub pp_dbmclose { unop(@_, "dbmclose") }
2026 sub pp_getc { unop(@_, "getc") }
2027 sub pp_eof { unop(@_, "eof") }
2028 sub pp_tell { unop(@_, "tell") }
2029 sub pp_getsockname { unop(@_, "getsockname") }
2030 sub pp_getpeername { unop(@_, "getpeername") }
2031
2032 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
2033 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2034 sub pp_readlink { unop(@_, "readlink") }
2035 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2036 sub pp_readdir { unop(@_, "readdir") }
2037 sub pp_telldir { unop(@_, "telldir") }
2038 sub pp_rewinddir { unop(@_, "rewinddir") }
2039 sub pp_closedir { unop(@_, "closedir") }
2040 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2041 sub pp_localtime { unop(@_, "localtime") }
2042 sub pp_gmtime { unop(@_, "gmtime") }
2043 sub pp_alarm { unop(@_, "alarm") }
2044 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2045
2046 sub pp_dofile {
2047     my $code = unop(@_, "do", 1); # llafr does not apply
2048     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2049     $code;
2050 }
2051 sub pp_entereval {
2052     unop(
2053       @_,
2054       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
2055     )
2056 }
2057
2058 sub pp_ghbyname { unop(@_, "gethostbyname") }
2059 sub pp_gnbyname { unop(@_, "getnetbyname") }
2060 sub pp_gpbyname { unop(@_, "getprotobyname") }
2061 sub pp_shostent { unop(@_, "sethostent") }
2062 sub pp_snetent { unop(@_, "setnetent") }
2063 sub pp_sprotoent { unop(@_, "setprotoent") }
2064 sub pp_sservent { unop(@_, "setservent") }
2065 sub pp_gpwnam { unop(@_, "getpwnam") }
2066 sub pp_gpwuid { unop(@_, "getpwuid") }
2067 sub pp_ggrnam { unop(@_, "getgrnam") }
2068 sub pp_ggrgid { unop(@_, "getgrgid") }
2069
2070 sub pp_lock { unop(@_, "lock") }
2071
2072 sub pp_continue { unop(@_, "continue"); }
2073 sub pp_break { unop(@_, "break"); }
2074
2075 sub givwhen {
2076     my $self = shift;
2077     my($op, $cx, $givwhen) = @_;
2078
2079     my $enterop = $op->first;
2080     my ($head, $block);
2081     if ($enterop->flags & OPf_SPECIAL) {
2082         $head = $self->keyword("default");
2083         $block = $self->deparse($enterop->first, 0);
2084     }
2085     else {
2086         my $cond = $enterop->first;
2087         my $cond_str = $self->deparse($cond, 1);
2088         $head = "$givwhen ($cond_str)";
2089         $block = $self->deparse($cond->sibling, 0);
2090     }
2091
2092     return "$head {\n".
2093         "\t$block\n".
2094         "\b}\cK";
2095 }
2096
2097 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2098 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2099
2100 sub pp_exists {
2101     my $self = shift;
2102     my($op, $cx) = @_;
2103     my $arg;
2104     if ($op->private & OPpEXISTS_SUB) {
2105         # Checking for the existence of a subroutine
2106         return $self->maybe_parens_func("exists",
2107                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2108     }
2109     if ($op->flags & OPf_SPECIAL) {
2110         # Array element, not hash element
2111         return $self->maybe_parens_func("exists",
2112                                 $self->pp_aelem($op->first, 16), $cx, 16);
2113     }
2114     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
2115                                     $cx, 16);
2116 }
2117
2118 sub pp_delete {
2119     my $self = shift;
2120     my($op, $cx) = @_;
2121     my $arg;
2122     if ($op->private & OPpSLICE) {
2123         if ($op->flags & OPf_SPECIAL) {
2124             # Deleting from an array, not a hash
2125             return $self->maybe_parens_func("delete",
2126                                         $self->pp_aslice($op->first, 16),
2127                                         $cx, 16);
2128         }
2129         return $self->maybe_parens_func("delete",
2130                                         $self->pp_hslice($op->first, 16),
2131                                         $cx, 16);
2132     } else {
2133         if ($op->flags & OPf_SPECIAL) {
2134             # Deleting from an array, not a hash
2135             return $self->maybe_parens_func("delete",
2136                                         $self->pp_aelem($op->first, 16),
2137                                         $cx, 16);
2138         }
2139         return $self->maybe_parens_func("delete",
2140                                         $self->pp_helem($op->first, 16),
2141                                         $cx, 16);
2142     }
2143 }
2144
2145 sub pp_require {
2146     my $self = shift;
2147     my($op, $cx) = @_;
2148     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2149     if (class($op) eq "UNOP" and $op->first->name eq "const"
2150         and $op->first->private & OPpCONST_BARE)
2151     {
2152         my $name = $self->const_sv($op->first)->PV;
2153         $name =~ s[/][::]g;
2154         $name =~ s/\.pm//g;
2155         return $self->maybe_parens("$opname $name", $cx, 16);
2156     } else {    
2157         $self->unop(
2158             $op, $cx,
2159             $op->first->name eq 'const'
2160              && $op->first->private & OPpCONST_NOVER
2161                  ? "no"
2162                  : $opname,
2163             1, # llafr does not apply
2164         );
2165     }
2166 }
2167
2168 sub pp_scalar {
2169     my $self = shift;
2170     my($op, $cx) = @_;
2171     my $kid = $op->first;
2172     if (not null $kid->sibling) {
2173         # XXX Was a here-doc
2174         return $self->dquote($op);
2175     }
2176     $self->unop(@_, "scalar");
2177 }
2178
2179
2180 sub padval {
2181     my $self = shift;
2182     my $targ = shift;
2183     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2184 }
2185
2186 sub anon_hash_or_list {
2187     my $self = shift;
2188     my($op, $cx) = @_;
2189
2190     my($pre, $post) = @{{"anonlist" => ["[","]"],
2191                          "anonhash" => ["{","}"]}->{$op->name}};
2192     my($expr, @exprs);
2193     $op = $op->first->sibling; # skip pushmark
2194     for (; !null($op); $op = $op->sibling) {
2195         $expr = $self->deparse($op, 6);
2196         push @exprs, $expr;
2197     }
2198     if ($pre eq "{" and $cx < 1) {
2199         # Disambiguate that it's not a block
2200         $pre = "+{";
2201     }
2202     return $pre . join(", ", @exprs) . $post;
2203 }
2204
2205 sub pp_anonlist {
2206     my $self = shift;
2207     my ($op, $cx) = @_;
2208     if ($op->flags & OPf_SPECIAL) {
2209         return $self->anon_hash_or_list($op, $cx);
2210     }
2211     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2212     return 'XXX';
2213 }
2214
2215 *pp_anonhash = \&pp_anonlist;
2216
2217 sub pp_refgen {
2218     my $self = shift;   
2219     my($op, $cx) = @_;
2220     my $kid = $op->first;
2221     if ($kid->name eq "null") {
2222         $kid = $kid->first;
2223         if (!null($kid->sibling) and
2224                  $kid->sibling->name eq "anoncode") {
2225             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
2226         } elsif ($kid->name eq "pushmark") {
2227             my $sib_name = $kid->sibling->name;
2228             if ($sib_name =~ /^(pad|rv2)[ah]v$/
2229                 and not $kid->sibling->flags & OPf_REF)
2230             {
2231                 # The @a in \(@a) isn't in ref context, but only when the
2232                 # parens are there.
2233                 return "\\(" . $self->pp_list($op->first) . ")";
2234             } elsif ($sib_name eq 'entersub') {
2235                 my $text = $self->deparse($kid->sibling, 1);
2236                 # Always show parens for \(&func()), but only with -p otherwise
2237                 $text = "($text)" if $self->{'parens'}
2238                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2239                 return "\\$text";
2240             }
2241         }
2242     }
2243     $self->pfixop($op, $cx, "\\", 20);
2244 }
2245
2246 sub e_anoncode {
2247     my ($self, $info) = @_;
2248     my $text = $self->deparse_sub($info->{code});
2249     return "sub " . $text;
2250 }
2251
2252 sub pp_srefgen { pp_refgen(@_) }
2253
2254 sub pp_readline {
2255     my $self = shift;
2256     my($op, $cx) = @_;
2257     my $kid = $op->first;
2258     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
2259     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
2260     return $self->unop($op, $cx, "readline");
2261 }
2262
2263 sub pp_rcatline {
2264     my $self = shift;
2265     my($op) = @_;
2266     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2267 }
2268
2269 # Unary operators that can occur as pseudo-listops inside double quotes
2270 sub dq_unop {
2271     my $self = shift;
2272     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2273     my $kid;
2274     if ($op->flags & OPf_KIDS) {
2275        $kid = $op->first;
2276        # If there's more than one kid, the first is an ex-pushmark.
2277        $kid = $kid->sibling if not null $kid->sibling;
2278        return $self->maybe_parens_unop($name, $kid, $cx);
2279     } else {
2280        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2281     }
2282 }
2283
2284 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2285 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2286 sub pp_uc { dq_unop(@_, "uc") }
2287 sub pp_lc { dq_unop(@_, "lc") }
2288 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2289 sub pp_fc { dq_unop(@_, "fc") }
2290
2291 sub loopex {
2292     my $self = shift;
2293     my ($op, $cx, $name) = @_;
2294     if (class($op) eq "PVOP") {
2295         $name .= " " . $op->pv;
2296     } elsif (class($op) eq "OP") {
2297         # no-op
2298     } elsif (class($op) eq "UNOP") {
2299         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2300         $name .= " $kid";
2301     }
2302     return $self->maybe_parens($name, $cx, 7);
2303 }
2304
2305 sub pp_last { loopex(@_, "last") }
2306 sub pp_next { loopex(@_, "next") }
2307 sub pp_redo { loopex(@_, "redo") }
2308 sub pp_goto { loopex(@_, "goto") }
2309 sub pp_dump { loopex(@_, "CORE::dump") }
2310
2311 sub ftst {
2312     my $self = shift;
2313     my($op, $cx, $name) = @_;
2314     if (class($op) eq "UNOP") {
2315         # Genuine '-X' filetests are exempt from the LLAFR, but not
2316         # l?stat()
2317         if ($name =~ /^-/) {
2318             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2319             return $self->maybe_parens("$name $kid", $cx, 16);
2320         }
2321         return $self->maybe_parens_unop($name, $op->first, $cx);
2322     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2323         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2324     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2325         return $name;
2326     }
2327 }
2328
2329 sub pp_lstat    { ftst(@_, "lstat") }
2330 sub pp_stat     { ftst(@_, "stat") }
2331 sub pp_ftrread  { ftst(@_, "-R") }
2332 sub pp_ftrwrite { ftst(@_, "-W") }
2333 sub pp_ftrexec  { ftst(@_, "-X") }
2334 sub pp_fteread  { ftst(@_, "-r") }
2335 sub pp_ftewrite { ftst(@_, "-w") }
2336 sub pp_fteexec  { ftst(@_, "-x") }
2337 sub pp_ftis     { ftst(@_, "-e") }
2338 sub pp_fteowned { ftst(@_, "-O") }
2339 sub pp_ftrowned { ftst(@_, "-o") }
2340 sub pp_ftzero   { ftst(@_, "-z") }
2341 sub pp_ftsize   { ftst(@_, "-s") }
2342 sub pp_ftmtime  { ftst(@_, "-M") }
2343 sub pp_ftatime  { ftst(@_, "-A") }
2344 sub pp_ftctime  { ftst(@_, "-C") }
2345 sub pp_ftsock   { ftst(@_, "-S") }
2346 sub pp_ftchr    { ftst(@_, "-c") }
2347 sub pp_ftblk    { ftst(@_, "-b") }
2348 sub pp_ftfile   { ftst(@_, "-f") }
2349 sub pp_ftdir    { ftst(@_, "-d") }
2350 sub pp_ftpipe   { ftst(@_, "-p") }
2351 sub pp_ftlink   { ftst(@_, "-l") }
2352 sub pp_ftsuid   { ftst(@_, "-u") }
2353 sub pp_ftsgid   { ftst(@_, "-g") }
2354 sub pp_ftsvtx   { ftst(@_, "-k") }
2355 sub pp_fttty    { ftst(@_, "-t") }
2356 sub pp_fttext   { ftst(@_, "-T") }
2357 sub pp_ftbinary { ftst(@_, "-B") }
2358
2359 sub SWAP_CHILDREN () { 1 }
2360 sub ASSIGN () { 2 } # has OP= variant
2361 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2362
2363 my(%left, %right);
2364
2365 sub assoc_class {
2366     my $op = shift;
2367     my $name = $op->name;
2368     if ($name eq "concat" and $op->first->name eq "concat") {
2369         # avoid spurious '=' -- see comment in pp_concat
2370         return "concat";
2371     }
2372     if ($name eq "null" and class($op) eq "UNOP"
2373         and $op->first->name =~ /^(and|x?or)$/
2374         and null $op->first->sibling)
2375     {
2376         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2377         # with a null that's used as the common end point of the two
2378         # flows of control. For precedence purposes, ignore it.
2379         # (COND_EXPRs have these too, but we don't bother with
2380         # their associativity).
2381         return assoc_class($op->first);
2382     }
2383     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2384 }
2385
2386 # Left associative operators, like '+', for which
2387 # $a + $b + $c is equivalent to ($a + $b) + $c
2388
2389 BEGIN {
2390     %left = ('multiply' => 19, 'i_multiply' => 19,
2391              'divide' => 19, 'i_divide' => 19,
2392              'modulo' => 19, 'i_modulo' => 19,
2393              'repeat' => 19,
2394              'add' => 18, 'i_add' => 18,
2395              'subtract' => 18, 'i_subtract' => 18,
2396              'concat' => 18,
2397              'left_shift' => 17, 'right_shift' => 17,
2398              'bit_and' => 13,
2399              'bit_or' => 12, 'bit_xor' => 12,
2400              'and' => 3,
2401              'or' => 2, 'xor' => 2,
2402             );
2403 }
2404
2405 sub deparse_binop_left {
2406     my $self = shift;
2407     my($op, $left, $prec) = @_;
2408     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2409         and $left{assoc_class($op)} == $left{assoc_class($left)})
2410     {
2411         return $self->deparse($left, $prec - .00001);
2412     } else {
2413         return $self->deparse($left, $prec);    
2414     }
2415 }
2416
2417 # Right associative operators, like '=', for which
2418 # $a = $b = $c is equivalent to $a = ($b = $c)
2419
2420 BEGIN {
2421     %right = ('pow' => 22,
2422               'sassign=' => 7, 'aassign=' => 7,
2423               'multiply=' => 7, 'i_multiply=' => 7,
2424               'divide=' => 7, 'i_divide=' => 7,
2425               'modulo=' => 7, 'i_modulo=' => 7,
2426               'repeat=' => 7,
2427               'add=' => 7, 'i_add=' => 7,
2428               'subtract=' => 7, 'i_subtract=' => 7,
2429               'concat=' => 7,
2430               'left_shift=' => 7, 'right_shift=' => 7,
2431               'bit_and=' => 7,
2432               'bit_or=' => 7, 'bit_xor=' => 7,
2433               'andassign' => 7,
2434               'orassign' => 7,
2435              );
2436 }
2437
2438 sub deparse_binop_right {
2439     my $self = shift;
2440     my($op, $right, $prec) = @_;
2441     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2442         and $right{assoc_class($op)} == $right{assoc_class($right)})
2443     {
2444         return $self->deparse($right, $prec - .00001);
2445     } else {
2446         return $self->deparse($right, $prec);   
2447     }
2448 }
2449
2450 sub binop {
2451     my $self = shift;
2452     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2453     my $left = $op->first;
2454     my $right = $op->last;
2455     my $eq = "";
2456     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2457         $eq = "=";
2458         $prec = 7;
2459     }
2460     if ($flags & SWAP_CHILDREN) {
2461         ($left, $right) = ($right, $left);
2462     }
2463     $left = $self->deparse_binop_left($op, $left, $prec);
2464     $left = "($left)" if $flags & LIST_CONTEXT
2465                 && $left !~ /^(my|our|local|)[\@\(]/;
2466     $right = $self->deparse_binop_right($op, $right, $prec);
2467     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2468 }
2469
2470 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2471 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2472 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2473 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2474 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2475 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2476 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2477 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2478 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2479 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2480 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2481
2482 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2483 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2484 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2485 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2486 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2487
2488 sub pp_eq { binop(@_, "==", 14) }
2489 sub pp_ne { binop(@_, "!=", 14) }
2490 sub pp_lt { binop(@_, "<", 15) }
2491 sub pp_gt { binop(@_, ">", 15) }
2492 sub pp_ge { binop(@_, ">=", 15) }
2493 sub pp_le { binop(@_, "<=", 15) }
2494 sub pp_ncmp { binop(@_, "<=>", 14) }
2495 sub pp_i_eq { binop(@_, "==", 14) }
2496 sub pp_i_ne { binop(@_, "!=", 14) }
2497 sub pp_i_lt { binop(@_, "<", 15) }
2498 sub pp_i_gt { binop(@_, ">", 15) }
2499 sub pp_i_ge { binop(@_, ">=", 15) }
2500 sub pp_i_le { binop(@_, "<=", 15) }
2501 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2502
2503 sub pp_seq { binop(@_, "eq", 14) }
2504 sub pp_sne { binop(@_, "ne", 14) }
2505 sub pp_slt { binop(@_, "lt", 15) }
2506 sub pp_sgt { binop(@_, "gt", 15) }
2507 sub pp_sge { binop(@_, "ge", 15) }
2508 sub pp_sle { binop(@_, "le", 15) }
2509 sub pp_scmp { binop(@_, "cmp", 14) }
2510
2511 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2512 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2513
2514 sub pp_smartmatch {
2515     my ($self, $op, $cx) = @_;
2516     if ($op->flags & OPf_SPECIAL) {
2517         return $self->deparse($op->last, $cx);
2518     }
2519     else {
2520         binop(@_, "~~", 14);
2521     }
2522 }
2523
2524 # '.' is special because concats-of-concats are optimized to save copying
2525 # by making all but the first concat stacked. The effect is as if the
2526 # programmer had written '($a . $b) .= $c', except legal.
2527 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2528 sub real_concat {
2529     my $self = shift;
2530     my($op, $cx) = @_;
2531     my $left = $op->first;
2532     my $right = $op->last;
2533     my $eq = "";
2534     my $prec = 18;
2535     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2536         $eq = "=";
2537         $prec = 7;
2538     }
2539     $left = $self->deparse_binop_left($op, $left, $prec);
2540     $right = $self->deparse_binop_right($op, $right, $prec);
2541     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2542 }
2543
2544 # 'x' is weird when the left arg is a list
2545 sub pp_repeat {
2546     my $self = shift;
2547     my($op, $cx) = @_;
2548     my $left = $op->first;
2549     my $right = $op->last;
2550     my $eq = "";
2551     my $prec = 19;
2552     if ($op->flags & OPf_STACKED) {
2553         $eq = "=";
2554         $prec = 7;
2555     }
2556     if (null($right)) { # list repeat; count is inside left-side ex-list
2557         my $kid = $left->first->sibling; # skip pushmark
2558         my @exprs;
2559         for (; !null($kid->sibling); $kid = $kid->sibling) {
2560             push @exprs, $self->deparse($kid, 6);
2561         }
2562         $right = $kid;
2563         $left = "(" . join(", ", @exprs). ")";
2564     } else {
2565         $left = $self->deparse_binop_left($op, $left, $prec);
2566     }
2567     $right = $self->deparse_binop_right($op, $right, $prec);
2568     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2569 }
2570
2571 sub range {
2572     my $self = shift;
2573     my ($op, $cx, $type) = @_;
2574     my $left = $op->first;
2575     my $right = $left->sibling;
2576     $left = $self->deparse($left, 9);
2577     $right = $self->deparse($right, 9);
2578     return $self->maybe_parens("$left $type $right", $cx, 9);
2579 }
2580
2581 sub pp_flop {
2582     my $self = shift;
2583     my($op, $cx) = @_;
2584     my $flip = $op->first;
2585     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2586     return $self->range($flip->first, $cx, $type);
2587 }
2588
2589 # one-line while/until is handled in pp_leave
2590
2591 sub logop {
2592     my $self = shift;
2593     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2594     my $left = $op->first;
2595     my $right = $op->first->sibling;
2596     if ($cx < 1 and is_scope($right) and $blockname
2597         and $self->{'expand'} < 7)
2598     { # if ($a) {$b}
2599         $left = $self->deparse($left, 1);
2600         $right = $self->deparse($right, 0);
2601         return "$blockname ($left) {\n\t$right\n\b}\cK";
2602     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2603              and $self->{'expand'} < 7) { # $b if $a
2604         $right = $self->deparse($right, 1);
2605         $left = $self->deparse($left, 1);
2606         return "$right $blockname $left";
2607     } elsif ($cx > $lowprec and $highop) { # $a && $b
2608         $left = $self->deparse_binop_left($op, $left, $highprec);
2609         $right = $self->deparse_binop_right($op, $right, $highprec);
2610         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2611     } else { # $a and $b
2612         $left = $self->deparse_binop_left($op, $left, $lowprec);
2613         $right = $self->deparse_binop_right($op, $right, $lowprec);
2614         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2615     }
2616 }
2617
2618 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2619 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2620 sub pp_dor { logop(@_, "//", 10) }
2621
2622 # xor is syntactically a logop, but it's really a binop (contrary to
2623 # old versions of opcode.pl). Syntax is what matters here.
2624 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2625
2626 sub logassignop {
2627     my $self = shift;
2628     my ($op, $cx, $opname) = @_;
2629     my $left = $op->first;
2630     my $right = $op->first->sibling->first; # skip sassign
2631     $left = $self->deparse($left, 7);
2632     $right = $self->deparse($right, 7);
2633     return $self->maybe_parens("$left $opname $right", $cx, 7);
2634 }
2635
2636 sub pp_andassign { logassignop(@_, "&&=") }
2637 sub pp_orassign  { logassignop(@_, "||=") }
2638 sub pp_dorassign { logassignop(@_, "//=") }
2639
2640 sub rv2gv_or_string {
2641     my($self,$op) = @_;
2642     if ($op->name eq "gv") { # could be open("open") or open("###")
2643         my($name,$quoted) =
2644             $self->stash_variable_name("", $self->gv_or_padgv($op));
2645         $quoted ? $name : "*$name";
2646     }
2647     else {
2648         $self->deparse($op, 6);
2649     }
2650 }
2651
2652 sub listop {
2653     my $self = shift;
2654     my($op, $cx, $name, $kid, $nollafr) = @_;
2655     my(@exprs);
2656     my $parens = ($cx >= 5) || $self->{'parens'};
2657     $kid ||= $op->first->sibling;
2658     # If there are no arguments, add final parentheses (or parenthesize the
2659     # whole thing if the llafr does not apply) to account for cases like
2660     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
2661     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
2662     if (null $kid) {
2663         return $nollafr
2664                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
2665                 : $self->keyword($name) . '()' x (7 < $cx);
2666     }
2667     my $first;
2668     $name = "socketpair" if $name eq "sockpair";
2669     my $fullname = $self->keyword($name);
2670     my $proto = prototype("CORE::$name");
2671     if (
2672          (     (defined $proto && $proto =~ /^;?\*/)
2673             || $name eq 'select' # select(F) doesn't have a proto
2674          )
2675          && $kid->name eq "rv2gv"
2676          && !($kid->private & OPpLVAL_INTRO)
2677     ) {
2678         $first = $self->rv2gv_or_string($kid->first);
2679     }
2680     else {
2681         $first = $self->deparse($kid, 6);
2682     }
2683     if ($name eq "chmod" && $first =~ /^\d+$/) {
2684         $first = sprintf("%#o", $first);
2685     }
2686     $first = "+$first"
2687         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
2688     push @exprs, $first;
2689     $kid = $kid->sibling;
2690     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
2691          && !($kid->private & OPpLVAL_INTRO)) {
2692         push @exprs, $first = $self->rv2gv_or_string($kid->first);
2693         $kid = $kid->sibling;
2694     }
2695     for (; !null($kid); $kid = $kid->sibling) {
2696         push @exprs, $self->deparse($kid, 6);
2697     }
2698     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2699         return "$exprs[0] = $fullname"
2700                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2701     }
2702     if ($name =~ /^(system|exec)$/
2703         && ($op->flags & OPf_STACKED)
2704         && @exprs > 1)
2705     {
2706         # handle the "system prog a1,a2,.." form
2707         my $prog = shift @exprs;
2708         $exprs[0] = "$prog $exprs[0]";
2709     }
2710
2711     if ($parens && $nollafr) {
2712         return "($fullname " . join(", ", @exprs) . ")";
2713     } elsif ($parens) {
2714         return "$fullname(" . join(", ", @exprs) . ")";
2715     } else {
2716         return "$fullname " . join(", ", @exprs);
2717     }
2718 }
2719
2720 sub pp_bless { listop(@_, "bless") }
2721 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2722 sub pp_substr {
2723     my ($self,$op,$cx) = @_;
2724     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2725         return
2726            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2727          . " = "
2728          . $self->deparse($op->first->sibling, 7);
2729     }
2730     maybe_local(@_, listop(@_, "substr"))
2731 }
2732 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2733 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2734 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2735 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2736 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2737 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2738 sub pp_unpack { listop(@_, "unpack") }
2739 sub pp_pack { listop(@_, "pack") }
2740 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2741 sub pp_splice { listop(@_, "splice") }
2742 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2743 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2744 sub pp_reverse { listop(@_, "reverse") }
2745 sub pp_warn { listop(@_, "warn") }
2746 sub pp_die { listop(@_, "die") }
2747 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
2748 sub pp_open { listop(@_, "open") }
2749 sub pp_pipe_op { listop(@_, "pipe") }
2750 sub pp_tie { listop(@_, "tie") }
2751 sub pp_binmode { listop(@_, "binmode") }
2752 sub pp_dbmopen { listop(@_, "dbmopen") }
2753 sub pp_sselect { listop(@_, "select") }
2754 sub pp_select { listop(@_, "select") }
2755 sub pp_read { listop(@_, "read") }
2756 sub pp_sysopen { listop(@_, "sysopen") }
2757 sub pp_sysseek { listop(@_, "sysseek") }
2758 sub pp_sysread { listop(@_, "sysread") }
2759 sub pp_syswrite { listop(@_, "syswrite") }
2760 sub pp_send { listop(@_, "send") }
2761 sub pp_recv { listop(@_, "recv") }
2762 sub pp_seek { listop(@_, "seek") }
2763 sub pp_fcntl { listop(@_, "fcntl") }
2764 sub pp_ioctl { listop(@_, "ioctl") }
2765 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2766 sub pp_socket { listop(@_, "socket") }
2767 sub pp_sockpair { listop(@_, "sockpair") }
2768 sub pp_bind { listop(@_, "bind") }
2769 sub pp_connect { listop(@_, "connect") }
2770 sub pp_listen { listop(@_, "listen") }
2771 sub pp_accept { listop(@_, "accept") }
2772 sub pp_shutdown { listop(@_, "shutdown") }
2773 sub pp_gsockopt { listop(@_, "getsockopt") }
2774 sub pp_ssockopt { listop(@_, "setsockopt") }
2775 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2776 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2777 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2778 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2779 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2780 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2781 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2782 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2783 sub pp_open_dir { listop(@_, "opendir") }
2784 sub pp_seekdir { listop(@_, "seekdir") }
2785 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2786 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2787 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2788 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2789 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2790 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2791 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2792 sub pp_shmget { listop(@_, "shmget") }
2793 sub pp_shmctl { listop(@_, "shmctl") }
2794 sub pp_shmread { listop(@_, "shmread") }
2795 sub pp_shmwrite { listop(@_, "shmwrite") }
2796 sub pp_msgget { listop(@_, "msgget") }
2797 sub pp_msgctl { listop(@_, "msgctl") }
2798 sub pp_msgsnd { listop(@_, "msgsnd") }
2799 sub pp_msgrcv { listop(@_, "msgrcv") }
2800 sub pp_semget { listop(@_, "semget") }
2801 sub pp_semctl { listop(@_, "semctl") }
2802 sub pp_semop { listop(@_, "semop") }
2803 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2804 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2805 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2806 sub pp_gsbyname { listop(@_, "getservbyname") }
2807 sub pp_gsbyport { listop(@_, "getservbyport") }
2808 sub pp_syscall { listop(@_, "syscall") }
2809
2810 sub pp_glob {
2811     my $self = shift;
2812     my($op, $cx) = @_;
2813     my $text = $self->dq($op->first->sibling);  # skip pushmark
2814     my $keyword =
2815         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2816     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2817         or $keyword =~ /^CORE::/
2818         or $text =~ /[<>]/) {
2819         return "$keyword(" . single_delim('qq', '"', $text) . ')';
2820     } else {
2821         return '<' . $text . '>';
2822     }
2823 }
2824
2825 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2826 # be a filehandle. This could probably be better fixed in the core
2827 # by moving the GV lookup into ck_truc.
2828
2829 sub pp_truncate {
2830     my $self = shift;
2831     my($op, $cx) = @_;
2832     my(@exprs);
2833     my $parens = ($cx >= 5) || $self->{'parens'};
2834     my $kid = $op->first->sibling;
2835     my $fh;
2836     if ($op->flags & OPf_SPECIAL) {
2837         # $kid is an OP_CONST
2838         $fh = $self->const_sv($kid)->PV;
2839     } else {
2840         $fh = $self->deparse($kid, 6);
2841         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2842     }
2843     my $len = $self->deparse($kid->sibling, 6);
2844     my $name = $self->keyword('truncate');
2845     if ($parens) {
2846         return "$name($fh, $len)";
2847     } else {
2848         return "$name $fh, $len";
2849     }
2850 }
2851
2852 sub indirop {
2853     my $self = shift;
2854     my($op, $cx, $name) = @_;
2855     my($expr, @exprs);
2856     my $firstkid = my $kid = $op->first->sibling;
2857     my $indir = "";
2858     if ($op->flags & OPf_STACKED) {
2859         $indir = $kid;
2860         $indir = $indir->first; # skip rv2gv
2861         if (is_scope($indir)) {
2862             $indir = "{" . $self->deparse($indir, 0) . "}";
2863             $indir = "{;}" if $indir eq "{}";
2864         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2865             $indir = $self->const_sv($indir)->PV;
2866         } else {
2867             $indir = $self->deparse($indir, 24);
2868         }
2869         $indir = $indir . " ";
2870         $kid = $kid->sibling;
2871     }
2872     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2873         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2874                                                   : '{$a <=> $b} ';
2875     }
2876     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2877         $indir = '{$b cmp $a} ';
2878     }
2879     for (; !null($kid); $kid = $kid->sibling) {
2880         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2881         push @exprs, $expr;
2882     }
2883     my $name2;
2884     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2885         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2886     }
2887     else { $name2 = $self->keyword($name) }
2888     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2889         return "$exprs[0] = $name2 $indir $exprs[0]";
2890     }
2891
2892     my $args = $indir . join(", ", @exprs);
2893     if ($indir ne "" && $name eq "sort") {
2894         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2895         # give bareword warnings in that case. Therefore if context
2896         # requires, we'll put parens around the outside "(sort f 1, 2,
2897         # 3)". Unfortunately, we'll currently think the parens are
2898         # necessary more often that they really are, because we don't
2899         # distinguish which side of an assignment we're on.
2900         if ($cx >= 5) {
2901             return "($name2 $args)";
2902         } else {
2903             return "$name2 $args";
2904         }
2905     } elsif (
2906         !$indir && $name eq "sort"
2907       && !null($op->first->sibling)
2908       && $op->first->sibling->name eq 'entersub'
2909     ) {
2910         # We cannot say sort foo(bar), as foo will be interpreted as a
2911         # comparison routine.  We have to say sort(...) in that case.
2912         return "$name2($args)";
2913     } else {
2914         return $self->maybe_parens_func($name2, $args, $cx, 5);
2915     }
2916
2917 }
2918
2919 sub pp_prtf { indirop(@_, "printf") }
2920 sub pp_print { indirop(@_, "print") }
2921 sub pp_say  { indirop(@_, "say") }
2922 sub pp_sort { indirop(@_, "sort") }
2923
2924 sub mapop {
2925     my $self = shift;
2926     my($op, $cx, $name) = @_;
2927     my($expr, @exprs);
2928     my $kid = $op->first; # this is the (map|grep)start
2929     $kid = $kid->first->sibling; # skip a pushmark
2930     my $code = $kid->first; # skip a null
2931     if (is_scope $code) {
2932         $code = "{" . $self->deparse($code, 0) . "} ";
2933     } else {
2934         $code = $self->deparse($code, 24);
2935         $code .= ", " if !null($kid->sibling);
2936     }
2937     $kid = $kid->sibling;
2938     for (; !null($kid); $kid = $kid->sibling) {
2939         $expr = $self->deparse($kid, 6);
2940         push @exprs, $expr if defined $expr;
2941     }
2942     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2943 }
2944
2945 sub pp_mapwhile { mapop(@_, "map") }
2946 sub pp_grepwhile { mapop(@_, "grep") }
2947 sub pp_mapstart { baseop(@_, "map") }
2948 sub pp_grepstart { baseop(@_, "grep") }
2949
2950 sub pp_list {
2951     my $self = shift;
2952     my($op, $cx) = @_;
2953     my($expr, @exprs);
2954     my $kid = $op->first->sibling; # skip pushmark
2955     return '' if class($kid) eq 'NULL';
2956     my $lop;
2957     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2958     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2959         # This assumes that no other private flags equal 128, and that
2960         # OPs that store things other than flags in their op_private,
2961         # like OP_AELEMFAST, won't be immediate children of a list.
2962         #
2963         # OP_ENTERSUB and OP_SPLIT can break this logic, so check for them.
2964         # I suspect that open and exit can too.
2965         # XXX This really needs to be rewritten to accept only those ops
2966         #     known to take the OPpLVAL_INTRO flag.
2967
2968         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2969                 or $lop->name eq "undef")
2970             or $lop->name =~ /^(?:entersub|exit|open|split)\z/)
2971         {
2972             $local = ""; # or not
2973             last;
2974         }
2975         if ($lop->name =~ /^pad[ash]v$/) {
2976             if ($lop->private & OPpPAD_STATE) { # state()
2977                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2978                 $local = "state";
2979             } else { # my()
2980                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2981                 $local = "my";
2982             }
2983         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2984                         && $lop->private & OPpOUR_INTRO
2985                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2986                         && $lop->first->private & OPpOUR_INTRO) { # our()
2987             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2988             $local = "our";
2989         } elsif ($lop->name ne "undef"
2990                 # specifically avoid the "reverse sort" optimisation,
2991                 # where "reverse" is nullified
2992                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2993         {
2994             # local()
2995             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2996             $local = "local";
2997         }
2998     }
2999     $local = "" if $local eq "either"; # no point if it's all undefs
3000     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3001     for (; !null($kid); $kid = $kid->sibling) {
3002         if ($local) {
3003             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3004                 $lop = $kid->first;
3005             } else {
3006                 $lop = $kid;
3007             }
3008             $self->{'avoid_local'}{$$lop}++;
3009             $expr = $self->deparse($kid, 6);
3010             delete $self->{'avoid_local'}{$$lop};
3011         } else {
3012             $expr = $self->deparse($kid, 6);
3013         }
3014         push @exprs, $expr;
3015     }
3016     if ($local) {
3017         return "$local(" . join(", ", @exprs) . ")";
3018     } else {
3019         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3020     }
3021 }
3022
3023 sub is_ifelse_cont {
3024     my $op = shift;
3025     return ($op->name eq "null" and class($op) eq "UNOP"
3026             and $op->first->name =~ /^(and|cond_expr)$/
3027             and is_scope($op->first->first->sibling));
3028 }
3029
3030 sub pp_cond_expr {
3031     my $self = shift;
3032     my($op, $cx) = @_;
3033     my $cond = $op->first;
3034     my $true = $cond->sibling;
3035     my $false = $true->sibling;
3036     my $cuddle = $self->{'cuddle'};
3037     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3038             (is_scope($false) || is_ifelse_cont($false))
3039             and $self->{'expand'} < 7) {
3040         $cond = $self->deparse($cond, 8);
3041         $true = $self->deparse($true, 6);
3042         $false = $self->deparse($false, 8);
3043         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3044     }
3045
3046     $cond = $self->deparse($cond, 1);
3047     $true = $self->deparse($true, 0);
3048     my $head = "if ($cond) {\n\t$true\n\b}";
3049     my @elsifs;
3050     while (!null($false) and is_ifelse_cont($false)) {
3051         my $newop = $false->first;
3052         my $newcond = $newop->first;
3053         my $newtrue = $newcond->sibling;
3054         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3055         if ($newcond->name eq "lineseq")
3056         {
3057             # lineseq to ensure correct line numbers in elsif()
3058             # Bug #37302 fixed by change #33710.
3059             $newcond = $newcond->first->sibling;
3060         }
3061         $newcond = $self->deparse($newcond, 1);
3062         $newtrue = $self->deparse($newtrue, 0);
3063         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
3064     }
3065     if (!null($false)) {
3066         $false = $cuddle . "else {\n\t" .
3067           $self->deparse($false, 0) . "\n\b}\cK";
3068     } else {
3069         $false = "\cK";
3070     }
3071     return $head . join($cuddle, "", @elsifs) . $false;
3072 }
3073
3074 sub pp_once {
3075     my ($self, $op, $cx) = @_;
3076     my $cond = $op->first;
3077     my $true = $cond->sibling;
3078
3079     return $self->deparse($true, $cx);
3080 }
3081
3082 sub loop_common {
3083     my $self = shift;
3084     my($op, $cx, $init) = @_;
3085     my $enter = $op->first;
3086     my $kid = $enter->sibling;
3087     local(@$self{qw'curstash warnings hints hinthash'})
3088                 = @$self{qw'curstash warnings hints hinthash'};
3089     my $head = "";
3090     my $bare = 0;
3091     my $body;
3092     my $cond = undef;
3093     if ($kid->name eq "lineseq") { # bare or infinite loop
3094         if ($kid->last->name eq "unstack") { # infinite
3095             $head = "while (1) "; # Can't use for(;;) if there's a continue
3096             $cond = "";
3097         } else {
3098             $bare = 1;
3099         }
3100         $body = $kid;
3101     } elsif ($enter->name eq "enteriter") { # foreach
3102         my $ary = $enter->first->sibling; # first was pushmark
3103         my $var = $ary->sibling;
3104         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3105             # "reverse" was optimised away
3106             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3107         } elsif ($enter->flags & OPf_STACKED
3108             and not null $ary->first->sibling->sibling)
3109         {
3110             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3111               $self->deparse($ary->first->sibling->sibling, 9);
3112         } else {
3113             $ary = $self->deparse($ary, 1);
3114         }
3115         if (null $var) {
3116             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
3117                 # thread special var, under 5005threads
3118                 $var = $self->pp_threadsv($enter, 1);
3119             } else { # regular my() variable
3120                 $var = $self->pp_padsv($enter, 1, 1);
3121             }
3122         } elsif ($var->name eq "rv2gv") {
3123             $var = $self->pp_rv2sv($var, 1);
3124             if ($enter->private & OPpOUR_INTRO) {
3125                 # our declarations don't have package names
3126                 $var =~ s/^(.).*::/$1/;
3127                 $var = "our $var";
3128             }
3129         } elsif ($var->name eq "gv") {
3130             $var = "\$" . $self->deparse($var, 1);
3131         }
3132         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3133         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3134             confess unless $var eq '$_';
3135             $body = $body->first;
3136             return $self->deparse($body, 2) . " foreach ($ary)";
3137         }
3138         $head = "foreach $var ($ary) ";
3139     } elsif ($kid->name eq "null") { # while/until
3140         $kid = $kid->first;
3141         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
3142         $cond = $self->deparse($kid->first, 1);
3143         $head = "$name ($cond) ";
3144         $body = $kid->first->sibling;
3145     } elsif ($kid->name eq "stub") { # bare and empty
3146         return "{;}"; # {} could be a hashref
3147     }
3148     # If there isn't a continue block, then the next pointer for the loop
3149     # will point to the unstack, which is kid's last child, except
3150     # in a bare loop, when it will point to the leaveloop. When neither of
3151     # these conditions hold, then the second-to-last child is the continue
3152     # block (or the last in a bare loop).
3153     my $cont_start = $enter->nextop;
3154     my $cont;
3155     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3156         if ($bare) {
3157             $cont = $body->last;
3158         } else {
3159             $cont = $body->first;
3160             while (!null($cont->sibling->sibling)) {
3161                 $cont = $cont->sibling;
3162             }
3163         }
3164         my $state = $body->first;
3165         my $cuddle = $self->{'cuddle'};
3166         my @states;
3167         for (; $$state != $$cont; $state = $state->sibling) {
3168             push @states, $state;
3169         }
3170         $body = $self->lineseq(undef, 0, @states);
3171         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3172             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
3173             $cont = "\cK";
3174         } else {
3175             $cont = $cuddle . "continue {\n\t" .
3176               $self->deparse($cont, 0) . "\n\b}\cK";
3177         }
3178     } else {
3179         return "" if !defined $body;
3180         if (length $init) {
3181             $head = "for ($init; $cond;) ";
3182         }
3183         $cont = "\cK";
3184         $body = $self->deparse($body, 0);
3185     }
3186     $body =~ s/;?$/;\n/;
3187
3188     return $head . "{\n\t" . $body . "\b}" . $cont;
3189 }
3190
3191 sub pp_leaveloop { shift->loop_common(@_, "") }
3192
3193 sub for_loop {
3194     my $self = shift;
3195     my($op, $cx) = @_;
3196     my $init = $self->deparse($op, 1);
3197     my $s = $op->sibling;
3198     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3199     return $self->loop_common($ll, $cx, $init);
3200 }
3201
3202 sub pp_leavetry {
3203     my $self = shift;
3204     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3205 }
3206
3207 BEGIN { for (qw[ const stringify rv2sv list glob ]) {
3208     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
3209 }}
3210
3211 sub pp_null {
3212     my $self = shift;
3213     my($op, $cx) = @_;
3214     if (class($op) eq "OP") {
3215         # old value is lost
3216         return $self->{'ex_const'} if $op->targ == OP_CONST;
3217     } elsif ($op->first->name eq "pushmark") {
3218         return $self->pp_list($op, $cx);
3219     } elsif ($op->first->name eq "enter") {
3220         return $self->pp_leave($op, $cx);
3221     } elsif ($op->first->name eq "leave") {
3222         return $self->pp_leave($op->first, $cx);
3223     } elsif ($op->first->name eq "scope") {
3224         return $self->pp_scope($op->first, $cx);
3225     } elsif ($op->targ == OP_STRINGIFY) {
3226         return $self->dquote($op, $cx);
3227     } elsif ($op->targ == OP_GLOB) {
3228         return $self->pp_glob(
3229                  $op->first    # entersub
3230                     ->first    # ex-list
3231                     ->first    # pushmark
3232                     ->sibling, # glob
3233                  $cx
3234                );
3235     } elsif (!null($op->first->sibling) and
3236              $op->first->sibling->name eq "readline" and
3237              $op->first->sibling->flags & OPf_STACKED) {
3238         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3239                                    . $self->deparse($op->first->sibling, 7),
3240                                    $cx, 7);
3241     } elsif (!null($op->first->sibling) and
3242              $op->first->sibling->name eq "trans" and
3243              $op->first->sibling->flags & OPf_STACKED) {
3244         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
3245                                    . $self->deparse($op->first->sibling, 20),
3246                                    $cx, 20);
3247     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
3248         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
3249     } elsif (!null($op->first->sibling) and
3250              $op->first->sibling->name eq "null" and
3251              class($op->first->sibling) eq "UNOP" and
3252              $op->first->sibling->first->flags & OPf_STACKED and
3253              $op->first->sibling->first->name eq "rcatline") {
3254         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
3255                                    . $self->deparse($op->first->sibling, 18),
3256                                    $cx, 18);
3257     } else {
3258         return $self->deparse($op->first, $cx);
3259     }
3260 }
3261
3262 sub padname {
3263     my $self = shift;
3264     my $targ = shift;
3265     return $self->padname_sv($targ)->PVX;
3266 }
3267
3268 sub padany {
3269     my $self = shift;
3270     my $op = shift;
3271     return substr($self->padname($op->targ), 1); # skip $/@/%
3272 }
3273
3274 sub pp_padsv {
3275     my $self = shift;
3276     my($op, $cx, $forbid_parens) = @_;
3277     return $self->maybe_my($op, $cx, $self->padname($op->targ),
3278                            $forbid_parens);
3279 }
3280
3281 sub pp_padav { pp_padsv(@_) }
3282 sub pp_padhv { pp_padsv(@_) }
3283
3284 my @threadsv_names = B::threadsv_names;
3285 sub pp_threadsv {
3286     my $self = shift;
3287     my($op, $cx) = @_;
3288     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
3289 }
3290
3291 sub gv_or_padgv {
3292     my $self = shift;
3293     my $op = shift;
3294     if (class($op) eq "PADOP") {
3295         return $self->padval($op->padix);
3296     } else { # class($op) eq "SVOP"
3297         return $op->gv;
3298     }
3299 }
3300
3301 sub pp_gvsv {
3302     my $self = shift;
3303     my($op, $cx) = @_;
3304     my $gv = $self->gv_or_padgv($op);
3305     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
3306                                  $self->gv_name($gv), $cx));
3307 }
3308
3309 sub pp_gv {
3310     my $self = shift;
3311     my($op, $cx) = @_;
3312     my $gv = $self->gv_or_padgv($op);
3313     return $self->gv_name($gv);
3314 }
3315
3316 sub pp_aelemfast_lex {
3317     my $self = shift;
3318     my($op, $cx) = @_;
3319     my $name = $self->padname($op->targ);
3320     $name =~ s/^@/\$/;
3321     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
3322 }
3323
3324 sub pp_aelemfast {
3325     my $self = shift;
3326     my($op, $cx) = @_;
3327     # optimised PADAV, pre 5.15
3328     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
3329
3330     my $gv = $self->gv_or_padgv($op);
3331     my($name,$quoted) = $self->stash_variable_name('@',$gv);
3332     $name = $quoted ? "$name->" : '$' . $name;
3333     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
3334 }
3335
3336 sub rv2x {
3337     my $self = shift;
3338     my($op, $cx, $type) = @_;
3339
3340     if (class($op) eq 'NULL' || !$op->can("first")) {
3341         carp("Unexpected op in pp_rv2x");
3342         return 'XXX';
3343     }
3344     my $kid = $op->first;
3345     if ($kid->name eq "gv") {
3346         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3347     } elsif (is_scalar $kid) {
3348         my $str = $self->deparse($kid, 0);
3349         if ($str =~ /^\$([^\w\d])\z/) {
3350             # "$$+" isn't a legal way to write the scalar dereference
3351             # of $+, since the lexer can't tell you aren't trying to
3352             # do something like "$$ + 1" to get one more than your
3353             # PID. Either "${$+}" or "$${+}" are workable
3354             # disambiguations, but if the programmer did the former,
3355             # they'd be in the "else" clause below rather than here.
3356             # It's not clear if this should somehow be unified with
3357             # the code in dq and re_dq that also adds lexer
3358             # disambiguation braces.
3359             $str = '$' . "{$1}"; #'
3360         }
3361         return $type . $str;
3362     } else {
3363         return $type . "{" . $self->deparse($kid, 0) . "}";
3364     }
3365 }
3366
3367 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3368 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3369 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3370
3371 # skip rv2av
3372 sub pp_av2arylen {
3373     my $self = shift;
3374     my($op, $cx) = @_;
3375     if ($op->first->name eq "padav") {
3376         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3377     } else {
3378         return $self->maybe_local($op, $cx,
3379                                   $self->rv2x($op->first, $cx, '$#'));
3380     }
3381 }
3382
3383 # skip down to the old, ex-rv2cv
3384 sub pp_rv2cv {
3385     my ($self, $op, $cx) = @_;
3386     if (!null($op->first) && $op->first->name eq 'null' &&
3387         $op->first->targ eq OP_LIST)
3388     {
3389         return $self->rv2x($op->first->first->sibling, $cx, "&")
3390     }
3391     else {
3392         return $self->rv2x($op, $cx, "")
3393     }
3394 }
3395
3396 sub list_const {
3397     my $self = shift;
3398     my($cx, @list) = @_;
3399     my @a = map $self->const($_, 6), @list;
3400     if (@a == 0) {
3401         return "()";
3402     } elsif (@a == 1) {
3403         return $a[0];
3404     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3405         # collapse (-1,0,1,2) into (-1..2)
3406         my ($s, $e) = @a[0,-1];
3407         my $i = $s;
3408         return $self->maybe_parens("$s..$e", $cx, 9)
3409           unless grep $i++ != $_, @a;
3410     }
3411     return $self->maybe_parens(join(", ", @a), $cx, 6);
3412 }
3413
3414 sub pp_rv2av {
3415     my $self = shift;
3416     my($op, $cx) = @_;
3417     my $kid = $op->first;
3418     if ($kid->name eq "const") { # constant list
3419         my $av = $self->const_sv($kid);
3420         return $self->list_const($cx, $av->ARRAY);
3421     } else {
3422         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3423     }
3424  }
3425
3426 sub is_subscriptable {
3427     my $op = shift;
3428     if ($op->name =~ /^[ahg]elem/) {
3429         return 1;
3430     } elsif ($op->name eq "entersub") {
3431         my $kid = $op->first;
3432         return 0 unless null $kid->sibling;
3433         $kid = $kid->first;
3434         $kid = $kid->sibling until null $kid->sibling;
3435         return 0 if is_scope($kid);
3436         $kid = $kid->first;
3437         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
3438         return 0 if is_scalar($kid);
3439         return is_subscriptable($kid);  
3440     } else {
3441         return 0;
3442     }
3443 }
3444
3445 sub elem_or_slice_array_name
3446 {
3447     my $self = shift;
3448     my ($array, $left, $padname, $allow_arrow) = @_;
3449
3450     if ($array->name eq $padname) {
3451         return $self->padany($array);
3452     } elsif (is_scope($array)) { # ${expr}[0]
3453         return "{" . $self->deparse($array, 0) . "}";
3454     } elsif ($array->name eq "gv") {
3455         ($array, my $quoted) =
3456             $self->stash_variable_name(
3457                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
3458             );
3459         if (!$allow_arrow && $quoted) {
3460             # This cannot happen.
3461             die "Invalid variable name $array for slice";
3462         }
3463         return $quoted ? "$array->" : $array;
3464     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3465         return $self->deparse($array, 24);
3466     } else {
3467         return undef;
3468     }
3469 }
3470
3471 sub elem_or_slice_single_index
3472 {
3473     my $self = shift;
3474     my ($idx) = @_;
3475
3476     $idx = $self->deparse($idx, 1);
3477
3478     # Outer parens in an array index will confuse perl
3479     # if we're interpolating in a regular expression, i.e.
3480     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3481     #
3482     # If $self->{parens}, then an initial '(' will
3483     # definitely be paired with a final ')'. If
3484     # !$self->{parens}, the misleading parens won't
3485     # have been added in the first place.
3486     #
3487     # [You might think that we could get "(...)...(...)"
3488     # where the initial and final parens do not match
3489     # each other. But we can't, because the above would
3490     # only happen if there's an infix binop between the
3491     # two pairs of parens, and *that* means that the whole
3492     # expression would be parenthesized as well.]
3493     #
3494     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3495
3496     # Hash-element braces will autoquote a bareword inside themselves.
3497     # We need to make sure that C<$hash{warn()}> doesn't come out as
3498     # C<$hash{warn}>, which has a quite different meaning. Currently
3499     # B::Deparse will always quote strings, even if the string was a
3500     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3501     # for constant strings.) So we can cheat slightly here - if we see
3502     # a bareword, we know that it is supposed to be a function call.
3503     #
3504     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3505
3506     return $idx;
3507 }
3508
3509 sub elem {
3510     my $self = shift;
3511     my ($op, $cx, $left, $right, $padname) = @_;
3512     my($array, $idx) = ($op->first, $op->first->sibling);
3513
3514     $idx = $self->elem_or_slice_single_index($idx);
3515
3516     unless ($array->name eq $padname) { # Maybe this has been fixed     
3517         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3518     }
3519     if (my $array_name=$self->elem_or_slice_array_name
3520             ($array, $left, $padname, 1)) {
3521         return ($array_name =~ /->\z/
3522                     ? $array_name
3523                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
3524               . $left . $idx . $right;
3525     } else {
3526         # $x[20][3]{hi} or expr->[20]
3527         my $arrow = is_subscriptable($array) ? "" : "->";
3528         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3529     }
3530
3531 }
3532
3533 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3534 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3535
3536 sub pp_gelem {
3537     my $self = shift;
3538     my($op, $cx) = @_;
3539     my($glob, $part) = ($op->first, $op->last);
3540     $glob = $glob->first; # skip rv2gv
3541     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3542     my $scope = is_scope($glob);
3543     $glob = $self->deparse($glob, 0);
3544     $part = $self->deparse($part, 1);
3545     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3546 }
3547
3548 sub slice {
3549     my $self = shift;
3550     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3551     my $last;
3552     my(@elems, $kid, $array, $list);
3553     if (class($op) eq "LISTOP") {
3554         $last = $op->last;
3555     } else { # ex-hslice inside delete()
3556         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3557         $last = $kid;
3558     }
3559     $array = $last;
3560     $array = $array->first
3561         if $array->name eq $regname or $array->name eq "null";
3562     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3563     $kid = $op->first->sibling; # skip pushmark
3564     if ($kid->name eq "list") {
3565         $kid = $kid->first->sibling; # skip list, pushmark
3566         for (; !null $kid; $kid = $kid->sibling) {
3567             push @elems, $self->deparse($kid, 6);
3568         }
3569         $list = join(", ", @elems);
3570     } else {
3571         $list = $self->elem_or_slice_single_index($kid);
3572     }
3573     my $lead = '@';
3574     $lead = '%' if $op->name =~ /^kv/i;
3575     return $lead . $array . $left . $list . $right;
3576 }
3577
3578 sub pp_aslice   { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3579 sub pp_kvaslice {                 slice(@_, "[", "]", "rv2av", "padav")  }
3580 sub pp_hslice   { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3581 sub pp_kvhslice {                 slice(@_, "{", "}", "rv2hv", "padhv")  }
3582
3583 sub pp_lslice {
3584     my $self = shift;
3585     my($op, $cx) = @_;
3586     my $idx = $op->first;
3587     my $list = $op->last;
3588     my(@elems, $kid);
3589     $list = $self->deparse($list, 1);
3590     $idx = $self->deparse($idx, 1);
3591     return "($list)" . "[$idx]";
3592 }
3593
3594 sub want_scalar {
3595     my $op = shift;
3596     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3597 }
3598
3599 sub want_list {
3600     my $op = shift;
3601     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3602 }
3603
3604 sub _method {
3605     my $self = shift;
3606     my($op, $cx) = @_;
3607     my $kid = $op->first->sibling; # skip pushmark
3608     my($meth, $obj, @exprs);
3609     if ($kid->name eq "list" and want_list $kid) {
3610         # When an indirect object isn't a bareword but the args are in
3611         # parens, the parens aren't part of the method syntax (the LLAFR
3612         # doesn't apply), but they make a list with OPf_PARENS set that
3613         # doesn't get flattened by the append_elem that adds the method,
3614         # making a (object, arg1, arg2, ...) list where the object
3615         # usually is. This can be distinguished from
3616         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3617         # object) because in the later the list is in scalar context
3618         # as the left side of -> always is, while in the former
3619         # the list is in list context as method arguments always are.
3620         # (Good thing there aren't method prototypes!)
3621         $meth = $kid->sibling;
3622         $kid = $kid->first->sibling; # skip pushmark
3623         $obj = $kid;
3624         $kid = $kid->sibling;
3625         for (; not null $kid; $kid = $kid->sibling) {
3626             push @exprs, $kid;
3627         }
3628     } else {
3629         $obj = $kid;
3630         $kid = $kid->sibling;
3631         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3632               $kid = $kid->sibling) {
3633             push @exprs, $kid
3634         }
3635         $meth = $kid;
3636     }
3637
3638     if ($meth->name eq "method_named") {
3639         $meth = $self->const_sv($meth)->PV;
3640     } else {
3641         $meth = $meth->first;
3642         if ($meth->name eq "const") {
3643             # As of 5.005_58, this case is probably obsoleted by the
3644             # method_named case above
3645             $meth = $self->const_sv($meth)->PV; # needs to be bare
3646         }
3647     }
3648
3649     return { method => $meth, variable_method => ref($meth),
3650              object => $obj, args => \@exprs  },
3651            $cx;
3652 }
3653
3654 # compat function only
3655 sub method {
3656     my $self = shift;
3657     my $info = $self->_method(@_);
3658     return $self->e_method( $self->_method(@_) );
3659 }
3660
3661 sub e_method {
3662     my ($self, $info, $cx) = @_;
3663     my $obj = $self->deparse($info->{object}, 24);
3664
3665     my $meth = $info->{method};
3666     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3667     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3668     if ($info->{object}->name eq 'scope' && want_list $info->{object}) {
3669         # method { $object }
3670         # This must be deparsed this way to preserve list context
3671         # of $object.
3672         my $need_paren = $cx >= 6;
3673         return '(' x $need_paren
3674              . $meth . substr($obj,2) # chop off the "do"
3675              . " $args"
3676              . ')' x $need_paren;
3677     }
3678     my $kid = $obj . "->" . $meth;
3679     if (length $args) {
3680         return $kid . "(" . $args . ")"; # parens mandatory
3681     } else {
3682         return $kid;
3683     }
3684 }
3685
3686 # returns "&" if the prototype doesn't match the args,
3687 # or ("", $args_after_prototype_demunging) if it does.
3688 sub check_proto {
3689     my $self = shift;
3690     return "&" if $self->{'noproto'};
3691     my($proto, @args) = @_;
3692     my($arg, $real);
3693     my $doneok = 0;
3694     my @reals;
3695     # An unbackslashed @ or % gobbles up the rest of the args
3696     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3697     while ($proto) {
3698         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3699         my $chr = $1;
3700         if ($chr eq "") {
3701             return "&" if @args;
3702         } elsif ($chr eq ";") {
3703             $doneok = 1;
3704         } elsif ($chr eq "@" or $chr eq "%") {
3705             push @reals, map($self->deparse($_, 6), @args);
3706             @args = ();
3707         } else {
3708             $arg = shift @args;
3709             last unless $arg;
3710             if ($chr eq "\$" || $chr eq "_") {
3711                 if (want_scalar $arg) {
3712                     push @reals, $self->deparse($arg, 6);
3713                 } else {
3714                     return "&";
3715                 }
3716             } elsif ($chr eq "&") {
3717                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3718                     push @reals, $self->deparse($arg, 6);
3719                 } else {
3720                     return "&";
3721                 }
3722             } elsif ($chr eq "*") {
3723                 if ($arg->name =~ /^s?refgen$/
3724                     and $arg->first->first->name eq "rv2gv")
3725                   {
3726                       $real = $arg->first->first; # skip refgen, null
3727                       if ($real->first->name eq "gv") {
3728                           push @reals, $self->deparse($real, 6);
3729                       } else {
3730                           push @reals, $self->deparse($real->first, 6);
3731                       }
3732                   } else {
3733                       return "&";
3734                   }
3735             } elsif (substr($chr, 0, 1) eq "\\") {
3736                 $chr =~ tr/\\[]//d;
3737                 if ($arg->name =~ /^s?refgen$/ and
3738                     !null($real = $arg->first) and
3739                     ($chr =~ /\$/ && is_scalar($real->first)
3740                      or ($chr =~ /@/
3741                          && class($real->first->sibling) ne 'NULL'
3742                          && $real->first->sibling->name
3743                          =~ /^(rv2|pad)av$/)
3744                      or ($chr =~ /%/
3745                          && class($real->first->sibling) ne 'NULL'
3746                          && $real->first->sibling->name
3747                          =~ /^(rv2|pad)hv$/)
3748                      #or ($chr =~ /&/ # This doesn't work
3749                      #   && $real->first->name eq "rv2cv")
3750                      or ($chr =~ /\*/
3751                          && $real->first->name eq "rv2gv")))
3752                   {
3753                       push @reals, $self->deparse($real, 6);
3754                   } else {
3755                       return "&";
3756                   }
3757             }
3758        }
3759     }
3760     return "&" if $proto and !$doneok; # too few args and no ';'
3761     return "&" if @args;               # too many args
3762     return ("", join ", ", @reals);
3763 }
3764
3765 sub pp_entersub {
3766     my $self = shift;
3767     my($op, $cx) = @_;
3768     return $self->e_method($self->_method($op, $cx))
3769         unless null $op->first->sibling;
3770     my $prefix = "";
3771     my $amper = "";
3772     my($kid, @exprs);
3773     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3774         $prefix = "do ";
3775     } elsif ($op->private & OPpENTERSUB_AMPER) {
3776         $amper = "&";
3777     }
3778     $kid = $op->first;
3779     $kid = $kid->first->sibling; # skip ex-list, pushmark
3780     for (; not null $kid->sibling; $kid = $kid->sibling) {
3781         push @exprs, $kid;
3782     }
3783     my $simple = 0;
3784     my $proto = undef;
3785     if (is_scope($kid)) {
3786         $amper = "&";
3787         $kid = "{" . $self->deparse($kid, 0) . "}";
3788     } elsif ($kid->first->name eq "gv") {
3789         my $gv = $self->gv_or_padgv($kid->first);
3790         if (class($gv->CV) ne "SPECIAL") {
3791             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3792         }
3793         $simple = 1; # only calls of named functions can be prototyped
3794         $kid = $self->deparse($kid, 24);
3795         if (!$amper) {
3796             if ($kid eq 'main::') {
3797                 $kid = '::';
3798             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3799                 $kid = single_delim("q", "'", $kid) . '->';
3800             }
3801         }
3802     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3803         $amper = "&";
3804         $kid = $self->deparse($kid, 24);
3805     } else {
3806         $prefix = "";
3807         my $arrow = is_subscriptable($kid->first) || $kid->first->name eq "padcv" ? "" : "->";
3808         $kid = $self->deparse($kid, 24) . $arrow;
3809     }
3810
3811     # Doesn't matter how many prototypes there are, if
3812     # they haven't happened yet!
3813     my $declared;
3814     {
3815         no strict 'refs';
3816         no warnings 'uninitialized';
3817         $declared = exists $self->{'subs_declared'}{$kid}
3818             || (
3819                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3820                  && !exists
3821                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3822                  && defined prototype $self->{'curstash'}."::".$kid
3823                );
3824         if (!$declared && defined($proto)) {
3825             # Avoid "too early to check prototype" warning
3826             ($amper, $proto) = ('&');
3827         }
3828     }
3829
3830     my $args;
3831     if ($declared and defined $proto and not $amper) {
3832         ($amper, $args) = $self->check_proto($proto, @exprs);
3833         if ($amper eq "&") {
3834             $args = join(", ", map($self->deparse($_, 6), @exprs));
3835         }
3836     } else {
3837         $args = join(", ", map($self->deparse($_, 6), @exprs));
3838     }
3839     if ($prefix or $amper) {
3840         if ($kid eq '&') { $kid = "{$kid}" } # &{&} cannot be written as &&
3841         if ($op->flags & OPf_STACKED) {
3842             return $prefix . $amper . $kid . "(" . $args . ")";
3843         } else {
3844             return $prefix . $amper. $kid;
3845         }
3846     } else {
3847         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3848         # so it must have been translated from a keyword call. Translate
3849         # it back.
3850         $kid =~ s/^CORE::GLOBAL:://;
3851
3852         my $dproto = defined($proto) ? $proto : "undefined";
3853         if (!$declared) {
3854             return "$kid(" . $args . ")";
3855         } elsif ($dproto eq "") {
3856             return $kid;
3857         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3858             # is_scalar is an excessively conservative test here:
3859             # really, we should be comparing to the precedence of the
3860             # top operator of $exprs[0] (ala unop()), but that would
3861             # take some major code restructuring to do right.
3862             return $self->maybe_parens_func($kid, $args, $cx, 16);
3863         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3864             return $self->maybe_parens_func($kid, $args, $cx, 5);
3865         } else {
3866             return "$kid(" . $args . ")";
3867         }
3868     }
3869 }
3870
3871 sub pp_enterwrite { unop(@_, "write") }
3872
3873 # escape things that cause interpolation in double quotes,
3874 # but not character escapes
3875 sub uninterp {
3876     my($str) = @_;
3877     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3878     return $str;
3879 }
3880
3881 {
3882 my $bal;
3883 BEGIN {
3884     use re "eval";
3885     # Matches any string which is balanced with respect to {braces}
3886     $bal = qr(
3887       (?:
3888         [^\\{}]
3889       | \\\\
3890       | \\[{}]
3891       | \{(??{$bal})\}
3892       )*
3893     )x;
3894 }
3895
3896 # the same, but treat $|, $), $( and $ at the end of the string differently
3897 sub re_uninterp {
3898     my($str) = @_;
3899
3900     $str =~ s/
3901           ( ^|\G                  # $1
3902           | [^\\]
3903           )
3904
3905           (                       # $2
3906             (?:\\\\)*
3907           )
3908
3909           (                       # $3
3910             (\(\?\??\{$bal\}\))   # $4
3911           | [\$\@]
3912             (?!\||\)|\(|$)
3913           | \\[uUlLQE]
3914           )
3915
3916         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3917
3918     return $str;
3919 }
3920
3921 # This is for regular expressions with the /x modifier
3922 # We have to leave comments unmangled.
3923 sub re_uninterp_extended {
3924     my($str) = @_;
3925
3926     $str =~ s/
3927           ( ^|\G                  # $1
3928           | [^\\]
3929           )
3930
3931           (                       # $2
3932             (?:\\\\)*
3933           )
3934
3935           (                       # $3
3936             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3937             | \#[^\n]*            #     (skip over comments)
3938             )
3939           | [\$\@]
3940             (?!\||\)|\(|$|\s)
3941           | \\[uUlLQE]
3942           )
3943
3944         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3945
3946     return $str;
3947 }
3948 }
3949
3950 my %unctrl = # portable to EBCDIC
3951     (
3952      "\c@" => '\c@',    # unused
3953      "\cA" => '\cA',
3954      "\cB" => '\cB',
3955      "\cC" => '\cC',
3956      "\cD" => '\cD',
3957      "\cE" => '\cE',
3958      "\cF" => '\cF',
3959      "\cG" => '\cG',
3960      "\cH" => '\cH',
3961      "\cI" => '\cI',
3962      "\cJ" => '\cJ',
3963      "\cK" => '\cK',
3964      "\cL" => '\cL',
3965      "\cM" => '\cM',
3966      "\cN" => '\cN',
3967      "\cO" => '\cO',
3968      "\cP" => '\cP',
3969      "\cQ" => '\cQ',
3970      "\cR" => '\cR',
3971      "\cS" => '\cS',
3972      "\cT" => '\cT',
3973      "\cU" => '\cU',
3974      "\cV" => '\cV',
3975      "\cW" => '\cW',
3976      "\cX" => '\cX',
3977      "\cY" => '\cY',
3978      "\cZ" => '\cZ',
3979      "\c[" => '\c[',    # unused
3980      "\c\\" => '\c\\',  # unused
3981      "\c]" => '\c]',    # unused
3982      "\c_" => '\c_',    # unused
3983     );
3984
3985 # character escapes, but not delimiters that might need to be escaped
3986 sub escape_str { # ASCII, UTF8
3987     my($str) = @_;
3988     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3989     $str =~ s/\a/\\a/g;
3990 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3991     $str =~ s/\t/\\t/g;
3992     $str =~ s/\n/\\n/g;
3993     $str =~ s/\e/\\e/g;
3994     $str =~ s/\f/\\f/g;
3995     $str =~ s/\r/\\r/g;
3996     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3997     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3998     return $str;
3999 }
4000
4001 # For regexes with the /x modifier.
4002 # Leave whitespace unmangled.
4003 sub escape_extended_re {
4004     my($str) = @_;
4005     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4006     $str =~ s/([[:^print:]])/
4007         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
4008     $str =~ s/\n/\n\f/g;
4009     return $str;
4010 }
4011
4012 # Don't do this for regexen
4013 sub unback {
4014     my($str) = @_;
4015     $str =~ s/\\/\\\\/g;
4016     return $str;
4017 }
4018
4019 # Remove backslashes which precede literal control characters,
4020 # to avoid creating ambiguity when we escape the latter.
4021 sub re_unback {
4022     my($str) = @_;
4023
4024     # the insane complexity here is due to the behaviour of "\c\"
4025     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
4026     return $str;
4027 }
4028
4029 sub balanced_delim {
4030     my($str) = @_;
4031     my @str = split //, $str;
4032     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
4033     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
4034         ($open, $close) = @$ar;
4035         $fail = 0; $cnt = 0; $last_bs = 0;
4036         for $c (@str) {
4037             if ($c eq $open) {
4038                 $fail = 1 if $last_bs;
4039                 $cnt++;
4040             } elsif ($c eq $close) {
4041                 $fail = 1 if $last_bs;
4042                 $cnt--;
4043                 if ($cnt < 0) {
4044                     # qq()() isn't ")("
4045                     $fail = 1;
4046                     last;
4047                 }
4048             }
4049             $last_bs = $c eq '\\';
4050         }
4051         $fail = 1 if $cnt != 0;
4052         return ($open, "$open$str$close") if not $fail;
4053     }
4054     return ("", $str);
4055 }
4056
4057 sub single_delim {
4058     my($q, $default, $str) = @_;
4059     return "$default$str$default" if $default and index($str, $default) == -1;
4060     if ($q ne 'qr') {
4061         (my $succeed, $str) = balanced_delim($str);
4062         return "$q$str" if $succeed;
4063     }
4064     for my $delim ('/', '"', '#') {
4065         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
4066     }
4067     if ($default) {
4068         $str =~ s/$default/\\$default/g;
4069         return "$default$str$default";
4070     } else {
4071         $str =~ s[/][\\/]g;
4072         return "$q/$str/";
4073     }
4074 }
4075
4076 my $max_prec;
4077 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
4078
4079 # Split a floating point number into an integer mantissa and a binary
4080 # exponent. Assumes you've already made sure the number isn't zero or
4081 # some weird infinity or NaN.
4082 sub split_float {
4083     my($f) = @_;
4084     my $exponent = 0;
4085     if ($f == int($f)) {
4086         while ($f % 2 == 0) {
4087             $f /= 2;
4088             $exponent++;
4089         }
4090     } else {
4091         while ($f != int($f)) {
4092             $f *= 2;
4093             $exponent--;
4094         }
4095     }
4096     my $mantissa = sprintf("%.0f", $f);
4097     return ($mantissa, $exponent);
4098 }
4099
4100 sub const {
4101     my $self = shift;
4102     my($sv, $cx) = @_;
4103     if ($self->{'use_dumper'}) {
4104         return $self->const_dumper($sv, $cx);
4105     }
4106     if (class($sv) eq "SPECIAL") {
4107         # sv_undef, sv_yes, sv_no
4108         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
4109     }
4110     if (class($sv) eq "NULL") {
4111        return 'undef';
4112     }
4113     # convert a version object into the "v1.2.3" string in its V magic
4114     if ($sv->FLAGS & SVs_RMG) {
4115         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4116             return $mg->PTR if $mg->TYPE eq 'V';
4117         }
4118     }
4119
4120     if ($sv->FLAGS & SVf_IOK) {
4121         my $str = $sv->int_value;
4122         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
4123         return $str;
4124     } elsif ($sv->FLAGS & SVf_NOK) {
4125         my $nv = $sv->NV;
4126         if ($nv == 0) {
4127             if (pack("F", $nv) eq pack("F", 0)) {
4128                 # positive zero
4129                 return "0";
4130             } else {
4131                 # negative zero
4132                 return $self->maybe_parens("-.0", $cx, 21);
4133             }
4134         } elsif (1/$nv == 0) {
4135             if ($nv > 0) {
4136                 # positive infinity
4137                 return $self->maybe_parens("9**9**9", $cx, 22);
4138             } else {
4139                 # negative infinity
4140                 return $self->maybe_parens("-9**9**9", $cx, 21);
4141             }
4142         } elsif ($nv != $nv) {
4143             # NaN
4144             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
4145                 # the normal kind
4146                 return "sin(9**9**9)";
4147             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
4148                 # the inverted kind
4149                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
4150             } else {
4151                 # some other kind
4152                 my $hex = unpack("h*", pack("F", $nv));
4153                 return qq'unpack("F", pack("h*", "$hex"))';
4154             }
4155         }
4156         # first, try the default stringification
4157         my $str = "$nv";
4158         if ($str != $nv) {
4159             # failing that, try using more precision
4160             $str = sprintf("%.${max_prec}g", $nv);
4161 #           if (pack("F", $str) ne pack("F", $nv)) {
4162             if ($str != $nv) {
4163                 # not representable in decimal with whatever sprintf()
4164                 # and atof() Perl is using here.
4165                 my($mant, $exp) = split_float($nv);
4166                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
4167             }
4168         }
4169         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
4170         return $str;
4171     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
4172         my $ref = $sv->RV;
4173         if (class($ref) eq "AV") {
4174             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
4175         } elsif (class($ref) eq "HV") {
4176             my %hash = $ref->ARRAY;
4177             my @elts;
4178             for my $k (sort keys %hash) {
4179                 push @elts, "$k => " . $self->const($hash{$k}, 6);
4180             }
4181             return "{" . join(", ", @elts) . "}";
4182         } elsif (class($ref) eq "CV") {
4183             BEGIN {
4184                 if ($] > 5.0150051) {
4185                     require overloading;
4186                     unimport overloading;
4187                 }
4188             }
4189             if ($] > 5.0150051 && $self->{curcv} &&
4190                  $self->{curcv}->object_2svref == $ref->object_2svref) {
4191                 return $self->keyword("__SUB__");
4192             }
4193             return "sub " . $self->deparse_sub($ref);
4194         }
4195         if ($ref->FLAGS & SVs_SMG) {
4196             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4197                 if ($mg->TYPE eq 'r') {
4198                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
4199                     return single_delim("qr", "", $re);
4200                 }
4201             }
4202         }
4203         
4204         my $const = $self->const($ref, 20);
4205         if ($self->{in_subst_repl} && $const =~ /^[0-9]/) {
4206             $const = "($const)";
4207         }
4208         return $self->maybe_parens("\\$const", $cx, 20);
4209     } elsif ($sv->FLAGS & SVf_POK) {
4210         my $str = $sv->PV;
4211         if ($str =~ /[[:^print:]]/) {
4212             return single_delim("qq", '"', uninterp escape_str unback $str);
4213         } else {
4214             return single_delim("q", "'", unback $str);
4215         }
4216     } else {
4217         return "undef";
4218     }
4219 }
4220
4221 sub const_dumper {
4222     my $self = shift;
4223     my($sv, $cx) = @_;
4224     my $ref = $sv->object_2svref();
4225     my $dumper = Data::Dumper->new([$$ref], ['$v']);
4226     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
4227     my $str = $dumper->Dump();
4228     if ($str =~ /^\$v/) {
4229         return '${my ' . $str . ' \$v}';
4230     } else {
4231         return $str;
4232     }
4233 }
4234
4235 sub const_sv {
4236     my $self = shift;
4237     my $op = shift;
4238     my $sv = $op->sv;
4239     # the constant could be in the pad (under useithreads)
4240     $sv = $self->padval($op->targ) unless $$sv;
4241     return $sv;
4242 }
4243
4244 sub pp_const {
4245     my $self = shift;
4246     my($op, $cx) = @_;
4247     if ($op->private & OPpCONST_ARYBASE) {
4248         return '$[';
4249     }
4250 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
4251 #       return $self->const_sv($op)->PV;
4252 #    }
4253     my $sv = $self->const_sv($op);
4254     return $self->const($sv, $cx);
4255 }
4256
4257 sub dq {
4258     my $self = shift;
4259     my $op = shift;
4260     my $type = $op->name;
4261     if ($type eq "const") {
4262         return '$[' if $op->private & OPpCONST_ARYBASE;
4263         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
4264     } elsif ($type eq "concat") {
4265         my $first = $self->dq($op->first);
4266         my $last  = $self->dq($op->last);
4267
4268         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
4269         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4270             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4271             || ($last =~ /^[:'{\[\w_]/ && #'
4272                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4273
4274         return $first . $last;
4275     } elsif ($type eq "uc") {
4276         return '\U' . $self->dq($op->first->sibling) . '\E';
4277     } elsif ($type eq "lc") {
4278         return '\L' . $self->dq($op->first->sibling) . '\E';
4279     } elsif ($type eq "ucfirst") {
4280         return '\u' . $self->dq($op->first->sibling);
4281     } elsif ($type eq "lcfirst") {
4282         return '\l' . $self->dq($op->first->sibling);
4283     } elsif ($type eq "quotemeta") {
4284         return '\Q' . $self->dq($op->first->sibling) . '\E';
4285     } elsif ($type eq "fc") {
4286         return '\F' . $self->dq($op->first->sibling) . '\E';
4287     } elsif ($type eq "join") {
4288         return $self->deparse($op->last, 26); # was join($", @ary)
4289     } else {
4290         return $self->deparse($op, 26);
4291     }
4292 }
4293
4294 sub pp_backtick {
4295     my $self = shift;
4296     my($op, $cx) = @_;
4297     # skip pushmark if it exists (readpipe() vs ``)
4298     my $child = $op->first->sibling->isa('B::NULL')
4299         ? $op->first : $op->first->sibling;
4300     if ($self->pure_string($child)) {
4301         return single_delim("qx", '`', $self->dq($child, 1));
4302     }
4303     unop($self, @_, "readpipe");
4304 }
4305
4306 sub dquote {
4307     my $self = shift;
4308     my($op, $cx) = @_;
4309     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
4310     return $self->deparse($kid, $cx) if $self->{'unquote'};
4311     $self->maybe_targmy($kid, $cx,
4312                         sub {single_delim("qq", '"', $self->dq($_[1]))});
4313 }
4314
4315 # OP_STRINGIFY is a listop, but it only ever has one arg
4316 sub pp_stringify { maybe_targmy(@_, \&dquote) }
4317
4318 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
4319 # note that tr(from)/to/ is OK, but not tr/from/(to)
4320 sub double_delim {
4321     my($from, $to) = @_;
4322     my($succeed, $delim);
4323     if ($from !~ m[/] and $to !~ m[/]) {
4324         return "/$from/$to/";
4325     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
4326         if (($succeed, $to) = balanced_delim($to) and $succeed) {
4327             return "$from$to";
4328         } else {
4329             for $delim ('/', '"', '#') { # note no "'" -- s''' is special
4330                 return "$from$delim$to$delim" if index($to, $delim) == -1;
4331             }
4332             $to =~ s[/][\\/]g;
4333             return "$from/$to/";
4334         }
4335     } else {
4336         for $delim ('/', '"', '#') { # note no '
4337             return "$delim$from$delim$to$delim"
4338                 if index($to . $from, $delim) == -1;
4339         }
4340         $from =~ s[/][\\/]g;
4341         $to =~ s[/][\\/]g;
4342         return "/$from/$to/";   
4343     }
4344 }
4345
4346 # Only used by tr///, so backslashes hyphens
4347 sub pchr { # ASCII
4348     my($n) = @_;
4349     if ($n == ord '\\') {
4350         return '\\\\';
4351     } elsif ($n == ord "-") {
4352         return "\\-";
4353     } elsif ($n >= ord(' ') and $n <= ord('~')) {
4354         return chr($n);
4355     } elsif ($n == ord "\a") {
4356         return '\\a';
4357     } elsif ($n == ord "\b") {
4358         return '\\b';
4359     } elsif ($n == ord "\t") {
4360         return '\\t';
4361     } elsif ($n == ord "\n") {
4362         return '\\n';
4363     } elsif ($n == ord "\e") {
4364         return '\\e';
4365     } elsif ($n == ord "\f") {
4366         return '\\f';
4367     } elsif ($n == ord "\r") {
4368         return '\\r';
4369     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
4370         return '\\c' . chr(ord("@") + $n);
4371     } else {
4372 #       return '\x' . sprintf("%02x", $n);
4373         return '\\' . sprintf("%03o", $n);
4374     }
4375 }
4376
4377 sub collapse {
4378     my(@chars) = @_;
4379     my($str, $c, $tr) = ("");
4380     for ($c = 0; $c < @chars; $c++) {
4381         $tr = $chars[$c];
4382         $str .= pchr($tr);
4383         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
4384             $chars[$c + 2] == $tr + 2)
4385         {
4386             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
4387               {}
4388             $str .= "-";
4389             $str .= pchr($chars[$c]);
4390         }
4391     }
4392     return $str;
4393 }
4394
4395 sub tr_decode_byte {
4396     my($table, $flags) = @_;
4397     my(@table) = unpack("s*", $table);
4398     splice @table, 0x100, 1;   # Number of subsequent elements
4399     my($c, $tr, @from, @to, @delfrom, $delhyphen);
4400     if ($table[ord "-"] != -1 and
4401         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
4402     {
4403         $tr = $table[ord "-"];
4404         $table[ord "-"] = -1;
4405         if ($tr >= 0) {
4406             @from = ord("-");
4407             @to = $tr;
4408         } else { # -2 ==> delete
4409             $delhyphen = 1;
4410         }
4411     }
4412     for ($c = 0; $c < @table; $c++) {
4413         $tr = $table[$c];
4414         if ($tr >= 0) {
4415             push @from, $c; push @to, $tr;
4416         } elsif ($tr == -2) {
4417             push @delfrom, $c;
4418         }
4419     }
4420     @from = (@from, @delfrom);
4421     if ($flags & OPpTRANS_COMPLEMENT) {
4422         my @newfrom = ();
4423         my %from;
4424         @from{@from} = (1) x @from;
4425         for ($c = 0; $c < 256; $c++) {
4426             push @newfrom, $c unless $from{$c};
4427         }
4428         @from = @newfrom;
4429     }
4430     unless ($flags & OPpTRANS_DELETE || !@to) {
4431         pop @to while $#to and $to[$#to] == $to[$#to -1];
4432     }
4433     my($from, $to);
4434     $from = collapse(@from);
4435     $to = collapse(@to);
4436     $from .= "-" if $delhyphen;
4437     return ($from, $to);
4438 }
4439
4440 sub tr_chr {
4441     my $x = shift;
4442     if ($x == ord "-") {
4443         return "\\-";
4444     } elsif ($x == ord "\\") {
4445         return "\\\\";
4446     } else {
4447         return chr $x;
4448     }
4449 }
4450
4451 # XXX This doesn't yet handle all cases correctly either
4452
4453 sub tr_decode_utf8 {
4454     my($swash_hv, $flags) = @_;
4455     my %swash = $swash_hv->ARRAY;
4456     my $final = undef;
4457     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4458     my $none = $swash{"NONE"}->IV;
4459     my $extra = $none + 1;
4460     my(@from, @delfrom, @to);
4461     my $line;
4462     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4463         my($min, $max, $result) = split(/\t/, $line);
4464         $min = hex $min;
4465         if (length $max) {
4466             $max = hex $max;
4467         } else {
4468             $max = $min;
4469         }
4470         $result = hex $result;
4471         if ($result == $extra) {
4472             push @delfrom, [$min, $max];
4473         } else {
4474             push @from, [$min, $max];
4475             push @to, [$result, $result + $max - $min];
4476         }
4477     }
4478     for my $i (0 .. $#from) {
4479         if ($from[$i][0] == ord '-') {
4480             unshift @from, splice(@from, $i, 1);
4481             unshift @to, splice(@to, $i, 1);
4482             last;
4483         } elsif ($from[$i][1] == ord '-') {
4484             $from[$i][1]--;
4485             $to[$i][1]--;
4486             unshift @from, ord '-';
4487             unshift @to, ord '-';
4488             last;
4489         }
4490     }
4491     for my $i (0 .. $#delfrom) {
4492         if ($delfrom[$i][0] == ord '-') {
4493             push @delfrom, splice(@delfrom, $i, 1);
4494             last;
4495         } elsif ($delfrom[$i][1] == ord '-') {
4496             $delfrom[$i][1]--;
4497             push @delfrom, ord '-';
4498             last;
4499         }
4500     }
4501     if (defined $final and $to[$#to][1] != $final) {
4502         push @to, [$final, $final];
4503     }
4504     push @from, @delfrom;
4505     if ($flags & OPpTRANS_COMPLEMENT) {
4506         my @newfrom;
4507         my $next = 0;
4508         for my $i (0 .. $#from) {
4509             push @newfrom, [$next, $from[$i][0] - 1];
4510             $next = $from[$i][1] + 1;
4511         }
4512         @from = ();
4513         for my $range (@newfrom) {
4514             if ($range->[0] <= $range->[1]) {
4515                 push @from, $range;
4516             }
4517         }
4518     }
4519     my($from, $to, $diff);
4520     for my $chunk (@from) {
4521         $diff = $chunk->[1] - $chunk->[0];
4522         if ($diff > 1) {
4523             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4524         } elsif ($diff == 1) {
4525             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);