This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
96bb041ad7427f38bc460f410576b54d8bd3ac3b
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy : if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds have elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 =item bind SOCKET,NAME
450
451 Binds a network address to a socket, just as the bind system call
452 does.  Returns true if it succeeded, false otherwise.  NAME should be a
453 packed address of the appropriate type for the socket.  See the examples in
454 L<perlipc/"Sockets: Client/Server Communication">.
455
456 =item binmode FILEHANDLE, LAYER
457
458 =item binmode FILEHANDLE
459
460 Arranges for FILEHANDLE to be read or written in "binary" or "text"
461 mode on systems where the run-time libraries distinguish between
462 binary and text files.  If FILEHANDLE is an expression, the value is
463 taken as the name of the filehandle.  Returns true on success,
464 otherwise it returns C<undef> and sets C<$!> (errno).
465
466 On some systems (in general, DOS and Windows-based systems) binmode()
467 is necessary when you're not working with a text file.  For the sake
468 of portability it is a good idea to always use it when appropriate,
469 and to never use it when it isn't appropriate.  Also, people can
470 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
471
472 In other words: regardless of platform, use binmode() on binary data,
473 like for example images.
474
475 If LAYER is present it is a single string, but may contain multiple
476 directives. The directives alter the behaviour of the file handle.
477 When LAYER is present using binmode on text file makes sense.
478
479 If LAYER is omitted or specified as C<:raw> the filehandle is made
480 suitable for passing binary data. This includes turning off possible CRLF
481 translation and marking it as bytes (as opposed to Unicode characters).
482 Note that, despite what may be implied in I<"Programming Perl"> (the
483 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
484 -- other layers which would affect binary nature of the stream are
485 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
486 PERLIO environment variable.
487
488 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
489 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
490 establish default I/O layers.  See L<open>.
491
492 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
493 in "Programming Perl, 3rd Edition".  However, since the publishing of this
494 book, by many known as "Camel III", the consensus of the naming of this
495 functionality has moved from "discipline" to "layer".  All documentation
496 of this version of Perl therefore refers to "layers" rather than to
497 "disciplines".  Now back to the regularly scheduled documentation...>
498
499 To mark FILEHANDLE as UTF-8, use C<:utf8>.
500
501 In general, binmode() should be called after open() but before any I/O
502 is done on the filehandle.  Calling binmode() will normally flush any
503 pending buffered output data (and perhaps pending input data) on the
504 handle.  An exception to this is the C<:encoding> layer that
505 changes the default character encoding of the handle, see L<open>.
506 The C<:encoding> layer sometimes needs to be called in
507 mid-stream, and it doesn't flush the stream.  The C<:encoding>
508 also implicitly pushes on top of itself the C<:utf8> layer because
509 internally Perl will operate on UTF-8 encoded Unicode characters.
510
511 The operating system, device drivers, C libraries, and Perl run-time
512 system all work together to let the programmer treat a single
513 character (C<\n>) as the line terminator, irrespective of the external
514 representation.  On many operating systems, the native text file
515 representation matches the internal representation, but on some
516 platforms the external representation of C<\n> is made up of more than
517 one character.
518
519 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
520 character to end each line in the external representation of text (even
521 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
522 on Unix and most VMS files). In other systems like OS/2, DOS and the
523 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
524 but what's stored in text files are the two characters C<\cM\cJ>.  That
525 means that, if you don't use binmode() on these systems, C<\cM\cJ>
526 sequences on disk will be converted to C<\n> on input, and any C<\n> in
527 your program will be converted back to C<\cM\cJ> on output.  This is what
528 you want for text files, but it can be disastrous for binary files.
529
530 Another consequence of using binmode() (on some systems) is that
531 special end-of-file markers will be seen as part of the data stream.
532 For systems from the Microsoft family this means that if your binary
533 data contains C<\cZ>, the I/O subsystem will regard it as the end of
534 the file, unless you use binmode().
535
536 binmode() is not only important for readline() and print() operations,
537 but also when using read(), seek(), sysread(), syswrite() and tell()
538 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
539 in L<perlvar> for how to manually set your input and output
540 line-termination sequences.
541
542 =item bless REF,CLASSNAME
543
544 =item bless REF
545
546 This function tells the thingy referenced by REF that it is now an object
547 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
548 is used.  Because a C<bless> is often the last thing in a constructor,
549 it returns the reference for convenience.  Always use the two-argument
550 version if the function doing the blessing might be inherited by a
551 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
552 (and blessings) of objects.
553
554 Consider always blessing objects in CLASSNAMEs that are mixed case.
555 Namespaces with all lowercase names are considered reserved for
556 Perl pragmata.  Builtin types have all uppercase names, so to prevent
557 confusion, you may wish to avoid such package names as well.  Make sure
558 that CLASSNAME is a true value.
559
560 See L<perlmod/"Perl Modules">.
561
562 =item caller EXPR
563
564 =item caller
565
566 Returns the context of the current subroutine call.  In scalar context,
567 returns the caller's package name if there is a caller, that is, if
568 we're in a subroutine or C<eval> or C<require>, and the undefined value
569 otherwise.  In list context, returns
570
571     ($package, $filename, $line) = caller;
572
573 With EXPR, it returns some extra information that the debugger uses to
574 print a stack trace.  The value of EXPR indicates how many call frames
575 to go back before the current one.
576
577     ($package, $filename, $line, $subroutine, $hasargs,
578     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
579
580 Here $subroutine may be C<(eval)> if the frame is not a subroutine
581 call, but an C<eval>.  In such a case additional elements $evaltext and
582 C<$is_require> are set: C<$is_require> is true if the frame is created by a
583 C<require> or C<use> statement, $evaltext contains the text of the
584 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
585 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
586 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
587 frame.)  $subroutine may also be C<(unknown)> if this particular
588 subroutine happens to have been deleted from the symbol table.
589 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
590 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
591 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
592 between versions of Perl, and are not meant for external use.
593
594 Furthermore, when called from within the DB package, caller returns more
595 detailed information: it sets the list variable C<@DB::args> to be the
596 arguments with which the subroutine was invoked.
597
598 Be aware that the optimizer might have optimized call frames away before
599 C<caller> had a chance to get the information.  That means that C<caller(N)>
600 might not return information about the call frame you expect it do, for
601 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
602 previous time C<caller> was called.
603
604 =item chdir EXPR
605
606 Changes the working directory to EXPR, if possible. If EXPR is omitted,
607 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
608 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
609 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
610 neither is set, C<chdir> does nothing. It returns true upon success,
611 false otherwise. See the example under C<die>.
612
613 =item chmod LIST
614
615 Changes the permissions of a list of files.  The first element of the
616 list must be the numerical mode, which should probably be an octal
617 number, and which definitely should I<not> a string of octal digits:
618 C<0644> is okay, C<'0644'> is not.  Returns the number of files
619 successfully changed.  See also L</oct>, if all you have is a string.
620
621     $cnt = chmod 0755, 'foo', 'bar';
622     chmod 0755, @executables;
623     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
624                                              # --w----r-T
625     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
626     $mode = 0644;   chmod $mode, 'foo';      # this is best
627
628 You can also import the symbolic C<S_I*> constants from the Fcntl
629 module:
630
631     use Fcntl ':mode';
632
633     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
634     # This is identical to the chmod 0755 of the above example.
635
636 =item chomp VARIABLE
637
638 =item chomp( LIST )
639
640 =item chomp
641
642 This safer version of L</chop> removes any trailing string
643 that corresponds to the current value of C<$/> (also known as
644 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
645 number of characters removed from all its arguments.  It's often used to
646 remove the newline from the end of an input record when you're worried
647 that the final record may be missing its newline.  When in paragraph
648 mode (C<$/ = "">), it removes all trailing newlines from the string.
649 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
650 a reference to an integer or the like, see L<perlvar>) chomp() won't
651 remove anything.
652 If VARIABLE is omitted, it chomps C<$_>.  Example:
653
654     while (<>) {
655         chomp;  # avoid \n on last field
656         @array = split(/:/);
657         # ...
658     }
659
660 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
661
662 You can actually chomp anything that's an lvalue, including an assignment:
663
664     chomp($cwd = `pwd`);
665     chomp($answer = <STDIN>);
666
667 If you chomp a list, each element is chomped, and the total number of
668 characters removed is returned.
669
670 If the C<encoding> pragma is in scope then the lengths returned are
671 calculated from the length of C<$/> in Unicode characters, which is not
672 always the same as the length of C<$/> in the native encoding.
673
674 Note that parentheses are necessary when you're chomping anything
675 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
676 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
677 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
678 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
679 as C<chomp($a, $b)>.
680
681 =item chop VARIABLE
682
683 =item chop( LIST )
684
685 =item chop
686
687 Chops off the last character of a string and returns the character
688 chopped.  It is much more efficient than C<s/.$//s> because it neither
689 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
690 If VARIABLE is a hash, it chops the hash's values, but not its keys.
691
692 You can actually chop anything that's an lvalue, including an assignment.
693
694 If you chop a list, each element is chopped.  Only the value of the
695 last C<chop> is returned.
696
697 Note that C<chop> returns the last character.  To return all but the last
698 character, use C<substr($string, 0, -1)>.
699
700 See also L</chomp>.
701
702 =item chown LIST
703
704 Changes the owner (and group) of a list of files.  The first two
705 elements of the list must be the I<numeric> uid and gid, in that
706 order.  A value of -1 in either position is interpreted by most
707 systems to leave that value unchanged.  Returns the number of files
708 successfully changed.
709
710     $cnt = chown $uid, $gid, 'foo', 'bar';
711     chown $uid, $gid, @filenames;
712
713 Here's an example that looks up nonnumeric uids in the passwd file:
714
715     print "User: ";
716     chomp($user = <STDIN>);
717     print "Files: ";
718     chomp($pattern = <STDIN>);
719
720     ($login,$pass,$uid,$gid) = getpwnam($user)
721         or die "$user not in passwd file";
722
723     @ary = glob($pattern);      # expand filenames
724     chown $uid, $gid, @ary;
725
726 On most systems, you are not allowed to change the ownership of the
727 file unless you're the superuser, although you should be able to change
728 the group to any of your secondary groups.  On insecure systems, these
729 restrictions may be relaxed, but this is not a portable assumption.
730 On POSIX systems, you can detect this condition this way:
731
732     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
733     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
734
735 =item chr NUMBER
736
737 =item chr
738
739 Returns the character represented by that NUMBER in the character set.
740 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
741 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
742 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
743 backward compatibility reasons (but see L<encoding>).
744
745 If NUMBER is omitted, uses C<$_>.
746
747 For the reverse, use L</ord>.
748
749 Note that under the C<bytes> pragma the NUMBER is masked to
750 the low eight bits.
751
752 See L<perlunicode> and L<encoding> for more about Unicode.
753
754 =item chroot FILENAME
755
756 =item chroot
757
758 This function works like the system call by the same name: it makes the
759 named directory the new root directory for all further pathnames that
760 begin with a C</> by your process and all its children.  (It doesn't
761 change your current working directory, which is unaffected.)  For security
762 reasons, this call is restricted to the superuser.  If FILENAME is
763 omitted, does a C<chroot> to C<$_>.
764
765 =item close FILEHANDLE
766
767 =item close
768
769 Closes the file or pipe associated with the file handle, returning
770 true only if IO buffers are successfully flushed and closes the system
771 file descriptor.  Closes the currently selected filehandle if the
772 argument is omitted.
773
774 You don't have to close FILEHANDLE if you are immediately going to do
775 another C<open> on it, because C<open> will close it for you.  (See
776 C<open>.)  However, an explicit C<close> on an input file resets the line
777 counter (C<$.>), while the implicit close done by C<open> does not.
778
779 If the file handle came from a piped open, C<close> will additionally
780 return false if one of the other system calls involved fails, or if the
781 program exits with non-zero status.  (If the only problem was that the
782 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
783 also waits for the process executing on the pipe to complete, in case you
784 want to look at the output of the pipe afterwards, and
785 implicitly puts the exit status value of that command into C<$?>.
786
787 Prematurely closing the read end of a pipe (i.e. before the process
788 writing to it at the other end has closed it) will result in a
789 SIGPIPE being delivered to the writer.  If the other end can't
790 handle that, be sure to read all the data before closing the pipe.
791
792 Example:
793
794     open(OUTPUT, '|sort >foo')  # pipe to sort
795         or die "Can't start sort: $!";
796     #...                        # print stuff to output
797     close OUTPUT                # wait for sort to finish
798         or warn $! ? "Error closing sort pipe: $!"
799                    : "Exit status $? from sort";
800     open(INPUT, 'foo')          # get sort's results
801         or die "Can't open 'foo' for input: $!";
802
803 FILEHANDLE may be an expression whose value can be used as an indirect
804 filehandle, usually the real filehandle name.
805
806 =item closedir DIRHANDLE
807
808 Closes a directory opened by C<opendir> and returns the success of that
809 system call.
810
811 =item connect SOCKET,NAME
812
813 Attempts to connect to a remote socket, just as the connect system call
814 does.  Returns true if it succeeded, false otherwise.  NAME should be a
815 packed address of the appropriate type for the socket.  See the examples in
816 L<perlipc/"Sockets: Client/Server Communication">.
817
818 =item continue BLOCK
819
820 Actually a flow control statement rather than a function.  If there is a
821 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
822 C<foreach>), it is always executed just before the conditional is about to
823 be evaluated again, just like the third part of a C<for> loop in C.  Thus
824 it can be used to increment a loop variable, even when the loop has been
825 continued via the C<next> statement (which is similar to the C C<continue>
826 statement).
827
828 C<last>, C<next>, or C<redo> may appear within a C<continue>
829 block.  C<last> and C<redo> will behave as if they had been executed within
830 the main block.  So will C<next>, but since it will execute a C<continue>
831 block, it may be more entertaining.
832
833     while (EXPR) {
834         ### redo always comes here
835         do_something;
836     } continue {
837         ### next always comes here
838         do_something_else;
839         # then back the top to re-check EXPR
840     }
841     ### last always comes here
842
843 Omitting the C<continue> section is semantically equivalent to using an
844 empty one, logically enough.  In that case, C<next> goes directly back
845 to check the condition at the top of the loop.
846
847 =item cos EXPR
848
849 =item cos
850
851 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
852 takes cosine of C<$_>.
853
854 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
855 function, or use this relation:
856
857     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
858
859 =item crypt PLAINTEXT,SALT
860
861 Encrypts a string exactly like the crypt(3) function in the C library
862 (assuming that you actually have a version there that has not been
863 extirpated as a potential munition).  This can prove useful for checking
864 the password file for lousy passwords, amongst other things.  Only the
865 guys wearing white hats should do this.
866
867 Note that L<crypt|/crypt> is intended to be a one-way function, much like
868 breaking eggs to make an omelette.  There is no (known) corresponding
869 decrypt function (in other words, the crypt() is a one-way hash
870 function).  As a result, this function isn't all that useful for
871 cryptography.  (For that, see your nearby CPAN mirror.)
872
873 When verifying an existing encrypted string you should use the
874 encrypted text as the salt (like C<crypt($plain, $crypted) eq
875 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
876 and with more exotic implementations.  In other words, do not assume
877 anything about the returned string itself, or how many bytes in
878 the encrypted string matter.
879
880 Traditionally the result is a string of 13 bytes: two first bytes of
881 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
882 the first eight bytes of the encrypted string mattered, but
883 alternative hashing schemes (like MD5), higher level security schemes
884 (like C2), and implementations on non-UNIX platforms may produce
885 different strings.
886
887 When choosing a new salt create a random two character string whose
888 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
889 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
890 characters is just a recommendation; the characters allowed in
891 the salt depend solely on your system's crypt library, and Perl can't
892 restrict what salts C<crypt()> accepts.
893
894 Here's an example that makes sure that whoever runs this program knows
895 their own password:
896
897     $pwd = (getpwuid($<))[1];
898
899     system "stty -echo";
900     print "Password: ";
901     chomp($word = <STDIN>);
902     print "\n";
903     system "stty echo";
904
905     if (crypt($word, $pwd) ne $pwd) {
906         die "Sorry...\n";
907     } else {
908         print "ok\n";
909     }
910
911 Of course, typing in your own password to whoever asks you
912 for it is unwise.
913
914 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
915 of data, not least of all because you can't get the information
916 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
917 on your favorite CPAN mirror for a slew of potentially useful
918 modules.
919
920 If using crypt() on a Unicode string (which I<potentially> has
921 characters with codepoints above 255), Perl tries to make sense
922 of the situation by trying to downgrade (a copy of the string)
923 the string back to an eight-bit byte string before calling crypt()
924 (on that copy).  If that works, good.  If not, crypt() dies with
925 C<Wide character in crypt>.
926
927 =item dbmclose HASH
928
929 [This function has been largely superseded by the C<untie> function.]
930
931 Breaks the binding between a DBM file and a hash.
932
933 =item dbmopen HASH,DBNAME,MASK
934
935 [This function has been largely superseded by the C<tie> function.]
936
937 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
938 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
939 argument is I<not> a filehandle, even though it looks like one).  DBNAME
940 is the name of the database (without the F<.dir> or F<.pag> extension if
941 any).  If the database does not exist, it is created with protection
942 specified by MASK (as modified by the C<umask>).  If your system supports
943 only the older DBM functions, you may perform only one C<dbmopen> in your
944 program.  In older versions of Perl, if your system had neither DBM nor
945 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
946 sdbm(3).
947
948 If you don't have write access to the DBM file, you can only read hash
949 variables, not set them.  If you want to test whether you can write,
950 either use file tests or try setting a dummy hash entry inside an C<eval>,
951 which will trap the error.
952
953 Note that functions such as C<keys> and C<values> may return huge lists
954 when used on large DBM files.  You may prefer to use the C<each>
955 function to iterate over large DBM files.  Example:
956
957     # print out history file offsets
958     dbmopen(%HIST,'/usr/lib/news/history',0666);
959     while (($key,$val) = each %HIST) {
960         print $key, ' = ', unpack('L',$val), "\n";
961     }
962     dbmclose(%HIST);
963
964 See also L<AnyDBM_File> for a more general description of the pros and
965 cons of the various dbm approaches, as well as L<DB_File> for a particularly
966 rich implementation.
967
968 You can control which DBM library you use by loading that library
969 before you call dbmopen():
970
971     use DB_File;
972     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
973         or die "Can't open netscape history file: $!";
974
975 =item defined EXPR
976
977 =item defined
978
979 Returns a Boolean value telling whether EXPR has a value other than
980 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
981 checked.
982
983 Many operations return C<undef> to indicate failure, end of file,
984 system error, uninitialized variable, and other exceptional
985 conditions.  This function allows you to distinguish C<undef> from
986 other values.  (A simple Boolean test will not distinguish among
987 C<undef>, zero, the empty string, and C<"0">, which are all equally
988 false.)  Note that since C<undef> is a valid scalar, its presence
989 doesn't I<necessarily> indicate an exceptional condition: C<pop>
990 returns C<undef> when its argument is an empty array, I<or> when the
991 element to return happens to be C<undef>.
992
993 You may also use C<defined(&func)> to check whether subroutine C<&func>
994 has ever been defined.  The return value is unaffected by any forward
995 declarations of C<&func>.  Note that a subroutine which is not defined
996 may still be callable: its package may have an C<AUTOLOAD> method that
997 makes it spring into existence the first time that it is called -- see
998 L<perlsub>.
999
1000 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1001 used to report whether memory for that aggregate has ever been
1002 allocated.  This behavior may disappear in future versions of Perl.
1003 You should instead use a simple test for size:
1004
1005     if (@an_array) { print "has array elements\n" }
1006     if (%a_hash)   { print "has hash members\n"   }
1007
1008 When used on a hash element, it tells you whether the value is defined,
1009 not whether the key exists in the hash.  Use L</exists> for the latter
1010 purpose.
1011
1012 Examples:
1013
1014     print if defined $switch{'D'};
1015     print "$val\n" while defined($val = pop(@ary));
1016     die "Can't readlink $sym: $!"
1017         unless defined($value = readlink $sym);
1018     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1019     $debugging = 0 unless defined $debugging;
1020
1021 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1022 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1023 defined values.  For example, if you say
1024
1025     "ab" =~ /a(.*)b/;
1026
1027 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1028 matched "nothing".  But it didn't really match nothing--rather, it
1029 matched something that happened to be zero characters long.  This is all
1030 very above-board and honest.  When a function returns an undefined value,
1031 it's an admission that it couldn't give you an honest answer.  So you
1032 should use C<defined> only when you're questioning the integrity of what
1033 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1034 what you want.
1035
1036 See also L</undef>, L</exists>, L</ref>.
1037
1038 =item delete EXPR
1039
1040 Given an expression that specifies a hash element, array element, hash slice,
1041 or array slice, deletes the specified element(s) from the hash or array.
1042 In the case of an array, if the array elements happen to be at the end,
1043 the size of the array will shrink to the highest element that tests
1044 true for exists() (or 0 if no such element exists).
1045
1046 Returns a list with the same number of elements as the number of elements
1047 for which deletion was attempted.  Each element of that list consists of
1048 either the value of the element deleted, or the undefined value.  In scalar
1049 context, this means that you get the value of the last element deleted (or
1050 the undefined value if that element did not exist).
1051
1052     %hash = (foo => 11, bar => 22, baz => 33);
1053     $scalar = delete $hash{foo};             # $scalar is 11
1054     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1055     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1056
1057 Deleting from C<%ENV> modifies the environment.  Deleting from
1058 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1059 from a C<tie>d hash or array may not necessarily return anything.
1060
1061 Deleting an array element effectively returns that position of the array
1062 to its initial, uninitialized state.  Subsequently testing for the same
1063 element with exists() will return false.  Note that deleting array
1064 elements in the middle of an array will not shift the index of the ones
1065 after them down--use splice() for that.  See L</exists>.
1066
1067 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1068
1069     foreach $key (keys %HASH) {
1070         delete $HASH{$key};
1071     }
1072
1073     foreach $index (0 .. $#ARRAY) {
1074         delete $ARRAY[$index];
1075     }
1076
1077 And so do these:
1078
1079     delete @HASH{keys %HASH};
1080
1081     delete @ARRAY[0 .. $#ARRAY];
1082
1083 But both of these are slower than just assigning the empty list
1084 or undefining %HASH or @ARRAY:
1085
1086     %HASH = ();         # completely empty %HASH
1087     undef %HASH;        # forget %HASH ever existed
1088
1089     @ARRAY = ();        # completely empty @ARRAY
1090     undef @ARRAY;       # forget @ARRAY ever existed
1091
1092 Note that the EXPR can be arbitrarily complicated as long as the final
1093 operation is a hash element, array element,  hash slice, or array slice
1094 lookup:
1095
1096     delete $ref->[$x][$y]{$key};
1097     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1098
1099     delete $ref->[$x][$y][$index];
1100     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1101
1102 =item die LIST
1103
1104 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1105 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1106 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1107 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1108 an C<eval(),> the error message is stuffed into C<$@> and the
1109 C<eval> is terminated with the undefined value.  This makes
1110 C<die> the way to raise an exception.
1111
1112 Equivalent examples:
1113
1114     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1115     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1116
1117 If the last element of LIST does not end in a newline, the current
1118 script line number and input line number (if any) are also printed,
1119 and a newline is supplied.  Note that the "input line number" (also
1120 known as "chunk") is subject to whatever notion of "line" happens to
1121 be currently in effect, and is also available as the special variable
1122 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1123
1124 Hint: sometimes appending C<", stopped"> to your message will cause it
1125 to make better sense when the string C<"at foo line 123"> is appended.
1126 Suppose you are running script "canasta".
1127
1128     die "/etc/games is no good";
1129     die "/etc/games is no good, stopped";
1130
1131 produce, respectively
1132
1133     /etc/games is no good at canasta line 123.
1134     /etc/games is no good, stopped at canasta line 123.
1135
1136 See also exit(), warn(), and the Carp module.
1137
1138 If LIST is empty and C<$@> already contains a value (typically from a
1139 previous eval) that value is reused after appending C<"\t...propagated">.
1140 This is useful for propagating exceptions:
1141
1142     eval { ... };
1143     die unless $@ =~ /Expected exception/;
1144
1145 If LIST is empty and C<$@> contains an object reference that has a
1146 C<PROPAGATE> method, that method will be called with additional file
1147 and line number parameters.  The return value replaces the value in
1148 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1149 were called.
1150
1151 If C<$@> is empty then the string C<"Died"> is used.
1152
1153 die() can also be called with a reference argument.  If this happens to be
1154 trapped within an eval(), $@ contains the reference.  This behavior permits
1155 a more elaborate exception handling implementation using objects that
1156 maintain arbitrary state about the nature of the exception.  Such a scheme
1157 is sometimes preferable to matching particular string values of $@ using
1158 regular expressions.  Here's an example:
1159
1160     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1161     if ($@) {
1162         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1163             # handle Some::Module::Exception
1164         }
1165         else {
1166             # handle all other possible exceptions
1167         }
1168     }
1169
1170 Because perl will stringify uncaught exception messages before displaying
1171 them, you may want to overload stringification operations on such custom
1172 exception objects.  See L<overload> for details about that.
1173
1174 You can arrange for a callback to be run just before the C<die>
1175 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1176 handler will be called with the error text and can change the error
1177 message, if it sees fit, by calling C<die> again.  See
1178 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1179 L<"eval BLOCK"> for some examples.  Although this feature was meant
1180 to be run only right before your program was to exit, this is not
1181 currently the case--the C<$SIG{__DIE__}> hook is currently called
1182 even inside eval()ed blocks/strings!  If one wants the hook to do
1183 nothing in such situations, put
1184
1185         die @_ if $^S;
1186
1187 as the first line of the handler (see L<perlvar/$^S>).  Because
1188 this promotes strange action at a distance, this counterintuitive
1189 behavior may be fixed in a future release.
1190
1191 =item do BLOCK
1192
1193 Not really a function.  Returns the value of the last command in the
1194 sequence of commands indicated by BLOCK.  When modified by a loop
1195 modifier, executes the BLOCK once before testing the loop condition.
1196 (On other statements the loop modifiers test the conditional first.)
1197
1198 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1199 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1200 See L<perlsyn> for alternative strategies.
1201
1202 =item do SUBROUTINE(LIST)
1203
1204 A deprecated form of subroutine call.  See L<perlsub>.
1205
1206 =item do EXPR
1207
1208 Uses the value of EXPR as a filename and executes the contents of the
1209 file as a Perl script.  Its primary use is to include subroutines
1210 from a Perl subroutine library.
1211
1212     do 'stat.pl';
1213
1214 is just like
1215
1216     eval `cat stat.pl`;
1217
1218 except that it's more efficient and concise, keeps track of the current
1219 filename for error messages, searches the @INC libraries, and updates
1220 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1221 variables.  It also differs in that code evaluated with C<do FILENAME>
1222 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1223 same, however, in that it does reparse the file every time you call it,
1224 so you probably don't want to do this inside a loop.
1225
1226 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1227 error.  If C<do> can read the file but cannot compile it, it
1228 returns undef and sets an error message in C<$@>.   If the file is
1229 successfully compiled, C<do> returns the value of the last expression
1230 evaluated.
1231
1232 Note that inclusion of library modules is better done with the
1233 C<use> and C<require> operators, which also do automatic error checking
1234 and raise an exception if there's a problem.
1235
1236 You might like to use C<do> to read in a program configuration
1237 file.  Manual error checking can be done this way:
1238
1239     # read in config files: system first, then user
1240     for $file ("/share/prog/defaults.rc",
1241                "$ENV{HOME}/.someprogrc")
1242    {
1243         unless ($return = do $file) {
1244             warn "couldn't parse $file: $@" if $@;
1245             warn "couldn't do $file: $!"    unless defined $return;
1246             warn "couldn't run $file"       unless $return;
1247         }
1248     }
1249
1250 =item dump LABEL
1251
1252 =item dump
1253
1254 This function causes an immediate core dump.  See also the B<-u>
1255 command-line switch in L<perlrun>, which does the same thing.
1256 Primarily this is so that you can use the B<undump> program (not
1257 supplied) to turn your core dump into an executable binary after
1258 having initialized all your variables at the beginning of the
1259 program.  When the new binary is executed it will begin by executing
1260 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1261 Think of it as a goto with an intervening core dump and reincarnation.
1262 If C<LABEL> is omitted, restarts the program from the top.
1263
1264 B<WARNING>: Any files opened at the time of the dump will I<not>
1265 be open any more when the program is reincarnated, with possible
1266 resulting confusion on the part of Perl.
1267
1268 This function is now largely obsolete, partly because it's very
1269 hard to convert a core file into an executable, and because the
1270 real compiler backends for generating portable bytecode and compilable
1271 C code have superseded it.  That's why you should now invoke it as
1272 C<CORE::dump()>, if you don't want to be warned against a possible
1273 typo.
1274
1275 If you're looking to use L<dump> to speed up your program, consider
1276 generating bytecode or native C code as described in L<perlcc>.  If
1277 you're just trying to accelerate a CGI script, consider using the
1278 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1279 You might also consider autoloading or selfloading, which at least
1280 make your program I<appear> to run faster.
1281
1282 =item each HASH
1283
1284 When called in list context, returns a 2-element list consisting of the
1285 key and value for the next element of a hash, so that you can iterate over
1286 it.  When called in scalar context, returns only the key for the next
1287 element in the hash.
1288
1289 Entries are returned in an apparently random order.  The actual random
1290 order is subject to change in future versions of perl, but it is
1291 guaranteed to be in the same order as either the C<keys> or C<values>
1292 function would produce on the same (unmodified) hash.  Since Perl
1293 5.8.1 the ordering is different even between different runs of Perl
1294 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1295
1296 When the hash is entirely read, a null array is returned in list context
1297 (which when assigned produces a false (C<0>) value), and C<undef> in
1298 scalar context.  The next call to C<each> after that will start iterating
1299 again.  There is a single iterator for each hash, shared by all C<each>,
1300 C<keys>, and C<values> function calls in the program; it can be reset by
1301 reading all the elements from the hash, or by evaluating C<keys HASH> or
1302 C<values HASH>.  If you add or delete elements of a hash while you're
1303 iterating over it, you may get entries skipped or duplicated, so
1304 don't.  Exception: It is always safe to delete the item most recently
1305 returned by C<each()>, which means that the following code will work:
1306
1307         while (($key, $value) = each %hash) {
1308           print $key, "\n";
1309           delete $hash{$key};   # This is safe
1310         }
1311
1312 The following prints out your environment like the printenv(1) program,
1313 only in a different order:
1314
1315     while (($key,$value) = each %ENV) {
1316         print "$key=$value\n";
1317     }
1318
1319 See also C<keys>, C<values> and C<sort>.
1320
1321 =item eof FILEHANDLE
1322
1323 =item eof ()
1324
1325 =item eof
1326
1327 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1328 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1329 gives the real filehandle.  (Note that this function actually
1330 reads a character and then C<ungetc>s it, so isn't very useful in an
1331 interactive context.)  Do not read from a terminal file (or call
1332 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1333 as terminals may lose the end-of-file condition if you do.
1334
1335 An C<eof> without an argument uses the last file read.  Using C<eof()>
1336 with empty parentheses is very different.  It refers to the pseudo file
1337 formed from the files listed on the command line and accessed via the
1338 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1339 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1340 used will cause C<@ARGV> to be examined to determine if input is
1341 available.   Similarly, an C<eof()> after C<< <> >> has returned
1342 end-of-file will assume you are processing another C<@ARGV> list,
1343 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1344 see L<perlop/"I/O Operators">.
1345
1346 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1347 detect the end of each file, C<eof()> will only detect the end of the
1348 last file.  Examples:
1349
1350     # reset line numbering on each input file
1351     while (<>) {
1352         next if /^\s*#/;        # skip comments
1353         print "$.\t$_";
1354     } continue {
1355         close ARGV  if eof;     # Not eof()!
1356     }
1357
1358     # insert dashes just before last line of last file
1359     while (<>) {
1360         if (eof()) {            # check for end of last file
1361             print "--------------\n";
1362         }
1363         print;
1364         last if eof();          # needed if we're reading from a terminal
1365     }
1366
1367 Practical hint: you almost never need to use C<eof> in Perl, because the
1368 input operators typically return C<undef> when they run out of data, or if
1369 there was an error.
1370
1371 =item eval EXPR
1372
1373 =item eval BLOCK
1374
1375 In the first form, the return value of EXPR is parsed and executed as if it
1376 were a little Perl program.  The value of the expression (which is itself
1377 determined within scalar context) is first parsed, and if there weren't any
1378 errors, executed in the lexical context of the current Perl program, so
1379 that any variable settings or subroutine and format definitions remain
1380 afterwards.  Note that the value is parsed every time the eval executes.
1381 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1382 delay parsing and subsequent execution of the text of EXPR until run time.
1383
1384 In the second form, the code within the BLOCK is parsed only once--at the
1385 same time the code surrounding the eval itself was parsed--and executed
1386 within the context of the current Perl program.  This form is typically
1387 used to trap exceptions more efficiently than the first (see below), while
1388 also providing the benefit of checking the code within BLOCK at compile
1389 time.
1390
1391 The final semicolon, if any, may be omitted from the value of EXPR or within
1392 the BLOCK.
1393
1394 In both forms, the value returned is the value of the last expression
1395 evaluated inside the mini-program; a return statement may be also used, just
1396 as with subroutines.  The expression providing the return value is evaluated
1397 in void, scalar, or list context, depending on the context of the eval itself.
1398 See L</wantarray> for more on how the evaluation context can be determined.
1399
1400 If there is a syntax error or runtime error, or a C<die> statement is
1401 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1402 error message.  If there was no error, C<$@> is guaranteed to be a null
1403 string.  Beware that using C<eval> neither silences perl from printing
1404 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1405 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1406 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1407 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1408
1409 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1410 determining whether a particular feature (such as C<socket> or C<symlink>)
1411 is implemented.  It is also Perl's exception trapping mechanism, where
1412 the die operator is used to raise exceptions.
1413
1414 If the code to be executed doesn't vary, you may use the eval-BLOCK
1415 form to trap run-time errors without incurring the penalty of
1416 recompiling each time.  The error, if any, is still returned in C<$@>.
1417 Examples:
1418
1419     # make divide-by-zero nonfatal
1420     eval { $answer = $a / $b; }; warn $@ if $@;
1421
1422     # same thing, but less efficient
1423     eval '$answer = $a / $b'; warn $@ if $@;
1424
1425     # a compile-time error
1426     eval { $answer = };                 # WRONG
1427
1428     # a run-time error
1429     eval '$answer =';   # sets $@
1430
1431 Due to the current arguably broken state of C<__DIE__> hooks, when using
1432 the C<eval{}> form as an exception trap in libraries, you may wish not
1433 to trigger any C<__DIE__> hooks that user code may have installed.
1434 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1435 as shown in this example:
1436
1437     # a very private exception trap for divide-by-zero
1438     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1439     warn $@ if $@;
1440
1441 This is especially significant, given that C<__DIE__> hooks can call
1442 C<die> again, which has the effect of changing their error messages:
1443
1444     # __DIE__ hooks may modify error messages
1445     {
1446        local $SIG{'__DIE__'} =
1447               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1448        eval { die "foo lives here" };
1449        print $@ if $@;                # prints "bar lives here"
1450     }
1451
1452 Because this promotes action at a distance, this counterintuitive behavior
1453 may be fixed in a future release.
1454
1455 With an C<eval>, you should be especially careful to remember what's
1456 being looked at when:
1457
1458     eval $x;            # CASE 1
1459     eval "$x";          # CASE 2
1460
1461     eval '$x';          # CASE 3
1462     eval { $x };        # CASE 4
1463
1464     eval "\$$x++";      # CASE 5
1465     $$x++;              # CASE 6
1466
1467 Cases 1 and 2 above behave identically: they run the code contained in
1468 the variable $x.  (Although case 2 has misleading double quotes making
1469 the reader wonder what else might be happening (nothing is).)  Cases 3
1470 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1471 does nothing but return the value of $x.  (Case 4 is preferred for
1472 purely visual reasons, but it also has the advantage of compiling at
1473 compile-time instead of at run-time.)  Case 5 is a place where
1474 normally you I<would> like to use double quotes, except that in this
1475 particular situation, you can just use symbolic references instead, as
1476 in case 6.
1477
1478 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1479 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1480
1481 Note that as a very special case, an C<eval ''> executed within the C<DB>
1482 package doesn't see the usual surrounding lexical scope, but rather the
1483 scope of the first non-DB piece of code that called it. You don't normally
1484 need to worry about this unless you are writing a Perl debugger.
1485
1486 =item exec LIST
1487
1488 =item exec PROGRAM LIST
1489
1490 The C<exec> function executes a system command I<and never returns>--
1491 use C<system> instead of C<exec> if you want it to return.  It fails and
1492 returns false only if the command does not exist I<and> it is executed
1493 directly instead of via your system's command shell (see below).
1494
1495 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1496 warns you if there is a following statement which isn't C<die>, C<warn>,
1497 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1498 I<really> want to follow an C<exec> with some other statement, you
1499 can use one of these styles to avoid the warning:
1500
1501     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1502     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1503
1504 If there is more than one argument in LIST, or if LIST is an array
1505 with more than one value, calls execvp(3) with the arguments in LIST.
1506 If there is only one scalar argument or an array with one element in it,
1507 the argument is checked for shell metacharacters, and if there are any,
1508 the entire argument is passed to the system's command shell for parsing
1509 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1510 If there are no shell metacharacters in the argument, it is split into
1511 words and passed directly to C<execvp>, which is more efficient.
1512 Examples:
1513
1514     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1515     exec "sort $outfile | uniq";
1516
1517 If you don't really want to execute the first argument, but want to lie
1518 to the program you are executing about its own name, you can specify
1519 the program you actually want to run as an "indirect object" (without a
1520 comma) in front of the LIST.  (This always forces interpretation of the
1521 LIST as a multivalued list, even if there is only a single scalar in
1522 the list.)  Example:
1523
1524     $shell = '/bin/csh';
1525     exec $shell '-sh';          # pretend it's a login shell
1526
1527 or, more directly,
1528
1529     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1530
1531 When the arguments get executed via the system shell, results will
1532 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1533 for details.
1534
1535 Using an indirect object with C<exec> or C<system> is also more
1536 secure.  This usage (which also works fine with system()) forces
1537 interpretation of the arguments as a multivalued list, even if the
1538 list had just one argument.  That way you're safe from the shell
1539 expanding wildcards or splitting up words with whitespace in them.
1540
1541     @args = ( "echo surprise" );
1542
1543     exec @args;               # subject to shell escapes
1544                                 # if @args == 1
1545     exec { $args[0] } @args;  # safe even with one-arg list
1546
1547 The first version, the one without the indirect object, ran the I<echo>
1548 program, passing it C<"surprise"> an argument.  The second version
1549 didn't--it tried to run a program literally called I<"echo surprise">,
1550 didn't find it, and set C<$?> to a non-zero value indicating failure.
1551
1552 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1553 output before the exec, but this may not be supported on some platforms
1554 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1555 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1556 open handles in order to avoid lost output.
1557
1558 Note that C<exec> will not call your C<END> blocks, nor will it call
1559 any C<DESTROY> methods in your objects.
1560
1561 =item exists EXPR
1562
1563 Given an expression that specifies a hash element or array element,
1564 returns true if the specified element in the hash or array has ever
1565 been initialized, even if the corresponding value is undefined.  The
1566 element is not autovivified if it doesn't exist.
1567
1568     print "Exists\n"    if exists $hash{$key};
1569     print "Defined\n"   if defined $hash{$key};
1570     print "True\n"      if $hash{$key};
1571
1572     print "Exists\n"    if exists $array[$index];
1573     print "Defined\n"   if defined $array[$index];
1574     print "True\n"      if $array[$index];
1575
1576 A hash or array element can be true only if it's defined, and defined if
1577 it exists, but the reverse doesn't necessarily hold true.
1578
1579 Given an expression that specifies the name of a subroutine,
1580 returns true if the specified subroutine has ever been declared, even
1581 if it is undefined.  Mentioning a subroutine name for exists or defined
1582 does not count as declaring it.  Note that a subroutine which does not
1583 exist may still be callable: its package may have an C<AUTOLOAD>
1584 method that makes it spring into existence the first time that it is
1585 called -- see L<perlsub>.
1586
1587     print "Exists\n"    if exists &subroutine;
1588     print "Defined\n"   if defined &subroutine;
1589
1590 Note that the EXPR can be arbitrarily complicated as long as the final
1591 operation is a hash or array key lookup or subroutine name:
1592
1593     if (exists $ref->{A}->{B}->{$key})  { }
1594     if (exists $hash{A}{B}{$key})       { }
1595
1596     if (exists $ref->{A}->{B}->[$ix])   { }
1597     if (exists $hash{A}{B}[$ix])        { }
1598
1599     if (exists &{$ref->{A}{B}{$key}})   { }
1600
1601 Although the deepest nested array or hash will not spring into existence
1602 just because its existence was tested, any intervening ones will.
1603 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1604 into existence due to the existence test for the $key element above.
1605 This happens anywhere the arrow operator is used, including even:
1606
1607     undef $ref;
1608     if (exists $ref->{"Some key"})      { }
1609     print $ref;             # prints HASH(0x80d3d5c)
1610
1611 This surprising autovivification in what does not at first--or even
1612 second--glance appear to be an lvalue context may be fixed in a future
1613 release.
1614
1615 Use of a subroutine call, rather than a subroutine name, as an argument
1616 to exists() is an error.
1617
1618     exists &sub;        # OK
1619     exists &sub();      # Error
1620
1621 =item exit EXPR
1622
1623 Evaluates EXPR and exits immediately with that value.    Example:
1624
1625     $ans = <STDIN>;
1626     exit 0 if $ans =~ /^[Xx]/;
1627
1628 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1629 universally recognized values for EXPR are C<0> for success and C<1>
1630 for error; other values are subject to interpretation depending on the
1631 environment in which the Perl program is running.  For example, exiting
1632 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1633 the mailer to return the item undelivered, but that's not true everywhere.
1634
1635 Don't use C<exit> to abort a subroutine if there's any chance that
1636 someone might want to trap whatever error happened.  Use C<die> instead,
1637 which can be trapped by an C<eval>.
1638
1639 The exit() function does not always exit immediately.  It calls any
1640 defined C<END> routines first, but these C<END> routines may not
1641 themselves abort the exit.  Likewise any object destructors that need to
1642 be called are called before the real exit.  If this is a problem, you
1643 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1644 See L<perlmod> for details.
1645
1646 =item exp EXPR
1647
1648 =item exp
1649
1650 Returns I<e> (the natural logarithm base) to the power of EXPR.
1651 If EXPR is omitted, gives C<exp($_)>.
1652
1653 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1654
1655 Implements the fcntl(2) function.  You'll probably have to say
1656
1657     use Fcntl;
1658
1659 first to get the correct constant definitions.  Argument processing and
1660 value return works just like C<ioctl> below.
1661 For example:
1662
1663     use Fcntl;
1664     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1665         or die "can't fcntl F_GETFL: $!";
1666
1667 You don't have to check for C<defined> on the return from C<fcntl>.
1668 Like C<ioctl>, it maps a C<0> return from the system call into
1669 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1670 in numeric context.  It is also exempt from the normal B<-w> warnings
1671 on improper numeric conversions.
1672
1673 Note that C<fcntl> will produce a fatal error if used on a machine that
1674 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1675 manpage to learn what functions are available on your system.
1676
1677 Here's an example of setting a filehandle named C<REMOTE> to be
1678 non-blocking at the system level.  You'll have to negotiate C<$|>
1679 on your own, though.
1680
1681     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1682
1683     $flags = fcntl(REMOTE, F_GETFL, 0)
1684                 or die "Can't get flags for the socket: $!\n";
1685
1686     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1687                 or die "Can't set flags for the socket: $!\n";
1688
1689 =item fileno FILEHANDLE
1690
1691 Returns the file descriptor for a filehandle, or undefined if the
1692 filehandle is not open.  This is mainly useful for constructing
1693 bitmaps for C<select> and low-level POSIX tty-handling operations.
1694 If FILEHANDLE is an expression, the value is taken as an indirect
1695 filehandle, generally its name.
1696
1697 You can use this to find out whether two handles refer to the
1698 same underlying descriptor:
1699
1700     if (fileno(THIS) == fileno(THAT)) {
1701         print "THIS and THAT are dups\n";
1702     }
1703
1704 (Filehandles connected to memory objects via new features of C<open> may
1705 return undefined even though they are open.)
1706
1707
1708 =item flock FILEHANDLE,OPERATION
1709
1710 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1711 for success, false on failure.  Produces a fatal error if used on a
1712 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1713 C<flock> is Perl's portable file locking interface, although it locks
1714 only entire files, not records.
1715
1716 Two potentially non-obvious but traditional C<flock> semantics are
1717 that it waits indefinitely until the lock is granted, and that its locks
1718 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1719 fewer guarantees.  This means that files locked with C<flock> may be
1720 modified by programs that do not also use C<flock>.  See L<perlport>,
1721 your port's specific documentation, or your system-specific local manpages
1722 for details.  It's best to assume traditional behavior if you're writing
1723 portable programs.  (But if you're not, you should as always feel perfectly
1724 free to write for your own system's idiosyncrasies (sometimes called
1725 "features").  Slavish adherence to portability concerns shouldn't get
1726 in the way of your getting your job done.)
1727
1728 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1729 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1730 you can use the symbolic names if you import them from the Fcntl module,
1731 either individually, or as a group using the ':flock' tag.  LOCK_SH
1732 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1733 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1734 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1735 waiting for the lock (check the return status to see if you got it).
1736
1737 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1738 before locking or unlocking it.
1739
1740 Note that the emulation built with lockf(3) doesn't provide shared
1741 locks, and it requires that FILEHANDLE be open with write intent.  These
1742 are the semantics that lockf(3) implements.  Most if not all systems
1743 implement lockf(3) in terms of fcntl(2) locking, though, so the
1744 differing semantics shouldn't bite too many people.
1745
1746 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1747 be open with read intent to use LOCK_SH and requires that it be open
1748 with write intent to use LOCK_EX.
1749
1750 Note also that some versions of C<flock> cannot lock things over the
1751 network; you would need to use the more system-specific C<fcntl> for
1752 that.  If you like you can force Perl to ignore your system's flock(2)
1753 function, and so provide its own fcntl(2)-based emulation, by passing
1754 the switch C<-Ud_flock> to the F<Configure> program when you configure
1755 perl.
1756
1757 Here's a mailbox appender for BSD systems.
1758
1759     use Fcntl ':flock'; # import LOCK_* constants
1760
1761     sub lock {
1762         flock(MBOX,LOCK_EX);
1763         # and, in case someone appended
1764         # while we were waiting...
1765         seek(MBOX, 0, 2);
1766     }
1767
1768     sub unlock {
1769         flock(MBOX,LOCK_UN);
1770     }
1771
1772     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1773             or die "Can't open mailbox: $!";
1774
1775     lock();
1776     print MBOX $msg,"\n\n";
1777     unlock();
1778
1779 On systems that support a real flock(), locks are inherited across fork()
1780 calls, whereas those that must resort to the more capricious fcntl()
1781 function lose the locks, making it harder to write servers.
1782
1783 See also L<DB_File> for other flock() examples.
1784
1785 =item fork
1786
1787 Does a fork(2) system call to create a new process running the
1788 same program at the same point.  It returns the child pid to the
1789 parent process, C<0> to the child process, or C<undef> if the fork is
1790 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1791 are shared, while everything else is copied.  On most systems supporting
1792 fork(), great care has gone into making it extremely efficient (for
1793 example, using copy-on-write technology on data pages), making it the
1794 dominant paradigm for multitasking over the last few decades.
1795
1796 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1797 output before forking the child process, but this may not be supported
1798 on some platforms (see L<perlport>).  To be safe, you may need to set
1799 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1800 C<IO::Handle> on any open handles in order to avoid duplicate output.
1801
1802 If you C<fork> without ever waiting on your children, you will
1803 accumulate zombies.  On some systems, you can avoid this by setting
1804 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1805 forking and reaping moribund children.
1806
1807 Note that if your forked child inherits system file descriptors like
1808 STDIN and STDOUT that are actually connected by a pipe or socket, even
1809 if you exit, then the remote server (such as, say, a CGI script or a
1810 backgrounded job launched from a remote shell) won't think you're done.
1811 You should reopen those to F</dev/null> if it's any issue.
1812
1813 =item format
1814
1815 Declare a picture format for use by the C<write> function.  For
1816 example:
1817
1818     format Something =
1819         Test: @<<<<<<<< @||||| @>>>>>
1820               $str,     $%,    '$' . int($num)
1821     .
1822
1823     $str = "widget";
1824     $num = $cost/$quantity;
1825     $~ = 'Something';
1826     write;
1827
1828 See L<perlform> for many details and examples.
1829
1830 =item formline PICTURE,LIST
1831
1832 This is an internal function used by C<format>s, though you may call it,
1833 too.  It formats (see L<perlform>) a list of values according to the
1834 contents of PICTURE, placing the output into the format output
1835 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1836 Eventually, when a C<write> is done, the contents of
1837 C<$^A> are written to some filehandle, but you could also read C<$^A>
1838 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1839 does one C<formline> per line of form, but the C<formline> function itself
1840 doesn't care how many newlines are embedded in the PICTURE.  This means
1841 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1842 You may therefore need to use multiple formlines to implement a single
1843 record format, just like the format compiler.
1844
1845 Be careful if you put double quotes around the picture, because an C<@>
1846 character may be taken to mean the beginning of an array name.
1847 C<formline> always returns true.  See L<perlform> for other examples.
1848
1849 =item getc FILEHANDLE
1850
1851 =item getc
1852
1853 Returns the next character from the input file attached to FILEHANDLE,
1854 or the undefined value at end of file, or if there was an error (in
1855 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1856 STDIN.  This is not particularly efficient.  However, it cannot be
1857 used by itself to fetch single characters without waiting for the user
1858 to hit enter.  For that, try something more like:
1859
1860     if ($BSD_STYLE) {
1861         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1862     }
1863     else {
1864         system "stty", '-icanon', 'eol', "\001";
1865     }
1866
1867     $key = getc(STDIN);
1868
1869     if ($BSD_STYLE) {
1870         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1871     }
1872     else {
1873         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1874     }
1875     print "\n";
1876
1877 Determination of whether $BSD_STYLE should be set
1878 is left as an exercise to the reader.
1879
1880 The C<POSIX::getattr> function can do this more portably on
1881 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1882 module from your nearest CPAN site; details on CPAN can be found on
1883 L<perlmodlib/CPAN>.
1884
1885 =item getlogin
1886
1887 Implements the C library function of the same name, which on most
1888 systems returns the current login from F</etc/utmp>, if any.  If null,
1889 use C<getpwuid>.
1890
1891     $login = getlogin || getpwuid($<) || "Kilroy";
1892
1893 Do not consider C<getlogin> for authentication: it is not as
1894 secure as C<getpwuid>.
1895
1896 =item getpeername SOCKET
1897
1898 Returns the packed sockaddr address of other end of the SOCKET connection.
1899
1900     use Socket;
1901     $hersockaddr    = getpeername(SOCK);
1902     ($port, $iaddr) = sockaddr_in($hersockaddr);
1903     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1904     $herstraddr     = inet_ntoa($iaddr);
1905
1906 =item getpgrp PID
1907
1908 Returns the current process group for the specified PID.  Use
1909 a PID of C<0> to get the current process group for the
1910 current process.  Will raise an exception if used on a machine that
1911 doesn't implement getpgrp(2).  If PID is omitted, returns process
1912 group of current process.  Note that the POSIX version of C<getpgrp>
1913 does not accept a PID argument, so only C<PID==0> is truly portable.
1914
1915 =item getppid
1916
1917 Returns the process id of the parent process.
1918
1919 Note for Linux users: on Linux, the C functions C<getpid()> and
1920 C<getppid()> return different values from different threads. In order to
1921 be portable, this behavior is not reflected by the perl-level function
1922 C<getppid()>, that returns a consistent value across threads. If you want
1923 to call the underlying C<getppid()>, you may use the CPAN module
1924 C<Linux::Pid>.
1925
1926 =item getpriority WHICH,WHO
1927
1928 Returns the current priority for a process, a process group, or a user.
1929 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1930 machine that doesn't implement getpriority(2).
1931
1932 =item getpwnam NAME
1933
1934 =item getgrnam NAME
1935
1936 =item gethostbyname NAME
1937
1938 =item getnetbyname NAME
1939
1940 =item getprotobyname NAME
1941
1942 =item getpwuid UID
1943
1944 =item getgrgid GID
1945
1946 =item getservbyname NAME,PROTO
1947
1948 =item gethostbyaddr ADDR,ADDRTYPE
1949
1950 =item getnetbyaddr ADDR,ADDRTYPE
1951
1952 =item getprotobynumber NUMBER
1953
1954 =item getservbyport PORT,PROTO
1955
1956 =item getpwent
1957
1958 =item getgrent
1959
1960 =item gethostent
1961
1962 =item getnetent
1963
1964 =item getprotoent
1965
1966 =item getservent
1967
1968 =item setpwent
1969
1970 =item setgrent
1971
1972 =item sethostent STAYOPEN
1973
1974 =item setnetent STAYOPEN
1975
1976 =item setprotoent STAYOPEN
1977
1978 =item setservent STAYOPEN
1979
1980 =item endpwent
1981
1982 =item endgrent
1983
1984 =item endhostent
1985
1986 =item endnetent
1987
1988 =item endprotoent
1989
1990 =item endservent
1991
1992 These routines perform the same functions as their counterparts in the
1993 system library.  In list context, the return values from the
1994 various get routines are as follows:
1995
1996     ($name,$passwd,$uid,$gid,
1997        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1998     ($name,$passwd,$gid,$members) = getgr*
1999     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2000     ($name,$aliases,$addrtype,$net) = getnet*
2001     ($name,$aliases,$proto) = getproto*
2002     ($name,$aliases,$port,$proto) = getserv*
2003
2004 (If the entry doesn't exist you get a null list.)
2005
2006 The exact meaning of the $gcos field varies but it usually contains
2007 the real name of the user (as opposed to the login name) and other
2008 information pertaining to the user.  Beware, however, that in many
2009 system users are able to change this information and therefore it
2010 cannot be trusted and therefore the $gcos is tainted (see
2011 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2012 login shell, are also tainted, because of the same reason.
2013
2014 In scalar context, you get the name, unless the function was a
2015 lookup by name, in which case you get the other thing, whatever it is.
2016 (If the entry doesn't exist you get the undefined value.)  For example:
2017
2018     $uid   = getpwnam($name);
2019     $name  = getpwuid($num);
2020     $name  = getpwent();
2021     $gid   = getgrnam($name);
2022     $name  = getgrgid($num);
2023     $name  = getgrent();
2024     #etc.
2025
2026 In I<getpw*()> the fields $quota, $comment, and $expire are special
2027 cases in the sense that in many systems they are unsupported.  If the
2028 $quota is unsupported, it is an empty scalar.  If it is supported, it
2029 usually encodes the disk quota.  If the $comment field is unsupported,
2030 it is an empty scalar.  If it is supported it usually encodes some
2031 administrative comment about the user.  In some systems the $quota
2032 field may be $change or $age, fields that have to do with password
2033 aging.  In some systems the $comment field may be $class.  The $expire
2034 field, if present, encodes the expiration period of the account or the
2035 password.  For the availability and the exact meaning of these fields
2036 in your system, please consult your getpwnam(3) documentation and your
2037 F<pwd.h> file.  You can also find out from within Perl what your
2038 $quota and $comment fields mean and whether you have the $expire field
2039 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2040 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2041 files are only supported if your vendor has implemented them in the
2042 intuitive fashion that calling the regular C library routines gets the
2043 shadow versions if you're running under privilege or if there exists
2044 the shadow(3) functions as found in System V ( this includes Solaris
2045 and Linux.)  Those systems which implement a proprietary shadow password
2046 facility are unlikely to be supported.
2047
2048 The $members value returned by I<getgr*()> is a space separated list of
2049 the login names of the members of the group.
2050
2051 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2052 C, it will be returned to you via C<$?> if the function call fails.  The
2053 C<@addrs> value returned by a successful call is a list of the raw
2054 addresses returned by the corresponding system library call.  In the
2055 Internet domain, each address is four bytes long and you can unpack it
2056 by saying something like:
2057
2058     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
2059
2060 The Socket library makes this slightly easier:
2061
2062     use Socket;
2063     $iaddr = inet_aton("127.1"); # or whatever address
2064     $name  = gethostbyaddr($iaddr, AF_INET);
2065
2066     # or going the other way
2067     $straddr = inet_ntoa($iaddr);
2068
2069 If you get tired of remembering which element of the return list
2070 contains which return value, by-name interfaces are provided
2071 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2072 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2073 and C<User::grent>.  These override the normal built-ins, supplying
2074 versions that return objects with the appropriate names
2075 for each field.  For example:
2076
2077    use File::stat;
2078    use User::pwent;
2079    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2080
2081 Even though it looks like they're the same method calls (uid),
2082 they aren't, because a C<File::stat> object is different from
2083 a C<User::pwent> object.
2084
2085 =item getsockname SOCKET
2086
2087 Returns the packed sockaddr address of this end of the SOCKET connection,
2088 in case you don't know the address because you have several different
2089 IPs that the connection might have come in on.
2090
2091     use Socket;
2092     $mysockaddr = getsockname(SOCK);
2093     ($port, $myaddr) = sockaddr_in($mysockaddr);
2094     printf "Connect to %s [%s]\n",
2095        scalar gethostbyaddr($myaddr, AF_INET),
2096        inet_ntoa($myaddr);
2097
2098 =item getsockopt SOCKET,LEVEL,OPTNAME
2099
2100 Returns the socket option requested, or undef if there is an error.
2101
2102 =item glob EXPR
2103
2104 =item glob
2105
2106 In list context, returns a (possibly empty) list of filename expansions on
2107 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2108 scalar context, glob iterates through such filename expansions, returning
2109 undef when the list is exhausted. This is the internal function
2110 implementing the C<< <*.c> >> operator, but you can use it directly. If
2111 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2112 more detail in L<perlop/"I/O Operators">.
2113
2114 Beginning with v5.6.0, this operator is implemented using the standard
2115 C<File::Glob> extension.  See L<File::Glob> for details.
2116
2117 =item gmtime EXPR
2118
2119 Converts a time as returned by the time function to an 8-element list
2120 with the time localized for the standard Greenwich time zone.
2121 Typically used as follows:
2122
2123     #  0    1    2     3     4    5     6     7
2124     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2125                                             gmtime(time);
2126
2127 All list elements are numeric, and come straight out of the C `struct
2128 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2129 specified time.  $mday is the day of the month, and $mon is the month
2130 itself, in the range C<0..11> with 0 indicating January and 11
2131 indicating December.  $year is the number of years since 1900.  That
2132 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2133 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2134 the year, in the range C<0..364> (or C<0..365> in leap years.)
2135
2136 Note that the $year element is I<not> simply the last two digits of
2137 the year.  If you assume it is, then you create non-Y2K-compliant
2138 programs--and you wouldn't want to do that, would you?
2139
2140 The proper way to get a complete 4-digit year is simply:
2141
2142         $year += 1900;
2143
2144 And to get the last two digits of the year (e.g., '01' in 2001) do:
2145
2146         $year = sprintf("%02d", $year % 100);
2147
2148 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2149
2150 In scalar context, C<gmtime()> returns the ctime(3) value:
2151
2152     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2153
2154 If you need local time instead of GMT use the L</localtime> builtin. 
2155 See also the C<timegm> function provided by the C<Time::Local> module,
2156 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2157
2158 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2159 instead a Perl builtin.  To get somewhat similar but locale dependent date
2160 strings, see the example in L</localtime>.
2161
2162 =item goto LABEL
2163
2164 =item goto EXPR
2165
2166 =item goto &NAME
2167
2168 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2169 execution there.  It may not be used to go into any construct that
2170 requires initialization, such as a subroutine or a C<foreach> loop.  It
2171 also can't be used to go into a construct that is optimized away,
2172 or to get out of a block or subroutine given to C<sort>.
2173 It can be used to go almost anywhere else within the dynamic scope,
2174 including out of subroutines, but it's usually better to use some other
2175 construct such as C<last> or C<die>.  The author of Perl has never felt the
2176 need to use this form of C<goto> (in Perl, that is--C is another matter).
2177 (The difference being that C does not offer named loops combined with
2178 loop control.  Perl does, and this replaces most structured uses of C<goto>
2179 in other languages.)
2180
2181 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2182 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2183 necessarily recommended if you're optimizing for maintainability:
2184
2185     goto ("FOO", "BAR", "GLARCH")[$i];
2186
2187 The C<goto-&NAME> form is quite different from the other forms of
2188 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2189 doesn't have the stigma associated with other gotos.  Instead, it
2190 exits the current subroutine (losing any changes set by local()) and
2191 immediately calls in its place the named subroutine using the current
2192 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2193 load another subroutine and then pretend that the other subroutine had
2194 been called in the first place (except that any modifications to C<@_>
2195 in the current subroutine are propagated to the other subroutine.)
2196 After the C<goto>, not even C<caller> will be able to tell that this
2197 routine was called first.
2198
2199 NAME needn't be the name of a subroutine; it can be a scalar variable
2200 containing a code reference, or a block which evaluates to a code
2201 reference.
2202
2203 =item grep BLOCK LIST
2204
2205 =item grep EXPR,LIST
2206
2207 This is similar in spirit to, but not the same as, grep(1) and its
2208 relatives.  In particular, it is not limited to using regular expressions.
2209
2210 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2211 C<$_> to each element) and returns the list value consisting of those
2212 elements for which the expression evaluated to true.  In scalar
2213 context, returns the number of times the expression was true.
2214
2215     @foo = grep(!/^#/, @bar);    # weed out comments
2216
2217 or equivalently,
2218
2219     @foo = grep {!/^#/} @bar;    # weed out comments
2220
2221 Note that C<$_> is an alias to the list value, so it can be used to
2222 modify the elements of the LIST.  While this is useful and supported,
2223 it can cause bizarre results if the elements of LIST are not variables.
2224 Similarly, grep returns aliases into the original list, much as a for
2225 loop's index variable aliases the list elements.  That is, modifying an
2226 element of a list returned by grep (for example, in a C<foreach>, C<map>
2227 or another C<grep>) actually modifies the element in the original list.
2228 This is usually something to be avoided when writing clear code.
2229
2230 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2231 been declared with C<my $_>) then, in addition the be locally aliased to
2232 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2233 can't be seen from the outside, avoiding any potential side-effects.
2234
2235 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2236
2237 =item hex EXPR
2238
2239 =item hex
2240
2241 Interprets EXPR as a hex string and returns the corresponding value.
2242 (To convert strings that might start with either 0, 0x, or 0b, see
2243 L</oct>.)  If EXPR is omitted, uses C<$_>.
2244
2245     print hex '0xAf'; # prints '175'
2246     print hex 'aF';   # same
2247
2248 Hex strings may only represent integers.  Strings that would cause
2249 integer overflow trigger a warning.  Leading whitespace is not stripped,
2250 unlike oct().
2251
2252 =item import
2253
2254 There is no builtin C<import> function.  It is just an ordinary
2255 method (subroutine) defined (or inherited) by modules that wish to export
2256 names to another module.  The C<use> function calls the C<import> method
2257 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2258
2259 =item index STR,SUBSTR,POSITION
2260
2261 =item index STR,SUBSTR
2262
2263 The index function searches for one string within another, but without
2264 the wildcard-like behavior of a full regular-expression pattern match.
2265 It returns the position of the first occurrence of SUBSTR in STR at
2266 or after POSITION.  If POSITION is omitted, starts searching from the
2267 beginning of the string.  The return value is based at C<0> (or whatever
2268 you've set the C<$[> variable to--but don't do that).  If the substring
2269 is not found, returns one less than the base, ordinarily C<-1>.
2270
2271 =item int EXPR
2272
2273 =item int
2274
2275 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2276 You should not use this function for rounding: one because it truncates
2277 towards C<0>, and two because machine representations of floating point
2278 numbers can sometimes produce counterintuitive results.  For example,
2279 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2280 because it's really more like -268.99999999999994315658 instead.  Usually,
2281 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2282 functions will serve you better than will int().
2283
2284 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2285
2286 Implements the ioctl(2) function.  You'll probably first have to say
2287
2288     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2289
2290 to get the correct function definitions.  If F<ioctl.ph> doesn't
2291 exist or doesn't have the correct definitions you'll have to roll your
2292 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2293 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2294 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2295 written depending on the FUNCTION--a pointer to the string value of SCALAR
2296 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2297 has no string value but does have a numeric value, that value will be
2298 passed rather than a pointer to the string value.  To guarantee this to be
2299 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2300 functions may be needed to manipulate the values of structures used by
2301 C<ioctl>.
2302
2303 The return value of C<ioctl> (and C<fcntl>) is as follows:
2304
2305         if OS returns:          then Perl returns:
2306             -1                    undefined value
2307              0                  string "0 but true"
2308         anything else               that number
2309
2310 Thus Perl returns true on success and false on failure, yet you can
2311 still easily determine the actual value returned by the operating
2312 system:
2313
2314     $retval = ioctl(...) || -1;
2315     printf "System returned %d\n", $retval;
2316
2317 The special string C<"0 but true"> is exempt from B<-w> complaints
2318 about improper numeric conversions.
2319
2320 =item join EXPR,LIST
2321
2322 Joins the separate strings of LIST into a single string with fields
2323 separated by the value of EXPR, and returns that new string.  Example:
2324
2325     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2326
2327 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2328 first argument.  Compare L</split>.
2329
2330 =item keys HASH
2331
2332 Returns a list consisting of all the keys of the named hash.
2333 (In scalar context, returns the number of keys.)
2334
2335 The keys are returned in an apparently random order.  The actual
2336 random order is subject to change in future versions of perl, but it
2337 is guaranteed to be the same order as either the C<values> or C<each>
2338 function produces (given that the hash has not been modified).  Since
2339 Perl 5.8.1 the ordering is different even between different runs of
2340 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2341 Attacks">).
2342
2343 As a side effect, calling keys() resets the HASH's internal iterator,
2344 see L</each>. (In particular, calling keys() in void context resets
2345 the iterator with no other overhead.)
2346
2347 Here is yet another way to print your environment:
2348
2349     @keys = keys %ENV;
2350     @values = values %ENV;
2351     while (@keys) {
2352         print pop(@keys), '=', pop(@values), "\n";
2353     }
2354
2355 or how about sorted by key:
2356
2357     foreach $key (sort(keys %ENV)) {
2358         print $key, '=', $ENV{$key}, "\n";
2359     }
2360
2361 The returned values are copies of the original keys in the hash, so
2362 modifying them will not affect the original hash.  Compare L</values>.
2363
2364 To sort a hash by value, you'll need to use a C<sort> function.
2365 Here's a descending numeric sort of a hash by its values:
2366
2367     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2368         printf "%4d %s\n", $hash{$key}, $key;
2369     }
2370
2371 As an lvalue C<keys> allows you to increase the number of hash buckets
2372 allocated for the given hash.  This can gain you a measure of efficiency if
2373 you know the hash is going to get big.  (This is similar to pre-extending
2374 an array by assigning a larger number to $#array.)  If you say
2375
2376     keys %hash = 200;
2377
2378 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2379 in fact, since it rounds up to the next power of two.  These
2380 buckets will be retained even if you do C<%hash = ()>, use C<undef
2381 %hash> if you want to free the storage while C<%hash> is still in scope.
2382 You can't shrink the number of buckets allocated for the hash using
2383 C<keys> in this way (but you needn't worry about doing this by accident,
2384 as trying has no effect).
2385
2386 See also C<each>, C<values> and C<sort>.
2387
2388 =item kill SIGNAL, LIST
2389
2390 Sends a signal to a list of processes.  Returns the number of
2391 processes successfully signaled (which is not necessarily the
2392 same as the number actually killed).
2393
2394     $cnt = kill 1, $child1, $child2;
2395     kill 9, @goners;
2396
2397 If SIGNAL is zero, no signal is sent to the process.  This is a
2398 useful way to check that a child process is alive and hasn't changed
2399 its UID.  See L<perlport> for notes on the portability of this
2400 construct.
2401
2402 Unlike in the shell, if SIGNAL is negative, it kills
2403 process groups instead of processes.  (On System V, a negative I<PROCESS>
2404 number will also kill process groups, but that's not portable.)  That
2405 means you usually want to use positive not negative signals.  You may also
2406 use a signal name in quotes.
2407
2408 See L<perlipc/"Signals"> for more details.
2409
2410 =item last LABEL
2411
2412 =item last
2413
2414 The C<last> command is like the C<break> statement in C (as used in
2415 loops); it immediately exits the loop in question.  If the LABEL is
2416 omitted, the command refers to the innermost enclosing loop.  The
2417 C<continue> block, if any, is not executed:
2418
2419     LINE: while (<STDIN>) {
2420         last LINE if /^$/;      # exit when done with header
2421         #...
2422     }
2423
2424 C<last> cannot be used to exit a block which returns a value such as
2425 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2426 a grep() or map() operation.
2427
2428 Note that a block by itself is semantically identical to a loop
2429 that executes once.  Thus C<last> can be used to effect an early
2430 exit out of such a block.
2431
2432 See also L</continue> for an illustration of how C<last>, C<next>, and
2433 C<redo> work.
2434
2435 =item lc EXPR
2436
2437 =item lc
2438
2439 Returns a lowercased version of EXPR.  This is the internal function
2440 implementing the C<\L> escape in double-quoted strings.  Respects
2441 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2442 and L<perlunicode> for more details about locale and Unicode support.
2443
2444 If EXPR is omitted, uses C<$_>.
2445
2446 =item lcfirst EXPR
2447
2448 =item lcfirst
2449
2450 Returns the value of EXPR with the first character lowercased.  This
2451 is the internal function implementing the C<\l> escape in
2452 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2453 locale> in force.  See L<perllocale> and L<perlunicode> for more
2454 details about locale and Unicode support.
2455
2456 If EXPR is omitted, uses C<$_>.
2457
2458 =item length EXPR
2459
2460 =item length
2461
2462 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2463 omitted, returns length of C<$_>.  Note that this cannot be used on
2464 an entire array or hash to find out how many elements these have.
2465 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2466
2467 Note the I<characters>: if the EXPR is in Unicode, you will get the
2468 number of characters, not the number of bytes.  To get the length
2469 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2470
2471 =item link OLDFILE,NEWFILE
2472
2473 Creates a new filename linked to the old filename.  Returns true for
2474 success, false otherwise.
2475
2476 =item listen SOCKET,QUEUESIZE
2477
2478 Does the same thing that the listen system call does.  Returns true if
2479 it succeeded, false otherwise.  See the example in
2480 L<perlipc/"Sockets: Client/Server Communication">.
2481
2482 =item local EXPR
2483
2484 You really probably want to be using C<my> instead, because C<local> isn't
2485 what most people think of as "local".  See
2486 L<perlsub/"Private Variables via my()"> for details.
2487
2488 A local modifies the listed variables to be local to the enclosing
2489 block, file, or eval.  If more than one value is listed, the list must
2490 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2491 for details, including issues with tied arrays and hashes.
2492
2493 =item localtime EXPR
2494
2495 Converts a time as returned by the time function to a 9-element list
2496 with the time analyzed for the local time zone.  Typically used as
2497 follows:
2498
2499     #  0    1    2     3     4    5     6     7     8
2500     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2501                                                 localtime(time);
2502
2503 All list elements are numeric, and come straight out of the C `struct
2504 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2505 specified time.  $mday is the day of the month, and $mon is the month
2506 itself, in the range C<0..11> with 0 indicating January and 11
2507 indicating December.  $year is the number of years since 1900.  That
2508 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2509 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2510 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2511 is true if the specified time occurs during daylight savings time,
2512 false otherwise.
2513
2514 Note that the $year element is I<not> simply the last two digits of
2515 the year.  If you assume it is, then you create non-Y2K-compliant
2516 programs--and you wouldn't want to do that, would you?
2517
2518 The proper way to get a complete 4-digit year is simply:
2519
2520         $year += 1900;
2521
2522 And to get the last two digits of the year (e.g., '01' in 2001) do:
2523
2524         $year = sprintf("%02d", $year % 100);
2525
2526 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2527
2528 In scalar context, C<localtime()> returns the ctime(3) value:
2529
2530     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2531
2532 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2533 instead of local time use the L</gmtime> builtin. See also the
2534 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2535 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2536 and mktime(3) functions.
2537
2538 To get somewhat similar but locale dependent date strings, set up your
2539 locale environment variables appropriately (please see L<perllocale>) and
2540 try for example:
2541
2542     use POSIX qw(strftime);
2543     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2544     # or for GMT formatted appropriately for your locale:
2545     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2546
2547 Note that the C<%a> and C<%b>, the short forms of the day of the week
2548 and the month of the year, may not necessarily be three characters wide.
2549
2550 =item lock THING
2551
2552 This function places an advisory lock on a shared variable, or referenced
2553 object contained in I<THING> until the lock goes out of scope.
2554
2555 lock() is a "weak keyword" : this means that if you've defined a function
2556 by this name (before any calls to it), that function will be called
2557 instead. (However, if you've said C<use threads>, lock() is always a
2558 keyword.) See L<threads>.
2559
2560 =item log EXPR
2561
2562 =item log
2563
2564 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2565 returns log of C<$_>.  To get the log of another base, use basic algebra:
2566 The base-N log of a number is equal to the natural log of that number
2567 divided by the natural log of N.  For example:
2568
2569     sub log10 {
2570         my $n = shift;
2571         return log($n)/log(10);
2572     }
2573
2574 See also L</exp> for the inverse operation.
2575
2576 =item lstat EXPR
2577
2578 =item lstat
2579
2580 Does the same thing as the C<stat> function (including setting the
2581 special C<_> filehandle) but stats a symbolic link instead of the file
2582 the symbolic link points to.  If symbolic links are unimplemented on
2583 your system, a normal C<stat> is done.  For much more detailed
2584 information, please see the documentation for C<stat>.
2585
2586 If EXPR is omitted, stats C<$_>.
2587
2588 =item m//
2589
2590 The match operator.  See L<perlop>.
2591
2592 =item map BLOCK LIST
2593
2594 =item map EXPR,LIST
2595
2596 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2597 C<$_> to each element) and returns the list value composed of the
2598 results of each such evaluation.  In scalar context, returns the
2599 total number of elements so generated.  Evaluates BLOCK or EXPR in
2600 list context, so each element of LIST may produce zero, one, or
2601 more elements in the returned value.
2602
2603     @chars = map(chr, @nums);
2604
2605 translates a list of numbers to the corresponding characters.  And
2606
2607     %hash = map { getkey($_) => $_ } @array;
2608
2609 is just a funny way to write
2610
2611     %hash = ();
2612     foreach $_ (@array) {
2613         $hash{getkey($_)} = $_;
2614     }
2615
2616 Note that C<$_> is an alias to the list value, so it can be used to
2617 modify the elements of the LIST.  While this is useful and supported,
2618 it can cause bizarre results if the elements of LIST are not variables.
2619 Using a regular C<foreach> loop for this purpose would be clearer in
2620 most cases.  See also L</grep> for an array composed of those items of
2621 the original list for which the BLOCK or EXPR evaluates to true.
2622
2623 If C<$_> is lexical in the scope where the C<map> appears (because it has
2624 been declared with C<my $_>) then, in addition the be locally aliased to
2625 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2626 can't be seen from the outside, avoiding any potential side-effects.
2627
2628 C<{> starts both hash references and blocks, so C<map { ...> could be either
2629 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2630 ahead for the closing C<}> it has to take a guess at which its dealing with
2631 based what it finds just after the C<{>. Usually it gets it right, but if it
2632 doesn't it won't realize something is wrong until it gets to the C<}> and
2633 encounters the missing (or unexpected) comma. The syntax error will be
2634 reported close to the C<}> but you'll need to change something near the C<{>
2635 such as using a unary C<+> to give perl some help:
2636
2637     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2638     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2639     %hash = map { ("\L$_", 1) } @array  # this also works
2640     %hash = map {  lc($_), 1  } @array  # as does this.
2641     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2642
2643     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2644
2645 or to force an anon hash constructor use C<+{>
2646
2647    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2648
2649 and you get list of anonymous hashes each with only 1 entry.
2650
2651 =item mkdir FILENAME,MASK
2652
2653 =item mkdir FILENAME
2654
2655 Creates the directory specified by FILENAME, with permissions
2656 specified by MASK (as modified by C<umask>).  If it succeeds it
2657 returns true, otherwise it returns false and sets C<$!> (errno).
2658 If omitted, MASK defaults to 0777.
2659
2660 In general, it is better to create directories with permissive MASK,
2661 and let the user modify that with their C<umask>, than it is to supply
2662 a restrictive MASK and give the user no way to be more permissive.
2663 The exceptions to this rule are when the file or directory should be
2664 kept private (mail files, for instance).  The perlfunc(1) entry on
2665 C<umask> discusses the choice of MASK in more detail.
2666
2667 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2668 number of trailing slashes.  Some operating and filesystems do not get
2669 this right, so Perl automatically removes all trailing slashes to keep
2670 everyone happy.
2671
2672 =item msgctl ID,CMD,ARG
2673
2674 Calls the System V IPC function msgctl(2).  You'll probably have to say
2675
2676     use IPC::SysV;
2677
2678 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2679 then ARG must be a variable which will hold the returned C<msqid_ds>
2680 structure.  Returns like C<ioctl>: the undefined value for error,
2681 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2682 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2683
2684 =item msgget KEY,FLAGS
2685
2686 Calls the System V IPC function msgget(2).  Returns the message queue
2687 id, or the undefined value if there is an error.  See also
2688 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2689
2690 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2691
2692 Calls the System V IPC function msgrcv to receive a message from
2693 message queue ID into variable VAR with a maximum message size of
2694 SIZE.  Note that when a message is received, the message type as a
2695 native long integer will be the first thing in VAR, followed by the
2696 actual message.  This packing may be opened with C<unpack("l! a*")>.
2697 Taints the variable.  Returns true if successful, or false if there is
2698 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2699 C<IPC::SysV::Msg> documentation.
2700
2701 =item msgsnd ID,MSG,FLAGS
2702
2703 Calls the System V IPC function msgsnd to send the message MSG to the
2704 message queue ID.  MSG must begin with the native long integer message
2705 type, and be followed by the length of the actual message, and finally
2706 the message itself.  This kind of packing can be achieved with
2707 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2708 or false if there is an error.  See also C<IPC::SysV>
2709 and C<IPC::SysV::Msg> documentation.
2710
2711 =item my EXPR
2712
2713 =item my TYPE EXPR
2714
2715 =item my EXPR : ATTRS
2716
2717 =item my TYPE EXPR : ATTRS
2718
2719 A C<my> declares the listed variables to be local (lexically) to the
2720 enclosing block, file, or C<eval>.  If more than one value is listed,
2721 the list must be placed in parentheses.
2722
2723 The exact semantics and interface of TYPE and ATTRS are still
2724 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2725 and attributes are handled using the C<attributes> pragma, or starting
2726 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2727 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2728 L<attributes>, and L<Attribute::Handlers>.
2729
2730 =item next LABEL
2731
2732 =item next
2733
2734 The C<next> command is like the C<continue> statement in C; it starts
2735 the next iteration of the loop:
2736
2737     LINE: while (<STDIN>) {
2738         next LINE if /^#/;      # discard comments
2739         #...
2740     }
2741
2742 Note that if there were a C<continue> block on the above, it would get
2743 executed even on discarded lines.  If the LABEL is omitted, the command
2744 refers to the innermost enclosing loop.
2745
2746 C<next> cannot be used to exit a block which returns a value such as
2747 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2748 a grep() or map() operation.
2749
2750 Note that a block by itself is semantically identical to a loop
2751 that executes once.  Thus C<next> will exit such a block early.
2752
2753 See also L</continue> for an illustration of how C<last>, C<next>, and
2754 C<redo> work.
2755
2756 =item no Module VERSION LIST
2757
2758 =item no Module VERSION
2759
2760 =item no Module LIST
2761
2762 =item no Module
2763
2764 See the C<use> function, of which C<no> is the opposite.
2765
2766 =item oct EXPR
2767
2768 =item oct
2769
2770 Interprets EXPR as an octal string and returns the corresponding
2771 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2772 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2773 binary string.  Leading whitespace is ignored in all three cases.)
2774 The following will handle decimal, binary, octal, and hex in the standard
2775 Perl or C notation:
2776
2777     $val = oct($val) if $val =~ /^0/;
2778
2779 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2780 in octal), use sprintf() or printf():
2781
2782     $perms = (stat("filename"))[2] & 07777;
2783     $oct_perms = sprintf "%lo", $perms;
2784
2785 The oct() function is commonly used when a string such as C<644> needs
2786 to be converted into a file mode, for example. (Although perl will
2787 automatically convert strings into numbers as needed, this automatic
2788 conversion assumes base 10.)
2789
2790 =item open FILEHANDLE,EXPR
2791
2792 =item open FILEHANDLE,MODE,EXPR
2793
2794 =item open FILEHANDLE,MODE,EXPR,LIST
2795
2796 =item open FILEHANDLE,MODE,REFERENCE
2797
2798 =item open FILEHANDLE
2799
2800 Opens the file whose filename is given by EXPR, and associates it with
2801 FILEHANDLE.
2802
2803 (The following is a comprehensive reference to open(): for a gentler
2804 introduction you may consider L<perlopentut>.)
2805
2806 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2807 the variable is assigned a reference to a new anonymous filehandle,
2808 otherwise if FILEHANDLE is an expression, its value is used as the name of
2809 the real filehandle wanted.  (This is considered a symbolic reference, so
2810 C<use strict 'refs'> should I<not> be in effect.)
2811
2812 If EXPR is omitted, the scalar variable of the same name as the
2813 FILEHANDLE contains the filename.  (Note that lexical variables--those
2814 declared with C<my>--will not work for this purpose; so if you're
2815 using C<my>, specify EXPR in your call to open.)
2816
2817 If three or more arguments are specified then the mode of opening and
2818 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2819 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2820 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2821 the file is opened for appending, again being created if necessary.
2822
2823 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2824 indicate that you want both read and write access to the file; thus
2825 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2826 '+>' >> mode would clobber the file first.  You can't usually use
2827 either read-write mode for updating textfiles, since they have
2828 variable length records.  See the B<-i> switch in L<perlrun> for a
2829 better approach.  The file is created with permissions of C<0666>
2830 modified by the process' C<umask> value.
2831
2832 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2833 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2834
2835 In the 2-arguments (and 1-argument) form of the call the mode and
2836 filename should be concatenated (in this order), possibly separated by
2837 spaces.  It is possible to omit the mode in these forms if the mode is
2838 C<< '<' >>.
2839
2840 If the filename begins with C<'|'>, the filename is interpreted as a
2841 command to which output is to be piped, and if the filename ends with a
2842 C<'|'>, the filename is interpreted as a command which pipes output to
2843 us.  See L<perlipc/"Using open() for IPC">
2844 for more examples of this.  (You are not allowed to C<open> to a command
2845 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2846 and L<perlipc/"Bidirectional Communication with Another Process">
2847 for alternatives.)
2848
2849 For three or more arguments if MODE is C<'|-'>, the filename is
2850 interpreted as a command to which output is to be piped, and if MODE
2851 is C<'-|'>, the filename is interpreted as a command which pipes
2852 output to us.  In the 2-arguments (and 1-argument) form one should
2853 replace dash (C<'-'>) with the command.
2854 See L<perlipc/"Using open() for IPC"> for more examples of this.
2855 (You are not allowed to C<open> to a command that pipes both in I<and>
2856 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2857 L<perlipc/"Bidirectional Communication"> for alternatives.)
2858
2859 In the three-or-more argument form of pipe opens, if LIST is specified
2860 (extra arguments after the command name) then LIST becomes arguments
2861 to the command invoked if the platform supports it.  The meaning of
2862 C<open> with more than three arguments for non-pipe modes is not yet
2863 specified. Experimental "layers" may give extra LIST arguments
2864 meaning.
2865
2866 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2867 and opening C<< '>-' >> opens STDOUT.
2868
2869 You may use the three-argument form of open to specify IO "layers"
2870 (sometimes also referred to as "disciplines") to be applied to the handle
2871 that affect how the input and output are processed (see L<open> and
2872 L<PerlIO> for more details). For example
2873
2874   open(FH, "<:utf8", "file")
2875
2876 will open the UTF-8 encoded file containing Unicode characters,
2877 see L<perluniintro>. (Note that if layers are specified in the
2878 three-arg form then default layers set by the C<open> pragma are
2879 ignored.)
2880
2881 Open returns nonzero upon success, the undefined value otherwise.  If
2882 the C<open> involved a pipe, the return value happens to be the pid of
2883 the subprocess.
2884
2885 If you're running Perl on a system that distinguishes between text
2886 files and binary files, then you should check out L</binmode> for tips
2887 for dealing with this.  The key distinction between systems that need
2888 C<binmode> and those that don't is their text file formats.  Systems
2889 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2890 character, and which encode that character in C as C<"\n">, do not
2891 need C<binmode>.  The rest need it.
2892
2893 When opening a file, it's usually a bad idea to continue normal execution
2894 if the request failed, so C<open> is frequently used in connection with
2895 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2896 where you want to make a nicely formatted error message (but there are
2897 modules that can help with that problem)) you should always check
2898 the return value from opening a file.  The infrequent exception is when
2899 working with an unopened filehandle is actually what you want to do.
2900
2901 As a special case the 3 arg form with a read/write mode and the third
2902 argument being C<undef>:
2903
2904     open(TMP, "+>", undef) or die ...
2905
2906 opens a filehandle to an anonymous temporary file.  Also using "+<"
2907 works for symmetry, but you really should consider writing something
2908 to the temporary file first.  You will need to seek() to do the
2909 reading.
2910
2911 File handles can be opened to "in memory" files held in Perl scalars via:
2912
2913     open($fh, '>', \$variable) || ..
2914
2915 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2916 file, you have to close it first:
2917
2918     close STDOUT;
2919     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2920
2921 Examples:
2922
2923     $ARTICLE = 100;
2924     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2925     while (<ARTICLE>) {...
2926
2927     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2928     # if the open fails, output is discarded
2929
2930     open(DBASE, '+<', 'dbase.mine')             # open for update
2931         or die "Can't open 'dbase.mine' for update: $!";
2932
2933     open(DBASE, '+<dbase.mine')                 # ditto
2934         or die "Can't open 'dbase.mine' for update: $!";
2935
2936     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2937         or die "Can't start caesar: $!";
2938
2939     open(ARTICLE, "caesar <$article |")         # ditto
2940         or die "Can't start caesar: $!";
2941
2942     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
2943         or die "Can't start sort: $!";
2944
2945     # in memory files
2946     open(MEMORY,'>', \$var)
2947         or die "Can't open memory file: $!";
2948     print MEMORY "foo!\n";                      # output will end up in $var
2949
2950     # process argument list of files along with any includes
2951
2952     foreach $file (@ARGV) {
2953         process($file, 'fh00');
2954     }
2955
2956     sub process {
2957         my($filename, $input) = @_;
2958         $input++;               # this is a string increment
2959         unless (open($input, $filename)) {
2960             print STDERR "Can't open $filename: $!\n";
2961             return;
2962         }
2963
2964         local $_;
2965         while (<$input>) {              # note use of indirection
2966             if (/^#include "(.*)"/) {
2967                 process($1, $input);
2968                 next;
2969             }
2970             #...                # whatever
2971         }
2972     }
2973
2974 You may also, in the Bourne shell tradition, specify an EXPR beginning
2975 with C<< '>&' >>, in which case the rest of the string is interpreted
2976 as the name of a filehandle (or file descriptor, if numeric) to be
2977 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
2978 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
2979 The mode you specify should match the mode of the original filehandle.
2980 (Duping a filehandle does not take into account any existing contents
2981 of IO buffers.) If you use the 3 arg form then you can pass either a
2982 number, the name of a filehandle or the normal "reference to a glob".
2983
2984 Here is a script that saves, redirects, and restores C<STDOUT> and
2985 C<STDERR> using various methods:
2986
2987     #!/usr/bin/perl
2988     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2989     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
2990
2991     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
2992     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2993
2994     select STDERR; $| = 1;      # make unbuffered
2995     select STDOUT; $| = 1;      # make unbuffered
2996
2997     print STDOUT "stdout 1\n";  # this works for
2998     print STDERR "stderr 1\n";  # subprocesses too
2999
3000     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3001     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3002
3003     print STDOUT "stdout 2\n";
3004     print STDERR "stderr 2\n";
3005
3006 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3007 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3008 that file descriptor (and not call L<dup(2)>); this is more
3009 parsimonious of file descriptors.  For example:
3010
3011     # open for input, reusing the fileno of $fd
3012     open(FILEHANDLE, "<&=$fd")
3013
3014 or
3015
3016     open(FILEHANDLE, "<&=", $fd)
3017
3018 or
3019
3020     # open for append, using the fileno of OLDFH
3021     open(FH, ">>&=", OLDFH)
3022
3023 or
3024
3025     open(FH, ">>&=OLDFH")
3026
3027 Being parsimonious on filehandles is also useful (besides being
3028 parsimonious) for example when something is dependent on file
3029 descriptors, like for example locking using flock().  If you do just
3030 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3031 descriptor as B, and therefore flock(A) will not flock(B), and vice
3032 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3033 the same file descriptor.
3034
3035 Note that if you are using Perls older than 5.8.0, Perl will be using
3036 the standard C libraries' fdopen() to implement the "=" functionality.
3037 On many UNIX systems fdopen() fails when file descriptors exceed a
3038 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3039 most often the default.
3040
3041 You can see whether Perl has been compiled with PerlIO or not by
3042 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3043 is C<define>, you have PerlIO, otherwise you don't.
3044
3045 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3046 with 2-arguments (or 1-argument) form of open(), then
3047 there is an implicit fork done, and the return value of open is the pid
3048 of the child within the parent process, and C<0> within the child
3049 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3050 The filehandle behaves normally for the parent, but i/o to that
3051 filehandle is piped from/to the STDOUT/STDIN of the child process.
3052 In the child process the filehandle isn't opened--i/o happens from/to
3053 the new STDOUT or STDIN.  Typically this is used like the normal
3054 piped open when you want to exercise more control over just how the
3055 pipe command gets executed, such as when you are running setuid, and
3056 don't want to have to scan shell commands for metacharacters.
3057 The following triples are more or less equivalent:
3058
3059     open(FOO, "|tr '[a-z]' '[A-Z]'");
3060     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3061     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3062     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3063
3064     open(FOO, "cat -n '$file'|");
3065     open(FOO, '-|', "cat -n '$file'");
3066     open(FOO, '-|') || exec 'cat', '-n', $file;
3067     open(FOO, '-|', "cat", '-n', $file);
3068
3069 The last example in each block shows the pipe as "list form", which is
3070 not yet supported on all platforms.  A good rule of thumb is that if
3071 your platform has true C<fork()> (in other words, if your platform is
3072 UNIX) you can use the list form.
3073
3074 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3075
3076 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3077 output before any operation that may do a fork, but this may not be
3078 supported on some platforms (see L<perlport>).  To be safe, you may need
3079 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3080 of C<IO::Handle> on any open handles.
3081
3082 On systems that support a close-on-exec flag on files, the flag will
3083 be set for the newly opened file descriptor as determined by the value
3084 of $^F.  See L<perlvar/$^F>.
3085
3086 Closing any piped filehandle causes the parent process to wait for the
3087 child to finish, and returns the status value in C<$?>.
3088
3089 The filename passed to 2-argument (or 1-argument) form of open() will
3090 have leading and trailing whitespace deleted, and the normal
3091 redirection characters honored.  This property, known as "magic open",
3092 can often be used to good effect.  A user could specify a filename of
3093 F<"rsh cat file |">, or you could change certain filenames as needed:
3094
3095     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3096     open(FH, $filename) or die "Can't open $filename: $!";
3097
3098 Use 3-argument form to open a file with arbitrary weird characters in it,
3099
3100     open(FOO, '<', $file);
3101
3102 otherwise it's necessary to protect any leading and trailing whitespace:
3103
3104     $file =~ s#^(\s)#./$1#;
3105     open(FOO, "< $file\0");
3106
3107 (this may not work on some bizarre filesystems).  One should
3108 conscientiously choose between the I<magic> and 3-arguments form
3109 of open():
3110
3111     open IN, $ARGV[0];
3112
3113 will allow the user to specify an argument of the form C<"rsh cat file |">,
3114 but will not work on a filename which happens to have a trailing space, while
3115
3116     open IN, '<', $ARGV[0];
3117
3118 will have exactly the opposite restrictions.
3119
3120 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3121 should use the C<sysopen> function, which involves no such magic (but
3122 may use subtly different filemodes than Perl open(), which is mapped
3123 to C fopen()).  This is
3124 another way to protect your filenames from interpretation.  For example:
3125
3126     use IO::Handle;
3127     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3128         or die "sysopen $path: $!";
3129     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3130     print HANDLE "stuff $$\n";
3131     seek(HANDLE, 0, 0);
3132     print "File contains: ", <HANDLE>;
3133
3134 Using the constructor from the C<IO::Handle> package (or one of its
3135 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3136 filehandles that have the scope of whatever variables hold references to
3137 them, and automatically close whenever and however you leave that scope:
3138
3139     use IO::File;
3140     #...
3141     sub read_myfile_munged {
3142         my $ALL = shift;
3143         my $handle = new IO::File;
3144         open($handle, "myfile") or die "myfile: $!";
3145         $first = <$handle>
3146             or return ();     # Automatically closed here.
3147         mung $first or die "mung failed";       # Or here.
3148         return $first, <$handle> if $ALL;       # Or here.
3149         $first;                                 # Or here.
3150     }
3151
3152 See L</seek> for some details about mixing reading and writing.
3153
3154 =item opendir DIRHANDLE,EXPR
3155
3156 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3157 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3158 DIRHANDLE may be an expression whose value can be used as an indirect
3159 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3160 scalar variable (or array or hash element), the variable is assigned a
3161 reference to a new anonymous dirhandle.
3162 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3163
3164 =item ord EXPR
3165
3166 =item ord
3167
3168 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3169 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3170 uses C<$_>.
3171
3172 For the reverse, see L</chr>.
3173 See L<perlunicode> and L<encoding> for more about Unicode.
3174
3175 =item our EXPR
3176
3177 =item our EXPR TYPE
3178
3179 =item our EXPR : ATTRS
3180
3181 =item our TYPE EXPR : ATTRS
3182
3183 An C<our> declares the listed variables to be valid globals within
3184 the enclosing block, file, or C<eval>.  That is, it has the same
3185 scoping rules as a "my" declaration, but does not create a local
3186 variable.  If more than one value is listed, the list must be placed
3187 in parentheses.  The C<our> declaration has no semantic effect unless
3188 "use strict vars" is in effect, in which case it lets you use the
3189 declared global variable without qualifying it with a package name.
3190 (But only within the lexical scope of the C<our> declaration.  In this
3191 it differs from "use vars", which is package scoped.)
3192
3193 An C<our> declaration declares a global variable that will be visible
3194 across its entire lexical scope, even across package boundaries.  The
3195 package in which the variable is entered is determined at the point
3196 of the declaration, not at the point of use.  This means the following
3197 behavior holds:
3198
3199     package Foo;
3200     our $bar;           # declares $Foo::bar for rest of lexical scope
3201     $bar = 20;
3202
3203     package Bar;
3204     print $bar;         # prints 20
3205
3206 Multiple C<our> declarations in the same lexical scope are allowed
3207 if they are in different packages.  If they happened to be in the same
3208 package, Perl will emit warnings if you have asked for them.
3209
3210     use warnings;
3211     package Foo;
3212     our $bar;           # declares $Foo::bar for rest of lexical scope
3213     $bar = 20;
3214
3215     package Bar;
3216     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3217     print $bar;         # prints 30
3218
3219     our $bar;           # emits warning
3220
3221 An C<our> declaration may also have a list of attributes associated
3222 with it.
3223
3224 The exact semantics and interface of TYPE and ATTRS are still
3225 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3226 and attributes are handled using the C<attributes> pragma, or starting
3227 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3228 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3229 L<attributes>, and L<Attribute::Handlers>.
3230
3231 The only currently recognized C<our()> attribute is C<unique> which
3232 indicates that a single copy of the global is to be used by all
3233 interpreters should the program happen to be running in a
3234 multi-interpreter environment. (The default behaviour would be for
3235 each interpreter to have its own copy of the global.)  Examples:
3236
3237     our @EXPORT : unique = qw(foo);
3238     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3239     our $VERSION : unique = "1.00";
3240
3241 Note that this attribute also has the effect of making the global
3242 readonly when the first new interpreter is cloned (for example,
3243 when the first new thread is created).
3244
3245 Multi-interpreter environments can come to being either through the
3246 fork() emulation on Windows platforms, or by embedding perl in a
3247 multi-threaded application.  The C<unique> attribute does nothing in
3248 all other environments.
3249
3250 Warning: the current implementation of this attribute operates on the
3251 typeglob associated with the variable; this means that C<our $x : unique>
3252 also has the effect of C<our @x : unique; our %x : unique>. This may be
3253 subject to change.
3254
3255 =item pack TEMPLATE,LIST
3256
3257 Takes a LIST of values and converts it into a string using the rules
3258 given by the TEMPLATE.  The resulting string is the concatenation of
3259 the converted values.  Typically, each converted value looks
3260 like its machine-level representation.  For example, on 32-bit machines
3261 a converted integer may be represented by a sequence of 4 bytes.
3262
3263 The TEMPLATE is a sequence of characters that give the order and type
3264 of values, as follows:
3265
3266     a   A string with arbitrary binary data, will be null padded.
3267     A   A text (ASCII) string, will be space padded.
3268     Z   A null terminated (ASCIZ) string, will be null padded.
3269
3270     b   A bit string (ascending bit order inside each byte, like vec()).
3271     B   A bit string (descending bit order inside each byte).
3272     h   A hex string (low nybble first).
3273     H   A hex string (high nybble first).
3274
3275     c   A signed char (8-bit) value.
3276     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3277
3278     s   A signed short (16-bit) value.
3279     S   An unsigned short value.
3280
3281     l   A signed long (32-bit) value.
3282     L   An unsigned long value.
3283
3284     q   A signed quad (64-bit) value.
3285     Q   An unsigned quad value.
3286           (Quads are available only if your system supports 64-bit
3287            integer values _and_ if Perl has been compiled to support those.
3288            Causes a fatal error otherwise.)
3289
3290     i   A signed integer value.
3291     I   A unsigned integer value.
3292           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3293            size depends on what a local C compiler calls 'int'.)
3294  
3295     n   An unsigned short (16-bit) in "network" (big-endian) order.
3296     N   An unsigned long (32-bit) in "network" (big-endian) order.
3297     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3298     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3299
3300     j   A Perl internal signed integer value (IV).
3301     J   A Perl internal unsigned integer value (UV).
3302
3303     f   A single-precision float in the native format.
3304     d   A double-precision float in the native format.
3305
3306     F   A Perl internal floating point value (NV) in the native format
3307     D   A long double-precision float in the native format.
3308           (Long doubles are available only if your system supports long
3309            double values _and_ if Perl has been compiled to support those.
3310            Causes a fatal error otherwise.)
3311
3312     p   A pointer to a null-terminated string.
3313     P   A pointer to a structure (fixed-length string).
3314
3315     u   A uuencoded string.
3316     U   A Unicode character number.  Encodes to UTF-8 internally
3317         (or UTF-EBCDIC in EBCDIC platforms).
3318
3319     w   A BER compressed integer.  Its bytes represent an unsigned
3320         integer in base 128, most significant digit first, with as
3321         few digits as possible.  Bit eight (the high bit) is set
3322         on each byte except the last.
3323
3324     x   A null byte.
3325     X   Back up a byte.
3326     @   Null fill to absolute position, counted from the start of
3327         the innermost ()-group.
3328     (   Start of a ()-group.
3329
3330 Some letters in the TEMPLATE may optionally be followed by one or
3331 more of these modifiers (the second column lists the letters for
3332 which the modifier is valid):
3333
3334     !   sSlLiI     Forces native (short, long, int) sizes instead
3335                    of fixed (16-/32-bit) sizes.
3336
3337         xX         Make x and X act as alignment commands.
3338
3339         nNvV       Treat integers as signed instead of unsigned.
3340
3341     >   sSiIlLqQ   Force big-endian byte-order on the type.
3342         jJfFdDpP   (The "big end" touches the construct.)
3343
3344     <   sSiIlLqQ   Force little-endian byte-order on the type.
3345         jJfFdDpP   (The "little end" touches the construct.)
3346
3347 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3348 in which case they force a certain byte-order on all components of
3349 that group, including subgroups.
3350
3351 The following rules apply:
3352
3353 =over 8
3354
3355 =item *
3356
3357 Each letter may optionally be followed by a number giving a repeat
3358 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3359 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3360 many values from the LIST.  A C<*> for the repeat count means to use
3361 however many items are left, except for C<@>, C<x>, C<X>, where it is
3362 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3363 is the same).  A numeric repeat count may optionally be enclosed in
3364 brackets, as in C<pack 'C[80]', @arr>.
3365
3366 One can replace the numeric repeat count by a template enclosed in brackets;
3367 then the packed length of this template in bytes is used as a count.
3368 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3369 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3370 If the template in brackets contains alignment commands (such as C<x![d]>),
3371 its packed length is calculated as if the start of the template has the maximal
3372 possible alignment.
3373
3374 When used with C<Z>, C<*> results in the addition of a trailing null
3375 byte (so the packed result will be one longer than the byte C<length>
3376 of the item).
3377
3378 The repeat count for C<u> is interpreted as the maximal number of bytes
3379 to encode per line of output, with 0 and 1 replaced by 45.
3380
3381 =item *
3382
3383 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3384 string of length count, padding with nulls or spaces as necessary.  When
3385 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3386 after the first null, and C<a> returns data verbatim.  When packing,
3387 C<a>, and C<Z> are equivalent.
3388
3389 If the value-to-pack is too long, it is truncated.  If too long and an
3390 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3391 by a null byte.  Thus C<Z> always packs a trailing null byte under
3392 all circumstances.
3393
3394 =item *
3395
3396 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3397 Each byte of the input field of pack() generates 1 bit of the result.
3398 Each result bit is based on the least-significant bit of the corresponding
3399 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3400 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3401
3402 Starting from the beginning of the input string of pack(), each 8-tuple
3403 of bytes is converted to 1 byte of output.  With format C<b>
3404 the first byte of the 8-tuple determines the least-significant bit of a
3405 byte, and with format C<B> it determines the most-significant bit of
3406 a byte.
3407
3408 If the length of the input string is not exactly divisible by 8, the
3409 remainder is packed as if the input string were padded by null bytes
3410 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3411
3412 If the input string of pack() is longer than needed, extra bytes are ignored.
3413 A C<*> for the repeat count of pack() means to use all the bytes of
3414 the input field.  On unpack()ing the bits are converted to a string
3415 of C<"0">s and C<"1">s.
3416
3417 =item *
3418
3419 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3420 representable as hexadecimal digits, 0-9a-f) long.
3421
3422 Each byte of the input field of pack() generates 4 bits of the result.
3423 For non-alphabetical bytes the result is based on the 4 least-significant
3424 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3425 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3426 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3427 is compatible with the usual hexadecimal digits, so that C<"a"> and
3428 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3429 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3430
3431 Starting from the beginning of the input string of pack(), each pair
3432 of bytes is converted to 1 byte of output.  With format C<h> the
3433 first byte of the pair determines the least-significant nybble of the
3434 output byte, and with format C<H> it determines the most-significant
3435 nybble.
3436
3437 If the length of the input string is not even, it behaves as if padded
3438 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3439 nybbles are ignored.
3440
3441 If the input string of pack() is longer than needed, extra bytes are ignored.
3442 A C<*> for the repeat count of pack() means to use all the bytes of
3443 the input field.  On unpack()ing the bits are converted to a string
3444 of hexadecimal digits.
3445
3446 =item *
3447
3448 The C<p> type packs a pointer to a null-terminated string.  You are
3449 responsible for ensuring the string is not a temporary value (which can
3450 potentially get deallocated before you get around to using the packed result).
3451 The C<P> type packs a pointer to a structure of the size indicated by the
3452 length.  A NULL pointer is created if the corresponding value for C<p> or
3453 C<P> is C<undef>, similarly for unpack().
3454
3455 If your system has a strange pointer size (i.e. a pointer is neither as
3456 big as an int nor as big as a long), it may not be possible to pack or
3457 unpack pointers in big- or little-endian byte order.  Attempting to do
3458 so will result in a fatal error.
3459
3460 =item *
3461
3462 The C</> template character allows packing and unpacking of strings where
3463 the packed structure contains a byte count followed by the string itself.
3464 You write I<length-item>C</>I<string-item>.
3465
3466 The I<length-item> can be any C<pack> template letter, and describes
3467 how the length value is packed.  The ones likely to be of most use are
3468 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3469 SNMP) and C<N> (for Sun XDR).
3470
3471 For C<pack>, the I<string-item> must, at present, be C<"A*">, C<"a*"> or
3472 C<"Z*">. For C<unpack> the length of the string is obtained from the
3473 I<length-item>, but if you put in the '*' it will be ignored. For all other
3474 codes, C<unpack> applies the length value to the next item, which must not
3475 have a repeat count.
3476
3477     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3478     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3479     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3480
3481 The I<length-item> is not returned explicitly from C<unpack>.
3482
3483 Adding a count to the I<length-item> letter is unlikely to do anything
3484 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3485 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3486 which Perl does not regard as legal in numeric strings.
3487
3488 =item *
3489
3490 The integer types C<s>, C<S>, C<l>, and C<L> may be
3491 followed by a C<!> modifier to signify native shorts or
3492 longs--as you can see from above for example a bare C<l> does mean
3493 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3494 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3495 see whether using C<!> makes any difference by
3496
3497         print length(pack("s")), " ", length(pack("s!")), "\n";
3498         print length(pack("l")), " ", length(pack("l!")), "\n";
3499
3500 C<i!> and C<I!> also work but only because of completeness;
3501 they are identical to C<i> and C<I>.
3502
3503 The actual sizes (in bytes) of native shorts, ints, longs, and long
3504 longs on the platform where Perl was built are also available via
3505 L<Config>:
3506
3507        use Config;
3508        print $Config{shortsize},    "\n";
3509        print $Config{intsize},      "\n";
3510        print $Config{longsize},     "\n";
3511        print $Config{longlongsize}, "\n";
3512
3513 (The C<$Config{longlongsize}> will be undefined if your system does
3514 not support long longs.)
3515
3516 =item *
3517
3518 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3519 are inherently non-portable between processors and operating systems
3520 because they obey the native byteorder and endianness.  For example a
3521 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3522 (arranged in and handled by the CPU registers) into bytes as
3523
3524         0x12 0x34 0x56 0x78     # big-endian
3525         0x78 0x56 0x34 0x12     # little-endian
3526
3527 Basically, the Intel and VAX CPUs are little-endian, while everybody
3528 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3529 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3530 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3531 mode.
3532
3533 The names `big-endian' and `little-endian' are comic references to
3534 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3535 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3536 the egg-eating habits of the Lilliputians.
3537
3538 Some systems may have even weirder byte orders such as
3539
3540         0x56 0x78 0x12 0x34
3541         0x34 0x12 0x78 0x56
3542
3543 You can see your system's preference with
3544
3545         print join(" ", map { sprintf "%#02x", $_ }
3546                             unpack("C*",pack("L",0x12345678))), "\n";
3547
3548 The byteorder on the platform where Perl was built is also available
3549 via L<Config>:
3550
3551         use Config;
3552         print $Config{byteorder}, "\n";
3553
3554 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3555 and C<'87654321'> are big-endian.
3556
3557 If you want portable packed integers you can either use the formats
3558 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3559 modifiers.  These modifiers are only available as of perl 5.8.5.
3560 See also L<perlport>.
3561
3562 =item *
3563
3564 All integer and floating point formats as well as C<p> and C<P> and
3565 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3566 to force big- or little- endian byte-order, respectively.
3567 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3568 signed integers, 64-bit integers and floating point values.  However,
3569 there are some things to keep in mind.
3570
3571 Exchanging signed integers between different platforms only works
3572 if all platforms store them in the same format.  Most platforms store
3573 signed integers in two's complement, so usually this is not an issue.
3574
3575 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3576 formats on big- or little-endian machines.  Otherwise, attempting to
3577 do so will result in a fatal error.
3578
3579 Forcing big- or little-endian byte-order on floating point values for
3580 data exchange can only work if all platforms are using the same
3581 binary representation (e.g. IEEE floating point format).  Even if all
3582 platforms are using IEEE, there may be subtle differences.  Being able
3583 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3584 but also very dangerous if you don't know exactly what you're doing.
3585 It is definetely not a general way to portably store floating point
3586 values.
3587
3588 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3589 all types inside the group that accept the byte-order modifiers,
3590 including all subgroups.  It will silently be ignored for all other
3591 types.  You are not allowed to override the byte-order within a group
3592 that already has a byte-order modifier suffix.
3593
3594 =item *
3595
3596 Real numbers (floats and doubles) are in the native machine format only;
3597 due to the multiplicity of floating formats around, and the lack of a
3598 standard "network" representation, no facility for interchange has been
3599 made.  This means that packed floating point data written on one machine
3600 may not be readable on another - even if both use IEEE floating point
3601 arithmetic (as the endian-ness of the memory representation is not part
3602 of the IEEE spec).  See also L<perlport>.
3603
3604 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3605 modifiers to force big- or little-endian byte-order on floating point values.
3606
3607 Note that Perl uses doubles (or long doubles, if configured) internally for
3608 all numeric calculation, and converting from double into float and thence back
3609 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3610 will not in general equal $foo).
3611
3612 =item *
3613
3614 If the pattern begins with a C<U>, the resulting string will be
3615 treated as UTF-8-encoded Unicode. You can force UTF-8 encoding on in a
3616 string with an initial C<U0>, and the bytes that follow will be
3617 interpreted as Unicode characters. If you don't want this to happen,
3618 you can begin your pattern with C<C0> (or anything else) to force Perl
3619 not to UTF-8 encode your string, and then follow this with a C<U*>
3620 somewhere in your pattern.
3621
3622 =item *
3623
3624 You must yourself do any alignment or padding by inserting for example
3625 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3626 could know where the bytes are going to or coming from.  Therefore
3627 C<pack> (and C<unpack>) handle their output and input as flat
3628 sequences of bytes.
3629
3630 =item *
3631
3632 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3633 take a repeat count, both as postfix, and for unpack() also via the C</>
3634 template character. Within each repetition of a group, positioning with
3635 C<@> starts again at 0. Therefore, the result of
3636
3637     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3638
3639 is the string "\0a\0\0bc".
3640
3641
3642 =item *
3643
3644 C<x> and C<X> accept C<!> modifier.  In this case they act as
3645 alignment commands: they jump forward/back to the closest position
3646 aligned at a multiple of C<count> bytes.  For example, to pack() or
3647 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3648 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3649 aligned on the double's size.
3650
3651 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3652 both result in no-ops.
3653
3654 =item *
3655
3656 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3657 will represent signed 16-/32-bit integers in big-/little-endian order.
3658 This is only portable if all platforms sharing the packed data use the
3659 same binary representation for signed integers (e.g. all platforms are
3660 using two's complement representation).
3661
3662 =item *
3663
3664 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3665 White space may be used to separate pack codes from each other, but
3666 modifiers and a repeat count must follow immediately.
3667
3668 =item *
3669
3670 If TEMPLATE requires more arguments to pack() than actually given, pack()
3671 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3672 to pack() than actually given, extra arguments are ignored.
3673
3674 =back
3675
3676 Examples:
3677
3678     $foo = pack("CCCC",65,66,67,68);
3679     # foo eq "ABCD"
3680     $foo = pack("C4",65,66,67,68);
3681     # same thing
3682     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3683     # same thing with Unicode circled letters
3684
3685     $foo = pack("ccxxcc",65,66,67,68);
3686     # foo eq "AB\0\0CD"
3687
3688     # note: the above examples featuring "C" and "c" are true
3689     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3690     # and UTF-8.  In EBCDIC the first example would be
3691     # $foo = pack("CCCC",193,194,195,196);
3692
3693     $foo = pack("s2",1,2);
3694     # "\1\0\2\0" on little-endian
3695     # "\0\1\0\2" on big-endian
3696
3697     $foo = pack("a4","abcd","x","y","z");
3698     # "abcd"
3699
3700     $foo = pack("aaaa","abcd","x","y","z");
3701     # "axyz"
3702
3703     $foo = pack("a14","abcdefg");
3704     # "abcdefg\0\0\0\0\0\0\0"
3705
3706     $foo = pack("i9pl", gmtime);
3707     # a real struct tm (on my system anyway)
3708
3709     $utmp_template = "Z8 Z8 Z16 L";
3710     $utmp = pack($utmp_template, @utmp1);
3711     # a struct utmp (BSDish)
3712
3713     @utmp2 = unpack($utmp_template, $utmp);
3714     # "@utmp1" eq "@utmp2"
3715
3716     sub bintodec {
3717         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3718     }
3719
3720     $foo = pack('sx2l', 12, 34);
3721     # short 12, two zero bytes padding, long 34
3722     $bar = pack('s@4l', 12, 34);
3723     # short 12, zero fill to position 4, long 34
3724     # $foo eq $bar
3725
3726     $foo = pack('nN', 42, 4711);
3727     # pack big-endian 16- and 32-bit unsigned integers
3728     $foo = pack('S>L>', 42, 4711);
3729     # exactly the same
3730     $foo = pack('s<l<', -42, 4711);
3731     # pack little-endian 16- and 32-bit signed integers
3732     $foo = pack('(sl)<', -42, 4711);
3733     # exactly the same
3734
3735 The same template may generally also be used in unpack().
3736
3737 =item package NAMESPACE
3738
3739 =item package
3740
3741 Declares the compilation unit as being in the given namespace.  The scope
3742 of the package declaration is from the declaration itself through the end
3743 of the enclosing block, file, or eval (the same as the C<my> operator).
3744 All further unqualified dynamic identifiers will be in this namespace.
3745 A package statement affects only dynamic variables--including those
3746 you've used C<local> on--but I<not> lexical variables, which are created
3747 with C<my>.  Typically it would be the first declaration in a file to
3748 be included by the C<require> or C<use> operator.  You can switch into a
3749 package in more than one place; it merely influences which symbol table
3750 is used by the compiler for the rest of that block.  You can refer to
3751 variables and filehandles in other packages by prefixing the identifier
3752 with the package name and a double colon:  C<$Package::Variable>.
3753 If the package name is null, the C<main> package as assumed.  That is,
3754 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3755 still seen in older code).
3756
3757 If NAMESPACE is omitted, then there is no current package, and all
3758 identifiers must be fully qualified or lexicals.  However, you are
3759 strongly advised not to make use of this feature. Its use can cause
3760 unexpected behaviour, even crashing some versions of Perl. It is
3761 deprecated, and will be removed from a future release.
3762
3763 See L<perlmod/"Packages"> for more information about packages, modules,
3764 and classes.  See L<perlsub> for other scoping issues.
3765
3766 =item pipe READHANDLE,WRITEHANDLE
3767
3768 Opens a pair of connected pipes like the corresponding system call.
3769 Note that if you set up a loop of piped processes, deadlock can occur
3770 unless you are very careful.  In addition, note that Perl's pipes use
3771 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3772 after each command, depending on the application.
3773
3774 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3775 for examples of such things.
3776
3777 On systems that support a close-on-exec flag on files, the flag will be set
3778 for the newly opened file descriptors as determined by the value of $^F.
3779 See L<perlvar/$^F>.
3780
3781 =item pop ARRAY
3782
3783 =item pop
3784
3785 Pops and returns the last value of the array, shortening the array by
3786 one element.  Has an effect similar to
3787
3788     $ARRAY[$#ARRAY--]
3789
3790 If there are no elements in the array, returns the undefined value
3791 (although this may happen at other times as well).  If ARRAY is
3792 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3793 array in subroutines, just like C<shift>.
3794
3795 =item pos SCALAR
3796
3797 =item pos
3798
3799 Returns the offset of where the last C<m//g> search left off for the variable
3800 in question (C<$_> is used when the variable is not specified).  May be
3801 modified to change that offset.  Such modification will also influence
3802 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3803 L<perlop>.
3804
3805 =item print FILEHANDLE LIST
3806
3807 =item print LIST
3808
3809 =item print
3810
3811 Prints a string or a list of strings.  Returns true if successful.
3812 FILEHANDLE may be a scalar variable name, in which case the variable
3813 contains the name of or a reference to the filehandle, thus introducing
3814 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3815 the next token is a term, it may be misinterpreted as an operator
3816 unless you interpose a C<+> or put parentheses around the arguments.)
3817 If FILEHANDLE is omitted, prints by default to standard output (or
3818 to the last selected output channel--see L</select>).  If LIST is
3819 also omitted, prints C<$_> to the currently selected output channel.
3820 To set the default output channel to something other than STDOUT
3821 use the select operation.  The current value of C<$,> (if any) is
3822 printed between each LIST item.  The current value of C<$\> (if
3823 any) is printed after the entire LIST has been printed.  Because
3824 print takes a LIST, anything in the LIST is evaluated in list
3825 context, and any subroutine that you call will have one or more of
3826 its expressions evaluated in list context.  Also be careful not to
3827 follow the print keyword with a left parenthesis unless you want
3828 the corresponding right parenthesis to terminate the arguments to
3829 the print--interpose a C<+> or put parentheses around all the
3830 arguments.
3831
3832 Note that if you're storing FILEHANDLES in an array or other expression,
3833 you will have to use a block returning its value instead:
3834
3835     print { $files[$i] } "stuff\n";
3836     print { $OK ? STDOUT : STDERR } "stuff\n";
3837
3838 =item printf FILEHANDLE FORMAT, LIST
3839
3840 =item printf FORMAT, LIST
3841
3842 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3843 (the output record separator) is not appended.  The first argument
3844 of the list will be interpreted as the C<printf> format. See C<sprintf>
3845 for an explanation of the format argument. If C<use locale> is in effect,
3846 the character used for the decimal point in formatted real numbers is
3847 affected by the LC_NUMERIC locale.  See L<perllocale>.
3848
3849 Don't fall into the trap of using a C<printf> when a simple
3850 C<print> would do.  The C<print> is more efficient and less
3851 error prone.
3852
3853 =item prototype FUNCTION
3854
3855 Returns the prototype of a function as a string (or C<undef> if the
3856 function has no prototype).  FUNCTION is a reference to, or the name of,
3857 the function whose prototype you want to retrieve.
3858
3859 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3860 name for Perl builtin.  If the builtin is not I<overridable> (such as
3861 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3862 C<system>) returns C<undef> because the builtin does not really behave
3863 like a Perl function.  Otherwise, the string describing the equivalent
3864 prototype is returned.
3865
3866 =item push ARRAY,LIST
3867
3868 Treats ARRAY as a stack, and pushes the values of LIST
3869 onto the end of ARRAY.  The length of ARRAY increases by the length of
3870 LIST.  Has the same effect as
3871
3872     for $value (LIST) {
3873         $ARRAY[++$#ARRAY] = $value;
3874     }
3875
3876 but is more efficient.  Returns the new number of elements in the array.
3877
3878 =item q/STRING/
3879
3880 =item qq/STRING/
3881
3882 =item qr/STRING/
3883
3884 =item qx/STRING/
3885
3886 =item qw/STRING/
3887
3888 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3889
3890 =item quotemeta EXPR
3891
3892 =item quotemeta
3893
3894 Returns the value of EXPR with all non-"word"
3895 characters backslashed.  (That is, all characters not matching
3896 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3897 returned string, regardless of any locale settings.)
3898 This is the internal function implementing
3899 the C<\Q> escape in double-quoted strings.
3900
3901 If EXPR is omitted, uses C<$_>.
3902
3903 =item rand EXPR
3904
3905 =item rand
3906
3907 Returns a random fractional number greater than or equal to C<0> and less
3908 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3909 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
3910 also special-cased as C<1> - this has not been documented before perl 5.8.0
3911 and is subject to change in future versions of perl.  Automatically calls
3912 C<srand> unless C<srand> has already been called.  See also C<srand>.
3913
3914 Apply C<int()> to the value returned by C<rand()> if you want random
3915 integers instead of random fractional numbers.  For example,
3916
3917     int(rand(10))
3918
3919 returns a random integer between C<0> and C<9>, inclusive.
3920
3921 (Note: If your rand function consistently returns numbers that are too
3922 large or too small, then your version of Perl was probably compiled
3923 with the wrong number of RANDBITS.)
3924
3925 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3926
3927 =item read FILEHANDLE,SCALAR,LENGTH
3928
3929 Attempts to read LENGTH I<characters> of data into variable SCALAR
3930 from the specified FILEHANDLE.  Returns the number of characters
3931 actually read, C<0> at end of file, or undef if there was an error (in
3932 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
3933 so that the last character actually read is the last character of the
3934 scalar after the read.
3935
3936 An OFFSET may be specified to place the read data at some place in the
3937 string other than the beginning.  A negative OFFSET specifies
3938 placement at that many characters counting backwards from the end of
3939 the string.  A positive OFFSET greater than the length of SCALAR
3940 results in the string being padded to the required size with C<"\0">
3941 bytes before the result of the read is appended.
3942
3943 The call is actually implemented in terms of either Perl's or system's
3944 fread() call.  To get a true read(2) system call, see C<sysread>.
3945
3946 Note the I<characters>: depending on the status of the filehandle,
3947 either (8-bit) bytes or characters are read.  By default all
3948 filehandles operate on bytes, but for example if the filehandle has
3949 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
3950 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3951 characters, not bytes.  Similarly for the C<:encoding> pragma:
3952 in that case pretty much any characters can be read.
3953
3954 =item readdir DIRHANDLE
3955
3956 Returns the next directory entry for a directory opened by C<opendir>.
3957 If used in list context, returns all the rest of the entries in the
3958 directory.  If there are no more entries, returns an undefined value in
3959 scalar context or a null list in list context.
3960
3961 If you're planning to filetest the return values out of a C<readdir>, you'd
3962 better prepend the directory in question.  Otherwise, because we didn't
3963 C<chdir> there, it would have been testing the wrong file.
3964
3965     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3966     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3967     closedir DIR;
3968
3969 =item readline EXPR
3970
3971 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3972 context, each call reads and returns the next line, until end-of-file is
3973 reached, whereupon the subsequent call returns undef.  In list context,
3974 reads until end-of-file is reached and returns a list of lines.  Note that
3975 the notion of "line" used here is however you may have defined it
3976 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3977
3978 When C<$/> is set to C<undef>, when readline() is in scalar
3979 context (i.e. file slurp mode), and when an empty file is read, it
3980 returns C<''> the first time, followed by C<undef> subsequently.
3981
3982 This is the internal function implementing the C<< <EXPR> >>
3983 operator, but you can use it directly.  The C<< <EXPR> >>
3984 operator is discussed in more detail in L<perlop/"I/O Operators">.
3985
3986     $line = <STDIN>;
3987     $line = readline(*STDIN);           # same thing
3988
3989 If readline encounters an operating system error, C<$!> will be set with the
3990 corresponding error message.  It can be helpful to check C<$!> when you are
3991 reading from filehandles you don't trust, such as a tty or a socket.  The
3992 following example uses the operator form of C<readline>, and takes the necessary
3993 steps to ensure that C<readline> was successful.
3994
3995     for (;;) {
3996         undef $!;
3997         unless (defined( $line = <> )) {
3998             die $! if $!;
3999             last; # reached EOF
4000         }
4001         # ...
4002     }
4003
4004 =item readlink EXPR
4005
4006 =item readlink
4007
4008 Returns the value of a symbolic link, if symbolic links are
4009 implemented.  If not, gives a fatal error.  If there is some system
4010 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4011 omitted, uses C<$_>.
4012
4013 =item readpipe EXPR
4014
4015 EXPR is executed as a system command.
4016 The collected standard output of the command is returned.
4017 In scalar context, it comes back as a single (potentially
4018 multi-line) string.  In list context, returns a list of lines
4019 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4020 This is the internal function implementing the C<qx/EXPR/>
4021 operator, but you can use it directly.  The C<qx/EXPR/>
4022 operator is discussed in more detail in L<perlop/"I/O Operators">.
4023
4024 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4025
4026 Receives a message on a socket.  Attempts to receive LENGTH characters
4027 of data into variable SCALAR from the specified SOCKET filehandle.
4028 SCALAR will be grown or shrunk to the length actually read.  Takes the
4029 same flags as the system call of the same name.  Returns the address
4030 of the sender if SOCKET's protocol supports this; returns an empty
4031 string otherwise.  If there's an error, returns the undefined value.
4032 This call is actually implemented in terms of recvfrom(2) system call.
4033 See L<perlipc/"UDP: Message Passing"> for examples.
4034
4035 Note the I<characters>: depending on the status of the socket, either
4036 (8-bit) bytes or characters are received.  By default all sockets
4037 operate on bytes, but for example if the socket has been changed using
4038 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4039 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4040 characters, not bytes.  Similarly for the C<:encoding> pragma:
4041 in that case pretty much any characters can be read.
4042
4043 =item redo LABEL
4044
4045 =item redo
4046
4047 The C<redo> command restarts the loop block without evaluating the
4048 conditional again.  The C<continue> block, if any, is not executed.  If
4049 the LABEL is omitted, the command refers to the innermost enclosing
4050 loop.  This command is normally used by programs that want to lie to
4051 themselves about what was just input:
4052
4053     # a simpleminded Pascal comment stripper
4054     # (warning: assumes no { or } in strings)
4055     LINE: while (<STDIN>) {
4056         while (s|({.*}.*){.*}|$1 |) {}
4057         s|{.*}| |;
4058         if (s|{.*| |) {
4059             $front = $_;
4060             while (<STDIN>) {
4061                 if (/}/) {      # end of comment?
4062                     s|^|$front\{|;
4063                     redo LINE;
4064                 }
4065             }
4066         }
4067         print;
4068     }
4069
4070 C<redo> cannot be used to retry a block which returns a value such as
4071 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4072 a grep() or map() operation.
4073
4074 Note that a block by itself is semantically identical to a loop
4075 that executes once.  Thus C<redo> inside such a block will effectively
4076 turn it into a looping construct.
4077
4078 See also L</continue> for an illustration of how C<last>, C<next>, and
4079 C<redo> work.
4080
4081 =item ref EXPR
4082
4083 =item ref
4084
4085 Returns a non-empty string if EXPR is a reference, the empty
4086 string otherwise. If EXPR
4087 is not specified, C<$_> will be used.  The value returned depends on the
4088 type of thing the reference is a reference to.
4089 Builtin types include:
4090
4091     SCALAR
4092     ARRAY
4093     HASH
4094     CODE
4095     REF
4096     GLOB
4097     LVALUE
4098
4099 If the referenced object has been blessed into a package, then that package
4100 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4101
4102     if (ref($r) eq "HASH") {
4103         print "r is a reference to a hash.\n";
4104     }
4105     unless (ref($r)) {
4106         print "r is not a reference at all.\n";
4107     }
4108     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
4109         print "r is a reference to something that isa hash.\n";
4110     }
4111
4112 See also L<perlref>.
4113
4114 =item rename OLDNAME,NEWNAME
4115
4116 Changes the name of a file; an existing file NEWNAME will be
4117 clobbered.  Returns true for success, false otherwise.
4118
4119 Behavior of this function varies wildly depending on your system
4120 implementation.  For example, it will usually not work across file system
4121 boundaries, even though the system I<mv> command sometimes compensates
4122 for this.  Other restrictions include whether it works on directories,
4123 open files, or pre-existing files.  Check L<perlport> and either the
4124 rename(2) manpage or equivalent system documentation for details.
4125
4126 =item require VERSION
4127
4128 =item require EXPR
4129
4130 =item require
4131
4132 Demands a version of Perl specified by VERSION, or demands some semantics
4133 specified by EXPR or by C<$_> if EXPR is not supplied.
4134
4135 VERSION may be either a numeric argument such as 5.006, which will be
4136 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4137 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4138 VERSION is greater than the version of the current Perl interpreter.
4139 Compare with L</use>, which can do a similar check at compile time.
4140
4141 Specifying VERSION as a literal of the form v5.6.1 should generally be
4142 avoided, because it leads to misleading error messages under earlier
4143 versions of Perl which do not support this syntax.  The equivalent numeric
4144 version should be used instead.
4145
4146     require v5.6.1;     # run time version check
4147     require 5.6.1;      # ditto
4148     require 5.006_001;  # ditto; preferred for backwards compatibility
4149
4150 Otherwise, demands that a library file be included if it hasn't already
4151 been included.  The file is included via the do-FILE mechanism, which is
4152 essentially just a variety of C<eval>.  Has semantics similar to the
4153 following subroutine:
4154
4155     sub require {
4156        my ($filename) = @_;
4157        if (exists $INC{$filename}) {
4158            return 1 if $INC{$filename};
4159            die "Compilation failed in require";
4160        }
4161        my ($realfilename,$result);
4162        ITER: {
4163            foreach $prefix (@INC) {
4164                $realfilename = "$prefix/$filename";
4165                if (-f $realfilename) {
4166                    $INC{$filename} = $realfilename;
4167                    $result = do $realfilename;
4168                    last ITER;
4169                }
4170            }
4171            die "Can't find $filename in \@INC";
4172        }
4173        if ($@) {
4174            $INC{$filename} = undef;
4175            die $@;
4176        } elsif (!$result) {
4177            delete $INC{$filename};
4178            die "$filename did not return true value";
4179        } else {
4180            return $result;
4181        }
4182     }
4183
4184 Note that the file will not be included twice under the same specified
4185 name.
4186
4187 The file must return true as the last statement to indicate
4188 successful execution of any initialization code, so it's customary to
4189 end such a file with C<1;> unless you're sure it'll return true
4190 otherwise.  But it's better just to put the C<1;>, in case you add more
4191 statements.
4192
4193 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4194 replaces "F<::>" with "F</>" in the filename for you,
4195 to make it easy to load standard modules.  This form of loading of
4196 modules does not risk altering your namespace.
4197
4198 In other words, if you try this:
4199
4200         require Foo::Bar;    # a splendid bareword
4201
4202 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4203 directories specified in the C<@INC> array.
4204
4205 But if you try this:
4206
4207         $class = 'Foo::Bar';
4208         require $class;      # $class is not a bareword
4209     #or
4210         require "Foo::Bar";  # not a bareword because of the ""
4211
4212 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4213 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4214
4215         eval "require $class";
4216
4217 Now that you understand how C<require> looks for files in the case of
4218 a bareword argument, there is a little extra functionality going on
4219 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4220 it will first look for a filename with a "F<.pmc>" extension.  A file
4221 with this extension is assumed to be Perl bytecode generated by
4222 L<B::Bytecode|B::Bytecode>.  If this file is found, and it's modification
4223 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4224 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4225
4226 You can also insert hooks into the import facility, by putting directly
4227 Perl code into the @INC array.  There are three forms of hooks: subroutine
4228 references, array references and blessed objects.
4229
4230 Subroutine references are the simplest case.  When the inclusion system
4231 walks through @INC and encounters a subroutine, this subroutine gets
4232 called with two parameters, the first being a reference to itself, and the
4233 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4234 subroutine should return C<undef> or a filehandle, from which the file to
4235 include will be read.  If C<undef> is returned, C<require> will look at
4236 the remaining elements of @INC.
4237
4238 If the hook is an array reference, its first element must be a subroutine
4239 reference.  This subroutine is called as above, but the first parameter is
4240 the array reference.  This enables to pass indirectly some arguments to
4241 the subroutine.
4242
4243 In other words, you can write:
4244
4245     push @INC, \&my_sub;
4246     sub my_sub {
4247         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4248         ...
4249     }
4250
4251 or:
4252
4253     push @INC, [ \&my_sub, $x, $y, ... ];
4254     sub my_sub {
4255         my ($arrayref, $filename) = @_;
4256         # Retrieve $x, $y, ...
4257         my @parameters = @$arrayref[1..$#$arrayref];
4258         ...
4259     }
4260
4261 If the hook is an object, it must provide an INC method, that will be
4262 called as above, the first parameter being the object itself.  (Note that
4263 you must fully qualify the sub's name, as it is always forced into package
4264 C<main>.)  Here is a typical code layout:
4265
4266     # In Foo.pm
4267     package Foo;
4268     sub new { ... }
4269     sub Foo::INC {
4270         my ($self, $filename) = @_;
4271         ...
4272     }
4273
4274     # In the main program
4275     push @INC, new Foo(...);
4276
4277 Note that these hooks are also permitted to set the %INC entry
4278 corresponding to the files they have loaded. See L<perlvar/%INC>.
4279
4280 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4281
4282 =item reset EXPR
4283
4284 =item reset
4285
4286 Generally used in a C<continue> block at the end of a loop to clear
4287 variables and reset C<??> searches so that they work again.  The
4288 expression is interpreted as a list of single characters (hyphens
4289 allowed for ranges).  All variables and arrays beginning with one of
4290 those letters are reset to their pristine state.  If the expression is
4291 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4292 only variables or searches in the current package.  Always returns
4293 1.  Examples:
4294
4295     reset 'X';          # reset all X variables
4296     reset 'a-z';        # reset lower case variables
4297     reset;              # just reset ?one-time? searches
4298
4299 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4300 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4301 variables--lexical variables are unaffected, but they clean themselves
4302 up on scope exit anyway, so you'll probably want to use them instead.
4303 See L</my>.
4304
4305 =item return EXPR
4306
4307 =item return
4308
4309 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4310 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4311 context, depending on how the return value will be used, and the context
4312 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4313 is given, returns an empty list in list context, the undefined value in
4314 scalar context, and (of course) nothing at all in a void context.
4315
4316 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4317 or do FILE will automatically return the value of the last expression
4318 evaluated.)
4319
4320 =item reverse LIST
4321
4322 In list context, returns a list value consisting of the elements
4323 of LIST in the opposite order.  In scalar context, concatenates the
4324 elements of LIST and returns a string value with all characters
4325 in the opposite order.
4326
4327     print reverse <>;           # line tac, last line first
4328
4329     undef $/;                   # for efficiency of <>
4330     print scalar reverse <>;    # character tac, last line tsrif
4331
4332 Used without arguments in scalar context, reverse() reverses C<$_>.
4333
4334 This operator is also handy for inverting a hash, although there are some
4335 caveats.  If a value is duplicated in the original hash, only one of those
4336 can be represented as a key in the inverted hash.  Also, this has to
4337 unwind one hash and build a whole new one, which may take some time
4338 on a large hash, such as from a DBM file.
4339
4340     %by_name = reverse %by_address;     # Invert the hash
4341
4342 =item rewinddir DIRHANDLE
4343
4344 Sets the current position to the beginning of the directory for the
4345 C<readdir> routine on DIRHANDLE.
4346
4347 =item rindex STR,SUBSTR,POSITION
4348
4349 =item rindex STR,SUBSTR
4350
4351 Works just like index() except that it returns the position of the LAST
4352 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4353 last occurrence at or before that position.
4354
4355 =item rmdir FILENAME
4356
4357 =item rmdir
4358
4359 Deletes the directory specified by FILENAME if that directory is
4360 empty.  If it succeeds it returns true, otherwise it returns false and
4361 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4362
4363 =item s///
4364
4365 The substitution operator.  See L<perlop>.
4366
4367 =item scalar EXPR
4368
4369 Forces EXPR to be interpreted in scalar context and returns the value
4370 of EXPR.
4371
4372     @counts = ( scalar @a, scalar @b, scalar @c );
4373
4374 There is no equivalent operator to force an expression to
4375 be interpolated in list context because in practice, this is never
4376 needed.  If you really wanted to do so, however, you could use
4377 the construction C<@{[ (some expression) ]}>, but usually a simple
4378 C<(some expression)> suffices.
4379
4380 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4381 parenthesized list, this behaves as a scalar comma expression, evaluating
4382 all but the last element in void context and returning the final element
4383 evaluated in scalar context.  This is seldom what you want.
4384
4385 The following single statement:
4386
4387         print uc(scalar(&foo,$bar)),$baz;
4388
4389 is the moral equivalent of these two:
4390
4391         &foo;
4392         print(uc($bar),$baz);
4393
4394 See L<perlop> for more details on unary operators and the comma operator.
4395
4396 =item seek FILEHANDLE,POSITION,WHENCE
4397
4398 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4399 FILEHANDLE may be an expression whose value gives the name of the
4400 filehandle.  The values for WHENCE are C<0> to set the new position
4401 I<in bytes> to POSITION, C<1> to set it to the current position plus
4402 POSITION, and C<2> to set it to EOF plus POSITION (typically
4403 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4404 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4405 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4406 otherwise.
4407
4408 Note the I<in bytes>: even if the filehandle has been set to
4409 operate on characters (for example by using the C<:utf8> open
4410 layer), tell() will return byte offsets, not character offsets
4411 (because implementing that would render seek() and tell() rather slow).
4412
4413 If you want to position file for C<sysread> or C<syswrite>, don't use
4414 C<seek>--buffering makes its effect on the file's system position
4415 unpredictable and non-portable.  Use C<sysseek> instead.
4416
4417 Due to the rules and rigors of ANSI C, on some systems you have to do a
4418 seek whenever you switch between reading and writing.  Amongst other
4419 things, this may have the effect of calling stdio's clearerr(3).
4420 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4421
4422     seek(TEST,0,1);
4423
4424 This is also useful for applications emulating C<tail -f>.  Once you hit
4425 EOF on your read, and then sleep for a while, you might have to stick in a
4426 seek() to reset things.  The C<seek> doesn't change the current position,
4427 but it I<does> clear the end-of-file condition on the handle, so that the
4428 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4429
4430 If that doesn't work (some IO implementations are particularly
4431 cantankerous), then you may need something more like this:
4432
4433     for (;;) {
4434         for ($curpos = tell(FILE); $_ = <FILE>;
4435              $curpos = tell(FILE)) {
4436             # search for some stuff and put it into files
4437         }
4438         sleep($for_a_while);
4439         seek(FILE, $curpos, 0);
4440     }
4441
4442 =item seekdir DIRHANDLE,POS
4443
4444 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4445 must be a value returned by C<telldir>.  Has the same caveats about
4446 possible directory compaction as the corresponding system library
4447 routine.
4448
4449 =item select FILEHANDLE
4450
4451 =item select
4452
4453 Returns the currently selected filehandle.  Sets the current default
4454 filehandle for output, if FILEHANDLE is supplied.  This has two
4455 effects: first, a C<write> or a C<print> without a filehandle will
4456 default to this FILEHANDLE.  Second, references to variables related to
4457 output will refer to this output channel.  For example, if you have to
4458 set the top of form format for more than one output channel, you might
4459 do the following:
4460
4461     select(REPORT1);
4462     $^ = 'report1_top';
4463     select(REPORT2);
4464     $^ = 'report2_top';
4465
4466 FILEHANDLE may be an expression whose value gives the name of the
4467 actual filehandle.  Thus:
4468
4469     $oldfh = select(STDERR); $| = 1; select($oldfh);
4470
4471 Some programmers may prefer to think of filehandles as objects with
4472 methods, preferring to write the last example as:
4473
4474     use IO::Handle;
4475     STDERR->autoflush(1);
4476
4477 =item select RBITS,WBITS,EBITS,TIMEOUT
4478
4479 This calls the select(2) system call with the bit masks specified, which
4480 can be constructed using C<fileno> and C<vec>, along these lines:
4481
4482     $rin = $win = $ein = '';
4483     vec($rin,fileno(STDIN),1) = 1;
4484     vec($win,fileno(STDOUT),1) = 1;
4485     $ein = $rin | $win;
4486
4487 If you want to select on many filehandles you might wish to write a
4488 subroutine:
4489
4490     sub fhbits {
4491         my(@fhlist) = split(' ',$_[0]);
4492         my($bits);
4493         for (@fhlist) {
4494             vec($bits,fileno($_),1) = 1;
4495         }
4496         $bits;
4497     }
4498     $rin = fhbits('STDIN TTY SOCK');
4499
4500 The usual idiom is:
4501
4502     ($nfound,$timeleft) =
4503       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4504
4505 or to block until something becomes ready just do this
4506
4507     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4508
4509 Most systems do not bother to return anything useful in $timeleft, so
4510 calling select() in scalar context just returns $nfound.
4511
4512 Any of the bit masks can also be undef.  The timeout, if specified, is
4513 in seconds, which may be fractional.  Note: not all implementations are
4514 capable of returning the $timeleft.  If not, they always return
4515 $timeleft equal to the supplied $timeout.
4516
4517 You can effect a sleep of 250 milliseconds this way:
4518
4519     select(undef, undef, undef, 0.25);
4520
4521 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4522 is implementation-dependent.
4523
4524 Also note that on Windows platforms, select() can B<only> be used
4525 on socket filehandles.  This means that select() cannot be used to
4526 multiplex normal filehandles such as STDIN or STDOUT.
4527
4528 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4529 or <FH>) with C<select>, except as permitted by POSIX, and even
4530 then only on POSIX systems.  You have to use C<sysread> instead.
4531
4532 =item semctl ID,SEMNUM,CMD,ARG
4533
4534 Calls the System V IPC function C<semctl>.  You'll probably have to say
4535
4536     use IPC::SysV;
4537
4538 first to get the correct constant definitions.  If CMD is IPC_STAT or
4539 GETALL, then ARG must be a variable which will hold the returned
4540 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4541 the undefined value for error, "C<0 but true>" for zero, or the actual
4542 return value otherwise.  The ARG must consist of a vector of native
4543 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4544 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4545 documentation.
4546
4547 =item semget KEY,NSEMS,FLAGS
4548
4549 Calls the System V IPC function semget.  Returns the semaphore id, or
4550 the undefined value if there is an error.  See also
4551 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4552 documentation.
4553
4554 =item semop KEY,OPSTRING
4555
4556 Calls the System V IPC function semop to perform semaphore operations
4557 such as signalling and waiting.  OPSTRING must be a packed array of
4558 semop structures.  Each semop structure can be generated with
4559 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4560 operations is implied by the length of OPSTRING.  Returns true if
4561 successful, or false if there is an error.  As an example, the
4562 following code waits on semaphore $semnum of semaphore id $semid:
4563
4564     $semop = pack("s!3", $semnum, -1, 0);
4565     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4566
4567 To signal the semaphore, replace C<-1> with C<1>.  See also
4568 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4569 documentation.
4570
4571 =item send SOCKET,MSG,FLAGS,TO
4572
4573 =item send SOCKET,MSG,FLAGS
4574
4575 Sends a message on a socket.  Attempts to send the scalar MSG to the
4576 SOCKET filehandle.  Takes the same flags as the system call of the
4577 same name.  On unconnected sockets you must specify a destination to
4578 send TO, in which case it does a C C<sendto>.  Returns the number of
4579 characters sent, or the undefined value if there is an error.  The C
4580 system call sendmsg(2) is currently unimplemented.  See
4581 L<perlipc/"UDP: Message Passing"> for examples.
4582
4583 Note the I<characters>: depending on the status of the socket, either
4584 (8-bit) bytes or characters are sent.  By default all sockets operate
4585 on bytes, but for example if the socket has been changed using
4586 binmode() to operate with the C<:utf8> I/O layer (see L</open>, or the
4587 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded
4588 Unicode characters, not bytes.  Similarly for the C<:encoding> pragma:
4589 in that case pretty much any characters can be sent.
4590
4591 =item setpgrp PID,PGRP
4592
4593 Sets the current process group for the specified PID, C<0> for the current
4594 process.  Will produce a fatal error if used on a machine that doesn't
4595 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4596 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4597 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4598 C<POSIX::setsid()>.
4599
4600 =item setpriority WHICH,WHO,PRIORITY
4601
4602 Sets the current priority for a process, a process group, or a user.
4603 (See setpriority(2).)  Will produce a fatal error if used on a machine
4604 that doesn't implement setpriority(2).
4605
4606 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4607
4608 Sets the socket option requested.  Returns undefined if there is an
4609 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4610 argument.
4611