This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
99566a71d53482b6da01d82355b0721150f8b46e
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34)>.
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 use Cwd ();
516
517 my $_initial_cwd;
518
519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
520
521 BEGIN {
522     require feature;
523     $^V =~ /^v(\d+\.\d+)/;
524     feature->import(":$1");
525     $_initial_cwd = Cwd::getcwd();
526 }
527
528 # Debugger for Perl 5.00x; perl5db.pl patch level:
529 use vars qw($VERSION $header);
530
531 $VERSION = '1.49_04';
532
533 $header = "perl5db.pl version $VERSION";
534
535 =head1 DEBUGGER ROUTINES
536
537 =head2 C<DB::eval()>
538
539 This function replaces straight C<eval()> inside the debugger; it simplifies
540 the process of evaluating code in the user's context.
541
542 The code to be evaluated is passed via the package global variable
543 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
544
545 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
546 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
547 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
548 user's current package, grabbed when C<DB::DB> got control.  This causes the
549 proper context to be used when the eval is actually done.  Afterward, we
550 restore C<$trace>, C<$single>, and C<$^D>.
551
552 Next we need to handle C<$@> without getting confused. We save C<$@> in a
553 local lexical, localize C<$saved[0]> (which is where C<save()> will put
554 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
555 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
556 considered sane by the debugger. If there was an C<eval()> error, we print
557 it on the debugger's output. If C<$onetimedump> is defined, we call
558 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
559 'methods'. Setting it to something else causes the debugger to do the eval
560 but not print the result - handy if you want to do something else with it
561 (the "watch expressions" code does this to get the value of the watch
562 expression but not show it unless it matters).
563
564 In any case, we then return the list of output from C<eval> to the caller,
565 and unwinding restores the former version of C<$@> in C<@saved> as well
566 (the localization of C<$saved[0]> goes away at the end of this scope).
567
568 =head3 Parameters and variables influencing execution of DB::eval()
569
570 C<DB::eval> isn't parameterized in the standard way; this is to keep the
571 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
572 The variables listed below influence C<DB::eval()>'s execution directly.
573
574 =over 4
575
576 =item C<$evalarg> - the thing to actually be eval'ed
577
578 =item C<$trace> - Current state of execution tracing
579
580 =item C<$single> - Current state of single-stepping
581
582 =item C<$onetimeDump> - what is to be displayed after the evaluation
583
584 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
585
586 =back
587
588 The following variables are altered by C<DB::eval()> during its execution. They
589 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
590
591 =over 4
592
593 =item C<@res> - used to capture output from actual C<eval>.
594
595 =item C<$otrace> - saved value of C<$trace>.
596
597 =item C<$osingle> - saved value of C<$single>.
598
599 =item C<$od> - saved value of C<$^D>.
600
601 =item C<$saved[0]> - saved value of C<$@>.
602
603 =item $\ - for output of C<$@> if there is an evaluation error.
604
605 =back
606
607 =head3 The problem of lexicals
608
609 The context of C<DB::eval()> presents us with some problems. Obviously,
610 we want to be 'sandboxed' away from the debugger's internals when we do
611 the eval, but we need some way to control how punctuation variables and
612 debugger globals are used.
613
614 We can't use local, because the code inside C<DB::eval> can see localized
615 variables; and we can't use C<my> either for the same reason. The code
616 in this routine compromises and uses C<my>.
617
618 After this routine is over, we don't have user code executing in the debugger's
619 context, so we can use C<my> freely.
620
621 =cut
622
623 ############################################## Begin lexical danger zone
624
625 # 'my' variables used here could leak into (that is, be visible in)
626 # the context that the code being evaluated is executing in. This means that
627 # the code could modify the debugger's variables.
628 #
629 # Fiddling with the debugger's context could be Bad. We insulate things as
630 # much as we can.
631
632 use vars qw(
633     @args
634     %break_on_load
635     $CommandSet
636     $CreateTTY
637     $DBGR
638     @dbline
639     $dbline
640     %dbline
641     $dieLevel
642     $filename
643     $histfile
644     $histsize
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $maxtrace
650     $od
651     @options
652     $osingle
653     $otrace
654     $pager
655     $post
656     %postponed
657     $prc
658     $pre
659     $pretype
660     $psh
661     @RememberOnROptions
662     $remoteport
663     @res
664     $rl
665     @saved
666     $signalLevel
667     $sub
668     $term
669     $usercontext
670     $warnLevel
671 );
672
673 our (
674     @cmdfhs,
675     $evalarg,
676     $frame,
677     $hist,
678     $ImmediateStop,
679     $line,
680     $onetimeDump,
681     $onetimedumpDepth,
682     %option,
683     $OUT,
684     $packname,
685     $signal,
686     $single,
687     $start,
688     %sub,
689     $subname,
690     $trace,
691     $window,
692 );
693
694 # Used to save @ARGV and extract any debugger-related flags.
695 use vars qw(@ARGS);
696
697 # Used to prevent multiple entries to diesignal()
698 # (if for instance diesignal() itself dies)
699 use vars qw($panic);
700
701 # Used to prevent the debugger from running nonstop
702 # after a restart
703 our ($second_time);
704
705 sub _calc_usercontext {
706     my ($package) = @_;
707
708     # Cancel strict completely for the evaluated code, so the code
709     # the user evaluates won't be affected by it. (Shlomi Fish)
710     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
711     . "package $package;";    # this won't let them modify, alas
712 }
713
714 sub eval {
715
716     # 'my' would make it visible from user code
717     #    but so does local! --tchrist
718     # Remember: this localizes @DB::res, not @main::res.
719     local @res;
720     {
721
722         # Try to keep the user code from messing  with us. Save these so that
723         # even if the eval'ed code changes them, we can put them back again.
724         # Needed because the user could refer directly to the debugger's
725         # package globals (and any 'my' variables in this containing scope)
726         # inside the eval(), and we want to try to stay safe.
727         local $otrace  = $trace;
728         local $osingle = $single;
729         local $od      = $^D;
730
731         # Untaint the incoming eval() argument.
732         { ($evalarg) = $evalarg =~ /(.*)/s; }
733
734         # $usercontext built in DB::DB near the comment
735         # "set up the context for DB::eval ..."
736         # Evaluate and save any results.
737         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
738
739         # Restore those old values.
740         $trace  = $otrace;
741         $single = $osingle;
742         $^D     = $od;
743     }
744
745     # Save the current value of $@, and preserve it in the debugger's copy
746     # of the saved precious globals.
747     my $at = $@;
748
749     # Since we're only saving $@, we only have to localize the array element
750     # that it will be stored in.
751     local $saved[0];    # Preserve the old value of $@
752     eval { &DB::save };
753
754     # Now see whether we need to report an error back to the user.
755     if ($at) {
756         local $\ = '';
757         print $OUT $at;
758     }
759
760     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
761     # are package globals.
762     elsif ($onetimeDump) {
763         if ( $onetimeDump eq 'dump' ) {
764             local $option{dumpDepth} = $onetimedumpDepth
765               if defined $onetimedumpDepth;
766             dumpit( $OUT, \@res );
767         }
768         elsif ( $onetimeDump eq 'methods' ) {
769             methods( $res[0] );
770         }
771     } ## end elsif ($onetimeDump)
772     @res;
773 } ## end sub eval
774
775 ############################################## End lexical danger zone
776
777 # After this point it is safe to introduce lexicals.
778 # The code being debugged will be executing in its own context, and
779 # can't see the inside of the debugger.
780 #
781 # However, one should not overdo it: leave as much control from outside as
782 # possible. If you make something a lexical, it's not going to be addressable
783 # from outside the debugger even if you know its name.
784
785 # This file is automatically included if you do perl -d.
786 # It's probably not useful to include this yourself.
787 #
788 # Before venturing further into these twisty passages, it is
789 # wise to read the perldebguts man page or risk the ire of dragons.
790 #
791 # (It should be noted that perldebguts will tell you a lot about
792 # the underlying mechanics of how the debugger interfaces into the
793 # Perl interpreter, but not a lot about the debugger itself. The new
794 # comments in this code try to address this problem.)
795
796 # Note that no subroutine call is possible until &DB::sub is defined
797 # (for subroutines defined outside of the package DB). In fact the same is
798 # true if $deep is not defined.
799
800 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
801
802 # modified Perl debugger, to be run from Emacs in perldb-mode
803 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
804 # Johan Vromans -- upgrade to 4.0 pl 10
805 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
806 ########################################################################
807
808 =head1 DEBUGGER INITIALIZATION
809
810 The debugger starts up in phases.
811
812 =head2 BASIC SETUP
813
814 First, it initializes the environment it wants to run in: turning off
815 warnings during its own compilation, defining variables which it will need
816 to avoid warnings later, setting itself up to not exit when the program
817 terminates, and defaulting to printing return values for the C<r> command.
818
819 =cut
820
821 # Needed for the statement after exec():
822 #
823 # This BEGIN block is simply used to switch off warnings during debugger
824 # compilation. Probably it would be better practice to fix the warnings,
825 # but this is how it's done at the moment.
826
827 BEGIN {
828     $ini_warn = $^W;
829     $^W       = 0;
830 }    # Switch compilation warnings off until another BEGIN.
831
832 local ($^W) = 0;    # Switch run-time warnings off during init.
833
834 =head2 THREADS SUPPORT
835
836 If we are running under a threaded Perl, we require threads and threads::shared
837 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
838 threaded debugger control.  C<-dt> can also be used to set this.
839
840 Each new thread will be announced and the debugger prompt will always inform
841 you of each new thread created.  It will also indicate the thread id in which
842 we are currently running within the prompt like this:
843
844     [tid] DB<$i>
845
846 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
847 command prompt.  The prompt will show: C<[0]> when running under threads, but
848 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
849
850 While running under threads, when you set or delete a breakpoint (etc.), this
851 will apply to all threads, not just the currently running one.  When you are
852 in a currently executing thread, you will stay there until it completes.  With
853 the current implementation it is not currently possible to hop from one thread
854 to another.
855
856 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
857
858 Note that threading support was built into the debugger as of Perl version
859 C<5.8.6> and debugger version C<1.2.8>.
860
861 =cut
862
863 BEGIN {
864     # ensure we can share our non-threaded variables or no-op
865     if ($ENV{PERL5DB_THREADED}) {
866         require threads;
867         require threads::shared;
868         import threads::shared qw(share);
869         $DBGR;
870         share(\$DBGR);
871         lock($DBGR);
872         print "Threads support enabled\n";
873     } else {
874         *lock = sub(*) {};
875         *share = sub(\[$@%]) {};
876     }
877 }
878
879 # These variables control the execution of 'dumpvar.pl'.
880 {
881     package dumpvar;
882     use vars qw(
883     $hashDepth
884     $arrayDepth
885     $dumpDBFiles
886     $dumpPackages
887     $quoteHighBit
888     $printUndef
889     $globPrint
890     $usageOnly
891     );
892 }
893
894 # used to control die() reporting in diesignal()
895 {
896     package Carp;
897     use vars qw($CarpLevel);
898 }
899
900 # without threads, $filename is not defined until DB::DB is called
901 share($main::{'_<'.$filename}) if defined $filename;
902
903 # Command-line + PERLLIB:
904 # Save the contents of @INC before they are modified elsewhere.
905 @ini_INC = @INC;
906
907 # This was an attempt to clear out the previous values of various
908 # trapped errors. Apparently it didn't help. XXX More info needed!
909 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
910
911 # We set these variables to safe values. We don't want to blindly turn
912 # off warnings, because other packages may still want them.
913 $trace = $signal = $single = 0;    # Uninitialized warning suppression
914                                    # (local $^W cannot help - other packages!).
915
916 # Default to not exiting when program finishes; print the return
917 # value when the 'r' command is used to return from a subroutine.
918 $inhibit_exit = $option{PrintRet} = 1;
919
920 use vars qw($trace_to_depth);
921
922 # Default to 1E9 so it won't be limited to a certain recursion depth.
923 $trace_to_depth = 1E9;
924
925 =head1 OPTION PROCESSING
926
927 The debugger's options are actually spread out over the debugger itself and
928 C<dumpvar.pl>; some of these are variables to be set, while others are
929 subs to be called with a value. To try to make this a little easier to
930 manage, the debugger uses a few data structures to define what options
931 are legal and how they are to be processed.
932
933 First, the C<@options> array defines the I<names> of all the options that
934 are to be accepted.
935
936 =cut
937
938 @options = qw(
939   CommandSet   HistFile      HistSize
940   hashDepth    arrayDepth    dumpDepth
941   DumpDBFiles  DumpPackages  DumpReused
942   compactDump  veryCompact   quote
943   HighBit      undefPrint    globPrint
944   PrintRet     UsageOnly     frame
945   AutoTrace    TTY           noTTY
946   ReadLine     NonStop       LineInfo
947   maxTraceLen  recallCommand ShellBang
948   pager        tkRunning     ornaments
949   signalLevel  warnLevel     dieLevel
950   inhibit_exit ImmediateStop bareStringify
951   CreateTTY    RemotePort    windowSize
952   DollarCaretP
953 );
954
955 @RememberOnROptions = qw(DollarCaretP);
956
957 =pod
958
959 Second, C<optionVars> lists the variables that each option uses to save its
960 state.
961
962 =cut
963
964 use vars qw(%optionVars);
965
966 %optionVars = (
967     hashDepth     => \$dumpvar::hashDepth,
968     arrayDepth    => \$dumpvar::arrayDepth,
969     CommandSet    => \$CommandSet,
970     DumpDBFiles   => \$dumpvar::dumpDBFiles,
971     DumpPackages  => \$dumpvar::dumpPackages,
972     DumpReused    => \$dumpvar::dumpReused,
973     HighBit       => \$dumpvar::quoteHighBit,
974     undefPrint    => \$dumpvar::printUndef,
975     globPrint     => \$dumpvar::globPrint,
976     UsageOnly     => \$dumpvar::usageOnly,
977     CreateTTY     => \$CreateTTY,
978     bareStringify => \$dumpvar::bareStringify,
979     frame         => \$frame,
980     AutoTrace     => \$trace,
981     inhibit_exit  => \$inhibit_exit,
982     maxTraceLen   => \$maxtrace,
983     ImmediateStop => \$ImmediateStop,
984     RemotePort    => \$remoteport,
985     windowSize    => \$window,
986     HistFile      => \$histfile,
987     HistSize      => \$histsize,
988 );
989
990 =pod
991
992 Third, C<%optionAction> defines the subroutine to be called to process each
993 option.
994
995 =cut
996
997 use vars qw(%optionAction);
998
999 %optionAction = (
1000     compactDump   => \&dumpvar::compactDump,
1001     veryCompact   => \&dumpvar::veryCompact,
1002     quote         => \&dumpvar::quote,
1003     TTY           => \&TTY,
1004     noTTY         => \&noTTY,
1005     ReadLine      => \&ReadLine,
1006     NonStop       => \&NonStop,
1007     LineInfo      => \&LineInfo,
1008     recallCommand => \&recallCommand,
1009     ShellBang     => \&shellBang,
1010     pager         => \&pager,
1011     signalLevel   => \&signalLevel,
1012     warnLevel     => \&warnLevel,
1013     dieLevel      => \&dieLevel,
1014     tkRunning     => \&tkRunning,
1015     ornaments     => \&ornaments,
1016     RemotePort    => \&RemotePort,
1017     DollarCaretP  => \&DollarCaretP,
1018 );
1019
1020 =pod
1021
1022 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1023 option is used.
1024
1025 =cut
1026
1027 # Note that this list is not complete: several options not listed here
1028 # actually require that dumpvar.pl be loaded for them to work, but are
1029 # not in the table. A subsequent patch will correct this problem; for
1030 # the moment, we're just recommenting, and we are NOT going to change
1031 # function.
1032 use vars qw(%optionRequire);
1033
1034 %optionRequire = (
1035     compactDump => 'dumpvar.pl',
1036     veryCompact => 'dumpvar.pl',
1037     quote       => 'dumpvar.pl',
1038 );
1039
1040 =pod
1041
1042 There are a number of initialization-related variables which can be set
1043 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1044 variable. These are:
1045
1046 =over 4
1047
1048 =item C<$rl> - readline control XXX needs more explanation
1049
1050 =item C<$warnLevel> - whether or not debugger takes over warning handling
1051
1052 =item C<$dieLevel> - whether or not debugger takes over die handling
1053
1054 =item C<$signalLevel> - whether or not debugger takes over signal handling
1055
1056 =item C<$pre> - preprompt actions (array reference)
1057
1058 =item C<$post> - postprompt actions (array reference)
1059
1060 =item C<$pretype>
1061
1062 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1063
1064 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1065
1066 =back
1067
1068 =cut
1069
1070 # These guys may be defined in $ENV{PERL5DB} :
1071 $rl          = 1     unless defined $rl;
1072 $warnLevel   = 1     unless defined $warnLevel;
1073 $dieLevel    = 1     unless defined $dieLevel;
1074 $signalLevel = 1     unless defined $signalLevel;
1075 $pre         = []    unless defined $pre;
1076 $post        = []    unless defined $post;
1077 $pretype     = []    unless defined $pretype;
1078 $CreateTTY   = 3     unless defined $CreateTTY;
1079 $CommandSet  = '580' unless defined $CommandSet;
1080
1081 share($rl);
1082 share($warnLevel);
1083 share($dieLevel);
1084 share($signalLevel);
1085 share($pre);
1086 share($post);
1087 share($pretype);
1088 share($rl);
1089 share($CreateTTY);
1090 share($CommandSet);
1091
1092 =pod
1093
1094 The default C<die>, C<warn>, and C<signal> handlers are set up.
1095
1096 =cut
1097
1098 warnLevel($warnLevel);
1099 dieLevel($dieLevel);
1100 signalLevel($signalLevel);
1101
1102 =pod
1103
1104 The pager to be used is needed next. We try to get it from the
1105 environment first.  If it's not defined there, we try to find it in
1106 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1107 then call the C<pager()> function to save the pager name.
1108
1109 =cut
1110
1111 # This routine makes sure $pager is set up so that '|' can use it.
1112 pager(
1113
1114     # If PAGER is defined in the environment, use it.
1115     defined $ENV{PAGER}
1116     ? $ENV{PAGER}
1117
1118       # If not, see if Config.pm defines it.
1119     : eval { require Config }
1120       && defined $Config::Config{pager}
1121     ? $Config::Config{pager}
1122
1123       # If not, fall back to 'more'.
1124     : 'more'
1125   )
1126   unless defined $pager;
1127
1128 =pod
1129
1130 We set up the command to be used to access the man pages, the command
1131 recall character (C<!> unless otherwise defined) and the shell escape
1132 character (C<!> unless otherwise defined). Yes, these do conflict, and
1133 neither works in the debugger at the moment.
1134
1135 =cut
1136
1137 setman();
1138
1139 # Set up defaults for command recall and shell escape (note:
1140 # these currently don't work in linemode debugging).
1141 recallCommand("!") unless defined $prc;
1142 shellBang("!")     unless defined $psh;
1143
1144 =pod
1145
1146 We then set up the gigantic string containing the debugger help.
1147 We also set the limit on the number of arguments we'll display during a
1148 trace.
1149
1150 =cut
1151
1152 sethelp();
1153
1154 # If we didn't get a default for the length of eval/stack trace args,
1155 # set it here.
1156 $maxtrace = 400 unless defined $maxtrace;
1157
1158 =head2 SETTING UP THE DEBUGGER GREETING
1159
1160 The debugger I<greeting> helps to inform the user how many debuggers are
1161 running, and whether the current debugger is the primary or a child.
1162
1163 If we are the primary, we just hang onto our pid so we'll have it when
1164 or if we start a child debugger. If we are a child, we'll set things up
1165 so we'll have a unique greeting and so the parent will give us our own
1166 TTY later.
1167
1168 We save the current contents of the C<PERLDB_PIDS> environment variable
1169 because we mess around with it. We'll also need to hang onto it because
1170 we'll need it if we restart.
1171
1172 Child debuggers make a label out of the current PID structure recorded in
1173 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1174 yet so the parent will give them one later via C<resetterm()>.
1175
1176 =cut
1177
1178 # Save the current contents of the environment; we're about to
1179 # much with it. We'll need this if we have to restart.
1180 use vars qw($ini_pids);
1181 $ini_pids = $ENV{PERLDB_PIDS};
1182
1183 use vars qw ($pids $term_pid);
1184
1185 if ( defined $ENV{PERLDB_PIDS} ) {
1186
1187     # We're a child. Make us a label out of the current PID structure
1188     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1189     # a term yet so the parent will give us one later via resetterm().
1190
1191     my $env_pids = $ENV{PERLDB_PIDS};
1192     $pids = "[$env_pids]";
1193
1194     # Unless we are on OpenVMS, all programs under the DCL shell run under
1195     # the same PID.
1196
1197     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1198         $term_pid         = $$;
1199     }
1200     else {
1201         $ENV{PERLDB_PIDS} .= "->$$";
1202         $term_pid = -1;
1203     }
1204
1205 } ## end if (defined $ENV{PERLDB_PIDS...
1206 else {
1207
1208     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1209     # child debugger, and mark us as the parent, so we'll know to set up
1210     # more TTY's is we have to.
1211     $ENV{PERLDB_PIDS} = "$$";
1212     $pids             = "[pid=$$]";
1213     $term_pid         = $$;
1214 }
1215
1216 use vars qw($pidprompt);
1217 $pidprompt = '';
1218
1219 # Sets up $emacs as a synonym for $slave_editor.
1220 our ($slave_editor);
1221 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1222
1223 =head2 READING THE RC FILE
1224
1225 The debugger will read a file of initialization options if supplied. If
1226 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1227
1228 =cut
1229
1230 # As noted, this test really doesn't check accurately that the debugger
1231 # is running at a terminal or not.
1232
1233 use vars qw($rcfile);
1234 {
1235     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1236     # this is the wrong metric!
1237     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1238 }
1239
1240 =pod
1241
1242 The debugger does a safety test of the file to be read. It must be owned
1243 either by the current user or root, and must only be writable by the owner.
1244
1245 =cut
1246
1247 # This wraps a safety test around "do" to read and evaluate the init file.
1248 #
1249 # This isn't really safe, because there's a race
1250 # between checking and opening.  The solution is to
1251 # open and fstat the handle, but then you have to read and
1252 # eval the contents.  But then the silly thing gets
1253 # your lexical scope, which is unfortunate at best.
1254 sub safe_do {
1255     my $file = shift;
1256
1257     # Just exactly what part of the word "CORE::" don't you understand?
1258     local $SIG{__WARN__};
1259     local $SIG{__DIE__};
1260
1261     unless ( is_safe_file($file) ) {
1262         CORE::warn <<EO_GRIPE;
1263 perldb: Must not source insecure rcfile $file.
1264         You or the superuser must be the owner, and it must not
1265         be writable by anyone but its owner.
1266 EO_GRIPE
1267         return;
1268     } ## end unless (is_safe_file($file...
1269
1270     do $file;
1271     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1272 } ## end sub safe_do
1273
1274 # This is the safety test itself.
1275 #
1276 # Verifies that owner is either real user or superuser and that no
1277 # one but owner may write to it.  This function is of limited use
1278 # when called on a path instead of upon a handle, because there are
1279 # no guarantees that filename (by dirent) whose file (by ino) is
1280 # eventually accessed is the same as the one tested.
1281 # Assumes that the file's existence is not in doubt.
1282 sub is_safe_file {
1283     my $path = shift;
1284     stat($path) || return;    # mysteriously vaporized
1285     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1286
1287     return 0 if $uid != 0 && $uid != $<;
1288     return 0 if $mode & 022;
1289     return 1;
1290 } ## end sub is_safe_file
1291
1292 # If the rcfile (whichever one we decided was the right one to read)
1293 # exists, we safely do it.
1294 if ( -f $rcfile ) {
1295     safe_do("./$rcfile");
1296 }
1297
1298 # If there isn't one here, try the user's home directory.
1299 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1300     safe_do("$ENV{HOME}/$rcfile");
1301 }
1302
1303 # Else try the login directory.
1304 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1305     safe_do("$ENV{LOGDIR}/$rcfile");
1306 }
1307
1308 # If the PERLDB_OPTS variable has options in it, parse those out next.
1309 if ( defined $ENV{PERLDB_OPTS} ) {
1310     parse_options( $ENV{PERLDB_OPTS} );
1311 }
1312
1313 =pod
1314
1315 The last thing we do during initialization is determine which subroutine is
1316 to be used to obtain a new terminal when a new debugger is started. Right now,
1317 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1318 (darwin).
1319
1320 =cut
1321
1322 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1323 # Works if you're running an xterm or xterm-like window, or you're on
1324 # OS/2, or on Mac OS X. This may need some expansion.
1325
1326 if (not defined &get_fork_TTY)       # only if no routine exists
1327 {
1328     if ( defined $remoteport ) {
1329                                                  # Expect an inetd-like server
1330         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1331     }
1332     elsif (defined $ENV{TERM}                    # If we know what kind
1333                                                  # of terminal this is,
1334         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1335         and defined $ENV{DISPLAY}                # and what display it's on,
1336       )
1337     {
1338         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1339     }
1340     elsif ( $ENV{TMUX} ) {
1341         *get_fork_TTY = \&tmux_get_fork_TTY;
1342     }
1343     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1344         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1345     }
1346     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1347             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1348             and $ENV{TERM_PROGRAM}
1349                 eq 'Apple_Terminal'              # Terminal.app
1350             )
1351     {
1352         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1353     }
1354 } ## end if (not defined &get_fork_TTY...
1355
1356 # untaint $^O, which may have been tainted by the last statement.
1357 # see bug [perl #24674]
1358 $^O =~ m/^(.*)\z/;
1359 $^O = $1;
1360
1361 # Here begin the unreadable code.  It needs fixing.
1362
1363 =head2 RESTART PROCESSING
1364
1365 This section handles the restart command. When the C<R> command is invoked, it
1366 tries to capture all of the state it can into environment variables, and
1367 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1368 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1369 the R command stuffed into the environment variables.
1370
1371   PERLDB_RESTART   - flag only, contains no restart data itself.
1372   PERLDB_HIST      - command history, if it's available
1373   PERLDB_ON_LOAD   - breakpoints set by the rc file
1374   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1375                      and have actions
1376   PERLDB_VISITED   - files that had breakpoints
1377   PERLDB_FILE_...  - breakpoints for a file
1378   PERLDB_OPT       - active options
1379   PERLDB_INC       - the original @INC
1380   PERLDB_PRETYPE   - preprompt debugger actions
1381   PERLDB_PRE       - preprompt Perl code
1382   PERLDB_POST      - post-prompt Perl code
1383   PERLDB_TYPEAHEAD - typeahead captured by readline()
1384
1385 We chug through all these variables and plug the values saved in them
1386 back into the appropriate spots in the debugger.
1387
1388 =cut
1389
1390 use vars qw(%postponed_file @typeahead);
1391
1392 our (@hist, @truehist);
1393
1394 sub _restore_shared_globals_after_restart
1395 {
1396     @hist          = get_list('PERLDB_HIST');
1397     %break_on_load = get_list("PERLDB_ON_LOAD");
1398     %postponed     = get_list("PERLDB_POSTPONE");
1399
1400     share(@hist);
1401     share(@truehist);
1402     share(%break_on_load);
1403     share(%postponed);
1404 }
1405
1406 sub _restore_breakpoints_and_actions {
1407
1408     my @had_breakpoints = get_list("PERLDB_VISITED");
1409
1410     for my $file_idx ( 0 .. $#had_breakpoints ) {
1411         my $filename = $had_breakpoints[$file_idx];
1412         my %pf = get_list("PERLDB_FILE_$file_idx");
1413         $postponed_file{ $filename } = \%pf if %pf;
1414         my @lines = sort {$a <=> $b} keys(%pf);
1415         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1416         for my $line_idx (0 .. $#lines) {
1417             _set_breakpoint_enabled_status(
1418                 $filename,
1419                 $lines[$line_idx],
1420                 ($enabled_statuses[$line_idx] ? 1 : ''),
1421             );
1422         }
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_options_after_restart
1429 {
1430     my %options_map = get_list("PERLDB_OPT");
1431
1432     while ( my ( $opt, $val ) = each %options_map ) {
1433         $val =~ s/[\\\']/\\$1/g;
1434         parse_options("$opt'$val'");
1435     }
1436
1437     return;
1438 }
1439
1440 sub _restore_globals_after_restart
1441 {
1442     # restore original @INC
1443     @INC     = get_list("PERLDB_INC");
1444     @ini_INC = @INC;
1445
1446     # return pre/postprompt actions and typeahead buffer
1447     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1448     $pre       = [ get_list("PERLDB_PRE") ];
1449     $post      = [ get_list("PERLDB_POST") ];
1450     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1451
1452     return;
1453 }
1454
1455
1456 if ( exists $ENV{PERLDB_RESTART} ) {
1457
1458     # We're restarting, so we don't need the flag that says to restart anymore.
1459     delete $ENV{PERLDB_RESTART};
1460
1461     # $restart = 1;
1462     _restore_shared_globals_after_restart();
1463
1464     _restore_breakpoints_and_actions();
1465
1466     # restore options
1467     _restore_options_after_restart();
1468
1469     _restore_globals_after_restart();
1470 } ## end if (exists $ENV{PERLDB_RESTART...
1471
1472 =head2 SETTING UP THE TERMINAL
1473
1474 Now, we'll decide how the debugger is going to interact with the user.
1475 If there's no TTY, we set the debugger to run non-stop; there's not going
1476 to be anyone there to enter commands.
1477
1478 =cut
1479
1480 use vars qw($notty $console $tty $LINEINFO);
1481 use vars qw($lineinfo $doccmd);
1482
1483 our ($runnonstop);
1484
1485 # Local autoflush to avoid rt#116769,
1486 # as calling IO::File methods causes an unresolvable loop
1487 # that results in debugger failure.
1488 sub _autoflush {
1489     my $o = select($_[0]);
1490     $|++;
1491     select($o);
1492 }
1493
1494 if ($notty) {
1495     $runnonstop = 1;
1496     share($runnonstop);
1497 }
1498
1499 =pod
1500
1501 If there is a TTY, we have to determine who it belongs to before we can
1502 proceed. If this is a slave editor or graphical debugger (denoted by
1503 the first command-line switch being '-emacs'), we shift this off and
1504 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1505
1506 =cut
1507
1508 else {
1509
1510     # Is Perl being run from a slave editor or graphical debugger?
1511     # If so, don't use readline, and set $slave_editor = 1.
1512     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1513         $rl = 0;
1514         shift(@main::ARGV);
1515     }
1516
1517     #require Term::ReadLine;
1518
1519 =pod
1520
1521 We then determine what the console should be on various systems:
1522
1523 =over 4
1524
1525 =item * Cygwin - We use C<stdin> instead of a separate device.
1526
1527 =cut
1528
1529     if ( $^O eq 'cygwin' ) {
1530
1531         # /dev/tty is binary. use stdin for textmode
1532         undef $console;
1533     }
1534
1535 =item * Unix - use F</dev/tty>.
1536
1537 =cut
1538
1539     elsif ( -e "/dev/tty" ) {
1540         $console = "/dev/tty";
1541     }
1542
1543 =item * Windows or MSDOS - use C<con>.
1544
1545 =cut
1546
1547     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1548         $console = "con";
1549     }
1550
1551 =item * AmigaOS - use C<CONSOLE:>.
1552
1553 =cut
1554
1555     elsif ( $^O eq 'amigaos' ) {
1556         $console = "CONSOLE:";
1557     }
1558
1559 =item * VMS - use C<sys$command>.
1560
1561 =cut
1562
1563     elsif ($^O eq 'VMS') {
1564         $console = 'sys$command';
1565     }
1566
1567 # Keep this last.
1568
1569     else {
1570         _db_warn("Can't figure out your console, using stdin");
1571         undef $console;
1572     }
1573
1574 =pod
1575
1576 =back
1577
1578 Several other systems don't use a specific console. We C<undef $console>
1579 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1580 with a slave editor).
1581
1582 =cut
1583
1584     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1585
1586         # /dev/tty is binary. use stdin for textmode
1587         $console = undef;
1588     }
1589
1590     if ( $^O eq 'NetWare' ) {
1591
1592         # /dev/tty is binary. use stdin for textmode
1593         $console = undef;
1594     }
1595
1596     # In OS/2, we need to use STDIN to get textmode too, even though
1597     # it pretty much looks like Unix otherwise.
1598     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1599     {    # In OS/2
1600         $console = undef;
1601     }
1602
1603 =pod
1604
1605 If there is a TTY hanging around from a parent, we use that as the console.
1606
1607 =cut
1608
1609     $console = $tty if defined $tty;
1610
1611 =head2 SOCKET HANDLING
1612
1613 The debugger is capable of opening a socket and carrying out a debugging
1614 session over the socket.
1615
1616 If C<RemotePort> was defined in the options, the debugger assumes that it
1617 should try to start a debugging session on that port. It builds the socket
1618 and then tries to connect the input and output filehandles to it.
1619
1620 =cut
1621
1622     # Handle socket stuff.
1623
1624     if ( defined $remoteport ) {
1625
1626         # If RemotePort was defined in the options, connect input and output
1627         # to the socket.
1628         $IN = $OUT = connect_remoteport();
1629     } ## end if (defined $remoteport)
1630
1631 =pod
1632
1633 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1634 this is probably a situation where multiple debuggers are running (for example,
1635 a backticked command that starts up another debugger). We create a new IN and
1636 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1637 and if we can.
1638
1639 =cut
1640
1641     # Non-socket.
1642     else {
1643
1644         # Two debuggers running (probably a system or a backtick that invokes
1645         # the debugger itself under the running one). create a new IN and OUT
1646         # filehandle, and do the necessary mojo to create a new tty if we
1647         # know how, and we can.
1648         create_IN_OUT(4) if $CreateTTY & 4;
1649         if ($console) {
1650
1651             # If we have a console, check to see if there are separate ins and
1652             # outs to open. (They are assumed identical if not.)
1653
1654             my ( $i, $o ) = split /,/, $console;
1655             $o = $i unless defined $o;
1656
1657             # read/write on in, or just read, or read on STDIN.
1658             open( IN,      "+<$i" )
1659               || open( IN, "<$i" )
1660               || open( IN, "<&STDIN" );
1661
1662             # read/write/create/clobber out, or write/create/clobber out,
1663             # or merge with STDERR, or merge with STDOUT.
1664                  open( OUT, "+>$o" )
1665               || open( OUT, ">$o" )
1666               || open( OUT, ">&STDERR" )
1667               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1668
1669         } ## end if ($console)
1670         elsif ( not defined $console ) {
1671
1672             # No console. Open STDIN.
1673             open( IN, "<&STDIN" );
1674
1675             # merge with STDERR, or with STDOUT.
1676             open( OUT,      ">&STDERR" )
1677               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1678             $console = 'STDIN/OUT';
1679         } ## end elsif (not defined $console)
1680
1681         # Keep copies of the filehandles so that when the pager runs, it
1682         # can close standard input without clobbering ours.
1683         if ($console or (not defined($console))) {
1684             $IN = \*IN;
1685             $OUT = \*OUT;
1686         }
1687     } ## end elsif (from if(defined $remoteport))
1688
1689     # Unbuffer DB::OUT. We need to see responses right away.
1690     _autoflush($OUT);
1691
1692     # Line info goes to debugger output unless pointed elsewhere.
1693     # Pointing elsewhere makes it possible for slave editors to
1694     # keep track of file and position. We have both a filehandle
1695     # and a I/O description to keep track of.
1696     $LINEINFO = $OUT     unless defined $LINEINFO;
1697     $lineinfo = $console unless defined $lineinfo;
1698     # share($LINEINFO); # <- unable to share globs
1699     share($lineinfo);   #
1700
1701 =pod
1702
1703 To finish initialization, we show the debugger greeting,
1704 and then call the C<afterinit()> subroutine if there is one.
1705
1706 =cut
1707
1708     # Show the debugger greeting.
1709     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1710     unless ($runnonstop) {
1711         local $\ = '';
1712         local $, = '';
1713         if ( $term_pid eq '-1' ) {
1714             print $OUT "\nDaughter DB session started...\n";
1715         }
1716         else {
1717             print $OUT "\nLoading DB routines from $header\n";
1718             print $OUT (
1719                 "Editor support ",
1720                 $slave_editor ? "enabled" : "available", ".\n"
1721             );
1722             print $OUT
1723 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1724         } ## end else [ if ($term_pid eq '-1')
1725     } ## end unless ($runnonstop)
1726 } ## end else [ if ($notty)
1727
1728 # XXX This looks like a bug to me.
1729 # Why copy to @ARGS and then futz with @args?
1730 @ARGS = @ARGV;
1731 # for (@args) {
1732     # Make sure backslashes before single quotes are stripped out, and
1733     # keep args unless they are numeric (XXX why?)
1734     # s/\'/\\\'/g;                      # removed while not justified understandably
1735     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1736 # }
1737
1738 # If there was an afterinit() sub defined, call it. It will get
1739 # executed in our scope, so it can fiddle with debugger globals.
1740 if ( defined &afterinit ) {    # May be defined in $rcfile
1741     afterinit();
1742 }
1743
1744 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1745 use vars qw($I_m_init);
1746
1747 $I_m_init = 1;
1748
1749 ############################################################ Subroutines
1750
1751 =head1 SUBROUTINES
1752
1753 =head2 DB
1754
1755 This gigantic subroutine is the heart of the debugger. Called before every
1756 statement, its job is to determine if a breakpoint has been reached, and
1757 stop if so; read commands from the user, parse them, and execute
1758 them, and then send execution off to the next statement.
1759
1760 Note that the order in which the commands are processed is very important;
1761 some commands earlier in the loop will actually alter the C<$cmd> variable
1762 to create other commands to be executed later. This is all highly I<optimized>
1763 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1764 see what's happening in any given command.
1765
1766 =cut
1767
1768 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1769
1770 use vars qw(
1771     $action
1772     $cmd
1773     $file
1774     $filename_ini
1775     $finished
1776     %had_breakpoints
1777     $level
1778     $max
1779     $package
1780     $try
1781 );
1782
1783 our (
1784     %alias,
1785     $doret,
1786     $end,
1787     $fall_off_end,
1788     $incr,
1789     $laststep,
1790     $rc,
1791     $sh,
1792     $stack_depth,
1793     @stack,
1794     @to_watch,
1795     @old_watch,
1796 );
1797
1798 sub _DB__determine_if_we_should_break
1799 {
1800     # if we have something here, see if we should break.
1801     # $stop is lexical and local to this block - $action on the other hand
1802     # is global.
1803     my $stop;
1804
1805     if ( $dbline{$line}
1806         && _is_breakpoint_enabled($filename, $line)
1807         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1808     {
1809
1810         # Stop if the stop criterion says to just stop.
1811         if ( $stop eq '1' ) {
1812             $signal |= 1;
1813         }
1814
1815         # It's a conditional stop; eval it in the user's context and
1816         # see if we should stop. If so, remove the one-time sigil.
1817         elsif ($stop) {
1818             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1819             # The &-call is here to ascertain the mutability of @_.
1820             &DB::eval;
1821             # If the breakpoint is temporary, then delete its enabled status.
1822             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1823                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1824             }
1825         }
1826     } ## end if ($dbline{$line} && ...
1827 }
1828
1829 sub _DB__is_finished {
1830     if ($finished and $level <= 1) {
1831         end_report();
1832         return 1;
1833     }
1834     else {
1835         return;
1836     }
1837 }
1838
1839 sub _DB__read_next_cmd
1840 {
1841     my ($tid) = @_;
1842
1843     # We have a terminal, or can get one ...
1844     if (!$term) {
1845         setterm();
1846     }
1847
1848     # ... and it belongs to this PID or we get one for this PID ...
1849     if ($term_pid != $$) {
1850         resetterm(1);
1851     }
1852
1853     # ... and we got a line of command input ...
1854     $cmd = DB::readline(
1855         "$pidprompt $tid DB"
1856         . ( '<' x $level )
1857         . ( $#hist + 1 )
1858         . ( '>' x $level ) . " "
1859     );
1860
1861     return defined($cmd);
1862 }
1863
1864 sub _DB__trim_command_and_return_first_component {
1865     my ($obj) = @_;
1866
1867     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1868     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1869
1870     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1871
1872     $obj->cmd_verb($verb);
1873     $obj->cmd_args($args);
1874
1875     return;
1876 }
1877
1878 sub _DB__handle_f_command {
1879     my ($obj) = @_;
1880
1881     if ($file = $obj->cmd_args) {
1882         # help for no arguments (old-style was return from sub).
1883         if ( !$file ) {
1884             print $OUT
1885             "The old f command is now the r command.\n";    # hint
1886             print $OUT "The new f command switches filenames.\n";
1887             next CMD;
1888         } ## end if (!$file)
1889
1890         # if not in magic file list, try a close match.
1891         if ( !defined $main::{ '_<' . $file } ) {
1892             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1893                 {
1894                     $try = substr( $try, 2 );
1895                     print $OUT "Choosing $try matching '$file':\n";
1896                     $file = $try;
1897                 }
1898             } ## end if (($try) = grep(m#^_<.*$file#...
1899         } ## end if (!defined $main::{ ...
1900
1901         # If not successfully switched now, we failed.
1902         if ( !defined $main::{ '_<' . $file } ) {
1903             print $OUT "No file matching '$file' is loaded.\n";
1904             next CMD;
1905         }
1906
1907         # We switched, so switch the debugger internals around.
1908         elsif ( $file ne $filename ) {
1909             *dbline   = $main::{ '_<' . $file };
1910             $max      = $#dbline;
1911             $filename = $file;
1912             $start    = 1;
1913             $cmd      = "l";
1914         } ## end elsif ($file ne $filename)
1915
1916         # We didn't switch; say we didn't.
1917         else {
1918             print $OUT "Already in $file.\n";
1919             next CMD;
1920         }
1921     }
1922
1923     return;
1924 }
1925
1926 sub _DB__handle_dot_command {
1927     my ($obj) = @_;
1928
1929     # . command.
1930     if ($obj->_is_full('.')) {
1931         $incr = -1;    # stay at current line
1932
1933         # Reset everything to the old location.
1934         $start    = $line;
1935         $filename = $filename_ini;
1936         *dbline   = $main::{ '_<' . $filename };
1937         $max      = $#dbline;
1938
1939         # Now where are we?
1940         print_lineinfo($obj->position());
1941         next CMD;
1942     }
1943
1944     return;
1945 }
1946
1947 sub _DB__handle_y_command {
1948     my ($obj) = @_;
1949
1950     if (my ($match_level, $match_vars)
1951         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1952
1953         # See if we've got the necessary support.
1954         if (!eval {
1955             local @INC = @INC;
1956             pop @INC if $INC[-1] eq '.';
1957             require PadWalker; PadWalker->VERSION(0.08) }) {
1958             my $Err = $@;
1959             _db_warn(
1960                 $Err =~ /locate/
1961                 ? "PadWalker module not found - please install\n"
1962                 : $Err
1963             );
1964             next CMD;
1965         }
1966
1967         # Load up dumpvar if we don't have it. If we can, that is.
1968         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1969         defined &main::dumpvar
1970             or print $OUT "dumpvar.pl not available.\n"
1971             and next CMD;
1972
1973         # Got all the modules we need. Find them and print them.
1974         my @vars = split( ' ', $match_vars || '' );
1975
1976         # Find the pad.
1977         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1978
1979         # Oops. Can't find it.
1980         if (my $Err = $@) {
1981             $Err =~ s/ at .*//;
1982             _db_warn($Err);
1983             next CMD;
1984         }
1985
1986         # Show the desired vars with dumplex().
1987         my $savout = select($OUT);
1988
1989         # Have dumplex dump the lexicals.
1990         foreach my $key (sort keys %$h) {
1991             dumpvar::dumplex( $key, $h->{$key},
1992                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1993                 @vars );
1994         }
1995         select($savout);
1996         next CMD;
1997     }
1998 }
1999
2000 sub _DB__handle_c_command {
2001     my ($obj) = @_;
2002
2003     my $i = $obj->cmd_args;
2004
2005     if ($i =~ m#\A[\w:]*\z#) {
2006
2007         # Hey, show's over. The debugged program finished
2008         # executing already.
2009         next CMD if _DB__is_finished();
2010
2011         # Capture the place to put a one-time break.
2012         $subname = $i;
2013
2014         #  Probably not needed, since we finish an interactive
2015         #  sub-session anyway...
2016         # local $filename = $filename;
2017         # local *dbline = *dbline; # XXX Would this work?!
2018         #
2019         # The above question wonders if localizing the alias
2020         # to the magic array works or not. Since it's commented
2021         # out, we'll just leave that to speculation for now.
2022
2023         # If the "subname" isn't all digits, we'll assume it
2024         # is a subroutine name, and try to find it.
2025         if ( $subname =~ /\D/ ) {    # subroutine name
2026             # Qualify it to the current package unless it's
2027             # already qualified.
2028             $subname = $package . "::" . $subname
2029             unless $subname =~ /::/;
2030
2031             # find_sub will return "file:line_number" corresponding
2032             # to where the subroutine is defined; we call find_sub,
2033             # break up the return value, and assign it in one
2034             # operation.
2035             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2036
2037             # Force the line number to be numeric.
2038             $i = $i + 0;
2039
2040             # If we got a line number, we found the sub.
2041             if ($i) {
2042
2043                 # Switch all the debugger's internals around so
2044                 # we're actually working with that file.
2045                 $filename = $file;
2046                 *dbline   = $main::{ '_<' . $filename };
2047
2048                 # Mark that there's a breakpoint in this file.
2049                 $had_breakpoints{$filename} |= 1;
2050
2051                 # Scan forward to the first executable line
2052                 # after the 'sub whatever' line.
2053                 $max = $#dbline;
2054                 my $_line_num = $i;
2055                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2056                 {
2057                     $_line_num++;
2058                 }
2059                 $i = $_line_num;
2060             } ## end if ($i)
2061
2062             # We didn't find a sub by that name.
2063             else {
2064                 print $OUT "Subroutine $subname not found.\n";
2065                 next CMD;
2066             }
2067         } ## end if ($subname =~ /\D/)
2068
2069         # At this point, either the subname was all digits (an
2070         # absolute line-break request) or we've scanned through
2071         # the code following the definition of the sub, looking
2072         # for an executable, which we may or may not have found.
2073         #
2074         # If $i (which we set $subname from) is non-zero, we
2075         # got a request to break at some line somewhere. On
2076         # one hand, if there wasn't any real subroutine name
2077         # involved, this will be a request to break in the current
2078         # file at the specified line, so we have to check to make
2079         # sure that the line specified really is breakable.
2080         #
2081         # On the other hand, if there was a subname supplied, the
2082         # preceding block has moved us to the proper file and
2083         # location within that file, and then scanned forward
2084         # looking for the next executable line. We have to make
2085         # sure that one was found.
2086         #
2087         # On the gripping hand, we can't do anything unless the
2088         # current value of $i points to a valid breakable line.
2089         # Check that.
2090         if ($i) {
2091
2092             # Breakable?
2093             if ( $dbline[$i] == 0 ) {
2094                 print $OUT "Line $i not breakable.\n";
2095                 next CMD;
2096             }
2097
2098             # Yes. Set up the one-time-break sigil.
2099             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2100             _enable_breakpoint_temp_enabled_status($filename, $i);
2101         } ## end if ($i)
2102
2103         # Turn off stack tracing from here up.
2104         for my $j (0 .. $stack_depth) {
2105             $stack[ $j ] &= ~1;
2106         }
2107         last CMD;
2108     }
2109
2110     return;
2111 }
2112
2113 sub _DB__handle_forward_slash_command {
2114     my ($obj) = @_;
2115
2116     # The pattern as a string.
2117     use vars qw($inpat);
2118
2119     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2120
2121         # Remove the final slash.
2122         $inpat =~ s:([^\\])/$:$1:;
2123
2124         # If the pattern isn't null ...
2125         if ( $inpat ne "" ) {
2126
2127             # Turn off warn and die processing for a bit.
2128             local $SIG{__DIE__};
2129             local $SIG{__WARN__};
2130
2131             # Create the pattern.
2132             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2133             if ( $@ ne "" ) {
2134
2135                 # Oops. Bad pattern. No biscuit.
2136                 # Print the eval error and go back for more
2137                 # commands.
2138                 print {$OUT} "$@";
2139                 next CMD;
2140             }
2141             $obj->pat($inpat);
2142         } ## end if ($inpat ne "")
2143
2144         # Set up to stop on wrap-around.
2145         $end = $start;
2146
2147         # Don't move off the current line.
2148         $incr = -1;
2149
2150         my $pat = $obj->pat;
2151
2152         # Done in eval so nothing breaks if the pattern
2153         # does something weird.
2154         eval
2155         {
2156             no strict q/vars/;
2157             for (;;) {
2158                 # Move ahead one line.
2159                 ++$start;
2160
2161                 # Wrap if we pass the last line.
2162                 if ($start > $max) {
2163                     $start = 1;
2164                 }
2165
2166                 # Stop if we have gotten back to this line again,
2167                 last if ($start == $end);
2168
2169                 # A hit! (Note, though, that we are doing
2170                 # case-insensitive matching. Maybe a qr//
2171                 # expression would be better, so the user could
2172                 # do case-sensitive matching if desired.
2173                 if ($dbline[$start] =~ m/$pat/i) {
2174                     if ($slave_editor) {
2175                         # Handle proper escaping in the slave.
2176                         print {$OUT} "\032\032$filename:$start:0\n";
2177                     }
2178                     else {
2179                         # Just print the line normally.
2180                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2181                     }
2182                     # And quit since we found something.
2183                     last;
2184                 }
2185             }
2186         };
2187
2188         if ($@) {
2189             warn $@;
2190         }
2191
2192         # If we wrapped, there never was a match.
2193         if ( $start == $end ) {
2194             print {$OUT} "/$pat/: not found\n";
2195         }
2196         next CMD;
2197     }
2198
2199     return;
2200 }
2201
2202 sub _DB__handle_question_mark_command {
2203     my ($obj) = @_;
2204
2205     # ? - backward pattern search.
2206     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2207
2208         # Get the pattern, remove trailing question mark.
2209         $inpat =~ s:([^\\])\?$:$1:;
2210
2211         # If we've got one ...
2212         if ( $inpat ne "" ) {
2213
2214             # Turn off die & warn handlers.
2215             local $SIG{__DIE__};
2216             local $SIG{__WARN__};
2217             eval '$inpat =~ m' . "\a$inpat\a";
2218
2219             if ( $@ ne "" ) {
2220
2221                 # Ouch. Not good. Print the error.
2222                 print $OUT $@;
2223                 next CMD;
2224             }
2225             $obj->pat($inpat);
2226         } ## end if ($inpat ne "")
2227
2228         # Where we are now is where to stop after wraparound.
2229         $end = $start;
2230
2231         # Don't move away from this line.
2232         $incr = -1;
2233
2234         my $pat = $obj->pat;
2235         # Search inside the eval to prevent pattern badness
2236         # from killing us.
2237         eval {
2238             no strict q/vars/;
2239             for (;;) {
2240                 # Back up a line.
2241                 --$start;
2242
2243                 # Wrap if we pass the first line.
2244
2245                 $start = $max if ($start <= 0);
2246
2247                 # Quit if we get back where we started,
2248                 last if ($start == $end);
2249
2250                 # Match?
2251                 if ($dbline[$start] =~ m/$pat/i) {
2252                     if ($slave_editor) {
2253                         # Yep, follow slave editor requirements.
2254                         print $OUT "\032\032$filename:$start:0\n";
2255                     }
2256                     else {
2257                         # Yep, just print normally.
2258                         print $OUT "$start:\t",$dbline[$start],"\n";
2259                     }
2260
2261                     # Found, so done.
2262                     last;
2263                 }
2264             }
2265         };
2266
2267         # Say we failed if the loop never found anything,
2268         if ( $start == $end ) {
2269             print {$OUT} "?$pat?: not found\n";
2270         }
2271         next CMD;
2272     }
2273
2274     return;
2275 }
2276
2277 sub _DB__handle_restart_and_rerun_commands {
2278     my ($obj) = @_;
2279
2280     my $cmd_cmd = $obj->cmd_verb;
2281     my $cmd_params = $obj->cmd_args;
2282     # R - restart execution.
2283     # rerun - controlled restart execution.
2284     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2285
2286         # Change directory to the initial current working directory on
2287         # the script startup, so if the debugged program changed the
2288         # directory, then we will still be able to find the path to the
2289         # the program. (perl 5 RT #121509 ).
2290         chdir ($_initial_cwd);
2291
2292         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2293
2294         # Close all non-system fds for a clean restart.  A more
2295         # correct method would be to close all fds that were not
2296         # open when the process started, but this seems to be
2297         # hard.  See "debugger 'R'estart and open database
2298         # connections" on p5p.
2299
2300         my $max_fd = 1024; # default if POSIX can't be loaded
2301         if (eval { require POSIX }) {
2302             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2303         }
2304
2305         if (defined $max_fd) {
2306             foreach ($^F+1 .. $max_fd-1) {
2307                 next unless open FD_TO_CLOSE, "<&=$_";
2308                 close(FD_TO_CLOSE);
2309             }
2310         }
2311
2312         # And run Perl again.  We use exec() to keep the
2313         # PID stable (and that way $ini_pids is still valid).
2314         exec(@args) or print {$OUT} "exec failed: $!\n";
2315
2316         last CMD;
2317     }
2318
2319     return;
2320 }
2321
2322 sub _DB__handle_run_command_in_pager_command {
2323     my ($obj) = @_;
2324
2325     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2326         if ( $pager =~ /^\|/ ) {
2327
2328             # Default pager is into a pipe. Redirect I/O.
2329             open( SAVEOUT, ">&STDOUT" )
2330             || _db_warn("Can't save STDOUT");
2331             open( STDOUT, ">&OUT" )
2332             || _db_warn("Can't redirect STDOUT");
2333         } ## end if ($pager =~ /^\|/)
2334         else {
2335
2336             # Not into a pipe. STDOUT is safe.
2337             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2338         }
2339
2340         # Fix up environment to record we have less if so.
2341         fix_less();
2342
2343         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2344
2345             # Couldn't open pipe to pager.
2346             _db_warn("Can't pipe output to '$pager'");
2347             if ( $pager =~ /^\|/ ) {
2348
2349                 # Redirect I/O back again.
2350                 open( OUT, ">&STDOUT" )    # XXX: lost message
2351                 || _db_warn("Can't restore DB::OUT");
2352                 open( STDOUT, ">&SAVEOUT" )
2353                 || _db_warn("Can't restore STDOUT");
2354                 close(SAVEOUT);
2355             } ## end if ($pager =~ /^\|/)
2356             else {
2357
2358                 # Redirect I/O. STDOUT already safe.
2359                 open( OUT, ">&STDOUT" )    # XXX: lost message
2360                 || _db_warn("Can't restore DB::OUT");
2361             }
2362             next CMD;
2363         } ## end unless ($piped = open(OUT,...
2364
2365         # Set up broken-pipe handler if necessary.
2366         $SIG{PIPE} = \&DB::catch
2367         if $pager =~ /^\|/
2368         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2369
2370         _autoflush(\*OUT);
2371         # Save current filehandle, and put it back.
2372         $obj->selected(scalar( select(OUT) ));
2373         # Don't put it back if pager was a pipe.
2374         if ($cmd !~ /\A\|\|/)
2375         {
2376             select($obj->selected());
2377             $obj->selected("");
2378         }
2379
2380         # Trim off the pipe symbols and run the command now.
2381         $cmd =~ s#\A\|+\s*##;
2382         redo PIPE;
2383     }
2384
2385     return;
2386 }
2387
2388 sub _DB__handle_m_command {
2389     my ($obj) = @_;
2390
2391     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2392         methods($1);
2393         next CMD;
2394     }
2395
2396     # m expr - set up DB::eval to do the work
2397     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2398         $onetimeDump = 'methods';   #  method output gets used there
2399     }
2400
2401     return;
2402 }
2403
2404 sub _DB__at_end_of_every_command {
2405     my ($obj) = @_;
2406
2407     # At the end of every command:
2408     if ($obj->piped) {
2409
2410         # Unhook the pipe mechanism now.
2411         if ( $pager =~ /^\|/ ) {
2412
2413             # No error from the child.
2414             $? = 0;
2415
2416             # we cannot warn here: the handle is missing --tchrist
2417             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2418
2419             # most of the $? crud was coping with broken cshisms
2420             # $? is explicitly set to 0, so this never runs.
2421             if ($?) {
2422                 print SAVEOUT "Pager '$pager' failed: ";
2423                 if ( $? == -1 ) {
2424                     print SAVEOUT "shell returned -1\n";
2425                 }
2426                 elsif ( $? >> 8 ) {
2427                     print SAVEOUT ( $? & 127 )
2428                     ? " (SIG#" . ( $? & 127 ) . ")"
2429                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2430                 }
2431                 else {
2432                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2433                 }
2434             } ## end if ($?)
2435
2436             # Reopen filehandle for our output (if we can) and
2437             # restore STDOUT (if we can).
2438             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2439             open( STDOUT, ">&SAVEOUT" )
2440             || _db_warn("Can't restore STDOUT");
2441
2442             # Turn off pipe exception handler if necessary.
2443             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2444
2445             # Will stop ignoring SIGPIPE if done like nohup(1)
2446             # does SIGINT but Perl doesn't give us a choice.
2447         } ## end if ($pager =~ /^\|/)
2448         else {
2449
2450             # Non-piped "pager". Just restore STDOUT.
2451             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2452         }
2453
2454         # Let Readline know about the new filehandles.
2455         reset_IN_OUT( \*IN, \*OUT );
2456
2457         # Close filehandle pager was using, restore the normal one
2458         # if necessary,
2459         close(SAVEOUT);
2460
2461         if ($obj->selected() ne "") {
2462             select($obj->selected);
2463             $obj->selected("");
2464         }
2465
2466         # No pipes now.
2467         $obj->piped("");
2468     } ## end if ($piped)
2469
2470     return;
2471 }
2472
2473 sub _DB__handle_watch_expressions
2474 {
2475     my $self = shift;
2476
2477     if ( $DB::trace & 2 ) {
2478         for my $n (0 .. $#DB::to_watch) {
2479             $DB::evalarg = $DB::to_watch[$n];
2480             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2481
2482             # Fix context DB::eval() wants to return an array, but
2483             # we need a scalar here.
2484             my ($val) = join( "', '", DB::eval(@_) );
2485             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2486
2487             # Did it change?
2488             if ( $val ne $DB::old_watch[$n] ) {
2489
2490                 # Yep! Show the difference, and fake an interrupt.
2491                 $DB::signal = 1;
2492                 print {$DB::OUT} <<EOP;
2493 Watchpoint $n:\t$DB::to_watch[$n] changed:
2494     old value:\t$DB::old_watch[$n]
2495     new value:\t$val
2496 EOP
2497                 $DB::old_watch[$n] = $val;
2498             } ## end if ($val ne $old_watch...
2499         } ## end for my $n (0 ..
2500     } ## end if ($trace & 2)
2501
2502     return;
2503 }
2504
2505 # 't' is type.
2506 # 'm' is method.
2507 # 'v' is the value (i.e: method name or subroutine ref).
2508 # 's' is subroutine.
2509 my %cmd_lookup;
2510
2511 BEGIN
2512 {
2513     %cmd_lookup =
2514 (
2515     '-' => { t => 'm', v => '_handle_dash_command', },
2516     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2517     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2518     'H' => { t => 'm', v => '_handle_H_command', },
2519     'S' => { t => 'm', v => '_handle_S_command', },
2520     'T' => { t => 'm', v => '_handle_T_command', },
2521     'W' => { t => 'm', v => '_handle_W_command', },
2522     'c' => { t => 's', v => \&_DB__handle_c_command, },
2523     'f' => { t => 's', v => \&_DB__handle_f_command, },
2524     'm' => { t => 's', v => \&_DB__handle_m_command, },
2525     'n' => { t => 'm', v => '_handle_n_command', },
2526     'p' => { t => 'm', v => '_handle_p_command', },
2527     'q' => { t => 'm', v => '_handle_q_command', },
2528     'r' => { t => 'm', v => '_handle_r_command', },
2529     's' => { t => 'm', v => '_handle_s_command', },
2530     'save' => { t => 'm', v => '_handle_save_command', },
2531     'source' => { t => 'm', v => '_handle_source_command', },
2532     't' => { t => 'm', v => '_handle_t_command', },
2533     'w' => { t => 'm', v => '_handle_w_command', },
2534     'x' => { t => 'm', v => '_handle_x_command', },
2535     'y' => { t => 's', v => \&_DB__handle_y_command, },
2536     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2537         ('X', 'V')),
2538     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2539         qw(enable disable)),
2540     (map { $_ =>
2541         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2542         } qw(R rerun)),
2543     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2544         qw(a A b B e E h i l L M o O v w W)),
2545 );
2546 };
2547
2548 sub DB {
2549
2550     # lock the debugger and get the thread id for the prompt
2551     lock($DBGR);
2552     my $tid;
2553     my $position;
2554     my ($prefix, $after, $infix);
2555     my $pat;
2556     my $explicit_stop;
2557     my $piped;
2558     my $selected;
2559
2560     if ($ENV{PERL5DB_THREADED}) {
2561         $tid = eval { "[".threads->tid."]" };
2562     }
2563
2564     my $cmd_verb;
2565     my $cmd_args;
2566
2567     my $obj = DB::Obj->new(
2568         {
2569             position => \$position,
2570             prefix => \$prefix,
2571             after => \$after,
2572             explicit_stop => \$explicit_stop,
2573             infix => \$infix,
2574             cmd_args => \$cmd_args,
2575             cmd_verb => \$cmd_verb,
2576             pat => \$pat,
2577             piped => \$piped,
2578             selected => \$selected,
2579         },
2580     );
2581
2582     $obj->_DB_on_init__initialize_globals(@_);
2583
2584     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2585     # The code being debugged may have altered them.
2586     DB::save();
2587
2588     # Since DB::DB gets called after every line, we can use caller() to
2589     # figure out where we last were executing. Sneaky, eh? This works because
2590     # caller is returning all the extra information when called from the
2591     # debugger.
2592     local ( $package, $filename, $line ) = caller;
2593     $filename_ini = $filename;
2594
2595     # set up the context for DB::eval, so it can properly execute
2596     # code on behalf of the user. We add the package in so that the
2597     # code is eval'ed in the proper package (not in the debugger!).
2598     local $usercontext = _calc_usercontext($package);
2599
2600     # Create an alias to the active file magical array to simplify
2601     # the code here.
2602     local (*dbline) = $main::{ '_<' . $filename };
2603
2604     # Last line in the program.
2605     $max = $#dbline;
2606
2607     # The &-call is here to ascertain the mutability of @_.
2608     &_DB__determine_if_we_should_break;
2609
2610     # Preserve the current stop-or-not, and see if any of the W
2611     # (watch expressions) has changed.
2612     my $was_signal = $signal;
2613
2614     # If we have any watch expressions ...
2615     _DB__handle_watch_expressions($obj);
2616
2617 =head2 C<watchfunction()>
2618
2619 C<watchfunction()> is a function that can be defined by the user; it is a
2620 function which will be run on each entry to C<DB::DB>; it gets the
2621 current package, filename, and line as its parameters.
2622
2623 The watchfunction can do anything it likes; it is executing in the
2624 debugger's context, so it has access to all of the debugger's internal
2625 data structures and functions.
2626
2627 C<watchfunction()> can control the debugger's actions. Any of the following
2628 will cause the debugger to return control to the user's program after
2629 C<watchfunction()> executes:
2630
2631 =over 4
2632
2633 =item *
2634
2635 Returning a false value from the C<watchfunction()> itself.
2636
2637 =item *
2638
2639 Altering C<$single> to a false value.
2640
2641 =item *
2642
2643 Altering C<$signal> to a false value.
2644
2645 =item *
2646
2647 Turning off the C<4> bit in C<$trace> (this also disables the
2648 check for C<watchfunction()>. This can be done with
2649
2650     $trace &= ~4;
2651
2652 =back
2653
2654 =cut
2655
2656     # If there's a user-defined DB::watchfunction, call it with the
2657     # current package, filename, and line. The function executes in
2658     # the DB:: package.
2659     if ( $trace & 4 ) {    # User-installed watch
2660         return
2661           if watchfunction( $package, $filename, $line )
2662           and not $single
2663           and not $was_signal
2664           and not( $trace & ~4 );
2665     } ## end if ($trace & 4)
2666
2667     # Pick up any alteration to $signal in the watchfunction, and
2668     # turn off the signal now.
2669     $was_signal = $signal;
2670     $signal     = 0;
2671
2672 =head2 GETTING READY TO EXECUTE COMMANDS
2673
2674 The debugger decides to take control if single-step mode is on, the
2675 C<t> command was entered, or the user generated a signal. If the program
2676 has fallen off the end, we set things up so that entering further commands
2677 won't cause trouble, and we say that the program is over.
2678
2679 =cut
2680
2681     # Make sure that we always print if asked for explicitly regardless
2682     # of $trace_to_depth .
2683     $explicit_stop = ($single || $was_signal);
2684
2685     # Check to see if we should grab control ($single true,
2686     # trace set appropriately, or we got a signal).
2687     if ( $explicit_stop || ( $trace & 1 ) ) {
2688         $obj->_DB__grab_control(@_);
2689     } ## end if ($single || ($trace...
2690
2691 =pod
2692
2693 If there's an action to be executed for the line we stopped at, execute it.
2694 If there are any preprompt actions, execute those as well.
2695
2696 =cut
2697
2698     # If there's an action, do it now.
2699     if ($action) {
2700         $evalarg = $action;
2701         # The &-call is here to ascertain the mutability of @_.
2702         &DB::eval;
2703     }
2704
2705     # Are we nested another level (e.g., did we evaluate a function
2706     # that had a breakpoint in it at the debugger prompt)?
2707     if ( $single || $was_signal ) {
2708
2709         # Yes, go down a level.
2710         local $level = $level + 1;
2711
2712         # Do any pre-prompt actions.
2713         foreach $evalarg (@$pre) {
2714             # The &-call is here to ascertain the mutability of @_.
2715             &DB::eval;
2716         }
2717
2718         # Complain about too much recursion if we passed the limit.
2719         if ($single & 4) {
2720             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2721         }
2722
2723         # The line we're currently on. Set $incr to -1 to stay here
2724         # until we get a command that tells us to advance.
2725         $start = $line;
2726         $incr  = -1;      # for backward motion.
2727
2728         # Tack preprompt debugger actions ahead of any actual input.
2729         @typeahead = ( @$pretype, @typeahead );
2730
2731 =head2 WHERE ARE WE?
2732
2733 XXX Relocate this section?
2734
2735 The debugger normally shows the line corresponding to the current line of
2736 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2737 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2738
2739 C<$incr> controls by how many lines the I<current> line should move forward
2740 after a command is executed. If set to -1, this indicates that the I<current>
2741 line shouldn't change.
2742
2743 C<$start> is the I<current> line. It is used for things like knowing where to
2744 move forwards or backwards from when doing an C<L> or C<-> command.
2745
2746 C<$max> tells the debugger where the last line of the current file is. It's
2747 used to terminate loops most often.
2748
2749 =head2 THE COMMAND LOOP
2750
2751 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2752 in two parts:
2753
2754 =over 4
2755
2756 =item *
2757
2758 The outer part of the loop, starting at the C<CMD> label. This loop
2759 reads a command and then executes it.
2760
2761 =item *
2762
2763 The inner part of the loop, starting at the C<PIPE> label. This part
2764 is wholly contained inside the C<CMD> block and only executes a command.
2765 Used to handle commands running inside a pager.
2766
2767 =back
2768
2769 So why have two labels to restart the loop? Because sometimes, it's easier to
2770 have a command I<generate> another command and then re-execute the loop to do
2771 the new command. This is faster, but perhaps a bit more convoluted.
2772
2773 =cut
2774
2775         # The big command dispatch loop. It keeps running until the
2776         # user yields up control again.
2777         #
2778         # If we have a terminal for input, and we get something back
2779         # from readline(), keep on processing.
2780
2781       CMD:
2782         while (_DB__read_next_cmd($tid))
2783         {
2784
2785             share($cmd);
2786             # ... try to execute the input as debugger commands.
2787
2788             # Don't stop running.
2789             $single = 0;
2790
2791             # No signal is active.
2792             $signal = 0;
2793
2794             # Handle continued commands (ending with \):
2795             if ($cmd =~ s/\\\z/\n/) {
2796                 $cmd .= DB::readline("  cont: ");
2797                 redo CMD;
2798             }
2799
2800 =head4 The null command
2801
2802 A newline entered by itself means I<re-execute the last command>. We grab the
2803 command out of C<$laststep> (where it was recorded previously), and copy it
2804 back into C<$cmd> to be executed below. If there wasn't any previous command,
2805 we'll do nothing below (no command will match). If there was, we also save it
2806 in the command history and fall through to allow the command parsing to pick
2807 it up.
2808
2809 =cut
2810
2811             # Empty input means repeat the last command.
2812             if ($cmd eq '') {
2813                 $cmd = $laststep;
2814             }
2815             chomp($cmd);    # get rid of the annoying extra newline
2816             if (length($cmd) >= 2) {
2817                 push( @hist, $cmd );
2818             }
2819             push( @truehist, $cmd );
2820             share(@hist);
2821             share(@truehist);
2822
2823             # This is a restart point for commands that didn't arrive
2824             # via direct user input. It allows us to 'redo PIPE' to
2825             # re-execute command processing without reading a new command.
2826           PIPE: {
2827                 _DB__trim_command_and_return_first_component($obj);
2828
2829 =head3 COMMAND ALIASES
2830
2831 The debugger can create aliases for commands (these are stored in the
2832 C<%alias> hash). Before a command is executed, the command loop looks it up
2833 in the alias hash and substitutes the contents of the alias for the command,
2834 completely replacing it.
2835
2836 =cut
2837
2838                 # See if there's an alias for the command, and set it up if so.
2839                 if ( $alias{$cmd_verb} ) {
2840
2841                     # Squelch signal handling; we want to keep control here
2842                     # if something goes loco during the alias eval.
2843                     local $SIG{__DIE__};
2844                     local $SIG{__WARN__};
2845
2846                     # This is a command, so we eval it in the DEBUGGER's
2847                     # scope! Otherwise, we can't see the special debugger
2848                     # variables, or get to the debugger's subs. (Well, we
2849                     # _could_, but why make it even more complicated?)
2850                     eval "\$cmd =~ $alias{$cmd_verb}";
2851                     if ($@) {
2852                         local $\ = '';
2853                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2854                         next CMD;
2855                     }
2856                     _DB__trim_command_and_return_first_component($obj);
2857                 } ## end if ($alias{$cmd_verb})
2858
2859 =head3 MAIN-LINE COMMANDS
2860
2861 All of these commands work up to and after the program being debugged has
2862 terminated.
2863
2864 =head4 C<q> - quit
2865
2866 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2867 try to execute further, cleaning any restart-related stuff out of the
2868 environment, and executing with the last value of C<$?>.
2869
2870 =cut
2871
2872                 # All of these commands were remapped in perl 5.8.0;
2873                 # we send them off to the secondary dispatcher (see below).
2874                 $obj->_handle_special_char_cmd_wrapper_commands;
2875                 _DB__trim_command_and_return_first_component($obj);
2876
2877                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2878                     my $type = $cmd_rec->{t};
2879                     my $val = $cmd_rec->{v};
2880                     if ($type eq 'm') {
2881                         $obj->$val();
2882                     }
2883                     elsif ($type eq 's') {
2884                         $val->($obj);
2885                     }
2886                 }
2887
2888 =head4 C<t> - trace [n]
2889
2890 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2891 If level is specified, set C<$trace_to_depth>.
2892
2893 =head4 C<S> - list subroutines matching/not matching a pattern
2894
2895 Walks through C<%sub>, checking to see whether or not to print the name.
2896
2897 =head4 C<X> - list variables in current package
2898
2899 Since the C<V> command actually processes this, just change this to the
2900 appropriate C<V> command and fall through.
2901
2902 =head4 C<V> - list variables
2903
2904 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2905
2906 =head4 C<x> - evaluate and print an expression
2907
2908 Hands the expression off to C<DB::eval>, setting it up to print the value
2909 via C<dumpvar.pl> instead of just printing it directly.
2910
2911 =head4 C<m> - print methods
2912
2913 Just uses C<DB::methods> to determine what methods are available.
2914
2915 =head4 C<f> - switch files
2916
2917 Switch to a different filename.
2918
2919 =head4 C<.> - return to last-executed line.
2920
2921 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2922 and then we look up the line in the magical C<%dbline> hash.
2923
2924 =head4 C<-> - back one window
2925
2926 We change C<$start> to be one window back; if we go back past the first line,
2927 we set it to be the first line. We ser C<$incr> to put us back at the
2928 currently-executing line, and then put a C<l $start +> (list one window from
2929 C<$start>) in C<$cmd> to be executed later.
2930
2931 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2932
2933 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2934 problems, most notably that the default case of several commands destroying
2935 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2936 retain the old commands for those who were used to using them or who preferred
2937 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2938 deal with them instead of processing them in-line.
2939
2940 =head4 C<y> - List lexicals in higher scope
2941
2942 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2943 above the current one and then displays then using C<dumpvar.pl>.
2944
2945 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2946
2947 All of the commands below this point don't work after the program being
2948 debugged has ended. All of them check to see if the program has ended; this
2949 allows the commands to be relocated without worrying about a 'line of
2950 demarcation' above which commands can be entered anytime, and below which
2951 they can't.
2952
2953 =head4 C<n> - single step, but don't trace down into subs
2954
2955 Done by setting C<$single> to 2, which forces subs to execute straight through
2956 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2957 so a null command knows what to re-execute.
2958
2959 =head4 C<s> - single-step, entering subs
2960
2961 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2962 subs. Also saves C<s> as C<$lastcmd>.
2963
2964 =head4 C<c> - run continuously, setting an optional breakpoint
2965
2966 Most of the code for this command is taken up with locating the optional
2967 breakpoint, which is either a subroutine name or a line number. We set
2968 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2969 in this and all call levels above this one.
2970
2971 =head4 C<r> - return from a subroutine
2972
2973 For C<r> to work properly, the debugger has to stop execution again
2974 immediately after the return is executed. This is done by forcing
2975 single-stepping to be on in the call level above the current one. If
2976 we are printing return values when a C<r> is executed, set C<$doret>
2977 appropriately, and force us out of the command loop.
2978
2979 =head4 C<T> - stack trace
2980
2981 Just calls C<DB::print_trace>.
2982
2983 =head4 C<w> - List window around current line.
2984
2985 Just calls C<DB::cmd_w>.
2986
2987 =head4 C<W> - watch-expression processing.
2988
2989 Just calls C<DB::cmd_W>.
2990
2991 =head4 C</> - search forward for a string in the source
2992
2993 We take the argument and treat it as a pattern. If it turns out to be a
2994 bad one, we return the error we got from trying to C<eval> it and exit.
2995 If not, we create some code to do the search and C<eval> it so it can't
2996 mess us up.
2997
2998 =cut
2999
3000                 _DB__handle_forward_slash_command($obj);
3001
3002 =head4 C<?> - search backward for a string in the source
3003
3004 Same as for C</>, except the loop runs backwards.
3005
3006 =cut
3007
3008                 _DB__handle_question_mark_command($obj);
3009
3010 =head4 C<$rc> - Recall command
3011
3012 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3013 that the terminal supports history). It finds the command required, puts it
3014 into C<$cmd>, and redoes the loop to execute it.
3015
3016 =cut
3017
3018                 # $rc - recall command.
3019                 $obj->_handle_rc_recall_command;
3020
3021 =head4 C<$sh$sh> - C<system()> command
3022
3023 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3024 C<STDOUT> from getting messed up.
3025
3026 =cut
3027
3028                 $obj->_handle_sh_command;
3029
3030 =head4 C<$rc I<pattern> $rc> - Search command history
3031
3032 Another command to manipulate C<@hist>: this one searches it with a pattern.
3033 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3034
3035 =cut
3036
3037                 $obj->_handle_rc_search_history_command;
3038
3039 =head4 C<$sh> - Invoke a shell
3040
3041 Uses C<_db_system()> to invoke a shell.
3042
3043 =cut
3044
3045 =head4 C<$sh I<command>> - Force execution of a command in a shell
3046
3047 Like the above, but the command is passed to the shell. Again, we use
3048 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3049
3050 =head4 C<H> - display commands in history
3051
3052 Prints the contents of C<@hist> (if any).
3053
3054 =head4 C<man, doc, perldoc> - look up documentation
3055
3056 Just calls C<runman()> to print the appropriate document.
3057
3058 =cut
3059
3060                 $obj->_handle_doc_command;
3061
3062 =head4 C<p> - print
3063
3064 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3065 the bottom of the loop.
3066
3067 =head4 C<=> - define command alias
3068
3069 Manipulates C<%alias> to add or list command aliases.
3070
3071 =head4 C<source> - read commands from a file.
3072
3073 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3074 pick it up.
3075
3076 =head4 C<enable> C<disable> - enable or disable breakpoints
3077
3078 This enables or disables breakpoints.
3079
3080 =head4 C<save> - send current history to a file
3081
3082 Takes the complete history, (not the shrunken version you see with C<H>),
3083 and saves it to the given filename, so it can be replayed using C<source>.
3084
3085 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3086
3087 =head4 C<R> - restart
3088
3089 Restart the debugger session.
3090
3091 =head4 C<rerun> - rerun the current session
3092
3093 Return to any given position in the B<true>-history list
3094
3095 =head4 C<|, ||> - pipe output through the pager.
3096
3097 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3098 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3099 pipe to the pager (restoring the output filehandles if this fails). If this
3100 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3101 set C<$signal>, sending us back into the debugger.
3102
3103 We then trim off the pipe symbols and C<redo> the command loop at the
3104 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3105 reading another.
3106
3107 =cut
3108
3109                 # || - run command in the pager, with output to DB::OUT.
3110                 _DB__handle_run_command_in_pager_command($obj);
3111
3112 =head3 END OF COMMAND PARSING
3113
3114 Anything left in C<$cmd> at this point is a Perl expression that we want to
3115 evaluate. We'll always evaluate in the user's context, and fully qualify
3116 any variables we might want to address in the C<DB> package.
3117
3118 =cut
3119
3120             }    # PIPE:
3121
3122             # trace an expression
3123             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3124
3125             # Make sure the flag that says "the debugger's running" is
3126             # still on, to make sure we get control again.
3127             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3128
3129             # Run *our* eval that executes in the caller's context.
3130             # The &-call is here to ascertain the mutability of @_.
3131             &DB::eval;
3132
3133             # Turn off the one-time-dump stuff now.
3134             if ($onetimeDump) {
3135                 $onetimeDump      = undef;
3136                 $onetimedumpDepth = undef;
3137             }
3138             elsif ( $term_pid == $$ ) {
3139                 eval { # May run under miniperl, when not available...
3140                     STDOUT->flush();
3141                     STDERR->flush();
3142                 };
3143
3144                 # XXX If this is the master pid, print a newline.
3145                 print {$OUT} "\n";
3146             }
3147         } ## end while (($term || &setterm...
3148
3149 =head3 POST-COMMAND PROCESSING
3150
3151 After each command, we check to see if the command output was piped anywhere.
3152 If so, we go through the necessary code to unhook the pipe and go back to
3153 our standard filehandles for input and output.
3154
3155 =cut
3156
3157         continue {    # CMD:
3158             _DB__at_end_of_every_command($obj);
3159         }    # CMD:
3160
3161 =head3 COMMAND LOOP TERMINATION
3162
3163 When commands have finished executing, we come here. If the user closed the
3164 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3165 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3166 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3167 The interpreter will then execute the next line and then return control to us
3168 again.
3169
3170 =cut
3171
3172         # No more commands? Quit.
3173         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3174
3175         # Evaluate post-prompt commands.
3176         foreach $evalarg (@$post) {
3177             # The &-call is here to ascertain the mutability of @_.
3178             &DB::eval;
3179         }
3180     }    # if ($single || $signal)
3181
3182     # Put the user's globals back where you found them.
3183     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3184     ();
3185 } ## end sub DB
3186
3187 # Because DB::Obj is used above,
3188 #
3189 #   my $obj = DB::Obj->new(
3190 #
3191 # The following package declaration must come before that,
3192 # or else runtime errors will occur with
3193 #
3194 #   PERLDB_OPTS="autotrace nonstop"
3195 #
3196 # ( rt#116771 )
3197 BEGIN {
3198
3199 package DB::Obj;
3200
3201 sub new {
3202     my $class = shift;
3203
3204     my $self = bless {}, $class;
3205
3206     $self->_init(@_);
3207
3208     return $self;
3209 }
3210
3211 sub _init {
3212     my ($self, $args) = @_;
3213
3214     %{$self} = (%$self, %$args);
3215
3216     return;
3217 }
3218
3219 {
3220     no strict 'refs';
3221     foreach my $slot_name (qw(
3222         after explicit_stop infix pat piped position prefix selected cmd_verb
3223         cmd_args
3224         )) {
3225         my $slot = $slot_name;
3226         *{$slot} = sub {
3227             my $self = shift;
3228
3229             if (@_) {
3230                 ${ $self->{$slot} } = shift;
3231             }
3232
3233             return ${ $self->{$slot} };
3234         };
3235
3236         *{"append_to_$slot"} = sub {
3237             my $self = shift;
3238             my $s = shift;
3239
3240             return $self->$slot($self->$slot . $s);
3241         };
3242     }
3243 }
3244
3245 sub _DB_on_init__initialize_globals
3246 {
3247     my $self = shift;
3248
3249     # Check for whether we should be running continuously or not.
3250     # _After_ the perl program is compiled, $single is set to 1:
3251     if ( $single and not $second_time++ ) {
3252
3253         # Options say run non-stop. Run until we get an interrupt.
3254         if ($runnonstop) {    # Disable until signal
3255                 # If there's any call stack in place, turn off single
3256                 # stepping into subs throughout the stack.
3257             for my $i (0 .. $stack_depth) {
3258                 $stack[ $i ] &= ~1;
3259             }
3260
3261             # And we are now no longer in single-step mode.
3262             $single = 0;
3263
3264             # If we simply returned at this point, we wouldn't get
3265             # the trace info. Fall on through.
3266             # return;
3267         } ## end if ($runnonstop)
3268
3269         elsif ($ImmediateStop) {
3270
3271             # We are supposed to stop here; XXX probably a break.
3272             $ImmediateStop = 0;    # We've processed it; turn it off
3273             $signal        = 1;    # Simulate an interrupt to force
3274                                    # us into the command loop
3275         }
3276     } ## end if ($single and not $second_time...
3277
3278     # If we're in single-step mode, or an interrupt (real or fake)
3279     # has occurred, turn off non-stop mode.
3280     $runnonstop = 0 if $single or $signal;
3281
3282     return;
3283 }
3284
3285 sub _my_print_lineinfo
3286 {
3287     my ($self, $i, $incr_pos) = @_;
3288
3289     if ($frame) {
3290         # Print it indented if tracing is on.
3291         DB::print_lineinfo( ' ' x $stack_depth,
3292             "$i:\t$DB::dbline[$i]" . $self->after );
3293     }
3294     else {
3295         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3296     }
3297 }
3298
3299 sub _curr_line {
3300     return $DB::dbline[$line];
3301 }
3302
3303 sub _is_full {
3304     my ($self, $letter) = @_;
3305
3306     return ($DB::cmd eq $letter);
3307 }
3308
3309 sub _DB__grab_control
3310 {
3311     my $self = shift;
3312
3313     # Yes, grab control.
3314     if ($slave_editor) {
3315
3316         # Tell the editor to update its position.
3317         $self->position("\032\032${DB::filename}:$line:0\n");
3318         DB::print_lineinfo($self->position());
3319     }
3320
3321 =pod
3322
3323 Special check: if we're in package C<DB::fake>, we've gone through the
3324 C<END> block at least once. We set up everything so that we can continue
3325 to enter commands and have a valid context to be in.
3326
3327 =cut
3328
3329     elsif ( $DB::package eq 'DB::fake' ) {
3330
3331         # Fallen off the end already.
3332         if (!$DB::term) {
3333             DB::setterm();
3334         }
3335
3336         DB::print_help(<<EOP);
3337 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3338 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3339 B<h q>, B<h R> or B<h o> to get additional info.
3340 EOP
3341
3342         # Set the DB::eval context appropriately.
3343         # At program termination disable any user actions.
3344         $DB::action = undef;
3345
3346         $DB::package     = 'main';
3347         $DB::usercontext = DB::_calc_usercontext($DB::package);
3348     } ## end elsif ($package eq 'DB::fake')
3349
3350 =pod
3351
3352 If the program hasn't finished executing, we scan forward to the
3353 next executable line, print that out, build the prompt from the file and line
3354 number information, and print that.
3355
3356 =cut
3357
3358     else {
3359
3360
3361         # Still somewhere in the midst of execution. Set up the
3362         #  debugger prompt.
3363         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3364                              # Perl 5 ones (sorry, we don't print Klingon
3365                              #module names)
3366
3367         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3368         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3369         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3370
3371         # Break up the prompt if it's really long.
3372         if ( length($self->prefix()) > 30 ) {
3373             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3374             $self->prefix("");
3375             $self->infix(":\t");
3376         }
3377         else {
3378             $self->infix("):\t");
3379             $self->position(
3380                 $self->prefix . $line. $self->infix
3381                 . $self->_curr_line . $self->after
3382             );
3383         }
3384
3385         # Print current line info, indenting if necessary.
3386         $self->_my_print_lineinfo($line, $self->position);
3387
3388         my $i;
3389         my $line_i = sub { return $DB::dbline[$i]; };
3390
3391         # Scan forward, stopping at either the end or the next
3392         # unbreakable line.
3393         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3394         {    #{ vi
3395
3396             # Drop out on null statements, block closers, and comments.
3397             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3398
3399             # Drop out if the user interrupted us.
3400             last if $signal;
3401
3402             # Append a newline if the line doesn't have one. Can happen
3403             # in eval'ed text, for instance.
3404             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3405
3406             # Next executable line.
3407             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3408                 . $self->after;
3409             $self->append_to_position($incr_pos);
3410             $self->_my_print_lineinfo($i, $incr_pos);
3411         } ## end for ($i = $line + 1 ; $i...
3412     } ## end else [ if ($slave_editor)
3413
3414     return;
3415 }
3416
3417 sub _handle_t_command {
3418     my $self = shift;
3419
3420     my $levels = $self->cmd_args();
3421
3422     if ((!length($levels)) or ($levels !~ /\D/)) {
3423         $trace ^= 1;
3424         local $\ = '';
3425         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3426         print {$OUT} "Trace = "
3427         . ( ( $trace & 1 )
3428             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3429             : "off" ) . "\n";
3430         next CMD;
3431     }
3432
3433     return;
3434 }
3435
3436
3437 sub _handle_S_command {
3438     my $self = shift;
3439
3440     if (my ($print_all_subs, $should_reverse, $Spatt)
3441         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3442         # $Spatt is the pattern (if any) to use.
3443         # Reverse scan?
3444         my $Srev     = defined $should_reverse;
3445         # No args - print all subs.
3446         my $Snocheck = !defined $print_all_subs;
3447
3448         # Need to make these sane here.
3449         local $\ = '';
3450         local $, = '';
3451
3452         # Search through the debugger's magical hash of subs.
3453         # If $nocheck is true, just print the sub name.
3454         # Otherwise, check it against the pattern. We then use
3455         # the XOR trick to reverse the condition as required.
3456         foreach $subname ( sort( keys %sub ) ) {
3457             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3458                 print $OUT $subname, "\n";
3459             }
3460         }
3461         next CMD;
3462     }
3463
3464     return;
3465 }
3466
3467 sub _handle_V_command_and_X_command {
3468     my $self = shift;
3469
3470     $DB::cmd =~ s/^X\b/V $DB::package/;
3471
3472     # Bare V commands get the currently-being-debugged package
3473     # added.
3474     if ($self->_is_full('V')) {
3475         $DB::cmd = "V $DB::package";
3476     }
3477
3478     # V - show variables in package.
3479     if (my ($new_packname, $new_vars_str) =
3480         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3481
3482         # Save the currently selected filehandle and
3483         # force output to debugger's filehandle (dumpvar
3484         # just does "print" for output).
3485         my $savout = select($OUT);
3486
3487         # Grab package name and variables to dump.
3488         $packname = $new_packname;
3489         my @vars     = split( ' ', $new_vars_str );
3490
3491         # If main::dumpvar isn't here, get it.
3492         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3493         if ( defined &main::dumpvar ) {
3494
3495             # We got it. Turn off subroutine entry/exit messages
3496             # for the moment, along with return values.
3497             local $frame = 0;
3498             local $doret = -2;
3499
3500             # must detect sigpipe failures  - not catching
3501             # then will cause the debugger to die.
3502             eval {
3503                 main::dumpvar(
3504                     $packname,
3505                     defined $option{dumpDepth}
3506                     ? $option{dumpDepth}
3507                     : -1,    # assume -1 unless specified
3508                     @vars
3509                 );
3510             };
3511
3512             # The die doesn't need to include the $@, because
3513             # it will automatically get propagated for us.
3514             if ($@) {
3515                 die unless $@ =~ /dumpvar print failed/;
3516             }
3517         } ## end if (defined &main::dumpvar)
3518         else {
3519
3520             # Couldn't load dumpvar.
3521             print $OUT "dumpvar.pl not available.\n";
3522         }
3523
3524         # Restore the output filehandle, and go round again.
3525         select($savout);
3526         next CMD;
3527     }
3528
3529     return;
3530 }
3531
3532 sub _handle_dash_command {
3533     my $self = shift;
3534
3535     if ($self->_is_full('-')) {
3536
3537         # back up by a window; go to 1 if back too far.
3538         $start -= $incr + $window + 1;
3539         $start = 1 if $start <= 0;
3540         $incr  = $window - 1;
3541
3542         # Generate and execute a "l +" command (handled below).
3543         $DB::cmd = 'l ' . ($start) . '+';
3544         redo CMD;
3545     }
3546     return;
3547 }
3548
3549 sub _n_or_s_commands_generic {
3550     my ($self, $new_val) = @_;
3551     # n - next
3552     next CMD if DB::_DB__is_finished();
3553
3554     # Single step, but don't enter subs.
3555     $single = $new_val;
3556
3557     # Save for empty command (repeat last).
3558     $laststep = $DB::cmd;
3559     last CMD;
3560 }
3561
3562 sub _n_or_s {
3563     my ($self, $letter, $new_val) = @_;
3564
3565     if ($self->_is_full($letter)) {
3566         $self->_n_or_s_commands_generic($new_val);
3567     }
3568     else {
3569         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3570     }
3571
3572     return;
3573 }
3574
3575 sub _handle_n_command {
3576     my $self = shift;
3577
3578     return $self->_n_or_s('n', 2);
3579 }
3580
3581 sub _handle_s_command {
3582     my $self = shift;
3583
3584     return $self->_n_or_s('s', 1);
3585 }
3586
3587 sub _handle_r_command {
3588     my $self = shift;
3589
3590     # r - return from the current subroutine.
3591     if ($self->_is_full('r')) {
3592
3593         # Can't do anything if the program's over.
3594         next CMD if DB::_DB__is_finished();
3595
3596         # Turn on stack trace.
3597         $stack[$stack_depth] |= 1;
3598
3599         # Print return value unless the stack is empty.
3600         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3601         last CMD;
3602     }
3603
3604     return;
3605 }
3606
3607 sub _handle_T_command {
3608     my $self = shift;
3609
3610     if ($self->_is_full('T')) {
3611         DB::print_trace( $OUT, 1 );    # skip DB
3612         next CMD;
3613     }
3614
3615     return;
3616 }
3617
3618 sub _handle_w_command {
3619     my $self = shift;
3620
3621     DB::cmd_w( 'w', $self->cmd_args() );
3622     next CMD;
3623
3624     return;
3625 }
3626
3627 sub _handle_W_command {
3628     my $self = shift;
3629
3630     if (my $arg = $self->cmd_args) {
3631         DB::cmd_W( 'W', $arg );
3632         next CMD;
3633     }
3634
3635     return;
3636 }
3637
3638 sub _handle_rc_recall_command {
3639     my $self = shift;
3640
3641     # $rc - recall command.
3642     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3643
3644         # No arguments, take one thing off history.
3645         pop(@hist) if length($DB::cmd) > 1;
3646
3647         # Relative (- found)?
3648         #  Y - index back from most recent (by 1 if bare minus)
3649         #  N - go to that particular command slot or the last
3650         #      thing if nothing following.
3651
3652         $self->cmd_verb(
3653             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3654         );
3655
3656         # Pick out the command desired.
3657         $DB::cmd = $hist[$self->cmd_verb];
3658
3659         # Print the command to be executed and restart the loop
3660         # with that command in the buffer.
3661         print {$OUT} $DB::cmd, "\n";
3662         redo CMD;
3663     }
3664
3665     return;
3666 }
3667
3668 sub _handle_rc_search_history_command {
3669     my $self = shift;
3670
3671     # $rc pattern $rc - find a command in the history.
3672     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3673
3674         # Create the pattern to use.
3675         my $pat = "^$arg";
3676         $self->pat($pat);
3677
3678         # Toss off last entry if length is >1 (and it always is).
3679         pop(@hist) if length($DB::cmd) > 1;
3680
3681         my $i;
3682
3683         # Look backward through the history.
3684         SEARCH_HIST:
3685         for ( $i = $#hist ; $i ; --$i ) {
3686             # Stop if we find it.
3687             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3688         }
3689
3690         if ( !$i ) {
3691
3692             # Never found it.
3693             print $OUT "No such command!\n\n";
3694             next CMD;
3695         }
3696
3697         # Found it. Put it in the buffer, print it, and process it.
3698         $DB::cmd = $hist[$i];
3699         print $OUT $DB::cmd, "\n";
3700         redo CMD;
3701     }
3702
3703     return;
3704 }
3705
3706 sub _handle_H_command {
3707     my $self = shift;
3708
3709     if ($self->cmd_args =~ m#\A\*#) {
3710         @hist = @truehist = ();
3711         print $OUT "History cleansed\n";
3712         next CMD;
3713     }
3714
3715     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3716
3717         # Anything other than negative numbers is ignored by
3718         # the (incorrect) pattern, so this test does nothing.
3719         $end = $num ? ( $#hist - $num ) : 0;
3720
3721         # Set to the minimum if less than zero.
3722         $hist = 0 if $hist < 0;
3723
3724         # Start at the end of the array.
3725         # Stay in while we're still above the ending value.
3726         # Tick back by one each time around the loop.
3727         my $i;
3728
3729         for ( $i = $#hist ; $i > $end ; $i-- ) {
3730
3731             # Print the command  unless it has no arguments.
3732             print $OUT "$i: ", $hist[$i], "\n"
3733             unless $hist[$i] =~ /^.?$/;
3734         }
3735
3736         next CMD;
3737     }
3738
3739     return;
3740 }
3741
3742 sub _handle_doc_command {
3743     my $self = shift;
3744
3745     # man, perldoc, doc - show manual pages.
3746     if (my ($man_page)
3747         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3748         DB::runman($man_page);
3749         next CMD;
3750     }
3751
3752     return;
3753 }
3754
3755 sub _handle_p_command {
3756     my $self = shift;
3757
3758     my $print_cmd = 'print {$DB::OUT} ';
3759     # p - print (no args): print $_.
3760     if ($self->_is_full('p')) {
3761         $DB::cmd = $print_cmd . '$_';
3762     }
3763     else {
3764         # p - print the given expression.
3765         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3766     }
3767
3768     return;
3769 }
3770
3771 sub _handle_equal_sign_command {
3772     my $self = shift;
3773
3774     if ($DB::cmd =~ s/\A=\s*//) {
3775         my @keys;
3776         if ( length $DB::cmd == 0 ) {
3777
3778             # No args, get current aliases.
3779             @keys = sort keys %alias;
3780         }
3781         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3782
3783             # Creating a new alias. $k is alias name, $v is
3784             # alias value.
3785
3786             # can't use $_ or kill //g state
3787             for my $x ( $k, $v ) {
3788
3789                 # Escape "alarm" characters.
3790                 $x =~ s/\a/\\a/g;
3791             }
3792
3793             # Substitute key for value, using alarm chars
3794             # as separators (which is why we escaped them in
3795             # the command).
3796             $alias{$k} = "s\a$k\a$v\a";
3797
3798             # Turn off standard warn and die behavior.
3799             local $SIG{__DIE__};
3800             local $SIG{__WARN__};
3801
3802             # Is it valid Perl?
3803             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3804
3805                 # Nope. Bad alias. Say so and get out.
3806                 print $OUT "Can't alias $k to $v: $@\n";
3807                 delete $alias{$k};
3808                 next CMD;
3809             }
3810
3811             # We'll only list the new one.
3812             @keys = ($k);
3813         } ## end elsif (my ($k, $v) = ($DB::cmd...
3814
3815         # The argument is the alias to list.
3816         else {
3817             @keys = ($DB::cmd);
3818         }
3819
3820         # List aliases.
3821         for my $k (@keys) {
3822
3823             # Messy metaquoting: Trim the substitution code off.
3824             # We use control-G as the delimiter because it's not
3825             # likely to appear in the alias.
3826             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3827
3828                 # Print the alias.
3829                 print $OUT "$k\t= $1\n";
3830             }
3831             elsif ( defined $alias{$k} ) {
3832
3833                 # Couldn't trim it off; just print the alias code.
3834                 print $OUT "$k\t$alias{$k}\n";
3835             }
3836             else {
3837
3838                 # No such, dude.
3839                 print "No alias for $k\n";
3840             }
3841         } ## end for my $k (@keys)
3842         next CMD;
3843     }
3844
3845     return;
3846 }
3847
3848 sub _handle_source_command {
3849     my $self = shift;
3850
3851     # source - read commands from a file (or pipe!) and execute.
3852     if (my $sourced_fn = $self->cmd_args) {
3853         if ( open my $fh, $sourced_fn ) {
3854
3855             # Opened OK; stick it in the list of file handles.
3856             push @cmdfhs, $fh;
3857         }
3858         else {
3859
3860             # Couldn't open it.
3861             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3862         }
3863         next CMD;
3864     }
3865
3866     return;
3867 }
3868
3869 sub _handle_enable_disable_commands {
3870     my $self = shift;
3871
3872     my $which_cmd = $self->cmd_verb;
3873     my $position = $self->cmd_args;
3874
3875     if ($position !~ /\s/) {
3876         my ($fn, $line_num);
3877         if ($position =~ m{\A\d+\z})
3878         {
3879             $fn = $DB::filename;
3880             $line_num = $position;
3881         }
3882         elsif (my ($new_fn, $new_line_num)
3883             = $position =~ m{\A(.*):(\d+)\z}) {
3884             ($fn, $line_num) = ($new_fn, $new_line_num);
3885         }
3886         else
3887         {
3888             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3889         }
3890
3891         if (defined($fn)) {
3892             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3893                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3894                     ($which_cmd eq 'enable' ? 1 : '')
3895                 );
3896             }
3897             else {
3898                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3899             }
3900         }
3901
3902         next CMD;
3903     }
3904
3905     return;
3906 }
3907
3908 sub _handle_save_command {
3909     my $self = shift;
3910
3911     if (my $new_fn = $self->cmd_args) {
3912         my $filename = $new_fn || '.perl5dbrc';    # default?
3913         if ( open my $fh, '>', $filename ) {
3914
3915             # chomp to remove extraneous newlines from source'd files
3916             chomp( my @truelist =
3917                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3918                 @truehist );
3919             print {$fh} join( "\n", @truelist );
3920             print "commands saved in $filename\n";
3921         }
3922         else {
3923             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3924         }
3925         next CMD;
3926     }
3927
3928     return;
3929 }
3930
3931 sub _n_or_s_and_arg_commands_generic {
3932     my ($self, $letter, $new_val) = @_;
3933
3934     # s - single-step. Remember the last command was 's'.
3935     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3936         $laststep = $letter;
3937     }
3938
3939     return;
3940 }
3941
3942 sub _handle_sh_command {
3943     my $self = shift;
3944
3945     # $sh$sh - run a shell command (if it's all ASCII).
3946     # Can't run shell commands with Unicode in the debugger, hmm.
3947     my $my_cmd = $DB::cmd;
3948     if ($my_cmd =~ m#\A$sh#gms) {
3949
3950         if ($my_cmd =~ m#\G\z#cgms) {
3951             # Run the user's shell. If none defined, run Bourne.
3952             # We resume execution when the shell terminates.
3953             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3954             next CMD;
3955         }
3956         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3957             # System it.
3958             DB::_db_system($1);
3959             next CMD;
3960         }
3961         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3962             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3963             next CMD;
3964         }
3965     }
3966 }
3967
3968 sub _handle_x_command {
3969     my $self = shift;
3970
3971     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3972         $onetimeDump = 'dump';    # main::dumpvar shows the output
3973
3974         # handle special  "x 3 blah" syntax XXX propagate
3975         # doc back to special variables.
3976         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3977             $onetimedumpDepth = $1;
3978         }
3979     }
3980
3981     return;
3982 }
3983
3984 sub _handle_q_command {
3985     my $self = shift;
3986
3987     if ($self->_is_full('q')) {
3988         $fall_off_end = 1;
3989         DB::clean_ENV();
3990         exit $?;
3991     }
3992
3993     return;
3994 }
3995
3996 sub _handle_cmd_wrapper_commands {
3997     my $self = shift;
3998
3999     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
4000     next CMD;
4001 }
4002
4003 sub _handle_special_char_cmd_wrapper_commands {
4004     my $self = shift;
4005
4006     # All of these commands were remapped in perl 5.8.0;
4007     # we send them off to the secondary dispatcher (see below).
4008     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
4009         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
4010         next CMD;
4011     }
4012
4013     return;
4014 }
4015
4016 } ## end DB::Obj
4017
4018 package DB;
4019
4020 # The following code may be executed now:
4021 # BEGIN {warn 4}
4022
4023 =head2 sub
4024
4025 C<sub> is called whenever a subroutine call happens in the program being
4026 debugged. The variable C<$DB::sub> contains the name of the subroutine
4027 being called.
4028
4029 The core function of this subroutine is to actually call the sub in the proper
4030 context, capturing its output. This of course causes C<DB::DB> to get called
4031 again, repeating until the subroutine ends and returns control to C<DB::sub>
4032 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4033 return value, and returns its captured copy of the return value as its own
4034 return value. The value then feeds back into the program being debugged as if
4035 C<DB::sub> hadn't been there at all.
4036
4037 C<sub> does all the work of printing the subroutine entry and exit messages
4038 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4039 and also prints the return value if needed (for the C<r> command and if
4040 the 16 bit is set in C<$frame>).
4041
4042 It also tracks the subroutine call depth by saving the current setting of
4043 C<$single> in the C<@stack> package global; if this exceeds the value in
4044 C<$deep>, C<sub> automatically turns on printing of the current depth by
4045 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4046 of stop/don't stop on entry to subs set as it currently is set.
4047
4048 =head3 C<caller()> support
4049
4050 If C<caller()> is called from the package C<DB>, it provides some
4051 additional data, in the following order:
4052
4053 =over 4
4054
4055 =item * C<$package>
4056
4057 The package name the sub was in
4058
4059 =item * C<$filename>
4060
4061 The filename it was defined in
4062
4063 =item * C<$line>
4064
4065 The line number it was defined on
4066
4067 =item * C<$subroutine>
4068
4069 The subroutine name; C<(eval)> if an C<eval>().
4070
4071 =item * C<$hasargs>
4072
4073 1 if it has arguments, 0 if not
4074
4075 =item * C<$wantarray>
4076
4077 1 if array context, 0 if scalar context
4078
4079 =item * C<$evaltext>
4080
4081 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4082
4083 =item * C<$is_require>
4084
4085 frame was created by a C<use> or C<require> statement
4086
4087 =item * C<$hints>
4088
4089 pragma information; subject to change between versions
4090
4091 =item * C<$bitmask>
4092
4093 pragma information; subject to change between versions
4094
4095 =item * C<@DB::args>
4096
4097 arguments with which the subroutine was invoked
4098
4099 =back
4100
4101 =cut
4102
4103 use vars qw($deep);
4104
4105 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4106 # happy. -- Shlomi Fish
4107
4108 sub _indent_print_line_info {
4109     my ($offset, $str) = @_;
4110
4111     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4112
4113     return;
4114 }
4115
4116 sub _print_frame_message {
4117     my ($al) = @_;
4118
4119     if ($frame) {
4120         if ($frame & 4) {   # Extended frame entry message
4121             _indent_print_line_info(-1, "in  ");
4122
4123             # Why -1? But it works! :-(
4124             # Because print_trace will call add 1 to it and then call
4125             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4126             # in dump_trace.
4127             #
4128             # Now it's 0 because we extracted a function.
4129             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4130         }
4131         else {
4132             _indent_print_line_info(-1, "entering $sub$al\n" );
4133         }
4134     }
4135
4136     return;
4137 }
4138
4139 sub DB::sub {
4140     # lock ourselves under threads
4141     lock($DBGR);
4142
4143     # Whether or not the autoloader was running, a scalar to put the
4144     # sub's return value in (if needed), and an array to put the sub's
4145     # return value in (if needed).
4146     my ( $al, $ret, @ret ) = "";
4147     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4148         print "creating new thread\n";
4149     }
4150
4151     # If the last ten characters are '::AUTOLOAD', note we've traced
4152     # into AUTOLOAD for $sub.
4153     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4154         no strict 'refs';
4155         $al = " for $$sub" if defined $$sub;
4156     }
4157
4158     # We stack the stack pointer and then increment it to protect us
4159     # from a situation that might unwind a whole bunch of call frames
4160     # at once. Localizing the stack pointer means that it will automatically
4161     # unwind the same amount when multiple stack frames are unwound.
4162     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4163
4164     # Expand @stack.
4165     $#stack = $stack_depth;
4166
4167     # Save current single-step setting.
4168     $stack[-1] = $single;
4169
4170     # Turn off all flags except single-stepping.
4171     $single &= 1;
4172
4173     # If we've gotten really deeply recursed, turn on the flag that will
4174     # make us stop with the 'deep recursion' message.
4175     $single |= 4 if $stack_depth == $deep;
4176
4177     # If frame messages are on ...
4178
4179     _print_frame_message($al);
4180     # standard frame entry message
4181
4182     my $print_exit_msg = sub {
4183         # Check for exit trace messages...
4184         if ($frame & 2)
4185         {
4186             if ($frame & 4)    # Extended exit message
4187             {
4188                 _indent_print_line_info(0, "out ");
4189                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4190             }
4191             else
4192             {
4193                 _indent_print_line_info(0, "exited $sub$al\n" );
4194             }
4195         }
4196         return;
4197     };
4198
4199     # Determine the sub's return type, and capture appropriately.
4200     if (wantarray) {
4201
4202         # Called in array context. call sub and capture output.
4203         # DB::DB will recursively get control again if appropriate; we'll come
4204         # back here when the sub is finished.
4205         {
4206             no strict 'refs';
4207             @ret = &$sub;
4208         }
4209
4210         # Pop the single-step value back off the stack.
4211         $single |= $stack[ $stack_depth-- ];
4212
4213         $print_exit_msg->();
4214
4215         # Print the return info if we need to.
4216         if ( $doret eq $stack_depth or $frame & 16 ) {
4217
4218             # Turn off output record separator.
4219             local $\ = '';
4220             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4221
4222             # Indent if we're printing because of $frame tracing.
4223             if ($frame & 16)
4224             {
4225                 print {$fh} ' ' x $stack_depth;
4226             }
4227
4228             # Print the return value.
4229             print {$fh} "list context return from $sub:\n";
4230             dumpit( $fh, \@ret );
4231
4232             # And don't print it again.
4233             $doret = -2;
4234         } ## end if ($doret eq $stack_depth...
4235             # And we have to return the return value now.
4236         @ret;
4237     } ## end if (wantarray)
4238
4239     # Scalar context.
4240     else {
4241         if ( defined wantarray ) {
4242             no strict 'refs';
4243             # Save the value if it's wanted at all.
4244             $ret = &$sub;
4245         }
4246         else {
4247             no strict 'refs';
4248             # Void return, explicitly.
4249             &$sub;
4250             undef $ret;
4251         }
4252
4253         # Pop the single-step value off the stack.
4254         $single |= $stack[ $stack_depth-- ];
4255
4256         # If we're doing exit messages...
4257         $print_exit_msg->();
4258
4259         # If we are supposed to show the return value... same as before.
4260         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4261             local $\ = '';
4262             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4263             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4264             print $fh (
4265                 defined wantarray
4266                 ? "scalar context return from $sub: "
4267                 : "void context return from $sub\n"
4268             );
4269             dumpit( $fh, $ret ) if defined wantarray;
4270             $doret = -2;
4271         } ## end if ($doret eq $stack_depth...
4272
4273         # Return the appropriate scalar value.
4274         $ret;
4275     } ## end else [ if (wantarray)
4276 } ## end sub _sub
4277
4278 sub lsub : lvalue {
4279
4280     no strict 'refs';
4281
4282     # lock ourselves under threads
4283     lock($DBGR);
4284
4285     # Whether or not the autoloader was running, a scalar to put the
4286     # sub's return value in (if needed), and an array to put the sub's
4287     # return value in (if needed).
4288     my ( $al, $ret, @ret ) = "";
4289     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4290         print "creating new thread\n";
4291     }
4292
4293     # If the last ten characters are C'::AUTOLOAD', note we've traced
4294     # into AUTOLOAD for $sub.
4295     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4296         $al = " for $$sub";
4297     }
4298
4299     # We stack the stack pointer and then increment it to protect us
4300     # from a situation that might unwind a whole bunch of call frames
4301     # at once. Localizing the stack pointer means that it will automatically
4302     # unwind the same amount when multiple stack frames are unwound.
4303     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4304
4305     # Expand @stack.
4306     $#stack = $stack_depth;
4307
4308     # Save current single-step setting.
4309     $stack[-1] = $single;
4310
4311     # Turn off all flags except single-stepping.
4312     # Use local so the single-step value is popped back off the
4313     # stack for us.
4314     local $single = $single & 1;
4315
4316     # If we've gotten really deeply recursed, turn on the flag that will
4317     # make us stop with the 'deep recursion' message.
4318     $single |= 4 if $stack_depth == $deep;
4319
4320     # If frame messages are on ...
4321     _print_frame_message($al);
4322
4323     # call the original lvalue sub.
4324     &$sub;
4325 }
4326
4327 # Abstracting common code from multiple places elsewhere:
4328 sub depth_print_lineinfo {
4329     my $always_print = shift;
4330
4331     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4332 }
4333
4334 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4335
4336 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4337 Most of the changes were to systematize the command structure and to eliminate
4338 commands that threw away user input without checking.
4339
4340 The following sections describe the code added to make it easy to support
4341 multiple command sets with conflicting command names. This section is a start
4342 at unifying all command processing to make it simpler to develop commands.
4343
4344 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4345 number, and C<$dbline> (the current line) as arguments.
4346
4347 Support functions in this section which have multiple modes of failure C<die>
4348 on error; the rest simply return a false value.
4349
4350 The user-interface functions (all of the C<cmd_*> functions) just output
4351 error messages.
4352
4353 =head2 C<%set>
4354
4355 The C<%set> hash defines the mapping from command letter to subroutine
4356 name suffix.
4357
4358 C<%set> is a two-level hash, indexed by set name and then by command name.
4359 Note that trying to set the CommandSet to C<foobar> simply results in the
4360 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4361
4362 =cut
4363
4364 ### The API section
4365
4366 my %set = (    #
4367     'pre580' => {
4368         'a' => 'pre580_a',
4369         'A' => 'pre580_null',
4370         'b' => 'pre580_b',
4371         'B' => 'pre580_null',
4372         'd' => 'pre580_null',
4373         'D' => 'pre580_D',
4374         'h' => 'pre580_h',
4375         'M' => 'pre580_null',
4376         'O' => 'o',
4377         'o' => 'pre580_null',
4378         'v' => 'M',
4379         'w' => 'v',
4380         'W' => 'pre580_W',
4381     },
4382     'pre590' => {
4383         '<'  => 'pre590_prepost',
4384         '<<' => 'pre590_prepost',
4385         '>'  => 'pre590_prepost',
4386         '>>' => 'pre590_prepost',
4387         '{'  => 'pre590_prepost',
4388         '{{' => 'pre590_prepost',
4389     },
4390 );
4391
4392 my %breakpoints_data;
4393
4394 sub _has_breakpoint_data_ref {
4395     my ($filename, $line) = @_;
4396
4397     return (
4398         exists( $breakpoints_data{$filename} )
4399             and
4400         exists( $breakpoints_data{$filename}{$line} )
4401     );
4402 }
4403
4404 sub _get_breakpoint_data_ref {
4405     my ($filename, $line) = @_;
4406
4407     return ($breakpoints_data{$filename}{$line} ||= +{});
4408 }
4409
4410 sub _delete_breakpoint_data_ref {
4411     my ($filename, $line) = @_;
4412
4413     delete($breakpoints_data{$filename}{$line});
4414     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4415         delete($breakpoints_data{$filename});
4416     }
4417
4418     return;
4419 }
4420
4421 sub _set_breakpoint_enabled_status {
4422     my ($filename, $line, $status) = @_;
4423
4424     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4425         ($status ? 1 : '')
4426         ;
4427
4428     return;
4429 }
4430
4431 sub _enable_breakpoint_temp_enabled_status {
4432     my ($filename, $line) = @_;
4433
4434     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4435
4436     return;
4437 }
4438
4439 sub _cancel_breakpoint_temp_enabled_status {
4440     my ($filename, $line) = @_;
4441
4442     my $ref = _get_breakpoint_data_ref($filename, $line);
4443
4444     delete ($ref->{'temp_enabled'});
4445
4446     if (! %$ref) {
4447         _delete_breakpoint_data_ref($filename, $line);
4448     }
4449
4450     return;
4451 }
4452
4453 sub _is_breakpoint_enabled {
4454     my ($filename, $line) = @_;
4455
4456     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4457     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4458 }
4459
4460 =head2 C<cmd_wrapper()> (API)
4461
4462 C<cmd_wrapper()> allows the debugger to switch command sets
4463 depending on the value of the C<CommandSet> option.
4464
4465 It tries to look up the command in the C<%set> package-level I<lexical>
4466 (which means external entities can't fiddle with it) and create the name of
4467 the sub to call based on the value found in the hash (if it's there). I<All>
4468 of the commands to be handled in a set have to be added to C<%set>; if they
4469 aren't found, the 5.8.0 equivalent is called (if there is one).
4470
4471 This code uses symbolic references.
4472
4473 =cut
4474
4475 sub cmd_wrapper {
4476     my $cmd      = shift;
4477     my $line     = shift;
4478     my $dblineno = shift;
4479
4480     # Assemble the command subroutine's name by looking up the
4481     # command set and command name in %set. If we can't find it,
4482     # default to the older version of the command.
4483     my $call = 'cmd_'
4484       . ( $set{$CommandSet}{$cmd}
4485           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4486
4487     # Call the command subroutine, call it by name.
4488     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4489 } ## end sub cmd_wrapper
4490
4491 =head3 C<cmd_a> (command)
4492
4493 The C<a> command handles pre-execution actions. These are associated with a
4494 particular line, so they're stored in C<%dbline>. We default to the current
4495 line if none is specified.
4496
4497 =cut
4498
4499 sub cmd_a {
4500     my $cmd    = shift;
4501     my $line   = shift || '';    # [.|line] expr
4502     my $dbline = shift;
4503
4504     # If it's dot (here), or not all digits,  use the current line.
4505     $line =~ s/\A\./$dbline/;
4506
4507     # Should be a line number followed by an expression.
4508     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4509
4510         if (! length($lineno)) {
4511             $lineno = $dbline;
4512         }
4513
4514         # If we have an expression ...
4515         if ( length $expr ) {
4516
4517             # ... but the line isn't breakable, complain.
4518             if ( $dbline[$lineno] == 0 ) {
4519                 print $OUT
4520                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4521             }
4522             else {
4523
4524                 # It's executable. Record that the line has an action.
4525                 $had_breakpoints{$filename} |= 2;
4526
4527                 # Remove any action, temp breakpoint, etc.
4528                 $dbline{$lineno} =~ s/\0[^\0]*//;
4529
4530                 # Add the action to the line.
4531                 $dbline{$lineno} .= "\0" . action($expr);
4532
4533                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4534             }
4535         } ## end if (length $expr)
4536     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4537     else {
4538
4539         # Syntax wrong.
4540         print $OUT
4541           "Adding an action requires an optional lineno and an expression\n"
4542           ;    # hint
4543     }
4544 } ## end sub cmd_a
4545
4546 =head3 C<cmd_A> (command)
4547
4548 Delete actions. Similar to above, except the delete code is in a separate
4549 subroutine, C<delete_action>.
4550
4551 =cut
4552
4553 sub cmd_A {
4554     my $cmd    = shift;
4555     my $line   = shift || '';
4556     my $dbline = shift;
4557
4558     # Dot is this line.
4559     $line =~ s/^\./$dbline/;
4560
4561     # Call delete_action with a null param to delete them all.
4562     # The '1' forces the eval to be true. It'll be false only
4563     # if delete_action blows up for some reason, in which case
4564     # we print $@ and get out.
4565     if ( $line eq '*' ) {
4566         if (! eval { _delete_all_actions(); 1 }) {
4567             print {$OUT} $@;
4568             return;
4569         }
4570     }
4571
4572     # There's a real line  number. Pass it to delete_action.
4573     # Error trapping is as above.
4574     elsif ( $line =~ /^(\S.*)/ ) {
4575         if (! eval { delete_action($1); 1 }) {
4576             print {$OUT} $@;
4577             return;
4578         }
4579     }
4580
4581     # Swing and a miss. Bad syntax.
4582     else {
4583         print $OUT
4584           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4585     }
4586 } ## end sub cmd_A
4587
4588 =head3 C<delete_action> (API)
4589
4590 C<delete_action> accepts either a line number or C<undef>. If a line number
4591 is specified, we check for the line being executable (if it's not, it
4592 couldn't have had an  action). If it is, we just take the action off (this
4593 will get any kind of an action, including breakpoints).
4594
4595 =cut
4596
4597 sub _remove_action_from_dbline {
4598     my $i = shift;
4599
4600     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4601     delete $dbline{$i} if $dbline{$i} eq '';
4602
4603     return;
4604 }
4605
4606 sub _delete_all_actions {
4607     print {$OUT} "Deleting all actions...\n";
4608
4609     for my $file ( keys %had_breakpoints ) {
4610         local *dbline = $main::{ '_<' . $file };
4611         $max = $#dbline;
4612         my $was;
4613         for my $i (1 .. $max) {
4614             if ( defined $dbline{$i} ) {
4615                 _remove_action_from_dbline($i);
4616             }
4617         }
4618
4619         unless ( $had_breakpoints{$file} &= ~2 ) {
4620             delete $had_breakpoints{$file};
4621         }
4622     }
4623
4624     return;
4625 }
4626
4627 sub delete_action {
4628     my $i = shift;
4629
4630     if ( defined($i) ) {
4631         # Can there be one?
4632         die "Line $i has no action .\n" if $dbline[$i] == 0;
4633
4634         # Nuke whatever's there.
4635         _remove_action_from_dbline($i);
4636     }
4637     else {
4638         _delete_all_actions();
4639     }
4640 }
4641
4642 =head3 C<cmd_b> (command)
4643
4644 Set breakpoints. Since breakpoints can be set in so many places, in so many
4645 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4646 we try to parse the command type, and then shuttle it off to an appropriate
4647 subroutine to actually do the work of setting the breakpoint in the right
4648 place.
4649
4650 =cut
4651
4652 sub cmd_b {
4653     my $cmd    = shift;
4654     my $line   = shift;    # [.|line] [cond]
4655     my $dbline = shift;
4656
4657     my $default_cond = sub {
4658         my $cond = shift;
4659         return length($cond) ? $cond : '1';
4660     };
4661
4662     # Make . the current line number if it's there..
4663     $line =~ s/^\.(\s|\z)/$dbline$1/;
4664
4665     # No line number, no condition. Simple break on current line.
4666     if ( $line =~ /^\s*$/ ) {
4667         cmd_b_line( $dbline, 1 );
4668     }
4669
4670     # Break on load for a file.
4671     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4672         $file =~ s/\s+\z//;
4673         cmd_b_load($file);
4674     }
4675
4676     # b compile|postpone <some sub> [<condition>]
4677     # The interpreter actually traps this one for us; we just put the
4678     # necessary condition in the %postponed hash.
4679     elsif ( my ($action, $subname, $cond)
4680         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4681
4682         # De-Perl4-ify the name - ' separators to ::.
4683         $subname =~ s/'/::/g;
4684
4685         # Qualify it into the current package unless it's already qualified.
4686         $subname = "${package}::" . $subname unless $subname =~ /::/;
4687
4688         # Add main if it starts with ::.
4689         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4690
4691         # Save the break type for this sub.
4692         $postponed{$subname} = (($action eq 'postpone')
4693             ? ( "break +0 if " . $default_cond->($cond) )
4694             : "compile");
4695     } ## end elsif ($line =~ ...
4696     # b <filename>:<line> [<condition>]
4697     elsif (my ($filename, $line_num, $cond)
4698         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4699         cmd_b_filename_line(
4700             $filename,
4701             $line_num,
4702             (length($cond) ? $cond : '1'),
4703         );
4704     }
4705     # b <sub name> [<condition>]
4706     elsif ( my ($new_subname, $new_cond) =
4707         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4708
4709         #
4710         $subname = $new_subname;
4711         cmd_b_sub( $subname, $default_cond->($new_cond) );
4712     }
4713
4714     # b <line> [<condition>].
4715     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4716
4717         # Capture the line. If none, it's the current line.
4718         $line = $line_n || $dbline;
4719
4720         # Break on line.
4721         cmd_b_line( $line, $default_cond->($cond) );
4722     }
4723
4724     # Line didn't make sense.
4725     else {
4726         print "confused by line($line)?\n";
4727     }
4728
4729     return;
4730 } ## end sub cmd_b
4731
4732 =head3 C<break_on_load> (API)
4733
4734 We want to break when this file is loaded. Mark this file in the
4735 C<%break_on_load> hash, and note that it has a breakpoint in
4736 C<%had_breakpoints>.
4737
4738 =cut
4739
4740 sub break_on_load {
4741     my $file = shift;
4742     $break_on_load{$file} = 1;
4743     $had_breakpoints{$file} |= 1;
4744 }
4745
4746 =head3 C<report_break_on_load> (API)
4747
4748 Gives us an array of filenames that are set to break on load. Note that
4749 only files with break-on-load are in here, so simply showing the keys
4750 suffices.
4751
4752 =cut
4753
4754 sub report_break_on_load {
4755     sort keys %break_on_load;
4756 }
4757
4758 =head3 C<cmd_b_load> (command)
4759
4760 We take the file passed in and try to find it in C<%INC> (which maps modules
4761 to files they came from). We mark those files for break-on-load via
4762 C<break_on_load> and then report that it was done.
4763
4764 =cut
4765
4766 sub cmd_b_load {
4767     my $file = shift;
4768     my @files;
4769
4770     # This is a block because that way we can use a redo inside it
4771     # even without there being any looping structure at all outside it.
4772     {
4773
4774         # Save short name and full path if found.
4775         push @files, $file;
4776         push @files, $::INC{$file} if $::INC{$file};
4777
4778         # Tack on .pm and do it again unless there was a '.' in the name
4779         # already.
4780         $file .= '.pm', redo unless $file =~ /\./;
4781     }
4782
4783     # Do the real work here.
4784     break_on_load($_) for @files;
4785
4786     # All the files that have break-on-load breakpoints.
4787     @files = report_break_on_load;
4788
4789     # Normalize for the purposes of our printing this.
4790     local $\ = '';
4791     local $" = ' ';
4792     print $OUT "Will stop on load of '@files'.\n";
4793 } ## end sub cmd_b_load
4794
4795 =head3 C<$filename_error> (API package global)
4796
4797 Several of the functions we need to implement in the API need to work both
4798 on the current file and on other files. We don't want to duplicate code, so
4799 C<$filename_error> is used to contain the name of the file that's being
4800 worked on (if it's not the current one).
4801
4802 We can now build functions in pairs: the basic function works on the current
4803 file, and uses C<$filename_error> as part of its error message. Since this is
4804 initialized to C<"">, no filename will appear when we are working on the
4805 current file.
4806
4807 The second function is a wrapper which does the following:
4808
4809 =over 4
4810
4811 =item *
4812
4813 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4814
4815 =item *
4816
4817 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4818
4819 =item *
4820
4821 Calls the first function.
4822
4823 The first function works on the I<current> file (i.e., the one we changed to),
4824 and prints C<$filename_error> in the error message (the name of the other file)
4825 if it needs to. When the functions return, C<*dbline> is restored to point
4826 to the actual current file (the one we're executing in) and
4827 C<$filename_error> is restored to C<"">. This restores everything to
4828 the way it was before the second function was called at all.
4829
4830 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4831 details.
4832
4833 =back
4834
4835 =cut
4836
4837 use vars qw($filename_error);
4838 $filename_error = '';
4839
4840 =head3 breakable_line(from, to) (API)
4841
4842 The subroutine decides whether or not a line in the current file is breakable.
4843 It walks through C<@dbline> within the range of lines specified, looking for
4844 the first line that is breakable.
4845
4846 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4847 first line I<after> C<$to> that's breakable, if there is one.
4848
4849 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4850 first line I<before> C<$to> that's breakable, if there is one.
4851
4852 =cut
4853