This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
96869c7cb3e85de18721032823f39eefa12310a3
[perl5.git] / ext / B / B / Concise.pm
1 package B::Concise;
2 # Copyright (C) 2000-2003 Stephen McCamant. All rights reserved.
3 # This program is free software; you can redistribute and/or modify it
4 # under the same terms as Perl itself.
5
6 # Note: we need to keep track of how many use declarations/BEGIN
7 # blocks this module uses, so we can avoid printing them when user
8 # asks for the BEGIN blocks in her program. Update the comments and
9 # the count in concise_specials if you add or delete one. The
10 # -MO=Concise counts as use #1.
11
12 use strict; # use #2
13 use warnings; # uses #3 and #4, since warnings uses Carp
14
15 use Exporter (); # use #5
16
17 our $VERSION   = "0.994";
18 our @ISA       = qw(Exporter);
19 our @EXPORT_OK = qw( set_style set_style_standard add_callback
20                      concise_subref concise_cv concise_main
21                      add_style walk_output compile reset_sequence );
22 our %EXPORT_TAGS =
23     ( io        => [qw( walk_output compile reset_sequence )],
24       style     => [qw( add_style set_style_standard )],
25       cb        => [qw( add_callback )],
26       mech      => [qw( concise_subref concise_cv concise_main )],  );
27
28 # use #6
29 use B qw(class ppname main_start main_root main_cv cstring svref_2object
30          SVf_IOK SVf_NOK SVf_POK SVf_IVisUV SVf_FAKE OPf_KIDS OPf_SPECIAL
31          CVf_ANON PAD_FAKELEX_ANON PAD_FAKELEX_MULTI SVf_ROK);
32
33 my %style =
34   ("terse" =>
35    ["(?(#label =>\n)?)(*(    )*)#class (#addr) #name (?([#targ])?) "
36     . "#svclass~(?((#svaddr))?)~#svval~(?(label \"#coplabel\")?)\n",
37     "(*(    )*)goto #class (#addr)\n",
38     "#class pp_#name"],
39    "concise" =>
40    ["#hyphseq2 (*(   (x( ;)x))*)<#classsym> #exname#arg(?([#targarglife])?)"
41     . "~#flags(?(/#private)?)(?(:#hints)?)(x(;~->#next)x)\n"
42     , "  (*(    )*)     goto #seq\n",
43     "(?(<#seq>)?)#exname#arg(?([#targarglife])?)"],
44    "linenoise" =>
45    ["(x(;(*( )*))x)#noise#arg(?([#targarg])?)(x( ;\n)x)",
46     "gt_#seq ",
47     "(?(#seq)?)#noise#arg(?([#targarg])?)"],
48    "debug" =>
49    ["#class (#addr)\n\top_next\t\t#nextaddr\n\t(?(op_other\t#otheraddr\n\t)?)"
50     . "op_sibling\t#sibaddr\n\t"
51     . "op_ppaddr\tPL_ppaddr[OP_#NAME]\n\top_type\t\t#typenum\n"
52     . "\top_flags\t#flagval\n\top_private\t#privval\t#hintsval\n"
53     . "(?(\top_first\t#firstaddr\n)?)(?(\top_last\t\t#lastaddr\n)?)"
54     . "(?(\top_sv\t\t#svaddr\n)?)",
55     "    GOTO #addr\n",
56     "#addr"],
57    "env" => [$ENV{B_CONCISE_FORMAT}, $ENV{B_CONCISE_GOTO_FORMAT},
58              $ENV{B_CONCISE_TREE_FORMAT}],
59   );
60
61 # Renderings, ie how Concise prints, is controlled by these vars
62 # primary:
63 our $stylename;         # selects current style from %style
64 my $order = "basic";    # how optree is walked & printed: basic, exec, tree
65
66 # rendering mechanics:
67 # these 'formats' are the line-rendering templates
68 # they're updated from %style when $stylename changes
69 my ($format, $gotofmt, $treefmt);
70
71 # lesser players:
72 my $base = 36;          # how <sequence#> is displayed
73 my $big_endian = 1;     # more <sequence#> display
74 my $tree_style = 0;     # tree-order details
75 my $banner = 1;         # print banner before optree is traversed
76 my $do_main = 0;        # force printing of main routine
77 my $show_src;           # show source code
78
79 # another factor: can affect all styles!
80 our @callbacks;         # allow external management
81
82 set_style_standard("concise");
83
84 my $curcv;
85 my $cop_seq_base;
86
87 sub set_style {
88     ($format, $gotofmt, $treefmt) = @_;
89     #warn "set_style: deprecated, use set_style_standard instead\n"; # someday
90     die "expecting 3 style-format args\n" unless @_ == 3;
91 }
92
93 sub add_style {
94     my ($newstyle,@args) = @_;
95     die "style '$newstyle' already exists, choose a new name\n"
96         if exists $style{$newstyle};
97     die "expecting 3 style-format args\n" unless @args == 3;
98     $style{$newstyle} = [@args];
99     $stylename = $newstyle; # update rendering state
100 }
101
102 sub set_style_standard {
103     ($stylename) = @_; # update rendering state
104     die "err: style '$stylename' unknown\n" unless exists $style{$stylename};
105     set_style(@{$style{$stylename}});
106 }
107
108 sub add_callback {
109     push @callbacks, @_;
110 }
111
112 # output handle, used with all Concise-output printing
113 our $walkHandle;        # public for your convenience
114 BEGIN { $walkHandle = \*STDOUT }
115
116 sub walk_output { # updates $walkHandle
117     my $handle = shift;
118     return $walkHandle unless $handle; # allow use as accessor
119
120     if (ref $handle eq 'SCALAR') {
121         require Config;
122         die "no perlio in this build, can't call walk_output (\\\$scalar)\n"
123             unless $Config::Config{useperlio};
124         # in 5.8+, open(FILEHANDLE,MODE,REFERENCE) writes to string
125         open my $tmp, '>', $handle;     # but cant re-set existing STDOUT
126         $walkHandle = $tmp;             # so use my $tmp as intermediate var
127         return $walkHandle;
128     }
129     my $iotype = ref $handle;
130     die "expecting argument/object that can print\n"
131         unless $iotype eq 'GLOB' or $iotype and $handle->can('print');
132     $walkHandle = $handle;
133 }
134
135 sub concise_subref {
136     my($order, $coderef, $name) = @_;
137     my $codeobj = svref_2object($coderef);
138
139     return concise_stashref(@_)
140         unless ref($codeobj) =~ '^B::(?:CV|FM)\z';
141     concise_cv_obj($order, $codeobj, $name);
142 }
143
144 sub concise_stashref {
145     my($order, $h) = @_;
146     local *s;
147     foreach my $k (sort keys %$h) {
148         next unless defined $h->{$k};
149         *s = $h->{$k};
150         my $coderef = *s{CODE} or next;
151         reset_sequence();
152         print "FUNC: ", *s, "\n";
153         my $codeobj = svref_2object($coderef);
154         next unless ref $codeobj eq 'B::CV';
155         eval { concise_cv_obj($order, $codeobj, $k) };
156         warn "err $@ on $codeobj" if $@;
157     }
158 }
159
160 # This should have been called concise_subref, but it was exported
161 # under this name in versions before 0.56
162 *concise_cv = \&concise_subref;
163
164 sub concise_cv_obj {
165     my ($order, $cv, $name) = @_;
166     # name is either a string, or a CODE ref (copy of $cv arg??)
167
168     $curcv = $cv;
169
170     if (ref($cv->XSUBANY) =~ /B::(\w+)/) {
171         print $walkHandle "$name is a constant sub, optimized to a $1\n";
172         return;
173     }
174     if ($cv->XSUB) {
175         print $walkHandle "$name is XS code\n";
176         return;
177     }
178     if (class($cv->START) eq "NULL") {
179         no strict 'refs';
180         if (ref $name eq 'CODE') {
181             print $walkHandle "coderef $name has no START\n";
182         }
183         elsif (exists &$name) {
184             print $walkHandle "$name exists in stash, but has no START\n";
185         }
186         else {
187             print $walkHandle "$name not in symbol table\n";
188         }
189         return;
190     }
191     sequence($cv->START);
192     if ($order eq "exec") {
193         walk_exec($cv->START);
194     }
195     elsif ($order eq "basic") {
196         # walk_topdown($cv->ROOT, sub { $_[0]->concise($_[1]) }, 0);
197         my $root = $cv->ROOT;
198         unless (ref $root eq 'B::NULL') {
199             walk_topdown($root, sub { $_[0]->concise($_[1]) }, 0);
200         } else {
201             print $walkHandle "B::NULL encountered doing ROOT on $cv. avoiding disaster\n";
202         }
203     } else {
204         print $walkHandle tree($cv->ROOT, 0);
205     }
206 }
207
208 sub concise_main {
209     my($order) = @_;
210     sequence(main_start);
211     $curcv = main_cv;
212     if ($order eq "exec") {
213         return if class(main_start) eq "NULL";
214         walk_exec(main_start);
215     } elsif ($order eq "tree") {
216         return if class(main_root) eq "NULL";
217         print $walkHandle tree(main_root, 0);
218     } elsif ($order eq "basic") {
219         return if class(main_root) eq "NULL";
220         walk_topdown(main_root,
221                      sub { $_[0]->concise($_[1]) }, 0);
222     }
223 }
224
225 sub concise_specials {
226     my($name, $order, @cv_s) = @_;
227     my $i = 1;
228     if ($name eq "BEGIN") {
229         splice(@cv_s, 0, 8); # skip 7 BEGIN blocks in this file. NOW 8 ??
230     } elsif ($name eq "CHECK") {
231         pop @cv_s; # skip the CHECK block that calls us
232     }
233     for my $cv (@cv_s) {
234         print $walkHandle "$name $i:\n";
235         $i++;
236         concise_cv_obj($order, $cv, $name);
237     }
238 }
239
240 my $start_sym = "\e(0"; # "\cN" sometimes also works
241 my $end_sym   = "\e(B"; # "\cO" respectively
242
243 my @tree_decorations =
244   (["  ", "--", "+-", "|-", "| ", "`-", "-", 1],
245    [" ", "-", "+", "+", "|", "`", "", 0],
246    ["  ", map("$start_sym$_$end_sym", "qq", "wq", "tq", "x ", "mq", "q"), 1],
247    [" ", map("$start_sym$_$end_sym", "q", "w", "t", "x", "m"), "", 0],
248   );
249
250 my @render_packs; # collect -stash=<packages>
251
252 sub compileOpts {
253     # set rendering state from options and args
254     my (@options,@args);
255     if (@_) {
256         @options = grep(/^-/, @_);
257         @args = grep(!/^-/, @_);
258     }
259     for my $o (@options) {
260         # mode/order
261         if ($o eq "-basic") {
262             $order = "basic";
263         } elsif ($o eq "-exec") {
264             $order = "exec";
265         } elsif ($o eq "-tree") {
266             $order = "tree";
267         }
268         # tree-specific
269         elsif ($o eq "-compact") {
270             $tree_style |= 1;
271         } elsif ($o eq "-loose") {
272             $tree_style &= ~1;
273         } elsif ($o eq "-vt") {
274             $tree_style |= 2;
275         } elsif ($o eq "-ascii") {
276             $tree_style &= ~2;
277         }
278         # sequence numbering
279         elsif ($o =~ /^-base(\d+)$/) {
280             $base = $1;
281         } elsif ($o eq "-bigendian") {
282             $big_endian = 1;
283         } elsif ($o eq "-littleendian") {
284             $big_endian = 0;
285         }
286         # miscellaneous, presentation
287         elsif ($o eq "-nobanner") {
288             $banner = 0;
289         } elsif ($o eq "-banner") {
290             $banner = 1;
291         }
292         elsif ($o eq "-main") {
293             $do_main = 1;
294         } elsif ($o eq "-nomain") {
295             $do_main = 0;
296         } elsif ($o eq "-src") {
297             $show_src = 1;
298         }
299         elsif ($o =~ /^-stash=(.*)/) {
300             my $pkg = $1;
301             no strict 'refs';
302             if (! %{$pkg.'::'}) {
303                 eval "require $pkg";
304             } else {
305                 require Config;
306                 if (!$Config::Config{usedl}
307                     && keys %{$pkg.'::'} == 1
308                     && $pkg->can('bootstrap')) {
309                     # It is something that we're statically linked to, but hasn't
310                     # yet been used.
311                     eval "require $pkg";
312                 }
313             }
314             push @render_packs, $pkg;
315         }
316         # line-style options
317         elsif (exists $style{substr($o, 1)}) {
318             $stylename = substr($o, 1);
319             set_style_standard($stylename);
320         } else {
321             warn "Option $o unrecognized";
322         }
323     }
324     return (@args);
325 }
326
327 sub compile {
328     my (@args) = compileOpts(@_);
329     return sub {
330         my @newargs = compileOpts(@_); # accept new rendering options
331         warn "disregarding non-options: @newargs\n" if @newargs;
332
333         for my $objname (@args) {
334             next unless $objname; # skip null args to avoid noisy responses
335
336             if ($objname eq "BEGIN") {
337                 concise_specials("BEGIN", $order,
338                                  B::begin_av->isa("B::AV") ?
339                                  B::begin_av->ARRAY : ());
340             } elsif ($objname eq "INIT") {
341                 concise_specials("INIT", $order,
342                                  B::init_av->isa("B::AV") ?
343                                  B::init_av->ARRAY : ());
344             } elsif ($objname eq "CHECK") {
345                 concise_specials("CHECK", $order,
346                                  B::check_av->isa("B::AV") ?
347                                  B::check_av->ARRAY : ());
348             } elsif ($objname eq "UNITCHECK") {
349                 concise_specials("UNITCHECK", $order,
350                                  B::unitcheck_av->isa("B::AV") ?
351                                  B::unitcheck_av->ARRAY : ());
352             } elsif ($objname eq "END") {
353                 concise_specials("END", $order,
354                                  B::end_av->isa("B::AV") ?
355                                  B::end_av->ARRAY : ());
356             }
357             else {
358                 # convert function names to subrefs
359                 if (ref $objname) {
360                     print $walkHandle "B::Concise::compile($objname)\n"
361                         if $banner;
362                     concise_subref($order, ($objname)x2);
363                     next;
364                 } else {
365                     $objname = "main::" . $objname unless $objname =~ /::/;
366                     no strict 'refs';
367                     my $glob = \*$objname;
368                     unless (*$glob{CODE} || *$glob{FORMAT}) {
369                         print $walkHandle "$objname:\n" if $banner;
370                         print $walkHandle "err: unknown function ($objname)\n";
371                         return;
372                     }
373                     if (my $objref = *$glob{CODE}) {
374                         print $walkHandle "$objname:\n" if $banner;
375                         concise_subref($order, $objref, $objname);
376                     }
377                     if (my $objref = *$glob{FORMAT}) {
378                         print $walkHandle "$objname (FORMAT):\n"
379                             if $banner;
380                         concise_subref($order, $objref, $objname);
381                     }
382                 }
383             }
384         }
385         for my $pkg (@render_packs) {
386             no strict 'refs';
387             concise_stashref($order, \%{$pkg.'::'});
388         }
389
390         if (!@args or $do_main or @render_packs) {
391             print $walkHandle "main program:\n" if $do_main;
392             concise_main($order);
393         }
394         return @args;   # something
395     }
396 }
397
398 my %labels;
399 my $lastnext;   # remembers op-chain, used to insert gotos
400
401 my %opclass = ('OP' => "0", 'UNOP' => "1", 'BINOP' => "2", 'LOGOP' => "|",
402                'LISTOP' => "@", 'PMOP' => "/", 'SVOP' => "\$", 'GVOP' => "*",
403                'PVOP' => '"', 'LOOP' => "{", 'COP' => ";", 'PADOP' => "#",
404                'METHOP' => '.');
405
406 no warnings 'qw'; # "Possible attempt to put comments..."; use #7
407 my @linenoise =
408   qw'#  () sc (  @? 1  $* gv *{ m$ m@ m% m? p/ *$ $  $# & a& pt \\ s\\ rf bl
409      `  *? <> ?? ?/ r/ c/ // qr s/ /c y/ =  @= C  sC Cp sp df un BM po +1 +I
410      -1 -I 1+ I+ 1- I- ** *  i* /  i/ %$ i% x  +  i+ -  i- .  "  << >> <  i<
411      >  i> <= i, >= i. == i= != i! <? i? s< s> s, s. s= s! s? b& b^ b| -0 -i
412      !  ~  a2 si cs rd sr e^ lg sq in %x %o ab le ss ve ix ri sf FL od ch cy
413      uf lf uc lc qm @  [f [  @[ eh vl ky dl ex %  ${ @{ uk pk st jn )  )[ a@
414      a% sl +] -] [- [+ so rv GS GW MS MW .. f. .f && || ^^ ?: &= |= -> s{ s}
415      v} ca wa di rs ;; ;  ;d }{ {  }  {} f{ it {l l} rt }l }n }r dm }g }e ^o
416      ^c ^| ^# um bm t~ u~ ~d DB db ^s se ^g ^r {w }w pf pr ^O ^K ^R ^W ^d ^v
417      ^e ^t ^k t. fc ic fl .s .p .b .c .l .a .h g1 s1 g2 s2 ?. l? -R -W -X -r
418      -w -x -e -o -O -z -s -M -A -C -S -c -b -f -d -p -l -u -g -k -t -T -B cd
419      co cr u. cm ut r. l@ s@ r@ mD uD oD rD tD sD wD cD f$ w$ p$ sh e$ k$ g3
420      g4 s4 g5 s5 T@ C@ L@ G@ A@ S@ Hg Hc Hr Hw Mg Mc Ms Mr Sg Sc So rq do {e
421      e} {t t} g6 G6 6e g7 G7 7e g8 G8 8e g9 G9 9e 6s 7s 8s 9s 6E 7E 8E 9E Pn
422      Pu GP SP EP Gn Gg GG SG EG g0 c$ lk t$ ;s n> // /= CO';
423
424 my $chars = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
425
426 sub op_flags { # common flags (see BASOP.op_flags in op.h)
427     my($x) = @_;
428     my(@v);
429     push @v, "v" if ($x & 3) == 1;
430     push @v, "s" if ($x & 3) == 2;
431     push @v, "l" if ($x & 3) == 3;
432     push @v, "K" if $x & 4;
433     push @v, "P" if $x & 8;
434     push @v, "R" if $x & 16;
435     push @v, "M" if $x & 32;
436     push @v, "S" if $x & 64;
437     push @v, "*" if $x & 128;
438     return join("", @v);
439 }
440
441 sub base_n {
442     my $x = shift;
443     return "-" . base_n(-$x) if $x < 0;
444     my $str = "";
445     do { $str .= substr($chars, $x % $base, 1) } while $x = int($x / $base);
446     $str = reverse $str if $big_endian;
447     return $str;
448 }
449
450 my %sequence_num;
451 my $seq_max = 1;
452
453 sub reset_sequence {
454     # reset the sequence
455     %sequence_num = ();
456     $seq_max = 1;
457     $lastnext = 0;
458 }
459
460 sub seq {
461     my($op) = @_;
462     return "-" if not exists $sequence_num{$$op};
463     return base_n($sequence_num{$$op});
464 }
465
466 sub walk_topdown {
467     my($op, $sub, $level) = @_;
468     $sub->($op, $level);
469     if ($op->flags & OPf_KIDS) {
470         for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
471             walk_topdown($kid, $sub, $level + 1);
472         }
473     }
474     if (class($op) eq "PMOP") {
475         my $maybe_root = $op->pmreplroot;
476         if (ref($maybe_root) and $maybe_root->isa("B::OP")) {
477             # It really is the root of the replacement, not something
478             # else stored here for lack of space elsewhere
479             walk_topdown($maybe_root, $sub, $level + 1);
480         }
481     }
482 }
483
484 sub walklines {
485     my($ar, $level) = @_;
486     for my $l (@$ar) {
487         if (ref($l) eq "ARRAY") {
488             walklines($l, $level + 1);
489         } else {
490             $l->concise($level);
491         }
492     }
493 }
494
495 sub walk_exec {
496     my($top, $level) = @_;
497     my %opsseen;
498     my @lines;
499     my @todo = ([$top, \@lines]);
500     while (@todo and my($op, $targ) = @{shift @todo}) {
501         for (; $$op; $op = $op->next) {
502             last if $opsseen{$$op}++;
503             push @$targ, $op;
504             my $name = $op->name;
505             if (class($op) eq "LOGOP") {
506                 my $ar = [];
507                 push @$targ, $ar;
508                 push @todo, [$op->other, $ar];
509             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
510                 my $ar = [];
511                 push @$targ, $ar;
512                 push @todo, [$op->pmreplstart, $ar];
513             } elsif ($name =~ /^enter(loop|iter)$/) {
514                 $labels{${$op->nextop}} = "NEXT";
515                 $labels{${$op->lastop}} = "LAST";
516                 $labels{${$op->redoop}} = "REDO";
517             }
518         }
519     }
520     walklines(\@lines, 0);
521 }
522
523 # The structure of this routine is purposely modeled after op.c's peep()
524 sub sequence {
525     my($op) = @_;
526     my $oldop = 0;
527     return if class($op) eq "NULL" or exists $sequence_num{$$op};
528     for (; $$op; $op = $op->next) {
529         last if exists $sequence_num{$$op};
530         my $name = $op->name;
531         if ($name =~ /^(null|scalar|lineseq|scope)$/) {
532             next if $oldop and $ {$op->next};
533         } else {
534             $sequence_num{$$op} = $seq_max++;
535             if (class($op) eq "LOGOP") {
536                 my $other = $op->other;
537                 $other = $other->next while $other->name eq "null";
538                 sequence($other);
539             } elsif (class($op) eq "LOOP") {
540                 my $redoop = $op->redoop;
541                 $redoop = $redoop->next while $redoop->name eq "null";
542                 sequence($redoop);
543                 my $nextop = $op->nextop;
544                 $nextop = $nextop->next while $nextop->name eq "null";
545                 sequence($nextop);
546                 my $lastop = $op->lastop;
547                 $lastop = $lastop->next while $lastop->name eq "null";
548                 sequence($lastop);
549             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
550                 my $replstart = $op->pmreplstart;
551                 $replstart = $replstart->next while $replstart->name eq "null";
552                 sequence($replstart);
553             }
554         }
555         $oldop = $op;
556     }
557 }
558
559 sub fmt_line {    # generate text-line for op.
560     my($hr, $op, $text, $level) = @_;
561
562     $_->($hr, $op, \$text, \$level, $stylename) for @callbacks;
563
564     return '' if $hr->{SKIP};   # suppress line if a callback said so
565     return '' if $hr->{goto} and $hr->{goto} eq '-';    # no goto nowhere
566
567     # spec: (?(text1#varText2)?)
568     $text =~ s/\(\?\(([^\#]*?)\#(\w+)([^\#]*?)\)\?\)/
569         $hr->{$2} ? $1.$hr->{$2}.$3 : ""/eg;
570
571     # spec: (x(exec_text;basic_text)x)
572     $text =~ s/\(x\((.*?);(.*?)\)x\)/$order eq "exec" ? $1 : $2/egs;
573
574     # spec: (*(text)*)
575     $text =~ s/\(\*\(([^;]*?)\)\*\)/$1 x $level/egs;
576
577     # spec: (*(text1;text2)*)
578     $text =~ s/\(\*\((.*?);(.*?)\)\*\)/$1 x ($level - 1) . $2 x ($level>0)/egs;
579
580     # convert #Var to tag=>val form: Var\t#var
581     $text =~ s/\#([A-Z][a-z]+)(\d+)?/\t\u$1\t\L#$1$2/gs;
582
583     # spec: #varN
584     $text =~ s/\#([a-zA-Z]+)(\d+)/sprintf("%-$2s", $hr->{$1})/eg;
585
586     $text =~ s/\#([a-zA-Z]+)/$hr->{$1}/eg;      # populate #var's
587     $text =~ s/[ \t]*~+[ \t]*/ /g;              # squeeze tildes
588
589     $text = "# $hr->{src}\n$text" if $show_src and $hr->{src};
590
591     chomp $text;
592     return "$text\n" if $text ne "" and $order ne "tree";
593     return $text; # suppress empty lines
594 }
595
596
597
598 # use require rather than use here to avoid disturbing tests that dump
599 # BEGIN blocks
600 require B::Op_private;
601
602
603
604 our %hints; # used to display each COP's op_hints values
605
606 # strict refs, subs, vars
607 @hints{2,512,1024,32,64,128} = ('$', '&', '*', 'x$', 'x&', 'x*');
608 # integers, locale, bytes
609 @hints{1,4,8,16} = ('i', 'l', 'b');
610 # block scope, localise %^H, $^OPEN (in), $^OPEN (out)
611 @hints{256,131072,262144,524288} = ('{','%','<','>');
612 # overload new integer, float, binary, string, re
613 @hints{4096,8192,16384,32768,65536} = ('I', 'F', 'B', 'S', 'R');
614 # taint and eval
615 @hints{1048576,2097152} = ('T', 'E');
616 # filetest access, UTF-8
617 @hints{4194304,8388608} = ('X', 'U');
618
619 sub _flags {
620     my($hash, $x) = @_;
621     my @s;
622     for my $flag (sort {$b <=> $a} keys %$hash) {
623         if ($hash->{$flag} and $x & $flag and $x >= $flag) {
624             $x -= $flag;
625             push @s, $hash->{$flag};
626         }
627     }
628     push @s, $x if $x;
629     return join(",", @s);
630 }
631
632 # return a string like 'LVINTRO,1' for the op $name with op_private
633 # value $x
634
635 sub private_flags {
636     my($name, $x) = @_;
637     my $entry = $B::Op_private::bits{$name};
638     return $x ? "$x" : '' unless $entry;
639
640     my @flags;
641     my $bit;
642     for ($bit = 7; $bit >= 0; $bit--) {
643         next unless exists $entry->{$bit};
644         my $e = $entry->{$bit};
645         if (ref($e) eq 'HASH') {
646             # bit field
647
648             my ($bitmin, $bitmax, $bitmask, $enum, $label) =
649                     @{$e}{qw(bitmin bitmax bitmask enum label)};
650             $bit = $bitmin;
651             next if defined $label && $label eq '-'; # display as raw number
652
653             my $val = $x & $bitmask;
654             $x &= ~$bitmask;
655             $val >>= $bitmin;
656
657             if (defined $enum) {
658                 # try to convert numeric $val into symbolic
659                 my @enum = @$enum;
660                 while (@enum) {
661                     my $ix    = shift @enum;
662                     my $name  = shift @enum;
663                     my $label = shift @enum;
664                     if ($val == $ix) {
665                         $val = $label;
666                         last;
667                     }
668                 }
669             }
670             next if $val eq '0'; # don't display anonymous zero values
671             push @flags, defined $label ? "$label=$val" : $val;
672
673         }
674         else {
675             # flag bit
676             my $label = $B::Op_private::labels{$e};
677             next if defined $label && $label eq '-'; # display as raw number
678             if ($x & (1<<$bit)) {
679                 $x -= (1<<$bit);
680                 push @flags, $label;
681             }
682         }
683     }
684
685     push @flags, $x if $x; # display unknown bits numerically
686     return join ",", @flags;
687 }
688
689 sub hints_flags {
690     my($x) = @_;
691     _flags(\%hints, $x);
692 }
693
694 sub concise_sv {
695     my($sv, $hr, $preferpv) = @_;
696     $hr->{svclass} = class($sv);
697     $hr->{svclass} = "UV"
698       if $hr->{svclass} eq "IV" and $sv->FLAGS & SVf_IVisUV;
699     Carp::cluck("bad concise_sv: $sv") unless $sv and $$sv;
700     $hr->{svaddr} = sprintf("%#x", $$sv);
701     if ($hr->{svclass} eq "GV" && $sv->isGV_with_GP()) {
702         my $gv = $sv;
703         my $stash = $gv->STASH;
704         if (class($stash) eq "SPECIAL") {
705             $stash = "<none>";
706         }
707         else {
708             $stash = $stash->NAME;
709         }
710         if ($stash eq "main") {
711             $stash = "";
712         } else {
713             $stash = $stash . "::";
714         }
715         $hr->{svval} = "*$stash" . $gv->SAFENAME;
716         return "*$stash" . $gv->SAFENAME;
717     } else {
718         if ($] >= 5.011) {
719             while (class($sv) eq "IV" && $sv->FLAGS & SVf_ROK) {
720                 $hr->{svval} .= "\\";
721                 $sv = $sv->RV;
722             }
723         } else {
724             while (class($sv) eq "RV") {
725                 $hr->{svval} .= "\\";
726                 $sv = $sv->RV;
727             }
728         }
729         if (class($sv) eq "SPECIAL") {
730             $hr->{svval} .= ["Null", "sv_undef", "sv_yes", "sv_no"]->[$$sv];
731         } elsif ($preferpv
732               && ($sv->FLAGS & SVf_POK || class($sv) eq "REGEXP")) {
733             $hr->{svval} .= cstring($sv->PV);
734         } elsif ($sv->FLAGS & SVf_NOK) {
735             $hr->{svval} .= $sv->NV;
736         } elsif ($sv->FLAGS & SVf_IOK) {
737             $hr->{svval} .= $sv->int_value;
738         } elsif ($sv->FLAGS & SVf_POK || class($sv) eq "REGEXP") {
739             $hr->{svval} .= cstring($sv->PV);
740         } elsif (class($sv) eq "HV") {
741             $hr->{svval} .= 'HASH';
742         }
743
744         $hr->{svval} = 'undef' unless defined $hr->{svval};
745         my $out = $hr->{svclass};
746         return $out .= " $hr->{svval}" ; 
747     }
748 }
749
750 my %srclines;
751
752 sub fill_srclines {
753     my $fullnm = shift;
754     if ($fullnm eq '-e') {
755         $srclines{$fullnm} = [ $fullnm, "-src not supported for -e" ];
756         return;
757     }
758     open (my $fh, '<', $fullnm)
759         or warn "# $fullnm: $!, (chdirs not supported by this feature yet)\n"
760         and return;
761     my @l = <$fh>;
762     chomp @l;
763     unshift @l, $fullnm; # like @{_<$fullnm} in debug, array starts at 1
764     $srclines{$fullnm} = \@l;
765 }
766
767 sub concise_op {
768     my ($op, $level, $format) = @_;
769     my %h;
770     $h{exname} = $h{name} = $op->name;
771     $h{NAME} = uc $h{name};
772     $h{class} = class($op);
773     $h{extarg} = $h{targ} = $op->targ;
774     $h{extarg} = "" unless $h{extarg};
775     $h{privval} = $op->private;
776     # for null ops, targ holds the old type
777     my $origname = $h{name} eq "null" && $h{targ}
778       ? substr(ppname($h{targ}), 3)
779       : $h{name};
780     $h{private} = private_flags($origname, $op->private);
781     if ($op->folded) {
782       $h{private} &&= "$h{private},";
783       $h{private} .= "FOLD";
784     }
785
786     if ($h{name} ne $origname) { # a null op
787         $h{exname} = "ex-$origname";
788         $h{extarg} = "";
789     } elsif ($h{private} =~ /\bREFC\b/) {
790         # targ holds a reference count
791         my $refs = "ref" . ($h{targ} != 1 ? "s" : "");
792         $h{targarglife} = $h{targarg} = "$h{targ} $refs";
793     } elsif ($h{targ}) {
794         my $count = $h{name} eq 'padrange'
795             ? ($op->private & $B::Op_private::defines{'OPpPADRANGE_COUNTMASK'})
796             : 1;
797         my (@targarg, @targarglife);
798         for my $i (0..$count-1) {
799             my ($targarg, $targarglife);
800             my $padname = (($curcv->PADLIST->ARRAY)[0]->ARRAY)[$h{targ}+$i];
801             if (defined $padname and class($padname) ne "SPECIAL") {
802                 $targarg  = $padname->PVX;
803                 if ($padname->FLAGS & SVf_FAKE) {
804                     # These changes relate to the jumbo closure fix.
805                     # See changes 19939 and 20005
806                     my $fake = '';
807                     $fake .= 'a'
808                         if $padname->PARENT_FAKELEX_FLAGS & PAD_FAKELEX_ANON;
809                     $fake .= 'm'
810                         if $padname->PARENT_FAKELEX_FLAGS & PAD_FAKELEX_MULTI;
811                     $fake .= ':' . $padname->PARENT_PAD_INDEX
812                         if $curcv->CvFLAGS & CVf_ANON;
813                     $targarglife = "$targarg:FAKE:$fake";
814                 }
815                 else {
816                     my $intro = $padname->COP_SEQ_RANGE_LOW - $cop_seq_base;
817                     my $finish = int($padname->COP_SEQ_RANGE_HIGH) - $cop_seq_base;
818                     $finish = "end" if $finish == 999999999 - $cop_seq_base;
819                     $targarglife = "$targarg:$intro,$finish";
820                 }
821             } else {
822                 $targarglife = $targarg = "t" . ($h{targ}+$i);
823             }
824             push @targarg,     $targarg;
825             push @targarglife, $targarglife;
826         }
827         $h{targarg}     = join '; ', @targarg;
828         $h{targarglife} = join '; ', @targarglife;
829     }
830     $h{arg} = "";
831     $h{svclass} = $h{svaddr} = $h{svval} = "";
832     if ($h{class} eq "PMOP") {
833         my $extra = '';
834         my $precomp = $op->precomp;
835         if (defined $precomp) {
836             $precomp = cstring($precomp); # Escape literal control sequences
837             $precomp = "/$precomp/";
838         } else {
839             $precomp = "";
840         }
841         if ($op->name eq 'subst') {
842             if (class($op->pmreplstart) ne "NULL") {
843                 undef $lastnext;
844                 $extra = " replstart->" . seq($op->pmreplstart);
845             }
846         }
847         elsif ($op->name eq 'pushre') {
848             # with C<@stash_array = split(/pat/, str);>,
849             #  *stash_array is stored in /pat/'s pmreplroot.
850             my $gv = $op->pmreplroot;
851             if (!ref($gv)) {
852                 # threaded: the value is actually a pad offset for where
853                 # the GV is kept (op_pmtargetoff)
854                 if ($gv) {
855                     $gv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$gv]->NAME;
856                 }
857             }
858             else {
859                 # unthreaded: its a GV (if it exists)
860                 $gv = (ref($gv) eq "B::GV") ? $gv->NAME : undef;
861             }
862             $extra = " => \@$gv" if $gv;
863         }
864         $h{arg} = "($precomp$extra)";
865     } elsif ($h{class} eq "PVOP" and $h{name} !~ '^transr?\z') {
866         $h{arg} = '("' . $op->pv . '")';
867         $h{svval} = '"' . $op->pv . '"';
868     } elsif ($h{class} eq "COP") {
869         my $label = $op->label;
870         $h{coplabel} = $label;
871         $label = $label ? "$label: " : "";
872         my $loc = $op->file;
873         my $pathnm = $loc;
874         $loc =~ s[.*/][];
875         my $ln = $op->line;
876         $loc .= ":$ln";
877         my($stash, $cseq) = ($op->stash->NAME, $op->cop_seq - $cop_seq_base);
878         $h{arg} = "($label$stash $cseq $loc)";
879         if ($show_src) {
880             fill_srclines($pathnm) unless exists $srclines{$pathnm};
881             # Would love to retain Jim's use of // but this code needs to be
882             # portable to 5.8.x
883             my $line = $srclines{$pathnm}[$ln];
884             $line = "-src unavailable under -e" unless defined $line;
885             $h{src} = "$ln: $line";
886         }
887     } elsif ($h{class} eq "LOOP") {
888         $h{arg} = "(next->" . seq($op->nextop) . " last->" . seq($op->lastop)
889           . " redo->" . seq($op->redoop) . ")";
890     } elsif ($h{class} eq "LOGOP") {
891         undef $lastnext;
892         $h{arg} = "(other->" . seq($op->other) . ")";
893         $h{otheraddr} = sprintf("%#x", $ {$op->other});
894     }
895     elsif ($h{class} eq "SVOP" or $h{class} eq "PADOP") {
896         unless ($h{name} eq 'aelemfast' and $op->flags & OPf_SPECIAL) {
897             my $idx = ($h{class} eq "SVOP") ? $op->targ : $op->padix;
898             if ($h{class} eq "PADOP" or !${$op->sv}) {
899                 my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$idx];
900                 $h{arg} = "[" . concise_sv($sv, \%h, 0) . "]";
901                 $h{targarglife} = $h{targarg} = "";
902             } else {
903                 $h{arg} = "(" . concise_sv($op->sv, \%h, 0) . ")";
904             }
905         }
906     }
907     elsif ($h{class} eq "METHOP") {
908         if ($h{name} eq "method_named") {
909             if (${$op->meth_sv}) {
910                 $h{arg} = "(" . concise_sv($op->meth_sv, \%h, 1) . ")";
911             } else {
912                 my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$op->targ];
913                 $h{arg} = "[" . concise_sv($sv, \%h, 1) . "]";
914                 $h{targarglife} = $h{targarg} = "";
915             }
916         }
917     }
918     $h{seq} = $h{hyphseq} = seq($op);
919     $h{seq} = "" if $h{seq} eq "-";
920     $h{opt} = $op->opt;
921     $h{label} = $labels{$$op};
922     $h{next} = $op->next;
923     $h{next} = (class($h{next}) eq "NULL") ? "(end)" : seq($h{next});
924     $h{nextaddr} = sprintf("%#x", $ {$op->next});
925     $h{sibaddr} = sprintf("%#x", $ {$op->sibling});
926     $h{firstaddr} = sprintf("%#x", $ {$op->first}) if $op->can("first");
927     $h{lastaddr} = sprintf("%#x", $ {$op->last}) if $op->can("last");
928
929     $h{classsym} = $opclass{$h{class}};
930     $h{flagval} = $op->flags;
931     $h{flags} = op_flags($op->flags);
932     if ($op->can("hints")) {
933       $h{hintsval} = $op->hints;
934       $h{hints} = hints_flags($h{hintsval});
935     } else {
936       $h{hintsval} = $h{hints} = '';
937     }
938     $h{addr} = sprintf("%#x", $$op);
939     $h{typenum} = $op->type;
940     $h{noise} = $linenoise[$op->type];
941
942     return fmt_line(\%h, $op, $format, $level);
943 }
944
945 sub B::OP::concise {
946     my($op, $level) = @_;
947     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
948         # insert a 'goto' line
949         my $synth = {"seq" => seq($lastnext), "class" => class($lastnext),
950                      "addr" => sprintf("%#x", $$lastnext),
951                      "goto" => seq($lastnext), # simplify goto '-' removal
952              };
953         print $walkHandle fmt_line($synth, $op, $gotofmt, $level+1);
954     }
955     $lastnext = $op->next;
956     print $walkHandle concise_op($op, $level, $format);
957 }
958
959 # B::OP::terse (see Terse.pm) now just calls this
960 sub b_terse {
961     my($op, $level) = @_;
962
963     # This isn't necessarily right, but there's no easy way to get
964     # from an OP to the right CV. This is a limitation of the
965     # ->terse() interface style, and there isn't much to do about
966     # it. In particular, we can die in concise_op if the main pad
967     # isn't long enough, or has the wrong kind of entries, compared to
968     # the pad a sub was compiled with. The fix for that would be to
969     # make a backwards compatible "terse" format that never even
970     # looked at the pad, just like the old B::Terse. I don't think
971     # that's worth the effort, though.
972     $curcv = main_cv unless $curcv;
973
974     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
975         # insert a 'goto'
976         my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
977                  "addr" => sprintf("%#x", $$lastnext)};
978         print # $walkHandle
979             fmt_line($h, $op, $style{"terse"}[1], $level+1);
980     }
981     $lastnext = $op->next;
982     print # $walkHandle 
983         concise_op($op, $level, $style{"terse"}[0]);
984 }
985
986 sub tree {
987     my $op = shift;
988     my $level = shift;
989     my $style = $tree_decorations[$tree_style];
990     my($space, $single, $kids, $kid, $nokid, $last, $lead, $size) = @$style;
991     my $name = concise_op($op, $level, $treefmt);
992     if (not $op->flags & OPf_KIDS) {
993         return $name . "\n";
994     }
995     my @lines;
996     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
997         push @lines, tree($kid, $level+1);
998     }
999     my $i;
1000     for ($i = $#lines; substr($lines[$i], 0, 1) eq " "; $i--) {
1001         $lines[$i] = $space . $lines[$i];
1002     }
1003     if ($i > 0) {
1004         $lines[$i] = $last . $lines[$i];
1005         while ($i-- > 1) {
1006             if (substr($lines[$i], 0, 1) eq " ") {
1007                 $lines[$i] = $nokid . $lines[$i];
1008             } else {
1009                 $lines[$i] = $kid . $lines[$i];
1010             }
1011         }
1012         $lines[$i] = $kids . $lines[$i];
1013     } else {
1014         $lines[0] = $single . $lines[0];
1015     }
1016     return("$name$lead" . shift @lines,
1017            map(" " x (length($name)+$size) . $_, @lines));
1018 }
1019
1020 # *** Warning: fragile kludge ahead ***
1021 # Because the B::* modules run in the same interpreter as the code
1022 # they're compiling, their presence tends to distort the view we have of
1023 # the code we're looking at. In particular, perl gives sequence numbers
1024 # to COPs. If the program we're looking at were run on its own, this
1025 # would start at 1. Because all of B::Concise and all the modules it
1026 # uses are compiled first, though, by the time we get to the user's
1027 # program the sequence number is already pretty high, which could be
1028 # distracting if you're trying to tell OPs apart. Therefore we'd like to
1029 # subtract an offset from all the sequence numbers we display, to
1030 # restore the simpler view of the world. The trick is to know what that
1031 # offset will be, when we're still compiling B::Concise!  If we
1032 # hardcoded a value, it would have to change every time B::Concise or
1033 # other modules we use do. To help a little, what we do here is compile
1034 # a little code at the end of the module, and compute the base sequence
1035 # number for the user's program as being a small offset later, so all we
1036 # have to worry about are changes in the offset.
1037
1038 # [For 5.8.x and earlier perl is generating sequence numbers for all ops,
1039 #  and using them to reference labels]
1040
1041
1042 # When you say "perl -MO=Concise -e '$a'", the output should look like:
1043
1044 # 4  <@> leave[t1] vKP/REFC ->(end)
1045 # 1     <0> enter ->2
1046  #^ smallest OP sequence number should be 1
1047 # 2     <;> nextstate(main 1 -e:1) v ->3
1048  #                         ^ smallest COP sequence number should be 1
1049 # -     <1> ex-rv2sv vK/1 ->4
1050 # 3        <$> gvsv(*a) s ->4
1051
1052 # If the second of the marked numbers there isn't 1, it means you need
1053 # to update the corresponding magic number in the next line.
1054 # Remember, this needs to stay the last things in the module.
1055
1056 # Why is this different for MacOS?  Does it matter?
1057 my $cop_seq_mnum = $^O eq 'MacOS' ? 12 : 11;
1058 $cop_seq_base = svref_2object(eval 'sub{0;}')->START->cop_seq + $cop_seq_mnum;
1059
1060 1;
1061
1062 __END__
1063
1064 =head1 NAME
1065
1066 B::Concise - Walk Perl syntax tree, printing concise info about ops
1067
1068 =head1 SYNOPSIS
1069
1070     perl -MO=Concise[,OPTIONS] foo.pl
1071
1072     use B::Concise qw(set_style add_callback);
1073
1074 =head1 DESCRIPTION
1075
1076 This compiler backend prints the internal OPs of a Perl program's syntax
1077 tree in one of several space-efficient text formats suitable for debugging
1078 the inner workings of perl or other compiler backends. It can print OPs in
1079 the order they appear in the OP tree, in the order they will execute, or
1080 in a text approximation to their tree structure, and the format of the
1081 information displayed is customizable. Its function is similar to that of
1082 perl's B<-Dx> debugging flag or the B<B::Terse> module, but it is more
1083 sophisticated and flexible.
1084
1085 =head1 EXAMPLE
1086
1087 Here's two outputs (or 'renderings'), using the -exec and -basic
1088 (i.e. default) formatting conventions on the same code snippet.
1089
1090     % perl -MO=Concise,-exec -e '$a = $b + 42'
1091     1  <0> enter
1092     2  <;> nextstate(main 1 -e:1) v
1093     3  <#> gvsv[*b] s
1094     4  <$> const[IV 42] s
1095  *  5  <2> add[t3] sK/2
1096     6  <#> gvsv[*a] s
1097     7  <2> sassign vKS/2
1098     8  <@> leave[1 ref] vKP/REFC
1099
1100 In this -exec rendering, each opcode is executed in the order shown.
1101 The add opcode, marked with '*', is discussed in more detail.
1102
1103 The 1st column is the op's sequence number, starting at 1, and is
1104 displayed in base 36 by default.  Here they're purely linear; the
1105 sequences are very helpful when looking at code with loops and
1106 branches.
1107
1108 The symbol between angle brackets indicates the op's type, for
1109 example; <2> is a BINOP, <@> a LISTOP, and <#> is a PADOP, which is
1110 used in threaded perls. (see L</"OP class abbreviations">).
1111
1112 The opname, as in B<'add[t1]'>, may be followed by op-specific
1113 information in parentheses or brackets (ex B<'[t1]'>).
1114
1115 The op-flags (ex B<'sK/2'>) are described in (L</"OP flags
1116 abbreviations">).
1117
1118     % perl -MO=Concise -e '$a = $b + 42'
1119     8  <@> leave[1 ref] vKP/REFC ->(end)
1120     1     <0> enter ->2
1121     2     <;> nextstate(main 1 -e:1) v ->3
1122     7     <2> sassign vKS/2 ->8
1123  *  5        <2> add[t1] sK/2 ->6
1124     -           <1> ex-rv2sv sK/1 ->4
1125     3              <$> gvsv(*b) s ->4
1126     4           <$> const(IV 42) s ->5
1127     -        <1> ex-rv2sv sKRM*/1 ->7
1128     6           <$> gvsv(*a) s ->7
1129
1130 The default rendering is top-down, so they're not in execution order.
1131 This form reflects the way the stack is used to parse and evaluate
1132 expressions; the add operates on the two terms below it in the tree.
1133
1134 Nullops appear as C<ex-opname>, where I<opname> is an op that has been
1135 optimized away by perl.  They're displayed with a sequence-number of
1136 '-', because they are not executed (they don't appear in previous
1137 example), they're printed here because they reflect the parse.
1138
1139 The arrow points to the sequence number of the next op; they're not
1140 displayed in -exec mode, for obvious reasons.
1141
1142 Note that because this rendering was done on a non-threaded perl, the
1143 PADOPs in the previous examples are now SVOPs, and some (but not all)
1144 of the square brackets have been replaced by round ones.  This is a
1145 subtle feature to provide some visual distinction between renderings
1146 on threaded and un-threaded perls.
1147
1148
1149 =head1 OPTIONS
1150
1151 Arguments that don't start with a hyphen are taken to be the names of
1152 subroutines or formats to render; if no
1153 such functions are specified, the main
1154 body of the program (outside any subroutines, and not including use'd
1155 or require'd files) is rendered.  Passing C<BEGIN>, C<UNITCHECK>,
1156 C<CHECK>, C<INIT>, or C<END> will cause all of the corresponding
1157 special blocks to be printed.  Arguments must follow options.
1158
1159 Options affect how things are rendered (ie printed).  They're presented
1160 here by their visual effect, 1st being strongest.  They're grouped
1161 according to how they interrelate; within each group the options are
1162 mutually exclusive (unless otherwise stated).
1163
1164 =head2 Options for Opcode Ordering
1165
1166 These options control the 'vertical display' of opcodes.  The display
1167 'order' is also called 'mode' elsewhere in this document.
1168
1169 =over 4
1170
1171 =item B<-basic>
1172
1173 Print OPs in the order they appear in the OP tree (a preorder
1174 traversal, starting at the root). The indentation of each OP shows its
1175 level in the tree, and the '->' at the end of the line indicates the
1176 next opcode in execution order.  This mode is the default, so the flag
1177 is included simply for completeness.
1178
1179 =item B<-exec>
1180
1181 Print OPs in the order they would normally execute (for the majority
1182 of constructs this is a postorder traversal of the tree, ending at the
1183 root). In most cases the OP that usually follows a given OP will
1184 appear directly below it; alternate paths are shown by indentation. In
1185 cases like loops when control jumps out of a linear path, a 'goto'
1186 line is generated.
1187
1188 =item B<-tree>
1189
1190 Print OPs in a text approximation of a tree, with the root of the tree
1191 at the left and 'left-to-right' order of children transformed into
1192 'top-to-bottom'. Because this mode grows both to the right and down,
1193 it isn't suitable for large programs (unless you have a very wide
1194 terminal).
1195
1196 =back
1197
1198 =head2 Options for Line-Style
1199
1200 These options select the line-style (or just style) used to render
1201 each opcode, and dictates what info is actually printed into each line.
1202
1203 =over 4
1204
1205 =item B<-concise>
1206
1207 Use the author's favorite set of formatting conventions. This is the
1208 default, of course.
1209
1210 =item B<-terse>
1211
1212 Use formatting conventions that emulate the output of B<B::Terse>. The
1213 basic mode is almost indistinguishable from the real B<B::Terse>, and the
1214 exec mode looks very similar, but is in a more logical order and lacks
1215 curly brackets. B<B::Terse> doesn't have a tree mode, so the tree mode
1216 is only vaguely reminiscent of B<B::Terse>.
1217
1218 =item B<-linenoise>
1219
1220 Use formatting conventions in which the name of each OP, rather than being
1221 written out in full, is represented by a one- or two-character abbreviation.
1222 This is mainly a joke.
1223
1224 =item B<-debug>
1225
1226 Use formatting conventions reminiscent of B<B::Debug>; these aren't
1227 very concise at all.
1228
1229 =item B<-env>
1230
1231 Use formatting conventions read from the environment variables
1232 C<B_CONCISE_FORMAT>, C<B_CONCISE_GOTO_FORMAT>, and C<B_CONCISE_TREE_FORMAT>.
1233
1234 =back
1235
1236 =head2 Options for tree-specific formatting
1237
1238 =over 4
1239
1240 =item B<-compact>
1241
1242 Use a tree format in which the minimum amount of space is used for the
1243 lines connecting nodes (one character in most cases). This squeezes out
1244 a few precious columns of screen real estate.
1245
1246 =item B<-loose>
1247
1248 Use a tree format that uses longer edges to separate OP nodes. This format
1249 tends to look better than the compact one, especially in ASCII, and is
1250 the default.
1251
1252 =item B<-vt>
1253
1254 Use tree connecting characters drawn from the VT100 line-drawing set.
1255 This looks better if your terminal supports it.
1256
1257 =item B<-ascii>
1258
1259 Draw the tree with standard ASCII characters like C<+> and C<|>. These don't
1260 look as clean as the VT100 characters, but they'll work with almost any
1261 terminal (or the horizontal scrolling mode of less(1)) and are suitable
1262 for text documentation or email. This is the default.
1263
1264 =back
1265
1266 These are pairwise exclusive, i.e. compact or loose, vt or ascii.
1267
1268 =head2 Options controlling sequence numbering
1269
1270 =over 4
1271
1272 =item B<-base>I<n>
1273
1274 Print OP sequence numbers in base I<n>. If I<n> is greater than 10, the
1275 digit for 11 will be 'a', and so on. If I<n> is greater than 36, the digit
1276 for 37 will be 'A', and so on until 62. Values greater than 62 are not
1277 currently supported. The default is 36.
1278
1279 =item B<-bigendian>
1280
1281 Print sequence numbers with the most significant digit first. This is the
1282 usual convention for Arabic numerals, and the default.
1283
1284 =item B<-littleendian>
1285
1286 Print sequence numbers with the least significant digit first.  This is
1287 obviously mutually exclusive with bigendian.
1288
1289 =back
1290
1291 =head2 Other options
1292
1293 =over 4
1294
1295 =item B<-src>
1296
1297 With this option, the rendering of each statement (starting with the
1298 nextstate OP) will be preceded by the 1st line of source code that
1299 generates it.  For example:
1300
1301     1  <0> enter
1302     # 1: my $i;
1303     2  <;> nextstate(main 1 junk.pl:1) v:{
1304     3  <0> padsv[$i:1,10] vM/LVINTRO
1305     # 3: for $i (0..9) {
1306     4  <;> nextstate(main 3 junk.pl:3) v:{
1307     5  <0> pushmark s
1308     6  <$> const[IV 0] s
1309     7  <$> const[IV 9] s
1310     8  <{> enteriter(next->j last->m redo->9)[$i:1,10] lKS
1311     k  <0> iter s
1312     l  <|> and(other->9) vK/1
1313     # 4:     print "line ";
1314     9      <;> nextstate(main 2 junk.pl:4) v
1315     a      <0> pushmark s
1316     b      <$> const[PV "line "] s
1317     c      <@> print vK
1318     # 5:     print "$i\n";
1319     ...
1320
1321 =item B<-stash="somepackage">
1322
1323 With this, "somepackage" will be required, then the stash is
1324 inspected, and each function is rendered.
1325
1326 =back
1327
1328 The following options are pairwise exclusive.
1329
1330 =over 4
1331
1332 =item B<-main>
1333
1334 Include the main program in the output, even if subroutines were also
1335 specified.  This rendering is normally suppressed when a subroutine
1336 name or reference is given.
1337
1338 =item B<-nomain>
1339
1340 This restores the default behavior after you've changed it with '-main'
1341 (it's not normally needed).  If no subroutine name/ref is given, main is
1342 rendered, regardless of this flag.
1343
1344 =item B<-nobanner>
1345
1346 Renderings usually include a banner line identifying the function name
1347 or stringified subref.  This suppresses the printing of the banner.
1348
1349 TBC: Remove the stringified coderef; while it provides a 'cookie' for
1350 each function rendered, the cookies used should be 1,2,3.. not a
1351 random hex-address.  It also complicates string comparison of two
1352 different trees.
1353
1354 =item B<-banner>
1355
1356 restores default banner behavior.
1357
1358 =item B<-banneris> => subref
1359
1360 TBC: a hookpoint (and an option to set it) for a user-supplied
1361 function to produce a banner appropriate for users needs.  It's not
1362 ideal, because the rendering-state variables, which are a natural
1363 candidate for use in concise.t, are unavailable to the user.
1364
1365 =back
1366
1367 =head2 Option Stickiness
1368
1369 If you invoke Concise more than once in a program, you should know that
1370 the options are 'sticky'.  This means that the options you provide in
1371 the first call will be remembered for the 2nd call, unless you
1372 re-specify or change them.
1373
1374 =head1 ABBREVIATIONS
1375
1376 The concise style uses symbols to convey maximum info with minimal
1377 clutter (like hex addresses).  With just a little practice, you can
1378 start to see the flowers, not just the branches, in the trees.
1379
1380 =head2 OP class abbreviations
1381
1382 These symbols appear before the op-name, and indicate the
1383 B:: namespace that represents the ops in your Perl code.
1384
1385     0      OP (aka BASEOP)  An OP with no children
1386     1      UNOP             An OP with one child
1387     2      BINOP            An OP with two children
1388     |      LOGOP            A control branch OP
1389     @      LISTOP           An OP that could have lots of children
1390     /      PMOP             An OP with a regular expression
1391     $      SVOP             An OP with an SV
1392     "      PVOP             An OP with a string
1393     {      LOOP             An OP that holds pointers for a loop
1394     ;      COP              An OP that marks the start of a statement
1395     #      PADOP            An OP with a GV on the pad
1396     .      METHOP           An OP with method call info
1397
1398 =head2 OP flags abbreviations
1399
1400 OP flags are either public or private.  The public flags alter the
1401 behavior of each opcode in consistent ways, and are represented by 0
1402 or more single characters.
1403
1404     v      OPf_WANT_VOID    Want nothing (void context)
1405     s      OPf_WANT_SCALAR  Want single value (scalar context)
1406     l      OPf_WANT_LIST    Want list of any length (list context)
1407                             Want is unknown
1408     K      OPf_KIDS         There is a firstborn child.
1409     P      OPf_PARENS       This operator was parenthesized.
1410                              (Or block needs explicit scope entry.)
1411     R      OPf_REF          Certified reference.
1412                              (Return container, not containee).
1413     M      OPf_MOD          Will modify (lvalue).
1414     S      OPf_STACKED      Some arg is arriving on the stack.
1415     *      OPf_SPECIAL      Do something weird for this op (see op.h)
1416
1417 Private flags, if any are set for an opcode, are displayed after a '/'
1418
1419     8  <@> leave[1 ref] vKP/REFC ->(end)
1420     7     <2> sassign vKS/2 ->8
1421
1422 They're opcode specific, and occur less often than the public ones, so
1423 they're represented by short mnemonics instead of single-chars; see
1424 B::Op_private and F<regen/op_private> for more details.
1425
1426 =head1 FORMATTING SPECIFICATIONS
1427
1428 For each line-style ('concise', 'terse', 'linenoise', etc.) there are
1429 3 format-specs which control how OPs are rendered.
1430
1431 The first is the 'default' format, which is used in both basic and exec
1432 modes to print all opcodes.  The 2nd, goto-format, is used in exec
1433 mode when branches are encountered.  They're not real opcodes, and are
1434 inserted to look like a closing curly brace.  The tree-format is tree
1435 specific.
1436
1437 When a line is rendered, the correct format-spec is copied and scanned
1438 for the following items; data is substituted in, and other
1439 manipulations like basic indenting are done, for each opcode rendered.
1440
1441 There are 3 kinds of items that may be populated; special patterns,
1442 #vars, and literal text, which is copied verbatim.  (Yes, it's a set
1443 of s///g steps.)
1444
1445 =head2 Special Patterns
1446
1447 These items are the primitives used to perform indenting, and to
1448 select text from amongst alternatives.
1449
1450 =over 4
1451
1452 =item B<(x(>I<exec_text>B<;>I<basic_text>B<)x)>
1453
1454 Generates I<exec_text> in exec mode, or I<basic_text> in basic mode.
1455
1456 =item B<(*(>I<text>B<)*)>
1457
1458 Generates one copy of I<text> for each indentation level.
1459
1460 =item B<(*(>I<text1>B<;>I<text2>B<)*)>
1461
1462 Generates one fewer copies of I<text1> than the indentation level, followed
1463 by one copy of I<text2> if the indentation level is more than 0.
1464
1465 =item B<(?(>I<text1>B<#>I<var>I<Text2>B<)?)>
1466
1467 If the value of I<var> is true (not empty or zero), generates the
1468 value of I<var> surrounded by I<text1> and I<Text2>, otherwise
1469 nothing.
1470
1471 =item B<~>
1472
1473 Any number of tildes and surrounding whitespace will be collapsed to
1474 a single space.
1475
1476 =back
1477
1478 =head2 # Variables
1479
1480 These #vars represent opcode properties that you may want as part of
1481 your rendering.  The '#' is intended as a private sigil; a #var's
1482 value is interpolated into the style-line, much like "read $this".
1483
1484 These vars take 3 forms:
1485
1486 =over 4
1487
1488 =item B<#>I<var>
1489
1490 A property named 'var' is assumed to exist for the opcodes, and is
1491 interpolated into the rendering.
1492
1493 =item B<#>I<var>I<N>
1494
1495 Generates the value of I<var>, left justified to fill I<N> spaces.
1496 Note that this means while you can have properties 'foo' and 'foo2',
1497 you cannot render 'foo2', but you could with 'foo2a'.  You would be
1498 wise not to rely on this behavior going forward ;-)
1499
1500 =item B<#>I<Var>
1501
1502 This ucfirst form of #var generates a tag-value form of itself for
1503 display; it converts '#Var' into a 'Var => #var' style, which is then
1504 handled as described above.  (Imp-note: #Vars cannot be used for
1505 conditional-fills, because the => #var transform is done after the check
1506 for #Var's value).
1507
1508 =back
1509
1510 The following variables are 'defined' by B::Concise; when they are
1511 used in a style, their respective values are plugged into the
1512 rendering of each opcode.
1513
1514 Only some of these are used by the standard styles, the others are
1515 provided for you to delve into optree mechanics, should you wish to
1516 add a new style (see L</add_style> below) that uses them.  You can
1517 also add new ones using L</add_callback>.
1518
1519 =over 4
1520
1521 =item B<#addr>
1522
1523 The address of the OP, in hexadecimal.
1524
1525 =item B<#arg>
1526
1527 The OP-specific information of the OP (such as the SV for an SVOP, the
1528 non-local exit pointers for a LOOP, etc.) enclosed in parentheses.
1529
1530 =item B<#class>
1531
1532 The B-determined class of the OP, in all caps.
1533
1534 =item B<#classsym>
1535
1536 A single symbol abbreviating the class of the OP.
1537
1538 =item B<#coplabel>
1539
1540 The label of the statement or block the OP is the start of, if any.
1541
1542 =item B<#exname>
1543
1544 The name of the OP, or 'ex-foo' if the OP is a null that used to be a foo.
1545
1546 =item B<#extarg>
1547
1548 The target of the OP, or nothing for a nulled OP.
1549
1550 =item B<#firstaddr>
1551
1552 The address of the OP's first child, in hexadecimal.
1553
1554 =item B<#flags>
1555
1556 The OP's flags, abbreviated as a series of symbols.
1557
1558 =item B<#flagval>
1559
1560 The numeric value of the OP's flags.
1561
1562 =item B<#hints>
1563
1564 The COP's hint flags, rendered with abbreviated names if possible. An empty
1565 string if this is not a COP. Here are the symbols used:
1566
1567     $ strict refs
1568     & strict subs
1569     * strict vars
1570    x$ explicit use/no strict refs
1571    x& explicit use/no strict subs
1572    x* explicit use/no strict vars
1573     i integers
1574     l locale
1575     b bytes
1576     { block scope
1577     % localise %^H
1578     < open in
1579     > open out
1580     I overload int
1581     F overload float
1582     B overload binary
1583     S overload string
1584     R overload re
1585     T taint
1586     E eval
1587     X filetest access
1588     U utf-8
1589
1590 =item B<#hintsval>
1591
1592 The numeric value of the COP's hint flags, or an empty string if this is not
1593 a COP.
1594
1595 =item B<#hyphseq>
1596
1597 The sequence number of the OP, or a hyphen if it doesn't have one.
1598
1599 =item B<#label>
1600
1601 'NEXT', 'LAST', or 'REDO' if the OP is a target of one of those in exec
1602 mode, or empty otherwise.
1603
1604 =item B<#lastaddr>
1605
1606 The address of the OP's last child, in hexadecimal.
1607
1608 =item B<#name>
1609
1610 The OP's name.
1611
1612 =item B<#NAME>
1613
1614 The OP's name, in all caps.
1615
1616 =item B<#next>
1617
1618 The sequence number of the OP's next OP.
1619
1620 =item B<#nextaddr>
1621
1622 The address of the OP's next OP, in hexadecimal.
1623
1624 =item B<#noise>
1625
1626 A one- or two-character abbreviation for the OP's name.
1627
1628 =item B<#private>
1629
1630 The OP's private flags, rendered with abbreviated names if possible.
1631
1632 =item B<#privval>
1633
1634 The numeric value of the OP's private flags.
1635
1636 =item B<#seq>
1637
1638 The sequence number of the OP. Note that this is a sequence number
1639 generated by B::Concise.
1640
1641 =item B<#seqnum>
1642
1643 5.8.x and earlier only. 5.9 and later do not provide this.
1644
1645 The real sequence number of the OP, as a regular number and not adjusted
1646 to be relative to the start of the real program. (This will generally be
1647 a fairly large number because all of B<B::Concise> is compiled before
1648 your program is).
1649
1650 =item B<#opt>
1651
1652 Whether or not the op has been optimized by the peephole optimizer.
1653
1654 Only available in 5.9 and later.
1655
1656 =item B<#sibaddr>
1657
1658 The address of the OP's next youngest sibling, in hexadecimal.
1659
1660 =item B<#svaddr>
1661
1662 The address of the OP's SV, if it has an SV, in hexadecimal.
1663
1664 =item B<#svclass>
1665
1666 The class of the OP's SV, if it has one, in all caps (e.g., 'IV').
1667
1668 =item B<#svval>
1669
1670 The value of the OP's SV, if it has one, in a short human-readable format.
1671
1672 =item B<#targ>
1673
1674 The numeric value of the OP's targ.
1675
1676 =item B<#targarg>
1677
1678 The name of the variable the OP's targ refers to, if any, otherwise the
1679 letter t followed by the OP's targ in decimal.
1680
1681 =item B<#targarglife>
1682
1683 Same as B<#targarg>, but followed by the COP sequence numbers that delimit
1684 the variable's lifetime (or 'end' for a variable in an open scope) for a
1685 variable.
1686
1687 =item B<#typenum>
1688
1689 The numeric value of the OP's type, in decimal.
1690
1691 =back
1692
1693 =head1 One-Liner Command tips
1694
1695 =over 4
1696
1697 =item perl -MO=Concise,bar foo.pl
1698
1699 Renders only bar() from foo.pl.  To see main, drop the ',bar'.  To see
1700 both, add ',-main'
1701
1702 =item perl -MDigest::MD5=md5 -MO=Concise,md5 -e1
1703
1704 Identifies md5 as an XS function.  The export is needed so that BC can
1705 find it in main.
1706
1707 =item perl -MPOSIX -MO=Concise,_POSIX_ARG_MAX -e1
1708
1709 Identifies _POSIX_ARG_MAX as a constant sub, optimized to an IV.
1710 Although POSIX isn't entirely consistent across platforms, this is
1711 likely to be present in virtually all of them.
1712
1713 =item perl -MPOSIX -MO=Concise,a -e 'print _POSIX_SAVED_IDS'
1714
1715 This renders a print statement, which includes a call to the function.
1716 It's identical to rendering a file with a use call and that single
1717 statement, except for the filename which appears in the nextstate ops.
1718
1719 =item perl -MPOSIX -MO=Concise,a -e 'sub a{_POSIX_SAVED_IDS}'
1720
1721 This is B<very> similar to previous, only the first two ops differ.  This
1722 subroutine rendering is more representative, insofar as a single main
1723 program will have many subs.
1724
1725 =item perl -MB::Concise -e 'B::Concise::compile("-exec","-src", \%B::Concise::)->()'
1726
1727 This renders all functions in the B::Concise package with the source
1728 lines.  It eschews the O framework so that the stashref can be passed
1729 directly to B::Concise::compile().  See -stash option for a more
1730 convenient way to render a package.
1731
1732 =back
1733
1734 =head1 Using B::Concise outside of the O framework
1735
1736 The common (and original) usage of B::Concise was for command-line
1737 renderings of simple code, as given in EXAMPLE.  But you can also use
1738 B<B::Concise> from your code, and call compile() directly, and
1739 repeatedly.  By doing so, you can avoid the compile-time only
1740 operation of O.pm, and even use the debugger to step through
1741 B::Concise::compile() itself.
1742
1743 Once you're doing this, you may alter Concise output by adding new
1744 rendering styles, and by optionally adding callback routines which
1745 populate new variables, if such were referenced from those (just
1746 added) styles.  
1747
1748 =head2 Example: Altering Concise Renderings
1749
1750     use B::Concise qw(set_style add_callback);
1751     add_style($yourStyleName => $defaultfmt, $gotofmt, $treefmt);
1752     add_callback
1753       ( sub {
1754             my ($h, $op, $format, $level, $stylename) = @_;
1755             $h->{variable} = some_func($op);
1756         });
1757     $walker = B::Concise::compile(@options,@subnames,@subrefs);
1758     $walker->();
1759
1760 =head2 set_style()
1761
1762 B<set_style> accepts 3 arguments, and updates the three format-specs
1763 comprising a line-style (basic-exec, goto, tree).  It has one minor
1764 drawback though; it doesn't register the style under a new name.  This
1765 can become an issue if you render more than once and switch styles.
1766 Thus you may prefer to use add_style() and/or set_style_standard()
1767 instead.
1768
1769 =head2 set_style_standard($name)
1770
1771 This restores one of the standard line-styles: C<terse>, C<concise>,
1772 C<linenoise>, C<debug>, C<env>, into effect.  It also accepts style
1773 names previously defined with add_style().
1774
1775 =head2 add_style ()
1776
1777 This subroutine accepts a new style name and three style arguments as
1778 above, and creates, registers, and selects the newly named style.  It is
1779 an error to re-add a style; call set_style_standard() to switch between
1780 several styles.
1781
1782 =head2 add_callback ()
1783
1784 If your newly minted styles refer to any new #variables, you'll need
1785 to define a callback subroutine that will populate (or modify) those
1786 variables.  They are then available for use in the style you've
1787 chosen.
1788
1789 The callbacks are called for each opcode visited by Concise, in the
1790 same order as they are added.  Each subroutine is passed five
1791 parameters.
1792
1793   1. A hashref, containing the variable names and values which are
1794      populated into the report-line for the op
1795   2. the op, as a B<B::OP> object
1796   3. a reference to the format string
1797   4. the formatting (indent) level
1798   5. the selected stylename
1799
1800 To define your own variables, simply add them to the hash, or change
1801 existing values if you need to.  The level and format are passed in as
1802 references to scalars, but it is unlikely that they will need to be
1803 changed or even used.
1804
1805 =head2 Running B::Concise::compile()
1806
1807 B<compile> accepts options as described above in L</OPTIONS>, and
1808 arguments, which are either coderefs, or subroutine names.
1809
1810 It constructs and returns a $treewalker coderef, which when invoked,
1811 traverses, or walks, and renders the optrees of the given arguments to
1812 STDOUT.  You can reuse this, and can change the rendering style used
1813 each time; thereafter the coderef renders in the new style.
1814
1815 B<walk_output> lets you change the print destination from STDOUT to
1816 another open filehandle, or into a string passed as a ref (unless
1817 you've built perl with -Uuseperlio).
1818
1819   my $walker = B::Concise::compile('-terse','aFuncName', \&aSubRef); # 1
1820   walk_output(\my $buf);
1821   $walker->();                          # 1 renders -terse
1822   set_style_standard('concise');        # 2
1823   $walker->();                          # 2 renders -concise
1824   $walker->(@new);                      # 3 renders whatever
1825   print "3 different renderings: terse, concise, and @new: $buf\n";
1826
1827 When $walker is called, it traverses the subroutines supplied when it
1828 was created, and renders them using the current style.  You can change
1829 the style afterwards in several different ways:
1830
1831   1. call C<compile>, altering style or mode/order
1832   2. call C<set_style_standard>
1833   3. call $walker, passing @new options
1834
1835 Passing new options to the $walker is the easiest way to change
1836 amongst any pre-defined styles (the ones you add are automatically
1837 recognized as options), and is the only way to alter rendering order
1838 without calling compile again.  Note however that rendering state is
1839 still shared amongst multiple $walker objects, so they must still be
1840 used in a coordinated manner.
1841
1842 =head2 B::Concise::reset_sequence()
1843
1844 This function (not exported) lets you reset the sequence numbers (note
1845 that they're numbered arbitrarily, their goal being to be human
1846 readable).  Its purpose is mostly to support testing, i.e. to compare
1847 the concise output from two identical anonymous subroutines (but
1848 different instances).  Without the reset, B::Concise, seeing that
1849 they're separate optrees, generates different sequence numbers in
1850 the output.
1851
1852 =head2 Errors
1853
1854 Errors in rendering (non-existent function-name, non-existent coderef)
1855 are written to the STDOUT, or wherever you've set it via
1856 walk_output().
1857
1858 Errors using the various *style* calls, and bad args to walk_output(),
1859 result in die().  Use an eval if you wish to catch these errors and
1860 continue processing.
1861
1862 =head1 AUTHOR
1863
1864 Stephen McCamant, E<lt>smcc@CSUA.Berkeley.EDUE<gt>.
1865
1866 =cut