This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
94520b7983ce3d7b8bc13148285a22c8486ea288
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still current
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the default, as it saves some fakery within TestInit
27 # which can perturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Tar' => 1,
32            '../cpan/AutoLoader' => 1,
33            '../cpan/CPAN' => 1,
34            '../cpan/Class-ISA' => 1,
35            '../cpan/Devel-PPPort' => 1,
36            '../cpan/Encode' => 1,
37            '../cpan/ExtUtils-Constant' => 1,
38            '../cpan/ExtUtils-MakeMaker' => 1,
39            '../cpan/File-Fetch' => 1,
40            '../cpan/IPC-Cmd' => 1,
41            '../cpan/IPC-SysV' => 1,
42            '../cpan/Locale-Codes' => 1,
43            '../cpan/Module-Load' => 1,
44            '../cpan/Module-Load-Conditional' => 1,
45            '../cpan/Parse-CPAN-Meta' => 1,
46            '../cpan/Pod-Simple' => 1,
47            '../cpan/Test-Simple' => 1,
48            '../cpan/podlators' => 1,
49            '../dist/Cwd' => 1,
50            '../dist/ExtUtils-Command' => 1,
51            '../dist/ExtUtils-Install' => 1,
52            '../dist/ExtUtils-Manifest' => 1,
53            '../dist/ExtUtils-ParseXS' => 1,
54            '../dist/Tie-File' => 1,
55           );
56
57 my %temp_no_core =
58     ('../cpan/B-Debug' => 1,
59      '../cpan/Compress-Raw-Bzip2' => 1,
60      '../cpan/Compress-Raw-Zlib' => 1,
61      '../cpan/Devel-PPPort' => 1,
62      '../cpan/Getopt-Long' => 1,
63      '../cpan/IO-Compress' => 1,
64      '../cpan/MIME-Base64' => 1,
65      '../cpan/parent' => 1,
66      '../cpan/Parse-CPAN-Meta' => 1,
67      '../cpan/Pod-Simple' => 1,
68      '../cpan/podlators' => 1,
69      '../cpan/Test-Simple' => 1,
70      '../cpan/Tie-RefHash' => 1,
71      '../cpan/Unicode-Collate' => 1,
72      '../cpan/Unicode-Normalize' => 1,
73     );
74
75 # delete env vars that may influence the results
76 # but allow override via *_TEST env var if wanted
77 # (e.g. PERL5OPT_TEST=-d:NYTProf)
78 my @bad_env_vars = qw(
79     PERL5LIB PERLLIB PERL5OPT
80     PERL_YAML_BACKEND PERL_JSON_BACKEND
81 );
82
83 for my $envname (@bad_env_vars) {
84     my $override = $ENV{"${envname}_TEST"};
85     if (defined $override) {
86         warn "$0: $envname=$override\n";
87         $ENV{$envname} = $override;
88     }
89     else {
90         delete $ENV{$envname};
91     }
92 }
93
94 # Location to put the Valgrind log.
95 our $Valgrind_Log;
96
97 my %skip = (
98             '.' => 1,
99             '..' => 1,
100             'CVS' => 1,
101             'RCS' => 1,
102             'SCCS' => 1,
103             '.svn' => 1,
104            );
105
106
107 if ($::do_nothing) {
108     return 1;
109 }
110
111 $| = 1;
112
113 # for testing TEST only
114 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
115 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
116
117 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
118 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
119 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
120
121 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
122 # can't rely on require working.
123 {
124     my @argv = ();
125     foreach my $idx (0..$#ARGV) {
126         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
127         $::benchmark = 1 if $1 eq 'benchmark';
128         $::core    = 1 if $1 eq 'core';
129         $::verbose = 1 if $1 eq 'v';
130         $::torture = 1 if $1 eq 'torture';
131         $::with_utf8 = 1 if $1 eq 'utf8';
132         $::with_utf16 = 1 if $1 eq 'utf16';
133         $::taintwarn = 1 if $1 eq 'taintwarn';
134         if ($1 =~ /^deparse(,.+)?$/) {
135             $::deparse = 1;
136             $::deparse_opts = $1;
137         }
138     }
139     @ARGV = @argv;
140 }
141
142 chdir 't' if -f 't/TEST';
143 if (-f 'TEST' && -f 'harness' && -d '../lib') {
144     @INC = '../lib';
145 }
146
147 die "You need to run \"make test\" first to set things up.\n"
148   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
149
150 # check leakage for embedders
151 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
152 # check existence of all symbols
153 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
154
155 $ENV{EMXSHELL} = 'sh';        # For OS/2
156
157 if ($show_elapsed_time) { require Time::HiRes }
158 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
159
160 # Roll your own File::Find!
161 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
162 sub _find_files {
163     my($patt, @dirs) = @_;
164     for my $dir (@dirs) {
165         opendir DIR, $dir or die "Trouble opening $dir: $!";
166         foreach my $f (sort { $a cmp $b } readdir DIR) {
167             next if $skip{$f};
168
169             my $fullpath = "$dir/$f";
170             
171             if (-d $fullpath) {
172                 _find_files($patt, $fullpath);
173             } elsif ($f =~ /$patt/) {
174                 push @found, $fullpath;
175             }
176         }
177     }
178     @found;
179 }
180
181
182 # Scan the text of the test program to find switches and special options
183 # we might need to apply.
184 sub _scan_test {
185     my($test, $type) = @_;
186
187     open(my $script, "<", $test) or die "Can't read $test.\n";
188     my $first_line = <$script>;
189
190     $first_line =~ tr/\0//d if $::with_utf16;
191
192     my $switch = "";
193     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
194         $switch = "-$1";
195     } else {
196         if ($::taintwarn) {
197             # not all tests are expected to pass with this option
198             $switch = '-t';
199         } else {
200             $switch = '';
201         }
202     }
203
204     my $file_opts = "";
205     if ($type eq 'deparse') {
206         # Look for #line directives which change the filename
207         while (<$script>) {
208             $file_opts = $file_opts . ",-f$3$4"
209               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
210         }
211     }
212
213     close $script;
214
215     my $perl = './perl';
216     my $lib  = '../lib';
217     my $run_dir;
218     my $return_dir;
219
220     $test =~ /^(.+)\/[^\/]+/;
221     my $dir = $1;
222     my $testswitch = $dir_to_switch{$dir};
223     if (!defined $testswitch) {
224         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
225             $run_dir = $1;
226             $return_dir = '../../t';
227             $lib = '../../lib';
228             $perl = '../../t/perl';
229             $testswitch = "-I../.. -MTestInit=U2T";
230             if ($2 eq 'cpan' || $2 eq 'dist') {
231                 if($abs{$run_dir}) {
232                     $testswitch = $testswitch . ',A';
233                 }
234                 if ($temp_no_core{$run_dir}) {
235                     $testswitch = $testswitch . ',NC';
236                 }
237             }
238         } elsif ($test =~ m!^\.\./lib!) {
239             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
240         } else {
241             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
242         }
243     }
244
245     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
246
247     my %options = (
248         perl => $perl,
249         lib => $lib,
250         test => $test,
251         run_dir => $run_dir,
252         return_dir => $return_dir,
253         testswitch => $testswitch,
254         utf8 => $utf8,
255         file => $file_opts,
256         switch => $switch,
257     );
258
259     return \%options;
260 }
261
262 sub _cmd {
263     my($options, $type) = @_;
264
265     my $test = $options->{test};
266
267     my $cmd;
268     if ($type eq 'deparse') {
269         my $perl = "$options->{perl} $options->{testswitch}";
270         my $lib = $options->{lib};
271
272         $cmd = (
273           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
274           "-l$::deparse_opts$options->{file} ".
275           "$test > $test.dp ".
276           "&& $perl $options->{switch} -I$lib $test.dp"
277         );
278     }
279     elsif ($type eq 'perl') {
280         my $perl = $options->{perl};
281         my $redir = $^O eq 'VMS' ? '2>&1' : '';
282
283         if ($ENV{PERL_VALGRIND}) {
284             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
285             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
286             if ($options->{run_dir}) {
287                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
288             }
289             my $vg_opts = $ENV{VG_OPTS}
290                //   "--log-file=$Valgrind_Log "
291                   . "--suppressions=$perl_supp --leak-check=yes "
292                   . "--leak-resolution=high --show-reachable=yes "
293                   . "--num-callers=50 --track-origins=yes";
294             # Force logging if not asked for (so cachegrind reporting works below)
295             if ($vg_opts !~ /--log-file/) {
296                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
297             }
298             $perl = "$valgrind_exe $vg_opts $perl";
299         }
300
301         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
302         $cmd = $perl . _quote_args($args) . " $test $redir";
303     }
304     return $cmd;
305 }
306
307 sub _before_fork {
308     my ($options) = @_;
309
310     if ($options->{run_dir}) {
311         my $run_dir = $options->{run_dir};
312         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
313     }
314
315     # Remove previous valgrind output otherwise it will interfere
316     my $test = $options->{test};
317
318     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
319
320     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
321         unlink $Valgrind_Log
322             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
323     }
324
325     return;
326 }
327
328 sub _after_fork {
329     my ($options) = @_;
330
331     if ($options->{return_dir}) {
332         my $return_dir = $options->{return_dir};
333         chdir $return_dir
334            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
335     }
336
337     return;
338 }
339
340 sub _run_test {
341     my ($test, $type) = @_;
342
343     my $options = _scan_test($test, $type);
344     # $test might have changed if we're in ext/Foo, so don't use it anymore
345     # from now on. Use $options->{test} instead.
346
347     _before_fork($options);
348
349     my $cmd = _cmd($options, $type);
350
351     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
352
353     _after_fork($options);
354
355     # Our environment may force us to use UTF-8, but we can't be sure that
356     # anything we're reading from will be generating (well formed) UTF-8
357     # This may not be the best way - possibly we should unset ${^OPEN} up
358     # top?
359     binmode $results;
360
361     return $results;
362 }
363
364 sub _quote_args {
365     my ($args) = @_;
366     my $argstring = '';
367
368     foreach (split(/\s+/,$args)) {
369        # In VMS protect with doublequotes because otherwise
370        # DCL will lowercase -- unless already doublequoted.
371        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
372        $argstring = $argstring . ' ' . $_;
373     }
374     return $argstring;
375 }
376
377 sub _populate_hash {
378     return unless defined $_[0];
379     return map {$_, 1} split /\s+/, $_[0];
380 }
381
382 sub _tests_from_manifest {
383     my ($extensions, $known_extensions) = @_;
384     my %skip;
385     my %extensions = _populate_hash($extensions);
386     my %known_extensions = _populate_hash($known_extensions);
387
388     foreach (keys %known_extensions) {
389         $skip{$_} = 1 unless $extensions{$_};
390     }
391
392     my @results;
393     my $mani = '../MANIFEST';
394     if (open(MANI, $mani)) {
395         while (<MANI>) {
396             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
397                 my $t = $1;
398                 my $extension = $2;
399                 if (!$::core || $t =~ m!^lib/[a-z]!) {
400                     if (defined $extension) {
401                         $extension =~ s!/t(:?/\S+)*$!!;
402                         # XXX Do I want to warn that I'm skipping these?
403                         next if $skip{$extension};
404                         my $flat_extension = $extension;
405                         $flat_extension =~ s!-!/!g;
406                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
407                     }
408                     my $path = "../$t";
409                     push @results, $path;
410                     $::path_to_name{$path} = $t;
411                 }
412             }
413         }
414         close MANI;
415     } else {
416         warn "$0: cannot open $mani: $!\n";
417     }
418     return @results;
419 }
420
421 unless (@ARGV) {
422     # base first, as TEST bails out if that can't run
423     # then comp, to validate that require works
424     # then run, to validate that -M works
425     # then we know we can -MTestInit for everything else, making life simpler
426     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro)) {
427         _find_tests($dir);
428     }
429     unless ($::core) {
430         _find_tests('porting');
431         _find_tests("lib"); 
432     }
433     # Config.pm may be broken for make minitest. And this is only a refinement
434     # for skipping tests on non-default builds, so it is allowed to fail.
435     # What we want to to is make a list of extensions which we did not build.
436     my $configsh = '../config.sh';
437     my ($extensions, $known_extensions);
438     if (-f $configsh) {
439         open FH, $configsh or die "Can't open $configsh: $!";
440         while (<FH>) {
441             if (/^extensions=['"](.*)['"]$/) {
442                 $extensions = $1;
443             }
444             elsif (/^known_extensions=['"](.*)['"]$/) {
445                 $known_extensions = $1;
446             }
447         }
448         if (!defined $known_extensions) {
449             warn "No known_extensions line found in $configsh";
450         }
451         if (!defined $extensions) {
452             warn "No extensions line found in $configsh";
453         }
454     }
455     # The "complex" constructions of list return from a subroutine, and push of
456     # a list, might fail if perl is really hosed, but they aren't needed for
457     # make minitest, and the building of extensions will likely also fail if
458     # something is that badly wrong.
459     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
460     unless ($::core) {
461         _find_tests('japh') if $::torture;
462         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
463         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
464     }
465 }
466
467 if ($::deparse) {
468     _testprogs('deparse', '',   @ARGV);
469 }
470 elsif ($::with_utf16) {
471     for my $e (0, 1) {
472         for my $b (0, 1) {
473             print STDERR "# ENDIAN $e BOM $b\n";
474             my @UARGV;
475             for my $a (@ARGV) {
476                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
477                 my $f = $e ? "v" : "n";
478                 push @UARGV, $u;
479                 unlink($u);
480                 if (open(A, $a)) {
481                     if (open(U, ">$u")) {
482                         print U pack("$f", 0xFEFF) if $b;
483                         while (<A>) {
484                             print U pack("$f*", unpack("C*", $_));
485                         }
486                         close(U);
487                     }
488                     close(A);
489                 }
490             }
491             _testprogs('perl', '', @UARGV);
492             unlink(@UARGV);
493         }
494     }
495 }
496 else {
497     _testprogs('perl',    '',   @ARGV);
498 }
499
500 sub _testprogs {
501     my ($type, $args, @tests) = @_;
502
503     print <<'EOT' if ($type eq 'deparse');
504 ------------------------------------------------------------------------------
505 TESTING DEPARSER
506 ------------------------------------------------------------------------------
507 EOT
508
509     $::bad_files = 0;
510
511     foreach my $t (@tests) {
512       unless (exists $::path_to_name{$t}) {
513         my $tname = "t/$t";
514         $::path_to_name{$t} = $tname;
515       }
516     }
517     my $maxlen = 0;
518     foreach (@::path_to_name{@tests}) {
519         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
520         my $len = length ;
521         $maxlen = $len if $len > $maxlen;
522     }
523     # + 3 : we want three dots between the test name and the "ok"
524     my $dotdotdot = $maxlen + 3 ;
525     my $grind_ct = 0;           # count of non-empty valgrind reports
526     my $total_files = @tests;
527     my $good_files = 0;
528     my $tested_files  = 0;
529     my $totmax = 0;
530     my %failed_tests;
531     my $toolnm;         # valgrind, cachegrind, perf
532
533     while (my $test = shift @tests) {
534         my ($test_start_time, @starttimes) = 0;
535         if ($show_elapsed_time) {
536             $test_start_time = Time::HiRes::time();
537             # times() reports usage by TEST, but we want usage of each
538             # testprog it calls, so record accumulated times now,
539             # subtract them out afterwards.  Ideally, we'd take times
540             # in BEGIN/END blocks (giving better visibility of self vs
541             # children of each testprog), but that would require some
542             # IPC to send results back here, or a completely different
543             # collection scheme (Storable isn't tuned for incremental use)
544             @starttimes = times;
545         }
546         if ($test =~ /^$/) {
547             next;
548         }
549         if ($type eq 'deparse') {
550             if ($test eq "comp/redef.t") {
551                 # Redefinition happens at compile time
552                 next;
553             }
554             elsif ($test =~ m{lib/Switch/t/}) {
555                 # B::Deparse doesn't support source filtering
556                 next;
557             }
558         }
559         my $te = $::path_to_name{$test} . '.'
560                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
561
562         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
563             print $te;
564             $te = '';
565         }
566
567         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
568
569         my $results = _run_test($test, $type);
570
571         my $failure;
572         my $next = 0;
573         my $seen_leader = 0;
574         my $seen_ok = 0;
575         my $trailing_leader = 0;
576         my $max;
577         my %todo;
578         while (<$results>) {
579             next if /^\s*$/; # skip blank lines
580             if (/^1..$/ && ($^O eq 'VMS')) {
581                 # VMS pipe bug inserts blank lines.
582                 my $l2 = <$results>;
583                 if ($l2 =~ /^\s*$/) {
584                     $l2 = <$results>;
585                 }
586                 $_ = '1..' . $l2;
587             }
588             if ($::verbose) {
589                 print $_;
590             }
591             unless (/^\#/) {
592                 if ($trailing_leader) {
593                     # shouldn't be anything following a postfix 1..n
594                     $failure = 'FAILED--extra output after trailing 1..n';
595                     last;
596                 }
597                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
598                     if ($seen_leader) {
599                         $failure = 'FAILED--seen duplicate leader';
600                         last;
601                     }
602                     $max = $1;
603                     %todo = map { $_ => 1 } split / /, $3 if $3;
604                     $totmax = $totmax + $max;
605                     $tested_files = $tested_files + 1;
606                     if ($seen_ok) {
607                         # 1..n appears at end of file
608                         $trailing_leader = 1;
609                         if ($next != $max) {
610                             $failure = "FAILED--expected $max tests, saw $next";
611                             last;
612                         }
613                     }
614                     else {
615                         $next = 0;
616                     }
617                     $seen_leader = 1;
618                 }
619                 else {
620                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
621                         unless ($seen_leader) {
622                             unless ($seen_ok) {
623                                 $next = 0;
624                             }
625                         }
626                         $seen_ok = 1;
627                         $next = $next + 1;
628                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
629                         $num = $next unless $num;
630
631                         if ($num == $next) {
632
633                             # SKIP is essentially the same as TODO for t/TEST
634                             # this still conforms to TAP:
635                             # http://testanything.org/wiki/index.php/TAP_specification
636                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
637                             $istodo = 1 if $todo{$num};
638
639                             if( $not && !$istodo ) {
640                                 $failure = "FAILED at test $num";
641                                 last;
642                             }
643                         }
644                         else {
645                             $failure ="FAILED--expected test $next, saw test $num";
646                             last;
647                         }
648                     }
649                     elsif (/^Bail out!\s*(.*)/i) { # magic words
650                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
651                     }
652                     else {
653                         # module tests are allowed extra output,
654                         # because Test::Harness allows it
655                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
656                         $failure = "FAILED--unexpected output at test $next";
657                         last;
658                     }
659                 }
660             }
661         }
662         close $results;
663
664         if (not defined $failure) {
665             $failure = 'FAILED--no leader found' unless $seen_leader;
666         }
667
668         _check_valgrind(\$toolnm, \$grind_ct, \$test);
669
670         if ($type eq 'deparse') {
671             unlink "./$test.dp";
672         }
673         if (not defined $failure and $next != $max) {
674             $failure="FAILED--expected $max tests, saw $next";
675         }
676
677         if( !defined $failure  # don't mask a test failure
678             and $? )
679         {
680             $failure = "FAILED--non-zero wait status: $?";
681         }
682
683         if (defined $failure) {
684             print "${te}$failure\n";
685             $::bad_files = $::bad_files + 1;
686             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
687                 # Die if running under minitest (no DynaLoader).  Otherwise
688                 # keep going, as  we know that Perl basically works, or we
689                 # would not have been able to actually compile it all the way.
690                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
691             }
692             $failed_tests{$test} = 1;
693         }
694         else {
695             if ($max) {
696                 my ($elapsed, $etms) = ("", 0);
697                 if ( $show_elapsed_time ) {
698                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
699                     $elapsed = sprintf(" %8.0f ms", $etms);
700
701                     my (@endtimes) = times;
702                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
703                     splice @endtimes, 0, 2;    # drop self/harness times
704                     $_ *= 1000 for @endtimes;  # and scale to ms
705                     $timings{$test} = [$etms,@endtimes];
706                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
707                 }
708                 print "${te}ok$elapsed\n";
709                 $good_files = $good_files + 1;
710             }
711             else {
712                 print "${te}skipped\n";
713                 $tested_files = $tested_files - 1;
714             }
715         }
716     } # while tests
717
718     if ($::bad_files == 0) {
719         if ($good_files) {
720             print "All tests successful.\n";
721             # XXX add mention of 'perlbug -ok' ?
722         }
723         else {
724             die "FAILED--no tests were run for some reason.\n";
725         }
726     }
727     else {
728         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
729         my $s = $::bad_files == 1 ? "" : "s";
730         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
731         for my $test ( sort keys %failed_tests ) {
732             print "\t$test\n";
733         }
734         warn <<'SHRDLU_1';
735 ### Since not all tests were successful, you may want to run some of
736 ### them individually and examine any diagnostic messages they produce.
737 ### See the INSTALL document's section on "make test".
738 SHRDLU_1
739         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
740 ### You have a good chance to get more information by running
741 ###   ./perl harness
742 ### in the 't' directory since most (>=80%) of the tests succeeded.
743 SHRDLU_2
744         if (eval {require Config; import Config; 1}) {
745             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
746                 warn <<SHRDLU_3;
747 ### You may have to set your dynamic library search path,
748 ### $p, to point to the build directory:
749 SHRDLU_3
750                 if (exists $ENV{$p} && $ENV{$p} ne '') {
751                     warn <<SHRDLU_4a;
752 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
753 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
754 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
755 SHRDLU_4a
756                 } else {
757                     warn <<SHRDLU_4b;
758 ###   setenv $p `pwd`; cd t; ./perl harness
759 ###   $p=`pwd`; export $p; cd t; ./perl harness
760 ###   export $p=`pwd`; cd t; ./perl harness
761 SHRDLU_4b
762                 }
763                 warn <<SHRDLU_5;
764 ### for csh-style shells, like tcsh; or for traditional/modern
765 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
766 SHRDLU_5
767             }
768         }
769     }
770     my ($user,$sys,$cuser,$csys) = times;
771     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
772                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
773     print "$tot\n";
774     if ($good_files) {
775         if (-d $show_elapsed_time) {
776             # HARNESS_TIMER = <a-directory>.  Save timings etc to
777             # storable file there.  NB: the test cds to ./t/, so
778             # relative path must account for that, ie ../../perf
779             # points to dir next to source tree.
780             require Storable;
781             my @dt = localtime;
782             $dt[5] += 1900; $dt[4] += 1; # fix year, month
783             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
784             Storable::store({ perf => \%timings,
785                               gather_conf_platform_info(),
786                               total => $tot,
787                             }, $fn);
788             print "wrote storable file: $fn\n";
789         }
790     }
791
792     _cleanup_valgrind(\$toolnm, \$grind_ct);
793 }
794 exit ($::bad_files != 0);
795
796 # Collect platform, config data that should allow comparing
797 # performance data between different machines.  With enough data,
798 # and/or clever statistical analysis, it should be possible to
799 # determine the effect of config choices, more memory, etc
800
801 sub gather_conf_platform_info {
802     # currently rather quick & dirty, and subject to change
803     # for both content and format.
804     require Config;
805     my (%conf, @platform) = ();
806     $conf{$_} = $Config::Config{$_} for
807         grep /cc|git|config_arg\d+/, keys %Config::Config;
808     if (-f '/proc/cpuinfo') {
809         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
810         @platform = grep /name|cpu/, <$fh>;
811         chomp $_ for @platform;
812     }
813     unshift @platform, $^O;
814
815     return (
816         conf => \%conf,
817         platform => {cpu => \@platform,
818                      mem => [ grep s/\s+/ /,
819                               grep chomp, `free` ],
820                      load => [ grep chomp, `uptime` ],
821         },
822         host => (grep chomp, `hostname -f`),
823         version => '0.03', # bump for conf, platform, or data collection changes
824         );
825 }
826
827 sub _check_valgrind {
828     return unless $ENV{PERL_VALGRIND};
829
830     my ($toolnm, $grind_ct, $test) = @_;
831
832     $$toolnm = $ENV{VALGRIND};
833     $$toolnm =~ s|.*/||;  # keep basename
834     my @valgrind;       # gets content of file
835     if (-e $Valgrind_Log) {
836         if (open(V, $Valgrind_Log)) {
837             @valgrind = <V>;
838             close V;
839         } else {
840             warn "$0: Failed to open '$Valgrind_Log': $!\n";
841         }
842     }
843     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
844         $$toolnm = $1;
845         if ($$toolnm eq 'perf') {
846             # append perfs subcommand, not just stat
847             my ($sub) = split /\s/, $ENV{VG_OPTS};
848             $$toolnm .= "-$sub";
849         }
850         if (rename $Valgrind_Log, "$$test.$$toolnm") {
851             $$grind_ct++;
852         } else {
853             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
854         }
855     }
856     elsif (@valgrind) {
857         my $leaks = 0;
858         my $errors = 0;
859         for my $i (0..$#valgrind) {
860             local $_ = $valgrind[$i];
861             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
862                 $errors = $errors + $1;   # there may be multiple error summaries
863             } elsif (/^==\d+== LEAK SUMMARY:/) {
864                 for my $off (1 .. 4) {
865                     if ($valgrind[$i+$off] =~
866                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
867                             $leaks = $leaks + $1;
868                     }
869                 }
870             }
871         }
872         if ($errors or $leaks) {
873             if (rename $Valgrind_Log, "$$test.valgrind") {
874                 $$grind_ct = $$grind_ct + 1;
875             } else {
876                 warn "$0: Failed to create '$$test.valgrind': $!\n";
877             }
878         }
879     } else {
880         # Quiet wasn't asked for? Something may be amiss
881         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
882             warn "No valgrind output?\n";
883         }
884     }
885     if (-e $Valgrind_Log) {
886         unlink $Valgrind_Log
887             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
888     }
889 }
890
891 sub _cleanup_valgrind {
892     return unless $ENV{PERL_VALGRIND};
893
894     my ($toolnm, $grind_ct) = @_;
895     my $s = $$grind_ct == 1 ? '' : 's';
896     print "$$grind_ct valgrind report$s created.\n", ;
897     if ($$toolnm eq 'cachegrind') {
898         # cachegrind leaves a lot of cachegrind.out.$pid litter
899         # around the tree, find and delete them
900         unlink _find_files('cachegrind.out.\d+$',
901                      qw ( ../t ../cpan ../ext ../dist/ ));
902     }
903 }
904
905 # ex: set ts=8 sts=4 sw=4 noet: