This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
951c23b4318a867d4fc51943d11eb538f560d96f
[perl5.git] / regen / regen_lib.pl
1 #!/usr/bin/perl -w
2 use strict;
3 use vars qw($Needs_Write $Verbose @Changed $TAP);
4 use File::Compare;
5 use Symbol;
6 use Text::Wrap;
7
8 # Common functions needed by the regen scripts
9
10 $Needs_Write = $^O eq 'cygwin' || $^O eq 'os2' || $^O eq 'MSWin32';
11
12 $Verbose = 0;
13 @ARGV = grep { not($_ eq '-q' and $Verbose = -1) }
14   grep { not($_ eq '--tap' and $TAP = 1) }
15   grep { not($_ eq '-v' and $Verbose = 1) } @ARGV;
16
17 END {
18   print STDOUT "Changed: @Changed\n" if @Changed;
19 }
20
21 sub safer_unlink {
22   my @names = @_;
23   my $cnt = 0;
24
25   my $name;
26   foreach $name (@names) {
27     next unless -e $name;
28     chmod 0777, $name if $Needs_Write;
29     ( CORE::unlink($name) and ++$cnt
30       or warn "Couldn't unlink $name: $!\n" );
31   }
32   return $cnt;
33 }
34
35 sub safer_rename_silent {
36   my ($from, $to) = @_;
37
38   # Some dosish systems can't rename over an existing file:
39   safer_unlink $to;
40   chmod 0600, $from if $Needs_Write;
41   rename $from, $to;
42 }
43
44 sub rename_if_different {
45   my ($from, $to) = @_;
46
47   if ($TAP) {
48       my $not = compare($from, $to) ? 'not ' : '';
49       print STDOUT $not . "ok - $0 $to\n";
50       safer_unlink($from);
51       return;
52   }
53   if (compare($from, $to) == 0) {
54       warn "no changes between '$from' & '$to'\n" if $Verbose > 0;
55       safer_unlink($from);
56       return;
57   }
58   warn "changed '$from' to '$to'\n" if $Verbose > 0;
59   push @Changed, $to unless $Verbose < 0;
60   safer_rename_silent($from, $to) or die "renaming $from to $to: $!";
61 }
62
63 # Open a new file.
64 sub open_new {
65     my ($final_name) = @_;
66     my $name = $final_name . '-new';
67     if (-f $name) {
68         unlink $name or die "$name exists but can't unlink: $!";
69     }
70     my $fh = gensym;
71     open $fh, ">$name" or die "Can't create $name: $!";
72     *{$fh}->{name} = $name;
73     *{$fh}->{final_name} = $final_name;
74     *{$fh}->{lang} = ($final_name =~ /\.(?:c|h|tab|act)$/ ? 'C' : 'Perl');
75     binmode $fh;
76     $fh;
77 }
78
79 sub safer_close {
80     my $fh = shift;
81     close $fh or die 'Error closing ' . *{$fh}->{name} . ": $!";
82 }
83
84 sub read_only_top {
85     my %args = @_;
86     die "Missing language argument" unless defined $args{lang};
87     die "Unknown language argument '$args{lang}'"
88         unless $args{lang} eq 'Perl' or $args{lang} eq 'C';
89     my $style = $args{style} ? " $args{style} " : '   ';
90
91     my $raw = "-*- buffer-read-only: t -*-\n";
92
93     if ($args{file}) {
94         $raw .= "\n   $args{file}\n";
95     }
96     if ($args{copyright}) {
97         local $" = ', ';
98         local $Text::Wrap::columns = 75;
99         $raw .= wrap('   ', '   ', <<"EOM") . "\n";
100
101 Copyright (C) @{$args{copyright}} by\0Larry\0Wall\0and\0others
102
103 You may distribute under the terms of either the GNU General Public
104 License or the Artistic License, as specified in the README file.
105 EOM
106     }
107
108     $raw .= "!!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!\n";
109
110     if ($args{by}) {
111         $raw .= "This file is built by $args{by}";
112         if ($args{from}) {
113             my @from = ref $args{from} eq 'ARRAY' ? @{$args{from}} : $args{from};
114             my $last = pop @from;
115             if (@from) {
116                 $raw .= ' from ' . join (', ', @from) . " and $last";
117             } else {
118                 $raw .= " from $last";
119             }
120         }
121         $raw .= ".\n";
122     }
123     $raw .= "Any changes made here will be lost!\n";
124     $raw .= $args{final} if $args{final};
125
126     local $Text::Wrap::columns = 78;
127     my $cooked = $args{lang} eq 'Perl'
128         ? wrap('# ', '# ', $raw) . "\n" : wrap('/* ', $style, $raw) . " */\n\n";
129     $cooked =~ tr/\0/ /; # Don't break Larry's name etc
130     $cooked =~ s/ +$//mg; # Remove all trailing spaces
131     return $cooked;
132 }
133
134 sub read_only_bottom {
135     my ($sources, $lang) = @_;
136
137     my $comment;
138     if ($sources) {
139         $comment = "Generated from:\n";
140         foreach my $file (sort @$sources) {
141             my $digest = digest($file);
142             $comment .= "$digest $file\n";
143         }
144     }
145     $comment .= "ex: set ro:";
146
147     if (defined $lang && $lang eq 'Perl') {
148         $comment =~ s/^/# /mg;
149     } else {
150         $comment =~ s/^/ * /mg;
151         $comment =~ s! \* !/* !;
152         $comment .= " */";
153     }
154     return "$comment\n";
155 }
156
157 sub read_only_bottom_close_and_rename {
158     my ($fh, $sources) = @_;
159     my $name = *{$fh}->{name};
160     my $lang = *{$fh}->{lang};
161     die "No final name specified at open time for $name"
162         unless *{$fh}->{final_name};
163
164     print $fh "\n", read_only_bottom($sources, $lang);
165
166     safer_close($fh);
167     rename_if_different($name, *{$fh}->{final_name});
168 }
169
170 sub tab {
171     my ($l, $t) = @_;
172     $t .= "\t" x ($l - (length($t) + 1) / 8);
173     $t;
174 }
175
176 sub digest {
177     my $file = shift;
178     # Need to defer loading this, as the main regen scripts work back to 5.004,
179     # and likely we don't even have this module on every 5.8 install yet:
180     require Digest::SHA;
181
182     local ($/, *FH);
183     open FH, "$file" or die "Can't open $file: $!";
184     my $raw = <FH>;
185     close FH or die "Can't close $file: $!";
186     return Digest::SHA::sha256_hex($raw);
187 };
188
189 1;