This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
957c22acfb1fb5d410a3867e84837f8ee4cd31b7
[perl5.git] / ext / Sys / Syslog / Syslog.pm
1 package Sys::Syslog;
2 use strict;
3 use warnings::register;
4 use Carp;
5 use Fcntl qw(O_WRONLY);
6 use File::Basename;
7 use POSIX qw(strftime setlocale LC_TIME);
8 use Socket ':all';
9 require 5.006;
10 require Exporter;
11
12 {   no strict 'vars';
13     $VERSION = '0.19_01';
14     @ISA = qw(Exporter);
15
16     %EXPORT_TAGS = (
17         standard => [qw(openlog syslog closelog setlogmask)],
18         extended => [qw(setlogsock)],
19         macros => [
20             # levels
21             qw(
22                 LOG_ALERT LOG_CRIT LOG_DEBUG LOG_EMERG LOG_ERR 
23                 LOG_INFO LOG_NOTICE LOG_WARNING
24             ), 
25
26             # standard facilities
27             qw(
28                 LOG_AUTH LOG_AUTHPRIV LOG_CRON LOG_DAEMON LOG_FTP LOG_KERN
29                 LOG_LOCAL0 LOG_LOCAL1 LOG_LOCAL2 LOG_LOCAL3 LOG_LOCAL4
30                 LOG_LOCAL5 LOG_LOCAL6 LOG_LOCAL7 LOG_LPR LOG_MAIL LOG_NEWS
31                 LOG_SYSLOG LOG_USER LOG_UUCP
32             ),
33             # Mac OS X specific facilities
34             qw( LOG_INSTALL LOG_LAUNCHD LOG_NETINFO LOG_RAS LOG_REMOTEAUTH ),
35             # modern BSD specific facilities
36             qw( LOG_CONSOLE LOG_NTP LOG_SECURITY ),
37             # IRIX specific facilities
38             qw( LOG_AUDIT LOG_LFMT ),
39
40             # options
41             qw(
42                 LOG_CONS LOG_PID LOG_NDELAY LOG_NOWAIT LOG_ODELAY LOG_PERROR 
43             ), 
44
45             # others macros
46             qw(
47                 LOG_FACMASK LOG_NFACILITIES LOG_PRIMASK 
48                 LOG_MASK LOG_UPTO
49             ), 
50         ],
51     );
52
53     @EXPORT = (
54         @{$EXPORT_TAGS{standard}}, 
55     );
56
57     @EXPORT_OK = (
58         @{$EXPORT_TAGS{extended}}, 
59         @{$EXPORT_TAGS{macros}}, 
60     );
61
62     eval {
63         require XSLoader;
64         XSLoader::load('Sys::Syslog', $VERSION);
65         1
66     } or do {
67         require DynaLoader;
68         push @ISA, 'DynaLoader';
69         bootstrap Sys::Syslog $VERSION;
70     };
71 }
72
73
74
75 # Public variables
76
77 use vars qw($host);             # host to send syslog messages to (see notes at end)
78
79
80 # Global variables
81
82 use vars qw($facility);
83 my $connected = 0;              # flag to indicate if we're connected or not
84 my $syslog_send;                # coderef of the function used to send messages
85 my $syslog_path = undef;        # syslog path for "stream" and "unix" mechanisms
86 my $syslog_xobj = undef;        # if defined, holds the external object used to send messages
87 my $transmit_ok = 0;            # flag to indicate if the last message was transmited
88 my $current_proto = undef;      # current mechanism used to transmit messages
89 my $ident = '';                 # identifiant prepended to each message
90 $facility = '';                 # current facility
91 my $maskpri = LOG_UPTO(&LOG_DEBUG);     # current log mask
92
93 my %options = (
94     ndelay  => 0, 
95     nofatal => 0, 
96     nowait  => 0, 
97     pid     => 0, 
98 );
99
100 # Default is now to first use the native mechanism, so Perl programs 
101 # behave like other normal C programs, then try other mechanisms.
102 my @connectMethods = qw(native tcp udp unix stream console);
103 if ($^O =~ /^(freebsd|linux)$/) {
104     @connectMethods = grep { $_ ne 'udp' } @connectMethods;
105 }
106
107 # use EventLog on Win32
108 my $is_Win32 = $^O =~ /Win32/i;
109 eval "use Sys::Syslog::Win32";
110
111 if (not $@) {
112     unshift @connectMethods, 'eventlog';
113 } elsif ($is_Win32) {
114     warn $@;
115 }
116
117 my @defaultMethods = @connectMethods;
118 my @fallbackMethods = ();
119
120 # coderef for a nicer handling of errors
121 my $err_sub = $options{nofatal} ? \&warnings::warnif : \&croak;
122
123
124 sub AUTOLOAD {
125     # This AUTOLOAD is used to 'autoload' constants from the constant()
126     # XS function.
127     no strict 'vars';
128     my $constname;
129     ($constname = $AUTOLOAD) =~ s/.*:://;
130     croak "Sys::Syslog::constant() not defined" if $constname eq 'constant';
131     my ($error, $val) = constant($constname);
132     croak $error if $error;
133     no strict 'refs';
134     *$AUTOLOAD = sub { $val };
135     goto &$AUTOLOAD;
136 }
137
138
139 sub openlog {
140     ($ident, my $logopt, $facility) = @_;
141
142     # default values
143     $ident    ||= basename($0) || getlogin() || getpwuid($<) || 'syslog';
144     $logopt   ||= '';
145     $facility ||= LOG_USER();
146
147     for my $opt (split /\b/, $logopt) {
148         $options{$opt} = 1 if exists $options{$opt}
149     }
150
151     $err_sub = $options{nofatal} ? \&warnings::warnif : \&croak;
152     return 1 unless $options{ndelay};
153     connect_log();
154
155
156 sub closelog {
157     $facility = $ident = '';
158     disconnect_log();
159
160
161 sub setlogmask {
162     my $oldmask = $maskpri;
163     $maskpri = shift unless $_[0] == 0;
164     $oldmask;
165 }
166  
167 sub setlogsock {
168     my $setsock = shift;
169     $syslog_path = shift;
170     disconnect_log() if $connected;
171     $transmit_ok = 0;
172     @fallbackMethods = ();
173     @connectMethods = @defaultMethods;
174
175     if (ref $setsock eq 'ARRAY') {
176         @connectMethods = @$setsock;
177
178     } elsif (lc $setsock eq 'stream') {
179         if (not defined $syslog_path) {
180             my @try = qw(/dev/log /dev/conslog);
181
182             if (length &_PATH_LOG) {        # Undefined _PATH_LOG is "".
183                 unshift @try, &_PATH_LOG;
184             }
185
186             for my $try (@try) {
187                 if (-w $try) {
188                     $syslog_path = $try;
189                     last;
190                 }
191             }
192
193             if (not defined $syslog_path) {
194                 warnings::warnif "stream passed to setlogsock, but could not find any device";
195                 return undef
196             }
197         }
198
199         if (not -w $syslog_path) {
200             warnings::warnif "stream passed to setlogsock, but $syslog_path is not writable";
201             return undef;
202         } else {
203             @connectMethods = qw(stream);
204         }
205
206     } elsif (lc $setsock eq 'unix') {
207         if (length _PATH_LOG() || (defined $syslog_path && -w $syslog_path)) {
208             $syslog_path = _PATH_LOG() unless defined $syslog_path;
209             @connectMethods = qw(unix);
210         } else {
211             warnings::warnif 'unix passed to setlogsock, but path not available';
212             return undef;
213         }
214
215     } elsif (lc $setsock eq 'native') {
216         @connectMethods = qw(native);
217
218     } elsif (lc $setsock eq 'eventlog') {
219         if (eval "use Win32::EventLog; 1") {
220             @connectMethods = qw(eventlog);
221         } else {
222             warnings::warnif "eventlog passed to setlogsock, but operating system isn't Win32-compatible"
223         }
224
225     } elsif (lc $setsock eq 'tcp') {
226         if (getservbyname('syslog', 'tcp') || getservbyname('syslogng', 'tcp')) {
227             @connectMethods = qw(tcp);
228         } else {
229             warnings::warnif "tcp passed to setlogsock, but tcp service unavailable";
230             return undef;
231         }
232
233     } elsif (lc $setsock eq 'udp') {
234         if (getservbyname('syslog', 'udp')) {
235             @connectMethods = qw(udp);
236         } else {
237             warnings::warnif "udp passed to setlogsock, but udp service unavailable";
238             return undef;
239         }
240
241     } elsif (lc $setsock eq 'inet') {
242         @connectMethods = ( 'tcp', 'udp' );
243
244     } elsif (lc $setsock eq 'console') {
245         @connectMethods = qw(console);
246
247     } else {
248         croak "Invalid argument passed to setlogsock; must be 'stream', 'unix', 'native', 'eventlog', 'tcp', 'udp' or 'inet'"
249     }
250
251     return 1;
252 }
253
254 sub syslog {
255     my $priority = shift;
256     my $mask = shift;
257     my ($message, $buf);
258     my (@words, $num, $numpri, $numfac, $sum);
259     my $failed = undef;
260     my $fail_time = undef;
261     my $error = $!;
262
263     # if $ident is undefined, it means openlog() wasn't previously called
264     # so do it now in order to have sensible defaults
265     openlog() unless $ident;
266
267     local $facility = $facility;    # may need to change temporarily.
268
269     croak "syslog: expecting argument \$priority" unless defined $priority;
270     croak "syslog: expecting argument \$format"   unless defined $mask;
271
272     @words = split(/\W+/, $priority, 2);    # Allow "level" or "level|facility".
273     undef $numpri;
274     undef $numfac;
275
276     foreach (@words) {
277         $num = xlate($_);                   # Translate word to number.
278         if ($num < 0) {
279             croak "syslog: invalid level/facility: $_"
280         }
281         elsif ($num <= &LOG_PRIMASK) {
282             croak "syslog: too many levels given: $_" if defined $numpri;
283             $numpri = $num;
284             return 0 unless LOG_MASK($numpri) & $maskpri;
285         }
286         else {
287             croak "syslog: too many facilities given: $_" if defined $numfac;
288             $facility = $_;
289             $numfac = $num;
290         }
291     }
292
293     croak "syslog: level must be given" unless defined $numpri;
294
295     if (not defined $numfac) {  # Facility not specified in this call.
296         $facility = 'user' unless $facility;
297         $numfac = xlate($facility);
298     }
299
300     connect_log() unless $connected;
301
302     if ($mask =~ /%m/) {
303         # escape percent signs for sprintf()
304         $error =~ s/%/%%/g if @_;
305         # replace %m with $error, if preceded by an even number of percent signs
306         $mask =~ s/(?<!%)((?:%%)*)%m/$1$error/g;
307     }
308
309     $mask .= "\n" unless $mask =~ /\n$/;
310     $message = @_ ? sprintf($mask, @_) : $mask;
311
312     if($current_proto eq 'native') {
313         $buf = $message;
314
315     }
316     elsif ($current_proto eq 'eventlog') {
317         $buf = $message;
318     }
319     else {
320         my $whoami = $ident;
321         $whoami .= "[$$]" if $options{pid};
322
323         $sum = $numpri + $numfac;
324         my $oldlocale = setlocale(LC_TIME);
325         setlocale(LC_TIME, 'C');
326         my $timestamp = strftime "%b %e %T", localtime;
327         setlocale(LC_TIME, $oldlocale);
328         $buf = "<$sum>$timestamp $whoami: $message\0";
329     }
330
331     # it's possible that we'll get an error from sending
332     # (e.g. if method is UDP and there is no UDP listener,
333     # then we'll get ECONNREFUSED on the send). So what we
334     # want to do at this point is to fallback onto a different
335     # connection method.
336     while (scalar @fallbackMethods || $syslog_send) {
337         if ($failed && (time - $fail_time) > 60) {
338             # it's been a while... maybe things have been fixed
339             @fallbackMethods = ();
340             disconnect_log();
341             $transmit_ok = 0; # make it look like a fresh attempt
342             connect_log();
343         }
344
345         if ($connected && !connection_ok()) {
346             # Something was OK, but has now broken. Remember coz we'll
347             # want to go back to what used to be OK.
348             $failed = $current_proto unless $failed;
349             $fail_time = time;
350             disconnect_log();
351         }
352
353         connect_log() unless $connected;
354         $failed = undef if ($current_proto && $failed && $current_proto eq $failed);
355
356         if ($syslog_send) {
357             if ($syslog_send->($buf, $numpri, $numfac)) {
358                 $transmit_ok++;
359                 return 1;
360             }
361             # typically doesn't happen, since errors are rare from write().
362             disconnect_log();
363         }
364     }
365     # could not send, could not fallback onto a working
366     # connection method. Lose.
367     return 0;
368 }
369
370 sub _syslog_send_console {
371     my ($buf) = @_;
372     chop($buf); # delete the NUL from the end
373     # The console print is a method which could block
374     # so we do it in a child process and always return success
375     # to the caller.
376     if (my $pid = fork) {
377
378         if ($options{nowait}) {
379             return 1;
380         } else {
381             if (waitpid($pid, 0) >= 0) {
382                 return ($? >> 8);
383             } else {
384                 # it's possible that the caller has other
385                 # plans for SIGCHLD, so let's not interfere
386                 return 1;
387             }
388         }
389     } else {
390         if (open(CONS, ">/dev/console")) {
391             my $ret = print CONS $buf . "\r";  # XXX: should this be \x0A ?
392             exit $ret if defined $pid;
393             close CONS;
394         }
395         exit if defined $pid;
396     }
397 }
398
399 sub _syslog_send_stream {
400     my ($buf) = @_;
401     # XXX: this only works if the OS stream implementation makes a write 
402     # look like a putmsg() with simple header. For instance it works on 
403     # Solaris 8 but not Solaris 7.
404     # To be correct, it should use a STREAMS API, but perl doesn't have one.
405     return syswrite(SYSLOG, $buf, length($buf));
406 }
407
408 sub _syslog_send_socket {
409     my ($buf) = @_;
410     return syswrite(SYSLOG, $buf, length($buf));
411     #return send(SYSLOG, $buf, 0);
412 }
413
414 sub _syslog_send_native {
415     my ($buf, $numpri) = @_;
416     syslog_xs($numpri, $buf);
417     return 1;
418 }
419
420
421 # xlate()
422 # -----
423 # private function to translate names to numeric values
424
425 sub xlate {
426     my($name) = @_;
427     return $name+0 if $name =~ /^\s*\d+\s*$/;
428     $name = uc $name;
429     $name = "LOG_$name" unless $name =~ /^LOG_/;
430     $name = "Sys::Syslog::$name";
431     # Can't have just eval { &$name } || -1 because some LOG_XXX may be zero.
432     my $value = eval { no strict 'refs'; &$name };
433     defined $value ? $value : -1;
434 }
435
436
437 # connect_log()
438 # -----------
439 # This function acts as a kind of front-end: it tries to connect to 
440 # a syslog service using the selected methods, trying each one in the 
441 # selected order. 
442
443 sub connect_log {
444     @fallbackMethods = @connectMethods unless scalar @fallbackMethods;
445
446     if ($transmit_ok && $current_proto) {
447         # Retry what we were on, because it has worked in the past.
448         unshift(@fallbackMethods, $current_proto);
449     }
450
451     $connected = 0;
452     my @errs = ();
453     my $proto = undef;
454
455     while ($proto = shift @fallbackMethods) {
456         no strict 'refs';
457         my $fn = "connect_$proto";
458         $connected = &$fn(\@errs) if defined &$fn;
459         last if $connected;
460     }
461
462     $transmit_ok = 0;
463     if ($connected) {
464         $current_proto = $proto;
465         my ($old) = select(SYSLOG); $| = 1; select($old);
466     } else {
467         @fallbackMethods = ();
468         $err_sub->(join "\n\t- ", "no connection to syslog available", @errs);
469         return undef;
470     }
471 }
472
473 sub connect_tcp {
474     my ($errs) = @_;
475
476     my $tcp = getprotobyname('tcp');
477     if (!defined $tcp) {
478         push @$errs, "getprotobyname failed for tcp";
479         return 0;
480     }
481
482     my $syslog = getservbyname('syslog', 'tcp');
483     $syslog = getservbyname('syslogng', 'tcp') unless defined $syslog;
484     if (!defined $syslog) {
485         push @$errs, "getservbyname failed for syslog/tcp and syslogng/tcp";
486         return 0;
487     }
488
489     my $addr;
490     if (defined $host) {
491         $addr = inet_aton($host);
492         if (!$addr) {
493             push @$errs, "can't lookup $host";
494             return 0;
495         }
496     } else {
497         $addr = INADDR_LOOPBACK;
498     }
499     $addr = sockaddr_in($syslog, $addr);
500
501     if (!socket(SYSLOG, AF_INET, SOCK_STREAM, $tcp)) {
502         push @$errs, "tcp socket: $!";
503         return 0;
504     }
505
506     setsockopt(SYSLOG, SOL_SOCKET, SO_KEEPALIVE, 1);
507     setsockopt(SYSLOG, IPPROTO_TCP, TCP_NODELAY, 1);
508     if (!connect(SYSLOG, $addr)) {
509         push @$errs, "tcp connect: $!";
510         return 0;
511     }
512
513     $syslog_send = \&_syslog_send_socket;
514
515     return 1;
516 }
517
518 sub connect_udp {
519     my ($errs) = @_;
520
521     my $udp = getprotobyname('udp');
522     if (!defined $udp) {
523         push @$errs, "getprotobyname failed for udp";
524         return 0;
525     }
526
527     my $syslog = getservbyname('syslog', 'udp');
528     if (!defined $syslog) {
529         push @$errs, "getservbyname failed for syslog/udp";
530         return 0;
531     }
532
533     my $addr;
534     if (defined $host) {
535         $addr = inet_aton($host);
536         if (!$addr) {
537             push @$errs, "can't lookup $host";
538             return 0;
539         }
540     } else {
541         $addr = INADDR_LOOPBACK;
542     }
543     $addr = sockaddr_in($syslog, $addr);
544
545     if (!socket(SYSLOG, AF_INET, SOCK_DGRAM, $udp)) {
546         push @$errs, "udp socket: $!";
547         return 0;
548     }
549     if (!connect(SYSLOG, $addr)) {
550         push @$errs, "udp connect: $!";
551         return 0;
552     }
553
554     # We want to check that the UDP connect worked. However the only
555     # way to do that is to send a message and see if an ICMP is returned
556     _syslog_send_socket("");
557     if (!connection_ok()) {
558         push @$errs, "udp connect: nobody listening";
559         return 0;
560     }
561
562     $syslog_send = \&_syslog_send_socket;
563
564     return 1;
565 }
566
567 sub connect_stream {
568     my ($errs) = @_;
569     # might want syslog_path to be variable based on syslog.h (if only
570     # it were in there!)
571     $syslog_path = '/dev/conslog' unless defined $syslog_path; 
572     if (!-w $syslog_path) {
573         push @$errs, "stream $syslog_path is not writable";
574         return 0;
575     }
576     if (!sysopen(SYSLOG, $syslog_path, 0400, O_WRONLY)) {
577         push @$errs, "stream can't open $syslog_path: $!";
578         return 0;
579     }
580     $syslog_send = \&_syslog_send_stream;
581     return 1;
582 }
583
584 sub connect_unix {
585     my ($errs) = @_;
586
587     $syslog_path ||= _PATH_LOG() if length _PATH_LOG();
588
589     if (not defined $syslog_path) {
590         push @$errs, "_PATH_LOG not available in syslog.h and no user-supplied socket path";
591         return 0;
592     }
593
594     if (! -S $syslog_path) {
595         push @$errs, "$syslog_path is not a socket";
596         return 0;
597     }
598
599     my $addr = sockaddr_un($syslog_path);
600     if (!$addr) {
601         push @$errs, "can't locate $syslog_path";
602         return 0;
603     }
604     if (!socket(SYSLOG, AF_UNIX, SOCK_STREAM, 0)) {
605         push @$errs, "unix stream socket: $!";
606         return 0;
607     }
608
609     if (!connect(SYSLOG, $addr)) {
610         if (!socket(SYSLOG, AF_UNIX, SOCK_DGRAM, 0)) {
611             push @$errs, "unix dgram socket: $!";
612             return 0;
613         }
614         if (!connect(SYSLOG, $addr)) {
615             push @$errs, "unix dgram connect: $!";
616             return 0;
617         }
618     }
619
620     $syslog_send = \&_syslog_send_socket;
621
622     return 1;
623 }
624
625 sub connect_native {
626     my ($errs) = @_;
627     my $logopt = 0;
628
629     # reconstruct the numeric equivalent of the options
630     for my $opt (keys %options) {
631         $logopt += xlate($opt) if $options{$opt}
632     }
633
634     eval { openlog_xs($ident, $logopt, xlate($facility)) };
635     if ($@) {
636         push @$errs, $@;
637         return 0;
638     }
639
640     $syslog_send = \&_syslog_send_native;
641
642     return 1;
643 }
644
645 sub connect_eventlog {
646     my ($errs) = @_;
647
648     $syslog_xobj = Sys::Syslog::Win32::_install();
649     $syslog_send = \&Sys::Syslog::Win32::_syslog_send;
650
651     return 1;
652 }
653
654 sub connect_console {
655     my ($errs) = @_;
656     if (!-w '/dev/console') {
657         push @$errs, "console is not writable";
658         return 0;
659     }
660     $syslog_send = \&_syslog_send_console;
661     return 1;
662 }
663
664 # To test if the connection is still good, we need to check if any
665 # errors are present on the connection. The errors will not be raised
666 # by a write. Instead, sockets are made readable and the next read
667 # would cause the error to be returned. Unfortunately the syslog 
668 # 'protocol' never provides anything for us to read. But with 
669 # judicious use of select(), we can see if it would be readable...
670 sub connection_ok {
671     return 1 if defined $current_proto and (
672         $current_proto eq 'native' or $current_proto eq 'console'
673         or $current_proto eq 'eventlog'
674     );
675
676     my $rin = '';
677     vec($rin, fileno(SYSLOG), 1) = 1;
678     my $ret = select $rin, undef, $rin, 0.25;
679     return ($ret ? 0 : 1);
680 }
681
682 sub disconnect_log {
683     $connected = 0;
684     $syslog_send = undef;
685
686     if (defined $current_proto and $current_proto eq 'native') {
687         closelog_xs();
688         return 1;
689     }
690     elsif (defined $current_proto and $current_proto eq 'eventlog') {
691         $syslog_xobj->Close();
692         return 1;
693     }
694
695     return close SYSLOG;
696 }
697
698 1;
699
700 __END__
701
702 =head1 NAME
703
704 Sys::Syslog - Perl interface to the UNIX syslog(3) calls
705
706 =head1 VERSION
707
708 Version 0.19
709
710 =head1 SYNOPSIS
711
712     use Sys::Syslog;                          # all except setlogsock(), or:
713     use Sys::Syslog qw(:DEFAULT setlogsock);  # default set, plus setlogsock()
714     use Sys::Syslog qw(:standard :macros);    # standard functions, plus macros
715
716     openlog $ident, $logopt, $facility;       # don't forget this
717     syslog $priority, $format, @args;
718     $oldmask = setlogmask $mask_priority;
719     closelog;
720
721
722 =head1 DESCRIPTION
723
724 C<Sys::Syslog> is an interface to the UNIX C<syslog(3)> program.
725 Call C<syslog()> with a string priority and a list of C<printf()> args
726 just like C<syslog(3)>.
727
728 You can find a kind of FAQ in L<"THE RULES OF SYS::SYSLOG">.  Please read 
729 it before coding, and again before asking questions. 
730
731
732 =head1 EXPORTS
733
734 C<Sys::Syslog> exports the following C<Exporter> tags: 
735
736 =over 4
737
738 =item *
739
740 C<:standard> exports the standard C<syslog(3)> functions: 
741
742     openlog closelog setlogmask syslog
743
744 =item *
745
746 C<:extended> exports the Perl specific functions for C<syslog(3)>: 
747
748     setlogsock
749
750 =item *
751
752 C<:macros> exports the symbols corresponding to most of your C<syslog(3)> 
753 macros and the C<LOG_UPTO()> and C<LOG_MASK()> functions. 
754 See L<"CONSTANTS"> for the supported constants and their meaning. 
755
756 =back
757
758 By default, C<Sys::Syslog> exports the symbols from the C<:standard> tag. 
759
760
761 =head1 FUNCTIONS
762
763 =over 4
764
765 =item B<openlog($ident, $logopt, $facility)>
766
767 Opens the syslog.
768 C<$ident> is prepended to every message.  C<$logopt> contains zero or
769 more of the options detailed below.  C<$facility> specifies the part 
770 of the system to report about, for example C<LOG_USER> or C<LOG_LOCAL0>:
771 see L<"Facilities"> for a list of well-known facilities, and your 
772 C<syslog(3)> documentation for the facilities available in your system. 
773 Check L<"SEE ALSO"> for useful links. Facility can be given as a string 
774 or a numeric macro. 
775
776 This function will croak if it can't connect to the syslog daemon.
777
778 Note that C<openlog()> now takes three arguments, just like C<openlog(3)>.
779
780 B<You should use C<openlog()> before calling C<syslog()>.>
781
782 B<Options>
783
784 =over 4
785
786 =item *
787
788 C<cons> - This option is ignored, since the failover mechanism will drop 
789 down to the console automatically if all other media fail.
790
791 =item *
792
793 C<ndelay> - Open the connection immediately (normally, the connection is
794 opened when the first message is logged).
795
796 =item *
797
798 C<nofatal> - When set to true, C<openlog()> and C<syslog()> will only 
799 emit warnings instead of dying if the connection to the syslog can't 
800 be established. 
801
802 =item *
803
804 C<nowait> - Don't wait for child processes that may have been created 
805 while logging the message.  (The GNU C library does not create a child
806 process, so this option has no effect on Linux.)
807
808 =item *
809
810 C<pid> - Include PID with each message.
811
812 =back
813
814 B<Examples>
815
816 Open the syslog with options C<ndelay> and C<pid>, and with facility C<LOCAL0>: 
817
818     openlog($name, "ndelay,pid", "local0");
819
820 Same thing, but this time using the macro corresponding to C<LOCAL0>: 
821
822     openlog($name, "ndelay,pid", LOG_LOCAL0);
823
824
825 =item B<syslog($priority, $message)>
826
827 =item B<syslog($priority, $format, @args)>
828
829 If C<$priority> permits, logs C<$message> or C<sprintf($format, @args)>
830 with the addition that C<%m> in $message or C<$format> is replaced with
831 C<"$!"> (the latest error message). 
832
833 C<$priority> can specify a level, or a level and a facility.  Levels and 
834 facilities can be given as strings or as macros.  When using the C<eventlog>
835 mechanism, priorities C<DEBUG> and C<INFO> are mapped to event type 
836 C<informational>, C<NOTICE> and C<WARNIN> to C<warning> and C<ERR> to 
837 C<EMERG> to C<error>.
838
839 If you didn't use C<openlog()> before using C<syslog()>, C<syslog()> will 
840 try to guess the C<$ident> by extracting the shortest prefix of 
841 C<$format> that ends in a C<":">.
842
843 B<Examples>
844
845     syslog("info", $message);           # informational level
846     syslog(LOG_INFO, $message);         # informational level
847
848     syslog("info|local0", $message);        # information level, Local0 facility
849     syslog(LOG_INFO|LOG_LOCAL0, $message);  # information level, Local0 facility
850
851 =over 4
852
853 =item B<Note>
854
855 C<Sys::Syslog> version v0.07 and older passed the C<$message> as the 
856 formatting string to C<sprintf()> even when no formatting arguments
857 were provided.  If the code calling C<syslog()> might execute with 
858 older versions of this module, make sure to call the function as
859 C<syslog($priority, "%s", $message)> instead of C<syslog($priority,
860 $message)>.  This protects against hostile formatting sequences that
861 might show up if $message contains tainted data.
862
863 =back
864
865
866 =item B<setlogmask($mask_priority)>
867
868 Sets the log mask for the current process to C<$mask_priority> and 
869 returns the old mask.  If the mask argument is 0, the current log mask 
870 is not modified.  See L<"Levels"> for the list of available levels. 
871 You can use the C<LOG_UPTO()> function to allow all levels up to a 
872 given priority (but it only accept the numeric macros as arguments).
873
874 B<Examples>
875
876 Only log errors: 
877
878     setlogmask( LOG_MASK(LOG_ERR) );
879
880 Log everything except informational messages: 
881
882     setlogmask( ~(LOG_MASK(LOG_INFO)) );
883
884 Log critical messages, errors and warnings: 
885
886     setlogmask( LOG_MASK(LOG_CRIT) | LOG_MASK(LOG_ERR) | LOG_MASK(LOG_WARNING) );
887
888 Log all messages up to debug: 
889
890     setlogmask( LOG_UPTO(LOG_DEBUG) );
891
892
893 =item B<setlogsock($sock_type)>
894
895 =item B<setlogsock($sock_type, $stream_location)> (added in Perl 5.004_02)
896
897 Sets the socket type to be used for the next call to
898 C<openlog()> or C<syslog()> and returns true on success,
899 C<undef> on failure. The available mechanisms are: 
900
901 =over
902
903 =item *
904
905 C<"native"> - use the native C functions from your C<syslog(3)> library
906 (added in C<Sys::Syslog> 0.15).
907
908 =item *
909
910 C<"tcp"> - connect to a TCP socket, on the C<syslog/tcp> or C<syslogng/tcp> 
911 service. 
912
913 =item *
914
915 C<"udp"> - connect to a UDP socket, on the C<syslog/udp> service.
916
917 =item *
918
919 C<"inet"> - connect to an INET socket, either TCP or UDP, tried in that order. 
920
921 =item *
922
923 C<"unix"> - connect to a UNIX domain socket (in some systems a character 
924 special device).  The name of that socket is the second parameter or, if 
925 you omit the second parameter, the value returned by the C<_PATH_LOG> macro 
926 (if your system defines it), or F</dev/log> or F</dev/conslog>, whatever is 
927 writable.  
928
929 =item *
930
931 C<"stream"> - connect to the stream indicated by the pathname provided as 
932 the optional second parameter, or, if omitted, to F</dev/conslog>. 
933 For example Solaris and IRIX system may prefer C<"stream"> instead of C<"unix">. 
934
935 =item *
936
937 C<"console"> - send messages directly to the console, as for the C<"cons"> 
938 option of C<openlog()>.
939
940 =item *
941
942 C<"eventlog"> - send messages to the Win32 events logger (Win32 only; 
943 added in C<Sys::Syslog> 0.19).
944
945 =back
946
947 A reference to an array can also be passed as the first parameter.
948 When this calling method is used, the array should contain a list of
949 mechanisms which are attempted in order.
950
951 The default is to try C<native>, C<tcp>, C<udp>, C<unix>, C<stream>, C<console>.
952
953 Giving an invalid value for C<$sock_type> will C<croak>.
954
955 B<Examples>
956
957 Select the UDP socket mechanism: 
958
959     setlogsock("udp");
960
961 Select the native, UDP socket then UNIX domain socket mechanisms: 
962
963     setlogsock(["native", "udp", "unix"]);
964
965 =over
966
967 =item B<Note>
968
969 Now that the "native" mechanism is supported by C<Sys::Syslog> and selected 
970 by default, the use of the C<setlogsock()> function is discouraged because 
971 other mechanisms are less portable across operating systems.  Authors of 
972 modules and programs that use this function, especially its cargo-cult form 
973 C<setlogsock("unix")>, are advised to remove any occurence of it unless they 
974 specifically want to use a given mechanism (like TCP or UDP to connect to 
975 a remote host).
976
977 =back
978
979 =item B<closelog()>
980
981 Closes the log file and returns true on success.
982
983 =back
984
985
986 =head1 THE RULES OF SYS::SYSLOG
987
988 I<The First Rule of Sys::Syslog is:>
989 You do not call C<setlogsock>.
990
991 I<The Second Rule of Sys::Syslog is:>
992 You B<do not> call C<setlogsock>.
993
994 I<The Third Rule of Sys::Syslog is:>
995 The program crashes, C<die>s, calls C<closelog>, the log is over.
996
997 I<The Fourth Rule of Sys::Syslog is:>
998 One facility, one priority.
999
1000 I<The Fifth Rule of Sys::Syslog is:>
1001 One log at a time.
1002
1003 I<The Sixth Rule of Sys::Syslog is:>
1004 No C<syslog> before C<openlog>.
1005
1006 I<The Seventh Rule of Sys::Syslog is:>
1007 Logs will go on as long as they have to. 
1008
1009 I<The Eighth, and Final Rule of Sys::Syslog is:>
1010 If this is your first use of Sys::Syslog, you must read the doc.
1011
1012
1013 =head1 EXAMPLES
1014
1015 An example:
1016
1017     openlog($program, 'cons,pid', 'user');
1018     syslog('info', '%s', 'this is another test');
1019     syslog('mail|warning', 'this is a better test: %d', time);
1020     closelog();
1021
1022     syslog('debug', 'this is the last test');
1023
1024 Another example:
1025
1026     openlog("$program $$", 'ndelay', 'user');
1027     syslog('notice', 'fooprogram: this is really done');
1028
1029 Example of use of C<%m>:
1030
1031     $! = 55;
1032     syslog('info', 'problem was %m');   # %m == $! in syslog(3)
1033
1034 Log to UDP port on C<$remotehost> instead of logging locally:
1035
1036     setlogsock('udp');
1037     $Sys::Syslog::host = $remotehost;
1038     openlog($program, 'ndelay', 'user');
1039     syslog('info', 'something happened over here');
1040
1041
1042 =head1 CONSTANTS
1043
1044 =head2 Facilities
1045
1046 =over 4
1047
1048 =item *
1049
1050 C<LOG_AUDIT> - audit daemon (IRIX); falls back to C<LOG_AUTH>
1051
1052 =item *
1053
1054 C<LOG_AUTH> - security/authorization messages
1055
1056 =item *
1057
1058 C<LOG_AUTHPRIV> - security/authorization messages (private)
1059
1060 =item *
1061
1062 C<LOG_CONSOLE> - C</dev/console> output (FreeBSD); falls back to C<LOG_USER>
1063
1064 =item *
1065
1066 C<LOG_CRON> - clock daemons (B<cron> and B<at>)
1067
1068 =item *
1069
1070 C<LOG_DAEMON> - system daemons without separate facility value
1071
1072 =item *
1073
1074 C<LOG_FTP> - FTP daemon
1075
1076 =item *
1077
1078 C<LOG_KERN> - kernel messages
1079
1080 =item *
1081
1082 C<LOG_INSTALL> - installer subsystem (Mac OS X); falls back to C<LOG_USER>
1083
1084 =item *
1085
1086 C<LOG_LAUNCHD> - launchd - general bootstrap daemon (Mac OS X);
1087 falls back to C<LOG_DAEMON>
1088
1089 =item *
1090
1091 C<LOG_LFMT> - logalert facility; falls back to C<LOG_USER>
1092
1093 =item *
1094
1095 C<LOG_LOCAL0> through C<LOG_LOCAL7> - reserved for local use
1096
1097 =item *
1098
1099 C<LOG_LPR> - line printer subsystem
1100
1101 =item *
1102
1103 C<LOG_MAIL> - mail subsystem
1104
1105 =item *
1106
1107 C<LOG_NETINFO> - NetInfo subsystem (Mac OS X); falls back to C<LOG_DAEMON>
1108
1109 =item *
1110
1111 C<LOG_NEWS> - USENET news subsystem
1112
1113 =item *
1114
1115 C<LOG_NTP> - NTP subsystem (FreeBSD, NetBSD); falls back to C<LOG_DAEMON>
1116
1117 =item *
1118
1119 C<LOG_RAS> - Remote Access Service (VPN / PPP) (Mac OS X);
1120 falls back to C<LOG_AUTH>
1121
1122 =item *
1123
1124 C<LOG_REMOTEAUTH> - remote authentication/authorization (Mac OS X);
1125 falls back to C<LOG_AUTH>
1126
1127 =item *
1128
1129 C<LOG_SECURITY> - security subsystems (firewalling, etc.) (FreeBSD);
1130 falls back to C<LOG_AUTH>
1131
1132 =item *
1133
1134 C<LOG_SYSLOG> - messages generated internally by B<syslogd>
1135
1136 =item *
1137
1138 C<LOG_USER> (default) - generic user-level messages
1139
1140 =item *
1141
1142 C<LOG_UUCP> - UUCP subsystem
1143
1144 =back
1145
1146
1147 =head2 Levels
1148
1149 =over 4
1150
1151 =item *
1152
1153 C<LOG_EMERG> - system is unusable
1154
1155 =item *
1156
1157 C<LOG_ALERT> - action must be taken immediately
1158
1159 =item *
1160
1161 C<LOG_CRIT> - critical conditions
1162
1163 =item *
1164
1165 C<LOG_ERR> - error conditions
1166
1167 =item *
1168
1169 C<LOG_WARNING> - warning conditions
1170
1171 =item *
1172
1173 C<LOG_NOTICE> - normal, but significant, condition
1174
1175 =item *
1176
1177 C<LOG_INFO> - informational message
1178
1179 =item *
1180
1181 C<LOG_DEBUG> - debug-level message
1182
1183 =back
1184
1185
1186 =head1 DIAGNOSTICS
1187
1188 =over
1189
1190 =item C<Invalid argument passed to setlogsock>
1191
1192 B<(F)> You gave C<setlogsock()> an invalid value for C<$sock_type>. 
1193
1194 =item C<eventlog passed to setlogsock, but operating system isn't Win32-compatible>
1195
1196 B<(W)> You asked C<setlogsock()> to use the Win32 event logger but the 
1197 operating system running the program isn't Win32 or does not provides Win32
1198 facilities.
1199
1200 =item C<no connection to syslog available>
1201
1202 B<(F)> C<syslog()> failed to connect to the specified socket.
1203
1204 =item C<stream passed to setlogsock, but %s is not writable>
1205
1206 B<(W)> You asked C<setlogsock()> to use a stream socket, but the given 
1207 path is not writable. 
1208
1209 =item C<stream passed to setlogsock, but could not find any device>
1210
1211 B<(W)> You asked C<setlogsock()> to use a stream socket, but didn't 
1212 provide a path, and C<Sys::Syslog> was unable to find an appropriate one.
1213
1214 =item C<tcp passed to setlogsock, but tcp service unavailable>
1215
1216 B<(W)> You asked C<setlogsock()> to use a TCP socket, but the service 
1217 is not available on the system. 
1218
1219 =item C<syslog: expecting argument %s>
1220
1221 B<(F)> You forgot to give C<syslog()> the indicated argument.
1222
1223 =item C<syslog: invalid level/facility: %s>
1224
1225 B<(F)> You specified an invalid level or facility.
1226
1227 =item C<syslog: too many levels given: %s>
1228
1229 B<(F)> You specified too many levels. 
1230
1231 =item C<syslog: too many facilities given: %s>
1232
1233 B<(F)> You specified too many facilities. 
1234
1235 =item C<syslog: level must be given>
1236
1237 B<(F)> You forgot to specify a level.
1238
1239 =item C<udp passed to setlogsock, but udp service unavailable>
1240
1241 B<(W)> You asked C<setlogsock()> to use a UDP socket, but the service 
1242 is not available on the system. 
1243
1244 =item C<unix passed to setlogsock, but path not available>
1245
1246 B<(W)> You asked C<setlogsock()> to use a UNIX socket, but C<Sys::Syslog> 
1247 was unable to find an appropriate an appropriate device.
1248
1249 =back
1250
1251
1252 =head1 SEE ALSO
1253
1254 =head2 Manual Pages
1255
1256 L<syslog(3)>
1257
1258 SUSv3 issue 6, IEEE Std 1003.1, 2004 edition, 
1259 L<http://www.opengroup.org/onlinepubs/000095399/basedefs/syslog.h.html>
1260
1261 GNU C Library documentation on syslog, 
1262 L<http://www.gnu.org/software/libc/manual/html_node/Syslog.html>
1263
1264 Solaris 10 documentation on syslog, 
1265 L<http://docs.sun.com/app/docs/doc/816-5168/6mbb3hruo?a=view>
1266
1267 IRIX 6.4 documentation on syslog,
1268 L<http://techpubs.sgi.com/library/tpl/cgi-bin/getdoc.cgi?coll=0640&db=man&fname=3c+syslog>
1269
1270 AIX 5L 5.3 documentation on syslog, 
1271 L<http://publib.boulder.ibm.com/infocenter/pseries/v5r3/index.jsp?topic=/com.ibm.aix.doc/libs/basetrf2/syslog.htm>
1272
1273 HP-UX 11i documentation on syslog, 
1274 L<http://docs.hp.com/en/B9106-90010/syslog.3C.html>
1275
1276 Tru64 5.1 documentation on syslog, 
1277 L<http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51_HTML/MAN/MAN3/0193____.HTM>
1278
1279 Stratus VOS 15.1, 
1280 L<http://stratadoc.stratus.com/vos/15.1.1/r502-01/wwhelp/wwhimpl/js/html/wwhelp.htm?context=r502-01&file=ch5r502-01bi.html>
1281
1282 =head2 RFCs
1283
1284 I<RFC 3164 - The BSD syslog Protocol>, L<http://www.faqs.org/rfcs/rfc3164.html>
1285 -- Please note that this is an informational RFC, and therefore does not 
1286 specify a standard of any kind.
1287
1288 I<RFC 3195 - Reliable Delivery for syslog>, L<http://www.faqs.org/rfcs/rfc3195.html>
1289
1290 =head2 Articles
1291
1292 I<Syslogging with Perl>, L<http://lexington.pm.org/meetings/022001.html>
1293
1294 =head2 Event Log
1295
1296 Windows Event Log,
1297 L<http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wes/wes/windows_event_log.asp>
1298
1299
1300 =head1 AUTHORS & ACKNOWLEDGEMENTS
1301
1302 Tom Christiansen E<lt>F<tchrist (at) perl.com>E<gt> and Larry Wall
1303 E<lt>F<larry (at) wall.org>E<gt>.
1304
1305 UNIX domain sockets added by Sean Robinson
1306 E<lt>F<robinson_s (at) sc.maricopa.edu>E<gt> with support from Tim Bunce 
1307 E<lt>F<Tim.Bunce (at) ig.co.uk>E<gt> and the C<perl5-porters> mailing list.
1308
1309 Dependency on F<syslog.ph> replaced with XS code by Tom Hughes
1310 E<lt>F<tom (at) compton.nu>E<gt>.
1311
1312 Code for C<constant()>s regenerated by Nicholas Clark E<lt>F<nick (at) ccl4.org>E<gt>.
1313
1314 Failover to different communication modes by Nick Williams
1315 E<lt>F<Nick.Williams (at) morganstanley.com>E<gt>.
1316
1317 Extracted from core distribution for publishing on the CPAN by 
1318 SE<eacute>bastien Aperghis-Tramoni E<lt>sebastien (at) aperghis.netE<gt>.
1319
1320 XS code for using native C functions borrowed from C<L<Unix::Syslog>>, 
1321 written by Marcus Harnisch E<lt>F<marcus.harnisch (at) gmx.net>E<gt>.
1322
1323 Yves Orton suggested and helped for making C<Sys::Syslog> use the native 
1324 event logger under Win32 systems.
1325
1326 Jerry D. Hedden and Reini Urban provided greatly appreciated help to 
1327 debug and polish C<Sys::Syslog> under Cygwin.
1328
1329
1330 =head1 BUGS
1331
1332 Please report any bugs or feature requests to
1333 C<bug-sys-syslog (at) rt.cpan.org>, or through the web interface at
1334 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sys-Syslog>.
1335 I will be notified, and then you'll automatically be notified of progress on
1336 your bug as I make changes.
1337
1338
1339 =head1 SUPPORT
1340
1341 You can find documentation for this module with the perldoc command.
1342
1343     perldoc Sys::Syslog
1344
1345 You can also look for information at:
1346
1347 =over 4
1348
1349 =item * AnnoCPAN: Annotated CPAN documentation
1350
1351 L<http://annocpan.org/dist/Sys-Syslog>
1352
1353 =item * CPAN Ratings
1354
1355 L<http://cpanratings.perl.org/d/Sys-Syslog>
1356
1357 =item * RT: CPAN's request tracker
1358
1359 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Sys-Syslog>
1360
1361 =item * Search CPAN
1362
1363 L<http://search.cpan.org/dist/Sys-Syslog/>
1364
1365 =item * Kobes' CPAN Search
1366
1367 L<http://cpan.uwinnipeg.ca/dist/Sys-Syslog>
1368
1369 =item * Perl Documentation
1370
1371 L<http://perldoc.perl.org/Sys/Syslog.html>
1372
1373 =back
1374
1375
1376 =head1 LICENSE
1377
1378 This program is free software; you can redistribute it and/or modify it
1379 under the same terms as Perl itself.
1380
1381 =cut
1382
1383 =begin comment
1384
1385 Notes for the future maintainer (even if it's still me..)
1386 - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
1387
1388 Using Google Code Search, I search who on Earth was relying on $host being 
1389 public. It found 5 hits: 
1390
1391 * First was inside Indigo Star Perl2exe documentation. Just an old version 
1392 of Sys::Syslog. 
1393
1394
1395 * One real hit was inside DalWeathDB, a weather related program. It simply 
1396 does a 
1397
1398     $Sys::Syslog::host = '127.0.0.1';
1399
1400 - L<http://www.gallistel.net/nparker/weather/code/>
1401
1402
1403 * Two hits were in TPC, a fax server thingy. It does a 
1404
1405     $Sys::Syslog::host = $TPC::LOGHOST;
1406
1407 but also has this strange piece of code:
1408
1409     # work around perl5.003 bug
1410     sub Sys::Syslog::hostname {}
1411
1412 I don't know what bug the author referred to.
1413
1414 - L<http://www.tpc.int/>
1415 - L<ftp://ftp.tpc.int/tpc/server/UNIX/>
1416 - L<ftp://ftp-usa.tpc.int/pub/tpc/server/UNIX/>
1417
1418
1419 * Last hit was in Filefix, which seems to be a FIDOnet mail program (!).
1420 This one does not use $host, but has the following piece of code:
1421
1422     sub Sys::Syslog::hostname
1423     {
1424         use Sys::Hostname;
1425         return hostname;
1426     }
1427
1428 I guess this was a more elaborate form of the previous bit, maybe because 
1429 of a bug in Sys::Syslog back then?
1430
1431 - L<ftp://ftp.kiae.su/pub/unix/fido/>
1432
1433 =end comment