This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
97b02d03feace4da0ddc2265e136161436d3e830
[perl5.git] / dist / Devel-PPPort / Makefile.PL
1 ################################################################################
2 #
3 #  Makefile.PL -- generate Makefile
4 #
5 ################################################################################
6 #
7 #  Version 3.x, Copyright (C) 2004-2013, Marcus Holland-Moritz.
8 #  Version 2.x, Copyright (C) 2001, Paul Marquess.
9 #  Version 1.x, Copyright (C) 1999, Kenneth Albanowski.
10 #
11 #  This program is free software; you can redistribute it and/or
12 #  modify it under the same terms as Perl itself.
13 #
14 ################################################################################
15
16 require 5.003;
17
18 use strict;
19 BEGIN { $^W = 1; }
20
21 use ExtUtils::MakeMaker;
22 use Config;
23
24 use vars '%opt';  # needs to be global, and we can't use 'our'
25
26 unless ($ENV{'PERL_CORE'}) {
27   $ENV{'PERL_CORE'} = 1 if grep { $_ eq 'PERL_CORE=1' } @ARGV;
28 }
29
30 @ARGV = map { /^--with-(apicheck)$/ && ++$opt{$1} ? () : $_ } @ARGV;
31
32 my %mf = (
33   NAME          => 'Devel::PPPort',
34   VERSION_FROM  => 'PPPort_pm.PL',
35   PM            => { 'PPPort.pm' => '$(INST_LIBDIR)/PPPort.pm' },
36   H             => [ qw(ppport.h) ],
37   OBJECT        => 'RealPPPort$(OBJ_EXT) $(O_FILES)',
38   XSPROTOARG    => '-noprototypes',
39   CONFIGURE     => \&configure,
40 );
41 WriteMakefile(%mf);
42
43 sub configure
44 {
45   my @clean    = qw{ $(H_FILES) RealPPPort.xs RealPPPort.c PPPort.pm };
46   my %depend   = (
47     '$(OBJECT)' => '$(H_FILES)',
48     'Makefile' => '$(VERSION_FROM)',
49   );
50   my @C_FILES  = qw{ module2.c module3.c },
51   my %PL_FILES = (
52     'ppport_h.PL'  => 'ppport.h',
53     'PPPort_pm.PL' => 'PPPort.pm',
54     'RealPPPort_xs.PL' => 'RealPPPort.xs',
55     'mktests.PL' => 't/01_test.t',
56   );
57   my @moreopts;
58
59   if (eval { ExtUtils::MakeMaker->VERSION(6) }) {
60     push @moreopts, AUTHOR => 'Marcus Holland-Moritz <mhx@cpan.org>';
61     push @moreopts, ABSTRACT_FROM => 'PPPort_pm.PL';
62   }
63
64   if (eval { ExtUtils::MakeMaker->VERSION(6.30_01) }) {
65     print "Setting license tag...\n";
66     push @moreopts, LICENSE => 'perl';
67   }
68
69   if (eval { ExtUtils::MakeMaker->VERSION (6.46) }) {
70     open FH, '<PPPort_pm.PL' or die "cannot open PPPort_pm.PL for reading: $!";
71     my $version;
72     while (my $line = <FH>) {
73       ($version) = $line =~ /^\$VERSION = '([\d.]+)';$/ and last;
74     };
75     die 'failed to extract $VERSION from PPPort_pm.PL' if not $version;
76     close FH;
77     print "Adding META_MERGE...\n";
78     push @moreopts, META_MERGE => {
79       'meta-spec' => { version => 2 },
80       provides => {
81         'Devel::PPPort' => {
82           file    => 'PPPort_pm.PL',
83           version => $version,
84         },
85       },
86       resources => {
87         bugtracker => {
88           web => 'https://rt.perl.org/rt3/',
89         },
90         repository => {
91           type => 'git',
92           url  => 'git://perl5.git.perl.org/perl.git',
93           web  => 'https://perl5.git.perl.org/perl.git',
94         },
95       },
96     };
97   }
98
99   if (not $ENV{'PERL_CORE'}) {
100     # Devel::PPPort is in the core since 5.7.3
101     # 5.11.0+ has site before perl
102     push @moreopts, INSTALLDIRS => (
103       ("$]" >= 5.007003 and "$]" < 5.011)
104         ? 'perl'
105         : 'site'
106     );
107   }
108
109   if ($opt{'apicheck'}) {
110     $PL_FILES{'apicheck_c.PL'} = 'apicheck.c';
111     push @C_FILES, qw{ apicheck.c };
112     push @clean,   qw{ apicheck.c apicheck.i };
113     $depend{'apicheck.i'} = 'ppport.h';
114   }
115
116   if ($Config{gccversion}) {
117     my $define = '-W -Wall';
118     $define .= ' -Wdeclaration-after-statement' if $Config{gccversion} =~ /^(\d+\.\d+)\./ && $1 >= 3.4;
119     push @moreopts, DEFINE => $define;
120   }
121
122   return {
123     C        => \@C_FILES,
124     XS       => { 'RealPPPort.xs' => 'RealPPPort.c' },
125     PL_FILES => \%PL_FILES,
126     depend   => \%depend,
127     clean    => { FILES => "@clean" },
128     @moreopts,
129   };
130 }
131
132 sub MY::postamble
133 {
134   package MY;
135   my $post = shift->SUPER::postamble(@_);
136   $post .= <<'POSTAMBLE';
137
138 purge_all: realclean
139         @$(RM_F) PPPort.pm t/*.t
140
141 regen_pm:
142         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) PPPort_pm.PL
143
144 regen_xs:
145         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) RealPPPort_xs.PL
146
147 regen_tests:
148         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) mktests.PL
149
150 regen_h:
151         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) ppport_h.PL
152
153 regen: regen_pm regen_xs regen_tests regen_h
154
155 POSTAMBLE
156   return $post;
157 }
158
159 sub MY::processPL
160 {
161   package MY;
162   my $original = shift->SUPER::processPL(@_);
163
164   require "./parts/ppptools.pl";
165   my $includes = join ' ', all_files_in_dir('parts/inc');
166
167   my $updated = '';
168   my @rules = split( m{^\s*$}m, $original );
169   foreach my $rule ( @rules ) {
170     if ( $rule =~ m{^\s*^PPPort\.pm\s+:}m ) {
171       $rule =~ s{^(\s*^PPPort\.pm\s+:.*)}{$1 $includes}m; # PPPort.pm depends on all files from parts/inc
172       $rule =~ s{pm_to_blib}{}m; # PPPort.pm must not depend on built PPPort.pm in blib/
173     } elsif ( $rule =~ m{^\s*^ppport\.h\s+:}m ) {
174       $rule =~ s{^(\s*^ppport\.h\s+:.*)}{$1 PPPort.pm}m; # ppport.h depends on PPPort.pm
175       $rule =~ s{pm_to_blib}{}m; # ppport.h is used to build RealPPPort.xs so cannot depend on built PPPort in blib/
176     } elsif ( $rule =~ m{^\s*^RealPPPort\.xs\s+:}m ) {
177       $rule =~ s{^(\s*^RealPPPort\.xs\s+:.*)}{$1 ppport.h}m; # RealPPPort.xs depends on ppport.h
178       $rule =~ s{pm_to_blib}{}m; # RealPPPort.xs is used to build PPPort binary, so it cannot depend on it
179     } elsif ( $rule =~ m{^\s*\S+\b01_test\.t\s+:}m ) {
180       $rule =~ s{^(\s*^\S+\b01_test\.t\s+:.*)}{$1 $includes}m; # all tests in t/ depends on all files from parts/inc
181       $rule =~ s{pm_to_blib}{}m; # Generating test files does not depend on built PPPort in blib/
182     }
183     $updated .= $rule;
184   }
185
186   return $updated;
187 }
188
189 sub MY::dist_core
190 {
191   package MY;
192   my $dist = shift->SUPER::dist_core(@_);
193
194   my $updated = '';
195   my @rules = split( m{^\s*$}m, $dist );
196   foreach my $rule ( @rules ) {
197     if ( $rule =~ m{^\s*^dist\s+:}m ) {
198         $rule =~ s{:}{: manifest}; # make sure we regenerate the manifest
199         $rule .= qq[\t].q[$(NOECHO) $(ECHO) "Warning: Please check '__MAX_PERL__' value in PPPort_pm.PL"].qq[\n];
200     }
201     $updated .= $rule;
202   }
203
204   return $updated;
205 }
206
207
208 sub MY::c_o
209 {
210   package MY;
211   my $co = shift->SUPER::c_o(@_);
212
213   if ($::opt{'apicheck'} && $co !~ /^\.c\.i:/m) {
214     print "Adding custom rule for preprocessed apicheck file...\n";
215
216     $co .= <<'CO'
217
218 .SUFFIXES: .i
219
220 .c.i:
221         $(CCCMD) -E -I$(PERL_INC) $(DEFINE) $*.c > $*.i
222 CO
223   }
224
225   return $co;
226 }