This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
968f0f5525658ed5535a469e23d84ade4e935991
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss, plus
3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
4 # on non ASCII-ish platforms need to be skipped
5
6
7 # NOTE:
8 #
9 # Increment ($x++) has a certain amount of cleverness for things like
10 #
11 #   $x = 'zz';
12 #   $x++; # $x eq 'aaa';
13 #
14 # stands more chance of breaking than just a simple
15 #
16 #   $x = $x + 1
17 #
18 # In this file, we use the latter "Baby Perl" approach, and increment
19 # will be worked over by t/op/inc.t
20
21 $Level = 1;
22 my $test = 1;
23 my $planned;
24 my $noplan;
25 my $Perl;       # Safer version of $^X set by which_perl()
26
27 $TODO = 0;
28 $NO_ENDING = 0;
29 $Tests_Are_Passing = 1;
30
31 # Use this instead of print to avoid interference while testing globals.
32 sub _print {
33     local($\, $", $,) = (undef, ' ', '');
34     print STDOUT @_;
35 }
36
37 sub _print_stderr {
38     local($\, $", $,) = (undef, ' ', '');
39     print STDERR @_;
40 }
41
42 sub plan {
43     my $n;
44     if (@_ == 1) {
45         $n = shift;
46         if ($n eq 'no_plan') {
47           undef $n;
48           $noplan = 1;
49         }
50     } else {
51         my %plan = @_;
52         $n = $plan{tests};
53     }
54     _print "1..$n\n" unless $noplan;
55     $planned = $n;
56 }
57
58
59 # Set the plan at the end.  See Test::More::done_testing.
60 sub done_testing {
61     my $n = $test - 1;
62     $n = shift if @_;
63
64     _print "1..$n\n";
65     $planned = $n;
66 }
67
68
69 END {
70     my $ran = $test - 1;
71     if (!$NO_ENDING) {
72         if (defined $planned && $planned != $ran) {
73             _print_stderr
74                 "# Looks like you planned $planned tests but ran $ran.\n";
75         } elsif ($noplan) {
76             _print "1..$ran\n";
77         }
78     }
79 }
80
81 sub _diag {
82     return unless @_;
83     my @mess = _comment(@_);
84     $TODO ? _print(@mess) : _print_stderr(@mess);
85 }
86
87 # Use this instead of "print STDERR" when outputting failure diagnostic
88 # messages
89 sub diag {
90     _diag(@_);
91 }
92
93 # Use this instead of "print" when outputting informational messages
94 sub note {
95     return unless @_;
96     _print( _comment(@_) );
97 }
98
99 sub is_miniperl {
100     return !defined &DynaLoader::boot_DynaLoader;
101 }
102
103 sub _comment {
104     return map { /^#/ ? "$_\n" : "# $_\n" }
105            map { split /\n/ } @_;
106 }
107
108 sub skip_all {
109     if (@_) {
110         _print "1..0 # Skip @_\n";
111     } else {
112         _print "1..0\n";
113     }
114     exit(0);
115 }
116
117 sub skip_all_if_miniperl {
118     skip_all(@_) if is_miniperl();
119 }
120
121 sub _ok {
122     my ($pass, $where, $name, @mess) = @_;
123     # Do not try to microoptimize by factoring out the "not ".
124     # VMS will avenge.
125     my $out;
126     if ($name) {
127         # escape out '#' or it will interfere with '# skip' and such
128         $name =~ s/#/\\#/g;
129         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
130     } else {
131         $out = $pass ? "ok $test" : "not ok $test";
132     }
133
134     if ($TODO) {
135         $out = $out . " # TODO $TODO";
136     } else {
137         $Tests_Are_Passing = 0 unless $pass;
138     }
139
140     _print "$out\n";
141
142     if ($pass) {
143         note @mess; # Ensure that the message is properly escaped.
144     }
145     else {
146         _diag "# Failed $where\n";
147         _diag @mess;
148     }
149
150     $test = $test + 1; # don't use ++
151
152     return $pass;
153 }
154
155 sub _where {
156     my @caller = caller($Level);
157     return "at $caller[1] line $caller[2]";
158 }
159
160 # DON'T use this for matches. Use like() instead.
161 sub ok ($@) {
162     my ($pass, $name, @mess) = @_;
163     _ok($pass, _where(), $name, @mess);
164 }
165
166 sub _q {
167     my $x = shift;
168     return 'undef' unless defined $x;
169     my $q = $x;
170     $q =~ s/\\/\\\\/g;
171     $q =~ s/'/\\'/g;
172     return "'$q'";
173 }
174
175 sub _qq {
176     my $x = shift;
177     return defined $x ? '"' . display ($x) . '"' : 'undef';
178 };
179
180 # keys are the codes \n etc map to, values are 2 char strings such as \n
181 my %backslash_escape;
182 foreach my $x (split //, 'nrtfa\\\'"') {
183     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
184 }
185 # A way to display scalars containing control characters and Unicode.
186 # Trying to avoid setting $_, or relying on local $_ to work.
187 sub display {
188     my @result;
189     foreach my $x (@_) {
190         if (defined $x and not ref $x) {
191             my $y = '';
192             foreach my $c (unpack("U*", $x)) {
193                 if ($c > 255) {
194                     $y = $y . sprintf "\\x{%x}", $c;
195                 } elsif ($backslash_escape{$c}) {
196                     $y = $y . $backslash_escape{$c};
197                 } else {
198                     my $z = chr $c; # Maybe we can get away with a literal...
199                     if ($z =~ /[[:^print:]]/) {
200
201                         # Use octal for characters traditionally expressed as
202                         # such: the low controls
203                         if ($c <= 037) {
204                             $z = sprintf "\\%03o", $c;
205                         } else {
206                             $z = sprintf "\\x{%x}", $c;
207                         }
208                     }
209                     $y = $y . $z;
210                 }
211             }
212             $x = $y;
213         }
214         return $x unless wantarray;
215         push @result, $x;
216     }
217     return @result;
218 }
219
220 sub is ($$@) {
221     my ($got, $expected, $name, @mess) = @_;
222
223     my $pass;
224     if( !defined $got || !defined $expected ) {
225         # undef only matches undef
226         $pass = !defined $got && !defined $expected;
227     }
228     else {
229         $pass = $got eq $expected;
230     }
231
232     unless ($pass) {
233         unshift(@mess, "#      got "._qq($got)."\n",
234                        "# expected "._qq($expected)."\n");
235     }
236     _ok($pass, _where(), $name, @mess);
237 }
238
239 sub isnt ($$@) {
240     my ($got, $isnt, $name, @mess) = @_;
241
242     my $pass;
243     if( !defined $got || !defined $isnt ) {
244         # undef only matches undef
245         $pass = defined $got || defined $isnt;
246     }
247     else {
248         $pass = $got ne $isnt;
249     }
250
251     unless( $pass ) {
252         unshift(@mess, "# it should not be "._qq($got)."\n",
253                        "# but it is.\n");
254     }
255     _ok($pass, _where(), $name, @mess);
256 }
257
258 sub cmp_ok ($$$@) {
259     my($got, $type, $expected, $name, @mess) = @_;
260
261     my $pass;
262     {
263         local $^W = 0;
264         local($@,$!);   # don't interfere with $@
265                         # eval() sometimes resets $!
266         $pass = eval "\$got $type \$expected";
267     }
268     unless ($pass) {
269         # It seems Irix long doubles can have 2147483648 and 2147483648
270         # that stringify to the same thing but are actually numerically
271         # different. Display the numbers if $type isn't a string operator,
272         # and the numbers are stringwise the same.
273         # (all string operators have alphabetic names, so tr/a-z// is true)
274         # This will also show numbers for some unneeded cases, but will
275         # definitely be helpful for things such as == and <= that fail
276         if ($got eq $expected and $type !~ tr/a-z//) {
277             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
278         }
279         unshift(@mess, "#      got "._qq($got)."\n",
280                        "# expected $type "._qq($expected)."\n");
281     }
282     _ok($pass, _where(), $name, @mess);
283 }
284
285 # Check that $got is within $range of $expected
286 # if $range is 0, then check it's exact
287 # else if $expected is 0, then $range is an absolute value
288 # otherwise $range is a fractional error.
289 # Here $range must be numeric, >= 0
290 # Non numeric ranges might be a useful future extension. (eg %)
291 sub within ($$$@) {
292     my ($got, $expected, $range, $name, @mess) = @_;
293     my $pass;
294     if (!defined $got or !defined $expected or !defined $range) {
295         # This is a fail, but doesn't need extra diagnostics
296     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
297         # This is a fail
298         unshift @mess, "# got, expected and range must be numeric\n";
299     } elsif ($range < 0) {
300         # This is also a fail
301         unshift @mess, "# range must not be negative\n";
302     } elsif ($range == 0) {
303         # Within 0 is ==
304         $pass = $got == $expected;
305     } elsif ($expected == 0) {
306         # If expected is 0, treat range as absolute
307         $pass = ($got <= $range) && ($got >= - $range);
308     } else {
309         my $diff = $got - $expected;
310         $pass = abs ($diff / $expected) < $range;
311     }
312     unless ($pass) {
313         if ($got eq $expected) {
314             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
315         }
316         unshift@mess, "#      got "._qq($got)."\n",
317                       "# expected "._qq($expected)." (within "._qq($range).")\n";
318     }
319     _ok($pass, _where(), $name, @mess);
320 }
321
322 # Note: this isn't quite as fancy as Test::More::like().
323
324 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
325 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
326
327 sub like_yn ($$$@) {
328     my ($flip, $got, $expected, $name, @mess) = @_;
329     my $pass;
330     $pass = $got =~ /$expected/ if !$flip;
331     $pass = $got !~ /$expected/ if $flip;
332     unless ($pass) {
333         unshift(@mess, "#      got '$got'\n",
334                 $flip
335                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
336     }
337     local $Level = $Level + 1;
338     _ok($pass, _where(), $name, @mess);
339 }
340
341 sub pass {
342     _ok(1, '', @_);
343 }
344
345 sub fail {
346     _ok(0, _where(), @_);
347 }
348
349 sub curr_test {
350     $test = shift if @_;
351     return $test;
352 }
353
354 sub next_test {
355   my $retval = $test;
356   $test = $test + 1; # don't use ++
357   $retval;
358 }
359
360 # Note: can't pass multipart messages since we try to
361 # be compatible with Test::More::skip().
362 sub skip {
363     my $why = shift;
364     my $n    = @_ ? shift : 1;
365     for (1..$n) {
366         _print "ok $test # skip $why\n";
367         $test = $test + 1;
368     }
369     local $^W = 0;
370     last SKIP;
371 }
372
373 sub skip_if_miniperl {
374     skip(@_) if is_miniperl();
375 }
376
377 sub todo_skip {
378     my $why = shift;
379     my $n   = @_ ? shift : 1;
380
381     for (1..$n) {
382         _print "not ok $test # TODO & SKIP $why\n";
383         $test = $test + 1;
384     }
385     local $^W = 0;
386     last TODO;
387 }
388
389 sub eq_array {
390     my ($ra, $rb) = @_;
391     return 0 unless $#$ra == $#$rb;
392     for my $i (0..$#$ra) {
393         next     if !defined $ra->[$i] && !defined $rb->[$i];
394         return 0 if !defined $ra->[$i];
395         return 0 if !defined $rb->[$i];
396         return 0 unless $ra->[$i] eq $rb->[$i];
397     }
398     return 1;
399 }
400
401 sub eq_hash {
402   my ($orig, $suspect) = @_;
403   my $fail;
404   while (my ($key, $value) = each %$suspect) {
405     # Force a hash recompute if this perl's internals can cache the hash key.
406     $key = "" . $key;
407     if (exists $orig->{$key}) {
408       if ($orig->{$key} ne $value) {
409         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
410                      " now ", _qq($value), "\n";
411         $fail = 1;
412       }
413     } else {
414       _print "# key ", _qq($key), " is ", _qq($value),
415                    ", not in original.\n";
416       $fail = 1;
417     }
418   }
419   foreach (keys %$orig) {
420     # Force a hash recompute if this perl's internals can cache the hash key.
421     $_ = "" . $_;
422     next if (exists $suspect->{$_});
423     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
424     $fail = 1;
425   }
426   !$fail;
427 }
428
429 # We only provide a subset of the Test::More functionality.
430 sub require_ok ($) {
431     my ($require) = @_;
432     if ($require =~ tr/[A-Za-z0-9:.]//c) {
433         fail("Invalid character in \"$require\", passed to require_ok");
434     } else {
435         eval <<REQUIRE_OK;
436 require $require;
437 REQUIRE_OK
438         is($@, '', _where(), "require $require");
439     }
440 }
441
442 sub use_ok ($) {
443     my ($use) = @_;
444     if ($use =~ tr/[A-Za-z0-9:.]//c) {
445         fail("Invalid character in \"$use\", passed to use");
446     } else {
447         eval <<USE_OK;
448 use $use;
449 USE_OK
450         is($@, '', _where(), "use $use");
451     }
452 }
453
454 # runperl - Runs a separate perl interpreter.
455 # Arguments :
456 #   switches => [ command-line switches ]
457 #   nolib    => 1 # don't use -I../lib (included by default)
458 #   non_portable => Don't warn if a one liner contains quotes
459 #   prog     => one-liner (avoid quotes)
460 #   progs    => [ multi-liner (avoid quotes) ]
461 #   progfile => perl script
462 #   stdin    => string to feed the stdin
463 #   stderr   => redirect stderr to stdout
464 #   args     => [ command-line arguments to the perl program ]
465 #   verbose  => print the command line
466
467 my $is_mswin    = $^O eq 'MSWin32';
468 my $is_netware  = $^O eq 'NetWare';
469 my $is_vms      = $^O eq 'VMS';
470 my $is_cygwin   = $^O eq 'cygwin';
471
472 sub _quote_args {
473     my ($runperl, $args) = @_;
474
475     foreach (@$args) {
476         # In VMS protect with doublequotes because otherwise
477         # DCL will lowercase -- unless already doublequoted.
478        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
479        $runperl = $runperl . ' ' . $_;
480     }
481     return $runperl;
482 }
483
484 sub _create_runperl { # Create the string to qx in runperl().
485     my %args = @_;
486     my $runperl = which_perl();
487     if ($runperl =~ m/\s/) {
488         $runperl = qq{"$runperl"};
489     }
490     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
491     if ($ENV{PERL_RUNPERL_DEBUG}) {
492         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
493     }
494     unless ($args{nolib}) {
495         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
496     }
497     if ($args{switches}) {
498         local $Level = 2;
499         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
500             unless ref $args{switches} eq "ARRAY";
501         $runperl = _quote_args($runperl, $args{switches});
502     }
503     if (defined $args{prog}) {
504         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
505             if defined $args{progs};
506         $args{progs} = [$args{prog}]
507     }
508     if (defined $args{progs}) {
509         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
510             unless ref $args{progs} eq "ARRAY";
511         foreach my $prog (@{$args{progs}}) {
512             if ($prog =~ tr/'"// && !$args{non_portable}) {
513                 warn "quotes in prog >>$prog<< are not portable";
514             }
515             if ($is_mswin || $is_netware || $is_vms) {
516                 $runperl = $runperl . qq ( -e "$prog" );
517             }
518             else {
519                 $runperl = $runperl . qq ( -e '$prog' );
520             }
521         }
522     } elsif (defined $args{progfile}) {
523         $runperl = $runperl . qq( "$args{progfile}");
524     } else {
525         # You probably didn't want to be sucking in from the upstream stdin
526         die "test.pl:runperl(): none of prog, progs, progfile, args, "
527             . " switches or stdin specified"
528             unless defined $args{args} or defined $args{switches}
529                 or defined $args{stdin};
530     }
531     if (defined $args{stdin}) {
532         # so we don't try to put literal newlines and crs onto the
533         # command line.
534         $args{stdin} =~ s/\n/\\n/g;
535         $args{stdin} =~ s/\r/\\r/g;
536
537         if ($is_mswin || $is_netware || $is_vms) {
538             $runperl = qq{$Perl -e "print qq(} .
539                 $args{stdin} . q{)" | } . $runperl;
540         }
541         else {
542             $runperl = qq{$Perl -e 'print qq(} .
543                 $args{stdin} . q{)' | } . $runperl;
544         }
545     }
546     if (defined $args{args}) {
547         $runperl = _quote_args($runperl, $args{args});
548     }
549     $runperl = $runperl . ' 2>&1' if $args{stderr};
550     if ($args{verbose}) {
551         my $runperldisplay = $runperl;
552         $runperldisplay =~ s/\n/\n\#/g;
553         _print_stderr "# $runperldisplay\n";
554     }
555     return $runperl;
556 }
557
558 sub runperl {
559     die "test.pl:runperl() does not take a hashref"
560         if ref $_[0] and ref $_[0] eq 'HASH';
561     my $runperl = &_create_runperl;
562     my $result;
563
564     my $tainted = ${^TAINT};
565     my %args = @_;
566     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
567
568     if ($tainted) {
569         # We will assume that if you're running under -T, you really mean to
570         # run a fresh perl, so we'll brute force launder everything for you
571         my $sep;
572
573         if (! eval 'require Config; 1') {
574             warn "test.pl had problems loading Config: $@";
575             $sep = ':';
576         } else {
577             $sep = $Config::Config{path_sep};
578         }
579
580         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
581         local @ENV{@keys} = ();
582         # Untaint, plus take out . and empty string:
583         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
584         $ENV{PATH} =~ /(.*)/s;
585         local $ENV{PATH} =
586             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
587                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
588                     split quotemeta ($sep), $1;
589         if ($is_cygwin) {   # Must have /bin under Cygwin
590             if (length $ENV{PATH}) {
591                 $ENV{PATH} = $ENV{PATH} . $sep;
592             }
593             $ENV{PATH} = $ENV{PATH} . '/bin';
594         }
595         $runperl =~ /(.*)/s;
596         $runperl = $1;
597
598         $result = `$runperl`;
599     } else {
600         $result = `$runperl`;
601     }
602     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
603     return $result;
604 }
605
606 # Nice alias
607 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
608
609 sub DIE {
610     _print_stderr "# @_\n";
611     exit 1;
612 }
613
614 # A somewhat safer version of the sometimes wrong $^X.
615 sub which_perl {
616     unless (defined $Perl) {
617         $Perl = $^X;
618
619         # VMS should have 'perl' aliased properly
620         return $Perl if $is_vms;
621
622         my $exe;
623         if (! eval 'require Config; 1') {
624             warn "test.pl had problems loading Config: $@";
625             $exe = '';
626         } else {
627             $exe = $Config::Config{_exe};
628         }
629        $exe = '' unless defined $exe;
630
631         # This doesn't absolutize the path: beware of future chdirs().
632         # We could do File::Spec->abs2rel() but that does getcwd()s,
633         # which is a bit heavyweight to do here.
634
635         if ($Perl =~ /^perl\Q$exe\E$/i) {
636             my $perl = "perl$exe";
637             if (! eval 'require File::Spec; 1') {
638                 warn "test.pl had problems loading File::Spec: $@";
639                 $Perl = "./$perl";
640             } else {
641                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
642             }
643         }
644
645         # Build up the name of the executable file from the name of
646         # the command.
647
648         if ($Perl !~ /\Q$exe\E$/i) {
649             $Perl = $Perl . $exe;
650         }
651
652         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
653
654         # For subcommands to use.
655         $ENV{PERLEXE} = $Perl;
656     }
657     return $Perl;
658 }
659
660 sub unlink_all {
661     my $count = 0;
662     foreach my $file (@_) {
663         1 while unlink $file;
664         if( -f $file ){
665             _print_stderr "# Couldn't unlink '$file': $!\n";
666         }else{
667             ++$count;
668         }
669     }
670     $count;
671 }
672
673 my %tmpfiles;
674 END { unlink_all keys %tmpfiles }
675
676 # A regexp that matches the tempfile names
677 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
678
679 # Avoid ++, avoid ranges, avoid split //
680 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
681 sub tempfile {
682     my $count = 0;
683     do {
684         my $temp = $count;
685         my $try = "tmp$$";
686         do {
687             $try = $try . $letters[$temp % 26];
688             $temp = int ($temp / 26);
689         } while $temp;
690         # Need to note all the file names we allocated, as a second request may
691         # come before the first is created.
692         if (!-e $try && !$tmpfiles{$try}) {
693             # We have a winner
694             $tmpfiles{$try} = 1;
695             return $try;
696         }
697         $count = $count + 1;
698     } while $count < 26 * 26;
699     die "Can't find temporary file name starting 'tmp$$'";
700 }
701
702 # This is the temporary file for _fresh_perl
703 my $tmpfile = tempfile();
704
705 #
706 # _fresh_perl
707 #
708 # The $resolve must be a subref that tests the first argument
709 # for success, or returns the definition of success (e.g. the
710 # expected scalar) if given no arguments.
711 #
712
713 sub _fresh_perl {
714     my($prog, $resolve, $runperl_args, $name) = @_;
715
716     # Given the choice of the mis-parsable {}
717     # (we want an anon hash, but a borked lexer might think that it's a block)
718     # or relying on taking a reference to a lexical
719     # (\ might be mis-parsed, and the reference counting on the pad may go
720     #  awry)
721     # it feels like the least-worse thing is to assume that auto-vivification
722     # works. At least, this is only going to be a run-time failure, so won't
723     # affect tests using this file but not this function.
724     $runperl_args->{progfile} = $tmpfile;
725     $runperl_args->{stderr} = 1;
726
727     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
728
729     # VMS adjustments
730     if( $is_vms ) {
731         $prog =~ s#/dev/null#NL:#;
732
733         # VMS file locking
734         $prog =~ s{if \(-e _ and -f _ and -r _\)}
735                   {if (-e _ and -f _)}
736     }
737
738     print TEST $prog;
739     close TEST or die "Cannot close $tmpfile: $!";
740
741     my $results = runperl(%$runperl_args);
742     my $status = $?;
743
744     # Clean up the results into something a bit more predictable.
745     $results  =~ s/\n+$//;
746     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
747     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
748
749     # bison says 'parse error' instead of 'syntax error',
750     # various yaccs may or may not capitalize 'syntax'.
751     $results =~ s/^(syntax|parse) error/syntax error/mig;
752
753     if ($is_vms) {
754         # some tests will trigger VMS messages that won't be expected
755         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
756
757         # pipes double these sometimes
758         $results =~ s/\n\n/\n/g;
759     }
760
761     my $pass = $resolve->($results);
762     unless ($pass) {
763         _diag "# PROG: \n$prog\n";
764         _diag "# EXPECTED:\n", $resolve->(), "\n";
765         _diag "# GOT:\n$results\n";
766         _diag "# STATUS: $status\n";
767     }
768
769     # Use the first line of the program as a name if none was given
770     unless( $name ) {
771         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
772         $name = $name . '...' if length $first_line > length $name;
773     }
774
775     _ok($pass, _where(), "fresh_perl - $name");
776 }
777
778 #
779 # fresh_perl_is
780 #
781 # Combination of run_perl() and is().
782 #
783
784 sub fresh_perl_is {
785     my($prog, $expected, $runperl_args, $name) = @_;
786
787     # _fresh_perl() is going to clip the trailing newlines off the result.
788     # This will make it so the test author doesn't have to know that.
789     $expected =~ s/\n+$//;
790
791     local $Level = 2;
792     _fresh_perl($prog,
793                 sub { @_ ? $_[0] eq $expected : $expected },
794                 $runperl_args, $name);
795 }
796
797 #
798 # fresh_perl_like
799 #
800 # Combination of run_perl() and like().
801 #
802
803 sub fresh_perl_like {
804     my($prog, $expected, $runperl_args, $name) = @_;
805     local $Level = 2;
806     _fresh_perl($prog,
807                 sub { @_ ? $_[0] =~ $expected : $expected },
808                 $runperl_args, $name);
809 }
810
811 sub can_ok ($@) {
812     my($proto, @methods) = @_;
813     my $class = ref $proto || $proto;
814
815     unless( @methods ) {
816         return _ok( 0, _where(), "$class->can(...)" );
817     }
818
819     my @nok = ();
820     foreach my $method (@methods) {
821         local($!, $@);  # don't interfere with caller's $@
822                         # eval sometimes resets $!
823         eval { $proto->can($method) } || push @nok, $method;
824     }
825
826     my $name;
827     $name = @methods == 1 ? "$class->can('$methods[0]')"
828                           : "$class->can(...)";
829
830     _ok( !@nok, _where(), $name );
831 }
832
833
834 # Call $class->new( @$args ); and run the result through isa_ok.
835 # See Test::More::new_ok
836 sub new_ok {
837     my($class, $args, $obj_name) = @_;
838     $args ||= [];
839     $object_name = "The object" unless defined $obj_name;
840
841     local $Level = $Level + 1;
842
843     my $obj;
844     my $ok = eval { $obj = $class->new(@$args); 1 };
845     my $error = $@;
846
847     if($ok) {
848         isa_ok($obj, $class, $object_name);
849     }
850     else {
851         ok( 0, "new() died" );
852         diag("Error was:  $@");
853     }
854
855     return $obj;
856
857 }
858
859
860 sub isa_ok ($$;$) {
861     my($object, $class, $obj_name) = @_;
862
863     my $diag;
864     $obj_name = 'The object' unless defined $obj_name;
865     my $name = "$obj_name isa $class";
866     if( !defined $object ) {
867         $diag = "$obj_name isn't defined";
868     }
869     elsif( !ref $object ) {
870         $diag = "$obj_name isn't a reference";
871     }
872     else {
873         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
874         local($@, $!);  # eval sometimes resets $!
875         my $rslt = eval { $object->isa($class) };
876         if( $@ ) {
877             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
878                 if( !UNIVERSAL::isa($object, $class) ) {
879                     my $ref = ref $object;
880                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
881                 }
882             } else {
883                 die <<WHOA;
884 WHOA! I tried to call ->isa on your object and got some weird error.
885 This should never happen.  Please contact the author immediately.
886 Here's the error.
887 $@
888 WHOA
889             }
890         }
891         elsif( !$rslt ) {
892             my $ref = ref $object;
893             $diag = "$obj_name isn't a '$class' it's a '$ref'";
894         }
895     }
896
897     _ok( !$diag, _where(), $name );
898 }
899
900 # Set a watchdog to timeout the entire test file
901 # NOTE:  If the test file uses 'threads', then call the watchdog() function
902 #        _AFTER_ the 'threads' module is loaded.
903 sub watchdog ($;$)
904 {
905     my $timeout = shift;
906     my $method  = shift || "";
907     my $timeout_msg = 'Test process timed out - terminating';
908
909     # Valgrind slows perl way down so give it more time before dying.
910     $timeout *= 10 if $ENV{PERL_VALGRIND};
911
912     my $pid_to_kill = $$;   # PID for this process
913
914     if ($method eq "alarm") {
915         goto WATCHDOG_VIA_ALARM;
916     }
917
918     # shut up use only once warning
919     my $threads_on = $threads::threads && $threads::threads;
920
921     # Don't use a watchdog process if 'threads' is loaded -
922     #   use a watchdog thread instead
923     if (!$threads_on) {
924
925         # On Windows and VMS, try launching a watchdog process
926         #   using system(1, ...) (see perlport.pod)
927         if ($is_mswin || $is_vms) {
928             # On Windows, try to get the 'real' PID
929             if ($is_mswin) {
930                 eval { require Win32; };
931                 if (defined(&Win32::GetCurrentProcessId)) {
932                     $pid_to_kill = Win32::GetCurrentProcessId();
933                 }
934             }
935
936             # If we still have a fake PID, we can't use this method at all
937             return if ($pid_to_kill <= 0);
938
939             # Launch watchdog process
940             my $watchdog;
941             eval {
942                 local $SIG{'__WARN__'} = sub {
943                     _diag("Watchdog warning: $_[0]");
944                 };
945                 my $sig = $is_vms ? 'TERM' : 'KILL';
946                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
947                                                     "warn qq/# $timeout_msg" . '\n/;' .
948                                                     "kill($sig, $pid_to_kill);");
949                 $watchdog = system(1, $cmd);
950             };
951             if ($@ || ($watchdog <= 0)) {
952                 _diag('Failed to start watchdog');
953                 _diag($@) if $@;
954                 undef($watchdog);
955                 return;
956             }
957
958             # Add END block to parent to terminate and
959             #   clean up watchdog process
960             eval "END { local \$! = 0; local \$? = 0;
961                         wait() if kill('KILL', $watchdog); };";
962             return;
963         }
964
965         # Try using fork() to generate a watchdog process
966         my $watchdog;
967         eval { $watchdog = fork() };
968         if (defined($watchdog)) {
969             if ($watchdog) {   # Parent process
970                 # Add END block to parent to terminate and
971                 #   clean up watchdog process
972                 eval "END { local \$! = 0; local \$? = 0;
973                             wait() if kill('KILL', $watchdog); };";
974                 return;
975             }
976
977             ### Watchdog process code
978
979             # Load POSIX if available
980             eval { require POSIX; };
981
982             # Execute the timeout
983             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
984             sleep(2);
985
986             # Kill test process if still running
987             if (kill(0, $pid_to_kill)) {
988                 _diag($timeout_msg);
989                 kill('KILL', $pid_to_kill);
990             }
991
992             # Don't execute END block (added at beginning of this file)
993             $NO_ENDING = 1;
994
995             # Terminate ourself (i.e., the watchdog)
996             POSIX::_exit(1) if (defined(&POSIX::_exit));
997             exit(1);
998         }
999
1000         # fork() failed - fall through and try using a thread
1001     }
1002
1003     # Use a watchdog thread because either 'threads' is loaded,
1004     #   or fork() failed
1005     if (eval 'require threads; 1') {
1006         'threads'->create(sub {
1007                 # Load POSIX if available
1008                 eval { require POSIX; };
1009
1010                 # Execute the timeout
1011                 my $time_left = $timeout;
1012                 do {
1013                     $time_left = $time_left - sleep($time_left);
1014                 } while ($time_left > 0);
1015
1016                 # Kill the parent (and ourself)
1017                 select(STDERR); $| = 1;
1018                 _diag($timeout_msg);
1019                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1020                 my $sig = $is_vms ? 'TERM' : 'KILL';
1021                 kill($sig, $pid_to_kill);
1022             })->detach();
1023         return;
1024     }
1025
1026     # If everything above fails, then just use an alarm timeout
1027 WATCHDOG_VIA_ALARM:
1028     if (eval { alarm($timeout); 1; }) {
1029         # Load POSIX if available
1030         eval { require POSIX; };
1031
1032         # Alarm handler will do the actual 'killing'
1033         $SIG{'ALRM'} = sub {
1034             select(STDERR); $| = 1;
1035             _diag($timeout_msg);
1036             POSIX::_exit(1) if (defined(&POSIX::_exit));
1037             my $sig = $is_vms ? 'TERM' : 'KILL';
1038             kill($sig, $pid_to_kill);
1039         };
1040     }
1041 }
1042
1043 my $cp_0037 =   # EBCDIC code page 0037
1044     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x25\x0B\x0C\x0D\x0E\x0F' .
1045     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1046     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1047     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1048     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1049     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBA\xE0\xBB\xB0\x6D' .
1050     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1051     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1052     '\x20\x21\x22\x23\x24\x15\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1053     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1054     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBD\xB4\x9A\x8A\x5F\xCA\xAF\xBC' .
1055     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1056     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1057     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xAD\xAE\x59' .
1058     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1059     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1060
1061 my $cp_1047 =   # EBCDIC code page 1047
1062     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1063     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1064     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1065     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1066     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1067     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xAD\xE0\xBD\x5F\x6D' .
1068     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1069     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1070     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1071     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1072     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBB\xB4\x9A\x8A\xB0\xCA\xAF\xBC' .
1073     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1074     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1075     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xBA\xAE\x59' .
1076     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1077     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1078
1079 my $cp_bc = # EBCDIC code page POSiX-BC
1080     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1081     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1082     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1083     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1084     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1085     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBB\xBC\xBD\x6A\x6D' .
1086     '\x4A\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1087     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xFB\x4F\xFD\xFF\x07' .
1088     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1089     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\x5F' .
1090     '\x41\xAA\xB0\xB1\x9F\xB2\xD0\xB5\x79\xB4\x9A\x8A\xBA\xCA\xAF\xA1' .
1091     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1092     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1093     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xE0\xFE\xDD\xFC\xAD\xAE\x59' .
1094     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1095     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xC0\xDE\xDB\xDC\x8D\x8E\xDF';
1096
1097 my $straight =  # Avoid ranges
1098     '\x00\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0A\x0B\x0C\x0D\x0E\x0F' .
1099     '\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1A\x1B\x1C\x1D\x1E\x1F' .
1100     '\x20\x21\x22\x23\x24\x25\x26\x27\x28\x29\x2A\x2B\x2C\x2D\x2E\x2F' .
1101     '\x30\x31\x32\x33\x34\x35\x36\x37\x38\x39\x3A\x3B\x3C\x3D\x3E\x3F' .
1102     '\x40\x41\x42\x43\x44\x45\x46\x47\x48\x49\x4A\x4B\x4C\x4D\x4E\x4F' .
1103     '\x50\x51\x52\x53\x54\x55\x56\x57\x58\x59\x5A\x5B\x5C\x5D\x5E\x5F' .
1104     '\x60\x61\x62\x63\x64\x65\x66\x67\x68\x69\x6A\x6B\x6C\x6D\x6E\x6F' .
1105     '\x70\x71\x72\x73\x74\x75\x76\x77\x78\x79\x7A\x7B\x7C\x7D\x7E\x7F' .
1106     '\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8A\x8B\x8C\x8D\x8E\x8F' .
1107     '\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9A\x9B\x9C\x9D\x9E\x9F' .
1108     '\xA0\xA1\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xAA\xAB\xAC\xAD\xAE\xAF' .
1109     '\xB0\xB1\xB2\xB3\xB4\xB5\xB6\xB7\xB8\xB9\xBA\xBB\xBC\xBD\xBE\xBF' .
1110     '\xC0\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xCA\xCB\xCC\xCD\xCE\xCF' .
1111     '\xD0\xD1\xD2\xD3\xD4\xD5\xD6\xD7\xD8\xD9\xDA\xDB\xDC\xDD\xDE\xDF' .
1112     '\xE0\xE1\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xEA\xEB\xEC\xED\xEE\xEF' .
1113     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\xFA\xFB\xFC\xFD\xFE\xFF';
1114
1115 # The following 2 functions allow tests to work on both EBCDIC and
1116 # ASCII-ish platforms.  They convert string scalars between the native
1117 # character set and the set of 256 characters which is usually called
1118 # Latin1.
1119 #
1120 # These routines don't work on UTF-EBCDIC and UTF-8.
1121
1122 sub native_to_latin1($) {
1123     my $string = shift;
1124
1125     return $string if ord('^') == 94;   # ASCII, Latin1
1126     my $cp;
1127     if (ord('^') == 95) {    # EBCDIC 1047
1128         $cp = \$cp_1047;
1129     }
1130     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1131         $cp = \$cp_bc;
1132     }
1133     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1134         $cp = \$cp_0037;
1135     }
1136     else {
1137         die "Unknown native character set";
1138     }
1139
1140     eval '$string =~ tr/' . $$cp . '/' . $straight . '/';
1141     return $string;
1142 }
1143
1144 sub latin1_to_native($) {
1145     my $string = shift;
1146
1147     return $string if ord('^') == 94;   # ASCII, Latin1
1148     my $cp;
1149     if (ord('^') == 95) {    # EBCDIC 1047
1150         $cp = \$cp_1047;
1151     }
1152     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1153         $cp = \$cp_bc;
1154     }
1155     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1156         $cp = \$cp_0037;
1157     }
1158     else {
1159         die "Unknown native character set";
1160     }
1161
1162     eval '$string =~ tr/' . $straight . '/' . $$cp . '/';
1163     return $string;
1164 }
1165
1166 sub ord_latin1_to_native {
1167     # given an input code point, return the platform's native
1168     # equivalent value.  Anything above latin1 is itself.
1169
1170     my $ord = shift;
1171     return $ord if $ord > 255;
1172     return ord latin1_to_native(chr $ord);
1173 }
1174
1175 sub ord_native_to_latin1 {
1176     # given an input platform code point, return the latin1 equivalent value.
1177     # Anything above latin1 is itself.
1178
1179     my $ord = shift;
1180     return $ord if $ord > 255;
1181     return ord native_to_latin1(chr $ord);
1182 }
1183
1184 1;