This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
99615bcfb566f37d84b4bd3c52fa226fc441b413
[perl5.git] / lib / Pod / Parser.pm
1 #############################################################################
2 # Pod/Parser.pm -- package which defines a base class for parsing POD docs.
3 #
4 # Copyright (C) 1996-2000 by Bradford Appleton. All rights reserved.
5 # This file is part of "PodParser". PodParser is free software;
6 # you can redistribute it and/or modify it under the same terms
7 # as Perl itself.
8 #############################################################################
9
10 package Pod::Parser;
11
12 use vars qw($VERSION);
13 $VERSION = 1.12;  ## Current version of this package
14 require  5.005;    ## requires this Perl version or later
15
16 #############################################################################
17
18 =head1 NAME
19
20 Pod::Parser - base class for creating POD filters and translators
21
22 =head1 SYNOPSIS
23
24     use Pod::Parser;
25
26     package MyParser;
27     @ISA = qw(Pod::Parser);
28
29     sub command { 
30         my ($parser, $command, $paragraph, $line_num) = @_;
31         ## Interpret the command and its text; sample actions might be:
32         if ($command eq 'head1') { ... }
33         elsif ($command eq 'head2') { ... }
34         ## ... other commands and their actions
35         my $out_fh = $parser->output_handle();
36         my $expansion = $parser->interpolate($paragraph, $line_num);
37         print $out_fh $expansion;
38     }
39
40     sub verbatim { 
41         my ($parser, $paragraph, $line_num) = @_;
42         ## Format verbatim paragraph; sample actions might be:
43         my $out_fh = $parser->output_handle();
44         print $out_fh $paragraph;
45     }
46
47     sub textblock { 
48         my ($parser, $paragraph, $line_num) = @_;
49         ## Translate/Format this block of text; sample actions might be:
50         my $out_fh = $parser->output_handle();
51         my $expansion = $parser->interpolate($paragraph, $line_num);
52         print $out_fh $expansion;
53     }
54
55     sub interior_sequence { 
56         my ($parser, $seq_command, $seq_argument) = @_;
57         ## Expand an interior sequence; sample actions might be:
58         return "*$seq_argument*"     if ($seq_command eq 'B');
59         return "`$seq_argument'"     if ($seq_command eq 'C');
60         return "_${seq_argument}_'"  if ($seq_command eq 'I');
61         ## ... other sequence commands and their resulting text
62     }
63
64     package main;
65
66     ## Create a parser object and have it parse file whose name was
67     ## given on the command-line (use STDIN if no files were given).
68     $parser = new MyParser();
69     $parser->parse_from_filehandle(\*STDIN)  if (@ARGV == 0);
70     for (@ARGV) { $parser->parse_from_file($_); }
71
72 =head1 REQUIRES
73
74 perl5.005, Pod::InputObjects, Exporter, Symbol, Carp
75
76 =head1 EXPORTS
77
78 Nothing.
79
80 =head1 DESCRIPTION
81
82 B<Pod::Parser> is a base class for creating POD filters and translators.
83 It handles most of the effort involved with parsing the POD sections
84 from an input stream, leaving subclasses free to be concerned only with
85 performing the actual translation of text.
86
87 B<Pod::Parser> parses PODs, and makes method calls to handle the various
88 components of the POD. Subclasses of B<Pod::Parser> override these methods
89 to translate the POD into whatever output format they desire.
90
91 =head1 QUICK OVERVIEW
92
93 To create a POD filter for translating POD documentation into some other
94 format, you create a subclass of B<Pod::Parser> which typically overrides
95 just the base class implementation for the following methods:
96
97 =over 2
98
99 =item *
100
101 B<command()>
102
103 =item *
104
105 B<verbatim()>
106
107 =item *
108
109 B<textblock()>
110
111 =item *
112
113 B<interior_sequence()>
114
115 =back
116
117 You may also want to override the B<begin_input()> and B<end_input()>
118 methods for your subclass (to perform any needed per-file and/or
119 per-document initialization or cleanup).
120
121 If you need to perform any preprocesssing of input before it is parsed
122 you may want to override one or more of B<preprocess_line()> and/or
123 B<preprocess_paragraph()>.
124
125 Sometimes it may be necessary to make more than one pass over the input
126 files. If this is the case you have several options. You can make the
127 first pass using B<Pod::Parser> and override your methods to store the
128 intermediate results in memory somewhere for the B<end_pod()> method to
129 process. You could use B<Pod::Parser> for several passes with an
130 appropriate state variable to control the operation for each pass. If
131 your input source can't be reset to start at the beginning, you can
132 store it in some other structure as a string or an array and have that
133 structure implement a B<getline()> method (which is all that
134 B<parse_from_filehandle()> uses to read input).
135
136 Feel free to add any member data fields you need to keep track of things
137 like current font, indentation, horizontal or vertical position, or
138 whatever else you like. Be sure to read L<"PRIVATE METHODS AND DATA">
139 to avoid name collisions.
140
141 For the most part, the B<Pod::Parser> base class should be able to
142 do most of the input parsing for you and leave you free to worry about
143 how to intepret the commands and translate the result.
144
145 Note that all we have described here in this quick overview is the
146 simplest most straightforward use of B<Pod::Parser> to do stream-based
147 parsing. It is also possible to use the B<Pod::Parser::parse_text> function
148 to do more sophisticated tree-based parsing. See L<"TREE-BASED PARSING">.
149
150 =head1 PARSING OPTIONS
151
152 A I<parse-option> is simply a named option of B<Pod::Parser> with a
153 value that corresponds to a certain specified behavior. These various
154 behaviors of B<Pod::Parser> may be enabled/disabled by setting or
155 or unsetting one or more I<parse-options> using the B<parseopts()> method.
156 The set of currently accepted parse-options is as follows:
157
158 =over 3
159
160 =item B<-want_nonPODs> (default: unset)
161
162 Normally (by default) B<Pod::Parser> will only provide access to
163 the POD sections of the input. Input paragraphs that are not part
164 of the POD-format documentation are not made available to the caller
165 (not even using B<preprocess_paragraph()>). Setting this option to a
166 non-empty, non-zero value will allow B<preprocess_paragraph()> to see
167 non-POD sections of the input as well as POD sections. The B<cutting()>
168 method can be used to determine if the corresponding paragraph is a POD
169 paragraph, or some other input paragraph.
170
171 =item B<-process_cut_cmd> (default: unset)
172
173 Normally (by default) B<Pod::Parser> handles the C<=cut> POD directive
174 by itself and does not pass it on to the caller for processing. Setting
175 this option to a non-empty, non-zero value will cause B<Pod::Parser> to
176 pass the C<=cut> directive to the caller just like any other POD command
177 (and hence it may be processed by the B<command()> method).
178
179 B<Pod::Parser> will still interpret the C<=cut> directive to mean that
180 "cutting mode" has been (re)entered, but the caller will get a chance
181 to capture the actual C<=cut> paragraph itself for whatever purpose
182 it desires.
183
184 =item B<-warnings> (default: unset)
185
186 Normally (by default) B<Pod::Parser> recognizes a bare minimum of
187 pod syntax errors and warnings and issues diagnostic messages
188 for errors, but not for warnings. (Use B<Pod::Checker> to do more
189 thorough checking of POD syntax.) Setting this option to a non-empty,
190 non-zero value will cause B<Pod::Parser> to issue diagnostics for
191 the few warnings it recognizes as well as the errors.
192
193 =back
194
195 Please see L<"parseopts()"> for a complete description of the interface
196 for the setting and unsetting of parse-options.
197
198 =cut
199
200 #############################################################################
201
202 use vars qw(@ISA);
203 use strict;
204 #use diagnostics;
205 use Pod::InputObjects;
206 use Carp;
207 use Exporter;
208 BEGIN {
209    if ($] < 5.6) {
210       require Symbol;
211       import Symbol;
212    }
213 }
214 @ISA = qw(Exporter);
215
216 ## These "variables" are used as local "glob aliases" for performance
217 use vars qw(%myData %myOpts @input_stack);
218
219 #############################################################################
220
221 =head1 RECOMMENDED SUBROUTINE/METHOD OVERRIDES
222
223 B<Pod::Parser> provides several methods which most subclasses will probably
224 want to override. These methods are as follows:
225
226 =cut
227
228 ##---------------------------------------------------------------------------
229
230 =head1 B<command()>
231
232             $parser->command($cmd,$text,$line_num,$pod_para);
233
234 This method should be overridden by subclasses to take the appropriate
235 action when a POD command paragraph (denoted by a line beginning with
236 "=") is encountered. When such a POD directive is seen in the input,
237 this method is called and is passed:
238
239 =over 3
240
241 =item C<$cmd>
242
243 the name of the command for this POD paragraph
244
245 =item C<$text>
246
247 the paragraph text for the given POD paragraph command.
248
249 =item C<$line_num>
250
251 the line-number of the beginning of the paragraph
252
253 =item C<$pod_para>
254
255 a reference to a C<Pod::Paragraph> object which contains further
256 information about the paragraph command (see L<Pod::InputObjects>
257 for details).
258
259 =back
260
261 B<Note> that this method I<is> called for C<=pod> paragraphs.
262
263 The base class implementation of this method simply treats the raw POD
264 command as normal block of paragraph text (invoking the B<textblock()>
265 method with the command paragraph).
266
267 =cut
268
269 sub command {
270     my ($self, $cmd, $text, $line_num, $pod_para)  = @_;
271     ## Just treat this like a textblock
272     $self->textblock($pod_para->raw_text(), $line_num, $pod_para);
273 }
274
275 ##---------------------------------------------------------------------------
276
277 =head1 B<verbatim()>
278
279             $parser->verbatim($text,$line_num,$pod_para);
280
281 This method may be overridden by subclasses to take the appropriate
282 action when a block of verbatim text is encountered. It is passed the
283 following parameters:
284
285 =over 3
286
287 =item C<$text>
288
289 the block of text for the verbatim paragraph
290
291 =item C<$line_num>
292
293 the line-number of the beginning of the paragraph
294
295 =item C<$pod_para>
296
297 a reference to a C<Pod::Paragraph> object which contains further
298 information about the paragraph (see L<Pod::InputObjects>
299 for details).
300
301 =back
302
303 The base class implementation of this method simply prints the textblock
304 (unmodified) to the output filehandle.
305
306 =cut
307
308 sub verbatim {
309     my ($self, $text, $line_num, $pod_para) = @_;
310     my $out_fh = $self->{_OUTPUT};
311     print $out_fh $text;
312 }
313
314 ##---------------------------------------------------------------------------
315
316 =head1 B<textblock()>
317
318             $parser->textblock($text,$line_num,$pod_para);
319
320 This method may be overridden by subclasses to take the appropriate
321 action when a normal block of POD text is encountered (although the base
322 class method will usually do what you want). It is passed the following
323 parameters:
324
325 =over 3
326
327 =item C<$text>
328
329 the block of text for the a POD paragraph
330
331 =item C<$line_num>
332
333 the line-number of the beginning of the paragraph
334
335 =item C<$pod_para>
336
337 a reference to a C<Pod::Paragraph> object which contains further
338 information about the paragraph (see L<Pod::InputObjects>
339 for details).
340
341 =back
342
343 In order to process interior sequences, subclasses implementations of
344 this method will probably want to invoke either B<interpolate()> or
345 B<parse_text()>, passing it the text block C<$text>, and the corresponding
346 line number in C<$line_num>, and then perform any desired processing upon
347 the returned result.
348
349 The base class implementation of this method simply prints the text block
350 as it occurred in the input stream).
351
352 =cut
353
354 sub textblock {
355     my ($self, $text, $line_num, $pod_para) = @_;
356     my $out_fh = $self->{_OUTPUT};
357     print $out_fh $self->interpolate($text, $line_num);
358 }
359
360 ##---------------------------------------------------------------------------
361
362 =head1 B<interior_sequence()>
363
364             $parser->interior_sequence($seq_cmd,$seq_arg,$pod_seq);
365
366 This method should be overridden by subclasses to take the appropriate
367 action when an interior sequence is encountered. An interior sequence is
368 an embedded command within a block of text which appears as a command
369 name (usually a single uppercase character) followed immediately by a
370 string of text which is enclosed in angle brackets. This method is
371 passed the sequence command C<$seq_cmd> and the corresponding text
372 C<$seq_arg>. It is invoked by the B<interpolate()> method for each interior
373 sequence that occurs in the string that it is passed. It should return
374 the desired text string to be used in place of the interior sequence.
375 The C<$pod_seq> argument is a reference to a C<Pod::InteriorSequence>
376 object which contains further information about the interior sequence.
377 Please see L<Pod::InputObjects> for details if you need to access this
378 additional information.
379
380 Subclass implementations of this method may wish to invoke the 
381 B<nested()> method of C<$pod_seq> to see if it is nested inside
382 some other interior-sequence (and if so, which kind).
383
384 The base class implementation of the B<interior_sequence()> method
385 simply returns the raw text of the interior sequence (as it occurred
386 in the input) to the caller.
387
388 =cut
389
390 sub interior_sequence {
391     my ($self, $seq_cmd, $seq_arg, $pod_seq) = @_;
392     ## Just return the raw text of the interior sequence
393     return  $pod_seq->raw_text();
394 }
395
396 #############################################################################
397
398 =head1 OPTIONAL SUBROUTINE/METHOD OVERRIDES
399
400 B<Pod::Parser> provides several methods which subclasses may want to override
401 to perform any special pre/post-processing. These methods do I<not> have to
402 be overridden, but it may be useful for subclasses to take advantage of them.
403
404 =cut
405
406 ##---------------------------------------------------------------------------
407
408 =head1 B<new()>
409
410             my $parser = Pod::Parser->new();
411
412 This is the constructor for B<Pod::Parser> and its subclasses. You
413 I<do not> need to override this method! It is capable of constructing
414 subclass objects as well as base class objects, provided you use
415 any of the following constructor invocation styles:
416
417     my $parser1 = MyParser->new();
418     my $parser2 = new MyParser();
419     my $parser3 = $parser2->new();
420
421 where C<MyParser> is some subclass of B<Pod::Parser>.
422
423 Using the syntax C<MyParser::new()> to invoke the constructor is I<not>
424 recommended, but if you insist on being able to do this, then the
425 subclass I<will> need to override the B<new()> constructor method. If
426 you do override the constructor, you I<must> be sure to invoke the
427 B<initialize()> method of the newly blessed object.
428
429 Using any of the above invocations, the first argument to the
430 constructor is always the corresponding package name (or object
431 reference). No other arguments are required, but if desired, an
432 associative array (or hash-table) my be passed to the B<new()>
433 constructor, as in:
434
435     my $parser1 = MyParser->new( MYDATA => $value1, MOREDATA => $value2 );
436     my $parser2 = new MyParser( -myflag => 1 );
437
438 All arguments passed to the B<new()> constructor will be treated as
439 key/value pairs in a hash-table. The newly constructed object will be
440 initialized by copying the contents of the given hash-table (which may
441 have been empty). The B<new()> constructor for this class and all of its
442 subclasses returns a blessed reference to the initialized object (hash-table).
443
444 =cut
445
446 sub new {
447     ## Determine if we were called via an object-ref or a classname
448     my $this = shift;
449     my $class = ref($this) || $this;
450     ## Any remaining arguments are treated as initial values for the
451     ## hash that is used to represent this object.
452     my %params = @_;
453     my $self = { %params };
454     ## Bless ourselves into the desired class and perform any initialization
455     bless $self, $class;
456     $self->initialize();
457     return $self;
458 }
459
460 ##---------------------------------------------------------------------------
461
462 =head1 B<initialize()>
463
464             $parser->initialize();
465
466 This method performs any necessary object initialization. It takes no
467 arguments (other than the object instance of course, which is typically
468 copied to a local variable named C<$self>). If subclasses override this
469 method then they I<must> be sure to invoke C<$self-E<gt>SUPER::initialize()>.
470
471 =cut
472
473 sub initialize {
474     #my $self = shift;
475     #return;
476 }
477
478 ##---------------------------------------------------------------------------
479
480 =head1 B<begin_pod()>
481
482             $parser->begin_pod();
483
484 This method is invoked at the beginning of processing for each POD
485 document that is encountered in the input. Subclasses should override
486 this method to perform any per-document initialization.
487
488 =cut
489
490 sub begin_pod {
491     #my $self = shift;
492     #return;
493 }
494
495 ##---------------------------------------------------------------------------
496
497 =head1 B<begin_input()>
498
499             $parser->begin_input();
500
501 This method is invoked by B<parse_from_filehandle()> immediately I<before>
502 processing input from a filehandle. The base class implementation does
503 nothing, however, subclasses may override it to perform any per-file
504 initializations.
505
506 Note that if multiple files are parsed for a single POD document
507 (perhaps the result of some future C<=include> directive) this method
508 is invoked for every file that is parsed. If you wish to perform certain
509 initializations once per document, then you should use B<begin_pod()>.
510
511 =cut
512
513 sub begin_input {
514     #my $self = shift;
515     #return;
516 }
517
518 ##---------------------------------------------------------------------------
519
520 =head1 B<end_input()>
521
522             $parser->end_input();
523
524 This method is invoked by B<parse_from_filehandle()> immediately I<after>
525 processing input from a filehandle. The base class implementation does
526 nothing, however, subclasses may override it to perform any per-file
527 cleanup actions.
528
529 Please note that if multiple files are parsed for a single POD document
530 (perhaps the result of some kind of C<=include> directive) this method
531 is invoked for every file that is parsed. If you wish to perform certain
532 cleanup actions once per document, then you should use B<end_pod()>.
533
534 =cut
535
536 sub end_input {
537     #my $self = shift;
538     #return;
539 }
540
541 ##---------------------------------------------------------------------------
542
543 =head1 B<end_pod()>
544
545             $parser->end_pod();
546
547 This method is invoked at the end of processing for each POD document
548 that is encountered in the input. Subclasses should override this method
549 to perform any per-document finalization.
550
551 =cut
552
553 sub end_pod {
554     #my $self = shift;
555     #return;
556 }
557
558 ##---------------------------------------------------------------------------
559
560 =head1 B<preprocess_line()>
561
562           $textline = $parser->preprocess_line($text, $line_num);
563
564 This method should be overridden by subclasses that wish to perform
565 any kind of preprocessing for each I<line> of input (I<before> it has
566 been determined whether or not it is part of a POD paragraph). The
567 parameter C<$text> is the input line; and the parameter C<$line_num> is
568 the line number of the corresponding text line.
569
570 The value returned should correspond to the new text to use in its
571 place.  If the empty string or an undefined value is returned then no
572 further processing will be performed for this line.
573
574 Please note that the B<preprocess_line()> method is invoked I<before>
575 the B<preprocess_paragraph()> method. After all (possibly preprocessed)
576 lines in a paragraph have been assembled together and it has been
577 determined that the paragraph is part of the POD documentation from one
578 of the selected sections, then B<preprocess_paragraph()> is invoked.
579
580 The base class implementation of this method returns the given text.
581
582 =cut
583
584 sub preprocess_line {
585     my ($self, $text, $line_num) = @_;
586     return  $text;
587 }
588
589 ##---------------------------------------------------------------------------
590
591 =head1 B<preprocess_paragraph()>
592
593             $textblock = $parser->preprocess_paragraph($text, $line_num);
594
595 This method should be overridden by subclasses that wish to perform any
596 kind of preprocessing for each block (paragraph) of POD documentation
597 that appears in the input stream. The parameter C<$text> is the POD
598 paragraph from the input file; and the parameter C<$line_num> is the
599 line number for the beginning of the corresponding paragraph.
600
601 The value returned should correspond to the new text to use in its
602 place If the empty string is returned or an undefined value is
603 returned, then the given C<$text> is ignored (not processed).
604
605 This method is invoked after gathering up all the lines in a paragraph
606 and after determining the cutting state of the paragraph,
607 but before trying to further parse or interpret them. After
608 B<preprocess_paragraph()> returns, the current cutting state (which
609 is returned by C<$self-E<gt>cutting()>) is examined. If it evaluates
610 to true then input text (including the given C<$text>) is cut (not
611 processed) until the next POD directive is encountered.
612
613 Please note that the B<preprocess_line()> method is invoked I<before>
614 the B<preprocess_paragraph()> method. After all (possibly preprocessed)
615 lines in a paragraph have been assembled together and either it has been
616 determined that the paragraph is part of the POD documentation from one
617 of the selected sections or the C<-want_nonPODs> option is true,
618 then B<preprocess_paragraph()> is invoked.
619
620 The base class implementation of this method returns the given text.
621
622 =cut
623
624 sub preprocess_paragraph {
625     my ($self, $text, $line_num) = @_;
626     return  $text;
627 }
628
629 #############################################################################
630
631 =head1 METHODS FOR PARSING AND PROCESSING
632
633 B<Pod::Parser> provides several methods to process input text. These
634 methods typically won't need to be overridden (and in some cases they
635 can't be overridden), but subclasses may want to invoke them to exploit
636 their functionality.
637
638 =cut
639
640 ##---------------------------------------------------------------------------
641
642 =head1 B<parse_text()>
643
644             $ptree1 = $parser->parse_text($text, $line_num);
645             $ptree2 = $parser->parse_text({%opts}, $text, $line_num);
646             $ptree3 = $parser->parse_text(\%opts, $text, $line_num);
647
648 This method is useful if you need to perform your own interpolation 
649 of interior sequences and can't rely upon B<interpolate> to expand
650 them in simple bottom-up order order.
651
652 The parameter C<$text> is a string or block of text to be parsed
653 for interior sequences; and the parameter C<$line_num> is the
654 line number curresponding to the beginning of C<$text>.
655
656 B<parse_text()> will parse the given text into a parse-tree of "nodes."
657 and interior-sequences.  Each "node" in the parse tree is either a
658 text-string, or a B<Pod::InteriorSequence>.  The result returned is a
659 parse-tree of type B<Pod::ParseTree>. Please see L<Pod::InputObjects>
660 for more information about B<Pod::InteriorSequence> and B<Pod::ParseTree>.
661
662 If desired, an optional hash-ref may be specified as the first argument
663 to customize certain aspects of the parse-tree that is created and
664 returned. The set of recognized option keywords are:
665
666 =over 3
667
668 =item B<-expand_seq> =E<gt> I<code-ref>|I<method-name>
669
670 Normally, the parse-tree returned by B<parse_text()> will contain an
671 unexpanded C<Pod::InteriorSequence> object for each interior-sequence
672 encountered. Specifying B<-expand_seq> tells B<parse_text()> to "expand"
673 every interior-sequence it sees by invoking the referenced function
674 (or named method of the parser object) and using the return value as the
675 expanded result.
676
677 If a subroutine reference was given, it is invoked as:
678
679   &$code_ref( $parser, $sequence )
680
681 and if a method-name was given, it is invoked as:
682
683   $parser->method_name( $sequence )
684
685 where C<$parser> is a reference to the parser object, and C<$sequence>
686 is a reference to the interior-sequence object.
687 [I<NOTE>: If the B<interior_sequence()> method is specified, then it is
688 invoked according to the interface specified in L<"interior_sequence()">].
689
690 =item B<-expand_text> =E<gt> I<code-ref>|I<method-name>
691
692 Normally, the parse-tree returned by B<parse_text()> will contain a
693 text-string for each contiguous sequence of characters outside of an
694 interior-sequence. Specifying B<-expand_text> tells B<parse_text()> to
695 "preprocess" every such text-string it sees by invoking the referenced
696 function (or named method of the parser object) and using the return value
697 as the preprocessed (or "expanded") result. [Note that if the result is
698 an interior-sequence, then it will I<not> be expanded as specified by the
699 B<-expand_seq> option; Any such recursive expansion needs to be handled by
700 the specified callback routine.]
701
702 If a subroutine reference was given, it is invoked as:
703
704   &$code_ref( $parser, $text, $ptree_node )
705
706 and if a method-name was given, it is invoked as:
707
708   $parser->method_name( $text, $ptree_node )
709
710 where C<$parser> is a reference to the parser object, C<$text> is the
711 text-string encountered, and C<$ptree_node> is a reference to the current
712 node in the parse-tree (usually an interior-sequence object or else the
713 top-level node of the parse-tree).
714
715 =item B<-expand_ptree> =E<gt> I<code-ref>|I<method-name>
716
717 Rather than returning a C<Pod::ParseTree>, pass the parse-tree as an
718 argument to the referenced subroutine (or named method of the parser
719 object) and return the result instead of the parse-tree object.
720
721 If a subroutine reference was given, it is invoked as:
722
723   &$code_ref( $parser, $ptree )
724
725 and if a method-name was given, it is invoked as:
726
727   $parser->method_name( $ptree )
728
729 where C<$parser> is a reference to the parser object, and C<$ptree>
730 is a reference to the parse-tree object.
731
732 =back
733
734 =cut
735
736 sub parse_text {
737     my $self = shift;
738     local $_ = '';
739
740     ## Get options and set any defaults
741     my %opts = (ref $_[0]) ? %{ shift() } : ();
742     my $expand_seq   = $opts{'-expand_seq'}   || undef;
743     my $expand_text  = $opts{'-expand_text'}  || undef;
744     my $expand_ptree = $opts{'-expand_ptree'} || undef;
745
746     my $text = shift;
747     my $line = shift;
748     my $file = $self->input_file();
749     my $cmd  = "";
750
751     ## Convert method calls into closures, for our convenience
752     my $xseq_sub   = $expand_seq;
753     my $xtext_sub  = $expand_text;
754     my $xptree_sub = $expand_ptree;
755     if (defined $expand_seq  and  $expand_seq eq 'interior_sequence') {
756         ## If 'interior_sequence' is the method to use, we have to pass
757         ## more than just the sequence object, we also need to pass the
758         ## sequence name and text.
759         $xseq_sub = sub {
760             my ($self, $iseq) = @_;
761             my $args = join("", $iseq->parse_tree->children);
762             return  $self->interior_sequence($iseq->name, $args, $iseq);
763         };
764     }
765     ref $xseq_sub    or  $xseq_sub   = sub { shift()->$expand_seq(@_) };
766     ref $xtext_sub   or  $xtext_sub  = sub { shift()->$expand_text(@_) };
767     ref $xptree_sub  or  $xptree_sub = sub { shift()->$expand_ptree(@_) };
768
769     ## Keep track of the "current" interior sequence, and maintain a stack
770     ## of "in progress" sequences.
771     ##
772     ## NOTE that we push our own "accumulator" at the very beginning of the
773     ## stack. It's really a parse-tree, not a sequence; but it implements
774     ## the methods we need so we can use it to gather-up all the sequences
775     ## and strings we parse. Thus, by the end of our parsing, it should be
776     ## the only thing left on our stack and all we have to do is return it!
777     ##
778     my $seq       = Pod::ParseTree->new();
779     my @seq_stack = ($seq);
780     my ($ldelim, $rdelim) = ('', '');
781
782     ## Iterate over all sequence starts text (NOTE: split with
783     ## capturing parens keeps the delimiters)
784     $_ = $text;
785     my @tokens = split /([A-Z]<(?:<+\s+)?)/;
786     while ( @tokens ) {
787         $_ = shift @tokens;
788         ## Look for the beginning of a sequence
789         if ( /^([A-Z])(<(?:<+\s+)?)$/ ) {
790             ## Push a new sequence onto the stack of those "in-progress"
791             ($cmd, $ldelim) = ($1, $2);
792             $seq = Pod::InteriorSequence->new(
793                        -name   => $cmd,
794                        -ldelim => $ldelim,  -rdelim => '',
795                        -file   => $file,    -line   => $line
796                    );
797             $ldelim =~ s/\s+$//, ($rdelim = $ldelim) =~ tr/</>/;
798             (@seq_stack > 1)  and  $seq->nested($seq_stack[-1]);
799             push @seq_stack, $seq;
800         }
801         ## Look for sequence ending
802         elsif ( @seq_stack > 1 ) {
803             ## Make sure we match the right kind of closing delimiter
804             my ($seq_end, $post_seq) = ("", "");
805             if ( ($ldelim eq '<'   and  /\A(.*?)(>)/s)
806                  or  /\A(.*?)(\s+$rdelim)/s )
807             {
808                 ## Found end-of-sequence, capture the interior and the
809                 ## closing the delimiter, and put the rest back on the
810                 ## token-list
811                 $post_seq = substr($_, length($1) + length($2));
812                 ($_, $seq_end) = ($1, $2);
813                 (length $post_seq)  and  unshift @tokens, $post_seq;
814             }
815             if (length) {
816                 ## In the middle of a sequence, append this text to it, and
817                 ## dont forget to "expand" it if that's what the caller wanted
818                 $seq->append($expand_text ? &$xtext_sub($self,$_,$seq) : $_);
819                 $_ .= $seq_end;
820             }
821             if (length $seq_end) {
822                 ## End of current sequence, record terminating delimiter
823                 $seq->rdelim($seq_end);
824                 ## Pop it off the stack of "in progress" sequences
825                 pop @seq_stack;
826                 ## Append result to its parent in current parse tree
827                 $seq_stack[-1]->append($expand_seq ? &$xseq_sub($self,$seq)
828                                                    : $seq);
829                 ## Remember the current cmd-name and left-delimiter
830                 $cmd = (@seq_stack > 1) ? $seq_stack[-1]->name : '';
831                 $ldelim = (@seq_stack > 1) ? $seq_stack[-1]->ldelim : '';
832                 $ldelim =~ s/\s+$//, ($rdelim = $ldelim) =~ tr/</>/;
833             }
834         }
835         elsif (length) {
836             ## In the middle of a sequence, append this text to it, and
837             ## dont forget to "expand" it if that's what the caller wanted
838             $seq->append($expand_text ? &$xtext_sub($self,$_,$seq) : $_);
839         }
840         ## Keep track of line count
841         $line += tr/\n//;
842         ## Remember the "current" sequence
843         $seq = $seq_stack[-1];
844     }
845
846     ## Handle unterminated sequences
847     my $errorsub = (@seq_stack > 1) ? $self->errorsub() : undef;
848     while (@seq_stack > 1) {
849        ($cmd, $file, $line) = ($seq->name, $seq->file_line);
850        $ldelim  = $seq->ldelim;
851        ($rdelim = $ldelim) =~ tr/</>/;
852        $rdelim  =~ s/^(\S+)(\s*)$/$2$1/;
853        pop @seq_stack;
854        my $errmsg = "*** ERROR: unterminated ${cmd}${ldelim}...${rdelim}".
855                     " at line $line in file $file\n";
856        (ref $errorsub) and &{$errorsub}($errmsg)
857            or (defined $errorsub) and $self->$errorsub($errmsg)
858                or  warn($errmsg);
859        $seq_stack[-1]->append($expand_seq ? &$xseq_sub($self,$seq) : $seq);
860        $seq = $seq_stack[-1];
861     }
862
863     ## Return the resulting parse-tree
864     my $ptree = (pop @seq_stack)->parse_tree;
865     return  $expand_ptree ? &$xptree_sub($self, $ptree) : $ptree;
866 }
867
868 ##---------------------------------------------------------------------------
869
870 =head1 B<interpolate()>
871
872             $textblock = $parser->interpolate($text, $line_num);
873
874 This method translates all text (including any embedded interior sequences)
875 in the given text string C<$text> and returns the interpolated result. The
876 parameter C<$line_num> is the line number corresponding to the beginning
877 of C<$text>.
878
879 B<interpolate()> merely invokes a private method to recursively expand
880 nested interior sequences in bottom-up order (innermost sequences are
881 expanded first). If there is a need to expand nested sequences in
882 some alternate order, use B<parse_text> instead.
883
884 =cut
885
886 sub interpolate {
887     my($self, $text, $line_num) = @_;
888     my %parse_opts = ( -expand_seq => 'interior_sequence' );
889     my $ptree = $self->parse_text( \%parse_opts, $text, $line_num );
890     return  join "", $ptree->children();
891 }
892
893 ##---------------------------------------------------------------------------
894
895 =begin __PRIVATE__
896
897 =head1 B<parse_paragraph()>
898
899             $parser->parse_paragraph($text, $line_num);
900
901 This method takes the text of a POD paragraph to be processed, along
902 with its corresponding line number, and invokes the appropriate method
903 (one of B<command()>, B<verbatim()>, or B<textblock()>).
904
905 For performance reasons, this method is invoked directly without any
906 dynamic lookup; Hence subclasses may I<not> override it!
907
908 =end __PRIVATE__
909
910 =cut
911
912 sub parse_paragraph {
913     my ($self, $text, $line_num) = @_;
914     local *myData = $self;  ## alias to avoid deref-ing overhead
915     local *myOpts = ($myData{_PARSEOPTS} ||= {});  ## get parse-options
916     local $_;
917
918     ## See if we want to preprocess nonPOD paragraphs as well as POD ones.
919     my $wantNonPods = $myOpts{'-want_nonPODs'};
920
921     ## Update cutting status
922     $myData{_CUTTING} = 0 if $text =~ /^={1,2}\S/;
923
924     ## Perform any desired preprocessing if we wanted it this early
925     $wantNonPods  and  $text = $self->preprocess_paragraph($text, $line_num);
926
927     ## Ignore up until next POD directive if we are cutting
928     return if $myData{_CUTTING};
929
930     ## Now we know this is block of text in a POD section!
931
932     ##-----------------------------------------------------------------
933     ## This is a hook (hack ;-) for Pod::Select to do its thing without
934     ## having to override methods, but also without Pod::Parser assuming
935     ## $self is an instance of Pod::Select (if the _SELECTED_SECTIONS
936     ## field exists then we assume there is an is_selected() method for
937     ## us to invoke (calling $self->can('is_selected') could verify this
938     ## but that is more overhead than I want to incur)
939     ##-----------------------------------------------------------------
940
941     ## Ignore this block if it isnt in one of the selected sections
942     if (exists $myData{_SELECTED_SECTIONS}) {
943         $self->is_selected($text)  or  return ($myData{_CUTTING} = 1);
944     }
945
946     ## If we havent already, perform any desired preprocessing and
947     ## then re-check the "cutting" state
948     unless ($wantNonPods) {
949        $text = $self->preprocess_paragraph($text, $line_num);
950        return 1  unless ((defined $text) and (length $text));
951        return 1  if ($myData{_CUTTING});
952     }
953
954     ## Look for one of the three types of paragraphs
955     my ($pfx, $cmd, $arg, $sep) = ('', '', '', '');
956     my $pod_para = undef;
957     if ($text =~ /^(={1,2})(?=\S)/) {
958         ## Looks like a command paragraph. Capture the command prefix used
959         ## ("=" or "=="), as well as the command-name, its paragraph text,
960         ## and whatever sequence of characters was used to separate them
961         $pfx = $1;
962         $_ = substr($text, length $pfx);
963         ($cmd, $sep, $text) = split /(\s+)/, $_, 2; 
964         ## If this is a "cut" directive then we dont need to do anything
965         ## except return to "cutting" mode.
966         if ($cmd eq 'cut') {
967            $myData{_CUTTING} = 1;
968            return  unless $myOpts{'-process_cut_cmd'};
969         }
970     }
971     ## Save the attributes indicating how the command was specified.
972     $pod_para = new Pod::Paragraph(
973           -name      => $cmd,
974           -text      => $text,
975           -prefix    => $pfx,
976           -separator => $sep,
977           -file      => $myData{_INFILE},
978           -line      => $line_num
979     );
980     # ## Invoke appropriate callbacks
981     # if (exists $myData{_CALLBACKS}) {
982     #    ## Look through the callback list, invoke callbacks,
983     #    ## then see if we need to do the default actions
984     #    ## (invoke_callbacks will return true if we do).
985     #    return  1  unless $self->invoke_callbacks($cmd, $text, $line_num, $pod_para);
986     # }
987     if (length $cmd) {
988         ## A command paragraph
989         $self->command($cmd, $text, $line_num, $pod_para);
990     }
991     elsif ($text =~ /^\s+/) {
992         ## Indented text - must be a verbatim paragraph
993         $self->verbatim($text, $line_num, $pod_para);
994     }
995     else {
996         ## Looks like an ordinary block of text
997         $self->textblock($text, $line_num, $pod_para);
998     }
999     return  1;
1000 }
1001
1002 ##---------------------------------------------------------------------------
1003
1004 =head1 B<parse_from_filehandle()>
1005
1006             $parser->parse_from_filehandle($in_fh,$out_fh);
1007
1008 This method takes an input filehandle (which is assumed to already be
1009 opened for reading) and reads the entire input stream looking for blocks
1010 (paragraphs) of POD documentation to be processed. If no first argument
1011 is given the default input filehandle C<STDIN> is used.
1012
1013 The C<$in_fh> parameter may be any object that provides a B<getline()>
1014 method to retrieve a single line of input text (hence, an appropriate
1015 wrapper object could be used to parse PODs from a single string or an
1016 array of strings).
1017
1018 Using C<$in_fh-E<gt>getline()>, input is read line-by-line and assembled
1019 into paragraphs or "blocks" (which are separated by lines containing
1020 nothing but whitespace). For each block of POD documentation
1021 encountered it will invoke a method to parse the given paragraph.
1022
1023 If a second argument is given then it should correspond to a filehandle where
1024 output should be sent (otherwise the default output filehandle is
1025 C<STDOUT> if no output filehandle is currently in use).
1026
1027 B<NOTE:> For performance reasons, this method caches the input stream at
1028 the top of the stack in a local variable. Any attempts by clients to
1029 change the stack contents during processing when in the midst executing
1030 of this method I<will not affect> the input stream used by the current
1031 invocation of this method.
1032
1033 This method does I<not> usually need to be overridden by subclasses.
1034
1035 =cut
1036
1037 sub parse_from_filehandle {
1038     my $self = shift;
1039     my %opts = (ref $_[0] eq 'HASH') ? %{ shift() } : ();
1040     my ($in_fh, $out_fh) = @_;
1041     $in_fh = \*STDIN  unless ($in_fh);
1042     local *myData = $self;  ## alias to avoid deref-ing overhead
1043     local *myOpts = ($myData{_PARSEOPTS} ||= {});  ## get parse-options
1044     local $_;
1045
1046     ## Put this stream at the top of the stack and do beginning-of-input
1047     ## processing. NOTE that $in_fh might be reset during this process.
1048     my $topstream = $self->_push_input_stream($in_fh, $out_fh);
1049     (exists $opts{-cutting})  and  $self->cutting( $opts{-cutting} );
1050
1051     ## Initialize line/paragraph
1052     my ($textline, $paragraph) = ('', '');
1053     my ($nlines, $plines) = (0, 0);
1054
1055     ## Use <$fh> instead of $fh->getline where possible (for speed)
1056     $_ = ref $in_fh;
1057     my $tied_fh = (/^(?:GLOB|FileHandle|IO::\w+)$/  or  tied $in_fh);
1058
1059     ## Read paragraphs line-by-line
1060     while (defined ($textline = $tied_fh ? <$in_fh> : $in_fh->getline)) {
1061         $textline = $self->preprocess_line($textline, ++$nlines);
1062         next  unless ((defined $textline)  &&  (length $textline));
1063         $_ = $paragraph;  ## save previous contents
1064
1065         if ((! length $paragraph) && ($textline =~ /^==/)) {
1066             ## '==' denotes a one-line command paragraph
1067             $paragraph = $textline;
1068             $plines    = 1;
1069             $textline  = '';
1070         } else {
1071             ## Append this line to the current paragraph
1072             $paragraph .= $textline;
1073             ++$plines;
1074         }
1075
1076         ## See if this line is blank and ends the current paragraph.
1077         ## If it isnt, then keep iterating until it is.
1078         next unless (($textline =~ /^([^\S\r\n]*)[\r\n]*$/)
1079                                      && (length $paragraph));
1080
1081         ## Issue a warning about any non-empty blank lines
1082         if (length($1) > 0 and $myOpts{'-warnings'} and ! $myData{_CUTTING}) {
1083             my $errorsub = $self->errorsub();
1084             my $file = $self->input_file();
1085             my $errmsg = "*** WARNING: line containing nothing but whitespace".
1086                          " in paragraph at line $nlines in file $file\n";
1087             (ref $errorsub) and &{$errorsub}($errmsg)
1088                 or (defined $errorsub) and $self->$errorsub($errmsg)
1089                     or  warn($errmsg);
1090         }
1091
1092         ## Now process the paragraph
1093         parse_paragraph($self, $paragraph, ($nlines - $plines) + 1);
1094         $paragraph = '';
1095         $plines = 0;
1096     }
1097     ## Dont forget about the last paragraph in the file
1098     if (length $paragraph) {
1099        parse_paragraph($self, $paragraph, ($nlines - $plines) + 1)
1100     }
1101
1102     ## Now pop the input stream off the top of the input stack.
1103     $self->_pop_input_stream();
1104 }
1105
1106 ##---------------------------------------------------------------------------
1107
1108 =head1 B<parse_from_file()>
1109
1110             $parser->parse_from_file($filename,$outfile);
1111
1112 This method takes a filename and does the following:
1113
1114 =over 2
1115
1116 =item *
1117
1118 opens the input and output files for reading
1119 (creating the appropriate filehandles)
1120
1121 =item *
1122
1123 invokes the B<parse_from_filehandle()> method passing it the
1124 corresponding input and output filehandles.
1125
1126 =item *
1127
1128 closes the input and output files.
1129
1130 =back
1131
1132 If the special input filename "-" or "<&STDIN" is given then the STDIN
1133 filehandle is used for input (and no open or close is performed). If no
1134 input filename is specified then "-" is implied.
1135
1136 If a second argument is given then it should be the name of the desired
1137 output file. If the special output filename "-" or ">&STDOUT" is given
1138 then the STDOUT filehandle is used for output (and no open or close is
1139 performed). If the special output filename ">&STDERR" is given then the
1140 STDERR filehandle is used for output (and no open or close is
1141 performed). If no output filehandle is currently in use and no output
1142 filename is specified, then "-" is implied.
1143
1144 This method does I<not> usually need to be overridden by subclasses.
1145
1146 =cut
1147
1148 sub parse_from_file {
1149     my $self = shift;
1150     my %opts = (ref $_[0] eq 'HASH') ? %{ shift() } : ();
1151     my ($infile, $outfile) = @_;
1152     my ($in_fh,  $out_fh) = (gensym, gensym)  if ($] < 5.6);
1153     my ($close_input, $close_output) = (0, 0);
1154     local *myData = $self;
1155     local $_;
1156
1157     ## Is $infile a filename or a (possibly implied) filehandle
1158     $infile  = '-'  unless ((defined $infile)  && (length $infile));
1159     if (($infile  eq '-') || ($infile =~ /^<&(STDIN|0)$/i)) {
1160         ## Not a filename, just a string implying STDIN
1161         $myData{_INFILE} = "<standard input>";
1162         $in_fh = \*STDIN;
1163     }
1164     elsif (ref $infile) {
1165         ## Must be a filehandle-ref (or else assume its a ref to an object
1166         ## that supports the common IO read operations).
1167         $myData{_INFILE} = ${$infile};
1168         $in_fh = $infile;
1169     }
1170     else {
1171         ## We have a filename, open it for reading
1172         $myData{_INFILE} = $infile;
1173         open($in_fh, "< $infile")  or
1174              croak "Can't open $infile for reading: $!\n";
1175         $close_input = 1;
1176     }
1177
1178     ## NOTE: we need to be *very* careful when "defaulting" the output
1179     ## file. We only want to use a default if this is the beginning of
1180     ## the entire document (but *not* if this is an included file). We
1181     ## determine this by seeing if the input stream stack has been set-up
1182     ## already
1183     ## 
1184     unless ((defined $outfile) && (length $outfile)) {
1185         (defined $myData{_TOP_STREAM}) && ($out_fh  = $myData{_OUTPUT})
1186                                        || ($outfile = '-');
1187     }
1188     ## Is $outfile a filename or a (possibly implied) filehandle
1189     if ((defined $outfile) && (length $outfile)) {
1190         if (($outfile  eq '-') || ($outfile =~ /^>&?(?:STDOUT|1)$/i)) {
1191             ## Not a filename, just a string implying STDOUT
1192             $myData{_OUTFILE} = "<standard output>";
1193             $out_fh  = \*STDOUT;
1194         }
1195         elsif ($outfile =~ /^>&(STDERR|2)$/i) {
1196             ## Not a filename, just a string implying STDERR
1197             $myData{_OUTFILE} = "<standard error>";
1198             $out_fh  = \*STDERR;
1199         }
1200         elsif (ref $outfile) {
1201             ## Must be a filehandle-ref (or else assume its a ref to an
1202             ## object that supports the common IO write operations).
1203             $myData{_OUTFILE} = ${$outfile};
1204             $out_fh = $outfile;
1205         }
1206         else {
1207             ## We have a filename, open it for writing
1208             $myData{_OUTFILE} = $outfile;
1209             (-d $outfile) and croak "$outfile is a directory, not POD input!\n";
1210             open($out_fh, "> $outfile")  or
1211                  croak "Can't open $outfile for writing: $!\n";
1212             $close_output = 1;
1213         }
1214     }
1215
1216     ## Whew! That was a lot of work to set up reasonably/robust behavior
1217     ## in the case of a non-filename for reading and writing. Now we just
1218     ## have to parse the input and close the handles when we're finished.
1219     $self->parse_from_filehandle(\%opts, $in_fh, $out_fh);
1220
1221     $close_input  and 
1222         close($in_fh) || croak "Can't close $infile after reading: $!\n";
1223     $close_output  and
1224         close($out_fh) || croak "Can't close $outfile after writing: $!\n";
1225 }
1226
1227 #############################################################################
1228
1229 =head1 ACCESSOR METHODS
1230
1231 Clients of B<Pod::Parser> should use the following methods to access
1232 instance data fields:
1233
1234 =cut
1235
1236 ##---------------------------------------------------------------------------
1237
1238 =head1 B<errorsub()>
1239
1240             $parser->errorsub("method_name");
1241             $parser->errorsub(\&warn_user);
1242             $parser->errorsub(sub { print STDERR, @_ });
1243
1244 Specifies the method or subroutine to use when printing error messages
1245 about POD syntax. The supplied method/subroutine I<must> return TRUE upon
1246 successful printing of the message. If C<undef> is given, then the B<warn>
1247 builtin is used to issue error messages (this is the default behavior).
1248
1249             my $errorsub = $parser->errorsub()
1250             my $errmsg = "This is an error message!\n"
1251             (ref $errorsub) and &{$errorsub}($errmsg)
1252                 or (defined $errorsub) and $parser->$errorsub($errmsg)
1253                     or  warn($errmsg);
1254
1255 Returns a method name, or else a reference to the user-supplied subroutine
1256 used to print error messages. Returns C<undef> if the B<warn> builtin
1257 is used to issue error messages (this is the default behavior).
1258
1259 =cut
1260
1261 sub errorsub {
1262    return (@_ > 1) ? ($_[0]->{_ERRORSUB} = $_[1]) : $_[0]->{_ERRORSUB};
1263 }
1264
1265 ##---------------------------------------------------------------------------
1266
1267 =head1 B<cutting()>
1268
1269             $boolean = $parser->cutting();
1270
1271 Returns the current C<cutting> state: a boolean-valued scalar which
1272 evaluates to true if text from the input file is currently being "cut"
1273 (meaning it is I<not> considered part of the POD document).
1274
1275             $parser->cutting($boolean);
1276
1277 Sets the current C<cutting> state to the given value and returns the
1278 result.
1279
1280 =cut
1281
1282 sub cutting {
1283    return (@_ > 1) ? ($_[0]->{_CUTTING} = $_[1]) : $_[0]->{_CUTTING};
1284 }
1285
1286 ##---------------------------------------------------------------------------
1287
1288 ##---------------------------------------------------------------------------
1289
1290 =head1 B<parseopts()>
1291
1292 When invoked with no additional arguments, B<parseopts> returns a hashtable
1293 of all the current parsing options.
1294
1295             ## See if we are parsing non-POD sections as well as POD ones
1296             my %opts = $parser->parseopts();
1297             $opts{'-want_nonPODs}' and print "-want_nonPODs\n";
1298
1299 When invoked using a single string, B<parseopts> treats the string as the
1300 name of a parse-option and returns its corresponding value if it exists
1301 (returns C<undef> if it doesn't).
1302
1303             ## Did we ask to see '=cut' paragraphs?
1304             my $want_cut = $parser->parseopts('-process_cut_cmd');
1305             $want_cut and print "-process_cut_cmd\n";
1306
1307 When invoked with multiple arguments, B<parseopts> treats them as
1308 key/value pairs and the specified parse-option names are set to the
1309 given values. Any unspecified parse-options are unaffected.
1310
1311             ## Set them back to the default
1312             $parser->parseopts(-warnings => 0);
1313
1314 When passed a single hash-ref, B<parseopts> uses that hash to completely
1315 reset the existing parse-options, all previous parse-option values
1316 are lost.
1317
1318             ## Reset all options to default 
1319             $parser->parseopts( { } );
1320
1321 See L<"PARSING OPTIONS"> for more information on the name and meaning of each
1322 parse-option currently recognized.
1323
1324 =cut
1325
1326 sub parseopts {
1327    local *myData = shift;
1328    local *myOpts = ($myData{_PARSEOPTS} ||= {});
1329    return %myOpts  if (@_ == 0);
1330    if (@_ == 1) {
1331       local $_ = shift;
1332       return  ref($_)  ?  $myData{_PARSEOPTS} = $_  :  $myOpts{$_};
1333    }
1334    my @newOpts = (%myOpts, @_);
1335    $myData{_PARSEOPTS} = { @newOpts };
1336 }
1337
1338 ##---------------------------------------------------------------------------
1339
1340 =head1 B<output_file()>
1341
1342             $fname = $parser->output_file();
1343
1344 Returns the name of the output file being written.
1345
1346 =cut
1347
1348 sub output_file {
1349    return $_[0]->{_OUTFILE};
1350 }
1351
1352 ##---------------------------------------------------------------------------
1353
1354 =head1 B<output_handle()>
1355
1356             $fhandle = $parser->output_handle();
1357
1358 Returns the output filehandle object.
1359
1360 =cut
1361
1362 sub output_handle {
1363    return $_[0]->{_OUTPUT};
1364 }
1365
1366 ##---------------------------------------------------------------------------
1367
1368 =head1 B<input_file()>
1369
1370             $fname = $parser->input_file();
1371
1372 Returns the name of the input file being read.
1373
1374 =cut
1375
1376 sub input_file {
1377    return $_[0]->{_INFILE};
1378 }
1379
1380 ##---------------------------------------------------------------------------
1381
1382 =head1 B<input_handle()>
1383
1384             $fhandle = $parser->input_handle();
1385
1386 Returns the current input filehandle object.
1387
1388 =cut
1389
1390 sub input_handle {
1391    return $_[0]->{_INPUT};
1392 }
1393
1394 ##---------------------------------------------------------------------------
1395
1396 =begin __PRIVATE__
1397
1398 =head1 B<input_streams()>
1399
1400             $listref = $parser->input_streams();
1401
1402 Returns a reference to an array which corresponds to the stack of all
1403 the input streams that are currently in the middle of being parsed.
1404
1405 While parsing an input stream, it is possible to invoke
1406 B<parse_from_file()> or B<parse_from_filehandle()> to parse a new input
1407 stream and then return to parsing the previous input stream. Each input
1408 stream to be parsed is pushed onto the end of this input stack
1409 before any of its input is read. The input stream that is currently
1410 being parsed is always at the end (or top) of the input stack. When an
1411 input stream has been exhausted, it is popped off the end of the
1412 input stack.
1413
1414 Each element on this input stack is a reference to C<Pod::InputSource>
1415 object. Please see L<Pod::InputObjects> for more details.
1416
1417 This method might be invoked when printing diagnostic messages, for example,
1418 to obtain the name and line number of the all input files that are currently
1419 being processed.
1420
1421 =end __PRIVATE__
1422
1423 =cut
1424
1425 sub input_streams {
1426    return $_[0]->{_INPUT_STREAMS};
1427 }
1428
1429 ##---------------------------------------------------------------------------
1430
1431 =begin __PRIVATE__
1432
1433 =head1 B<top_stream()>
1434
1435             $hashref = $parser->top_stream();
1436
1437 Returns a reference to the hash-table that represents the element
1438 that is currently at the top (end) of the input stream stack
1439 (see L<"input_streams()">). The return value will be the C<undef>
1440 if the input stack is empty.
1441
1442 This method might be used when printing diagnostic messages, for example,
1443 to obtain the name and line number of the current input file.
1444
1445 =end __PRIVATE__
1446
1447 =cut
1448
1449 sub top_stream {
1450    return $_[0]->{_TOP_STREAM} || undef;
1451 }
1452
1453 #############################################################################
1454
1455 =head1 PRIVATE METHODS AND DATA
1456
1457 B<Pod::Parser> makes use of several internal methods and data fields
1458 which clients should not need to see or use. For the sake of avoiding
1459 name collisions for client data and methods, these methods and fields
1460 are briefly discussed here. Determined hackers may obtain further
1461 information about them by reading the B<Pod::Parser> source code.
1462
1463 Private data fields are stored in the hash-object whose reference is
1464 returned by the B<new()> constructor for this class. The names of all
1465 private methods and data-fields used by B<Pod::Parser> begin with a
1466 prefix of "_" and match the regular expression C</^_\w+$/>.
1467
1468 =cut
1469
1470 ##---------------------------------------------------------------------------
1471
1472 =begin _PRIVATE_
1473
1474 =head1 B<_push_input_stream()>
1475
1476             $hashref = $parser->_push_input_stream($in_fh,$out_fh);
1477
1478 This method will push the given input stream on the input stack and
1479 perform any necessary beginning-of-document or beginning-of-file
1480 processing. The argument C<$in_fh> is the input stream filehandle to
1481 push, and C<$out_fh> is the corresponding output filehandle to use (if
1482 it is not given or is undefined, then the current output stream is used,
1483 which defaults to standard output if it doesnt exist yet).
1484
1485 The value returned will be reference to the hash-table that represents
1486 the new top of the input stream stack. I<Please Note> that it is
1487 possible for this method to use default values for the input and output
1488 file handles. If this happens, you will need to look at the C<INPUT>
1489 and C<OUTPUT> instance data members to determine their new values.
1490
1491 =end _PRIVATE_
1492
1493 =cut
1494
1495 sub _push_input_stream {
1496     my ($self, $in_fh, $out_fh) = @_;
1497     local *myData = $self;
1498
1499     ## Initialize stuff for the entire document if this is *not*
1500     ## an included file.
1501     ##
1502     ## NOTE: we need to be *very* careful when "defaulting" the output
1503     ## filehandle. We only want to use a default value if this is the
1504     ## beginning of the entire document (but *not* if this is an included
1505     ## file).
1506     unless (defined  $myData{_TOP_STREAM}) {
1507         $out_fh  = \*STDOUT  unless (defined $out_fh);
1508         $myData{_CUTTING}       = 1;   ## current "cutting" state
1509         $myData{_INPUT_STREAMS} = [];  ## stack of all input streams
1510     }
1511
1512     ## Initialize input indicators
1513     $myData{_OUTFILE} = '(unknown)'  unless (defined  $myData{_OUTFILE});
1514     $myData{_OUTPUT}  = $out_fh      if (defined  $out_fh);
1515     $in_fh            = \*STDIN      unless (defined  $in_fh);
1516     $myData{_INFILE}  = '(unknown)'  unless (defined  $myData{_INFILE});
1517     $myData{_INPUT}   = $in_fh;
1518     my $input_top     = $myData{_TOP_STREAM}
1519                       = new Pod::InputSource(
1520                             -name        => $myData{_INFILE},
1521                             -handle      => $in_fh,
1522                             -was_cutting => $myData{_CUTTING}
1523                         );
1524     local *input_stack = $myData{_INPUT_STREAMS};
1525     push(@input_stack, $input_top);
1526
1527     ## Perform beginning-of-document and/or beginning-of-input processing
1528     $self->begin_pod()  if (@input_stack == 1);
1529     $self->begin_input();
1530
1531     return  $input_top;
1532 }
1533
1534 ##---------------------------------------------------------------------------
1535
1536 =begin _PRIVATE_
1537
1538 =head1 B<_pop_input_stream()>
1539
1540             $hashref = $parser->_pop_input_stream();
1541
1542 This takes no arguments. It will perform any necessary end-of-file or
1543 end-of-document processing and then pop the current input stream from
1544 the top of the input stack.
1545
1546 The value returned will be reference to the hash-table that represents
1547 the new top of the input stream stack.
1548
1549 =end _PRIVATE_
1550
1551 =cut
1552
1553 sub _pop_input_stream {
1554     my ($self) = @_;
1555     local *myData = $self;
1556     local *input_stack = $myData{_INPUT_STREAMS};
1557
1558     ## Perform end-of-input and/or end-of-document processing
1559     $self->end_input()  if (@input_stack > 0);
1560     $self->end_pod()    if (@input_stack == 1);
1561
1562     ## Restore cutting state to whatever it was before we started
1563     ## parsing this file.
1564     my $old_top = pop(@input_stack);
1565     $myData{_CUTTING} = $old_top->was_cutting();
1566
1567     ## Dont forget to reset the input indicators
1568     my $input_top = undef;
1569     if (@input_stack > 0) {
1570        $input_top = $myData{_TOP_STREAM} = $input_stack[-1];
1571        $myData{_INFILE}  = $input_top->name();
1572        $myData{_INPUT}   = $input_top->handle();
1573     } else {
1574        delete $myData{_TOP_STREAM};
1575        delete $myData{_INPUT_STREAMS};
1576     }
1577
1578     return  $input_top;
1579 }
1580
1581 #############################################################################
1582
1583 =head1 TREE-BASED PARSING
1584
1585 If straightforward stream-based parsing wont meet your needs (as is
1586 likely the case for tasks such as translating PODs into structured
1587 markup languages like HTML and XML) then you may need to take the
1588 tree-based approach. Rather than doing everything in one pass and
1589 calling the B<interpolate()> method to expand sequences into text, it
1590 may be desirable to instead create a parse-tree using the B<parse_text()>
1591 method to return a tree-like structure which may contain an ordered list
1592 list of children (each of which may be a text-string, or a similar
1593 tree-like structure).
1594
1595 Pay special attention to L<"METHODS FOR PARSING AND PROCESSING"> and
1596 to the objects described in L<Pod::InputObjects>. The former describes
1597 the gory details and parameters for how to customize and extend the
1598 parsing behavior of B<Pod::Parser>. B<Pod::InputObjects> provides
1599 several objects that may all be used interchangeably as parse-trees. The
1600 most obvious one is the B<Pod::ParseTree> object. It defines the basic
1601 interface and functionality that all things trying to be a POD parse-tree
1602 should do. A B<Pod::ParseTree> is defined such that each "node" may be a
1603 text-string, or a reference to another parse-tree.  Each B<Pod::Paragraph>
1604 object and each B<Pod::InteriorSequence> object also supports the basic
1605 parse-tree interface.
1606
1607 The B<parse_text()> method takes a given paragraph of text, and
1608 returns a parse-tree that contains one or more children, each of which
1609 may be a text-string, or an InteriorSequence object. There are also
1610 callback-options that may be passed to B<parse_text()> to customize
1611 the way it expands or transforms interior-sequences, as well as the
1612 returned result. These callbacks can be used to create a parse-tree
1613 with custom-made objects (which may or may not support the parse-tree
1614 interface, depending on how you choose to do it).
1615
1616 If you wish to turn an entire POD document into a parse-tree, that process
1617 is fairly straightforward. The B<parse_text()> method is the key to doing
1618 this successfully. Every paragraph-callback (i.e. the polymorphic methods
1619 for B<command()>, B<verbatim()>, and B<textblock()> paragraphs) takes
1620 a B<Pod::Paragraph> object as an argument. Each paragraph object has a
1621 B<parse_tree()> method that can be used to get or set a corresponding
1622 parse-tree. So for each of those paragraph-callback methods, simply call
1623 B<parse_text()> with the options you desire, and then use the returned
1624 parse-tree to assign to the given paragraph object.
1625
1626 That gives you a parse-tree for each paragraph - so now all you need is
1627 an ordered list of paragraphs. You can maintain that yourself as a data
1628 element in the object/hash. The most straightforward way would be simply
1629 to use an array-ref, with the desired set of custom "options" for each
1630 invocation of B<parse_text>. Let's assume the desired option-set is
1631 given by the hash C<%options>. Then we might do something like the
1632 following:
1633
1634     package MyPodParserTree;
1635
1636     @ISA = qw( Pod::Parser );
1637
1638     ...
1639
1640     sub begin_pod {
1641         my $self = shift;
1642         $self->{'-paragraphs'} = [];  ## initialize paragraph list
1643     }
1644
1645     sub command { 
1646         my ($parser, $command, $paragraph, $line_num, $pod_para) = @_;
1647         my $ptree = $parser->parse_text({%options}, $paragraph, ...);
1648         $pod_para->parse_tree( $ptree );
1649         push @{ $self->{'-paragraphs'} }, $pod_para;
1650     }
1651
1652     sub verbatim { 
1653         my ($parser, $paragraph, $line_num, $pod_para) = @_;
1654         push @{ $self->{'-paragraphs'} }, $pod_para;
1655     }
1656
1657     sub textblock { 
1658         my ($parser, $paragraph, $line_num, $pod_para) = @_;
1659         my $ptree = $parser->parse_text({%options}, $paragraph, ...);
1660         $pod_para->parse_tree( $ptree );
1661         push @{ $self->{'-paragraphs'} }, $pod_para;
1662     }
1663
1664     ...
1665
1666     package main;
1667     ...
1668     my $parser = new MyPodParserTree(...);
1669     $parser->parse_from_file(...);
1670     my $paragraphs_ref = $parser->{'-paragraphs'};
1671
1672 Of course, in this module-author's humble opinion, I'd be more inclined to
1673 use the existing B<Pod::ParseTree> object than a simple array. That way
1674 everything in it, paragraphs and sequences, all respond to the same core
1675 interface for all parse-tree nodes. The result would look something like:
1676
1677     package MyPodParserTree2;
1678
1679     ...
1680
1681     sub begin_pod {
1682         my $self = shift;
1683         $self->{'-ptree'} = new Pod::ParseTree;  ## initialize parse-tree
1684     }
1685
1686     sub parse_tree {
1687         ## convenience method to get/set the parse-tree for the entire POD
1688         (@_ > 1)  and  $_[0]->{'-ptree'} = $_[1];
1689         return $_[0]->{'-ptree'};
1690     }
1691
1692     sub command { 
1693         my ($parser, $command, $paragraph, $line_num, $pod_para) = @_;
1694         my $ptree = $parser->parse_text({<<options>>}, $paragraph, ...);
1695         $pod_para->parse_tree( $ptree );
1696         $parser->parse_tree()->append( $pod_para );
1697     }
1698
1699     sub verbatim { 
1700         my ($parser, $paragraph, $line_num, $pod_para) = @_;
1701         $parser->parse_tree()->append( $pod_para );
1702     }
1703
1704     sub textblock { 
1705         my ($parser, $paragraph, $line_num, $pod_para) = @_;
1706         my $ptree = $parser->parse_text({<<options>>}, $paragraph, ...);
1707         $pod_para->parse_tree( $ptree );
1708         $parser->parse_tree()->append( $pod_para );
1709     }
1710
1711     ...
1712
1713     package main;
1714     ...
1715     my $parser = new MyPodParserTree2(...);
1716     $parser->parse_from_file(...);
1717     my $ptree = $parser->parse_tree;
1718     ...
1719
1720 Now you have the entire POD document as one great big parse-tree. You
1721 can even use the B<-expand_seq> option to B<parse_text> to insert
1722 whole different kinds of objects. Just don't expect B<Pod::Parser>
1723 to know what to do with them after that. That will need to be in your
1724 code. Or, alternatively, you can insert any object you like so long as
1725 it conforms to the B<Pod::ParseTree> interface.
1726
1727 One could use this to create subclasses of B<Pod::Paragraphs> and
1728 B<Pod::InteriorSequences> for specific commands (or to create your own
1729 custom node-types in the parse-tree) and add some kind of B<emit()>
1730 method to each custom node/subclass object in the tree. Then all you'd
1731 need to do is recursively walk the tree in the desired order, processing
1732 the children (most likely from left to right) by formatting them if
1733 they are text-strings, or by calling their B<emit()> method if they
1734 are objects/references.
1735
1736 =head1 SEE ALSO
1737
1738 L<Pod::InputObjects>, L<Pod::Select>
1739
1740 B<Pod::InputObjects> defines POD input objects corresponding to
1741 command paragraphs, parse-trees, and interior-sequences.
1742
1743 B<Pod::Select> is a subclass of B<Pod::Parser> which provides the ability
1744 to selectively include and/or exclude sections of a POD document from being
1745 translated based upon the current heading, subheading, subsubheading, etc.
1746
1747 =for __PRIVATE__
1748 B<Pod::Callbacks> is a subclass of B<Pod::Parser> which gives its users
1749 the ability the employ I<callback functions> instead of, or in addition
1750 to, overriding methods of the base class.
1751
1752 =for __PRIVATE__
1753 B<Pod::Select> and B<Pod::Callbacks> do not override any
1754 methods nor do they define any new methods with the same name. Because
1755 of this, they may I<both> be used (in combination) as a base class of
1756 the same subclass in order to combine their functionality without
1757 causing any namespace clashes due to multiple inheritance.
1758
1759 =head1 AUTHOR
1760
1761 Brad Appleton E<lt>bradapp@enteract.comE<gt>
1762
1763 Based on code for B<Pod::Text> written by
1764 Tom Christiansen E<lt>tchrist@mox.perl.comE<gt>
1765
1766 =cut
1767
1768 1;