This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
9a172ad4368f4b1729f9279c3700669b35ceaf38
[perl5.git] / ext / re / re.pm
1 package re;
2
3 # pragma for controlling the regexp engine
4 use strict;
5 use warnings;
6
7 our $VERSION     = "0.31";
8 our @ISA         = qw(Exporter);
9 our @EXPORT_OK   = ('regmust',
10                     qw(is_regexp regexp_pattern
11                        regname regnames regnames_count));
12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
13
14 my %bitmask = (
15     taint   => 0x00100000, # HINT_RE_TAINT
16     eval    => 0x00200000, # HINT_RE_EVAL
17 );
18
19 my $flags_hint = 0x02000000; # HINT_RE_FLAGS
20 my $PMMOD_SHIFT = 0;
21 my %reflags = (
22     m => 1 << ($PMMOD_SHIFT + 0),
23     s => 1 << ($PMMOD_SHIFT + 1),
24     i => 1 << ($PMMOD_SHIFT + 2),
25     x => 1 << ($PMMOD_SHIFT + 3),
26     n => 1 << ($PMMOD_SHIFT + 5),
27     p => 1 << ($PMMOD_SHIFT + 6),
28     strict => 1 << ($PMMOD_SHIFT + 10),
29 # special cases:
30     d => 0,
31     l => 1,
32     u => 2,
33     a => 3,
34     aa => 4,
35 );
36
37 sub setcolor {
38  eval {                         # Ignore errors
39   require Term::Cap;
40
41   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
42   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
43   my @props = split /,/, $props;
44   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
45
46   $colors =~ s/\0//g;
47   $ENV{PERL_RE_COLORS} = $colors;
48  };
49  if ($@) {
50     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
51  }
52
53 }
54
55 my %flags = (
56     COMPILE         => 0x0000FF,
57     PARSE           => 0x000001,
58     OPTIMISE        => 0x000002,
59     TRIEC           => 0x000004,
60     DUMP            => 0x000008,
61     FLAGS           => 0x000010,
62     TEST            => 0x000020,
63
64     EXECUTE         => 0x00FF00,
65     INTUIT          => 0x000100,
66     MATCH           => 0x000200,
67     TRIEE           => 0x000400,
68
69     EXTRA           => 0xFF0000,
70     TRIEM           => 0x010000,
71     OFFSETS         => 0x020000,
72     OFFSETSDBG      => 0x040000,
73     STATE           => 0x080000,
74     OPTIMISEM       => 0x100000,
75     STACK           => 0x280000,
76     BUFFERS         => 0x400000,
77     GPOS            => 0x800000,
78 );
79 $flags{ALL} = -1 & ~($flags{OFFSETS}|$flags{OFFSETSDBG}|$flags{BUFFERS});
80 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
81 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE} | $flags{GPOS};
82 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
83 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
84 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
85
86 if (defined &DynaLoader::boot_DynaLoader) {
87     require XSLoader;
88     XSLoader::load();
89 }
90 # else we're miniperl
91 # We need to work for miniperl, because the XS toolchain uses Text::Wrap, which
92 # uses re 'taint'.
93
94 sub _load_unload {
95     my ($on)= @_;
96     if ($on) {
97         # We call install() every time, as if we didn't, we wouldn't
98         # "see" any changes to the color environment var since
99         # the last time it was called.
100
101         # install() returns an integer, which if casted properly
102         # in C resolves to a structure containing the regexp
103         # hooks. Setting it to a random integer will guarantee
104         # segfaults.
105         $^H{regcomp} = install();
106     } else {
107         delete $^H{regcomp};
108     }
109 }
110
111 sub bits {
112     my $on = shift;
113     my $bits = 0;
114     my $turning_all_off = ! @_ && ! $on;
115     my %seen;   # Has flag already been seen?
116     if ($turning_all_off) {
117
118         # Pretend were called with certain parameters, which are best dealt
119         # with XXX
120         push @_, keys %bitmask; # taint and eval
121         push @_, 'strict';
122     }
123
124     # Process each subpragma parameter
125    ARG:
126     foreach my $idx (0..$#_){
127         my $s=$_[$idx];
128         if ($s eq 'Debug' or $s eq 'Debugcolor') {
129             setcolor() if $s =~/color/i;
130             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
131             for my $idx ($idx+1..$#_) {
132                 if ($flags{$_[$idx]}) {
133                     if ($on) {
134                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
135                     } else {
136                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
137                     }
138                 } else {
139                     require Carp;
140                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
141                                join(", ",sort keys %flags ) );
142                 }
143             }
144             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
145             last;
146         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
147             setcolor() if $s =~/color/i;
148             _load_unload($on);
149             last;
150         } elsif (exists $bitmask{$s}) {
151             $bits |= $bitmask{$s};
152         } elsif ($EXPORT_OK{$s}) {
153             require Exporter;
154             re->export_to_level(2, 're', $s);
155         } elsif ($s eq 'strict') {
156             if ($on) {
157                 $^H{reflags} |= $reflags{$s};
158                 warnings::warnif('experimental::re_strict',
159                                  "\"use re 'strict'\" is experimental");
160
161                 # Turn on warnings if not already done.
162                 if (! warnings::enabled('regexp')) {
163                     require warnings;
164                     warnings->import('regexp');
165                     $^H{re_strict} = 1;
166                 }
167             }
168             else {
169                 $^H{reflags} &= ~$reflags{$s} if $^H{reflags};
170
171                 # Turn off warnings if we turned them on.
172                 warnings->unimport('regexp') if $^H{re_strict};
173             }
174             if ($^H{reflags}) {
175                 $^H |= $flags_hint;
176             }
177             else {
178                 $^H &= ~$flags_hint;
179             }
180         } elsif ($s =~ s/^\///) {
181             my $reflags = $^H{reflags} || 0;
182             my $seen_charset;
183             while ($s =~ m/( . )/gx) {
184                 local $_ = $1;
185                 if (/[adul]/) {
186                     # The 'a' may be repeated; hide this from the rest of the
187                     # code by counting and getting rid of all of them, then
188                     # changing to 'aa' if there is a repeat.
189                     if ($_ eq 'a') {
190                         my $sav_pos = pos $s;
191                         my $a_count = $s =~ s/a//g;
192                         pos $s = $sav_pos - 1;  # -1 because got rid of the 'a'
193                         if ($a_count > 2) {
194                             require Carp;
195                             Carp::carp(
196                             qq 'The "a" flag may only appear a maximum of twice'
197                             );
198                         }
199                         elsif ($a_count == 2) {
200                             $_ = 'aa';
201                         }
202                     }
203                     if ($on) {
204                         if ($seen_charset) {
205                             require Carp;
206                             if ($seen_charset ne $_) {
207                                 Carp::carp(
208                                 qq 'The "$seen_charset" and "$_" flags '
209                                 .qq 'are exclusive'
210                                 );
211                             }
212                             else {
213                                 Carp::carp(
214                                 qq 'The "$seen_charset" flag may not appear '
215                                 .qq 'twice'
216                                 );
217                             }
218                         }
219                         $^H{reflags_charset} = $reflags{$_};
220                         $seen_charset = $_;
221                     }
222                     else {
223                         delete $^H{reflags_charset}
224                                      if defined $^H{reflags_charset}
225                                         && $^H{reflags_charset} == $reflags{$_};
226                     }
227                 } elsif (exists $reflags{$_}) {
228                     $seen{$_}++;
229                     $on
230                       ? $reflags |= $reflags{$_}
231                       : ($reflags &= ~$reflags{$_});
232                 } else {
233                     require Carp;
234                     Carp::carp(
235                      qq'Unknown regular expression flag "$_"'
236                     );
237                     next ARG;
238                 }
239             }
240             ($^H{reflags} = $reflags or defined $^H{reflags_charset})
241                             ? $^H |= $flags_hint
242                             : ($^H &= ~$flags_hint);
243         } else {
244             require Carp;
245             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
246                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
247                        ")");
248         }
249     }
250     if (exists $seen{'x'} && $seen{'x'} > 1
251         && (warnings::enabled("deprecated")
252             || warnings::enabled("regexp")))
253     {
254         my $message = "Having more than one /x regexp modifier is deprecated";
255         if (warnings::enabled("deprecated")) {
256             warnings::warn("deprecated", $message);
257         }
258         else {
259             warnings::warn("regexp", $message);
260         }
261     }
262
263     if ($turning_all_off) {
264         _load_unload(0);
265         $^H{reflags} = 0;
266         $^H{reflags_charset} = 0;
267         $^H &= ~$flags_hint;
268     }
269
270     $bits;
271 }
272
273 sub import {
274     shift;
275     $^H |= bits(1, @_);
276 }
277
278 sub unimport {
279     shift;
280     $^H &= ~ bits(0, @_);
281 }
282
283 1;
284
285 __END__
286
287 =head1 NAME
288
289 re - Perl pragma to alter regular expression behaviour
290
291 =head1 SYNOPSIS
292
293     use re 'taint';
294     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
295
296     $pat = '(?{ $foo = 1 })';
297     use re 'eval';
298     /foo${pat}bar/;                # won't fail (when not under -T
299                                    # switch)
300
301     {
302         no re 'taint';             # the default
303         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
304
305         no re 'eval';              # the default
306         /foo${pat}bar/;            # disallowed (with or without -T
307                                    # switch)
308     }
309
310     use re 'strict';               # Raise warnings for more conditions
311
312     use re '/ix';
313     "FOO" =~ / foo /; # /ix implied
314     no re '/x';
315     "FOO" =~ /foo/; # just /i implied
316
317     use re 'debug';                # output debugging info during
318     /^(.*)$/s;                     # compile and run time
319
320
321     use re 'debugcolor';           # same as 'debug', but with colored
322                                    # output
323     ...
324
325     use re qw(Debug All);          # Same as "use re 'debug'", but you
326                                    # can use "Debug" with things other
327                                    # than 'All'
328     use re qw(Debug More);         # 'All' plus output more details
329     no re qw(Debug ALL);           # Turn on (almost) all re debugging
330                                    # in this scope
331
332     use re qw(is_regexp regexp_pattern); # import utility functions
333     my ($pat,$mods)=regexp_pattern(qr/foo/i);
334     if (is_regexp($obj)) { 
335         print "Got regexp: ",
336             scalar regexp_pattern($obj); # just as perl would stringify
337     }                                    # it but no hassle with blessed
338                                          # re's.
339
340 (We use $^X in these examples because it's tainted by default.)
341
342 =head1 DESCRIPTION
343
344 =head2 'taint' mode
345
346 When C<use re 'taint'> is in effect, and a tainted string is the target
347 of a regexp, the regexp memories (or values returned by the m// operator
348 in list context) are tainted.  This feature is useful when regexp operations
349 on tainted data aren't meant to extract safe substrings, but to perform
350 other transformations.
351
352 =head2 'eval' mode
353
354 When C<use re 'eval'> is in effect, a regexp is allowed to contain
355 C<(?{ ... })> zero-width assertions and C<(??{ ... })> postponed
356 subexpressions that are derived from variable interpolation, rather than
357 appearing literally within the regexp.  That is normally disallowed, since
358 it is a
359 potential security risk.  Note that this pragma is ignored when the regular
360 expression is obtained from tainted data, i.e.  evaluation is always
361 disallowed with tainted regular expressions.  See L<perlre/(?{ code })> 
362 and L<perlre/(??{ code })>.
363
364 For the purpose of this pragma, interpolation of precompiled regular
365 expressions (i.e., the result of C<qr//>) is I<not> considered variable
366 interpolation.  Thus:
367
368     /foo${pat}bar/
369
370 I<is> allowed if $pat is a precompiled regular expression, even
371 if $pat contains C<(?{ ... })> assertions or C<(??{ ... })> subexpressions.
372
373 =head2 'strict' mode
374
375 When C<use re 'strict'> is in effect, stricter checks are applied than
376 otherwise when compiling regular expressions patterns.  These may cause more
377 warnings to be raised than otherwise, and more things to be fatal instead of
378 just warnings.  The purpose of this is to find and report at compile time some
379 things, which may be legal, but have a reasonable possibility of not being the
380 programmer's actual intent.  This automatically turns on the C<"regexp">
381 warnings category (if not already on) within its scope.
382
383 As an example of something that is caught under C<"strict'> but not otherwise
384 is the pattern
385
386  qr/\xABC/
387
388 The C<"\x"> construct without curly braces should be followed by exactly two
389 hex digits; this one is followed by three.  This currently evaluates as
390 equivalent to
391
392  qr/\x{AB}C/
393
394 that is, the character whose code point value is C<0xAB>, followed by the
395 letter C<C>.  But since C<C> is a a hex digit, there is a reasonable chance
396 that the intent was
397
398  qr/\x{ABC}/
399
400 that is the single character at C<0xABC>.  Under C<'strict'> it is an error to
401 not follow C<\x> with exactly two hex digits.  When not under C<'strict'> a
402 warning is generated if there is only one hex digit, and no warning is raised
403 if there are more than two.
404
405 It is expected that what exactly C<'strict'> does will evolve over time as we
406 gain experience with it.  This means that programs that compile under it in
407 today's Perl may not compile, or may have more or fewer warnings, in future
408 Perls.  There is no backwards compatibility promises with regards to it.  For
409 this reason, using it will raise a C<experimental::re_strict> class warning,
410 unless that category is turned off.
411
412 Note that if a pattern compiled within C<'strict'> is recompiled, say by
413 interpolating into another pattern, outside of C<'strict'>, it is not checked
414 again for strictness.  This is because if it works under strict it must work
415 under non-strict.
416
417 =head2 '/flags' mode
418
419 When C<use re '/flags'> is specified, the given flags are automatically
420 added to every regular expression till the end of the lexical scope.
421
422 C<no re '/flags'> will turn off the effect of C<use re '/flags'> for the
423 given flags.
424
425 For example, if you want all your regular expressions to have /msx on by
426 default, simply put
427
428     use re '/msx';
429
430 at the top of your code.
431
432 The character set /adul flags cancel each other out. So, in this example,
433
434     use re "/u";
435     "ss" =~ /\xdf/;
436     use re "/d";
437     "ss" =~ /\xdf/;
438
439 the second C<use re> does an implicit C<no re '/u'>.
440
441 Turning on one of the character set flags with C<use re> takes precedence over the
442 C<locale> pragma and the 'unicode_strings' C<feature>, for regular
443 expressions. Turning off one of these flags when it is active reverts to
444 the behaviour specified by whatever other pragmata are in scope. For
445 example:
446
447     use feature "unicode_strings";
448     no re "/u"; # does nothing
449     use re "/l";
450     no re "/l"; # reverts to unicode_strings behaviour
451
452 =head2 'debug' mode
453
454 When C<use re 'debug'> is in effect, perl emits debugging messages when
455 compiling and using regular expressions.  The output is the same as that
456 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
457 B<-Dr> switch. It may be quite voluminous depending on the complexity
458 of the match.  Using C<debugcolor> instead of C<debug> enables a
459 form of output that can be used to get a colorful display on terminals
460 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
461 comma-separated list of C<termcap> properties to use for highlighting
462 strings on/off, pre-point part on/off.
463 See L<perldebug/"Debugging Regular Expressions"> for additional info.
464
465 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
466 lexically scoped, as the other directives are.  However they have both 
467 compile-time and run-time effects.
468
469 See L<perlmodlib/Pragmatic Modules>.
470
471 =head2 'Debug' mode
472
473 Similarly C<use re 'Debug'> produces debugging output, the difference
474 being that it allows the fine tuning of what debugging output will be
475 emitted. Options are divided into three groups, those related to
476 compilation, those related to execution and those related to special
477 purposes. The options are as follows:
478
479 =over 4
480
481 =item Compile related options
482
483 =over 4
484
485 =item COMPILE
486
487 Turns on all compile related debug options.
488
489 =item PARSE
490
491 Turns on debug output related to the process of parsing the pattern.
492
493 =item OPTIMISE
494
495 Enables output related to the optimisation phase of compilation.
496
497 =item TRIEC
498
499 Detailed info about trie compilation.
500
501 =item DUMP
502
503 Dump the final program out after it is compiled and optimised.
504
505 =item FLAGS
506
507 Dump the flags associated with the program
508
509 =item TEST
510
511 Print output intended for testing the internals of the compile process
512
513 =back
514
515 =item Execute related options
516
517 =over 4
518
519 =item EXECUTE
520
521 Turns on all execute related debug options.
522
523 =item MATCH
524
525 Turns on debugging of the main matching loop.
526
527 =item TRIEE
528
529 Extra debugging of how tries execute.
530
531 =item INTUIT
532
533 Enable debugging of start-point optimisations.
534
535 =back
536
537 =item Extra debugging options
538
539 =over 4
540
541 =item EXTRA
542
543 Turns on all "extra" debugging options.
544
545 =item BUFFERS
546
547 Enable debugging the capture group storage during match. Warning,
548 this can potentially produce extremely large output.
549
550 =item TRIEM
551
552 Enable enhanced TRIE debugging. Enhances both TRIEE
553 and TRIEC.
554
555 =item STATE
556
557 Enable debugging of states in the engine.
558
559 =item STACK
560
561 Enable debugging of the recursion stack in the engine. Enabling
562 or disabling this option automatically does the same for debugging
563 states as well. This output from this can be quite large.
564
565 =item GPOS
566
567 Enable debugging of the \G modifier.
568
569 =item OPTIMISEM
570
571 Enable enhanced optimisation debugging and start-point optimisations.
572 Probably not useful except when debugging the regexp engine itself.
573
574 =item OFFSETS
575
576 Dump offset information. This can be used to see how regops correlate
577 to the pattern. Output format is
578
579    NODENUM:POSITION[LENGTH]
580
581 Where 1 is the position of the first char in the string. Note that position
582 can be 0, or larger than the actual length of the pattern, likewise length
583 can be zero.
584
585 =item OFFSETSDBG
586
587 Enable debugging of offsets information. This emits copious
588 amounts of trace information and doesn't mesh well with other
589 debug options.
590
591 Almost definitely only useful to people hacking
592 on the offsets part of the debug engine.
593
594
595 =back
596
597 =item Other useful flags
598
599 These are useful shortcuts to save on the typing.
600
601 =over 4
602
603 =item ALL
604
605 Enable all options at once except OFFSETS, OFFSETSDBG and BUFFERS.
606 (To get every single option without exception, use both ALL and EXTRA.)
607
608 =item All
609
610 Enable DUMP and all execute options. Equivalent to:
611
612   use re 'debug';
613
614 =item MORE
615
616 =item More
617
618 Enable the options enabled by "All", plus STATE, TRIEC, and TRIEM.
619
620 =back
621
622 =back
623
624 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
625 lexically scoped, as are the other directives.  However they have both
626 compile-time and run-time effects.
627
628 =head2 Exportable Functions
629
630 As of perl 5.9.5 're' debug contains a number of utility functions that
631 may be optionally exported into the caller's namespace. They are listed
632 below.
633
634 =over 4
635
636 =item is_regexp($ref)
637
638 Returns true if the argument is a compiled regular expression as returned
639 by C<qr//>, false if it is not.
640
641 This function will not be confused by overloading or blessing. In
642 internals terms, this extracts the regexp pointer out of the
643 PERL_MAGIC_qr structure so it cannot be fooled.
644
645 =item regexp_pattern($ref)
646
647 If the argument is a compiled regular expression as returned by C<qr//>,
648 then this function returns the pattern.
649
650 In list context it returns a two element list, the first element
651 containing the pattern and the second containing the modifiers used when
652 the pattern was compiled.
653
654   my ($pat, $mods) = regexp_pattern($ref);
655
656 In scalar context it returns the same as perl would when stringifying a raw
657 C<qr//> with the same pattern inside.  If the argument is not a compiled
658 reference then this routine returns false but defined in scalar context,
659 and the empty list in list context. Thus the following
660
661     if (regexp_pattern($ref) eq '(?^i:foo)')
662
663 will be warning free regardless of what $ref actually is.
664
665 Like C<is_regexp> this function will not be confused by overloading
666 or blessing of the object.
667
668 =item regmust($ref)
669
670 If the argument is a compiled regular expression as returned by C<qr//>,
671 then this function returns what the optimiser considers to be the longest
672 anchored fixed string and longest floating fixed string in the pattern.
673
674 A I<fixed string> is defined as being a substring that must appear for the
675 pattern to match. An I<anchored fixed string> is a fixed string that must
676 appear at a particular offset from the beginning of the match. A I<floating
677 fixed string> is defined as a fixed string that can appear at any point in
678 a range of positions relative to the start of the match. For example,
679
680     my $qr = qr/here .* there/x;
681     my ($anchored, $floating) = regmust($qr);
682     print "anchored:'$anchored'\nfloating:'$floating'\n";
683
684 results in
685
686     anchored:'here'
687     floating:'there'
688
689 Because the C<here> is before the C<.*> in the pattern, its position
690 can be determined exactly. That's not true, however, for the C<there>;
691 it could appear at any point after where the anchored string appeared.
692 Perl uses both for its optimisations, preferring the longer, or, if they are
693 equal, the floating.
694
695 B<NOTE:> This may not necessarily be the definitive longest anchored and
696 floating string. This will be what the optimiser of the Perl that you
697 are using thinks is the longest. If you believe that the result is wrong
698 please report it via the L<perlbug> utility.
699
700 =item regname($name,$all)
701
702 Returns the contents of a named buffer of the last successful match. If
703 $all is true, then returns an array ref containing one entry per buffer,
704 otherwise returns the first defined buffer.
705
706 =item regnames($all)
707
708 Returns a list of all of the named buffers defined in the last successful
709 match. If $all is true, then it returns all names defined, if not it returns
710 only names which were involved in the match.
711
712 =item regnames_count()
713
714 Returns the number of distinct names defined in the pattern used
715 for the last successful match.
716
717 B<Note:> this result is always the actual number of distinct
718 named buffers defined, it may not actually match that which is
719 returned by C<regnames()> and related routines when those routines
720 have not been called with the $all parameter set.
721
722 =back
723
724 =head1 SEE ALSO
725
726 L<perlmodlib/Pragmatic Modules>.
727
728 =cut