This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
9b1319a7a6c1899ba4af3595ace4d83a113393ae
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in S<C<2 + 4 * 5>>, the multiplication has higher
32 precedence so S<C<4 * 5>> is evaluated first yielding S<C<2 + 20 ==
33 22>> and not S<C<6 * 5 == 30>>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first, or the right first.  For example, in
38 S<C<8 - 4 - 2>>, subtraction is left associative so Perl evaluates the
39 expression left to right.  S<C<8 - 4>> is evaluated first making the
40 expression S<C<4 - 2 == 2>> and not S<C<8 - 2 == 6>>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in precedence order.
75
76 Many operators can be overloaded for objects.  See L<overload>.
77
78 =head2 Terms and List Operators (Leftward)
79 X<list operator> X<operator, list> X<term>
80
81 A TERM has the highest precedence in Perl.  They include variables,
82 quote and quote-like operators, any expression in parentheses,
83 and any function whose arguments are parenthesized.  Actually, there
84 aren't really functions in this sense, just list operators and unary
85 operators behaving as functions because you put parentheses around
86 the arguments.  These are all documented in L<perlfunc>.
87
88 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
89 is followed by a left parenthesis as the next token, the operator and
90 arguments within parentheses are taken to be of highest precedence,
91 just like a normal function call.
92
93 In the absence of parentheses, the precedence of list operators such as
94 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
95 whether you are looking at the left side or the right side of the operator.
96 For example, in
97
98     @ary = (1, 3, sort 4, 2);
99     print @ary;         # prints 1324
100
101 the commas on the right of the C<sort> are evaluated before the C<sort>,
102 but the commas on the left are evaluated after.  In other words,
103 list operators tend to gobble up all arguments that follow, and
104 then act like a simple TERM with regard to the preceding expression.
105 Be careful with parentheses:
106
107     # These evaluate exit before doing the print:
108     print($foo, exit);  # Obviously not what you want.
109     print $foo, exit;   # Nor is this.
110
111     # These do the print before evaluating exit:
112     (print $foo), exit; # This is what you want.
113     print($foo), exit;  # Or this.
114     print ($foo), exit; # Or even this.
115
116 Also note that
117
118     print ($foo & 255) + 1, "\n";
119
120 probably doesn't do what you expect at first glance.  The parentheses
121 enclose the argument list for C<print> which is evaluated (printing
122 the result of S<C<$foo & 255>>).  Then one is added to the return value
123 of C<print> (usually 1).  The result is something like this:
124
125     1 + 1, "\n";    # Obviously not what you meant.
126
127 To do what you meant properly, you must write:
128
129     print(($foo & 255) + 1, "\n");
130
131 See L<Named Unary Operators> for more discussion of this.
132
133 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
134 well as subroutine and method calls, and the anonymous
135 constructors C<[]> and C<{}>.
136
137 See also L<Quote and Quote-like Operators> toward the end of this section,
138 as well as L</"I/O Operators">.
139
140 =head2 The Arrow Operator
141 X<arrow> X<dereference> X<< -> >>
142
143 "C<< -> >>" is an infix dereference operator, just as it is in C
144 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
145 C<(...)> subscript, then the left side must be either a hard or
146 symbolic reference to an array, a hash, or a subroutine respectively.
147 (Or technically speaking, a location capable of holding a hard
148 reference, if it's an array or hash reference being used for
149 assignment.)  See L<perlreftut> and L<perlref>.
150
151 Otherwise, the right side is a method name or a simple scalar
152 variable containing either the method name or a subroutine reference,
153 and the left side must be either an object (a blessed reference)
154 or a class name (that is, a package name).  See L<perlobj>.
155
156 The dereferencing cases (as opposed to method-calling cases) are
157 somewhat extended by the C<postderef> feature.  For the
158 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
159
160 =head2 Auto-increment and Auto-decrement
161 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
162
163 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
164 they increment or decrement the variable by one before returning the
165 value, and if placed after, increment or decrement after returning the
166 value.
167
168     $i = 0;  $j = 0;
169     print $i++;  # prints 0
170     print ++$j;  # prints 1
171
172 Note that just as in C, Perl doesn't define B<when> the variable is
173 incremented or decremented.  You just know it will be done sometime
174 before or after the value is returned.  This also means that modifying
175 a variable twice in the same statement will lead to undefined behavior.
176 Avoid statements like:
177
178     $i = $i ++;
179     print ++ $i + $i ++;
180
181 Perl will not guarantee what the result of the above statements is.
182
183 The auto-increment operator has a little extra builtin magic to it.  If
184 you increment a variable that is numeric, or that has ever been used in
185 a numeric context, you get a normal increment.  If, however, the
186 variable has been used in only string contexts since it was set, and
187 has a value that is not the empty string and matches the pattern
188 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
189 character within its range, with carry:
190
191     print ++($foo = "99");      # prints "100"
192     print ++($foo = "a0");      # prints "a1"
193     print ++($foo = "Az");      # prints "Ba"
194     print ++($foo = "zz");      # prints "aaa"
195
196 C<undef> is always treated as numeric, and in particular is changed
197 to C<0> before incrementing (so that a post-increment of an undef value
198 will return C<0> rather than C<undef>).
199
200 The auto-decrement operator is not magical.
201
202 =head2 Exponentiation
203 X<**> X<exponentiation> X<power>
204
205 Binary C<"**"> is the exponentiation operator.  It binds even more
206 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
207 (This is
208 implemented using C's C<pow(3)> function, which actually works on doubles
209 internally.)
210
211 Note that certain exponentiation expressions are ill-defined:
212 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
213 any particular results from these special cases, the results
214 are platform-dependent.
215
216 =head2 Symbolic Unary Operators
217 X<unary operator> X<operator, unary>
218
219 Unary C<"!"> performs logical negation, that is, "not".  See also C<not> for a lower
220 precedence version of this.
221 X<!>
222
223 Unary C<"-"> performs arithmetic negation if the operand is numeric,
224 including any string that looks like a number.  If the operand is
225 an identifier, a string consisting of a minus sign concatenated
226 with the identifier is returned.  Otherwise, if the string starts
227 with a plus or minus, a string starting with the opposite sign is
228 returned.  One effect of these rules is that C<-bareword> is equivalent
229 to the string C<"-bareword">.  If, however, the string begins with a
230 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
231 to convert
232 the string to a numeric, and the arithmetic negation is performed.  If the
233 string cannot be cleanly converted to a numeric, Perl will give the warning
234 B<Argument "the string" isn't numeric in negation (-) at ...>.
235 X<-> X<negation, arithmetic>
236
237 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
238 example, S<C<0666 & ~027>> is 0640.  (See also L<Integer Arithmetic> and
239 L<Bitwise String Operators>.)  Note that the width of the result is
240 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
241 bits wide on a 64-bit platform, so if you are expecting a certain bit
242 width, remember to use the C<"&"> operator to mask off the excess bits.
243 X<~> X<negation, binary>
244
245 When complementing strings, if all characters have ordinal values under
246 256, then their complements will, also.  But if they do not, all
247 characters will be in either 32- or 64-bit complements, depending on your
248 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
249 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
250
251 If the experimental "bitwise" feature is enabled via S<C<use feature
252 'bitwise'>>, then unary C<"~"> always treats its argument as a number, and an
253 alternate form of the operator, C<"~.">, always treats its argument as a
254 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
255 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  This feature
256 produces a warning unless you use S<C<no warnings 'experimental::bitwise'>>.
257
258 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
259 syntactically for separating a function name from a parenthesized expression
260 that would otherwise be interpreted as the complete list of function
261 arguments.  (See examples above under L</Terms and List Operators (Leftward)>.)
262 X<+>
263
264 Unary C<"\"> creates a reference to whatever follows it.  See L<perlreftut>
265 and L<perlref>.  Do not confuse this behavior with the behavior of
266 backslash within a string, although both forms do convey the notion
267 of protecting the next thing from interpolation.
268 X<\> X<reference> X<backslash>
269
270 =head2 Binding Operators
271 X<binding> X<operator, binding> X<=~> X<!~>
272
273 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
274 search or modify the string C<$_> by default.  This operator makes that kind
275 of operation work on some other string.  The right argument is a search
276 pattern, substitution, or transliteration.  The left argument is what is
277 supposed to be searched, substituted, or transliterated instead of the default
278 C<$_>.  When used in scalar context, the return value generally indicates the
279 success of the operation.  The exceptions are substitution (C<s///>)
280 and transliteration (C<y///>) with the C</r> (non-destructive) option,
281 which cause the B<r>eturn value to be the result of the substitution.
282 Behavior in list context depends on the particular operator.
283 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
284 examples using these operators.
285
286 If the right argument is an expression rather than a search pattern,
287 substitution, or transliteration, it is interpreted as a search pattern at run
288 time.  Note that this means that its
289 contents will be interpolated twice, so
290
291     '\\' =~ q'\\';
292
293 is not ok, as the regex engine will end up trying to compile the
294 pattern C<\>, which it will consider a syntax error.
295
296 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
297 the logical sense.
298
299 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
300 (C<y///r>) is a syntax error.
301
302 =head2 Multiplicative Operators
303 X<operator, multiplicative>
304
305 Binary C<"*"> multiplies two numbers.
306 X<*>
307
308 Binary C<"/"> divides two numbers.
309 X</> X<slash>
310
311 Binary C<"%"> is the modulo operator, which computes the division
312 remainder of its first argument with respect to its second argument.
313 Given integer
314 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
315 C<$m> minus the largest multiple of C<$n> less than or equal to
316 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
317 smallest multiple of C<$n> that is not less than C<$m> (that is, the
318 result will be less than or equal to zero).  If the operands
319 C<$m> and C<$n> are floating point values and the absolute value of
320 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
321 the integer portion of C<$m> and C<$n> will be used in the operation
322 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
323 If the absolute value of the right operand (C<abs($n)>) is greater than
324 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
325 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
326 integer that makes C<$r> have the same sign as the right operand
327 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
328 and the absolute value less than that of C<$n>.
329 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
330 to the modulo operator as implemented by your C compiler.  This
331 operator is not as well defined for negative operands, but it will
332 execute faster.
333 X<%> X<remainder> X<modulo> X<mod>
334
335 Binary C<"x"> is the repetition operator.  In scalar context or if the left
336 operand is not enclosed in parentheses, it returns a string consisting
337 of the left operand repeated the number of times specified by the right
338 operand.  In list context, if the left operand is enclosed in
339 parentheses or is a list formed by C<qw/I<STRING>/>, it repeats the list.
340 If the right operand is zero or negative (raising a warning on
341 negative), it returns an empty string
342 or an empty list, depending on the context.
343 X<x>
344
345     print '-' x 80;             # print row of dashes
346
347     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
348
349     @ones = (1) x 80;           # a list of 80 1's
350     @ones = (5) x @ones;        # set all elements to 5
351
352
353 =head2 Additive Operators
354 X<operator, additive>
355
356 Binary C<"+"> returns the sum of two numbers.
357 X<+>
358
359 Binary C<"-"> returns the difference of two numbers.
360 X<->
361
362 Binary C<"."> concatenates two strings.
363 X<string, concatenation> X<concatenation>
364 X<cat> X<concat> X<concatenate> X<.>
365
366 =head2 Shift Operators
367 X<shift operator> X<operator, shift> X<<< << >>>
368 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
369 X<shl> X<shr> X<shift, right> X<shift, left>
370
371 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
372 number of bits specified by the right argument.  Arguments should be
373 integers.  (See also L<Integer Arithmetic>.)
374
375 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
376 the number of bits specified by the right argument.  Arguments should
377 be integers.  (See also L<Integer Arithmetic>.)
378
379 If S<C<use integer>> (see L<Integer Arithmetic>) is in force then
380 signed C integers are used (I<arithmetic shift>), otherwise unsigned C
381 integers are used (I<logical shift>), even for negative shiftees.
382 In arithmetic right shift the sign bit is replicated on the left,
383 in logical shift zero bits come in from the left.
384
385 Either way, the implementation isn't going to generate results larger
386 than the size of the integer type Perl was built with (32 bits or 64 bits).
387
388 Shifting by negative number of bits means the reverse shift: left
389 shift becomes right shift, right shift becomes left shift.  This is
390 unlike in C, where negative shift is undefined.
391
392 Shifting by more bits than the size of the integers means most of the
393 time zero (all bits fall off), except that under S<C<use integer>>
394 right overshifting a negative shiftee results in -1.  This is unlike
395 in C, where shifting by too many bits is undefined.  A common C
396 behavior is "shift by modulo wordbits", so that for example
397
398     1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1  # Common C behavior.
399
400 but that is completely accidental.
401
402 If you get tired of being subject to your platform's native integers,
403 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
404
405     print 20 << 20;  # 20971520
406     print 20 << 40;  # 5120 on 32-bit machines, 
407                      # 21990232555520 on 64-bit machines
408     use bigint;
409     print 20 << 100; # 25353012004564588029934064107520
410
411 =head2 Named Unary Operators
412 X<operator, named unary>
413
414 The various named unary operators are treated as functions with one
415 argument, with optional parentheses.
416
417 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
418 is followed by a left parenthesis as the next token, the operator and
419 arguments within parentheses are taken to be of highest precedence,
420 just like a normal function call.  For example,
421 because named unary operators are higher precedence than C<||>:
422
423     chdir $foo    || die;       # (chdir $foo) || die
424     chdir($foo)   || die;       # (chdir $foo) || die
425     chdir ($foo)  || die;       # (chdir $foo) || die
426     chdir +($foo) || die;       # (chdir $foo) || die
427
428 but, because C<"*"> is higher precedence than named operators:
429
430     chdir $foo * 20;    # chdir ($foo * 20)
431     chdir($foo) * 20;   # (chdir $foo) * 20
432     chdir ($foo) * 20;  # (chdir $foo) * 20
433     chdir +($foo) * 20; # chdir ($foo * 20)
434
435     rand 10 * 20;       # rand (10 * 20)
436     rand(10) * 20;      # (rand 10) * 20
437     rand (10) * 20;     # (rand 10) * 20
438     rand +(10) * 20;    # rand (10 * 20)
439
440 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
441 treated like named unary operators, but they don't follow this functional
442 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
443 equivalent to S<C<-f "$file.bak">>.
444 X<-X> X<filetest> X<operator, filetest>
445
446 See also L<"Terms and List Operators (Leftward)">.
447
448 =head2 Relational Operators
449 X<relational operator> X<operator, relational>
450
451 Perl operators that return true or false generally return values 
452 that can be safely used as numbers.  For example, the relational
453 operators in this section and the equality operators in the next
454 one return C<1> for true and a special version of the defined empty
455 string, C<"">, which counts as a zero but is exempt from warnings
456 about improper numeric conversions, just as S<C<"0 but true">> is.
457
458 Binary C<< "<" >> returns true if the left argument is numerically less than
459 the right argument.
460 X<< < >>
461
462 Binary C<< ">" >> returns true if the left argument is numerically greater
463 than the right argument.
464 X<< > >>
465
466 Binary C<< "<=" >> returns true if the left argument is numerically less than
467 or equal to the right argument.
468 X<< <= >>
469
470 Binary C<< ">=" >> returns true if the left argument is numerically greater
471 than or equal to the right argument.
472 X<< >= >>
473
474 Binary C<"lt"> returns true if the left argument is stringwise less than
475 the right argument.
476 X<< lt >>
477
478 Binary C<"gt"> returns true if the left argument is stringwise greater
479 than the right argument.
480 X<< gt >>
481
482 Binary C<"le"> returns true if the left argument is stringwise less than
483 or equal to the right argument.
484 X<< le >>
485
486 Binary C<"ge"> returns true if the left argument is stringwise greater
487 than or equal to the right argument.
488 X<< ge >>
489
490 =head2 Equality Operators
491 X<equality> X<equal> X<equals> X<operator, equality>
492
493 Binary C<< "==" >> returns true if the left argument is numerically equal to
494 the right argument.
495 X<==>
496
497 Binary C<< "!=" >> returns true if the left argument is numerically not equal
498 to the right argument.
499 X<!=>
500
501 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
502 argument is numerically less than, equal to, or greater than the right
503 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
504 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
505 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
506 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
507 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
508 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
509 X<< <=> >>
510 X<spaceship>
511
512     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
513     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
514
515 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
516 support C<"NaN">.)
517
518 Binary C<"eq"> returns true if the left argument is stringwise equal to
519 the right argument.
520 X<eq>
521
522 Binary C<"ne"> returns true if the left argument is stringwise not equal
523 to the right argument.
524 X<ne>
525
526 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
527 argument is stringwise less than, equal to, or greater than the right
528 argument.
529 X<cmp>
530
531 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
532 is described in the next section.
533 X<~~>
534
535 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
536 order specified by the current C<LC_COLLATE> locale if a S<C<use
537 locale>> form that includes collation is in effect.  See L<perllocale>.
538 Do not mix these with Unicode,
539 only use them with legacy 8-bit locale encodings.
540 The standard C<L<Unicode::Collate>> and
541 C<L<Unicode::Collate::Locale>> modules offer much more powerful
542 solutions to collation issues.
543
544 For case-insensitive comparisions, look at the L<perlfunc/fc> case-folding
545 function, available in Perl v5.16 or later:
546
547     if ( fc($x) eq fc($y) ) { ... }
548
549 =head2 Smartmatch Operator
550
551 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
552 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
553 used implicitly in the C<when> construct described in L<perlsyn>, although
554 not all C<when> clauses call the smartmatch operator.  Unique among all of
555 Perl's operators, the smartmatch operator can recurse.  The smartmatch
556 operator is L<experimental|perlpolicy/experimental> and its behavior is
557 subject to change.
558
559 It is also unique in that all other Perl operators impose a context
560 (usually string or numeric context) on their operands, autoconverting
561 those operands to those imposed contexts.  In contrast, smartmatch
562 I<infers> contexts from the actual types of its operands and uses that
563 type information to select a suitable comparison mechanism.
564
565 The C<~~> operator compares its operands "polymorphically", determining how
566 to compare them according to their actual types (numeric, string, array,
567 hash, etc.)  Like the equality operators with which it shares the same
568 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
569 read aloud as "in", "inside of", or "is contained in", because the left
570 operand is often looked for I<inside> the right operand.  That makes the
571 order of the operands to the smartmatch operand often opposite that of
572 the regular match operator.  In other words, the "smaller" thing is usually
573 placed in the left operand and the larger one in the right.
574
575 The behavior of a smartmatch depends on what type of things its arguments
576 are, as determined by the following table.  The first row of the table
577 whose types apply determines the smartmatch behavior.  Because what
578 actually happens is mostly determined by the type of the second operand,
579 the table is sorted on the right operand instead of on the left.
580
581  Left      Right      Description and pseudocode                               
582  ===============================================================
583  Any       undef      check whether Any is undefined                    
584                 like: !defined Any
585
586  Any       Object     invoke ~~ overloading on Object, or die
587
588  Right operand is an ARRAY:
589
590  Left      Right      Description and pseudocode                               
591  ===============================================================
592  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
593                 like: (ARRAY1[0] ~~ ARRAY2[0])
594                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
595  HASH      ARRAY      any ARRAY elements exist as HASH keys             
596                 like: grep { exists HASH->{$_} } ARRAY
597  Regexp    ARRAY      any ARRAY elements pattern match Regexp
598                 like: grep { /Regexp/ } ARRAY
599  undef     ARRAY      undef in ARRAY                                    
600                 like: grep { !defined } ARRAY
601  Any       ARRAY      smartmatch each ARRAY element[3]                   
602                 like: grep { Any ~~ $_ } ARRAY
603
604  Right operand is a HASH:
605
606  Left      Right      Description and pseudocode                               
607  ===============================================================
608  HASH1     HASH2      all same keys in both HASHes                      
609                 like: keys HASH1 ==
610                          grep { exists HASH2->{$_} } keys HASH1
611  ARRAY     HASH       any ARRAY elements exist as HASH keys             
612                 like: grep { exists HASH->{$_} } ARRAY
613  Regexp    HASH       any HASH keys pattern match Regexp                
614                 like: grep { /Regexp/ } keys HASH
615  undef     HASH       always false (undef can't be a key)               
616                 like: 0 == 1
617  Any       HASH       HASH key existence                                
618                 like: exists HASH->{Any}
619
620  Right operand is CODE:
621
622  Left      Right      Description and pseudocode                               
623  ===============================================================
624  ARRAY     CODE       sub returns true on all ARRAY elements[1]
625                 like: !grep { !CODE->($_) } ARRAY
626  HASH      CODE       sub returns true on all HASH keys[1]
627                 like: !grep { !CODE->($_) } keys HASH
628  Any       CODE       sub passed Any returns true              
629                 like: CODE->(Any)
630
631 Right operand is a Regexp:
632
633  Left      Right      Description and pseudocode                               
634  ===============================================================
635  ARRAY     Regexp     any ARRAY elements match Regexp                   
636                 like: grep { /Regexp/ } ARRAY
637  HASH      Regexp     any HASH keys match Regexp                        
638                 like: grep { /Regexp/ } keys HASH
639  Any       Regexp     pattern match                                     
640                 like: Any =~ /Regexp/
641
642  Other:
643
644  Left      Right      Description and pseudocode                               
645  ===============================================================
646  Object    Any        invoke ~~ overloading on Object,
647                       or fall back to...
648
649  Any       Num        numeric equality                                  
650                  like: Any == Num
651  Num       nummy[4]    numeric equality
652                  like: Num == nummy
653  undef     Any        check whether undefined
654                  like: !defined(Any)
655  Any       Any        string equality                                   
656                  like: Any eq Any
657
658
659 Notes:
660
661 =over
662
663 =item 1.
664 Empty hashes or arrays match. 
665
666 =item 2.
667 That is, each element smartmatches the element of the same index in the other array.[3]
668
669 =item 3.
670 If a circular reference is found, fall back to referential equality. 
671
672 =item 4.
673 Either an actual number, or a string that looks like one.
674
675 =back
676
677 The smartmatch implicitly dereferences any non-blessed hash or array
678 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
679 For blessed references, the C<I<Object>> entries apply.  Smartmatches
680 involving hashes only consider hash keys, never hash values.
681
682 The "like" code entry is not always an exact rendition.  For example, the
683 smartmatch operator short-circuits whenever possible, but C<grep> does
684 not.  Also, C<grep> in scalar context returns the number of matches, but
685 C<~~> returns only true or false.
686
687 Unlike most operators, the smartmatch operator knows to treat C<undef>
688 specially:
689
690     use v5.10.1;
691     @array = (1, 2, 3, undef, 4, 5);
692     say "some elements undefined" if undef ~~ @array;
693
694 Each operand is considered in a modified scalar context, the modification
695 being that array and hash variables are passed by reference to the
696 operator, which implicitly dereferences them.  Both elements
697 of each pair are the same:
698
699     use v5.10.1;
700
701     my %hash = (red    => 1, blue   => 2, green  => 3,
702                 orange => 4, yellow => 5, purple => 6,
703                 black  => 7, grey   => 8, white  => 9);
704
705     my @array = qw(red blue green);
706
707     say "some array elements in hash keys" if  @array ~~  %hash;
708     say "some array elements in hash keys" if \@array ~~ \%hash;
709
710     say "red in array" if "red" ~~  @array;
711     say "red in array" if "red" ~~ \@array;
712
713     say "some keys end in e" if /e$/ ~~  %hash;
714     say "some keys end in e" if /e$/ ~~ \%hash;
715
716 Two arrays smartmatch if each element in the first array smartmatches
717 (that is, is "in") the corresponding element in the second array,
718 recursively.
719
720     use v5.10.1;
721     my @little = qw(red blue green);
722     my @bigger = ("red", "blue", [ "orange", "green" ] );
723     if (@little ~~ @bigger) {  # true!
724         say "little is contained in bigger";
725     } 
726
727 Because the smartmatch operator recurses on nested arrays, this
728 will still report that "red" is in the array.
729
730     use v5.10.1;
731     my @array = qw(red blue green);
732     my $nested_array = [[[[[[[ @array ]]]]]]];
733     say "red in array" if "red" ~~ $nested_array;
734
735 If two arrays smartmatch each other, then they are deep
736 copies of each others' values, as this example reports:
737
738     use v5.12.0;
739     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
740     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
741
742     if (@a ~~ @b && @b ~~ @a) {
743         say "a and b are deep copies of each other";
744     } 
745     elsif (@a ~~ @b) {
746         say "a smartmatches in b";
747     } 
748     elsif (@b ~~ @a) {
749         say "b smartmatches in a";
750     } 
751     else {
752         say "a and b don't smartmatch each other at all";
753     } 
754
755
756 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
757 are deep copies of each other", it now reports that C<"b smartmatches in a">.
758 That's because the corresponding position in C<@a> contains an array that
759 (eventually) has a 4 in it.
760
761 Smartmatching one hash against another reports whether both contain the
762 same keys, no more and no less.  This could be used to see whether two
763 records have the same field names, without caring what values those fields
764 might have.  For example:
765
766     use v5.10.1;
767     sub make_dogtag {
768         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
769
770         my ($class, $init_fields) = @_;
771
772         die "Must supply (only) name, rank, and serial number"
773             unless $init_fields ~~ $REQUIRED_FIELDS;
774
775         ...
776     }
777
778 However, this only does what you mean if C<$init_fields> is indeed a hash
779 reference. The condition C<$init_fields ~~ $REQUIRED_FIELDS> also allows the
780 strings C<"name">, C<"rank">, C<"serial_num"> as well as any array reference
781 that contains C<"name"> or C<"rank"> or C<"serial_num"> anywhere to pass
782 through.
783
784 The smartmatch operator is most often used as the implicit operator of a
785 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
786
787 =head3 Smartmatching of Objects
788
789 To avoid relying on an object's underlying representation, if the
790 smartmatch's right operand is an object that doesn't overload C<~~>,
791 it raises the exception "C<Smartmatching a non-overloaded object
792 breaks encapsulation>".  That's because one has no business digging
793 around to see whether something is "in" an object.  These are all
794 illegal on objects without a C<~~> overload:
795
796     %hash ~~ $object
797        42 ~~ $object
798    "fred" ~~ $object
799
800 However, you can change the way an object is smartmatched by overloading
801 the C<~~> operator.  This is allowed to
802 extend the usual smartmatch semantics.
803 For objects that do have an C<~~> overload, see L<overload>.
804
805 Using an object as the left operand is allowed, although not very useful.
806 Smartmatching rules take precedence over overloading, so even if the
807 object in the left operand has smartmatch overloading, this will be
808 ignored.  A left operand that is a non-overloaded object falls back on a
809 string or numeric comparison of whatever the C<ref> operator returns.  That
810 means that
811
812     $object ~~ X
813
814 does I<not> invoke the overload method with C<I<X>> as an argument.
815 Instead the above table is consulted as normal, and based on the type of
816 C<I<X>>, overloading may or may not be invoked.  For simple strings or
817 numbers, "in" becomes equivalent to this:
818
819     $object ~~ $number          ref($object) == $number
820     $object ~~ $string          ref($object) eq $string 
821
822 For example, this reports that the handle smells IOish
823 (but please don't really do this!):
824
825     use IO::Handle;
826     my $fh = IO::Handle->new();
827     if ($fh ~~ /\bIO\b/) {
828         say "handle smells IOish";
829     } 
830
831 That's because it treats C<$fh> as a string like
832 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
833
834 =head2 Bitwise And
835 X<operator, bitwise, and> X<bitwise and> X<&>
836
837 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
838 warning is currently raised, the result is not well defined when this operation
839 is performed on operands that aren't either numbers (see
840 L<Integer Arithmetic>) nor bitstrings (see L<Bitwise String Operators>).
841
842 Note that C<"&"> has lower priority than relational operators, so for example
843 the parentheses are essential in a test like
844
845     print "Even\n" if ($x & 1) == 0;
846
847 If the experimental "bitwise" feature is enabled via S<C<use feature
848 'bitwise'>>, then this operator always treats its operand as numbers.  This
849 feature produces a warning unless you also use C<S<no warnings
850 'experimental::bitwise'>>.
851
852 =head2 Bitwise Or and Exclusive Or
853 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
854 X<bitwise xor> X<^>
855
856 Binary C<"|"> returns its operands ORed together bit by bit.
857
858 Binary C<"^"> returns its operands XORed together bit by bit.
859
860 Although no warning is currently raised, the results are not well
861 defined when these operations are performed on operands that aren't either
862 numbers (see L<Integer Arithmetic>) nor bitstrings (see L<Bitwise String
863 Operators>).
864
865 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
866 for example the parentheses are essential in a test like
867
868     print "false\n" if (8 | 2) != 10;
869
870 If the experimental "bitwise" feature is enabled via S<C<use feature
871 'bitwise'>>, then this operator always treats its operand as numbers.  This
872 feature produces a warning unless you also use S<C<no warnings
873 'experimental::bitwise'>>.
874
875 =head2 C-style Logical And
876 X<&&> X<logical and> X<operator, logical, and>
877
878 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
879 if the left operand is false, the right operand is not even evaluated.
880 Scalar or list context propagates down to the right operand if it
881 is evaluated.
882
883 =head2 C-style Logical Or
884 X<||> X<operator, logical, or>
885
886 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
887 if the left operand is true, the right operand is not even evaluated.
888 Scalar or list context propagates down to the right operand if it
889 is evaluated.
890
891 =head2 Logical Defined-Or
892 X<//> X<operator, logical, defined-or>
893
894 Although it has no direct equivalent in C, Perl's C<//> operator is related
895 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
896 tests the left hand side's definedness instead of its truth.  Thus,
897 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
898 otherwise, the value of C<< EXPR2 >> is returned.
899 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
900 in the context of C<< // >> itself).  Usually,
901 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
902 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
903 cannot).  This is very useful for
904 providing default values for variables.  If you actually want to test if
905 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
906
907 The C<||>, C<//> and C<&&> operators return the last value evaluated
908 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
909 portable way to find out the home directory might be:
910
911     $home =  $ENV{HOME}
912           // $ENV{LOGDIR}
913           // (getpwuid($<))[7]
914           // die "You're homeless!\n";
915
916 In particular, this means that you shouldn't use this
917 for selecting between two aggregates for assignment:
918
919     @a = @b || @c;            # This doesn't do the right thing
920     @a = scalar(@b) || @c;    # because it really means this.
921     @a = @b ? @b : @c;        # This works fine, though.
922
923 As alternatives to C<&&> and C<||> when used for
924 control flow, Perl provides the C<and> and C<or> operators (see below).
925 The short-circuit behavior is identical.  The precedence of C<"and">
926 and C<"or"> is much lower, however, so that you can safely use them after a
927 list operator without the need for parentheses:
928
929     unlink "alpha", "beta", "gamma"
930             or gripe(), next LINE;
931
932 With the C-style operators that would have been written like this:
933
934     unlink("alpha", "beta", "gamma")
935             || (gripe(), next LINE);
936
937 It would be even more readable to write that this way:
938
939     unless(unlink("alpha", "beta", "gamma")) {
940         gripe();
941         next LINE;
942     } 
943
944 Using C<"or"> for assignment is unlikely to do what you want; see below.
945
946 =head2 Range Operators
947 X<operator, range> X<range> X<..> X<...>
948
949 Binary C<".."> is the range operator, which is really two different
950 operators depending on the context.  In list context, it returns a
951 list of values counting (up by ones) from the left value to the right
952 value.  If the left value is greater than the right value then it
953 returns the empty list.  The range operator is useful for writing
954 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
955 the current implementation, no temporary array is created when the
956 range operator is used as the expression in C<foreach> loops, but older
957 versions of Perl might burn a lot of memory when you write something
958 like this:
959
960     for (1 .. 1_000_000) {
961         # code
962     }
963
964 The range operator also works on strings, using the magical
965 auto-increment, see below.
966
967 In scalar context, C<".."> returns a boolean value.  The operator is
968 bistable, like a flip-flop, and emulates the line-range (comma)
969 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
970 maintains its own boolean state, even across calls to a subroutine
971 that contains it.  It is false as long as its left operand is false.
972 Once the left operand is true, the range operator stays true until the
973 right operand is true, I<AFTER> which the range operator becomes false
974 again.  It doesn't become false till the next time the range operator
975 is evaluated.  It can test the right operand and become false on the
976 same evaluation it became true (as in B<awk>), but it still returns
977 true once.  If you don't want it to test the right operand until the
978 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
979 two.  In all other regards, C<"..."> behaves just like C<".."> does.
980
981 The right operand is not evaluated while the operator is in the
982 "false" state, and the left operand is not evaluated while the
983 operator is in the "true" state.  The precedence is a little lower
984 than || and &&.  The value returned is either the empty string for
985 false, or a sequence number (beginning with 1) for true.  The sequence
986 number is reset for each range encountered.  The final sequence number
987 in a range has the string C<"E0"> appended to it, which doesn't affect
988 its numeric value, but gives you something to search for if you want
989 to exclude the endpoint.  You can exclude the beginning point by
990 waiting for the sequence number to be greater than 1.
991
992 If either operand of scalar C<".."> is a constant expression,
993 that operand is considered true if it is equal (C<==>) to the current
994 input line number (the C<$.> variable).
995
996 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
997 but that is only an issue if you use a floating point expression; when
998 implicitly using C<$.> as described in the previous paragraph, the
999 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
1000 is set to a floating point value and you are not reading from a file.
1001 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
1002 you want in scalar context because each of the operands are evaluated
1003 using their integer representation.
1004
1005 Examples:
1006
1007 As a scalar operator:
1008
1009     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1010                                #  if ($. == 101 .. $. == 200) { print; }
1011
1012     next LINE if (1 .. /^$/);  # skip header lines, short for
1013                                #   next LINE if ($. == 1 .. /^$/);
1014                                # (typically in a loop labeled LINE)
1015
1016     s/^/> / if (/^$/ .. eof());  # quote body
1017
1018     # parse mail messages
1019     while (<>) {
1020         $in_header =   1  .. /^$/;
1021         $in_body   = /^$/ .. eof;
1022         if ($in_header) {
1023             # do something
1024         } else { # in body
1025             # do something else
1026         }
1027     } continue {
1028         close ARGV if eof;             # reset $. each file
1029     }
1030
1031 Here's a simple example to illustrate the difference between
1032 the two range operators:
1033
1034     @lines = ("   - Foo",
1035               "01 - Bar",
1036               "1  - Baz",
1037               "   - Quux");
1038
1039     foreach (@lines) {
1040         if (/0/ .. /1/) {
1041             print "$_\n";
1042         }
1043     }
1044
1045 This program will print only the line containing "Bar".  If
1046 the range operator is changed to C<...>, it will also print the
1047 "Baz" line.
1048
1049 And now some examples as a list operator:
1050
1051     for (101 .. 200) { print }      # print $_ 100 times
1052     @foo = @foo[0 .. $#foo];        # an expensive no-op
1053     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1054
1055 The range operator (in list context) makes use of the magical
1056 auto-increment algorithm if the operands are strings.  You
1057 can say
1058
1059     @alphabet = ("A" .. "Z");
1060
1061 to get all normal letters of the English alphabet, or
1062
1063     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1064
1065 to get a hexadecimal digit, or
1066
1067     @z2 = ("01" .. "31");
1068     print $z2[$mday];
1069
1070 to get dates with leading zeros.
1071
1072 If the final value specified is not in the sequence that the magical
1073 increment would produce, the sequence goes until the next value would
1074 be longer than the final value specified.
1075
1076 If the initial value specified isn't part of a magical increment
1077 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1078 only the initial value will be returned.  So the following will only
1079 return an alpha:
1080
1081     use charnames "greek";
1082     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1083
1084 To get the 25 traditional lowercase Greek letters, including both sigmas,
1085 you could use this instead:
1086
1087     use charnames "greek";
1088     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1089                                         ..
1090                                      ord("\N{omega}") 
1091                                    );
1092
1093 However, because there are I<many> other lowercase Greek characters than
1094 just those, to match lowercase Greek characters in a regular expression,
1095 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1096 L<experimental feature|perlrecharclass/Extended Bracketed Character
1097 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1098
1099 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1100 return two elements in list context.
1101
1102     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1103
1104 =head2 Conditional Operator
1105 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1106
1107 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1108 like an if-then-else.  If the argument before the C<?> is true, the
1109 argument before the C<:> is returned, otherwise the argument after the
1110 C<:> is returned.  For example:
1111
1112     printf "I have %d dog%s.\n", $n,
1113             ($n == 1) ? "" : "s";
1114
1115 Scalar or list context propagates downward into the 2nd
1116 or 3rd argument, whichever is selected.
1117
1118     $x = $ok ? $y : $z;  # get a scalar
1119     @x = $ok ? @y : @z;  # get an array
1120     $x = $ok ? @y : @z;  # oops, that's just a count!
1121
1122 The operator may be assigned to if both the 2nd and 3rd arguments are
1123 legal lvalues (meaning that you can assign to them):
1124
1125     ($x_or_y ? $x : $y) = $z;
1126
1127 Because this operator produces an assignable result, using assignments
1128 without parentheses will get you in trouble.  For example, this:
1129
1130     $x % 2 ? $x += 10 : $x += 2
1131
1132 Really means this:
1133
1134     (($x % 2) ? ($x += 10) : $x) += 2
1135
1136 Rather than this:
1137
1138     ($x % 2) ? ($x += 10) : ($x += 2)
1139
1140 That should probably be written more simply as:
1141
1142     $x += ($x % 2) ? 10 : 2;
1143
1144 =head2 Assignment Operators
1145 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1146 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1147 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1148
1149 C<"="> is the ordinary assignment operator.
1150
1151 Assignment operators work as in C.  That is,
1152
1153     $x += 2;
1154
1155 is equivalent to
1156
1157     $x = $x + 2;
1158
1159 although without duplicating any side effects that dereferencing the lvalue
1160 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1161 The following are recognized:
1162
1163     **=    +=    *=    &=    &.=    <<=    &&=
1164            -=    /=    |=    |.=    >>=    ||=
1165            .=    %=    ^=    ^.=           //=
1166                  x=
1167
1168 Although these are grouped by family, they all have the precedence
1169 of assignment.  These combined assignment operators can only operate on
1170 scalars, whereas the ordinary assignment operator can assign to arrays,
1171 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1172 and L<perldata/List value constructors>, and L<perlref/Assigning to
1173 References>.)
1174
1175 Unlike in C, the scalar assignment operator produces a valid lvalue.
1176 Modifying an assignment is equivalent to doing the assignment and
1177 then modifying the variable that was assigned to.  This is useful
1178 for modifying a copy of something, like this:
1179
1180     ($tmp = $global) =~ tr/13579/24680/;
1181
1182 Although as of 5.14, that can be also be accomplished this way:
1183
1184     use v5.14;
1185     $tmp = ($global =~  tr/13579/24680/r);
1186
1187 Likewise,
1188
1189     ($x += 2) *= 3;
1190
1191 is equivalent to
1192
1193     $x += 2;
1194     $x *= 3;
1195
1196 Similarly, a list assignment in list context produces the list of
1197 lvalues assigned to, and a list assignment in scalar context returns
1198 the number of elements produced by the expression on the right hand
1199 side of the assignment.
1200
1201 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1202 Perl 5.22 and experimental.  See L</Bitwise String Operators>.
1203
1204 =head2 Comma Operator
1205 X<comma> X<operator, comma> X<,>
1206
1207 Binary C<","> is the comma operator.  In scalar context it evaluates
1208 its left argument, throws that value away, then evaluates its right
1209 argument and returns that value.  This is just like C's comma operator.
1210
1211 In list context, it's just the list argument separator, and inserts
1212 both its arguments into the list.  These arguments are also evaluated
1213 from left to right.
1214
1215 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1216 for the comma except that it causes a
1217 word on its left to be interpreted as a string if it begins with a letter
1218 or underscore and is composed only of letters, digits and underscores.
1219 This includes operands that might otherwise be interpreted as operators,
1220 constants, single number v-strings or function calls.  If in doubt about
1221 this behavior, the left operand can be quoted explicitly.
1222
1223 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1224 or list argument separator, according to context.
1225
1226 For example:
1227
1228     use constant FOO => "something";
1229
1230     my %h = ( FOO => 23 );
1231
1232 is equivalent to:
1233
1234     my %h = ("FOO", 23);
1235
1236 It is I<NOT>:
1237
1238     my %h = ("something", 23);
1239
1240 The C<< => >> operator is helpful in documenting the correspondence
1241 between keys and values in hashes, and other paired elements in lists.
1242
1243     %hash = ( $key => $value );
1244     login( $username => $password );
1245
1246 The special quoting behavior ignores precedence, and hence may apply to
1247 I<part> of the left operand:
1248
1249     print time.shift => "bbb";
1250
1251 That example prints something like C<"1314363215shiftbbb">, because the
1252 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1253 the fact that C<time.shift> is the entire left operand.
1254
1255 =head2 List Operators (Rightward)
1256 X<operator, list, rightward> X<list operator>
1257
1258 On the right side of a list operator, the comma has very low precedence,
1259 such that it controls all comma-separated expressions found there.
1260 The only operators with lower precedence are the logical operators
1261 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1262 operators without the need for parentheses:
1263
1264     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1265
1266 However, some people find that code harder to read than writing
1267 it with parentheses:
1268
1269     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1270
1271 in which case you might as well just use the more customary C<"||"> operator:
1272
1273     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1274
1275 See also discussion of list operators in L</Terms and List Operators (Leftward)>.
1276
1277 =head2 Logical Not
1278 X<operator, logical, not> X<not>
1279
1280 Unary C<"not"> returns the logical negation of the expression to its right.
1281 It's the equivalent of C<"!"> except for the very low precedence.
1282
1283 =head2 Logical And
1284 X<operator, logical, and> X<and>
1285
1286 Binary C<"and"> returns the logical conjunction of the two surrounding
1287 expressions.  It's equivalent to C<&&> except for the very low
1288 precedence.  This means that it short-circuits: the right
1289 expression is evaluated only if the left expression is true.
1290
1291 =head2 Logical or and Exclusive Or
1292 X<operator, logical, or> X<operator, logical, xor>
1293 X<operator, logical, exclusive or>
1294 X<or> X<xor>
1295
1296 Binary C<"or"> returns the logical disjunction of the two surrounding
1297 expressions.  It's equivalent to C<||> except for the very low precedence.
1298 This makes it useful for control flow:
1299
1300     print FH $data              or die "Can't write to FH: $!";
1301
1302 This means that it short-circuits: the right expression is evaluated
1303 only if the left expression is false.  Due to its precedence, you must
1304 be careful to avoid using it as replacement for the C<||> operator.
1305 It usually works out better for flow control than in assignments:
1306
1307     $x = $y or $z;              # bug: this is wrong
1308     ($x = $y) or $z;            # really means this
1309     $x = $y || $z;              # better written this way
1310
1311 However, when it's a list-context assignment and you're trying to use
1312 C<||> for control flow, you probably need C<"or"> so that the assignment
1313 takes higher precedence.
1314
1315     @info = stat($file) || die;     # oops, scalar sense of stat!
1316     @info = stat($file) or die;     # better, now @info gets its due
1317
1318 Then again, you could always use parentheses.
1319
1320 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1321 It cannot short-circuit (of course).
1322
1323 There is no low precedence operator for defined-OR.
1324
1325 =head2 C Operators Missing From Perl
1326 X<operator, missing from perl> X<&> X<*>
1327 X<typecasting> X<(TYPE)>
1328
1329 Here is what C has that Perl doesn't:
1330
1331 =over 8
1332
1333 =item unary &
1334
1335 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1336
1337 =item unary *
1338
1339 Dereference-address operator.  (Perl's prefix dereferencing
1340 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1341
1342 =item (TYPE)
1343
1344 Type-casting operator.
1345
1346 =back
1347
1348 =head2 Quote and Quote-like Operators
1349 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1350 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1351 X<escape sequence> X<escape>
1352
1353 While we usually think of quotes as literal values, in Perl they
1354 function as operators, providing various kinds of interpolating and
1355 pattern matching capabilities.  Perl provides customary quote characters
1356 for these behaviors, but also provides a way for you to choose your
1357 quote character for any of them.  In the following table, a C<{}> represents
1358 any pair of delimiters you choose.
1359
1360     Customary  Generic        Meaning        Interpolates
1361         ''       q{}          Literal             no
1362         ""      qq{}          Literal             yes
1363         ``      qx{}          Command             yes*
1364                 qw{}         Word list            no
1365         //       m{}       Pattern match          yes*
1366                 qr{}          Pattern             yes*
1367                  s{}{}      Substitution          yes*
1368                 tr{}{}    Transliteration         no (but see below)
1369                  y{}{}    Transliteration         no (but see below)
1370         <<EOF                 here-doc            yes*
1371
1372         * unless the delimiter is ''.
1373
1374 Non-bracketing delimiters use the same character fore and aft, but the four
1375 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1376 that
1377
1378     q{foo{bar}baz}
1379
1380 is the same as
1381
1382     'foo{bar}baz'
1383
1384 Note, however, that this does not always work for quoting Perl code:
1385
1386     $s = q{ if($x eq "}") ... }; # WRONG
1387
1388 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1389 and from CPAN before then) is able to do this properly.
1390
1391 There can be whitespace between the operator and the quoting
1392 characters, except when C<#> is being used as the quoting character.
1393 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1394 operator C<q> followed by a comment.  Its argument will be taken
1395 from the next line.  This allows you to write:
1396
1397     s {foo}  # Replace foo
1398       {bar}  # with bar.
1399
1400 The following escape sequences are available in constructs that interpolate,
1401 and in transliterations:
1402 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1403 X<\o{}>
1404
1405     Sequence     Note  Description
1406     \t                  tab               (HT, TAB)
1407     \n                  newline           (NL)
1408     \r                  return            (CR)
1409     \f                  form feed         (FF)
1410     \b                  backspace         (BS)
1411     \a                  alarm (bell)      (BEL)
1412     \e                  escape            (ESC)
1413     \x{263A}     [1,8]  hex char          (example: SMILEY)
1414     \x1b         [2,8]  restricted range hex char (example: ESC)
1415     \N{name}     [3]    named Unicode character or character sequence
1416     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1417     \c[          [5]    control char      (example: chr(27))
1418     \o{23072}    [6,8]  octal char        (example: SMILEY)
1419     \033         [7,8]  restricted range octal char  (example: ESC)
1420
1421 =over 4
1422
1423 =item [1]
1424
1425 The result is the character specified by the hexadecimal number between
1426 the braces.  See L</[8]> below for details on which character.
1427
1428 Only hexadecimal digits are valid between the braces.  If an invalid
1429 character is encountered, a warning will be issued and the invalid
1430 character and all subsequent characters (valid or invalid) within the
1431 braces will be discarded.
1432
1433 If there are no valid digits between the braces, the generated character is
1434 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1435 will not cause a warning (currently).
1436
1437 =item [2]
1438
1439 The result is the character specified by the hexadecimal number in the range
1440 0x00 to 0xFF.  See L</[8]> below for details on which character.
1441
1442 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1443 by fewer than two valid digits, any valid digits will be zero-padded.  This
1444 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1445 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1446 two valid digits will result in a warning.  Note that although the warning
1447 says the illegal character is ignored, it is only ignored as part of the
1448 escape and will still be used as the subsequent character in the string.
1449 For example:
1450
1451   Original    Result    Warns?
1452   "\x7"       "\x07"    no
1453   "\x"        "\x00"    no
1454   "\x7q"      "\x07q"   yes
1455   "\xq"       "\x00q"   yes
1456
1457 =item [3]
1458
1459 The result is the Unicode character or character sequence given by I<name>.
1460 See L<charnames>.
1461
1462 =item [4]
1463
1464 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1465 point is I<hexadecimal number>.
1466
1467 =item [5]
1468
1469 The character following C<\c> is mapped to some other character as shown in the
1470 table:
1471
1472  Sequence   Value
1473    \c@      chr(0)
1474    \cA      chr(1)
1475    \ca      chr(1)
1476    \cB      chr(2)
1477    \cb      chr(2)
1478    ...
1479    \cZ      chr(26)
1480    \cz      chr(26)
1481    \c[      chr(27)
1482                      # See below for chr(28)
1483    \c]      chr(29)
1484    \c^      chr(30)
1485    \c_      chr(31)
1486    \c?      chr(127) # (on ASCII platforms; see below for link to
1487                      #  EBCDIC discussion)
1488
1489 In other words, it's the character whose code point has had 64 xor'd with
1490 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1491 S<C<ord("?") ^ 64>> is 127, and
1492 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1493
1494 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1495 end of a string, because the backslash would be parsed as escaping the end
1496 quote.
1497
1498 On ASCII platforms, the resulting characters from the list above are the
1499 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1500 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1501 differences between these for ASCII versus EBCDIC platforms.
1502
1503 Use of any other character following the C<"c"> besides those listed above is
1504 discouraged, and as of Perl v5.20, the only characters actually allowed
1505 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1506 for any of the allowed other characters is that the value is derived by
1507 xor'ing with the seventh bit, which is 64, and a warning raised if
1508 enabled.  Using the non-allowed characters generates a fatal error.
1509
1510 To get platform independent controls, you can use C<\N{...}>.
1511
1512 =item [6]
1513
1514 The result is the character specified by the octal number between the braces.
1515 See L</[8]> below for details on which character.
1516
1517 If a character that isn't an octal digit is encountered, a warning is raised,
1518 and the value is based on the octal digits before it, discarding it and all
1519 following characters up to the closing brace.  It is a fatal error if there are
1520 no octal digits at all.
1521
1522 =item [7]
1523
1524 The result is the character specified by the three-digit octal number in the
1525 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1526 L</[8]> below for details on which character.
1527
1528 Some contexts allow 2 or even 1 digit, but any usage without exactly
1529 three digits, the first being a zero, may give unintended results.  (For
1530 example, in a regular expression it may be confused with a backreference;
1531 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1532 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1533 use this construct only for ordinals C<\077> and below, remembering to pad to
1534 the left with zeros to make three digits.  For larger ordinals, either use
1535 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1536 (which is portable between platforms with different character sets) or
1537 C<\x{}> instead.
1538
1539 =item [8]
1540
1541 Several constructs above specify a character by a number.  That number
1542 gives the character's position in the character set encoding (indexed from 0).
1543 This is called synonymously its ordinal, code position, or code point.  Perl
1544 works on platforms that have a native encoding currently of either ASCII/Latin1
1545 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1546 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1547 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1548 it as a Unicode code point and the result is the corresponding Unicode
1549 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1550 decimal, which is less than 256, so the number is interpreted in the native
1551 character set encoding.  In ASCII the character in the 80th position (indexed
1552 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1553 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1554 as a Unicode code point no matter what the native encoding is.  The name of the
1555 character in the 256th position (indexed by 0) in Unicode is
1556 C<LATIN CAPITAL LETTER A WITH MACRON>.
1557
1558 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1559 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1560 on EBCDIC platforms.  And if C<S<L<use encoding|encoding>>> is in effect, the
1561 number is considered to be in that encoding, and is translated from that into
1562 the platform's native encoding if there is a corresponding native character;
1563 otherwise to Unicode.
1564
1565 =back
1566
1567 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1568 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1569 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1570 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1571
1572 The following escape sequences are available in constructs that interpolate,
1573 but not in transliterations.
1574 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1575
1576     \l          lowercase next character only
1577     \u          titlecase (not uppercase!) next character only
1578     \L          lowercase all characters till \E or end of string
1579     \U          uppercase all characters till \E or end of string
1580     \F          foldcase all characters till \E or end of string
1581     \Q          quote (disable) pattern metacharacters till \E or
1582                 end of string
1583     \E          end either case modification or quoted section
1584                 (whichever was last seen)
1585
1586 See L<perlfunc/quotemeta> for the exact definition of characters that
1587 are quoted by C<\Q>.
1588
1589 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1590 C<\E> for each.  For example:
1591
1592  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1593  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1594
1595 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1596 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1597 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1598 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1599 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1600 case-mapping a single character can sometimes produce a sequence of
1601 several characters.
1602 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1603 for all locales but a UTF-8 one, where it instead uses the Unicode
1604 definition.
1605
1606 All systems use the virtual C<"\n"> to represent a line terminator,
1607 called a "newline".  There is no such thing as an unvarying, physical
1608 newline character.  It is only an illusion that the operating system,
1609 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1610 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1611 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1612 and on systems without a line terminator,
1613 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1614 you mean a "newline" for your system, but use the literal ASCII when you
1615 need an exact character.  For example, most networking protocols expect
1616 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1617 and although they often accept just C<"\012">, they seldom tolerate just
1618 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1619 you may be burned some day.
1620 X<newline> X<line terminator> X<eol> X<end of line>
1621 X<\n> X<\r> X<\r\n>
1622
1623 For constructs that do interpolate, variables beginning with "C<$>"
1624 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1625 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1626 But method calls such as C<< $obj->meth >> are not.
1627
1628 Interpolating an array or slice interpolates the elements in order,
1629 separated by the value of C<$">, so is equivalent to interpolating
1630 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1631 interpolated only if the name is enclosed in braces C<@{*}>, but the
1632 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1633
1634 For double-quoted strings, the quoting from C<\Q> is applied after
1635 interpolation and escapes are processed.
1636
1637     "abc\Qfoo\tbar$s\Exyz"
1638
1639 is equivalent to
1640
1641     "abc" . quotemeta("foo\tbar$s") . "xyz"
1642
1643 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1644 the quoting from C<\Q> is applied after interpolation is processed,
1645 but before escapes are processed.  This allows the pattern to match
1646 literally (except for C<$> and C<@>).  For example, the following matches:
1647
1648     '\s\t' =~ /\Q\s\t/
1649
1650 Because C<$> or C<@> trigger interpolation, you'll need to use something
1651 like C</\Quser\E\@\Qhost/> to match them literally.
1652
1653 Patterns are subject to an additional level of interpretation as a
1654 regular expression.  This is done as a second pass, after variables are
1655 interpolated, so that regular expressions may be incorporated into the
1656 pattern from the variables.  If this is not what you want, use C<\Q> to
1657 interpolate a variable literally.
1658
1659 Apart from the behavior described above, Perl does not expand
1660 multiple levels of interpolation.  In particular, contrary to the
1661 expectations of shell programmers, back-quotes do I<NOT> interpolate
1662 within double quotes, nor do single quotes impede evaluation of
1663 variables when used within double quotes.
1664
1665 =head2 Regexp Quote-Like Operators
1666 X<operator, regexp>
1667
1668 Here are the quote-like operators that apply to pattern
1669 matching and related activities.
1670
1671 =over 8
1672
1673 =item C<qr/I<STRING>/msixpodualn>
1674 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1675
1676 This operator quotes (and possibly compiles) its I<STRING> as a regular
1677 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1678 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no interpolation
1679 is done.  Returns a Perl value which may be used instead of the
1680 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1681 normalized version of the original pattern.  It magically differs from
1682 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1683 however, dereferencing it is not well defined (you currently get the 
1684 normalized version of the original pattern, but this may change).
1685
1686
1687 For example,
1688
1689     $rex = qr/my.STRING/is;
1690     print $rex;                 # prints (?si-xm:my.STRING)
1691     s/$rex/foo/;
1692
1693 is equivalent to
1694
1695     s/my.STRING/foo/is;
1696
1697 The result may be used as a subpattern in a match:
1698
1699     $re = qr/$pattern/;
1700     $string =~ /foo${re}bar/;   # can be interpolated in other
1701                                 # patterns
1702     $string =~ $re;             # or used standalone
1703     $string =~ /$re/;           # or this way
1704
1705 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1706 operator, using C<qr()> may have speed advantages in some situations,
1707 notably if the result of C<qr()> is used standalone:
1708
1709     sub match {
1710         my $patterns = shift;
1711         my @compiled = map qr/$_/i, @$patterns;
1712         grep {
1713             my $success = 0;
1714             foreach my $pat (@compiled) {
1715                 $success = 1, last if /$pat/;
1716             }
1717             $success;
1718         } @_;
1719     }
1720
1721 Precompilation of the pattern into an internal representation at
1722 the moment of C<qr()> avoids the need to recompile the pattern every
1723 time a match C</$pat/> is attempted.  (Perl has many other internal
1724 optimizations, but none would be triggered in the above example if
1725 we did not use C<qr()> operator.)
1726
1727 Options (specified by the following modifiers) are:
1728
1729     m   Treat string as multiple lines.
1730     s   Treat string as single line. (Make . match a newline)
1731     i   Do case-insensitive pattern matching.
1732     x   Use extended regular expressions.
1733     p   When matching preserve a copy of the matched string so
1734         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1735         defined (ignored starting in v5.20) as these are always
1736         defined starting in that relese
1737     o   Compile pattern only once.
1738     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1739         a's further restricts things to that that no ASCII
1740         character will match a non-ASCII one under /i.
1741     l   Use the current run-time locale's rules.
1742     u   Use Unicode rules.
1743     d   Use Unicode or native charset, as in 5.12 and earlier.
1744     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1745
1746 If a precompiled pattern is embedded in a larger pattern then the effect
1747 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1748 C</o> modifier has is not propagated, being restricted to those patterns
1749 explicitly using it.
1750
1751 The last four modifiers listed above, added in Perl 5.14,
1752 control the character set rules, but C</a> is the only one you are likely
1753 to want to specify explicitly; the other three are selected
1754 automatically by various pragmas.
1755
1756 See L<perlre> for additional information on valid syntax for I<STRING>, and
1757 for a detailed look at the semantics of regular expressions.  In
1758 particular, all modifiers except the largely obsolete C</o> are further
1759 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1760
1761 =item C<m/I<PATTERN>/msixpodualngc>
1762 X<m> X<operator, match>
1763 X<regexp, options> X<regexp> X<regex, options> X<regex>
1764 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1765
1766 =item C</I<PATTERN>/msixpodualngc>
1767
1768 Searches a string for a pattern match, and in scalar context returns
1769 true if it succeeds, false if it fails.  If no string is specified
1770 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1771 string specified with C<=~> need not be an lvalue--it may be the
1772 result of an expression evaluation, but remember the C<=~> binds
1773 rather tightly.)  See also L<perlre>.
1774
1775 Options are as described in C<qr//> above; in addition, the following match
1776 process modifiers are available:
1777
1778  g  Match globally, i.e., find all occurrences.
1779  c  Do not reset search position on a failed match when /g is
1780     in effect.
1781
1782 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
1783 you can use any pair of non-whitespace (ASCII) characters
1784 as delimiters.  This is particularly useful for matching path names
1785 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
1786 the delimiter, then a match-only-once rule applies,
1787 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
1788 no interpolation is performed on the I<PATTERN>.
1789 When using a delimiter character valid in an identifier, whitespace is required
1790 after the C<m>.
1791
1792 I<PATTERN> may contain variables, which will be interpolated
1793 every time the pattern search is evaluated, except
1794 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1795 C<$|> are not interpolated because they look like end-of-string tests.)
1796 Perl will not recompile the pattern unless an interpolated
1797 variable that it contains changes.  You can force Perl to skip the
1798 test and never recompile by adding a C</o> (which stands for "once")
1799 after the trailing delimiter.
1800 Once upon a time, Perl would recompile regular expressions
1801 unnecessarily, and this modifier was useful to tell it not to do so, in the
1802 interests of speed.  But now, the only reasons to use C</o> are one of:
1803
1804 =over
1805
1806 =item 1
1807
1808 The variables are thousands of characters long and you know that they
1809 don't change, and you need to wring out the last little bit of speed by
1810 having Perl skip testing for that.  (There is a maintenance penalty for
1811 doing this, as mentioning C</o> constitutes a promise that you won't
1812 change the variables in the pattern.  If you do change them, Perl won't
1813 even notice.)
1814
1815 =item 2
1816
1817 you want the pattern to use the initial values of the variables
1818 regardless of whether they change or not.  (But there are saner ways
1819 of accomplishing this than using C</o>.)
1820
1821 =item 3
1822
1823 If the pattern contains embedded code, such as
1824
1825     use re 'eval';
1826     $code = 'foo(?{ $x })';
1827     /$code/
1828
1829 then perl will recompile each time, even though the pattern string hasn't
1830 changed, to ensure that the current value of C<$x> is seen each time.
1831 Use C</o> if you want to avoid this.
1832
1833 =back
1834
1835 The bottom line is that using C</o> is almost never a good idea.
1836
1837 =item The empty pattern C<//>
1838
1839 If the I<PATTERN> evaluates to the empty string, the last
1840 I<successfully> matched regular expression is used instead.  In this
1841 case, only the C<g> and C<c> flags on the empty pattern are honored;
1842 the other flags are taken from the original pattern.  If no match has
1843 previously succeeded, this will (silently) act instead as a genuine
1844 empty pattern (which will always match).
1845
1846 Note that it's possible to confuse Perl into thinking C<//> (the empty
1847 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1848 good about this, but some pathological cases might trigger this, such as
1849 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
1850 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
1851 will assume you meant defined-or.  If you meant the empty regex, just
1852 use parentheses or spaces to disambiguate, or even prefix the empty
1853 regex with an C<m> (so C<//> becomes C<m//>).
1854
1855 =item Matching in list context
1856
1857 If the C</g> option is not used, C<m//> in list context returns a
1858 list consisting of the subexpressions matched by the parentheses in the
1859 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1860 also set).  When there are no parentheses in the pattern, the return
1861 value is the list C<(1)> for success.  
1862 With or without parentheses, an empty list is returned upon failure.
1863
1864 Examples:
1865
1866  open(TTY, "+</dev/tty")
1867     || die "can't access /dev/tty: $!";
1868
1869  <TTY> =~ /^y/i && foo();       # do foo if desired
1870
1871  if (/Version: *([0-9.]*)/) { $version = $1; }
1872
1873  next if m#^/usr/spool/uucp#;
1874
1875  # poor man's grep
1876  $arg = shift;
1877  while (<>) {
1878     print if /$arg/o; # compile only once (no longer needed!)
1879  }
1880
1881  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1882
1883 This last example splits C<$foo> into the first two words and the
1884 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
1885 C<$Etc>.  The conditional is true if any variables were assigned; that is,
1886 if the pattern matched.
1887
1888 The C</g> modifier specifies global pattern matching--that is,
1889 matching as many times as possible within the string.  How it behaves
1890 depends on the context.  In list context, it returns a list of the
1891 substrings matched by any capturing parentheses in the regular
1892 expression.  If there are no parentheses, it returns a list of all
1893 the matched strings, as if there were parentheses around the whole
1894 pattern.
1895
1896 In scalar context, each execution of C<m//g> finds the next match,
1897 returning true if it matches, and false if there is no further match.
1898 The position after the last match can be read or set using the C<pos()>
1899 function; see L<perlfunc/pos>.  A failed match normally resets the
1900 search position to the beginning of the string, but you can avoid that
1901 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1902 string also resets the search position.
1903
1904 =item C<\G I<assertion>>
1905
1906 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1907 zero-width assertion that matches the exact position where the
1908 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1909 C<\G> assertion still anchors at C<pos()> as it was at the start of
1910 the operation (see L<perlfunc/pos>), but the match is of course only
1911 attempted once.  Using C<\G> without C</g> on a target string that has
1912 not previously had a C</g> match applied to it is the same as using
1913 the C<\A> assertion to match the beginning of the string.  Note also
1914 that, currently, C<\G> is only properly supported when anchored at the
1915 very beginning of the pattern.
1916
1917 Examples:
1918
1919     # list context
1920     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1921
1922     # scalar context
1923     local $/ = "";
1924     while ($paragraph = <>) {
1925         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1926             $sentences++;
1927         }
1928     }
1929     say $sentences;
1930
1931 Here's another way to check for sentences in a paragraph:
1932
1933  my $sentence_rx = qr{
1934     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1935                                 # whitespace
1936     \p{Lu}                      # capital letter
1937     .*?                         # a bunch of anything
1938     (?<= \S )                   # that ends in non-
1939                                 # whitespace
1940     (?<! \b [DMS]r  )           # but isn't a common abbr.
1941     (?<! \b Mrs )
1942     (?<! \b Sra )
1943     (?<! \b St  )
1944     [.?!]                       # followed by a sentence
1945                                 # ender
1946     (?= $ | \s )                # in front of end-of-string
1947                                 # or whitespace
1948  }sx;
1949  local $/ = "";
1950  while (my $paragraph = <>) {
1951     say "NEW PARAGRAPH";
1952     my $count = 0;
1953     while ($paragraph =~ /($sentence_rx)/g) {
1954         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1955     }
1956  }
1957
1958 Here's how to use C<m//gc> with C<\G>:
1959
1960     $_ = "ppooqppqq";
1961     while ($i++ < 2) {
1962         print "1: '";
1963         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1964         print "2: '";
1965         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1966         print "3: '";
1967         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1968     }
1969     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1970
1971 The last example should print:
1972
1973     1: 'oo', pos=4
1974     2: 'q', pos=5
1975     3: 'pp', pos=7
1976     1: '', pos=7
1977     2: 'q', pos=8
1978     3: '', pos=8
1979     Final: 'q', pos=8
1980
1981 Notice that the final match matched C<q> instead of C<p>, which a match
1982 without the C<\G> anchor would have done.  Also note that the final match
1983 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
1984 final match did indeed match C<p>, it's a good bet that you're running a
1985 very old (pre-5.6.0) version of Perl.
1986
1987 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1988 combine several regexps like this to process a string part-by-part,
1989 doing different actions depending on which regexp matched.  Each
1990 regexp tries to match where the previous one leaves off.
1991
1992  $_ = <<'EOL';
1993     $url = URI::URL->new( "http://example.com/" );
1994     die if $url eq "xXx";
1995  EOL
1996
1997  LOOP: {
1998      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1999      print(" lowercase"),    redo LOOP
2000                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
2001      print(" UPPERCASE"),    redo LOOP
2002                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2003      print(" Capitalized"),  redo LOOP
2004                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2005      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2006      print(" alphanumeric"), redo LOOP
2007                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2008      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2009      print ". That's all!\n";
2010  }
2011
2012 Here is the output (split into several lines):
2013
2014  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2015  line-noise lowercase line-noise lowercase line-noise lowercase
2016  lowercase line-noise lowercase lowercase line-noise lowercase
2017  lowercase line-noise MiXeD line-noise. That's all!
2018
2019 =item C<m?I<PATTERN>?msixpodualngc>
2020 X<?> X<operator, match-once>
2021
2022 =item C<?I<PATTERN>?msixpodualngc>
2023
2024 This is just like the C<m/I<PATTERN>/> search, except that it matches
2025 only once between calls to the C<reset()> operator.  This is a useful
2026 optimization when you want to see only the first occurrence of
2027 something in each file of a set of files, for instance.  Only C<m??>
2028 patterns local to the current package are reset.
2029
2030     while (<>) {
2031         if (m?^$?) {
2032                             # blank line between header and body
2033         }
2034     } continue {
2035         reset if eof;       # clear m?? status for next file
2036     }
2037
2038 Another example switched the first "latin1" encoding it finds
2039 to "utf8" in a pod file:
2040
2041     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2042
2043 The match-once behavior is controlled by the match delimiter being
2044 C<?>; with any other delimiter this is the normal C<m//> operator.
2045
2046 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2047 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2048 syntax error.  If you encounter this construct in older code, you can just add
2049 C<m>.
2050
2051 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2052 X<substitute> X<substitution> X<replace> X<regexp, replace>
2053 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2054
2055 Searches a string for a pattern, and if found, replaces that pattern
2056 with the replacement text and returns the number of substitutions
2057 made.  Otherwise it returns false (specifically, the empty string).
2058
2059 If the C</r> (non-destructive) option is used then it runs the
2060 substitution on a copy of the string and instead of returning the
2061 number of substitutions, it returns the copy whether or not a
2062 substitution occurred.  The original string is never changed when
2063 C</r> is used.  The copy will always be a plain string, even if the
2064 input is an object or a tied variable.
2065
2066 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2067 variable is searched and modified.  Unless the C</r> option is used,
2068 the string specified must be a scalar variable, an array element, a
2069 hash element, or an assignment to one of those; that is, some sort of
2070 scalar lvalue.
2071
2072 If the delimiter chosen is a single quote, no interpolation is
2073 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2074 I<PATTERN> contains a C<$> that looks like a variable rather than an
2075 end-of-string test, the variable will be interpolated into the pattern
2076 at run-time.  If you want the pattern compiled only once the first time
2077 the variable is interpolated, use the C</o> option.  If the pattern
2078 evaluates to the empty string, the last successfully executed regular
2079 expression is used instead.  See L<perlre> for further explanation on these.
2080
2081 Options are as with C<m//> with the addition of the following replacement
2082 specific options:
2083
2084     e   Evaluate the right side as an expression.
2085     ee  Evaluate the right side as a string then eval the
2086         result.
2087     r   Return substitution and leave the original string
2088         untouched.
2089
2090 Any non-whitespace delimiter may replace the slashes.  Add space after
2091 the C<s> when using a character allowed in identifiers.  If single quotes
2092 are used, no interpretation is done on the replacement string (the C</e>
2093 modifier overrides this, however).  Note that Perl treats backticks
2094 as normal delimiters; the replacement text is not evaluated as a command.
2095 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2096 its own pair of quotes, which may or may not be bracketing quotes, for example,
2097 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2098 replacement portion to be treated as a full-fledged Perl expression
2099 and evaluated right then and there.  It is, however, syntax checked at
2100 compile-time.  A second C<e> modifier will cause the replacement portion
2101 to be C<eval>ed before being run as a Perl expression.
2102
2103 Examples:
2104
2105     s/\bgreen\b/mauve/g;              # don't change wintergreen
2106
2107     $path =~ s|/usr/bin|/usr/local/bin|;
2108
2109     s/Login: $foo/Login: $bar/; # run-time pattern
2110
2111     ($foo = $bar) =~ s/this/that/;      # copy first, then
2112                                         # change
2113     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2114                                         # copy, then change
2115     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2116     $foo = $bar =~ s/this/that/r
2117                 =~ s/that/the other/r;  # Chained substitutes
2118                                         # using /r
2119     @foo = map { s/this/that/r } @bar   # /r is very useful in
2120                                         # maps
2121
2122     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2123
2124     $_ = 'abc123xyz';
2125     s/\d+/$&*2/e;               # yields 'abc246xyz'
2126     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2127     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2128
2129     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2130     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2131     s/^=(\w+)/pod($1)/ge;       # use function call
2132
2133     $_ = 'abc123xyz';
2134     $x = s/abc/def/r;           # $x is 'def123xyz' and
2135                                 # $_ remains 'abc123xyz'.
2136
2137     # expand variables in $_, but dynamics only, using
2138     # symbolic dereferencing
2139     s/\$(\w+)/${$1}/g;
2140
2141     # Add one to the value of any numbers in the string
2142     s/(\d+)/1 + $1/eg;
2143
2144     # Titlecase words in the last 30 characters only
2145     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2146
2147     # This will expand any embedded scalar variable
2148     # (including lexicals) in $_ : First $1 is interpolated
2149     # to the variable name, and then evaluated
2150     s/(\$\w+)/$1/eeg;
2151
2152     # Delete (most) C comments.
2153     $program =~ s {
2154         /\*     # Match the opening delimiter.
2155         .*?     # Match a minimal number of characters.
2156         \*/     # Match the closing delimiter.
2157     } []gsx;
2158
2159     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2160                                 # expensively
2161
2162     for ($variable) {           # trim whitespace in $variable,
2163                                 # cheap
2164         s/^\s+//;
2165         s/\s+$//;
2166     }
2167
2168     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2169
2170 Note the use of C<$> instead of C<\> in the last example.  Unlike
2171 B<sed>, we use the \<I<digit>> form only in the left hand side.
2172 Anywhere else it's $<I<digit>>.
2173
2174 Occasionally, you can't use just a C</g> to get all the changes
2175 to occur that you might want.  Here are two common cases:
2176
2177     # put commas in the right places in an integer
2178     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2179
2180     # expand tabs to 8-column spacing
2181     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2182
2183 =back
2184
2185 =head2 Quote-Like Operators
2186 X<operator, quote-like>
2187
2188 =over 4
2189
2190 =item C<q/I<STRING>/>
2191 X<q> X<quote, single> X<'> X<''>
2192
2193 =item C<'I<STRING>'>
2194
2195 A single-quoted, literal string.  A backslash represents a backslash
2196 unless followed by the delimiter or another backslash, in which case
2197 the delimiter or backslash is interpolated.
2198
2199     $foo = q!I said, "You said, 'She said it.'"!;
2200     $bar = q('This is it.');
2201     $baz = '\n';                # a two-character string
2202
2203 =item C<qq/I<STRING>/>
2204 X<qq> X<quote, double> X<"> X<"">
2205
2206 =item "I<STRING>"
2207
2208 A double-quoted, interpolated string.
2209
2210     $_ .= qq
2211      (*** The previous line contains the naughty word "$1".\n)
2212                 if /\b(tcl|java|python)\b/i;      # :-)
2213     $baz = "\n";                # a one-character string
2214
2215 =item C<qx/I<STRING>/>
2216 X<qx> X<`> X<``> X<backtick>
2217
2218 =item C<`I<STRING>`>
2219
2220 A string which is (possibly) interpolated and then executed as a
2221 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2222 pipes, and redirections will be honored.  The collected standard
2223 output of the command is returned; standard error is unaffected.  In
2224 scalar context, it comes back as a single (potentially multi-line)
2225 string, or C<undef> if the command failed.  In list context, returns a
2226 list of lines (however you've defined lines with C<$/> or
2227 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the command failed.
2228
2229 Because backticks do not affect standard error, use shell file descriptor
2230 syntax (assuming the shell supports this) if you care to address this.
2231 To capture a command's STDERR and STDOUT together:
2232
2233     $output = `cmd 2>&1`;
2234
2235 To capture a command's STDOUT but discard its STDERR:
2236
2237     $output = `cmd 2>/dev/null`;
2238
2239 To capture a command's STDERR but discard its STDOUT (ordering is
2240 important here):
2241
2242     $output = `cmd 2>&1 1>/dev/null`;
2243
2244 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2245 but leave its STDOUT to come out the old STDERR:
2246
2247     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2248
2249 To read both a command's STDOUT and its STDERR separately, it's easiest
2250 to redirect them separately to files, and then read from those files
2251 when the program is done:
2252
2253     system("program args 1>program.stdout 2>program.stderr");
2254
2255 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2256 For example:
2257
2258     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2259     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2260     print STDOUT `sort`;
2261
2262 will print the sorted contents of the file named F<"stuff">.
2263
2264 Using single-quote as a delimiter protects the command from Perl's
2265 double-quote interpolation, passing it on to the shell instead:
2266
2267     $perl_info  = qx(ps $$);            # that's Perl's $$
2268     $shell_info = qx'ps $$';            # that's the new shell's $$
2269
2270 How that string gets evaluated is entirely subject to the command
2271 interpreter on your system.  On most platforms, you will have to protect
2272 shell metacharacters if you want them treated literally.  This is in
2273 practice difficult to do, as it's unclear how to escape which characters.
2274 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2275 to emulate backticks safely.
2276
2277 On some platforms (notably DOS-like ones), the shell may not be
2278 capable of dealing with multiline commands, so putting newlines in
2279 the string may not get you what you want.  You may be able to evaluate
2280 multiple commands in a single line by separating them with the command
2281 separator character, if your shell supports that (for example, C<;> on 
2282 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2283
2284 Perl will attempt to flush all files opened for
2285 output before starting the child process, but this may not be supported
2286 on some platforms (see L<perlport>).  To be safe, you may need to set
2287 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2288 C<L<IO::Handle>> on any open handles.
2289
2290 Beware that some command shells may place restrictions on the length
2291 of the command line.  You must ensure your strings don't exceed this
2292 limit after any necessary interpolations.  See the platform-specific
2293 release notes for more details about your particular environment.
2294
2295 Using this operator can lead to programs that are difficult to port,
2296 because the shell commands called vary between systems, and may in
2297 fact not be present at all.  As one example, the C<type> command under
2298 the POSIX shell is very different from the C<type> command under DOS.
2299 That doesn't mean you should go out of your way to avoid backticks
2300 when they're the right way to get something done.  Perl was made to be
2301 a glue language, and one of the things it glues together is commands.
2302 Just understand what you're getting yourself into.
2303
2304 Like C<system>, backticks put the child process exit code in C<$?>.
2305 If you'd like to manually inspect failure, you can check all possible
2306 failure modes by inspecting C<$?> like this:
2307
2308     if ($? == -1) {
2309         print "failed to execute: $!\n";
2310     }
2311     elsif ($? & 127) {
2312         printf "child died with signal %d, %s coredump\n",
2313             ($? & 127),  ($? & 128) ? 'with' : 'without';
2314     }
2315     else {
2316         printf "child exited with value %d\n", $? >> 8;
2317     }
2318
2319 See L</"I/O Operators"> for more discussion.
2320
2321 =item C<qw/I<STRING>/>
2322 X<qw> X<quote, list> X<quote, words>
2323
2324 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2325 whitespace as the word delimiters.  It can be understood as being roughly
2326 equivalent to:
2327
2328     split(" ", q/STRING/);
2329
2330 the differences being that it generates a real list at compile time, and
2331 in scalar context it returns the last element in the list.  So
2332 this expression:
2333
2334     qw(foo bar baz)
2335
2336 is semantically equivalent to the list:
2337
2338     "foo", "bar", "baz"
2339
2340 Some frequently seen examples:
2341
2342     use POSIX qw( setlocale localeconv )
2343     @EXPORT = qw( foo bar baz );
2344
2345 A common mistake is to try to separate the words with commas or to
2346 put comments into a multi-line C<qw>-string.  For this reason, the
2347 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2348 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2349
2350 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2351 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2352
2353 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2354
2355 Transliterates all occurrences of the characters found in the search list
2356 with the corresponding character in the replacement list.  It returns
2357 the number of characters replaced or deleted.  If no string is
2358 specified via the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2359
2360 If the C</r> (non-destructive) option is present, a new copy of the string
2361 is made and its characters transliterated, and this copy is returned no
2362 matter whether it was modified or not: the original string is always
2363 left unchanged.  The new copy is always a plain string, even if the input
2364 string is an object or a tied variable.
2365
2366 Unless the C</r> option is used, the string specified with C<=~> must be a
2367 scalar variable, an array element, a hash element, or an assignment to one
2368 of those; in other words, an lvalue.
2369
2370 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2371 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2372 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2373 I<SEARCHLIST> is delimited by bracketing quotes, the I<REPLACEMENTLIST> has
2374 its own pair of quotes, which may or may not be bracketing quotes;
2375 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2376
2377 Characters may be literals or any of the escape sequences accepted in
2378 double-quoted strings.  But there is no interpolation, so C<"$"> and
2379 C<"@"> are treated as literals.  A hyphen at the beginning or end, or
2380 preceded by a backslash is considered a literal.  Escape sequence
2381 details are in L<the table near the beginning of this section|/Quote and
2382 Quote-like Operators>.
2383
2384 Note that C<tr> does B<not> do regular expression character classes such as
2385 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2386 utility.  If you want to map strings between lower/upper cases, see
2387 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2388 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2389 C<\l> string-interpolation escapes on the right side of a substitution
2390 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2391 (except sometimes on legacy 7-bit data).
2392
2393 Most ranges are unportable between character sets, but certain ones
2394 signal Perl to do special handling to make them portable.  There are two
2395 classes of portable ranges.  The first are any subsets of the ranges
2396 C<A-Z>, C<a-z>, and C<0-9>, when expressed as literal characters.
2397
2398   tr/h-k/H-K/
2399
2400 capitalizes the letters C<"h">, C<"i">, C<"j">, and C<"k"> and nothing
2401 else, no matter what the platform's character set is.  In contrast, all
2402 of
2403
2404   tr/\x68-\x6B/\x48-\x4B/
2405   tr/h-\x6B/H-\x4B/
2406   tr/\x68-k/\x48-K/
2407
2408 do the same capitalizations as the previous example when run on ASCII
2409 platforms, but something completely different on EBCDIC ones.
2410
2411 The second class of portable ranges is invoked when one or both of the
2412 range's end points are expressed as C<\N{...}>
2413
2414  $string =~ tr/\N{U+20}-\N{U+7E}//d;
2415
2416 removes from C<$string> all the platform's characters which are
2417 equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E.  This
2418 is a portable range, and has the same effect on every platform it is
2419 run on.  It turns out that in this example, these are the ASCII
2420 printable characters.  So after this is run, C<$string> has only
2421 controls and characters which have no ASCII equivalents.
2422
2423 But, even for portable ranges, it is not generally obvious what is
2424 included without having to look things up.  A sound principle is to use
2425 only ranges that begin from and end at either ASCII alphabetics of equal
2426 case (C<b-e>, C<b-E>), or digits (C<1-4>).  Anything else is unclear
2427 (and unportable unless C<\N{...}> is used).  If in doubt, spell out the
2428 character sets in full.
2429
2430 Options:
2431
2432     c   Complement the SEARCHLIST.
2433     d   Delete found but unreplaced characters.
2434     s   Squash duplicate replaced characters.
2435     r   Return the modified string and leave the original string
2436         untouched.
2437
2438 If the C</c> modifier is specified, the I<SEARCHLIST> character set
2439 is complemented.  If the C</d> modifier is specified, any characters
2440 specified by I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted.
2441 (Note that this is slightly more flexible than the behavior of some
2442 B<tr> programs, which delete anything they find in the I<SEARCHLIST>,
2443 period.)  If the C</s> modifier is specified, sequences of characters
2444 that were transliterated to the same character are squashed down
2445 to a single instance of the character.
2446
2447 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2448 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2449 than the I<SEARCHLIST>, the final character is replicated till it is long
2450 enough.  If the I<REPLACEMENTLIST> is empty, the I<SEARCHLIST> is replicated.
2451 This latter is useful for counting characters in a class or for
2452 squashing character sequences in a class.
2453
2454 Examples:
2455
2456     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2457
2458     $cnt = tr/*/*/;             # count the stars in $_
2459
2460     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2461
2462     $cnt = tr/0-9//;            # count the digits in $_
2463
2464     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2465
2466     ($HOST = $host) =~ tr/a-z/A-Z/;
2467      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2468
2469     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2470                   =~ s/:/ -p/r;
2471
2472     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2473
2474     @stripped = map tr/a-zA-Z/ /csr, @original;
2475                                 # /r with map
2476
2477     tr [\200-\377]
2478        [\000-\177];             # wickedly delete 8th bit
2479
2480 If multiple transliterations are given for a character, only the
2481 first one is used:
2482
2483     tr/AAA/XYZ/
2484
2485 will transliterate any A to X.
2486
2487 Because the transliteration table is built at compile time, neither
2488 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2489 interpolation.  That means that if you want to use variables, you
2490 must use an C<eval()>:
2491
2492     eval "tr/$oldlist/$newlist/";
2493     die $@ if $@;
2494
2495     eval "tr/$oldlist/$newlist/, 1" or die $@;
2496
2497 =item C<< <<I<EOF> >>
2498 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2499
2500 A line-oriented form of quoting is based on the shell "here-document"
2501 syntax.  Following a C<< << >> you specify a string to terminate
2502 the quoted material, and all lines following the current line down to
2503 the terminating string are the value of the item.
2504
2505 The terminating string may be either an identifier (a word), or some
2506 quoted text.  An unquoted identifier works like double quotes.
2507 There may not be a space between the C<< << >> and the identifier,
2508 unless the identifier is explicitly quoted.  (If you put a space it
2509 will be treated as a null identifier, which is valid, and matches the
2510 first empty line.)  The terminating string must appear by itself
2511 (unquoted and with no surrounding whitespace) on the terminating line.
2512
2513 If the terminating string is quoted, the type of quotes used determine
2514 the treatment of the text.
2515
2516 =over 4
2517
2518 =item Double Quotes
2519
2520 Double quotes indicate that the text will be interpolated using exactly
2521 the same rules as normal double quoted strings.
2522
2523        print <<EOF;
2524     The price is $Price.
2525     EOF
2526
2527        print << "EOF"; # same as above
2528     The price is $Price.
2529     EOF
2530
2531
2532 =item Single Quotes
2533
2534 Single quotes indicate the text is to be treated literally with no
2535 interpolation of its content.  This is similar to single quoted
2536 strings except that backslashes have no special meaning, with C<\\>
2537 being treated as two backslashes and not one as they would in every
2538 other quoting construct.
2539
2540 Just as in the shell, a backslashed bareword following the C<<< << >>>
2541 means the same thing as a single-quoted string does:
2542
2543         $cost = <<'VISTA';  # hasta la ...
2544     That'll be $10 please, ma'am.
2545     VISTA
2546
2547         $cost = <<\VISTA;   # Same thing!
2548     That'll be $10 please, ma'am.
2549     VISTA
2550
2551 This is the only form of quoting in perl where there is no need
2552 to worry about escaping content, something that code generators
2553 can and do make good use of.
2554
2555 =item Backticks
2556
2557 The content of the here doc is treated just as it would be if the
2558 string were embedded in backticks.  Thus the content is interpolated
2559 as though it were double quoted and then executed via the shell, with
2560 the results of the execution returned.
2561
2562        print << `EOC`; # execute command and get results
2563     echo hi there
2564     EOC
2565
2566 =back
2567
2568 It is possible to stack multiple here-docs in a row:
2569
2570        print <<"foo", <<"bar"; # you can stack them
2571     I said foo.
2572     foo
2573     I said bar.
2574     bar
2575
2576        myfunc(<< "THIS", 23, <<'THAT');
2577     Here's a line
2578     or two.
2579     THIS
2580     and here's another.
2581     THAT
2582
2583 Just don't forget that you have to put a semicolon on the end
2584 to finish the statement, as Perl doesn't know you're not going to
2585 try to do this:
2586
2587        print <<ABC
2588     179231
2589     ABC
2590        + 20;
2591
2592 If you want to remove the line terminator from your here-docs,
2593 use C<chomp()>.
2594
2595     chomp($string = <<'END');
2596     This is a string.
2597     END
2598
2599 If you want your here-docs to be indented with the rest of the code,
2600 you'll need to remove leading whitespace from each line manually:
2601
2602     ($quote = <<'FINIS') =~ s/^\s+//gm;
2603        The Road goes ever on and on,
2604        down from the door where it began.
2605     FINIS
2606
2607 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2608 the quoted material must still come on the line following the
2609 C<<< <<FOO >>> marker, which means it may be inside the delimited
2610 construct:
2611
2612     s/this/<<E . 'that'
2613     the other
2614     E
2615      . 'more '/eg;
2616
2617 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2618 you would have to write
2619
2620     s/this/<<E . 'that'
2621      . 'more '/eg;
2622     the other
2623     E
2624
2625 outside of string evals.
2626
2627 Additionally, quoting rules for the end-of-string identifier are
2628 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2629 supported in place of C<''> and C<"">, and the only interpolation is for
2630 backslashing the quoting character:
2631
2632     print << "abc\"def";
2633     testing...
2634     abc"def
2635
2636 Finally, quoted strings cannot span multiple lines.  The general rule is
2637 that the identifier must be a string literal.  Stick with that, and you
2638 should be safe.
2639
2640 =back
2641
2642 =head2 Gory details of parsing quoted constructs
2643 X<quote, gory details>
2644
2645 When presented with something that might have several different
2646 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2647 principle to pick the most probable interpretation.  This strategy
2648 is so successful that Perl programmers often do not suspect the
2649 ambivalence of what they write.  But from time to time, Perl's
2650 notions differ substantially from what the author honestly meant.
2651
2652 This section hopes to clarify how Perl handles quoted constructs.
2653 Although the most common reason to learn this is to unravel labyrinthine
2654 regular expressions, because the initial steps of parsing are the
2655 same for all quoting operators, they are all discussed together.
2656
2657 The most important Perl parsing rule is the first one discussed
2658 below: when processing a quoted construct, Perl first finds the end
2659 of that construct, then interprets its contents.  If you understand
2660 this rule, you may skip the rest of this section on the first
2661 reading.  The other rules are likely to contradict the user's
2662 expectations much less frequently than this first one.
2663
2664 Some passes discussed below are performed concurrently, but because
2665 their results are the same, we consider them individually.  For different
2666 quoting constructs, Perl performs different numbers of passes, from
2667 one to four, but these passes are always performed in the same order.
2668
2669 =over 4
2670
2671 =item Finding the end
2672
2673 The first pass is finding the end of the quoted construct.  This results
2674 in saving to a safe location a copy of the text (between the starting
2675 and ending delimiters), normalized as necessary to avoid needing to know
2676 what the original delimiters were.
2677
2678 If the construct is a here-doc, the ending delimiter is a line
2679 that has a terminating string as the content.  Therefore C<<<EOF> is
2680 terminated by C<EOF> immediately followed by C<"\n"> and starting
2681 from the first column of the terminating line.
2682 When searching for the terminating line of a here-doc, nothing
2683 is skipped.  In other words, lines after the here-doc syntax
2684 are compared with the terminating string line by line.
2685
2686 For the constructs except here-docs, single characters are used as starting
2687 and ending delimiters.  If the starting delimiter is an opening punctuation
2688 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2689 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2690 If the starting delimiter is an unpaired character like C</> or a closing
2691 punctuation, the ending delimiter is the same as the starting delimiter.
2692 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2693 both C<qq[]> and C<qq]]> constructs.
2694
2695 When searching for single-character delimiters, escaped delimiters
2696 and C<\\> are skipped.  For example, while searching for terminating C</>,
2697 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2698 bracketing, nested pairs are also skipped.  For example, while searching
2699 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2700 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2701 However, when backslashes are used as the delimiters (like C<qq\\> and
2702 C<tr\\\>), nothing is skipped.
2703 During the search for the end, backslashes that escape delimiters or
2704 other backslashes are removed (exactly speaking, they are not copied to the
2705 safe location).
2706
2707 For constructs with three-part delimiters (C<s///>, C<y///>, and
2708 C<tr///>), the search is repeated once more.
2709 If the first delimiter is not an opening punctuation, the three delimiters must
2710 be the same, such as C<s!!!> and C<tr)))>,
2711 in which case the second delimiter
2712 terminates the left part and starts the right part at once.
2713 If the left part is delimited by bracketing punctuation (that is C<()>,
2714 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2715 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2716 and comments are allowed between the two parts, although the comment must follow
2717 at least one whitespace character; otherwise a character expected as the 
2718 start of the comment may be regarded as the starting delimiter of the right part.
2719
2720 During this search no attention is paid to the semantics of the construct.
2721 Thus:
2722
2723     "$hash{"$foo/$bar"}"
2724
2725 or:
2726
2727     m/
2728       bar       # NOT a comment, this slash / terminated m//!
2729      /x
2730
2731 do not form legal quoted expressions.   The quoted part ends on the
2732 first C<"> and C</>, and the rest happens to be a syntax error.
2733 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2734 the example above is not C<m//x>, but rather C<m//> with no C</x>
2735 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2736
2737 Also no attention is paid to C<\c\> (multichar control char syntax) during
2738 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2739 of C<\/>, and the following C</> is not recognized as a delimiter.
2740 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2741
2742 =item Interpolation
2743 X<interpolation>
2744
2745 The next step is interpolation in the text obtained, which is now
2746 delimiter-independent.  There are multiple cases.
2747
2748 =over 4
2749
2750 =item C<<<'EOF'>
2751
2752 No interpolation is performed.
2753 Note that the combination C<\\> is left intact, since escaped delimiters
2754 are not available for here-docs.
2755
2756 =item  C<m''>, the pattern of C<s'''>
2757
2758 No interpolation is performed at this stage.
2759 Any backslashed sequences including C<\\> are treated at the stage
2760 to L</"parsing regular expressions">.
2761
2762 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2763
2764 The only interpolation is removal of C<\> from pairs of C<\\>.
2765 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
2766 as a hyphen and no character range is available.
2767 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2768
2769 =item C<tr///>, C<y///>
2770
2771 No variable interpolation occurs.  String modifying combinations for
2772 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2773 The other escape sequences such as C<\200> and C<\t> and backslashed
2774 characters such as C<\\> and C<\-> are converted to appropriate literals.
2775 The character C<"-"> is treated specially and therefore C<\-> is treated
2776 as a literal C<"-">.
2777
2778 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2779
2780 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2781 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2782 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
2783 The other escape sequences such as C<\200> and C<\t> and backslashed
2784 characters such as C<\\> and C<\-> are replaced with appropriate
2785 expansions.
2786
2787 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2788 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2789 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2790 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2791 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2792 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2793 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2794
2795   $str = '\t';
2796   return "\Q$str";
2797
2798 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2799
2800 Interpolated scalars and arrays are converted internally to the C<join> and
2801 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
2802
2803   $foo . " XXX '" . (join $", @arr) . "'";
2804
2805 All operations above are performed simultaneously, left to right.
2806
2807 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
2808 quoted, there is no way to insert a literal C<$> or C<@> inside a
2809 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
2810 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2811 scalar.
2812
2813 Note also that the interpolation code needs to make a decision on
2814 where the interpolated scalar ends.  For instance, whether
2815 S<C<< "a $x -> {c}" >>> really means:
2816
2817   "a " . $x . " -> {c}";
2818
2819 or:
2820
2821   "a " . $x -> {c};
2822
2823 Most of the time, the longest possible text that does not include
2824 spaces between components and which contains matching braces or
2825 brackets.  because the outcome may be determined by voting based
2826 on heuristic estimators, the result is not strictly predictable.
2827 Fortunately, it's usually correct for ambiguous cases.
2828
2829 =item the replacement of C<s///>
2830
2831 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2832 happens as with C<qq//> constructs.
2833
2834 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2835 the replacement text of C<s///>, in order to correct the incorrigible
2836 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2837 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
2838 (that is, the C<$^W> variable) was set.
2839
2840 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2841
2842 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2843 and interpolation happens (almost) as with C<qq//> constructs.
2844
2845 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2846 form for the regex compiler.  (This is because, as mentioned below, the regex
2847 compilation may be done at execution time, and C<\N{...}> is a compile-time
2848 construct.)
2849
2850 However any other combinations of C<\> followed by a character
2851 are not substituted but only skipped, in order to parse them
2852 as regular expressions at the following step.
2853 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2854 treated as an array symbol (for example C<@foo>),
2855 even though the same text in C<qq//> gives interpolation of C<\c@>.
2856
2857 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2858 back to the perl parser, in a similar way that an interpolated array
2859 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2860
2861 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
2862 a C<#>-comment in a C</x>-regular expression, no processing is
2863 performed whatsoever.  This is the first step at which the presence
2864 of the C</x> modifier is relevant.
2865
2866 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2867 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2868 voted (by several different estimators) to be either an array element
2869 or C<$var> followed by an RE alternative.  This is where the notation
2870 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2871 array element C<-9>, not as a regular expression from the variable
2872 C<$arr> followed by a digit, which would be the interpretation of
2873 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2874 the result is not predictable.
2875
2876 The lack of processing of C<\\> creates specific restrictions on
2877 the post-processed text.  If the delimiter is C</>, one cannot get
2878 the combination C<\/> into the result of this step.  C</> will
2879 finish the regular expression, C<\/> will be stripped to C</> on
2880 the previous step, and C<\\/> will be left as is.  Because C</> is
2881 equivalent to C<\/> inside a regular expression, this does not
2882 matter unless the delimiter happens to be character special to the
2883 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2884 alphanumeric char, as in:
2885
2886   m m ^ a \s* b mmx;
2887
2888 In the RE above, which is intentionally obfuscated for illustration, the
2889 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2890 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
2891 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2892 non-whitespace choices.
2893
2894 =back
2895
2896 This step is the last one for all constructs except regular expressions,
2897 which are processed further.
2898
2899 =item parsing regular expressions
2900 X<regexp, parse>
2901
2902 Previous steps were performed during the compilation of Perl code,
2903 but this one happens at run time, although it may be optimized to
2904 be calculated at compile time if appropriate.  After preprocessing
2905 described above, and possibly after evaluation if concatenation,
2906 joining, casing translation, or metaquoting are involved, the
2907 resulting I<string> is passed to the RE engine for compilation.
2908
2909 Whatever happens in the RE engine might be better discussed in L<perlre>,
2910 but for the sake of continuity, we shall do so here.
2911
2912 This is another step where the presence of the C</x> modifier is
2913 relevant.  The RE engine scans the string from left to right and
2914 converts it into a finite automaton.
2915
2916 Backslashed characters are either replaced with corresponding
2917 literal strings (as with C<\{>), or else they generate special nodes
2918 in the finite automaton (as with C<\b>).  Characters special to the
2919 RE engine (such as C<|>) generate corresponding nodes or groups of
2920 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2921 converted to literal strings to match, or else is ignored (as is
2922 whitespace and C<#>-style comments if C</x> is present).
2923
2924 Parsing of the bracketed character class construct, C<[...]>, is
2925 rather different than the rule used for the rest of the pattern.
2926 The terminator of this construct is found using the same rules as
2927 for finding the terminator of a C<{}>-delimited construct, the only
2928 exception being that C<]> immediately following C<[> is treated as
2929 though preceded by a backslash.
2930
2931 The terminator of runtime C<(?{...})> is found by temporarily switching
2932 control to the perl parser, which should stop at the point where the
2933 logically balancing terminating C<}> is found.
2934
2935 It is possible to inspect both the string given to RE engine and the
2936 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2937 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
2938 switch documented in L<perlrun/"Command Switches">.
2939
2940 =item Optimization of regular expressions
2941 X<regexp, optimization>
2942
2943 This step is listed for completeness only.  Since it does not change
2944 semantics, details of this step are not documented and are subject
2945 to change without notice.  This step is performed over the finite
2946 automaton that was generated during the previous pass.
2947
2948 It is at this stage that C<split()> silently optimizes C</^/> to
2949 mean C</^/m>.
2950
2951 =back
2952
2953 =head2 I/O Operators
2954 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2955 X<< <> >> X<< <<>> >> X<@ARGV>
2956
2957 There are several I/O operators you should know about.
2958
2959 A string enclosed by backticks (grave accents) first undergoes
2960 double-quote interpolation.  It is then interpreted as an external
2961 command, and the output of that command is the value of the
2962 backtick string, like in a shell.  In scalar context, a single string
2963 consisting of all output is returned.  In list context, a list of
2964 values is returned, one per line of output.  (You can set C<$/> to use
2965 a different line terminator.)  The command is executed each time the
2966 pseudo-literal is evaluated.  The status value of the command is
2967 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2968 Unlike in B<csh>, no translation is done on the return data--newlines
2969 remain newlines.  Unlike in any of the shells, single quotes do not
2970 hide variable names in the command from interpretation.  To pass a
2971 literal dollar-sign through to the shell you need to hide it with a
2972 backslash.  The generalized form of backticks is C<qx//>.  (Because
2973 backticks always undergo shell expansion as well, see L<perlsec> for
2974 security concerns.)
2975 X<qx> X<`> X<``> X<backtick> X<glob>
2976
2977 In scalar context, evaluating a filehandle in angle brackets yields
2978 the next line from that file (the newline, if any, included), or
2979 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2980 (sometimes known as file-slurp mode) and the file is empty, it
2981 returns C<''> the first time, followed by C<undef> subsequently.
2982
2983 Ordinarily you must assign the returned value to a variable, but
2984 there is one situation where an automatic assignment happens.  If
2985 and only if the input symbol is the only thing inside the conditional
2986 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2987 the value is automatically assigned to the global variable C<$_>,
2988 destroying whatever was there previously.  (This may seem like an
2989 odd thing to you, but you'll use the construct in almost every Perl
2990 script you write.)  The C<$_> variable is not implicitly localized.
2991 You'll have to put a S<C<local $_;>> before the loop if you want that
2992 to happen.
2993
2994 The following lines are equivalent:
2995
2996     while (defined($_ = <STDIN>)) { print; }
2997     while ($_ = <STDIN>) { print; }
2998     while (<STDIN>) { print; }
2999     for (;<STDIN>;) { print; }
3000     print while defined($_ = <STDIN>);
3001     print while ($_ = <STDIN>);
3002     print while <STDIN>;
3003
3004 This also behaves similarly, but assigns to a lexical variable 
3005 instead of to C<$_>:
3006
3007     while (my $line = <STDIN>) { print $line }
3008
3009 In these loop constructs, the assigned value (whether assignment
3010 is automatic or explicit) is then tested to see whether it is
3011 defined.  The defined test avoids problems where the line has a string
3012 value that would be treated as false by Perl; for example a "" or
3013 a C<"0"> with no trailing newline.  If you really mean for such values
3014 to terminate the loop, they should be tested for explicitly:
3015
3016     while (($_ = <STDIN>) ne '0') { ... }
3017     while (<STDIN>) { last unless $_; ... }
3018
3019 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
3020 explicit C<defined> test or comparison elicits a warning if the
3021 S<C<use warnings>> pragma or the B<-w>
3022 command-line switch (the C<$^W> variable) is in effect.
3023
3024 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
3025 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
3026 in packages, where they would be interpreted as local identifiers
3027 rather than global.)  Additional filehandles may be created with
3028 the C<open()> function, amongst others.  See L<perlopentut> and
3029 L<perlfunc/open> for details on this.
3030 X<stdin> X<stdout> X<sterr>
3031
3032 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
3033 a list, a list comprising all input lines is returned, one line per
3034 list element.  It's easy to grow to a rather large data space this
3035 way, so use with care.
3036
3037 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
3038 See L<perlfunc/readline>.
3039
3040 The null filehandle C<< <> >> is special: it can be used to emulate the
3041 behavior of B<sed> and B<awk>, and any other Unix filter program
3042 that takes a list of filenames, doing the same to each line
3043 of input from all of them.  Input from C<< <> >> comes either from
3044 standard input, or from each file listed on the command line.  Here's
3045 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3046 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3047 gives you standard input.  The C<@ARGV> array is then processed as a list
3048 of filenames.  The loop
3049
3050     while (<>) {
3051         ...                     # code for each line
3052     }
3053
3054 is equivalent to the following Perl-like pseudo code:
3055
3056     unshift(@ARGV, '-') unless @ARGV;
3057     while ($ARGV = shift) {
3058         open(ARGV, $ARGV);
3059         while (<ARGV>) {
3060             ...         # code for each line
3061         }
3062     }
3063
3064 except that it isn't so cumbersome to say, and will actually work.
3065 It really does shift the C<@ARGV> array and put the current filename
3066 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3067 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3068 is magical.  (The pseudo code above doesn't work because it treats
3069 C<< <ARGV> >> as non-magical.)
3070
3071 Since the null filehandle uses the two argument form of L<perlfunc/open>
3072 it interprets special characters, so if you have a script like this:
3073
3074     while (<>) {
3075         print;
3076     }
3077
3078 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3079 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3080 If you want all items in C<@ARGV> to be interpreted as file names, you
3081 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3082
3083     while (<<>>) {
3084         print;
3085     }
3086
3087 Using double angle brackets inside of a while causes the open to use the
3088 three argument form (with the second argument being C<< < >>), so all
3089 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3090 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3091 empty, it will still read from the standard input.)
3092
3093 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3094 containing the list of filenames you really want.  Line numbers (C<$.>)
3095 continue as though the input were one big happy file.  See the example
3096 in L<perlfunc/eof> for how to reset line numbers on each file.
3097
3098 If you want to set C<@ARGV> to your own list of files, go right ahead.
3099 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3100
3101     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3102
3103 You can even set them to pipe commands.  For example, this automatically
3104 filters compressed arguments through B<gzip>:
3105
3106     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3107
3108 If you want to pass switches into your script, you can use one of the
3109 C<Getopts> modules or put a loop on the front like this:
3110
3111     while ($_ = $ARGV[0], /^-/) {
3112         shift;
3113         last if /^--$/;
3114         if (/^-D(.*)/) { $debug = $1 }
3115         if (/^-v/)     { $verbose++  }
3116         # ...           # other switches
3117     }
3118
3119     while (<>) {
3120         # ...           # code for each line
3121     }
3122
3123 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3124 If you call it again after this, it will assume you are processing another
3125 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3126
3127 If what the angle brackets contain is a simple scalar variable (for example,
3128 C<$foo>), then that variable contains the name of the
3129 filehandle to input from, or its typeglob, or a reference to the
3130 same.  For example:
3131
3132     $fh = \*STDIN;
3133     $line = <$fh>;
3134
3135 If what's within the angle brackets is neither a filehandle nor a simple
3136 scalar variable containing a filehandle name, typeglob, or typeglob
3137 reference, it is interpreted as a filename pattern to be globbed, and
3138 either a list of filenames or the next filename in the list is returned,
3139 depending on context.  This distinction is determined on syntactic
3140 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3141 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3142 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3143 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3144 is treated as C<glob("$x ")>, not C<readline($x)>.
3145
3146 One level of double-quote interpretation is done first, but you can't
3147 say C<< <$foo> >> because that's an indirect filehandle as explained
3148 in the previous paragraph.  (In older versions of Perl, programmers
3149 would insert curly brackets to force interpretation as a filename glob:
3150 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3151 internal function directly as C<glob($foo)>, which is probably the right
3152 way to have done it in the first place.)  For example:
3153
3154     while (<*.c>) {
3155         chmod 0644, $_;
3156     }
3157
3158 is roughly equivalent to:
3159
3160     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3161     while (<FOO>) {
3162         chomp;
3163         chmod 0644, $_;
3164     }
3165
3166 except that the globbing is actually done internally using the standard
3167 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3168
3169     chmod 0644, <*.c>;
3170
3171 A (file)glob evaluates its (embedded) argument only when it is
3172 starting a new list.  All values must be read before it will start
3173 over.  In list context, this isn't important because you automatically
3174 get them all anyway.  However, in scalar context the operator returns
3175 the next value each time it's called, or C<undef> when the list has
3176 run out.  As with filehandle reads, an automatic C<defined> is
3177 generated when the glob occurs in the test part of a C<while>,
3178 because legal glob returns (for example,
3179 a file called F<0>) would otherwise
3180 terminate the loop.  Again, C<undef> is returned only once.  So if
3181 you're expecting a single value from a glob, it is much better to
3182 say
3183
3184     ($file) = <blurch*>;
3185
3186 than
3187
3188     $file = <blurch*>;
3189
3190 because the latter will alternate between returning a filename and
3191 returning false.
3192
3193 If you're trying to do variable interpolation, it's definitely better
3194 to use the C<glob()> function, because the older notation can cause people
3195 to become confused with the indirect filehandle notation.
3196
3197     @files = glob("$dir/*.[ch]");
3198     @files = glob($files[$i]);
3199
3200 =head2 Constant Folding
3201 X<constant folding> X<folding>
3202
3203 Like C, Perl does a certain amount of expression evaluation at
3204 compile time whenever it determines that all arguments to an
3205 operator are static and have no side effects.  In particular, string
3206 concatenation happens at compile time between literals that don't do
3207 variable substitution.  Backslash interpolation also happens at
3208 compile time.  You can say
3209
3210       'Now is the time for all'
3211     . "\n" 
3212     .  'good men to come to.'
3213
3214 and this all reduces to one string internally.  Likewise, if
3215 you say
3216
3217     foreach $file (@filenames) {
3218         if (-s $file > 5 + 100 * 2**16) {  }
3219     }
3220
3221 the compiler precomputes the number which that expression
3222 represents so that the interpreter won't have to.
3223
3224 =head2 No-ops
3225 X<no-op> X<nop>
3226
3227 Perl doesn't officially have a no-op operator, but the bare constants
3228 C<0> and C<1> are special-cased not to produce a warning in void
3229 context, so you can for example safely do
3230
3231     1 while foo();
3232
3233 =head2 Bitwise String Operators
3234 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3235
3236 Bitstrings of any size may be manipulated by the bitwise operators
3237 (C<~ | & ^>).
3238
3239 If the operands to a binary bitwise op are strings of different
3240 sizes, B<|> and B<^> ops act as though the shorter operand had
3241 additional zero bits on the right, while the B<&> op acts as though
3242 the longer operand were truncated to the length of the shorter.
3243 The granularity for such extension or truncation is one or more
3244 bytes.
3245
3246     # ASCII-based examples
3247     print "j p \n" ^ " a h";            # prints "JAPH\n"
3248     print "JA" | "  ph\n";              # prints "japh\n"
3249     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3250     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3251
3252 If you are intending to manipulate bitstrings, be certain that
3253 you're supplying bitstrings: If an operand is a number, that will imply
3254 a B<numeric> bitwise operation.  You may explicitly show which type of
3255 operation you intend by using C<""> or C<0+>, as in the examples below.
3256
3257     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3258     $foo = '150' |  105;        # yields 255
3259     $foo =  150  | '105';       # yields 255
3260     $foo = '150' | '105';       # yields string '155' (under ASCII)
3261
3262     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3263     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3264
3265 This somewhat unpredictable behavior can be avoided with the experimental
3266 "bitwise" feature, new in Perl 5.22.  You can enable it via S<C<use feature
3267 'bitwise'>>.  By default, it will warn unless the C<"experimental::bitwise">
3268 warnings category has been disabled.  (S<C<use experimental 'bitwise'>> will
3269 enable the feature and disable the warning.)  Under this feature, the four
3270 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3271 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3272 strings:
3273
3274     use experimental "bitwise";
3275     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3276     $foo = '150' |  105;        # yields 255
3277     $foo =  150  | '105';       # yields 255
3278     $foo = '150' | '105';       # yields 255
3279     $foo =  150  |. 105;        # yields string '155'
3280     $foo = '150' |. 105;        # yields string '155'
3281     $foo =  150  |.'105';       # yields string '155'
3282     $foo = '150' |.'105';       # yields string '155'
3283
3284     $baz = $foo &  $bar;        # both operands numeric
3285     $biz = $foo ^. $bar;        # both operands stringy
3286
3287 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3288 behave likewise under the feature.
3289
3290 The behavior of these operators is problematic (and subject to change)
3291 if either or both of the strings are encoded in UTF-8 (see
3292 L<perlunicode/Byte and Character Semantics>.
3293
3294 See L<perlfunc/vec> for information on how to manipulate individual bits
3295 in a bit vector.
3296
3297 =head2 Integer Arithmetic
3298 X<integer>
3299
3300 By default, Perl assumes that it must do most of its arithmetic in
3301 floating point.  But by saying
3302
3303     use integer;
3304
3305 you may tell the compiler to use integer operations
3306 (see L<integer> for a detailed explanation) from here to the end of
3307 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3308
3309     no integer;
3310
3311 which lasts until the end of that BLOCK.  Note that this doesn't
3312 mean everything is an integer, merely that Perl will use integer
3313 operations for arithmetic, comparison, and bitwise operators.  For
3314 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3315 still get C<1.4142135623731> or so.
3316
3317 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3318 C<< >> >>) always produce integral results.  (But see also
3319 L<Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3320 them.  By default, their results are interpreted as unsigned integers, but
3321 if S<C<use integer>> is in effect, their results are interpreted
3322 as signed integers.  For example, C<~0> usually evaluates to a large
3323 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3324 machines.
3325
3326 =head2 Floating-point Arithmetic
3327
3328 X<floating-point> X<floating point> X<float> X<real>
3329
3330 While S<C<use integer>> provides integer-only arithmetic, there is no
3331 analogous mechanism to provide automatic rounding or truncation to a
3332 certain number of decimal places.  For rounding to a certain number
3333 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3334 See L<perlfaq4>.
3335
3336 Floating-point numbers are only approximations to what a mathematician
3337 would call real numbers.  There are infinitely more reals than floats,
3338 so some corners must be cut.  For example:
3339
3340     printf "%.20g\n", 123456789123456789;
3341     #        produces 123456789123456784
3342
3343 Testing for exact floating-point equality or inequality is not a
3344 good idea.  Here's a (relatively expensive) work-around to compare
3345 whether two floating-point numbers are equal to a particular number of
3346 decimal places.  See Knuth, volume II, for a more robust treatment of
3347 this topic.
3348
3349     sub fp_equal {
3350         my ($X, $Y, $POINTS) = @_;
3351         my ($tX, $tY);
3352         $tX = sprintf("%.${POINTS}g", $X);
3353         $tY = sprintf("%.${POINTS}g", $Y);
3354         return $tX eq $tY;
3355     }
3356
3357 The POSIX module (part of the standard perl distribution) implements
3358 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3359 The C<L<Math::Complex>> module (part of the standard perl distribution)
3360 defines mathematical functions that work on both the reals and the
3361 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3362 POSIX can't work with complex numbers.
3363
3364 Rounding in financial applications can have serious implications, and
3365 the rounding method used should be specified precisely.  In these
3366 cases, it probably pays not to trust whichever system rounding is
3367 being used by Perl, but to instead implement the rounding function you
3368 need yourself.
3369
3370 =head2 Bigger Numbers
3371 X<number, arbitrary precision>
3372
3373 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3374 C<L<Math::BigFloat>> modules,
3375 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3376 variable-precision arithmetic and overloaded operators, although
3377 they're currently pretty slow.  At the cost of some space and
3378 considerable speed, they avoid the normal pitfalls associated with
3379 limited-precision representations.
3380
3381         use 5.010;
3382         use bigint;  # easy interface to Math::BigInt
3383         $x = 123456789123456789;
3384         say $x * $x;
3385     +15241578780673678515622620750190521
3386
3387 Or with rationals:
3388
3389         use 5.010;
3390         use bigrat;
3391         $x = 3/22;
3392         $y = 4/6;
3393         say "x/y is ", $x/$y;
3394         say "x*y is ", $x*$y;
3395         x/y is 9/44
3396         x*y is 1/11
3397
3398 Several modules let you calculate with unlimited or fixed precision
3399 (bound only by memory and CPU time).  There
3400 are also some non-standard modules that
3401 provide faster implementations via external C libraries.
3402
3403 Here is a short, but incomplete summary:
3404
3405   Math::String           treat string sequences like numbers
3406   Math::FixedPrecision   calculate with a fixed precision
3407   Math::Currency         for currency calculations
3408   Bit::Vector            manipulate bit vectors fast (uses C)
3409   Math::BigIntFast       Bit::Vector wrapper for big numbers
3410   Math::Pari             provides access to the Pari C library
3411   Math::Cephes           uses the external Cephes C library (no
3412                          big numbers)
3413   Math::Cephes::Fraction fractions via the Cephes library
3414   Math::GMP              another one using an external C library
3415   Math::GMPz             an alternative interface to libgmp's big ints
3416   Math::GMPq             an interface to libgmp's fraction numbers
3417   Math::GMPf             an interface to libgmp's floating point numbers
3418
3419 Choose wisely.
3420
3421 =cut