This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
99291d49d21e5a9998f80d1fc57f3c041d6104a5
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;        # Prints 7.
41     print(1+2) + 4;     # Prints 3.
42     print (1+2)+4;      # Also prints 3!
43     print +(1+2)+4;     # Prints 7.
44     print ((1+2)+4);    # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 =head2 Perl Functions by Category
90 X<function>
91
92 Here are Perl's functions (including things that look like
93 functions, like some keywords and named operators)
94 arranged by category.  Some functions appear in more
95 than one place.
96
97 =over 4
98
99 =item Functions for SCALARs or strings
100 X<scalar> X<string> X<character>
101
102 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
103 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
104 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
105
106 =item Regular expressions and pattern matching
107 X<regular expression> X<regex> X<regexp>
108
109 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
110
111 =item Numeric functions
112 X<numeric> X<number> X<trigonometric> X<trigonometry>
113
114 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
115 C<sin>, C<sqrt>, C<srand>
116
117 =item Functions for real @ARRAYs
118 X<array>
119
120 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
121
122 =item Functions for list data
123 X<list>
124
125 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
126
127 =item Functions for real %HASHes
128 X<hash>
129
130 C<delete>, C<each>, C<exists>, C<keys>, C<values>
131
132 =item Input and output functions
133 X<I/O> X<input> X<output> X<dbm>
134
135 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
136 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
137 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
138 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
139 C<warn>, C<write>
140
141 =item Functions for fixed length data or records
142
143 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
144
145 =item Functions for filehandles, files, or directories
146 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
147
148 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
149 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
150 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
151 C<umask>, C<unlink>, C<utime>
152
153 =item Keywords related to the control flow of your Perl program
154 X<control flow>
155
156 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
157 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
158
159 =item Keywords related to switch
160
161 C<break>, C<continue>
162
163 (These are only available if you enable the "switch" feature.
164 See L<feature> and L<perlsyn/"Switch statements">.)
165
166 =item Keywords related to scoping
167
168 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
169
170 =item Miscellaneous functions
171
172 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
173 C<scalar>, C<undef>, C<wantarray>
174
175 =item Functions for processes and process groups
176 X<process> X<pid> X<process id>
177
178 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
179 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
180 C<times>, C<wait>, C<waitpid>
181
182 =item Keywords related to perl modules
183 X<module>
184
185 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
186
187 =item Keywords related to classes and object-orientedness
188 X<object> X<class> X<package>
189
190 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
191 C<untie>, C<use>
192
193 =item Low-level socket functions
194 X<socket> X<sock>
195
196 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
197 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
198 C<socket>, C<socketpair>
199
200 =item System V interprocess communication functions
201 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
202
203 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
204 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
205
206 =item Fetching user and group info
207 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
208
209 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
210 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
211 C<getpwuid>, C<setgrent>, C<setpwent>
212
213 =item Fetching network info
214 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
215
216 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
217 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
218 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
219 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
220 C<setnetent>, C<setprotoent>, C<setservent>
221
222 =item Time-related functions
223 X<time> X<date>
224
225 C<gmtime>, C<localtime>, C<time>, C<times>
226
227 =item Functions new in perl5
228 X<perl5>
229
230 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
231 C<import>, C<lc>, C<lcfirst>, C<lock>, C<map>, C<my>, C<no>, C<our>,
232 C<prototype>, C<qr>, C<qw>, C<qx>, C<readline>, C<readpipe>, C<ref>,
233 C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
234
235 * - C<sub> was a keyword in perl4, but in perl5 it is an
236 operator, which can be used in expressions.
237
238 =item Functions obsoleted in perl5
239
240 C<dbmclose>, C<dbmopen>
241
242 =back
243
244 =head2 Portability
245 X<portability> X<Unix> X<portable>
246
247 Perl was born in Unix and can therefore access all common Unix
248 system calls.  In non-Unix environments, the functionality of some
249 Unix system calls may not be available, or details of the available
250 functionality may differ slightly.  The Perl functions affected
251 by this are:
252
253 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
254 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
255 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
256 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
257 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
258 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
259 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
260 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
261 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
262 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
263 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
264 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
265 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
266 C<shmwrite>, C<socket>, C<socketpair>,
267 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
268 C<times>, C<truncate>, C<umask>, C<unlink>,
269 C<utime>, C<wait>, C<waitpid>
270
271 For more information about the portability of these functions, see
272 L<perlport> and other available platform-specific documentation.
273
274 =head2 Alphabetical Listing of Perl Functions
275
276 =over 8
277
278 =item -X FILEHANDLE
279 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
280 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
281
282 =item -X EXPR
283
284 =item -X
285
286 A file test, where X is one of the letters listed below.  This unary
287 operator takes one argument, either a filename or a filehandle, and
288 tests the associated file to see if something is true about it.  If the
289 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
290 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
291 the undefined value if the file doesn't exist.  Despite the funny
292 names, precedence is the same as any other named unary operator, and
293 the argument may be parenthesized like any other unary operator.  The
294 operator may be any of:
295
296     -r  File is readable by effective uid/gid.
297     -w  File is writable by effective uid/gid.
298     -x  File is executable by effective uid/gid.
299     -o  File is owned by effective uid.
300
301     -R  File is readable by real uid/gid.
302     -W  File is writable by real uid/gid.
303     -X  File is executable by real uid/gid.
304     -O  File is owned by real uid.
305
306     -e  File exists.
307     -z  File has zero size (is empty).
308     -s  File has nonzero size (returns size in bytes).
309
310     -f  File is a plain file.
311     -d  File is a directory.
312     -l  File is a symbolic link.
313     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
314     -S  File is a socket.
315     -b  File is a block special file.
316     -c  File is a character special file.
317     -t  Filehandle is opened to a tty.
318
319     -u  File has setuid bit set.
320     -g  File has setgid bit set.
321     -k  File has sticky bit set.
322
323     -T  File is an ASCII text file (heuristic guess).
324     -B  File is a "binary" file (opposite of -T).
325
326     -M  Script start time minus file modification time, in days.
327     -A  Same for access time.
328     -C  Same for inode change time (Unix, may differ for other platforms)
329
330 Example:
331
332     while (<>) {
333         chomp;
334         next unless -f $_;      # ignore specials
335         #...
336     }
337
338 The interpretation of the file permission operators C<-r>, C<-R>,
339 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
340 of the file and the uids and gids of the user.  There may be other
341 reasons you can't actually read, write, or execute the file.  Such
342 reasons may be for example network filesystem access controls, ACLs
343 (access control lists), read-only filesystems, and unrecognized
344 executable formats.
345
346 Also note that, for the superuser on the local filesystems, the C<-r>,
347 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
348 if any execute bit is set in the mode.  Scripts run by the superuser
349 may thus need to do a stat() to determine the actual mode of the file,
350 or temporarily set their effective uid to something else.
351
352 If you are using ACLs, there is a pragma called C<filetest> that may
353 produce more accurate results than the bare stat() mode bits.
354 When under the C<use filetest 'access'> the above-mentioned filetests
355 will test whether the permission can (not) be granted using the
356 access() family of system calls.  Also note that the C<-x> and C<-X> may
357 under this pragma return true even if there are no execute permission
358 bits set (nor any extra execute permission ACLs).  This strangeness is
359 due to the underlying system calls' definitions.  Read the
360 documentation for the C<filetest> pragma for more information.
361
362 Note that C<-s/a/b/> does not do a negated substitution.  Saying
363 C<-exp($foo)> still works as expected, however--only single letters
364 following a minus are interpreted as file tests.
365
366 The C<-T> and C<-B> switches work as follows.  The first block or so of the
367 file is examined for odd characters such as strange control codes or
368 characters with the high bit set.  If too many strange characters (>30%)
369 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
370 containing null in the first block is considered a binary file.  If C<-T>
371 or C<-B> is used on a filehandle, the current IO buffer is examined
372 rather than the first block.  Both C<-T> and C<-B> return true on a null
373 file, or a file at EOF when testing a filehandle.  Because you have to
374 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
375 against the file first, as in C<next unless -f $file && -T $file>.
376
377 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
378 the special filehandle consisting of a solitary underline, then the stat
379 structure of the previous file test (or stat operator) is used, saving
380 a system call.  (This doesn't work with C<-t>, and you need to remember
381 that lstat() and C<-l> will leave values in the stat structure for the
382 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
383 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
384 Example:
385
386     print "Can do.\n" if -r $a || -w _ || -x _;
387
388     stat($filename);
389     print "Readable\n" if -r _;
390     print "Writable\n" if -w _;
391     print "Executable\n" if -x _;
392     print "Setuid\n" if -u _;
393     print "Setgid\n" if -g _;
394     print "Sticky\n" if -k _;
395     print "Text\n" if -T _;
396     print "Binary\n" if -B _;
397
398 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
399 test operators, in a way that C<-f -w -x $file> is equivalent to
400 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
401 the return value of C<-f $file> as an argument to another filetest
402 operator, no special magic will happen.)
403
404 =item abs VALUE
405 X<abs> X<absolute>
406
407 =item abs
408
409 Returns the absolute value of its argument.
410 If VALUE is omitted, uses C<$_>.
411
412 =item accept NEWSOCKET,GENERICSOCKET
413 X<accept>
414
415 Accepts an incoming socket connect, just as the accept(2) system call
416 does.  Returns the packed address if it succeeded, false otherwise.
417 See the example in L<perlipc/"Sockets: Client/Server Communication">.
418
419 On systems that support a close-on-exec flag on files, the flag will
420 be set for the newly opened file descriptor, as determined by the
421 value of $^F.  See L<perlvar/$^F>.
422
423 =item alarm SECONDS
424 X<alarm>
425 X<SIGALRM>
426 X<timer>
427
428 =item alarm
429
430 Arranges to have a SIGALRM delivered to this process after the
431 specified number of wallclock seconds has elapsed.  If SECONDS is not
432 specified, the value stored in C<$_> is used. (On some machines,
433 unfortunately, the elapsed time may be up to one second less or more
434 than you specified because of how seconds are counted, and process
435 scheduling may delay the delivery of the signal even further.)
436
437 Only one timer may be counting at once.  Each call disables the
438 previous timer, and an argument of C<0> may be supplied to cancel the
439 previous timer without starting a new one.  The returned value is the
440 amount of time remaining on the previous timer.
441
442 For delays of finer granularity than one second, you may use Perl's
443 four-argument version of select() leaving the first three arguments
444 undefined, or you might be able to use the C<syscall> interface to
445 access setitimer(2) if your system supports it.  The Time::HiRes
446 module (from CPAN, and starting from Perl 5.8 part of the standard
447 distribution) may also prove useful.
448
449 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
450 (C<sleep> may be internally implemented in your system with C<alarm>)
451
452 If you want to use C<alarm> to time out a system call you need to use an
453 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
454 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
455 restart system calls on some systems.  Using C<eval>/C<die> always works,
456 modulo the caveats given in L<perlipc/"Signals">.
457
458     eval {
459         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
460         alarm $timeout;
461         $nread = sysread SOCKET, $buffer, $size;
462         alarm 0;
463     };
464     if ($@) {
465         die unless $@ eq "alarm\n";   # propagate unexpected errors
466         # timed out
467     }
468     else {
469         # didn't
470     }
471
472 For more information see L<perlipc>.
473
474 =item atan2 Y,X
475 X<atan2> X<arctangent> X<tan> X<tangent>
476
477 Returns the arctangent of Y/X in the range -PI to PI.
478
479 For the tangent operation, you may use the C<Math::Trig::tan>
480 function, or use the familiar relation:
481
482     sub tan { sin($_[0]) / cos($_[0])  }
483
484 Note that atan2(0, 0) is not well-defined.
485
486 =item bind SOCKET,NAME
487 X<bind>
488
489 Binds a network address to a socket, just as the bind system call
490 does.  Returns true if it succeeded, false otherwise.  NAME should be a
491 packed address of the appropriate type for the socket.  See the examples in
492 L<perlipc/"Sockets: Client/Server Communication">.
493
494 =item binmode FILEHANDLE, LAYER
495 X<binmode> X<binary> X<text> X<DOS> X<Windows>
496
497 =item binmode FILEHANDLE
498
499 Arranges for FILEHANDLE to be read or written in "binary" or "text"
500 mode on systems where the run-time libraries distinguish between
501 binary and text files.  If FILEHANDLE is an expression, the value is
502 taken as the name of the filehandle.  Returns true on success,
503 otherwise it returns C<undef> and sets C<$!> (errno).
504
505 On some systems (in general, DOS and Windows-based systems) binmode()
506 is necessary when you're not working with a text file.  For the sake
507 of portability it is a good idea to always use it when appropriate,
508 and to never use it when it isn't appropriate.  Also, people can
509 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
510
511 In other words: regardless of platform, use binmode() on binary data,
512 like for example images.
513
514 If LAYER is present it is a single string, but may contain multiple
515 directives. The directives alter the behaviour of the file handle.
516 When LAYER is present using binmode on text file makes sense.
517
518 If LAYER is omitted or specified as C<:raw> the filehandle is made
519 suitable for passing binary data. This includes turning off possible CRLF
520 translation and marking it as bytes (as opposed to Unicode characters).
521 Note that, despite what may be implied in I<"Programming Perl"> (the
522 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
523 -- other layers which would affect binary nature of the stream are
524 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
525 PERLIO environment variable.
526
527 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
528 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
529 establish default I/O layers.  See L<open>.
530
531 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
532 in "Programming Perl, 3rd Edition".  However, since the publishing of this
533 book, by many known as "Camel III", the consensus of the naming of this
534 functionality has moved from "discipline" to "layer".  All documentation
535 of this version of Perl therefore refers to "layers" rather than to
536 "disciplines".  Now back to the regularly scheduled documentation...>
537
538 To mark FILEHANDLE as UTF-8, use C<:utf8>.
539
540 In general, binmode() should be called after open() but before any I/O
541 is done on the filehandle.  Calling binmode() will normally flush any
542 pending buffered output data (and perhaps pending input data) on the
543 handle.  An exception to this is the C<:encoding> layer that
544 changes the default character encoding of the handle, see L<open>.
545 The C<:encoding> layer sometimes needs to be called in
546 mid-stream, and it doesn't flush the stream.  The C<:encoding>
547 also implicitly pushes on top of itself the C<:utf8> layer because
548 internally Perl will operate on UTF-8 encoded Unicode characters.
549
550 The operating system, device drivers, C libraries, and Perl run-time
551 system all work together to let the programmer treat a single
552 character (C<\n>) as the line terminator, irrespective of the external
553 representation.  On many operating systems, the native text file
554 representation matches the internal representation, but on some
555 platforms the external representation of C<\n> is made up of more than
556 one character.
557
558 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
559 character to end each line in the external representation of text (even
560 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
561 on Unix and most VMS files). In other systems like OS/2, DOS and the
562 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
563 but what's stored in text files are the two characters C<\cM\cJ>.  That
564 means that, if you don't use binmode() on these systems, C<\cM\cJ>
565 sequences on disk will be converted to C<\n> on input, and any C<\n> in
566 your program will be converted back to C<\cM\cJ> on output.  This is what
567 you want for text files, but it can be disastrous for binary files.
568
569 Another consequence of using binmode() (on some systems) is that
570 special end-of-file markers will be seen as part of the data stream.
571 For systems from the Microsoft family this means that if your binary
572 data contains C<\cZ>, the I/O subsystem will regard it as the end of
573 the file, unless you use binmode().
574
575 binmode() is not only important for readline() and print() operations,
576 but also when using read(), seek(), sysread(), syswrite() and tell()
577 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
578 in L<perlvar> for how to manually set your input and output
579 line-termination sequences.
580
581 =item bless REF,CLASSNAME
582 X<bless>
583
584 =item bless REF
585
586 This function tells the thingy referenced by REF that it is now an object
587 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
588 is used.  Because a C<bless> is often the last thing in a constructor,
589 it returns the reference for convenience.  Always use the two-argument
590 version if a derived class might inherit the function doing the blessing.
591 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
592 of objects.
593
594 Consider always blessing objects in CLASSNAMEs that are mixed case.
595 Namespaces with all lowercase names are considered reserved for
596 Perl pragmata.  Builtin types have all uppercase names. To prevent
597 confusion, you may wish to avoid such package names as well.  Make sure
598 that CLASSNAME is a true value.
599
600 See L<perlmod/"Perl Modules">.
601
602 =item break
603
604 Break out of a C<given()> block.
605
606 This keyword is enabled by the "switch" feature: see L<feature>
607 for more information.
608
609 =item caller EXPR
610 X<caller> X<call stack> X<stack> X<stack trace>
611
612 =item caller
613
614 Returns the context of the current subroutine call.  In scalar context,
615 returns the caller's package name if there is a caller, that is, if
616 we're in a subroutine or C<eval> or C<require>, and the undefined value
617 otherwise.  In list context, returns
618
619     ($package, $filename, $line) = caller;
620
621 With EXPR, it returns some extra information that the debugger uses to
622 print a stack trace.  The value of EXPR indicates how many call frames
623 to go back before the current one.
624
625     ($package, $filename, $line, $subroutine, $hasargs,
626     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
627          = caller($i);
628
629 Here $subroutine may be C<(eval)> if the frame is not a subroutine
630 call, but an C<eval>.  In such a case additional elements $evaltext and
631 C<$is_require> are set: C<$is_require> is true if the frame is created by a
632 C<require> or C<use> statement, $evaltext contains the text of the
633 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
634 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
635 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
636 frame.)  $subroutine may also be C<(unknown)> if this particular
637 subroutine happens to have been deleted from the symbol table.
638 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
639 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
640 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
641 between versions of Perl, and are not meant for external use.
642
643 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
644 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
645 of this hash, as they are the actual values stored in the optree.
646
647 Furthermore, when called from within the DB package, caller returns more
648 detailed information: it sets the list variable C<@DB::args> to be the
649 arguments with which the subroutine was invoked.
650
651 Be aware that the optimizer might have optimized call frames away before
652 C<caller> had a chance to get the information.  That means that C<caller(N)>
653 might not return information about the call frame you expect it do, for
654 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
655 previous time C<caller> was called.
656
657 =item chdir EXPR
658 X<chdir>
659 X<cd>
660
661 =item chdir FILEHANDLE
662
663 =item chdir DIRHANDLE
664
665 =item chdir
666
667 Changes the working directory to EXPR, if possible. If EXPR is omitted,
668 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
669 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
670 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
671 neither is set, C<chdir> does nothing. It returns true upon success,
672 false otherwise. See the example under C<die>.
673
674 On systems that support fchdir, you might pass a file handle or
675 directory handle as argument.  On systems that don't support fchdir,
676 passing handles produces a fatal error at run time.
677
678 =item chmod LIST
679 X<chmod> X<permission> X<mode>
680
681 Changes the permissions of a list of files.  The first element of the
682 list must be the numerical mode, which should probably be an octal
683 number, and which definitely should I<not> be a string of octal digits:
684 C<0644> is okay, C<'0644'> is not.  Returns the number of files
685 successfully changed.  See also L</oct>, if all you have is a string.
686
687     $cnt = chmod 0755, 'foo', 'bar';
688     chmod 0755, @executables;
689     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
690                                              # --w----r-T
691     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
692     $mode = 0644;   chmod $mode, 'foo';      # this is best
693
694 On systems that support fchmod, you might pass file handles among the
695 files.  On systems that don't support fchmod, passing file handles
696 produces a fatal error at run time.   The file handles must be passed
697 as globs or references to be recognized.  Barewords are considered
698 file names.
699
700     open(my $fh, "<", "foo");
701     my $perm = (stat $fh)[2] & 07777;
702     chmod($perm | 0600, $fh);
703
704 You can also import the symbolic C<S_I*> constants from the Fcntl
705 module:
706
707     use Fcntl ':mode';
708
709     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
710     # This is identical to the chmod 0755 of the above example.
711
712 =item chomp VARIABLE
713 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
714
715 =item chomp( LIST )
716
717 =item chomp
718
719 This safer version of L</chop> removes any trailing string
720 that corresponds to the current value of C<$/> (also known as
721 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
722 number of characters removed from all its arguments.  It's often used to
723 remove the newline from the end of an input record when you're worried
724 that the final record may be missing its newline.  When in paragraph
725 mode (C<$/ = "">), it removes all trailing newlines from the string.
726 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
727 a reference to an integer or the like, see L<perlvar>) chomp() won't
728 remove anything.
729 If VARIABLE is omitted, it chomps C<$_>.  Example:
730
731     while (<>) {
732         chomp;  # avoid \n on last field
733         @array = split(/:/);
734         # ...
735     }
736
737 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
738
739 You can actually chomp anything that's an lvalue, including an assignment:
740
741     chomp($cwd = `pwd`);
742     chomp($answer = <STDIN>);
743
744 If you chomp a list, each element is chomped, and the total number of
745 characters removed is returned.
746
747 If the C<encoding> pragma is in scope then the lengths returned are
748 calculated from the length of C<$/> in Unicode characters, which is not
749 always the same as the length of C<$/> in the native encoding.
750
751 Note that parentheses are necessary when you're chomping anything
752 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
753 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
754 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
755 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
756 as C<chomp($a, $b)>.
757
758 =item chop VARIABLE
759 X<chop>
760
761 =item chop( LIST )
762
763 =item chop
764
765 Chops off the last character of a string and returns the character
766 chopped.  It is much more efficient than C<s/.$//s> because it neither
767 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
768 If VARIABLE is a hash, it chops the hash's values, but not its keys.
769
770 You can actually chop anything that's an lvalue, including an assignment.
771
772 If you chop a list, each element is chopped.  Only the value of the
773 last C<chop> is returned.
774
775 Note that C<chop> returns the last character.  To return all but the last
776 character, use C<substr($string, 0, -1)>.
777
778 See also L</chomp>.
779
780 =item chown LIST
781 X<chown> X<owner> X<user> X<group>
782
783 Changes the owner (and group) of a list of files.  The first two
784 elements of the list must be the I<numeric> uid and gid, in that
785 order.  A value of -1 in either position is interpreted by most
786 systems to leave that value unchanged.  Returns the number of files
787 successfully changed.
788
789     $cnt = chown $uid, $gid, 'foo', 'bar';
790     chown $uid, $gid, @filenames;
791
792 On systems that support fchown, you might pass file handles among the
793 files.  On systems that don't support fchown, passing file handles
794 produces a fatal error at run time.  The file handles must be passed
795 as globs or references to be recognized.  Barewords are considered
796 file names.
797
798 Here's an example that looks up nonnumeric uids in the passwd file:
799
800     print "User: ";
801     chomp($user = <STDIN>);
802     print "Files: ";
803     chomp($pattern = <STDIN>);
804
805     ($login,$pass,$uid,$gid) = getpwnam($user)
806         or die "$user not in passwd file";
807
808     @ary = glob($pattern);      # expand filenames
809     chown $uid, $gid, @ary;
810
811 On most systems, you are not allowed to change the ownership of the
812 file unless you're the superuser, although you should be able to change
813 the group to any of your secondary groups.  On insecure systems, these
814 restrictions may be relaxed, but this is not a portable assumption.
815 On POSIX systems, you can detect this condition this way:
816
817     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
818     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
819
820 =item chr NUMBER
821 X<chr> X<character> X<ASCII> X<Unicode>
822
823 =item chr
824
825 Returns the character represented by that NUMBER in the character set.
826 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
827 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
828 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
829 backward compatibility reasons (but see L<encoding>).
830
831 Negative values give the Unicode replacement character (chr(0xfffd)),
832 except under the L<bytes> pragma, where low eight bits of the value
833 (truncated to an integer) are used.
834
835 If NUMBER is omitted, uses C<$_>.
836
837 For the reverse, use L</ord>.
838
839 Note that under the C<bytes> pragma the NUMBER is masked to
840 the low eight bits.
841
842 See L<perlunicode> and L<encoding> for more about Unicode.
843
844 =item chroot FILENAME
845 X<chroot> X<root>
846
847 =item chroot
848
849 This function works like the system call by the same name: it makes the
850 named directory the new root directory for all further pathnames that
851 begin with a C</> by your process and all its children.  (It doesn't
852 change your current working directory, which is unaffected.)  For security
853 reasons, this call is restricted to the superuser.  If FILENAME is
854 omitted, does a C<chroot> to C<$_>.
855
856 =item close FILEHANDLE
857 X<close>
858
859 =item close
860
861 Closes the file or pipe associated with the file handle, returning
862 true only if IO buffers are successfully flushed and closes the system
863 file descriptor.  Closes the currently selected filehandle if the
864 argument is omitted.
865
866 You don't have to close FILEHANDLE if you are immediately going to do
867 another C<open> on it, because C<open> will close it for you.  (See
868 C<open>.)  However, an explicit C<close> on an input file resets the line
869 counter (C<$.>), while the implicit close done by C<open> does not.
870
871 If the file handle came from a piped open, C<close> will additionally
872 return false if one of the other system calls involved fails, or if the
873 program exits with non-zero status.  (If the only problem was that the
874 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
875 also waits for the process executing on the pipe to complete, in case you
876 want to look at the output of the pipe afterwards, and
877 implicitly puts the exit status value of that command into C<$?> and
878 C<${^CHILD_ERROR_NATIVE}>.
879
880 Prematurely closing the read end of a pipe (i.e. before the process
881 writing to it at the other end has closed it) will result in a
882 SIGPIPE being delivered to the writer.  If the other end can't
883 handle that, be sure to read all the data before closing the pipe.
884
885 Example:
886
887     open(OUTPUT, '|sort >foo')  # pipe to sort
888         or die "Can't start sort: $!";
889     #...                        # print stuff to output
890     close OUTPUT                # wait for sort to finish
891         or warn $! ? "Error closing sort pipe: $!"
892                    : "Exit status $? from sort";
893     open(INPUT, 'foo')          # get sort's results
894         or die "Can't open 'foo' for input: $!";
895
896 FILEHANDLE may be an expression whose value can be used as an indirect
897 filehandle, usually the real filehandle name.
898
899 =item closedir DIRHANDLE
900 X<closedir>
901
902 Closes a directory opened by C<opendir> and returns the success of that
903 system call.
904
905 =item connect SOCKET,NAME
906 X<connect>
907
908 Attempts to connect to a remote socket, just as the connect system call
909 does.  Returns true if it succeeded, false otherwise.  NAME should be a
910 packed address of the appropriate type for the socket.  See the examples in
911 L<perlipc/"Sockets: Client/Server Communication">.
912
913 =item continue BLOCK
914 X<continue>
915
916 =item continue
917
918 C<continue> is actually a flow control statement rather than a function.  If
919 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
920 C<foreach>), it is always executed just before the conditional is about to
921 be evaluated again, just like the third part of a C<for> loop in C.  Thus
922 it can be used to increment a loop variable, even when the loop has been
923 continued via the C<next> statement (which is similar to the C C<continue>
924 statement).
925
926 C<last>, C<next>, or C<redo> may appear within a C<continue>
927 block.  C<last> and C<redo> will behave as if they had been executed within
928 the main block.  So will C<next>, but since it will execute a C<continue>
929 block, it may be more entertaining.
930
931     while (EXPR) {
932         ### redo always comes here
933         do_something;
934     } continue {
935         ### next always comes here
936         do_something_else;
937         # then back the top to re-check EXPR
938     }
939     ### last always comes here
940
941 Omitting the C<continue> section is semantically equivalent to using an
942 empty one, logically enough.  In that case, C<next> goes directly back
943 to check the condition at the top of the loop.
944
945 If the "switch" feature is enabled, C<continue> is also a
946 function that will break out of the current C<when> or C<default>
947 block, and fall through to the next case. See L<feature> and
948 L<perlsyn/"Switch statements"> for more information.
949
950
951 =item cos EXPR
952 X<cos> X<cosine> X<acos> X<arccosine>
953
954 =item cos
955
956 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
957 takes cosine of C<$_>.
958
959 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
960 function, or use this relation:
961
962     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
963
964 =item crypt PLAINTEXT,SALT
965 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
966 X<decrypt> X<cryptography> X<passwd>
967
968 Creates a digest string exactly like the crypt(3) function in the C
969 library (assuming that you actually have a version there that has not
970 been extirpated as a potential munitions).
971
972 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
973 into a short string, called a digest, which is returned.  The same
974 PLAINTEXT and SALT will always return the same string, but there is no
975 (known) way to get the original PLAINTEXT from the hash.  Small
976 changes in the PLAINTEXT or SALT will result in large changes in the
977 digest.
978
979 There is no decrypt function.  This function isn't all that useful for
980 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
981 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
982 primarily used to check if two pieces of text are the same without
983 having to transmit or store the text itself.  An example is checking
984 if a correct password is given.  The digest of the password is stored,
985 not the password itself.  The user types in a password that is
986 crypt()'d with the same salt as the stored digest.  If the two digests
987 match the password is correct.
988
989 When verifying an existing digest string you should use the digest as
990 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
991 to create the digest is visible as part of the digest.  This ensures
992 crypt() will hash the new string with the same salt as the digest.
993 This allows your code to work with the standard L<crypt|/crypt> and
994 with more exotic implementations.  In other words, do not assume
995 anything about the returned string itself, or how many bytes in the
996 digest matter.
997
998 Traditionally the result is a string of 13 bytes: two first bytes of
999 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1000 the first eight bytes of the digest string mattered, but alternative
1001 hashing schemes (like MD5), higher level security schemes (like C2),
1002 and implementations on non-UNIX platforms may produce different
1003 strings.
1004
1005 When choosing a new salt create a random two character string whose
1006 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1007 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1008 characters is just a recommendation; the characters allowed in
1009 the salt depend solely on your system's crypt library, and Perl can't
1010 restrict what salts C<crypt()> accepts.
1011
1012 Here's an example that makes sure that whoever runs this program knows
1013 their password:
1014
1015     $pwd = (getpwuid($<))[1];
1016
1017     system "stty -echo";
1018     print "Password: ";
1019     chomp($word = <STDIN>);
1020     print "\n";
1021     system "stty echo";
1022
1023     if (crypt($word, $pwd) ne $pwd) {
1024         die "Sorry...\n";
1025     } else {
1026         print "ok\n";
1027     }
1028
1029 Of course, typing in your own password to whoever asks you
1030 for it is unwise.
1031
1032 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1033 of data, not least of all because you can't get the information
1034 back.  Look at the L<Digest> module for more robust algorithms.
1035
1036 If using crypt() on a Unicode string (which I<potentially> has
1037 characters with codepoints above 255), Perl tries to make sense
1038 of the situation by trying to downgrade (a copy of the string)
1039 the string back to an eight-bit byte string before calling crypt()
1040 (on that copy).  If that works, good.  If not, crypt() dies with
1041 C<Wide character in crypt>.
1042
1043 =item dbmclose HASH
1044 X<dbmclose>
1045
1046 [This function has been largely superseded by the C<untie> function.]
1047
1048 Breaks the binding between a DBM file and a hash.
1049
1050 =item dbmopen HASH,DBNAME,MASK
1051 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1052
1053 [This function has been largely superseded by the C<tie> function.]
1054
1055 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1056 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1057 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1058 is the name of the database (without the F<.dir> or F<.pag> extension if
1059 any).  If the database does not exist, it is created with protection
1060 specified by MASK (as modified by the C<umask>).  If your system supports
1061 only the older DBM functions, you may perform only one C<dbmopen> in your
1062 program.  In older versions of Perl, if your system had neither DBM nor
1063 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1064 sdbm(3).
1065
1066 If you don't have write access to the DBM file, you can only read hash
1067 variables, not set them.  If you want to test whether you can write,
1068 either use file tests or try setting a dummy hash entry inside an C<eval>,
1069 which will trap the error.
1070
1071 Note that functions such as C<keys> and C<values> may return huge lists
1072 when used on large DBM files.  You may prefer to use the C<each>
1073 function to iterate over large DBM files.  Example:
1074
1075     # print out history file offsets
1076     dbmopen(%HIST,'/usr/lib/news/history',0666);
1077     while (($key,$val) = each %HIST) {
1078         print $key, ' = ', unpack('L',$val), "\n";
1079     }
1080     dbmclose(%HIST);
1081
1082 See also L<AnyDBM_File> for a more general description of the pros and
1083 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1084 rich implementation.
1085
1086 You can control which DBM library you use by loading that library
1087 before you call dbmopen():
1088
1089     use DB_File;
1090     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1091         or die "Can't open netscape history file: $!";
1092
1093 =item defined EXPR
1094 X<defined> X<undef> X<undefined>
1095
1096 =item defined
1097
1098 Returns a Boolean value telling whether EXPR has a value other than
1099 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1100 checked.
1101
1102 Many operations return C<undef> to indicate failure, end of file,
1103 system error, uninitialized variable, and other exceptional
1104 conditions.  This function allows you to distinguish C<undef> from
1105 other values.  (A simple Boolean test will not distinguish among
1106 C<undef>, zero, the empty string, and C<"0">, which are all equally
1107 false.)  Note that since C<undef> is a valid scalar, its presence
1108 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1109 returns C<undef> when its argument is an empty array, I<or> when the
1110 element to return happens to be C<undef>.
1111
1112 You may also use C<defined(&func)> to check whether subroutine C<&func>
1113 has ever been defined.  The return value is unaffected by any forward
1114 declarations of C<&func>.  Note that a subroutine which is not defined
1115 may still be callable: its package may have an C<AUTOLOAD> method that
1116 makes it spring into existence the first time that it is called -- see
1117 L<perlsub>.
1118
1119 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1120 used to report whether memory for that aggregate has ever been
1121 allocated.  This behavior may disappear in future versions of Perl.
1122 You should instead use a simple test for size:
1123
1124     if (@an_array) { print "has array elements\n" }
1125     if (%a_hash)   { print "has hash members\n"   }
1126
1127 When used on a hash element, it tells you whether the value is defined,
1128 not whether the key exists in the hash.  Use L</exists> for the latter
1129 purpose.
1130
1131 Examples:
1132
1133     print if defined $switch{'D'};
1134     print "$val\n" while defined($val = pop(@ary));
1135     die "Can't readlink $sym: $!"
1136         unless defined($value = readlink $sym);
1137     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1138     $debugging = 0 unless defined $debugging;
1139
1140 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1141 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1142 defined values.  For example, if you say
1143
1144     "ab" =~ /a(.*)b/;
1145
1146 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1147 matched "nothing".  It didn't really fail to match anything.  Rather, it
1148 matched something that happened to be zero characters long.  This is all
1149 very above-board and honest.  When a function returns an undefined value,
1150 it's an admission that it couldn't give you an honest answer.  So you
1151 should use C<defined> only when you're questioning the integrity of what
1152 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1153 what you want.
1154
1155 See also L</undef>, L</exists>, L</ref>.
1156
1157 =item delete EXPR
1158 X<delete>
1159
1160 Given an expression that specifies a hash element, array element, hash slice,
1161 or array slice, deletes the specified element(s) from the hash or array.
1162 In the case of an array, if the array elements happen to be at the end,
1163 the size of the array will shrink to the highest element that tests
1164 true for exists() (or 0 if no such element exists).
1165
1166 Returns a list with the same number of elements as the number of elements
1167 for which deletion was attempted.  Each element of that list consists of
1168 either the value of the element deleted, or the undefined value.  In scalar
1169 context, this means that you get the value of the last element deleted (or
1170 the undefined value if that element did not exist).
1171
1172     %hash = (foo => 11, bar => 22, baz => 33);
1173     $scalar = delete $hash{foo};             # $scalar is 11
1174     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1175     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1176
1177 Deleting from C<%ENV> modifies the environment.  Deleting from
1178 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1179 from a C<tie>d hash or array may not necessarily return anything.
1180
1181 Deleting an array element effectively returns that position of the array
1182 to its initial, uninitialized state.  Subsequently testing for the same
1183 element with exists() will return false.  Also, deleting array elements
1184 in the middle of an array will not shift the index of the elements
1185 after them down.  Use splice() for that.  See L</exists>.
1186
1187 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1188
1189     foreach $key (keys %HASH) {
1190         delete $HASH{$key};
1191     }
1192
1193     foreach $index (0 .. $#ARRAY) {
1194         delete $ARRAY[$index];
1195     }
1196
1197 And so do these:
1198
1199     delete @HASH{keys %HASH};
1200
1201     delete @ARRAY[0 .. $#ARRAY];
1202
1203 But both of these are slower than just assigning the empty list
1204 or undefining %HASH or @ARRAY:
1205
1206     %HASH = ();         # completely empty %HASH
1207     undef %HASH;        # forget %HASH ever existed
1208
1209     @ARRAY = ();        # completely empty @ARRAY
1210     undef @ARRAY;       # forget @ARRAY ever existed
1211
1212 Note that the EXPR can be arbitrarily complicated as long as the final
1213 operation is a hash element, array element,  hash slice, or array slice
1214 lookup:
1215
1216     delete $ref->[$x][$y]{$key};
1217     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1218
1219     delete $ref->[$x][$y][$index];
1220     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1221
1222 =item die LIST
1223 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1224
1225 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1226 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1227 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1228 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1229 an C<eval(),> the error message is stuffed into C<$@> and the
1230 C<eval> is terminated with the undefined value.  This makes
1231 C<die> the way to raise an exception.
1232
1233 Equivalent examples:
1234
1235     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1236     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1237
1238 If the last element of LIST does not end in a newline, the current
1239 script line number and input line number (if any) are also printed,
1240 and a newline is supplied.  Note that the "input line number" (also
1241 known as "chunk") is subject to whatever notion of "line" happens to
1242 be currently in effect, and is also available as the special variable
1243 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1244
1245 Hint: sometimes appending C<", stopped"> to your message will cause it
1246 to make better sense when the string C<"at foo line 123"> is appended.
1247 Suppose you are running script "canasta".
1248
1249     die "/etc/games is no good";
1250     die "/etc/games is no good, stopped";
1251
1252 produce, respectively
1253
1254     /etc/games is no good at canasta line 123.
1255     /etc/games is no good, stopped at canasta line 123.
1256
1257 See also exit(), warn(), and the Carp module.
1258
1259 If LIST is empty and C<$@> already contains a value (typically from a
1260 previous eval) that value is reused after appending C<"\t...propagated">.
1261 This is useful for propagating exceptions:
1262
1263     eval { ... };
1264     die unless $@ =~ /Expected exception/;
1265
1266 If LIST is empty and C<$@> contains an object reference that has a
1267 C<PROPAGATE> method, that method will be called with additional file
1268 and line number parameters.  The return value replaces the value in
1269 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1270 were called.
1271
1272 If C<$@> is empty then the string C<"Died"> is used.
1273
1274 die() can also be called with a reference argument.  If this happens to be
1275 trapped within an eval(), $@ contains the reference.  This behavior permits
1276 a more elaborate exception handling implementation using objects that
1277 maintain arbitrary state about the nature of the exception.  Such a scheme
1278 is sometimes preferable to matching particular string values of $@ using
1279 regular expressions.  Here's an example:
1280
1281     use Scalar::Util 'blessed';
1282
1283     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1284     if ($@) {
1285         if (blessed($@) && $@->isa("Some::Module::Exception")) {
1286             # handle Some::Module::Exception
1287         }
1288         else {
1289             # handle all other possible exceptions
1290         }
1291     }
1292
1293 Because perl will stringify uncaught exception messages before displaying
1294 them, you may want to overload stringification operations on such custom
1295 exception objects.  See L<overload> for details about that.
1296
1297 You can arrange for a callback to be run just before the C<die>
1298 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1299 handler will be called with the error text and can change the error
1300 message, if it sees fit, by calling C<die> again.  See
1301 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1302 L<"eval BLOCK"> for some examples.  Although this feature was 
1303 to be run only right before your program was to exit, this is not
1304 currently the case--the C<$SIG{__DIE__}> hook is currently called
1305 even inside eval()ed blocks/strings!  If one wants the hook to do
1306 nothing in such situations, put
1307
1308         die @_ if $^S;
1309
1310 as the first line of the handler (see L<perlvar/$^S>).  Because
1311 this promotes strange action at a distance, this counterintuitive
1312 behavior may be fixed in a future release.
1313
1314 =item do BLOCK
1315 X<do> X<block>
1316
1317 Not really a function.  Returns the value of the last command in the
1318 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1319 C<until> loop modifier, executes the BLOCK once before testing the loop
1320 condition. (On other statements the loop modifiers test the conditional
1321 first.)
1322
1323 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1324 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1325 See L<perlsyn> for alternative strategies.
1326
1327 =item do SUBROUTINE(LIST)
1328 X<do>
1329
1330 This form of subroutine call is deprecated.  See L<perlsub>.
1331
1332 =item do EXPR
1333 X<do>
1334
1335 Uses the value of EXPR as a filename and executes the contents of the
1336 file as a Perl script.
1337
1338     do 'stat.pl';
1339
1340 is just like
1341
1342     eval `cat stat.pl`;
1343
1344 except that it's more efficient and concise, keeps track of the current
1345 filename for error messages, searches the @INC directories, and updates
1346 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1347 variables.  It also differs in that code evaluated with C<do FILENAME>
1348 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1349 same, however, in that it does reparse the file every time you call it,
1350 so you probably don't want to do this inside a loop.
1351
1352 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1353 error.  If C<do> can read the file but cannot compile it, it
1354 returns undef and sets an error message in C<$@>.   If the file is
1355 successfully compiled, C<do> returns the value of the last expression
1356 evaluated.
1357
1358 Note that inclusion of library modules is better done with the
1359 C<use> and C<require> operators, which also do automatic error checking
1360 and raise an exception if there's a problem.
1361
1362 You might like to use C<do> to read in a program configuration
1363 file.  Manual error checking can be done this way:
1364
1365     # read in config files: system first, then user
1366     for $file ("/share/prog/defaults.rc",
1367                "$ENV{HOME}/.someprogrc")
1368    {
1369         unless ($return = do $file) {
1370             warn "couldn't parse $file: $@" if $@;
1371             warn "couldn't do $file: $!"    unless defined $return;
1372             warn "couldn't run $file"       unless $return;
1373         }
1374     }
1375
1376 =item dump LABEL
1377 X<dump> X<core> X<undump>
1378
1379 =item dump
1380
1381 This function causes an immediate core dump.  See also the B<-u>
1382 command-line switch in L<perlrun>, which does the same thing.
1383 Primarily this is so that you can use the B<undump> program (not
1384 supplied) to turn your core dump into an executable binary after
1385 having initialized all your variables at the beginning of the
1386 program.  When the new binary is executed it will begin by executing
1387 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1388 Think of it as a goto with an intervening core dump and reincarnation.
1389 If C<LABEL> is omitted, restarts the program from the top.
1390
1391 B<WARNING>: Any files opened at the time of the dump will I<not>
1392 be open any more when the program is reincarnated, with possible
1393 resulting confusion on the part of Perl.
1394
1395 This function is now largely obsolete, partly because it's very
1396 hard to convert a core file into an executable, and because the
1397 real compiler backends for generating portable bytecode and compilable
1398 C code have superseded it.  That's why you should now invoke it as
1399 C<CORE::dump()>, if you don't want to be warned against a possible
1400 typo.
1401
1402 If you're looking to use L<dump> to speed up your program, consider
1403 generating bytecode or native C code as described in L<perlcc>.  If
1404 you're just trying to accelerate a CGI script, consider using the
1405 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1406 You might also consider autoloading or selfloading, which at least
1407 make your program I<appear> to run faster.
1408
1409 =item each HASH
1410 X<each> X<hash, iterator>
1411
1412 When called in list context, returns a 2-element list consisting of the
1413 key and value for the next element of a hash, so that you can iterate over
1414 it.  When called in scalar context, returns only the key for the next
1415 element in the hash.
1416
1417 Entries are returned in an apparently random order.  The actual random
1418 order is subject to change in future versions of perl, but it is
1419 guaranteed to be in the same order as either the C<keys> or C<values>
1420 function would produce on the same (unmodified) hash.  Since Perl
1421 5.8.1 the ordering is different even between different runs of Perl
1422 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1423
1424 When the hash is entirely read, a null array is returned in list context
1425 (which when assigned produces a false (C<0>) value), and C<undef> in
1426 scalar context.  The next call to C<each> after that will start iterating
1427 again.  There is a single iterator for each hash, shared by all C<each>,
1428 C<keys>, and C<values> function calls in the program; it can be reset by
1429 reading all the elements from the hash, or by evaluating C<keys HASH> or
1430 C<values HASH>.  If you add or delete elements of a hash while you're
1431 iterating over it, you may get entries skipped or duplicated, so
1432 don't.  Exception: It is always safe to delete the item most recently
1433 returned by C<each()>, which means that the following code will work:
1434
1435         while (($key, $value) = each %hash) {
1436           print $key, "\n";
1437           delete $hash{$key};   # This is safe
1438         }
1439
1440 The following prints out your environment like the printenv(1) program,
1441 only in a different order:
1442
1443     while (($key,$value) = each %ENV) {
1444         print "$key=$value\n";
1445     }
1446
1447 See also C<keys>, C<values> and C<sort>.
1448
1449 =item eof FILEHANDLE
1450 X<eof>
1451 X<end of file>
1452 X<end-of-file>
1453
1454 =item eof ()
1455
1456 =item eof
1457
1458 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1459 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1460 gives the real filehandle.  (Note that this function actually
1461 reads a character and then C<ungetc>s it, so isn't very useful in an
1462 interactive context.)  Do not read from a terminal file (or call
1463 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1464 as terminals may lose the end-of-file condition if you do.
1465
1466 An C<eof> without an argument uses the last file read.  Using C<eof()>
1467 with empty parentheses is very different.  It refers to the pseudo file
1468 formed from the files listed on the command line and accessed via the
1469 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1470 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1471 used will cause C<@ARGV> to be examined to determine if input is
1472 available.   Similarly, an C<eof()> after C<< <> >> has returned
1473 end-of-file will assume you are processing another C<@ARGV> list,
1474 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1475 see L<perlop/"I/O Operators">.
1476
1477 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1478 detect the end of each file, C<eof()> will only detect the end of the
1479 last file.  Examples:
1480
1481     # reset line numbering on each input file
1482     while (<>) {
1483         next if /^\s*#/;        # skip comments
1484         print "$.\t$_";
1485     } continue {
1486         close ARGV  if eof;     # Not eof()!
1487     }
1488
1489     # insert dashes just before last line of last file
1490     while (<>) {
1491         if (eof()) {            # check for end of last file
1492             print "--------------\n";
1493         }
1494         print;
1495         last if eof();          # needed if we're reading from a terminal
1496     }
1497
1498 Practical hint: you almost never need to use C<eof> in Perl, because the
1499 input operators typically return C<undef> when they run out of data, or if
1500 there was an error.
1501
1502 =item eval EXPR
1503 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1504
1505 =item eval BLOCK
1506
1507 =item eval
1508
1509 In the first form, the return value of EXPR is parsed and executed as if it
1510 were a little Perl program.  The value of the expression (which is itself
1511 determined within scalar context) is first parsed, and if there weren't any
1512 errors, executed in the lexical context of the current Perl program, so
1513 that any variable settings or subroutine and format definitions remain
1514 afterwards.  Note that the value is parsed every time the C<eval> executes.
1515 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1516 delay parsing and subsequent execution of the text of EXPR until run time.
1517
1518 In the second form, the code within the BLOCK is parsed only once--at the
1519 same time the code surrounding the C<eval> itself was parsed--and executed
1520 within the context of the current Perl program.  This form is typically
1521 used to trap exceptions more efficiently than the first (see below), while
1522 also providing the benefit of checking the code within BLOCK at compile
1523 time.
1524
1525 The final semicolon, if any, may be omitted from the value of EXPR or within
1526 the BLOCK.
1527
1528 In both forms, the value returned is the value of the last expression
1529 evaluated inside the mini-program; a return statement may be also used, just
1530 as with subroutines.  The expression providing the return value is evaluated
1531 in void, scalar, or list context, depending on the context of the C<eval> 
1532 itself.  See L</wantarray> for more on how the evaluation context can be 
1533 determined.
1534
1535 If there is a syntax error or runtime error, or a C<die> statement is
1536 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1537 error message.  If there was no error, C<$@> is guaranteed to be a null
1538 string.  Beware that using C<eval> neither silences perl from printing
1539 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1540 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1541 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1542 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1543
1544 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1545 determining whether a particular feature (such as C<socket> or C<symlink>)
1546 is implemented.  It is also Perl's exception trapping mechanism, where
1547 the die operator is used to raise exceptions.
1548
1549 If the code to be executed doesn't vary, you may use the eval-BLOCK
1550 form to trap run-time errors without incurring the penalty of
1551 recompiling each time.  The error, if any, is still returned in C<$@>.
1552 Examples:
1553
1554     # make divide-by-zero nonfatal
1555     eval { $answer = $a / $b; }; warn $@ if $@;
1556
1557     # same thing, but less efficient
1558     eval '$answer = $a / $b'; warn $@ if $@;
1559
1560     # a compile-time error
1561     eval { $answer = };                 # WRONG
1562
1563     # a run-time error
1564     eval '$answer =';   # sets $@
1565
1566 Using the C<eval{}> form as an exception trap in libraries does have some
1567 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1568 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1569 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1570 as shown in this example:
1571
1572     # a very private exception trap for divide-by-zero
1573     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1574     warn $@ if $@;
1575
1576 This is especially significant, given that C<__DIE__> hooks can call
1577 C<die> again, which has the effect of changing their error messages:
1578
1579     # __DIE__ hooks may modify error messages
1580     {
1581        local $SIG{'__DIE__'} =
1582               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1583        eval { die "foo lives here" };
1584        print $@ if $@;                # prints "bar lives here"
1585     }
1586
1587 Because this promotes action at a distance, this counterintuitive behavior
1588 may be fixed in a future release.
1589
1590 With an C<eval>, you should be especially careful to remember what's
1591 being looked at when:
1592
1593     eval $x;            # CASE 1
1594     eval "$x";          # CASE 2
1595
1596     eval '$x';          # CASE 3
1597     eval { $x };        # CASE 4
1598
1599     eval "\$$x++";      # CASE 5
1600     $$x++;              # CASE 6
1601
1602 Cases 1 and 2 above behave identically: they run the code contained in
1603 the variable $x.  (Although case 2 has misleading double quotes making
1604 the reader wonder what else might be happening (nothing is).)  Cases 3
1605 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1606 does nothing but return the value of $x.  (Case 4 is preferred for
1607 purely visual reasons, but it also has the advantage of compiling at
1608 compile-time instead of at run-time.)  Case 5 is a place where
1609 normally you I<would> like to use double quotes, except that in this
1610 particular situation, you can just use symbolic references instead, as
1611 in case 6.
1612
1613 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1614 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1615
1616 Note that as a very special case, an C<eval ''> executed within the C<DB>
1617 package doesn't see the usual surrounding lexical scope, but rather the
1618 scope of the first non-DB piece of code that called it. You don't normally
1619 need to worry about this unless you are writing a Perl debugger.
1620
1621 =item exec LIST
1622 X<exec> X<execute>
1623
1624 =item exec PROGRAM LIST
1625
1626 The C<exec> function executes a system command I<and never returns>--
1627 use C<system> instead of C<exec> if you want it to return.  It fails and
1628 returns false only if the command does not exist I<and> it is executed
1629 directly instead of via your system's command shell (see below).
1630
1631 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1632 warns you if there is a following statement which isn't C<die>, C<warn>,
1633 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1634 I<really> want to follow an C<exec> with some other statement, you
1635 can use one of these styles to avoid the warning:
1636
1637     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1638     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1639
1640 If there is more than one argument in LIST, or if LIST is an array
1641 with more than one value, calls execvp(3) with the arguments in LIST.
1642 If there is only one scalar argument or an array with one element in it,
1643 the argument is checked for shell metacharacters, and if there are any,
1644 the entire argument is passed to the system's command shell for parsing
1645 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1646 If there are no shell metacharacters in the argument, it is split into
1647 words and passed directly to C<execvp>, which is more efficient.
1648 Examples:
1649
1650     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1651     exec "sort $outfile | uniq";
1652
1653 If you don't really want to execute the first argument, but want to lie
1654 to the program you are executing about its own name, you can specify
1655 the program you actually want to run as an "indirect object" (without a
1656 comma) in front of the LIST.  (This always forces interpretation of the
1657 LIST as a multivalued list, even if there is only a single scalar in
1658 the list.)  Example:
1659
1660     $shell = '/bin/csh';
1661     exec $shell '-sh';          # pretend it's a login shell
1662
1663 or, more directly,
1664
1665     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1666
1667 When the arguments get executed via the system shell, results will
1668 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1669 for details.
1670
1671 Using an indirect object with C<exec> or C<system> is also more
1672 secure.  This usage (which also works fine with system()) forces
1673 interpretation of the arguments as a multivalued list, even if the
1674 list had just one argument.  That way you're safe from the shell
1675 expanding wildcards or splitting up words with whitespace in them.
1676
1677     @args = ( "echo surprise" );
1678
1679     exec @args;               # subject to shell escapes
1680                                 # if @args == 1
1681     exec { $args[0] } @args;  # safe even with one-arg list
1682
1683 The first version, the one without the indirect object, ran the I<echo>
1684 program, passing it C<"surprise"> an argument.  The second version
1685 didn't--it tried to run a program literally called I<"echo surprise">,
1686 didn't find it, and set C<$?> to a non-zero value indicating failure.
1687
1688 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1689 output before the exec, but this may not be supported on some platforms
1690 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1691 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1692 open handles in order to avoid lost output.
1693
1694 Note that C<exec> will not call your C<END> blocks, nor will it call
1695 any C<DESTROY> methods in your objects.
1696
1697 =item exists EXPR
1698 X<exists> X<autovivification>
1699
1700 Given an expression that specifies a hash element or array element,
1701 returns true if the specified element in the hash or array has ever
1702 been initialized, even if the corresponding value is undefined.  The
1703 element is not autovivified if it doesn't exist.
1704
1705     print "Exists\n"    if exists $hash{$key};
1706     print "Defined\n"   if defined $hash{$key};
1707     print "True\n"      if $hash{$key};
1708
1709     print "Exists\n"    if exists $array[$index];
1710     print "Defined\n"   if defined $array[$index];
1711     print "True\n"      if $array[$index];
1712
1713 A hash or array element can be true only if it's defined, and defined if
1714 it exists, but the reverse doesn't necessarily hold true.
1715
1716 Given an expression that specifies the name of a subroutine,
1717 returns true if the specified subroutine has ever been declared, even
1718 if it is undefined.  Mentioning a subroutine name for exists or defined
1719 does not count as declaring it.  Note that a subroutine which does not
1720 exist may still be callable: its package may have an C<AUTOLOAD>
1721 method that makes it spring into existence the first time that it is
1722 called -- see L<perlsub>.
1723
1724     print "Exists\n"    if exists &subroutine;
1725     print "Defined\n"   if defined &subroutine;
1726
1727 Note that the EXPR can be arbitrarily complicated as long as the final
1728 operation is a hash or array key lookup or subroutine name:
1729
1730     if (exists $ref->{A}->{B}->{$key})  { }
1731     if (exists $hash{A}{B}{$key})       { }
1732
1733     if (exists $ref->{A}->{B}->[$ix])   { }
1734     if (exists $hash{A}{B}[$ix])        { }
1735
1736     if (exists &{$ref->{A}{B}{$key}})   { }
1737
1738 Although the deepest nested array or hash will not spring into existence
1739 just because its existence was tested, any intervening ones will.
1740 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1741 into existence due to the existence test for the $key element above.
1742 This happens anywhere the arrow operator is used, including even:
1743
1744     undef $ref;
1745     if (exists $ref->{"Some key"})      { }
1746     print $ref;             # prints HASH(0x80d3d5c)
1747
1748 This surprising autovivification in what does not at first--or even
1749 second--glance appear to be an lvalue context may be fixed in a future
1750 release.
1751
1752 Use of a subroutine call, rather than a subroutine name, as an argument
1753 to exists() is an error.
1754
1755     exists &sub;        # OK
1756     exists &sub();      # Error
1757
1758 =item exit EXPR
1759 X<exit> X<terminate> X<abort>
1760
1761 =item exit
1762
1763 Evaluates EXPR and exits immediately with that value.    Example:
1764
1765     $ans = <STDIN>;
1766     exit 0 if $ans =~ /^[Xx]/;
1767
1768 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1769 universally recognized values for EXPR are C<0> for success and C<1>
1770 for error; other values are subject to interpretation depending on the
1771 environment in which the Perl program is running.  For example, exiting
1772 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1773 the mailer to return the item undelivered, but that's not true everywhere.
1774
1775 Don't use C<exit> to abort a subroutine if there's any chance that
1776 someone might want to trap whatever error happened.  Use C<die> instead,
1777 which can be trapped by an C<eval>.
1778
1779 The exit() function does not always exit immediately.  It calls any
1780 defined C<END> routines first, but these C<END> routines may not
1781 themselves abort the exit.  Likewise any object destructors that need to
1782 be called are called before the real exit.  If this is a problem, you
1783 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1784 See L<perlmod> for details.
1785
1786 =item exp EXPR
1787 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1788
1789 =item exp
1790
1791 Returns I<e> (the natural logarithm base) to the power of EXPR.
1792 If EXPR is omitted, gives C<exp($_)>.
1793
1794 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1795 X<fcntl>
1796
1797 Implements the fcntl(2) function.  You'll probably have to say
1798
1799     use Fcntl;
1800
1801 first to get the correct constant definitions.  Argument processing and
1802 value return works just like C<ioctl> below.
1803 For example:
1804
1805     use Fcntl;
1806     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1807         or die "can't fcntl F_GETFL: $!";
1808
1809 You don't have to check for C<defined> on the return from C<fcntl>.
1810 Like C<ioctl>, it maps a C<0> return from the system call into
1811 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1812 in numeric context.  It is also exempt from the normal B<-w> warnings
1813 on improper numeric conversions.
1814
1815 Note that C<fcntl> will produce a fatal error if used on a machine that
1816 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1817 manpage to learn what functions are available on your system.
1818
1819 Here's an example of setting a filehandle named C<REMOTE> to be
1820 non-blocking at the system level.  You'll have to negotiate C<$|>
1821 on your own, though.
1822
1823     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1824
1825     $flags = fcntl(REMOTE, F_GETFL, 0)
1826                 or die "Can't get flags for the socket: $!\n";
1827
1828     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1829                 or die "Can't set flags for the socket: $!\n";
1830
1831 =item fileno FILEHANDLE
1832 X<fileno>
1833
1834 Returns the file descriptor for a filehandle, or undefined if the
1835 filehandle is not open.  This is mainly useful for constructing
1836 bitmaps for C<select> and low-level POSIX tty-handling operations.
1837 If FILEHANDLE is an expression, the value is taken as an indirect
1838 filehandle, generally its name.
1839
1840 You can use this to find out whether two handles refer to the
1841 same underlying descriptor:
1842
1843     if (fileno(THIS) == fileno(THAT)) {
1844         print "THIS and THAT are dups\n";
1845     }
1846
1847 (Filehandles connected to memory objects via new features of C<open> may
1848 return undefined even though they are open.)
1849
1850
1851 =item flock FILEHANDLE,OPERATION
1852 X<flock> X<lock> X<locking>
1853
1854 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1855 for success, false on failure.  Produces a fatal error if used on a
1856 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1857 C<flock> is Perl's portable file locking interface, although it locks
1858 only entire files, not records.
1859
1860 Two potentially non-obvious but traditional C<flock> semantics are
1861 that it waits indefinitely until the lock is granted, and that its locks
1862 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1863 fewer guarantees.  This means that programs that do not also use C<flock>
1864 may modify files locked with C<flock>.  See L<perlport>, 
1865 your port's specific documentation, or your system-specific local manpages
1866 for details.  It's best to assume traditional behavior if you're writing
1867 portable programs.  (But if you're not, you should as always feel perfectly
1868 free to write for your own system's idiosyncrasies (sometimes called
1869 "features").  Slavish adherence to portability concerns shouldn't get
1870 in the way of your getting your job done.)
1871
1872 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1873 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1874 you can use the symbolic names if you import them from the Fcntl module,
1875 either individually, or as a group using the ':flock' tag.  LOCK_SH
1876 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1877 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1878 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1879 waiting for the lock (check the return status to see if you got it).
1880
1881 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1882 before locking or unlocking it.
1883
1884 Note that the emulation built with lockf(3) doesn't provide shared
1885 locks, and it requires that FILEHANDLE be open with write intent.  These
1886 are the semantics that lockf(3) implements.  Most if not all systems
1887 implement lockf(3) in terms of fcntl(2) locking, though, so the
1888 differing semantics shouldn't bite too many people.
1889
1890 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1891 be open with read intent to use LOCK_SH and requires that it be open
1892 with write intent to use LOCK_EX.
1893
1894 Note also that some versions of C<flock> cannot lock things over the
1895 network; you would need to use the more system-specific C<fcntl> for
1896 that.  If you like you can force Perl to ignore your system's flock(2)
1897 function, and so provide its own fcntl(2)-based emulation, by passing
1898 the switch C<-Ud_flock> to the F<Configure> program when you configure
1899 perl.
1900
1901 Here's a mailbox appender for BSD systems.
1902
1903     use Fcntl ':flock'; # import LOCK_* constants
1904
1905     sub lock {
1906         flock(MBOX,LOCK_EX);
1907         # and, in case someone appended
1908         # while we were waiting...
1909         seek(MBOX, 0, 2);
1910     }
1911
1912     sub unlock {
1913         flock(MBOX,LOCK_UN);
1914     }
1915
1916     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1917             or die "Can't open mailbox: $!";
1918
1919     lock();
1920     print MBOX $msg,"\n\n";
1921     unlock();
1922
1923 On systems that support a real flock(), locks are inherited across fork()
1924 calls, whereas those that must resort to the more capricious fcntl()
1925 function lose the locks, making it harder to write servers.
1926
1927 See also L<DB_File> for other flock() examples.
1928
1929 =item fork
1930 X<fork> X<child> X<parent>
1931
1932 Does a fork(2) system call to create a new process running the
1933 same program at the same point.  It returns the child pid to the
1934 parent process, C<0> to the child process, or C<undef> if the fork is
1935 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1936 are shared, while everything else is copied.  On most systems supporting
1937 fork(), great care has gone into making it extremely efficient (for
1938 example, using copy-on-write technology on data pages), making it the
1939 dominant paradigm for multitasking over the last few decades.
1940
1941 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1942 output before forking the child process, but this may not be supported
1943 on some platforms (see L<perlport>).  To be safe, you may need to set
1944 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1945 C<IO::Handle> on any open handles in order to avoid duplicate output.
1946
1947 If you C<fork> without ever waiting on your children, you will
1948 accumulate zombies.  On some systems, you can avoid this by setting
1949 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1950 forking and reaping moribund children.
1951
1952 Note that if your forked child inherits system file descriptors like
1953 STDIN and STDOUT that are actually connected by a pipe or socket, even
1954 if you exit, then the remote server (such as, say, a CGI script or a
1955 backgrounded job launched from a remote shell) won't think you're done.
1956 You should reopen those to F</dev/null> if it's any issue.
1957
1958 =item format
1959 X<format>
1960
1961 Declare a picture format for use by the C<write> function.  For
1962 example:
1963
1964     format Something =
1965         Test: @<<<<<<<< @||||| @>>>>>
1966               $str,     $%,    '$' . int($num)
1967     .
1968
1969     $str = "widget";
1970     $num = $cost/$quantity;
1971     $~ = 'Something';
1972     write;
1973
1974 See L<perlform> for many details and examples.
1975
1976 =item formline PICTURE,LIST
1977 X<formline>
1978
1979 This is an internal function used by C<format>s, though you may call it,
1980 too.  It formats (see L<perlform>) a list of values according to the
1981 contents of PICTURE, placing the output into the format output
1982 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1983 Eventually, when a C<write> is done, the contents of
1984 C<$^A> are written to some filehandle.  You could also read C<$^A>
1985 and then set C<$^A> back to C<"">.  Note that a format typically
1986 does one C<formline> per line of form, but the C<formline> function itself
1987 doesn't care how many newlines are embedded in the PICTURE.  This means
1988 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1989 You may therefore need to use multiple formlines to implement a single
1990 record format, just like the format compiler.
1991
1992 Be careful if you put double quotes around the picture, because an C<@>
1993 character may be taken to mean the beginning of an array name.
1994 C<formline> always returns true.  See L<perlform> for other examples.
1995
1996 =item getc FILEHANDLE
1997 X<getc> X<getchar>
1998
1999 =item getc
2000
2001 Returns the next character from the input file attached to FILEHANDLE,
2002 or the undefined value at end of file, or if there was an error (in
2003 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2004 STDIN.  This is not particularly efficient.  However, it cannot be
2005 used by itself to fetch single characters without waiting for the user
2006 to hit enter.  For that, try something more like:
2007
2008     if ($BSD_STYLE) {
2009         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2010     }
2011     else {
2012         system "stty", '-icanon', 'eol', "\001";
2013     }
2014
2015     $key = getc(STDIN);
2016
2017     if ($BSD_STYLE) {
2018         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2019     }
2020     else {
2021         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2022     }
2023     print "\n";
2024
2025 Determination of whether $BSD_STYLE should be set
2026 is left as an exercise to the reader.
2027
2028 The C<POSIX::getattr> function can do this more portably on
2029 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2030 module from your nearest CPAN site; details on CPAN can be found on
2031 L<perlmodlib/CPAN>.
2032
2033 =item getlogin
2034 X<getlogin> X<login>
2035
2036 This implements the C library function of the same name, which on most
2037 systems returns the current login from F</etc/utmp>, if any.  If null,
2038 use C<getpwuid>.
2039
2040     $login = getlogin || getpwuid($<) || "Kilroy";
2041
2042 Do not consider C<getlogin> for authentication: it is not as
2043 secure as C<getpwuid>.
2044
2045 =item getpeername SOCKET
2046 X<getpeername> X<peer>
2047
2048 Returns the packed sockaddr address of other end of the SOCKET connection.
2049
2050     use Socket;
2051     $hersockaddr    = getpeername(SOCK);
2052     ($port, $iaddr) = sockaddr_in($hersockaddr);
2053     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2054     $herstraddr     = inet_ntoa($iaddr);
2055
2056 =item getpgrp PID
2057 X<getpgrp> X<group>
2058
2059 Returns the current process group for the specified PID.  Use
2060 a PID of C<0> to get the current process group for the
2061 current process.  Will raise an exception if used on a machine that
2062 doesn't implement getpgrp(2).  If PID is omitted, returns process
2063 group of current process.  Note that the POSIX version of C<getpgrp>
2064 does not accept a PID argument, so only C<PID==0> is truly portable.
2065
2066 =item getppid
2067 X<getppid> X<parent> X<pid>
2068
2069 Returns the process id of the parent process.
2070
2071 Note for Linux users: on Linux, the C functions C<getpid()> and
2072 C<getppid()> return different values from different threads. In order to
2073 be portable, this behavior is not reflected by the perl-level function
2074 C<getppid()>, that returns a consistent value across threads. If you want
2075 to call the underlying C<getppid()>, you may use the CPAN module
2076 C<Linux::Pid>.
2077
2078 =item getpriority WHICH,WHO
2079 X<getpriority> X<priority> X<nice>
2080
2081 Returns the current priority for a process, a process group, or a user.
2082 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2083 machine that doesn't implement getpriority(2).
2084
2085 =item getpwnam NAME
2086 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2087 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2088 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2089 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2090 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2091 X<endnetent> X<endprotoent> X<endservent> 
2092
2093 =item getgrnam NAME
2094
2095 =item gethostbyname NAME
2096
2097 =item getnetbyname NAME
2098
2099 =item getprotobyname NAME
2100
2101 =item getpwuid UID
2102
2103 =item getgrgid GID
2104
2105 =item getservbyname NAME,PROTO
2106
2107 =item gethostbyaddr ADDR,ADDRTYPE
2108
2109 =item getnetbyaddr ADDR,ADDRTYPE
2110
2111 =item getprotobynumber NUMBER
2112
2113 =item getservbyport PORT,PROTO
2114
2115 =item getpwent
2116
2117 =item getgrent
2118
2119 =item gethostent
2120
2121 =item getnetent
2122
2123 =item getprotoent
2124
2125 =item getservent
2126
2127 =item setpwent
2128
2129 =item setgrent
2130
2131 =item sethostent STAYOPEN
2132
2133 =item setnetent STAYOPEN
2134
2135 =item setprotoent STAYOPEN
2136
2137 =item setservent STAYOPEN
2138
2139 =item endpwent
2140
2141 =item endgrent
2142
2143 =item endhostent
2144
2145 =item endnetent
2146
2147 =item endprotoent
2148
2149 =item endservent
2150
2151 These routines perform the same functions as their counterparts in the
2152 system library.  In list context, the return values from the
2153 various get routines are as follows:
2154
2155     ($name,$passwd,$uid,$gid,
2156        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2157     ($name,$passwd,$gid,$members) = getgr*
2158     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2159     ($name,$aliases,$addrtype,$net) = getnet*
2160     ($name,$aliases,$proto) = getproto*
2161     ($name,$aliases,$port,$proto) = getserv*
2162
2163 (If the entry doesn't exist you get a null list.)
2164
2165 The exact meaning of the $gcos field varies but it usually contains
2166 the real name of the user (as opposed to the login name) and other
2167 information pertaining to the user.  Beware, however, that in many
2168 system users are able to change this information and therefore it
2169 cannot be trusted and therefore the $gcos is tainted (see
2170 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2171 login shell, are also tainted, because of the same reason.
2172
2173 In scalar context, you get the name, unless the function was a
2174 lookup by name, in which case you get the other thing, whatever it is.
2175 (If the entry doesn't exist you get the undefined value.)  For example:
2176
2177     $uid   = getpwnam($name);
2178     $name  = getpwuid($num);
2179     $name  = getpwent();
2180     $gid   = getgrnam($name);
2181     $name  = getgrgid($num);
2182     $name  = getgrent();
2183     #etc.
2184
2185 In I<getpw*()> the fields $quota, $comment, and $expire are special
2186 cases in the sense that in many systems they are unsupported.  If the
2187 $quota is unsupported, it is an empty scalar.  If it is supported, it
2188 usually encodes the disk quota.  If the $comment field is unsupported,
2189 it is an empty scalar.  If it is supported it usually encodes some
2190 administrative comment about the user.  In some systems the $quota
2191 field may be $change or $age, fields that have to do with password
2192 aging.  In some systems the $comment field may be $class.  The $expire
2193 field, if present, encodes the expiration period of the account or the
2194 password.  For the availability and the exact meaning of these fields
2195 in your system, please consult your getpwnam(3) documentation and your
2196 F<pwd.h> file.  You can also find out from within Perl what your
2197 $quota and $comment fields mean and whether you have the $expire field
2198 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2199 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2200 files are only supported if your vendor has implemented them in the
2201 intuitive fashion that calling the regular C library routines gets the
2202 shadow versions if you're running under privilege or if there exists
2203 the shadow(3) functions as found in System V (this includes Solaris
2204 and Linux.)  Those systems that implement a proprietary shadow password
2205 facility are unlikely to be supported.
2206
2207 The $members value returned by I<getgr*()> is a space separated list of
2208 the login names of the members of the group.
2209
2210 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2211 C, it will be returned to you via C<$?> if the function call fails.  The
2212 C<@addrs> value returned by a successful call is a list of the raw
2213 addresses returned by the corresponding system library call.  In the
2214 Internet domain, each address is four bytes long and you can unpack it
2215 by saying something like:
2216
2217     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2218
2219 The Socket library makes this slightly easier:
2220
2221     use Socket;
2222     $iaddr = inet_aton("127.1"); # or whatever address
2223     $name  = gethostbyaddr($iaddr, AF_INET);
2224
2225     # or going the other way
2226     $straddr = inet_ntoa($iaddr);
2227
2228 If you get tired of remembering which element of the return list
2229 contains which return value, by-name interfaces are provided
2230 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2231 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2232 and C<User::grent>.  These override the normal built-ins, supplying
2233 versions that return objects with the appropriate names
2234 for each field.  For example:
2235
2236    use File::stat;
2237    use User::pwent;
2238    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2239
2240 Even though it looks like they're the same method calls (uid),
2241 they aren't, because a C<File::stat> object is different from
2242 a C<User::pwent> object.
2243
2244 =item getsockname SOCKET
2245 X<getsockname>
2246
2247 Returns the packed sockaddr address of this end of the SOCKET connection,
2248 in case you don't know the address because you have several different
2249 IPs that the connection might have come in on.
2250
2251     use Socket;
2252     $mysockaddr = getsockname(SOCK);
2253     ($port, $myaddr) = sockaddr_in($mysockaddr);
2254     printf "Connect to %s [%s]\n",
2255        scalar gethostbyaddr($myaddr, AF_INET),
2256        inet_ntoa($myaddr);
2257
2258 =item getsockopt SOCKET,LEVEL,OPTNAME
2259 X<getsockopt>
2260
2261 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2262 Options may exist at multiple protocol levels depending on the socket
2263 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2264 C<Socket> module) will exist. To query options at another level the
2265 protocol number of the appropriate protocol controlling the option
2266 should be supplied. For example, to indicate that an option is to be
2267 interpreted by the TCP protocol, LEVEL should be set to the protocol
2268 number of TCP, which you can get using getprotobyname.
2269
2270 The call returns a packed string representing the requested socket option,
2271 or C<undef> if there is an error (the error reason will be in $!). What
2272 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2273 your system documentation for details. A very common case however is that
2274 the option is an integer, in which case the result will be a packed
2275 integer which you can decode using unpack with the C<i> (or C<I>) format.
2276
2277 An example testing if Nagle's algorithm is turned on on a socket:
2278
2279     use Socket qw(:all);
2280
2281     defined(my $tcp = getprotobyname("tcp"))
2282         or die "Could not determine the protocol number for tcp";
2283     # my $tcp = IPPROTO_TCP; # Alternative
2284     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2285         or die "Could not query TCP_NODELAY socket option: $!";
2286     my $nodelay = unpack("I", $packed);
2287     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2288
2289
2290 =item glob EXPR
2291 X<glob> X<wildcard> X<filename, expansion> X<expand>
2292
2293 =item glob
2294
2295 In list context, returns a (possibly empty) list of filename expansions on
2296 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2297 scalar context, glob iterates through such filename expansions, returning
2298 undef when the list is exhausted. This is the internal function
2299 implementing the C<< <*.c> >> operator, but you can use it directly. If
2300 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2301 more detail in L<perlop/"I/O Operators">.
2302
2303 Beginning with v5.6.0, this operator is implemented using the standard
2304 C<File::Glob> extension.  See L<File::Glob> for details.
2305
2306 =item gmtime EXPR
2307 X<gmtime> X<UTC> X<Greenwich>
2308
2309 =item gmtime
2310
2311 Converts a time as returned by the time function to an 9-element list
2312 with the time localized for the standard Greenwich time zone.
2313 Typically used as follows:
2314
2315     #  0    1    2     3     4    5     6     7     8
2316     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2317                                             gmtime(time);
2318
2319 All list elements are numeric, and come straight out of the C `struct
2320 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2321 specified time.  $mday is the day of the month, and $mon is the month
2322 itself, in the range C<0..11> with 0 indicating January and 11
2323 indicating December.  $year is the number of years since 1900.  That
2324 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2325 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2326 the year, in the range C<0..364> (or C<0..365> in leap years).  $isdst
2327 is always C<0>.
2328
2329 Note that the $year element is I<not> simply the last two digits of
2330 the year.  If you assume it is then you create non-Y2K-compliant
2331 programs--and you wouldn't want to do that, would you?
2332
2333 The proper way to get a complete 4-digit year is simply:
2334
2335         $year += 1900;
2336
2337 And to get the last two digits of the year (e.g., '01' in 2001) do:
2338
2339         $year = sprintf("%02d", $year % 100);
2340
2341 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2342
2343 In scalar context, C<gmtime()> returns the ctime(3) value:
2344
2345     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2346
2347 If you need local time instead of GMT use the L</localtime> builtin. 
2348 See also the C<timegm> function provided by the C<Time::Local> module,
2349 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2350
2351 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2352 instead a Perl builtin.  To get somewhat similar but locale dependent date
2353 strings, see the example in L</localtime>.
2354
2355 See L<perlport/gmtime> for portability concerns.
2356
2357 =item goto LABEL
2358 X<goto> X<jump> X<jmp>
2359
2360 =item goto EXPR
2361
2362 =item goto &NAME
2363
2364 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2365 execution there.  It may not be used to go into any construct that
2366 requires initialization, such as a subroutine or a C<foreach> loop.  It
2367 also can't be used to go into a construct that is optimized away,
2368 or to get out of a block or subroutine given to C<sort>.
2369 It can be used to go almost anywhere else within the dynamic scope,
2370 including out of subroutines, but it's usually better to use some other
2371 construct such as C<last> or C<die>.  The author of Perl has never felt the
2372 need to use this form of C<goto> (in Perl, that is--C is another matter).
2373 (The difference being that C does not offer named loops combined with
2374 loop control.  Perl does, and this replaces most structured uses of C<goto>
2375 in other languages.)
2376
2377 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2378 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2379 necessarily recommended if you're optimizing for maintainability:
2380
2381     goto ("FOO", "BAR", "GLARCH")[$i];
2382
2383 The C<goto-&NAME> form is quite different from the other forms of
2384 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2385 doesn't have the stigma associated with other gotos.  Instead, it
2386 exits the current subroutine (losing any changes set by local()) and
2387 immediately calls in its place the named subroutine using the current
2388 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2389 load another subroutine and then pretend that the other subroutine had
2390 been called in the first place (except that any modifications to C<@_>
2391 in the current subroutine are propagated to the other subroutine.)
2392 After the C<goto>, not even C<caller> will be able to tell that this
2393 routine was called first.
2394
2395 NAME needn't be the name of a subroutine; it can be a scalar variable
2396 containing a code reference, or a block that evaluates to a code
2397 reference.
2398
2399 =item grep BLOCK LIST
2400 X<grep>
2401
2402 =item grep EXPR,LIST
2403
2404 This is similar in spirit to, but not the same as, grep(1) and its
2405 relatives.  In particular, it is not limited to using regular expressions.
2406
2407 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2408 C<$_> to each element) and returns the list value consisting of those
2409 elements for which the expression evaluated to true.  In scalar
2410 context, returns the number of times the expression was true.
2411
2412     @foo = grep(!/^#/, @bar);    # weed out comments
2413
2414 or equivalently,
2415
2416     @foo = grep {!/^#/} @bar;    # weed out comments
2417
2418 Note that C<$_> is an alias to the list value, so it can be used to
2419 modify the elements of the LIST.  While this is useful and supported,
2420 it can cause bizarre results if the elements of LIST are not variables.
2421 Similarly, grep returns aliases into the original list, much as a for
2422 loop's index variable aliases the list elements.  That is, modifying an
2423 element of a list returned by grep (for example, in a C<foreach>, C<map>
2424 or another C<grep>) actually modifies the element in the original list.
2425 This is usually something to be avoided when writing clear code.
2426
2427 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2428 been declared with C<my $_>) then, in addition to being locally aliased to
2429 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2430 can't be seen from the outside, avoiding any potential side-effects.
2431
2432 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2433
2434 =item hex EXPR
2435 X<hex> X<hexadecimal>
2436
2437 =item hex
2438
2439 Interprets EXPR as a hex string and returns the corresponding value.
2440 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2441 L</oct>.)  If EXPR is omitted, uses C<$_>.
2442
2443     print hex '0xAf'; # prints '175'
2444     print hex 'aF';   # same
2445
2446 Hex strings may only represent integers.  Strings that would cause
2447 integer overflow trigger a warning.  Leading whitespace is not stripped,
2448 unlike oct(). To present something as hex, look into L</printf>,
2449 L</sprintf>, or L</unpack>.
2450
2451 =item import LIST
2452 X<import>
2453
2454 There is no builtin C<import> function.  It is just an ordinary
2455 method (subroutine) defined (or inherited) by modules that wish to export
2456 names to another module.  The C<use> function calls the C<import> method
2457 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2458
2459 =item index STR,SUBSTR,POSITION
2460 X<index> X<indexOf> X<InStr>
2461
2462 =item index STR,SUBSTR
2463
2464 The index function searches for one string within another, but without
2465 the wildcard-like behavior of a full regular-expression pattern match.
2466 It returns the position of the first occurrence of SUBSTR in STR at
2467 or after POSITION.  If POSITION is omitted, starts searching from the
2468 beginning of the string.  POSITION before the beginning of the string
2469 or after its end is treated as if it were the beginning or the end,
2470 respectively.  POSITION and the return value are based at C<0> (or whatever
2471 you've set the C<$[> variable to--but don't do that).  If the substring
2472 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2473
2474 =item int EXPR
2475 X<int> X<integer> X<truncate> X<trunc>
2476
2477 =item int
2478
2479 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2480 You should not use this function for rounding: one because it truncates
2481 towards C<0>, and two because machine representations of floating point
2482 numbers can sometimes produce counterintuitive results.  For example,
2483 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2484 because it's really more like -268.99999999999994315658 instead.  Usually,
2485 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2486 functions will serve you better than will int().
2487
2488 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2489 X<ioctl>
2490
2491 Implements the ioctl(2) function.  You'll probably first have to say
2492
2493     require "sys/ioctl.ph";     # probably in $Config{archlib}/sys/ioctl.ph
2494
2495 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2496 exist or doesn't have the correct definitions you'll have to roll your
2497 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2498 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2499 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2500 written depending on the FUNCTION--a pointer to the string value of SCALAR
2501 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2502 has no string value but does have a numeric value, that value will be
2503 passed rather than a pointer to the string value.  To guarantee this to be
2504 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2505 functions may be needed to manipulate the values of structures used by
2506 C<ioctl>.
2507
2508 The return value of C<ioctl> (and C<fcntl>) is as follows:
2509
2510         if OS returns:          then Perl returns:
2511             -1                    undefined value
2512              0                  string "0 but true"
2513         anything else               that number
2514
2515 Thus Perl returns true on success and false on failure, yet you can
2516 still easily determine the actual value returned by the operating
2517 system:
2518
2519     $retval = ioctl(...) || -1;
2520     printf "System returned %d\n", $retval;
2521
2522 The special string C<"0 but true"> is exempt from B<-w> complaints
2523 about improper numeric conversions.
2524
2525 =item join EXPR,LIST
2526 X<join>
2527
2528 Joins the separate strings of LIST into a single string with fields
2529 separated by the value of EXPR, and returns that new string.  Example:
2530
2531     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2532
2533 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2534 first argument.  Compare L</split>.
2535
2536 =item keys HASH
2537 X<keys> X<key>
2538
2539 Returns a list consisting of all the keys of the named hash.
2540 (In scalar context, returns the number of keys.)
2541
2542 The keys are returned in an apparently random order.  The actual
2543 random order is subject to change in future versions of perl, but it
2544 is guaranteed to be the same order as either the C<values> or C<each>
2545 function produces (given that the hash has not been modified).  Since
2546 Perl 5.8.1 the ordering is different even between different runs of
2547 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2548 Attacks">).
2549
2550 As a side effect, calling keys() resets the HASH's internal iterator
2551 (see L</each>).  In particular, calling keys() in void context resets
2552 the iterator with no other overhead.
2553
2554 Here is yet another way to print your environment:
2555
2556     @keys = keys %ENV;
2557     @values = values %ENV;
2558     while (@keys) {
2559         print pop(@keys), '=', pop(@values), "\n";
2560     }
2561
2562 or how about sorted by key:
2563
2564     foreach $key (sort(keys %ENV)) {
2565         print $key, '=', $ENV{$key}, "\n";
2566     }
2567
2568 The returned values are copies of the original keys in the hash, so
2569 modifying them will not affect the original hash.  Compare L</values>.
2570
2571 To sort a hash by value, you'll need to use a C<sort> function.
2572 Here's a descending numeric sort of a hash by its values:
2573
2574     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2575         printf "%4d %s\n", $hash{$key}, $key;
2576     }
2577
2578 As an lvalue C<keys> allows you to increase the number of hash buckets
2579 allocated for the given hash.  This can gain you a measure of efficiency if
2580 you know the hash is going to get big.  (This is similar to pre-extending
2581 an array by assigning a larger number to $#array.)  If you say
2582
2583     keys %hash = 200;
2584
2585 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2586 in fact, since it rounds up to the next power of two.  These
2587 buckets will be retained even if you do C<%hash = ()>, use C<undef
2588 %hash> if you want to free the storage while C<%hash> is still in scope.
2589 You can't shrink the number of buckets allocated for the hash using
2590 C<keys> in this way (but you needn't worry about doing this by accident,
2591 as trying has no effect).
2592
2593 See also C<each>, C<values> and C<sort>.
2594
2595 =item kill SIGNAL, LIST
2596 X<kill> X<signal>
2597
2598 Sends a signal to a list of processes.  Returns the number of
2599 processes successfully signaled (which is not necessarily the
2600 same as the number actually killed).
2601
2602     $cnt = kill 1, $child1, $child2;
2603     kill 9, @goners;
2604
2605 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2606 system call will check whether it's possible to send a signal to it (that
2607 means, to be brief, that the process is owned by the same user, or we are
2608 the super-user).  This is a useful way to check that a child process is
2609 alive and hasn't changed its UID.  See L<perlport> for notes on the
2610 portability of this construct.
2611
2612 Unlike in the shell, if SIGNAL is negative, it kills
2613 process groups instead of processes.  (On System V, a negative I<PROCESS>
2614 number will also kill process groups, but that's not portable.)  That
2615 means you usually want to use positive not negative signals.  You may also
2616 use a signal name in quotes.
2617
2618 See L<perlipc/"Signals"> for more details.
2619
2620 =item last LABEL
2621 X<last> X<break>
2622
2623 =item last
2624
2625 The C<last> command is like the C<break> statement in C (as used in
2626 loops); it immediately exits the loop in question.  If the LABEL is
2627 omitted, the command refers to the innermost enclosing loop.  The
2628 C<continue> block, if any, is not executed:
2629
2630     LINE: while (<STDIN>) {
2631         last LINE if /^$/;      # exit when done with header
2632         #...
2633     }
2634
2635 C<last> cannot be used to exit a block which returns a value such as
2636 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2637 a grep() or map() operation.
2638
2639 Note that a block by itself is semantically identical to a loop
2640 that executes once.  Thus C<last> can be used to effect an early
2641 exit out of such a block.
2642
2643 See also L</continue> for an illustration of how C<last>, C<next>, and
2644 C<redo> work.
2645
2646 =item lc EXPR
2647 X<lc> X<lowercase>
2648
2649 =item lc
2650
2651 Returns a lowercased version of EXPR.  This is the internal function
2652 implementing the C<\L> escape in double-quoted strings.  Respects
2653 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2654 and L<perlunicode> for more details about locale and Unicode support.
2655
2656 If EXPR is omitted, uses C<$_>.
2657
2658 =item lcfirst EXPR
2659 X<lcfirst> X<lowercase>
2660
2661 =item lcfirst
2662
2663 Returns the value of EXPR with the first character lowercased.  This
2664 is the internal function implementing the C<\l> escape in
2665 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2666 locale> in force.  See L<perllocale> and L<perlunicode> for more
2667 details about locale and Unicode support.
2668
2669 If EXPR is omitted, uses C<$_>.
2670
2671 =item length EXPR
2672 X<length> X<size>
2673
2674 =item length
2675
2676 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2677 omitted, returns length of C<$_>.  Note that this cannot be used on
2678 an entire array or hash to find out how many elements these have.
2679 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2680
2681 Note the I<characters>: if the EXPR is in Unicode, you will get the
2682 number of characters, not the number of bytes.  To get the length
2683 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2684
2685 =item link OLDFILE,NEWFILE
2686 X<link>
2687
2688 Creates a new filename linked to the old filename.  Returns true for
2689 success, false otherwise.
2690
2691 =item listen SOCKET,QUEUESIZE
2692 X<listen>
2693
2694 Does the same thing that the listen system call does.  Returns true if
2695 it succeeded, false otherwise.  See the example in
2696 L<perlipc/"Sockets: Client/Server Communication">.
2697
2698 =item local EXPR
2699 X<local>
2700
2701 You really probably want to be using C<my> instead, because C<local> isn't
2702 what most people think of as "local".  See
2703 L<perlsub/"Private Variables via my()"> for details.
2704
2705 A local modifies the listed variables to be local to the enclosing
2706 block, file, or eval.  If more than one value is listed, the list must
2707 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2708 for details, including issues with tied arrays and hashes.
2709
2710 =item localtime EXPR
2711 X<localtime>
2712
2713 =item localtime
2714
2715 Converts a time as returned by the time function to a 9-element list
2716 with the time analyzed for the local time zone.  Typically used as
2717 follows:
2718
2719     #  0    1    2     3     4    5     6     7     8
2720     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2721                                                 localtime(time);
2722
2723 All list elements are numeric, and come straight out of the C `struct
2724 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2725 of the specified time.
2726
2727 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2728 the range C<0..11> with 0 indicating January and 11 indicating December.
2729 This makes it easy to get a month name from a list:
2730
2731     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2732     print "$abbr[$mon] $mday";
2733     # $mon=9, $mday=18 gives "Oct 18"
2734
2735 C<$year> is the number of years since 1900, not just the last two digits
2736 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2737 to get a complete 4-digit year is simply:
2738
2739     $year += 1900;
2740
2741 To get the last two digits of the year (e.g., '01' in 2001) do:
2742
2743     $year = sprintf("%02d", $year % 100);
2744
2745 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2746 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2747 (or C<0..365> in leap years.)
2748
2749 C<$isdst> is true if the specified time occurs during Daylight Saving
2750 Time, false otherwise.
2751
2752 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2753
2754 In scalar context, C<localtime()> returns the ctime(3) value:
2755
2756     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2757
2758 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2759 instead of local time use the L</gmtime> builtin. See also the
2760 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2761 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2762 and mktime(3) functions.
2763
2764 To get somewhat similar but locale dependent date strings, set up your
2765 locale environment variables appropriately (please see L<perllocale>) and
2766 try for example:
2767
2768     use POSIX qw(strftime);
2769     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2770     # or for GMT formatted appropriately for your locale:
2771     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2772
2773 Note that the C<%a> and C<%b>, the short forms of the day of the week
2774 and the month of the year, may not necessarily be three characters wide.
2775
2776 See L<perlport/localtime> for portability concerns.
2777
2778 =item lock THING
2779 X<lock>
2780
2781 This function places an advisory lock on a shared variable, or referenced
2782 object contained in I<THING> until the lock goes out of scope.
2783
2784 lock() is a "weak keyword" : this means that if you've defined a function
2785 by this name (before any calls to it), that function will be called
2786 instead. (However, if you've said C<use threads>, lock() is always a
2787 keyword.) See L<threads>.
2788
2789 =item log EXPR
2790 X<log> X<logarithm> X<e> X<ln> X<base>
2791
2792 =item log
2793
2794 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2795 returns log of C<$_>.  To get the log of another base, use basic algebra:
2796 The base-N log of a number is equal to the natural log of that number
2797 divided by the natural log of N.  For example:
2798
2799     sub log10 {
2800         my $n = shift;
2801         return log($n)/log(10);
2802     }
2803
2804 See also L</exp> for the inverse operation.
2805
2806 =item lstat EXPR
2807 X<lstat>
2808
2809 =item lstat
2810
2811 Does the same thing as the C<stat> function (including setting the
2812 special C<_> filehandle) but stats a symbolic link instead of the file
2813 the symbolic link points to.  If symbolic links are unimplemented on
2814 your system, a normal C<stat> is done.  For much more detailed
2815 information, please see the documentation for C<stat>.
2816
2817 If EXPR is omitted, stats C<$_>.
2818
2819 =item m//
2820
2821 The match operator.  See L<perlop>.
2822
2823 =item map BLOCK LIST
2824 X<map>
2825
2826 =item map EXPR,LIST
2827
2828 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2829 C<$_> to each element) and returns the list value composed of the
2830 results of each such evaluation.  In scalar context, returns the
2831 total number of elements so generated.  Evaluates BLOCK or EXPR in
2832 list context, so each element of LIST may produce zero, one, or
2833 more elements in the returned value.
2834
2835     @chars = map(chr, @nums);
2836
2837 translates a list of numbers to the corresponding characters.  And
2838
2839     %hash = map { getkey($_) => $_ } @array;
2840
2841 is just a funny way to write
2842
2843     %hash = ();
2844     foreach $_ (@array) {
2845         $hash{getkey($_)} = $_;
2846     }
2847
2848 Note that C<$_> is an alias to the list value, so it can be used to
2849 modify the elements of the LIST.  While this is useful and supported,
2850 it can cause bizarre results if the elements of LIST are not variables.
2851 Using a regular C<foreach> loop for this purpose would be clearer in
2852 most cases.  See also L</grep> for an array composed of those items of
2853 the original list for which the BLOCK or EXPR evaluates to true.
2854
2855 If C<$_> is lexical in the scope where the C<map> appears (because it has
2856 been declared with C<my $_>) then, in addition to being locally aliased to
2857 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2858 can't be seen from the outside, avoiding any potential side-effects.
2859
2860 C<{> starts both hash references and blocks, so C<map { ...> could be either
2861 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2862 ahead for the closing C<}> it has to take a guess at which its dealing with
2863 based what it finds just after the C<{>. Usually it gets it right, but if it
2864 doesn't it won't realize something is wrong until it gets to the C<}> and
2865 encounters the missing (or unexpected) comma. The syntax error will be
2866 reported close to the C<}> but you'll need to change something near the C<{>
2867 such as using a unary C<+> to give perl some help:
2868
2869     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2870     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2871     %hash = map { ("\L$_", 1) } @array  # this also works
2872     %hash = map {  lc($_), 1  } @array  # as does this.
2873     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2874
2875     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2876
2877 or to force an anon hash constructor use C<+{>
2878
2879    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2880
2881 and you get list of anonymous hashes each with only 1 entry.
2882
2883 =item mkdir FILENAME,MASK
2884 X<mkdir> X<md> X<directory, create>
2885
2886 =item mkdir FILENAME
2887
2888 =item mkdir
2889
2890 Creates the directory specified by FILENAME, with permissions
2891 specified by MASK (as modified by C<umask>).  If it succeeds it
2892 returns true, otherwise it returns false and sets C<$!> (errno).
2893 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2894 to C<$_>.
2895
2896 In general, it is better to create directories with permissive MASK,
2897 and let the user modify that with their C<umask>, than it is to supply
2898 a restrictive MASK and give the user no way to be more permissive.
2899 The exceptions to this rule are when the file or directory should be
2900 kept private (mail files, for instance).  The perlfunc(1) entry on
2901 C<umask> discusses the choice of MASK in more detail.
2902
2903 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2904 number of trailing slashes.  Some operating and filesystems do not get
2905 this right, so Perl automatically removes all trailing slashes to keep
2906 everyone happy.
2907
2908 =item msgctl ID,CMD,ARG
2909 X<msgctl>
2910
2911 Calls the System V IPC function msgctl(2).  You'll probably have to say
2912
2913     use IPC::SysV;
2914
2915 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2916 then ARG must be a variable that will hold the returned C<msqid_ds>
2917 structure.  Returns like C<ioctl>: the undefined value for error,
2918 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2919 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2920
2921 =item msgget KEY,FLAGS
2922 X<msgget>
2923
2924 Calls the System V IPC function msgget(2).  Returns the message queue
2925 id, or the undefined value if there is an error.  See also
2926 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2927
2928 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2929 X<msgrcv>
2930
2931 Calls the System V IPC function msgrcv to receive a message from
2932 message queue ID into variable VAR with a maximum message size of
2933 SIZE.  Note that when a message is received, the message type as a
2934 native long integer will be the first thing in VAR, followed by the
2935 actual message.  This packing may be opened with C<unpack("l! a*")>.
2936 Taints the variable.  Returns true if successful, or false if there is
2937 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2938 C<IPC::SysV::Msg> documentation.
2939
2940 =item msgsnd ID,MSG,FLAGS
2941 X<msgsnd>
2942
2943 Calls the System V IPC function msgsnd to send the message MSG to the
2944 message queue ID.  MSG must begin with the native long integer message
2945 type, and be followed by the length of the actual message, and finally
2946 the message itself.  This kind of packing can be achieved with
2947 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2948 or false if there is an error.  See also C<IPC::SysV>
2949 and C<IPC::SysV::Msg> documentation.
2950
2951 =item my EXPR
2952 X<my>
2953
2954 =item my TYPE EXPR
2955
2956 =item my EXPR : ATTRS
2957
2958 =item my TYPE EXPR : ATTRS
2959
2960 A C<my> declares the listed variables to be local (lexically) to the
2961 enclosing block, file, or C<eval>.  If more than one value is listed,
2962 the list must be placed in parentheses.
2963
2964 The exact semantics and interface of TYPE and ATTRS are still
2965 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2966 and attributes are handled using the C<attributes> pragma, or starting
2967 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2968 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2969 L<attributes>, and L<Attribute::Handlers>.
2970
2971 =item next LABEL
2972 X<next> X<continue>
2973
2974 =item next
2975
2976 The C<next> command is like the C<continue> statement in C; it starts
2977 the next iteration of the loop:
2978
2979     LINE: while (<STDIN>) {
2980         next LINE if /^#/;      # discard comments
2981         #...
2982     }
2983
2984 Note that if there were a C<continue> block on the above, it would get
2985 executed even on discarded lines.  If the LABEL is omitted, the command
2986 refers to the innermost enclosing loop.
2987
2988 C<next> cannot be used to exit a block which returns a value such as
2989 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2990 a grep() or map() operation.
2991
2992 Note that a block by itself is semantically identical to a loop
2993 that executes once.  Thus C<next> will exit such a block early.
2994
2995 See also L</continue> for an illustration of how C<last>, C<next>, and
2996 C<redo> work.
2997
2998 =item no Module VERSION LIST
2999 X<no>
3000
3001 =item no Module VERSION
3002
3003 =item no Module LIST
3004
3005 =item no Module
3006
3007 See the C<use> function, of which C<no> is the opposite.
3008
3009 =item oct EXPR
3010 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3011
3012 =item oct
3013
3014 Interprets EXPR as an octal string and returns the corresponding
3015 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3016 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3017 binary string.  Leading whitespace is ignored in all three cases.)
3018 The following will handle decimal, binary, octal, and hex in the standard
3019 Perl or C notation:
3020
3021     $val = oct($val) if $val =~ /^0/;
3022
3023 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3024 in octal), use sprintf() or printf():
3025
3026     $perms = (stat("filename"))[2] & 07777;
3027     $oct_perms = sprintf "%lo", $perms;
3028
3029 The oct() function is commonly used when a string such as C<644> needs
3030 to be converted into a file mode, for example. (Although perl will
3031 automatically convert strings into numbers as needed, this automatic
3032 conversion assumes base 10.)
3033
3034 =item open FILEHANDLE,EXPR
3035 X<open> X<pipe> X<file, open> X<fopen>
3036
3037 =item open FILEHANDLE,MODE,EXPR
3038
3039 =item open FILEHANDLE,MODE,EXPR,LIST
3040
3041 =item open FILEHANDLE,MODE,REFERENCE
3042
3043 =item open FILEHANDLE
3044
3045 Opens the file whose filename is given by EXPR, and associates it with
3046 FILEHANDLE.
3047
3048 (The following is a comprehensive reference to open(): for a gentler
3049 introduction you may consider L<perlopentut>.)
3050
3051 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3052 the variable is assigned a reference to a new anonymous filehandle,
3053 otherwise if FILEHANDLE is an expression, its value is used as the name of
3054 the real filehandle wanted.  (This is considered a symbolic reference, so
3055 C<use strict 'refs'> should I<not> be in effect.)
3056
3057 If EXPR is omitted, the scalar variable of the same name as the
3058 FILEHANDLE contains the filename.  (Note that lexical variables--those
3059 declared with C<my>--will not work for this purpose; so if you're
3060 using C<my>, specify EXPR in your call to open.)
3061
3062 If three or more arguments are specified then the mode of opening and
3063 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3064 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3065 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3066 the file is opened for appending, again being created if necessary.
3067
3068 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3069 indicate that you want both read and write access to the file; thus
3070 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3071 '+>' >> mode would clobber the file first.  You can't usually use
3072 either read-write mode for updating textfiles, since they have
3073 variable length records.  See the B<-i> switch in L<perlrun> for a
3074 better approach.  The file is created with permissions of C<0666>
3075 modified by the process' C<umask> value.
3076
3077 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3078 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3079
3080 In the 2-arguments (and 1-argument) form of the call the mode and
3081 filename should be concatenated (in this order), possibly separated by
3082 spaces.  It is possible to omit the mode in these forms if the mode is
3083 C<< '<' >>.
3084
3085 If the filename begins with C<'|'>, the filename is interpreted as a
3086 command to which output is to be piped, and if the filename ends with a
3087 C<'|'>, the filename is interpreted as a command which pipes output to
3088 us.  See L<perlipc/"Using open() for IPC">
3089 for more examples of this.  (You are not allowed to C<open> to a command
3090 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3091 and L<perlipc/"Bidirectional Communication with Another Process">
3092 for alternatives.)
3093
3094 For three or more arguments if MODE is C<'|-'>, the filename is
3095 interpreted as a command to which output is to be piped, and if MODE
3096 is C<'-|'>, the filename is interpreted as a command which pipes
3097 output to us.  In the 2-arguments (and 1-argument) form one should
3098 replace dash (C<'-'>) with the command.
3099 See L<perlipc/"Using open() for IPC"> for more examples of this.
3100 (You are not allowed to C<open> to a command that pipes both in I<and>
3101 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3102 L<perlipc/"Bidirectional Communication"> for alternatives.)
3103
3104 In the three-or-more argument form of pipe opens, if LIST is specified
3105 (extra arguments after the command name) then LIST becomes arguments
3106 to the command invoked if the platform supports it.  The meaning of
3107 C<open> with more than three arguments for non-pipe modes is not yet
3108 specified. Experimental "layers" may give extra LIST arguments
3109 meaning.
3110
3111 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3112 and opening C<< '>-' >> opens STDOUT.
3113
3114 You may use the three-argument form of open to specify IO "layers"
3115 (sometimes also referred to as "disciplines") to be applied to the handle
3116 that affect how the input and output are processed (see L<open> and
3117 L<PerlIO> for more details). For example
3118
3119   open(FH, "<:utf8", "file")
3120
3121 will open the UTF-8 encoded file containing Unicode characters,
3122 see L<perluniintro>. Note that if layers are specified in the
3123 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3124 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3125
3126 Open returns nonzero upon success, the undefined value otherwise.  If
3127 the C<open> involved a pipe, the return value happens to be the pid of
3128 the subprocess.
3129
3130 If you're running Perl on a system that distinguishes between text
3131 files and binary files, then you should check out L</binmode> for tips
3132 for dealing with this.  The key distinction between systems that need
3133 C<binmode> and those that don't is their text file formats.  Systems
3134 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3135 character, and which encode that character in C as C<"\n">, do not
3136 need C<binmode>.  The rest need it.
3137
3138 When opening a file, it's usually a bad idea to continue normal execution
3139 if the request failed, so C<open> is frequently used in connection with
3140 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3141 where you want to make a nicely formatted error message (but there are
3142 modules that can help with that problem)) you should always check
3143 the return value from opening a file.  The infrequent exception is when
3144 working with an unopened filehandle is actually what you want to do.
3145
3146 As a special case the 3-arg form with a read/write mode and the third
3147 argument being C<undef>:
3148
3149     open(TMP, "+>", undef) or die ...
3150
3151 opens a filehandle to an anonymous temporary file.  Also using "+<"
3152 works for symmetry, but you really should consider writing something
3153 to the temporary file first.  You will need to seek() to do the
3154 reading.
3155
3156 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3157 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3158 "in memory" files held in Perl scalars via:
3159
3160     open($fh, '>', \$variable) || ..
3161
3162 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3163 file, you have to close it first:
3164
3165     close STDOUT;
3166     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3167
3168 Examples:
3169
3170     $ARTICLE = 100;
3171     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3172     while (<ARTICLE>) {...
3173
3174     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3175     # if the open fails, output is discarded
3176
3177     open(DBASE, '+<', 'dbase.mine')             # open for update
3178         or die "Can't open 'dbase.mine' for update: $!";
3179
3180     open(DBASE, '+<dbase.mine')                 # ditto
3181         or die "Can't open 'dbase.mine' for update: $!";
3182
3183     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3184         or die "Can't start caesar: $!";
3185
3186     open(ARTICLE, "caesar <$article |")         # ditto
3187         or die "Can't start caesar: $!";
3188
3189     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3190         or die "Can't start sort: $!";
3191
3192     # in memory files
3193     open(MEMORY,'>', \$var)
3194         or die "Can't open memory file: $!";
3195     print MEMORY "foo!\n";                      # output will end up in $var
3196
3197     # process argument list of files along with any includes
3198
3199     foreach $file (@ARGV) {
3200         process($file, 'fh00');
3201     }
3202
3203     sub process {
3204         my($filename, $input) = @_;
3205         $input++;               # this is a string increment
3206         unless (open($input, $filename)) {
3207             print STDERR "Can't open $filename: $!\n";
3208             return;
3209         }
3210
3211         local $_;
3212         while (<$input>) {              # note use of indirection
3213             if (/^#include "(.*)"/) {
3214                 process($1, $input);
3215                 next;
3216             }
3217             #...                # whatever
3218         }
3219     }
3220
3221 See L<perliol> for detailed info on PerlIO.
3222
3223 You may also, in the Bourne shell tradition, specify an EXPR beginning
3224 with C<< '>&' >>, in which case the rest of the string is interpreted
3225 as the name of a filehandle (or file descriptor, if numeric) to be
3226 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3227 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3228 The mode you specify should match the mode of the original filehandle.
3229 (Duping a filehandle does not take into account any existing contents
3230 of IO buffers.) If you use the 3-arg form then you can pass either a
3231 number, the name of a filehandle or the normal "reference to a glob".
3232
3233 Here is a script that saves, redirects, and restores C<STDOUT> and
3234 C<STDERR> using various methods:
3235
3236     #!/usr/bin/perl
3237     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3238     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3239
3240     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3241     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3242
3243     select STDERR; $| = 1;      # make unbuffered
3244     select STDOUT; $| = 1;      # make unbuffered
3245
3246     print STDOUT "stdout 1\n";  # this works for
3247     print STDERR "stderr 1\n";  # subprocesses too
3248
3249     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3250     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3251
3252     print STDOUT "stdout 2\n";
3253     print STDERR "stderr 2\n";
3254
3255 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3256 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3257 that file descriptor (and not call L<dup(2)>); this is more
3258 parsimonious of file descriptors.  For example:
3259
3260     # open for input, reusing the fileno of $fd
3261     open(FILEHANDLE, "<&=$fd")
3262
3263 or
3264
3265     open(FILEHANDLE, "<&=", $fd)
3266
3267 or
3268
3269     # open for append, using the fileno of OLDFH
3270     open(FH, ">>&=", OLDFH)
3271
3272 or
3273
3274     open(FH, ">>&=OLDFH")
3275
3276 Being parsimonious on filehandles is also useful (besides being
3277 parsimonious) for example when something is dependent on file
3278 descriptors, like for example locking using flock().  If you do just
3279 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3280 descriptor as B, and therefore flock(A) will not flock(B), and vice
3281 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3282 the same file descriptor.
3283
3284 Note that if you are using Perls older than 5.8.0, Perl will be using
3285 the standard C libraries' fdopen() to implement the "=" functionality.
3286 On many UNIX systems fdopen() fails when file descriptors exceed a
3287 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3288 most often the default.
3289
3290 You can see whether Perl has been compiled with PerlIO or not by
3291 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3292 is C<define>, you have PerlIO, otherwise you don't.
3293
3294 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3295 with 2-arguments (or 1-argument) form of open(), then
3296 there is an implicit fork done, and the return value of open is the pid
3297 of the child within the parent process, and C<0> within the child
3298 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3299 The filehandle behaves normally for the parent, but i/o to that
3300 filehandle is piped from/to the STDOUT/STDIN of the child process.
3301 In the child process the filehandle isn't opened--i/o happens from/to
3302 the new STDOUT or STDIN.  Typically this is used like the normal
3303 piped open when you want to exercise more control over just how the
3304 pipe command gets executed, such as when you are running setuid, and
3305 don't want to have to scan shell commands for metacharacters.
3306 The following triples are more or less equivalent:
3307
3308     open(FOO, "|tr '[a-z]' '[A-Z]'");
3309     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3310     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3311     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3312
3313     open(FOO, "cat -n '$file'|");
3314     open(FOO, '-|', "cat -n '$file'");
3315     open(FOO, '-|') || exec 'cat', '-n', $file;
3316     open(FOO, '-|', "cat", '-n', $file);
3317
3318 The last example in each block shows the pipe as "list form", which is
3319 not yet supported on all platforms.  A good rule of thumb is that if
3320 your platform has true C<fork()> (in other words, if your platform is
3321 UNIX) you can use the list form.
3322
3323 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3324
3325 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3326 output before any operation that may do a fork, but this may not be
3327 supported on some platforms (see L<perlport>).  To be safe, you may need
3328 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3329 of C<IO::Handle> on any open handles.
3330
3331 On systems that support a close-on-exec flag on files, the flag will
3332 be set for the newly opened file descriptor as determined by the value
3333 of $^F.  See L<perlvar/$^F>.
3334
3335 Closing any piped filehandle causes the parent process to wait for the
3336 child to finish, and returns the status value in C<$?> and
3337 C<${^CHILD_ERROR_NATIVE}>.
3338
3339 The filename passed to 2-argument (or 1-argument) form of open() will
3340 have leading and trailing whitespace deleted, and the normal
3341 redirection characters honored.  This property, known as "magic open",
3342 can often be used to good effect.  A user could specify a filename of
3343 F<"rsh cat file |">, or you could change certain filenames as needed:
3344
3345     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3346     open(FH, $filename) or die "Can't open $filename: $!";
3347
3348 Use 3-argument form to open a file with arbitrary weird characters in it,
3349
3350     open(FOO, '<', $file);
3351
3352 otherwise it's necessary to protect any leading and trailing whitespace:
3353
3354     $file =~ s#^(\s)#./$1#;
3355     open(FOO, "< $file\0");
3356
3357 (this may not work on some bizarre filesystems).  One should
3358 conscientiously choose between the I<magic> and 3-arguments form
3359 of open():
3360
3361     open IN, $ARGV[0];
3362
3363 will allow the user to specify an argument of the form C<"rsh cat file |">,
3364 but will not work on a filename which happens to have a trailing space, while
3365
3366     open IN, '<', $ARGV[0];
3367
3368 will have exactly the opposite restrictions.
3369
3370 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3371 should use the C<sysopen> function, which involves no such magic (but
3372 may use subtly different filemodes than Perl open(), which is mapped
3373 to C fopen()).  This is
3374 another way to protect your filenames from interpretation.  For example:
3375
3376     use IO::Handle;
3377     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3378         or die "sysopen $path: $!";
3379     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3380     print HANDLE "stuff $$\n";
3381     seek(HANDLE, 0, 0);
3382     print "File contains: ", <HANDLE>;
3383
3384 Using the constructor from the C<IO::Handle> package (or one of its
3385 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3386 filehandles that have the scope of whatever variables hold references to
3387 them, and automatically close whenever and however you leave that scope:
3388
3389     use IO::File;
3390     #...
3391     sub read_myfile_munged {
3392         my $ALL = shift;
3393         my $handle = new IO::File;
3394         open($handle, "myfile") or die "myfile: $!";
3395         $first = <$handle>
3396             or return ();     # Automatically closed here.
3397         mung $first or die "mung failed";       # Or here.
3398         return $first, <$handle> if $ALL;       # Or here.
3399         $first;                                 # Or here.
3400     }
3401
3402 See L</seek> for some details about mixing reading and writing.
3403
3404 =item opendir DIRHANDLE,EXPR
3405 X<opendir>
3406
3407 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3408 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3409 DIRHANDLE may be an expression whose value can be used as an indirect
3410 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3411 scalar variable (or array or hash element), the variable is assigned a
3412 reference to a new anonymous dirhandle.
3413 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3414
3415 =item ord EXPR
3416 X<ord> X<encoding>
3417
3418 =item ord
3419
3420 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3421 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3422 uses C<$_>.
3423
3424 For the reverse, see L</chr>.
3425 See L<perlunicode> and L<encoding> for more about Unicode.
3426
3427 =item our EXPR
3428 X<our> X<global>
3429
3430 =item our EXPR TYPE
3431
3432 =item our EXPR : ATTRS
3433
3434 =item our TYPE EXPR : ATTRS
3435
3436 C<our> associates a simple name with a package variable in the current
3437 package for use within the current scope.  When C<use strict 'vars'> is in
3438 effect, C<our> lets you use declared global variables without qualifying
3439 them with package names, within the lexical scope of the C<our> declaration.
3440 In this way C<our> differs from C<use vars>, which is package scoped.
3441
3442 Unlike C<my>, which both allocates storage for a variable and associates
3443 a simple name with that storage for use within the current scope, C<our>
3444 associates a simple name with a package variable in the current package,
3445 for use within the current scope.  In other words, C<our> has the same
3446 scoping rules as C<my>, but does not necessarily create a
3447 variable.
3448
3449 If more than one value is listed, the list must be placed
3450 in parentheses.
3451
3452     our $foo;
3453     our($bar, $baz);
3454
3455 An C<our> declaration declares a global variable that will be visible
3456 across its entire lexical scope, even across package boundaries.  The
3457 package in which the variable is entered is determined at the point
3458 of the declaration, not at the point of use.  This means the following
3459 behavior holds:
3460
3461     package Foo;
3462     our $bar;           # declares $Foo::bar for rest of lexical scope
3463     $bar = 20;
3464
3465     package Bar;
3466     print $bar;         # prints 20, as it refers to $Foo::bar
3467
3468 Multiple C<our> declarations with the same name in the same lexical
3469 scope are allowed if they are in different packages.  If they happen
3470 to be in the same package, Perl will emit warnings if you have asked
3471 for them, just like multiple C<my> declarations.  Unlike a second
3472 C<my> declaration, which will bind the name to a fresh variable, a
3473 second C<our> declaration in the same package, in the same scope, is
3474 merely redundant.
3475
3476     use warnings;
3477     package Foo;
3478     our $bar;           # declares $Foo::bar for rest of lexical scope
3479     $bar = 20;
3480
3481     package Bar;
3482     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3483     print $bar;         # prints 30
3484
3485     our $bar;           # emits warning but has no other effect
3486     print $bar;         # still prints 30
3487
3488 An C<our> declaration may also have a list of attributes associated
3489 with it.
3490
3491 The exact semantics and interface of TYPE and ATTRS are still
3492 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3493 and attributes are handled using the C<attributes> pragma, or starting
3494 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3495 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3496 L<attributes>, and L<Attribute::Handlers>.
3497
3498 =item pack TEMPLATE,LIST
3499 X<pack>
3500
3501 Takes a LIST of values and converts it into a string using the rules
3502 given by the TEMPLATE.  The resulting string is the concatenation of
3503 the converted values.  Typically, each converted value looks
3504 like its machine-level representation.  For example, on 32-bit machines
3505 an integer may be represented by a sequence of 4 bytes that will be 
3506 converted to a sequence of 4 characters.
3507
3508 The TEMPLATE is a sequence of characters that give the order and type
3509 of values, as follows:
3510
3511     a   A string with arbitrary binary data, will be null padded.
3512     A   A text (ASCII) string, will be space padded.
3513     Z   A null terminated (ASCIZ) string, will be null padded.
3514
3515     b   A bit string (ascending bit order inside each byte, like vec()).
3516     B   A bit string (descending bit order inside each byte).
3517     h   A hex string (low nybble first).
3518     H   A hex string (high nybble first).
3519
3520     c   A signed char (8-bit) value.
3521     C   An unsigned C char (octet) even under Unicode. Should normally not
3522         be used. See U and W instead.
3523     W   An unsigned char value (can be greater than 255).
3524
3525     s   A signed short (16-bit) value.
3526     S   An unsigned short value.
3527
3528     l   A signed long (32-bit) value.
3529     L   An unsigned long value.
3530
3531     q   A signed quad (64-bit) value.
3532     Q   An unsigned quad value.
3533           (Quads are available only if your system supports 64-bit
3534            integer values _and_ if Perl has been compiled to support those.
3535            Causes a fatal error otherwise.)
3536
3537     i   A signed integer value.
3538     I   A unsigned integer value.
3539           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3540            size depends on what a local C compiler calls 'int'.)
3541
3542     n   An unsigned short (16-bit) in "network" (big-endian) order.
3543     N   An unsigned long (32-bit) in "network" (big-endian) order.
3544     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3545     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3546
3547     j   A Perl internal signed integer value (IV).
3548     J   A Perl internal unsigned integer value (UV).
3549
3550     f   A single-precision float in the native format.
3551     d   A double-precision float in the native format.
3552
3553     F   A Perl internal floating point value (NV) in the native format
3554     D   A long double-precision float in the native format.
3555           (Long doubles are available only if your system supports long
3556            double values _and_ if Perl has been compiled to support those.
3557            Causes a fatal error otherwise.)
3558
3559     p   A pointer to a null-terminated string.
3560     P   A pointer to a structure (fixed-length string).
3561
3562     u   A uuencoded string.
3563     U   A Unicode character number.  Encodes to UTF-8 internally
3564         (or UTF-EBCDIC in EBCDIC platforms).
3565
3566     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3567         details).  Its bytes represent an unsigned integer in base 128,
3568         most significant digit first, with as few digits as possible.  Bit
3569         eight (the high bit) is set on each byte except the last.
3570
3571     x   A null byte.
3572     X   Back up a byte.
3573     @   Null fill or truncate to absolute position, counted from the
3574         start of the innermost ()-group.
3575     .   Null fill or truncate to absolute position specified by value.
3576     (   Start of a ()-group.
3577
3578 One or more of the modifiers below may optionally follow some letters in the
3579 TEMPLATE (the second column lists the letters for which the modifier is
3580 valid):
3581
3582     !   sSlLiI     Forces native (short, long, int) sizes instead
3583                    of fixed (16-/32-bit) sizes.
3584
3585         xX         Make x and X act as alignment commands.
3586
3587         nNvV       Treat integers as signed instead of unsigned.
3588
3589         @.         Specify position as byte offset in the internal
3590                    representation of the packed string. Efficient but
3591                    dangerous.
3592
3593     >   sSiIlLqQ   Force big-endian byte-order on the type.
3594         jJfFdDpP   (The "big end" touches the construct.)
3595
3596     <   sSiIlLqQ   Force little-endian byte-order on the type.
3597         jJfFdDpP   (The "little end" touches the construct.)
3598
3599 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3600 in which case they force a certain byte-order on all components of
3601 that group, including subgroups.
3602
3603 The following rules apply:
3604
3605 =over 8
3606
3607 =item *
3608
3609 Each letter may optionally be followed by a number giving a repeat
3610 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3611 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3612 that many values from the LIST.  A C<*> for the repeat count means to
3613 use however many items are left, except for C<@>, C<x>, C<X>, where it
3614 is equivalent to C<0>, for <.> where it means relative to string start
3615 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3616 A numeric repeat count may optionally be enclosed in brackets, as in
3617 C<pack 'C[80]', @arr>.
3618
3619 One can replace the numeric repeat count by a template enclosed in brackets;
3620 then the packed length of this template in bytes is used as a count.
3621 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3622 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3623 If the template in brackets contains alignment commands (such as C<x![d]>),
3624 its packed length is calculated as if the start of the template has the maximal
3625 possible alignment.
3626
3627 When used with C<Z>, C<*> results in the addition of a trailing null
3628 byte (so the packed result will be one longer than the byte C<length>
3629 of the item).
3630
3631 When used with C<@>, the repeat count represents an offset from the start
3632 of the innermost () group.
3633
3634 When used with C<.>, the repeat count is used to determine the starting
3635 position from where the value offset is calculated. If the repeat count
3636 is 0, it's relative to the current position. If the repeat count is C<*>,
3637 the offset is relative to the start of the packed string. And if its an
3638 integer C<n> the offset is relative to the start of the n-th innermost
3639 () group (or the start of the string if C<n> is bigger then the group
3640 level).
3641
3642 The repeat count for C<u> is interpreted as the maximal number of bytes
3643 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3644 count should not be more than 65.
3645
3646 =item *
3647
3648 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3649 string of length count, padding with nulls or spaces as necessary.  When
3650 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3651 after the first null, and C<a> returns data verbatim.
3652
3653 If the value-to-pack is too long, it is truncated.  If too long and an
3654 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3655 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3656 count is 0).
3657
3658 =item *
3659
3660 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3661 Each character of the input field of pack() generates 1 bit of the result.
3662 Each result bit is based on the least-significant bit of the corresponding
3663 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3664 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3665
3666 Starting from the beginning of the input string of pack(), each 8-tuple
3667 of characters is converted to 1 character of output.  With format C<b>
3668 the first character of the 8-tuple determines the least-significant bit of a
3669 character, and with format C<B> it determines the most-significant bit of
3670 a character.
3671
3672 If the length of the input string is not exactly divisible by 8, the
3673 remainder is packed as if the input string were padded by null characters
3674 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3675
3676 If the input string of pack() is longer than needed, extra characters are 
3677 ignored. A C<*> for the repeat count of pack() means to use all the 
3678 characters of the input field.  On unpack()ing the bits are converted to a 
3679 string of C<"0">s and C<"1">s.
3680
3681 =item *
3682
3683 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3684 representable as hexadecimal digits, 0-9a-f) long.
3685
3686 Each character of the input field of pack() generates 4 bits of the result.
3687 For non-alphabetical characters the result is based on the 4 least-significant
3688 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3689 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3690 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3691 is compatible with the usual hexadecimal digits, so that C<"a"> and
3692 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3693 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3694
3695 Starting from the beginning of the input string of pack(), each pair
3696 of characters is converted to 1 character of output.  With format C<h> the
3697 first character of the pair determines the least-significant nybble of the
3698 output character, and with format C<H> it determines the most-significant
3699 nybble.
3700
3701 If the length of the input string is not even, it behaves as if padded
3702 by a null character at the end.  Similarly, during unpack()ing the "extra"
3703 nybbles are ignored.
3704
3705 If the input string of pack() is longer than needed, extra characters are
3706 ignored.
3707 A C<*> for the repeat count of pack() means to use all the characters of
3708 the input field.  On unpack()ing the nybbles are converted to a string
3709 of hexadecimal digits.
3710
3711 =item *
3712
3713 The C<p> type packs a pointer to a null-terminated string.  You are
3714 responsible for ensuring the string is not a temporary value (which can
3715 potentially get deallocated before you get around to using the packed result).
3716 The C<P> type packs a pointer to a structure of the size indicated by the
3717 length.  A NULL pointer is created if the corresponding value for C<p> or
3718 C<P> is C<undef>, similarly for unpack().
3719
3720 If your system has a strange pointer size (i.e. a pointer is neither as
3721 big as an int nor as big as a long), it may not be possible to pack or
3722 unpack pointers in big- or little-endian byte order.  Attempting to do
3723 so will result in a fatal error.
3724
3725 =item *
3726
3727 The C</> template character allows packing and unpacking of a sequence of
3728 items where the packed structure contains a packed item count followed by 
3729 the packed items themselves.
3730 You write I<length-item>C</>I<sequence-item>.
3731
3732 The I<length-item> can be any C<pack> template letter, and describes
3733 how the length value is packed.  The ones likely to be of most use are
3734 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3735 SNMP) and C<N> (for Sun XDR).
3736
3737 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3738 the minimum of that and the number of available items is used as argument
3739 for the I<length-item>. If it has no repeat count or uses a '*', the number
3740 of available items is used. For C<unpack> the repeat count is always obtained
3741 by decoding the packed item count, and the I<sequence-item> must not have a
3742 repeat count.
3743
3744 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3745 the I<length-item> is a string length, not a number of strings. If there is
3746 an explicit repeat count for pack, the packed string will be adjusted to that
3747 given length.
3748
3749     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3750     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3751     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3752     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3753
3754 The I<length-item> is not returned explicitly from C<unpack>.
3755
3756 Adding a count to the I<length-item> letter is unlikely to do anything
3757 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3758 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3759 which Perl does not regard as legal in numeric strings.
3760
3761 =item *
3762
3763 The integer types C<s>, C<S>, C<l>, and C<L> may be
3764 followed by a C<!> modifier to signify native shorts or
3765 longs--as you can see from above for example a bare C<l> does mean
3766 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3767 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3768 see whether using C<!> makes any difference by
3769
3770         print length(pack("s")), " ", length(pack("s!")), "\n";
3771         print length(pack("l")), " ", length(pack("l!")), "\n";
3772
3773 C<i!> and C<I!> also work but only because of completeness;
3774 they are identical to C<i> and C<I>.
3775
3776 The actual sizes (in bytes) of native shorts, ints, longs, and long
3777 longs on the platform where Perl was built are also available via
3778 L<Config>:
3779
3780        use Config;
3781        print $Config{shortsize},    "\n";
3782        print $Config{intsize},      "\n";
3783        print $Config{longsize},     "\n";
3784        print $Config{longlongsize}, "\n";
3785
3786 (The C<$Config{longlongsize}> will be undefined if your system does
3787 not support long longs.)
3788
3789 =item *
3790
3791 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3792 are inherently non-portable between processors and operating systems
3793 because they obey the native byteorder and endianness.  For example a
3794 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3795 (arranged in and handled by the CPU registers) into bytes as
3796
3797         0x12 0x34 0x56 0x78     # big-endian
3798         0x78 0x56 0x34 0x12     # little-endian
3799
3800 Basically, the Intel and VAX CPUs are little-endian, while everybody
3801 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3802 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3803 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3804 mode.
3805
3806 The names `big-endian' and `little-endian' are comic references to
3807 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3808 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3809 the egg-eating habits of the Lilliputians.
3810
3811 Some systems may have even weirder byte orders such as
3812
3813         0x56 0x78 0x12 0x34
3814         0x34 0x12 0x78 0x56
3815
3816 You can see your system's preference with
3817
3818         print join(" ", map { sprintf "%#02x", $_ }
3819                             unpack("W*",pack("L",0x12345678))), "\n";
3820
3821 The byteorder on the platform where Perl was built is also available
3822 via L<Config>:
3823
3824         use Config;
3825         print $Config{byteorder}, "\n";
3826
3827 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3828 and C<'87654321'> are big-endian.
3829
3830 If you want portable packed integers you can either use the formats
3831 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3832 modifiers.  These modifiers are only available as of perl 5.9.2.
3833 See also L<perlport>.
3834
3835 =item *
3836
3837 All integer and floating point formats as well as C<p> and C<P> and
3838 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3839 to force big- or little- endian byte-order, respectively.
3840 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3841 signed integers, 64-bit integers and floating point values.  However,
3842 there are some things to keep in mind.
3843
3844 Exchanging signed integers between different platforms only works
3845 if all platforms store them in the same format.  Most platforms store
3846 signed integers in two's complement, so usually this is not an issue.
3847
3848 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3849 formats on big- or little-endian machines.  Otherwise, attempting to
3850 do so will result in a fatal error.
3851
3852 Forcing big- or little-endian byte-order on floating point values for
3853 data exchange can only work if all platforms are using the same
3854 binary representation (e.g. IEEE floating point format).  Even if all
3855 platforms are using IEEE, there may be subtle differences.  Being able
3856 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3857 but also very dangerous if you don't know exactly what you're doing.
3858 It is definitely not a general way to portably store floating point
3859 values.
3860
3861 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3862 all types inside the group that accept the byte-order modifiers,
3863 including all subgroups.  It will silently be ignored for all other
3864 types.  You are not allowed to override the byte-order within a group
3865 that already has a byte-order modifier suffix.
3866
3867 =item *
3868
3869 Real numbers (floats and doubles) are in the native machine format only;
3870 due to the multiplicity of floating formats around, and the lack of a
3871 standard "network" representation, no facility for interchange has been
3872 made.  This means that packed floating point data written on one machine
3873 may not be readable on another - even if both use IEEE floating point
3874 arithmetic (as the endian-ness of the memory representation is not part
3875 of the IEEE spec).  See also L<perlport>.
3876
3877 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3878 modifiers to force big- or little-endian byte-order on floating point values.
3879
3880 Note that Perl uses doubles (or long doubles, if configured) internally for
3881 all numeric calculation, and converting from double into float and thence back
3882 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3883 will not in general equal $foo).
3884
3885 =item *
3886
3887 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3888 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3889 where the packed string is processed in its UTF-8-encoded Unicode form on
3890 a byte by byte basis. Character mode is the default unless the format string 
3891 starts with an C<U>. You can switch mode at any moment with an explicit 
3892 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3893 or until the end of the ()-group in which it was entered.
3894
3895 =item *
3896
3897 You must yourself do any alignment or padding by inserting for example
3898 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3899 could know where the characters are going to or coming from.  Therefore
3900 C<pack> (and C<unpack>) handle their output and input as flat
3901 sequences of characters.
3902
3903 =item *
3904
3905 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3906 take a repeat count, both as postfix, and for unpack() also via the C</>
3907 template character. Within each repetition of a group, positioning with
3908 C<@> starts again at 0. Therefore, the result of
3909
3910     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3911
3912 is the string "\0a\0\0bc".
3913
3914 =item *
3915
3916 C<x> and C<X> accept C<!> modifier.  In this case they act as
3917 alignment commands: they jump forward/back to the closest position
3918 aligned at a multiple of C<count> characters. For example, to pack() or
3919 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3920 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3921 aligned on the double's size.
3922
3923 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3924 both result in no-ops.
3925
3926 =item *
3927
3928 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3929 will represent signed 16-/32-bit integers in big-/little-endian order.
3930 This is only portable if all platforms sharing the packed data use the
3931 same binary representation for signed integers (e.g. all platforms are
3932 using two's complement representation).
3933
3934 =item *
3935
3936 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3937 White space may be used to separate pack codes from each other, but
3938 modifiers and a repeat count must follow immediately.
3939
3940 =item *
3941
3942 If TEMPLATE requires more arguments to pack() than actually given, pack()
3943 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3944 to pack() than actually given, extra arguments are ignored.
3945
3946 =back
3947
3948 Examples:
3949
3950     $foo = pack("WWWW",65,66,67,68);
3951     # foo eq "ABCD"
3952     $foo = pack("W4",65,66,67,68);
3953     # same thing
3954     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3955     # same thing with Unicode circled letters.
3956     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3957     # same thing with Unicode circled letters. You don't get the UTF-8
3958     # bytes because the U at the start of the format caused a switch to
3959     # U0-mode, so the UTF-8 bytes get joined into characters
3960     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3961     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3962     # This is the UTF-8 encoding of the string in the previous example
3963
3964     $foo = pack("ccxxcc",65,66,67,68);
3965     # foo eq "AB\0\0CD"
3966
3967     # note: the above examples featuring "W" and "c" are true
3968     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3969     # and UTF-8.  In EBCDIC the first example would be
3970     # $foo = pack("WWWW",193,194,195,196);
3971
3972     $foo = pack("s2",1,2);
3973     # "\1\0\2\0" on little-endian
3974     # "\0\1\0\2" on big-endian
3975
3976     $foo = pack("a4","abcd","x","y","z");
3977     # "abcd"
3978
3979     $foo = pack("aaaa","abcd","x","y","z");
3980     # "axyz"
3981
3982     $foo = pack("a14","abcdefg");
3983     # "abcdefg\0\0\0\0\0\0\0"
3984
3985     $foo = pack("i9pl", gmtime);
3986     # a real struct tm (on my system anyway)
3987
3988     $utmp_template = "Z8 Z8 Z16 L";
3989     $utmp = pack($utmp_template, @utmp1);
3990     # a struct utmp (BSDish)
3991
3992     @utmp2 = unpack($utmp_template, $utmp);
3993     # "@utmp1" eq "@utmp2"
3994
3995     sub bintodec {
3996         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3997     }
3998
3999     $foo = pack('sx2l', 12, 34);
4000     # short 12, two zero bytes padding, long 34
4001     $bar = pack('s@4l', 12, 34);
4002     # short 12, zero fill to position 4, long 34
4003     # $foo eq $bar
4004     $baz = pack('s.l', 12, 4, 34);
4005     # short 12, zero fill to position 4, long 34
4006
4007     $foo = pack('nN', 42, 4711);
4008     # pack big-endian 16- and 32-bit unsigned integers
4009     $foo = pack('S>L>', 42, 4711);
4010     # exactly the same
4011     $foo = pack('s<l<', -42, 4711);
4012     # pack little-endian 16- and 32-bit signed integers
4013     $foo = pack('(sl)<', -42, 4711);
4014     # exactly the same
4015
4016 The same template may generally also be used in unpack().
4017
4018 =item package NAMESPACE
4019 X<package> X<module> X<namespace>
4020
4021 =item package
4022
4023 Declares the compilation unit as being in the given namespace.  The scope
4024 of the package declaration is from the declaration itself through the end
4025 of the enclosing block, file, or eval (the same as the C<my> operator).
4026 All further unqualified dynamic identifiers will be in this namespace.
4027 A package statement affects only dynamic variables--including those
4028 you've used C<local> on--but I<not> lexical variables, which are created
4029 with C<my>.  Typically it would be the first declaration in a file to
4030 be included by the C<require> or C<use> operator.  You can switch into a
4031 package in more than one place; it merely influences which symbol table
4032 is used by the compiler for the rest of that block.  You can refer to
4033 variables and filehandles in other packages by prefixing the identifier
4034 with the package name and a double colon:  C<$Package::Variable>.
4035 If the package name is null, the C<main> package as assumed.  That is,
4036 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4037 still seen in older code).
4038
4039 If NAMESPACE is omitted, then there is no current package, and all
4040 identifiers must be fully qualified or lexicals.  However, you are
4041 strongly advised not to make use of this feature. Its use can cause
4042 unexpected behaviour, even crashing some versions of Perl. It is
4043 deprecated, and will be removed from a future release.
4044
4045 See L<perlmod/"Packages"> for more information about packages, modules,
4046 and classes.  See L<perlsub> for other scoping issues.
4047
4048 =item pipe READHANDLE,WRITEHANDLE
4049 X<pipe>
4050
4051 Opens a pair of connected pipes like the corresponding system call.
4052 Note that if you set up a loop of piped processes, deadlock can occur
4053 unless you are very careful.  In addition, note that Perl's pipes use
4054 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4055 after each command, depending on the application.
4056
4057 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4058 for examples of such things.
4059
4060 On systems that support a close-on-exec flag on files, the flag will be set
4061 for the newly opened file descriptors as determined by the value of $^F.
4062 See L<perlvar/$^F>.
4063
4064 =item pop ARRAY
4065 X<pop> X<stack>
4066
4067 =item pop
4068
4069 Pops and returns the last value of the array, shortening the array by
4070 one element.  Has an effect similar to
4071
4072     $ARRAY[$#ARRAY--]
4073
4074 If there are no elements in the array, returns the undefined value
4075 (although this may happen at other times as well).  If ARRAY is
4076 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4077 array in subroutines, just like C<shift>.
4078
4079 =item pos SCALAR
4080 X<pos> X<match, position>
4081
4082 =item pos
4083
4084 Returns the offset of where the last C<m//g> search left off for the variable
4085 in question (C<$_> is used when the variable is not specified).  Note that
4086 0 is a valid match offset.  C<undef> indicates that the search position
4087 is reset (usually due to match failure, but can also be because no match has
4088 yet been performed on the scalar). C<pos> directly accesses the location used
4089 by the regexp engine to store the offset, so assigning to C<pos> will change
4090 that offset, and so will also influence the C<\G> zero-width assertion in
4091 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4092 the return from C<pos> won't change either in this case.  See L<perlre> and
4093 L<perlop>.
4094
4095 =item print FILEHANDLE LIST
4096 X<print>
4097
4098 =item print LIST
4099
4100 =item print
4101
4102 Prints a string or a list of strings.  Returns true if successful.
4103 FILEHANDLE may be a scalar variable name, in which case the variable
4104 contains the name of or a reference to the filehandle, thus introducing
4105 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4106 the next token is a term, it may be misinterpreted as an operator
4107 unless you interpose a C<+> or put parentheses around the arguments.)
4108 If FILEHANDLE is omitted, prints by default to standard output (or
4109 to the last selected output channel--see L</select>).  If LIST is
4110 also omitted, prints C<$_> to the currently selected output channel.
4111 To set the default output channel to something other than STDOUT
4112 use the select operation.  The current value of C<$,> (if any) is
4113 printed between each LIST item.  The current value of C<$\> (if
4114 any) is printed after the entire LIST has been printed.  Because
4115 print takes a LIST, anything in the LIST is evaluated in list
4116 context, and any subroutine that you call will have one or more of
4117 its expressions evaluated in list context.  Also be careful not to
4118 follow the print keyword with a left parenthesis unless you want
4119 the corresponding right parenthesis to terminate the arguments to
4120 the print--interpose a C<+> or put parentheses around all the
4121 arguments.
4122
4123 Note that if you're storing FILEHANDLEs in an array, or if you're using
4124 any other expression more complex than a scalar variable to retrieve it,
4125 you will have to use a block returning the filehandle value instead:
4126
4127     print { $files[$i] } "stuff\n";
4128     print { $OK ? STDOUT : STDERR } "stuff\n";
4129
4130 =item printf FILEHANDLE FORMAT, LIST
4131 X<printf>
4132
4133 =item printf FORMAT, LIST
4134
4135 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4136 (the output record separator) is not appended.  The first argument
4137 of the list will be interpreted as the C<printf> format. See C<sprintf>
4138 for an explanation of the format argument. If C<use locale> is in effect,
4139 the character used for the decimal point in formatted real numbers is
4140 affected by the LC_NUMERIC locale.  See L<perllocale>.
4141
4142 Don't fall into the trap of using a C<printf> when a simple
4143 C<print> would do.  The C<print> is more efficient and less
4144 error prone.
4145
4146 =item prototype FUNCTION
4147 X<prototype>
4148
4149 Returns the prototype of a function as a string (or C<undef> if the
4150 function has no prototype).  FUNCTION is a reference to, or the name of,
4151 the function whose prototype you want to retrieve.
4152
4153 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4154 name for Perl builtin.  If the builtin is not I<overridable> (such as
4155 C<qw//>) or its arguments cannot be expressed by a prototype (such as
4156 C<system>) returns C<undef> because the builtin does not really behave
4157 like a Perl function.  Otherwise, the string describing the equivalent
4158 prototype is returned.
4159
4160 =item push ARRAY,LIST
4161 X<push>, X<stack>
4162
4163 Treats ARRAY as a stack, and pushes the values of LIST
4164 onto the end of ARRAY.  The length of ARRAY increases by the length of
4165 LIST.  Has the same effect as
4166
4167     for $value (LIST) {
4168         $ARRAY[++$#ARRAY] = $value;
4169     }
4170
4171 but is more efficient.  Returns the number of elements in the array following
4172 the completed C<push>.
4173
4174 =item q/STRING/
4175
4176 =item qq/STRING/
4177
4178 =item qr/STRING/
4179
4180 =item qx/STRING/
4181
4182 =item qw/STRING/
4183
4184 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4185
4186 =item quotemeta EXPR
4187 X<quotemeta> X<metacharacter>
4188
4189 =item quotemeta
4190
4191 Returns the value of EXPR with all non-"word"
4192 characters backslashed.  (That is, all characters not matching
4193 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4194 returned string, regardless of any locale settings.)
4195 This is the internal function implementing
4196 the C<\Q> escape in double-quoted strings.
4197
4198 If EXPR is omitted, uses C<$_>.
4199
4200 =item rand EXPR
4201 X<rand> X<random>
4202
4203 =item rand
4204
4205 Returns a random fractional number greater than or equal to C<0> and less
4206 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4207 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4208 also special-cased as C<1> - this has not been documented before perl 5.8.0
4209 and is subject to change in future versions of perl.  Automatically calls
4210 C<srand> unless C<srand> has already been called.  See also C<srand>.
4211
4212 Apply C<int()> to the value returned by C<rand()> if you want random
4213 integers instead of random fractional numbers.  For example,
4214
4215     int(rand(10))
4216
4217 returns a random integer between C<0> and C<9>, inclusive.
4218
4219 (Note: If your rand function consistently returns numbers that are too
4220 large or too small, then your version of Perl was probably compiled
4221 with the wrong number of RANDBITS.)
4222
4223 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4224 X<read>
4225
4226 =item read FILEHANDLE,SCALAR,LENGTH
4227
4228 Attempts to read LENGTH I<characters> of data into variable SCALAR
4229 from the specified FILEHANDLE.  Returns the number of characters
4230 actually read, C<0> at end of file, or undef if there was an error (in
4231 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4232 so that the last character actually read is the last character of the
4233 scalar after the read.
4234
4235 An OFFSET may be specified to place the read data at some place in the
4236 string other than the beginning.  A negative OFFSET specifies
4237 placement at that many characters counting backwards from the end of
4238 the string.  A positive OFFSET greater than the length of SCALAR
4239 results in the string being padded to the required size with C<"\0">
4240 bytes before the result of the read is appended.
4241
4242 The call is actually implemented in terms of either Perl's or system's
4243 fread() call.  To get a true read(2) system call, see C<sysread>.
4244
4245 Note the I<characters>: depending on the status of the filehandle,
4246 either (8-bit) bytes or characters are read.  By default all
4247 filehandles operate on bytes, but for example if the filehandle has
4248 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4249 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4250 characters, not bytes.  Similarly for the C<:encoding> pragma:
4251 in that case pretty much any characters can be read.
4252
4253 =item readdir DIRHANDLE
4254 X<readdir>
4255
4256 Returns the next directory entry for a directory opened by C<opendir>.
4257 If used in list context, returns all the rest of the entries in the
4258 directory.  If there are no more entries, returns an undefined value in
4259 scalar context or a null list in list context.
4260
4261 If you're planning to filetest the return values out of a C<readdir>, you'd
4262 better prepend the directory in question.  Otherwise, because we didn't
4263 C<chdir> there, it would have been testing the wrong file.
4264
4265     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4266     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4267     closedir DIR;
4268
4269 =item readline EXPR
4270 X<readline> X<gets> X<fgets>
4271
4272 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4273 context, each call reads and returns the next line, until end-of-file is
4274 reached, whereupon the subsequent call returns undef.  In list context,
4275 reads until end-of-file is reached and returns a list of lines.  Note that
4276 the notion of "line" used here is however you may have defined it
4277 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4278
4279 When C<$/> is set to C<undef>, when readline() is in scalar
4280 context (i.e. file slurp mode), and when an empty file is read, it
4281 returns C<''> the first time, followed by C<undef> subsequently.
4282
4283 This is the internal function implementing the C<< <EXPR> >>
4284 operator, but you can use it directly.  The C<< <EXPR> >>
4285 operator is discussed in more detail in L<perlop/"I/O Operators">.
4286
4287     $line = <STDIN>;
4288     $line = readline(*STDIN);           # same thing
4289
4290 If readline encounters an operating system error, C<$!> will be set with the
4291 corresponding error message.  It can be helpful to check C<$!> when you are
4292 reading from filehandles you don't trust, such as a tty or a socket.  The
4293 following example uses the operator form of C<readline>, and takes the necessary
4294 steps to ensure that C<readline> was successful.
4295
4296     for (;;) {
4297         undef $!;
4298         unless (defined( $line = <> )) {
4299             die $! if $!;
4300             last; # reached EOF
4301         }
4302         # ...
4303     }
4304
4305 =item readlink EXPR
4306 X<readlink>
4307
4308 =item readlink
4309
4310 Returns the value of a symbolic link, if symbolic links are
4311 implemented.  If not, gives a fatal error.  If there is some system
4312 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4313 omitted, uses C<$_>.
4314
4315 =item readpipe EXPR
4316 X<readpipe>
4317
4318 EXPR is executed as a system command.
4319 The collected standard output of the command is returned.
4320 In scalar context, it comes back as a single (potentially
4321 multi-line) string.  In list context, returns a list of lines
4322 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4323 This is the internal function implementing the C<qx/EXPR/>
4324 operator, but you can use it directly.  The C<qx/EXPR/>
4325 operator is discussed in more detail in L<perlop/"I/O Operators">.
4326
4327 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4328 X<recv>
4329
4330 Receives a message on a socket.  Attempts to receive LENGTH characters
4331 of data into variable SCALAR from the specified SOCKET filehandle.
4332 SCALAR will be grown or shrunk to the length actually read.  Takes the
4333 same flags as the system call of the same name.  Returns the address
4334 of the sender if SOCKET's protocol supports this; returns an empty
4335 string otherwise.  If there's an error, returns the undefined value.
4336 This call is actually implemented in terms of recvfrom(2) system call.
4337 See L<perlipc/"UDP: Message Passing"> for examples.
4338
4339 Note the I<characters>: depending on the status of the socket, either
4340 (8-bit) bytes or characters are received.  By default all sockets
4341 operate on bytes, but for example if the socket has been changed using
4342 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4343 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4344 characters, not bytes.  Similarly for the C<:encoding> pragma:
4345 in that case pretty much any characters can be read.
4346
4347 =item redo LABEL
4348 X<redo>
4349
4350 =item redo
4351
4352 The C<redo> command restarts the loop block without evaluating the
4353 conditional again.  The C<continue> block, if any, is not executed.  If
4354 the LABEL is omitted, the command refers to the innermost enclosing
4355 loop.  Programs that want to lie to themselves about what was just input 
4356 normally use this command:
4357
4358     # a simpleminded Pascal comment stripper
4359     # (warning: assumes no { or } in strings)
4360     LINE: while (<STDIN>) {
4361         while (s|({.*}.*){.*}|$1 |) {}
4362         s|{.*}| |;
4363         if (s|{.*| |) {
4364             $front = $_;
4365             while (<STDIN>) {
4366                 if (/}/) {      # end of comment?
4367                     s|^|$front\{|;
4368                     redo LINE;
4369                 }
4370             }
4371         }
4372         print;
4373     }
4374
4375 C<redo> cannot be used to retry a block which returns a value such as
4376 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4377 a grep() or map() operation.
4378
4379 Note that a block by itself is semantically identical to a loop
4380 that executes once.  Thus C<redo> inside such a block will effectively
4381 turn it into a looping construct.
4382
4383 See also L</continue> for an illustration of how C<last>, C<next>, and
4384 C<redo> work.
4385
4386 =item ref EXPR
4387 X<ref> X<reference>
4388
4389 =item ref
4390
4391 Returns a non-empty string if EXPR is a reference, the empty
4392 string otherwise. If EXPR
4393 is not specified, C<$_> will be used.  The value returned depends on the
4394 type of thing the reference is a reference to.
4395 Builtin types include:
4396
4397     SCALAR
4398     ARRAY
4399     HASH
4400     CODE
4401     REF
4402     GLOB
4403     LVALUE
4404
4405 If the referenced object has been blessed into a package, then that package
4406 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4407
4408     if (ref($r) eq "HASH") {
4409         print "r is a reference to a hash.\n";
4410     }
4411     unless (ref($r)) {
4412         print "r is not a reference at all.\n";
4413     }
4414
4415 See also L<perlref>.
4416
4417 =item rename OLDNAME,NEWNAME
4418 X<rename> X<move> X<mv> X<ren>
4419
4420 Changes the name of a file; an existing file NEWNAME will be
4421 clobbered.  Returns true for success, false otherwise.
4422
4423 Behavior of this function varies wildly depending on your system
4424 implementation.  For example, it will usually not work across file system
4425 boundaries, even though the system I<mv> command sometimes compensates
4426 for this.  Other restrictions include whether it works on directories,
4427 open files, or pre-existing files.  Check L<perlport> and either the
4428 rename(2) manpage or equivalent system documentation for details.
4429
4430 =item require VERSION
4431 X<require>
4432
4433 =item require EXPR
4434
4435 =item require
4436
4437 Demands a version of Perl specified by VERSION, or demands some semantics
4438 specified by EXPR or by C<$_> if EXPR is not supplied.
4439
4440 VERSION may be either a numeric argument such as 5.006, which will be
4441 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4442 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4443 VERSION is greater than the version of the current Perl interpreter.
4444 Compare with L</use>, which can do a similar check at compile time.
4445
4446 Specifying VERSION as a literal of the form v5.6.1 should generally be
4447 avoided, because it leads to misleading error messages under earlier
4448 versions of Perl that do not support this syntax.  The equivalent numeric
4449 version should be used instead.
4450
4451     require v5.6.1;     # run time version check
4452     require 5.6.1;      # ditto
4453     require 5.006_001;  # ditto; preferred for backwards compatibility
4454
4455 Otherwise, C<require> demands that a library file be included if it
4456 hasn't already been included.  The file is included via the do-FILE
4457 mechanism, which is essentially just a variety of C<eval>.  Has
4458 semantics similar to the following subroutine:
4459
4460     sub require {
4461        my ($filename) = @_;
4462        if (exists $INC{$filename}) {
4463            return 1 if $INC{$filename};
4464            die "Compilation failed in require";
4465        }
4466        my ($realfilename,$result);
4467        ITER: {
4468            foreach $prefix (@INC) {
4469                $realfilename = "$prefix/$filename";
4470                if (-f $realfilename) {
4471                    $INC{$filename} = $realfilename;
4472                    $result = do $realfilename;
4473                    last ITER;
4474                }
4475            }
4476            die "Can't find $filename in \@INC";
4477        }
4478        if ($@) {
4479            $INC{$filename} = undef;
4480            die $@;
4481        } elsif (!$result) {
4482            delete $INC{$filename};
4483            die "$filename did not return true value";
4484        } else {
4485            return $result;
4486        }
4487     }
4488
4489 Note that the file will not be included twice under the same specified
4490 name.
4491
4492 The file must return true as the last statement to indicate
4493 successful execution of any initialization code, so it's customary to
4494 end such a file with C<1;> unless you're sure it'll return true
4495 otherwise.  But it's better just to put the C<1;>, in case you add more
4496 statements.
4497
4498 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4499 replaces "F<::>" with "F</>" in the filename for you,
4500 to make it easy to load standard modules.  This form of loading of
4501 modules does not risk altering your namespace.
4502
4503 In other words, if you try this:
4504
4505         require Foo::Bar;    # a splendid bareword
4506
4507 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4508 directories specified in the C<@INC> array.
4509
4510 But if you try this:
4511
4512         $class = 'Foo::Bar';
4513         require $class;      # $class is not a bareword
4514     #or
4515         require "Foo::Bar";  # not a bareword because of the ""
4516
4517 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4518 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4519
4520         eval "require $class";
4521
4522 Now that you understand how C<require> looks for files in the case of a
4523 bareword argument, there is a little extra functionality going on behind
4524 the scenes.  Before C<require> looks for a "F<.pm>" extension, it will
4525 first look for a similar filename with a "F<.pmc>" extension. If this file
4526 is found, it will be loaded in place of any file ending in a "F<.pm>"
4527 extension.
4528
4529 You can also insert hooks into the import facility, by putting directly
4530 Perl code into the @INC array.  There are three forms of hooks: subroutine
4531 references, array references and blessed objects.
4532
4533 Subroutine references are the simplest case.  When the inclusion system
4534 walks through @INC and encounters a subroutine, this subroutine gets
4535 called with two parameters, the first being a reference to itself, and the
4536 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4537 subroutine should return nothing, or a list of up to 4 values in the
4538 following order:
4539
4540 =over
4541
4542 =item 1
4543
4544 A reference to a scalar, containing any initial source code to prepend to
4545 the file or generator output.
4546
4547
4548 =item 2
4549
4550 A filehandle, from which the file will be read.  
4551
4552 =item 3
4553
4554 A reference to a subroutine. If there is no file handle, then this subroutine
4555 is expected to generate one line of source code per call, writing the line
4556 into C<$_> and returning 1, then returning 0 at "end of FILE" If there is a
4557 file handle then the subroutine will be called to act a simple source filter,
4558 with the line as read in C<$_>. Again, return 1 for each valid line, and 0
4559 after all lines have been returned.
4560
4561 =item 4
4562
4563 Optional state for the subroutine. The state is passed in as C<$_[1]>. A
4564 reference to the subroutine itself is passed in as C<$_[0]>.
4565
4566 =back
4567
4568 If an empty list, C<undef>, or nothing that matches the first 3 values above
4569 is returned then C<require> will look at the remaining elements of @INC.
4570 Note that this file handle must be a real file handle (strictly a typeglob,
4571 or reference to a typeglob, blessed or unblessed) - tied file handles will be
4572 ignored and return value processing will stop there.
4573
4574 If the hook is an array reference, its first element must be a subroutine
4575 reference.  This subroutine is called as above, but the first parameter is
4576 the array reference.  This enables to pass indirectly some arguments to
4577 the subroutine.
4578
4579 In other words, you can write:
4580
4581     push @INC, \&my_sub;
4582     sub my_sub {
4583         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4584         ...
4585     }
4586
4587 or:
4588
4589     push @INC, [ \&my_sub, $x, $y, ... ];
4590     sub my_sub {
4591         my ($arrayref, $filename) = @_;
4592         # Retrieve $x, $y, ...
4593         my @parameters = @$arrayref[1..$#$arrayref];
4594         ...
4595     }
4596
4597 If the hook is an object, it must provide an INC method that will be
4598 called as above, the first parameter being the object itself.  (Note that
4599 you must fully qualify the sub's name, as unqualified C<INC> is always forced
4600 into package C<main>.)  Here is a typical code layout:
4601
4602     # In Foo.pm
4603     package Foo;
4604     sub new { ... }
4605     sub Foo::INC {
4606         my ($self, $filename) = @_;
4607         ...
4608     }
4609
4610     # In the main program
4611     push @INC, new Foo(...);
4612
4613 Note that these hooks are also permitted to set the %INC entry
4614 corresponding to the files they have loaded. See L<perlvar/%INC>.
4615
4616 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4617
4618 =item reset EXPR
4619 X<reset>
4620
4621 =item reset
4622
4623 Generally used in a C<continue> block at the end of a loop to clear