installperl

   1 #!./perl -w
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8
   9     # This needs to be at BEGIN time, before any use of Config
  10     require './install_lib.pl';
  11 }
  12
  13 use strict;
  14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
  15             %opts $packlist);
  16 my ($dostrip, $versiononly, $force,
  17     $otherperls, $archname, $nwinstall, $nopods);
  18
  19 BEGIN {
  20     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  21 }
  22
  23 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  24
  25 use File::Find;
  26 use File::Compare;
  27 use File::Copy ();
  28 use File::Path ();
  29 use ExtUtils::Packlist;
  30 use Cwd;
  31
  32 require './Porting/pod_lib.pl';
  33
  34 if ($Is_NetWare) {
  35     $Is_W32 = 0;
  36     $scr_ext = '.pl';
  37 }
  38
  39 # override the ones in the rest of the script
  40 sub mkpath {
  41     File::Path::mkpath(@_) unless $opts{notify};
  42 }
  43
  44 my $mainperldir = "/usr/bin";
  45 my $exe_ext = $Config{exe_ext};
  46
  47 # Allow "make install PERLNAME=something_besides_perl":
  48 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  49
  50 # This is the base used for versioned names, like "perl5.6.0".
  51 # It's separate because a common use of $PERLNAME is to install
  52 # perl as "perl5", if that's used as base for versioned files you
  53 # get "perl55.6.0".
  54 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  55                     ? $ENV{PERLNAME_VERBASE}
  56                     : $perl;
  57 my $dbg = '';
  58 my $ndbg = '';
  59 if ( $Is_VMS ) {
  60     if ( defined $Config{usevmsdebug} ) {
  61         if ( $Config{usevmsdebug} eq 'define' ) {
  62             $dbg = 'dbg';
  63             $ndbg = 'ndbg';
  64         }
  65     }
  66 }
  67
  68 $otherperls = 1;
  69 # This little hack simplifies making the code after the comment "Fetch some
  70 # frequently-used items from %Config" warning free. With $opts{destdir} always
  71 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
  72
  73 $opts{destdir} = '';
  74 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
  75 # feature is implemented, to distinguish + and - options.
  76 while (@ARGV) {
  77     $opts{notify} = 1 if $ARGV[0] eq '-n';
  78     $dostrip = 1 if $ARGV[0] eq '-s';
  79     $versiononly = 1 if $ARGV[0] eq '-v';
  80     $versiononly = 0 if $ARGV[0] eq '+v';
  81     $opts{silent} = 1 if $ARGV[0] eq '-S';
  82     $otherperls = 0 if $ARGV[0] eq '-o';
  83     $force = 1 if $ARGV[0] eq '-f';
  84     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  85     $archname = 1 if $ARGV[0] eq '-A';
  86     $nwinstall = 1 if $ARGV[0] eq '-netware';
  87     $nopods = 1 if $ARGV[0] eq '-p';
  88     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  89     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  90         print <<"EOT";
  91 Usage $0: [switches]
  92   -n        Don't actually run any commands; just print them.
  93   -s        Run strip on installed binaries.
  94   -v        Only install perl as a binary with the version number in the name.
  95             (Override whatever config.sh says)
  96   +v        Install perl as "perl" and as a binary with the version number in
  97             the name.  (Override whatever config.sh says)
  98   -S        Silent mode.
  99   -f        Force installation (don't check if same version is there)
 100   -o        Skip checking for other copies of perl in your PATH.
 101   -V        Verbose mode.
 102   -A        Also install perl with the architecture's name in the perl binary's
 103             name.
 104   -p        Don't install the pod files. [This will break use diagnostics;]
 105   -netware  Install correctly on a Netware server.
 106   -destdir  Prefix installation directories by this string.
 107 EOT
 108         exit;
 109     }
 110     shift;
 111 }
 112
 113 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 114 my (@scripts, @tolink);
 115 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 116 while (<SCRIPTS>) {
 117     next if /^#/;
 118     next if /a2p/; # a2p is binary, to be installed separately
 119     chomp;
 120     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 121         push @scripts, $1;
 122         push @tolink, [$1, $2];
 123     } else {
 124         push @scripts, $_;
 125     }
 126 }
 127 close SCRIPTS;
 128
 129 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 130
 131 # Specify here any .pm files that are actually architecture-dependent.
 132 # (Those included with XS extensions under ext/ are automatically
 133 # added later.)
 134 # Now that the default privlib has the full perl version number included,
 135 # we no longer have to play the trick of sticking version-specific .pm
 136 # files under the archlib directory.
 137 my %archpms = (
 138     Config => 1,
 139     lib => 1,
 140     Cwd => 1,
 141 );
 142
 143 if ($^O eq 'dos') {
 144     push(@scripts,'djgpp/fixpmain');
 145     $archpms{config} = $archpms{filehand} = 1;
 146 }
 147
 148 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 149     push(@scripts, map("$_.exe", @scripts));
 150 }
 151
 152 # Exclude nonxs extensions that are not architecture dependent
 153 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
 154
 155 my @ext_dirs = qw(cpan dist ext);
 156 foreach my $ext_dir (@ext_dirs) {
 157     find(sub {
 158         if (($File::Find::name =~ m{^$ext_dir\b(.*)/([^/]+)\.pm$}) &&
 159             ! grep { (my $dir = $_) =~ s/\//-/g;
 160                      $File::Find::name =~ /^$ext_dir\/$dir\// } @nonxs)
 161         {
 162             my($path, $modname) = ($1,$2);
 163
 164             # Change hyphenated name like Filter-Util-Call to nested
 165             # directory name Filter/Util/Call
 166             $path =~ s{-}{/}g;
 167
 168             # strip to optional "/lib", or remove trailing component
 169             $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
 170
 171             # strip any leading /
 172             $path =~ s{^/}{};
 173
 174             # reconstitute canonical module name
 175             $modname = "$path/$modname" if length $path;
 176
 177             # remember it
 178             $archpms{$modname} = 1;
 179         }
 180     }, $ext_dir);
 181 }
 182
 183 # print "[$_]\n" for sort keys %archpms;
 184
 185 my $ver = $Config{version};
 186 my $release = substr($],0,3);   # Not used currently.
 187 my $patchlevel = substr($],3,2);
 188 die "Patchlevel of perl ($patchlevel)",
 189     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 190         if $patchlevel != $Config{'PERL_VERSION'};
 191
 192 # Fetch some frequently-used items from %Config
 193 my $installbin = "$opts{destdir}$Config{installbin}";
 194 my $installscript = "$opts{destdir}$Config{installscript}";
 195 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
 196 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
 197 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
 198 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
 199 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
 200 my $man1ext = $Config{man1ext};
 201 my $libperl = $Config{libperl};
 202 # Shared library and dynamic loading suffixes.
 203 my $so = $Config{so};
 204 my $dlext = $Config{dlext};
 205 my $dlsrc = $Config{dlsrc};
 206 if ($^O eq 'os390') {
 207     my $pwd;
 208     chomp($pwd=`pwd`);
 209     my $archlibexp = $Config{archlibexp};
 210     my $usedl = $Config{usedl};
 211     if ($usedl eq 'define') {
 212         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 213     }
 214 }
 215
 216 if ($nwinstall) {
 217     # This is required only if we are installing on a NetWare server
 218     $installscript = $Config{installnwscripts};
 219     $installprivlib = $Config{installnwlib};
 220     $installarchlib = $Config{installnwlib};
 221     $installsitelib = $Config{installnwlib};
 222 }
 223
 224 my $binexp = $Config{binexp};
 225
 226 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 227     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 228               \$installarchlib, \$installsitelib, \$installsitearch,
 229               \$installman1dir ) {
 230         $$_ = unixify($$_);  $$_ =~ s:/$::;
 231     }
 232 }
 233
 234 # Do some quick sanity checks.
 235
 236    $installbin          || die "No installbin directory in config.sh\n";
 237 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
 238 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
 239 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
 240         unless $installbin =~ m#^/afs/# || $opts{notify};
 241
 242 if (!$Is_NetWare) {
 243 if (!$Is_VMS) {
 244 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 245 }
 246 else {
 247 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 248     if ($dbg) {
 249         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 250     }
 251 }
 252
 253 -f 't/rantests'         || $Is_W32
 254                         || warn "WARNING: You've never run 'make test' or",
 255                                 " some tests failed! (Installing anyway.)\n";
 256 } #if (!$Is_NetWare)
 257
 258 # This will be used to store the packlist
 259 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 260
 261 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 262     my $perldll;
 263
 264     if ($Is_Cygwin) {
 265         $perldll = $libperl;
 266     } else {
 267         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
 268     }
 269
 270     if ($dlsrc ne "dl_none.xs") {
 271         -f $perldll || die "No perl DLL built\n";
 272     }
 273
 274     # Install the DLL
 275     safe_unlink("$installbin/$perldll");
 276     copy("$perldll", "$installbin/$perldll");
 277     chmod(0755, "$installbin/$perldll");
 278     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 279 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 280
 281 # First we install the version-numbered executables.
 282
 283 if ($Is_VMS) {
 284     safe_unlink("$installbin/perl_setup.com");
 285     copy("perl_setup.com", "$installbin/perl_setup.com");
 286     chmod(0755, "$installbin/perl_setup.com");
 287     safe_unlink("$installbin/$dbg$perl$exe_ext");
 288     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 289     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 290     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 291     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 292     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 293     if ($ndbg) {
 294         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 295         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 296         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 297         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 298         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 299         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 300     }
 301 }
 302 elsif ($^O eq 'mpeix') {
 303     # MPE lacks hard links and requires that executables with special
 304     # capabilities reside in the MPE namespace.
 305     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 306     # Install the primary executable into the MPE namespace as perlpath.
 307     copy("perl$exe_ext", $Config{perlpath});
 308     chmod(0755, $Config{perlpath});
 309     # Create a backup copy with the version number.
 310     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 311 }
 312 elsif ($^O ne 'dos') {
 313     if (!$Is_NetWare) {
 314         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 315         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 316         strip("$installbin/$perl_verbase$ver$exe_ext");
 317         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 318     }
 319     else {
 320         # If installing onto a NetWare server
 321         if ($nwinstall) {
 322             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 323             mkpath($Config{installnwsystem}, $opts{verbose}, 0777);
 324             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 325             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 326             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 327             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 328             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 329             mkpath($Config{installnwlcgi}, $opts{verbose}, 0777);
 330             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 331         }
 332     } #if (!$Is_NetWare)
 333 }
 334 else {
 335     safe_unlink("$installbin/$perl.exe");
 336     copy("perl.exe", "$installbin/$perl.exe");
 337 }
 338
 339 # Install library files.
 340
 341 my $do_installarchlib = !samepath($installarchlib, 'lib');
 342 my $do_installprivlib = !samepath($installprivlib, 'lib');
 343 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
 344 $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
 345
 346 mkpath($installprivlib, $opts{verbose}, 0777);
 347 mkpath($installarchlib, $opts{verbose}, 0777);
 348 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
 349 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
 350
 351 if (-d 'lib') {
 352     find({no_chdir => 1, wanted => \&installlib}, 'lib')
 353         if $do_installarchlib || $do_installprivlib;
 354 }
 355 else {
 356     warn "Can't install lib files - 'lib/' does not exist";
 357 }
 358
 359 # Install header files and libraries.
 360 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
 361 my @corefiles;
 362 if ($Is_VMS) {  # We did core file selection during build
 363     my $coredir = "lib/$Config{archname}/$ver/CORE";
 364     $coredir =~ tr/./_/;
 365     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 366 }
 367 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
 368     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 369     my $coredll = "$installarchlib/CORE/$libperl";
 370     safe_unlink($coredll);
 371     ( $Config{'d_link'} eq 'define' &&
 372       eval {
 373           CORE::link("$installbin/$libperl", $coredll);
 374           $packlist->{$coredll} = { from => "$installbin/$libperl",
 375                                     type => 'link' };
 376       }
 377     ) ||
 378     eval {
 379         symlink("$installbin/$libperl", $coredll);
 380         $packlist->{$coredll} = { from => "$installbin/$libperl",
 381                                   type => 'link' };
 382     } ||
 383     ( copy("$installbin/$libperl", $coredll) &&
 384       push(@corefiles, $coredll)
 385     )
 386 } else {
 387     # [als] hard-coded 'libperl' name... not good!
 388     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 389
 390     # AIX needs perl.exp installed as well.
 391     push(@corefiles,'perl.exp') if $^O eq 'aix';
 392     if ($^O eq 'mpeix') {
 393         # MPE needs mpeixish.h installed as well.
 394         mkpath("$installarchlib/CORE/mpeix", $opts{verbose}, 0777);
 395         push(@corefiles,'mpeix/mpeixish.h');
 396     }
 397 }
 398 foreach my $file (@corefiles) {
 399     # HP-UX (at least) needs to maintain execute permissions
 400     # on dynamically-loadable libraries. So we do it for all.
 401     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 402         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 403             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 404             chmod(0555, "$installarchlib/CORE/$file");
 405         } else {
 406             chmod(0444, "$installarchlib/CORE/$file");
 407         }
 408     }
 409 }
 410
 411 # Install main perl executables
 412 # Make links to ordinary names if installbin directory isn't current directory.
 413
 414 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 415     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 416     if ($^O eq 'mpeix') {
 417         # MPE doesn't support hard links, so use a symlink.
 418         # We don't want another cloned copy.
 419         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 420     } elsif ($^O eq 'vos') {
 421         # VOS doesn't support hard links, so use a symlink.
 422         symlink("$installbin/$perl_verbase$ver$exe_ext",
 423                 "$installbin/$perl$exe_ext");
 424     } else {
 425         link("$installbin/$perl_verbase$ver$exe_ext",
 426                 "$installbin/$perl$exe_ext");
 427     }
 428 }
 429
 430 # For development purposes it can be very useful to have multiple perls
 431 # build for different "architectures" (eg threading or not) simultaneously.
 432 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 433     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 434     safe_unlink("$installbin/$archperl");
 435     if ($^O eq 'mpeix') {
 436         # MPE doesn't support hard links, so use a symlink.
 437         # We don't want another cloned copy.
 438         symlink($Config{perlpath}, "$installbin/$archperl");
 439     } elsif ($^O eq 'vos') {
 440         # VOS doesn't support hard links, so use a symlink.
 441         symlink("$installbin/$perl_verbase$ver$exe_ext",
 442                 "$installbin/$archperl");
 443     } else {
 444         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 445     }
 446 }
 447
 448 # Offer to install perl in a "standard" location
 449
 450 my $mainperl_is_instperl = 0;
 451
 452 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 453     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 454         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 455     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 456     my($instperl)       = "$installbin/$perl$exe_ext";
 457     my($expinstperl)    = "$binexp/$perl$exe_ext";
 458
 459     # First make sure $usrbinperl is not already the same as the perl we
 460     # just installed.
 461     if (-x $usrbinperl) {
 462         # Try to be clever about mainperl being a symbolic link
 463         # to binexp/perl if binexp and installbin are different.
 464         $mainperl_is_instperl =
 465             samepath($usrbinperl, $instperl) ||
 466             samepath($usrbinperl, $expinstperl) ||
 467              (($binexp ne $installbin) &&
 468               (-l $usrbinperl) &&
 469               ((readlink $usrbinperl) eq $expinstperl));
 470     }
 471     if (! $mainperl_is_instperl) {
 472         unlink($usrbinperl);
 473         ( $Config{'d_link'} eq 'define' &&
 474           eval { CORE::link $instperl, $usrbinperl } )  ||
 475         eval { symlink $expinstperl, $usrbinperl }      ||
 476         copy($instperl, $usrbinperl);
 477
 478         $mainperl_is_instperl = 1;
 479     }
 480 }
 481
 482 # Make links to ordinary names if installbin directory isn't current directory.
 483 if (!$Is_NetWare && $dbg eq '') {
 484     if (! samepath($installbin, 'x2p')) {
 485         my $base = 'a2p';
 486         $base .= $ver if $versiononly;
 487         safe_unlink("$installbin/$base$exe_ext");
 488         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 489         strip("$installbin/$base$exe_ext");
 490         chmod(0755, "$installbin/$base$exe_ext");
 491     }
 492 }
 493
 494 # cppstdin is just a script, but it is architecture-dependent, so
 495 # it can't safely be shared.  Place it in $installbin.
 496 # Note that Configure doesn't build cppstin if it isn't needed, so
 497 # we skip this if cppstdin doesn't exist.
 498 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 499     safe_unlink("$installbin/cppstdin");
 500     copy("cppstdin", "$installbin/cppstdin");
 501     chmod(0755, "$installbin/cppstdin");
 502 }
 503
 504 sub script_alias {
 505     my ($installscript, $orig, $alias, $scr_ext) = @_;
 506
 507     safe_unlink("$installscript/$alias$scr_ext");
 508     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 509         copy("$installscript/$orig$scr_ext",
 510              "$installscript/$alias$scr_ext");
 511     } elsif ($^O eq 'vos') {
 512         symlink("$installscript/$orig$scr_ext",
 513                 "$installscript/$alias$scr_ext");
 514     } else {
 515         link("$installscript/$orig$scr_ext",
 516              "$installscript/$alias$scr_ext");
 517     }
 518 }
 519
 520 # Install scripts.
 521 mkpath($installscript, $opts{verbose}, 0777);
 522 if ($versiononly) {
 523     for (@scripts) {
 524         (my $base = $_) =~ s#.*/##;
 525         $base .= $ver;
 526         copy($_,    "$installscript/$base");
 527         chmod(0755, "$installscript/$base");
 528     }
 529
 530     for (@tolink) {
 531         my ($from, $to) = map { "$_$ver" } @$_;
 532         (my $frbase = $from) =~ s#.*/##;
 533         (my $tobase = $to) =~ s#.*/##;
 534         script_alias($installscript, $frbase, $tobase, $scr_ext);
 535     }
 536 } else {
 537     for (@scripts) {
 538         (my $base = $_) =~ s#.*/##;
 539         copy($_, "$installscript/$base");
 540         chmod(0755, "$installscript/$base");
 541     }
 542
 543     for (@tolink) {
 544         my ($from, $to) = @$_;
 545         (my $frbase = $from) =~ s#.*/##;
 546         (my $tobase = $to) =~ s#.*/##;
 547         script_alias($installscript, $frbase, $tobase, $scr_ext);
 548     }
 549 }
 550
 551 # Install pod pages.  Where? I guess in $installprivlib/pod
 552 # ($installprivlib/pods for cygwin).
 553 if (!$nopods && (!$versiononly || ($installprivlib =~ m/\Q$vershort/))) {
 554     my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
 555     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
 556
 557     for (map {$_->[1]} @{get_pod_metadata()->{master}}) {
 558         # $_ is a name like  pod/perl.pod
 559         (my $base = $_) =~ s#.*/##;
 560         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 561         chmod(0644, "${installprivlib}/$pod/${base}");
 562     }
 563
 564 }
 565
 566 # Check to make sure there aren't other perls around in installer's
 567 # path.  This is probably UNIX-specific.  Check all absolute directories
 568 # in the path except for where public executables are supposed to live.
 569 # Also skip $mainperl if the user opted to have it be a link to the
 570 # installed perl.
 571
 572 if (!$versiononly && $otherperls) {
 573     my ($path, @path);
 574     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 575     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 576     @path = split(/$dirsep/, $path);
 577     if ($Is_VMS) {
 578         my $i = 0;
 579         while (exists $ENV{'DCL$PATH' . $i}) {
 580             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 581             push(@path,$dir);
 582         }
 583     }
 584     my @otherperls;
 585     my %otherperls;
 586     for (@path) {
 587         next unless m,^/,;
 588         # Use &samepath here because some systems have other dirs linked
 589         # to $mainperldir (like SunOS)
 590         next unless -d;
 591         next if samepath($_, $binexp);
 592         next if samepath($_, cwd());
 593         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 594         my $otherperl = "$_/$perl$exe_ext";
 595         next if $otherperls{$otherperl}++;
 596         push(@otherperls, $otherperl)
 597             if (-x $otherperl && ! -d $otherperl);
 598     }
 599     if (@otherperls) {
 600         warn "\nWarning: $perl appears in your path in the following " .
 601             "locations beyond where\nwe just installed it:\n";
 602         for (@otherperls) {
 603             warn "    ", $_, "\n";
 604         }
 605         warn "\n";
 606     }
 607
 608 }
 609
 610 $packlist->write() unless $opts{notify};
 611 print "  Installation complete\n" if $opts{verbose};
 612
 613 exit 0;
 614
 615 ###############################################################################
 616
 617 # If these are needed elsewhere, move them into install_lib.pl rather than
 618 # copying them.
 619
 620 sub yn {
 621     my($prompt) = @_;
 622     my($answer);
 623     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 624     print STDERR $prompt;
 625     chop($answer = <STDIN>);
 626     $answer = $default if $answer =~ m/^\s*$/;
 627     ($answer =~ m/^[yY]/);
 628 }
 629
 630 sub safe_unlink {
 631     return if $opts{notify} or $Is_VMS;
 632     my @names = @_;
 633     foreach my $name (@names) {
 634         next unless -e $name;
 635         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 636         print "  unlink $name\n" if $opts{verbose};
 637         next if CORE::unlink($name);
 638         warn "Couldn't unlink $name: $!\n";
 639         if ($! =~ /busy/i) {
 640             print "  mv $name $name.old\n" if $opts{verbose};
 641             safe_rename($name, "$name.old")
 642                 or warn "Couldn't rename $name: $!\n";
 643         }
 644     }
 645 }
 646
 647 sub safe_rename {
 648     my($from,$to) = @_;
 649     if (-f $to and not unlink($to)) {
 650         my($i);
 651         for ($i = 1; $i < 50; $i++) {
 652             last if rename($to, "$to.$i");
 653         }
 654         warn("Cannot rename to '$to.$i': $!"), return 0
 655            if $i >= 50; # Give up!
 656     }
 657     link($from,$to) || return 0;
 658     unlink($from);
 659 }
 660
 661 sub copy {
 662     my($from,$to) = @_;
 663
 664     my $xto = $to;
 665     $xto =~ s/^\Q$opts{destdir}\E//;
 666     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
 667         unless $opts{silent};
 668     print "  creating new version of $xto\n"
 669         if $Is_VMS and -e $to and !$opts{silent};
 670     unless ($opts{notify} or File::Copy::copy($from, $to)) {
 671         # Might have been that F::C::c can't overwrite the target
 672         warn "Couldn't copy $from to $to: $!\n"
 673             unless -f $to and (chmod(0666, $to), unlink $to)
 674                    and File::Copy::copy($from, $to);
 675     }
 676     $packlist->{$xto} = { type => 'file' };
 677 }
 678
 679 sub installlib {
 680     my $dir = $File::Find::dir;
 681     $dir =~ s!\Alib/?!!;
 682
 683     m!([^/]+)\z!;
 684     my $name = $1;
 685
 686     # This remains ugly, and in need of refactoring.
 687
 688     # $name always starts as the leafname
 689     # $dir is the directory *within* lib
 690     # $name later has $dir pre-pended, to give the relative path in lib/
 691     # which is used to create the path in the target directory.
 692
 693     # $_ was always the filename to use on disk. Adding no_chdir doesn't change
 694     # this, as $_ becomes a pathname, and so still works. However, it's not
 695     # obvious that $_ is needed later, and hence $_ must not be modified.
 696
 697     # Also, many of the regex exlusion tests below are now superfluous, as the
 698     # files in question are either no longer in blead, or now in ext/, dist/ or
 699     # cpan/ and not copied into lib/
 700
 701     # Ignore version control directories.
 702     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 703         $File::Find::prune = 1;
 704         return;
 705     }
 706
 707     # ignore patch backups, RCS files, emacs backup & temp files and the
 708     # .exists files, .PL files, and test files.
 709     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util\.pl$|^filter-util\.pl$|^uupacktool\.pl$|^\.gitignore$} ||
 710               $dir  =~ m{/t(?:/|$)};
 711     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 712     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
 713     # the corelist script from lib/Module/CoreList/bin and ptar* in
 714     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
 715     # and zipdetails in cpan/IO-Compress/bin
 716     # (they're installed later with other utils)
 717     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|ptargrep|config_data|zipdetails)\z/;
 718     # ignore the Makefiles
 719     return if $name =~ /^makefile$/i;
 720     # ignore the test extensions
 721     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
 722     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
 723     # ignore the build support code
 724     return if $name =~ /\bbuildcustomize\.pl$/;
 725     # ignore the demo files
 726     return if $dir =~ /\b(?:demos?|eg)\b/;
 727     # ignore unneeded unicore files
 728     if ( $dir =~ /^unicore/ ) {
 729       if ( $name =~ /\.txt\z/ ) {
 730         # We can ignore most, but not all .txt files
 731         return unless $name =~ /\A(?:Blocks|SpecialCasing|NamedSequences)\.txt\z/;
 732       }
 733       else {
 734         # TestProp only needed during testing
 735         return if $name =~ /\ATestProp.pl\z/;
 736         # we need version and *.pl files and can skip the rest
 737         return unless $name =~ /\A(?:version|\w+\.p[lm])\z/;
 738       }
 739     }
 740
 741     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 742     # Changes.e2x and README.e2x are needed by enc2xs.
 743     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
 744     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
 745     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
 746     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 747     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
 748     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
 749
 750     # if using a shared perl library then ignore:
 751     # - static library files [of statically linked extensions];
 752     # - import library files and export library files (only present on Win32
 753     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
 754     return if $Config{useshrplib} eq 'true' and
 755              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
 756
 757     $name = "$dir/$name" if $dir ne '';
 758
 759     # ignore pods that are stand alone documentation from dual life modules.
 760     return if /\.pod\z/ && is_duplicate_pod($_);
 761
 762     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
 763
 764     my $installlib = $installprivlib;
 765     if ($dir =~ /^auto\// ||
 766           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 767           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 768           $name=~/^Config_(heavy|git)\.pl\z/
 769        ) {
 770         $installlib = $installarchlib;
 771         return unless $do_installarchlib;
 772     } else {
 773         return unless $do_installprivlib;
 774     }
 775
 776     if ($Is_NetWare && !$nwinstall && /\.(?:nlp|nlm|bs)$/) {
 777         # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 778         # if copied will give problems when building new extensions.
 779         # Has to be copied if we are installing on a NetWare server and
 780         # hence the check !$nwinstall
 781         return;
 782     }
 783
 784     if (-f $_) {
 785         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
 786             $installlib = $installprivlib;
 787             #We're installing *.al and *.ix files into $installprivlib,
 788             #but we have to delete old *.al and *.ix files from the 5.000
 789             #distribution:
 790             #This might not work because $archname might have changed.
 791             unlink("$installarchlib/$name");
 792         }
 793         my $xname = "$installlib/$name";
 794         $xname =~ s/^\Q$opts{destdir}\E//;
 795         $packlist->{$xname} = { type => 'file' };
 796         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
 797             unlink("$installlib/$name");
 798             mkpath("$installlib/$dir", $opts{verbose}, 0777);
 799             # HP-UX (at least) needs to maintain execute permissions
 800             # on dynamically-loaded libraries.
 801             if (copy_if_diff($_, "$installlib/$name")) {
 802                 strip("-S", "$installlib/$name")
 803                     if $^O =~ /^(rhapsody|darwin)$/ and /\.(?:so|$dlext|a)$/;
 804                 chmod(/\.(so|$dlext)$/ ? 0555 : 0444, "$installlib/$name");
 805             }
 806         }
 807     }
 808 }
 809
 810 # Copy $from to $to, only if $from is different than $to.
 811 # Also preserve modification times for .a libraries.
 812 # On some systems, if you do
 813 #   ranlib libperl.a
 814 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 815 # and then try to link against the installed libperl.a, you might
 816 # get an error message to the effect that the symbol table is older
 817 # than the library.
 818 # Return true if copying occurred.
 819
 820 sub copy_if_diff {
 821     my($from,$to)=@_;
 822     return 1 if (($^O eq 'VMS') && (-d $from));
 823     my $xto = $to;
 824     $xto =~ s/^\Q$opts{destdir}\E//;
 825     my $perlpodbadsymlink;
 826     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 827         -l $from &&
 828         ! -e $from) {
 829         # Some Linux implementations have problems traversing over
 830         # multiple symlinks (when going over NFS?) and fail to read
 831         # the symlink target.  Combine this with the fact that some
 832         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 833         # and you end up with those pods not getting installed.
 834         $perlpodbadsymlink = 1;
 835     }
 836     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 837     $packlist->{$xto} = { type => 'file' };
 838     if ($force || compare($from, $to) || $opts{notify}) {
 839         safe_unlink($to);   # In case we don't have write permissions.
 840         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 841             $from = "README.$1";
 842         }
 843         copy($from, $to);
 844         # Restore timestamps if it's a .a library or for OS/2.
 845         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
 846             my ($atime, $mtime) = (stat $from)[8,9];
 847             utime $atime, $mtime, $to;
 848         }
 849         1;
 850     }
 851 }
 852
 853 sub strip
 854 {
 855     my(@args) = @_;
 856
 857     return unless $dostrip;
 858
 859     my @opts;
 860     while (@args && $args[0] =~ /^(-\w+)$/) {
 861         push @opts, shift @args;
 862     }
 863
 864     foreach my $file (@args) {
 865         if (-f $file) {
 866             if ($opts{verbose}) {
 867                 print "  strip " . join(' ', @opts);
 868                 print " " if (@opts);
 869                 print "$file\n";
 870             }
 871             system("strip", @opts, $file);
 872         } else {
 873             print "# file '$file' skipped\n" if $opts{verbose};
 874         }
 875     }
 876 }
 877
 878 # Local variables:
 879 # cperl-indent-level: 4
 880 # indent-tabs-mode: nil
 881 # End:
 882 #
 883 # ex: set ts=8 sts=4 sw=4 et: