This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Move the common Pod scanning code from installman and buildtoc to pod_lib.pl
[perl5.git] / installman
1 #!./perl -w
2 BEGIN {
3     @INC = qw(lib);
4
5     # This needs to be at BEGIN time, before any use of Config
6     require './install_lib.pl';
7 }
8 use strict;
9
10 use Getopt::Long;
11 use File::Path qw(mkpath);
12 use ExtUtils::Packlist;
13 use Pod::Man;
14 use vars qw(%opts $packlist);
15
16 require './Porting/pod_lib.pl';
17 my $state = get_pod_metadata();
18
19 $ENV{SHELL} = 'sh' if $^O eq 'os2';
20
21 my $patchlevel = substr($],3,2);
22 die "Patchlevel of perl ($patchlevel)",
23     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
24         if $patchlevel != $Config{'PERL_VERSION'};
25
26 my $usage =
27 "Usage:  installman --man1dir=/usr/wherever --man1ext=1
28                    --man3dir=/usr/wherever --man3ext=3
29                    --notify --verbose --silent --help
30         Defaults are:
31         man1dir = $Config{'installman1dir'};
32         man1ext = $Config{'man1ext'};
33         man3dir = $Config{'installman3dir'};
34         man3ext = $Config{'man3ext'};
35         --notify  (or -n) just lists commands that would be executed.
36         --verbose (or -V) report all progress.
37         --silent  (or -S) be silent. Only report errors.\n";
38
39 GetOptions( \%opts,
40             qw( man1dir=s man1ext=s man3dir=s man3ext=s
41                 destdir:s notify n help silent S verbose V))
42         || die $usage;
43 die $usage if $opts{help};
44 $opts{destdir} //= '';
45
46 foreach my $pre (qw(man1 man3)) {
47     $opts{"${pre}dir"} //= $opts{destdir} . $Config{"install${pre}dir"};
48     $opts{"${pre}ext"} //= $Config{"${pre}ext"};
49 }
50 $opts{silent} ||= $opts{S};
51 $opts{notify} ||= $opts{n};
52 $opts{verbose} ||= $opts{V} || $opts{notify};
53
54 #Sanity checks
55
56 -x  "./perl$Config{exe_ext}"
57   or warn "./perl$Config{exe_ext} not found!  Have you run make?\n";
58 -d  "$opts{destdir}$Config{'installprivlib'}"
59         || warn "Perl library directory $Config{'installprivlib'} not found.
60                 Have you run make install?.  (Installing anyway.)\n";
61 -x "t/perl$Config{exe_ext}"             || warn "WARNING: You've never run 'make test'!!!",
62         "  (Installing anyway.)\n";
63
64 $packlist = ExtUtils::Packlist->new("$opts{destdir}$Config{installarchlib}/.packlist");
65
66 # Install the main pod pages.
67 pod2man({
68          map {
69              ($_->[0], $_->[1])
70          } @{$state->{master}}
71         }, $opts{man1dir}, $opts{man1ext}, 'pod');
72
73 # Install the pods for library modules.
74 {
75     my $found = pods_to_install();
76     pod2man($found->{$_}, $opts{man3dir}, $opts{man3ext}, 'lib')
77         foreach qw(MODULE PRAGMA);
78 }
79
80 # Install the pods embedded in the installed scripts
81 my $has_man1dir = $opts{man1dir} ne '' && -d $opts{man1dir};
82 open UTILS, "utils.lst" or die "Can't open 'utils.lst': $!";
83 while (<UTILS>) {
84     next if /^#/;
85     chomp;
86     $_ = $1 if /#.*pod\s*=\s*(\S+)/;
87     my ($path, $leaf) = m|^(\S*/(\S+))|;
88     $leaf =~ s/\.pod\z//;
89     pod2man({$leaf, $path}, $opts{man1dir}, $opts{man1ext});
90     if ($has_man1dir) {
91         if (my ($link) = m|#.*link\s*=\s*\S+/(\S+)|) {
92             my $old = "$opts{man1dir}/$leaf.$opts{man1ext}";
93             my $new = "$opts{man1dir}/$link.$opts{man1ext}";
94             unlink($new);
95             link($old, $new);
96             my $xold = $old;
97             $xold =~ s/^\Q$opts{'destdir'}\E// if $opts{'destdir'};
98             my $xnew = $new;
99             $xnew =~ s/^\Q$opts{'destdir'}\E// if $opts{'destdir'};
100             $packlist->{$xnew} = { from => $xold, type => 'link' };
101         }
102     }
103 }
104
105 sub pod2man {
106     my($modpods, $mandir, $manext, $where) = @_;
107     if ($mandir eq ' ' or $mandir eq '') {
108         if ($where) {
109             warn "Skipping installation of $where man pages.\n"
110         } else {
111             warn "Skipping installation of $_ man page.\n"
112                 foreach values %$modpods;
113         }
114         return;
115     }
116
117     if ($opts{verbose}) {
118         if ($where) {
119             print "installing from $where\n";
120         } else {
121             print "installing $_\n"
122                 foreach sort keys %$modpods;
123         }
124     }
125
126     mkpath($mandir, $opts{verbose}, 0777) unless $opts{notify};  # In File::Path
127
128     foreach my $manpage (sort keys %$modpods) {
129         my $mod = $modpods->{$manpage};
130
131         # Skip files without pod docs
132         my $has_pod;
133         if (open T, $mod)
134         {
135             local $_;
136             while (<T>)
137             {
138                 ++$has_pod and last if /^=head1\b/;
139             }
140
141             close T;
142         }
143
144         unless ($has_pod)
145         {
146             warn "no documentation in $mod\n";
147             next;
148         }
149
150         if ($^O eq 'os2' || $^O eq 'amigaos' || $^O eq 'uwin' || $^O eq 'cygwin') {
151             $manpage =~ s#::#.#g;
152         }
153         my $tmp = "${mandir}/${manpage}.tmp";
154         $manpage = "${mandir}/${manpage}.${manext}";
155
156         my $parser = Pod::Man->new( section => $manext,
157                                     official=> 1,
158                                     center  => 'Perl Programmers Reference Guide'
159                                   );
160         my $xmanpage = $manpage;
161         $xmanpage =~ s/^\Q$opts{'destdir'}\E// if $opts{'destdir'};
162         print "  $xmanpage\n";
163         if (!$opts{notify} && $parser->parse_from_file($mod, $tmp)) {
164             if (-s $tmp) {
165                 if (rename($tmp, $manpage)) {
166                     $packlist->{$xmanpage} = { type => 'file' };
167                     next;
168                 }
169             }
170             unlink($tmp);
171         }
172     }
173 }
174
175 $packlist->write() unless $opts{notify};
176 print "  Installation complete\n" if $opts{verbose};
177
178 exit 0;
179
180 sub rename {
181     my($from,$to) = @_;
182     if (-f $to and not unlink($to)) {
183         my($i);
184         for ($i = 1; $i < 50; $i++) {
185             last if CORE::rename($to, "$to.$i");
186         }
187         warn("Cannot rename to '$to.$i': $!"), return 0
188             if $i >= 50;        # Give up!
189     }
190     link($from,$to) || return 0;
191     unlink($from);
192 }
193
194 # Local variables:
195 # cperl-indent-level: 4
196 # indent-tabs-mode: nil
197 # End:
198 #
199 # ex: set ts=8 sts=4 sw=4 et: