This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
944772b75822a4554c329382816b8262654dd7c4
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2
3 perlop - Perl operators and precedence
4
5 =head1 SYNOPSIS
6
7 Perl operators have the following associativity and precedence,
8 listed from highest precedence to lowest.  Operators borrowed from
9 C keep the same precedence relationship with each other, even where
10 C's precedence is slightly screwy.  (This makes learning Perl easier
11 for C folks.)  With very few exceptions, these all operate on scalar
12 values only, not array values.
13
14     left        terms and list operators (leftward)
15     left        ->
16     nonassoc    ++ --
17     right       **
18     right       ! ~ \ and unary + and -
19     left        =~ !~
20     left        * / % x
21     left        + - .
22     left        << >>
23     nonassoc    named unary operators
24     nonassoc    < > <= >= lt gt le ge
25     nonassoc    == != <=> eq ne cmp
26     left        &
27     left        | ^
28     left        &&
29     left        ||
30     nonassoc    ..  ...
31     right       ?:
32     right       = += -= *= etc.
33     left        , =>
34     nonassoc    list operators (rightward)
35     right       not
36     left        and
37     left        or xor
38
39 In the following sections, these operators are covered in precedence order.
40
41 Many operators can be overloaded for objects.  See L<overload>.
42
43 =head1 DESCRIPTION
44
45 =head2 Terms and List Operators (Leftward)
46
47 A TERM has the highest precedence in Perl.  They include variables,
48 quote and quote-like operators, any expression in parentheses,
49 and any function whose arguments are parenthesized.  Actually, there
50 aren't really functions in this sense, just list operators and unary
51 operators behaving as functions because you put parentheses around
52 the arguments.  These are all documented in L<perlfunc>.
53
54 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
55 is followed by a left parenthesis as the next token, the operator and
56 arguments within parentheses are taken to be of highest precedence,
57 just like a normal function call.
58
59 In the absence of parentheses, the precedence of list operators such as
60 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
61 whether you are looking at the left side or the right side of the operator.
62 For example, in
63
64     @ary = (1, 3, sort 4, 2);
65     print @ary;         # prints 1324
66
67 the commas on the right of the sort are evaluated before the sort,
68 but the commas on the left are evaluated after.  In other words,
69 list operators tend to gobble up all arguments that follow, and
70 then act like a simple TERM with regard to the preceding expression.
71 Be careful with parentheses:
72
73     # These evaluate exit before doing the print:
74     print($foo, exit);  # Obviously not what you want.
75     print $foo, exit;   # Nor is this.
76
77     # These do the print before evaluating exit:
78     (print $foo), exit; # This is what you want.
79     print($foo), exit;  # Or this.
80     print ($foo), exit; # Or even this.
81
82 Also note that
83
84     print ($foo & 255) + 1, "\n";
85
86 probably doesn't do what you expect at first glance.  See
87 L<Named Unary Operators> for more discussion of this.
88
89 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
90 well as subroutine and method calls, and the anonymous
91 constructors C<[]> and C<{}>.
92
93 See also L<Quote and Quote-like Operators> toward the end of this section,
94 as well as L<"I/O Operators">.
95
96 =head2 The Arrow Operator
97
98 "C<< -> >>" is an infix dereference operator, just as it is in C
99 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
100 C<(...)> subscript, then the left side must be either a hard or
101 symbolic reference to an array, a hash, or a subroutine respectively.
102 (Or technically speaking, a location capable of holding a hard
103 reference, if it's an array or hash reference being used for
104 assignment.)  See L<perlreftut> and L<perlref>.
105
106 Otherwise, the right side is a method name or a simple scalar
107 variable containing either the method name or a subroutine reference,
108 and the left side must be either an object (a blessed reference)
109 or a class name (that is, a package name).  See L<perlobj>.
110
111 =head2 Auto-increment and Auto-decrement
112
113 "++" and "--" work as in C.  That is, if placed before a variable, they
114 increment or decrement the variable before returning the value, and if
115 placed after, increment or decrement the variable after returning the value.
116
117 The auto-increment operator has a little extra builtin magic to it.  If
118 you increment a variable that is numeric, or that has ever been used in
119 a numeric context, you get a normal increment.  If, however, the
120 variable has been used in only string contexts since it was set, and
121 has a value that is not the empty string and matches the pattern
122 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
123 character within its range, with carry:
124
125     print ++($foo = '99');      # prints '100'
126     print ++($foo = 'a0');      # prints 'a1'
127     print ++($foo = 'Az');      # prints 'Ba'
128     print ++($foo = 'zz');      # prints 'aaa'
129
130 The auto-decrement operator is not magical.
131
132 =head2 Exponentiation
133
134 Binary "**" is the exponentiation operator.  It binds even more
135 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
136 implemented using C's pow(3) function, which actually works on doubles
137 internally.)
138
139 =head2 Symbolic Unary Operators
140
141 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
142 precedence version of this.
143
144 Unary "-" performs arithmetic negation if the operand is numeric.  If
145 the operand is an identifier, a string consisting of a minus sign
146 concatenated with the identifier is returned.  Otherwise, if the string
147 starts with a plus or minus, a string starting with the opposite sign
148 is returned.  One effect of these rules is that C<-bareword> is equivalent
149 to C<"-bareword">.
150
151 Unary "~" performs bitwise negation, i.e., 1's complement.  For
152 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
153 L<Bitwise String Operators>.)  Note that the width of the result is
154 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
155 bits wide on a 64-bit platform, so if you are expecting a certain bit
156 width, remember use the & operator to mask off the excess bits.
157
158 Unary "+" has no effect whatsoever, even on strings.  It is useful
159 syntactically for separating a function name from a parenthesized expression
160 that would otherwise be interpreted as the complete list of function
161 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
162
163 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
164 and L<perlref>.  Do not confuse this behavior with the behavior of
165 backslash within a string, although both forms do convey the notion
166 of protecting the next thing from interpolation.
167
168 =head2 Binding Operators
169
170 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
171 search or modify the string $_ by default.  This operator makes that kind
172 of operation work on some other string.  The right argument is a search
173 pattern, substitution, or transliteration.  The left argument is what is
174 supposed to be searched, substituted, or transliterated instead of the default
175 $_.  When used in scalar context, the return value generally indicates the
176 success of the operation.  Behavior in list context depends on the particular
177 operator.  See L</"Regexp Quote-Like Operators"> for details.
178
179 If the right argument is an expression rather than a search pattern,
180 substitution, or transliteration, it is interpreted as a search pattern at run
181 time.  This can be less efficient than an explicit search, because the
182 pattern must be compiled every time the expression is evaluated.
183
184 Binary "!~" is just like "=~" except the return value is negated in
185 the logical sense.
186
187 =head2 Multiplicative Operators
188
189 Binary "*" multiplies two numbers.
190
191 Binary "/" divides two numbers.
192
193 Binary "%" computes the modulus of two numbers.  Given integer
194 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
195 C<$a> minus the largest multiple of C<$b> that is not greater than
196 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
197 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
198 result will be less than or equal to zero). 
199 Note than when C<use integer> is in scope, "%" gives you direct access
200 to the modulus operator as implemented by your C compiler.  This
201 operator is not as well defined for negative operands, but it will
202 execute faster.
203
204 Binary "x" is the repetition operator.  In scalar context or if the left
205 operand is not enclosed in parentheses, it returns a string consisting
206 of the left operand repeated the number of times specified by the right
207 operand.  In list context, if the left operand is enclosed in
208 parentheses, it repeats the list.
209
210     print '-' x 80;             # print row of dashes
211
212     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
213
214     @ones = (1) x 80;           # a list of 80 1's
215     @ones = (5) x @ones;        # set all elements to 5
216
217
218 =head2 Additive Operators
219
220 Binary "+" returns the sum of two numbers.
221
222 Binary "-" returns the difference of two numbers.
223
224 Binary "." concatenates two strings.
225
226 =head2 Shift Operators
227
228 Binary "<<" returns the value of its left argument shifted left by the
229 number of bits specified by the right argument.  Arguments should be
230 integers.  (See also L<Integer Arithmetic>.)
231
232 Binary ">>" returns the value of its left argument shifted right by
233 the number of bits specified by the right argument.  Arguments should
234 be integers.  (See also L<Integer Arithmetic>.)
235
236 Note that both "<<" and ">>" in Perl are implemented directly using
237 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
238 in force then signed C integers are used, else unsigned C integers are
239 used.  Either way, the implementation isn't going to generate results
240 larger than the size of the integer type Perl was built with (32 bits
241 or 64 bits).
242
243 The result of overflowing the range of the integers is undefined
244 because it is undefined also in C.  In other words, using 32-bit
245 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
246 of bits is also undefined.
247
248 =head2 Named Unary Operators
249
250 The various named unary operators are treated as functions with one
251 argument, with optional parentheses.  These include the filetest
252 operators, like C<-f>, C<-M>, etc.  See L<perlfunc>.
253
254 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
255 is followed by a left parenthesis as the next token, the operator and
256 arguments within parentheses are taken to be of highest precedence,
257 just like a normal function call.  For example,
258 because named unary operators are higher precedence than ||:
259
260     chdir $foo    || die;       # (chdir $foo) || die
261     chdir($foo)   || die;       # (chdir $foo) || die
262     chdir ($foo)  || die;       # (chdir $foo) || die
263     chdir +($foo) || die;       # (chdir $foo) || die
264
265 but, because * is higher precedence than named operators:
266
267     chdir $foo * 20;    # chdir ($foo * 20)
268     chdir($foo) * 20;   # (chdir $foo) * 20
269     chdir ($foo) * 20;  # (chdir $foo) * 20
270     chdir +($foo) * 20; # chdir ($foo * 20)
271
272     rand 10 * 20;       # rand (10 * 20)
273     rand(10) * 20;      # (rand 10) * 20
274     rand (10) * 20;     # (rand 10) * 20
275     rand +(10) * 20;    # rand (10 * 20)
276
277 See also L<"Terms and List Operators (Leftward)">.
278
279 =head2 Relational Operators
280
281 Binary "<" returns true if the left argument is numerically less than
282 the right argument.
283
284 Binary ">" returns true if the left argument is numerically greater
285 than the right argument.
286
287 Binary "<=" returns true if the left argument is numerically less than
288 or equal to the right argument.
289
290 Binary ">=" returns true if the left argument is numerically greater
291 than or equal to the right argument.
292
293 Binary "lt" returns true if the left argument is stringwise less than
294 the right argument.
295
296 Binary "gt" returns true if the left argument is stringwise greater
297 than the right argument.
298
299 Binary "le" returns true if the left argument is stringwise less than
300 or equal to the right argument.
301
302 Binary "ge" returns true if the left argument is stringwise greater
303 than or equal to the right argument.
304
305 =head2 Equality Operators
306
307 Binary "==" returns true if the left argument is numerically equal to
308 the right argument.
309
310 Binary "!=" returns true if the left argument is numerically not equal
311 to the right argument.
312
313 Binary "<=>" returns -1, 0, or 1 depending on whether the left
314 argument is numerically less than, equal to, or greater than the right
315 argument.  If your platform supports NaNs (not-a-numbers) as numeric
316 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
317 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
318 returns true, as does NaN != anything else. If your platform doesn't
319 support NaNs then NaN is just a string with numeric value 0.
320
321     perl -le '$a = NaN; print "No NaN support here" if $a == $a'
322     perl -le '$a = NaN; print "NaN support here" if $a != $a'
323
324 Binary "eq" returns true if the left argument is stringwise equal to
325 the right argument.
326
327 Binary "ne" returns true if the left argument is stringwise not equal
328 to the right argument.
329
330 Binary "cmp" returns -1, 0, or 1 depending on whether the left
331 argument is stringwise less than, equal to, or greater than the right
332 argument.
333
334 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
335 by the current locale if C<use locale> is in effect.  See L<perllocale>.
336
337 =head2 Bitwise And
338
339 Binary "&" returns its operators ANDed together bit by bit.
340 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
341
342 =head2 Bitwise Or and Exclusive Or
343
344 Binary "|" returns its operators ORed together bit by bit.
345 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
346
347 Binary "^" returns its operators XORed together bit by bit.
348 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
349
350 =head2 C-style Logical And
351
352 Binary "&&" performs a short-circuit logical AND operation.  That is,
353 if the left operand is false, the right operand is not even evaluated.
354 Scalar or list context propagates down to the right operand if it
355 is evaluated.
356
357 =head2 C-style Logical Or
358
359 Binary "||" performs a short-circuit logical OR operation.  That is,
360 if the left operand is true, the right operand is not even evaluated.
361 Scalar or list context propagates down to the right operand if it
362 is evaluated.
363
364 The C<||> and C<&&> operators differ from C's in that, rather than returning
365 0 or 1, they return the last value evaluated.  Thus, a reasonably portable
366 way to find out the home directory (assuming it's not "0") might be:
367
368     $home = $ENV{'HOME'} || $ENV{'LOGDIR'} ||
369         (getpwuid($<))[7] || die "You're homeless!\n";
370
371 In particular, this means that you shouldn't use this
372 for selecting between two aggregates for assignment:
373
374     @a = @b || @c;              # this is wrong
375     @a = scalar(@b) || @c;      # really meant this
376     @a = @b ? @b : @c;          # this works fine, though
377
378 As more readable alternatives to C<&&> and C<||> when used for
379 control flow, Perl provides C<and> and C<or> operators (see below).
380 The short-circuit behavior is identical.  The precedence of "and" and
381 "or" is much lower, however, so that you can safely use them after a
382 list operator without the need for parentheses:
383
384     unlink "alpha", "beta", "gamma"
385             or gripe(), next LINE;
386
387 With the C-style operators that would have been written like this:
388
389     unlink("alpha", "beta", "gamma")
390             || (gripe(), next LINE);
391
392 Using "or" for assignment is unlikely to do what you want; see below.
393
394 =head2 Range Operators
395
396 Binary ".." is the range operator, which is really two different
397 operators depending on the context.  In list context, it returns an
398 list of values counting (up by ones) from the left value to the right
399 value.  If the left value is greater than the right value then it
400 returns the empty array.  The range operator is useful for writing
401 C<foreach (1..10)> loops and for doing slice operations on arrays. In
402 the current implementation, no temporary array is created when the
403 range operator is used as the expression in C<foreach> loops, but older
404 versions of Perl might burn a lot of memory when you write something
405 like this:
406
407     for (1 .. 1_000_000) {
408         # code
409     }
410
411 The range operator also works on strings, using the magical auto-increment,
412 see below.
413
414 In scalar context, ".." returns a boolean value.  The operator is
415 bistable, like a flip-flop, and emulates the line-range (comma) operator
416 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
417 own boolean state.  It is false as long as its left operand is false.
418 Once the left operand is true, the range operator stays true until the
419 right operand is true, I<AFTER> which the range operator becomes false
420 again.  It doesn't become false till the next time the range operator is
421 evaluated.  It can test the right operand and become false on the same
422 evaluation it became true (as in B<awk>), but it still returns true once.
423 If you don't want it to test the right operand till the next
424 evaluation, as in B<sed>, just use three dots ("...") instead of
425 two.  In all other regards, "..." behaves just like ".." does.
426
427 The right operand is not evaluated while the operator is in the
428 "false" state, and the left operand is not evaluated while the
429 operator is in the "true" state.  The precedence is a little lower
430 than || and &&.  The value returned is either the empty string for
431 false, or a sequence number (beginning with 1) for true.  The
432 sequence number is reset for each range encountered.  The final
433 sequence number in a range has the string "E0" appended to it, which
434 doesn't affect its numeric value, but gives you something to search
435 for if you want to exclude the endpoint.  You can exclude the
436 beginning point by waiting for the sequence number to be greater
437 than 1.  If either operand of scalar ".." is a constant expression,
438 that operand is implicitly compared to the C<$.> variable, the
439 current line number.  Examples:
440
441 As a scalar operator:
442
443     if (101 .. 200) { print; }  # print 2nd hundred lines
444     next line if (1 .. /^$/);   # skip header lines
445     s/^/> / if (/^$/ .. eof()); # quote body
446
447     # parse mail messages
448     while (<>) {
449         $in_header =   1  .. /^$/;
450         $in_body   = /^$/ .. eof();
451         # do something based on those
452     } continue {
453         close ARGV if eof;              # reset $. each file
454     }
455
456 As a list operator:
457
458     for (101 .. 200) { print; } # print $_ 100 times
459     @foo = @foo[0 .. $#foo];    # an expensive no-op
460     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
461
462 The range operator (in list context) makes use of the magical
463 auto-increment algorithm if the operands are strings.  You
464 can say
465
466     @alphabet = ('A' .. 'Z');
467
468 to get all normal letters of the English alphabet, or
469
470     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
471
472 to get a hexadecimal digit, or
473
474     @z2 = ('01' .. '31');  print $z2[$mday];
475
476 to get dates with leading zeros.  If the final value specified is not
477 in the sequence that the magical increment would produce, the sequence
478 goes until the next value would be longer than the final value
479 specified.
480
481 =head2 Conditional Operator
482
483 Ternary "?:" is the conditional operator, just as in C.  It works much
484 like an if-then-else.  If the argument before the ? is true, the
485 argument before the : is returned, otherwise the argument after the :
486 is returned.  For example:
487
488     printf "I have %d dog%s.\n", $n,
489             ($n == 1) ? '' : "s";
490
491 Scalar or list context propagates downward into the 2nd
492 or 3rd argument, whichever is selected.
493
494     $a = $ok ? $b : $c;  # get a scalar
495     @a = $ok ? @b : @c;  # get an array
496     $a = $ok ? @b : @c;  # oops, that's just a count!
497
498 The operator may be assigned to if both the 2nd and 3rd arguments are
499 legal lvalues (meaning that you can assign to them):
500
501     ($a_or_b ? $a : $b) = $c;
502
503 Because this operator produces an assignable result, using assignments
504 without parentheses will get you in trouble.  For example, this:
505
506     $a % 2 ? $a += 10 : $a += 2
507
508 Really means this:
509
510     (($a % 2) ? ($a += 10) : $a) += 2
511
512 Rather than this:
513
514     ($a % 2) ? ($a += 10) : ($a += 2)
515
516 That should probably be written more simply as:
517
518     $a += ($a % 2) ? 10 : 2;
519
520 =head2 Assignment Operators
521
522 "=" is the ordinary assignment operator.
523
524 Assignment operators work as in C.  That is,
525
526     $a += 2;
527
528 is equivalent to
529
530     $a = $a + 2;
531
532 although without duplicating any side effects that dereferencing the lvalue
533 might trigger, such as from tie().  Other assignment operators work similarly.
534 The following are recognized:
535
536     **=    +=    *=    &=    <<=    &&=
537            -=    /=    |=    >>=    ||=
538            .=    %=    ^=
539                  x=
540
541 Although these are grouped by family, they all have the precedence
542 of assignment.
543
544 Unlike in C, the scalar assignment operator produces a valid lvalue.
545 Modifying an assignment is equivalent to doing the assignment and
546 then modifying the variable that was assigned to.  This is useful
547 for modifying a copy of something, like this:
548
549     ($tmp = $global) =~ tr [A-Z] [a-z];
550
551 Likewise,
552
553     ($a += 2) *= 3;
554
555 is equivalent to
556
557     $a += 2;
558     $a *= 3;
559
560 Similarly, a list assignment in list context produces the list of
561 lvalues assigned to, and a list assignment in scalar context returns
562 the number of elements produced by the expression on the right hand
563 side of the assignment.
564
565 =head2 Comma Operator
566
567 Binary "," is the comma operator.  In scalar context it evaluates
568 its left argument, throws that value away, then evaluates its right
569 argument and returns that value.  This is just like C's comma operator.
570
571 In list context, it's just the list argument separator, and inserts
572 both its arguments into the list.
573
574 The => digraph is mostly just a synonym for the comma operator.  It's useful for
575 documenting arguments that come in pairs.  As of release 5.001, it also forces
576 any word to the left of it to be interpreted as a string.
577
578 =head2 List Operators (Rightward)
579
580 On the right side of a list operator, it has very low precedence,
581 such that it controls all comma-separated expressions found there.
582 The only operators with lower precedence are the logical operators
583 "and", "or", and "not", which may be used to evaluate calls to list
584 operators without the need for extra parentheses:
585
586     open HANDLE, "filename"
587         or die "Can't open: $!\n";
588
589 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
590
591 =head2 Logical Not
592
593 Unary "not" returns the logical negation of the expression to its right.
594 It's the equivalent of "!" except for the very low precedence.
595
596 =head2 Logical And
597
598 Binary "and" returns the logical conjunction of the two surrounding
599 expressions.  It's equivalent to && except for the very low
600 precedence.  This means that it short-circuits: i.e., the right
601 expression is evaluated only if the left expression is true.
602
603 =head2 Logical or and Exclusive Or
604
605 Binary "or" returns the logical disjunction of the two surrounding
606 expressions.  It's equivalent to || except for the very low precedence.
607 This makes it useful for control flow
608
609     print FH $data              or die "Can't write to FH: $!";
610
611 This means that it short-circuits: i.e., the right expression is evaluated
612 only if the left expression is false.  Due to its precedence, you should
613 probably avoid using this for assignment, only for control flow.
614
615     $a = $b or $c;              # bug: this is wrong
616     ($a = $b) or $c;            # really means this
617     $a = $b || $c;              # better written this way
618
619 However, when it's a list-context assignment and you're trying to use
620 "||" for control flow, you probably need "or" so that the assignment
621 takes higher precedence.
622
623     @info = stat($file) || die;     # oops, scalar sense of stat!
624     @info = stat($file) or die;     # better, now @info gets its due
625
626 Then again, you could always use parentheses. 
627
628 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
629 It cannot short circuit, of course.
630
631 =head2 C Operators Missing From Perl
632
633 Here is what C has that Perl doesn't:
634
635 =over 8
636
637 =item unary &
638
639 Address-of operator.  (But see the "\" operator for taking a reference.)
640
641 =item unary *
642
643 Dereference-address operator. (Perl's prefix dereferencing
644 operators are typed: $, @, %, and &.)
645
646 =item (TYPE)
647
648 Type-casting operator.
649
650 =back
651
652 =head2 Quote and Quote-like Operators
653
654 While we usually think of quotes as literal values, in Perl they
655 function as operators, providing various kinds of interpolating and
656 pattern matching capabilities.  Perl provides customary quote characters
657 for these behaviors, but also provides a way for you to choose your
658 quote character for any of them.  In the following table, a C<{}> represents
659 any pair of delimiters you choose.  
660
661     Customary  Generic        Meaning        Interpolates
662         ''       q{}          Literal             no
663         ""      qq{}          Literal             yes
664         ``      qx{}          Command             yes*
665                 qw{}         Word list            no
666         //       m{}       Pattern match          yes*
667                 qr{}          Pattern             yes*
668                  s{}{}      Substitution          yes*
669                 tr{}{}    Transliteration         no (but see below)
670         <<EOF                 here-doc            yes*
671
672         * unless the delimiter is ''.
673
674 Non-bracketing delimiters use the same character fore and aft, but the four
675 sorts of brackets (round, angle, square, curly) will all nest, which means
676 that 
677
678         q{foo{bar}baz} 
679
680 is the same as 
681
682         'foo{bar}baz'
683
684 Note, however, that this does not always work for quoting Perl code:
685
686         $s = q{ if($a eq "}") ... }; # WRONG
687
688 is a syntax error. The C<Text::Balanced> module (from CPAN, and
689 starting from Perl 5.8 part of the standard distribution) is able
690 to do this properly.
691
692 There can be whitespace between the operator and the quoting
693 characters, except when C<#> is being used as the quoting character.
694 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
695 operator C<q> followed by a comment.  Its argument will be taken
696 from the next line.  This allows you to write:
697
698     s {foo}  # Replace foo
699       {bar}  # with bar.
700
701 The following escape sequences are available in constructs that interpolate
702 and in transliterations.
703
704     \t          tab             (HT, TAB)
705     \n          newline         (NL)
706     \r          return          (CR)
707     \f          form feed       (FF)
708     \b          backspace       (BS)
709     \a          alarm (bell)    (BEL)
710     \e          escape          (ESC)
711     \033        octal char      (ESC)
712     \x1b        hex char        (ESC)
713     \x{263a}    wide hex char   (SMILEY)
714     \c[         control char    (ESC)
715     \N{name}    named Unicode character
716
717 The following escape sequences are available in constructs that interpolate
718 but not in transliterations.
719
720     \l          lowercase next char
721     \u          uppercase next char
722     \L          lowercase till \E
723     \U          uppercase till \E
724     \E          end case modification
725     \Q          quote non-word characters till \E
726
727 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
728 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
729 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
730 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
731 C<\U> is as defined by Unicode.  For documentation of C<\N{name}>,
732 see L<charnames>.
733
734 All systems use the virtual C<"\n"> to represent a line terminator,
735 called a "newline".  There is no such thing as an unvarying, physical
736 newline character.  It is only an illusion that the operating system,
737 device drivers, C libraries, and Perl all conspire to preserve.  Not all
738 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
739 on a Mac, these are reversed, and on systems without line terminator,
740 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
741 you mean a "newline" for your system, but use the literal ASCII when you
742 need an exact character.  For example, most networking protocols expect
743 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
744 and although they often accept just C<"\012">, they seldom tolerate just
745 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
746 you may be burned some day.
747
748 For constructs that do interpolate, variables beginning with "C<$>"
749 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
750 C<$href->{key}[0]> are also interpolated, as are array and hash slices.
751 But method calls such as C<$obj->meth> are not.
752
753 Interpolating an array or slice interpolates the elements in order,
754 separated by the value of C<$">, so is equivalent to interpolating
755 C<join $", @array>.    "Punctuation" arrays such as C<@+> are only
756 interpolated if the name is enclosed in braces C<@{+}>.
757
758 You cannot include a literal C<$> or C<@> within a C<\Q> sequence. 
759 An unescaped C<$> or C<@> interpolates the corresponding variable, 
760 while escaping will cause the literal string C<\$> to be inserted.
761 You'll need to write something like C<m/\Quser\E\@\Qhost/>. 
762
763 Patterns are subject to an additional level of interpretation as a
764 regular expression.  This is done as a second pass, after variables are
765 interpolated, so that regular expressions may be incorporated into the
766 pattern from the variables.  If this is not what you want, use C<\Q> to
767 interpolate a variable literally.
768
769 Apart from the behavior described above, Perl does not expand
770 multiple levels of interpolation.  In particular, contrary to the
771 expectations of shell programmers, back-quotes do I<NOT> interpolate
772 within double quotes, nor do single quotes impede evaluation of
773 variables when used within double quotes.
774
775 =head2 Regexp Quote-Like Operators
776
777 Here are the quote-like operators that apply to pattern
778 matching and related activities.
779
780 =over 8
781
782 =item ?PATTERN?
783
784 This is just like the C</pattern/> search, except that it matches only
785 once between calls to the reset() operator.  This is a useful
786 optimization when you want to see only the first occurrence of
787 something in each file of a set of files, for instance.  Only C<??>
788 patterns local to the current package are reset.
789
790     while (<>) {
791         if (?^$?) {
792                             # blank line between header and body
793         }
794     } continue {
795         reset if eof;       # clear ?? status for next file
796     }
797
798 This usage is vaguely deprecated, which means it just might possibly
799 be removed in some distant future version of Perl, perhaps somewhere
800 around the year 2168.
801
802 =item m/PATTERN/cgimosx
803
804 =item /PATTERN/cgimosx
805
806 Searches a string for a pattern match, and in scalar context returns
807 true if it succeeds, false if it fails.  If no string is specified
808 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
809 string specified with C<=~> need not be an lvalue--it may be the
810 result of an expression evaluation, but remember the C<=~> binds
811 rather tightly.)  See also L<perlre>.  See L<perllocale> for
812 discussion of additional considerations that apply when C<use locale>
813 is in effect.
814
815 Options are:
816
817     c   Do not reset search position on a failed match when /g is in effect.
818     g   Match globally, i.e., find all occurrences.
819     i   Do case-insensitive pattern matching.
820     m   Treat string as multiple lines.
821     o   Compile pattern only once.
822     s   Treat string as single line.
823     x   Use extended regular expressions.
824
825 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
826 you can use any pair of non-alphanumeric, non-whitespace characters 
827 as delimiters.  This is particularly useful for matching path names
828 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
829 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
830 If "'" is the delimiter, no interpolation is performed on the PATTERN.
831
832 PATTERN may contain variables, which will be interpolated (and the
833 pattern recompiled) every time the pattern search is evaluated, except
834 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
835 C<$|> are not interpolated because they look like end-of-string tests.)
836 If you want such a pattern to be compiled only once, add a C</o> after
837 the trailing delimiter.  This avoids expensive run-time recompilations,
838 and is useful when the value you are interpolating won't change over
839 the life of the script.  However, mentioning C</o> constitutes a promise
840 that you won't change the variables in the pattern.  If you change them,
841 Perl won't even notice.  See also L<"qr/STRING/imosx">.
842
843 If the PATTERN evaluates to the empty string, the last
844 I<successfully> matched regular expression is used instead.
845
846 If the C</g> option is not used, C<m//> in list context returns a
847 list consisting of the subexpressions matched by the parentheses in the
848 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
849 also set, and that this differs from Perl 4's behavior.)  When there are
850 no parentheses in the pattern, the return value is the list C<(1)> for
851 success.  With or without parentheses, an empty list is returned upon
852 failure.
853
854 Examples:
855
856     open(TTY, '/dev/tty');
857     <TTY> =~ /^y/i && foo();    # do foo if desired
858
859     if (/Version: *([0-9.]*)/) { $version = $1; }
860
861     next if m#^/usr/spool/uucp#;
862
863     # poor man's grep
864     $arg = shift;
865     while (<>) {
866         print if /$arg/o;       # compile only once
867     }
868
869     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
870
871 This last example splits $foo into the first two words and the
872 remainder of the line, and assigns those three fields to $F1, $F2, and
873 $Etc.  The conditional is true if any variables were assigned, i.e., if
874 the pattern matched.
875
876 The C</g> modifier specifies global pattern matching--that is,
877 matching as many times as possible within the string.  How it behaves
878 depends on the context.  In list context, it returns a list of the
879 substrings matched by any capturing parentheses in the regular
880 expression.  If there are no parentheses, it returns a list of all
881 the matched strings, as if there were parentheses around the whole
882 pattern.
883
884 In scalar context, each execution of C<m//g> finds the next match,
885 returning true if it matches, and false if there is no further match.
886 The position after the last match can be read or set using the pos()
887 function; see L<perlfunc/pos>.   A failed match normally resets the
888 search position to the beginning of the string, but you can avoid that
889 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
890 string also resets the search position.
891
892 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
893 zero-width assertion that matches the exact position where the previous
894 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
895 still anchors at pos(), but the match is of course only attempted once.
896 Using C<\G> without C</g> on a target string that has not previously had a
897 C</g> match applied to it is the same as using the C<\A> assertion to match
898 the beginning of the string.
899
900 Examples:
901
902     # list context
903     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
904
905     # scalar context
906     $/ = "";
907     while (defined($paragraph = <>)) {
908         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
909             $sentences++;
910         }
911     }
912     print "$sentences\n";
913
914     # using m//gc with \G
915     $_ = "ppooqppqq";
916     while ($i++ < 2) {
917         print "1: '";
918         print $1 while /(o)/gc; print "', pos=", pos, "\n";
919         print "2: '";
920         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
921         print "3: '";
922         print $1 while /(p)/gc; print "', pos=", pos, "\n";
923     }
924     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
925
926 The last example should print:
927
928     1: 'oo', pos=4
929     2: 'q', pos=5
930     3: 'pp', pos=7
931     1: '', pos=7
932     2: 'q', pos=8
933     3: '', pos=8
934     Final: 'q', pos=8
935
936 Notice that the final match matched C<q> instead of C<p>, which a match
937 without the C<\G> anchor would have done. Also note that the final match
938 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
939 final match did indeed match C<p>, it's a good bet that you're running an
940 older (pre-5.6.0) Perl.
941
942 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
943 combine several regexps like this to process a string part-by-part,
944 doing different actions depending on which regexp matched.  Each
945 regexp tries to match where the previous one leaves off.
946
947  $_ = <<'EOL';
948       $url = new URI::URL "http://www/";   die if $url eq "xXx";
949  EOL
950  LOOP:
951     {
952       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
953       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
954       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
955       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
956       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
957       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
958       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
959       print ". That's all!\n";
960     }
961
962 Here is the output (split into several lines):
963
964  line-noise lowercase line-noise lowercase UPPERCASE line-noise
965  UPPERCASE line-noise lowercase line-noise lowercase line-noise
966  lowercase lowercase line-noise lowercase lowercase line-noise
967  MiXeD line-noise. That's all!
968
969 =item q/STRING/
970
971 =item C<'STRING'>
972
973 A single-quoted, literal string.  A backslash represents a backslash
974 unless followed by the delimiter or another backslash, in which case
975 the delimiter or backslash is interpolated.
976
977     $foo = q!I said, "You said, 'She said it.'"!;
978     $bar = q('This is it.');
979     $baz = '\n';                # a two-character string
980
981 =item qq/STRING/
982
983 =item "STRING"
984
985 A double-quoted, interpolated string.
986
987     $_ .= qq
988      (*** The previous line contains the naughty word "$1".\n)
989                 if /\b(tcl|java|python)\b/i;      # :-)
990     $baz = "\n";                # a one-character string
991
992 =item qr/STRING/imosx
993
994 This operator quotes (and possibly compiles) its I<STRING> as a regular
995 expression.  I<STRING> is interpolated the same way as I<PATTERN>
996 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
997 is done.  Returns a Perl value which may be used instead of the
998 corresponding C</STRING/imosx> expression.
999
1000 For example,
1001
1002     $rex = qr/my.STRING/is;
1003     s/$rex/foo/;
1004
1005 is equivalent to
1006
1007     s/my.STRING/foo/is;
1008
1009 The result may be used as a subpattern in a match:
1010
1011     $re = qr/$pattern/;
1012     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1013     $string =~ $re;             # or used standalone
1014     $string =~ /$re/;           # or this way
1015
1016 Since Perl may compile the pattern at the moment of execution of qr()
1017 operator, using qr() may have speed advantages in some situations,
1018 notably if the result of qr() is used standalone:
1019
1020     sub match {
1021         my $patterns = shift;
1022         my @compiled = map qr/$_/i, @$patterns;
1023         grep {
1024             my $success = 0;
1025             foreach my $pat (@compiled) {
1026                 $success = 1, last if /$pat/;
1027             }
1028             $success;
1029         } @_;
1030     }
1031
1032 Precompilation of the pattern into an internal representation at
1033 the moment of qr() avoids a need to recompile the pattern every
1034 time a match C</$pat/> is attempted.  (Perl has many other internal
1035 optimizations, but none would be triggered in the above example if
1036 we did not use qr() operator.)
1037
1038 Options are:
1039
1040     i   Do case-insensitive pattern matching.
1041     m   Treat string as multiple lines.
1042     o   Compile pattern only once.
1043     s   Treat string as single line.
1044     x   Use extended regular expressions.
1045
1046 See L<perlre> for additional information on valid syntax for STRING, and
1047 for a detailed look at the semantics of regular expressions.
1048
1049 =item qx/STRING/
1050
1051 =item `STRING`
1052
1053 A string which is (possibly) interpolated and then executed as a
1054 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1055 pipes, and redirections will be honored.  The collected standard
1056 output of the command is returned; standard error is unaffected.  In
1057 scalar context, it comes back as a single (potentially multi-line)
1058 string, or undef if the command failed.  In list context, returns a
1059 list of lines (however you've defined lines with $/ or
1060 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1061
1062 Because backticks do not affect standard error, use shell file descriptor
1063 syntax (assuming the shell supports this) if you care to address this.
1064 To capture a command's STDERR and STDOUT together:
1065
1066     $output = `cmd 2>&1`;
1067
1068 To capture a command's STDOUT but discard its STDERR:
1069
1070     $output = `cmd 2>/dev/null`;
1071
1072 To capture a command's STDERR but discard its STDOUT (ordering is
1073 important here):
1074
1075     $output = `cmd 2>&1 1>/dev/null`;
1076
1077 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1078 but leave its STDOUT to come out the old STDERR:
1079
1080     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1081
1082 To read both a command's STDOUT and its STDERR separately, it's easiest
1083 and safest to redirect them separately to files, and then read from those
1084 files when the program is done:
1085
1086     system("program args 1>/tmp/program.stdout 2>/tmp/program.stderr");
1087
1088 Using single-quote as a delimiter protects the command from Perl's
1089 double-quote interpolation, passing it on to the shell instead:
1090
1091     $perl_info  = qx(ps $$);            # that's Perl's $$
1092     $shell_info = qx'ps $$';            # that's the new shell's $$
1093
1094 How that string gets evaluated is entirely subject to the command
1095 interpreter on your system.  On most platforms, you will have to protect
1096 shell metacharacters if you want them treated literally.  This is in
1097 practice difficult to do, as it's unclear how to escape which characters.
1098 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1099 to emulate backticks safely.
1100
1101 On some platforms (notably DOS-like ones), the shell may not be
1102 capable of dealing with multiline commands, so putting newlines in
1103 the string may not get you what you want.  You may be able to evaluate
1104 multiple commands in a single line by separating them with the command
1105 separator character, if your shell supports that (e.g. C<;> on many Unix
1106 shells; C<&> on the Windows NT C<cmd> shell).
1107
1108 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1109 output before starting the child process, but this may not be supported
1110 on some platforms (see L<perlport>).  To be safe, you may need to set
1111 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1112 C<IO::Handle> on any open handles.
1113
1114 Beware that some command shells may place restrictions on the length
1115 of the command line.  You must ensure your strings don't exceed this
1116 limit after any necessary interpolations.  See the platform-specific
1117 release notes for more details about your particular environment.
1118
1119 Using this operator can lead to programs that are difficult to port,
1120 because the shell commands called vary between systems, and may in
1121 fact not be present at all.  As one example, the C<type> command under
1122 the POSIX shell is very different from the C<type> command under DOS.
1123 That doesn't mean you should go out of your way to avoid backticks
1124 when they're the right way to get something done.  Perl was made to be
1125 a glue language, and one of the things it glues together is commands.
1126 Just understand what you're getting yourself into.
1127
1128 See L<"I/O Operators"> for more discussion.
1129
1130 =item qw/STRING/
1131
1132 Evaluates to a list of the words extracted out of STRING, using embedded
1133 whitespace as the word delimiters.  It can be understood as being roughly
1134 equivalent to:
1135
1136     split(' ', q/STRING/);
1137
1138 the difference being that it generates a real list at compile time.  So
1139 this expression:
1140
1141     qw(foo bar baz)
1142
1143 is semantically equivalent to the list:
1144
1145     'foo', 'bar', 'baz'
1146
1147 Some frequently seen examples:
1148
1149     use POSIX qw( setlocale localeconv )
1150     @EXPORT = qw( foo bar baz );
1151
1152 A common mistake is to try to separate the words with comma or to
1153 put comments into a multi-line C<qw>-string.  For this reason, the
1154 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable) 
1155 produces warnings if the STRING contains the "," or the "#" character.
1156
1157 =item s/PATTERN/REPLACEMENT/egimosx
1158
1159 Searches a string for a pattern, and if found, replaces that pattern
1160 with the replacement text and returns the number of substitutions
1161 made.  Otherwise it returns false (specifically, the empty string).
1162
1163 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1164 variable is searched and modified.  (The string specified with C<=~> must
1165 be scalar variable, an array element, a hash element, or an assignment
1166 to one of those, i.e., an lvalue.)
1167
1168 If the delimiter chosen is a single quote, no interpolation is
1169 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1170 PATTERN contains a $ that looks like a variable rather than an
1171 end-of-string test, the variable will be interpolated into the pattern
1172 at run-time.  If you want the pattern compiled only once the first time
1173 the variable is interpolated, use the C</o> option.  If the pattern
1174 evaluates to the empty string, the last successfully executed regular
1175 expression is used instead.  See L<perlre> for further explanation on these.
1176 See L<perllocale> for discussion of additional considerations that apply
1177 when C<use locale> is in effect.
1178
1179 Options are:
1180
1181     e   Evaluate the right side as an expression.
1182     g   Replace globally, i.e., all occurrences.
1183     i   Do case-insensitive pattern matching.
1184     m   Treat string as multiple lines.
1185     o   Compile pattern only once.
1186     s   Treat string as single line.
1187     x   Use extended regular expressions.
1188
1189 Any non-alphanumeric, non-whitespace delimiter may replace the
1190 slashes.  If single quotes are used, no interpretation is done on the
1191 replacement string (the C</e> modifier overrides this, however).  Unlike
1192 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1193 text is not evaluated as a command.  If the
1194 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1195 pair of quotes, which may or may not be bracketing quotes, e.g.,
1196 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1197 replacement portion to be treated as a full-fledged Perl expression
1198 and evaluated right then and there.  It is, however, syntax checked at
1199 compile-time. A second C<e> modifier will cause the replacement portion
1200 to be C<eval>ed before being run as a Perl expression.
1201
1202 Examples:
1203
1204     s/\bgreen\b/mauve/g;                # don't change wintergreen
1205
1206     $path =~ s|/usr/bin|/usr/local/bin|;
1207
1208     s/Login: $foo/Login: $bar/; # run-time pattern
1209
1210     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1211
1212     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1213
1214     $_ = 'abc123xyz';
1215     s/\d+/$&*2/e;               # yields 'abc246xyz'
1216     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1217     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1218
1219     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1220     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1221     s/^=(\w+)/&pod($1)/ge;      # use function call
1222
1223     # expand variables in $_, but dynamics only, using
1224     # symbolic dereferencing
1225     s/\$(\w+)/${$1}/g;
1226
1227     # Add one to the value of any numbers in the string
1228     s/(\d+)/1 + $1/eg;
1229
1230     # This will expand any embedded scalar variable
1231     # (including lexicals) in $_ : First $1 is interpolated
1232     # to the variable name, and then evaluated
1233     s/(\$\w+)/$1/eeg;
1234
1235     # Delete (most) C comments.
1236     $program =~ s {
1237         /\*     # Match the opening delimiter.
1238         .*?     # Match a minimal number of characters.
1239         \*/     # Match the closing delimiter.
1240     } []gsx;
1241
1242     s/^\s*(.*?)\s*$/$1/;        # trim white space in $_, expensively
1243
1244     for ($variable) {           # trim white space in $variable, cheap
1245         s/^\s+//;
1246         s/\s+$//;
1247     }
1248
1249     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1250
1251 Note the use of $ instead of \ in the last example.  Unlike
1252 B<sed>, we use the \<I<digit>> form in only the left hand side.
1253 Anywhere else it's $<I<digit>>.
1254
1255 Occasionally, you can't use just a C</g> to get all the changes
1256 to occur that you might want.  Here are two common cases:
1257
1258     # put commas in the right places in an integer
1259     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;  
1260
1261     # expand tabs to 8-column spacing
1262     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1263
1264 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1265
1266 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1267
1268 Transliterates all occurrences of the characters found in the search list
1269 with the corresponding character in the replacement list.  It returns
1270 the number of characters replaced or deleted.  If no string is
1271 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1272 string specified with =~ must be a scalar variable, an array element, a
1273 hash element, or an assignment to one of those, i.e., an lvalue.)
1274
1275 A character range may be specified with a hyphen, so C<tr/A-J/0-9/> 
1276 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1277 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1278 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1279 its own pair of quotes, which may or may not be bracketing quotes,
1280 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1281
1282 Note that C<tr> does B<not> do regular expression character classes
1283 such as C<\d> or C<[:lower:]>.  The <tr> operator is not equivalent to
1284 the tr(1) utility.  If you want to map strings between lower/upper
1285 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1286 using the C<s> operator if you need regular expressions.
1287
1288 Note also that the whole range idea is rather unportable between
1289 character sets--and even within character sets they may cause results
1290 you probably didn't expect.  A sound principle is to use only ranges
1291 that begin from and end at either alphabets of equal case (a-e, A-E),
1292 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1293 character sets in full.
1294
1295 Options:
1296
1297     c   Complement the SEARCHLIST.
1298     d   Delete found but unreplaced characters.
1299     s   Squash duplicate replaced characters.
1300
1301 If the C</c> modifier is specified, the SEARCHLIST character set
1302 is complemented.  If the C</d> modifier is specified, any characters
1303 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1304 (Note that this is slightly more flexible than the behavior of some
1305 B<tr> programs, which delete anything they find in the SEARCHLIST,
1306 period.) If the C</s> modifier is specified, sequences of characters
1307 that were transliterated to the same character are squashed down
1308 to a single instance of the character.
1309
1310 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1311 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1312 than the SEARCHLIST, the final character is replicated till it is long
1313 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1314 This latter is useful for counting characters in a class or for
1315 squashing character sequences in a class.
1316
1317 Examples:
1318
1319     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1320
1321     $cnt = tr/*/*/;             # count the stars in $_
1322
1323     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1324
1325     $cnt = tr/0-9//;            # count the digits in $_
1326
1327     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1328
1329     ($HOST = $host) =~ tr/a-z/A-Z/;
1330
1331     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1332
1333     tr [\200-\377]
1334        [\000-\177];             # delete 8th bit
1335
1336 If multiple transliterations are given for a character, only the
1337 first one is used:
1338
1339     tr/AAA/XYZ/
1340
1341 will transliterate any A to X.
1342
1343 Because the transliteration table is built at compile time, neither
1344 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1345 interpolation.  That means that if you want to use variables, you
1346 must use an eval():
1347
1348     eval "tr/$oldlist/$newlist/";
1349     die $@ if $@;
1350
1351     eval "tr/$oldlist/$newlist/, 1" or die $@;
1352
1353 =item <<EOF
1354
1355 A line-oriented form of quoting is based on the shell "here-document"
1356 syntax.  Following a C<< << >> you specify a string to terminate
1357 the quoted material, and all lines following the current line down to
1358 the terminating string are the value of the item.  The terminating
1359 string may be either an identifier (a word), or some quoted text.  If
1360 quoted, the type of quotes you use determines the treatment of the
1361 text, just as in regular quoting.  An unquoted identifier works like
1362 double quotes.  There must be no space between the C<< << >> and
1363 the identifier, unless the identifier is quoted.  (If you put a space it
1364 will be treated as a null identifier, which is valid, and matches the first
1365 empty line.)  The terminating string must appear by itself (unquoted and
1366 with no surrounding whitespace) on the terminating line.
1367
1368        print <<EOF;
1369     The price is $Price.
1370     EOF
1371
1372        print << "EOF"; # same as above
1373     The price is $Price.
1374     EOF
1375
1376        print << `EOC`; # execute commands
1377     echo hi there
1378     echo lo there
1379     EOC
1380
1381        print <<"foo", <<"bar"; # you can stack them
1382     I said foo.
1383     foo
1384     I said bar.
1385     bar
1386
1387        myfunc(<< "THIS", 23, <<'THAT');
1388     Here's a line
1389     or two.
1390     THIS
1391     and here's another.
1392     THAT
1393
1394 Just don't forget that you have to put a semicolon on the end
1395 to finish the statement, as Perl doesn't know you're not going to
1396 try to do this:
1397
1398        print <<ABC
1399     179231
1400     ABC
1401        + 20;
1402
1403 If you want your here-docs to be indented with the 
1404 rest of the code, you'll need to remove leading whitespace
1405 from each line manually:
1406
1407     ($quote = <<'FINIS') =~ s/^\s+//gm;
1408        The Road goes ever on and on, 
1409        down from the door where it began.
1410     FINIS
1411
1412 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1413 the quoted material must come on the lines following the final delimiter.
1414 So instead of
1415
1416     s/this/<<E . 'that'
1417     the other
1418     E
1419      . 'more '/eg;
1420
1421 you have to write
1422
1423     s/this/<<E . 'that' 
1424      . 'more '/eg; 
1425     the other 
1426     E 
1427
1428 If the terminating identifier is on the last line of the program, you
1429 must be sure there is a newline after it; otherwise, Perl will give the
1430 warning B<Can't find string terminator "END" anywhere before EOF...>.
1431
1432 Additionally, the quoting rules for the identifier are not related to
1433 Perl's quoting rules -- C<q()>, C<qq()>, and the like are not supported
1434 in place of C<''> and C<"">, and the only interpolation is for backslashing
1435 the quoting character:
1436
1437     print << "abc\"def";
1438     testing...
1439     abc"def
1440
1441 Finally, quoted strings cannot span multiple lines.  The general rule is
1442 that the identifier must be a string literal.  Stick with that, and you
1443 should be safe.
1444
1445 =back
1446
1447 =head2 Gory details of parsing quoted constructs
1448
1449 When presented with something that might have several different
1450 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1451 principle to pick the most probable interpretation.  This strategy
1452 is so successful that Perl programmers often do not suspect the
1453 ambivalence of what they write.  But from time to time, Perl's
1454 notions differ substantially from what the author honestly meant.
1455
1456 This section hopes to clarify how Perl handles quoted constructs.
1457 Although the most common reason to learn this is to unravel labyrinthine
1458 regular expressions, because the initial steps of parsing are the
1459 same for all quoting operators, they are all discussed together.
1460
1461 The most important Perl parsing rule is the first one discussed
1462 below: when processing a quoted construct, Perl first finds the end
1463 of that construct, then interprets its contents.  If you understand
1464 this rule, you may skip the rest of this section on the first
1465 reading.  The other rules are likely to contradict the user's
1466 expectations much less frequently than this first one.
1467
1468 Some passes discussed below are performed concurrently, but because
1469 their results are the same, we consider them individually.  For different
1470 quoting constructs, Perl performs different numbers of passes, from
1471 one to five, but these passes are always performed in the same order.
1472
1473 =over 4
1474
1475 =item Finding the end
1476
1477 The first pass is finding the end of the quoted construct, whether
1478 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1479 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1480 terminates C<qq[]> construct, or a C<< > >> which terminates a
1481 fileglob started with C<< < >>.
1482
1483 When searching for single-character non-pairing delimiters, such
1484 as C</>, combinations of C<\\> and C<\/> are skipped.  However,
1485 when searching for single-character pairing delimiter like C<[>,
1486 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1487 C<[>, C<]> are skipped as well.  When searching for multicharacter
1488 delimiters, nothing is skipped.
1489
1490 For constructs with three-part delimiters (C<s///>, C<y///>, and
1491 C<tr///>), the search is repeated once more.
1492
1493 During this search no attention is paid to the semantics of the construct.
1494 Thus:
1495
1496     "$hash{"$foo/$bar"}"
1497
1498 or:
1499
1500     m/ 
1501       bar       # NOT a comment, this slash / terminated m//!
1502      /x
1503
1504 do not form legal quoted expressions.   The quoted part ends on the
1505 first C<"> and C</>, and the rest happens to be a syntax error.
1506 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1507 the example above is not C<m//x>, but rather C<m//> with no C</x>
1508 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1509
1510 =item Removal of backslashes before delimiters
1511
1512 During the second pass, text between the starting and ending
1513 delimiters is copied to a safe location, and the C<\> is removed
1514 from combinations consisting of C<\> and delimiter--or delimiters,
1515 meaning both starting and ending delimiters will should these differ.
1516 This removal does not happen for multi-character delimiters.
1517 Note that the combination C<\\> is left intact, just as it was.
1518
1519 Starting from this step no information about the delimiters is
1520 used in parsing.
1521
1522 =item Interpolation
1523
1524 The next step is interpolation in the text obtained, which is now
1525 delimiter-independent.  There are four different cases.
1526
1527 =over 4
1528
1529 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1530
1531 No interpolation is performed.
1532
1533 =item C<''>, C<q//>
1534
1535 The only interpolation is removal of C<\> from pairs C<\\>.
1536
1537 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>
1538
1539 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1540 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1541 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1542 The other combinations are replaced with appropriate expansions.
1543
1544 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1545 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1546 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1547 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1548 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1549 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1550 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1551
1552   $str = '\t';
1553   return "\Q$str";
1554
1555 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1556
1557 Interpolated scalars and arrays are converted internally to the C<join> and
1558 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1559
1560   $foo . " XXX '" . (join $", @arr) . "'";
1561
1562 All operations above are performed simultaneously, left to right.
1563
1564 Because the result of C<"\Q STRING \E"> has all metacharacters
1565 quoted, there is no way to insert a literal C<$> or C<@> inside a
1566 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1567 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1568 scalar.
1569
1570 Note also that the interpolation code needs to make a decision on
1571 where the interpolated scalar ends.  For instance, whether 
1572 C<< "a $b -> {c}" >> really means:
1573
1574   "a " . $b . " -> {c}";
1575
1576 or:
1577
1578   "a " . $b -> {c};
1579
1580 Most of the time, the longest possible text that does not include
1581 spaces between components and which contains matching braces or
1582 brackets.  because the outcome may be determined by voting based
1583 on heuristic estimators, the result is not strictly predictable.
1584 Fortunately, it's usually correct for ambiguous cases.
1585
1586 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, 
1587
1588 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1589 happens (almost) as with C<qq//> constructs, but the substitution
1590 of C<\> followed by RE-special chars (including C<\>) is not
1591 performed.  Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1592 a C<#>-comment in a C<//x>-regular expression, no processing is
1593 performed whatsoever.  This is the first step at which the presence
1594 of the C<//x> modifier is relevant.
1595
1596 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1597 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1598 different estimators) to be either an array element or C<$var>
1599 followed by an RE alternative.  This is where the notation
1600 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1601 array element C<-9>, not as a regular expression from the variable
1602 C<$arr> followed by a digit, which would be the interpretation of
1603 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1604 the result is not predictable.
1605
1606 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1607 the replacement text of C<s///> to correct the incorrigible
1608 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1609 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1610 (that is, the C<$^W> variable) was set.
1611
1612 The lack of processing of C<\\> creates specific restrictions on
1613 the post-processed text.  If the delimiter is C</>, one cannot get
1614 the combination C<\/> into the result of this step.  C</> will
1615 finish the regular expression, C<\/> will be stripped to C</> on
1616 the previous step, and C<\\/> will be left as is.  Because C</> is
1617 equivalent to C<\/> inside a regular expression, this does not
1618 matter unless the delimiter happens to be character special to the
1619 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1620 alphanumeric char, as in:
1621
1622   m m ^ a \s* b mmx;
1623
1624 In the RE above, which is intentionally obfuscated for illustration, the
1625 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1626 RE is the same as for C<m/ ^ a s* b /mx>).  There's more than one 
1627 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1628 non-whitespace choices.
1629
1630 =back
1631
1632 This step is the last one for all constructs except regular expressions,
1633 which are processed further.
1634
1635 =item Interpolation of regular expressions
1636
1637 Previous steps were performed during the compilation of Perl code,
1638 but this one happens at run time--although it may be optimized to
1639 be calculated at compile time if appropriate.  After preprocessing
1640 described above, and possibly after evaluation if catenation,
1641 joining, casing translation, or metaquoting are involved, the
1642 resulting I<string> is passed to the RE engine for compilation.
1643
1644 Whatever happens in the RE engine might be better discussed in L<perlre>,
1645 but for the sake of continuity, we shall do so here.
1646
1647 This is another step where the presence of the C<//x> modifier is
1648 relevant.  The RE engine scans the string from left to right and
1649 converts it to a finite automaton.
1650
1651 Backslashed characters are either replaced with corresponding
1652 literal strings (as with C<\{>), or else they generate special nodes
1653 in the finite automaton (as with C<\b>).  Characters special to the
1654 RE engine (such as C<|>) generate corresponding nodes or groups of
1655 nodes.  C<(?#...)> comments are ignored.  All the rest is either
1656 converted to literal strings to match, or else is ignored (as is
1657 whitespace and C<#>-style comments if C<//x> is present).
1658
1659 Parsing of the bracketed character class construct, C<[...]>, is
1660 rather different than the rule used for the rest of the pattern.
1661 The terminator of this construct is found using the same rules as
1662 for finding the terminator of a C<{}>-delimited construct, the only
1663 exception being that C<]> immediately following C<[> is treated as
1664 though preceded by a backslash.  Similarly, the terminator of
1665 C<(?{...})> is found using the same rules as for finding the
1666 terminator of a C<{}>-delimited construct.
1667
1668 It is possible to inspect both the string given to RE engine and the
1669 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
1670 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1671 switch documented in L<perlrun/"Command Switches">.
1672
1673 =item Optimization of regular expressions
1674
1675 This step is listed for completeness only.  Since it does not change
1676 semantics, details of this step are not documented and are subject
1677 to change without notice.  This step is performed over the finite
1678 automaton that was generated during the previous pass.
1679
1680 It is at this stage that C<split()> silently optimizes C</^/> to
1681 mean C</^/m>.
1682
1683 =back
1684
1685 =head2 I/O Operators
1686
1687 There are several I/O operators you should know about.
1688
1689 A string enclosed by backticks (grave accents) first undergoes
1690 double-quote interpolation.  It is then interpreted as an external
1691 command, and the output of that command is the value of the
1692 backtick string, like in a shell.  In scalar context, a single string
1693 consisting of all output is returned.  In list context, a list of
1694 values is returned, one per line of output.  (You can set C<$/> to use
1695 a different line terminator.)  The command is executed each time the
1696 pseudo-literal is evaluated.  The status value of the command is
1697 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
1698 Unlike in B<csh>, no translation is done on the return data--newlines
1699 remain newlines.  Unlike in any of the shells, single quotes do not
1700 hide variable names in the command from interpretation.  To pass a
1701 literal dollar-sign through to the shell you need to hide it with a
1702 backslash.  The generalized form of backticks is C<qx//>.  (Because
1703 backticks always undergo shell expansion as well, see L<perlsec> for
1704 security concerns.)
1705
1706 In scalar context, evaluating a filehandle in angle brackets yields
1707 the next line from that file (the newline, if any, included), or
1708 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
1709 (sometimes known as file-slurp mode) and the file is empty, it
1710 returns C<''> the first time, followed by C<undef> subsequently.
1711
1712 Ordinarily you must assign the returned value to a variable, but
1713 there is one situation where an automatic assignment happens.  If
1714 and only if the input symbol is the only thing inside the conditional
1715 of a C<while> statement (even if disguised as a C<for(;;)> loop),
1716 the value is automatically assigned to the global variable $_,
1717 destroying whatever was there previously.  (This may seem like an
1718 odd thing to you, but you'll use the construct in almost every Perl
1719 script you write.)  The $_ variable is not implicitly localized.
1720 You'll have to put a C<local $_;> before the loop if you want that
1721 to happen.
1722
1723 The following lines are equivalent:
1724
1725     while (defined($_ = <STDIN>)) { print; }
1726     while ($_ = <STDIN>) { print; }
1727     while (<STDIN>) { print; }
1728     for (;<STDIN>;) { print; }
1729     print while defined($_ = <STDIN>);
1730     print while ($_ = <STDIN>);
1731     print while <STDIN>;
1732
1733 This also behaves similarly, but avoids $_ :
1734
1735     while (my $line = <STDIN>) { print $line }    
1736
1737 In these loop constructs, the assigned value (whether assignment
1738 is automatic or explicit) is then tested to see whether it is
1739 defined.  The defined test avoids problems where line has a string
1740 value that would be treated as false by Perl, for example a "" or
1741 a "0" with no trailing newline.  If you really mean for such values
1742 to terminate the loop, they should be tested for explicitly:
1743
1744     while (($_ = <STDIN>) ne '0') { ... }
1745     while (<STDIN>) { last unless $_; ... }
1746
1747 In other boolean contexts, C<< <I<filehandle>> >> without an
1748 explicit C<defined> test or comparison elicit a warning if the 
1749 C<use warnings> pragma or the B<-w>
1750 command-line switch (the C<$^W> variable) is in effect.
1751
1752 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
1753 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
1754 in packages, where they would be interpreted as local identifiers
1755 rather than global.)  Additional filehandles may be created with
1756 the open() function, amongst others.  See L<perlopentut> and
1757 L<perlfunc/open> for details on this.
1758
1759 If a <FILEHANDLE> is used in a context that is looking for
1760 a list, a list comprising all input lines is returned, one line per
1761 list element.  It's easy to grow to a rather large data space this
1762 way, so use with care.
1763
1764 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
1765 See L<perlfunc/readline>.
1766
1767 The null filehandle <> is special: it can be used to emulate the
1768 behavior of B<sed> and B<awk>.  Input from <> comes either from
1769 standard input, or from each file listed on the command line.  Here's
1770 how it works: the first time <> is evaluated, the @ARGV array is
1771 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
1772 gives you standard input.  The @ARGV array is then processed as a list
1773 of filenames.  The loop
1774
1775     while (<>) {
1776         ...                     # code for each line
1777     }
1778
1779 is equivalent to the following Perl-like pseudo code:
1780
1781     unshift(@ARGV, '-') unless @ARGV;
1782     while ($ARGV = shift) {
1783         open(ARGV, $ARGV);
1784         while (<ARGV>) {
1785             ...         # code for each line
1786         }
1787     }
1788
1789 except that it isn't so cumbersome to say, and will actually work.
1790 It really does shift the @ARGV array and put the current filename
1791 into the $ARGV variable.  It also uses filehandle I<ARGV>
1792 internally--<> is just a synonym for <ARGV>, which
1793 is magical.  (The pseudo code above doesn't work because it treats
1794 <ARGV> as non-magical.)
1795
1796 You can modify @ARGV before the first <> as long as the array ends up
1797 containing the list of filenames you really want.  Line numbers (C<$.>)
1798 continue as though the input were one big happy file.  See the example
1799 in L<perlfunc/eof> for how to reset line numbers on each file.
1800
1801 If you want to set @ARGV to your own list of files, go right ahead.  
1802 This sets @ARGV to all plain text files if no @ARGV was given:
1803
1804     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
1805
1806 You can even set them to pipe commands.  For example, this automatically
1807 filters compressed arguments through B<gzip>:
1808
1809     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
1810
1811 If you want to pass switches into your script, you can use one of the
1812 Getopts modules or put a loop on the front like this:
1813
1814     while ($_ = $ARGV[0], /^-/) {
1815         shift;
1816         last if /^--$/;
1817         if (/^-D(.*)/) { $debug = $1 }
1818         if (/^-v/)     { $verbose++  }
1819         # ...           # other switches
1820     }
1821
1822     while (<>) {
1823         # ...           # code for each line
1824     }
1825
1826 The <> symbol will return C<undef> for end-of-file only once.  
1827 If you call it again after this, it will assume you are processing another 
1828 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
1829
1830 If what the angle brackets contain is a simple scalar variable (e.g.,
1831 <$foo>), then that variable contains the name of the
1832 filehandle to input from, or its typeglob, or a reference to the
1833 same.  For example:
1834
1835     $fh = \*STDIN;
1836     $line = <$fh>;
1837
1838 If what's within the angle brackets is neither a filehandle nor a simple
1839 scalar variable containing a filehandle name, typeglob, or typeglob
1840 reference, it is interpreted as a filename pattern to be globbed, and
1841 either a list of filenames or the next filename in the list is returned,
1842 depending on context.  This distinction is determined on syntactic
1843 grounds alone.  That means C<< <$x> >> is always a readline() from
1844 an indirect handle, but C<< <$hash{key}> >> is always a glob().
1845 That's because $x is a simple scalar variable, but C<$hash{key}> is
1846 not--it's a hash element.
1847
1848 One level of double-quote interpretation is done first, but you can't
1849 say C<< <$foo> >> because that's an indirect filehandle as explained
1850 in the previous paragraph.  (In older versions of Perl, programmers
1851 would insert curly brackets to force interpretation as a filename glob:
1852 C<< <${foo}> >>.  These days, it's considered cleaner to call the
1853 internal function directly as C<glob($foo)>, which is probably the right
1854 way to have done it in the first place.)  For example:
1855
1856     while (<*.c>) {
1857         chmod 0644, $_;
1858     }
1859
1860 is roughly equivalent to:
1861
1862     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
1863     while (<FOO>) {
1864         chomp;
1865         chmod 0644, $_;
1866     }
1867
1868 except that the globbing is actually done internally using the standard
1869 C<File::Glob> extension.  Of course, the shortest way to do the above is:
1870
1871     chmod 0644, <*.c>;
1872
1873 A (file)glob evaluates its (embedded) argument only when it is
1874 starting a new list.  All values must be read before it will start
1875 over.  In list context, this isn't important because you automatically
1876 get them all anyway.  However, in scalar context the operator returns
1877 the next value each time it's called, or C<undef> when the list has
1878 run out.  As with filehandle reads, an automatic C<defined> is
1879 generated when the glob occurs in the test part of a C<while>,
1880 because legal glob returns (e.g. a file called F<0>) would otherwise
1881 terminate the loop.  Again, C<undef> is returned only once.  So if
1882 you're expecting a single value from a glob, it is much better to
1883 say
1884
1885     ($file) = <blurch*>;
1886
1887 than
1888
1889     $file = <blurch*>;
1890
1891 because the latter will alternate between returning a filename and
1892 returning false.
1893
1894 If you're trying to do variable interpolation, it's definitely better
1895 to use the glob() function, because the older notation can cause people
1896 to become confused with the indirect filehandle notation.
1897
1898     @files = glob("$dir/*.[ch]");
1899     @files = glob($files[$i]);
1900
1901 =head2 Constant Folding
1902
1903 Like C, Perl does a certain amount of expression evaluation at
1904 compile time whenever it determines that all arguments to an
1905 operator are static and have no side effects.  In particular, string
1906 concatenation happens at compile time between literals that don't do
1907 variable substitution.  Backslash interpolation also happens at
1908 compile time.  You can say
1909
1910     'Now is the time for all' . "\n" .
1911         'good men to come to.'
1912
1913 and this all reduces to one string internally.  Likewise, if
1914 you say
1915
1916     foreach $file (@filenames) {
1917         if (-s $file > 5 + 100 * 2**16) {  }
1918     }
1919
1920 the compiler will precompute the number which that expression
1921 represents so that the interpreter won't have to.
1922
1923 =head2 Bitwise String Operators
1924
1925 Bitstrings of any size may be manipulated by the bitwise operators
1926 (C<~ | & ^>).
1927
1928 If the operands to a binary bitwise op are strings of different
1929 sizes, B<|> and B<^> ops act as though the shorter operand had
1930 additional zero bits on the right, while the B<&> op acts as though
1931 the longer operand were truncated to the length of the shorter.
1932 The granularity for such extension or truncation is one or more
1933 bytes.
1934
1935     # ASCII-based examples 
1936     print "j p \n" ^ " a h";            # prints "JAPH\n"
1937     print "JA" | "  ph\n";              # prints "japh\n"
1938     print "japh\nJunk" & '_____';       # prints "JAPH\n";
1939     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
1940
1941 If you are intending to manipulate bitstrings, be certain that
1942 you're supplying bitstrings: If an operand is a number, that will imply
1943 a B<numeric> bitwise operation.  You may explicitly show which type of
1944 operation you intend by using C<""> or C<0+>, as in the examples below.
1945
1946     $foo =  150  |  105 ;       # yields 255  (0x96 | 0x69 is 0xFF)
1947     $foo = '150' |  105 ;       # yields 255
1948     $foo =  150  | '105';       # yields 255
1949     $foo = '150' | '105';       # yields string '155' (under ASCII)
1950
1951     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
1952     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
1953
1954 See L<perlfunc/vec> for information on how to manipulate individual bits
1955 in a bit vector.
1956
1957 =head2 Integer Arithmetic
1958
1959 By default, Perl assumes that it must do most of its arithmetic in
1960 floating point.  But by saying
1961
1962     use integer;
1963
1964 you may tell the compiler that it's okay to use integer operations
1965 (if it feels like it) from here to the end of the enclosing BLOCK.
1966 An inner BLOCK may countermand this by saying
1967
1968     no integer;
1969
1970 which lasts until the end of that BLOCK.  Note that this doesn't
1971 mean everything is only an integer, merely that Perl may use integer
1972 operations if it is so inclined.  For example, even under C<use
1973 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
1974 or so.
1975
1976 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
1977 and ">>") always produce integral results.  (But see also 
1978 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
1979 them.  By default, their results are interpreted as unsigned integers, but
1980 if C<use integer> is in effect, their results are interpreted
1981 as signed integers.  For example, C<~0> usually evaluates to a large
1982 integral value.  However, C<use integer; ~0> is C<-1> on twos-complement
1983 machines.
1984
1985 =head2 Floating-point Arithmetic
1986
1987 While C<use integer> provides integer-only arithmetic, there is no
1988 analogous mechanism to provide automatic rounding or truncation to a
1989 certain number of decimal places.  For rounding to a certain number
1990 of digits, sprintf() or printf() is usually the easiest route.
1991 See L<perlfaq4>.
1992
1993 Floating-point numbers are only approximations to what a mathematician
1994 would call real numbers.  There are infinitely more reals than floats,
1995 so some corners must be cut.  For example:
1996
1997     printf "%.20g\n", 123456789123456789;
1998     #        produces 123456789123456784
1999
2000 Testing for exact equality of floating-point equality or inequality is
2001 not a good idea.  Here's a (relatively expensive) work-around to compare
2002 whether two floating-point numbers are equal to a particular number of
2003 decimal places.  See Knuth, volume II, for a more robust treatment of
2004 this topic.
2005
2006     sub fp_equal {
2007         my ($X, $Y, $POINTS) = @_;
2008         my ($tX, $tY);
2009         $tX = sprintf("%.${POINTS}g", $X);
2010         $tY = sprintf("%.${POINTS}g", $Y);
2011         return $tX eq $tY;
2012     }
2013
2014 The POSIX module (part of the standard perl distribution) implements
2015 ceil(), floor(), and other mathematical and trigonometric functions.
2016 The Math::Complex module (part of the standard perl distribution)
2017 defines mathematical functions that work on both the reals and the
2018 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2019 POSIX can't work with complex numbers.
2020
2021 Rounding in financial applications can have serious implications, and
2022 the rounding method used should be specified precisely.  In these
2023 cases, it probably pays not to trust whichever system rounding is
2024 being used by Perl, but to instead implement the rounding function you
2025 need yourself.
2026
2027 =head2 Bigger Numbers
2028
2029 The standard Math::BigInt and Math::BigFloat modules provide
2030 variable-precision arithmetic and overloaded operators, although
2031 they're currently pretty slow. At the cost of some space and
2032 considerable speed, they avoid the normal pitfalls associated with
2033 limited-precision representations.
2034
2035     use Math::BigInt;
2036     $x = Math::BigInt->new('123456789123456789');
2037     print $x * $x;
2038
2039     # prints +15241578780673678515622620750190521
2040
2041 There are several modules that let you calculate with (bound only by
2042 memory and cpu-time) unlimited or fixed precision. There are also
2043 some non-standard modules that provide faster implementations via
2044 external C libraries.
2045
2046 Here is a short, but incomplete summary:
2047
2048         Math::Fraction          big, unlimited fractions like 9973 / 12967
2049         Math::String            treat string sequences like numbers
2050         Math::FixedPrecision    calculate with a fixed precision
2051         Math::Currency          for currency calculations
2052         Bit::Vector             manipulate bit vectors fast (uses C)
2053         Math::BigIntFast        Bit::Vector wrapper for big numbers
2054         Math::Pari              provides access to the Pari C library
2055         Math::BigInteger        uses an external C library
2056         Math::Cephes            uses external Cephes C library (no big numbers)
2057         Math::Cephes::Fraction  fractions via the Cephes library
2058         Math::GMP               another one using an external C library
2059
2060 Choose wisely.
2061
2062 =cut