This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add examples to perlre on perils of not using \g{}
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore most whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
99 whether space interpretation within a single multi-character construct.  For
100 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
102 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103 but can between the C<(> and C<?>.  Within any delimiters for such a
104 construct, allowed spaces are not affected by C</x>, and depend on the
105 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
106 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
107 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
108 L<perluniprops/Properties accessible through \p{} and \P{}>.
109 X</x>
110
111 =head2 Regular Expressions
112
113 =head3 Metacharacters
114
115 The patterns used in Perl pattern matching evolved from those supplied in
116 the Version 8 regex routines.  (The routines are derived
117 (distantly) from Henry Spencer's freely redistributable reimplementation
118 of the V8 routines.)  See L<Version 8 Regular Expressions> for
119 details.
120
121 In particular the following metacharacters have their standard I<egrep>-ish
122 meanings:
123 X<metacharacter>
124 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127     \        Quote the next metacharacter
128     ^        Match the beginning of the line
129     .        Match any character (except newline)
130     $        Match the end of the line (or before newline at the end)
131     |        Alternation
132     ()       Grouping
133     []       Bracketed Character class
134
135 By default, the "^" character is guaranteed to match only the
136 beginning of the string, the "$" character only the end (or before the
137 newline at the end), and Perl does certain optimizations with the
138 assumption that the string contains only one line.  Embedded newlines
139 will not be matched by "^" or "$".  You may, however, wish to treat a
140 string as a multi-line buffer, such that the "^" will match after any
141 newline within the string (except if the newline is the last character in
142 the string), and "$" will match before any newline.  At the
143 cost of a little more overhead, you can do this by using the /m modifier
144 on the pattern match operator.  (Older programs did this by setting C<$*>,
145 but this practice has been removed in perl 5.9.)
146 X<^> X<$> X</m>
147
148 To simplify multi-line substitutions, the "." character never matches a
149 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150 the string is a single line--even if it isn't.
151 X<.> X</s>
152
153 =head3 Quantifiers
154
155 The following standard quantifiers are recognized:
156 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158     *           Match 0 or more times
159     +           Match 1 or more times
160     ?           Match 1 or 0 times
161     {n}         Match exactly n times
162     {n,}        Match at least n times
163     {n,m}       Match at least n but not more than m times
164
165 (If a curly bracket occurs in any other context, it is treated
166 as a regular character.  In particular, the lower bound
167 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
168 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
169 to non-negative integral values less than a preset limit defined when perl is built.
170 This is usually 32766 on the most common platforms.  The actual limit can
171 be seen in the error message generated by code such as this:
172
173     $_ **= $_ , / {$_} / for 2 .. 42;
174
175 By default, a quantified subpattern is "greedy", that is, it will match as
176 many times as possible (given a particular starting location) while still
177 allowing the rest of the pattern to match.  If you want it to match the
178 minimum number of times possible, follow the quantifier with a "?".  Note
179 that the meanings don't change, just the "greediness":
180 X<metacharacter> X<greedy> X<greediness>
181 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183     *?        Match 0 or more times, not greedily
184     +?        Match 1 or more times, not greedily
185     ??        Match 0 or 1 time, not greedily
186     {n}?      Match exactly n times, not greedily
187     {n,}?     Match at least n times, not greedily
188     {n,m}?    Match at least n but not more than m times, not greedily
189
190 By default, when a quantified subpattern does not allow the rest of the
191 overall pattern to match, Perl will backtrack. However, this behaviour is
192 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193 as well.
194
195  *+     Match 0 or more times and give nothing back
196  ++     Match 1 or more times and give nothing back
197  ?+     Match 0 or 1 time and give nothing back
198  {n}+   Match exactly n times and give nothing back (redundant)
199  {n,}+  Match at least n times and give nothing back
200  {n,m}+ Match at least n but not more than m times and give nothing back
201
202 For instance,
203
204    'aaaa' =~ /a++a/
205
206 will never match, as the C<a++> will gobble up all the C<a>'s in the
207 string and won't leave any for the remaining part of the pattern. This
208 feature can be extremely useful to give perl hints about where it
209 shouldn't backtrack. For instance, the typical "match a double-quoted
210 string" problem can be most efficiently performed when written as:
211
212    /"(?:[^"\\]++|\\.)*+"/
213
214 as we know that if the final quote does not match, backtracking will not
215 help. See the independent subexpression C<< (?>...) >> for more details;
216 possessive quantifiers are just syntactic sugar for that construct. For
217 instance the above example could also be written as follows:
218
219    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221 =head3 Escape sequences
222
223 Because patterns are processed as double quoted strings, the following
224 also work:
225
226  \t          tab                   (HT, TAB)
227  \n          newline               (LF, NL)
228  \r          return                (CR)
229  \f          form feed             (FF)
230  \a          alarm (bell)          (BEL)
231  \e          escape (think troff)  (ESC)
232  \033        octal char            (example: ESC)
233  \x1B        hex char              (example: ESC)
234  \x{263a}    long hex char         (example: Unicode SMILEY)
235  \cK         control char          (example: VT)
236  \N{name}    named Unicode character
237  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
238  \l          lowercase next char (think vi)
239  \u          uppercase next char (think vi)
240  \L          lowercase till \E (think vi)
241  \U          uppercase till \E (think vi)
242  \Q          quote (disable) pattern metacharacters till \E
243  \E          end either case modification or quoted section, think vi
244
245 Details are in L<perlop/Quote and Quote-like Operators>.
246
247 =head3 Character Classes and other Special Escapes
248
249 In addition, Perl defines the following:
250 X<\g> X<\k> X<\K> X<backreference>
251
252  Sequence   Note    Description
253   [...]     [1]  Match a character according to the rules of the
254                    bracketed character class defined by the "...".
255                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
256   [[:...:]] [2]  Match a character according to the rules of the POSIX
257                    character class "..." within the outer bracketed
258                    character class.  Example: [[:upper:]] matches any
259                    uppercase character.
260   \w        [3]  Match a "word" character (alphanumeric plus "_")
261   \W        [3]  Match a non-"word" character
262   \s        [3]  Match a whitespace character
263   \S        [3]  Match a non-whitespace character
264   \d        [3]  Match a decimal digit character
265   \D        [3]  Match a non-digit character
266   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
267   \PP       [3]  Match non-P
268   \X        [4]  Match Unicode "eXtended grapheme cluster"
269   \C             Match a single C-language char (octet) even if that is
270                    part of a larger UTF-8 character.  Thus it breaks up
271                    characters into their UTF-8 bytes, so you may end up
272                    with malformed pieces of UTF-8.  Unsupported in
273                    lookbehind.
274   \1        [5]  Backreference to a specific capture group or buffer.
275                    '1' may actually be any positive integer.
276   \g1       [5]  Backreference to a specific or previous group,
277   \g{-1}    [5]  The number may be negative indicating a relative
278                    previous group and may optionally be wrapped in
279                    curly brackets for safer parsing.
280   \g{name}  [5]  Named backreference
281   \k<name>  [5]  Named backreference
282   \K        [6]  Keep the stuff left of the \K, don't include it in $&
283   \N        [7]  Any character but \n (experimental).  Not affected by
284                    /s modifier
285   \v        [3]  Vertical whitespace
286   \V        [3]  Not vertical whitespace
287   \h        [3]  Horizontal whitespace
288   \H        [3]  Not horizontal whitespace
289   \R        [4]  Linebreak
290
291 =over 4
292
293 =item [1]
294
295 See L<perlrecharclass/Bracketed Character Classes> for details.
296
297 =item [2]
298
299 See L<perlrecharclass/POSIX Character Classes> for details.
300
301 =item [3]
302
303 See L<perlrecharclass/Backslash sequences> for details.
304
305 =item [4]
306
307 See L<perlrebackslash/Misc> for details.
308
309 =item [5]
310
311 See L</Capture groups> below for details.
312
313 =item [6]
314
315 See L</Extended Patterns> below for details.
316
317 =item [7]
318
319 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
320 character whose name is C<NAME>; and similarly when of the form
321 C<\N{U+I<wide hex char>}>, it matches the character whose Unicode ordinal is
322 I<wide hex char>.  Otherwise it matches any character but C<\n>.
323
324 =back
325
326 =head3 Assertions
327
328 Perl defines the following zero-width assertions:
329 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
330 X<regexp, zero-width assertion>
331 X<regular expression, zero-width assertion>
332 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
333
334     \b  Match a word boundary
335     \B  Match except at a word boundary
336     \A  Match only at beginning of string
337     \Z  Match only at end of string, or before newline at the end
338     \z  Match only at end of string
339     \G  Match only at pos() (e.g. at the end-of-match position
340         of prior m//g)
341
342 A word boundary (C<\b>) is a spot between two characters
343 that has a C<\w> on one side of it and a C<\W> on the other side
344 of it (in either order), counting the imaginary characters off the
345 beginning and end of the string as matching a C<\W>.  (Within
346 character classes C<\b> represents backspace rather than a word
347 boundary, just as it normally does in any double-quoted string.)
348 The C<\A> and C<\Z> are just like "^" and "$", except that they
349 won't match multiple times when the C</m> modifier is used, while
350 "^" and "$" will match at every internal line boundary.  To match
351 the actual end of the string and not ignore an optional trailing
352 newline, use C<\z>.
353 X<\b> X<\A> X<\Z> X<\z> X</m>
354
355 The C<\G> assertion can be used to chain global matches (using
356 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
357 It is also useful when writing C<lex>-like scanners, when you have
358 several patterns that you want to match against consequent substrings
359 of your string, see the previous reference.  The actual location
360 where C<\G> will match can also be influenced by using C<pos()> as
361 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
362 matches is modified somewhat, in that contents to the left of C<\G> is
363 not counted when determining the length of the match. Thus the following
364 will not match forever:
365 X<\G>
366
367     $str = 'ABC';
368     pos($str) = 1;
369     while (/.\G/g) {
370         print $&;
371     }
372
373 It will print 'A' and then terminate, as it considers the match to
374 be zero-width, and thus will not match at the same position twice in a
375 row.
376
377 It is worth noting that C<\G> improperly used can result in an infinite
378 loop. Take care when using patterns that include C<\G> in an alternation.
379
380 =head3 Capture groups
381
382 The bracketing construct C<( ... )> creates capture groups (also referred to as
383 capture buffers). To refer to the current contents of a group later on, within
384 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
385 for the second, and so on.
386 This is called a I<backreference>.
387 X<regex, capture buffer> X<regexp, capture buffer>
388 X<regex, capture group> X<regexp, capture group>
389 X<regular expression, capture buffer> X<backreference>
390 X<regular expression, capture group> X<backreference>
391 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
392 X<named capture buffer> X<regular expression, named capture buffer>
393 X<named capture group> X<regular expression, named capture group>
394 X<%+> X<$+{name}> X<< \k<name> >>
395 There is no limit to the number of captured substrings that you may use.
396 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
397 a group did not match, the associated backreference won't match either. (This
398 can happen if the group is optional, or in a different branch of an
399 alternation.)
400 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
401 this form, described below.
402
403 You can also refer to capture groups relatively, by using a negative number, so
404 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
405 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
406 example:
407
408         /
409          (Y)            # group 1
410          (              # group 2
411             (X)         # group 3
412             \g{-1}      # backref to group 3
413             \g{-3}      # backref to group 1
414          )
415         /x
416
417 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
418 interpolate regexes into larger regexes and not have to worry about the
419 capture groups being renumbered.
420
421 You can dispense with numbers altogether and create named capture groups.
422 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
423 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
424 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
425 I<name> must not begin with a number, nor contain hyphens.
426 When different groups within the same pattern have the same name, any reference
427 to that name assumes the leftmost defined group.  Named groups count in
428 absolute and relative numbering, and so can also be referred to by those
429 numbers.
430 (It's possible to do things with named capture groups that would otherwise
431 require C<(??{})>.)
432
433 Capture group contents are dynamically scoped and available to you outside the
434 pattern until the end of the enclosing block or until the next successful
435 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
436 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
437 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
438
439 Braces are required in referring to named capture groups, but are optional for
440 absolute or relative numbered ones.  Braces are safer when creating a regex by
441 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
442 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
443 is probably not what you intended.
444
445 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
446 there were no named nor relative numbered capture groups.  Absolute numbered
447 groups were referred to using C<\1>, C<\2>, etc, and this notation is still
448 accepted (and likely always will be).  But it leads to some ambiguities if
449 there are more than 9 capture groups, as C<\10> could mean either the tenth
450 capture group, or the character whose ordinal in octal is 010 (a backspace in
451 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
452 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
453 a backreference only if at least 11 left parentheses have opened before it.
454 And so on.  C<\1> through C<\9> are always interpreted as backreferences.  You
455 can minimize the ambiguity by always using C<\g> if you mean capturing groups;
456 and always using 3 digits for octal constants, with the first always "0" (which
457 works if there are 63 (= \077) or fewer capture groups).  There are several
458 examples below that illustrate these perils.
459
460 The C<\I<digit>> notation also works in certain circumstances outside
461 the pattern.  See L</Warning on \1 Instead of $1> below for details.)
462
463 Examples:
464
465     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
466
467     /(.)\g1/                        # find first doubled char
468          and print "'$1' is the first doubled character\n";
469
470     /(?<char>.)\k<char>/            # ... a different way
471          and print "'$+{char}' is the first doubled character\n";
472
473     /(?'char'.)\g1/                 # ... mix and match
474          and print "'$1' is the first doubled character\n";
475
476     if (/Time: (..):(..):(..)/) {   # parse out values
477         $hours = $1;
478         $minutes = $2;
479         $seconds = $3;
480     }
481
482     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
483     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
484     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
485     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
486
487     $a = '(.)\1';        # Creates problems when concatenated.
488     $b = '(.)\g{1}';     # Avoids the problems.
489     "aa" =~ /${a}/;      # True
490     "aa" =~ /${b}/;      # True
491     "aa0" =~ /${a}0/;    # False!
492     "aa0" =~ /${b}0/;    # True
493     "aa\x8" =~ /${a}0/;  # True!
494     "aa\x8" =~ /${b}0/;  # False
495
496 Several special variables also refer back to portions of the previous
497 match.  C<$+> returns whatever the last bracket match matched.
498 C<$&> returns the entire matched string.  (At one point C<$0> did
499 also, but now it returns the name of the program.)  C<$`> returns
500 everything before the matched string.  C<$'> returns everything
501 after the matched string. And C<$^N> contains whatever was matched by
502 the most-recently closed group (submatch). C<$^N> can be used in
503 extended patterns (see below), for example to assign a submatch to a
504 variable.
505 X<$+> X<$^N> X<$&> X<$`> X<$'>
506
507 These special variables, like the C<%+> hash and the numbered match variables
508 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
509 until the end of the enclosing block or until the next successful
510 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
511 X<$+> X<$^N> X<$&> X<$`> X<$'>
512 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
513
514 B<NOTE>: Failed matches in Perl do not reset the match variables,
515 which makes it easier to write code that tests for a series of more
516 specific cases and remembers the best match.
517
518 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
519 C<$'> anywhere in the program, it has to provide them for every
520 pattern match.  This may substantially slow your program.  Perl
521 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
522 price for each pattern that contains capturing parentheses.  (To
523 avoid this cost while retaining the grouping behaviour, use the
524 extended regular expression C<(?: ... )> instead.)  But if you never
525 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
526 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
527 if you can, but if you can't (and some algorithms really appreciate
528 them), once you've used them once, use them at will, because you've
529 already paid the price.  As of 5.005, C<$&> is not so costly as the
530 other two.
531 X<$&> X<$`> X<$'>
532
533 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
534 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
535 and C<$'>, B<except> that they are only guaranteed to be defined after a
536 successful match that was executed with the C</p> (preserve) modifier.
537 The use of these variables incurs no global performance penalty, unlike
538 their punctuation char equivalents, however at the trade-off that you
539 have to tell perl when you want to use them.
540 X</p> X<p modifier>
541
542 =head2 Quoting metacharacters
543
544 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
545 C<\w>, C<\n>.  Unlike some other regular expression languages, there
546 are no backslashed symbols that aren't alphanumeric.  So anything
547 that looks like \\, \(, \), \<, \>, \{, or \} is always
548 interpreted as a literal character, not a metacharacter.  This was
549 once used in a common idiom to disable or quote the special meanings
550 of regular expression metacharacters in a string that you want to
551 use for a pattern. Simply quote all non-"word" characters:
552
553     $pattern =~ s/(\W)/\\$1/g;
554
555 (If C<use locale> is set, then this depends on the current locale.)
556 Today it is more common to use the quotemeta() function or the C<\Q>
557 metaquoting escape sequence to disable all metacharacters' special
558 meanings like this:
559
560     /$unquoted\Q$quoted\E$unquoted/
561
562 Beware that if you put literal backslashes (those not inside
563 interpolated variables) between C<\Q> and C<\E>, double-quotish
564 backslash interpolation may lead to confusing results.  If you
565 I<need> to use literal backslashes within C<\Q...\E>,
566 consult L<perlop/"Gory details of parsing quoted constructs">.
567
568 =head2 Extended Patterns
569
570 Perl also defines a consistent extension syntax for features not
571 found in standard tools like B<awk> and B<lex>.  The syntax is a
572 pair of parentheses with a question mark as the first thing within
573 the parentheses.  The character after the question mark indicates
574 the extension.
575
576 The stability of these extensions varies widely.  Some have been
577 part of the core language for many years.  Others are experimental
578 and may change without warning or be completely removed.  Check
579 the documentation on an individual feature to verify its current
580 status.
581
582 A question mark was chosen for this and for the minimal-matching
583 construct because 1) question marks are rare in older regular
584 expressions, and 2) whenever you see one, you should stop and
585 "question" exactly what is going on.  That's psychology...
586
587 =over 10
588
589 =item C<(?#text)>
590 X<(?#)>
591
592 A comment.  The text is ignored.  If the C</x> modifier enables
593 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
594 the comment as soon as it sees a C<)>, so there is no way to put a literal
595 C<)> in the comment.
596
597 =item C<(?pimsx-imsx)>
598 X<(?)>
599
600 One or more embedded pattern-match modifiers, to be turned on (or
601 turned off, if preceded by C<->) for the remainder of the pattern or
602 the remainder of the enclosing pattern group (if any). This is
603 particularly useful for dynamic patterns, such as those read in from a
604 configuration file, taken from an argument, or specified in a table
605 somewhere.  Consider the case where some patterns want to be case
606 sensitive and some do not:  The case insensitive ones merely need to
607 include C<(?i)> at the front of the pattern.  For example:
608
609     $pattern = "foobar";
610     if ( /$pattern/i ) { }
611
612     # more flexible:
613
614     $pattern = "(?i)foobar";
615     if ( /$pattern/ ) { }
616
617 These modifiers are restored at the end of the enclosing group. For example,
618
619     ( (?i) blah ) \s+ \g1
620
621 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
622 repetition of the previous word, assuming the C</x> modifier, and no C</i>
623 modifier outside this group.
624
625 These modifiers do not carry over into named subpatterns called in the
626 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
627 change the case-sensitivity of the "NAME" pattern.
628
629 Note that the C<p> modifier is special in that it can only be enabled,
630 not disabled, and that its presence anywhere in a pattern has a global
631 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
632 when executed under C<use warnings>.
633
634 =item C<(?:pattern)>
635 X<(?:)>
636
637 =item C<(?imsx-imsx:pattern)>
638
639 This is for clustering, not capturing; it groups subexpressions like
640 "()", but doesn't make backreferences as "()" does.  So
641
642     @fields = split(/\b(?:a|b|c)\b/)
643
644 is like
645
646     @fields = split(/\b(a|b|c)\b/)
647
648 but doesn't spit out extra fields.  It's also cheaper not to capture
649 characters if you don't need to.
650
651 Any letters between C<?> and C<:> act as flags modifiers as with
652 C<(?imsx-imsx)>.  For example,
653
654     /(?s-i:more.*than).*million/i
655
656 is equivalent to the more verbose
657
658     /(?:(?s-i)more.*than).*million/i
659
660 =item C<(?|pattern)>
661 X<(?|)> X<Branch reset>
662
663 This is the "branch reset" pattern, which has the special property
664 that the capture groups are numbered from the same starting point
665 in each alternation branch. It is available starting from perl 5.10.0.
666
667 Capture groups are numbered from left to right, but inside this
668 construct the numbering is restarted for each branch.
669
670 The numbering within each branch will be as normal, and any groups
671 following this construct will be numbered as though the construct
672 contained only one branch, that being the one with the most capture
673 groups in it.
674
675 This construct will be useful when you want to capture one of a
676 number of alternative matches.
677
678 Consider the following pattern.  The numbers underneath show in
679 which group the captured content will be stored.
680
681
682     # before  ---------------branch-reset----------- after        
683     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
684     # 1            2         2  3        2     3     4  
685
686 Be careful when using the branch reset pattern in combination with 
687 named captures. Named captures are implemented as being aliases to 
688 numbered groups holding the captures, and that interferes with the
689 implementation of the branch reset pattern. If you are using named
690 captures in a branch reset pattern, it's best to use the same names,
691 in the same order, in each of the alternations:
692
693    /(?|  (?<a> x ) (?<b> y )
694       |  (?<a> z ) (?<b> w )) /x
695
696 Not doing so may lead to surprises:
697
698   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
699   say $+ {a};   # Prints '12'
700   say $+ {b};   # *Also* prints '12'.
701
702 The problem here is that both the group named C<< a >> and the group
703 named C<< b >> are aliases for the group belonging to C<< $1 >>.
704
705 =item Look-Around Assertions
706 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
707
708 Look-around assertions are zero width patterns which match a specific
709 pattern without including it in C<$&>. Positive assertions match when
710 their subpattern matches, negative assertions match when their subpattern
711 fails. Look-behind matches text up to the current match position,
712 look-ahead matches text following the current match position.
713
714 =over 4
715
716 =item C<(?=pattern)>
717 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
718
719 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
720 matches a word followed by a tab, without including the tab in C<$&>.
721
722 =item C<(?!pattern)>
723 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
724
725 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
726 matches any occurrence of "foo" that isn't followed by "bar".  Note
727 however that look-ahead and look-behind are NOT the same thing.  You cannot
728 use this for look-behind.
729
730 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
731 will not do what you want.  That's because the C<(?!foo)> is just saying that
732 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
733 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
734 say "like" because there's the case of your "bar" not having three characters
735 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
736 Sometimes it's still easier just to say:
737
738     if (/bar/ && $` !~ /foo$/)
739
740 For look-behind see below.
741
742 =item C<(?<=pattern)> C<\K>
743 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
744
745 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
746 matches a word that follows a tab, without including the tab in C<$&>.
747 Works only for fixed-width look-behind.
748
749 There is a special form of this construct, called C<\K>, which causes the
750 regex engine to "keep" everything it had matched prior to the C<\K> and
751 not include it in C<$&>. This effectively provides variable length
752 look-behind. The use of C<\K> inside of another look-around assertion
753 is allowed, but the behaviour is currently not well defined.
754
755 For various reasons C<\K> may be significantly more efficient than the
756 equivalent C<< (?<=...) >> construct, and it is especially useful in
757 situations where you want to efficiently remove something following
758 something else in a string. For instance
759
760   s/(foo)bar/$1/g;
761
762 can be rewritten as the much more efficient
763
764   s/foo\Kbar//g;
765
766 =item C<(?<!pattern)>
767 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
768
769 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
770 matches any occurrence of "foo" that does not follow "bar".  Works
771 only for fixed-width look-behind.
772
773 =back
774
775 =item C<(?'NAME'pattern)>
776
777 =item C<< (?<NAME>pattern) >>
778 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
779
780 A named capture group. Identical in every respect to normal capturing
781 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
782 used after a successful match to refer to a named group. See C<perlvar>
783 for more details on the C<%+> and C<%-> hashes.
784
785 If multiple distinct capture groups have the same name then the
786 $+{NAME} will refer to the leftmost defined group in the match.
787
788 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
789
790 B<NOTE:> While the notation of this construct is the same as the similar
791 function in .NET regexes, the behavior is not. In Perl the groups are
792 numbered sequentially regardless of being named or not. Thus in the
793 pattern
794
795   /(x)(?<foo>y)(z)/
796
797 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
798 the opposite which is what a .NET regex hacker might expect.
799
800 Currently NAME is restricted to simple identifiers only.
801 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
802 its Unicode extension (see L<utf8>),
803 though it isn't extended by the locale (see L<perllocale>).
804
805 B<NOTE:> In order to make things easier for programmers with experience
806 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
807 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
808 support the use of single quotes as a delimiter for the name.
809
810 =item C<< \k<NAME> >>
811
812 =item C<< \k'NAME' >>
813
814 Named backreference. Similar to numeric backreferences, except that
815 the group is designated by name and not number. If multiple groups
816 have the same name then it refers to the leftmost defined group in
817 the current match.
818
819 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
820 earlier in the pattern.
821
822 Both forms are equivalent.
823
824 B<NOTE:> In order to make things easier for programmers with experience
825 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
826 may be used instead of C<< \k<NAME> >>.
827
828 =item C<(?{ code })>
829 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
830
831 B<WARNING>: This extended regular expression feature is considered
832 experimental, and may be changed without notice. Code executed that
833 has side effects may not perform identically from version to version
834 due to the effect of future optimisations in the regex engine.
835
836 This zero-width assertion evaluates any embedded Perl code.  It
837 always succeeds, and its C<code> is not interpolated.  Currently,
838 the rules to determine where the C<code> ends are somewhat convoluted.
839
840 This feature can be used together with the special variable C<$^N> to
841 capture the results of submatches in variables without having to keep
842 track of the number of nested parentheses. For example:
843
844   $_ = "The brown fox jumps over the lazy dog";
845   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
846   print "color = $color, animal = $animal\n";
847
848 Inside the C<(?{...})> block, C<$_> refers to the string the regular
849 expression is matching against. You can also use C<pos()> to know what is
850 the current position of matching within this string.
851
852 The C<code> is properly scoped in the following sense: If the assertion
853 is backtracked (compare L<"Backtracking">), all changes introduced after
854 C<local>ization are undone, so that
855
856   $_ = 'a' x 8;
857   m<
858      (?{ $cnt = 0 })                   # Initialize $cnt.
859      (
860        a
861        (?{
862            local $cnt = $cnt + 1;      # Update $cnt, backtracking-safe.
863        })
864      )*
865      aaaa
866      (?{ $res = $cnt })                # On success copy to
867                                        # non-localized location.
868    >x;
869
870 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
871 introduced value, because the scopes that restrict C<local> operators
872 are unwound.
873
874 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
875 switch.  If I<not> used in this way, the result of evaluation of
876 C<code> is put into the special variable C<$^R>.  This happens
877 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
878 inside the same regular expression.
879
880 The assignment to C<$^R> above is properly localized, so the old
881 value of C<$^R> is restored if the assertion is backtracked; compare
882 L<"Backtracking">.
883
884 For reasons of security, this construct is forbidden if the regular
885 expression involves run-time interpolation of variables, unless the
886 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
887 variables contain results of C<qr//> operator (see
888 L<perlop/"qr/STRINGE<sol>msixpo">).
889
890 This restriction is due to the wide-spread and remarkably convenient
891 custom of using run-time determined strings as patterns.  For example:
892
893     $re = <>;
894     chomp $re;
895     $string =~ /$re/;
896
897 Before Perl knew how to execute interpolated code within a pattern,
898 this operation was completely safe from a security point of view,
899 although it could raise an exception from an illegal pattern.  If
900 you turn on the C<use re 'eval'>, though, it is no longer secure,
901 so you should only do so if you are also using taint checking.
902 Better yet, use the carefully constrained evaluation within a Safe
903 compartment.  See L<perlsec> for details about both these mechanisms.
904
905 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
906 broken. The result is unpredictable and will make perl unstable. The
907 workaround is to use global (C<our>) variables.
908
909 B<WARNING>: Because Perl's regex engine is currently not re-entrant,
910 interpolated code may not invoke the regex engine either directly with
911 C<m//> or C<s///>), or indirectly with functions such as
912 C<split>. Invoking the regex engine in these blocks will make perl
913 unstable.
914
915 =item C<(??{ code })>
916 X<(??{})>
917 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
918
919 B<WARNING>: This extended regular expression feature is considered
920 experimental, and may be changed without notice. Code executed that
921 has side effects may not perform identically from version to version
922 due to the effect of future optimisations in the regex engine.
923
924 This is a "postponed" regular subexpression.  The C<code> is evaluated
925 at run time, at the moment this subexpression may match.  The result
926 of evaluation is considered as a regular expression and matched as
927 if it were inserted instead of this construct.  Note that this means
928 that the contents of capture groups defined inside an eval'ed pattern
929 are not available outside of the pattern, and vice versa, there is no
930 way for the inner pattern to refer to a capture group defined outside.
931 Thus,
932
933     ('a' x 100)=~/(??{'(.)' x 100})/
934
935 B<will> match, it will B<not> set $1.
936
937 The C<code> is not interpolated.  As before, the rules to determine
938 where the C<code> ends are currently somewhat convoluted.
939
940 The following pattern matches a parenthesized group:
941
942   $re = qr{
943              \(
944              (?:
945                 (?> [^()]+ )       # Non-parens without backtracking
946               |
947                 (??{ $re })        # Group with matching parens
948              )*
949              \)
950           }x;
951
952 See also C<(?PARNO)> for a different, more efficient way to accomplish
953 the same task.
954
955 For reasons of security, this construct is forbidden if the regular
956 expression involves run-time interpolation of variables, unless the
957 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
958 variables contain results of C<qr//> operator (see
959 L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
960
961 Because perl's regex engine is not currently re-entrant, delayed
962 code may not invoke the regex engine either directly with C<m//> or C<s///>),
963 or indirectly with functions such as C<split>.
964
965 Recursing deeper than 50 times without consuming any input string will
966 result in a fatal error.  The maximum depth is compiled into perl, so
967 changing it requires a custom build.
968
969 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
970 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
971 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
972 X<regex, relative recursion>
973
974 Similar to C<(??{ code })> except it does not involve compiling any code,
975 instead it treats the contents of a capture group as an independent
976 pattern that must match at the current position.  Capture groups
977 contained by the pattern will have the value as determined by the
978 outermost recursion.
979
980 PARNO is a sequence of digits (not starting with 0) whose value reflects
981 the paren-number of the capture group to recurse to. C<(?R)> recurses to
982 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
983 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
984 to be relative, with negative numbers indicating preceding capture groups
985 and positive ones following. Thus C<(?-1)> refers to the most recently
986 declared group, and C<(?+1)> indicates the next group to be declared.
987 Note that the counting for relative recursion differs from that of
988 relative backreferences, in that with recursion unclosed groups B<are>
989 included.
990
991 The following pattern matches a function foo() which may contain
992 balanced parentheses as the argument.
993
994   $re = qr{ (                    # paren group 1 (full function)
995               foo
996               (                  # paren group 2 (parens)
997                 \(
998                   (              # paren group 3 (contents of parens)
999                   (?:
1000                    (?> [^()]+ )  # Non-parens without backtracking
1001                   |
1002                    (?2)          # Recurse to start of paren group 2
1003                   )*
1004                   )
1005                 \)
1006               )
1007             )
1008           }x;
1009
1010 If the pattern was used as follows
1011
1012     'foo(bar(baz)+baz(bop))'=~/$re/
1013         and print "\$1 = $1\n",
1014                   "\$2 = $2\n",
1015                   "\$3 = $3\n";
1016
1017 the output produced should be the following:
1018
1019     $1 = foo(bar(baz)+baz(bop))
1020     $2 = (bar(baz)+baz(bop))
1021     $3 = bar(baz)+baz(bop)
1022
1023 If there is no corresponding capture group defined, then it is a
1024 fatal error.  Recursing deeper than 50 times without consuming any input
1025 string will also result in a fatal error.  The maximum depth is compiled
1026 into perl, so changing it requires a custom build.
1027
1028 The following shows how using negative indexing can make it
1029 easier to embed recursive patterns inside of a C<qr//> construct
1030 for later use:
1031
1032     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1033     if (/foo $parens \s+ + \s+ bar $parens/x) {
1034        # do something here...
1035     }
1036
1037 B<Note> that this pattern does not behave the same way as the equivalent
1038 PCRE or Python construct of the same form. In Perl you can backtrack into
1039 a recursed group, in PCRE and Python the recursed into group is treated
1040 as atomic. Also, modifiers are resolved at compile time, so constructs
1041 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1042 be processed.
1043
1044 =item C<(?&NAME)>
1045 X<(?&NAME)>
1046
1047 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1048 parenthesis to recurse to is determined by name. If multiple parentheses have
1049 the same name, then it recurses to the leftmost.
1050
1051 It is an error to refer to a name that is not declared somewhere in the
1052 pattern.
1053
1054 B<NOTE:> In order to make things easier for programmers with experience
1055 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1056 may be used instead of C<< (?&NAME) >>.
1057
1058 =item C<(?(condition)yes-pattern|no-pattern)>
1059 X<(?()>
1060
1061 =item C<(?(condition)yes-pattern)>
1062
1063 Conditional expression.  C<(condition)> should be either an integer in
1064 parentheses (which is valid if the corresponding pair of parentheses
1065 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1066 name in angle brackets or single quotes (which is valid if a group
1067 with the given name matched), or the special symbol (R) (true when
1068 evaluated inside of recursion or eval). Additionally the R may be
1069 followed by a number, (which will be true when evaluated when recursing
1070 inside of the appropriate group), or by C<&NAME>, in which case it will
1071 be true only when evaluated during recursion in the named group.
1072
1073 Here's a summary of the possible predicates:
1074
1075 =over 4
1076
1077 =item (1) (2) ...
1078
1079 Checks if the numbered capturing group has matched something.
1080
1081 =item (<NAME>) ('NAME')
1082
1083 Checks if a group with the given name has matched something.
1084
1085 =item (?{ CODE })
1086
1087 Treats the code block as the condition.
1088
1089 =item (R)
1090
1091 Checks if the expression has been evaluated inside of recursion.
1092
1093 =item (R1) (R2) ...
1094
1095 Checks if the expression has been evaluated while executing directly
1096 inside of the n-th capture group. This check is the regex equivalent of
1097
1098   if ((caller(0))[3] eq 'subname') { ... }
1099
1100 In other words, it does not check the full recursion stack.
1101
1102 =item (R&NAME)
1103
1104 Similar to C<(R1)>, this predicate checks to see if we're executing
1105 directly inside of the leftmost group with a given name (this is the same
1106 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1107 stack, but only the name of the innermost active recursion.
1108
1109 =item (DEFINE)
1110
1111 In this case, the yes-pattern is never directly executed, and no
1112 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1113 See below for details.
1114
1115 =back
1116
1117 For example:
1118
1119     m{ ( \( )?
1120        [^()]+
1121        (?(1) \) )
1122      }x
1123
1124 matches a chunk of non-parentheses, possibly included in parentheses
1125 themselves.
1126
1127 A special form is the C<(DEFINE)> predicate, which never executes directly
1128 its yes-pattern, and does not allow a no-pattern. This allows to define
1129 subpatterns which will be executed only by using the recursion mechanism.
1130 This way, you can define a set of regular expression rules that can be
1131 bundled into any pattern you choose.
1132
1133 It is recommended that for this usage you put the DEFINE block at the
1134 end of the pattern, and that you name any subpatterns defined within it.
1135
1136 Also, it's worth noting that patterns defined this way probably will
1137 not be as efficient, as the optimiser is not very clever about
1138 handling them.
1139
1140 An example of how this might be used is as follows:
1141
1142   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1143    (?(DEFINE)
1144      (?<NAME_PAT>....)
1145      (?<ADRESS_PAT>....)
1146    )/x
1147
1148 Note that capture groups matched inside of recursion are not accessible
1149 after the recursion returns, so the extra layer of capturing groups is
1150 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1151 C<$+{NAME}> would be.
1152
1153 =item C<< (?>pattern) >>
1154 X<backtrack> X<backtracking> X<atomic> X<possessive>
1155
1156 An "independent" subexpression, one which matches the substring
1157 that a I<standalone> C<pattern> would match if anchored at the given
1158 position, and it matches I<nothing other than this substring>.  This
1159 construct is useful for optimizations of what would otherwise be
1160 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1161 It may also be useful in places where the "grab all you can, and do not
1162 give anything back" semantic is desirable.
1163
1164 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1165 (anchored at the beginning of string, as above) will match I<all>
1166 characters C<a> at the beginning of string, leaving no C<a> for
1167 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1168 since the match of the subgroup C<a*> is influenced by the following
1169 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1170 C<a*ab> will match fewer characters than a standalone C<a*>, since
1171 this makes the tail match.
1172
1173 An effect similar to C<< (?>pattern) >> may be achieved by writing
1174 C<(?=(pattern))\g1>.  This matches the same substring as a standalone
1175 C<a+>, and the following C<\g1> eats the matched string; it therefore
1176 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1177 (The difference between these two constructs is that the second one
1178 uses a capturing group, thus shifting ordinals of backreferences
1179 in the rest of a regular expression.)
1180
1181 Consider this pattern:
1182
1183     m{ \(
1184           (
1185             [^()]+           # x+
1186           |
1187             \( [^()]* \)
1188           )+
1189        \)
1190      }x
1191
1192 That will efficiently match a nonempty group with matching parentheses
1193 two levels deep or less.  However, if there is no such group, it
1194 will take virtually forever on a long string.  That's because there
1195 are so many different ways to split a long string into several
1196 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1197 to a subpattern of the above pattern.  Consider how the pattern
1198 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1199 seconds, but that each extra letter doubles this time.  This
1200 exponential performance will make it appear that your program has
1201 hung.  However, a tiny change to this pattern
1202
1203     m{ \(
1204           (
1205             (?> [^()]+ )        # change x+ above to (?> x+ )
1206           |
1207             \( [^()]* \)
1208           )+
1209        \)
1210      }x
1211
1212 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1213 this yourself would be a productive exercise), but finishes in a fourth
1214 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1215 however, that this pattern currently triggers a warning message under
1216 the C<use warnings> pragma or B<-w> switch saying it
1217 C<"matches null string many times in regex">.
1218
1219 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1220 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1221 This was only 4 times slower on a string with 1000000 C<a>s.
1222
1223 The "grab all you can, and do not give anything back" semantic is desirable
1224 in many situations where on the first sight a simple C<()*> looks like
1225 the correct solution.  Suppose we parse text with comments being delimited
1226 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1227 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1228 the comment delimiter, because it may "give up" some whitespace if
1229 the remainder of the pattern can be made to match that way.  The correct
1230 answer is either one of these:
1231
1232     (?>#[ \t]*)
1233     #[ \t]*(?![ \t])
1234
1235 For example, to grab non-empty comments into $1, one should use either
1236 one of these:
1237
1238     / (?> \# [ \t]* ) (        .+ ) /x;
1239     /     \# [ \t]*   ( [^ \t] .* ) /x;
1240
1241 Which one you pick depends on which of these expressions better reflects
1242 the above specification of comments.
1243
1244 In some literature this construct is called "atomic matching" or
1245 "possessive matching".
1246
1247 Possessive quantifiers are equivalent to putting the item they are applied
1248 to inside of one of these constructs. The following equivalences apply:
1249
1250     Quantifier Form     Bracketing Form
1251     ---------------     ---------------
1252     PAT*+               (?>PAT*)
1253     PAT++               (?>PAT+)
1254     PAT?+               (?>PAT?)
1255     PAT{min,max}+       (?>PAT{min,max})
1256
1257 =back
1258
1259 =head2 Special Backtracking Control Verbs
1260
1261 B<WARNING:> These patterns are experimental and subject to change or
1262 removal in a future version of Perl. Their usage in production code should
1263 be noted to avoid problems during upgrades.
1264
1265 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1266 otherwise stated the ARG argument is optional; in some cases, it is
1267 forbidden.
1268
1269 Any pattern containing a special backtracking verb that allows an argument
1270 has the special behaviour that when executed it sets the current package's
1271 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1272 rules apply:
1273
1274 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1275 verb pattern, if the verb was involved in the failure of the match. If the
1276 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1277 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1278 none. Also, the C<$REGMARK> variable will be set to FALSE.
1279
1280 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1281 the C<$REGMARK> variable will be set to the name of the last
1282 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1283 C<(*MARK:NAME)> verb below for more details.
1284
1285 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1286 and most other regex related variables. They are not local to a scope, nor
1287 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1288 Use C<local> to localize changes to them to a specific scope if necessary.
1289
1290 If a pattern does not contain a special backtracking verb that allows an
1291 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1292
1293 =over 4
1294
1295 =item Verbs that take an argument
1296
1297 =over 4
1298
1299 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1300 X<(*PRUNE)> X<(*PRUNE:NAME)>
1301
1302 This zero-width pattern prunes the backtracking tree at the current point
1303 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1304 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1305 A may backtrack as necessary to match. Once it is reached, matching
1306 continues in B, which may also backtrack as necessary; however, should B
1307 not match, then no further backtracking will take place, and the pattern
1308 will fail outright at the current starting position.
1309
1310 The following example counts all the possible matching strings in a
1311 pattern (without actually matching any of them).
1312
1313     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1314     print "Count=$count\n";
1315
1316 which produces:
1317
1318     aaab
1319     aaa
1320     aa
1321     a
1322     aab
1323     aa
1324     a
1325     ab
1326     a
1327     Count=9
1328
1329 If we add a C<(*PRUNE)> before the count like the following
1330
1331     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1332     print "Count=$count\n";
1333
1334 we prevent backtracking and find the count of the longest matching
1335 at each matching starting point like so:
1336
1337     aaab
1338     aab
1339     ab
1340     Count=3
1341
1342 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1343
1344 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1345 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1346 replaced with a C<< (?>pattern) >> with no functional difference; however,
1347 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1348 C<< (?>pattern) >> alone.
1349
1350
1351 =item C<(*SKIP)> C<(*SKIP:NAME)>
1352 X<(*SKIP)>
1353
1354 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1355 failure it also signifies that whatever text that was matched leading up
1356 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1357 of this pattern. This effectively means that the regex engine "skips" forward
1358 to this position on failure and tries to match again, (assuming that
1359 there is sufficient room to match).
1360
1361 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1362 C<(*MARK:NAME)> was encountered while matching, then it is that position
1363 which is used as the "skip point". If no C<(*MARK)> of that name was
1364 encountered, then the C<(*SKIP)> operator has no effect. When used
1365 without a name the "skip point" is where the match point was when
1366 executing the (*SKIP) pattern.
1367
1368 Compare the following to the examples in C<(*PRUNE)>, note the string
1369 is twice as long:
1370
1371     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1372     print "Count=$count\n";
1373
1374 outputs
1375
1376     aaab
1377     aaab
1378     Count=2
1379
1380 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1381 executed, the next starting point will be where the cursor was when the
1382 C<(*SKIP)> was executed.
1383
1384 =item C<(*MARK:NAME)> C<(*:NAME)>
1385 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1386
1387 This zero-width pattern can be used to mark the point reached in a string
1388 when a certain part of the pattern has been successfully matched. This
1389 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1390 forward to that point if backtracked into on failure. Any number of
1391 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1392
1393 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1394 can be used to "label" a pattern branch, so that after matching, the
1395 program can determine which branches of the pattern were involved in the
1396 match.
1397
1398 When a match is successful, the C<$REGMARK> variable will be set to the
1399 name of the most recently executed C<(*MARK:NAME)> that was involved
1400 in the match.
1401
1402 This can be used to determine which branch of a pattern was matched
1403 without using a separate capture group for each branch, which in turn
1404 can result in a performance improvement, as perl cannot optimize
1405 C</(?:(x)|(y)|(z))/> as efficiently as something like
1406 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1407
1408 When a match has failed, and unless another verb has been involved in
1409 failing the match and has provided its own name to use, the C<$REGERROR>
1410 variable will be set to the name of the most recently executed
1411 C<(*MARK:NAME)>.
1412
1413 See C<(*SKIP)> for more details.
1414
1415 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1416
1417 =item C<(*THEN)> C<(*THEN:NAME)>
1418
1419 This is similar to the "cut group" operator C<::> from Perl 6. Like
1420 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1421 failure, it causes the regex engine to try the next alternation in the
1422 innermost enclosing group (capturing or otherwise).
1423
1424 Its name comes from the observation that this operation combined with the
1425 alternation operator (C<|>) can be used to create what is essentially a
1426 pattern-based if/then/else block:
1427
1428   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1429
1430 Note that if this operator is used and NOT inside of an alternation then
1431 it acts exactly like the C<(*PRUNE)> operator.
1432
1433   / A (*PRUNE) B /
1434
1435 is the same as
1436
1437   / A (*THEN) B /
1438
1439 but
1440
1441   / ( A (*THEN) B | C (*THEN) D ) /
1442
1443 is not the same as
1444
1445   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1446
1447 as after matching the A but failing on the B the C<(*THEN)> verb will
1448 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1449
1450 =item C<(*COMMIT)>
1451 X<(*COMMIT)>
1452
1453 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1454 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1455 into on failure it causes the match to fail outright. No further attempts
1456 to find a valid match by advancing the start pointer will occur again.
1457 For example,
1458
1459     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1460     print "Count=$count\n";
1461
1462 outputs
1463
1464     aaab
1465     Count=1
1466
1467 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1468 does not match, the regex engine will not try any further matching on the
1469 rest of the string.
1470
1471 =back
1472
1473 =item Verbs without an argument
1474
1475 =over 4
1476
1477 =item C<(*FAIL)> C<(*F)>
1478 X<(*FAIL)> X<(*F)>
1479
1480 This pattern matches nothing and always fails. It can be used to force the
1481 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1482 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1483
1484 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1485
1486 =item C<(*ACCEPT)>
1487 X<(*ACCEPT)>
1488
1489 B<WARNING:> This feature is highly experimental. It is not recommended
1490 for production code.
1491
1492 This pattern matches nothing and causes the end of successful matching at
1493 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1494 whether there is actually more to match in the string. When inside of a
1495 nested pattern, such as recursion, or in a subpattern dynamically generated
1496 via C<(??{})>, only the innermost pattern is ended immediately.
1497
1498 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1499 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1500 For instance:
1501
1502   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1503
1504 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1505 be set. If another branch in the inner parentheses were matched, such as in the
1506 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1507
1508 =back
1509
1510 =back
1511
1512 =head2 Backtracking
1513 X<backtrack> X<backtracking>
1514
1515 NOTE: This section presents an abstract approximation of regular
1516 expression behavior.  For a more rigorous (and complicated) view of
1517 the rules involved in selecting a match among possible alternatives,
1518 see L<Combining RE Pieces>.
1519
1520 A fundamental feature of regular expression matching involves the
1521 notion called I<backtracking>, which is currently used (when needed)
1522 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1523 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1524 internally, but the general principle outlined here is valid.
1525
1526 For a regular expression to match, the I<entire> regular expression must
1527 match, not just part of it.  So if the beginning of a pattern containing a
1528 quantifier succeeds in a way that causes later parts in the pattern to
1529 fail, the matching engine backs up and recalculates the beginning
1530 part--that's why it's called backtracking.
1531
1532 Here is an example of backtracking:  Let's say you want to find the
1533 word following "foo" in the string "Food is on the foo table.":
1534
1535     $_ = "Food is on the foo table.";
1536     if ( /\b(foo)\s+(\w+)/i ) {
1537         print "$2 follows $1.\n";
1538     }
1539
1540 When the match runs, the first part of the regular expression (C<\b(foo)>)
1541 finds a possible match right at the beginning of the string, and loads up
1542 $1 with "Foo".  However, as soon as the matching engine sees that there's
1543 no whitespace following the "Foo" that it had saved in $1, it realizes its
1544 mistake and starts over again one character after where it had the
1545 tentative match.  This time it goes all the way until the next occurrence
1546 of "foo". The complete regular expression matches this time, and you get
1547 the expected output of "table follows foo."
1548
1549 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1550 everything between "foo" and "bar".  Initially, you write something
1551 like this:
1552
1553     $_ =  "The food is under the bar in the barn.";
1554     if ( /foo(.*)bar/ ) {
1555         print "got <$1>\n";
1556     }
1557
1558 Which perhaps unexpectedly yields:
1559
1560   got <d is under the bar in the >
1561
1562 That's because C<.*> was greedy, so you get everything between the
1563 I<first> "foo" and the I<last> "bar".  Here it's more effective
1564 to use minimal matching to make sure you get the text between a "foo"
1565 and the first "bar" thereafter.
1566
1567     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1568   got <d is under the >
1569
1570 Here's another example. Let's say you'd like to match a number at the end
1571 of a string, and you also want to keep the preceding part of the match.
1572 So you write this:
1573
1574     $_ = "I have 2 numbers: 53147";
1575     if ( /(.*)(\d*)/ ) {                                # Wrong!
1576         print "Beginning is <$1>, number is <$2>.\n";
1577     }
1578
1579 That won't work at all, because C<.*> was greedy and gobbled up the
1580 whole string. As C<\d*> can match on an empty string the complete
1581 regular expression matched successfully.
1582
1583     Beginning is <I have 2 numbers: 53147>, number is <>.
1584
1585 Here are some variants, most of which don't work:
1586
1587     $_ = "I have 2 numbers: 53147";
1588     @pats = qw{
1589         (.*)(\d*)
1590         (.*)(\d+)
1591         (.*?)(\d*)
1592         (.*?)(\d+)
1593         (.*)(\d+)$
1594         (.*?)(\d+)$
1595         (.*)\b(\d+)$
1596         (.*\D)(\d+)$
1597     };
1598
1599     for $pat (@pats) {
1600         printf "%-12s ", $pat;
1601         if ( /$pat/ ) {
1602             print "<$1> <$2>\n";
1603         } else {
1604             print "FAIL\n";
1605         }
1606     }
1607
1608 That will print out:
1609
1610     (.*)(\d*)    <I have 2 numbers: 53147> <>
1611     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1612     (.*?)(\d*)   <> <>
1613     (.*?)(\d+)   <I have > <2>
1614     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1615     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1616     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1617     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1618
1619 As you see, this can be a bit tricky.  It's important to realize that a
1620 regular expression is merely a set of assertions that gives a definition
1621 of success.  There may be 0, 1, or several different ways that the
1622 definition might succeed against a particular string.  And if there are
1623 multiple ways it might succeed, you need to understand backtracking to
1624 know which variety of success you will achieve.
1625
1626 When using look-ahead assertions and negations, this can all get even
1627 trickier.  Imagine you'd like to find a sequence of non-digits not
1628 followed by "123".  You might try to write that as
1629
1630     $_ = "ABC123";
1631     if ( /^\D*(?!123)/ ) {                # Wrong!
1632         print "Yup, no 123 in $_\n";
1633     }
1634
1635 But that isn't going to match; at least, not the way you're hoping.  It
1636 claims that there is no 123 in the string.  Here's a clearer picture of
1637 why that pattern matches, contrary to popular expectations:
1638
1639     $x = 'ABC123';
1640     $y = 'ABC445';
1641
1642     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1643     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1644
1645     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1646     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1647
1648 This prints
1649
1650     2: got ABC
1651     3: got AB
1652     4: got ABC
1653
1654 You might have expected test 3 to fail because it seems to a more
1655 general purpose version of test 1.  The important difference between
1656 them is that test 3 contains a quantifier (C<\D*>) and so can use
1657 backtracking, whereas test 1 will not.  What's happening is
1658 that you've asked "Is it true that at the start of $x, following 0 or more
1659 non-digits, you have something that's not 123?"  If the pattern matcher had
1660 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1661 fail.
1662
1663 The search engine will initially match C<\D*> with "ABC".  Then it will
1664 try to match C<(?!123> with "123", which fails.  But because
1665 a quantifier (C<\D*>) has been used in the regular expression, the
1666 search engine can backtrack and retry the match differently
1667 in the hope of matching the complete regular expression.
1668
1669 The pattern really, I<really> wants to succeed, so it uses the
1670 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1671 time.  Now there's indeed something following "AB" that is not
1672 "123".  It's "C123", which suffices.
1673
1674 We can deal with this by using both an assertion and a negation.
1675 We'll say that the first part in $1 must be followed both by a digit
1676 and by something that's not "123".  Remember that the look-aheads
1677 are zero-width expressions--they only look, but don't consume any
1678 of the string in their match.  So rewriting this way produces what
1679 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1680
1681     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1682     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1683
1684     6: got ABC
1685
1686 In other words, the two zero-width assertions next to each other work as though
1687 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1688 matches only if you're at the beginning of the line AND the end of the
1689 line simultaneously.  The deeper underlying truth is that juxtaposition in
1690 regular expressions always means AND, except when you write an explicit OR
1691 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1692 although the attempted matches are made at different positions because "a"
1693 is not a zero-width assertion, but a one-width assertion.
1694
1695 B<WARNING>: Particularly complicated regular expressions can take
1696 exponential time to solve because of the immense number of possible
1697 ways they can use backtracking to try for a match.  For example, without
1698 internal optimizations done by the regular expression engine, this will
1699 take a painfully long time to run:
1700
1701     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1702
1703 And if you used C<*>'s in the internal groups instead of limiting them
1704 to 0 through 5 matches, then it would take forever--or until you ran
1705 out of stack space.  Moreover, these internal optimizations are not
1706 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1707 on the external group, no current optimization is applicable, and the
1708 match takes a long time to finish.
1709
1710 A powerful tool for optimizing such beasts is what is known as an
1711 "independent group",
1712 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1713 zero-length look-ahead/look-behind assertions will not backtrack to make
1714 the tail match, since they are in "logical" context: only
1715 whether they match is considered relevant.  For an example
1716 where side-effects of look-ahead I<might> have influenced the
1717 following match, see L<C<< (?>pattern) >>>.
1718
1719 =head2 Version 8 Regular Expressions
1720 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1721
1722 In case you're not familiar with the "regular" Version 8 regex
1723 routines, here are the pattern-matching rules not described above.
1724
1725 Any single character matches itself, unless it is a I<metacharacter>
1726 with a special meaning described here or above.  You can cause
1727 characters that normally function as metacharacters to be interpreted
1728 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1729 character; "\\" matches a "\"). This escape mechanism is also required
1730 for the character used as the pattern delimiter.
1731
1732 A series of characters matches that series of characters in the target
1733 string, so the pattern  C<blurfl> would match "blurfl" in the target
1734 string.
1735
1736 You can specify a character class, by enclosing a list of characters
1737 in C<[]>, which will match any character from the list.  If the
1738 first character after the "[" is "^", the class matches any character not
1739 in the list.  Within a list, the "-" character specifies a
1740 range, so that C<a-z> represents all characters between "a" and "z",
1741 inclusive.  If you want either "-" or "]" itself to be a member of a
1742 class, put it at the start of the list (possibly after a "^"), or
1743 escape it with a backslash.  "-" is also taken literally when it is
1744 at the end of the list, just before the closing "]".  (The
1745 following all specify the same class of three characters: C<[-az]>,
1746 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1747 specifies a class containing twenty-six characters, even on EBCDIC-based
1748 character sets.)  Also, if you try to use the character
1749 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1750 a range, the "-" is understood literally.
1751
1752 Note also that the whole range idea is rather unportable between
1753 character sets--and even within character sets they may cause results
1754 you probably didn't expect.  A sound principle is to use only ranges
1755 that begin from and end at either alphabetics of equal case ([a-e],
1756 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1757 spell out the character sets in full.
1758
1759 Characters may be specified using a metacharacter syntax much like that
1760 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1761 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1762 of octal digits, matches the character whose coded character set value
1763 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1764 matches the character whose numeric value is I<nn>. The expression \cI<x>
1765 matches the character control-I<x>.  Finally, the "." metacharacter
1766 matches any character except "\n" (unless you use C</s>).
1767
1768 You can specify a series of alternatives for a pattern using "|" to
1769 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1770 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1771 first alternative includes everything from the last pattern delimiter
1772 ("(", "[", or the beginning of the pattern) up to the first "|", and
1773 the last alternative contains everything from the last "|" to the next
1774 pattern delimiter.  That's why it's common practice to include
1775 alternatives in parentheses: to minimize confusion about where they
1776 start and end.
1777
1778 Alternatives are tried from left to right, so the first
1779 alternative found for which the entire expression matches, is the one that
1780 is chosen. This means that alternatives are not necessarily greedy. For
1781 example: when matching C<foo|foot> against "barefoot", only the "foo"
1782 part will match, as that is the first alternative tried, and it successfully
1783 matches the target string. (This might not seem important, but it is
1784 important when you are capturing matched text using parentheses.)
1785
1786 Also remember that "|" is interpreted as a literal within square brackets,
1787 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1788
1789 Within a pattern, you may designate subpatterns for later reference
1790 by enclosing them in parentheses, and you may refer back to the
1791 I<n>th subpattern later in the pattern using the metacharacter
1792 \I<n>.  Subpatterns are numbered based on the left to right order
1793 of their opening parenthesis.  A backreference matches whatever
1794 actually matched the subpattern in the string being examined, not
1795 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
1796 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1797 1 matched "0x", even though the rule C<0|0x> could potentially match
1798 the leading 0 in the second number.
1799
1800 =head2 Warning on \1 Instead of $1
1801
1802 Some people get too used to writing things like:
1803
1804     $pattern =~ s/(\W)/\\\1/g;
1805
1806 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
1807 shocking the
1808 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1809 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1810 the usual double-quoted string means a control-A.  The customary Unix
1811 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1812 of doing that, you get yourself into trouble if you then add an C</e>
1813 modifier.
1814
1815     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
1816
1817 Or if you try to do
1818
1819     s/(\d+)/\1000/;
1820
1821 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1822 C<${1}000>.  The operation of interpolation should not be confused
1823 with the operation of matching a backreference.  Certainly they mean two
1824 different things on the I<left> side of the C<s///>.
1825
1826 =head2 Repeated Patterns Matching a Zero-length Substring
1827
1828 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1829
1830 Regular expressions provide a terse and powerful programming language.  As
1831 with most other power tools, power comes together with the ability
1832 to wreak havoc.
1833
1834 A common abuse of this power stems from the ability to make infinite
1835 loops using regular expressions, with something as innocuous as:
1836
1837     'foo' =~ m{ ( o? )* }x;
1838
1839 The C<o?> matches at the beginning of C<'foo'>, and since the position
1840 in the string is not moved by the match, C<o?> would match again and again
1841 because of the C<*> quantifier.  Another common way to create a similar cycle
1842 is with the looping modifier C<//g>:
1843
1844     @matches = ( 'foo' =~ m{ o? }xg );
1845
1846 or
1847
1848     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1849
1850 or the loop implied by split().
1851
1852 However, long experience has shown that many programming tasks may
1853 be significantly simplified by using repeated subexpressions that
1854 may match zero-length substrings.  Here's a simple example being:
1855
1856     @chars = split //, $string;                  # // is not magic in split
1857     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1858
1859 Thus Perl allows such constructs, by I<forcefully breaking
1860 the infinite loop>.  The rules for this are different for lower-level
1861 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1862 ones like the C</g> modifier or split() operator.
1863
1864 The lower-level loops are I<interrupted> (that is, the loop is
1865 broken) when Perl detects that a repeated expression matched a
1866 zero-length substring.   Thus
1867
1868    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1869
1870 is made equivalent to
1871
1872    m{   (?: NON_ZERO_LENGTH )*
1873       |
1874         (?: ZERO_LENGTH )?
1875     }x;
1876
1877 The higher level-loops preserve an additional state between iterations:
1878 whether the last match was zero-length.  To break the loop, the following
1879 match after a zero-length match is prohibited to have a length of zero.
1880 This prohibition interacts with backtracking (see L<"Backtracking">),
1881 and so the I<second best> match is chosen if the I<best> match is of
1882 zero length.
1883
1884 For example:
1885
1886     $_ = 'bar';
1887     s/\w??/<$&>/g;
1888
1889 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1890 match given by non-greedy C<??> is the zero-length match, and the I<second
1891 best> match is what is matched by C<\w>.  Thus zero-length matches
1892 alternate with one-character-long matches.
1893
1894 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1895 position one notch further in the string.
1896
1897 The additional state of being I<matched with zero-length> is associated with
1898 the matched string, and is reset by each assignment to pos().
1899 Zero-length matches at the end of the previous match are ignored
1900 during C<split>.
1901
1902 =head2 Combining RE Pieces
1903
1904 Each of the elementary pieces of regular expressions which were described
1905 before (such as C<ab> or C<\Z>) could match at most one substring
1906 at the given position of the input string.  However, in a typical regular
1907 expression these elementary pieces are combined into more complicated
1908 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1909 (in these examples C<S> and C<T> are regular subexpressions).
1910
1911 Such combinations can include alternatives, leading to a problem of choice:
1912 if we match a regular expression C<a|ab> against C<"abc">, will it match
1913 substring C<"a"> or C<"ab">?  One way to describe which substring is
1914 actually matched is the concept of backtracking (see L<"Backtracking">).
1915 However, this description is too low-level and makes you think
1916 in terms of a particular implementation.
1917
1918 Another description starts with notions of "better"/"worse".  All the
1919 substrings which may be matched by the given regular expression can be
1920 sorted from the "best" match to the "worst" match, and it is the "best"
1921 match which is chosen.  This substitutes the question of "what is chosen?"
1922 by the question of "which matches are better, and which are worse?".
1923
1924 Again, for elementary pieces there is no such question, since at most
1925 one match at a given position is possible.  This section describes the
1926 notion of better/worse for combining operators.  In the description
1927 below C<S> and C<T> are regular subexpressions.
1928
1929 =over 4
1930
1931 =item C<ST>
1932
1933 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1934 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1935 which can be matched by C<T>.
1936
1937 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1938 match than C<A'B'>.
1939
1940 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1941 C<B> is better match for C<T> than C<B'>.
1942
1943 =item C<S|T>
1944
1945 When C<S> can match, it is a better match than when only C<T> can match.
1946
1947 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1948 two matches for C<T>.
1949
1950 =item C<S{REPEAT_COUNT}>
1951
1952 Matches as C<SSS...S> (repeated as many times as necessary).
1953
1954 =item C<S{min,max}>
1955
1956 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1957
1958 =item C<S{min,max}?>
1959
1960 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1961
1962 =item C<S?>, C<S*>, C<S+>
1963
1964 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1965
1966 =item C<S??>, C<S*?>, C<S+?>
1967
1968 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1969
1970 =item C<< (?>S) >>
1971
1972 Matches the best match for C<S> and only that.
1973
1974 =item C<(?=S)>, C<(?<=S)>
1975
1976 Only the best match for C<S> is considered.  (This is important only if
1977 C<S> has capturing parentheses, and backreferences are used somewhere
1978 else in the whole regular expression.)
1979
1980 =item C<(?!S)>, C<(?<!S)>
1981
1982 For this grouping operator there is no need to describe the ordering, since
1983 only whether or not C<S> can match is important.
1984
1985 =item C<(??{ EXPR })>, C<(?PARNO)>
1986
1987 The ordering is the same as for the regular expression which is
1988 the result of EXPR, or the pattern contained by capture group PARNO.
1989
1990 =item C<(?(condition)yes-pattern|no-pattern)>
1991
1992 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1993 already determined.  The ordering of the matches is the same as for the
1994 chosen subexpression.
1995
1996 =back
1997
1998 The above recipes describe the ordering of matches I<at a given position>.
1999 One more rule is needed to understand how a match is determined for the
2000 whole regular expression: a match at an earlier position is always better
2001 than a match at a later position.
2002
2003 =head2 Creating Custom RE Engines
2004
2005 Overloaded constants (see L<overload>) provide a simple way to extend
2006 the functionality of the RE engine.
2007
2008 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2009 matches at a boundary between whitespace characters and non-whitespace
2010 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2011 at these positions, so we want to have each C<\Y|> in the place of the
2012 more complicated version.  We can create a module C<customre> to do
2013 this:
2014
2015     package customre;
2016     use overload;
2017
2018     sub import {
2019       shift;
2020       die "No argument to customre::import allowed" if @_;
2021       overload::constant 'qr' => \&convert;
2022     }
2023
2024     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2025
2026     # We must also take care of not escaping the legitimate \\Y|
2027     # sequence, hence the presence of '\\' in the conversion rules.
2028     my %rules = ( '\\' => '\\\\',
2029                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2030     sub convert {
2031       my $re = shift;
2032       $re =~ s{
2033                 \\ ( \\ | Y . )
2034               }
2035               { $rules{$1} or invalid($re,$1) }sgex;
2036       return $re;
2037     }
2038
2039 Now C<use customre> enables the new escape in constant regular
2040 expressions, i.e., those without any runtime variable interpolations.
2041 As documented in L<overload>, this conversion will work only over
2042 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2043 part of this regular expression needs to be converted explicitly
2044 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2045
2046     use customre;
2047     $re = <>;
2048     chomp $re;
2049     $re = customre::convert $re;
2050     /\Y|$re\Y|/;
2051
2052 =head1 PCRE/Python Support
2053
2054 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2055 to the regex syntax. While Perl programmers are encouraged to use the
2056 Perl specific syntax, the following are also accepted:
2057
2058 =over 4
2059
2060 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2061
2062 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2063
2064 =item C<< (?P=NAME) >>
2065
2066 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2067
2068 =item C<< (?P>NAME) >>
2069
2070 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2071
2072 =back
2073
2074 =head1 BUGS
2075
2076 There are numerous problems with case insensitive matching of characters
2077 outside the ASCII range, especially with those whose folds are multiple
2078 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2079
2080 In a bracketed character class with case insensitive matching, ranges only work
2081 for ASCII characters.  For example,
2082 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2083 doesn't match all the Russian upper and lower case letters.
2084
2085 Many regular expression constructs don't work on EBCDIC platforms.
2086
2087 This document varies from difficult to understand to completely
2088 and utterly opaque.  The wandering prose riddled with jargon is
2089 hard to fathom in several places.
2090
2091 This document needs a rewrite that separates the tutorial content
2092 from the reference content.
2093
2094 =head1 SEE ALSO
2095
2096 L<perlrequick>.
2097
2098 L<perlretut>.
2099
2100 L<perlop/"Regexp Quote-Like Operators">.
2101
2102 L<perlop/"Gory details of parsing quoted constructs">.
2103
2104 L<perlfaq6>.
2105
2106 L<perlfunc/pos>.
2107
2108 L<perllocale>.
2109
2110 L<perlebcdic>.
2111
2112 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2113 by O'Reilly and Associates.