This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
avoid ass_u_ming uppercase types are not user objects (spotted
[perl5.git] / ext / Data / Dumper / Dumper.pm
1 #
2 # Data/Dumper.pm
3 #
4 # convert perl data structures into perl syntax suitable for both printing
5 # and eval
6 #
7 # Documentation at the __END__
8 #
9
10 package Data::Dumper;
11
12 $VERSION = $VERSION = '2.101';
13
14 #$| = 1;
15
16 require 5.004_02;
17 require Exporter;
18 require DynaLoader;
19 require overload;
20
21 use Carp;
22
23 @ISA = qw(Exporter DynaLoader);
24 @EXPORT = qw(Dumper);
25 @EXPORT_OK = qw(DumperX);
26
27 bootstrap Data::Dumper;
28
29 # module vars and their defaults
30 $Indent = 2 unless defined $Indent;
31 $Purity = 0 unless defined $Purity;
32 $Pad = "" unless defined $Pad;
33 $Varname = "VAR" unless defined $Varname;
34 $Useqq = 0 unless defined $Useqq;
35 $Terse = 0 unless defined $Terse;
36 $Freezer = "" unless defined $Freezer;
37 $Toaster = "" unless defined $Toaster;
38 $Deepcopy = 0 unless defined $Deepcopy;
39 $Quotekeys = 1 unless defined $Quotekeys;
40 $Bless = "bless" unless defined $Bless;
41 #$Expdepth = 0 unless defined $Expdepth;
42 $Maxdepth = 0 unless defined $Maxdepth;
43
44 #
45 # expects an arrayref of values to be dumped.
46 # can optionally pass an arrayref of names for the values.
47 # names must have leading $ sign stripped. begin the name with *
48 # to cause output of arrays and hashes rather than refs.
49 #
50 sub new {
51   my($c, $v, $n) = @_;
52
53   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])" 
54     unless (defined($v) && (ref($v) eq 'ARRAY'));
55   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
56
57   my($s) = { 
58              level      => 0,           # current recursive depth
59              indent     => $Indent,     # various styles of indenting
60              pad        => $Pad,        # all lines prefixed by this string
61              xpad       => "",          # padding-per-level
62              apad       => "",          # added padding for hash keys n such
63              sep        => "",          # list separator
64              seen       => {},          # local (nested) refs (id => [name, val])
65              todump     => $v,          # values to dump []
66              names      => $n,          # optional names for values []
67              varname    => $Varname,    # prefix to use for tagging nameless ones
68              purity     => $Purity,     # degree to which output is evalable
69              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
70              terse      => $Terse,      # avoid name output (where feasible)
71              freezer    => $Freezer,    # name of Freezer method for objects
72              toaster    => $Toaster,    # name of method to revive objects
73              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
74              quotekeys  => $Quotekeys,  # quote hash keys
75              'bless'    => $Bless,      # keyword to use for "bless"
76 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
77              maxdepth   => $Maxdepth,   # depth beyond which we give up
78            };
79
80   if ($Indent > 0) {
81     $s->{xpad} = "  ";
82     $s->{sep} = "\n";
83   }
84   return bless($s, $c);
85 }
86
87 #
88 # add-to or query the table of already seen references
89 #
90 sub Seen {
91   my($s, $g) = @_;
92   if (defined($g) && (ref($g) eq 'HASH'))  {
93     my($k, $v, $id);
94     while (($k, $v) = each %$g) {
95       if (defined $v and ref $v) {
96         ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
97         if ($k =~ /^[*](.*)$/) {
98           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
99                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
100                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
101                                      (   "\$" . $1 ) ;
102         }
103         elsif ($k !~ /^\$/) {
104           $k = "\$" . $k;
105         }
106         $s->{seen}{$id} = [$k, $v];
107       }
108       else {
109         carp "Only refs supported, ignoring non-ref item \$$k";
110       }
111     }
112     return $s;
113   }
114   else {
115     return map { @$_ } values %{$s->{seen}};
116   }
117 }
118
119 #
120 # set or query the values to be dumped
121 #
122 sub Values {
123   my($s, $v) = @_;
124   if (defined($v) && (ref($v) eq 'ARRAY'))  {
125     $s->{todump} = [@$v];        # make a copy
126     return $s;
127   }
128   else {
129     return @{$s->{todump}};
130   }
131 }
132
133 #
134 # set or query the names of the values to be dumped
135 #
136 sub Names {
137   my($s, $n) = @_;
138   if (defined($n) && (ref($n) eq 'ARRAY'))  {
139     $s->{names} = [@$n];         # make a copy
140     return $s;
141   }
142   else {
143     return @{$s->{names}};
144   }
145 }
146
147 sub DESTROY {}
148
149 #
150 # dump the refs in the current dumper object.
151 # expects same args as new() if called via package name.
152 #
153 sub Dump {
154   my($s) = shift;
155   my(@out, $val, $name);
156   my($i) = 0;
157   local(@post);
158
159   $s = $s->new(@_) unless ref $s;
160
161   for $val (@{$s->{todump}}) {
162     my $out = "";
163     @post = ();
164     $name = $s->{names}[$i++];
165     if (defined $name) {
166       if ($name =~ /^[*](.*)$/) {
167         if (defined $val) {
168           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
169                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
170                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
171                                           ( "\$" . $1 ) ;
172         }
173         else {
174           $name = "\$" . $1;
175         }
176       }
177       elsif ($name !~ /^\$/) {
178         $name = "\$" . $name;
179       }
180     }
181     else {
182       $name = "\$" . $s->{varname} . $i;
183     }
184
185     my $valstr;
186     {
187       local($s->{apad}) = $s->{apad};
188       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
189       $valstr = $s->_dump($val, $name);
190     }
191
192     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
193     $out .= $s->{pad} . $valstr . $s->{sep};
194     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post) 
195       . ';' . $s->{sep} if @post;
196
197     push @out, $out;
198   }
199   return wantarray ? @out : join('', @out);
200 }
201
202 #
203 # twist, toil and turn;
204 # and recurse, of course.
205 #
206 sub _dump {
207   my($s, $val, $name) = @_;
208   my($sname);
209   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
210
211   $type = ref $val;
212   $out = "";
213
214   if ($type) {
215
216     # prep it, if it looks like an object
217     if (my $freezer = $s->{freezer}) {
218       $val->$freezer() if UNIVERSAL::can($val, $freezer);
219     }
220
221     ($realpack, $realtype, $id) =
222       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
223
224     # if it has a name, we need to either look it up, or keep a tab
225     # on it so we know when we hit it later
226     if (defined($name) and length($name)) {
227       # keep a tab on it so that we dont fall into recursive pit
228       if (exists $s->{seen}{$id}) {
229 #       if ($s->{expdepth} < $s->{level}) {
230           if ($s->{purity} and $s->{level} > 0) {
231             $out = ($realtype eq 'HASH')  ? '{}' :
232               ($realtype eq 'ARRAY') ? '[]' :
233                 "''" ;
234             push @post, $name . " = " . $s->{seen}{$id}[0];
235           }
236           else {
237             $out = $s->{seen}{$id}[0];
238             if ($name =~ /^([\@\%])/) {
239               my $start = $1;
240               if ($out =~ /^\\$start/) {
241                 $out = substr($out, 1);
242               }
243               else {
244                 $out = $start . '{' . $out . '}';
245               }
246             }
247           }
248           return $out;
249 #        }
250       }
251       else {
252         # store our name
253         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
254                              ($realtype eq 'CODE' and
255                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
256                              $name          ),
257                             $val ];
258       }
259     }
260
261     if ($realpack and $realpack eq 'Regexp') {
262         $out = "$val";
263         $out =~ s,/,\\/,g;
264         return "qr/$out/";
265     }
266
267     # If purity is not set and maxdepth is set, then check depth: 
268     # if we have reached maximum depth, return the string
269     # representation of the thing we are currently examining
270     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)'). 
271     if (!$s->{purity}
272         and $s->{maxdepth} > 0
273         and $s->{level} >= $s->{maxdepth})
274     {
275       return qq['$val'];
276     }
277
278     # we have a blessed ref
279     if ($realpack) {
280       $out = $s->{'bless'} . '( ';
281       $blesspad = $s->{apad};
282       $s->{apad} .= '       ' if ($s->{indent} >= 2);
283     }
284
285     $s->{level}++;
286     $ipad = $s->{xpad} x $s->{level};
287
288     
289     if ($realtype eq 'SCALAR') {
290       if ($realpack) {
291         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
292       }
293       else {
294         $out .= '\\' . $s->_dump($$val, "\${$name}");
295       }
296     }
297     elsif ($realtype eq 'GLOB') {
298         $out .= '\\' . $s->_dump($$val, "*{$name}");
299     }
300     elsif ($realtype eq 'ARRAY') {
301       my($v, $pad, $mname);
302       my($i) = 0;
303       $out .= ($name =~ /^\@/) ? '(' : '[';
304       $pad = $s->{sep} . $s->{pad} . $s->{apad};
305       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) : 
306         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
307         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
308           ($mname = $name . '->');
309       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
310       for $v (@$val) {
311         $sname = $mname . '[' . $i . ']';
312         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
313         $out .= $pad . $ipad . $s->_dump($v, $sname);
314         $out .= "," if $i++ < $#$val;
315       }
316       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
317       $out .= ($name =~ /^\@/) ? ')' : ']';
318     }
319     elsif ($realtype eq 'HASH') {
320       my($k, $v, $pad, $lpad, $mname);
321       $out .= ($name =~ /^\%/) ? '(' : '{';
322       $pad = $s->{sep} . $s->{pad} . $s->{apad};
323       $lpad = $s->{apad};
324       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
325         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
326         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
327           ($mname = $name . '->');
328       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
329       while (($k, $v) = each %$val) {
330         my $nk = $s->_dump($k, "");
331         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
332         $sname = $mname . '{' . $nk . '}';
333         $out .= $pad . $ipad . $nk . " => ";
334
335         # temporarily alter apad
336         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
337         $out .= $s->_dump($val->{$k}, $sname) . ",";
338         $s->{apad} = $lpad if $s->{indent} >= 2;
339       }
340       if (substr($out, -1) eq ',') {
341         chop $out;
342         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
343       }
344       $out .= ($name =~ /^\%/) ? ')' : '}';
345     }
346     elsif ($realtype eq 'CODE') {
347       $out .= 'sub { "DUMMY" }';
348       carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
349     }
350     else {
351       croak "Can\'t handle $realtype type.";
352     }
353     
354     if ($realpack) { # we have a blessed ref
355       $out .= ', \'' . $realpack . '\'' . ' )';
356       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
357       $s->{apad} = $blesspad;
358     }
359     $s->{level}--;
360
361   }
362   else {                                 # simple scalar
363
364     my $ref = \$_[1];
365     # first, catalog the scalar
366     if ($name ne '') {
367       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
368       if (exists $s->{seen}{$id}) {
369         if ($s->{seen}{$id}[2]) {
370           $out = $s->{seen}{$id}[0];
371           #warn "[<$out]\n";
372           return "\${$out}";
373         }
374       }
375       else {
376         #warn "[>\\$name]\n";
377         $s->{seen}{$id} = ["\\$name", $ref];
378       }
379     }
380     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
381       my $name = substr($val, 1);
382       if ($name =~ /^[A-Za-z_][\w:]*$/) {
383         $name =~ s/^main::/::/;
384         $sname = $name;
385       }
386       else {
387         $sname = $s->_dump($name, "");
388         $sname = '{' . $sname . '}';
389       }
390       if ($s->{purity}) {
391         my $k;
392         local ($s->{level}) = 0;
393         for $k (qw(SCALAR ARRAY HASH)) {
394           my $gval = *$val{$k};
395           next unless defined $gval;
396           next if $k eq "SCALAR" && ! defined $$gval;  # always there
397
398           # _dump can push into @post, so we hold our place using $postlen
399           my $postlen = scalar @post;
400           $post[$postlen] = "\*$sname = ";
401           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
402           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
403         }
404       }
405       $out .= '*' . $sname;
406     }
407     elsif (!defined($val)) {
408       $out .= "undef";
409     }
410     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})$/) { # safe decimal number
411       $out .= $val;
412     }
413     else {                               # string
414       if ($s->{useqq}) {
415         $out .= qquote($val, $s->{useqq});
416       }
417       else {
418         $val =~ s/([\\\'])/\\$1/g;
419         $out .= '\'' . $val .  '\'';
420       }
421     }
422   }
423   if ($id) {
424     # if we made it this far, $id was added to seen list at current
425     # level, so remove it to get deep copies
426     if ($s->{deepcopy}) {
427       delete($s->{seen}{$id});
428     }
429     elsif ($name) {
430       $s->{seen}{$id}[2] = 1;
431     }
432   }
433   return $out;
434 }
435   
436 #
437 # non-OO style of earlier version
438 #
439 sub Dumper {
440   return Data::Dumper->Dump([@_]);
441 }
442
443 #
444 # same, only calls the XS version
445 #
446 sub DumperX {
447   return Data::Dumper->Dumpxs([@_], []);
448 }
449
450 sub Dumpf { return Data::Dumper->Dump(@_) }
451
452 sub Dumpp { print Data::Dumper->Dump(@_) }
453
454 #
455 # reset the "seen" cache 
456 #
457 sub Reset {
458   my($s) = shift;
459   $s->{seen} = {};
460   return $s;
461 }
462
463 sub Indent {
464   my($s, $v) = @_;
465   if (defined($v)) {
466     if ($v == 0) {
467       $s->{xpad} = "";
468       $s->{sep} = "";
469     }
470     else {
471       $s->{xpad} = "  ";
472       $s->{sep} = "\n";
473     }
474     $s->{indent} = $v;
475     return $s;
476   }
477   else {
478     return $s->{indent};
479   }
480 }
481
482 sub Pad {
483   my($s, $v) = @_;
484   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
485 }
486
487 sub Varname {
488   my($s, $v) = @_;
489   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
490 }
491
492 sub Purity {
493   my($s, $v) = @_;
494   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
495 }
496
497 sub Useqq {
498   my($s, $v) = @_;
499   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
500 }
501
502 sub Terse {
503   my($s, $v) = @_;
504   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
505 }
506
507 sub Freezer {
508   my($s, $v) = @_;
509   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
510 }
511
512 sub Toaster {
513   my($s, $v) = @_;
514   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
515 }
516
517 sub Deepcopy {
518   my($s, $v) = @_;
519   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
520 }
521
522 sub Quotekeys {
523   my($s, $v) = @_;
524   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
525 }
526
527 sub Bless {
528   my($s, $v) = @_;
529   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
530 }
531
532 sub Maxdepth {
533   my($s, $v) = @_;
534   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
535 }
536
537
538 # used by qquote below
539 my %esc = (  
540     "\a" => "\\a",
541     "\b" => "\\b",
542     "\t" => "\\t",
543     "\n" => "\\n",
544     "\f" => "\\f",
545     "\r" => "\\r",
546     "\e" => "\\e",
547 );
548
549 # put a string value in double quotes
550 sub qquote {
551   local($_) = shift;
552   s/([\\\"\@\$])/\\$1/g;
553   return qq("$_") unless /[^\040-\176]/;  # fast exit
554
555   my $high = shift || "";
556   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
557
558   # no need for 3 digits in escape for these
559   s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
560
561   s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
562   if ($high eq "iso8859") {
563     s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
564   } elsif ($high eq "utf8") {
565 #   use utf8;
566 #   $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
567   } elsif ($high eq "8bit") {
568       # leave it as it is
569   } else {
570     s/([\0-\037\177-\377])/'\\'.sprintf('%03o',ord($1))/eg;
571   }
572   return qq("$_");
573 }
574
575 1;
576 __END__
577
578 =head1 NAME
579
580 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
581
582
583 =head1 SYNOPSIS
584
585     use Data::Dumper;
586
587     # simple procedural interface
588     print Dumper($foo, $bar);
589
590     # extended usage with names
591     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
592
593     # configuration variables
594     {
595       local $Data::Dump::Purity = 1;
596       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
597     }
598
599     # OO usage
600     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
601        ...
602     print $d->Dump;
603        ...
604     $d->Purity(1)->Terse(1)->Deepcopy(1);
605     eval $d->Dump;
606
607
608 =head1 DESCRIPTION
609
610 Given a list of scalars or reference variables, writes out their contents in
611 perl syntax. The references can also be objects.  The contents of each
612 variable is output in a single Perl statement.  Handles self-referential
613 structures correctly.
614
615 The return value can be C<eval>ed to get back an identical copy of the
616 original reference structure.
617
618 Any references that are the same as one of those passed in will be named
619 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
620 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
621 notation.  You can specify names for individual values to be dumped if you
622 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
623 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
624 below.
625
626 The default output of self-referential structures can be C<eval>ed, but the
627 nested references to C<$VAR>I<n> will be undefined, since a recursive
628 structure cannot be constructed using one Perl statement.  You should set the
629 C<Purity> flag to 1 to get additional statements that will correctly fill in
630 these references.
631
632 In the extended usage form, the references to be dumped can be given
633 user-specified names.  If a name begins with a C<*>, the output will 
634 describe the dereferenced type of the supplied reference for hashes and
635 arrays, and coderefs.  Output of names will be avoided where possible if
636 the C<Terse> flag is set.
637
638 In many cases, methods that are used to set the internal state of the
639 object will return the object itself, so method calls can be conveniently
640 chained together.
641
642 Several styles of output are possible, all controlled by setting
643 the C<Indent> flag.  See L<Configuration Variables or Methods> below 
644 for details.
645
646
647 =head2 Methods
648
649 =over 4
650
651 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
652
653 Returns a newly created C<Data::Dumper> object.  The first argument is an
654 anonymous array of values to be dumped.  The optional second argument is an
655 anonymous array of names for the values.  The names need not have a leading
656 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
657 a name with a C<*> to specify that the dereferenced type must be dumped
658 instead of the reference itself, for ARRAY and HASH references.
659
660 The prefix specified by C<$Data::Dumper::Varname> will be used with a
661 numeric suffix if the name for a value is undefined.
662
663 Data::Dumper will catalog all references encountered while dumping the
664 values. Cross-references (in the form of names of substructures in perl
665 syntax) will be inserted at all possible points, preserving any structural
666 interdependencies in the original set of values.  Structure traversal is
667 depth-first,  and proceeds in order from the first supplied value to
668 the last.
669
670 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
671
672 Returns the stringified form of the values stored in the object (preserving
673 the order in which they were supplied to C<new>), subject to the
674 configuration options below.  In an array context, it returns a list
675 of strings corresponding to the supplied values.
676
677 The second form, for convenience, simply calls the C<new> method on its
678 arguments before dumping the object immediately.
679
680 =item I<$OBJ>->Dumpxs  I<or>  I<PACKAGE>->Dumpxs(I<ARRAYREF [>, I<ARRAYREF]>)
681
682 This method is available if you were able to compile and install the XSUB
683 extension to C<Data::Dumper>. It is exactly identical to the C<Dump> method 
684 above, only about 4 to 5 times faster, since it is written entirely in C.
685
686 =item I<$OBJ>->Seen(I<[HASHREF]>)
687
688 Queries or adds to the internal table of already encountered references.
689 You must use C<Reset> to explicitly clear the table if needed.  Such
690 references are not dumped; instead, their names are inserted wherever they
691 are encountered subsequently.  This is useful especially for properly
692 dumping subroutine references.
693
694 Expects a anonymous hash of name => value pairs.  Same rules apply for names
695 as in C<new>.  If no argument is supplied, will return the "seen" list of
696 name => value pairs, in an array context.  Otherwise, returns the object
697 itself.
698
699 =item I<$OBJ>->Values(I<[ARRAYREF]>)
700
701 Queries or replaces the internal array of values that will be dumped.
702 When called without arguments, returns the values.  Otherwise, returns the
703 object itself.
704
705 =item I<$OBJ>->Names(I<[ARRAYREF]>)
706
707 Queries or replaces the internal array of user supplied names for the values
708 that will be dumped.  When called without arguments, returns the names.
709 Otherwise, returns the object itself.
710
711 =item I<$OBJ>->Reset
712
713 Clears the internal table of "seen" references and returns the object
714 itself.
715
716 =back
717
718 =head2 Functions
719
720 =over 4
721
722 =item Dumper(I<LIST>)
723
724 Returns the stringified form of the values in the list, subject to the
725 configuration options below.  The values will be named C<$VAR>I<n> in the
726 output, where I<n> is a numeric suffix.  Will return a list of strings
727 in an array context.
728
729 =item DumperX(I<LIST>)
730
731 Identical to the C<Dumper()> function above, but this calls the XSUB 
732 implementation.  Only available if you were able to compile and install
733 the XSUB extensions in C<Data::Dumper>.
734
735 =back
736
737 =head2 Configuration Variables or Methods
738
739 Several configuration variables can be used to control the kind of output
740 generated when using the procedural interface.  These variables are usually
741 C<local>ized in a block so that other parts of the code are not affected by
742 the change.  
743
744 These variables determine the default state of the object created by calling
745 the C<new> method, but cannot be used to alter the state of the object
746 thereafter.  The equivalent method names should be used instead to query
747 or set the internal state of the object.
748
749 The method forms return the object itself when called with arguments,
750 so that they can be chained together nicely.
751
752 =over 4
753
754 =item $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
755
756 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
757 spews output without any newlines, indentation, or spaces between list
758 items.  It is the most compact format possible that can still be called
759 valid perl.  Style 1 outputs a readable form with newlines but no fancy
760 indentation (each level in the structure is simply indented by a fixed
761 amount of whitespace).  Style 2 (the default) outputs a very readable form
762 which takes into account the length of hash keys (so the hash value lines
763 up).  Style 3 is like style 2, but also annotates the elements of arrays
764 with their index (but the comment is on its own line, so array output
765 consumes twice the number of lines).  Style 2 is the default.
766
767 =item $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
768
769 Controls the degree to which the output can be C<eval>ed to recreate the
770 supplied reference structures.  Setting it to 1 will output additional perl
771 statements that will correctly recreate nested references.  The default is
772 0.
773
774 =item $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
775
776 Specifies the string that will be prefixed to every line of the output.
777 Empty string by default.
778
779 =item $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
780
781 Contains the prefix to use for tagging variable names in the output. The
782 default is "VAR".
783
784 =item $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
785
786 When set, enables the use of double quotes for representing string values.
787 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
788 characters will be backslashed, and unprintable characters will be output as
789 quoted octal integers.  Since setting this variable imposes a performance
790 penalty, the default is 0.  The C<Dumpxs()> method does not honor this
791 flag yet.
792
793 =item $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
794
795 When set, Data::Dumper will emit single, non-self-referential values as
796 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
797 will be avoided where possible, but be advised that such output may not
798 always be parseable by C<eval>.
799
800 =item $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
801
802 Can be set to a method name, or to an empty string to disable the feature.
803 Data::Dumper will invoke that method via the object before attempting to
804 stringify it.  This method can alter the contents of the object (if, for
805 instance, it contains data allocated from C), and even rebless it in a
806 different package.  The client is responsible for making sure the specified
807 method can be called via the object, and that the object ends up containing
808 only perl data types after the method has been called.  Defaults to an empty
809 string.
810
811 =item $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
812
813 Can be set to a method name, or to an empty string to disable the feature.
814 Data::Dumper will emit a method call for any objects that are to be dumped
815 using the syntax C<bless(DATA, CLASS)->METHOD()>.  Note that this means that
816 the method specified will have to perform any modifications required on the
817 object (like creating new state within it, and/or reblessing it in a
818 different package) and then return it.  The client is responsible for making
819 sure the method can be called via the object, and that it returns a valid
820 object.  Defaults to an empty string.
821
822 =item $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
823
824 Can be set to a boolean value to enable deep copies of structures.
825 Cross-referencing will then only be done when absolutely essential
826 (i.e., to break reference cycles).  Default is 0.
827
828 =item $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
829
830 Can be set to a boolean value to control whether hash keys are quoted.
831 A false value will avoid quoting hash keys when it looks like a simple
832 string.  Default is 1, which will always enclose hash keys in quotes.
833
834 =item $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
835
836 Can be set to a string that specifies an alternative to the C<bless>
837 builtin operator used to create objects.  A function with the specified
838 name should exist, and should accept the same arguments as the builtin.
839 Default is C<bless>.
840
841 =item $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
842
843 Can be set to a positive integer that specifies the depth beyond which
844 which we don't venture into a structure.  Has no effect when
845 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
846 want to see more than enough).  Default is 0, which means there is 
847 no maximum depth. 
848
849 =back
850
851 =head2 Exports
852
853 =over 4
854
855 =item Dumper
856
857 =back
858
859 =head1 EXAMPLES
860
861 Run these code snippets to get a quick feel for the behavior of this
862 module.  When you are through with these examples, you may want to
863 add or change the various configuration variables described above,
864 to see their behavior.  (See the testsuite in the Data::Dumper
865 distribution for more examples.)
866
867
868     use Data::Dumper;
869
870     package Foo;
871     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
872
873     package Fuz;                       # a weird REF-REF-SCALAR object
874     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
875
876     package main;
877     $foo = Foo->new;
878     $fuz = Fuz->new;
879     $boo = [ 1, [], "abcd", \*foo,
880              {1 => 'a', 023 => 'b', 0x45 => 'c'}, 
881              \\"p\q\'r", $foo, $fuz];
882     
883     ########
884     # simple usage
885     ########
886
887     $bar = eval(Dumper($boo));
888     print($@) if $@;
889     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
890
891     $Data::Dumper::Terse = 1;          # don't output names where feasible
892     $Data::Dumper::Indent = 0;         # turn off all pretty print
893     print Dumper($boo), "\n";
894
895     $Data::Dumper::Indent = 1;         # mild pretty print
896     print Dumper($boo);
897
898     $Data::Dumper::Indent = 3;         # pretty print with array indices
899     print Dumper($boo);
900
901     $Data::Dumper::Useqq = 1;          # print strings in double quotes
902     print Dumper($boo);
903     
904     
905     ########
906     # recursive structures
907     ########
908     
909     @c = ('c');
910     $c = \@c;
911     $b = {};
912     $a = [1, $b, $c];
913     $b->{a} = $a;
914     $b->{b} = $a->[1];
915     $b->{c} = $a->[2];
916     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
917     
918     
919     $Data::Dumper::Purity = 1;         # fill in the holes for eval
920     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
921     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
922     
923     
924     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
925     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
926     
927     
928     $Data::Dumper::Purity = 0;         # avoid cross-refs
929     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
930     
931     ########
932     # deep structures
933     ########
934     
935     $a = "pearl";
936     $b = [ $a ];
937     $c = { 'b' => $b };
938     $d = [ $c ];
939     $e = { 'd' => $d };
940     $f = { 'e' => $e };
941     print Data::Dumper->Dump([$f], [qw(f)]);
942
943     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
944     print Data::Dumper->Dump([$f], [qw(f)]);
945
946     
947     ########
948     # object-oriented usage
949     ########
950     
951     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
952     $d->Seen({'*c' => $c});            # stash a ref without printing it
953     $d->Indent(3);
954     print $d->Dump;
955     $d->Reset->Purity(0);              # empty the seen cache
956     print join "----\n", $d->Dump;
957     
958     
959     ########
960     # persistence
961     ########
962     
963     package Foo;
964     sub new { bless { state => 'awake' }, shift }
965     sub Freeze {
966         my $s = shift;
967         print STDERR "preparing to sleep\n";
968         $s->{state} = 'asleep';
969         return bless $s, 'Foo::ZZZ';
970     }
971     
972     package Foo::ZZZ;
973     sub Thaw {
974         my $s = shift;
975         print STDERR "waking up\n";
976         $s->{state} = 'awake';
977         return bless $s, 'Foo';
978     }
979     
980     package Foo;
981     use Data::Dumper;
982     $a = Foo->new;
983     $b = Data::Dumper->new([$a], ['c']);
984     $b->Freezer('Freeze');
985     $b->Toaster('Thaw');
986     $c = $b->Dump;
987     print $c;
988     $d = eval $c;
989     print Data::Dumper->Dump([$d], ['d']);
990     
991     
992     ########
993     # symbol substitution (useful for recreating CODE refs)
994     ########
995     
996     sub foo { print "foo speaking\n" }
997     *other = \&foo;
998     $bar = [ \&other ];
999     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1000     $d->Seen({ '*foo' => \&foo });
1001     print $d->Dump;
1002
1003
1004 =head1 BUGS
1005
1006 Due to limitations of Perl subroutine call semantics, you cannot pass an
1007 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1008 will be remedied in time, with the arrival of prototypes in later versions
1009 of Perl.  For now, you need to use the extended usage form, and prepend the
1010 name with a C<*> to output it as a hash or array.
1011
1012 C<Data::Dumper> cheats with CODE references.  If a code reference is
1013 encountered in the structure being processed, an anonymous subroutine that
1014 contains the string '"DUMMY"' will be inserted in its place, and a warning
1015 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1016 in mind that the anonymous sub that gets created is just a placeholder.
1017 Someday, perl will have a switch to cache-on-demand the string
1018 representation of a compiled piece of code, I hope.  If you have prior
1019 knowledge of all the code refs that your data structures are likely
1020 to have, you can use the C<Seen> method to pre-seed the internal reference
1021 table and make the dumped output point to them, instead.  See L<EXAMPLES>
1022 above.
1023
1024 The C<Useqq> flag is not honored by C<Dumpxs()> (it always outputs
1025 strings in single quotes).
1026
1027 SCALAR objects have the weirdest looking C<bless> workaround.
1028
1029
1030 =head1 AUTHOR
1031
1032 Gurusamy Sarathy        gsar@umich.edu
1033
1034 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1035 This program is free software; you can redistribute it and/or
1036 modify it under the same terms as Perl itself.
1037
1038
1039 =head1 VERSION
1040
1041 Version 2.11   (unreleased)
1042
1043 =head1 SEE ALSO
1044
1045 perl(1)
1046
1047 =cut