This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlre: Add heading to separate unrelated paragraphs
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore most whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
99 whether space interpretation within a single multi-character construct.  For
100 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
102 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103 but can between the C<(> and C<?>.  Within any delimiters for such a
104 construct, allowed spaces are not affected by C</x>, and depend on the
105 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
106 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
107 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
108 L<perluniprops/Properties accessible through \p{} and \P{}>.
109 X</x>
110
111 =head2 Regular Expressions
112
113 =head3 Metacharacters
114
115 The patterns used in Perl pattern matching evolved from those supplied in
116 the Version 8 regex routines.  (The routines are derived
117 (distantly) from Henry Spencer's freely redistributable reimplementation
118 of the V8 routines.)  See L<Version 8 Regular Expressions> for
119 details.
120
121 In particular the following metacharacters have their standard I<egrep>-ish
122 meanings:
123 X<metacharacter>
124 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127     \        Quote the next metacharacter
128     ^        Match the beginning of the line
129     .        Match any character (except newline)
130     $        Match the end of the line (or before newline at the end)
131     |        Alternation
132     ()       Grouping
133     []       Bracketed Character class
134
135 By default, the "^" character is guaranteed to match only the
136 beginning of the string, the "$" character only the end (or before the
137 newline at the end), and Perl does certain optimizations with the
138 assumption that the string contains only one line.  Embedded newlines
139 will not be matched by "^" or "$".  You may, however, wish to treat a
140 string as a multi-line buffer, such that the "^" will match after any
141 newline within the string (except if the newline is the last character in
142 the string), and "$" will match before any newline.  At the
143 cost of a little more overhead, you can do this by using the /m modifier
144 on the pattern match operator.  (Older programs did this by setting C<$*>,
145 but this practice has been removed in perl 5.9.)
146 X<^> X<$> X</m>
147
148 To simplify multi-line substitutions, the "." character never matches a
149 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150 the string is a single line--even if it isn't.
151 X<.> X</s>
152
153 =head3 Quantifiers
154
155 The following standard quantifiers are recognized:
156 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158     *           Match 0 or more times
159     +           Match 1 or more times
160     ?           Match 1 or 0 times
161     {n}         Match exactly n times
162     {n,}        Match at least n times
163     {n,m}       Match at least n but not more than m times
164
165 (If a curly bracket occurs in any other context, it is treated
166 as a regular character.  In particular, the lower bound
167 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
168 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
169 to non-negative integral values less than a preset limit defined when perl is built.
170 This is usually 32766 on the most common platforms.  The actual limit can
171 be seen in the error message generated by code such as this:
172
173     $_ **= $_ , / {$_} / for 2 .. 42;
174
175 By default, a quantified subpattern is "greedy", that is, it will match as
176 many times as possible (given a particular starting location) while still
177 allowing the rest of the pattern to match.  If you want it to match the
178 minimum number of times possible, follow the quantifier with a "?".  Note
179 that the meanings don't change, just the "greediness":
180 X<metacharacter> X<greedy> X<greediness>
181 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183     *?        Match 0 or more times, not greedily
184     +?        Match 1 or more times, not greedily
185     ??        Match 0 or 1 time, not greedily
186     {n}?      Match exactly n times, not greedily
187     {n,}?     Match at least n times, not greedily
188     {n,m}?    Match at least n but not more than m times, not greedily
189
190 By default, when a quantified subpattern does not allow the rest of the
191 overall pattern to match, Perl will backtrack. However, this behaviour is
192 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193 as well.
194
195  *+     Match 0 or more times and give nothing back
196  ++     Match 1 or more times and give nothing back
197  ?+     Match 0 or 1 time and give nothing back
198  {n}+   Match exactly n times and give nothing back (redundant)
199  {n,}+  Match at least n times and give nothing back
200  {n,m}+ Match at least n but not more than m times and give nothing back
201
202 For instance,
203
204    'aaaa' =~ /a++a/
205
206 will never match, as the C<a++> will gobble up all the C<a>'s in the
207 string and won't leave any for the remaining part of the pattern. This
208 feature can be extremely useful to give perl hints about where it
209 shouldn't backtrack. For instance, the typical "match a double-quoted
210 string" problem can be most efficiently performed when written as:
211
212    /"(?:[^"\\]++|\\.)*+"/
213
214 as we know that if the final quote does not match, backtracking will not
215 help. See the independent subexpression C<< (?>...) >> for more details;
216 possessive quantifiers are just syntactic sugar for that construct. For
217 instance the above example could also be written as follows:
218
219    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221 =head3 Escape sequences
222
223 Because patterns are processed as double quoted strings, the following
224 also work:
225
226  \t          tab                   (HT, TAB)
227  \n          newline               (LF, NL)
228  \r          return                (CR)
229  \f          form feed             (FF)
230  \a          alarm (bell)          (BEL)
231  \e          escape (think troff)  (ESC)
232  \033        octal char            (example: ESC)
233  \x1B        hex char              (example: ESC)
234  \x{263a}    long hex char         (example: Unicode SMILEY)
235  \cK         control char          (example: VT)
236  \N{name}    named Unicode character
237  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
238  \l          lowercase next char (think vi)
239  \u          uppercase next char (think vi)
240  \L          lowercase till \E (think vi)
241  \U          uppercase till \E (think vi)
242  \Q          quote (disable) pattern metacharacters till \E
243  \E          end either case modification or quoted section, think vi
244
245 Details are in L<perlop/Quote and Quote-like Operators>.
246
247 =head3 Character Classes and other Special Escapes
248
249 In addition, Perl defines the following:
250 X<\g> X<\k> X<\K> X<backreference>
251
252  Sequence   Note    Description
253   [...]     [1]  Match a character according to the rules of the
254                    bracketed character class defined by the "...".
255                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
256   [[:...:]] [2]  Match a character according to the rules of the POSIX
257                    character class "..." within the outer bracketed
258                    character class.  Example: [[:upper:]] matches any
259                    uppercase character.
260   \w        [3]  Match a "word" character (alphanumeric plus "_")
261   \W        [3]  Match a non-"word" character
262   \s        [3]  Match a whitespace character
263   \S        [3]  Match a non-whitespace character
264   \d        [3]  Match a decimal digit character
265   \D        [3]  Match a non-digit character
266   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
267   \PP       [3]  Match non-P
268   \X        [4]  Match Unicode "eXtended grapheme cluster"
269   \C             Match a single C-language char (octet) even if that is
270                    part of a larger UTF-8 character.  Thus it breaks up
271                    characters into their UTF-8 bytes, so you may end up
272                    with malformed pieces of UTF-8.  Unsupported in
273                    lookbehind.
274   \1        [5]  Backreference to a specific capture group or buffer.
275                    '1' may actually be any positive integer.
276   \g1       [5]  Backreference to a specific or previous group,
277   \g{-1}    [5]  The number may be negative indicating a relative
278                    previous group and may optionally be wrapped in
279                    curly brackets for safer parsing.
280   \g{name}  [5]  Named backreference
281   \k<name>  [5]  Named backreference
282   \K        [6]  Keep the stuff left of the \K, don't include it in $&
283   \N        [7]  Any character but \n (experimental).  Not affected by
284                    /s modifier
285   \v        [3]  Vertical whitespace
286   \V        [3]  Not vertical whitespace
287   \h        [3]  Horizontal whitespace
288   \H        [3]  Not horizontal whitespace
289   \R        [4]  Linebreak
290
291 =over 4
292
293 =item [1]
294
295 See L<perlrecharclass/Bracketed Character Classes> for details.
296
297 =item [2]
298
299 See L<perlrecharclass/POSIX Character Classes> for details.
300
301 =item [3]
302
303 See L<perlrecharclass/Backslash sequences> for details.
304
305 =item [4]
306
307 See L<perlrebackslash/Misc> for details.
308
309 =item [5]
310
311 See L</Capture groups> below for details.
312
313 =item [6]
314
315 See L</Extended Patterns> below for details.
316
317 =item [7]
318
319 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
320 character whose name is C<NAME>; and similarly when of the form
321 C<\N{U+I<wide hex char>}>, it matches the character whose Unicode ordinal is
322 I<wide hex char>.  Otherwise it matches any character but C<\n>.
323
324 =back
325
326 =head3 Assertions
327
328 Perl defines the following zero-width assertions:
329 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
330 X<regexp, zero-width assertion>
331 X<regular expression, zero-width assertion>
332 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
333
334     \b  Match a word boundary
335     \B  Match except at a word boundary
336     \A  Match only at beginning of string
337     \Z  Match only at end of string, or before newline at the end
338     \z  Match only at end of string
339     \G  Match only at pos() (e.g. at the end-of-match position
340         of prior m//g)
341
342 A word boundary (C<\b>) is a spot between two characters
343 that has a C<\w> on one side of it and a C<\W> on the other side
344 of it (in either order), counting the imaginary characters off the
345 beginning and end of the string as matching a C<\W>.  (Within
346 character classes C<\b> represents backspace rather than a word
347 boundary, just as it normally does in any double-quoted string.)
348 The C<\A> and C<\Z> are just like "^" and "$", except that they
349 won't match multiple times when the C</m> modifier is used, while
350 "^" and "$" will match at every internal line boundary.  To match
351 the actual end of the string and not ignore an optional trailing
352 newline, use C<\z>.
353 X<\b> X<\A> X<\Z> X<\z> X</m>
354
355 The C<\G> assertion can be used to chain global matches (using
356 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
357 It is also useful when writing C<lex>-like scanners, when you have
358 several patterns that you want to match against consequent substrings
359 of your string, see the previous reference.  The actual location
360 where C<\G> will match can also be influenced by using C<pos()> as
361 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
362 matches is modified somewhat, in that contents to the left of C<\G> is
363 not counted when determining the length of the match. Thus the following
364 will not match forever:
365 X<\G>
366
367     $str = 'ABC';
368     pos($str) = 1;
369     while (/.\G/g) {
370         print $&;
371     }
372
373 It will print 'A' and then terminate, as it considers the match to
374 be zero-width, and thus will not match at the same position twice in a
375 row.
376
377 It is worth noting that C<\G> improperly used can result in an infinite
378 loop. Take care when using patterns that include C<\G> in an alternation.
379
380 =head3 Capture groups
381
382 The bracketing construct C<( ... )> creates capture groups (also referred to as
383 capture buffers). To refer to the current contents of a group later on, within
384 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
385 for the second, and so on.
386 This is called a I<backreference>.
387 X<regex, capture buffer> X<regexp, capture buffer>
388 X<regex, capture group> X<regexp, capture group>
389 X<regular expression, capture buffer> X<backreference>
390 X<regular expression, capture group> X<backreference>
391 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
392 X<named capture buffer> X<regular expression, named capture buffer>
393 X<named capture group> X<regular expression, named capture group>
394 X<%+> X<$+{name}> X<< \k<name> >>
395 There is no limit to the number of captured substrings that you may use.
396 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
397 a group did not match, the associated backreference won't match either. (This
398 can happen if the group is optional, or in a different branch of an
399 alternation.)
400 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
401 this form, described below.
402
403 You can also refer to capture groups relatively, by using a negative number, so
404 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
405 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
406 example:
407
408         /
409          (Y)            # group 1
410          (              # group 2
411             (X)         # group 3
412             \g{-1}      # backref to group 3
413             \g{-3}      # backref to group 1
414          )
415         /x
416
417 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
418 interpolate regexes into larger regexes and not have to worry about the
419 capture groups being renumbered.
420
421 You can dispense with numbers altogether and create named capture groups.
422 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
423 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
424 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
425 I<name> must not begin with a number, nor contain hyphens.
426 When different groups within the same pattern have the same name, any reference
427 to that name assumes the leftmost defined group.  Named groups count in
428 absolute and relative numbering, and so can also be referred to by those
429 numbers.
430 (It's possible to do things with named capture groups that would otherwise
431 require C<(??{})>.)
432
433 Capture group contents are dynamically scoped and available to you outside the
434 pattern until the end of the enclosing block or until the next successful
435 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
436 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
437 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
438
439 Braces are required in referring to named capture groups, but are optional for
440 absolute or relative numbered ones.  Braces are safer when creating a regex by
441 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
442 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
443 is probably not what you intended.
444
445 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
446 there were no named nor relative numbered capture groups.  Absolute numbered
447 groups were referred to using C<\1>, C<\2>, etc, and this notation is still
448 accepted (and likely always will be).  But it leads to some ambiguities if
449 there are more than 9 capture groups, as C<\10> could mean either the tenth
450 capture group, or the character whose ordinal in octal is 010 (a backspace in
451 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
452 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
453 a backreference only if at least 11 left parentheses have opened before it.
454 And so on.  C<\1> through C<\9> are always interpreted as backreferences.  You
455 can minimize the ambiguity by always using C<\g> if you mean capturing groups;
456 and always using 3 digits for octal constants, with the first always "0" (which
457 works if there are 63 (= \077) or fewer capture groups).
458
459 The C<\I<digit>> notation also works in certain circumstances outside
460 the pattern.  See L</Warning on \1 Instead of $1> below for details.)
461
462 Examples:
463
464     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
465
466     /(.)\g1/                        # find first doubled char
467          and print "'$1' is the first doubled character\n";
468
469     /(?<char>.)\k<char>/            # ... a different way
470          and print "'$+{char}' is the first doubled character\n";
471
472     /(?'char'.)\g1/                 # ... mix and match
473          and print "'$1' is the first doubled character\n";
474
475     if (/Time: (..):(..):(..)/) {   # parse out values
476         $hours = $1;
477         $minutes = $2;
478         $seconds = $3;
479     }
480
481 Several special variables also refer back to portions of the previous
482 match.  C<$+> returns whatever the last bracket match matched.
483 C<$&> returns the entire matched string.  (At one point C<$0> did
484 also, but now it returns the name of the program.)  C<$`> returns
485 everything before the matched string.  C<$'> returns everything
486 after the matched string. And C<$^N> contains whatever was matched by
487 the most-recently closed group (submatch). C<$^N> can be used in
488 extended patterns (see below), for example to assign a submatch to a
489 variable.
490 X<$+> X<$^N> X<$&> X<$`> X<$'>
491
492 These special variables, like the C<%+> hash and the numbered match variables
493 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
494 until the end of the enclosing block or until the next successful
495 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
496 X<$+> X<$^N> X<$&> X<$`> X<$'>
497 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
498
499 B<NOTE>: Failed matches in Perl do not reset the match variables,
500 which makes it easier to write code that tests for a series of more
501 specific cases and remembers the best match.
502
503 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
504 C<$'> anywhere in the program, it has to provide them for every
505 pattern match.  This may substantially slow your program.  Perl
506 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
507 price for each pattern that contains capturing parentheses.  (To
508 avoid this cost while retaining the grouping behaviour, use the
509 extended regular expression C<(?: ... )> instead.)  But if you never
510 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
511 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
512 if you can, but if you can't (and some algorithms really appreciate
513 them), once you've used them once, use them at will, because you've
514 already paid the price.  As of 5.005, C<$&> is not so costly as the
515 other two.
516 X<$&> X<$`> X<$'>
517
518 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
519 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
520 and C<$'>, B<except> that they are only guaranteed to be defined after a
521 successful match that was executed with the C</p> (preserve) modifier.
522 The use of these variables incurs no global performance penalty, unlike
523 their punctuation char equivalents, however at the trade-off that you
524 have to tell perl when you want to use them.
525 X</p> X<p modifier>
526
527 =head2 Quoting metacharacters
528
529 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
530 C<\w>, C<\n>.  Unlike some other regular expression languages, there
531 are no backslashed symbols that aren't alphanumeric.  So anything
532 that looks like \\, \(, \), \<, \>, \{, or \} is always
533 interpreted as a literal character, not a metacharacter.  This was
534 once used in a common idiom to disable or quote the special meanings
535 of regular expression metacharacters in a string that you want to
536 use for a pattern. Simply quote all non-"word" characters:
537
538     $pattern =~ s/(\W)/\\$1/g;
539
540 (If C<use locale> is set, then this depends on the current locale.)
541 Today it is more common to use the quotemeta() function or the C<\Q>
542 metaquoting escape sequence to disable all metacharacters' special
543 meanings like this:
544
545     /$unquoted\Q$quoted\E$unquoted/
546
547 Beware that if you put literal backslashes (those not inside
548 interpolated variables) between C<\Q> and C<\E>, double-quotish
549 backslash interpolation may lead to confusing results.  If you
550 I<need> to use literal backslashes within C<\Q...\E>,
551 consult L<perlop/"Gory details of parsing quoted constructs">.
552
553 =head2 Extended Patterns
554
555 Perl also defines a consistent extension syntax for features not
556 found in standard tools like B<awk> and B<lex>.  The syntax is a
557 pair of parentheses with a question mark as the first thing within
558 the parentheses.  The character after the question mark indicates
559 the extension.
560
561 The stability of these extensions varies widely.  Some have been
562 part of the core language for many years.  Others are experimental
563 and may change without warning or be completely removed.  Check
564 the documentation on an individual feature to verify its current
565 status.
566
567 A question mark was chosen for this and for the minimal-matching
568 construct because 1) question marks are rare in older regular
569 expressions, and 2) whenever you see one, you should stop and
570 "question" exactly what is going on.  That's psychology...
571
572 =over 10
573
574 =item C<(?#text)>
575 X<(?#)>
576
577 A comment.  The text is ignored.  If the C</x> modifier enables
578 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
579 the comment as soon as it sees a C<)>, so there is no way to put a literal
580 C<)> in the comment.
581
582 =item C<(?pimsx-imsx)>
583 X<(?)>
584
585 One or more embedded pattern-match modifiers, to be turned on (or
586 turned off, if preceded by C<->) for the remainder of the pattern or
587 the remainder of the enclosing pattern group (if any). This is
588 particularly useful for dynamic patterns, such as those read in from a
589 configuration file, taken from an argument, or specified in a table
590 somewhere.  Consider the case where some patterns want to be case
591 sensitive and some do not:  The case insensitive ones merely need to
592 include C<(?i)> at the front of the pattern.  For example:
593
594     $pattern = "foobar";
595     if ( /$pattern/i ) { }
596
597     # more flexible:
598
599     $pattern = "(?i)foobar";
600     if ( /$pattern/ ) { }
601
602 These modifiers are restored at the end of the enclosing group. For example,
603
604     ( (?i) blah ) \s+ \g1
605
606 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
607 repetition of the previous word, assuming the C</x> modifier, and no C</i>
608 modifier outside this group.
609
610 These modifiers do not carry over into named subpatterns called in the
611 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
612 change the case-sensitivity of the "NAME" pattern.
613
614 Note that the C<p> modifier is special in that it can only be enabled,
615 not disabled, and that its presence anywhere in a pattern has a global
616 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
617 when executed under C<use warnings>.
618
619 =item C<(?:pattern)>
620 X<(?:)>
621
622 =item C<(?imsx-imsx:pattern)>
623
624 This is for clustering, not capturing; it groups subexpressions like
625 "()", but doesn't make backreferences as "()" does.  So
626
627     @fields = split(/\b(?:a|b|c)\b/)
628
629 is like
630
631     @fields = split(/\b(a|b|c)\b/)
632
633 but doesn't spit out extra fields.  It's also cheaper not to capture
634 characters if you don't need to.
635
636 Any letters between C<?> and C<:> act as flags modifiers as with
637 C<(?imsx-imsx)>.  For example,
638
639     /(?s-i:more.*than).*million/i
640
641 is equivalent to the more verbose
642
643     /(?:(?s-i)more.*than).*million/i
644
645 =item C<(?|pattern)>
646 X<(?|)> X<Branch reset>
647
648 This is the "branch reset" pattern, which has the special property
649 that the capture groups are numbered from the same starting point
650 in each alternation branch. It is available starting from perl 5.10.0.
651
652 Capture groups are numbered from left to right, but inside this
653 construct the numbering is restarted for each branch.
654
655 The numbering within each branch will be as normal, and any groups
656 following this construct will be numbered as though the construct
657 contained only one branch, that being the one with the most capture
658 groups in it.
659
660 This construct will be useful when you want to capture one of a
661 number of alternative matches.
662
663 Consider the following pattern.  The numbers underneath show in
664 which group the captured content will be stored.
665
666
667     # before  ---------------branch-reset----------- after        
668     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
669     # 1            2         2  3        2     3     4  
670
671 Be careful when using the branch reset pattern in combination with 
672 named captures. Named captures are implemented as being aliases to 
673 numbered groups holding the captures, and that interferes with the
674 implementation of the branch reset pattern. If you are using named
675 captures in a branch reset pattern, it's best to use the same names,
676 in the same order, in each of the alternations:
677
678    /(?|  (?<a> x ) (?<b> y )
679       |  (?<a> z ) (?<b> w )) /x
680
681 Not doing so may lead to surprises:
682
683   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
684   say $+ {a};   # Prints '12'
685   say $+ {b};   # *Also* prints '12'.
686
687 The problem here is that both the group named C<< a >> and the group
688 named C<< b >> are aliases for the group belonging to C<< $1 >>.
689
690 =item Look-Around Assertions
691 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
692
693 Look-around assertions are zero width patterns which match a specific
694 pattern without including it in C<$&>. Positive assertions match when
695 their subpattern matches, negative assertions match when their subpattern
696 fails. Look-behind matches text up to the current match position,
697 look-ahead matches text following the current match position.
698
699 =over 4
700
701 =item C<(?=pattern)>
702 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
703
704 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
705 matches a word followed by a tab, without including the tab in C<$&>.
706
707 =item C<(?!pattern)>
708 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
709
710 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
711 matches any occurrence of "foo" that isn't followed by "bar".  Note
712 however that look-ahead and look-behind are NOT the same thing.  You cannot
713 use this for look-behind.
714
715 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
716 will not do what you want.  That's because the C<(?!foo)> is just saying that
717 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
718 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
719 say "like" because there's the case of your "bar" not having three characters
720 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
721 Sometimes it's still easier just to say:
722
723     if (/bar/ && $` !~ /foo$/)
724
725 For look-behind see below.
726
727 =item C<(?<=pattern)> C<\K>
728 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
729
730 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
731 matches a word that follows a tab, without including the tab in C<$&>.
732 Works only for fixed-width look-behind.
733
734 There is a special form of this construct, called C<\K>, which causes the
735 regex engine to "keep" everything it had matched prior to the C<\K> and
736 not include it in C<$&>. This effectively provides variable length
737 look-behind. The use of C<\K> inside of another look-around assertion
738 is allowed, but the behaviour is currently not well defined.
739
740 For various reasons C<\K> may be significantly more efficient than the
741 equivalent C<< (?<=...) >> construct, and it is especially useful in
742 situations where you want to efficiently remove something following
743 something else in a string. For instance
744
745   s/(foo)bar/$1/g;
746
747 can be rewritten as the much more efficient
748
749   s/foo\Kbar//g;
750
751 =item C<(?<!pattern)>
752 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
753
754 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
755 matches any occurrence of "foo" that does not follow "bar".  Works
756 only for fixed-width look-behind.
757
758 =back
759
760 =item C<(?'NAME'pattern)>
761
762 =item C<< (?<NAME>pattern) >>
763 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
764
765 A named capture group. Identical in every respect to normal capturing
766 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
767 used after a successful match to refer to a named group. See C<perlvar>
768 for more details on the C<%+> and C<%-> hashes.
769
770 If multiple distinct capture groups have the same name then the
771 $+{NAME} will refer to the leftmost defined group in the match.
772
773 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
774
775 B<NOTE:> While the notation of this construct is the same as the similar
776 function in .NET regexes, the behavior is not. In Perl the groups are
777 numbered sequentially regardless of being named or not. Thus in the
778 pattern
779
780   /(x)(?<foo>y)(z)/
781
782 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
783 the opposite which is what a .NET regex hacker might expect.
784
785 Currently NAME is restricted to simple identifiers only.
786 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
787 its Unicode extension (see L<utf8>),
788 though it isn't extended by the locale (see L<perllocale>).
789
790 B<NOTE:> In order to make things easier for programmers with experience
791 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
792 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
793 support the use of single quotes as a delimiter for the name.
794
795 =item C<< \k<NAME> >>
796
797 =item C<< \k'NAME' >>
798
799 Named backreference. Similar to numeric backreferences, except that
800 the group is designated by name and not number. If multiple groups
801 have the same name then it refers to the leftmost defined group in
802 the current match.
803
804 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
805 earlier in the pattern.
806
807 Both forms are equivalent.
808
809 B<NOTE:> In order to make things easier for programmers with experience
810 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
811 may be used instead of C<< \k<NAME> >>.
812
813 =item C<(?{ code })>
814 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
815
816 B<WARNING>: This extended regular expression feature is considered
817 experimental, and may be changed without notice. Code executed that
818 has side effects may not perform identically from version to version
819 due to the effect of future optimisations in the regex engine.
820
821 This zero-width assertion evaluates any embedded Perl code.  It
822 always succeeds, and its C<code> is not interpolated.  Currently,
823 the rules to determine where the C<code> ends are somewhat convoluted.
824
825 This feature can be used together with the special variable C<$^N> to
826 capture the results of submatches in variables without having to keep
827 track of the number of nested parentheses. For example:
828
829   $_ = "The brown fox jumps over the lazy dog";
830   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
831   print "color = $color, animal = $animal\n";
832
833 Inside the C<(?{...})> block, C<$_> refers to the string the regular
834 expression is matching against. You can also use C<pos()> to know what is
835 the current position of matching within this string.
836
837 The C<code> is properly scoped in the following sense: If the assertion
838 is backtracked (compare L<"Backtracking">), all changes introduced after
839 C<local>ization are undone, so that
840
841   $_ = 'a' x 8;
842   m<
843      (?{ $cnt = 0 })                   # Initialize $cnt.
844      (
845        a
846        (?{
847            local $cnt = $cnt + 1;      # Update $cnt, backtracking-safe.
848        })
849      )*
850      aaaa
851      (?{ $res = $cnt })                # On success copy to
852                                        # non-localized location.
853    >x;
854
855 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
856 introduced value, because the scopes that restrict C<local> operators
857 are unwound.
858
859 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
860 switch.  If I<not> used in this way, the result of evaluation of
861 C<code> is put into the special variable C<$^R>.  This happens
862 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
863 inside the same regular expression.
864
865 The assignment to C<$^R> above is properly localized, so the old
866 value of C<$^R> is restored if the assertion is backtracked; compare
867 L<"Backtracking">.
868
869 For reasons of security, this construct is forbidden if the regular
870 expression involves run-time interpolation of variables, unless the
871 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
872 variables contain results of C<qr//> operator (see
873 L<perlop/"qr/STRINGE<sol>msixpo">).
874
875 This restriction is due to the wide-spread and remarkably convenient
876 custom of using run-time determined strings as patterns.  For example:
877
878     $re = <>;
879     chomp $re;
880     $string =~ /$re/;
881
882 Before Perl knew how to execute interpolated code within a pattern,
883 this operation was completely safe from a security point of view,
884 although it could raise an exception from an illegal pattern.  If
885 you turn on the C<use re 'eval'>, though, it is no longer secure,
886 so you should only do so if you are also using taint checking.
887 Better yet, use the carefully constrained evaluation within a Safe
888 compartment.  See L<perlsec> for details about both these mechanisms.
889
890 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
891 broken. The result is unpredictable and will make perl unstable. The
892 workaround is to use global (C<our>) variables.
893
894 B<WARNING>: Because Perl's regex engine is currently not re-entrant,
895 interpolated code may not invoke the regex engine either directly with
896 C<m//> or C<s///>), or indirectly with functions such as
897 C<split>. Invoking the regex engine in these blocks will make perl
898 unstable.
899
900 =item C<(??{ code })>
901 X<(??{})>
902 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
903
904 B<WARNING>: This extended regular expression feature is considered
905 experimental, and may be changed without notice. Code executed that
906 has side effects may not perform identically from version to version
907 due to the effect of future optimisations in the regex engine.
908
909 This is a "postponed" regular subexpression.  The C<code> is evaluated
910 at run time, at the moment this subexpression may match.  The result
911 of evaluation is considered as a regular expression and matched as
912 if it were inserted instead of this construct.  Note that this means
913 that the contents of capture groups defined inside an eval'ed pattern
914 are not available outside of the pattern, and vice versa, there is no
915 way for the inner pattern to refer to a capture group defined outside.
916 Thus,
917
918     ('a' x 100)=~/(??{'(.)' x 100})/
919
920 B<will> match, it will B<not> set $1.
921
922 The C<code> is not interpolated.  As before, the rules to determine
923 where the C<code> ends are currently somewhat convoluted.
924
925 The following pattern matches a parenthesized group:
926
927   $re = qr{
928              \(
929              (?:
930                 (?> [^()]+ )       # Non-parens without backtracking
931               |
932                 (??{ $re })        # Group with matching parens
933              )*
934              \)
935           }x;
936
937 See also C<(?PARNO)> for a different, more efficient way to accomplish
938 the same task.
939
940 For reasons of security, this construct is forbidden if the regular
941 expression involves run-time interpolation of variables, unless the
942 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
943 variables contain results of C<qr//> operator (see
944 L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
945
946 Because perl's regex engine is not currently re-entrant, delayed
947 code may not invoke the regex engine either directly with C<m//> or C<s///>),
948 or indirectly with functions such as C<split>.
949
950 Recursing deeper than 50 times without consuming any input string will
951 result in a fatal error.  The maximum depth is compiled into perl, so
952 changing it requires a custom build.
953
954 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
955 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
956 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
957 X<regex, relative recursion>
958
959 Similar to C<(??{ code })> except it does not involve compiling any code,
960 instead it treats the contents of a capture group as an independent
961 pattern that must match at the current position.  Capture groups
962 contained by the pattern will have the value as determined by the
963 outermost recursion.
964
965 PARNO is a sequence of digits (not starting with 0) whose value reflects
966 the paren-number of the capture group to recurse to. C<(?R)> recurses to
967 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
968 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
969 to be relative, with negative numbers indicating preceding capture groups
970 and positive ones following. Thus C<(?-1)> refers to the most recently
971 declared group, and C<(?+1)> indicates the next group to be declared.
972 Note that the counting for relative recursion differs from that of
973 relative backreferences, in that with recursion unclosed groups B<are>
974 included.
975
976 The following pattern matches a function foo() which may contain
977 balanced parentheses as the argument.
978
979   $re = qr{ (                    # paren group 1 (full function)
980               foo
981               (                  # paren group 2 (parens)
982                 \(
983                   (              # paren group 3 (contents of parens)
984                   (?:
985                    (?> [^()]+ )  # Non-parens without backtracking
986                   |
987                    (?2)          # Recurse to start of paren group 2
988                   )*
989                   )
990                 \)
991               )
992             )
993           }x;
994
995 If the pattern was used as follows
996
997     'foo(bar(baz)+baz(bop))'=~/$re/
998         and print "\$1 = $1\n",
999                   "\$2 = $2\n",
1000                   "\$3 = $3\n";
1001
1002 the output produced should be the following:
1003
1004     $1 = foo(bar(baz)+baz(bop))
1005     $2 = (bar(baz)+baz(bop))
1006     $3 = bar(baz)+baz(bop)
1007
1008 If there is no corresponding capture group defined, then it is a
1009 fatal error.  Recursing deeper than 50 times without consuming any input
1010 string will also result in a fatal error.  The maximum depth is compiled
1011 into perl, so changing it requires a custom build.
1012
1013 The following shows how using negative indexing can make it
1014 easier to embed recursive patterns inside of a C<qr//> construct
1015 for later use:
1016
1017     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1018     if (/foo $parens \s+ + \s+ bar $parens/x) {
1019        # do something here...
1020     }
1021
1022 B<Note> that this pattern does not behave the same way as the equivalent
1023 PCRE or Python construct of the same form. In Perl you can backtrack into
1024 a recursed group, in PCRE and Python the recursed into group is treated
1025 as atomic. Also, modifiers are resolved at compile time, so constructs
1026 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1027 be processed.
1028
1029 =item C<(?&NAME)>
1030 X<(?&NAME)>
1031
1032 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1033 parenthesis to recurse to is determined by name. If multiple parentheses have
1034 the same name, then it recurses to the leftmost.
1035
1036 It is an error to refer to a name that is not declared somewhere in the
1037 pattern.
1038
1039 B<NOTE:> In order to make things easier for programmers with experience
1040 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1041 may be used instead of C<< (?&NAME) >>.
1042
1043 =item C<(?(condition)yes-pattern|no-pattern)>
1044 X<(?()>
1045
1046 =item C<(?(condition)yes-pattern)>
1047
1048 Conditional expression.  C<(condition)> should be either an integer in
1049 parentheses (which is valid if the corresponding pair of parentheses
1050 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1051 name in angle brackets or single quotes (which is valid if a group
1052 with the given name matched), or the special symbol (R) (true when
1053 evaluated inside of recursion or eval). Additionally the R may be
1054 followed by a number, (which will be true when evaluated when recursing
1055 inside of the appropriate group), or by C<&NAME>, in which case it will
1056 be true only when evaluated during recursion in the named group.
1057
1058 Here's a summary of the possible predicates:
1059
1060 =over 4
1061
1062 =item (1) (2) ...
1063
1064 Checks if the numbered capturing group has matched something.
1065
1066 =item (<NAME>) ('NAME')
1067
1068 Checks if a group with the given name has matched something.
1069
1070 =item (?{ CODE })
1071
1072 Treats the code block as the condition.
1073
1074 =item (R)
1075
1076 Checks if the expression has been evaluated inside of recursion.
1077
1078 =item (R1) (R2) ...
1079
1080 Checks if the expression has been evaluated while executing directly
1081 inside of the n-th capture group. This check is the regex equivalent of
1082
1083   if ((caller(0))[3] eq 'subname') { ... }
1084
1085 In other words, it does not check the full recursion stack.
1086
1087 =item (R&NAME)
1088
1089 Similar to C<(R1)>, this predicate checks to see if we're executing
1090 directly inside of the leftmost group with a given name (this is the same
1091 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1092 stack, but only the name of the innermost active recursion.
1093
1094 =item (DEFINE)
1095
1096 In this case, the yes-pattern is never directly executed, and no
1097 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1098 See below for details.
1099
1100 =back
1101
1102 For example:
1103
1104     m{ ( \( )?
1105        [^()]+
1106        (?(1) \) )
1107      }x
1108
1109 matches a chunk of non-parentheses, possibly included in parentheses
1110 themselves.
1111
1112 A special form is the C<(DEFINE)> predicate, which never executes directly
1113 its yes-pattern, and does not allow a no-pattern. This allows to define
1114 subpatterns which will be executed only by using the recursion mechanism.
1115 This way, you can define a set of regular expression rules that can be
1116 bundled into any pattern you choose.
1117
1118 It is recommended that for this usage you put the DEFINE block at the
1119 end of the pattern, and that you name any subpatterns defined within it.
1120
1121 Also, it's worth noting that patterns defined this way probably will
1122 not be as efficient, as the optimiser is not very clever about
1123 handling them.
1124
1125 An example of how this might be used is as follows:
1126
1127   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1128    (?(DEFINE)
1129      (?<NAME_PAT>....)
1130      (?<ADRESS_PAT>....)
1131    )/x
1132
1133 Note that capture groups matched inside of recursion are not accessible
1134 after the recursion returns, so the extra layer of capturing groups is
1135 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1136 C<$+{NAME}> would be.
1137
1138 =item C<< (?>pattern) >>
1139 X<backtrack> X<backtracking> X<atomic> X<possessive>
1140
1141 An "independent" subexpression, one which matches the substring
1142 that a I<standalone> C<pattern> would match if anchored at the given
1143 position, and it matches I<nothing other than this substring>.  This
1144 construct is useful for optimizations of what would otherwise be
1145 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1146 It may also be useful in places where the "grab all you can, and do not
1147 give anything back" semantic is desirable.
1148
1149 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1150 (anchored at the beginning of string, as above) will match I<all>
1151 characters C<a> at the beginning of string, leaving no C<a> for
1152 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1153 since the match of the subgroup C<a*> is influenced by the following
1154 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1155 C<a*ab> will match fewer characters than a standalone C<a*>, since
1156 this makes the tail match.
1157
1158 An effect similar to C<< (?>pattern) >> may be achieved by writing
1159 C<(?=(pattern))\g1>.  This matches the same substring as a standalone
1160 C<a+>, and the following C<\g1> eats the matched string; it therefore
1161 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1162 (The difference between these two constructs is that the second one
1163 uses a capturing group, thus shifting ordinals of backreferences
1164 in the rest of a regular expression.)
1165
1166 Consider this pattern:
1167
1168     m{ \(
1169           (
1170             [^()]+           # x+
1171           |
1172             \( [^()]* \)
1173           )+
1174        \)
1175      }x
1176
1177 That will efficiently match a nonempty group with matching parentheses
1178 two levels deep or less.  However, if there is no such group, it
1179 will take virtually forever on a long string.  That's because there
1180 are so many different ways to split a long string into several
1181 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1182 to a subpattern of the above pattern.  Consider how the pattern
1183 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1184 seconds, but that each extra letter doubles this time.  This
1185 exponential performance will make it appear that your program has
1186 hung.  However, a tiny change to this pattern
1187
1188     m{ \(
1189           (
1190             (?> [^()]+ )        # change x+ above to (?> x+ )
1191           |
1192             \( [^()]* \)
1193           )+
1194        \)
1195      }x
1196
1197 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1198 this yourself would be a productive exercise), but finishes in a fourth
1199 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1200 however, that this pattern currently triggers a warning message under
1201 the C<use warnings> pragma or B<-w> switch saying it
1202 C<"matches null string many times in regex">.
1203
1204 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1205 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1206 This was only 4 times slower on a string with 1000000 C<a>s.
1207
1208 The "grab all you can, and do not give anything back" semantic is desirable
1209 in many situations where on the first sight a simple C<()*> looks like
1210 the correct solution.  Suppose we parse text with comments being delimited
1211 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1212 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1213 the comment delimiter, because it may "give up" some whitespace if
1214 the remainder of the pattern can be made to match that way.  The correct
1215 answer is either one of these:
1216
1217     (?>#[ \t]*)
1218     #[ \t]*(?![ \t])
1219
1220 For example, to grab non-empty comments into $1, one should use either
1221 one of these:
1222
1223     / (?> \# [ \t]* ) (        .+ ) /x;
1224     /     \# [ \t]*   ( [^ \t] .* ) /x;
1225
1226 Which one you pick depends on which of these expressions better reflects
1227 the above specification of comments.
1228
1229 In some literature this construct is called "atomic matching" or
1230 "possessive matching".
1231
1232 Possessive quantifiers are equivalent to putting the item they are applied
1233 to inside of one of these constructs. The following equivalences apply:
1234
1235     Quantifier Form     Bracketing Form
1236     ---------------     ---------------
1237     PAT*+               (?>PAT*)
1238     PAT++               (?>PAT+)
1239     PAT?+               (?>PAT?)
1240     PAT{min,max}+       (?>PAT{min,max})
1241
1242 =back
1243
1244 =head2 Special Backtracking Control Verbs
1245
1246 B<WARNING:> These patterns are experimental and subject to change or
1247 removal in a future version of Perl. Their usage in production code should
1248 be noted to avoid problems during upgrades.
1249
1250 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1251 otherwise stated the ARG argument is optional; in some cases, it is
1252 forbidden.
1253
1254 Any pattern containing a special backtracking verb that allows an argument
1255 has the special behaviour that when executed it sets the current package's
1256 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1257 rules apply:
1258
1259 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1260 verb pattern, if the verb was involved in the failure of the match. If the
1261 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1262 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1263 none. Also, the C<$REGMARK> variable will be set to FALSE.
1264
1265 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1266 the C<$REGMARK> variable will be set to the name of the last
1267 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1268 C<(*MARK:NAME)> verb below for more details.
1269
1270 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1271 and most other regex related variables. They are not local to a scope, nor
1272 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1273 Use C<local> to localize changes to them to a specific scope if necessary.
1274
1275 If a pattern does not contain a special backtracking verb that allows an
1276 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1277
1278 =over 4
1279
1280 =item Verbs that take an argument
1281
1282 =over 4
1283
1284 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1285 X<(*PRUNE)> X<(*PRUNE:NAME)>
1286
1287 This zero-width pattern prunes the backtracking tree at the current point
1288 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1289 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1290 A may backtrack as necessary to match. Once it is reached, matching
1291 continues in B, which may also backtrack as necessary; however, should B
1292 not match, then no further backtracking will take place, and the pattern
1293 will fail outright at the current starting position.
1294
1295 The following example counts all the possible matching strings in a
1296 pattern (without actually matching any of them).
1297
1298     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1299     print "Count=$count\n";
1300
1301 which produces:
1302
1303     aaab
1304     aaa
1305     aa
1306     a
1307     aab
1308     aa
1309     a
1310     ab
1311     a
1312     Count=9
1313
1314 If we add a C<(*PRUNE)> before the count like the following
1315
1316     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1317     print "Count=$count\n";
1318
1319 we prevent backtracking and find the count of the longest matching
1320 at each matching starting point like so:
1321
1322     aaab
1323     aab
1324     ab
1325     Count=3
1326
1327 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1328
1329 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1330 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1331 replaced with a C<< (?>pattern) >> with no functional difference; however,
1332 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1333 C<< (?>pattern) >> alone.
1334
1335
1336 =item C<(*SKIP)> C<(*SKIP:NAME)>
1337 X<(*SKIP)>
1338
1339 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1340 failure it also signifies that whatever text that was matched leading up
1341 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1342 of this pattern. This effectively means that the regex engine "skips" forward
1343 to this position on failure and tries to match again, (assuming that
1344 there is sufficient room to match).
1345
1346 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1347 C<(*MARK:NAME)> was encountered while matching, then it is that position
1348 which is used as the "skip point". If no C<(*MARK)> of that name was
1349 encountered, then the C<(*SKIP)> operator has no effect. When used
1350 without a name the "skip point" is where the match point was when
1351 executing the (*SKIP) pattern.
1352
1353 Compare the following to the examples in C<(*PRUNE)>, note the string
1354 is twice as long:
1355
1356     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1357     print "Count=$count\n";
1358
1359 outputs
1360
1361     aaab
1362     aaab
1363     Count=2
1364
1365 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1366 executed, the next starting point will be where the cursor was when the
1367 C<(*SKIP)> was executed.
1368
1369 =item C<(*MARK:NAME)> C<(*:NAME)>
1370 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1371
1372 This zero-width pattern can be used to mark the point reached in a string
1373 when a certain part of the pattern has been successfully matched. This
1374 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1375 forward to that point if backtracked into on failure. Any number of
1376 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1377
1378 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1379 can be used to "label" a pattern branch, so that after matching, the
1380 program can determine which branches of the pattern were involved in the
1381 match.
1382
1383 When a match is successful, the C<$REGMARK> variable will be set to the
1384 name of the most recently executed C<(*MARK:NAME)> that was involved
1385 in the match.
1386
1387 This can be used to determine which branch of a pattern was matched
1388 without using a separate capture group for each branch, which in turn
1389 can result in a performance improvement, as perl cannot optimize
1390 C</(?:(x)|(y)|(z))/> as efficiently as something like
1391 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1392
1393 When a match has failed, and unless another verb has been involved in
1394 failing the match and has provided its own name to use, the C<$REGERROR>
1395 variable will be set to the name of the most recently executed
1396 C<(*MARK:NAME)>.
1397
1398 See C<(*SKIP)> for more details.
1399
1400 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1401
1402 =item C<(*THEN)> C<(*THEN:NAME)>
1403
1404 This is similar to the "cut group" operator C<::> from Perl 6. Like
1405 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1406 failure, it causes the regex engine to try the next alternation in the
1407 innermost enclosing group (capturing or otherwise).
1408
1409 Its name comes from the observation that this operation combined with the
1410 alternation operator (C<|>) can be used to create what is essentially a
1411 pattern-based if/then/else block:
1412
1413   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1414
1415 Note that if this operator is used and NOT inside of an alternation then
1416 it acts exactly like the C<(*PRUNE)> operator.
1417
1418   / A (*PRUNE) B /
1419
1420 is the same as
1421
1422   / A (*THEN) B /
1423
1424 but
1425
1426   / ( A (*THEN) B | C (*THEN) D ) /
1427
1428 is not the same as
1429
1430   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1431
1432 as after matching the A but failing on the B the C<(*THEN)> verb will
1433 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1434
1435 =item C<(*COMMIT)>
1436 X<(*COMMIT)>
1437
1438 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1439 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1440 into on failure it causes the match to fail outright. No further attempts
1441 to find a valid match by advancing the start pointer will occur again.
1442 For example,
1443
1444     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1445     print "Count=$count\n";
1446
1447 outputs
1448
1449     aaab
1450     Count=1
1451
1452 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1453 does not match, the regex engine will not try any further matching on the
1454 rest of the string.
1455
1456 =back
1457
1458 =item Verbs without an argument
1459
1460 =over 4
1461
1462 =item C<(*FAIL)> C<(*F)>
1463 X<(*FAIL)> X<(*F)>
1464
1465 This pattern matches nothing and always fails. It can be used to force the
1466 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1467 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1468
1469 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1470
1471 =item C<(*ACCEPT)>
1472 X<(*ACCEPT)>
1473
1474 B<WARNING:> This feature is highly experimental. It is not recommended
1475 for production code.
1476
1477 This pattern matches nothing and causes the end of successful matching at
1478 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1479 whether there is actually more to match in the string. When inside of a
1480 nested pattern, such as recursion, or in a subpattern dynamically generated
1481 via C<(??{})>, only the innermost pattern is ended immediately.
1482
1483 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1484 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1485 For instance:
1486
1487   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1488
1489 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1490 be set. If another branch in the inner parentheses were matched, such as in the
1491 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1492
1493 =back
1494
1495 =back
1496
1497 =head2 Backtracking
1498 X<backtrack> X<backtracking>
1499
1500 NOTE: This section presents an abstract approximation of regular
1501 expression behavior.  For a more rigorous (and complicated) view of
1502 the rules involved in selecting a match among possible alternatives,
1503 see L<Combining RE Pieces>.
1504
1505 A fundamental feature of regular expression matching involves the
1506 notion called I<backtracking>, which is currently used (when needed)
1507 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1508 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1509 internally, but the general principle outlined here is valid.
1510
1511 For a regular expression to match, the I<entire> regular expression must
1512 match, not just part of it.  So if the beginning of a pattern containing a
1513 quantifier succeeds in a way that causes later parts in the pattern to
1514 fail, the matching engine backs up and recalculates the beginning
1515 part--that's why it's called backtracking.
1516
1517 Here is an example of backtracking:  Let's say you want to find the
1518 word following "foo" in the string "Food is on the foo table.":
1519
1520     $_ = "Food is on the foo table.";
1521     if ( /\b(foo)\s+(\w+)/i ) {
1522         print "$2 follows $1.\n";
1523     }
1524
1525 When the match runs, the first part of the regular expression (C<\b(foo)>)
1526 finds a possible match right at the beginning of the string, and loads up
1527 $1 with "Foo".  However, as soon as the matching engine sees that there's
1528 no whitespace following the "Foo" that it had saved in $1, it realizes its
1529 mistake and starts over again one character after where it had the
1530 tentative match.  This time it goes all the way until the next occurrence
1531 of "foo". The complete regular expression matches this time, and you get
1532 the expected output of "table follows foo."
1533
1534 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1535 everything between "foo" and "bar".  Initially, you write something
1536 like this:
1537
1538     $_ =  "The food is under the bar in the barn.";
1539     if ( /foo(.*)bar/ ) {
1540         print "got <$1>\n";
1541     }
1542
1543 Which perhaps unexpectedly yields:
1544
1545   got <d is under the bar in the >
1546
1547 That's because C<.*> was greedy, so you get everything between the
1548 I<first> "foo" and the I<last> "bar".  Here it's more effective
1549 to use minimal matching to make sure you get the text between a "foo"
1550 and the first "bar" thereafter.
1551
1552     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1553   got <d is under the >
1554
1555 Here's another example. Let's say you'd like to match a number at the end
1556 of a string, and you also want to keep the preceding part of the match.
1557 So you write this:
1558
1559     $_ = "I have 2 numbers: 53147";
1560     if ( /(.*)(\d*)/ ) {                                # Wrong!
1561         print "Beginning is <$1>, number is <$2>.\n";
1562     }
1563
1564 That won't work at all, because C<.*> was greedy and gobbled up the
1565 whole string. As C<\d*> can match on an empty string the complete
1566 regular expression matched successfully.
1567
1568     Beginning is <I have 2 numbers: 53147>, number is <>.
1569
1570 Here are some variants, most of which don't work:
1571
1572     $_ = "I have 2 numbers: 53147";
1573     @pats = qw{
1574         (.*)(\d*)
1575         (.*)(\d+)
1576         (.*?)(\d*)
1577         (.*?)(\d+)
1578         (.*)(\d+)$
1579         (.*?)(\d+)$
1580         (.*)\b(\d+)$
1581         (.*\D)(\d+)$
1582     };
1583
1584     for $pat (@pats) {
1585         printf "%-12s ", $pat;
1586         if ( /$pat/ ) {
1587             print "<$1> <$2>\n";
1588         } else {
1589             print "FAIL\n";
1590         }
1591     }
1592
1593 That will print out:
1594
1595     (.*)(\d*)    <I have 2 numbers: 53147> <>
1596     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1597     (.*?)(\d*)   <> <>
1598     (.*?)(\d+)   <I have > <2>
1599     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1600     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1601     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1602     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1603
1604 As you see, this can be a bit tricky.  It's important to realize that a
1605 regular expression is merely a set of assertions that gives a definition
1606 of success.  There may be 0, 1, or several different ways that the
1607 definition might succeed against a particular string.  And if there are
1608 multiple ways it might succeed, you need to understand backtracking to
1609 know which variety of success you will achieve.
1610
1611 When using look-ahead assertions and negations, this can all get even
1612 trickier.  Imagine you'd like to find a sequence of non-digits not
1613 followed by "123".  You might try to write that as
1614
1615     $_ = "ABC123";
1616     if ( /^\D*(?!123)/ ) {                # Wrong!
1617         print "Yup, no 123 in $_\n";
1618     }
1619
1620 But that isn't going to match; at least, not the way you're hoping.  It
1621 claims that there is no 123 in the string.  Here's a clearer picture of
1622 why that pattern matches, contrary to popular expectations:
1623
1624     $x = 'ABC123';
1625     $y = 'ABC445';
1626
1627     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1628     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1629
1630     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1631     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1632
1633 This prints
1634
1635     2: got ABC
1636     3: got AB
1637     4: got ABC
1638
1639 You might have expected test 3 to fail because it seems to a more
1640 general purpose version of test 1.  The important difference between
1641 them is that test 3 contains a quantifier (C<\D*>) and so can use
1642 backtracking, whereas test 1 will not.  What's happening is
1643 that you've asked "Is it true that at the start of $x, following 0 or more
1644 non-digits, you have something that's not 123?"  If the pattern matcher had
1645 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1646 fail.
1647
1648 The search engine will initially match C<\D*> with "ABC".  Then it will
1649 try to match C<(?!123> with "123", which fails.  But because
1650 a quantifier (C<\D*>) has been used in the regular expression, the
1651 search engine can backtrack and retry the match differently
1652 in the hope of matching the complete regular expression.
1653
1654 The pattern really, I<really> wants to succeed, so it uses the
1655 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1656 time.  Now there's indeed something following "AB" that is not
1657 "123".  It's "C123", which suffices.
1658
1659 We can deal with this by using both an assertion and a negation.
1660 We'll say that the first part in $1 must be followed both by a digit
1661 and by something that's not "123".  Remember that the look-aheads
1662 are zero-width expressions--they only look, but don't consume any
1663 of the string in their match.  So rewriting this way produces what
1664 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1665
1666     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1667     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1668
1669     6: got ABC
1670
1671 In other words, the two zero-width assertions next to each other work as though
1672 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1673 matches only if you're at the beginning of the line AND the end of the
1674 line simultaneously.  The deeper underlying truth is that juxtaposition in
1675 regular expressions always means AND, except when you write an explicit OR
1676 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1677 although the attempted matches are made at different positions because "a"
1678 is not a zero-width assertion, but a one-width assertion.
1679
1680 B<WARNING>: Particularly complicated regular expressions can take
1681 exponential time to solve because of the immense number of possible
1682 ways they can use backtracking to try for a match.  For example, without
1683 internal optimizations done by the regular expression engine, this will
1684 take a painfully long time to run:
1685
1686     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1687
1688 And if you used C<*>'s in the internal groups instead of limiting them
1689 to 0 through 5 matches, then it would take forever--or until you ran
1690 out of stack space.  Moreover, these internal optimizations are not
1691 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1692 on the external group, no current optimization is applicable, and the
1693 match takes a long time to finish.
1694
1695 A powerful tool for optimizing such beasts is what is known as an
1696 "independent group",
1697 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1698 zero-length look-ahead/look-behind assertions will not backtrack to make
1699 the tail match, since they are in "logical" context: only
1700 whether they match is considered relevant.  For an example
1701 where side-effects of look-ahead I<might> have influenced the
1702 following match, see L<C<< (?>pattern) >>>.
1703
1704 =head2 Version 8 Regular Expressions
1705 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1706
1707 In case you're not familiar with the "regular" Version 8 regex
1708 routines, here are the pattern-matching rules not described above.
1709
1710 Any single character matches itself, unless it is a I<metacharacter>
1711 with a special meaning described here or above.  You can cause
1712 characters that normally function as metacharacters to be interpreted
1713 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1714 character; "\\" matches a "\"). This escape mechanism is also required
1715 for the character used as the pattern delimiter.
1716
1717 A series of characters matches that series of characters in the target
1718 string, so the pattern  C<blurfl> would match "blurfl" in the target
1719 string.
1720
1721 You can specify a character class, by enclosing a list of characters
1722 in C<[]>, which will match any character from the list.  If the
1723 first character after the "[" is "^", the class matches any character not
1724 in the list.  Within a list, the "-" character specifies a
1725 range, so that C<a-z> represents all characters between "a" and "z",
1726 inclusive.  If you want either "-" or "]" itself to be a member of a
1727 class, put it at the start of the list (possibly after a "^"), or
1728 escape it with a backslash.  "-" is also taken literally when it is
1729 at the end of the list, just before the closing "]".  (The
1730 following all specify the same class of three characters: C<[-az]>,
1731 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1732 specifies a class containing twenty-six characters, even on EBCDIC-based
1733 character sets.)  Also, if you try to use the character
1734 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1735 a range, the "-" is understood literally.
1736
1737 Note also that the whole range idea is rather unportable between
1738 character sets--and even within character sets they may cause results
1739 you probably didn't expect.  A sound principle is to use only ranges
1740 that begin from and end at either alphabetics of equal case ([a-e],
1741 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1742 spell out the character sets in full.
1743
1744 Characters may be specified using a metacharacter syntax much like that
1745 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1746 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1747 of octal digits, matches the character whose coded character set value
1748 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1749 matches the character whose numeric value is I<nn>. The expression \cI<x>
1750 matches the character control-I<x>.  Finally, the "." metacharacter
1751 matches any character except "\n" (unless you use C</s>).
1752
1753 You can specify a series of alternatives for a pattern using "|" to
1754 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1755 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1756 first alternative includes everything from the last pattern delimiter
1757 ("(", "[", or the beginning of the pattern) up to the first "|", and
1758 the last alternative contains everything from the last "|" to the next
1759 pattern delimiter.  That's why it's common practice to include
1760 alternatives in parentheses: to minimize confusion about where they
1761 start and end.
1762
1763 Alternatives are tried from left to right, so the first
1764 alternative found for which the entire expression matches, is the one that
1765 is chosen. This means that alternatives are not necessarily greedy. For
1766 example: when matching C<foo|foot> against "barefoot", only the "foo"
1767 part will match, as that is the first alternative tried, and it successfully
1768 matches the target string. (This might not seem important, but it is
1769 important when you are capturing matched text using parentheses.)
1770
1771 Also remember that "|" is interpreted as a literal within square brackets,
1772 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1773
1774 Within a pattern, you may designate subpatterns for later reference
1775 by enclosing them in parentheses, and you may refer back to the
1776 I<n>th subpattern later in the pattern using the metacharacter
1777 \I<n>.  Subpatterns are numbered based on the left to right order
1778 of their opening parenthesis.  A backreference matches whatever
1779 actually matched the subpattern in the string being examined, not
1780 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
1781 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1782 1 matched "0x", even though the rule C<0|0x> could potentially match
1783 the leading 0 in the second number.
1784
1785 =head2 Warning on \1 Instead of $1
1786
1787 Some people get too used to writing things like:
1788
1789     $pattern =~ s/(\W)/\\\1/g;
1790
1791 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
1792 shocking the
1793 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1794 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1795 the usual double-quoted string means a control-A.  The customary Unix
1796 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1797 of doing that, you get yourself into trouble if you then add an C</e>
1798 modifier.
1799
1800     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
1801
1802 Or if you try to do
1803
1804     s/(\d+)/\1000/;
1805
1806 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1807 C<${1}000>.  The operation of interpolation should not be confused
1808 with the operation of matching a backreference.  Certainly they mean two
1809 different things on the I<left> side of the C<s///>.
1810
1811 =head2 Repeated Patterns Matching a Zero-length Substring
1812
1813 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1814
1815 Regular expressions provide a terse and powerful programming language.  As
1816 with most other power tools, power comes together with the ability
1817 to wreak havoc.
1818
1819 A common abuse of this power stems from the ability to make infinite
1820 loops using regular expressions, with something as innocuous as:
1821
1822     'foo' =~ m{ ( o? )* }x;
1823
1824 The C<o?> matches at the beginning of C<'foo'>, and since the position
1825 in the string is not moved by the match, C<o?> would match again and again
1826 because of the C<*> quantifier.  Another common way to create a similar cycle
1827 is with the looping modifier C<//g>:
1828
1829     @matches = ( 'foo' =~ m{ o? }xg );
1830
1831 or
1832
1833     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1834
1835 or the loop implied by split().
1836
1837 However, long experience has shown that many programming tasks may
1838 be significantly simplified by using repeated subexpressions that
1839 may match zero-length substrings.  Here's a simple example being:
1840
1841     @chars = split //, $string;                  # // is not magic in split
1842     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1843
1844 Thus Perl allows such constructs, by I<forcefully breaking
1845 the infinite loop>.  The rules for this are different for lower-level
1846 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1847 ones like the C</g> modifier or split() operator.
1848
1849 The lower-level loops are I<interrupted> (that is, the loop is
1850 broken) when Perl detects that a repeated expression matched a
1851 zero-length substring.   Thus
1852
1853    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1854
1855 is made equivalent to
1856
1857    m{   (?: NON_ZERO_LENGTH )*
1858       |
1859         (?: ZERO_LENGTH )?
1860     }x;
1861
1862 The higher level-loops preserve an additional state between iterations:
1863 whether the last match was zero-length.  To break the loop, the following
1864 match after a zero-length match is prohibited to have a length of zero.
1865 This prohibition interacts with backtracking (see L<"Backtracking">),
1866 and so the I<second best> match is chosen if the I<best> match is of
1867 zero length.
1868
1869 For example:
1870
1871     $_ = 'bar';
1872     s/\w??/<$&>/g;
1873
1874 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1875 match given by non-greedy C<??> is the zero-length match, and the I<second
1876 best> match is what is matched by C<\w>.  Thus zero-length matches
1877 alternate with one-character-long matches.
1878
1879 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1880 position one notch further in the string.
1881
1882 The additional state of being I<matched with zero-length> is associated with
1883 the matched string, and is reset by each assignment to pos().
1884 Zero-length matches at the end of the previous match are ignored
1885 during C<split>.
1886
1887 =head2 Combining RE Pieces
1888
1889 Each of the elementary pieces of regular expressions which were described
1890 before (such as C<ab> or C<\Z>) could match at most one substring
1891 at the given position of the input string.  However, in a typical regular
1892 expression these elementary pieces are combined into more complicated
1893 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1894 (in these examples C<S> and C<T> are regular subexpressions).
1895
1896 Such combinations can include alternatives, leading to a problem of choice:
1897 if we match a regular expression C<a|ab> against C<"abc">, will it match
1898 substring C<"a"> or C<"ab">?  One way to describe which substring is
1899 actually matched is the concept of backtracking (see L<"Backtracking">).
1900 However, this description is too low-level and makes you think
1901 in terms of a particular implementation.
1902
1903 Another description starts with notions of "better"/"worse".  All the
1904 substrings which may be matched by the given regular expression can be
1905 sorted from the "best" match to the "worst" match, and it is the "best"
1906 match which is chosen.  This substitutes the question of "what is chosen?"
1907 by the question of "which matches are better, and which are worse?".
1908
1909 Again, for elementary pieces there is no such question, since at most
1910 one match at a given position is possible.  This section describes the
1911 notion of better/worse for combining operators.  In the description
1912 below C<S> and C<T> are regular subexpressions.
1913
1914 =over 4
1915
1916 =item C<ST>
1917
1918 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1919 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1920 which can be matched by C<T>.
1921
1922 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1923 match than C<A'B'>.
1924
1925 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1926 C<B> is better match for C<T> than C<B'>.
1927
1928 =item C<S|T>
1929
1930 When C<S> can match, it is a better match than when only C<T> can match.
1931
1932 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1933 two matches for C<T>.
1934
1935 =item C<S{REPEAT_COUNT}>
1936
1937 Matches as C<SSS...S> (repeated as many times as necessary).
1938
1939 =item C<S{min,max}>
1940
1941 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1942
1943 =item C<S{min,max}?>
1944
1945 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1946
1947 =item C<S?>, C<S*>, C<S+>
1948
1949 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1950
1951 =item C<S??>, C<S*?>, C<S+?>
1952
1953 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1954
1955 =item C<< (?>S) >>
1956
1957 Matches the best match for C<S> and only that.
1958
1959 =item C<(?=S)>, C<(?<=S)>
1960
1961 Only the best match for C<S> is considered.  (This is important only if
1962 C<S> has capturing parentheses, and backreferences are used somewhere
1963 else in the whole regular expression.)
1964
1965 =item C<(?!S)>, C<(?<!S)>
1966
1967 For this grouping operator there is no need to describe the ordering, since
1968 only whether or not C<S> can match is important.
1969
1970 =item C<(??{ EXPR })>, C<(?PARNO)>
1971
1972 The ordering is the same as for the regular expression which is
1973 the result of EXPR, or the pattern contained by capture group PARNO.
1974
1975 =item C<(?(condition)yes-pattern|no-pattern)>
1976
1977 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1978 already determined.  The ordering of the matches is the same as for the
1979 chosen subexpression.
1980
1981 =back
1982
1983 The above recipes describe the ordering of matches I<at a given position>.
1984 One more rule is needed to understand how a match is determined for the
1985 whole regular expression: a match at an earlier position is always better
1986 than a match at a later position.
1987
1988 =head2 Creating Custom RE Engines
1989
1990 Overloaded constants (see L<overload>) provide a simple way to extend
1991 the functionality of the RE engine.
1992
1993 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1994 matches at a boundary between whitespace characters and non-whitespace
1995 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1996 at these positions, so we want to have each C<\Y|> in the place of the
1997 more complicated version.  We can create a module C<customre> to do
1998 this:
1999
2000     package customre;
2001     use overload;
2002
2003     sub import {
2004       shift;
2005       die "No argument to customre::import allowed" if @_;
2006       overload::constant 'qr' => \&convert;
2007     }
2008
2009     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2010
2011     # We must also take care of not escaping the legitimate \\Y|
2012     # sequence, hence the presence of '\\' in the conversion rules.
2013     my %rules = ( '\\' => '\\\\',
2014                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2015     sub convert {
2016       my $re = shift;
2017       $re =~ s{
2018                 \\ ( \\ | Y . )
2019               }
2020               { $rules{$1} or invalid($re,$1) }sgex;
2021       return $re;
2022     }
2023
2024 Now C<use customre> enables the new escape in constant regular
2025 expressions, i.e., those without any runtime variable interpolations.
2026 As documented in L<overload>, this conversion will work only over
2027 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2028 part of this regular expression needs to be converted explicitly
2029 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2030
2031     use customre;
2032     $re = <>;
2033     chomp $re;
2034     $re = customre::convert $re;
2035     /\Y|$re\Y|/;
2036
2037 =head1 PCRE/Python Support
2038
2039 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2040 to the regex syntax. While Perl programmers are encouraged to use the
2041 Perl specific syntax, the following are also accepted:
2042
2043 =over 4
2044
2045 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2046
2047 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2048
2049 =item C<< (?P=NAME) >>
2050
2051 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2052
2053 =item C<< (?P>NAME) >>
2054
2055 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2056
2057 =back
2058
2059 =head1 BUGS
2060
2061 There are numerous problems with case insensitive matching of characters
2062 outside the ASCII range, especially with those whose folds are multiple
2063 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2064
2065 In a bracketed character class with case insensitive matching, ranges only work
2066 for ASCII characters.  For example,
2067 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2068 doesn't match all the Russian upper and lower case letters.
2069
2070 Many regular expression constructs don't work on EBCDIC platforms.
2071
2072 This document varies from difficult to understand to completely
2073 and utterly opaque.  The wandering prose riddled with jargon is
2074 hard to fathom in several places.
2075
2076 This document needs a rewrite that separates the tutorial content
2077 from the reference content.
2078
2079 =head1 SEE ALSO
2080
2081 L<perlrequick>.
2082
2083 L<perlretut>.
2084
2085 L<perlop/"Regexp Quote-Like Operators">.
2086
2087 L<perlop/"Gory details of parsing quoted constructs">.
2088
2089 L<perlfaq6>.
2090
2091 L<perlfunc/pos>.
2092
2093 L<perllocale>.
2094
2095 L<perlebcdic>.
2096
2097 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2098 by O'Reilly and Associates.