This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add /d, /l, /u (infixed) regex modifiers
[perl5.git] / ext / re / re.pm
1 package re;
2
3 # pragma for controlling the regexp engine
4 use strict;
5 use warnings;
6
7 our $VERSION     = "0.12";
8 our @ISA         = qw(Exporter);
9 our @EXPORT_OK   = ('regmust',
10                     qw(is_regexp regexp_pattern
11                        regname regnames regnames_count));
12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
13
14 my %bitmask = (
15     taint   => 0x00100000, # HINT_RE_TAINT
16     eval    => 0x00200000, # HINT_RE_EVAL
17 );
18
19 sub setcolor {
20  eval {                         # Ignore errors
21   require Term::Cap;
22
23   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
24   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
25   my @props = split /,/, $props;
26   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
27
28   $colors =~ s/\0//g;
29   $ENV{PERL_RE_COLORS} = $colors;
30  };
31  if ($@) {
32     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
33  }
34
35 }
36
37 my %flags = (
38     COMPILE         => 0x0000FF,
39     PARSE           => 0x000001,
40     OPTIMISE        => 0x000002,
41     TRIEC           => 0x000004,
42     DUMP            => 0x000008,
43     FLAGS           => 0x000010,
44
45     EXECUTE         => 0x00FF00,
46     INTUIT          => 0x000100,
47     MATCH           => 0x000200,
48     TRIEE           => 0x000400,
49
50     EXTRA           => 0xFF0000,
51     TRIEM           => 0x010000,
52     OFFSETS         => 0x020000,
53     OFFSETSDBG      => 0x040000,
54     STATE           => 0x080000,
55     OPTIMISEM       => 0x100000,
56     STACK           => 0x280000,
57     BUFFERS         => 0x400000,
58     GPOS            => 0x800000,
59 );
60 $flags{ALL} = -1 & ~($flags{OFFSETS}|$flags{OFFSETSDBG}|$flags{BUFFERS});
61 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
62 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE} | $flags{GPOS};
63 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
64 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
65 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
66
67 if (defined &DynaLoader::boot_DynaLoader) {
68     require XSLoader;
69     XSLoader::load( __PACKAGE__, $VERSION);
70 }
71 # else we're miniperl
72 # We need to work for miniperl, because the XS toolchain uses Text::Wrap, which
73 # uses re 'taint'.
74
75 sub _load_unload {
76     my ($on)= @_;
77     if ($on) {
78         # We call install() every time, as if we didn't, we wouldn't
79         # "see" any changes to the color environment var since
80         # the last time it was called.
81
82         # install() returns an integer, which if casted properly
83         # in C resolves to a structure containing the regexp
84         # hooks. Setting it to a random integer will guarantee
85         # segfaults.
86         $^H{regcomp} = install();
87     } else {
88         delete $^H{regcomp};
89     }
90 }
91
92 sub bits {
93     my $on = shift;
94     my $bits = 0;
95     unless (@_) {
96         require Carp;
97         Carp::carp("Useless use of \"re\" pragma"); 
98     }
99     foreach my $idx (0..$#_){
100         my $s=$_[$idx];
101         if ($s eq 'Debug' or $s eq 'Debugcolor') {
102             setcolor() if $s =~/color/i;
103             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
104             for my $idx ($idx+1..$#_) {
105                 if ($flags{$_[$idx]}) {
106                     if ($on) {
107                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
108                     } else {
109                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
110                     }
111                 } else {
112                     require Carp;
113                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
114                                join(", ",sort keys %flags ) );
115                 }
116             }
117             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
118             last;
119         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
120             setcolor() if $s =~/color/i;
121             _load_unload($on);
122             last;
123         } elsif (exists $bitmask{$s}) {
124             $bits |= $bitmask{$s};
125         } elsif ($EXPORT_OK{$s}) {
126             require Exporter;
127             re->export_to_level(2, 're', $s);
128         } else {
129             require Carp;
130             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
131                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
132                        ")");
133         }
134     }
135     $bits;
136 }
137
138 sub import {
139     shift;
140     $^H |= bits(1, @_);
141 }
142
143 sub unimport {
144     shift;
145     $^H &= ~ bits(0, @_);
146 }
147
148 1;
149
150 __END__
151
152 =head1 NAME
153
154 re - Perl pragma to alter regular expression behaviour
155
156 =head1 SYNOPSIS
157
158     use re 'taint';
159     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
160
161     $pat = '(?{ $foo = 1 })';
162     use re 'eval';
163     /foo${pat}bar/;                # won't fail (when not under -T switch)
164
165     {
166         no re 'taint';             # the default
167         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
168
169         no re 'eval';              # the default
170         /foo${pat}bar/;            # disallowed (with or without -T switch)
171     }
172
173     use re 'debug';                # output debugging info during
174     /^(.*)$/s;                     #     compile and run time
175
176
177     use re 'debugcolor';           # same as 'debug', but with colored output
178     ...
179
180     use re qw(Debug All);          # Finer tuned debugging options.
181     use re qw(Debug More);
182     no re qw(Debug ALL);           # Turn of all re debugging in this scope
183
184     use re qw(is_regexp regexp_pattern); # import utility functions
185     my ($pat,$mods)=regexp_pattern(qr/foo/i);
186     if (is_regexp($obj)) { 
187         print "Got regexp: ",
188             scalar regexp_pattern($obj); # just as perl would stringify it
189     }                                    # but no hassle with blessed re's.
190
191 (We use $^X in these examples because it's tainted by default.)
192
193 =head1 DESCRIPTION
194
195 =head2 'taint' mode
196
197 When C<use re 'taint'> is in effect, and a tainted string is the target
198 of a regexp, the regexp memories (or values returned by the m// operator
199 in list context) are tainted.  This feature is useful when regexp operations
200 on tainted data aren't meant to extract safe substrings, but to perform
201 other transformations.
202
203 =head2 'eval' mode
204
205 When C<use re 'eval'> is in effect, a regexp is allowed to contain
206 C<(?{ ... })> zero-width assertions and C<(??{ ... })> postponed
207 subexpressions, even if the regular expression contains
208 variable interpolation.  That is normally disallowed, since it is a
209 potential security risk.  Note that this pragma is ignored when the regular
210 expression is obtained from tainted data, i.e.  evaluation is always
211 disallowed with tainted regular expressions.  See L<perlre/(?{ code })> 
212 and L<perlre/(??{ code })>.
213
214 For the purpose of this pragma, interpolation of precompiled regular
215 expressions (i.e., the result of C<qr//>) is I<not> considered variable
216 interpolation.  Thus:
217
218     /foo${pat}bar/
219
220 I<is> allowed if $pat is a precompiled regular expression, even
221 if $pat contains C<(?{ ... })> assertions or C<(??{ ... })> subexpressions.
222
223 =head2 'debug' mode
224
225 When C<use re 'debug'> is in effect, perl emits debugging messages when
226 compiling and using regular expressions.  The output is the same as that
227 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
228 B<-Dr> switch. It may be quite voluminous depending on the complexity
229 of the match.  Using C<debugcolor> instead of C<debug> enables a
230 form of output that can be used to get a colorful display on terminals
231 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
232 comma-separated list of C<termcap> properties to use for highlighting
233 strings on/off, pre-point part on/off.
234 See L<perldebug/"Debugging regular expressions"> for additional info.
235
236 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
237 lexically scoped, as the other directives are.  However they have both 
238 compile-time and run-time effects.
239
240 See L<perlmodlib/Pragmatic Modules>.
241
242 =head2 'Debug' mode
243
244 Similarly C<use re 'Debug'> produces debugging output, the difference
245 being that it allows the fine tuning of what debugging output will be
246 emitted. Options are divided into three groups, those related to
247 compilation, those related to execution and those related to special
248 purposes. The options are as follows:
249
250 =over 4
251
252 =item Compile related options
253
254 =over 4
255
256 =item COMPILE
257
258 Turns on all compile related debug options.
259
260 =item PARSE
261
262 Turns on debug output related to the process of parsing the pattern.
263
264 =item OPTIMISE
265
266 Enables output related to the optimisation phase of compilation.
267
268 =item TRIEC
269
270 Detailed info about trie compilation.
271
272 =item DUMP
273
274 Dump the final program out after it is compiled and optimised.
275
276 =back
277
278 =item Execute related options
279
280 =over 4
281
282 =item EXECUTE
283
284 Turns on all execute related debug options.
285
286 =item MATCH
287
288 Turns on debugging of the main matching loop.
289
290 =item TRIEE
291
292 Extra debugging of how tries execute.
293
294 =item INTUIT
295
296 Enable debugging of start point optimisations.
297
298 =back
299
300 =item Extra debugging options
301
302 =over 4
303
304 =item EXTRA
305
306 Turns on all "extra" debugging options.
307
308 =item BUFFERS
309
310 Enable debugging the capture group storage during match. Warning,
311 this can potentially produce extremely large output.
312
313 =item TRIEM
314
315 Enable enhanced TRIE debugging. Enhances both TRIEE
316 and TRIEC.
317
318 =item STATE
319
320 Enable debugging of states in the engine.
321
322 =item STACK
323
324 Enable debugging of the recursion stack in the engine. Enabling
325 or disabling this option automatically does the same for debugging
326 states as well. This output from this can be quite large.
327
328 =item OPTIMISEM
329
330 Enable enhanced optimisation debugging and start point optimisations.
331 Probably not useful except when debugging the regexp engine itself.
332
333 =item OFFSETS
334
335 Dump offset information. This can be used to see how regops correlate
336 to the pattern. Output format is
337
338    NODENUM:POSITION[LENGTH]
339
340 Where 1 is the position of the first char in the string. Note that position
341 can be 0, or larger than the actual length of the pattern, likewise length
342 can be zero.
343
344 =item OFFSETSDBG
345
346 Enable debugging of offsets information. This emits copious
347 amounts of trace information and doesn't mesh well with other
348 debug options.
349
350 Almost definitely only useful to people hacking
351 on the offsets part of the debug engine.
352
353 =back
354
355 =item Other useful flags
356
357 These are useful shortcuts to save on the typing.
358
359 =over 4
360
361 =item ALL
362
363 Enable all options at once except OFFSETS, OFFSETSDBG and BUFFERS
364
365 =item All
366
367 Enable DUMP and all execute options. Equivalent to:
368
369   use re 'debug';
370
371 =item MORE
372
373 =item More
374
375 Enable TRIEM and all execute compile and execute options.
376
377 =back
378
379 =back
380
381 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
382 lexically scoped, as the other directives are.  However they have both
383 compile-time and run-time effects.
384
385 =head2 Exportable Functions
386
387 As of perl 5.9.5 're' debug contains a number of utility functions that
388 may be optionally exported into the caller's namespace. They are listed
389 below.
390
391 =over 4
392
393 =item is_regexp($ref)
394
395 Returns true if the argument is a compiled regular expression as returned
396 by C<qr//>, false if it is not.
397
398 This function will not be confused by overloading or blessing. In
399 internals terms, this extracts the regexp pointer out of the
400 PERL_MAGIC_qr structure so it it cannot be fooled.
401
402 =item regexp_pattern($ref)
403
404 If the argument is a compiled regular expression as returned by C<qr//>,
405 then this function returns the pattern.
406
407 In list context it returns a two element list, the first element
408 containing the pattern and the second containing the modifiers used when
409 the pattern was compiled.
410
411   my ($pat, $mods) = regexp_pattern($ref);
412
413 In scalar context it returns the same as perl would when stringifying a raw
414 C<qr//> with the same pattern inside.  If the argument is not a compiled
415 reference then this routine returns false but defined in scalar context,
416 and the empty list in list context. Thus the following
417
418     if (regexp_pattern($ref) eq '(?i-xsm:foo)')
419
420 will be warning free regardless of what $ref actually is.
421
422 Like C<is_regexp> this function will not be confused by overloading
423 or blessing of the object.
424
425 =item regmust($ref)
426
427 If the argument is a compiled regular expression as returned by C<qr//>,
428 then this function returns what the optimiser considers to be the longest
429 anchored fixed string and longest floating fixed string in the pattern.
430
431 A I<fixed string> is defined as being a substring that must appear for the
432 pattern to match. An I<anchored fixed string> is a fixed string that must
433 appear at a particular offset from the beginning of the match. A I<floating
434 fixed string> is defined as a fixed string that can appear at any point in
435 a range of positions relative to the start of the match. For example,
436
437     my $qr = qr/here .* there/x;
438     my ($anchored, $floating) = regmust($qr);
439     print "anchored:'$anchored'\nfloating:'$floating'\n";
440
441 results in
442
443     anchored:'here'
444     floating:'there'
445
446 Because the C<here> is before the C<.*> in the pattern, its position
447 can be determined exactly. That's not true, however, for the C<there>;
448 it could appear at any point after where the anchored string appeared.
449 Perl uses both for its optimisations, prefering the longer, or, if they are
450 equal, the floating.
451
452 B<NOTE:> This may not necessarily be the definitive longest anchored and
453 floating string. This will be what the optimiser of the Perl that you
454 are using thinks is the longest. If you believe that the result is wrong
455 please report it via the L<perlbug> utility.
456
457 =item regname($name,$all)
458
459 Returns the contents of a named buffer of the last successful match. If
460 $all is true, then returns an array ref containing one entry per buffer,
461 otherwise returns the first defined buffer.
462
463 =item regnames($all)
464
465 Returns a list of all of the named buffers defined in the last successful
466 match. If $all is true, then it returns all names defined, if not it returns
467 only names which were involved in the match.
468
469 =item regnames_count()
470
471 Returns the number of distinct names defined in the pattern used
472 for the last successful match.
473
474 B<Note:> this result is always the actual number of distinct
475 named buffers defined, it may not actually match that which is
476 returned by C<regnames()> and related routines when those routines
477 have not been called with the $all parameter set.
478
479 =back
480
481 =head1 SEE ALSO
482
483 L<perlmodlib/Pragmatic Modules>.
484
485 =cut