installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose,
  13     $otherperls, $archname,$Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41         $Is_W32 = 0;
  42         $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63
  64 $otherperls = 1;
  65 while (@ARGV) {
  66     $nonono = 1 if $ARGV[0] eq '-n';
  67     $dostrip = 1 if $ARGV[0] eq '-s';
  68     $versiononly = 1 if $ARGV[0] eq '-v';
  69     $versiononly = 0 if $ARGV[0] eq '+v';
  70     $silent = 1 if $ARGV[0] eq '-S';
  71     $otherperls = 0 if $ARGV[0] eq '-o';
  72     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  73     $archname = 1 if $ARGV[0] eq '-A';
  74         $nwinstall = 1 if $ARGV[0] eq '-netware';
  75     $nopods = 1 if $ARGV[0] eq '-p';
  76     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  77       print <<"EOT";
  78 Usage $0: [switches]
  79   -n        Don't actually run any commands; just print them.
  80   -s        Run strip on installed binaries.
  81   -v        Only install perl as a binary with the version number in the name.
  82             (Override whatever config.sh says)
  83   +v        Install perl as "perl" and as a binary with the version number in
  84             the name.  (Override whatever config.sh says)
  85   -S        Silent mode.
  86   -o        Skip checking for other copies of perl in your PATH.
  87   -V        Verbose mode.
  88   -A        Also install perl with the architecture's name in the perl binary's
  89             name.
  90   -p        Don't install the pod files. [This will break use diagnostics;]
  91   -netware  Install correctly on a Netware server.
  92 EOT
  93       exit;
  94     }
  95     shift;
  96 }
  97
  98 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
  99 my (@scripts, @tolink);
 100 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 101 while (<SCRIPTS>) {
 102     next if /^#/;
 103     next if /#\s*pod\s*=/; # Binary programs need separate treatment
 104     chomp;
 105     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 106         push @scripts, $1;
 107         push @tolink, [$1, $2];
 108     } else {
 109         push @scripts, $_;
 110     }
 111 }
 112 close SCRIPTS;
 113
 114 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 115
 116 my @pods = $nopods ? () : (<pod/*.pod>);
 117
 118 # Specify here any .pm files that are actually architecture-dependent.
 119 # (Those included with XS extensions under ext/ are automatically
 120 # added later.)
 121 # Now that the default privlib has the full perl version number included,
 122 # we no longer have to play the trick of sticking version-specific .pm
 123 # files under the archlib directory.
 124 my %archpms = (
 125     Config => 1,
 126     lib => 1,
 127     Cwd => 1,
 128 );
 129
 130 if ($^O eq 'dos') {
 131     push(@scripts,'djgpp/fixpmain');
 132     $archpms{config} = $archpms{filehand} = 1;
 133 }
 134
 135 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
 136 {
 137         push(@scripts, map("$_.exe", @scripts));
 138 }
 139
 140 find(sub {
 141         if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 142             my($path, $modname) = ($1,$2);
 143
 144             # strip trailing component first
 145             $path =~ s{/[^/]*$}{};
 146
 147             # strip optional "/lib";
 148             $path =~ s{/lib\b}{};
 149
 150             # strip any leading /
 151             $path =~ s{^/}{};
 152
 153             # reconstitute canonical module name
 154             $modname = "$path/$modname" if length $path;
 155
 156             # remember it
 157             $archpms{$modname} = 1;
 158         }
 159     }, 'ext');
 160
 161 # print "[$_]\n" for sort keys %archpms;
 162
 163 my $ver = $Config{version};
 164 my $release = substr($],0,3);   # Not used currently.
 165 my $patchlevel = substr($],3,2);
 166 die "Patchlevel of perl ($patchlevel)",
 167     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 168         if $patchlevel != $Config{'PERL_VERSION'};
 169
 170 # Fetch some frequently-used items from %Config
 171 my $installbin = $Config{installbin};
 172 my $installscript = $Config{installscript};
 173 my $installprivlib = $Config{installprivlib};
 174 my $installarchlib = $Config{installarchlib};
 175 my $installsitelib = $Config{installsitelib};
 176 my $installsitearch = $Config{installsitearch};
 177 my $installman1dir = $Config{installman1dir};
 178 my $man1ext = $Config{man1ext};
 179 my $libperl = $Config{libperl};
 180 # Shared library and dynamic loading suffixes.
 181 my $so = $Config{so};
 182 my $dlext = $Config{dlext};
 183 my $dlsrc = $Config{dlsrc};
 184 if ($^O eq 'os390') {
 185     my $pwd;
 186     chomp($pwd=`pwd`);
 187     my $archlibexp = $Config{archlibexp};
 188     my $usedl = $Config{usedl};
 189     if ($usedl eq 'define') {
 190         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 191     }
 192 }
 193
 194 if ($nwinstall) {
 195         # This is required only if we are installing on a NetWare server
 196         $installscript = $Config{installnwscripts};
 197         $installprivlib = $Config{installnwlib};
 198         $installarchlib = $Config{installnwlib};
 199         $installsitelib = $Config{installnwlib};
 200 }
 201
 202 my $d_dosuid = $Config{d_dosuid};
 203 my $binexp = $Config{binexp};
 204
 205 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 206     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 207               \$installarchlib, \$installsitelib, \$installsitearch,
 208               \$installman1dir ) {
 209       $$_ = unixify($$_);  $$_ =~ s:/$::;
 210     }
 211 }
 212
 213 # Do some quick sanity checks.
 214
 215 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 216
 217    $installbin          || die "No installbin directory in config.sh\n";
 218 -d $installbin          || mkpath($installbin, $verbose, 0777);
 219 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 220 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 221         unless $installbin =~ m#^/afs/# || $nonono;
 222
 223 if (!$Is_NetWare) {
 224 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 225 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 226
 227 -f 't/rantests'         || $Is_W32
 228                         || warn "WARNING: You've never run 'make test' or",
 229                                 " some tests failed! (Installing anyway.)\n";
 230 } #if (!$Is_NetWare)
 231
 232 if (($Is_W32 and ! $Is_NetWare)  or $Is_Cygwin) {
 233   my $perldll;
 234
 235   if ($Is_Cygwin) {
 236     $perldll = $libperl;
 237     my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 238     $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 239     $perldll =~ s/^lib/cyg/;
 240     if ($Config{useshrplib} eq 'true') {
 241       # install ld2 and perlld as well
 242       foreach ('ld2', 'perlld') {
 243         safe_unlink("$installbin/$_");
 244         copy("$_", "$installbin/$_");
 245         chmod(0755, "$installbin/$_");
 246       };
 247       {
 248                 open (LD2, ">$installbin/ld2");
 249                 print LD2 "#!/bin/sh\n#\n# ld wrapper, passes all args to perlld;\n#\n"
 250                           . "for trythis in $installbin/perl\ndo\n  if [ -x \$trythis ]\n"
 251                           . "  then\n    \$trythis $installbin/perlld \"\$\@\"\n"
 252                           . "    exit \$?\n  fi\ndone\n# hard luck!\necho i see no perl"
 253                           . " executable around there\necho perl is required to build "
 254                           . "dynamic libraries\necho look if the path to perl in /bin/ld2"
 255                           . " is correct\nexit 1\n";
 256                 close LD2;
 257       };
 258       chmod(0755, "$installbin/ld2");
 259     };
 260   } else {
 261     $perldll = 'perl57.' . $dlext;
 262   }
 263
 264   if ($dlsrc ne "dl_none.xs") {
 265     -f $perldll || die "No perl DLL built\n";
 266   }
 267   # Install the DLL
 268
 269   safe_unlink("$installbin/$perldll");
 270   copy("$perldll", "$installbin/$perldll");
 271   chmod(0755, "$installbin/$perldll");
 272
 273 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 274
 275 # This will be used to store the packlist
 276 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 277
 278 # First we install the version-numbered executables.
 279
 280 if ($Is_VMS) {
 281     safe_unlink("$installbin/$perl$exe_ext");
 282     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 283     chmod(0755, "$installbin/$perl$exe_ext");
 284     safe_unlink("$installbin/${perl}shr$exe_ext");
 285     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 286     chmod(0755, "$installbin/${perl}shr$exe_ext");
 287 }
 288 elsif ($^O eq 'mpeix') {
 289     # MPE lacks hard links and requires that executables with special
 290     # capabilities reside in the MPE namespace.
 291     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 292     # Install the primary executable into the MPE namespace as perlpath.
 293     copy("perl$exe_ext", $Config{perlpath});
 294     chmod(0755, $Config{perlpath});
 295     # Create a backup copy with the version number.
 296     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 297 }
 298 elsif ($^O ne 'dos') {
 299         if (!$Is_NetWare) {
 300                 safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 301                 copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 302                 strip("$installbin/$perl_verbase$ver$exe_ext");
 303                 chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 304         }
 305         else {
 306                 # If installing onto a NetWare server
 307                 if ($nwinstall) {
 308                         # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 309                         mkpath($Config{installnwsystem}, 1, 0777);
 310                         copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 311                         copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 312                         copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 313                         copy("x2p\\a2p.nlm", $Config{installnwsystem});
 314                         chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 315                         mkpath($Config{installnwlcgi}, 1, 0777);
 316                         copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 317                 }
 318         } #if (!$Is_NetWare)
 319 }
 320 else {
 321     safe_unlink("$installbin/$perl.exe");
 322     copy("perl.exe", "$installbin/$perl.exe");
 323 }
 324
 325 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 326 if ($d_dosuid) {
 327     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 328     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 329 }
 330
 331 # Install library files.
 332
 333 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 334
 335 mkpath($installprivlib, $verbose, 0777);
 336 mkpath($installarchlib, $verbose, 0777);
 337 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 338 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 339
 340 if (chdir "lib") {
 341     $do_installarchlib = ! samepath($installarchlib, '.');
 342     $do_installprivlib = ! samepath($installprivlib, '.');
 343     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 344
 345     if ($do_installarchlib || $do_installprivlib) {
 346         find(\&installlib, '.');
 347     }
 348     chdir ".." || die "Can't cd back to source directory: $!\n";
 349 }
 350 else {
 351     warn "Can't cd to lib to install lib files: $!\n";
 352 }
 353
 354 # Install header files and libraries.
 355 mkpath("$installarchlib/CORE", $verbose, 0777);
 356 my @corefiles;
 357 if ($Is_VMS) {  # We did core file selection during build
 358     my $coredir = "lib/$Config{archname}/$ver/CORE";
 359     $coredir =~ tr/./_/;
 360     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 361 }
 362 else {
 363     # [als] hard-coded 'libperl' name... not good!
 364     @corefiles = <*.h libperl*.*>;
 365
 366     # AIX needs perl.exp installed as well.
 367     push(@corefiles,'perl.exp') if $^O eq 'aix';
 368     if ($^O eq 'mpeix') {
 369         # MPE needs mpeixish.h installed as well.
 370         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 371         push(@corefiles,'mpeix/mpeixish.h');
 372     }
 373     # If they have built sperl.o...
 374     push(@corefiles,'sperl.o') if -f 'sperl.o';
 375 }
 376 foreach my $file (@corefiles) {
 377     # HP-UX (at least) needs to maintain execute permissions
 378     # on dynamically-loadable libraries. So we do it for all.
 379     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 380         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 381             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 382            chmod(0555, "$installarchlib/CORE/$file");
 383         } else {
 384             chmod(0444, "$installarchlib/CORE/$file");
 385         }
 386     }
 387 }
 388
 389 # Install main perl executables
 390 # Make links to ordinary names if installbin directory isn't current directory.
 391
 392 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 393     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 394     if ($^O eq 'mpeix') {
 395         # MPE doesn't support hard links, so use a symlink.
 396         # We don't want another cloned copy.
 397         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 398     } else {
 399         link("$installbin/$perl_verbase$ver$exe_ext",
 400                 "$installbin/$perl$exe_ext");
 401     }
 402     link("$installbin/s$perl_verbase$ver$exe_ext",
 403             "$installbin/suid$perl$exe_ext")
 404       if $d_dosuid;
 405 }
 406
 407 # For development purposes it can be very useful to have multiple perls
 408 # build for different "architectures" (eg threading or not) simultaneously.
 409 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 410     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 411     safe_unlink("$installbin/$archperl");
 412     if ($^O eq 'mpeix') {
 413         # MPE doesn't support hard links, so use a symlink.
 414         # We don't want another cloned copy.
 415         symlink($Config{perlpath}, "$installbin/$archperl");
 416     } else {
 417         link("$installbin/$perl_verbase$ver$exe_ext",
 418                 "$installbin/$archperl");
 419     }
 420 }
 421
 422 # Offer to install perl in a "standard" location
 423
 424 my $mainperl_is_instperl = 0;
 425
 426 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 427     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 428         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 429     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 430     my($instperl)       = "$installbin/$perl$exe_ext";
 431     my($expinstperl)    = "$binexp/$perl$exe_ext";
 432
 433     # First make sure $usrbinperl is not already the same as the perl we
 434     # just installed.
 435     if (-x $usrbinperl) {
 436         # Try to be clever about mainperl being a symbolic link
 437         # to binexp/perl if binexp and installbin are different.
 438         $mainperl_is_instperl =
 439             samepath($usrbinperl, $instperl) ||
 440             samepath($usrbinperl, $expinstperl) ||
 441              (($binexp ne $installbin) &&
 442               (-l $usrbinperl) &&
 443               ((readlink $usrbinperl) eq $expinstperl));
 444     }
 445     if (! $mainperl_is_instperl) {
 446         unlink($usrbinperl);
 447         ( $Config{'d_link'} eq 'define' &&
 448           eval { CORE::link $instperl, $usrbinperl } )  ||
 449         eval { symlink $expinstperl, $usrbinperl }      ||
 450         copy($instperl, $usrbinperl);
 451
 452         $mainperl_is_instperl = 1;
 453     }
 454 }
 455
 456 # Make links to ordinary names if installbin directory isn't current directory.
 457 if (!$Is_NetWare) {
 458         if (!$versiononly && ! samepath($installbin, 'x2p')) {
 459                 safe_unlink("$installbin/a2p$exe_ext");
 460                 copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 461                strip("$installbin/a2p$exe_ext");
 462                 chmod(0755, "$installbin/a2p$exe_ext");
 463         }
 464 }
 465
 466 # cppstdin is just a script, but it is architecture-dependent, so
 467 # it can't safely be shared.  Place it in $installbin.
 468 # Note that Configure doesn't build cppstin if it isn't needed, so
 469 # we skip this if cppstdin doesn't exist.
 470 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 471     safe_unlink("$installbin/cppstdin");
 472     copy("cppstdin", "$installbin/cppstdin");
 473     chmod(0755, "$installbin/cppstdin");
 474 }
 475
 476 sub script_alias {
 477     my ($installscript, $orig, $alias, $scr_ext) = @_;
 478
 479     safe_unlink("$installscript/$alias$scr_ext");
 480     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 481         copy("$installscript/$orig$scr_ext",
 482              "$installscript/$alias$scr_ext");
 483     } else {
 484         link("$installscript/$orig$scr_ext",
 485              "$installscript/$alias$scr_ext");
 486     }
 487 }
 488
 489 # Install scripts.
 490 mkpath($installscript, $verbose, 0777);
 491 if ($versiononly) {
 492     for (@scripts) {
 493         (my $base = $_) =~ s#.*/##;
 494         $base .= $ver;
 495         copy($_,    "$installscript/$base");
 496         chmod(0755, "$installscript/$base");
 497     }
 498
 499     for (@tolink) {
 500         my ($from, $to) = map { "$_$ver" } @$_;
 501         (my $frbase = $from) =~ s#.*/##;
 502         (my $tobase = $to) =~ s#.*/##;
 503         script_alias($installscript, $frbase, $tobase, $scr_ext);
 504     }
 505 } else {
 506     for (@scripts) {
 507         (my $base = $_) =~ s#.*/##;
 508         copy($_, "$installscript/$base");
 509         chmod(0755, "$installscript/$base");
 510     }
 511
 512     for (@tolink) {
 513         my ($from, $to) = @$_;
 514         (my $frbase = $from) =~ s#.*/##;
 515         (my $tobase = $to) =~ s#.*/##;
 516         script_alias($installscript, $frbase, $tobase, $scr_ext);
 517     }
 518 }
 519
 520 # Install pod pages.  Where? I guess in $installprivlib/pod
 521 # ($installprivlib/pods for cygwin).
 522
 523 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 524 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 525     mkpath("${installprivlib}/$pod", $verbose, 0777);
 526
 527     # If Perl 5.003's perldiag.pod is there, rename it.
 528     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 529         read POD, $_, 4000;
 530         close POD;
 531         # Some of Perl 5.003's diagnostic messages ended with periods.
 532         if (/^=.*\.$/m) {
 533             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 534                                "${installprivlib}/$pod/perldiag-5.003.pod");
 535             print "  rename $from $to";
 536             rename($from, $to)
 537                 or warn "Couldn't rename $from to $to: $!\n"
 538                 unless $nonono;
 539         }
 540     }
 541
 542     for (@pods) {
 543         # $_ is a name like  pod/perl.pod
 544         (my $base = $_) =~ s#.*/##;
 545         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 546     }
 547
 548 }
 549
 550 # Check to make sure there aren't other perls around in installer's
 551 # path.  This is probably UNIX-specific.  Check all absolute directories
 552 # in the path except for where public executables are supposed to live.
 553 # Also skip $mainperl if the user opted to have it be a link to the
 554 # installed perl.
 555
 556 if (!$versiononly && $otherperls) {
 557     my ($path, @path);
 558     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 559     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 560     @path = split(/$dirsep/, $path);
 561     if ($Is_VMS) {
 562         my $i = 0;
 563         while (exists $ENV{'DCL$PATH' . $i}) {
 564             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 565             push(@path,$dir);
 566         }
 567     }
 568     my @otherperls;
 569     my %otherperls;
 570     for (@path) {
 571         next unless m,^/,;
 572         # Use &samepath here because some systems have other dirs linked
 573         # to $mainperldir (like SunOS)
 574         next if samepath($_, $binexp);
 575         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 576         my $otherperl = "$_/$perl$exe_ext";
 577         next if $otherperls{$otherperl}++;
 578         push(@otherperls, $otherperl)
 579             if (-x $otherperl && ! -d $otherperl);
 580     }
 581     if (@otherperls) {
 582         warn "\nWarning: $perl appears in your path in the following " .
 583             "locations beyond where\nwe just installed it:\n";
 584         for (@otherperls) {
 585             warn "    ", $_, "\n";
 586         }
 587         warn "\n";
 588     }
 589
 590 }
 591
 592 $packlist->write() unless $nonono;
 593 print "  Installation complete\n" if $verbose;
 594
 595 exit 0;
 596
 597 ###############################################################################
 598
 599 sub yn {
 600     my($prompt) = @_;
 601     my($answer);
 602     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 603     print STDERR $prompt;
 604     chop($answer = <STDIN>);
 605     $answer = $default if $answer =~ m/^\s*$/;
 606     ($answer =~ m/^[yY]/);
 607 }
 608
 609 sub unlink {
 610     my(@names) = @_;
 611     my($cnt) = 0;
 612
 613     return scalar(@names) if $Is_VMS;
 614
 615     foreach my $name (@names) {
 616         next unless -e $name;
 617         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 618         print "  unlink $name\n" if $verbose;
 619         ( CORE::unlink($name) and ++$cnt
 620           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 621     }
 622     return $cnt;
 623 }
 624
 625 sub safe_unlink {
 626     return if $nonono or $Is_VMS;
 627     my @names = @_;
 628     foreach my $name (@names) {
 629         next unless -e $name;
 630         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 631         print "  unlink $name\n" if $verbose;
 632         next if CORE::unlink($name);
 633         warn "Couldn't unlink $name: $!\n";
 634         if ($! =~ /busy/i) {
 635             print "  mv $name $name.old\n" if $verbose;
 636             safe_rename($name, "$name.old")
 637                 or warn "Couldn't rename $name: $!\n";
 638         }
 639     }
 640 }
 641
 642 sub safe_rename {
 643     my($from,$to) = @_;
 644     if (-f $to and not unlink($to)) {
 645         my($i);
 646         for ($i = 1; $i < 50; $i++) {
 647             last if rename($to, "$to.$i");
 648         }
 649         warn("Cannot rename to `$to.$i': $!"), return 0
 650            if $i >= 50; # Give up!
 651     }
 652     link($from,$to) || return 0;
 653     unlink($from);
 654 }
 655
 656 sub link {
 657     my($from,$to) = @_;
 658     my($success) = 0;
 659
 660     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
 661     eval {
 662         CORE::link($from, $to)
 663             ? $success++
 664             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 665               ? die "AFS"  # okay inside eval {}
 666               : die "Couldn't link $from to $to: $!\n"
 667           unless $nonono;
 668         $packlist->{$to} = { from => $from, type => 'link' };
 669     };
 670     if ($@) {
 671         warn $@;
 672         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 673         print "  creating new version of $to\n"
 674                  if $Is_VMS and -e $to and !$silent;
 675         File::Copy::copy($from, $to)
 676             ? $success++
 677             : warn "Couldn't copy $from to $to: $!\n"
 678           unless $nonono;
 679         $packlist->{$to} = { type => 'file' };
 680     }
 681     $success;
 682 }
 683
 684 sub chmod {
 685     my($mode,$name) = @_;
 686
 687     return if ($^O eq 'dos');
 688     printf "  chmod %o %s\n", $mode, $name if $verbose;
 689     CORE::chmod($mode,$name)
 690         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 691       unless $nonono;
 692 }
 693
 694 sub copy {
 695     my($from,$to) = @_;
 696
 697     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 698     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
 699     File::Copy::copy($from, $to)
 700         || warn "Couldn't copy $from to $to: $!\n"
 701       unless $nonono;
 702     $packlist->{$to} = { type => 'file' };
 703 }
 704
 705 sub samepath {
 706     my($p1, $p2) = @_;
 707
 708     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 709
 710     if ($p1 ne $p2) {
 711         my($dev1, $ino1, $dev2, $ino2);
 712         ($dev1, $ino1) = stat($p1);
 713         ($dev2, $ino2) = stat($p2);
 714         ($dev1 == $dev2 && $ino1 == $ino2);
 715     }
 716     else {
 717         1;
 718     }
 719 }
 720
 721 sub installlib {
 722     my $dir = $File::Find::dir;
 723     $dir =~ s#^\.(?![^/])/?##;
 724     local($depth) = $dir ? "lib/$dir" : "lib";
 725
 726     my $name = $_;
 727
 728     # Ignore RCS and CVS directories.
 729     if (($name eq 'CVS' or $name eq 'RCS') and -d $name) {
 730         $File::Find::prune = 1;
 731         return;
 732     }
 733
 734     # ignore patch backups, RCS files, emacs backup & temp files and the
 735     # .exists files, .PL files, and .t files.
 736     return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.t$};
 737
 738     $name = "$dir/$name" if $dir ne '';
 739
 740     my $installlib = $installprivlib;
 741     if ($dir =~ /^auto/ ||
 742           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 743           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 744        ) {
 745         $installlib = $installarchlib;
 746         return unless $do_installarchlib;
 747     } else {
 748         return unless $do_installprivlib;
 749     }
 750
 751     if (-f $_) {
 752         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 753             $installlib = $installprivlib;
 754             #We're installing *.al and *.ix files into $installprivlib,
 755             #but we have to delete old *.al and *.ix files from the 5.000
 756             #distribution:
 757             #This might not work because $archname might have changed.
 758             unlink("$installarchlib/$name");
 759         }
 760         $packlist->{"$installlib/$name"} = { type => 'file' };
 761         if (compare($_, "$installlib/$name") || $nonono) {
 762             unlink("$installlib/$name");
 763             mkpath("$installlib/$dir", $verbose, 0777);
 764             # HP-UX (at least) needs to maintain execute permissions
 765             # on dynamically-loaded libraries.
 766            if ($Is_NetWare && !$nwinstall) {
 767                # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 768                # if copied will give problems when building new extensions.
 769                # Has to be copied if we are installing on a NetWare server and hence
 770                # the check !$nwinstall
 771                if (!(/\.(?:nlp|nlm|bs)$/)) {
 772                    copy_if_diff($_, "$installlib/$name")
 773                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 774                                  "$installlib/$name");
 775                }
 776            } else {
 777                if (copy_if_diff($_, "$installlib/$name")) {
 778                    if ($name =~ /\.(so|$dlext)$/o) {
 779                        strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 780                        chmod(0555, "$installlib/$name");
 781                    } else {
 782                        strip("-S", "$installlib/$name")
 783                            if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 784                        chmod(0444, "$installlib/$name");
 785                    }
 786                }
 787            } #if ($Is_NetWare)
 788         }
 789     }
 790 }
 791
 792 # Copy $from to $to, only if $from is different than $to.
 793 # Also preserve modification times for .a libraries.
 794 # On some systems, if you do
 795 #   ranlib libperl.a
 796 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 797 # and then try to link against the installed libperl.a, you might
 798 # get an error message to the effect that the symbol table is older
 799 # than the library.
 800 # Return true if copying occurred.
 801
 802 sub copy_if_diff {
 803     my($from,$to)=@_;
 804     return 1 if (($^O eq 'VMS') && (-d $from));
 805     -f $from || warn "$0: $from not found";
 806     $packlist->{$to} = { type => 'file' };
 807     if (compare($from, $to) || $nonono) {
 808         safe_unlink($to);   # In case we don't have write permissions.
 809         if ($nonono) {
 810             $from = $depth . "/" . $from if $depth;
 811         }
 812         copy($from, $to);
 813         # Restore timestamps if it's a .a library or for OS/2.
 814         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 815             my ($atime, $mtime) = (stat $from)[8,9];
 816             utime $atime, $mtime, $to;
 817         }
 818         1;
 819     }
 820 }
 821
 822 sub strip
 823 {
 824     my(@args) = @_;
 825
 826     return unless $dostrip;
 827
 828     my @opts;
 829     while (@args && $args[0] =~ /^(-\w+)$/) {
 830         push @opts, shift @args;
 831     }
 832
 833     foreach my $file (@args) {
 834         if (-f $file) {
 835            if ($verbose) {
 836                print "  strip " . join(' ', @opts);
 837                print " " if (@opts);
 838                print "$file\n";
 839            }
 840             system("strip", @opts, $file);
 841         } else {
 842             print "# file '$file' skipped\n" if $verbose;
 843         }
 844     }
 845 }