t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     require './test.pl';        # for which_perl() etc
   6     set_up_inc('../lib');
   7 }
   8
   9 use strict;
  10 use warnings;
  11 use Config;
  12
  13 my ($Null, $Curdir);
  14 if(eval {require File::Spec; 1}) {
  15     $Null = File::Spec->devnull;
  16     $Curdir = File::Spec->curdir;
  17 } else {
  18     die $@ unless is_miniperl();
  19     $Curdir = '.';
  20     diag("miniperl failed to load File::Spec, error is:\n$@");
  21     diag("\ncontinuing, assuming '.' for current directory. Some tests will be skipped.");
  22 }
  23
  24 if ($^O eq 'MSWin32') {
  25     # under minitest, buildcustomize sets this to 1, which means
  26     # nlinks isn't populated properly, allow nlinks tests to pass
  27     ${^WIN32_SLOPPY_STAT} = 0;
  28 }
  29
  30 plan tests => 110;
  31
  32 my $Perl = which_perl();
  33
  34 $ENV{LC_ALL}   = 'C';           # Forge English error messages.
  35 $ENV{LANGUAGE} = 'C';           # Ditto in GNU.
  36
  37 my $Is_Amiga   = $^O eq 'amigaos';
  38 my $Is_Cygwin  = $^O eq 'cygwin';
  39 my $Is_Darwin  = $^O eq 'darwin';
  40 my $Is_Dos     = $^O eq 'dos';
  41 my $Is_MSWin32 = $^O eq 'MSWin32';
  42 my $Is_NetWare = $^O eq 'NetWare';
  43 my $Is_OS2     = $^O eq 'os2';
  44 my $Is_Solaris = $^O eq 'solaris';
  45 my $Is_VMS     = $^O eq 'VMS';
  46 my $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  47 my $Is_Android = $^O =~ /android/;
  48 my $Is_Dfly    = $^O eq 'dragonfly';
  49
  50 my $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare;
  51
  52 my $ufs_no_ctime = ($Is_Dfly || $Is_Darwin) && (() = `df -t ufs . 2>/dev/null`) == 2;
  53
  54 my $Is_linux_container = is_linux_container();
  55
  56 if ($Is_Cygwin && !is_miniperl) {
  57   require Win32;
  58   Win32->import;
  59 }
  60
  61 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  62    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  63
  64 my $tmpfile = tempfile();
  65 my $tmpfile_link = tempfile();
  66
  67 chmod 0666, $tmpfile;
  68 unlink_all $tmpfile;
  69 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  70 close FOO;
  71
  72 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  73
  74 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  75
  76 # The clock on a network filesystem might be different from the
  77 # system clock.
  78 my $Filesystem_Time_Offset = abs($mtime - time);
  79
  80 #nlink should if link support configured in Perl.
  81 SKIP: {
  82     skip "No link count - Hard link support not built in.", 1
  83         unless $Config{d_link};
  84
  85     is($nlink, 1, 'nlink on regular file');
  86 }
  87
  88 SKIP: {
  89   skip "mtime and ctime not reliable", 2
  90     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_Darwin;
  91
  92   ok( $mtime,           'mtime' );
  93   is( $mtime, $ctime,   'mtime == ctime' );
  94 }
  95
  96
  97 # Cygwin seems to have a 3 second granularity on its timestamps.
  98 my $funky_FAT_timestamps = $Is_Cygwin;
  99 sleep 3 if $funky_FAT_timestamps;
 100
 101 print FOO "Now is the time for all good men to come to.\n";
 102 close(FOO);
 103
 104 sleep 2;
 105
 106 my $has_link = 1;
 107 my $inaccurate_atime = 0;
 108 if (defined &Win32::IsWinNT && Win32::IsWinNT()) {
 109     if (Win32::FsType() ne 'NTFS') {
 110         $has_link            = 0;
 111         $inaccurate_atime    = 1;
 112     }
 113 }
 114
 115 SKIP: {
 116     skip "No link on this filesystem", 6 unless $has_link;
 117     unlink $tmpfile_link;
 118     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
 119     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
 120
 121     is( $@, '',         'link() implemented' );
 122     ok( $lnk_result,    'linked tmp testfile' );
 123     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
 124
 125     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
 126
 127     SKIP: {
 128         skip "No link count", 1 if $Config{dont_use_nlink};
 129         skip "Cygwin9X fakes hard links by copying", 1
 130           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
 131
 132         is($nlink, 2,     'Link count on hard linked file' );
 133     }
 134
 135     SKIP: {
 136         skip_if_miniperl("File::Spec not built for minitest", 2);
 137         my $cwd = File::Spec->rel2abs($Curdir);
 138         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 139                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 140                                         $mtime && $mtime == $ctime;
 141         skip "AFS has different mtime/ctime link semantics", 2
 142                                      if $cwd =~ m#$Config{'afsroot'}/#;
 143         skip "AmigaOS has different mtime/ctime link semantics", 2
 144                                      if $Is_Amiga;
 145         # Win32 could pass $mtime test but as FAT and NTFS have
 146         # no ctime concept $ctime is ALWAYS == $mtime
 147         # expect netware to be the same ...
 148         skip "No ctime concept on this OS", 2
 149                                      if $Is_MSWin32 || $ufs_no_ctime;
 150         my $ok_mtime = ok($mtime, 'hard link mtime');
 151         local our $TODO;
 152         # https://bugs.dragonflybsd.org/issues/3251
 153         # this might be hammer/hammer2 specific
 154         $TODO = "DragonFly BSD doesn't touch ctime on link()/chmod"
 155             if $^O eq "dragonfly" && $Config{myuname} =~ /5\.8/;
 156         if(!$ok_mtime ||
 157             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 158             print STDERR <<DIAG;
 159 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 160 # has this problem.  Building on the ClearCase VOBS filesystem may also
 161 # cause this failure.
 162 #
 163 # Some UFS implementations don't have a ctime concept, and thus are
 164 # expected to fail this test.
 165 DIAG
 166         }
 167     }
 168
 169 }
 170
 171 # truncate and touch $tmpfile.
 172 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 173 ok(-z \*F,     '-z on empty filehandle');
 174 ok(! -s \*F,   '   and -s');
 175 close F;
 176
 177 ok(-z $tmpfile,     '-z on empty file');
 178 ok(! -s $tmpfile,   '   and -s');
 179
 180 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 181 print F "hi\n";
 182 close F;
 183
 184 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 185 ok(!-z *F,     '-z on empty filehandle');
 186 ok( -s *F,   '   and -s');
 187 close F;
 188
 189 ok(! -z $tmpfile,   '-z on non-empty file');
 190 ok(-s $tmpfile,     '   and -s');
 191
 192
 193 # Strip all access rights from the file.
 194 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 195
 196 SKIP: {
 197     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 198
 199     SKIP: {
 200         # Going to try to switch away from root.  Might not work.
 201         my $olduid = $>;
 202         eval { $> = 1; };
 203         skip "Can't test -r or -w meaningfully if you're superuser", 2
 204           if ($Is_Cygwin ? _ingroup(544, 1) : $> == 0);
 205
 206         SKIP: {
 207             skip "Can't test -r meaningfully?", 1 if $Is_Dos;
 208             ok(!-r $tmpfile,    "   -r");
 209         }
 210
 211         ok(!-w $tmpfile,    "   -w");
 212
 213         # switch uid back (may not be implemented)
 214         eval { $> = $olduid; };
 215     }
 216
 217     ok(! -x $tmpfile,   '   -x');
 218 }
 219
 220
 221
 222 ok(chmod(0700,$tmpfile),    'chmod 0700');
 223 ok(-r $tmpfile,     '   -r');
 224 ok(-w $tmpfile,     '   -w');
 225
 226 SKIP: {
 227     skip "-x simply determines if a file ends in an executable suffix", 1
 228       if $Is_Dosish;
 229
 230     ok(-x $tmpfile,     '   -x');
 231 }
 232
 233 ok(  -f $tmpfile,   '   -f');
 234 ok(! -d $tmpfile,   '   !-d');
 235
 236 # Is this portable?
 237 ok(  -d '.',          '-d cwd' );
 238 ok(! -f '.',          '!-f cwd' );
 239
 240
 241 SKIP: {
 242     unlink($tmpfile_link);
 243     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 244     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 245
 246     is( $@, '',     'symlink() implemented' );
 247     ok( $symlink_rslt,      'symlink() ok' );
 248     ok(-l $tmpfile_link,    '-l');
 249 }
 250
 251 ok(-o $tmpfile,     '-o');
 252
 253 ok(-e $tmpfile,     '-e');
 254
 255 unlink($tmpfile_link);
 256 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 257
 258 SKIP: {
 259     skip "No character, socket or block special files", 6
 260       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 261     skip "/dev isn't available to test against", 6
 262       unless -d '/dev' && -r '/dev' && -x '/dev';
 263     skip "Skipping: unexpected ls output in MP-RAS", 6
 264       if $Is_MPRAS;
 265
 266     # VMS problem:  If GNV or other UNIX like tool is installed, then
 267     # sometimes Perl will find /bin/ls, and will try to run it.
 268     # But since Perl on VMS does not know to run it under Bash, it will
 269     # try to run the DCL verb LS.  And if the VMS product Language
 270     # Sensitive Editor is installed, or some other LS verb, that will
 271     # be run instead.  So do not do this until we can teach Perl
 272     # when to use BASH on VMS.
 273     skip "ls command not available to Perl in OpenVMS right now.", 6
 274       if $Is_VMS;
 275
 276     delete $ENV{CLICOLOR_FORCE};
 277     my $LS  = $Config{d_readlink} && !$Is_Android ? "ls -lL" : "ls -l";
 278     my $CMD = "$LS /dev 2>/dev/null";
 279     my $DEV = qx($CMD);
 280
 281     skip "$CMD failed", 6 if $DEV eq '';
 282
 283     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 284
 285     skip "opendir failed: $!", 6 if @DEV == 0;
 286
 287     # /dev/stdout might be either character special or a named pipe,
 288     # or a symlink, or a socket, depending on which OS and how are
 289     # you running the test, so let's censor that one away.
 290     # Similar remarks hold for stderr.
 291     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 292     @DEV =  grep { $_ ne 'stdout' } @DEV;
 293     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 294     @DEV =  grep { $_ ne 'stderr' } @DEV;
 295
 296     # /dev/printer is also naughty: in IRIX it shows up as
 297     # Srwx-----, not srwx------.
 298     $DEV =~ s{^.+?\sprinter$}{}m;
 299     @DEV =  grep { $_ ne 'printer' } @DEV;
 300
 301     # If running as root, we will see .files in the ls result,
 302     # and readdir() will see them always.  Potential for conflict,
 303     # so let's weed them out.
 304     $DEV =~ s{^.+?\s\..+?$}{}m;
 305     @DEV =  grep { ! m{^\..+$} } @DEV;
 306
 307     # sometimes files cannot be stat'd on cygwin, making inspecting pointless
 308     # remove them from both @DEV and $DEV
 309     @DEV = grep $DEV =~ s/^.\?{9}.*\s$_(?: -> .*)?$//m ? () : $_, @DEV
 310       if $Is_Cygwin;
 311
 312     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 313     if ($^O eq 'irix') {
 314         $DEV =~ s{^S(.+?)}{s$1}mg;
 315     }
 316
 317     my $try = sub {
 318         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 319         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 320         my $c1 = scalar @c1;
 321         my $c2 = scalar @c2;
 322         diag "= before", $DEV, "-", @DEV, "= after", @c1, "-", @c2, "="
 323           unless is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 324     };
 325
 326 {
 327     $try->('b', '-b');
 328     $try->('c', '-c');
 329     $try->('s', '-S');
 330 }
 331
 332 ok(! -b $Curdir,    '!-b cwd');
 333 ok(! -c $Curdir,    '!-c cwd');
 334 ok(! -S $Curdir,    '!-S cwd');
 335
 336 }
 337
 338 SKIP: {
 339     my($cnt, $uid);
 340     $cnt = $uid = 0;
 341
 342     # Find a set of directories that's very likely to have setuid files
 343     # but not likely to be *all* setuid files.
 344     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 345     skip "Can't find a setuid file to test with", 3 unless @bin;
 346
 347     for my $bin (@bin) {
 348         opendir BIN, $bin or die "Can't opendir $bin: $!";
 349         while (defined($_ = readdir BIN)) {
 350             $_ = "$bin/$_";
 351             $cnt++;
 352             $uid++ if -u;
 353             last if $uid && $uid < $cnt;
 354         }
 355     }
 356     closedir BIN;
 357
 358     skip "No setuid programs", 3 if $uid == 0;
 359
 360     isnt($cnt, 0,    'found some programs');
 361     isnt($uid, 0,    '  found some setuid programs');
 362     ok($uid < $cnt,  "    they're not all setuid");
 363 }
 364
 365
 366 # To assist in automated testing when a controlling terminal (/dev/tty)
 367 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 368 # can be set to skip the tests that need a tty.
 369 SKIP: {
 370     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 371     skip "Skipping TTY tests on linux containers", 4 if $Is_linux_container;
 372
 373     my $TTY = "/dev/tty";
 374
 375     SKIP: {
 376         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 377         skip "No TTY to test -t with", 2 unless -e $TTY;
 378
 379         open(TTY, $TTY) ||
 380           warn "Can't open $TTY--run t/TEST outside of make.\n";
 381         ok(-t TTY,  '-t');
 382         ok(-c TTY,  'tty is -c');
 383         close(TTY);
 384     }
 385     ok(! -t TTY,    '!-t on closed TTY filehandle');
 386
 387     {
 388         local our $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 389         ok(-t,          '-t on STDIN');
 390     }
 391 }
 392
 393 SKIP: {
 394     skip "No null device to test with", 1 unless -e $Null;
 395     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 396
 397     open(NULL, $Null) or DIE("Can't open $Null: $!");
 398     ok(! -t NULL,   'null device is not a TTY');
 399     close(NULL);
 400 }
 401
 402
 403 # These aren't strictly "stat" calls, but so what?
 404 my $statfile = './op/stat.t';
 405 ok(  -T $statfile,    '-T');
 406 ok(! -B $statfile,    '!-B');
 407 ok(-B $Perl,      '-B');
 408 ok(! -T $Perl,    '!-T');
 409
 410 open(FOO,$statfile);
 411 SKIP: {
 412     eval { -T FOO; };
 413     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 414
 415     is( $@, '',     '-T on filehandle causes no errors' );
 416
 417     ok(-T FOO,      '   -T');
 418     ok(! -B FOO,    '   !-B');
 419
 420     $_ = <FOO>;
 421     like($_, qr/perl/, 'after readline');
 422     ok(-T FOO,      '   still -T');
 423     ok(! -B FOO,    '   still -B');
 424     close(FOO);
 425
 426     open(FOO,$statfile);
 427     $_ = <FOO>;
 428     like($_, qr/perl/,      'reopened and after readline');
 429     ok(-T FOO,      '   still -T');
 430     ok(! -B FOO,    '   still !-B');
 431
 432     ok(seek(FOO,0,0),   'after seek');
 433     ok(-T FOO,          '   still -T');
 434     ok(! -B FOO,        '   still !-B');
 435
 436     # It's documented this way in perlfunc *shrug*
 437     () = <FOO>;
 438     ok(eof FOO,         'at EOF');
 439     ok(-T FOO,          '   still -T');
 440     ok(-B FOO,          '   now -B');
 441 }
 442 close(FOO);
 443
 444
 445 SKIP: {
 446     skip "No null device to test with", 2 unless -e $Null;
 447
 448     ok(-T $Null,  'null device is -T');
 449     ok(-B $Null,  '    and -B');
 450 }
 451
 452
 453 # and now, a few parsing tests:
 454 $_ = $tmpfile;
 455 ok(-f,      'bare -f   uses $_');
 456 ok(-f(),    '     -f() "');
 457
 458 unlink $tmpfile or print "# unlink failed: $!\n";
 459
 460 # bug id 20011101.069 (#7861)
 461 my @r = \stat($Curdir);
 462 is(scalar @r, 13,   'stat returns full 13 elements');
 463
 464 stat $0;
 465 eval { lstat _ };
 466 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 467     'lstat _ croaks after stat' );
 468 eval { lstat *_ };
 469 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 470     'lstat *_ croaks after stat' );
 471 eval { lstat \*_ };
 472 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 473     'lstat \*_ croaks after stat' );
 474 eval { -l _ };
 475 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 476     '-l _ croaks after stat' );
 477
 478 lstat $0;
 479 eval { lstat _ };
 480 is( "$@", "", "lstat _ ok after lstat" );
 481 eval { -l _ };
 482 is( "$@", "", "-l _ ok after lstat" );
 483
 484 eval { lstat "test.pl" };
 485 {
 486     open my $fh, "test.pl";
 487     stat *$fh{IO};
 488     eval { lstat _ }
 489 }
 490 like $@, qr/^The stat preceding lstat\(\) wasn't an lstat at /,
 491 'stat $ioref resets stat type';
 492
 493 {
 494     open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
 495     my @statbuf = stat FOO;
 496     stat "test.pl";
 497     no warnings 'io';
 498     my @lstatbuf = lstat *FOO{IO};
 499     is "@lstatbuf", "@statbuf", 'lstat $ioref reverts to regular fstat';
 500     close(FOO);
 501     unlink $tmpfile or print "# unlink failed: $!\n";
 502 }
 503
 504 SKIP: {
 505     skip "No lstat", 2 unless $Config{d_lstat} && $Config{d_symlink};
 506
 507     # bug id 20020124.004 (#8334)
 508     my $linkname = 'stat-' . rand =~ y/.//dr;
 509     my $target = $Perl;
 510     $target =~ s/;\d+\z// if $Is_VMS; # symlinks don't like version numbers
 511     unless (symlink $target, $linkname) {
 512         if ($^O eq "MSWin32") {
 513             # likely we don't have permission
 514             skip "symlink failed: $!", 2;
 515         }
 516         die "# Can't symlink $0: $!";
 517     }
 518     lstat $linkname;
 519     -T _;
 520     eval { lstat _ };
 521     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 522         'lstat croaks after -T _' );
 523     eval { -l _ };
 524     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 525         '-l _ croaks after -T _' );
 526     unlink $linkname or print "# unlink $linkname failed: $!\n";
 527 }
 528
 529 SKIP: {
 530     skip "Too much clock skew between system and filesystem", 5
 531         if ($Filesystem_Time_Offset > 5);
 532     print "# Zzz...\n";
 533     sleep($Filesystem_Time_Offset+1);
 534     my $f = 'tstamp.tmp';
 535     unlink $f;
 536     ok (open(S, "> $f"), 'can create tmp file');
 537     close S or die;
 538     my @a = stat $f;
 539     print "# time=$^T, stat=(@a)\n";
 540     my @b = (-M _, -A _, -C _);
 541     print "# -MAC=(@b)\n";
 542     ok( (-M _) < 0, 'negative -M works');
 543   SKIP:
 544     {
 545         skip "Access timestamps inaccurate", 1 if $inaccurate_atime;
 546         ok( (-A _) < 0, 'negative -A works');
 547     }
 548     ok( (-C _) < 0, 'negative -C works');
 549     ok(unlink($f), 'unlink tmp file');
 550 }
 551
 552 # [perl #4253]
 553 {
 554     ok(open(F, ">", $tmpfile), 'can create temp file');
 555     close F;
 556     chmod 0077, $tmpfile;
 557     my @a = stat($tmpfile);
 558     my $s1 = -s _;
 559     -T _;
 560     my $s2 = -s _;
 561     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 562     SKIP: {
 563         my $root_uid = $Is_Cygwin ? 18 : 0;
 564         skip "No lstat", 1 unless $Config{d_lstat};
 565         skip "uid=0", 1 if $< == $root_uid or $> == $root_uid;
 566         skip "Can't check if admin user in miniperl", 1
 567           if $^O =~ /^(cygwin|MSWin32|msys)$/ && is_miniperl();
 568         skip "Readable by group/other means readable by me on $^O", 1 if $^O eq 'VMS'
 569           or ($^O =~ /^(cygwin|MSWin32|msys)$/ and Win32::IsAdminUser());
 570         lstat($tmpfile);
 571         -T _;
 572         ok(eval { lstat _ },
 573            q(-T _ doesn't break lstat for unreadable file));
 574     }
 575     unlink $tmpfile;
 576 }
 577
 578 SKIP: {
 579     skip "No dirfd()", 4 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 580     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 581     ok(stat(DIR), "stat() on dirhandle works");
 582     ok(-d -r _ , "chained -x's on dirhandle");
 583     ok(-d DIR, "-d on a dirhandle works");
 584     closedir DIR or die $!;
 585 }
 586
 587 {
 588     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 589     ok(open(F, ">", $tmpfile), 'can create temp file');
 590     my @thwap = stat *F{IO};
 591     ok(@thwap, "stat(*F{IO}) works");
 592     ok( -f *F{IO} , "single file tests work with *F{IO}");
 593     close F;
 594     unlink $tmpfile;
 595
 596     #PVIO's hold dirhandle information, so let's test them too.
 597
 598     SKIP: {
 599         skip "No dirfd()", 4 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 600         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 601         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 602         ok(-d _ , "The special file handle _ is set correctly");
 603         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 604         closedir DIR or die $!;
 605     }
 606 }
 607
 608 # [perl #71002]
 609 {
 610     my $w;
 611     local $SIG{__WARN__} = sub { warn shift; ++$w };
 612     stat 'prepeinamehyparcheiarcheiometoonomaavto';
 613     stat _;
 614     is $w, undef, 'no unopened warning from stat _';
 615 }
 616
 617 {
 618     # [perl #123816]
 619     # Inappropriate stacking of l?stat with filetests should either work or
 620     # give a syntax error, they shouldn't crash.
 621     eval { stat -t };
 622     ok(1, 'can "stat -t" without crashing');
 623         eval { lstat -t };
 624     ok(1, 'can "lstat -t" without crashing');
 625 }
 626
 627 # [perl #126064] stat stat stack busting
 628 is join("-", 1,2,3,(stat stat stat),4,5,6), "1-2-3-4-5-6",
 629   'stat inside stat gets scalar context';
 630
 631 # [perl #126162] stat an array should not work
 632 # skip if -e '2'.
 633 SKIP:
 634 {
 635     skip "There is a file named '2', which invalidates this test", 2 if -e '2';
 636
 637     my $Errno_loaded = eval { require Errno };
 638     my @statarg = ($statfile, $statfile);
 639     no warnings 'syntax';
 640     ok !stat(@statarg),
 641     'stat on an array of valid paths should warn and should not return any data';
 642     my $error = 0+$!;
 643     skip "Errno not available", 1
 644       unless $Errno_loaded;
 645     is $error, &Errno::ENOENT,
 646       'stat on an array of valid paths should return ENOENT';
 647 }
 648
 649 # [perl #131895] stat() doesn't fail on filenames containing \0 / NUL
 650 {
 651     no warnings 'syscalls';
 652     ok !stat("TEST\0-"), 'stat on filename with \0';
 653 }
 654 SKIP: {
 655     my $link = "stat_t_$$\_TEST.symlink";
 656     my $can_symlink = eval { symlink "TEST", $link };
 657     skip "cannot symlink", 1 unless $can_symlink;
 658     no warnings 'syscalls';
 659     ok !lstat("$link\0-"), 'lstat on filename with \0';
 660     unlink $link;
 661 }
 662
 663 END {
 664     chmod 0666, $tmpfile;
 665     unlink_all $tmpfile;
 666 }
 667
 668 sub _ingroup {
 669     my ($gid, $eff)   = @_;
 670
 671     $^O eq "VMS"    and return $_[0] == $);
 672
 673     my ($egid, @supp) = split " ", $);
 674     my ($rgid)        = split " ", $(;
 675
 676     $gid == ($eff ? $egid : $rgid)  and return 1;
 677     grep $gid == $_, @supp          and return 1;
 678
 679     return "";
 680 }